src/HOL/Hilbert_Choice.thy
author wenzelm
Mon Mar 16 18:24:30 2009 +0100 (2009-03-16)
changeset 30549 d2d7874648bd
parent 29655 ac31940cfb69
child 31380 f25536c0bb80
permissions -rw-r--r--
simplified method setup;
     1 (*  Title:      HOL/Hilbert_Choice.thy
     2     Author:     Lawrence C Paulson
     3     Copyright   2001  University of Cambridge
     4 *)
     5 
     6 header {* Hilbert's Epsilon-Operator and the Axiom of Choice *}
     7 
     8 theory Hilbert_Choice
     9 imports Nat Wellfounded Plain
    10 uses ("Tools/meson.ML") ("Tools/specification_package.ML")
    11 begin
    12 
    13 subsection {* Hilbert's epsilon *}
    14 
    15 axiomatization
    16   Eps :: "('a => bool) => 'a"
    17 where
    18   someI: "P x ==> P (Eps P)"
    19 
    20 syntax (epsilon)
    21   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3\<some>_./ _)" [0, 10] 10)
    22 syntax (HOL)
    23   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3@ _./ _)" [0, 10] 10)
    24 syntax
    25   "_Eps"        :: "[pttrn, bool] => 'a"    ("(3SOME _./ _)" [0, 10] 10)
    26 translations
    27   "SOME x. P" == "CONST Eps (%x. P)"
    28 
    29 print_translation {*
    30 (* to avoid eta-contraction of body *)
    31 [(@{const_syntax Eps}, fn [Abs abs] =>
    32      let val (x,t) = atomic_abs_tr' abs
    33      in Syntax.const "_Eps" $ x $ t end)]
    34 *}
    35 
    36 constdefs
    37   inv :: "('a => 'b) => ('b => 'a)"
    38   "inv(f :: 'a => 'b) == %y. SOME x. f x = y"
    39 
    40   Inv :: "'a set => ('a => 'b) => ('b => 'a)"
    41   "Inv A f == %x. SOME y. y \<in> A & f y = x"
    42 
    43 
    44 subsection {*Hilbert's Epsilon-operator*}
    45 
    46 text{*Easier to apply than @{text someI} if the witness comes from an
    47 existential formula*}
    48 lemma someI_ex [elim?]: "\<exists>x. P x ==> P (SOME x. P x)"
    49 apply (erule exE)
    50 apply (erule someI)
    51 done
    52 
    53 text{*Easier to apply than @{text someI} because the conclusion has only one
    54 occurrence of @{term P}.*}
    55 lemma someI2: "[| P a;  !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    56 by (blast intro: someI)
    57 
    58 text{*Easier to apply than @{text someI2} if the witness comes from an
    59 existential formula*}
    60 lemma someI2_ex: "[| \<exists>a. P a; !!x. P x ==> Q x |] ==> Q (SOME x. P x)"
    61 by (blast intro: someI2)
    62 
    63 lemma some_equality [intro]:
    64      "[| P a;  !!x. P x ==> x=a |] ==> (SOME x. P x) = a"
    65 by (blast intro: someI2)
    66 
    67 lemma some1_equality: "[| EX!x. P x; P a |] ==> (SOME x. P x) = a"
    68 by (blast intro: some_equality)
    69 
    70 lemma some_eq_ex: "P (SOME x. P x) =  (\<exists>x. P x)"
    71 by (blast intro: someI)
    72 
    73 lemma some_eq_trivial [simp]: "(SOME y. y=x) = x"
    74 apply (rule some_equality)
    75 apply (rule refl, assumption)
    76 done
    77 
    78 lemma some_sym_eq_trivial [simp]: "(SOME y. x=y) = x"
    79 apply (rule some_equality)
    80 apply (rule refl)
    81 apply (erule sym)
    82 done
    83 
    84 
    85 subsection{*Axiom of Choice, Proved Using the Description Operator*}
    86 
    87 text{*Used in @{text "Tools/meson.ML"}*}
    88 lemma choice: "\<forall>x. \<exists>y. Q x y ==> \<exists>f. \<forall>x. Q x (f x)"
    89 by (fast elim: someI)
    90 
    91 lemma bchoice: "\<forall>x\<in>S. \<exists>y. Q x y ==> \<exists>f. \<forall>x\<in>S. Q x (f x)"
    92 by (fast elim: someI)
    93 
    94 
    95 subsection {*Function Inverse*}
    96 
    97 lemma inv_id [simp]: "inv id = id"
    98 by (simp add: inv_def id_def)
    99 
   100 text{*A one-to-one function has an inverse.*}
   101 lemma inv_f_f [simp]: "inj f ==> inv f (f x) = x"
   102 by (simp add: inv_def inj_eq)
   103 
   104 lemma inv_f_eq: "[| inj f;  f x = y |] ==> inv f y = x"
   105 apply (erule subst)
   106 apply (erule inv_f_f)
   107 done
   108 
   109 lemma inj_imp_inv_eq: "[| inj f; \<forall>x. f(g x) = x |] ==> inv f = g"
   110 by (blast intro: ext inv_f_eq)
   111 
   112 text{*But is it useful?*}
   113 lemma inj_transfer:
   114   assumes injf: "inj f" and minor: "!!y. y \<in> range(f) ==> P(inv f y)"
   115   shows "P x"
   116 proof -
   117   have "f x \<in> range f" by auto
   118   hence "P(inv f (f x))" by (rule minor)
   119   thus "P x" by (simp add: inv_f_f [OF injf])
   120 qed
   121 
   122 
   123 lemma inj_iff: "(inj f) = (inv f o f = id)"
   124 apply (simp add: o_def expand_fun_eq)
   125 apply (blast intro: inj_on_inverseI inv_f_f)
   126 done
   127 
   128 lemma inv_o_cancel[simp]: "inj f ==> inv f o f = id"
   129 by (simp add: inj_iff)
   130 
   131 lemma o_inv_o_cancel[simp]: "inj f ==> g o inv f o f = g"
   132 by (simp add: o_assoc[symmetric])
   133 
   134 lemma inv_image_cancel[simp]:
   135   "inj f ==> inv f ` f ` S = S"
   136 by (simp add: image_compose[symmetric])
   137  
   138 lemma inj_imp_surj_inv: "inj f ==> surj (inv f)"
   139 by (blast intro: surjI inv_f_f)
   140 
   141 lemma f_inv_f: "y \<in> range(f) ==> f(inv f y) = y"
   142 apply (simp add: inv_def)
   143 apply (fast intro: someI)
   144 done
   145 
   146 lemma surj_f_inv_f: "surj f ==> f(inv f y) = y"
   147 by (simp add: f_inv_f surj_range)
   148 
   149 lemma inv_injective:
   150   assumes eq: "inv f x = inv f y"
   151       and x: "x: range f"
   152       and y: "y: range f"
   153   shows "x=y"
   154 proof -
   155   have "f (inv f x) = f (inv f y)" using eq by simp
   156   thus ?thesis by (simp add: f_inv_f x y) 
   157 qed
   158 
   159 lemma inj_on_inv: "A <= range(f) ==> inj_on (inv f) A"
   160 by (fast intro: inj_onI elim: inv_injective injD)
   161 
   162 lemma surj_imp_inj_inv: "surj f ==> inj (inv f)"
   163 by (simp add: inj_on_inv surj_range)
   164 
   165 lemma surj_iff: "(surj f) = (f o inv f = id)"
   166 apply (simp add: o_def expand_fun_eq)
   167 apply (blast intro: surjI surj_f_inv_f)
   168 done
   169 
   170 lemma surj_imp_inv_eq: "[| surj f; \<forall>x. g(f x) = x |] ==> inv f = g"
   171 apply (rule ext)
   172 apply (drule_tac x = "inv f x" in spec)
   173 apply (simp add: surj_f_inv_f)
   174 done
   175 
   176 lemma bij_imp_bij_inv: "bij f ==> bij (inv f)"
   177 by (simp add: bij_def inj_imp_surj_inv surj_imp_inj_inv)
   178 
   179 lemma inv_equality: "[| !!x. g (f x) = x;  !!y. f (g y) = y |] ==> inv f = g"
   180 apply (rule ext)
   181 apply (auto simp add: inv_def)
   182 done
   183 
   184 lemma inv_inv_eq: "bij f ==> inv (inv f) = f"
   185 apply (rule inv_equality)
   186 apply (auto simp add: bij_def surj_f_inv_f)
   187 done
   188 
   189 (** bij(inv f) implies little about f.  Consider f::bool=>bool such that
   190     f(True)=f(False)=True.  Then it's consistent with axiom someI that
   191     inv f could be any function at all, including the identity function.
   192     If inv f=id then inv f is a bijection, but inj f, surj(f) and
   193     inv(inv f)=f all fail.
   194 **)
   195 
   196 lemma o_inv_distrib: "[| bij f; bij g |] ==> inv (f o g) = inv g o inv f"
   197 apply (rule inv_equality)
   198 apply (auto simp add: bij_def surj_f_inv_f)
   199 done
   200 
   201 
   202 lemma image_surj_f_inv_f: "surj f ==> f ` (inv f ` A) = A"
   203 by (simp add: image_eq_UN surj_f_inv_f)
   204 
   205 lemma image_inv_f_f: "inj f ==> (inv f) ` (f ` A) = A"
   206 by (simp add: image_eq_UN)
   207 
   208 lemma inv_image_comp: "inj f ==> inv f ` (f`X) = X"
   209 by (auto simp add: image_def)
   210 
   211 lemma bij_image_Collect_eq: "bij f ==> f ` Collect P = {y. P (inv f y)}"
   212 apply auto
   213 apply (force simp add: bij_is_inj)
   214 apply (blast intro: bij_is_surj [THEN surj_f_inv_f, symmetric])
   215 done
   216 
   217 lemma bij_vimage_eq_inv_image: "bij f ==> f -` A = inv f ` A" 
   218 apply (auto simp add: bij_is_surj [THEN surj_f_inv_f])
   219 apply (blast intro: bij_is_inj [THEN inv_f_f, symmetric])
   220 done
   221 
   222 
   223 subsection {*Inverse of a PI-function (restricted domain)*}
   224 
   225 lemma Inv_f_f: "[| inj_on f A;  x \<in> A |] ==> Inv A f (f x) = x"
   226 apply (simp add: Inv_def inj_on_def)
   227 apply (blast intro: someI2)
   228 done
   229 
   230 lemma f_Inv_f: "y \<in> f`A  ==> f (Inv A f y) = y"
   231 apply (simp add: Inv_def)
   232 apply (fast intro: someI2)
   233 done
   234 
   235 lemma Inv_injective:
   236   assumes eq: "Inv A f x = Inv A f y"
   237       and x: "x: f`A"
   238       and y: "y: f`A"
   239   shows "x=y"
   240 proof -
   241   have "f (Inv A f x) = f (Inv A f y)" using eq by simp
   242   thus ?thesis by (simp add: f_Inv_f x y) 
   243 qed
   244 
   245 lemma inj_on_Inv: "B <= f`A ==> inj_on (Inv A f) B"
   246 apply (rule inj_onI)
   247 apply (blast intro: inj_onI dest: Inv_injective injD)
   248 done
   249 
   250 lemma Inv_mem: "[| f ` A = B;  x \<in> B |] ==> Inv A f x \<in> A"
   251 apply (simp add: Inv_def)
   252 apply (fast intro: someI2)
   253 done
   254 
   255 lemma Inv_f_eq: "[| inj_on f A; f x = y; x \<in> A |] ==> Inv A f y = x"
   256   apply (erule subst)
   257   apply (erule Inv_f_f, assumption)
   258   done
   259 
   260 lemma Inv_comp:
   261   "[| inj_on f (g ` A); inj_on g A; x \<in> f ` g ` A |] ==>
   262   Inv A (f o g) x = (Inv A g o Inv (g ` A) f) x"
   263   apply simp
   264   apply (rule Inv_f_eq)
   265     apply (fast intro: comp_inj_on)
   266    apply (simp add: f_Inv_f Inv_mem)
   267   apply (simp add: Inv_mem)
   268   done
   269 
   270 lemma bij_betw_Inv: "bij_betw f A B \<Longrightarrow> bij_betw (Inv A f) B A"
   271   apply (auto simp add: bij_betw_def inj_on_Inv Inv_mem)
   272   apply (simp add: image_compose [symmetric] o_def)
   273   apply (simp add: image_def Inv_f_f)
   274   done
   275 
   276 subsection {*Other Consequences of Hilbert's Epsilon*}
   277 
   278 text {*Hilbert's Epsilon and the @{term split} Operator*}
   279 
   280 text{*Looping simprule*}
   281 lemma split_paired_Eps: "(SOME x. P x) = (SOME (a,b). P(a,b))"
   282   by simp
   283 
   284 lemma Eps_split: "Eps (split P) = (SOME xy. P (fst xy) (snd xy))"
   285   by (simp add: split_def)
   286 
   287 lemma Eps_split_eq [simp]: "(@(x',y'). x = x' & y = y') = (x,y)"
   288   by blast
   289 
   290 
   291 text{*A relation is wellfounded iff it has no infinite descending chain*}
   292 lemma wf_iff_no_infinite_down_chain:
   293   "wf r = (~(\<exists>f. \<forall>i. (f(Suc i),f i) \<in> r))"
   294 apply (simp only: wf_eq_minimal)
   295 apply (rule iffI)
   296  apply (rule notI)
   297  apply (erule exE)
   298  apply (erule_tac x = "{w. \<exists>i. w=f i}" in allE, blast)
   299 apply (erule contrapos_np, simp, clarify)
   300 apply (subgoal_tac "\<forall>n. nat_rec x (%i y. @z. z:Q & (z,y) :r) n \<in> Q")
   301  apply (rule_tac x = "nat_rec x (%i y. @z. z:Q & (z,y) :r)" in exI)
   302  apply (rule allI, simp)
   303  apply (rule someI2_ex, blast, blast)
   304 apply (rule allI)
   305 apply (induct_tac "n", simp_all)
   306 apply (rule someI2_ex, blast+)
   307 done
   308 
   309 lemma wf_no_infinite_down_chainE:
   310   assumes "wf r" obtains k where "(f (Suc k), f k) \<notin> r"
   311 using `wf r` wf_iff_no_infinite_down_chain[of r] by blast
   312 
   313 
   314 text{*A dynamically-scoped fact for TFL *}
   315 lemma tfl_some: "\<forall>P x. P x --> P (Eps P)"
   316   by (blast intro: someI)
   317 
   318 
   319 subsection {* Least value operator *}
   320 
   321 constdefs
   322   LeastM :: "['a => 'b::ord, 'a => bool] => 'a"
   323   "LeastM m P == SOME x. P x & (\<forall>y. P y --> m x <= m y)"
   324 
   325 syntax
   326   "_LeastM" :: "[pttrn, 'a => 'b::ord, bool] => 'a"    ("LEAST _ WRT _. _" [0, 4, 10] 10)
   327 translations
   328   "LEAST x WRT m. P" == "LeastM m (%x. P)"
   329 
   330 lemma LeastMI2:
   331   "P x ==> (!!y. P y ==> m x <= m y)
   332     ==> (!!x. P x ==> \<forall>y. P y --> m x \<le> m y ==> Q x)
   333     ==> Q (LeastM m P)"
   334   apply (simp add: LeastM_def)
   335   apply (rule someI2_ex, blast, blast)
   336   done
   337 
   338 lemma LeastM_equality:
   339   "P k ==> (!!x. P x ==> m k <= m x)
   340     ==> m (LEAST x WRT m. P x) = (m k::'a::order)"
   341   apply (rule LeastMI2, assumption, blast)
   342   apply (blast intro!: order_antisym)
   343   done
   344 
   345 lemma wf_linord_ex_has_least:
   346   "wf r ==> \<forall>x y. ((x,y):r^+) = ((y,x)~:r^*) ==> P k
   347     ==> \<exists>x. P x & (!y. P y --> (m x,m y):r^*)"
   348   apply (drule wf_trancl [THEN wf_eq_minimal [THEN iffD1]])
   349   apply (drule_tac x = "m`Collect P" in spec, force)
   350   done
   351 
   352 lemma ex_has_least_nat:
   353     "P k ==> \<exists>x. P x & (\<forall>y. P y --> m x <= (m y::nat))"
   354   apply (simp only: pred_nat_trancl_eq_le [symmetric])
   355   apply (rule wf_pred_nat [THEN wf_linord_ex_has_least])
   356    apply (simp add: less_eq linorder_not_le pred_nat_trancl_eq_le, assumption)
   357   done
   358 
   359 lemma LeastM_nat_lemma:
   360     "P k ==> P (LeastM m P) & (\<forall>y. P y --> m (LeastM m P) <= (m y::nat))"
   361   apply (simp add: LeastM_def)
   362   apply (rule someI_ex)
   363   apply (erule ex_has_least_nat)
   364   done
   365 
   366 lemmas LeastM_natI = LeastM_nat_lemma [THEN conjunct1, standard]
   367 
   368 lemma LeastM_nat_le: "P x ==> m (LeastM m P) <= (m x::nat)"
   369 by (rule LeastM_nat_lemma [THEN conjunct2, THEN spec, THEN mp], assumption, assumption)
   370 
   371 
   372 subsection {* Greatest value operator *}
   373 
   374 constdefs
   375   GreatestM :: "['a => 'b::ord, 'a => bool] => 'a"
   376   "GreatestM m P == SOME x. P x & (\<forall>y. P y --> m y <= m x)"
   377 
   378   Greatest :: "('a::ord => bool) => 'a"    (binder "GREATEST " 10)
   379   "Greatest == GreatestM (%x. x)"
   380 
   381 syntax
   382   "_GreatestM" :: "[pttrn, 'a=>'b::ord, bool] => 'a"
   383       ("GREATEST _ WRT _. _" [0, 4, 10] 10)
   384 
   385 translations
   386   "GREATEST x WRT m. P" == "GreatestM m (%x. P)"
   387 
   388 lemma GreatestMI2:
   389   "P x ==> (!!y. P y ==> m y <= m x)
   390     ==> (!!x. P x ==> \<forall>y. P y --> m y \<le> m x ==> Q x)
   391     ==> Q (GreatestM m P)"
   392   apply (simp add: GreatestM_def)
   393   apply (rule someI2_ex, blast, blast)
   394   done
   395 
   396 lemma GreatestM_equality:
   397  "P k ==> (!!x. P x ==> m x <= m k)
   398     ==> m (GREATEST x WRT m. P x) = (m k::'a::order)"
   399   apply (rule_tac m = m in GreatestMI2, assumption, blast)
   400   apply (blast intro!: order_antisym)
   401   done
   402 
   403 lemma Greatest_equality:
   404   "P (k::'a::order) ==> (!!x. P x ==> x <= k) ==> (GREATEST x. P x) = k"
   405   apply (simp add: Greatest_def)
   406   apply (erule GreatestM_equality, blast)
   407   done
   408 
   409 lemma ex_has_greatest_nat_lemma:
   410   "P k ==> \<forall>x. P x --> (\<exists>y. P y & ~ ((m y::nat) <= m x))
   411     ==> \<exists>y. P y & ~ (m y < m k + n)"
   412   apply (induct n, force)
   413   apply (force simp add: le_Suc_eq)
   414   done
   415 
   416 lemma ex_has_greatest_nat:
   417   "P k ==> \<forall>y. P y --> m y < b
   418     ==> \<exists>x. P x & (\<forall>y. P y --> (m y::nat) <= m x)"
   419   apply (rule ccontr)
   420   apply (cut_tac P = P and n = "b - m k" in ex_has_greatest_nat_lemma)
   421     apply (subgoal_tac [3] "m k <= b", auto)
   422   done
   423 
   424 lemma GreatestM_nat_lemma:
   425   "P k ==> \<forall>y. P y --> m y < b
   426     ==> P (GreatestM m P) & (\<forall>y. P y --> (m y::nat) <= m (GreatestM m P))"
   427   apply (simp add: GreatestM_def)
   428   apply (rule someI_ex)
   429   apply (erule ex_has_greatest_nat, assumption)
   430   done
   431 
   432 lemmas GreatestM_natI = GreatestM_nat_lemma [THEN conjunct1, standard]
   433 
   434 lemma GreatestM_nat_le:
   435   "P x ==> \<forall>y. P y --> m y < b
   436     ==> (m x::nat) <= m (GreatestM m P)"
   437   apply (blast dest: GreatestM_nat_lemma [THEN conjunct2, THEN spec, of P])
   438   done
   439 
   440 
   441 text {* \medskip Specialization to @{text GREATEST}. *}
   442 
   443 lemma GreatestI: "P (k::nat) ==> \<forall>y. P y --> y < b ==> P (GREATEST x. P x)"
   444   apply (simp add: Greatest_def)
   445   apply (rule GreatestM_natI, auto)
   446   done
   447 
   448 lemma Greatest_le:
   449     "P x ==> \<forall>y. P y --> y < b ==> (x::nat) <= (GREATEST x. P x)"
   450   apply (simp add: Greatest_def)
   451   apply (rule GreatestM_nat_le, auto)
   452   done
   453 
   454 
   455 subsection {* The Meson proof procedure *}
   456 
   457 subsubsection {* Negation Normal Form *}
   458 
   459 text {* de Morgan laws *}
   460 
   461 lemma meson_not_conjD: "~(P&Q) ==> ~P | ~Q"
   462   and meson_not_disjD: "~(P|Q) ==> ~P & ~Q"
   463   and meson_not_notD: "~~P ==> P"
   464   and meson_not_allD: "!!P. ~(\<forall>x. P(x)) ==> \<exists>x. ~P(x)"
   465   and meson_not_exD: "!!P. ~(\<exists>x. P(x)) ==> \<forall>x. ~P(x)"
   466   by fast+
   467 
   468 text {* Removal of @{text "-->"} and @{text "<->"} (positive and
   469 negative occurrences) *}
   470 
   471 lemma meson_imp_to_disjD: "P-->Q ==> ~P | Q"
   472   and meson_not_impD: "~(P-->Q) ==> P & ~Q"
   473   and meson_iff_to_disjD: "P=Q ==> (~P | Q) & (~Q | P)"
   474   and meson_not_iffD: "~(P=Q) ==> (P | Q) & (~P | ~Q)"
   475     -- {* Much more efficient than @{prop "(P & ~Q) | (Q & ~P)"} for computing CNF *}
   476   and meson_not_refl_disj_D: "x ~= x | P ==> P"
   477   by fast+
   478 
   479 
   480 subsubsection {* Pulling out the existential quantifiers *}
   481 
   482 text {* Conjunction *}
   483 
   484 lemma meson_conj_exD1: "!!P Q. (\<exists>x. P(x)) & Q ==> \<exists>x. P(x) & Q"
   485   and meson_conj_exD2: "!!P Q. P & (\<exists>x. Q(x)) ==> \<exists>x. P & Q(x)"
   486   by fast+
   487 
   488 
   489 text {* Disjunction *}
   490 
   491 lemma meson_disj_exD: "!!P Q. (\<exists>x. P(x)) | (\<exists>x. Q(x)) ==> \<exists>x. P(x) | Q(x)"
   492   -- {* DO NOT USE with forall-Skolemization: makes fewer schematic variables!! *}
   493   -- {* With ex-Skolemization, makes fewer Skolem constants *}
   494   and meson_disj_exD1: "!!P Q. (\<exists>x. P(x)) | Q ==> \<exists>x. P(x) | Q"
   495   and meson_disj_exD2: "!!P Q. P | (\<exists>x. Q(x)) ==> \<exists>x. P | Q(x)"
   496   by fast+
   497 
   498 
   499 subsubsection {* Generating clauses for the Meson Proof Procedure *}
   500 
   501 text {* Disjunctions *}
   502 
   503 lemma meson_disj_assoc: "(P|Q)|R ==> P|(Q|R)"
   504   and meson_disj_comm: "P|Q ==> Q|P"
   505   and meson_disj_FalseD1: "False|P ==> P"
   506   and meson_disj_FalseD2: "P|False ==> P"
   507   by fast+
   508 
   509 
   510 subsection{*Lemmas for Meson, the Model Elimination Procedure*}
   511 
   512 text{* Generation of contrapositives *}
   513 
   514 text{*Inserts negated disjunct after removing the negation; P is a literal.
   515   Model elimination requires assuming the negation of every attempted subgoal,
   516   hence the negated disjuncts.*}
   517 lemma make_neg_rule: "~P|Q ==> ((~P==>P) ==> Q)"
   518 by blast
   519 
   520 text{*Version for Plaisted's "Postive refinement" of the Meson procedure*}
   521 lemma make_refined_neg_rule: "~P|Q ==> (P ==> Q)"
   522 by blast
   523 
   524 text{*@{term P} should be a literal*}
   525 lemma make_pos_rule: "P|Q ==> ((P==>~P) ==> Q)"
   526 by blast
   527 
   528 text{*Versions of @{text make_neg_rule} and @{text make_pos_rule} that don't
   529 insert new assumptions, for ordinary resolution.*}
   530 
   531 lemmas make_neg_rule' = make_refined_neg_rule
   532 
   533 lemma make_pos_rule': "[|P|Q; ~P|] ==> Q"
   534 by blast
   535 
   536 text{* Generation of a goal clause -- put away the final literal *}
   537 
   538 lemma make_neg_goal: "~P ==> ((~P==>P) ==> False)"
   539 by blast
   540 
   541 lemma make_pos_goal: "P ==> ((P==>~P) ==> False)"
   542 by blast
   543 
   544 
   545 subsubsection{* Lemmas for Forward Proof*}
   546 
   547 text{*There is a similarity to congruence rules*}
   548 
   549 (*NOTE: could handle conjunctions (faster?) by
   550     nf(th RS conjunct2) RS (nf(th RS conjunct1) RS conjI) *)
   551 lemma conj_forward: "[| P'&Q';  P' ==> P;  Q' ==> Q |] ==> P&Q"
   552 by blast
   553 
   554 lemma disj_forward: "[| P'|Q';  P' ==> P;  Q' ==> Q |] ==> P|Q"
   555 by blast
   556 
   557 (*Version of @{text disj_forward} for removal of duplicate literals*)
   558 lemma disj_forward2:
   559     "[| P'|Q';  P' ==> P;  [| Q'; P==>False |] ==> Q |] ==> P|Q"
   560 apply blast 
   561 done
   562 
   563 lemma all_forward: "[| \<forall>x. P'(x);  !!x. P'(x) ==> P(x) |] ==> \<forall>x. P(x)"
   564 by blast
   565 
   566 lemma ex_forward: "[| \<exists>x. P'(x);  !!x. P'(x) ==> P(x) |] ==> \<exists>x. P(x)"
   567 by blast
   568 
   569 
   570 text{*Many of these bindings are used by the ATP linkup, and not just by
   571 legacy proof scripts.*}
   572 ML
   573 {*
   574 val inv_def = thm "inv_def";
   575 val Inv_def = thm "Inv_def";
   576 
   577 val someI = thm "someI";
   578 val someI_ex = thm "someI_ex";
   579 val someI2 = thm "someI2";
   580 val someI2_ex = thm "someI2_ex";
   581 val some_equality = thm "some_equality";
   582 val some1_equality = thm "some1_equality";
   583 val some_eq_ex = thm "some_eq_ex";
   584 val some_eq_trivial = thm "some_eq_trivial";
   585 val some_sym_eq_trivial = thm "some_sym_eq_trivial";
   586 val choice = thm "choice";
   587 val bchoice = thm "bchoice";
   588 val inv_id = thm "inv_id";
   589 val inv_f_f = thm "inv_f_f";
   590 val inv_f_eq = thm "inv_f_eq";
   591 val inj_imp_inv_eq = thm "inj_imp_inv_eq";
   592 val inj_transfer = thm "inj_transfer";
   593 val inj_iff = thm "inj_iff";
   594 val inj_imp_surj_inv = thm "inj_imp_surj_inv";
   595 val f_inv_f = thm "f_inv_f";
   596 val surj_f_inv_f = thm "surj_f_inv_f";
   597 val inv_injective = thm "inv_injective";
   598 val inj_on_inv = thm "inj_on_inv";
   599 val surj_imp_inj_inv = thm "surj_imp_inj_inv";
   600 val surj_iff = thm "surj_iff";
   601 val surj_imp_inv_eq = thm "surj_imp_inv_eq";
   602 val bij_imp_bij_inv = thm "bij_imp_bij_inv";
   603 val inv_equality = thm "inv_equality";
   604 val inv_inv_eq = thm "inv_inv_eq";
   605 val o_inv_distrib = thm "o_inv_distrib";
   606 val image_surj_f_inv_f = thm "image_surj_f_inv_f";
   607 val image_inv_f_f = thm "image_inv_f_f";
   608 val inv_image_comp = thm "inv_image_comp";
   609 val bij_image_Collect_eq = thm "bij_image_Collect_eq";
   610 val bij_vimage_eq_inv_image = thm "bij_vimage_eq_inv_image";
   611 val Inv_f_f = thm "Inv_f_f";
   612 val f_Inv_f = thm "f_Inv_f";
   613 val Inv_injective = thm "Inv_injective";
   614 val inj_on_Inv = thm "inj_on_Inv";
   615 val split_paired_Eps = thm "split_paired_Eps";
   616 val Eps_split = thm "Eps_split";
   617 val Eps_split_eq = thm "Eps_split_eq";
   618 val wf_iff_no_infinite_down_chain = thm "wf_iff_no_infinite_down_chain";
   619 val Inv_mem = thm "Inv_mem";
   620 val Inv_f_eq = thm "Inv_f_eq";
   621 val Inv_comp = thm "Inv_comp";
   622 val tfl_some = thm "tfl_some";
   623 val make_neg_rule = thm "make_neg_rule";
   624 val make_refined_neg_rule = thm "make_refined_neg_rule";
   625 val make_pos_rule = thm "make_pos_rule";
   626 val make_neg_rule' = thm "make_neg_rule'";
   627 val make_pos_rule' = thm "make_pos_rule'";
   628 val make_neg_goal = thm "make_neg_goal";
   629 val make_pos_goal = thm "make_pos_goal";
   630 val conj_forward = thm "conj_forward";
   631 val disj_forward = thm "disj_forward";
   632 val disj_forward2 = thm "disj_forward2";
   633 val all_forward = thm "all_forward";
   634 val ex_forward = thm "ex_forward";
   635 *}
   636 
   637 
   638 subsection {* Meson package *}
   639 
   640 use "Tools/meson.ML"
   641 
   642 setup Meson.setup
   643 
   644 
   645 subsection {* Specification package -- Hilbertized version *}
   646 
   647 lemma exE_some: "[| Ex P ; c == Eps P |] ==> P c"
   648   by (simp only: someI_ex)
   649 
   650 use "Tools/specification_package.ML"
   651 
   652 end