src/HOL/Fun.thy
author haftmann
Thu Mar 13 08:56:08 2014 +0100 (2014-03-13)
changeset 56077 d397030fb27e
parent 56015 57e2cfba9c6e
child 56154 f0a927235162
permissions -rw-r--r--
tuned proofs
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Author:     Andrei Popescu, TU Muenchen
     4     Copyright   1994, 2012
     5 *)
     6 
     7 header {* Notions about functions *}
     8 
     9 theory Fun
    10 imports Set
    11 keywords "functor" :: thy_goal
    12 begin
    13 
    14 lemma apply_inverse:
    15   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    16   by auto
    17 
    18 
    19 subsection {* The Identity Function @{text id} *}
    20 
    21 definition id :: "'a \<Rightarrow> 'a" where
    22   "id = (\<lambda>x. x)"
    23 
    24 lemma id_apply [simp]: "id x = x"
    25   by (simp add: id_def)
    26 
    27 lemma image_id [simp]: "image id = id"
    28   by (simp add: id_def fun_eq_iff)
    29 
    30 lemma vimage_id [simp]: "vimage id = id"
    31   by (simp add: id_def fun_eq_iff)
    32 
    33 code_printing
    34   constant id \<rightharpoonup> (Haskell) "id"
    35 
    36 
    37 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    38 
    39 definition comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55) where
    40   "f o g = (\<lambda>x. f (g x))"
    41 
    42 notation (xsymbols)
    43   comp  (infixl "\<circ>" 55)
    44 
    45 notation (HTML output)
    46   comp  (infixl "\<circ>" 55)
    47 
    48 lemma comp_apply [simp]: "(f o g) x = f (g x)"
    49   by (simp add: comp_def)
    50 
    51 lemma comp_assoc: "(f o g) o h = f o (g o h)"
    52   by (simp add: fun_eq_iff)
    53 
    54 lemma id_comp [simp]: "id o g = g"
    55   by (simp add: fun_eq_iff)
    56 
    57 lemma comp_id [simp]: "f o id = f"
    58   by (simp add: fun_eq_iff)
    59 
    60 lemma comp_eq_dest:
    61   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    62   by (simp add: fun_eq_iff)
    63 
    64 lemma comp_eq_elim:
    65   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    66   by (simp add: fun_eq_iff) 
    67 
    68 lemma comp_eq_dest_lhs: "a o b = c \<Longrightarrow> a (b v) = c v"
    69   by clarsimp
    70 
    71 lemma comp_eq_id_dest: "a o b = id o c \<Longrightarrow> a (b v) = c v"
    72   by clarsimp
    73 
    74 lemma image_comp:
    75   "(f o g) ` r = f ` (g ` r)"
    76   by auto
    77 
    78 lemma vimage_comp:
    79   "(g \<circ> f) -` x = f -` (g -` x)"
    80   by auto
    81 
    82 code_printing
    83   constant comp \<rightharpoonup> (SML) infixl 5 "o" and (Haskell) infixr 9 "."
    84 
    85 
    86 subsection {* The Forward Composition Operator @{text fcomp} *}
    87 
    88 definition fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60) where
    89   "f \<circ>> g = (\<lambda>x. g (f x))"
    90 
    91 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
    92   by (simp add: fcomp_def)
    93 
    94 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
    95   by (simp add: fcomp_def)
    96 
    97 lemma id_fcomp [simp]: "id \<circ>> g = g"
    98   by (simp add: fcomp_def)
    99 
   100 lemma fcomp_id [simp]: "f \<circ>> id = f"
   101   by (simp add: fcomp_def)
   102 
   103 code_printing
   104   constant fcomp \<rightharpoonup> (Eval) infixl 1 "#>"
   105 
   106 no_notation fcomp (infixl "\<circ>>" 60)
   107 
   108 
   109 subsection {* Mapping functions *}
   110 
   111 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   112   "map_fun f g h = g \<circ> h \<circ> f"
   113 
   114 lemma map_fun_apply [simp]:
   115   "map_fun f g h x = g (h (f x))"
   116   by (simp add: map_fun_def)
   117 
   118 
   119 subsection {* Injectivity and Bijectivity *}
   120 
   121 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   122   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   123 
   124 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   125   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   126 
   127 text{*A common special case: functions injective, surjective or bijective over
   128 the entire domain type.*}
   129 
   130 abbreviation
   131   "inj f \<equiv> inj_on f UNIV"
   132 
   133 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   134   "surj f \<equiv> (range f = UNIV)"
   135 
   136 abbreviation
   137   "bij f \<equiv> bij_betw f UNIV UNIV"
   138 
   139 text{* The negated case: *}
   140 translations
   141 "\<not> CONST surj f" <= "CONST range f \<noteq> CONST UNIV"
   142 
   143 lemma injI:
   144   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   145   shows "inj f"
   146   using assms unfolding inj_on_def by auto
   147 
   148 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   149   by (unfold inj_on_def, blast)
   150 
   151 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   152 by (simp add: inj_on_def)
   153 
   154 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   155 by (force simp add: inj_on_def)
   156 
   157 lemma inj_on_cong:
   158   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   159 unfolding inj_on_def by auto
   160 
   161 lemma inj_on_strict_subset:
   162   "inj_on f B \<Longrightarrow> A \<subset> B \<Longrightarrow> f ` A \<subset> f ` B"
   163   unfolding inj_on_def by blast
   164 
   165 lemma inj_comp:
   166   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   167   by (simp add: inj_on_def)
   168 
   169 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   170   by (simp add: inj_on_def fun_eq_iff)
   171 
   172 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   173 by (simp add: inj_on_eq_iff)
   174 
   175 lemma inj_on_id[simp]: "inj_on id A"
   176   by (simp add: inj_on_def)
   177 
   178 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   179 by (simp add: inj_on_def)
   180 
   181 lemma inj_on_Int: "inj_on f A \<or> inj_on f B \<Longrightarrow> inj_on f (A \<inter> B)"
   182 unfolding inj_on_def by blast
   183 
   184 lemma surj_id: "surj id"
   185 by simp
   186 
   187 lemma bij_id[simp]: "bij id"
   188 by (simp add: bij_betw_def)
   189 
   190 lemma inj_onI:
   191     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   192 by (simp add: inj_on_def)
   193 
   194 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   195 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   196 
   197 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   198 by (unfold inj_on_def, blast)
   199 
   200 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   201   by (fact inj_on_eq_iff)
   202 
   203 lemma comp_inj_on:
   204      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   205 by (simp add: comp_def inj_on_def)
   206 
   207 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   208   by (simp add: inj_on_def) blast
   209 
   210 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   211   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   212 apply(unfold inj_on_def)
   213 apply blast
   214 done
   215 
   216 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   217 by (unfold inj_on_def, blast)
   218 
   219 lemma inj_singleton: "inj (%s. {s})"
   220 by (simp add: inj_on_def)
   221 
   222 lemma inj_on_empty[iff]: "inj_on f {}"
   223 by(simp add: inj_on_def)
   224 
   225 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   226 by (unfold inj_on_def, blast)
   227 
   228 lemma inj_on_Un:
   229  "inj_on f (A Un B) =
   230   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   231 apply(unfold inj_on_def)
   232 apply (blast intro:sym)
   233 done
   234 
   235 lemma inj_on_insert[iff]:
   236   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   237 apply(unfold inj_on_def)
   238 apply (blast intro:sym)
   239 done
   240 
   241 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   242 apply(unfold inj_on_def)
   243 apply (blast)
   244 done
   245 
   246 lemma comp_inj_on_iff:
   247   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   248 by(auto simp add: comp_inj_on inj_on_def)
   249 
   250 lemma inj_on_imageI2:
   251   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   252 by(auto simp add: comp_inj_on inj_on_def)
   253 
   254 lemma inj_img_insertE:
   255   assumes "inj_on f A"
   256   assumes "x \<notin> B" and "insert x B = f ` A"
   257   obtains x' A' where "x' \<notin> A'" and "A = insert x' A'"
   258     and "x = f x'" and "B = f ` A'"
   259 proof -
   260   from assms have "x \<in> f ` A" by auto
   261   then obtain x' where *: "x' \<in> A" "x = f x'" by auto
   262   then have "A = insert x' (A - {x'})" by auto
   263   with assms * have "B = f ` (A - {x'})"
   264     by (auto dest: inj_on_contraD)
   265   have "x' \<notin> A - {x'}" by simp
   266   from `x' \<notin> A - {x'}` `A = insert x' (A - {x'})` `x = f x'` `B = image f (A - {x'})`
   267   show ?thesis ..
   268 qed
   269 
   270 lemma linorder_injI:
   271   assumes hyp: "\<And>x y. x < (y::'a::linorder) \<Longrightarrow> f x \<noteq> f y"
   272   shows "inj f"
   273   -- {* Courtesy of Stephan Merz *}
   274 proof (rule inj_onI)
   275   fix x y
   276   assume f_eq: "f x = f y"
   277   show "x = y" by (rule linorder_cases) (auto dest: hyp simp: f_eq)
   278 qed
   279 
   280 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   281   by auto
   282 
   283 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   284   using *[symmetric] by auto
   285 
   286 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   287   by (simp add: surj_def)
   288 
   289 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   290   by (simp add: surj_def, blast)
   291 
   292 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   293 apply (simp add: comp_def surj_def, clarify)
   294 apply (drule_tac x = y in spec, clarify)
   295 apply (drule_tac x = x in spec, blast)
   296 done
   297 
   298 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   299   unfolding bij_betw_def by auto
   300 
   301 lemma bij_betw_empty1:
   302   assumes "bij_betw f {} A"
   303   shows "A = {}"
   304 using assms unfolding bij_betw_def by blast
   305 
   306 lemma bij_betw_empty2:
   307   assumes "bij_betw f A {}"
   308   shows "A = {}"
   309 using assms unfolding bij_betw_def by blast
   310 
   311 lemma inj_on_imp_bij_betw:
   312   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   313 unfolding bij_betw_def by simp
   314 
   315 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   316   unfolding bij_betw_def ..
   317 
   318 lemma bijI: "[| inj f; surj f |] ==> bij f"
   319 by (simp add: bij_def)
   320 
   321 lemma bij_is_inj: "bij f ==> inj f"
   322 by (simp add: bij_def)
   323 
   324 lemma bij_is_surj: "bij f ==> surj f"
   325 by (simp add: bij_def)
   326 
   327 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   328 by (simp add: bij_betw_def)
   329 
   330 lemma bij_betw_trans:
   331   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   332 by(auto simp add:bij_betw_def comp_inj_on)
   333 
   334 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   335   by (rule bij_betw_trans)
   336 
   337 lemma bij_betw_comp_iff:
   338   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   339 by(auto simp add: bij_betw_def inj_on_def)
   340 
   341 lemma bij_betw_comp_iff2:
   342   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   343   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   344 using assms
   345 proof(auto simp add: bij_betw_comp_iff)
   346   assume *: "bij_betw (f' \<circ> f) A A''"
   347   thus "bij_betw f A A'"
   348   using IM
   349   proof(auto simp add: bij_betw_def)
   350     assume "inj_on (f' \<circ> f) A"
   351     thus "inj_on f A" using inj_on_imageI2 by blast
   352   next
   353     fix a' assume **: "a' \<in> A'"
   354     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   355     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   356     unfolding bij_betw_def by force
   357     hence "f a \<in> A'" using IM by auto
   358     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   359     thus "a' \<in> f ` A" using 1 by auto
   360   qed
   361 qed
   362 
   363 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   364 proof -
   365   have i: "inj_on f A" and s: "f ` A = B"
   366     using assms by(auto simp:bij_betw_def)
   367   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   368   { fix a b assume P: "?P b a"
   369     hence ex1: "\<exists>a. ?P b a" using s by blast
   370     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   371     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   372   } note g = this
   373   have "inj_on ?g B"
   374   proof(rule inj_onI)
   375     fix x y assume "x:B" "y:B" "?g x = ?g y"
   376     from s `x:B` obtain a1 where a1: "?P x a1" by blast
   377     from s `y:B` obtain a2 where a2: "?P y a2" by blast
   378     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   379   qed
   380   moreover have "?g ` B = A"
   381   proof(auto simp: image_def)
   382     fix b assume "b:B"
   383     with s obtain a where P: "?P b a" by blast
   384     thus "?g b \<in> A" using g[OF P] by auto
   385   next
   386     fix a assume "a:A"
   387     then obtain b where P: "?P b a" using s by blast
   388     then have "b:B" using s by blast
   389     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   390   qed
   391   ultimately show ?thesis by(auto simp:bij_betw_def)
   392 qed
   393 
   394 lemma bij_betw_cong:
   395   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   396 unfolding bij_betw_def inj_on_def by force
   397 
   398 lemma bij_betw_id[intro, simp]:
   399   "bij_betw id A A"
   400 unfolding bij_betw_def id_def by auto
   401 
   402 lemma bij_betw_id_iff:
   403   "bij_betw id A B \<longleftrightarrow> A = B"
   404 by(auto simp add: bij_betw_def)
   405 
   406 lemma bij_betw_combine:
   407   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   408   shows "bij_betw f (A \<union> C) (B \<union> D)"
   409   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   410 
   411 lemma bij_betw_subset:
   412   assumes BIJ: "bij_betw f A A'" and
   413           SUB: "B \<le> A" and IM: "f ` B = B'"
   414   shows "bij_betw f B B'"
   415 using assms
   416 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   417 
   418 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   419 by simp
   420 
   421 lemma surj_vimage_empty:
   422   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   423   using surj_image_vimage_eq[OF `surj f`, of A]
   424   by (intro iffI) fastforce+
   425 
   426 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   427 by (simp add: inj_on_def, blast)
   428 
   429 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   430 by (blast intro: sym)
   431 
   432 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   433 by (unfold inj_on_def, blast)
   434 
   435 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   436 apply (unfold bij_def)
   437 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   438 done
   439 
   440 lemma inj_on_image_eq_iff: "\<lbrakk> inj_on f C; A \<subseteq> C; B \<subseteq> C \<rbrakk> \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   441 by(fastforce simp add: inj_on_def)
   442 
   443 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   444 by(erule inj_on_image_eq_iff) simp_all
   445 
   446 lemma inj_on_image_Int:
   447    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   448 apply (simp add: inj_on_def, blast)
   449 done
   450 
   451 lemma inj_on_image_set_diff:
   452    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   453 apply (simp add: inj_on_def, blast)
   454 done
   455 
   456 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   457 by (simp add: inj_on_def, blast)
   458 
   459 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   460 by (simp add: inj_on_def, blast)
   461 
   462 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   463 by (blast dest: injD)
   464 
   465 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   466 by (simp add: inj_on_def, blast)
   467 
   468 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   469 by (blast dest: injD)
   470 
   471 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   472 by auto
   473 
   474 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   475 by (auto simp add: inj_on_def)
   476 
   477 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   478 apply (simp add: bij_def)
   479 apply (rule equalityI)
   480 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   481 done
   482 
   483 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   484   -- {* The inverse image of a singleton under an injective function
   485          is included in a singleton. *}
   486   apply (auto simp add: inj_on_def)
   487   apply (blast intro: the_equality [symmetric])
   488   done
   489 
   490 lemma inj_on_vimage_singleton:
   491   "inj_on f A \<Longrightarrow> f -` {a} \<inter> A \<subseteq> {THE x. x \<in> A \<and> f x = a}"
   492   by (auto simp add: inj_on_def intro: the_equality [symmetric])
   493 
   494 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   495   by (auto intro!: inj_onI)
   496 
   497 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   498   by (auto intro!: inj_onI dest: strict_mono_eq)
   499 
   500 lemma bij_betw_byWitness:
   501 assumes LEFT: "\<forall>a \<in> A. f'(f a) = a" and
   502         RIGHT: "\<forall>a' \<in> A'. f(f' a') = a'" and
   503         IM1: "f ` A \<le> A'" and IM2: "f' ` A' \<le> A"
   504 shows "bij_betw f A A'"
   505 using assms
   506 proof(unfold bij_betw_def inj_on_def, safe)
   507   fix a b assume *: "a \<in> A" "b \<in> A" and **: "f a = f b"
   508   have "a = f'(f a) \<and> b = f'(f b)" using * LEFT by simp
   509   with ** show "a = b" by simp
   510 next
   511   fix a' assume *: "a' \<in> A'"
   512   hence "f' a' \<in> A" using IM2 by blast
   513   moreover
   514   have "a' = f(f' a')" using * RIGHT by simp
   515   ultimately show "a' \<in> f ` A" by blast
   516 qed
   517 
   518 corollary notIn_Un_bij_betw:
   519 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'" and
   520        BIJ: "bij_betw f A A'"
   521 shows "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   522 proof-
   523   have "bij_betw f {b} {f b}"
   524   unfolding bij_betw_def inj_on_def by simp
   525   with assms show ?thesis
   526   using bij_betw_combine[of f A A' "{b}" "{f b}"] by blast
   527 qed
   528 
   529 lemma notIn_Un_bij_betw3:
   530 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'"
   531 shows "bij_betw f A A' = bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   532 proof
   533   assume "bij_betw f A A'"
   534   thus "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   535   using assms notIn_Un_bij_betw[of b A f A'] by blast
   536 next
   537   assume *: "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   538   have "f ` A = A'"
   539   proof(auto)
   540     fix a assume **: "a \<in> A"
   541     hence "f a \<in> A' \<union> {f b}" using * unfolding bij_betw_def by blast
   542     moreover
   543     {assume "f a = f b"
   544      hence "a = b" using * ** unfolding bij_betw_def inj_on_def by blast
   545      with NIN ** have False by blast
   546     }
   547     ultimately show "f a \<in> A'" by blast
   548   next
   549     fix a' assume **: "a' \<in> A'"
   550     hence "a' \<in> f`(A \<union> {b})"
   551     using * by (auto simp add: bij_betw_def)
   552     then obtain a where 1: "a \<in> A \<union> {b} \<and> f a = a'" by blast
   553     moreover
   554     {assume "a = b" with 1 ** NIN' have False by blast
   555     }
   556     ultimately have "a \<in> A" by blast
   557     with 1 show "a' \<in> f ` A" by blast
   558   qed
   559   thus "bij_betw f A A'" using * bij_betw_subset[of f "A \<union> {b}" _ A] by blast
   560 qed
   561 
   562 
   563 subsection{*Function Updating*}
   564 
   565 definition fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   566   "fun_upd f a b == % x. if x=a then b else f x"
   567 
   568 nonterminal updbinds and updbind
   569 
   570 syntax
   571   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   572   ""         :: "updbind => updbinds"             ("_")
   573   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   574   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   575 
   576 translations
   577   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   578   "f(x:=y)" == "CONST fun_upd f x y"
   579 
   580 (* Hint: to define the sum of two functions (or maps), use case_sum.
   581          A nice infix syntax could be defined (in Datatype.thy or below) by
   582 notation
   583   case_sum  (infixr "'(+')"80)
   584 *)
   585 
   586 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   587 apply (simp add: fun_upd_def, safe)
   588 apply (erule subst)
   589 apply (rule_tac [2] ext, auto)
   590 done
   591 
   592 lemma fun_upd_idem: "f x = y ==> f(x:=y) = f"
   593   by (simp only: fun_upd_idem_iff)
   594 
   595 lemma fun_upd_triv [iff]: "f(x := f x) = f"
   596   by (simp only: fun_upd_idem)
   597 
   598 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   599 by (simp add: fun_upd_def)
   600 
   601 (* fun_upd_apply supersedes these two,   but they are useful
   602    if fun_upd_apply is intentionally removed from the simpset *)
   603 lemma fun_upd_same: "(f(x:=y)) x = y"
   604 by simp
   605 
   606 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   607 by simp
   608 
   609 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   610 by (simp add: fun_eq_iff)
   611 
   612 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   613 by (rule ext, auto)
   614 
   615 lemma inj_on_fun_updI:
   616   "inj_on f A \<Longrightarrow> y \<notin> f ` A \<Longrightarrow> inj_on (f(x := y)) A"
   617   by (fastforce simp: inj_on_def)
   618 
   619 lemma fun_upd_image:
   620      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   621 by auto
   622 
   623 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   624   by auto
   625 
   626 
   627 subsection {* @{text override_on} *}
   628 
   629 definition override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b" where
   630   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   631 
   632 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   633 by(simp add:override_on_def)
   634 
   635 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   636 by(simp add:override_on_def)
   637 
   638 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   639 by(simp add:override_on_def)
   640 
   641 
   642 subsection {* @{text swap} *}
   643 
   644 definition swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)" where
   645   "swap a b f = f (a := f b, b:= f a)"
   646 
   647 lemma swap_self [simp]: "swap a a f = f"
   648 by (simp add: swap_def)
   649 
   650 lemma swap_commute: "swap a b f = swap b a f"
   651 by (rule ext, simp add: fun_upd_def swap_def)
   652 
   653 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   654 by (rule ext, simp add: fun_upd_def swap_def)
   655 
   656 lemma swap_triple:
   657   assumes "a \<noteq> c" and "b \<noteq> c"
   658   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   659   using assms by (simp add: fun_eq_iff swap_def)
   660 
   661 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   662 by (rule ext, simp add: fun_upd_def swap_def)
   663 
   664 lemma swap_image_eq [simp]:
   665   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   666 proof -
   667   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   668     using assms by (auto simp: image_iff swap_def)
   669   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   670   with subset[of f] show ?thesis by auto
   671 qed
   672 
   673 lemma inj_on_imp_inj_on_swap:
   674   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   675   by (simp add: inj_on_def swap_def, blast)
   676 
   677 lemma inj_on_swap_iff [simp]:
   678   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   679 proof
   680   assume "inj_on (swap a b f) A"
   681   with A have "inj_on (swap a b (swap a b f)) A"
   682     by (iprover intro: inj_on_imp_inj_on_swap)
   683   thus "inj_on f A" by simp
   684 next
   685   assume "inj_on f A"
   686   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   687 qed
   688 
   689 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   690   by simp
   691 
   692 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   693   by simp
   694 
   695 lemma bij_betw_swap_iff [simp]:
   696   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   697   by (auto simp: bij_betw_def)
   698 
   699 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   700   by simp
   701 
   702 hide_const (open) swap
   703 
   704 subsection {* Inversion of injective functions *}
   705 
   706 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   707   "the_inv_into A f == %x. THE y. y : A & f y = x"
   708 
   709 lemma the_inv_into_f_f:
   710   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   711 apply (simp add: the_inv_into_def inj_on_def)
   712 apply blast
   713 done
   714 
   715 lemma f_the_inv_into_f:
   716   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   717 apply (simp add: the_inv_into_def)
   718 apply (rule the1I2)
   719  apply(blast dest: inj_onD)
   720 apply blast
   721 done
   722 
   723 lemma the_inv_into_into:
   724   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   725 apply (simp add: the_inv_into_def)
   726 apply (rule the1I2)
   727  apply(blast dest: inj_onD)
   728 apply blast
   729 done
   730 
   731 lemma the_inv_into_onto[simp]:
   732   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   733 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   734 
   735 lemma the_inv_into_f_eq:
   736   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   737   apply (erule subst)
   738   apply (erule the_inv_into_f_f, assumption)
   739   done
   740 
   741 lemma the_inv_into_comp:
   742   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   743   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   744 apply (rule the_inv_into_f_eq)
   745   apply (fast intro: comp_inj_on)
   746  apply (simp add: f_the_inv_into_f the_inv_into_into)
   747 apply (simp add: the_inv_into_into)
   748 done
   749 
   750 lemma inj_on_the_inv_into:
   751   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   752 by (auto intro: inj_onI simp: the_inv_into_f_f)
   753 
   754 lemma bij_betw_the_inv_into:
   755   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   756 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   757 
   758 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   759   "the_inv f \<equiv> the_inv_into UNIV f"
   760 
   761 lemma the_inv_f_f:
   762   assumes "inj f"
   763   shows "the_inv f (f x) = x" using assms UNIV_I
   764   by (rule the_inv_into_f_f)
   765 
   766 
   767 subsection {* Cantor's Paradox *}
   768 
   769 lemma Cantors_paradox:
   770   "\<not>(\<exists>f. f ` A = Pow A)"
   771 proof clarify
   772   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   773   let ?X = "{a \<in> A. a \<notin> f a}"
   774   have "?X \<in> Pow A" unfolding Pow_def by auto
   775   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   776   thus False by best
   777 qed
   778 
   779 subsection {* Setup *} 
   780 
   781 subsubsection {* Proof tools *}
   782 
   783 text {* simplifies terms of the form
   784   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   785 
   786 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   787 let
   788   fun gen_fun_upd NONE T _ _ = NONE
   789     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   790   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   791   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   792     let
   793       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   794             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   795         | find t = NONE
   796     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   797 
   798   val ss = simpset_of @{context}
   799 
   800   fun proc ctxt ct =
   801     let
   802       val t = Thm.term_of ct
   803     in
   804       case find_double t of
   805         (T, NONE) => NONE
   806       | (T, SOME rhs) =>
   807           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   808             (fn _ =>
   809               rtac eq_reflection 1 THEN
   810               rtac @{thm ext} 1 THEN
   811               simp_tac (put_simpset ss ctxt) 1))
   812     end
   813 in proc end
   814 *}
   815 
   816 
   817 subsubsection {* Functorial structure of types *}
   818 
   819 ML_file "Tools/functor.ML"
   820 
   821 functor map_fun: map_fun
   822   by (simp_all add: fun_eq_iff)
   823 
   824 functor vimage
   825   by (simp_all add: fun_eq_iff vimage_comp)
   826 
   827 text {* Legacy theorem names *}
   828 
   829 lemmas o_def = comp_def
   830 lemmas o_apply = comp_apply
   831 lemmas o_assoc = comp_assoc [symmetric]
   832 lemmas id_o = id_comp
   833 lemmas o_id = comp_id
   834 lemmas o_eq_dest = comp_eq_dest
   835 lemmas o_eq_elim = comp_eq_elim
   836 lemmas o_eq_dest_lhs = comp_eq_dest_lhs
   837 lemmas o_eq_id_dest = comp_eq_id_dest
   838 lemmas image_compose = image_comp
   839 lemmas vimage_compose = vimage_comp
   840 
   841 end
   842