src/HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
author krauss
Mon Feb 21 23:14:36 2011 +0100 (2011-02-21)
changeset 41812 d46c2908a838
parent 41811 7e338ccabff0
child 41813 4eb43410d2fa
permissions -rw-r--r--
recdef -> fun; curried
     1 (*  Title:      HOL/Decision_Procs/Reflected_Multivariate_Polynomial.thy
     2     Author:     Amine Chaieb
     3 *)
     4 
     5 header {* Implementation and verification of multivariate polynomials *}
     6 
     7 theory Reflected_Multivariate_Polynomial
     8 imports Complex_Main "~~/src/HOL/Library/Abstract_Rat" Polynomial_List
     9 begin
    10 
    11   (* Implementation *)
    12 
    13 subsection{* Datatype of polynomial expressions *} 
    14 
    15 datatype poly = C Num| Bound nat| Add poly poly|Sub poly poly
    16   | Mul poly poly| Neg poly| Pw poly nat| CN poly nat poly
    17 
    18 abbreviation poly_0 :: "poly" ("0\<^sub>p") where "0\<^sub>p \<equiv> C (0\<^sub>N)"
    19 abbreviation poly_p :: "int \<Rightarrow> poly" ("_\<^sub>p") where "i\<^sub>p \<equiv> C (i\<^sub>N)"
    20 
    21 subsection{* Boundedness, substitution and all that *}
    22 primrec polysize:: "poly \<Rightarrow> nat" where
    23   "polysize (C c) = 1"
    24 | "polysize (Bound n) = 1"
    25 | "polysize (Neg p) = 1 + polysize p"
    26 | "polysize (Add p q) = 1 + polysize p + polysize q"
    27 | "polysize (Sub p q) = 1 + polysize p + polysize q"
    28 | "polysize (Mul p q) = 1 + polysize p + polysize q"
    29 | "polysize (Pw p n) = 1 + polysize p"
    30 | "polysize (CN c n p) = 4 + polysize c + polysize p"
    31 
    32 primrec polybound0:: "poly \<Rightarrow> bool" (* a poly is INDEPENDENT of Bound 0 *) where
    33   "polybound0 (C c) = True"
    34 | "polybound0 (Bound n) = (n>0)"
    35 | "polybound0 (Neg a) = polybound0 a"
    36 | "polybound0 (Add a b) = (polybound0 a \<and> polybound0 b)"
    37 | "polybound0 (Sub a b) = (polybound0 a \<and> polybound0 b)" 
    38 | "polybound0 (Mul a b) = (polybound0 a \<and> polybound0 b)"
    39 | "polybound0 (Pw p n) = (polybound0 p)"
    40 | "polybound0 (CN c n p) = (n \<noteq> 0 \<and> polybound0 c \<and> polybound0 p)"
    41 
    42 primrec polysubst0:: "poly \<Rightarrow> poly \<Rightarrow> poly" (* substitute a poly into a poly for Bound 0 *) where
    43   "polysubst0 t (C c) = (C c)"
    44 | "polysubst0 t (Bound n) = (if n=0 then t else Bound n)"
    45 | "polysubst0 t (Neg a) = Neg (polysubst0 t a)"
    46 | "polysubst0 t (Add a b) = Add (polysubst0 t a) (polysubst0 t b)"
    47 | "polysubst0 t (Sub a b) = Sub (polysubst0 t a) (polysubst0 t b)" 
    48 | "polysubst0 t (Mul a b) = Mul (polysubst0 t a) (polysubst0 t b)"
    49 | "polysubst0 t (Pw p n) = Pw (polysubst0 t p) n"
    50 | "polysubst0 t (CN c n p) = (if n=0 then Add (polysubst0 t c) (Mul t (polysubst0 t p))
    51                              else CN (polysubst0 t c) n (polysubst0 t p))"
    52 
    53 fun decrpoly:: "poly \<Rightarrow> poly" 
    54 where
    55   "decrpoly (Bound n) = Bound (n - 1)"
    56 | "decrpoly (Neg a) = Neg (decrpoly a)"
    57 | "decrpoly (Add a b) = Add (decrpoly a) (decrpoly b)"
    58 | "decrpoly (Sub a b) = Sub (decrpoly a) (decrpoly b)"
    59 | "decrpoly (Mul a b) = Mul (decrpoly a) (decrpoly b)"
    60 | "decrpoly (Pw p n) = Pw (decrpoly p) n"
    61 | "decrpoly (CN c n p) = CN (decrpoly c) (n - 1) (decrpoly p)"
    62 | "decrpoly a = a"
    63 
    64 subsection{* Degrees and heads and coefficients *}
    65 
    66 fun degree:: "poly \<Rightarrow> nat"
    67 where
    68   "degree (CN c 0 p) = 1 + degree p"
    69 | "degree p = 0"
    70 
    71 fun head:: "poly \<Rightarrow> poly"
    72 where
    73   "head (CN c 0 p) = head p"
    74 | "head p = p"
    75 
    76 (* More general notions of degree and head *)
    77 fun degreen:: "poly \<Rightarrow> nat \<Rightarrow> nat"
    78 where
    79   "degreen (CN c n p) = (\<lambda>m. if n=m then 1 + degreen p n else 0)"
    80  |"degreen p = (\<lambda>m. 0)"
    81 
    82 fun headn:: "poly \<Rightarrow> nat \<Rightarrow> poly"
    83 where
    84   "headn (CN c n p) = (\<lambda>m. if n \<le> m then headn p m else CN c n p)"
    85 | "headn p = (\<lambda>m. p)"
    86 
    87 fun coefficients:: "poly \<Rightarrow> poly list"
    88 where
    89   "coefficients (CN c 0 p) = c#(coefficients p)"
    90 | "coefficients p = [p]"
    91 
    92 fun isconstant:: "poly \<Rightarrow> bool"
    93 where
    94   "isconstant (CN c 0 p) = False"
    95 | "isconstant p = True"
    96 
    97 fun behead:: "poly \<Rightarrow> poly"
    98 where
    99   "behead (CN c 0 p) = (let p' = behead p in if p' = 0\<^sub>p then c else CN c 0 p')"
   100 | "behead p = 0\<^sub>p"
   101 
   102 fun headconst:: "poly \<Rightarrow> Num"
   103 where
   104   "headconst (CN c n p) = headconst p"
   105 | "headconst (C n) = n"
   106 
   107 subsection{* Operations for normalization *}
   108 
   109 
   110 consts 
   111   polysub :: "poly\<times>poly \<Rightarrow> poly"
   112   polymul :: "poly\<times>poly \<Rightarrow> poly"
   113 
   114 abbreviation poly_mul :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "*\<^sub>p" 60)
   115   where "a *\<^sub>p b \<equiv> polymul (a,b)"
   116 abbreviation poly_sub :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "-\<^sub>p" 60)
   117   where "a -\<^sub>p b \<equiv> polysub (a,b)"
   118 
   119 declare if_cong[fundef_cong del]
   120 declare let_cong[fundef_cong del]
   121 
   122 fun polyadd :: "poly \<Rightarrow> poly \<Rightarrow> poly" (infixl "+\<^sub>p" 60)
   123 where
   124   "polyadd (C c) (C c') = C (c+\<^sub>Nc')"
   125 |  "polyadd (C c) (CN c' n' p') = CN (polyadd (C c) c') n' p'"
   126 | "polyadd (CN c n p) (C c') = CN (polyadd c (C c')) n p"
   127 | "polyadd (CN c n p) (CN c' n' p') =
   128     (if n < n' then CN (polyadd c (CN c' n' p')) n p
   129      else if n'<n then CN (polyadd (CN c n p) c') n' p'
   130      else (let cc' = polyadd c c' ; 
   131                pp' = polyadd p p'
   132            in (if pp' = 0\<^sub>p then cc' else CN cc' n pp')))"
   133 | "polyadd a b = Add a b"
   134 
   135 
   136 fun polyneg :: "poly \<Rightarrow> poly" ("~\<^sub>p")
   137 where
   138   "polyneg (C c) = C (~\<^sub>N c)"
   139 | "polyneg (CN c n p) = CN (polyneg c) n (polyneg p)"
   140 | "polyneg a = Neg a"
   141 
   142 defs polysub_def[code]: "polysub \<equiv> \<lambda> (p,q). polyadd p (polyneg q)"
   143 
   144 recdef polymul "measure (\<lambda>(a,b). size a + size b)"
   145   "polymul(C c, C c') = C (c*\<^sub>Nc')"
   146   "polymul(C c, CN c' n' p') = 
   147       (if c = 0\<^sub>N then 0\<^sub>p else CN (polymul(C c,c')) n' (polymul(C c, p')))"
   148   "polymul(CN c n p, C c') = 
   149       (if c' = 0\<^sub>N  then 0\<^sub>p else CN (polymul(c,C c')) n (polymul(p, C c')))"
   150   "polymul(CN c n p, CN c' n' p') = 
   151   (if n<n' then CN (polymul(c,CN c' n' p')) n (polymul(p,CN c' n' p'))
   152   else if n' < n 
   153   then CN (polymul(CN c n p,c')) n' (polymul(CN c n p,p'))
   154   else polyadd (polymul(CN c n p, c')) (CN 0\<^sub>p n' (polymul(CN c n p, p'))))"
   155   "polymul (a,b) = Mul a b"
   156 (hints recdef_cong del: if_cong)
   157 
   158 declare if_cong[fundef_cong]
   159 declare let_cong[fundef_cong]
   160 
   161 fun polypow :: "nat \<Rightarrow> poly \<Rightarrow> poly"
   162 where
   163   "polypow 0 = (\<lambda>p. 1\<^sub>p)"
   164 | "polypow n = (\<lambda>p. let q = polypow (n div 2) p ; d = polymul(q,q) in 
   165                     if even n then d else polymul(p,d))"
   166 
   167 abbreviation poly_pow :: "poly \<Rightarrow> nat \<Rightarrow> poly" (infixl "^\<^sub>p" 60)
   168   where "a ^\<^sub>p k \<equiv> polypow k a"
   169 
   170 function polynate :: "poly \<Rightarrow> poly"
   171 where
   172   "polynate (Bound n) = CN 0\<^sub>p n 1\<^sub>p"
   173 | "polynate (Add p q) = (polynate p +\<^sub>p polynate q)"
   174 | "polynate (Sub p q) = (polynate p -\<^sub>p polynate q)"
   175 | "polynate (Mul p q) = (polynate p *\<^sub>p polynate q)"
   176 | "polynate (Neg p) = (~\<^sub>p (polynate p))"
   177 | "polynate (Pw p n) = ((polynate p) ^\<^sub>p n)"
   178 | "polynate (CN c n p) = polynate (Add c (Mul (Bound n) p))"
   179 | "polynate (C c) = C (normNum c)"
   180 by pat_completeness auto
   181 termination by (relation "measure polysize") auto
   182 
   183 fun poly_cmul :: "Num \<Rightarrow> poly \<Rightarrow> poly" where
   184   "poly_cmul y (C x) = C (y *\<^sub>N x)"
   185 | "poly_cmul y (CN c n p) = CN (poly_cmul y c) n (poly_cmul y p)"
   186 | "poly_cmul y p = C y *\<^sub>p p"
   187 
   188 definition monic :: "poly \<Rightarrow> (poly \<times> bool)" where
   189   "monic p \<equiv> (let h = headconst p in if h = 0\<^sub>N then (p,False) else ((C (Ninv h)) *\<^sub>p p, 0>\<^sub>N h))"
   190 
   191 subsection{* Pseudo-division *}
   192 
   193 definition shift1 :: "poly \<Rightarrow> poly" where
   194   "shift1 p \<equiv> CN 0\<^sub>p 0 p"
   195 
   196 abbreviation funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)" where
   197   "funpow \<equiv> compow"
   198 
   199 partial_function (tailrec) polydivide_aux :: "poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> nat \<times> poly"
   200   where
   201   "polydivide_aux a n p k s = 
   202   (if s = 0\<^sub>p then (k,s)
   203   else (let b = head s; m = degree s in
   204   (if m < n then (k,s) else 
   205   (let p'= funpow (m - n) shift1 p in 
   206   (if a = b then polydivide_aux a n p k (s -\<^sub>p p') 
   207   else polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (b *\<^sub>p p')))))))"
   208 
   209 definition polydivide :: "poly \<Rightarrow> poly \<Rightarrow> (nat \<times> poly)" where
   210   "polydivide s p \<equiv> polydivide_aux (head p) (degree p) p 0 s"
   211 
   212 fun poly_deriv_aux :: "nat \<Rightarrow> poly \<Rightarrow> poly" where
   213   "poly_deriv_aux n (CN c 0 p) = CN (poly_cmul ((int n)\<^sub>N) c) 0 (poly_deriv_aux (n + 1) p)"
   214 | "poly_deriv_aux n p = poly_cmul ((int n)\<^sub>N) p"
   215 
   216 fun poly_deriv :: "poly \<Rightarrow> poly" where
   217   "poly_deriv (CN c 0 p) = poly_deriv_aux 1 p"
   218 | "poly_deriv p = 0\<^sub>p"
   219 
   220   (* Verification *)
   221 lemma nth_pos2[simp]: "0 < n \<Longrightarrow> (x#xs) ! n = xs ! (n - 1)"
   222 using Nat.gr0_conv_Suc
   223 by clarsimp
   224 
   225 subsection{* Semantics of the polynomial representation *}
   226 
   227 primrec Ipoly :: "'a list \<Rightarrow> poly \<Rightarrow> 'a::{field_char_0, field_inverse_zero, power}" where
   228   "Ipoly bs (C c) = INum c"
   229 | "Ipoly bs (Bound n) = bs!n"
   230 | "Ipoly bs (Neg a) = - Ipoly bs a"
   231 | "Ipoly bs (Add a b) = Ipoly bs a + Ipoly bs b"
   232 | "Ipoly bs (Sub a b) = Ipoly bs a - Ipoly bs b"
   233 | "Ipoly bs (Mul a b) = Ipoly bs a * Ipoly bs b"
   234 | "Ipoly bs (Pw t n) = (Ipoly bs t) ^ n"
   235 | "Ipoly bs (CN c n p) = (Ipoly bs c) + (bs!n)*(Ipoly bs p)"
   236 
   237 abbreviation
   238   Ipoly_syntax :: "poly \<Rightarrow> 'a list \<Rightarrow>'a::{field_char_0, field_inverse_zero, power}" ("\<lparr>_\<rparr>\<^sub>p\<^bsup>_\<^esup>")
   239   where "\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<equiv> Ipoly bs p"
   240 
   241 lemma Ipoly_CInt: "Ipoly bs (C (i,1)) = of_int i" 
   242   by (simp add: INum_def)
   243 lemma Ipoly_CRat: "Ipoly bs (C (i, j)) = of_int i / of_int j" 
   244   by (simp  add: INum_def)
   245 
   246 lemmas RIpoly_eqs = Ipoly.simps(2-7) Ipoly_CInt Ipoly_CRat
   247 
   248 subsection {* Normal form and normalization *}
   249 
   250 fun isnpolyh:: "poly \<Rightarrow> nat \<Rightarrow> bool"
   251 where
   252   "isnpolyh (C c) = (\<lambda>k. isnormNum c)"
   253 | "isnpolyh (CN c n p) = (\<lambda>k. n \<ge> k \<and> (isnpolyh c (Suc n)) \<and> (isnpolyh p n) \<and> (p \<noteq> 0\<^sub>p))"
   254 | "isnpolyh p = (\<lambda>k. False)"
   255 
   256 lemma isnpolyh_mono: "\<lbrakk>n' \<le> n ; isnpolyh p n\<rbrakk> \<Longrightarrow> isnpolyh p n'"
   257 by (induct p rule: isnpolyh.induct, auto)
   258 
   259 definition isnpoly :: "poly \<Rightarrow> bool" where
   260   "isnpoly p \<equiv> isnpolyh p 0"
   261 
   262 text{* polyadd preserves normal forms *}
   263 
   264 lemma polyadd_normh: "\<lbrakk>isnpolyh p n0 ; isnpolyh q n1\<rbrakk> 
   265       \<Longrightarrow> isnpolyh (polyadd p q) (min n0 n1)"
   266 proof(induct p q arbitrary: n0 n1 rule: polyadd.induct)
   267   case (2 ab c' n' p' n0 n1)
   268   from prems have  th1: "isnpolyh (C ab) (Suc n')" by simp 
   269   from prems(3) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1" by simp_all
   270   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')" by simp
   271   with prems(1)[OF th1 th2] have th3:"isnpolyh (C ab +\<^sub>p c') (Suc n')" by simp
   272   from nplen1 have n01len1: "min n0 n1 \<le> n'" by simp 
   273   thus ?case using prems th3 by simp
   274 next
   275   case (3 c' n' p' ab n1 n0)
   276   from prems have  th1: "isnpolyh (C ab) (Suc n')" by simp 
   277   from prems(2) have th2: "isnpolyh c' (Suc n')"  and nplen1: "n' \<ge> n1" by simp_all
   278   with isnpolyh_mono have cp: "isnpolyh c' (Suc n')" by simp
   279   with prems(1)[OF th2 th1] have th3:"isnpolyh (c' +\<^sub>p C ab) (Suc n')" by simp
   280   from nplen1 have n01len1: "min n0 n1 \<le> n'" by simp 
   281   thus ?case using prems th3 by simp
   282 next
   283   case (4 c n p c' n' p' n0 n1)
   284   hence nc: "isnpolyh c (Suc n)" and np: "isnpolyh p n" by simp_all
   285   from prems have nc': "isnpolyh c' (Suc n')" and np': "isnpolyh p' n'" by simp_all 
   286   from prems have ngen0: "n \<ge> n0" by simp
   287   from prems have n'gen1: "n' \<ge> n1" by simp 
   288   have "n < n' \<or> n' < n \<or> n = n'" by auto
   289   moreover {assume eq: "n = n'"
   290     with "4.hyps"(3)[OF nc nc'] 
   291     have ncc':"isnpolyh (c +\<^sub>p c') (Suc n)" by auto
   292     hence ncc'n01: "isnpolyh (c +\<^sub>p c') (min n0 n1)"
   293       using isnpolyh_mono[where n'="min n0 n1" and n="Suc n"] ngen0 n'gen1 by auto
   294     from eq "4.hyps"(4)[OF np np'] have npp': "isnpolyh (p +\<^sub>p p') n" by simp
   295     have minle: "min n0 n1 \<le> n'" using ngen0 n'gen1 eq by simp
   296     from minle npp' ncc'n01 prems ngen0 n'gen1 ncc' have ?case by (simp add: Let_def)}
   297   moreover {assume lt: "n < n'"
   298     have "min n0 n1 \<le> n0" by simp
   299     with prems have th1:"min n0 n1 \<le> n" by auto 
   300     from prems have th21: "isnpolyh c (Suc n)" by simp
   301     from prems have th22: "isnpolyh (CN c' n' p') n'" by simp
   302     from lt have th23: "min (Suc n) n' = Suc n" by arith
   303     from "4.hyps"(1)[OF th21 th22]
   304     have "isnpolyh (polyadd c (CN c' n' p')) (Suc n)" using th23 by simp
   305     with prems th1 have ?case by simp } 
   306   moreover {assume gt: "n' < n" hence gt': "n' < n \<and> \<not> n < n'" by simp
   307     have "min n0 n1 \<le> n1"  by simp
   308     with prems have th1:"min n0 n1 \<le> n'" by auto
   309     from prems have th21: "isnpolyh c' (Suc n')" by simp_all
   310     from prems have th22: "isnpolyh (CN c n p) n" by simp
   311     from gt have th23: "min n (Suc n') = Suc n'" by arith
   312     from "4.hyps"(2)[OF th22 th21]
   313     have "isnpolyh (polyadd (CN c n p) c') (Suc n')" using th23 by simp
   314     with prems th1 have ?case by simp}
   315       ultimately show ?case by blast
   316 qed auto
   317 
   318 lemma polyadd[simp]: "Ipoly bs (polyadd p q) = Ipoly bs p + Ipoly bs q"
   319 by (induct p q rule: polyadd.induct, auto simp add: Let_def field_simps right_distrib[symmetric] simp del: right_distrib)
   320 
   321 lemma polyadd_norm: "\<lbrakk> isnpoly p ; isnpoly q\<rbrakk> \<Longrightarrow> isnpoly (polyadd p q)"
   322   using polyadd_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   323 
   324 text{* The degree of addition and other general lemmas needed for the normal form of polymul *}
   325 
   326 lemma polyadd_different_degreen: 
   327   "\<lbrakk>isnpolyh p n0 ; isnpolyh q n1; degreen p m \<noteq> degreen q m ; m \<le> min n0 n1\<rbrakk> \<Longrightarrow> 
   328   degreen (polyadd p q) m = max (degreen p m) (degreen q m)"
   329 proof (induct p q arbitrary: m n0 n1 rule: polyadd.induct)
   330   case (4 c n p c' n' p' m n0 n1)
   331   have "n' = n \<or> n < n' \<or> n' < n" by arith
   332   thus ?case
   333   proof (elim disjE)
   334     assume [simp]: "n' = n"
   335     from 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   336     show ?thesis by (auto simp: Let_def)
   337   next
   338     assume "n < n'"
   339     with 4 show ?thesis by auto
   340   next
   341     assume "n' < n"
   342     with 4 show ?thesis by auto
   343   qed
   344 qed auto
   345 
   346 lemma headnz[simp]: "\<lbrakk>isnpolyh p n ; p \<noteq> 0\<^sub>p\<rbrakk> \<Longrightarrow> headn p m \<noteq> 0\<^sub>p"
   347   by (induct p arbitrary: n rule: headn.induct, auto)
   348 lemma degree_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> degree p = 0"
   349   by (induct p arbitrary: n rule: degree.induct, auto)
   350 lemma degreen_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> degreen p m = 0"
   351   by (induct p arbitrary: n rule: degreen.induct, auto)
   352 
   353 lemma degree_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> degree p = 0"
   354   by (induct p arbitrary: n rule: degree.induct, auto)
   355 
   356 lemma degree_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degree c = 0"
   357   using degree_isnpolyh_Suc by auto
   358 lemma degreen_npolyhCN[simp]: "isnpolyh (CN c n p) n0 \<Longrightarrow> degreen c n = 0"
   359   using degreen_0 by auto
   360 
   361 
   362 lemma degreen_polyadd:
   363   assumes np: "isnpolyh p n0" and nq: "isnpolyh q n1" and m: "m \<le> max n0 n1"
   364   shows "degreen (p +\<^sub>p q) m \<le> max (degreen p m) (degreen q m)"
   365   using np nq m
   366 proof (induct p q arbitrary: n0 n1 m rule: polyadd.induct)
   367   case (2 c c' n' p' n0 n1) thus ?case  by (cases n', simp_all)
   368 next
   369   case (3 c n p c' n0 n1) thus ?case by (cases n, auto)
   370 next
   371   case (4 c n p c' n' p' n0 n1 m) 
   372   have "n' = n \<or> n < n' \<or> n' < n" by arith
   373   thus ?case
   374   proof (elim disjE)
   375     assume [simp]: "n' = n"
   376     from 4(4)[of n n m] 4(3)[of "Suc n" "Suc n" m] 4(5-7)
   377     show ?thesis by (auto simp: Let_def)
   378   qed simp_all
   379 qed auto
   380 
   381 lemma polyadd_eq_const_degreen: "\<lbrakk> isnpolyh p n0 ; isnpolyh q n1 ; polyadd p q = C c\<rbrakk> 
   382   \<Longrightarrow> degreen p m = degreen q m"
   383 proof (induct p q arbitrary: m n0 n1 c rule: polyadd.induct)
   384   case (4 c n p c' n' p' m n0 n1 x) 
   385   {assume nn': "n' < n" hence ?case using prems by simp}
   386   moreover 
   387   {assume nn':"\<not> n' < n" hence "n < n' \<or> n = n'" by arith
   388     moreover {assume "n < n'" with prems have ?case by simp }
   389     moreover {assume eq: "n = n'" hence ?case using prems 
   390         apply (cases "p +\<^sub>p p' = 0\<^sub>p")
   391         apply (auto simp add: Let_def)
   392         by blast
   393       }
   394     ultimately have ?case by blast}
   395   ultimately show ?case by blast
   396 qed simp_all
   397 
   398 lemma polymul_properties:
   399   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   400   and np: "isnpolyh p n0" and nq: "isnpolyh q n1" and m: "m \<le> min n0 n1"
   401   shows "isnpolyh (p *\<^sub>p q) (min n0 n1)" 
   402   and "(p *\<^sub>p q = 0\<^sub>p) = (p = 0\<^sub>p \<or> q = 0\<^sub>p)" 
   403   and "degreen (p *\<^sub>p q) m = (if (p = 0\<^sub>p \<or> q = 0\<^sub>p) then 0 
   404                              else degreen p m + degreen q m)"
   405   using np nq m
   406 proof(induct p q arbitrary: n0 n1 m rule: polymul.induct)
   407   case (2 a b c' n' p') 
   408   let ?c = "(a,b)"
   409   { case (1 n0 n1) 
   410     with "2.hyps"(1-3)[of n' n' n']
   411       and "2.hyps"(4-6)[of "Suc n'" "Suc n'" n']
   412     show ?case by (auto simp add: min_def)
   413   next
   414     case (2 n0 n1) thus ?case by auto 
   415   next
   416     case (3 n0 n1) thus ?case  using "2.hyps" by auto } 
   417 next
   418   case (3 c n p a b)
   419   let ?c' = "(a,b)"
   420   { case (1 n0 n1) 
   421     with "3.hyps"(1-3)[of n n n]
   422       "3.hyps"(4-6)[of "Suc n" "Suc n" n]
   423     show ?case by (auto simp add: min_def)
   424   next
   425     case (2 n0 n1) thus ?case by auto
   426   next
   427     case (3 n0 n1) thus ?case  using "3.hyps" by auto } 
   428 next
   429   case (4 c n p c' n' p')
   430   let ?cnp = "CN c n p" let ?cnp' = "CN c' n' p'"
   431     {
   432       case (1 n0 n1)
   433       hence cnp: "isnpolyh ?cnp n" and cnp': "isnpolyh ?cnp' n'"
   434         and np: "isnpolyh p n" and nc: "isnpolyh c (Suc n)" 
   435         and np': "isnpolyh p' n'" and nc': "isnpolyh c' (Suc n')"
   436         and nn0: "n \<ge> n0" and nn1:"n' \<ge> n1"
   437         by simp_all
   438       { assume "n < n'"
   439         with "4.hyps"(13-14)[OF np cnp', of n]
   440           "4.hyps"(16)[OF nc cnp', of n] nn0 cnp
   441         have ?case by (simp add: min_def)
   442       } moreover {
   443         assume "n' < n"
   444         with "4.hyps"(1-2)[OF cnp np', of "n'"]
   445           "4.hyps"(4)[OF cnp nc', of "Suc n'"] nn1 cnp'
   446         have ?case
   447           by (cases "Suc n' = n", simp_all add: min_def)
   448       } moreover {
   449         assume "n' = n"
   450         with "4.hyps"(1-2)[OF cnp np', of n]
   451           "4.hyps"(4)[OF cnp nc', of n] cnp cnp' nn1 nn0
   452         have ?case
   453           apply (auto intro!: polyadd_normh)
   454           apply (simp_all add: min_def isnpolyh_mono[OF nn0])
   455           done
   456       }
   457       ultimately show ?case by arith
   458     next
   459       fix n0 n1 m
   460       assume np: "isnpolyh ?cnp n0" and np':"isnpolyh ?cnp' n1"
   461       and m: "m \<le> min n0 n1"
   462       let ?d = "degreen (?cnp *\<^sub>p ?cnp') m"
   463       let ?d1 = "degreen ?cnp m"
   464       let ?d2 = "degreen ?cnp' m"
   465       let ?eq = "?d = (if ?cnp = 0\<^sub>p \<or> ?cnp' = 0\<^sub>p then 0  else ?d1 + ?d2)"
   466       have "n'<n \<or> n < n' \<or> n' = n" by auto
   467       moreover 
   468       {assume "n' < n \<or> n < n'"
   469         with "4.hyps"(3,15,18) np np' m 
   470         have ?eq by auto }
   471       moreover
   472       {assume nn': "n' = n" hence nn:"\<not> n' < n \<and> \<not> n < n'" by arith
   473         from "4.hyps"(1,3)[of n n' n]
   474           "4.hyps"(4,5)[of n "Suc n'" n]
   475           np np' nn'
   476         have norm: "isnpolyh ?cnp n" "isnpolyh c' (Suc n)" "isnpolyh (?cnp *\<^sub>p c') n"
   477           "isnpolyh p' n" "isnpolyh (?cnp *\<^sub>p p') n" "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   478           "(?cnp *\<^sub>p c' = 0\<^sub>p) = (c' = 0\<^sub>p)" 
   479           "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p" by (auto simp add: min_def)
   480         {assume mn: "m = n" 
   481           from "4.hyps"(2,3)[OF norm(1,4), of n]
   482             "4.hyps"(4,6)[OF norm(1,2), of n] norm nn' mn
   483           have degs:  "degreen (?cnp *\<^sub>p c') n = 
   484             (if c'=0\<^sub>p then 0 else ?d1 + degreen c' n)"
   485             "degreen (?cnp *\<^sub>p p') n = ?d1  + degreen p' n" by (simp_all add: min_def)
   486           from degs norm
   487           have th1: "degreen(?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n" by simp
   488           hence neq: "degreen (?cnp *\<^sub>p c') n \<noteq> degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n"
   489             by simp
   490           have nmin: "n \<le> min n n" by (simp add: min_def)
   491           from polyadd_different_degreen[OF norm(3,6) neq nmin] th1
   492           have deg: "degreen (CN c n p *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n = degreen (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n" by simp 
   493           from "4.hyps"(1-3)[OF norm(1,4), of n]
   494             "4.hyps"(4-6)[OF norm(1,2), of n]
   495             mn norm m nn' deg
   496           have ?eq by simp}
   497         moreover
   498         {assume mn: "m \<noteq> n" hence mn': "m < n" using m np by auto
   499           from nn' m np have max1: "m \<le> max n n"  by simp 
   500           hence min1: "m \<le> min n n" by simp     
   501           hence min2: "m \<le> min n (Suc n)" by simp
   502           from "4.hyps"(1-3)[OF norm(1,4) min1]
   503             "4.hyps"(4-6)[OF norm(1,2) min2]
   504             degreen_polyadd[OF norm(3,6) max1]
   505 
   506           have "degreen (?cnp *\<^sub>p c' +\<^sub>p CN 0\<^sub>p n (?cnp *\<^sub>p p')) m 
   507             \<le> max (degreen (?cnp *\<^sub>p c') m) (degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) m)"
   508             using mn nn' np np' by simp
   509           with "4.hyps"(1-3)[OF norm(1,4) min1]
   510             "4.hyps"(4-6)[OF norm(1,2) min2]
   511             degreen_0[OF norm(3) mn']
   512           have ?eq using nn' mn np np' by clarsimp}
   513         ultimately have ?eq by blast}
   514       ultimately show ?eq by blast}
   515     { case (2 n0 n1)
   516       hence np: "isnpolyh ?cnp n0" and np': "isnpolyh ?cnp' n1" 
   517         and m: "m \<le> min n0 n1" by simp_all
   518       hence mn: "m \<le> n" by simp
   519       let ?c0p = "CN 0\<^sub>p n (?cnp *\<^sub>p p')"
   520       {assume C: "?cnp *\<^sub>p c' +\<^sub>p ?c0p = 0\<^sub>p" "n' = n"
   521         hence nn: "\<not>n' < n \<and> \<not> n<n'" by simp
   522         from "4.hyps"(1-3) [of n n n]
   523           "4.hyps"(4-6)[of n "Suc n" n]
   524           np np' C(2) mn
   525         have norm: "isnpolyh ?cnp n" "isnpolyh c' (Suc n)" "isnpolyh (?cnp *\<^sub>p c') n"
   526           "isnpolyh p' n" "isnpolyh (?cnp *\<^sub>p p') n" "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n"
   527           "(?cnp *\<^sub>p c' = 0\<^sub>p) = (c' = 0\<^sub>p)" 
   528           "?cnp *\<^sub>p p' \<noteq> 0\<^sub>p" 
   529           "degreen (?cnp *\<^sub>p c') n = (if c'=0\<^sub>p then 0 else degreen ?cnp n + degreen c' n)"
   530             "degreen (?cnp *\<^sub>p p') n = degreen ?cnp n + degreen p' n"
   531           by (simp_all add: min_def)
   532             
   533           from norm have cn: "isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n" by simp
   534           have degneq: "degreen (?cnp *\<^sub>p c') n < degreen (CN 0\<^sub>p n (?cnp *\<^sub>p p')) n" 
   535             using norm by simp
   536         from polyadd_eq_const_degreen[OF norm(3) cn C(1), where m="n"]  degneq
   537         have "False" by simp }
   538       thus ?case using "4.hyps" by clarsimp}
   539 qed auto
   540 
   541 lemma polymul[simp]: "Ipoly bs (p *\<^sub>p q) = (Ipoly bs p) * (Ipoly bs q)"
   542 by(induct p q rule: polymul.induct, auto simp add: field_simps)
   543 
   544 lemma polymul_normh: 
   545     assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   546   shows "\<lbrakk>isnpolyh p n0 ; isnpolyh q n1\<rbrakk> \<Longrightarrow> isnpolyh (p *\<^sub>p q) (min n0 n1)"
   547   using polymul_properties(1)  by blast
   548 lemma polymul_eq0_iff: 
   549   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   550   shows "\<lbrakk> isnpolyh p n0 ; isnpolyh q n1\<rbrakk> \<Longrightarrow> (p *\<^sub>p q = 0\<^sub>p) = (p = 0\<^sub>p \<or> q = 0\<^sub>p) "
   551   using polymul_properties(2)  by blast
   552 lemma polymul_degreen:  
   553   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   554   shows "\<lbrakk> isnpolyh p n0 ; isnpolyh q n1 ; m \<le> min n0 n1\<rbrakk> \<Longrightarrow> degreen (p *\<^sub>p q) m = (if (p = 0\<^sub>p \<or> q = 0\<^sub>p) then 0 else degreen p m + degreen q m)"
   555   using polymul_properties(3) by blast
   556 lemma polymul_norm:   
   557   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   558   shows "\<lbrakk> isnpoly p; isnpoly q\<rbrakk> \<Longrightarrow> isnpoly (polymul (p,q))"
   559   using polymul_normh[of "p" "0" "q" "0"] isnpoly_def by simp
   560 
   561 lemma headconst_zero: "isnpolyh p n0 \<Longrightarrow> headconst p = 0\<^sub>N \<longleftrightarrow> p = 0\<^sub>p"
   562   by (induct p arbitrary: n0 rule: headconst.induct, auto)
   563 
   564 lemma headconst_isnormNum: "isnpolyh p n0 \<Longrightarrow> isnormNum (headconst p)"
   565   by (induct p arbitrary: n0, auto)
   566 
   567 lemma monic_eqI: assumes np: "isnpolyh p n0" 
   568   shows "INum (headconst p) * Ipoly bs (fst (monic p)) = (Ipoly bs p ::'a::{field_char_0, field_inverse_zero, power})"
   569   unfolding monic_def Let_def
   570 proof(cases "headconst p = 0\<^sub>N", simp_all add: headconst_zero[OF np])
   571   let ?h = "headconst p"
   572   assume pz: "p \<noteq> 0\<^sub>p"
   573   {assume hz: "INum ?h = (0::'a)"
   574     from headconst_isnormNum[OF np] have norm: "isnormNum ?h" "isnormNum 0\<^sub>N" by simp_all
   575     from isnormNum_unique[where ?'a = 'a, OF norm] hz have "?h = 0\<^sub>N" by simp
   576     with headconst_zero[OF np] have "p =0\<^sub>p" by blast with pz have "False" by blast}
   577   thus "INum (headconst p) = (0::'a) \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0" by blast
   578 qed
   579 
   580 
   581 text{* polyneg is a negation and preserves normal forms *}
   582 
   583 lemma polyneg[simp]: "Ipoly bs (polyneg p) = - Ipoly bs p"
   584 by (induct p rule: polyneg.induct, auto)
   585 
   586 lemma polyneg0: "isnpolyh p n \<Longrightarrow> ((~\<^sub>p p) = 0\<^sub>p) = (p = 0\<^sub>p)"
   587   by (induct p arbitrary: n rule: polyneg.induct, auto simp add: Nneg_def)
   588 lemma polyneg_polyneg: "isnpolyh p n0 \<Longrightarrow> ~\<^sub>p (~\<^sub>p p) = p"
   589   by (induct p arbitrary: n0 rule: polyneg.induct, auto)
   590 lemma polyneg_normh: "\<And>n. isnpolyh p n \<Longrightarrow> isnpolyh (polyneg p) n "
   591 by (induct p rule: polyneg.induct, auto simp add: polyneg0)
   592 
   593 lemma polyneg_norm: "isnpoly p \<Longrightarrow> isnpoly (polyneg p)"
   594   using isnpoly_def polyneg_normh by simp
   595 
   596 
   597 text{* polysub is a substraction and preserves normal forms *}
   598 
   599 lemma polysub[simp]: "Ipoly bs (polysub (p,q)) = (Ipoly bs p) - (Ipoly bs q)"
   600 by (simp add: polysub_def polyneg polyadd)
   601 lemma polysub_normh: "\<And> n0 n1. \<lbrakk> isnpolyh p n0 ; isnpolyh q n1\<rbrakk> \<Longrightarrow> isnpolyh (polysub(p,q)) (min n0 n1)"
   602 by (simp add: polysub_def polyneg_normh polyadd_normh)
   603 
   604 lemma polysub_norm: "\<lbrakk> isnpoly p; isnpoly q\<rbrakk> \<Longrightarrow> isnpoly (polysub(p,q))"
   605   using polyadd_norm polyneg_norm by (simp add: polysub_def) 
   606 lemma polysub_same_0[simp]:   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   607   shows "isnpolyh p n0 \<Longrightarrow> polysub (p, p) = 0\<^sub>p"
   608 unfolding polysub_def split_def fst_conv snd_conv
   609 by (induct p arbitrary: n0,auto simp add: Let_def Nsub0[simplified Nsub_def])
   610 
   611 lemma polysub_0: 
   612   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   613   shows "\<lbrakk> isnpolyh p n0 ; isnpolyh q n1\<rbrakk> \<Longrightarrow> (p -\<^sub>p q = 0\<^sub>p) = (p = q)"
   614   unfolding polysub_def split_def fst_conv snd_conv
   615   by (induct p q arbitrary: n0 n1 rule:polyadd.induct)
   616   (auto simp: Nsub0[simplified Nsub_def] Let_def)
   617 
   618 text{* polypow is a power function and preserves normal forms *}
   619 
   620 lemma polypow[simp]: "Ipoly bs (polypow n p) = ((Ipoly bs p :: 'a::{field_char_0, field_inverse_zero})) ^ n"
   621 proof(induct n rule: polypow.induct)
   622   case 1 thus ?case by simp
   623 next
   624   case (2 n)
   625   let ?q = "polypow ((Suc n) div 2) p"
   626   let ?d = "polymul(?q,?q)"
   627   have "odd (Suc n) \<or> even (Suc n)" by simp
   628   moreover 
   629   {assume odd: "odd (Suc n)"
   630     have th: "(Suc (Suc (Suc (0\<Colon>nat)) * (Suc n div Suc (Suc (0\<Colon>nat))))) = Suc n div 2 + Suc n div 2 + 1" by arith
   631     from odd have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs (polymul(p, ?d))" by (simp add: Let_def)
   632     also have "\<dots> = (Ipoly bs p) * (Ipoly bs p)^(Suc n div 2)*(Ipoly bs p)^(Suc n div 2)"
   633       using "2.hyps" by simp
   634     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2 + 1)"
   635       apply (simp only: power_add power_one_right) by simp
   636     also have "\<dots> = (Ipoly bs p) ^ (Suc (Suc (Suc (0\<Colon>nat)) * (Suc n div Suc (Suc (0\<Colon>nat)))))"
   637       by (simp only: th)
   638     finally have ?case 
   639     using odd_nat_div_two_times_two_plus_one[OF odd, symmetric] by simp  }
   640   moreover 
   641   {assume even: "even (Suc n)"
   642     have th: "(Suc (Suc (0\<Colon>nat))) * (Suc n div Suc (Suc (0\<Colon>nat))) = Suc n div 2 + Suc n div 2" by arith
   643     from even have "Ipoly bs (p ^\<^sub>p Suc n) = Ipoly bs ?d" by (simp add: Let_def)
   644     also have "\<dots> = (Ipoly bs p) ^ (Suc n div 2 + Suc n div 2)"
   645       using "2.hyps" apply (simp only: power_add) by simp
   646     finally have ?case using even_nat_div_two_times_two[OF even] by (simp only: th)}
   647   ultimately show ?case by blast
   648 qed
   649 
   650 lemma polypow_normh: 
   651     assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   652   shows "isnpolyh p n \<Longrightarrow> isnpolyh (polypow k p) n"
   653 proof (induct k arbitrary: n rule: polypow.induct)
   654   case (2 k n)
   655   let ?q = "polypow (Suc k div 2) p"
   656   let ?d = "polymul (?q,?q)"
   657   from prems have th1:"isnpolyh ?q n" and th2: "isnpolyh p n" by blast+
   658   from polymul_normh[OF th1 th1] have dn: "isnpolyh ?d n" by simp
   659   from polymul_normh[OF th2 dn] have on: "isnpolyh (polymul(p,?d)) n" by simp
   660   from dn on show ?case by (simp add: Let_def)
   661 qed auto 
   662 
   663 lemma polypow_norm:   
   664   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   665   shows "isnpoly p \<Longrightarrow> isnpoly (polypow k p)"
   666   by (simp add: polypow_normh isnpoly_def)
   667 
   668 text{* Finally the whole normalization *}
   669 
   670 lemma polynate[simp]: "Ipoly bs (polynate p) = (Ipoly bs p :: 'a ::{field_char_0, field_inverse_zero})"
   671 by (induct p rule:polynate.induct, auto)
   672 
   673 lemma polynate_norm[simp]: 
   674   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
   675   shows "isnpoly (polynate p)"
   676   by (induct p rule: polynate.induct, simp_all add: polyadd_norm polymul_norm polysub_norm polyneg_norm polypow_norm) (simp_all add: isnpoly_def)
   677 
   678 text{* shift1 *}
   679 
   680 
   681 lemma shift1: "Ipoly bs (shift1 p) = Ipoly bs (Mul (Bound 0) p)"
   682 by (simp add: shift1_def polymul)
   683 
   684 lemma shift1_isnpoly: 
   685   assumes pn: "isnpoly p" and pnz: "p \<noteq> 0\<^sub>p" shows "isnpoly (shift1 p) "
   686   using pn pnz by (simp add: shift1_def isnpoly_def )
   687 
   688 lemma shift1_nz[simp]:"shift1 p \<noteq> 0\<^sub>p"
   689   by (simp add: shift1_def)
   690 lemma funpow_shift1_isnpoly: 
   691   "\<lbrakk> isnpoly p ; p \<noteq> 0\<^sub>p\<rbrakk> \<Longrightarrow> isnpoly (funpow n shift1 p)"
   692   by (induct n arbitrary: p) (auto simp add: shift1_isnpoly funpow_swap1)
   693 
   694 lemma funpow_isnpolyh: 
   695   assumes f: "\<And> p. isnpolyh p n \<Longrightarrow> isnpolyh (f p) n "and np: "isnpolyh p n"
   696   shows "isnpolyh (funpow k f p) n"
   697   using f np by (induct k arbitrary: p, auto)
   698 
   699 lemma funpow_shift1: "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0, field_inverse_zero}) = Ipoly bs (Mul (Pw (Bound 0) n) p)"
   700   by (induct n arbitrary: p, simp_all add: shift1_isnpoly shift1 power_Suc )
   701 
   702 lemma shift1_isnpolyh: "isnpolyh p n0 \<Longrightarrow> p\<noteq> 0\<^sub>p \<Longrightarrow> isnpolyh (shift1 p) 0"
   703   using isnpolyh_mono[where n="n0" and n'="0" and p="p"] by (simp add: shift1_def)
   704 
   705 lemma funpow_shift1_1: 
   706   "(Ipoly bs (funpow n shift1 p) :: 'a :: {field_char_0, field_inverse_zero}) = Ipoly bs (funpow n shift1 1\<^sub>p *\<^sub>p p)"
   707   by (simp add: funpow_shift1)
   708 
   709 lemma poly_cmul[simp]: "Ipoly bs (poly_cmul c p) = Ipoly bs (Mul (C c) p)"
   710 by (induct p  arbitrary: n0 rule: poly_cmul.induct, auto simp add: field_simps)
   711 
   712 lemma behead:
   713   assumes np: "isnpolyh p n"
   714   shows "Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) = (Ipoly bs p :: 'a :: {field_char_0, field_inverse_zero})"
   715   using np
   716 proof (induct p arbitrary: n rule: behead.induct)
   717   case (1 c p n) hence pn: "isnpolyh p n" by simp
   718   from prems(2)[OF pn] 
   719   have th:"Ipoly bs (Add (Mul (head p) (Pw (Bound 0) (degree p))) (behead p)) = Ipoly bs p" . 
   720   then show ?case using "1.hyps" apply (simp add: Let_def,cases "behead p = 0\<^sub>p")
   721     by (simp_all add: th[symmetric] field_simps power_Suc)
   722 qed (auto simp add: Let_def)
   723 
   724 lemma behead_isnpolyh:
   725   assumes np: "isnpolyh p n" shows "isnpolyh (behead p) n"
   726   using np by (induct p rule: behead.induct, auto simp add: Let_def isnpolyh_mono)
   727 
   728 subsection{* Miscellaneous lemmas about indexes, decrementation, substitution  etc ... *}
   729 lemma isnpolyh_polybound0: "isnpolyh p (Suc n) \<Longrightarrow> polybound0 p"
   730 proof(induct p arbitrary: n rule: poly.induct, auto)
   731   case (goal1 c n p n')
   732   hence "n = Suc (n - 1)" by simp
   733   hence "isnpolyh p (Suc (n - 1))"  using `isnpolyh p n` by simp
   734   with prems(2) show ?case by simp
   735 qed
   736 
   737 lemma isconstant_polybound0: "isnpolyh p n0 \<Longrightarrow> isconstant p \<longleftrightarrow> polybound0 p"
   738 by (induct p arbitrary: n0 rule: isconstant.induct, auto simp add: isnpolyh_polybound0)
   739 
   740 lemma decrpoly_zero[simp]: "decrpoly p = 0\<^sub>p \<longleftrightarrow> p = 0\<^sub>p" by (induct p, auto)
   741 
   742 lemma decrpoly_normh: "isnpolyh p n0 \<Longrightarrow> polybound0 p \<Longrightarrow> isnpolyh (decrpoly p) (n0 - 1)"
   743   apply (induct p arbitrary: n0, auto)
   744   apply (atomize)
   745   apply (erule_tac x = "Suc nat" in allE)
   746   apply auto
   747   done
   748 
   749 lemma head_polybound0: "isnpolyh p n0 \<Longrightarrow> polybound0 (head p)"
   750  by (induct p  arbitrary: n0 rule: head.induct, auto intro: isnpolyh_polybound0)
   751 
   752 lemma polybound0_I:
   753   assumes nb: "polybound0 a"
   754   shows "Ipoly (b#bs) a = Ipoly (b'#bs) a"
   755 using nb
   756 by (induct a rule: poly.induct) auto 
   757 lemma polysubst0_I:
   758   shows "Ipoly (b#bs) (polysubst0 a t) = Ipoly ((Ipoly (b#bs) a)#bs) t"
   759   by (induct t) simp_all
   760 
   761 lemma polysubst0_I':
   762   assumes nb: "polybound0 a"
   763   shows "Ipoly (b#bs) (polysubst0 a t) = Ipoly ((Ipoly (b'#bs) a)#bs) t"
   764   by (induct t) (simp_all add: polybound0_I[OF nb, where b="b" and b'="b'"])
   765 
   766 lemma decrpoly: assumes nb: "polybound0 t"
   767   shows "Ipoly (x#bs) t = Ipoly bs (decrpoly t)"
   768   using nb by (induct t rule: decrpoly.induct, simp_all)
   769 
   770 lemma polysubst0_polybound0: assumes nb: "polybound0 t"
   771   shows "polybound0 (polysubst0 t a)"
   772 using nb by (induct a rule: poly.induct, auto)
   773 
   774 lemma degree0_polybound0: "isnpolyh p n \<Longrightarrow> degree p = 0 \<Longrightarrow> polybound0 p"
   775   by (induct p arbitrary: n rule: degree.induct, auto simp add: isnpolyh_polybound0)
   776 
   777 primrec maxindex :: "poly \<Rightarrow> nat" where
   778   "maxindex (Bound n) = n + 1"
   779 | "maxindex (CN c n p) = max  (n + 1) (max (maxindex c) (maxindex p))"
   780 | "maxindex (Add p q) = max (maxindex p) (maxindex q)"
   781 | "maxindex (Sub p q) = max (maxindex p) (maxindex q)"
   782 | "maxindex (Mul p q) = max (maxindex p) (maxindex q)"
   783 | "maxindex (Neg p) = maxindex p"
   784 | "maxindex (Pw p n) = maxindex p"
   785 | "maxindex (C x) = 0"
   786 
   787 definition wf_bs :: "'a list \<Rightarrow> poly \<Rightarrow> bool" where
   788   "wf_bs bs p = (length bs \<ge> maxindex p)"
   789 
   790 lemma wf_bs_coefficients: "wf_bs bs p \<Longrightarrow> \<forall> c \<in> set (coefficients p). wf_bs bs c"
   791 proof(induct p rule: coefficients.induct)
   792   case (1 c p) 
   793   show ?case 
   794   proof
   795     fix x assume xc: "x \<in> set (coefficients (CN c 0 p))"
   796     hence "x = c \<or> x \<in> set (coefficients p)" by simp
   797     moreover 
   798     {assume "x = c" hence "wf_bs bs x" using "1.prems"  unfolding wf_bs_def by simp}
   799     moreover 
   800     {assume H: "x \<in> set (coefficients p)" 
   801       from "1.prems" have "wf_bs bs p" unfolding wf_bs_def by simp
   802       with "1.hyps" H have "wf_bs bs x" by blast }
   803     ultimately  show "wf_bs bs x" by blast
   804   qed
   805 qed simp_all
   806 
   807 lemma maxindex_coefficients: " \<forall>c\<in> set (coefficients p). maxindex c \<le> maxindex p"
   808 by (induct p rule: coefficients.induct, auto)
   809 
   810 lemma wf_bs_I: "wf_bs bs p ==> Ipoly (bs@bs') p = Ipoly bs p"
   811   unfolding wf_bs_def by (induct p, auto simp add: nth_append)
   812 
   813 lemma take_maxindex_wf: assumes wf: "wf_bs bs p" 
   814   shows "Ipoly (take (maxindex p) bs) p = Ipoly bs p"
   815 proof-
   816   let ?ip = "maxindex p"
   817   let ?tbs = "take ?ip bs"
   818   from wf have "length ?tbs = ?ip" unfolding wf_bs_def by simp
   819   hence wf': "wf_bs ?tbs p" unfolding wf_bs_def by  simp
   820   have eq: "bs = ?tbs @ (drop ?ip bs)" by simp
   821   from wf_bs_I[OF wf', of "drop ?ip bs"] show ?thesis using eq by simp
   822 qed
   823 
   824 lemma decr_maxindex: "polybound0 p \<Longrightarrow> maxindex (decrpoly p) = maxindex p - 1"
   825   by (induct p, auto)
   826 
   827 lemma wf_bs_insensitive: "length bs = length bs' \<Longrightarrow> wf_bs bs p = wf_bs bs' p"
   828   unfolding wf_bs_def by simp
   829 
   830 lemma wf_bs_insensitive': "wf_bs (x#bs) p = wf_bs (y#bs) p"
   831   unfolding wf_bs_def by simp
   832 
   833 
   834 
   835 lemma wf_bs_coefficients': "\<forall>c \<in> set (coefficients p). wf_bs bs c \<Longrightarrow> wf_bs (x#bs) p"
   836 by(induct p rule: coefficients.induct, auto simp add: wf_bs_def)
   837 lemma coefficients_Nil[simp]: "coefficients p \<noteq> []"
   838   by (induct p rule: coefficients.induct, simp_all)
   839 
   840 
   841 lemma coefficients_head: "last (coefficients p) = head p"
   842   by (induct p rule: coefficients.induct, auto)
   843 
   844 lemma wf_bs_decrpoly: "wf_bs bs (decrpoly p) \<Longrightarrow> wf_bs (x#bs) p"
   845   unfolding wf_bs_def by (induct p rule: decrpoly.induct, auto)
   846 
   847 lemma length_le_list_ex: "length xs \<le> n \<Longrightarrow> \<exists> ys. length (xs @ ys) = n"
   848   apply (rule exI[where x="replicate (n - length xs) z"])
   849   by simp
   850 lemma isnpolyh_Suc_const:"isnpolyh p (Suc n) \<Longrightarrow> isconstant p"
   851 by (cases p, auto) (case_tac "nat", simp_all)
   852 
   853 lemma wf_bs_polyadd: "wf_bs bs p \<and> wf_bs bs q \<longrightarrow> wf_bs bs (p +\<^sub>p q)"
   854   unfolding wf_bs_def 
   855   apply (induct p q rule: polyadd.induct)
   856   apply (auto simp add: Let_def)
   857   done
   858 
   859 lemma wf_bs_polyul: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p *\<^sub>p q)"
   860   unfolding wf_bs_def 
   861   apply (induct p q arbitrary: bs rule: polymul.induct) 
   862   apply (simp_all add: wf_bs_polyadd)
   863   apply clarsimp
   864   apply (rule wf_bs_polyadd[unfolded wf_bs_def, rule_format])
   865   apply auto
   866   done
   867 
   868 lemma wf_bs_polyneg: "wf_bs bs p \<Longrightarrow> wf_bs bs (~\<^sub>p p)"
   869   unfolding wf_bs_def by (induct p rule: polyneg.induct, auto)
   870 
   871 lemma wf_bs_polysub: "wf_bs bs p \<Longrightarrow> wf_bs bs q \<Longrightarrow> wf_bs bs (p -\<^sub>p q)"
   872   unfolding polysub_def split_def fst_conv snd_conv using wf_bs_polyadd wf_bs_polyneg by blast
   873 
   874 subsection{* Canonicity of polynomial representation, see lemma isnpolyh_unique*}
   875 
   876 definition "polypoly bs p = map (Ipoly bs) (coefficients p)"
   877 definition "polypoly' bs p = map ((Ipoly bs o decrpoly)) (coefficients p)"
   878 definition "poly_nate bs p = map ((Ipoly bs o decrpoly)) (coefficients (polynate p))"
   879 
   880 lemma coefficients_normh: "isnpolyh p n0 \<Longrightarrow> \<forall> q \<in> set (coefficients p). isnpolyh q n0"
   881 proof (induct p arbitrary: n0 rule: coefficients.induct)
   882   case (1 c p n0)
   883   have cp: "isnpolyh (CN c 0 p) n0" by fact
   884   hence norm: "isnpolyh c 0" "isnpolyh p 0" "p \<noteq> 0\<^sub>p" "n0 = 0"
   885     by (auto simp add: isnpolyh_mono[where n'=0])
   886   from "1.hyps"[OF norm(2)] norm(1) norm(4)  show ?case by simp 
   887 qed auto
   888 
   889 lemma coefficients_isconst:
   890   "isnpolyh p n \<Longrightarrow> \<forall>q\<in>set (coefficients p). isconstant q"
   891   by (induct p arbitrary: n rule: coefficients.induct, 
   892     auto simp add: isnpolyh_Suc_const)
   893 
   894 lemma polypoly_polypoly':
   895   assumes np: "isnpolyh p n0"
   896   shows "polypoly (x#bs) p = polypoly' bs p"
   897 proof-
   898   let ?cf = "set (coefficients p)"
   899   from coefficients_normh[OF np] have cn_norm: "\<forall> q\<in> ?cf. isnpolyh q n0" .
   900   {fix q assume q: "q \<in> ?cf"
   901     from q cn_norm have th: "isnpolyh q n0" by blast
   902     from coefficients_isconst[OF np] q have "isconstant q" by blast
   903     with isconstant_polybound0[OF th] have "polybound0 q" by blast}
   904   hence "\<forall>q \<in> ?cf. polybound0 q" ..
   905   hence "\<forall>q \<in> ?cf. Ipoly (x#bs) q = Ipoly bs (decrpoly q)"
   906     using polybound0_I[where b=x and bs=bs and b'=y] decrpoly[where x=x and bs=bs]
   907     by auto
   908   
   909   thus ?thesis unfolding polypoly_def polypoly'_def by simp 
   910 qed
   911 
   912 lemma polypoly_poly:
   913   assumes np: "isnpolyh p n0" shows "Ipoly (x#bs) p = poly (polypoly (x#bs) p) x"
   914   using np 
   915 by (induct p arbitrary: n0 bs rule: coefficients.induct, auto simp add: polypoly_def)
   916 
   917 lemma polypoly'_poly: 
   918   assumes np: "isnpolyh p n0" shows "\<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup> = poly (polypoly' bs p) x"
   919   using polypoly_poly[OF np, simplified polypoly_polypoly'[OF np]] .
   920 
   921 
   922 lemma polypoly_poly_polybound0:
   923   assumes np: "isnpolyh p n0" and nb: "polybound0 p"
   924   shows "polypoly bs p = [Ipoly bs p]"
   925   using np nb unfolding polypoly_def 
   926   by (cases p, auto, case_tac nat, auto)
   927 
   928 lemma head_isnpolyh: "isnpolyh p n0 \<Longrightarrow> isnpolyh (head p) n0" 
   929   by (induct p rule: head.induct, auto)
   930 
   931 lemma headn_nz[simp]: "isnpolyh p n0 \<Longrightarrow> (headn p m = 0\<^sub>p) = (p = 0\<^sub>p)"
   932   by (cases p,auto)
   933 
   934 lemma head_eq_headn0: "head p = headn p 0"
   935   by (induct p rule: head.induct, simp_all)
   936 
   937 lemma head_nz[simp]: "isnpolyh p n0 \<Longrightarrow> (head p = 0\<^sub>p) = (p = 0\<^sub>p)"
   938   by (simp add: head_eq_headn0)
   939 
   940 lemma isnpolyh_zero_iff: 
   941   assumes nq: "isnpolyh p n0" and eq :"\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a::{field_char_0, field_inverse_zero, power})"
   942   shows "p = 0\<^sub>p"
   943 using nq eq
   944 proof (induct "maxindex p" arbitrary: p n0 rule: less_induct)
   945   case less
   946   note np = `isnpolyh p n0` and zp = `\<forall>bs. wf_bs bs p \<longrightarrow> \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)`
   947   {assume nz: "maxindex p = 0"
   948     then obtain c where "p = C c" using np by (cases p, auto)
   949     with zp np have "p = 0\<^sub>p" unfolding wf_bs_def by simp}
   950   moreover
   951   {assume nz: "maxindex p \<noteq> 0"
   952     let ?h = "head p"
   953     let ?hd = "decrpoly ?h"
   954     let ?ihd = "maxindex ?hd"
   955     from head_isnpolyh[OF np] head_polybound0[OF np] have h:"isnpolyh ?h n0" "polybound0 ?h" 
   956       by simp_all
   957     hence nhd: "isnpolyh ?hd (n0 - 1)" using decrpoly_normh by blast
   958     
   959     from maxindex_coefficients[of p] coefficients_head[of p, symmetric]
   960     have mihn: "maxindex ?h \<le> maxindex p" by auto
   961     with decr_maxindex[OF h(2)] nz  have ihd_lt_n: "?ihd < maxindex p" by auto
   962     {fix bs:: "'a list"  assume bs: "wf_bs bs ?hd"
   963       let ?ts = "take ?ihd bs"
   964       let ?rs = "drop ?ihd bs"
   965       have ts: "wf_bs ?ts ?hd" using bs unfolding wf_bs_def by simp
   966       have bs_ts_eq: "?ts@ ?rs = bs" by simp
   967       from wf_bs_decrpoly[OF ts] have tsh: " \<forall>x. wf_bs (x#?ts) ?h" by simp
   968       from ihd_lt_n have "ALL x. length (x#?ts) \<le> maxindex p" by simp
   969       with length_le_list_ex obtain xs where xs:"length ((x#?ts) @ xs) = maxindex p" by blast
   970       hence "\<forall> x. wf_bs ((x#?ts) @ xs) p" unfolding wf_bs_def by simp
   971       with zp have "\<forall> x. Ipoly ((x#?ts) @ xs) p = 0" by blast
   972       hence "\<forall> x. Ipoly (x#(?ts @ xs)) p = 0" by simp
   973       with polypoly_poly[OF np, where ?'a = 'a] polypoly_polypoly'[OF np, where ?'a = 'a]
   974       have "\<forall>x. poly (polypoly' (?ts @ xs) p) x = poly [] x"  by simp
   975       hence "poly (polypoly' (?ts @ xs) p) = poly []" by (auto intro: ext) 
   976       hence "\<forall> c \<in> set (coefficients p). Ipoly (?ts @ xs) (decrpoly c) = 0"
   977         using poly_zero[where ?'a='a] by (simp add: polypoly'_def list_all_iff)
   978       with coefficients_head[of p, symmetric]
   979       have th0: "Ipoly (?ts @ xs) ?hd = 0" by simp
   980       from bs have wf'': "wf_bs ?ts ?hd" unfolding wf_bs_def by simp
   981       with th0 wf_bs_I[of ?ts ?hd xs] have "Ipoly ?ts ?hd = 0" by simp
   982       with wf'' wf_bs_I[of ?ts ?hd ?rs] bs_ts_eq have "\<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = 0" by simp }
   983     then have hdz: "\<forall>bs. wf_bs bs ?hd \<longrightarrow> \<lparr>?hd\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)" by blast
   984     
   985     from less(1)[OF ihd_lt_n nhd] hdz have "?hd = 0\<^sub>p" by blast
   986     hence "?h = 0\<^sub>p" by simp
   987     with head_nz[OF np] have "p = 0\<^sub>p" by simp}
   988   ultimately show "p = 0\<^sub>p" by blast
   989 qed
   990 
   991 lemma isnpolyh_unique:  
   992   assumes np:"isnpolyh p n0" and nq: "isnpolyh q n1"
   993   shows "(\<forall>bs. \<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (\<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup> :: 'a::{field_char_0, field_inverse_zero, power})) \<longleftrightarrow>  p = q"
   994 proof(auto)
   995   assume H: "\<forall>bs. (\<lparr>p\<rparr>\<^sub>p\<^bsup>bs\<^esup> ::'a)= \<lparr>q\<rparr>\<^sub>p\<^bsup>bs\<^esup>"
   996   hence "\<forall>bs.\<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup>= (0::'a)" by simp
   997   hence "\<forall>bs. wf_bs bs (p -\<^sub>p q) \<longrightarrow> \<lparr>p -\<^sub>p q\<rparr>\<^sub>p\<^bsup>bs\<^esup> = (0::'a)" 
   998     using wf_bs_polysub[where p=p and q=q] by auto
   999   with isnpolyh_zero_iff[OF polysub_normh[OF np nq]] polysub_0[OF np nq]
  1000   show "p = q" by blast
  1001 qed
  1002 
  1003 
  1004 text{* consequences of unicity on the algorithms for polynomial normalization *}
  1005 
  1006 lemma polyadd_commute:   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1007   and np: "isnpolyh p n0" and nq: "isnpolyh q n1" shows "p +\<^sub>p q = q +\<^sub>p p"
  1008   using isnpolyh_unique[OF polyadd_normh[OF np nq] polyadd_normh[OF nq np]] by simp
  1009 
  1010 lemma zero_normh: "isnpolyh 0\<^sub>p n" by simp
  1011 lemma one_normh: "isnpolyh 1\<^sub>p n" by simp
  1012 lemma polyadd_0[simp]: 
  1013   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1014   and np: "isnpolyh p n0" shows "p +\<^sub>p 0\<^sub>p = p" and "0\<^sub>p +\<^sub>p p = p"
  1015   using isnpolyh_unique[OF polyadd_normh[OF np zero_normh] np] 
  1016     isnpolyh_unique[OF polyadd_normh[OF zero_normh np] np] by simp_all
  1017 
  1018 lemma polymul_1[simp]: 
  1019     assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1020   and np: "isnpolyh p n0" shows "p *\<^sub>p 1\<^sub>p = p" and "1\<^sub>p *\<^sub>p p = p"
  1021   using isnpolyh_unique[OF polymul_normh[OF np one_normh] np] 
  1022     isnpolyh_unique[OF polymul_normh[OF one_normh np] np] by simp_all
  1023 lemma polymul_0[simp]: 
  1024   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1025   and np: "isnpolyh p n0" shows "p *\<^sub>p 0\<^sub>p = 0\<^sub>p" and "0\<^sub>p *\<^sub>p p = 0\<^sub>p"
  1026   using isnpolyh_unique[OF polymul_normh[OF np zero_normh] zero_normh] 
  1027     isnpolyh_unique[OF polymul_normh[OF zero_normh np] zero_normh] by simp_all
  1028 
  1029 lemma polymul_commute: 
  1030     assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1031   and np:"isnpolyh p n0" and nq: "isnpolyh q n1"
  1032   shows "p *\<^sub>p q = q *\<^sub>p p"
  1033 using isnpolyh_unique[OF polymul_normh[OF np nq] polymul_normh[OF nq np], where ?'a = "'a\<Colon>{field_char_0, field_inverse_zero, power}"] by simp
  1034 
  1035 declare polyneg_polyneg[simp]
  1036   
  1037 lemma isnpolyh_polynate_id[simp]: 
  1038   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1039   and np:"isnpolyh p n0" shows "polynate p = p"
  1040   using isnpolyh_unique[where ?'a= "'a::{field_char_0, field_inverse_zero}", OF polynate_norm[of p, unfolded isnpoly_def] np] polynate[where ?'a = "'a::{field_char_0, field_inverse_zero}"] by simp
  1041 
  1042 lemma polynate_idempotent[simp]: 
  1043     assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1044   shows "polynate (polynate p) = polynate p"
  1045   using isnpolyh_polynate_id[OF polynate_norm[of p, unfolded isnpoly_def]] .
  1046 
  1047 lemma poly_nate_polypoly': "poly_nate bs p = polypoly' bs (polynate p)"
  1048   unfolding poly_nate_def polypoly'_def ..
  1049 lemma poly_nate_poly: shows "poly (poly_nate bs p) = (\<lambda>x:: 'a ::{field_char_0, field_inverse_zero}. \<lparr>p\<rparr>\<^sub>p\<^bsup>x # bs\<^esup>)"
  1050   using polypoly'_poly[OF polynate_norm[unfolded isnpoly_def], symmetric, of bs p]
  1051   unfolding poly_nate_polypoly' by (auto intro: ext)
  1052 
  1053 subsection{* heads, degrees and all that *}
  1054 lemma degree_eq_degreen0: "degree p = degreen p 0"
  1055   by (induct p rule: degree.induct, simp_all)
  1056 
  1057 lemma degree_polyneg: assumes n: "isnpolyh p n"
  1058   shows "degree (polyneg p) = degree p"
  1059   using n
  1060   by (induct p arbitrary: n rule: polyneg.induct, simp_all) (case_tac na, auto)
  1061 
  1062 lemma degree_polyadd:
  1063   assumes np: "isnpolyh p n0" and nq: "isnpolyh q n1"
  1064   shows "degree (p +\<^sub>p q) \<le> max (degree p) (degree q)"
  1065 using degreen_polyadd[OF np nq, where m= "0"] degree_eq_degreen0 by simp
  1066 
  1067 
  1068 lemma degree_polysub: assumes np: "isnpolyh p n0" and nq: "isnpolyh q n1"
  1069   shows "degree (p -\<^sub>p q) \<le> max (degree p) (degree q)"
  1070 proof-
  1071   from nq have nq': "isnpolyh (~\<^sub>p q) n1" using polyneg_normh by simp
  1072   from degree_polyadd[OF np nq'] show ?thesis by (simp add: polysub_def degree_polyneg[OF nq])
  1073 qed
  1074 
  1075 lemma degree_polysub_samehead: 
  1076   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1077   and np: "isnpolyh p n0" and nq: "isnpolyh q n1" and h: "head p = head q" 
  1078   and d: "degree p = degree q"
  1079   shows "degree (p -\<^sub>p q) < degree p \<or> (p -\<^sub>p q = 0\<^sub>p)"
  1080 unfolding polysub_def split_def fst_conv snd_conv
  1081 using np nq h d
  1082 proof(induct p q rule:polyadd.induct)
  1083   case (1 c c') thus ?case by (simp add: Nsub_def Nsub0[simplified Nsub_def]) 
  1084 next
  1085   case (2 c c' n' p') 
  1086   from prems have "degree (C c) = degree (CN c' n' p')" by simp
  1087   hence nz:"n' > 0" by (cases n', auto)
  1088   hence "head (CN c' n' p') = CN c' n' p'" by (cases n', auto)
  1089   with prems show ?case by simp
  1090 next
  1091   case (3 c n p c') 
  1092   from prems have "degree (C c') = degree (CN c n p)" by simp
  1093   hence nz:"n > 0" by (cases n, auto)
  1094   hence "head (CN c n p) = CN c n p" by (cases n, auto)
  1095   with prems show ?case by simp
  1096 next
  1097   case (4 c n p c' n' p')
  1098   hence H: "isnpolyh (CN c n p) n0" "isnpolyh (CN c' n' p') n1" 
  1099     "head (CN c n p) = head (CN c' n' p')" "degree (CN c n p) = degree (CN c' n' p')" by simp+
  1100   hence degc: "degree c = 0" and degc': "degree c' = 0" by simp_all  
  1101   hence degnc: "degree (~\<^sub>p c) = 0" and degnc': "degree (~\<^sub>p c') = 0" 
  1102     using H(1-2) degree_polyneg by auto
  1103   from H have cnh: "isnpolyh c (Suc n)" and c'nh: "isnpolyh c' (Suc n')"  by simp+
  1104   from degree_polysub[OF cnh c'nh, simplified polysub_def] degc degc' have degcmc': "degree (c +\<^sub>p  ~\<^sub>pc') = 0"  by simp
  1105   from H have pnh: "isnpolyh p n" and p'nh: "isnpolyh p' n'" by auto
  1106   have "n = n' \<or> n < n' \<or> n > n'" by arith
  1107   moreover
  1108   {assume nn': "n = n'"
  1109     have "n = 0 \<or> n >0" by arith
  1110     moreover {assume nz: "n = 0" hence ?case using prems by (auto simp add: Let_def degcmc')}
  1111     moreover {assume nz: "n > 0"
  1112       with nn' H(3) have  cc':"c = c'" and pp': "p = p'" by (cases n, auto)+
  1113       hence ?case using polysub_same_0[OF p'nh, simplified polysub_def split_def fst_conv snd_conv] polysub_same_0[OF c'nh, simplified polysub_def split_def fst_conv snd_conv] using nn' prems by (simp add: Let_def)}
  1114     ultimately have ?case by blast}
  1115   moreover
  1116   {assume nn': "n < n'" hence n'p: "n' > 0" by simp 
  1117     hence headcnp':"head (CN c' n' p') = CN c' n' p'"  by (cases n', simp_all)
  1118     have degcnp': "degree (CN c' n' p') = 0" and degcnpeq: "degree (CN c n p) = degree (CN c' n' p')" using prems by (cases n', simp_all)
  1119     hence "n > 0" by (cases n, simp_all)
  1120     hence headcnp: "head (CN c n p) = CN c n p" by (cases n, auto)
  1121     from H(3) headcnp headcnp' nn' have ?case by auto}
  1122   moreover
  1123   {assume nn': "n > n'"  hence np: "n > 0" by simp 
  1124     hence headcnp:"head (CN c n p) = CN c n p"  by (cases n, simp_all)
  1125     from prems have degcnpeq: "degree (CN c' n' p') = degree (CN c n p)" by simp
  1126     from np have degcnp: "degree (CN c n p) = 0" by (cases n, simp_all)
  1127     with degcnpeq have "n' > 0" by (cases n', simp_all)
  1128     hence headcnp': "head (CN c' n' p') = CN c' n' p'" by (cases n', auto)
  1129     from H(3) headcnp headcnp' nn' have ?case by auto}
  1130   ultimately show ?case  by blast
  1131 qed auto
  1132  
  1133 lemma shift1_head : "isnpolyh p n0 \<Longrightarrow> head (shift1 p) = head p"
  1134 by (induct p arbitrary: n0 rule: head.induct, simp_all add: shift1_def)
  1135 
  1136 lemma funpow_shift1_head: "isnpolyh p n0 \<Longrightarrow> p\<noteq> 0\<^sub>p \<Longrightarrow> head (funpow k shift1 p) = head p"
  1137 proof(induct k arbitrary: n0 p)
  1138   case (Suc k n0 p) hence "isnpolyh (shift1 p) 0" by (simp add: shift1_isnpolyh)
  1139   with prems have "head (funpow k shift1 (shift1 p)) = head (shift1 p)"
  1140     and "head (shift1 p) = head p" by (simp_all add: shift1_head) 
  1141   thus ?case by (simp add: funpow_swap1)
  1142 qed auto  
  1143 
  1144 lemma shift1_degree: "degree (shift1 p) = 1 + degree p"
  1145   by (simp add: shift1_def)
  1146 lemma funpow_shift1_degree: "degree (funpow k shift1 p) = k + degree p "
  1147   by (induct k arbitrary: p, auto simp add: shift1_degree)
  1148 
  1149 lemma funpow_shift1_nz: "p \<noteq> 0\<^sub>p \<Longrightarrow> funpow n shift1 p \<noteq> 0\<^sub>p"
  1150   by (induct n arbitrary: p, simp_all add: funpow_def)
  1151 
  1152 lemma head_isnpolyh_Suc[simp]: "isnpolyh p (Suc n) \<Longrightarrow> head p = p"
  1153   by (induct p arbitrary: n rule: degree.induct, auto)
  1154 lemma headn_0[simp]: "isnpolyh p n \<Longrightarrow> m < n \<Longrightarrow> headn p m = p"
  1155   by (induct p arbitrary: n rule: degreen.induct, auto)
  1156 lemma head_isnpolyh_Suc': "n > 0 \<Longrightarrow> isnpolyh p n \<Longrightarrow> head p = p"
  1157   by (induct p arbitrary: n rule: degree.induct, auto)
  1158 lemma head_head[simp]: "isnpolyh p n0 \<Longrightarrow> head (head p) = head p"
  1159   by (induct p rule: head.induct, auto)
  1160 
  1161 lemma polyadd_eq_const_degree: 
  1162   "\<lbrakk> isnpolyh p n0 ; isnpolyh q n1 ; polyadd p q = C c\<rbrakk> \<Longrightarrow> degree p = degree q" 
  1163   using polyadd_eq_const_degreen degree_eq_degreen0 by simp
  1164 
  1165 lemma polyadd_head: assumes np: "isnpolyh p n0" and nq: "isnpolyh q n1"
  1166   and deg: "degree p \<noteq> degree q"
  1167   shows "head (p +\<^sub>p q) = (if degree p < degree q then head q else head p)"
  1168 using np nq deg
  1169 apply(induct p q arbitrary: n0 n1 rule: polyadd.induct,simp_all)
  1170 apply (case_tac n', simp, simp)
  1171 apply (case_tac n, simp, simp)
  1172 apply (case_tac n, case_tac n', simp add: Let_def)
  1173 apply (case_tac "pa +\<^sub>p p' = 0\<^sub>p")
  1174 apply (auto simp add: polyadd_eq_const_degree)
  1175 apply (metis head_nz)
  1176 apply (metis head_nz)
  1177 apply (metis degree.simps(9) gr0_conv_Suc head.simps(1) less_Suc0 not_less_eq)
  1178 by (metis degree.simps(9) gr0_conv_Suc nat_less_le order_le_less_trans)
  1179 
  1180 lemma polymul_head_polyeq: 
  1181    assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1182   shows "\<lbrakk>isnpolyh p n0; isnpolyh q n1 ; p \<noteq> 0\<^sub>p ; q \<noteq> 0\<^sub>p \<rbrakk> \<Longrightarrow> head (p *\<^sub>p q) = head p *\<^sub>p head q"
  1183 proof (induct p q arbitrary: n0 n1 rule: polymul.induct)
  1184   case (2 a b c' n' p' n0 n1)
  1185   hence "isnpolyh (head (CN c' n' p')) n1" "isnormNum (a,b)"  by (simp_all add: head_isnpolyh)
  1186   thus ?case using prems by (cases n', auto) 
  1187 next 
  1188   case (3 c n p a' b' n0 n1) 
  1189   hence "isnpolyh (head (CN c n p)) n0" "isnormNum (a',b')"  by (simp_all add: head_isnpolyh)
  1190   thus ?case using prems by (cases n, auto)
  1191 next
  1192   case (4 c n p c' n' p' n0 n1)
  1193   hence norm: "isnpolyh p n" "isnpolyh c (Suc n)" "isnpolyh p' n'" "isnpolyh c' (Suc n')"
  1194     "isnpolyh (CN c n p) n" "isnpolyh (CN c' n' p') n'"
  1195     by simp_all
  1196   have "n < n' \<or> n' < n \<or> n = n'" by arith
  1197   moreover 
  1198   {assume nn': "n < n'" hence ?case 
  1199       using norm 
  1200     "4.hyps"(5)[OF norm(1,6)]
  1201     "4.hyps"(6)[OF norm(2,6)] by (simp, cases n, simp,cases n', simp_all)}
  1202   moreover {assume nn': "n'< n"
  1203     hence ?case using norm "4.hyps"(1) [OF norm(5,3)]
  1204       "4.hyps"(2)[OF norm(5,4)] 
  1205       by (simp,cases n',simp,cases n,auto)}
  1206   moreover {assume nn': "n' = n"
  1207     from nn' polymul_normh[OF norm(5,4)] 
  1208     have ncnpc':"isnpolyh (CN c n p *\<^sub>p c') n" by (simp add: min_def)
  1209     from nn' polymul_normh[OF norm(5,3)] norm 
  1210     have ncnpp':"isnpolyh (CN c n p *\<^sub>p p') n" by simp
  1211     from nn' ncnpp' polymul_eq0_iff[OF norm(5,3)] norm(6)
  1212     have ncnpp0':"isnpolyh (CN 0\<^sub>p n (CN c n p *\<^sub>p p')) n" by simp 
  1213     from polyadd_normh[OF ncnpc' ncnpp0'] 
  1214     have nth: "isnpolyh ((CN c n p *\<^sub>p c') +\<^sub>p (CN 0\<^sub>p n (CN c n p *\<^sub>p p'))) n" 
  1215       by (simp add: min_def)
  1216     {assume np: "n > 0"
  1217       with nn' head_isnpolyh_Suc'[OF np nth]
  1218         head_isnpolyh_Suc'[OF np norm(5)] head_isnpolyh_Suc'[OF np norm(6)[simplified nn']]
  1219       have ?case by simp}
  1220     moreover
  1221     {moreover assume nz: "n = 0"
  1222       from polymul_degreen[OF norm(5,4), where m="0"]
  1223         polymul_degreen[OF norm(5,3), where m="0"] nn' nz degree_eq_degreen0
  1224       norm(5,6) degree_npolyhCN[OF norm(6)]
  1225     have dth:"degree (CN c 0 p *\<^sub>p c') < degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))" by simp
  1226     hence dth':"degree (CN c 0 p *\<^sub>p c') \<noteq> degree (CN 0\<^sub>p 0 (CN c 0 p *\<^sub>p p'))" by simp
  1227     from polyadd_head[OF ncnpc'[simplified nz] ncnpp0'[simplified nz] dth'] dth
  1228     have ?case   using norm "4.hyps"(1)[OF norm(5,3)]
  1229         "4.hyps"(2)[OF norm(5,4)] nn' nz by simp }
  1230     ultimately have ?case by (cases n) auto} 
  1231   ultimately show ?case by blast
  1232 qed simp_all
  1233 
  1234 lemma degree_coefficients: "degree p = length (coefficients p) - 1"
  1235   by(induct p rule: degree.induct, auto)
  1236 
  1237 lemma degree_head[simp]: "degree (head p) = 0"
  1238   by (induct p rule: head.induct, auto)
  1239 
  1240 lemma degree_CN: "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<le> 1 + degree p"
  1241   by (cases n, simp_all)
  1242 lemma degree_CN': "isnpolyh p n \<Longrightarrow> degree (CN c n p) \<ge>  degree p"
  1243   by (cases n, simp_all)
  1244 
  1245 lemma polyadd_different_degree: "\<lbrakk>isnpolyh p n0 ; isnpolyh q n1; degree p \<noteq> degree q\<rbrakk> \<Longrightarrow> degree (polyadd p q) = max (degree p) (degree q)"
  1246   using polyadd_different_degreen degree_eq_degreen0 by simp
  1247 
  1248 lemma degreen_polyneg: "isnpolyh p n0 \<Longrightarrow> degreen (~\<^sub>p p) m = degreen p m"
  1249   by (induct p arbitrary: n0 rule: polyneg.induct, auto)
  1250 
  1251 lemma degree_polymul:
  1252   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1253   and np: "isnpolyh p n0" and nq: "isnpolyh q n1"
  1254   shows "degree (p *\<^sub>p q) \<le> degree p + degree q"
  1255   using polymul_degreen[OF np nq, where m="0"]  degree_eq_degreen0 by simp
  1256 
  1257 lemma polyneg_degree: "isnpolyh p n \<Longrightarrow> degree (polyneg p) = degree p"
  1258   by (induct p arbitrary: n rule: degree.induct, auto)
  1259 
  1260 lemma polyneg_head: "isnpolyh p n \<Longrightarrow> head(polyneg p) = polyneg (head p)"
  1261   by (induct p arbitrary: n rule: degree.induct, auto)
  1262 
  1263 subsection {* Correctness of polynomial pseudo division *}
  1264 
  1265 lemma polydivide_aux_properties:
  1266   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1267   and np: "isnpolyh p n0" and ns: "isnpolyh s n1"
  1268   and ap: "head p = a" and ndp: "degree p = n" and pnz: "p \<noteq> 0\<^sub>p"
  1269   shows "(polydivide_aux a n p k s = (k',r) \<longrightarrow> (k' \<ge> k) \<and> (degree r = 0 \<or> degree r < degree p) 
  1270           \<and> (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> ((polypow (k' - k) a) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)))"
  1271   using ns
  1272 proof(induct "degree s" arbitrary: s k k' r n1 rule: less_induct)
  1273   case less
  1274   let ?qths = "\<exists>q n1. isnpolyh q n1 \<and> (a ^\<^sub>p (k' - k) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)"
  1275   let ?ths = "polydivide_aux a n p k s = (k', r) \<longrightarrow>  k \<le> k' \<and> (degree r = 0 \<or> degree r < degree p) 
  1276     \<and> (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1277   let ?b = "head s"
  1278   let ?p' = "funpow (degree s - n) shift1 p"
  1279   let ?xdn = "funpow (degree s - n) shift1 1\<^sub>p"
  1280   let ?akk' = "a ^\<^sub>p (k' - k)"
  1281   note ns = `isnpolyh s n1`
  1282   from np have np0: "isnpolyh p 0" 
  1283     using isnpolyh_mono[where n="n0" and n'="0" and p="p"]  by simp
  1284   have np': "isnpolyh ?p' 0" using funpow_shift1_isnpoly[OF np0[simplified isnpoly_def[symmetric]] pnz, where n="degree s - n"] isnpoly_def by simp
  1285   have headp': "head ?p' = head p" using funpow_shift1_head[OF np pnz] by simp
  1286   from funpow_shift1_isnpoly[where p="1\<^sub>p"] have nxdn: "isnpolyh ?xdn 0" by (simp add: isnpoly_def)
  1287   from polypow_normh [OF head_isnpolyh[OF np0], where k="k' - k"] ap 
  1288   have nakk':"isnpolyh ?akk' 0" by blast
  1289   {assume sz: "s = 0\<^sub>p"
  1290    hence ?ths using np polydivide_aux.simps apply clarsimp by (rule exI[where x="0\<^sub>p"], simp) }
  1291   moreover
  1292   {assume sz: "s \<noteq> 0\<^sub>p"
  1293     {assume dn: "degree s < n"
  1294       hence "?ths" using ns ndp np polydivide_aux.simps by auto (rule exI[where x="0\<^sub>p"],simp) }
  1295     moreover 
  1296     {assume dn': "\<not> degree s < n" hence dn: "degree s \<ge> n" by arith
  1297       have degsp': "degree s = degree ?p'" 
  1298         using dn ndp funpow_shift1_degree[where k = "degree s - n" and p="p"] by simp
  1299       {assume ba: "?b = a"
  1300         hence headsp': "head s = head ?p'" using ap headp' by simp
  1301         have nr: "isnpolyh (s -\<^sub>p ?p') 0" using polysub_normh[OF ns np'] by simp
  1302         from degree_polysub_samehead[OF ns np' headsp' degsp']
  1303         have "degree (s -\<^sub>p ?p') < degree s \<or> s -\<^sub>p ?p' = 0\<^sub>p" by simp
  1304         moreover 
  1305         {assume deglt:"degree (s -\<^sub>p ?p') < degree s"
  1306           from polydivide_aux.simps sz dn' ba
  1307           have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1308             by (simp add: Let_def)
  1309           {assume h1: "polydivide_aux a n p k s = (k', r)"
  1310             from less(1)[OF deglt nr, of k k' r]
  1311               trans[OF eq[symmetric] h1]
  1312             have kk': "k \<le> k'" and nr:"\<exists>nr. isnpolyh r nr" and dr: "degree r = 0 \<or> degree r < degree p"
  1313               and q1:"\<exists>q nq. isnpolyh q nq \<and> (a ^\<^sub>p k' - k *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r)" by auto
  1314             from q1 obtain q n1 where nq: "isnpolyh q n1" 
  1315               and asp:"a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p') = p *\<^sub>p q +\<^sub>p r"  by blast
  1316             from nr obtain nr where nr': "isnpolyh r nr" by blast
  1317             from polymul_normh[OF nakk' ns] have nakks': "isnpolyh (a ^\<^sub>p (k' - k) *\<^sub>p s) 0" by simp
  1318             from polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]
  1319             have nq': "isnpolyh (?akk' *\<^sub>p ?xdn +\<^sub>p q) 0" by simp
  1320             from polyadd_normh[OF polymul_normh[OF np 
  1321               polyadd_normh[OF polymul_normh[OF nakk' nxdn] nq]] nr']
  1322             have nqr': "isnpolyh (p *\<^sub>p (?akk' *\<^sub>p ?xdn +\<^sub>p q) +\<^sub>p r) 0" by simp 
  1323             from asp have "\<forall> (bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a^\<^sub>p (k' - k) *\<^sub>p (s -\<^sub>p ?p')) = 
  1324               Ipoly bs (p *\<^sub>p q +\<^sub>p r)" by simp
  1325             hence " \<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a^\<^sub>p (k' - k)*\<^sub>p s) = 
  1326               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs ?p' + Ipoly bs p * Ipoly bs q + Ipoly bs r" 
  1327               by (simp add: field_simps)
  1328             hence " \<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) = 
  1329               Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 1\<^sub>p *\<^sub>p p) 
  1330               + Ipoly bs p * Ipoly bs q + Ipoly bs r"
  1331               by (auto simp only: funpow_shift1_1) 
  1332             hence "\<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) = 
  1333               Ipoly bs p * (Ipoly bs (a^\<^sub>p (k' - k)) * Ipoly bs (funpow (degree s - n) shift1 1\<^sub>p) 
  1334               + Ipoly bs q) + Ipoly bs r" by (simp add: field_simps)
  1335             hence "\<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) = 
  1336               Ipoly bs (p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 1\<^sub>p) +\<^sub>p q) +\<^sub>p r)" by simp
  1337             with isnpolyh_unique[OF nakks' nqr']
  1338             have "a ^\<^sub>p (k' - k) *\<^sub>p s = 
  1339               p *\<^sub>p ((a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 1\<^sub>p) +\<^sub>p q) +\<^sub>p r" by blast
  1340             hence ?qths using nq'
  1341               apply (rule_tac x="(a^\<^sub>p (k' - k)) *\<^sub>p (funpow (degree s - n) shift1 1\<^sub>p) +\<^sub>p q" in exI)
  1342               apply (rule_tac x="0" in exI) by simp
  1343             with kk' nr dr have "k \<le> k' \<and> (degree r = 0 \<or> degree r < degree p) \<and> (\<exists>nr. isnpolyh r nr) \<and> ?qths"
  1344               by blast } hence ?ths by blast }
  1345         moreover 
  1346         {assume spz:"s -\<^sub>p ?p' = 0\<^sub>p"
  1347           from spz isnpolyh_unique[OF polysub_normh[OF ns np'], where q="0\<^sub>p", symmetric, where ?'a = "'a::{field_char_0, field_inverse_zero}"]
  1348           have " \<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs s = Ipoly bs ?p'" by simp
  1349           hence "\<forall>(bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs s = Ipoly bs (?xdn *\<^sub>p p)" using np nxdn apply simp
  1350             by (simp only: funpow_shift1_1) simp
  1351           hence sp': "s = ?xdn *\<^sub>p p" using isnpolyh_unique[OF ns polymul_normh[OF nxdn np]] by blast
  1352           {assume h1: "polydivide_aux a n p k s = (k',r)"
  1353             from polydivide_aux.simps sz dn' ba
  1354             have eq: "polydivide_aux a n p k s = polydivide_aux a n p k (s -\<^sub>p ?p')"
  1355               by (simp add: Let_def)
  1356             also have "\<dots> = (k,0\<^sub>p)" using polydivide_aux.simps spz by simp
  1357             finally have "(k',r) = (k,0\<^sub>p)" using h1 by simp
  1358             with sp'[symmetric] ns np nxdn polyadd_0(1)[OF polymul_normh[OF np nxdn]]
  1359               polyadd_0(2)[OF polymul_normh[OF np nxdn]] have ?ths
  1360               apply auto
  1361               apply (rule exI[where x="?xdn"])        
  1362               apply (auto simp add: polymul_commute[of p])
  1363               done} }
  1364         ultimately have ?ths by blast }
  1365       moreover
  1366       {assume ba: "?b \<noteq> a"
  1367         from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns] 
  1368           polymul_normh[OF head_isnpolyh[OF ns] np']]
  1369         have nth: "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0" by(simp add: min_def)
  1370         have nzths: "a *\<^sub>p s \<noteq> 0\<^sub>p" "?b *\<^sub>p ?p' \<noteq> 0\<^sub>p"
  1371           using polymul_eq0_iff[OF head_isnpolyh[OF np0, simplified ap] ns] 
  1372             polymul_eq0_iff[OF head_isnpolyh[OF ns] np']head_nz[OF np0] ap pnz sz head_nz[OF ns]
  1373             funpow_shift1_nz[OF pnz] by simp_all
  1374         from polymul_head_polyeq[OF head_isnpolyh[OF np] ns] head_nz[OF np] sz ap head_head[OF np] pnz
  1375           polymul_head_polyeq[OF head_isnpolyh[OF ns] np'] head_nz [OF ns] sz funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1376         have hdth: "head (a *\<^sub>p s) = head (?b *\<^sub>p ?p')" 
  1377           using head_head[OF ns] funpow_shift1_head[OF np pnz]
  1378             polymul_commute[OF head_isnpolyh[OF np] head_isnpolyh[OF ns]]
  1379           by (simp add: ap)
  1380         from polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1381           head_nz[OF np] pnz sz ap[symmetric]
  1382           funpow_shift1_nz[OF pnz, where n="degree s - n"]
  1383           polymul_degreen[OF head_isnpolyh[OF ns] np', where m="0"]  head_nz[OF ns]
  1384           ndp dn
  1385         have degth: "degree (a *\<^sub>p s) = degree (?b *\<^sub>p ?p') "
  1386           by (simp add: degree_eq_degreen0[symmetric] funpow_shift1_degree)
  1387         {assume dth: "degree ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) < degree s"
  1388           from polysub_normh[OF polymul_normh[OF head_isnpolyh[OF np] ns] polymul_normh[OF head_isnpolyh[OF ns]np']]
  1389           ap have nasbp': "isnpolyh ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) 0" by simp
  1390           {assume h1:"polydivide_aux a n p k s = (k', r)"
  1391             from h1 polydivide_aux.simps sz dn' ba
  1392             have eq:"polydivide_aux a n p (Suc k) ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = (k',r)"
  1393               by (simp add: Let_def)
  1394             with less(1)[OF dth nasbp', of "Suc k" k' r]
  1395             obtain q nq nr where kk': "Suc k \<le> k'" and nr: "isnpolyh r nr" and nq: "isnpolyh q nq" 
  1396               and dr: "degree r = 0 \<or> degree r < degree p"
  1397               and qr: "a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p')) = p *\<^sub>p q +\<^sub>p r" by auto
  1398             from kk' have kk'':"Suc (k' - Suc k) = k' - k" by arith
  1399             {fix bs:: "'a::{field_char_0, field_inverse_zero} list"
  1400               
  1401             from qr isnpolyh_unique[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k", simplified ap] nasbp', symmetric]
  1402             have "Ipoly bs (a ^\<^sub>p (k' - Suc k) *\<^sub>p ((a *\<^sub>p s) -\<^sub>p (?b *\<^sub>p ?p'))) = Ipoly bs (p *\<^sub>p q +\<^sub>p r)" by simp
  1403             hence "Ipoly bs a ^ (Suc (k' - Suc k)) * Ipoly bs s = Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?p' + Ipoly bs r"
  1404               by (simp add: field_simps power_Suc)
  1405             hence "Ipoly bs a ^ (k' - k)  * Ipoly bs s = Ipoly bs p * Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn * Ipoly bs p + Ipoly bs r"
  1406               by (simp add:kk'' funpow_shift1_1[where n="degree s - n" and p="p"])
  1407             hence "Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) = Ipoly bs p * (Ipoly bs q + Ipoly bs a ^ (k' - Suc k) * Ipoly bs ?b * Ipoly bs ?xdn) + Ipoly bs r"
  1408               by (simp add: field_simps)}
  1409             hence ieq:"\<forall>(bs :: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a ^\<^sub>p (k' - k) *\<^sub>p s) = 
  1410               Ipoly bs (p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r)" by auto 
  1411             let ?q = "q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)"
  1412             from polyadd_normh[OF nq polymul_normh[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - Suc k"] head_isnpolyh[OF ns], simplified ap ] nxdn]]
  1413             have nqw: "isnpolyh ?q 0" by simp
  1414             from ieq isnpolyh_unique[OF polymul_normh[OF polypow_normh[OF head_isnpolyh[OF np], where k="k' - k"] ns, simplified ap] polyadd_normh[OF polymul_normh[OF np nqw] nr]]
  1415             have asth: "(a ^\<^sub>p (k' - k) *\<^sub>p s) = p *\<^sub>p (q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn)) +\<^sub>p r" by blast
  1416             from dr kk' nr h1 asth nqw have ?ths apply simp
  1417               apply (rule conjI)
  1418               apply (rule exI[where x="nr"], simp)
  1419               apply (rule exI[where x="(q +\<^sub>p (a ^\<^sub>p (k' - Suc k) *\<^sub>p ?b *\<^sub>p ?xdn))"], simp)
  1420               apply (rule exI[where x="0"], simp)
  1421               done}
  1422           hence ?ths by blast }
  1423         moreover 
  1424         {assume spz: "a *\<^sub>p s -\<^sub>p (?b *\<^sub>p ?p') = 0\<^sub>p"
  1425           {fix bs :: "'a::{field_char_0, field_inverse_zero} list"
  1426             from isnpolyh_unique[OF nth, where ?'a="'a" and q="0\<^sub>p",simplified,symmetric] spz
  1427           have "Ipoly bs (a*\<^sub>p s) = Ipoly bs ?b * Ipoly bs ?p'" by simp
  1428           hence "Ipoly bs (a*\<^sub>p s) = Ipoly bs (?b *\<^sub>p ?xdn) * Ipoly bs p" 
  1429             by (simp add: funpow_shift1_1[where n="degree s - n" and p="p"])
  1430           hence "Ipoly bs (a*\<^sub>p s) = Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))" by simp
  1431         }
  1432         hence hth: "\<forall> (bs:: 'a::{field_char_0, field_inverse_zero} list). Ipoly bs (a*\<^sub>p s) = Ipoly bs (p *\<^sub>p (?b *\<^sub>p ?xdn))" ..
  1433           from hth
  1434           have asq: "a *\<^sub>p s = p *\<^sub>p (?b *\<^sub>p ?xdn)" 
  1435             using isnpolyh_unique[where ?'a = "'a::{field_char_0, field_inverse_zero}", OF polymul_normh[OF head_isnpolyh[OF np] ns] 
  1436                     polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]],
  1437               simplified ap] by simp
  1438           {assume h1: "polydivide_aux a n p k s = (k', r)"
  1439           from h1 sz ba dn' spz polydivide_aux.simps polydivide_aux.simps
  1440           have "(k',r) = (Suc k, 0\<^sub>p)" by (simp add: Let_def)
  1441           with h1 np head_isnpolyh[OF np, simplified ap] ns polymul_normh[OF head_isnpolyh[OF ns] nxdn]
  1442             polymul_normh[OF np polymul_normh[OF head_isnpolyh[OF ns] nxdn]] asq
  1443           have ?ths apply (clarsimp simp add: Let_def)
  1444             apply (rule exI[where x="?b *\<^sub>p ?xdn"]) apply simp
  1445             apply (rule exI[where x="0"], simp)
  1446             done}
  1447         hence ?ths by blast}
  1448         ultimately have ?ths using  degree_polysub_samehead[OF polymul_normh[OF head_isnpolyh[OF np0, simplified ap] ns] polymul_normh[OF head_isnpolyh[OF ns] np'] hdth degth] polymul_degreen[OF head_isnpolyh[OF np] ns, where m="0"]
  1449           head_nz[OF np] pnz sz ap[symmetric]
  1450           by (simp add: degree_eq_degreen0[symmetric]) blast }
  1451       ultimately have ?ths by blast
  1452     }
  1453     ultimately have ?ths by blast}
  1454   ultimately show ?ths by blast
  1455 qed
  1456 
  1457 lemma polydivide_properties: 
  1458   assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1459   and np: "isnpolyh p n0" and ns: "isnpolyh s n1" and pnz: "p \<noteq> 0\<^sub>p"
  1460   shows "(\<exists> k r. polydivide s p = (k,r) \<and> (\<exists>nr. isnpolyh r nr) \<and> (degree r = 0 \<or> degree r < degree p) 
  1461   \<and> (\<exists>q n1. isnpolyh q n1 \<and> ((polypow k (head p)) *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)))"
  1462 proof-
  1463   have trv: "head p = head p" "degree p = degree p" by simp_all
  1464   from polydivide_def[where s="s" and p="p"] 
  1465   have ex: "\<exists> k r. polydivide s p = (k,r)" by auto
  1466   then obtain k r where kr: "polydivide s p = (k,r)" by blast
  1467   from trans[OF meta_eq_to_obj_eq[OF polydivide_def[where s="s"and p="p"], symmetric] kr]
  1468     polydivide_aux_properties[OF np ns trv pnz, where k="0" and k'="k" and r="r"]
  1469   have "(degree r = 0 \<or> degree r < degree p) \<and>
  1470    (\<exists>nr. isnpolyh r nr) \<and> (\<exists>q n1. isnpolyh q n1 \<and> head p ^\<^sub>p k - 0 *\<^sub>p s = p *\<^sub>p q +\<^sub>p r)" by blast
  1471   with kr show ?thesis 
  1472     apply -
  1473     apply (rule exI[where x="k"])
  1474     apply (rule exI[where x="r"])
  1475     apply simp
  1476     done
  1477 qed
  1478 
  1479 subsection{* More about polypoly and pnormal etc *}
  1480 
  1481 definition "isnonconstant p = (\<not> isconstant p)"
  1482 
  1483 lemma isnonconstant_pnormal_iff: assumes nc: "isnonconstant p" 
  1484   shows "pnormal (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0" 
  1485 proof
  1486   let ?p = "polypoly bs p"  
  1487   assume H: "pnormal ?p"
  1488   have csz: "coefficients p \<noteq> []" using nc by (cases p, auto)
  1489   
  1490   from coefficients_head[of p] last_map[OF csz, of "Ipoly bs"]  
  1491     pnormal_last_nonzero[OF H]
  1492   show "Ipoly bs (head p) \<noteq> 0" by (simp add: polypoly_def)
  1493 next
  1494   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1495   let ?p = "polypoly bs p"
  1496   have csz: "coefficients p \<noteq> []" using nc by (cases p, auto)
  1497   hence pz: "?p \<noteq> []" by (simp add: polypoly_def) 
  1498   hence lg: "length ?p > 0" by simp
  1499   from h coefficients_head[of p] last_map[OF csz, of "Ipoly bs"] 
  1500   have lz: "last ?p \<noteq> 0" by (simp add: polypoly_def)
  1501   from pnormal_last_length[OF lg lz] show "pnormal ?p" .
  1502 qed
  1503 
  1504 lemma isnonconstant_coefficients_length: "isnonconstant p \<Longrightarrow> length (coefficients p) > 1"
  1505   unfolding isnonconstant_def
  1506   apply (cases p, simp_all)
  1507   apply (case_tac nat, auto)
  1508   done
  1509 lemma isnonconstant_nonconstant: assumes inc: "isnonconstant p"
  1510   shows "nonconstant (polypoly bs p) \<longleftrightarrow> Ipoly bs (head p) \<noteq> 0"
  1511 proof
  1512   let ?p = "polypoly bs p"
  1513   assume nc: "nonconstant ?p"
  1514   from isnonconstant_pnormal_iff[OF inc, of bs] nc
  1515   show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0" unfolding nonconstant_def by blast
  1516 next
  1517   let ?p = "polypoly bs p"
  1518   assume h: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1519   from isnonconstant_pnormal_iff[OF inc, of bs] h
  1520   have pn: "pnormal ?p" by blast
  1521   {fix x assume H: "?p = [x]" 
  1522     from H have "length (coefficients p) = 1" unfolding polypoly_def by auto
  1523     with isnonconstant_coefficients_length[OF inc] have False by arith}
  1524   thus "nonconstant ?p" using pn unfolding nonconstant_def by blast  
  1525 qed
  1526 
  1527 lemma pnormal_length: "p\<noteq>[] \<Longrightarrow> pnormal p \<longleftrightarrow> length (pnormalize p) = length p"
  1528   unfolding pnormal_def
  1529  apply (induct p)
  1530  apply (simp_all, case_tac "p=[]", simp_all)
  1531  done
  1532 
  1533 lemma degree_degree: assumes inc: "isnonconstant p"
  1534   shows "degree p = Polynomial_List.degree (polypoly bs p) \<longleftrightarrow> \<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1535 proof
  1536   let  ?p = "polypoly bs p"
  1537   assume H: "degree p = Polynomial_List.degree ?p"
  1538   from isnonconstant_coefficients_length[OF inc] have pz: "?p \<noteq> []"
  1539     unfolding polypoly_def by auto
  1540   from H degree_coefficients[of p] isnonconstant_coefficients_length[OF inc]
  1541   have lg:"length (pnormalize ?p) = length ?p"
  1542     unfolding Polynomial_List.degree_def polypoly_def by simp
  1543   hence "pnormal ?p" using pnormal_length[OF pz] by blast 
  1544   with isnonconstant_pnormal_iff[OF inc]  
  1545   show "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0" by blast
  1546 next
  1547   let  ?p = "polypoly bs p"  
  1548   assume H: "\<lparr>head p\<rparr>\<^sub>p\<^bsup>bs\<^esup> \<noteq> 0"
  1549   with isnonconstant_pnormal_iff[OF inc] have "pnormal ?p" by blast
  1550   with degree_coefficients[of p] isnonconstant_coefficients_length[OF inc]
  1551   show "degree p = Polynomial_List.degree ?p" 
  1552     unfolding polypoly_def pnormal_def Polynomial_List.degree_def by auto
  1553 qed
  1554 
  1555 section{* Swaps ; Division by a certain variable *}
  1556 primrec swap:: "nat \<Rightarrow> nat \<Rightarrow> poly \<Rightarrow> poly" where
  1557   "swap n m (C x) = C x"
  1558 | "swap n m (Bound k) = Bound (if k = n then m else if k=m then n else k)"
  1559 | "swap n m (Neg t) = Neg (swap n m t)"
  1560 | "swap n m (Add s t) = Add (swap n m s) (swap n m t)"
  1561 | "swap n m (Sub s t) = Sub (swap n m s) (swap n m t)"
  1562 | "swap n m (Mul s t) = Mul (swap n m s) (swap n m t)"
  1563 | "swap n m (Pw t k) = Pw (swap n m t) k"
  1564 | "swap n m (CN c k p) = CN (swap n m c) (if k = n then m else if k=m then n else k)
  1565   (swap n m p)"
  1566 
  1567 lemma swap: assumes nbs: "n < length bs" and mbs: "m < length bs"
  1568   shows "Ipoly bs (swap n m t) = Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  1569 proof (induct t)
  1570   case (Bound k) thus ?case using nbs mbs by simp 
  1571 next
  1572   case (CN c k p) thus ?case using nbs mbs by simp 
  1573 qed simp_all
  1574 lemma swap_swap_id[simp]: "swap n m (swap m n t) = t"
  1575   by (induct t,simp_all)
  1576 
  1577 lemma swap_commute: "swap n m p = swap m n p" by (induct p, simp_all)
  1578 
  1579 lemma swap_same_id[simp]: "swap n n t = t"
  1580   by (induct t, simp_all)
  1581 
  1582 definition "swapnorm n m t = polynate (swap n m t)"
  1583 
  1584 lemma swapnorm: assumes nbs: "n < length bs" and mbs: "m < length bs"
  1585   shows "((Ipoly bs (swapnorm n m t) :: 'a\<Colon>{field_char_0, field_inverse_zero})) = Ipoly ((bs[n:= bs!m])[m:= bs!n]) t"
  1586   using swap[OF prems] swapnorm_def by simp
  1587 
  1588 lemma swapnorm_isnpoly[simp]: 
  1589     assumes "SORT_CONSTRAINT('a::{field_char_0, field_inverse_zero})"
  1590   shows "isnpoly (swapnorm n m p)"
  1591   unfolding swapnorm_def by simp
  1592 
  1593 definition "polydivideby n s p = 
  1594     (let ss = swapnorm 0 n s ; sp = swapnorm 0 n p ; h = head sp; (k,r) = polydivide ss sp
  1595      in (k,swapnorm 0 n h,swapnorm 0 n r))"
  1596 
  1597 lemma swap_nz [simp]: " (swap n m p = 0\<^sub>p) = (p = 0\<^sub>p)" by (induct p, simp_all)
  1598 
  1599 fun isweaknpoly :: "poly \<Rightarrow> bool"
  1600 where
  1601   "isweaknpoly (C c) = True"
  1602 | "isweaknpoly (CN c n p) \<longleftrightarrow> isweaknpoly c \<and> isweaknpoly p"
  1603 | "isweaknpoly p = False"
  1604 
  1605 lemma isnpolyh_isweaknpoly: "isnpolyh p n0 \<Longrightarrow> isweaknpoly p" 
  1606   by (induct p arbitrary: n0, auto)
  1607 
  1608 lemma swap_isweanpoly: "isweaknpoly p \<Longrightarrow> isweaknpoly (swap n m p)" 
  1609   by (induct p, auto)
  1610 
  1611 end