src/HOL/Set.ML
author paulson
Wed Dec 02 15:53:05 1998 +0100 (1998-12-02)
changeset 6006 d2e271b8d651
parent 5931 325300576da7
child 6171 cd237a10cbf8
permissions -rw-r--r--
new rule rev_bexI
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 open Set;
    10 
    11 section "Relating predicates and sets";
    12 
    13 Addsimps [Collect_mem_eq];
    14 AddIffs  [mem_Collect_eq];
    15 
    16 Goal "P(a) ==> a : {x. P(x)}";
    17 by (Asm_simp_tac 1);
    18 qed "CollectI";
    19 
    20 Goal "a : {x. P(x)} ==> P(a)";
    21 by (Asm_full_simp_tac 1);
    22 qed "CollectD";
    23 
    24 val [prem] = Goal "[| !!x. (x:A) = (x:B) |] ==> A = B";
    25 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    26 by (rtac Collect_mem_eq 1);
    27 by (rtac Collect_mem_eq 1);
    28 qed "set_ext";
    29 
    30 val [prem] = Goal "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    31 by (rtac (prem RS ext RS arg_cong) 1);
    32 qed "Collect_cong";
    33 
    34 val CollectE = make_elim CollectD;
    35 
    36 AddSIs [CollectI];
    37 AddSEs [CollectE];
    38 
    39 
    40 section "Bounded quantifiers";
    41 
    42 val prems = Goalw [Ball_def]
    43     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    44 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    45 qed "ballI";
    46 
    47 Goalw [Ball_def] "[| ! x:A. P(x);  x:A |] ==> P(x)";
    48 by (Blast_tac 1);
    49 qed "bspec";
    50 
    51 val major::prems = Goalw [Ball_def]
    52     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    53 by (rtac (major RS spec RS impCE) 1);
    54 by (REPEAT (eresolve_tac prems 1));
    55 qed "ballE";
    56 
    57 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    58 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    59 
    60 AddSIs [ballI];
    61 AddEs  [ballE];
    62 (* gives better instantiation for bound: *)
    63 claset_ref() := claset() addWrapper ("bspec", fn tac2 =>
    64 			 (dtac bspec THEN' atac) APPEND' tac2);
    65 
    66 (*Normally the best argument order: P(x) constrains the choice of x:A*)
    67 Goalw [Bex_def] "[| P(x);  x:A |] ==> ? x:A. P(x)";
    68 by (Blast_tac 1);
    69 qed "bexI";
    70 
    71 (*The best argument order when there is only one x:A*)
    72 Goalw [Bex_def] "[| x:A;  P(x) |] ==> ? x:A. P(x)";
    73 by (Blast_tac 1);
    74 qed "rev_bexI";
    75 
    76 qed_goal "bexCI" Set.thy 
    77    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A. P(x)" (fn prems =>
    78   [ (rtac classical 1),
    79     (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ]);
    80 
    81 val major::prems = Goalw [Bex_def]
    82     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    83 by (rtac (major RS exE) 1);
    84 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    85 qed "bexE";
    86 
    87 AddIs  [bexI];
    88 AddSEs [bexE];
    89 
    90 (*Trival rewrite rule*)
    91 Goal "(! x:A. P) = ((? x. x:A) --> P)";
    92 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    93 qed "ball_triv";
    94 
    95 (*Dual form for existentials*)
    96 Goal "(? x:A. P) = ((? x. x:A) & P)";
    97 by (simp_tac (simpset() addsimps [Bex_def]) 1);
    98 qed "bex_triv";
    99 
   100 Addsimps [ball_triv, bex_triv];
   101 
   102 (** Congruence rules **)
   103 
   104 val prems = Goal
   105     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   106 \    (! x:A. P(x)) = (! x:B. Q(x))";
   107 by (resolve_tac (prems RL [ssubst]) 1);
   108 by (REPEAT (ares_tac [ballI,iffI] 1
   109      ORELSE eresolve_tac ([make_elim bspec, mp] @ (prems RL [iffE])) 1));
   110 qed "ball_cong";
   111 
   112 val prems = Goal
   113     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   114 \    (? x:A. P(x)) = (? x:B. Q(x))";
   115 by (resolve_tac (prems RL [ssubst]) 1);
   116 by (REPEAT (etac bexE 1
   117      ORELSE ares_tac ([bexI,iffI] @ (prems RL [iffD1,iffD2])) 1));
   118 qed "bex_cong";
   119 
   120 section "Subsets";
   121 
   122 val prems = Goalw [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   123 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   124 qed "subsetI";
   125 
   126 (*Map the type ('a set => anything) to just 'a.
   127   For overloading constants whose first argument has type "'a set" *)
   128 fun overload_1st_set s = Blast.overloaded (s, HOLogic.dest_setT o domain_type);
   129 
   130 (*While (:) is not, its type must be kept
   131   for overloading of = to work.*)
   132 Blast.overloaded ("op :", domain_type);
   133 
   134 overload_1st_set "Ball";		(*need UNION, INTER also?*)
   135 overload_1st_set "Bex";
   136 
   137 (*Image: retain the type of the set being expressed*)
   138 Blast.overloaded ("op ``", domain_type);
   139 
   140 (*Rule in Modus Ponens style*)
   141 Goalw [subset_def] "[| A <= B;  c:A |] ==> c:B";
   142 by (Blast_tac 1);
   143 qed "subsetD";
   144 
   145 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   146 qed_goal "rev_subsetD" Set.thy "[| c:A;  A <= B |] ==> c:B"
   147  (fn prems=>  [ (REPEAT (resolve_tac (prems@[subsetD]) 1)) ]);
   148 
   149 (*Converts A<=B to x:A ==> x:B*)
   150 fun impOfSubs th = th RSN (2, rev_subsetD);
   151 
   152 qed_goal "contra_subsetD" Set.thy "!!c. [| A <= B; c ~: B |] ==> c ~: A"
   153  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   154 
   155 qed_goal "rev_contra_subsetD" Set.thy "!!c. [| c ~: B;  A <= B |] ==> c ~: A"
   156  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   157 
   158 (*Classical elimination rule*)
   159 val major::prems = Goalw [subset_def] 
   160     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   161 by (rtac (major RS ballE) 1);
   162 by (REPEAT (eresolve_tac prems 1));
   163 qed "subsetCE";
   164 
   165 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   166 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   167 
   168 AddSIs [subsetI];
   169 AddEs  [subsetD, subsetCE];
   170 
   171 qed_goal "subset_refl" Set.thy "A <= (A::'a set)"
   172  (fn _=> [Fast_tac 1]);		(*Blast_tac would try order_refl and fail*)
   173 
   174 Goal "[| A<=B;  B<=C |] ==> A<=(C::'a set)";
   175 by (Blast_tac 1);
   176 qed "subset_trans";
   177 
   178 
   179 section "Equality";
   180 
   181 (*Anti-symmetry of the subset relation*)
   182 Goal "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   183 by (rtac set_ext 1);
   184 by (blast_tac (claset() addIs [subsetD]) 1);
   185 qed "subset_antisym";
   186 val equalityI = subset_antisym;
   187 
   188 AddSIs [equalityI];
   189 
   190 (* Equality rules from ZF set theory -- are they appropriate here? *)
   191 Goal "A = B ==> A<=(B::'a set)";
   192 by (etac ssubst 1);
   193 by (rtac subset_refl 1);
   194 qed "equalityD1";
   195 
   196 Goal "A = B ==> B<=(A::'a set)";
   197 by (etac ssubst 1);
   198 by (rtac subset_refl 1);
   199 qed "equalityD2";
   200 
   201 val prems = Goal
   202     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   203 by (resolve_tac prems 1);
   204 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   205 qed "equalityE";
   206 
   207 val major::prems = Goal
   208     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   209 by (rtac (major RS equalityE) 1);
   210 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   211 qed "equalityCE";
   212 
   213 (*Lemma for creating induction formulae -- for "pattern matching" on p
   214   To make the induction hypotheses usable, apply "spec" or "bspec" to
   215   put universal quantifiers over the free variables in p. *)
   216 val prems = Goal 
   217     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   218 by (rtac mp 1);
   219 by (REPEAT (resolve_tac (refl::prems) 1));
   220 qed "setup_induction";
   221 
   222 
   223 section "The universal set -- UNIV";
   224 
   225 qed_goalw "UNIV_I" Set.thy [UNIV_def] "x : UNIV"
   226   (fn _ => [rtac CollectI 1, rtac TrueI 1]);
   227 
   228 Addsimps [UNIV_I];
   229 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   230 
   231 qed_goal "subset_UNIV" Set.thy "A <= UNIV"
   232   (fn _ => [rtac subsetI 1, rtac UNIV_I 1]);
   233 
   234 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   235     because of their interaction with congruence rules. **)
   236 
   237 Goalw [Ball_def] "Ball UNIV P = All P";
   238 by (Simp_tac 1);
   239 qed "ball_UNIV";
   240 
   241 Goalw [Bex_def] "Bex UNIV P = Ex P";
   242 by (Simp_tac 1);
   243 qed "bex_UNIV";
   244 Addsimps [ball_UNIV, bex_UNIV];
   245 
   246 
   247 section "The empty set -- {}";
   248 
   249 qed_goalw "empty_iff" Set.thy [empty_def] "(c : {}) = False"
   250  (fn _ => [ (Blast_tac 1) ]);
   251 
   252 Addsimps [empty_iff];
   253 
   254 qed_goal "emptyE" Set.thy "!!a. a:{} ==> P"
   255  (fn _ => [Full_simp_tac 1]);
   256 
   257 AddSEs [emptyE];
   258 
   259 qed_goal "empty_subsetI" Set.thy "{} <= A"
   260  (fn _ => [ (Blast_tac 1) ]);
   261 
   262 (*One effect is to delete the ASSUMPTION {} <= A*)
   263 AddIffs [empty_subsetI];
   264 
   265 qed_goal "equals0I" Set.thy "[| !!y. y:A ==> False |] ==> A={}"
   266  (fn [prem]=>
   267   [ (blast_tac (claset() addIs [prem RS FalseE]) 1) ]);
   268 
   269 (*Use for reasoning about disjointness: A Int B = {} *)
   270 qed_goal "equals0D" Set.thy "!!a. A={} ==> a ~: A"
   271  (fn _ => [ (Blast_tac 1) ]);
   272 
   273 AddDs [equals0D, sym RS equals0D];
   274 
   275 Goalw [Ball_def] "Ball {} P = True";
   276 by (Simp_tac 1);
   277 qed "ball_empty";
   278 
   279 Goalw [Bex_def] "Bex {} P = False";
   280 by (Simp_tac 1);
   281 qed "bex_empty";
   282 Addsimps [ball_empty, bex_empty];
   283 
   284 Goal "UNIV ~= {}";
   285 by (blast_tac (claset() addEs [equalityE]) 1);
   286 qed "UNIV_not_empty";
   287 AddIffs [UNIV_not_empty];
   288 
   289 
   290 
   291 section "The Powerset operator -- Pow";
   292 
   293 qed_goalw "Pow_iff" Set.thy [Pow_def] "(A : Pow(B)) = (A <= B)"
   294  (fn _ => [ (Asm_simp_tac 1) ]);
   295 
   296 AddIffs [Pow_iff]; 
   297 
   298 qed_goalw "PowI" Set.thy [Pow_def] "!!A B. A <= B ==> A : Pow(B)"
   299  (fn _ => [ (etac CollectI 1) ]);
   300 
   301 qed_goalw "PowD" Set.thy [Pow_def] "!!A B. A : Pow(B)  ==>  A<=B"
   302  (fn _=> [ (etac CollectD 1) ]);
   303 
   304 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   305 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   306 
   307 
   308 section "Set complement";
   309 
   310 qed_goalw "Compl_iff" Set.thy [Compl_def] "(c : -A) = (c~:A)"
   311  (fn _ => [ (Blast_tac 1) ]);
   312 
   313 Addsimps [Compl_iff];
   314 
   315 val prems = Goalw [Compl_def] "[| c:A ==> False |] ==> c : -A";
   316 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   317 qed "ComplI";
   318 
   319 (*This form, with negated conclusion, works well with the Classical prover.
   320   Negated assumptions behave like formulae on the right side of the notional
   321   turnstile...*)
   322 Goalw [Compl_def] "c : -A ==> c~:A";
   323 by (etac CollectD 1);
   324 qed "ComplD";
   325 
   326 val ComplE = make_elim ComplD;
   327 
   328 AddSIs [ComplI];
   329 AddSEs [ComplE];
   330 
   331 
   332 section "Binary union -- Un";
   333 
   334 qed_goalw "Un_iff" Set.thy [Un_def] "(c : A Un B) = (c:A | c:B)"
   335  (fn _ => [ Blast_tac 1 ]);
   336 
   337 Addsimps [Un_iff];
   338 
   339 Goal "c:A ==> c : A Un B";
   340 by (Asm_simp_tac 1);
   341 qed "UnI1";
   342 
   343 Goal "c:B ==> c : A Un B";
   344 by (Asm_simp_tac 1);
   345 qed "UnI2";
   346 
   347 (*Classical introduction rule: no commitment to A vs B*)
   348 qed_goal "UnCI" Set.thy "(c~:B ==> c:A) ==> c : A Un B"
   349  (fn prems=>
   350   [ (Simp_tac 1),
   351     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   352 
   353 val major::prems = Goalw [Un_def]
   354     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   355 by (rtac (major RS CollectD RS disjE) 1);
   356 by (REPEAT (eresolve_tac prems 1));
   357 qed "UnE";
   358 
   359 AddSIs [UnCI];
   360 AddSEs [UnE];
   361 
   362 
   363 section "Binary intersection -- Int";
   364 
   365 qed_goalw "Int_iff" Set.thy [Int_def] "(c : A Int B) = (c:A & c:B)"
   366  (fn _ => [ (Blast_tac 1) ]);
   367 
   368 Addsimps [Int_iff];
   369 
   370 Goal "[| c:A;  c:B |] ==> c : A Int B";
   371 by (Asm_simp_tac 1);
   372 qed "IntI";
   373 
   374 Goal "c : A Int B ==> c:A";
   375 by (Asm_full_simp_tac 1);
   376 qed "IntD1";
   377 
   378 Goal "c : A Int B ==> c:B";
   379 by (Asm_full_simp_tac 1);
   380 qed "IntD2";
   381 
   382 val [major,minor] = Goal
   383     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   384 by (rtac minor 1);
   385 by (rtac (major RS IntD1) 1);
   386 by (rtac (major RS IntD2) 1);
   387 qed "IntE";
   388 
   389 AddSIs [IntI];
   390 AddSEs [IntE];
   391 
   392 section "Set difference";
   393 
   394 qed_goalw "Diff_iff" Set.thy [set_diff_def] "(c : A-B) = (c:A & c~:B)"
   395  (fn _ => [ (Blast_tac 1) ]);
   396 
   397 Addsimps [Diff_iff];
   398 
   399 qed_goal "DiffI" Set.thy "!!c. [| c : A;  c ~: B |] ==> c : A - B"
   400  (fn _=> [ Asm_simp_tac 1 ]);
   401 
   402 qed_goal "DiffD1" Set.thy "!!c. c : A - B ==> c : A"
   403  (fn _=> [ (Asm_full_simp_tac 1) ]);
   404 
   405 qed_goal "DiffD2" Set.thy "!!c. [| c : A - B;  c : B |] ==> P"
   406  (fn _=> [ (Asm_full_simp_tac 1) ]);
   407 
   408 qed_goal "DiffE" Set.thy "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P"
   409  (fn prems=>
   410   [ (resolve_tac prems 1),
   411     (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ]);
   412 
   413 AddSIs [DiffI];
   414 AddSEs [DiffE];
   415 
   416 
   417 section "Augmenting a set -- insert";
   418 
   419 qed_goalw "insert_iff" Set.thy [insert_def] "a : insert b A = (a=b | a:A)"
   420  (fn _ => [Blast_tac 1]);
   421 
   422 Addsimps [insert_iff];
   423 
   424 qed_goal "insertI1" Set.thy "a : insert a B"
   425  (fn _ => [Simp_tac 1]);
   426 
   427 qed_goal "insertI2" Set.thy "!!a. a : B ==> a : insert b B"
   428  (fn _=> [Asm_simp_tac 1]);
   429 
   430 qed_goalw "insertE" Set.thy [insert_def]
   431     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P"
   432  (fn major::prems=>
   433   [ (rtac (major RS UnE) 1),
   434     (REPEAT (eresolve_tac (prems @ [CollectE]) 1)) ]);
   435 
   436 (*Classical introduction rule*)
   437 qed_goal "insertCI" Set.thy "(a~:B ==> a=b) ==> a: insert b B"
   438  (fn prems=>
   439   [ (Simp_tac 1),
   440     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   441 
   442 AddSIs [insertCI]; 
   443 AddSEs [insertE];
   444 
   445 section "Singletons, using insert";
   446 
   447 qed_goal "singletonI" Set.thy "a : {a}"
   448  (fn _=> [ (rtac insertI1 1) ]);
   449 
   450 Goal "b : {a} ==> b=a";
   451 by (Blast_tac 1);
   452 qed "singletonD";
   453 
   454 bind_thm ("singletonE", make_elim singletonD);
   455 
   456 qed_goal "singleton_iff" thy "(b : {a}) = (b=a)" 
   457 (fn _ => [Blast_tac 1]);
   458 
   459 Goal "{a}={b} ==> a=b";
   460 by (blast_tac (claset() addEs [equalityE]) 1);
   461 qed "singleton_inject";
   462 
   463 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   464 AddSIs [singletonI];   
   465 AddSDs [singleton_inject];
   466 AddSEs [singletonE];
   467 
   468 Goal "{x. x=a} = {a}";
   469 by (Blast_tac 1);
   470 qed "singleton_conv";
   471 Addsimps [singleton_conv];
   472 
   473 Goal "{x. a=x} = {a}";
   474 by(Blast_tac 1);
   475 qed "singleton_conv2";
   476 Addsimps [singleton_conv2];
   477 
   478 
   479 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   480 
   481 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   482 by (Blast_tac 1);
   483 qed "UN_iff";
   484 
   485 Addsimps [UN_iff];
   486 
   487 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   488 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   489 by Auto_tac;
   490 qed "UN_I";
   491 
   492 val major::prems = Goalw [UNION_def]
   493     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   494 by (rtac (major RS CollectD RS bexE) 1);
   495 by (REPEAT (ares_tac prems 1));
   496 qed "UN_E";
   497 
   498 AddIs  [UN_I];
   499 AddSEs [UN_E];
   500 
   501 val prems = Goal
   502     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   503 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   504 by (REPEAT (etac UN_E 1
   505      ORELSE ares_tac ([UN_I,equalityI,subsetI] @ 
   506                       (prems RL [equalityD1,equalityD2] RL [subsetD])) 1));
   507 qed "UN_cong";
   508 
   509 
   510 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   511 
   512 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   513 by Auto_tac;
   514 qed "INT_iff";
   515 
   516 Addsimps [INT_iff];
   517 
   518 val prems = Goalw [INTER_def]
   519     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   520 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   521 qed "INT_I";
   522 
   523 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   524 by Auto_tac;
   525 qed "INT_D";
   526 
   527 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   528 val major::prems = Goalw [INTER_def]
   529     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   530 by (rtac (major RS CollectD RS ballE) 1);
   531 by (REPEAT (eresolve_tac prems 1));
   532 qed "INT_E";
   533 
   534 AddSIs [INT_I];
   535 AddEs  [INT_D, INT_E];
   536 
   537 val prems = Goal
   538     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   539 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   540 by (REPEAT_FIRST (resolve_tac [INT_I,equalityI,subsetI]));
   541 by (REPEAT (dtac INT_D 1
   542      ORELSE ares_tac (prems RL [equalityD1,equalityD2] RL [subsetD]) 1));
   543 qed "INT_cong";
   544 
   545 
   546 section "Union";
   547 
   548 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   549 by (Blast_tac 1);
   550 qed "Union_iff";
   551 
   552 Addsimps [Union_iff];
   553 
   554 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   555 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   556 by Auto_tac;
   557 qed "UnionI";
   558 
   559 val major::prems = Goalw [Union_def]
   560     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   561 by (rtac (major RS UN_E) 1);
   562 by (REPEAT (ares_tac prems 1));
   563 qed "UnionE";
   564 
   565 AddIs  [UnionI];
   566 AddSEs [UnionE];
   567 
   568 
   569 section "Inter";
   570 
   571 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   572 by (Blast_tac 1);
   573 qed "Inter_iff";
   574 
   575 Addsimps [Inter_iff];
   576 
   577 val prems = Goalw [Inter_def]
   578     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   579 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   580 qed "InterI";
   581 
   582 (*A "destruct" rule -- every X in C contains A as an element, but
   583   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   584 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   585 by Auto_tac;
   586 qed "InterD";
   587 
   588 (*"Classical" elimination rule -- does not require proving X:C *)
   589 val major::prems = Goalw [Inter_def]
   590     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   591 by (rtac (major RS INT_E) 1);
   592 by (REPEAT (eresolve_tac prems 1));
   593 qed "InterE";
   594 
   595 AddSIs [InterI];
   596 AddEs  [InterD, InterE];
   597 
   598 
   599 (*** Image of a set under a function ***)
   600 
   601 (*Frequently b does not have the syntactic form of f(x).*)
   602 Goalw [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   603 by (Blast_tac 1);
   604 qed "image_eqI";
   605 Addsimps [image_eqI];
   606 
   607 bind_thm ("imageI", refl RS image_eqI);
   608 
   609 (*The eta-expansion gives variable-name preservation.*)
   610 val major::prems = Goalw [image_def]
   611     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   612 by (rtac (major RS CollectD RS bexE) 1);
   613 by (REPEAT (ares_tac prems 1));
   614 qed "imageE";
   615 
   616 AddIs  [image_eqI];
   617 AddSEs [imageE]; 
   618 
   619 Goal "f``(A Un B) = f``A Un f``B";
   620 by (Blast_tac 1);
   621 qed "image_Un";
   622 
   623 Goal "(z : f``A) = (EX x:A. z = f x)";
   624 by (Blast_tac 1);
   625 qed "image_iff";
   626 
   627 (*This rewrite rule would confuse users if made default.*)
   628 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   629 by (Blast_tac 1);
   630 qed "image_subset_iff";
   631 
   632 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   633   many existing proofs.*)
   634 val prems = Goal "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   635 by (blast_tac (claset() addIs prems) 1);
   636 qed "image_subsetI";
   637 
   638 
   639 (*** Range of a function -- just a translation for image! ***)
   640 
   641 Goal "b=f(x) ==> b : range(f)";
   642 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   643 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   644 
   645 bind_thm ("rangeI", UNIV_I RS imageI);
   646 
   647 val [major,minor] = Goal 
   648     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   649 by (rtac (major RS imageE) 1);
   650 by (etac minor 1);
   651 qed "rangeE";
   652 
   653 
   654 (*** Set reasoning tools ***)
   655 
   656 
   657 (** Rewrite rules for boolean case-splitting: faster than 
   658 	addsplits[split_if]
   659 **)
   660 
   661 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   662 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   663 
   664 (*Split ifs on either side of the membership relation.
   665 	Not for Addsimps -- can cause goals to blow up!*)
   666 bind_thm ("split_if_mem1", 
   667     read_instantiate_sg (sign_of Set.thy) [("P", "%x. x : ?b")] split_if);
   668 bind_thm ("split_if_mem2", 
   669     read_instantiate_sg (sign_of Set.thy) [("P", "%x. ?a : x")] split_if);
   670 
   671 val split_ifs = [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   672 		  split_if_mem1, split_if_mem2];
   673 
   674 
   675 (*Each of these has ALREADY been added to simpset() above.*)
   676 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   677                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff];
   678 
   679 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   680 
   681 simpset_ref() := simpset() addcongs [ball_cong,bex_cong]
   682                     setmksimps (mksimps mksimps_pairs);
   683 
   684 Addsimps[subset_UNIV, subset_refl];
   685 
   686 
   687 (*** < ***)
   688 
   689 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   690 by (Blast_tac 1);
   691 qed "psubsetI";
   692 
   693 Goalw [psubset_def] "A < insert x B ==> (x ~: A) & A<=B | x:A & A-{x}<B";
   694 by Auto_tac;
   695 qed "psubset_insertD";
   696 
   697 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);