src/HOL/Rings.thy
author haftmann
Mon Jun 01 18:59:21 2015 +0200 (2015-06-01)
changeset 60352 d46de31a50c4
parent 59910 815de5506080
child 60353 838025c6e278
permissions -rw-r--r--
separate class for division operator, with particular syntax added in more specific classes
     1 (*  Title:      HOL/Rings.thy
     2     Author:     Gertrud Bauer
     3     Author:     Steven Obua
     4     Author:     Tobias Nipkow
     5     Author:     Lawrence C Paulson
     6     Author:     Markus Wenzel
     7     Author:     Jeremy Avigad
     8 *)
     9 
    10 section {* Rings *}
    11 
    12 theory Rings
    13 imports Groups
    14 begin
    15 
    16 class semiring = ab_semigroup_add + semigroup_mult +
    17   assumes distrib_right[algebra_simps]: "(a + b) * c = a * c + b * c"
    18   assumes distrib_left[algebra_simps]: "a * (b + c) = a * b + a * c"
    19 begin
    20 
    21 text{*For the @{text combine_numerals} simproc*}
    22 lemma combine_common_factor:
    23   "a * e + (b * e + c) = (a + b) * e + c"
    24 by (simp add: distrib_right ac_simps)
    25 
    26 end
    27 
    28 class mult_zero = times + zero +
    29   assumes mult_zero_left [simp]: "0 * a = 0"
    30   assumes mult_zero_right [simp]: "a * 0 = 0"
    31 begin
    32 
    33 lemma mult_not_zero:
    34   "a * b \<noteq> 0 \<Longrightarrow> a \<noteq> 0 \<and> b \<noteq> 0"
    35   by auto
    36 
    37 end
    38 
    39 class semiring_0 = semiring + comm_monoid_add + mult_zero
    40 
    41 class semiring_0_cancel = semiring + cancel_comm_monoid_add
    42 begin
    43 
    44 subclass semiring_0
    45 proof
    46   fix a :: 'a
    47   have "0 * a + 0 * a = 0 * a + 0" by (simp add: distrib_right [symmetric])
    48   thus "0 * a = 0" by (simp only: add_left_cancel)
    49 next
    50   fix a :: 'a
    51   have "a * 0 + a * 0 = a * 0 + 0" by (simp add: distrib_left [symmetric])
    52   thus "a * 0 = 0" by (simp only: add_left_cancel)
    53 qed
    54 
    55 end
    56 
    57 class comm_semiring = ab_semigroup_add + ab_semigroup_mult +
    58   assumes distrib: "(a + b) * c = a * c + b * c"
    59 begin
    60 
    61 subclass semiring
    62 proof
    63   fix a b c :: 'a
    64   show "(a + b) * c = a * c + b * c" by (simp add: distrib)
    65   have "a * (b + c) = (b + c) * a" by (simp add: ac_simps)
    66   also have "... = b * a + c * a" by (simp only: distrib)
    67   also have "... = a * b + a * c" by (simp add: ac_simps)
    68   finally show "a * (b + c) = a * b + a * c" by blast
    69 qed
    70 
    71 end
    72 
    73 class comm_semiring_0 = comm_semiring + comm_monoid_add + mult_zero
    74 begin
    75 
    76 subclass semiring_0 ..
    77 
    78 end
    79 
    80 class comm_semiring_0_cancel = comm_semiring + cancel_comm_monoid_add
    81 begin
    82 
    83 subclass semiring_0_cancel ..
    84 
    85 subclass comm_semiring_0 ..
    86 
    87 end
    88 
    89 class zero_neq_one = zero + one +
    90   assumes zero_neq_one [simp]: "0 \<noteq> 1"
    91 begin
    92 
    93 lemma one_neq_zero [simp]: "1 \<noteq> 0"
    94 by (rule not_sym) (rule zero_neq_one)
    95 
    96 definition of_bool :: "bool \<Rightarrow> 'a"
    97 where
    98   "of_bool p = (if p then 1 else 0)" 
    99 
   100 lemma of_bool_eq [simp, code]:
   101   "of_bool False = 0"
   102   "of_bool True = 1"
   103   by (simp_all add: of_bool_def)
   104 
   105 lemma of_bool_eq_iff:
   106   "of_bool p = of_bool q \<longleftrightarrow> p = q"
   107   by (simp add: of_bool_def)
   108 
   109 lemma split_of_bool [split]:
   110   "P (of_bool p) \<longleftrightarrow> (p \<longrightarrow> P 1) \<and> (\<not> p \<longrightarrow> P 0)"
   111   by (cases p) simp_all
   112 
   113 lemma split_of_bool_asm:
   114   "P (of_bool p) \<longleftrightarrow> \<not> (p \<and> \<not> P 1 \<or> \<not> p \<and> \<not> P 0)"
   115   by (cases p) simp_all
   116   
   117 end  
   118 
   119 class semiring_1 = zero_neq_one + semiring_0 + monoid_mult
   120 
   121 text {* Abstract divisibility *}
   122 
   123 class dvd = times
   124 begin
   125 
   126 definition dvd :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "dvd" 50) where
   127   "b dvd a \<longleftrightarrow> (\<exists>k. a = b * k)"
   128 
   129 lemma dvdI [intro?]: "a = b * k \<Longrightarrow> b dvd a"
   130   unfolding dvd_def ..
   131 
   132 lemma dvdE [elim?]: "b dvd a \<Longrightarrow> (\<And>k. a = b * k \<Longrightarrow> P) \<Longrightarrow> P"
   133   unfolding dvd_def by blast 
   134 
   135 end
   136 
   137 context comm_monoid_mult
   138 begin
   139 
   140 subclass dvd .
   141 
   142 lemma dvd_refl [simp]:
   143   "a dvd a"
   144 proof
   145   show "a = a * 1" by simp
   146 qed
   147 
   148 lemma dvd_trans:
   149   assumes "a dvd b" and "b dvd c"
   150   shows "a dvd c"
   151 proof -
   152   from assms obtain v where "b = a * v" by (auto elim!: dvdE)
   153   moreover from assms obtain w where "c = b * w" by (auto elim!: dvdE)
   154   ultimately have "c = a * (v * w)" by (simp add: mult.assoc)
   155   then show ?thesis ..
   156 qed
   157 
   158 lemma one_dvd [simp]:
   159   "1 dvd a"
   160   by (auto intro!: dvdI)
   161 
   162 lemma dvd_mult [simp]:
   163   "a dvd c \<Longrightarrow> a dvd (b * c)"
   164   by (auto intro!: mult.left_commute dvdI elim!: dvdE)
   165 
   166 lemma dvd_mult2 [simp]:
   167   "a dvd b \<Longrightarrow> a dvd (b * c)"
   168   using dvd_mult [of a b c] by (simp add: ac_simps) 
   169 
   170 lemma dvd_triv_right [simp]:
   171   "a dvd b * a"
   172   by (rule dvd_mult) (rule dvd_refl)
   173 
   174 lemma dvd_triv_left [simp]:
   175   "a dvd a * b"
   176   by (rule dvd_mult2) (rule dvd_refl)
   177 
   178 lemma mult_dvd_mono:
   179   assumes "a dvd b"
   180     and "c dvd d"
   181   shows "a * c dvd b * d"
   182 proof -
   183   from `a dvd b` obtain b' where "b = a * b'" ..
   184   moreover from `c dvd d` obtain d' where "d = c * d'" ..
   185   ultimately have "b * d = (a * c) * (b' * d')" by (simp add: ac_simps)
   186   then show ?thesis ..
   187 qed
   188 
   189 lemma dvd_mult_left:
   190   "a * b dvd c \<Longrightarrow> a dvd c"
   191   by (simp add: dvd_def mult.assoc) blast
   192 
   193 lemma dvd_mult_right:
   194   "a * b dvd c \<Longrightarrow> b dvd c"
   195   using dvd_mult_left [of b a c] by (simp add: ac_simps)
   196   
   197 end
   198 
   199 class comm_semiring_1 = zero_neq_one + comm_semiring_0 + comm_monoid_mult
   200 begin
   201 
   202 subclass semiring_1 ..
   203 
   204 lemma dvd_0_left_iff [simp]:
   205   "0 dvd a \<longleftrightarrow> a = 0"
   206   by (auto intro: dvd_refl elim!: dvdE)
   207 
   208 lemma dvd_0_right [iff]:
   209   "a dvd 0"
   210 proof
   211   show "0 = a * 0" by simp
   212 qed
   213 
   214 lemma dvd_0_left:
   215   "0 dvd a \<Longrightarrow> a = 0"
   216   by simp
   217 
   218 lemma dvd_add [simp]:
   219   assumes "a dvd b" and "a dvd c"
   220   shows "a dvd (b + c)"
   221 proof -
   222   from `a dvd b` obtain b' where "b = a * b'" ..
   223   moreover from `a dvd c` obtain c' where "c = a * c'" ..
   224   ultimately have "b + c = a * (b' + c')" by (simp add: distrib_left)
   225   then show ?thesis ..
   226 qed
   227 
   228 end
   229 
   230 class semiring_1_cancel = semiring + cancel_comm_monoid_add
   231   + zero_neq_one + monoid_mult
   232 begin
   233 
   234 subclass semiring_0_cancel ..
   235 
   236 subclass semiring_1 ..
   237 
   238 end
   239 
   240 class comm_semiring_1_cancel = comm_semiring + cancel_comm_monoid_add
   241   + zero_neq_one + comm_monoid_mult
   242 begin
   243 
   244 subclass semiring_1_cancel ..
   245 subclass comm_semiring_0_cancel ..
   246 subclass comm_semiring_1 ..
   247 
   248 end
   249 
   250 class comm_semiring_1_diff_distrib = comm_semiring_1_cancel +
   251   assumes right_diff_distrib' [algebra_simps]: "a * (b - c) = a * b - a * c"
   252 begin
   253 
   254 lemma left_diff_distrib' [algebra_simps]:
   255   "(b - c) * a = b * a - c * a"
   256   by (simp add: algebra_simps)
   257 
   258 lemma dvd_add_times_triv_left_iff [simp]:
   259   "a dvd c * a + b \<longleftrightarrow> a dvd b"
   260 proof -
   261   have "a dvd a * c + b \<longleftrightarrow> a dvd b" (is "?P \<longleftrightarrow> ?Q")
   262   proof
   263     assume ?Q then show ?P by simp
   264   next
   265     assume ?P
   266     then obtain d where "a * c + b = a * d" ..
   267     then have "a * c + b - a * c = a * d - a * c" by simp
   268     then have "b = a * d - a * c" by simp
   269     then have "b = a * (d - c)" by (simp add: algebra_simps) 
   270     then show ?Q ..
   271   qed
   272   then show "a dvd c * a + b \<longleftrightarrow> a dvd b" by (simp add: ac_simps)
   273 qed
   274 
   275 lemma dvd_add_times_triv_right_iff [simp]:
   276   "a dvd b + c * a \<longleftrightarrow> a dvd b"
   277   using dvd_add_times_triv_left_iff [of a c b] by (simp add: ac_simps)
   278 
   279 lemma dvd_add_triv_left_iff [simp]:
   280   "a dvd a + b \<longleftrightarrow> a dvd b"
   281   using dvd_add_times_triv_left_iff [of a 1 b] by simp
   282 
   283 lemma dvd_add_triv_right_iff [simp]:
   284   "a dvd b + a \<longleftrightarrow> a dvd b"
   285   using dvd_add_times_triv_right_iff [of a b 1] by simp
   286 
   287 lemma dvd_add_right_iff:
   288   assumes "a dvd b"
   289   shows "a dvd b + c \<longleftrightarrow> a dvd c" (is "?P \<longleftrightarrow> ?Q")
   290 proof
   291   assume ?P then obtain d where "b + c = a * d" ..
   292   moreover from `a dvd b` obtain e where "b = a * e" ..
   293   ultimately have "a * e + c = a * d" by simp
   294   then have "a * e + c - a * e = a * d - a * e" by simp
   295   then have "c = a * d - a * e" by simp
   296   then have "c = a * (d - e)" by (simp add: algebra_simps)
   297   then show ?Q ..
   298 next
   299   assume ?Q with assms show ?P by simp
   300 qed
   301 
   302 lemma dvd_add_left_iff:
   303   assumes "a dvd c"
   304   shows "a dvd b + c \<longleftrightarrow> a dvd b"
   305   using assms dvd_add_right_iff [of a c b] by (simp add: ac_simps)
   306 
   307 end
   308 
   309 class ring = semiring + ab_group_add
   310 begin
   311 
   312 subclass semiring_0_cancel ..
   313 
   314 text {* Distribution rules *}
   315 
   316 lemma minus_mult_left: "- (a * b) = - a * b"
   317 by (rule minus_unique) (simp add: distrib_right [symmetric]) 
   318 
   319 lemma minus_mult_right: "- (a * b) = a * - b"
   320 by (rule minus_unique) (simp add: distrib_left [symmetric]) 
   321 
   322 text{*Extract signs from products*}
   323 lemmas mult_minus_left [simp] = minus_mult_left [symmetric]
   324 lemmas mult_minus_right [simp] = minus_mult_right [symmetric]
   325 
   326 lemma minus_mult_minus [simp]: "- a * - b = a * b"
   327 by simp
   328 
   329 lemma minus_mult_commute: "- a * b = a * - b"
   330 by simp
   331 
   332 lemma right_diff_distrib [algebra_simps]:
   333   "a * (b - c) = a * b - a * c"
   334   using distrib_left [of a b "-c "] by simp
   335 
   336 lemma left_diff_distrib [algebra_simps]:
   337   "(a - b) * c = a * c - b * c"
   338   using distrib_right [of a "- b" c] by simp
   339 
   340 lemmas ring_distribs =
   341   distrib_left distrib_right left_diff_distrib right_diff_distrib
   342 
   343 lemma eq_add_iff1:
   344   "a * e + c = b * e + d \<longleftrightarrow> (a - b) * e + c = d"
   345 by (simp add: algebra_simps)
   346 
   347 lemma eq_add_iff2:
   348   "a * e + c = b * e + d \<longleftrightarrow> c = (b - a) * e + d"
   349 by (simp add: algebra_simps)
   350 
   351 end
   352 
   353 lemmas ring_distribs =
   354   distrib_left distrib_right left_diff_distrib right_diff_distrib
   355 
   356 class comm_ring = comm_semiring + ab_group_add
   357 begin
   358 
   359 subclass ring ..
   360 subclass comm_semiring_0_cancel ..
   361 
   362 lemma square_diff_square_factored:
   363   "x * x - y * y = (x + y) * (x - y)"
   364   by (simp add: algebra_simps)
   365 
   366 end
   367 
   368 class ring_1 = ring + zero_neq_one + monoid_mult
   369 begin
   370 
   371 subclass semiring_1_cancel ..
   372 
   373 lemma square_diff_one_factored:
   374   "x * x - 1 = (x + 1) * (x - 1)"
   375   by (simp add: algebra_simps)
   376 
   377 end
   378 
   379 class comm_ring_1 = comm_ring + zero_neq_one + comm_monoid_mult
   380 begin
   381 
   382 subclass ring_1 ..
   383 subclass comm_semiring_1_cancel ..
   384 
   385 subclass comm_semiring_1_diff_distrib
   386   by unfold_locales (simp add: algebra_simps)
   387 
   388 lemma dvd_minus_iff [simp]: "x dvd - y \<longleftrightarrow> x dvd y"
   389 proof
   390   assume "x dvd - y"
   391   then have "x dvd - 1 * - y" by (rule dvd_mult)
   392   then show "x dvd y" by simp
   393 next
   394   assume "x dvd y"
   395   then have "x dvd - 1 * y" by (rule dvd_mult)
   396   then show "x dvd - y" by simp
   397 qed
   398 
   399 lemma minus_dvd_iff [simp]: "- x dvd y \<longleftrightarrow> x dvd y"
   400 proof
   401   assume "- x dvd y"
   402   then obtain k where "y = - x * k" ..
   403   then have "y = x * - k" by simp
   404   then show "x dvd y" ..
   405 next
   406   assume "x dvd y"
   407   then obtain k where "y = x * k" ..
   408   then have "y = - x * - k" by simp
   409   then show "- x dvd y" ..
   410 qed
   411 
   412 lemma dvd_diff [simp]:
   413   "x dvd y \<Longrightarrow> x dvd z \<Longrightarrow> x dvd (y - z)"
   414   using dvd_add [of x y "- z"] by simp
   415 
   416 end
   417 
   418 class divide =
   419   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   420 
   421 setup {* Sign.add_const_constraint (@{const_name "divide"}, SOME @{typ "'a \<Rightarrow> 'a \<Rightarrow> 'a"}) *}
   422 
   423 context semiring
   424 begin
   425 
   426 lemma [field_simps]:
   427   shows distrib_left_NO_MATCH: "NO_MATCH (divide x y) a \<Longrightarrow> a * (b + c) = a * b + a * c"
   428     and distrib_right_NO_MATCH: "NO_MATCH (divide x y) c \<Longrightarrow> (a + b) * c = a * c + b * c"
   429   by (rule distrib_left distrib_right)+
   430 
   431 end
   432 
   433 context ring
   434 begin
   435 
   436 lemma [field_simps]:
   437   shows left_diff_distrib_NO_MATCH: "NO_MATCH (divide x y) c \<Longrightarrow> (a - b) * c = a * c - b * c"
   438     and right_diff_distrib_NO_MATCH: "NO_MATCH (divide x y) a \<Longrightarrow> a * (b - c) = a * b - a * c"
   439   by (rule left_diff_distrib right_diff_distrib)+
   440 
   441 end
   442 
   443 setup {* Sign.add_const_constraint (@{const_name "divide"}, SOME @{typ "'a::divide \<Rightarrow> 'a \<Rightarrow> 'a"}) *}
   444   
   445 class semiring_no_zero_divisors = semiring_0 +
   446   assumes no_zero_divisors: "a \<noteq> 0 \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a * b \<noteq> 0"
   447 begin
   448 
   449 lemma divisors_zero:
   450   assumes "a * b = 0"
   451   shows "a = 0 \<or> b = 0"
   452 proof (rule classical)
   453   assume "\<not> (a = 0 \<or> b = 0)"
   454   then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   455   with no_zero_divisors have "a * b \<noteq> 0" by blast
   456   with assms show ?thesis by simp
   457 qed
   458 
   459 lemma mult_eq_0_iff [simp]:
   460   shows "a * b = 0 \<longleftrightarrow> a = 0 \<or> b = 0"
   461 proof (cases "a = 0 \<or> b = 0")
   462   case False then have "a \<noteq> 0" and "b \<noteq> 0" by auto
   463     then show ?thesis using no_zero_divisors by simp
   464 next
   465   case True then show ?thesis by auto
   466 qed
   467 
   468 end
   469 
   470 class ring_no_zero_divisors = ring + semiring_no_zero_divisors
   471 begin
   472 
   473 text{*Cancellation of equalities with a common factor*}
   474 lemma mult_cancel_right [simp]:
   475   "a * c = b * c \<longleftrightarrow> c = 0 \<or> a = b"
   476 proof -
   477   have "(a * c = b * c) = ((a - b) * c = 0)"
   478     by (simp add: algebra_simps)
   479   thus ?thesis by (simp add: disj_commute)
   480 qed
   481 
   482 lemma mult_cancel_left [simp]:
   483   "c * a = c * b \<longleftrightarrow> c = 0 \<or> a = b"
   484 proof -
   485   have "(c * a = c * b) = (c * (a - b) = 0)"
   486     by (simp add: algebra_simps)
   487   thus ?thesis by simp
   488 qed
   489 
   490 lemma mult_left_cancel:
   491   "c \<noteq> 0 \<Longrightarrow> c * a = c * b \<longleftrightarrow> a = b"
   492   by simp 
   493 
   494 lemma mult_right_cancel:
   495   "c \<noteq> 0 \<Longrightarrow> a * c = b * c \<longleftrightarrow> a = b"
   496   by simp 
   497 
   498 end
   499 
   500 class ring_1_no_zero_divisors = ring_1 + ring_no_zero_divisors
   501 begin
   502 
   503 lemma square_eq_1_iff:
   504   "x * x = 1 \<longleftrightarrow> x = 1 \<or> x = - 1"
   505 proof -
   506   have "(x - 1) * (x + 1) = x * x - 1"
   507     by (simp add: algebra_simps)
   508   hence "x * x = 1 \<longleftrightarrow> (x - 1) * (x + 1) = 0"
   509     by simp
   510   thus ?thesis
   511     by (simp add: eq_neg_iff_add_eq_0)
   512 qed
   513 
   514 lemma mult_cancel_right1 [simp]:
   515   "c = b * c \<longleftrightarrow> c = 0 \<or> b = 1"
   516 by (insert mult_cancel_right [of 1 c b], force)
   517 
   518 lemma mult_cancel_right2 [simp]:
   519   "a * c = c \<longleftrightarrow> c = 0 \<or> a = 1"
   520 by (insert mult_cancel_right [of a c 1], simp)
   521  
   522 lemma mult_cancel_left1 [simp]:
   523   "c = c * b \<longleftrightarrow> c = 0 \<or> b = 1"
   524 by (insert mult_cancel_left [of c 1 b], force)
   525 
   526 lemma mult_cancel_left2 [simp]:
   527   "c * a = c \<longleftrightarrow> c = 0 \<or> a = 1"
   528 by (insert mult_cancel_left [of c a 1], simp)
   529 
   530 end
   531 
   532 class semidom = comm_semiring_1_diff_distrib + semiring_no_zero_divisors
   533 
   534 class idom = comm_ring_1 + semiring_no_zero_divisors
   535 begin
   536 
   537 subclass semidom ..
   538 
   539 subclass ring_1_no_zero_divisors ..
   540 
   541 lemma dvd_mult_cancel_right [simp]:
   542   "a * c dvd b * c \<longleftrightarrow> c = 0 \<or> a dvd b"
   543 proof -
   544   have "a * c dvd b * c \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   545     unfolding dvd_def by (simp add: ac_simps)
   546   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   547     unfolding dvd_def by simp
   548   finally show ?thesis .
   549 qed
   550 
   551 lemma dvd_mult_cancel_left [simp]:
   552   "c * a dvd c * b \<longleftrightarrow> c = 0 \<or> a dvd b"
   553 proof -
   554   have "c * a dvd c * b \<longleftrightarrow> (\<exists>k. b * c = (a * k) * c)"
   555     unfolding dvd_def by (simp add: ac_simps)
   556   also have "(\<exists>k. b * c = (a * k) * c) \<longleftrightarrow> c = 0 \<or> a dvd b"
   557     unfolding dvd_def by simp
   558   finally show ?thesis .
   559 qed
   560 
   561 lemma square_eq_iff: "a * a = b * b \<longleftrightarrow> (a = b \<or> a = - b)"
   562 proof
   563   assume "a * a = b * b"
   564   then have "(a - b) * (a + b) = 0"
   565     by (simp add: algebra_simps)
   566   then show "a = b \<or> a = - b"
   567     by (simp add: eq_neg_iff_add_eq_0)
   568 next
   569   assume "a = b \<or> a = - b"
   570   then show "a * a = b * b" by auto
   571 qed
   572 
   573 end
   574 
   575 text {*
   576   The theory of partially ordered rings is taken from the books:
   577   \begin{itemize}
   578   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
   579   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
   580   \end{itemize}
   581   Most of the used notions can also be looked up in 
   582   \begin{itemize}
   583   \item @{url "http://www.mathworld.com"} by Eric Weisstein et. al.
   584   \item \emph{Algebra I} by van der Waerden, Springer.
   585   \end{itemize}
   586 *}
   587 
   588 class ordered_semiring = semiring + comm_monoid_add + ordered_ab_semigroup_add +
   589   assumes mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   590   assumes mult_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * c"
   591 begin
   592 
   593 lemma mult_mono:
   594   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   595 apply (erule mult_right_mono [THEN order_trans], assumption)
   596 apply (erule mult_left_mono, assumption)
   597 done
   598 
   599 lemma mult_mono':
   600   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a * c \<le> b * d"
   601 apply (rule mult_mono)
   602 apply (fast intro: order_trans)+
   603 done
   604 
   605 end
   606 
   607 class ordered_cancel_semiring = ordered_semiring + cancel_comm_monoid_add
   608 begin
   609 
   610 subclass semiring_0_cancel ..
   611 
   612 lemma mult_nonneg_nonneg[simp]: "0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> a * b"
   613 using mult_left_mono [of 0 b a] by simp
   614 
   615 lemma mult_nonneg_nonpos: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> a * b \<le> 0"
   616 using mult_left_mono [of b 0 a] by simp
   617 
   618 lemma mult_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> b \<Longrightarrow> a * b \<le> 0"
   619 using mult_right_mono [of a 0 b] by simp
   620 
   621 text {* Legacy - use @{text mult_nonpos_nonneg} *}
   622 lemma mult_nonneg_nonpos2: "0 \<le> a \<Longrightarrow> b \<le> 0 \<Longrightarrow> b * a \<le> 0" 
   623 by (drule mult_right_mono [of b 0], auto)
   624 
   625 lemma split_mult_neg_le: "(0 \<le> a & b \<le> 0) | (a \<le> 0 & 0 \<le> b) \<Longrightarrow> a * b \<le> 0" 
   626 by (auto simp add: mult_nonneg_nonpos mult_nonneg_nonpos2)
   627 
   628 end
   629 
   630 class linordered_semiring = ordered_semiring + linordered_cancel_ab_semigroup_add
   631 begin
   632 
   633 subclass ordered_cancel_semiring ..
   634 
   635 subclass ordered_comm_monoid_add ..
   636 
   637 lemma mult_left_less_imp_less:
   638   "c * a < c * b \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   639 by (force simp add: mult_left_mono not_le [symmetric])
   640  
   641 lemma mult_right_less_imp_less:
   642   "a * c < b * c \<Longrightarrow> 0 \<le> c \<Longrightarrow> a < b"
   643 by (force simp add: mult_right_mono not_le [symmetric])
   644 
   645 end
   646 
   647 class linordered_semiring_1 = linordered_semiring + semiring_1
   648 begin
   649 
   650 lemma convex_bound_le:
   651   assumes "x \<le> a" "y \<le> a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   652   shows "u * x + v * y \<le> a"
   653 proof-
   654   from assms have "u * x + v * y \<le> u * a + v * a"
   655     by (simp add: add_mono mult_left_mono)
   656   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   657 qed
   658 
   659 end
   660 
   661 class linordered_semiring_strict = semiring + comm_monoid_add + linordered_cancel_ab_semigroup_add +
   662   assumes mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   663   assumes mult_strict_right_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> a * c < b * c"
   664 begin
   665 
   666 subclass semiring_0_cancel ..
   667 
   668 subclass linordered_semiring
   669 proof
   670   fix a b c :: 'a
   671   assume A: "a \<le> b" "0 \<le> c"
   672   from A show "c * a \<le> c * b"
   673     unfolding le_less
   674     using mult_strict_left_mono by (cases "c = 0") auto
   675   from A show "a * c \<le> b * c"
   676     unfolding le_less
   677     using mult_strict_right_mono by (cases "c = 0") auto
   678 qed
   679 
   680 lemma mult_left_le_imp_le:
   681   "c * a \<le> c * b \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   682 by (force simp add: mult_strict_left_mono _not_less [symmetric])
   683  
   684 lemma mult_right_le_imp_le:
   685   "a * c \<le> b * c \<Longrightarrow> 0 < c \<Longrightarrow> a \<le> b"
   686 by (force simp add: mult_strict_right_mono not_less [symmetric])
   687 
   688 lemma mult_pos_pos[simp]: "0 < a \<Longrightarrow> 0 < b \<Longrightarrow> 0 < a * b"
   689 using mult_strict_left_mono [of 0 b a] by simp
   690 
   691 lemma mult_pos_neg: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> a * b < 0"
   692 using mult_strict_left_mono [of b 0 a] by simp
   693 
   694 lemma mult_neg_pos: "a < 0 \<Longrightarrow> 0 < b \<Longrightarrow> a * b < 0"
   695 using mult_strict_right_mono [of a 0 b] by simp
   696 
   697 text {* Legacy - use @{text mult_neg_pos} *}
   698 lemma mult_pos_neg2: "0 < a \<Longrightarrow> b < 0 \<Longrightarrow> b * a < 0" 
   699 by (drule mult_strict_right_mono [of b 0], auto)
   700 
   701 lemma zero_less_mult_pos:
   702   "0 < a * b \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   703 apply (cases "b\<le>0")
   704  apply (auto simp add: le_less not_less)
   705 apply (drule_tac mult_pos_neg [of a b])
   706  apply (auto dest: less_not_sym)
   707 done
   708 
   709 lemma zero_less_mult_pos2:
   710   "0 < b * a \<Longrightarrow> 0 < a \<Longrightarrow> 0 < b"
   711 apply (cases "b\<le>0")
   712  apply (auto simp add: le_less not_less)
   713 apply (drule_tac mult_pos_neg2 [of a b])
   714  apply (auto dest: less_not_sym)
   715 done
   716 
   717 text{*Strict monotonicity in both arguments*}
   718 lemma mult_strict_mono:
   719   assumes "a < b" and "c < d" and "0 < b" and "0 \<le> c"
   720   shows "a * c < b * d"
   721   using assms apply (cases "c=0")
   722   apply (simp)
   723   apply (erule mult_strict_right_mono [THEN less_trans])
   724   apply (force simp add: le_less)
   725   apply (erule mult_strict_left_mono, assumption)
   726   done
   727 
   728 text{*This weaker variant has more natural premises*}
   729 lemma mult_strict_mono':
   730   assumes "a < b" and "c < d" and "0 \<le> a" and "0 \<le> c"
   731   shows "a * c < b * d"
   732 by (rule mult_strict_mono) (insert assms, auto)
   733 
   734 lemma mult_less_le_imp_less:
   735   assumes "a < b" and "c \<le> d" and "0 \<le> a" and "0 < c"
   736   shows "a * c < b * d"
   737   using assms apply (subgoal_tac "a * c < b * c")
   738   apply (erule less_le_trans)
   739   apply (erule mult_left_mono)
   740   apply simp
   741   apply (erule mult_strict_right_mono)
   742   apply assumption
   743   done
   744 
   745 lemma mult_le_less_imp_less:
   746   assumes "a \<le> b" and "c < d" and "0 < a" and "0 \<le> c"
   747   shows "a * c < b * d"
   748   using assms apply (subgoal_tac "a * c \<le> b * c")
   749   apply (erule le_less_trans)
   750   apply (erule mult_strict_left_mono)
   751   apply simp
   752   apply (erule mult_right_mono)
   753   apply simp
   754   done
   755 
   756 end
   757 
   758 class linordered_semiring_1_strict = linordered_semiring_strict + semiring_1
   759 begin
   760 
   761 subclass linordered_semiring_1 ..
   762 
   763 lemma convex_bound_lt:
   764   assumes "x < a" "y < a" "0 \<le> u" "0 \<le> v" "u + v = 1"
   765   shows "u * x + v * y < a"
   766 proof -
   767   from assms have "u * x + v * y < u * a + v * a"
   768     by (cases "u = 0")
   769        (auto intro!: add_less_le_mono mult_strict_left_mono mult_left_mono)
   770   thus ?thesis using assms unfolding distrib_right[symmetric] by simp
   771 qed
   772 
   773 end
   774 
   775 class ordered_comm_semiring = comm_semiring_0 + ordered_ab_semigroup_add + 
   776   assumes comm_mult_left_mono: "a \<le> b \<Longrightarrow> 0 \<le> c \<Longrightarrow> c * a \<le> c * b"
   777 begin
   778 
   779 subclass ordered_semiring
   780 proof
   781   fix a b c :: 'a
   782   assume "a \<le> b" "0 \<le> c"
   783   thus "c * a \<le> c * b" by (rule comm_mult_left_mono)
   784   thus "a * c \<le> b * c" by (simp only: mult.commute)
   785 qed
   786 
   787 end
   788 
   789 class ordered_cancel_comm_semiring = ordered_comm_semiring + cancel_comm_monoid_add
   790 begin
   791 
   792 subclass comm_semiring_0_cancel ..
   793 subclass ordered_comm_semiring ..
   794 subclass ordered_cancel_semiring ..
   795 
   796 end
   797 
   798 class linordered_comm_semiring_strict = comm_semiring_0 + linordered_cancel_ab_semigroup_add +
   799   assumes comm_mult_strict_left_mono: "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   800 begin
   801 
   802 subclass linordered_semiring_strict
   803 proof
   804   fix a b c :: 'a
   805   assume "a < b" "0 < c"
   806   thus "c * a < c * b" by (rule comm_mult_strict_left_mono)
   807   thus "a * c < b * c" by (simp only: mult.commute)
   808 qed
   809 
   810 subclass ordered_cancel_comm_semiring
   811 proof
   812   fix a b c :: 'a
   813   assume "a \<le> b" "0 \<le> c"
   814   thus "c * a \<le> c * b"
   815     unfolding le_less
   816     using mult_strict_left_mono by (cases "c = 0") auto
   817 qed
   818 
   819 end
   820 
   821 class ordered_ring = ring + ordered_cancel_semiring 
   822 begin
   823 
   824 subclass ordered_ab_group_add ..
   825 
   826 lemma less_add_iff1:
   827   "a * e + c < b * e + d \<longleftrightarrow> (a - b) * e + c < d"
   828 by (simp add: algebra_simps)
   829 
   830 lemma less_add_iff2:
   831   "a * e + c < b * e + d \<longleftrightarrow> c < (b - a) * e + d"
   832 by (simp add: algebra_simps)
   833 
   834 lemma le_add_iff1:
   835   "a * e + c \<le> b * e + d \<longleftrightarrow> (a - b) * e + c \<le> d"
   836 by (simp add: algebra_simps)
   837 
   838 lemma le_add_iff2:
   839   "a * e + c \<le> b * e + d \<longleftrightarrow> c \<le> (b - a) * e + d"
   840 by (simp add: algebra_simps)
   841 
   842 lemma mult_left_mono_neg:
   843   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c * a \<le> c * b"
   844   apply (drule mult_left_mono [of _ _ "- c"])
   845   apply simp_all
   846   done
   847 
   848 lemma mult_right_mono_neg:
   849   "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a * c \<le> b * c"
   850   apply (drule mult_right_mono [of _ _ "- c"])
   851   apply simp_all
   852   done
   853 
   854 lemma mult_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a * b"
   855 using mult_right_mono_neg [of a 0 b] by simp
   856 
   857 lemma split_mult_pos_le:
   858   "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a * b"
   859 by (auto simp add: mult_nonpos_nonpos)
   860 
   861 end
   862 
   863 class linordered_ring = ring + linordered_semiring + linordered_ab_group_add + abs_if
   864 begin
   865 
   866 subclass ordered_ring ..
   867 
   868 subclass ordered_ab_group_add_abs
   869 proof
   870   fix a b
   871   show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
   872     by (auto simp add: abs_if not_le not_less algebra_simps simp del: add.commute dest: add_neg_neg add_nonneg_nonneg)
   873 qed (auto simp add: abs_if)
   874 
   875 lemma zero_le_square [simp]: "0 \<le> a * a"
   876   using linear [of 0 a]
   877   by (auto simp add: mult_nonpos_nonpos)
   878 
   879 lemma not_square_less_zero [simp]: "\<not> (a * a < 0)"
   880   by (simp add: not_less)
   881 
   882 end
   883 
   884 class linordered_ring_strict = ring + linordered_semiring_strict
   885   + ordered_ab_group_add + abs_if
   886 begin
   887 
   888 subclass linordered_ring ..
   889 
   890 lemma mult_strict_left_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> c * a < c * b"
   891 using mult_strict_left_mono [of b a "- c"] by simp
   892 
   893 lemma mult_strict_right_mono_neg: "b < a \<Longrightarrow> c < 0 \<Longrightarrow> a * c < b * c"
   894 using mult_strict_right_mono [of b a "- c"] by simp
   895 
   896 lemma mult_neg_neg: "a < 0 \<Longrightarrow> b < 0 \<Longrightarrow> 0 < a * b"
   897 using mult_strict_right_mono_neg [of a 0 b] by simp
   898 
   899 subclass ring_no_zero_divisors
   900 proof
   901   fix a b
   902   assume "a \<noteq> 0" then have A: "a < 0 \<or> 0 < a" by (simp add: neq_iff)
   903   assume "b \<noteq> 0" then have B: "b < 0 \<or> 0 < b" by (simp add: neq_iff)
   904   have "a * b < 0 \<or> 0 < a * b"
   905   proof (cases "a < 0")
   906     case True note A' = this
   907     show ?thesis proof (cases "b < 0")
   908       case True with A'
   909       show ?thesis by (auto dest: mult_neg_neg)
   910     next
   911       case False with B have "0 < b" by auto
   912       with A' show ?thesis by (auto dest: mult_strict_right_mono)
   913     qed
   914   next
   915     case False with A have A': "0 < a" by auto
   916     show ?thesis proof (cases "b < 0")
   917       case True with A'
   918       show ?thesis by (auto dest: mult_strict_right_mono_neg)
   919     next
   920       case False with B have "0 < b" by auto
   921       with A' show ?thesis by auto
   922     qed
   923   qed
   924   then show "a * b \<noteq> 0" by (simp add: neq_iff)
   925 qed
   926 
   927 lemma zero_less_mult_iff: "0 < a * b \<longleftrightarrow> 0 < a \<and> 0 < b \<or> a < 0 \<and> b < 0"
   928   by (cases a 0 b 0 rule: linorder_cases[case_product linorder_cases])
   929      (auto simp add: mult_neg_neg not_less le_less dest: zero_less_mult_pos zero_less_mult_pos2)
   930 
   931 lemma zero_le_mult_iff: "0 \<le> a * b \<longleftrightarrow> 0 \<le> a \<and> 0 \<le> b \<or> a \<le> 0 \<and> b \<le> 0"
   932   by (auto simp add: eq_commute [of 0] le_less not_less zero_less_mult_iff)
   933 
   934 lemma mult_less_0_iff:
   935   "a * b < 0 \<longleftrightarrow> 0 < a \<and> b < 0 \<or> a < 0 \<and> 0 < b"
   936   apply (insert zero_less_mult_iff [of "-a" b])
   937   apply force
   938   done
   939 
   940 lemma mult_le_0_iff:
   941   "a * b \<le> 0 \<longleftrightarrow> 0 \<le> a \<and> b \<le> 0 \<or> a \<le> 0 \<and> 0 \<le> b"
   942   apply (insert zero_le_mult_iff [of "-a" b]) 
   943   apply force
   944   done
   945 
   946 text{*Cancellation laws for @{term "c*a < c*b"} and @{term "a*c < b*c"},
   947    also with the relations @{text "\<le>"} and equality.*}
   948 
   949 text{*These ``disjunction'' versions produce two cases when the comparison is
   950  an assumption, but effectively four when the comparison is a goal.*}
   951 
   952 lemma mult_less_cancel_right_disj:
   953   "a * c < b * c \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   954   apply (cases "c = 0")
   955   apply (auto simp add: neq_iff mult_strict_right_mono 
   956                       mult_strict_right_mono_neg)
   957   apply (auto simp add: not_less 
   958                       not_le [symmetric, of "a*c"]
   959                       not_le [symmetric, of a])
   960   apply (erule_tac [!] notE)
   961   apply (auto simp add: less_imp_le mult_right_mono 
   962                       mult_right_mono_neg)
   963   done
   964 
   965 lemma mult_less_cancel_left_disj:
   966   "c * a < c * b \<longleftrightarrow> 0 < c \<and> a < b \<or> c < 0 \<and>  b < a"
   967   apply (cases "c = 0")
   968   apply (auto simp add: neq_iff mult_strict_left_mono 
   969                       mult_strict_left_mono_neg)
   970   apply (auto simp add: not_less 
   971                       not_le [symmetric, of "c*a"]
   972                       not_le [symmetric, of a])
   973   apply (erule_tac [!] notE)
   974   apply (auto simp add: less_imp_le mult_left_mono 
   975                       mult_left_mono_neg)
   976   done
   977 
   978 text{*The ``conjunction of implication'' lemmas produce two cases when the
   979 comparison is a goal, but give four when the comparison is an assumption.*}
   980 
   981 lemma mult_less_cancel_right:
   982   "a * c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
   983   using mult_less_cancel_right_disj [of a c b] by auto
   984 
   985 lemma mult_less_cancel_left:
   986   "c * a < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < b) \<and> (c \<le> 0 \<longrightarrow> b < a)"
   987   using mult_less_cancel_left_disj [of c a b] by auto
   988 
   989 lemma mult_le_cancel_right:
   990    "a * c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   991 by (simp add: not_less [symmetric] mult_less_cancel_right_disj)
   992 
   993 lemma mult_le_cancel_left:
   994   "c * a \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   995 by (simp add: not_less [symmetric] mult_less_cancel_left_disj)
   996 
   997 lemma mult_le_cancel_left_pos:
   998   "0 < c \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> a \<le> b"
   999 by (auto simp: mult_le_cancel_left)
  1000 
  1001 lemma mult_le_cancel_left_neg:
  1002   "c < 0 \<Longrightarrow> c * a \<le> c * b \<longleftrightarrow> b \<le> a"
  1003 by (auto simp: mult_le_cancel_left)
  1004 
  1005 lemma mult_less_cancel_left_pos:
  1006   "0 < c \<Longrightarrow> c * a < c * b \<longleftrightarrow> a < b"
  1007 by (auto simp: mult_less_cancel_left)
  1008 
  1009 lemma mult_less_cancel_left_neg:
  1010   "c < 0 \<Longrightarrow> c * a < c * b \<longleftrightarrow> b < a"
  1011 by (auto simp: mult_less_cancel_left)
  1012 
  1013 end
  1014 
  1015 lemmas mult_sign_intros =
  1016   mult_nonneg_nonneg mult_nonneg_nonpos
  1017   mult_nonpos_nonneg mult_nonpos_nonpos
  1018   mult_pos_pos mult_pos_neg
  1019   mult_neg_pos mult_neg_neg
  1020 
  1021 class ordered_comm_ring = comm_ring + ordered_comm_semiring
  1022 begin
  1023 
  1024 subclass ordered_ring ..
  1025 subclass ordered_cancel_comm_semiring ..
  1026 
  1027 end
  1028 
  1029 class linordered_semidom = semidom + linordered_comm_semiring_strict +
  1030   assumes zero_less_one [simp]: "0 < 1"
  1031 begin
  1032 
  1033 lemma pos_add_strict:
  1034   shows "0 < a \<Longrightarrow> b < c \<Longrightarrow> b < a + c"
  1035   using add_strict_mono [of 0 a b c] by simp
  1036 
  1037 lemma zero_le_one [simp]: "0 \<le> 1"
  1038 by (rule zero_less_one [THEN less_imp_le]) 
  1039 
  1040 lemma not_one_le_zero [simp]: "\<not> 1 \<le> 0"
  1041 by (simp add: not_le) 
  1042 
  1043 lemma not_one_less_zero [simp]: "\<not> 1 < 0"
  1044 by (simp add: not_less) 
  1045 
  1046 lemma less_1_mult:
  1047   assumes "1 < m" and "1 < n"
  1048   shows "1 < m * n"
  1049   using assms mult_strict_mono [of 1 m 1 n]
  1050     by (simp add:  less_trans [OF zero_less_one]) 
  1051 
  1052 lemma mult_left_le: "c \<le> 1 \<Longrightarrow> 0 \<le> a \<Longrightarrow> a * c \<le> a"
  1053   using mult_left_mono[of c 1 a] by simp
  1054 
  1055 lemma mult_le_one: "a \<le> 1 \<Longrightarrow> 0 \<le> b \<Longrightarrow> b \<le> 1 \<Longrightarrow> a * b \<le> 1"
  1056   using mult_mono[of a 1 b 1] by simp
  1057 
  1058 end
  1059 
  1060 class linordered_idom = comm_ring_1 +
  1061   linordered_comm_semiring_strict + ordered_ab_group_add +
  1062   abs_if + sgn_if
  1063 begin
  1064 
  1065 subclass linordered_semiring_1_strict ..
  1066 subclass linordered_ring_strict ..
  1067 subclass ordered_comm_ring ..
  1068 subclass idom ..
  1069 
  1070 subclass linordered_semidom
  1071 proof
  1072   have "0 \<le> 1 * 1" by (rule zero_le_square)
  1073   thus "0 < 1" by (simp add: le_less)
  1074 qed 
  1075 
  1076 lemma linorder_neqE_linordered_idom:
  1077   assumes "x \<noteq> y" obtains "x < y" | "y < x"
  1078   using assms by (rule neqE)
  1079 
  1080 text {* These cancellation simprules also produce two cases when the comparison is a goal. *}
  1081 
  1082 lemma mult_le_cancel_right1:
  1083   "c \<le> b * c \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1084 by (insert mult_le_cancel_right [of 1 c b], simp)
  1085 
  1086 lemma mult_le_cancel_right2:
  1087   "a * c \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1088 by (insert mult_le_cancel_right [of a c 1], simp)
  1089 
  1090 lemma mult_le_cancel_left1:
  1091   "c \<le> c * b \<longleftrightarrow> (0 < c \<longrightarrow> 1 \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> 1)"
  1092 by (insert mult_le_cancel_left [of c 1 b], simp)
  1093 
  1094 lemma mult_le_cancel_left2:
  1095   "c * a \<le> c \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> 1) \<and> (c < 0 \<longrightarrow> 1 \<le> a)"
  1096 by (insert mult_le_cancel_left [of c a 1], simp)
  1097 
  1098 lemma mult_less_cancel_right1:
  1099   "c < b * c \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1100 by (insert mult_less_cancel_right [of 1 c b], simp)
  1101 
  1102 lemma mult_less_cancel_right2:
  1103   "a * c < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1104 by (insert mult_less_cancel_right [of a c 1], simp)
  1105 
  1106 lemma mult_less_cancel_left1:
  1107   "c < c * b \<longleftrightarrow> (0 \<le> c \<longrightarrow> 1 < b) \<and> (c \<le> 0 \<longrightarrow> b < 1)"
  1108 by (insert mult_less_cancel_left [of c 1 b], simp)
  1109 
  1110 lemma mult_less_cancel_left2:
  1111   "c * a < c \<longleftrightarrow> (0 \<le> c \<longrightarrow> a < 1) \<and> (c \<le> 0 \<longrightarrow> 1 < a)"
  1112 by (insert mult_less_cancel_left [of c a 1], simp)
  1113 
  1114 lemma sgn_sgn [simp]:
  1115   "sgn (sgn a) = sgn a"
  1116 unfolding sgn_if by simp
  1117 
  1118 lemma sgn_0_0:
  1119   "sgn a = 0 \<longleftrightarrow> a = 0"
  1120 unfolding sgn_if by simp
  1121 
  1122 lemma sgn_1_pos:
  1123   "sgn a = 1 \<longleftrightarrow> a > 0"
  1124 unfolding sgn_if by simp
  1125 
  1126 lemma sgn_1_neg:
  1127   "sgn a = - 1 \<longleftrightarrow> a < 0"
  1128 unfolding sgn_if by auto
  1129 
  1130 lemma sgn_pos [simp]:
  1131   "0 < a \<Longrightarrow> sgn a = 1"
  1132 unfolding sgn_1_pos .
  1133 
  1134 lemma sgn_neg [simp]:
  1135   "a < 0 \<Longrightarrow> sgn a = - 1"
  1136 unfolding sgn_1_neg .
  1137 
  1138 lemma sgn_times:
  1139   "sgn (a * b) = sgn a * sgn b"
  1140 by (auto simp add: sgn_if zero_less_mult_iff)
  1141 
  1142 lemma abs_sgn: "\<bar>k\<bar> = k * sgn k"
  1143 unfolding sgn_if abs_if by auto
  1144 
  1145 lemma sgn_greater [simp]:
  1146   "0 < sgn a \<longleftrightarrow> 0 < a"
  1147   unfolding sgn_if by auto
  1148 
  1149 lemma sgn_less [simp]:
  1150   "sgn a < 0 \<longleftrightarrow> a < 0"
  1151   unfolding sgn_if by auto
  1152 
  1153 lemma abs_dvd_iff [simp]: "\<bar>m\<bar> dvd k \<longleftrightarrow> m dvd k"
  1154   by (simp add: abs_if)
  1155 
  1156 lemma dvd_abs_iff [simp]: "m dvd \<bar>k\<bar> \<longleftrightarrow> m dvd k"
  1157   by (simp add: abs_if)
  1158 
  1159 lemma dvd_if_abs_eq:
  1160   "\<bar>l\<bar> = \<bar>k\<bar> \<Longrightarrow> l dvd k"
  1161 by(subst abs_dvd_iff[symmetric]) simp
  1162 
  1163 text {* The following lemmas can be proven in more general structures, but
  1164 are dangerous as simp rules in absence of @{thm neg_equal_zero}, 
  1165 @{thm neg_less_pos}, @{thm neg_less_eq_nonneg}. *}
  1166 
  1167 lemma equation_minus_iff_1 [simp, no_atp]:
  1168   "1 = - a \<longleftrightarrow> a = - 1"
  1169   by (fact equation_minus_iff)
  1170 
  1171 lemma minus_equation_iff_1 [simp, no_atp]:
  1172   "- a = 1 \<longleftrightarrow> a = - 1"
  1173   by (subst minus_equation_iff, auto)
  1174 
  1175 lemma le_minus_iff_1 [simp, no_atp]:
  1176   "1 \<le> - b \<longleftrightarrow> b \<le> - 1"
  1177   by (fact le_minus_iff)
  1178 
  1179 lemma minus_le_iff_1 [simp, no_atp]:
  1180   "- a \<le> 1 \<longleftrightarrow> - 1 \<le> a"
  1181   by (fact minus_le_iff)
  1182 
  1183 lemma less_minus_iff_1 [simp, no_atp]:
  1184   "1 < - b \<longleftrightarrow> b < - 1"
  1185   by (fact less_minus_iff)
  1186 
  1187 lemma minus_less_iff_1 [simp, no_atp]:
  1188   "- a < 1 \<longleftrightarrow> - 1 < a"
  1189   by (fact minus_less_iff)
  1190 
  1191 end
  1192 
  1193 text {* Simprules for comparisons where common factors can be cancelled. *}
  1194 
  1195 lemmas mult_compare_simps =
  1196     mult_le_cancel_right mult_le_cancel_left
  1197     mult_le_cancel_right1 mult_le_cancel_right2
  1198     mult_le_cancel_left1 mult_le_cancel_left2
  1199     mult_less_cancel_right mult_less_cancel_left
  1200     mult_less_cancel_right1 mult_less_cancel_right2
  1201     mult_less_cancel_left1 mult_less_cancel_left2
  1202     mult_cancel_right mult_cancel_left
  1203     mult_cancel_right1 mult_cancel_right2
  1204     mult_cancel_left1 mult_cancel_left2
  1205 
  1206 text {* Reasoning about inequalities with division *}
  1207 
  1208 context linordered_semidom
  1209 begin
  1210 
  1211 lemma less_add_one: "a < a + 1"
  1212 proof -
  1213   have "a + 0 < a + 1"
  1214     by (blast intro: zero_less_one add_strict_left_mono)
  1215   thus ?thesis by simp
  1216 qed
  1217 
  1218 lemma zero_less_two: "0 < 1 + 1"
  1219 by (blast intro: less_trans zero_less_one less_add_one)
  1220 
  1221 end
  1222 
  1223 context linordered_idom
  1224 begin
  1225 
  1226 lemma mult_right_le_one_le:
  1227   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> x * y \<le> x"
  1228   by (rule mult_left_le)
  1229 
  1230 lemma mult_left_le_one_le:
  1231   "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> y \<le> 1 \<Longrightarrow> y * x \<le> x"
  1232   by (auto simp add: mult_le_cancel_right2)
  1233 
  1234 end
  1235 
  1236 text {* Absolute Value *}
  1237 
  1238 context linordered_idom
  1239 begin
  1240 
  1241 lemma mult_sgn_abs:
  1242   "sgn x * \<bar>x\<bar> = x"
  1243   unfolding abs_if sgn_if by auto
  1244 
  1245 lemma abs_one [simp]:
  1246   "\<bar>1\<bar> = 1"
  1247   by (simp add: abs_if)
  1248 
  1249 end
  1250 
  1251 class ordered_ring_abs = ordered_ring + ordered_ab_group_add_abs +
  1252   assumes abs_eq_mult:
  1253     "(0 \<le> a \<or> a \<le> 0) \<and> (0 \<le> b \<or> b \<le> 0) \<Longrightarrow> \<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>"
  1254 
  1255 context linordered_idom
  1256 begin
  1257 
  1258 subclass ordered_ring_abs proof
  1259 qed (auto simp add: abs_if not_less mult_less_0_iff)
  1260 
  1261 lemma abs_mult:
  1262   "\<bar>a * b\<bar> = \<bar>a\<bar> * \<bar>b\<bar>" 
  1263   by (rule abs_eq_mult) auto
  1264 
  1265 lemma abs_mult_self:
  1266   "\<bar>a\<bar> * \<bar>a\<bar> = a * a"
  1267   by (simp add: abs_if) 
  1268 
  1269 lemma abs_mult_less:
  1270   "\<bar>a\<bar> < c \<Longrightarrow> \<bar>b\<bar> < d \<Longrightarrow> \<bar>a\<bar> * \<bar>b\<bar> < c * d"
  1271 proof -
  1272   assume ac: "\<bar>a\<bar> < c"
  1273   hence cpos: "0<c" by (blast intro: le_less_trans abs_ge_zero)
  1274   assume "\<bar>b\<bar> < d"
  1275   thus ?thesis by (simp add: ac cpos mult_strict_mono) 
  1276 qed
  1277 
  1278 lemma abs_less_iff:
  1279   "\<bar>a\<bar> < b \<longleftrightarrow> a < b \<and> - a < b" 
  1280   by (simp add: less_le abs_le_iff) (auto simp add: abs_if)
  1281 
  1282 lemma abs_mult_pos:
  1283   "0 \<le> x \<Longrightarrow> \<bar>y\<bar> * x = \<bar>y * x\<bar>"
  1284   by (simp add: abs_mult)
  1285 
  1286 lemma abs_diff_less_iff:
  1287   "\<bar>x - a\<bar> < r \<longleftrightarrow> a - r < x \<and> x < a + r"
  1288   by (auto simp add: diff_less_eq ac_simps abs_less_iff)
  1289 
  1290 lemma abs_diff_le_iff:
  1291    "\<bar>x - a\<bar> \<le> r \<longleftrightarrow> a - r \<le> x \<and> x \<le> a + r"
  1292   by (auto simp add: diff_le_eq ac_simps abs_le_iff)
  1293 
  1294 end
  1295 
  1296 hide_fact (open) comm_mult_left_mono comm_mult_strict_left_mono distrib
  1297 
  1298 code_identifier
  1299   code_module Rings \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1300 
  1301 end