src/HOL/Product_Type.thy
author haftmann
Mon Jun 28 15:03:07 2010 +0200 (2010-06-28)
changeset 37591 d3daea901123
parent 37411 c88c44156083
child 37678 0040bafffdef
permissions -rw-r--r--
merged constants "split" and "prod_case"
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_codegen.ML")
    13   ("Tools/inductive_set.ML")
    14 begin
    15 
    16 subsection {* @{typ bool} is a datatype *}
    17 
    18 rep_datatype True False by (auto intro: bool_induct)
    19 
    20 declare case_split [cases type: bool]
    21   -- "prefer plain propositional version"
    22 
    23 lemma
    24   shows [code]: "eq_class.eq False P \<longleftrightarrow> \<not> P"
    25     and [code]: "eq_class.eq True P \<longleftrightarrow> P" 
    26     and [code]: "eq_class.eq P False \<longleftrightarrow> \<not> P" 
    27     and [code]: "eq_class.eq P True \<longleftrightarrow> P"
    28     and [code nbe]: "eq_class.eq P P \<longleftrightarrow> True"
    29   by (simp_all add: eq)
    30 
    31 code_const "eq_class.eq \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    32   (Haskell infixl 4 "==")
    33 
    34 code_instance bool :: eq
    35   (Haskell -)
    36 
    37 
    38 subsection {* The @{text unit} type *}
    39 
    40 typedef unit = "{True}"
    41 proof
    42   show "True : ?unit" ..
    43 qed
    44 
    45 definition
    46   Unity :: unit    ("'(')")
    47 where
    48   "() = Abs_unit True"
    49 
    50 lemma unit_eq [no_atp]: "u = ()"
    51   by (induct u) (simp add: unit_def Unity_def)
    52 
    53 text {*
    54   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    55   this rule directly --- it loops!
    56 *}
    57 
    58 ML {*
    59   val unit_eq_proc =
    60     let val unit_meta_eq = mk_meta_eq @{thm unit_eq} in
    61       Simplifier.simproc @{theory} "unit_eq" ["x::unit"]
    62       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    63     end;
    64 
    65   Addsimprocs [unit_eq_proc];
    66 *}
    67 
    68 rep_datatype "()" by simp
    69 
    70 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    71   by simp
    72 
    73 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    74   by (rule triv_forall_equality)
    75 
    76 text {*
    77   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    78   [source] "%u::unit. f u"}, replacing it by @{term [source]
    79   f} rather than by @{term [source] "%u. f ()"}.
    80 *}
    81 
    82 lemma unit_abs_eta_conv [simp,no_atp]: "(%u::unit. f ()) = f"
    83   by (rule ext) simp
    84 
    85 instantiation unit :: default
    86 begin
    87 
    88 definition "default = ()"
    89 
    90 instance ..
    91 
    92 end
    93 
    94 lemma [code]:
    95   "eq_class.eq (u\<Colon>unit) v \<longleftrightarrow> True" unfolding eq unit_eq [of u] unit_eq [of v] by rule+
    96 
    97 code_type unit
    98   (SML "unit")
    99   (OCaml "unit")
   100   (Haskell "()")
   101   (Scala "Unit")
   102 
   103 code_const Unity
   104   (SML "()")
   105   (OCaml "()")
   106   (Haskell "()")
   107   (Scala "()")
   108 
   109 code_instance unit :: eq
   110   (Haskell -)
   111 
   112 code_const "eq_class.eq \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   113   (Haskell infixl 4 "==")
   114 
   115 code_reserved SML
   116   unit
   117 
   118 code_reserved OCaml
   119   unit
   120 
   121 code_reserved Scala
   122   Unit
   123 
   124 
   125 subsection {* The product type *}
   126 
   127 subsubsection {* Type definition *}
   128 
   129 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   130   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   131 
   132 typedef (prod) ('a, 'b) "*" (infixr "*" 20)
   133   = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   134 proof
   135   fix a b show "Pair_Rep a b \<in> ?prod"
   136     by rule+
   137 qed
   138 
   139 type_notation (xsymbols)
   140   "*"  ("(_ \<times>/ _)" [21, 20] 20)
   141 type_notation (HTML output)
   142   "*"  ("(_ \<times>/ _)" [21, 20] 20)
   143 
   144 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   145   "Pair a b = Abs_prod (Pair_Rep a b)"
   146 
   147 rep_datatype (prod) Pair proof -
   148   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   149   assume "\<And>a b. P (Pair a b)"
   150   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   151 next
   152   fix a c :: 'a and b d :: 'b
   153   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   154     by (auto simp add: Pair_Rep_def expand_fun_eq)
   155   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   156     by (auto simp add: prod_def)
   157   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   158     by (simp add: Pair_def Abs_prod_inject)
   159 qed
   160 
   161 declare weak_case_cong [cong del]
   162 
   163 
   164 subsubsection {* Tuple syntax *}
   165 
   166 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   167   "split \<equiv> prod_case"
   168 
   169 text {*
   170   Patterns -- extends pre-defined type @{typ pttrn} used in
   171   abstractions.
   172 *}
   173 
   174 nonterminals
   175   tuple_args patterns
   176 
   177 syntax
   178   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   179   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   180   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   181   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   182   ""            :: "pttrn => patterns"                  ("_")
   183   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   184 
   185 translations
   186   "(x, y)" == "CONST Pair x y"
   187   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   188   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   189   "%(x, y). b" == "CONST prod_case (%x y. b)"
   190   "_abs (CONST Pair x y) t" => "%(x, y). t"
   191   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   192      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   193 
   194 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   195   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   196 print_translation {*
   197 let
   198   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   199         (* split (%x y. t) => %(x,y) t *)
   200         let
   201           val (y, t') = atomic_abs_tr' abs;
   202           val (x', t'') = atomic_abs_tr' (x, T, t');
   203         in
   204           Syntax.const @{syntax_const "_abs"} $
   205             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   206         end
   207     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   208         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   209         let
   210           val Const (@{syntax_const "_abs"}, _) $
   211             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   212           val (x', t'') = atomic_abs_tr' (x, T, t');
   213         in
   214           Syntax.const @{syntax_const "_abs"} $
   215             (Syntax.const @{syntax_const "_pattern"} $ x' $
   216               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   217         end
   218     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   219         (* split (split (%x y z. t)) => %((x, y), z). t *)
   220         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   221     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   222         (* split (%pttrn z. t) => %(pttrn,z). t *)
   223         let val (z, t) = atomic_abs_tr' abs in
   224           Syntax.const @{syntax_const "_abs"} $
   225             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   226         end
   227     | split_tr' _ = raise Match;
   228 in [(@{const_syntax prod_case}, split_tr')] end
   229 *}
   230 
   231 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   232 typed_print_translation {*
   233 let
   234   fun split_guess_names_tr' _ T [Abs (x, _, Abs _)] = raise Match
   235     | split_guess_names_tr' _ T [Abs (x, xT, t)] =
   236         (case (head_of t) of
   237           Const (@{const_syntax prod_case}, _) => raise Match
   238         | _ =>
   239           let 
   240             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   241             val (y, t') = atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   242             val (x', t'') = atomic_abs_tr' (x, xT, t');
   243           in
   244             Syntax.const @{syntax_const "_abs"} $
   245               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   246           end)
   247     | split_guess_names_tr' _ T [t] =
   248         (case head_of t of
   249           Const (@{const_syntax prod_case}, _) => raise Match
   250         | _ =>
   251           let
   252             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   253             val (y, t') = atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   254             val (x', t'') = atomic_abs_tr' ("x", xT, t');
   255           in
   256             Syntax.const @{syntax_const "_abs"} $
   257               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   258           end)
   259     | split_guess_names_tr' _ _ _ = raise Match;
   260 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   261 *}
   262 
   263 
   264 subsubsection {* Code generator setup *}
   265 
   266 code_type *
   267   (SML infix 2 "*")
   268   (OCaml infix 2 "*")
   269   (Haskell "!((_),/ (_))")
   270   (Scala "((_),/ (_))")
   271 
   272 code_const Pair
   273   (SML "!((_),/ (_))")
   274   (OCaml "!((_),/ (_))")
   275   (Haskell "!((_),/ (_))")
   276   (Scala "!((_),/ (_))")
   277 
   278 code_instance * :: eq
   279   (Haskell -)
   280 
   281 code_const "eq_class.eq \<Colon> 'a\<Colon>eq \<times> 'b\<Colon>eq \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   282   (Haskell infixl 4 "==")
   283 
   284 types_code
   285   "*"     ("(_ */ _)")
   286 attach (term_of) {*
   287 fun term_of_id_42 aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   288 *}
   289 attach (test) {*
   290 fun gen_id_42 aG aT bG bT i =
   291   let
   292     val (x, t) = aG i;
   293     val (y, u) = bG i
   294   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   295 *}
   296 
   297 consts_code
   298   "Pair"    ("(_,/ _)")
   299 
   300 setup {*
   301 let
   302 
   303 fun strip_abs_split 0 t = ([], t)
   304   | strip_abs_split i (Abs (s, T, t)) =
   305       let
   306         val s' = Codegen.new_name t s;
   307         val v = Free (s', T)
   308       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   309   | strip_abs_split i (u as Const (@{const_name prod_case}, _) $ t) =
   310       (case strip_abs_split (i+1) t of
   311         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   312       | _ => ([], u))
   313   | strip_abs_split i t =
   314       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
   315 
   316 fun let_codegen thy defs dep thyname brack t gr =
   317   (case strip_comb t of
   318     (t1 as Const (@{const_name Let}, _), t2 :: t3 :: ts) =>
   319     let
   320       fun dest_let (l as Const (@{const_name Let}, _) $ t $ u) =
   321           (case strip_abs_split 1 u of
   322              ([p], u') => apfst (cons (p, t)) (dest_let u')
   323            | _ => ([], l))
   324         | dest_let t = ([], t);
   325       fun mk_code (l, r) gr =
   326         let
   327           val (pl, gr1) = Codegen.invoke_codegen thy defs dep thyname false l gr;
   328           val (pr, gr2) = Codegen.invoke_codegen thy defs dep thyname false r gr1;
   329         in ((pl, pr), gr2) end
   330     in case dest_let (t1 $ t2 $ t3) of
   331         ([], _) => NONE
   332       | (ps, u) =>
   333           let
   334             val (qs, gr1) = fold_map mk_code ps gr;
   335             val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
   336             val (pargs, gr3) = fold_map
   337               (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
   338           in
   339             SOME (Codegen.mk_app brack
   340               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
   341                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
   342                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
   343                        Pretty.brk 1, pr]]) qs))),
   344                 Pretty.brk 1, Codegen.str "in ", pu,
   345                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
   346           end
   347     end
   348   | _ => NONE);
   349 
   350 fun split_codegen thy defs dep thyname brack t gr = (case strip_comb t of
   351     (t1 as Const (@{const_name prod_case}, _), t2 :: ts) =>
   352       let
   353         val ([p], u) = strip_abs_split 1 (t1 $ t2);
   354         val (q, gr1) = Codegen.invoke_codegen thy defs dep thyname false p gr;
   355         val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
   356         val (pargs, gr3) = fold_map
   357           (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
   358       in
   359         SOME (Codegen.mk_app brack
   360           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
   361             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
   362       end
   363   | _ => NONE);
   364 
   365 in
   366 
   367   Codegen.add_codegen "let_codegen" let_codegen
   368   #> Codegen.add_codegen "split_codegen" split_codegen
   369 
   370 end
   371 *}
   372 
   373 
   374 subsubsection {* Fundamental operations and properties *}
   375 
   376 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   377   by (cases p) simp
   378 
   379 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   380   "fst p = (case p of (a, b) \<Rightarrow> a)"
   381 
   382 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   383   "snd p = (case p of (a, b) \<Rightarrow> b)"
   384 
   385 lemma fst_conv [simp, code]: "fst (a, b) = a"
   386   unfolding fst_def by simp
   387 
   388 lemma snd_conv [simp, code]: "snd (a, b) = b"
   389   unfolding snd_def by simp
   390 
   391 code_const fst and snd
   392   (Haskell "fst" and "snd")
   393 
   394 lemma prod_case_unfold: "prod_case = (%c p. c (fst p) (snd p))"
   395   by (simp add: expand_fun_eq split: prod.split)
   396 
   397 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   398   by simp
   399 
   400 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   401   by simp
   402 
   403 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   404   by (cases p) simp
   405 
   406 lemmas surjective_pairing = pair_collapse [symmetric]
   407 
   408 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   409   by (cases s, cases t) simp
   410 
   411 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   412   by (simp add: Pair_fst_snd_eq)
   413 
   414 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   415   by (fact prod.cases)
   416 
   417 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   418   by (rule split_conv [THEN iffD2])
   419 
   420 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   421   by (rule split_conv [THEN iffD1])
   422 
   423 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   424   by (simp add: expand_fun_eq split: prod.split)
   425 
   426 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   427   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   428   by (simp add: expand_fun_eq split: prod.split)
   429 
   430 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   431   by (cases x) simp
   432 
   433 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   434   by (cases p) simp
   435 
   436 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   437   by (simp add: prod_case_unfold)
   438 
   439 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   440   -- {* Prevents simplification of @{term c}: much faster *}
   441   by (erule arg_cong)
   442 
   443 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   444   by (simp add: split_eta)
   445 
   446 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   447 proof
   448   fix a b
   449   assume "!!x. PROP P x"
   450   then show "PROP P (a, b)" .
   451 next
   452   fix x
   453   assume "!!a b. PROP P (a, b)"
   454   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   455 qed
   456 
   457 text {*
   458   The rule @{thm [source] split_paired_all} does not work with the
   459   Simplifier because it also affects premises in congrence rules,
   460   where this can lead to premises of the form @{text "!!a b. ... =
   461   ?P(a, b)"} which cannot be solved by reflexivity.
   462 *}
   463 
   464 lemmas split_tupled_all = split_paired_all unit_all_eq2
   465 
   466 ML {*
   467   (* replace parameters of product type by individual component parameters *)
   468   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   469   local (* filtering with exists_paired_all is an essential optimization *)
   470     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   471           can HOLogic.dest_prodT T orelse exists_paired_all t
   472       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   473       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   474       | exists_paired_all _ = false;
   475     val ss = HOL_basic_ss
   476       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   477       addsimprocs [unit_eq_proc];
   478   in
   479     val split_all_tac = SUBGOAL (fn (t, i) =>
   480       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   481     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   482       if exists_paired_all t then full_simp_tac ss i else no_tac);
   483     fun split_all th =
   484    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   485   end;
   486 *}
   487 
   488 declaration {* fn _ =>
   489   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   490 *}
   491 
   492 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   493   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   494   by fast
   495 
   496 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   497   by fast
   498 
   499 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   500   -- {* Can't be added to simpset: loops! *}
   501   by (simp add: split_eta)
   502 
   503 text {*
   504   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   505   @{thm [source] split_eta} as a rewrite rule is not general enough,
   506   and using @{thm [source] cond_split_eta} directly would render some
   507   existing proofs very inefficient; similarly for @{text
   508   split_beta}.
   509 *}
   510 
   511 ML {*
   512 local
   513   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   514   fun Pair_pat k 0 (Bound m) = (m = k)
   515     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   516         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   517     | Pair_pat _ _ _ = false;
   518   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   519     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   520     | no_args k i (Bound m) = m < k orelse m > k + i
   521     | no_args _ _ _ = true;
   522   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   523     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   524     | split_pat tp i _ = NONE;
   525   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   526         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   527         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   528 
   529   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   530     | beta_term_pat k i (t $ u) =
   531         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   532     | beta_term_pat k i t = no_args k i t;
   533   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   534     | eta_term_pat _ _ _ = false;
   535   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   536     | subst arg k i (t $ u) =
   537         if Pair_pat k i (t $ u) then incr_boundvars k arg
   538         else (subst arg k i t $ subst arg k i u)
   539     | subst arg k i t = t;
   540   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   541         (case split_pat beta_term_pat 1 t of
   542           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   543         | NONE => NONE)
   544     | beta_proc _ _ = NONE;
   545   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   546         (case split_pat eta_term_pat 1 t of
   547           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   548         | NONE => NONE)
   549     | eta_proc _ _ = NONE;
   550 in
   551   val split_beta_proc = Simplifier.simproc @{theory} "split_beta" ["split f z"] (K beta_proc);
   552   val split_eta_proc = Simplifier.simproc @{theory} "split_eta" ["split f"] (K eta_proc);
   553 end;
   554 
   555 Addsimprocs [split_beta_proc, split_eta_proc];
   556 *}
   557 
   558 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   559   by (subst surjective_pairing, rule split_conv)
   560 
   561 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   562   -- {* For use with @{text split} and the Simplifier. *}
   563   by (insert surj_pair [of p], clarify, simp)
   564 
   565 text {*
   566   @{thm [source] split_split} could be declared as @{text "[split]"}
   567   done after the Splitter has been speeded up significantly;
   568   precompute the constants involved and don't do anything unless the
   569   current goal contains one of those constants.
   570 *}
   571 
   572 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   573 by (subst split_split, simp)
   574 
   575 text {*
   576   \medskip @{term split} used as a logical connective or set former.
   577 
   578   \medskip These rules are for use with @{text blast}; could instead
   579   call @{text simp} using @{thm [source] split} as rewrite. *}
   580 
   581 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   582   apply (simp only: split_tupled_all)
   583   apply (simp (no_asm_simp))
   584   done
   585 
   586 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   587   apply (simp only: split_tupled_all)
   588   apply (simp (no_asm_simp))
   589   done
   590 
   591 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   592   by (induct p) auto
   593 
   594 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   595   by (induct p) auto
   596 
   597 lemma splitE2:
   598   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   599 proof -
   600   assume q: "Q (split P z)"
   601   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   602   show R
   603     apply (rule r surjective_pairing)+
   604     apply (rule split_beta [THEN subst], rule q)
   605     done
   606 qed
   607 
   608 lemma splitD': "split R (a,b) c ==> R a b c"
   609   by simp
   610 
   611 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   612   by simp
   613 
   614 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   615 by (simp only: split_tupled_all, simp)
   616 
   617 lemma mem_splitE:
   618   assumes major: "z \<in> split c p"
   619     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   620   shows Q
   621   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   622 
   623 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   624 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   625 
   626 ML {*
   627 local (* filtering with exists_p_split is an essential optimization *)
   628   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   629     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   630     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   631     | exists_p_split _ = false;
   632   val ss = HOL_basic_ss addsimps @{thms split_conv};
   633 in
   634 val split_conv_tac = SUBGOAL (fn (t, i) =>
   635     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   636 end;
   637 *}
   638 
   639 (* This prevents applications of splitE for already splitted arguments leading
   640    to quite time-consuming computations (in particular for nested tuples) *)
   641 declaration {* fn _ =>
   642   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   643 *}
   644 
   645 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   646   by (rule ext) fast
   647 
   648 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   649   by (rule ext) fast
   650 
   651 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   652   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   653   by (rule ext) blast
   654 
   655 (* Do NOT make this a simp rule as it
   656    a) only helps in special situations
   657    b) can lead to nontermination in the presence of split_def
   658 *)
   659 lemma split_comp_eq: 
   660   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   661   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   662   by (rule ext) auto
   663 
   664 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   665   apply (rule_tac x = "(a, b)" in image_eqI)
   666    apply auto
   667   done
   668 
   669 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   670   by blast
   671 
   672 (*
   673 the following  would be slightly more general,
   674 but cannot be used as rewrite rule:
   675 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   676 ### ?y = .x
   677 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   678 by (rtac some_equality 1)
   679 by ( Simp_tac 1)
   680 by (split_all_tac 1)
   681 by (Asm_full_simp_tac 1)
   682 qed "The_split_eq";
   683 *)
   684 
   685 text {*
   686   Setup of internal @{text split_rule}.
   687 *}
   688 
   689 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   690 
   691 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   692   by auto
   693 
   694 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   695   by (auto simp: split_tupled_all)
   696 
   697 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   698   by (induct p) auto
   699 
   700 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   701   by (induct p) auto
   702 
   703 declare prod_caseI2' [intro!] prod_caseI2 [intro!] prod_caseI [intro!]
   704 declare prod_caseE' [elim!] prod_caseE [elim!]
   705 
   706 lemma prod_case_beta:
   707   "prod_case f p = f (fst p) (snd p)"
   708   by (fact split_beta)
   709 
   710 lemma prod_cases3 [cases type]:
   711   obtains (fields) a b c where "y = (a, b, c)"
   712   by (cases y, case_tac b) blast
   713 
   714 lemma prod_induct3 [case_names fields, induct type]:
   715     "(!!a b c. P (a, b, c)) ==> P x"
   716   by (cases x) blast
   717 
   718 lemma prod_cases4 [cases type]:
   719   obtains (fields) a b c d where "y = (a, b, c, d)"
   720   by (cases y, case_tac c) blast
   721 
   722 lemma prod_induct4 [case_names fields, induct type]:
   723     "(!!a b c d. P (a, b, c, d)) ==> P x"
   724   by (cases x) blast
   725 
   726 lemma prod_cases5 [cases type]:
   727   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   728   by (cases y, case_tac d) blast
   729 
   730 lemma prod_induct5 [case_names fields, induct type]:
   731     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   732   by (cases x) blast
   733 
   734 lemma prod_cases6 [cases type]:
   735   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   736   by (cases y, case_tac e) blast
   737 
   738 lemma prod_induct6 [case_names fields, induct type]:
   739     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   740   by (cases x) blast
   741 
   742 lemma prod_cases7 [cases type]:
   743   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   744   by (cases y, case_tac f) blast
   745 
   746 lemma prod_induct7 [case_names fields, induct type]:
   747     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   748   by (cases x) blast
   749 
   750 lemma split_def:
   751   "split = (\<lambda>c p. c (fst p) (snd p))"
   752   by (fact prod_case_unfold)
   753 
   754 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   755   "internal_split == split"
   756 
   757 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   758   by (simp only: internal_split_def split_conv)
   759 
   760 use "Tools/split_rule.ML"
   761 setup Split_Rule.setup
   762 
   763 hide_const internal_split
   764 
   765 
   766 subsubsection {* Derived operations *}
   767 
   768 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   769   "curry = (\<lambda>c x y. c (x, y))"
   770 
   771 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   772   by (simp add: curry_def)
   773 
   774 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   775   by (simp add: curry_def)
   776 
   777 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   778   by (simp add: curry_def)
   779 
   780 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   781   by (simp add: curry_def)
   782 
   783 lemma curry_split [simp]: "curry (split f) = f"
   784   by (simp add: curry_def split_def)
   785 
   786 lemma split_curry [simp]: "split (curry f) = f"
   787   by (simp add: curry_def split_def)
   788 
   789 text {*
   790   The composition-uncurry combinator.
   791 *}
   792 
   793 notation fcomp (infixl "o>" 60)
   794 
   795 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "o\<rightarrow>" 60) where
   796   "f o\<rightarrow> g = (\<lambda>x. split g (f x))"
   797 
   798 lemma scomp_apply:  "(f o\<rightarrow> g) x = split g (f x)"
   799   by (simp add: scomp_def)
   800 
   801 lemma Pair_scomp: "Pair x o\<rightarrow> f = f x"
   802   by (simp add: expand_fun_eq scomp_apply)
   803 
   804 lemma scomp_Pair: "x o\<rightarrow> Pair = x"
   805   by (simp add: expand_fun_eq scomp_apply)
   806 
   807 lemma scomp_scomp: "(f o\<rightarrow> g) o\<rightarrow> h = f o\<rightarrow> (\<lambda>x. g x o\<rightarrow> h)"
   808   by (simp add: expand_fun_eq split_twice scomp_def)
   809 
   810 lemma scomp_fcomp: "(f o\<rightarrow> g) o> h = f o\<rightarrow> (\<lambda>x. g x o> h)"
   811   by (simp add: expand_fun_eq scomp_apply fcomp_def split_def)
   812 
   813 lemma fcomp_scomp: "(f o> g) o\<rightarrow> h = f o> (g o\<rightarrow> h)"
   814   by (simp add: expand_fun_eq scomp_apply fcomp_apply)
   815 
   816 code_const scomp
   817   (Eval infixl 3 "#->")
   818 
   819 no_notation fcomp (infixl "o>" 60)
   820 no_notation scomp (infixl "o\<rightarrow>" 60)
   821 
   822 text {*
   823   @{term prod_fun} --- action of the product functor upon
   824   functions.
   825 *}
   826 
   827 definition prod_fun :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   828   [code del]: "prod_fun f g = (\<lambda>(x, y). (f x, g y))"
   829 
   830 lemma prod_fun [simp, code]: "prod_fun f g (a, b) = (f a, g b)"
   831   by (simp add: prod_fun_def)
   832 
   833 lemma fst_prod_fun[simp]: "fst (prod_fun f g x) = f (fst x)"
   834 by (cases x, auto)
   835 
   836 lemma snd_prod_fun[simp]: "snd (prod_fun f g x) = g (snd x)"
   837 by (cases x, auto)
   838 
   839 lemma fst_comp_prod_fun[simp]: "fst \<circ> prod_fun f g = f \<circ> fst"
   840 by (rule ext) auto
   841 
   842 lemma snd_comp_prod_fun[simp]: "snd \<circ> prod_fun f g = g \<circ> snd"
   843 by (rule ext) auto
   844 
   845 
   846 lemma prod_fun_compose:
   847   "prod_fun (f1 o f2) (g1 o g2) = (prod_fun f1 g1 o prod_fun f2 g2)"
   848 by (rule ext) auto
   849 
   850 lemma prod_fun_ident [simp]: "prod_fun (%x. x) (%y. y) = (%z. z)"
   851   by (rule ext) auto
   852 
   853 lemma prod_fun_imageI [intro]: "(a, b) : r ==> (f a, g b) : prod_fun f g ` r"
   854   apply (rule image_eqI)
   855   apply (rule prod_fun [symmetric], assumption)
   856   done
   857 
   858 lemma prod_fun_imageE [elim!]:
   859   assumes major: "c: (prod_fun f g)`r"
   860     and cases: "!!x y. [| c=(f(x),g(y));  (x,y):r |] ==> P"
   861   shows P
   862   apply (rule major [THEN imageE])
   863   apply (case_tac x)
   864   apply (rule cases)
   865    apply (blast intro: prod_fun)
   866   apply blast
   867   done
   868 
   869 
   870 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   871   "apfst f = prod_fun f id"
   872 
   873 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   874   "apsnd f = prod_fun id f"
   875 
   876 lemma apfst_conv [simp, code]:
   877   "apfst f (x, y) = (f x, y)" 
   878   by (simp add: apfst_def)
   879 
   880 lemma apsnd_conv [simp, code]:
   881   "apsnd f (x, y) = (x, f y)" 
   882   by (simp add: apsnd_def)
   883 
   884 lemma fst_apfst [simp]:
   885   "fst (apfst f x) = f (fst x)"
   886   by (cases x) simp
   887 
   888 lemma fst_apsnd [simp]:
   889   "fst (apsnd f x) = fst x"
   890   by (cases x) simp
   891 
   892 lemma snd_apfst [simp]:
   893   "snd (apfst f x) = snd x"
   894   by (cases x) simp
   895 
   896 lemma snd_apsnd [simp]:
   897   "snd (apsnd f x) = f (snd x)"
   898   by (cases x) simp
   899 
   900 lemma apfst_compose:
   901   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   902   by (cases x) simp
   903 
   904 lemma apsnd_compose:
   905   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   906   by (cases x) simp
   907 
   908 lemma apfst_apsnd [simp]:
   909   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   910   by (cases x) simp
   911 
   912 lemma apsnd_apfst [simp]:
   913   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   914   by (cases x) simp
   915 
   916 lemma apfst_id [simp] :
   917   "apfst id = id"
   918   by (simp add: expand_fun_eq)
   919 
   920 lemma apsnd_id [simp] :
   921   "apsnd id = id"
   922   by (simp add: expand_fun_eq)
   923 
   924 lemma apfst_eq_conv [simp]:
   925   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   926   by (cases x) simp
   927 
   928 lemma apsnd_eq_conv [simp]:
   929   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   930   by (cases x) simp
   931 
   932 lemma apsnd_apfst_commute:
   933   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   934   by simp
   935 
   936 text {*
   937   Disjoint union of a family of sets -- Sigma.
   938 *}
   939 
   940 definition  Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   941   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   942 
   943 abbreviation
   944   Times :: "['a set, 'b set] => ('a * 'b) set"
   945     (infixr "<*>" 80) where
   946   "A <*> B == Sigma A (%_. B)"
   947 
   948 notation (xsymbols)
   949   Times  (infixr "\<times>" 80)
   950 
   951 notation (HTML output)
   952   Times  (infixr "\<times>" 80)
   953 
   954 syntax
   955   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   956 translations
   957   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   958 
   959 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   960   by (unfold Sigma_def) blast
   961 
   962 lemma SigmaE [elim!]:
   963     "[| c: Sigma A B;
   964         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   965      |] ==> P"
   966   -- {* The general elimination rule. *}
   967   by (unfold Sigma_def) blast
   968 
   969 text {*
   970   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   971   eigenvariables.
   972 *}
   973 
   974 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   975   by blast
   976 
   977 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   978   by blast
   979 
   980 lemma SigmaE2:
   981     "[| (a, b) : Sigma A B;
   982         [| a:A;  b:B(a) |] ==> P
   983      |] ==> P"
   984   by blast
   985 
   986 lemma Sigma_cong:
   987      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   988       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   989   by auto
   990 
   991 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   992   by blast
   993 
   994 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   995   by blast
   996 
   997 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   998   by blast
   999 
  1000 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
  1001   by auto
  1002 
  1003 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
  1004   by auto
  1005 
  1006 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
  1007   by auto
  1008 
  1009 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
  1010   by blast
  1011 
  1012 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
  1013   by blast
  1014 
  1015 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
  1016   by (blast elim: equalityE)
  1017 
  1018 lemma SetCompr_Sigma_eq:
  1019     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
  1020   by blast
  1021 
  1022 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
  1023   by blast
  1024 
  1025 lemma UN_Times_distrib:
  1026   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
  1027   -- {* Suggested by Pierre Chartier *}
  1028   by blast
  1029 
  1030 lemma split_paired_Ball_Sigma [simp,no_atp]:
  1031     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
  1032   by blast
  1033 
  1034 lemma split_paired_Bex_Sigma [simp,no_atp]:
  1035     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
  1036   by blast
  1037 
  1038 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
  1039   by blast
  1040 
  1041 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
  1042   by blast
  1043 
  1044 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
  1045   by blast
  1046 
  1047 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
  1048   by blast
  1049 
  1050 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
  1051   by blast
  1052 
  1053 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1054   by blast
  1055 
  1056 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1057   by blast
  1058 
  1059 text {*
  1060   Non-dependent versions are needed to avoid the need for higher-order
  1061   matching, especially when the rules are re-oriented.
  1062 *}
  1063 
  1064 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1065 by blast
  1066 
  1067 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1068 by blast
  1069 
  1070 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1071 by blast
  1072 
  1073 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1074   by auto
  1075 
  1076 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1077   by (auto intro!: image_eqI)
  1078 
  1079 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1080   by (auto intro!: image_eqI)
  1081 
  1082 lemma insert_times_insert[simp]:
  1083   "insert a A \<times> insert b B =
  1084    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1085 by blast
  1086 
  1087 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1088   by (auto, case_tac "f x", auto)
  1089 
  1090 text{* The following @{const prod_fun} lemmas are due to Joachim Breitner: *}
  1091 
  1092 lemma prod_fun_inj_on:
  1093   assumes "inj_on f A" and "inj_on g B"
  1094   shows "inj_on (prod_fun f g) (A \<times> B)"
  1095 proof (rule inj_onI)
  1096   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1097   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1098   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1099   assume "prod_fun f g x = prod_fun f g y"
  1100   hence "fst (prod_fun f g x) = fst (prod_fun f g y)" by (auto)
  1101   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1102   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1103   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1104   moreover from `prod_fun f g x = prod_fun f g y`
  1105   have "snd (prod_fun f g x) = snd (prod_fun f g y)" by (auto)
  1106   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1107   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1108   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1109   ultimately show "x = y" by(rule prod_eqI)
  1110 qed
  1111 
  1112 lemma prod_fun_surj:
  1113   assumes "surj f" and "surj g"
  1114   shows "surj (prod_fun f g)"
  1115 unfolding surj_def
  1116 proof
  1117   fix y :: "'b \<times> 'd"
  1118   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1119   moreover
  1120   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1121   ultimately have "(fst y, snd y) = prod_fun f g (a,b)" by auto
  1122   thus "\<exists>x. y = prod_fun f g x" by auto
  1123 qed
  1124 
  1125 lemma prod_fun_surj_on:
  1126   assumes "f ` A = A'" and "g ` B = B'"
  1127   shows "prod_fun f g ` (A \<times> B) = A' \<times> B'"
  1128 unfolding image_def
  1129 proof(rule set_ext,rule iffI)
  1130   fix x :: "'a \<times> 'c"
  1131   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = prod_fun f g x}"
  1132   then obtain y where "y \<in> A \<times> B" and "x = prod_fun f g y" by blast
  1133   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1134   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1135   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1136   with `x = prod_fun f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1137 next
  1138   fix x :: "'a \<times> 'c"
  1139   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1140   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1141   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1142   moreover from `image g B = B'` and `snd x \<in> B'`
  1143   obtain b where "b \<in> B" and "snd x = g b" by auto
  1144   ultimately have "(fst x, snd x) = prod_fun f g (a,b)" by auto
  1145   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1146   ultimately have "\<exists>y \<in> A \<times> B. x = prod_fun f g y" by auto
  1147   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = prod_fun f g y}" by auto
  1148 qed
  1149 
  1150 lemma swap_inj_on:
  1151   "inj_on (\<lambda>(i, j). (j, i)) A"
  1152   by (auto intro!: inj_onI)
  1153 
  1154 lemma swap_product:
  1155   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1156   by (simp add: split_def image_def) blast
  1157 
  1158 lemma image_split_eq_Sigma:
  1159   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1160 proof (safe intro!: imageI vimageI)
  1161   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1162   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1163     using * eq[symmetric] by auto
  1164 qed simp_all
  1165 
  1166 
  1167 subsection {* Inductively defined sets *}
  1168 
  1169 use "Tools/inductive_codegen.ML"
  1170 setup Inductive_Codegen.setup
  1171 
  1172 use "Tools/inductive_set.ML"
  1173 setup Inductive_Set.setup
  1174 
  1175 
  1176 subsection {* Legacy theorem bindings and duplicates *}
  1177 
  1178 lemma PairE:
  1179   obtains x y where "p = (x, y)"
  1180   by (fact prod.exhaust)
  1181 
  1182 lemma Pair_inject:
  1183   assumes "(a, b) = (a', b')"
  1184     and "a = a' ==> b = b' ==> R"
  1185   shows R
  1186   using assms by simp
  1187 
  1188 lemmas Pair_eq = prod.inject
  1189 
  1190 lemmas split = split_conv  -- {* for backwards compatibility *}
  1191 
  1192 end