src/HOL/Tools/datatype_package.ML
author haftmann
Sat Sep 15 19:27:44 2007 +0200 (2007-09-15)
changeset 24589 d3fca349736c
parent 24423 ae9cd0e92423
child 24624 b8383b1bbae3
permissions -rw-r--r--
clarified class interfaces and internals
     1 (*  Title:      HOL/Tools/datatype_package.ML
     2     ID:         $Id$
     3     Author:     Stefan Berghofer, TU Muenchen
     4 
     5 Datatype package for Isabelle/HOL.
     6 *)
     7 
     8 signature BASIC_DATATYPE_PACKAGE =
     9 sig
    10   val induct_tac : string -> int -> tactic
    11   val induct_thm_tac : thm -> string -> int -> tactic
    12   val case_tac : string -> int -> tactic
    13   val distinct_simproc : simproc
    14 end;
    15 
    16 signature DATATYPE_PACKAGE =
    17 sig
    18   include BASIC_DATATYPE_PACKAGE
    19   val quiet_mode : bool ref
    20   val add_datatype : bool -> string list -> (string list * bstring * mixfix *
    21     (bstring * string list * mixfix) list) list -> theory ->
    22       {distinct : thm list list,
    23        inject : thm list list,
    24        exhaustion : thm list,
    25        rec_thms : thm list,
    26        case_thms : thm list list,
    27        split_thms : (thm * thm) list,
    28        induction : thm,
    29        size : thm list,
    30        simps : thm list} * theory
    31   val add_datatype_i : bool -> bool -> string list -> (string list * bstring * mixfix *
    32     (bstring * typ list * mixfix) list) list -> theory ->
    33       {distinct : thm list list,
    34        inject : thm list list,
    35        exhaustion : thm list,
    36        rec_thms : thm list,
    37        case_thms : thm list list,
    38        split_thms : (thm * thm) list,
    39        induction : thm,
    40        size : thm list,
    41        simps : thm list} * theory
    42   val rep_datatype_i : string list option -> (thm list * attribute list) list list ->
    43     (thm list * attribute list) list list -> (thm list * attribute list) ->
    44     theory ->
    45       {distinct : thm list list,
    46        inject : thm list list,
    47        exhaustion : thm list,
    48        rec_thms : thm list,
    49        case_thms : thm list list,
    50        split_thms : (thm * thm) list,
    51        induction : thm,
    52        size : thm list,
    53        simps : thm list} * theory
    54   val rep_datatype : string list option -> (thmref * Attrib.src list) list list ->
    55     (thmref * Attrib.src list) list list -> thmref * Attrib.src list -> theory ->
    56       {distinct : thm list list,
    57        inject : thm list list,
    58        exhaustion : thm list,
    59        rec_thms : thm list,
    60        case_thms : thm list list,
    61        split_thms : (thm * thm) list,
    62        induction : thm,
    63        size : thm list,
    64        simps : thm list} * theory
    65   val get_datatypes : theory -> DatatypeAux.datatype_info Symtab.table
    66   val get_datatype : theory -> string -> DatatypeAux.datatype_info option
    67   val the_datatype : theory -> string -> DatatypeAux.datatype_info
    68   val datatype_of_constr : theory -> string -> DatatypeAux.datatype_info option
    69   val datatype_of_case : theory -> string -> DatatypeAux.datatype_info option
    70   val get_datatype_spec : theory -> string -> ((string * sort) list * (string * typ list) list) option
    71   val get_datatype_constrs : theory -> string -> (string * typ) list option
    72   val print_datatypes : theory -> unit
    73   val make_case :  Proof.context -> bool -> string list -> term ->
    74     (term * term) list -> term * (term * (int * bool)) list
    75   val strip_case: Proof.context -> bool ->
    76     term -> (term * (term * term) list) option
    77   val setup: theory -> theory
    78 end;
    79 
    80 structure DatatypePackage : DATATYPE_PACKAGE =
    81 struct
    82 
    83 open DatatypeAux;
    84 
    85 val quiet_mode = quiet_mode;
    86 
    87 
    88 (* theory data *)
    89 
    90 structure DatatypesData = TheoryDataFun
    91 (
    92   type T =
    93     {types: datatype_info Symtab.table,
    94      constrs: datatype_info Symtab.table,
    95      cases: datatype_info Symtab.table};
    96 
    97   val empty =
    98     {types = Symtab.empty, constrs = Symtab.empty, cases = Symtab.empty};
    99   val copy = I;
   100   val extend = I;
   101   fun merge _
   102     ({types = types1, constrs = constrs1, cases = cases1},
   103      {types = types2, constrs = constrs2, cases = cases2}) =
   104     {types = Symtab.merge (K true) (types1, types2),
   105      constrs = Symtab.merge (K true) (constrs1, constrs2),
   106      cases = Symtab.merge (K true) (cases1, cases2)};
   107 );
   108 
   109 val get_datatypes = #types o DatatypesData.get;
   110 val map_datatypes = DatatypesData.map;
   111 
   112 fun print_datatypes thy =
   113   Pretty.writeln (Pretty.strs ("datatypes:" ::
   114     map #1 (NameSpace.extern_table (Sign.type_space thy, get_datatypes thy))));
   115 
   116 
   117 (** theory information about datatypes **)
   118 
   119 fun put_dt_infos (dt_infos : (string * datatype_info) list) =
   120   map_datatypes (fn {types, constrs, cases} =>
   121     {types = fold Symtab.update dt_infos types,
   122      constrs = fold Symtab.update
   123        (maps (fn (_, info as {descr, index, ...}) => map (rpair info o fst)
   124           (#3 (the (AList.lookup op = descr index)))) dt_infos) constrs,
   125      cases = fold Symtab.update
   126        (map (fn (_, info as {case_name, ...}) => (case_name, info)) dt_infos)
   127        cases});
   128 
   129 val get_datatype = Symtab.lookup o get_datatypes;
   130 
   131 fun the_datatype thy name = (case get_datatype thy name of
   132       SOME info => info
   133     | NONE => error ("Unknown datatype " ^ quote name));
   134 
   135 val datatype_of_constr = Symtab.lookup o #constrs o DatatypesData.get;
   136 val datatype_of_case = Symtab.lookup o #cases o DatatypesData.get;
   137 
   138 fun get_datatype_descr thy dtco =
   139   get_datatype thy dtco
   140   |> Option.map (fn info as { descr, index, ... } => 
   141        (info, (((fn SOME (_, dtys, cos) => (dtys, cos)) o AList.lookup (op =) descr) index)));
   142 
   143 fun get_datatype_spec thy dtco =
   144   let
   145     fun mk_cons typ_of_dtyp (co, tys) =
   146       (co, map typ_of_dtyp tys);
   147     fun mk_dtyp ({ sorts = raw_sorts, descr, ... } : DatatypeAux.datatype_info, (dtys, cos)) =
   148       let
   149         val sorts = map ((fn v => (v, (the o AList.lookup (op =) raw_sorts) v))
   150           o DatatypeAux.dest_DtTFree) dtys;
   151         val typ_of_dtyp = DatatypeAux.typ_of_dtyp descr sorts;
   152         val tys = map typ_of_dtyp dtys;
   153       in (sorts, map (mk_cons typ_of_dtyp) cos) end;
   154   in Option.map mk_dtyp (get_datatype_descr thy dtco) end;
   155 
   156 fun get_datatype_constrs thy dtco =
   157   case get_datatype_spec thy dtco
   158    of SOME (sorts, cos) =>
   159         let
   160           fun subst (v, sort) = TVar ((v, 0), sort);
   161           fun subst_ty (TFree v) = subst v
   162             | subst_ty ty = ty;
   163           val dty = Type (dtco, map subst sorts);
   164           fun mk_co (co, tys) = (co, map (Term.map_atyps subst_ty) tys ---> dty);
   165         in SOME (map mk_co cos) end
   166     | NONE => NONE;
   167 
   168 fun find_tname var Bi =
   169   let val frees = map dest_Free (term_frees Bi)
   170       val params = rename_wrt_term Bi (Logic.strip_params Bi);
   171   in case AList.lookup (op =) (frees @ params) var of
   172        NONE => error ("No such variable in subgoal: " ^ quote var)
   173      | SOME(Type (tn, _)) => tn
   174      | _ => error ("Cannot determine type of " ^ quote var)
   175   end;
   176 
   177 fun infer_tname state i aterm =
   178   let
   179     val sign = Thm.theory_of_thm state;
   180     val (_, _, Bi, _) = Thm.dest_state (state, i)
   181     val params = Logic.strip_params Bi;   (*params of subgoal i*)
   182     val params = rev (rename_wrt_term Bi params);   (*as they are printed*)
   183     val (types, sorts) = types_sorts state;
   184     fun types' (a, ~1) = (case AList.lookup (op =) params a of NONE => types(a, ~1) | sm => sm)
   185       | types' ixn = types ixn;
   186     val ([ct], _) = Thm.read_def_cterms (sign, types', sorts) [] false [(aterm, dummyT)];
   187   in case #T (rep_cterm ct) of
   188        Type (tn, _) => tn
   189      | _ => error ("Cannot determine type of " ^ quote aterm)
   190   end;
   191 
   192 (*Warn if the (induction) variable occurs Free among the premises, which
   193   usually signals a mistake.  But calls the tactic either way!*)
   194 fun occs_in_prems tacf vars =
   195   SUBGOAL (fn (Bi, i) =>
   196            (if exists (fn (a, _) => member (op =) vars a)
   197                       (fold Term.add_frees (#2 (strip_context Bi)) [])
   198              then warning "Induction variable occurs also among premises!"
   199              else ();
   200             tacf i));
   201 
   202 
   203 (* generic induction tactic for datatypes *)
   204 
   205 local
   206 
   207 fun prep_var (Var (ixn, _), SOME x) = SOME (ixn, x)
   208   | prep_var _ = NONE;
   209 
   210 fun prep_inst (concl, xs) = (*exception Library.UnequalLengths*)
   211   let val vs = InductAttrib.vars_of concl
   212   in map_filter prep_var (Library.drop (length vs - length xs, vs) ~~ xs) end;
   213 
   214 in
   215 
   216 fun gen_induct_tac inst_tac (varss, opt_rule) i state = 
   217   SUBGOAL (fn (Bi,_) =>
   218   let
   219     val (rule, rule_name) =
   220       case opt_rule of
   221           SOME r => (r, "Induction rule")
   222         | NONE =>
   223             let val tn = find_tname (hd (map_filter I (flat varss))) Bi
   224                 val thy = Thm.theory_of_thm state
   225             in (#induction (the_datatype thy tn), "Induction rule for type " ^ tn) 
   226             end
   227     val concls = HOLogic.dest_concls (Thm.concl_of rule);
   228     val insts = maps prep_inst (concls ~~ varss) handle Library.UnequalLengths =>
   229       error (rule_name ^ " has different numbers of variables");
   230   in occs_in_prems (inst_tac insts rule) (map #2 insts) i end)
   231   i state;
   232 
   233 fun induct_tac s =
   234   gen_induct_tac Tactic.res_inst_tac'
   235     (map (single o SOME) (Syntax.read_idents s), NONE);
   236 
   237 fun induct_thm_tac th s =
   238   gen_induct_tac Tactic.res_inst_tac'
   239     ([map SOME (Syntax.read_idents s)], SOME th);
   240 
   241 end;
   242 
   243 
   244 (* generic case tactic for datatypes *)
   245 
   246 fun case_inst_tac inst_tac t rule i state =
   247   let
   248     val _ $ Var (ixn, _) $ _ = HOLogic.dest_Trueprop
   249       (hd (Logic.strip_assums_hyp (hd (Thm.prems_of rule))));
   250   in inst_tac [(ixn, t)] rule i state end;
   251 
   252 fun gen_case_tac inst_tac (t, SOME rule) i state =
   253       case_inst_tac inst_tac t rule i state
   254   | gen_case_tac inst_tac (t, NONE) i state =
   255       let val tn = infer_tname state i t in
   256         if tn = HOLogic.boolN then inst_tac [(("P", 0), t)] case_split_thm i state
   257         else case_inst_tac inst_tac t
   258                (#exhaustion (the_datatype (Thm.theory_of_thm state) tn))
   259                i state
   260       end handle THM _ => Seq.empty;
   261 
   262 fun case_tac t = gen_case_tac Tactic.res_inst_tac' (t, NONE);
   263 
   264 
   265 
   266 (** Isar tactic emulations **)
   267 
   268 local
   269 
   270 val rule_spec = Scan.lift (Args.$$$ "rule" -- Args.$$$ ":");
   271 val opt_rule = Scan.option (rule_spec |-- Attrib.thm);
   272 
   273 val varss =
   274   Args.and_list (Scan.repeat (Scan.unless rule_spec (Scan.lift (Args.maybe Args.name))));
   275 
   276 val inst_tac = RuleInsts.bires_inst_tac false;
   277 
   278 fun induct_meth ctxt (varss, opt_rule) =
   279   gen_induct_tac (inst_tac ctxt) (varss, opt_rule);
   280 fun case_meth ctxt (varss, opt_rule) =
   281   gen_case_tac (inst_tac ctxt) (varss, opt_rule);
   282 
   283 in
   284 
   285 val tactic_emulations =
   286  [("induct_tac", Method.goal_args_ctxt' (varss -- opt_rule) induct_meth,
   287     "induct_tac emulation (dynamic instantiation)"),
   288   ("case_tac", Method.goal_args_ctxt' (Scan.lift Args.name -- opt_rule) case_meth,
   289     "case_tac emulation (dynamic instantiation)")];
   290 
   291 end;
   292 
   293 
   294 
   295 (** induct method setup **)
   296 
   297 (* case names *)
   298 
   299 local
   300 
   301 fun dt_recs (DtTFree _) = []
   302   | dt_recs (DtType (_, dts)) = maps dt_recs dts
   303   | dt_recs (DtRec i) = [i];
   304 
   305 fun dt_cases (descr: descr) (_, args, constrs) =
   306   let
   307     fun the_bname i = Sign.base_name (#1 (the (AList.lookup (op =) descr i)));
   308     val bnames = map the_bname (distinct (op =) (maps dt_recs args));
   309   in map (fn (c, _) => space_implode "_" (Sign.base_name c :: bnames)) constrs end;
   310 
   311 
   312 fun induct_cases descr =
   313   DatatypeProp.indexify_names (maps (dt_cases descr) (map #2 descr));
   314 
   315 fun exhaust_cases descr i = dt_cases descr (the (AList.lookup (op =) descr i));
   316 
   317 in
   318 
   319 fun mk_case_names_induct descr = RuleCases.case_names (induct_cases descr);
   320 
   321 fun mk_case_names_exhausts descr new =
   322   map (RuleCases.case_names o exhaust_cases descr o #1)
   323     (filter (fn ((_, (name, _, _))) => member (op =) new name) descr);
   324 
   325 end;
   326 
   327 fun add_rules simps case_thms size_thms rec_thms inject distinct
   328                   weak_case_congs cong_att =
   329   PureThy.add_thmss [(("simps", simps), []),
   330     (("", flat case_thms @ size_thms @ 
   331           flat distinct @ rec_thms), [Simplifier.simp_add]),
   332     (("", size_thms @ rec_thms), [RecfunCodegen.add NONE]),
   333     (("", flat inject), [iff_add]),
   334     (("", map (fn th => th RS notE) (flat distinct)), [Classical.safe_elim NONE]),
   335     (("", weak_case_congs), [cong_att])]
   336   #> snd;
   337 
   338 
   339 (* add_cases_induct *)
   340 
   341 fun add_cases_induct infos induction thy =
   342   let
   343     val inducts = ProjectRule.projections (ProofContext.init thy) induction;
   344 
   345     fun named_rules (name, {index, exhaustion, ...}: datatype_info) =
   346       [(("", nth inducts index), [InductAttrib.induct_type name]),
   347        (("", exhaustion), [InductAttrib.cases_type name])];
   348     fun unnamed_rule i =
   349       (("", nth inducts i), [PureThy.kind_internal, InductAttrib.induct_type ""]);
   350   in
   351     thy |> PureThy.add_thms
   352       (maps named_rules infos @
   353         map unnamed_rule (length infos upto length inducts - 1)) |> snd
   354     |> PureThy.add_thmss [(("inducts", inducts), [])] |> snd
   355   end;
   356 
   357 
   358 
   359 (**** simplification procedure for showing distinctness of constructors ****)
   360 
   361 fun stripT (i, Type ("fun", [_, T])) = stripT (i + 1, T)
   362   | stripT p = p;
   363 
   364 fun stripC (i, f $ x) = stripC (i + 1, f)
   365   | stripC p = p;
   366 
   367 val distinctN = "constr_distinct";
   368 
   369 exception ConstrDistinct of term;
   370 
   371 fun distinct_proc thy ss (t as Const ("op =", _) $ t1 $ t2) =
   372   (case (stripC (0, t1), stripC (0, t2)) of
   373      ((i, Const (cname1, T1)), (j, Const (cname2, T2))) =>
   374          (case (stripT (0, T1), stripT (0, T2)) of
   375             ((i', Type (tname1, _)), (j', Type (tname2, _))) =>
   376                 if tname1 = tname2 andalso not (cname1 = cname2) andalso i = i' andalso j = j' then
   377                    (case (get_datatype_descr thy) tname1 of
   378                       SOME (_, (_, constrs)) => let val cnames = map fst constrs
   379                         in if cname1 mem cnames andalso cname2 mem cnames then
   380                              let val eq_t = Logic.mk_equals (t, Const ("False", HOLogic.boolT));
   381                                  val eq_ct = cterm_of thy eq_t;
   382                                  val Datatype_thy = ThyInfo.the_theory "Datatype" thy;
   383                                  val [In0_inject, In1_inject, In0_not_In1, In1_not_In0] =
   384                                    map (get_thm Datatype_thy o Name)
   385                                      ["In0_inject", "In1_inject", "In0_not_In1", "In1_not_In0"]
   386                              in (case (#distinct (the_datatype thy tname1)) of
   387                                  QuickAndDirty => SOME (Thm.invoke_oracle
   388                                    Datatype_thy distinctN (thy, ConstrDistinct eq_t))
   389                                | FewConstrs thms =>
   390                                    SOME (Goal.prove (Simplifier.the_context ss) [] [] eq_t (K
   391                                      (EVERY [rtac eq_reflection 1, rtac iffI 1, rtac notE 1,
   392                                        atac 2, resolve_tac thms 1, etac FalseE 1])))
   393                                | ManyConstrs (thm, simpset) =>
   394                                    SOME (Goal.prove (Simplifier.the_context ss) [] [] eq_t (K
   395                                      (EVERY [rtac eq_reflection 1, rtac iffI 1, dtac thm 1,
   396                                       full_simp_tac (Simplifier.inherit_context ss simpset) 1,
   397                                       REPEAT (dresolve_tac [In0_inject, In1_inject] 1),
   398                                       eresolve_tac [In0_not_In1 RS notE, In1_not_In0 RS notE] 1,
   399                                       etac FalseE 1]))))
   400                              end
   401                            else NONE
   402                         end
   403                     | NONE => NONE)
   404                 else NONE
   405           | _ => NONE)
   406    | _ => NONE)
   407   | distinct_proc _ _ _ = NONE;
   408 
   409 val distinct_simproc =
   410   Simplifier.simproc HOL.thy distinctN ["s = t"] distinct_proc;
   411 
   412 val dist_ss = HOL_ss addsimprocs [distinct_simproc];
   413 
   414 val simproc_setup =
   415   Theory.add_oracle (distinctN, fn (_, ConstrDistinct t) => t) #>
   416   (fn thy => ((change_simpset_of thy) (fn ss => ss addsimprocs [distinct_simproc]); thy));
   417 
   418 
   419 (**** translation rules for case ****)
   420 
   421 fun make_case ctxt = DatatypeCase.make_case
   422   (datatype_of_constr (ProofContext.theory_of ctxt)) ctxt;
   423 
   424 fun strip_case ctxt = DatatypeCase.strip_case
   425   (datatype_of_case (ProofContext.theory_of ctxt));
   426 
   427 fun add_case_tr' case_names thy =
   428   Theory.add_advanced_trfuns ([], [],
   429     map (fn case_name => 
   430       let val case_name' = Sign.const_syntax_name thy case_name
   431       in (case_name', DatatypeCase.case_tr' datatype_of_case case_name')
   432       end) case_names, []) thy;
   433 
   434 val trfun_setup =
   435   Theory.add_advanced_trfuns ([],
   436     [("_case_syntax", DatatypeCase.case_tr true datatype_of_constr)],
   437     [], []);
   438 
   439 
   440 (* prepare types *)
   441 
   442 fun read_typ sign ((Ts, sorts), str) =
   443   let
   444     val T = Type.no_tvars (Sign.read_def_typ (sign, AList.lookup (op =)
   445       (map (apfst (rpair ~1)) sorts)) str) handle TYPE (msg, _, _) => error msg
   446   in (Ts @ [T], add_typ_tfrees (T, sorts)) end;
   447 
   448 fun cert_typ sign ((Ts, sorts), raw_T) =
   449   let
   450     val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle
   451       TYPE (msg, _, _) => error msg;
   452     val sorts' = add_typ_tfrees (T, sorts)
   453   in (Ts @ [T],
   454       case duplicates (op =) (map fst sorts') of
   455          [] => sorts'
   456        | dups => error ("Inconsistent sort constraints for " ^ commas dups))
   457   end;
   458 
   459 
   460 (**** make datatype info ****)
   461 
   462 fun make_dt_info descr sorts induct reccomb_names rec_thms
   463     (((((((((i, (_, (tname, _, _))), case_name), case_thms),
   464       exhaustion_thm), distinct_thm), inject), nchotomy), case_cong), weak_case_cong) =
   465   (tname,
   466    {index = i,
   467     descr = descr,
   468     sorts = sorts,
   469     rec_names = reccomb_names,
   470     rec_rewrites = rec_thms,
   471     case_name = case_name,
   472     case_rewrites = case_thms,
   473     induction = induct,
   474     exhaustion = exhaustion_thm,
   475     distinct = distinct_thm,
   476     inject = inject,
   477     nchotomy = nchotomy,
   478     case_cong = case_cong,
   479     weak_case_cong = weak_case_cong});
   480 
   481 
   482 (********************* axiomatic introduction of datatypes ********************)
   483 
   484 fun add_axiom label t atts thy =
   485   thy
   486   |> PureThy.add_axioms_i [((label, t), atts)];
   487 
   488 fun add_axioms label ts atts thy =
   489   thy
   490   |> PureThy.add_axiomss_i [((label, ts), atts)];
   491 
   492 fun add_and_get_axioms_atts label tnames ts attss =
   493   fold_map (fn (tname, (atts, t)) => fn thy =>
   494     thy
   495     |> Theory.add_path tname
   496     |> add_axiom label t atts
   497     ||> Theory.parent_path
   498     |-> (fn [ax] => pair ax)) (tnames ~~ (attss ~~ ts));
   499 
   500 fun add_and_get_axioms label tnames ts =
   501   add_and_get_axioms_atts label tnames ts (replicate (length tnames) []);
   502 
   503 fun add_and_get_axiomss label tnames tss =
   504   fold_map (fn (tname, ts) => fn thy =>
   505     thy
   506     |> Theory.add_path tname
   507     |> add_axioms label ts []
   508     ||> Theory.parent_path
   509     |-> (fn [ax] => pair ax)) (tnames ~~ tss);
   510 
   511 fun gen_specify_consts add args thy =
   512   let
   513     val specs = map (fn (c, T, mx) =>
   514       Const (Sign.full_name thy (Syntax.const_name c mx), T)) args;
   515   in
   516     thy
   517     |> add args
   518     |> Theory.add_finals_i false specs
   519   end;
   520 
   521 val specify_consts = gen_specify_consts Sign.add_consts_i;
   522 val specify_consts_authentic = gen_specify_consts Sign.add_consts_authentic;
   523 
   524 fun add_datatype_axm flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   525     case_names_induct case_names_exhausts thy =
   526   let
   527     val descr' = flat descr;
   528     val recTs = get_rec_types descr' sorts;
   529     val used = map fst (fold Term.add_tfreesT recTs []);
   530     val newTs = Library.take (length (hd descr), recTs);
   531 
   532     val no_size = exists (fn (_, (_, _, constrs)) => exists (fn (_, cargs) => exists
   533       (fn dt => is_rec_type dt andalso not (null (fst (strip_dtyp dt))))
   534         cargs) constrs) descr';
   535 
   536     (**** declare new types and constants ****)
   537 
   538     val tyvars = map (fn (_, (_, Ts, _)) => map dest_DtTFree Ts) (hd descr);
   539 
   540     val constr_decls = map (fn (((_, (_, _, constrs)), T), constr_syntax') =>
   541       map (fn ((_, cargs), (cname, mx)) =>
   542         (cname, map (typ_of_dtyp descr' sorts) cargs ---> T, mx))
   543           (constrs ~~ constr_syntax')) ((hd descr) ~~ newTs ~~ constr_syntax);
   544 
   545     val (rec_result_Ts, reccomb_fn_Ts) = DatatypeProp.make_primrec_Ts descr sorts used;
   546 
   547     val big_reccomb_name = (space_implode "_" new_type_names) ^ "_rec";
   548     val reccomb_names = if length descr' = 1 then [big_reccomb_name] else
   549       (map ((curry (op ^) (big_reccomb_name ^ "_")) o string_of_int)
   550         (1 upto (length descr')));
   551 
   552     val size_names = DatatypeProp.indexify_names
   553       (map (fn T => name_of_typ T ^ "_size") (Library.drop (length (hd descr), recTs)));
   554 
   555     val freeT = TFree (Name.variant used "'t", HOLogic.typeS);
   556     val case_fn_Ts = map (fn (i, (_, _, constrs)) =>
   557       map (fn (_, cargs) =>
   558         let val Ts = map (typ_of_dtyp descr' sorts) cargs
   559         in Ts ---> freeT end) constrs) (hd descr);
   560 
   561     val case_names = map (fn s => (s ^ "_case")) new_type_names;
   562 
   563     fun instance_size_class tyco thy =
   564       let
   565         val n = Sign.arity_number thy tyco;
   566       in
   567         thy
   568         |> Class.prove_instance (Class.intro_classes_tac [])
   569             [(tyco, replicate n HOLogic.typeS, [HOLogic.class_size])] []
   570         |> snd
   571       end
   572 
   573     val thy2' = thy
   574 
   575       (** new types **)
   576       |> fold2 (fn (name, mx) => fn tvs => TypedefPackage.add_typedecls [(name, tvs, mx)])
   577            types_syntax tyvars
   578       |> fold (fn (_, (name, _, _)) => instance_size_class name) descr'
   579       |> add_path flat_names (space_implode "_" new_type_names)
   580 
   581       (** primrec combinators **)
   582 
   583       |> specify_consts (map (fn ((name, T), T') =>
   584            (name, reccomb_fn_Ts @ [T] ---> T', NoSyn)) (reccomb_names ~~ recTs ~~ rec_result_Ts))
   585 
   586       (** case combinators **)
   587 
   588       |> specify_consts_authentic (map (fn ((name, T), Ts) =>
   589            (name, Ts @ [T] ---> freeT, NoSyn)) (case_names ~~ newTs ~~ case_fn_Ts));
   590 
   591     val reccomb_names' = map (Sign.full_name thy2') reccomb_names;
   592     val case_names' = map (Sign.full_name thy2') case_names;
   593 
   594     val thy2 = thy2'
   595 
   596       (** size functions **)
   597 
   598       |> (if no_size then I else specify_consts (map (fn (s, T) =>
   599         (Sign.base_name s, T --> HOLogic.natT, NoSyn))
   600           (size_names ~~ Library.drop (length (hd descr), recTs))))
   601 
   602       (** constructors **)
   603 
   604       |> parent_path flat_names
   605       |> fold (fn ((((_, (_, _, constrs)), T), tname),
   606         constr_syntax') =>
   607           add_path flat_names tname #>
   608             specify_consts (map (fn ((_, cargs), (cname, mx)) =>
   609               (cname, map (typ_of_dtyp descr' sorts) cargs ---> T, mx))
   610                 (constrs ~~ constr_syntax')) #>
   611           parent_path flat_names)
   612             (hd descr ~~ newTs ~~ new_type_names ~~ constr_syntax);
   613 
   614     (**** introduction of axioms ****)
   615 
   616     val rec_axs = DatatypeProp.make_primrecs new_type_names descr sorts thy2;
   617     val size_axs = if no_size then [] else DatatypeProp.make_size descr sorts thy2;
   618 
   619     val ((([induct], [rec_thms]), inject), thy3) =
   620       thy2
   621       |> Theory.add_path (space_implode "_" new_type_names)
   622       |> add_axiom "induct" (DatatypeProp.make_ind descr sorts) [case_names_induct]
   623       ||>> add_axioms "recs" rec_axs []
   624       ||> (if no_size then I else add_axioms "size" size_axs [] #> snd)
   625       ||> Theory.parent_path
   626       ||>> add_and_get_axiomss "inject" new_type_names
   627             (DatatypeProp.make_injs descr sorts);
   628     val size_thms = if no_size then [] else get_thms thy3 (Name "size");
   629     val (distinct, thy4) = add_and_get_axiomss "distinct" new_type_names
   630       (DatatypeProp.make_distincts new_type_names descr sorts thy3) thy3;
   631 
   632     val exhaust_ts = DatatypeProp.make_casedists descr sorts;
   633     val (exhaustion, thy5) = add_and_get_axioms_atts "exhaust" new_type_names
   634       exhaust_ts (map single case_names_exhausts) thy4;
   635     val (case_thms, thy6) = add_and_get_axiomss "cases" new_type_names
   636       (DatatypeProp.make_cases new_type_names descr sorts thy5) thy5;
   637     val (split_ts, split_asm_ts) = ListPair.unzip
   638       (DatatypeProp.make_splits new_type_names descr sorts thy6);
   639     val (split, thy7) = add_and_get_axioms "split" new_type_names split_ts thy6;
   640     val (split_asm, thy8) = add_and_get_axioms "split_asm" new_type_names
   641       split_asm_ts thy7;
   642     val (nchotomys, thy9) = add_and_get_axioms "nchotomy" new_type_names
   643       (DatatypeProp.make_nchotomys descr sorts) thy8;
   644     val (case_congs, thy10) = add_and_get_axioms "case_cong" new_type_names
   645       (DatatypeProp.make_case_congs new_type_names descr sorts thy9) thy9;
   646     val (weak_case_congs, thy11) = add_and_get_axioms "weak_case_cong" new_type_names
   647       (DatatypeProp.make_weak_case_congs new_type_names descr sorts thy10) thy10;
   648 
   649     val dt_infos = map (make_dt_info descr' sorts induct reccomb_names' rec_thms)
   650       ((0 upto length (hd descr) - 1) ~~ (hd descr) ~~ case_names' ~~ case_thms ~~
   651         exhaustion ~~ replicate (length (hd descr)) QuickAndDirty ~~ inject ~~
   652           nchotomys ~~ case_congs ~~ weak_case_congs);
   653 
   654     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   655     val split_thms = split ~~ split_asm;
   656 
   657     val thy12 =
   658       thy11
   659       |> add_case_tr' case_names'
   660       |> Theory.add_path (space_implode "_" new_type_names)
   661       |> add_rules simps case_thms size_thms rec_thms inject distinct
   662           weak_case_congs Simplifier.cong_add
   663       |> put_dt_infos dt_infos
   664       |> add_cases_induct dt_infos induct
   665       |> Theory.parent_path
   666       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms)
   667       |> snd
   668       |> DatatypeRealizer.add_dt_realizers sorts (map snd dt_infos)
   669       |> DatatypeHooks.all (map fst dt_infos);
   670   in
   671     ({distinct = distinct,
   672       inject = inject,
   673       exhaustion = exhaustion,
   674       rec_thms = rec_thms,
   675       case_thms = case_thms,
   676       split_thms = split_thms,
   677       induction = induct,
   678       size = size_thms,
   679       simps = simps}, thy12)
   680   end;
   681 
   682 
   683 (******************* definitional introduction of datatypes *******************)
   684 
   685 fun add_datatype_def flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   686     case_names_induct case_names_exhausts thy =
   687   let
   688     val _ = message ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   689 
   690     val ((inject, distinct, dist_rewrites, simproc_dists, induct), thy2) = thy |>
   691       DatatypeRepProofs.representation_proofs flat_names dt_info new_type_names descr sorts
   692         types_syntax constr_syntax case_names_induct;
   693 
   694     val (casedist_thms, thy3) = DatatypeAbsProofs.prove_casedist_thms new_type_names descr
   695       sorts induct case_names_exhausts thy2;
   696     val ((reccomb_names, rec_thms), thy4) = DatatypeAbsProofs.prove_primrec_thms
   697       flat_names new_type_names descr sorts dt_info inject dist_rewrites
   698       (Simplifier.theory_context thy3 dist_ss) induct thy3;
   699     val ((case_thms, case_names), thy6) = DatatypeAbsProofs.prove_case_thms
   700       flat_names new_type_names descr sorts reccomb_names rec_thms thy4;
   701     val (split_thms, thy7) = DatatypeAbsProofs.prove_split_thms new_type_names
   702       descr sorts inject dist_rewrites casedist_thms case_thms thy6;
   703     val (nchotomys, thy8) = DatatypeAbsProofs.prove_nchotomys new_type_names
   704       descr sorts casedist_thms thy7;
   705     val (case_congs, thy9) = DatatypeAbsProofs.prove_case_congs new_type_names
   706       descr sorts nchotomys case_thms thy8;
   707     val (weak_case_congs, thy10) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   708       descr sorts thy9;
   709     val (size_thms, thy11) = DatatypeAbsProofs.prove_size_thms flat_names new_type_names
   710       descr sorts reccomb_names rec_thms thy10;
   711 
   712     val dt_infos = map (make_dt_info (flat descr) sorts induct reccomb_names rec_thms)
   713       ((0 upto length (hd descr) - 1) ~~ (hd descr) ~~ case_names ~~ case_thms ~~
   714         casedist_thms ~~ simproc_dists ~~ inject ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   715 
   716     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   717 
   718     val thy12 =
   719       thy11
   720       |> add_case_tr' case_names
   721       |> Theory.add_path (space_implode "_" new_type_names)
   722       |> add_rules simps case_thms size_thms rec_thms inject distinct
   723           weak_case_congs (Simplifier.attrib (op addcongs))
   724       |> put_dt_infos dt_infos
   725       |> add_cases_induct dt_infos induct
   726       |> Theory.parent_path
   727       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms) |> snd
   728       |> DatatypeRealizer.add_dt_realizers sorts (map snd dt_infos)
   729       |> DatatypeHooks.all (map fst dt_infos);
   730   in
   731     ({distinct = distinct,
   732       inject = inject,
   733       exhaustion = casedist_thms,
   734       rec_thms = rec_thms,
   735       case_thms = case_thms,
   736       split_thms = split_thms,
   737       induction = induct,
   738       size = size_thms,
   739       simps = simps}, thy12)
   740   end;
   741 
   742 
   743 (*********************** declare existing type as datatype *********************)
   744 
   745 fun gen_rep_datatype apply_theorems alt_names raw_distinct raw_inject raw_induction thy0 =
   746   let
   747     val (((distinct, inject), [induction]), thy1) =
   748       thy0
   749       |> fold_map apply_theorems raw_distinct
   750       ||>> fold_map apply_theorems raw_inject
   751       ||>> apply_theorems [raw_induction];
   752 
   753     val ((_, [induction']), _) =
   754       Variable.importT_thms [induction] (Variable.thm_context induction);
   755 
   756     fun err t = error ("Ill-formed predicate in induction rule: " ^
   757       Sign.string_of_term thy1 t);
   758 
   759     fun get_typ (t as _ $ Var (_, Type (tname, Ts))) =
   760           ((tname, map dest_TFree Ts) handle TERM _ => err t)
   761       | get_typ t = err t;
   762 
   763     val dtnames = map get_typ (HOLogic.dest_conj (HOLogic.dest_Trueprop (Thm.concl_of induction')));
   764     val new_type_names = getOpt (alt_names, map fst dtnames);
   765 
   766     fun get_constr t = (case Logic.strip_assums_concl t of
   767         _ $ (_ $ t') => (case head_of t' of
   768             Const (cname, cT) => (case strip_type cT of
   769                 (Ts, Type (tname, _)) => (tname, (cname, map (dtyp_of_typ dtnames) Ts))
   770               | _ => err t)
   771           | _ => err t)
   772       | _ => err t);
   773 
   774     fun make_dt_spec [] _ _ = []
   775       | make_dt_spec ((tname, tvs)::dtnames') i constrs =
   776           let val (constrs', constrs'') = take_prefix (equal tname o fst) constrs
   777           in (i, (tname, map DtTFree tvs, map snd constrs'))::
   778             (make_dt_spec dtnames' (i + 1) constrs'')
   779           end;
   780 
   781     val descr = make_dt_spec dtnames 0 (map get_constr (prems_of induction'));
   782     val sorts = add_term_tfrees (concl_of induction', []);
   783     val dt_info = get_datatypes thy1;
   784 
   785     val (case_names_induct, case_names_exhausts) =
   786       (mk_case_names_induct descr, mk_case_names_exhausts descr (map #1 dtnames));
   787 
   788     val _ = message ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   789 
   790     val (casedist_thms, thy2) = thy1 |>
   791       DatatypeAbsProofs.prove_casedist_thms new_type_names [descr] sorts induction
   792         case_names_exhausts;
   793     val ((reccomb_names, rec_thms), thy3) = DatatypeAbsProofs.prove_primrec_thms
   794       false new_type_names [descr] sorts dt_info inject distinct
   795       (Simplifier.theory_context thy2 dist_ss) induction thy2;
   796     val ((case_thms, case_names), thy4) = DatatypeAbsProofs.prove_case_thms false
   797       new_type_names [descr] sorts reccomb_names rec_thms thy3;
   798     val (split_thms, thy5) = DatatypeAbsProofs.prove_split_thms
   799       new_type_names [descr] sorts inject distinct casedist_thms case_thms thy4;
   800     val (nchotomys, thy6) = DatatypeAbsProofs.prove_nchotomys new_type_names
   801       [descr] sorts casedist_thms thy5;
   802     val (case_congs, thy7) = DatatypeAbsProofs.prove_case_congs new_type_names
   803       [descr] sorts nchotomys case_thms thy6;
   804     val (weak_case_congs, thy8) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   805       [descr] sorts thy7;
   806     val (size_thms, thy9) =
   807       DatatypeAbsProofs.prove_size_thms false new_type_names
   808         [descr] sorts reccomb_names rec_thms thy8;
   809 
   810     val ((_, [induction']), thy10) =
   811       thy9
   812       |> store_thmss "inject" new_type_names inject
   813       ||>> store_thmss "distinct" new_type_names distinct
   814       ||> Theory.add_path (space_implode "_" new_type_names)
   815       ||>> PureThy.add_thms [(("induct", induction), [case_names_induct])];
   816 
   817     val dt_infos = map (make_dt_info descr sorts induction' reccomb_names rec_thms)
   818       ((0 upto length descr - 1) ~~ descr ~~ case_names ~~ case_thms ~~ casedist_thms ~~
   819         map FewConstrs distinct ~~ inject ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   820 
   821     val simps = flat (distinct @ inject @ case_thms) @ size_thms @ rec_thms;
   822 
   823     val thy11 =
   824       thy10
   825       |> add_case_tr' case_names
   826       |> add_rules simps case_thms size_thms rec_thms inject distinct
   827            weak_case_congs (Simplifier.attrib (op addcongs))
   828       |> put_dt_infos dt_infos
   829       |> add_cases_induct dt_infos induction'
   830       |> Theory.parent_path
   831       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms)
   832       |> snd
   833       |> DatatypeRealizer.add_dt_realizers sorts (map snd dt_infos)
   834       |> DatatypeHooks.all (map fst dt_infos);
   835   in
   836     ({distinct = distinct,
   837       inject = inject,
   838       exhaustion = casedist_thms,
   839       rec_thms = rec_thms,
   840       case_thms = case_thms,
   841       split_thms = split_thms,
   842       induction = induction',
   843       size = size_thms,
   844       simps = simps}, thy11)
   845   end;
   846 
   847 val rep_datatype = gen_rep_datatype IsarCmd.apply_theorems;
   848 val rep_datatype_i = gen_rep_datatype IsarCmd.apply_theorems_i;
   849 
   850 
   851 
   852 (******************************** add datatype ********************************)
   853 
   854 fun gen_add_datatype prep_typ err flat_names new_type_names dts thy =
   855   let
   856     val _ = Theory.requires thy "Datatype" "datatype definitions";
   857 
   858     (* this theory is used just for parsing *)
   859 
   860     val tmp_thy = thy |>
   861       Theory.copy |>
   862       Theory.add_types (map (fn (tvs, tname, mx, _) =>
   863         (tname, length tvs, mx)) dts);
   864 
   865     val (tyvars, _, _, _)::_ = dts;
   866     val (new_dts, types_syntax) = ListPair.unzip (map (fn (tvs, tname, mx, _) =>
   867       let val full_tname = Sign.full_name tmp_thy (Syntax.type_name tname mx)
   868       in (case duplicates (op =) tvs of
   869             [] => if eq_set (tyvars, tvs) then ((full_tname, tvs), (tname, mx))
   870                   else error ("Mutually recursive datatypes must have same type parameters")
   871           | dups => error ("Duplicate parameter(s) for datatype " ^ full_tname ^
   872               " : " ^ commas dups))
   873       end) dts);
   874 
   875     val _ = (case duplicates (op =) (map fst new_dts) @ duplicates (op =) new_type_names of
   876       [] => () | dups => error ("Duplicate datatypes: " ^ commas dups));
   877 
   878     fun prep_dt_spec (tvs, tname, mx, constrs) (dts', constr_syntax, sorts, i) =
   879       let
   880         fun prep_constr (cname, cargs, mx') (constrs, constr_syntax', sorts') =
   881           let
   882             val (cargs', sorts'') = Library.foldl (prep_typ tmp_thy) (([], sorts'), cargs);
   883             val _ = (case fold (curry add_typ_tfree_names) cargs' [] \\ tvs of
   884                 [] => ()
   885               | vs => error ("Extra type variables on rhs: " ^ commas vs))
   886           in (constrs @ [((if flat_names then Sign.full_name tmp_thy else
   887                 Sign.full_name_path tmp_thy tname) (Syntax.const_name cname mx'),
   888                    map (dtyp_of_typ new_dts) cargs')],
   889               constr_syntax' @ [(cname, mx')], sorts'')
   890           end handle ERROR msg =>
   891             cat_error msg ("The error above occured in constructor " ^ cname ^
   892               " of datatype " ^ tname);
   893 
   894         val (constrs', constr_syntax', sorts') =
   895           fold prep_constr constrs ([], [], sorts)
   896 
   897       in
   898         case duplicates (op =) (map fst constrs') of
   899            [] =>
   900              (dts' @ [(i, (Sign.full_name tmp_thy (Syntax.type_name tname mx),
   901                 map DtTFree tvs, constrs'))],
   902               constr_syntax @ [constr_syntax'], sorts', i + 1)
   903          | dups => error ("Duplicate constructors " ^ commas dups ^
   904              " in datatype " ^ tname)
   905       end;
   906 
   907     val (dts', constr_syntax, sorts', i) = fold prep_dt_spec dts ([], [], [], 0);
   908     val sorts = sorts' @ (map (rpair (Sign.defaultS tmp_thy)) (tyvars \\ map fst sorts'));
   909     val dt_info = get_datatypes thy;
   910     val (descr, _) = unfold_datatypes tmp_thy dts' sorts dt_info dts' i;
   911     val _ = check_nonempty descr handle (exn as Datatype_Empty s) =>
   912       if err then error ("Nonemptiness check failed for datatype " ^ s)
   913       else raise exn;
   914 
   915     val descr' = flat descr;
   916     val case_names_induct = mk_case_names_induct descr';
   917     val case_names_exhausts = mk_case_names_exhausts descr' (map #1 new_dts);
   918   in
   919     (if (!quick_and_dirty) then add_datatype_axm else add_datatype_def)
   920       flat_names new_type_names descr sorts types_syntax constr_syntax dt_info
   921       case_names_induct case_names_exhausts thy
   922   end;
   923 
   924 val add_datatype_i = gen_add_datatype cert_typ;
   925 val add_datatype = gen_add_datatype read_typ true;
   926 
   927 
   928 
   929 (** package setup **)
   930 
   931 (* setup theory *)
   932 
   933 val setup =
   934   DatatypeProp.distinctness_limit_setup #>
   935   Method.add_methods tactic_emulations #>
   936   simproc_setup #>
   937   trfun_setup;
   938 
   939 
   940 (* outer syntax *)
   941 
   942 local structure P = OuterParse and K = OuterKeyword in
   943 
   944 val datatype_decl =
   945   Scan.option (P.$$$ "(" |-- P.name --| P.$$$ ")") -- P.type_args -- P.name -- P.opt_infix --
   946     (P.$$$ "=" |-- P.enum1 "|" (P.name -- Scan.repeat P.typ -- P.opt_mixfix));
   947 
   948 fun mk_datatype args =
   949   let
   950     val names = map (fn ((((NONE, _), t), _), _) => t | ((((SOME t, _), _), _), _) => t) args;
   951     val specs = map (fn ((((_, vs), t), mx), cons) =>
   952       (vs, t, mx, map (fn ((x, y), z) => (x, y, z)) cons)) args;
   953   in snd o add_datatype false names specs end;
   954 
   955 val datatypeP =
   956   OuterSyntax.command "datatype" "define inductive datatypes" K.thy_decl
   957     (P.and_list1 datatype_decl >> (Toplevel.theory o mk_datatype));
   958 
   959 
   960 val rep_datatype_decl =
   961   Scan.option (Scan.repeat1 P.name) --
   962     Scan.optional (P.$$$ "distinct" |-- P.!!! (P.and_list1 SpecParse.xthms1)) [[]] --
   963     Scan.optional (P.$$$ "inject" |-- P.!!! (P.and_list1 SpecParse.xthms1)) [[]] --
   964     (P.$$$ "induction" |-- P.!!! SpecParse.xthm);
   965 
   966 fun mk_rep_datatype (((opt_ts, dss), iss), ind) = #2 o rep_datatype opt_ts dss iss ind;
   967 
   968 val rep_datatypeP =
   969   OuterSyntax.command "rep_datatype" "represent existing types inductively" K.thy_decl
   970     (rep_datatype_decl >> (Toplevel.theory o mk_rep_datatype));
   971 
   972 
   973 val _ = OuterSyntax.add_keywords ["distinct", "inject", "induction"];
   974 val _ = OuterSyntax.add_parsers [datatypeP, rep_datatypeP];
   975 
   976 end;
   977 
   978 
   979 end;
   980 
   981 structure BasicDatatypePackage: BASIC_DATATYPE_PACKAGE = DatatypePackage;
   982 open BasicDatatypePackage;
   983