src/Pure/context.ML
author wenzelm
Tue Oct 04 19:01:37 2005 +0200 (2005-10-04)
changeset 17756 d4a35f82fbb4
parent 17412 e26cb20ef0cc
child 18632 3149c6abe876
permissions -rw-r--r--
minor tweaks for Poplog/ML;
     1 (*  Title:      Pure/context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Generic theory contexts with unique identity, arbitrarily typed data,
     6 development graph and history support.  Implicit theory contexts in ML.
     7 Generic proof contexts with arbitrarily typed data.
     8 *)
     9 
    10 signature BASIC_CONTEXT =
    11 sig
    12   type theory
    13   type theory_ref
    14   exception THEORY of string * theory list
    15   val context: theory -> unit
    16   val the_context: unit -> theory
    17 end;
    18 
    19 signature CONTEXT =
    20 sig
    21   include BASIC_CONTEXT
    22   (*theory context*)
    23   val theory_name: theory -> string
    24   val parents_of: theory -> theory list
    25   val ancestors_of: theory -> theory list
    26   val is_stale: theory -> bool
    27   val ProtoPureN: string
    28   val PureN: string
    29   val CPureN: string
    30   val draftN: string
    31   val exists_name: string -> theory -> bool
    32   val names_of: theory -> string list
    33   val pretty_thy: theory -> Pretty.T
    34   val string_of_thy: theory -> string
    35   val pprint_thy: theory -> pprint_args -> unit
    36   val pretty_abbrev_thy: theory -> Pretty.T
    37   val str_of_thy: theory -> string
    38   val check_thy: theory -> theory
    39   val eq_thy: theory * theory -> bool
    40   val subthy: theory * theory -> bool
    41   val joinable: theory * theory -> bool
    42   val merge: theory * theory -> theory                     (*exception TERM*)
    43   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    44   val self_ref: theory -> theory_ref
    45   val deref: theory_ref -> theory
    46   val copy_thy: theory -> theory
    47   val checkpoint_thy: theory -> theory
    48   val finish_thy: theory -> theory
    49   val theory_data_of: theory -> string list
    50   val pre_pure_thy: theory
    51   val begin_thy: (theory -> Pretty.pp) -> string -> theory list -> theory
    52   (*ML theory context*)
    53   val get_context: unit -> theory option
    54   val set_context: theory option -> unit
    55   val reset_context: unit -> unit
    56   val setmp: theory option -> ('a -> 'b) -> 'a -> 'b
    57   val pass: theory option -> ('a -> 'b) -> 'a -> 'b * theory option
    58   val pass_theory: theory -> ('a -> 'b) -> 'a -> 'b * theory
    59   val save: ('a -> 'b) -> 'a -> 'b
    60   val >> : (theory -> theory) -> unit
    61   val ml_output: (string -> unit) * (string -> unit)
    62   val use_mltext: string -> bool -> theory option -> unit
    63   val use_mltext_theory: string -> bool -> theory -> theory
    64   val use_let: string -> string -> string -> theory -> theory
    65   val add_setup: (theory -> theory) list -> unit
    66   val setup: unit -> (theory -> theory) list
    67   (*proof context*)
    68   type proof
    69   exception PROOF of string * proof
    70   val theory_of_proof: proof -> theory
    71   val transfer_proof: theory -> proof -> proof
    72   val init_proof: theory -> proof
    73   val proof_data_of: theory -> string list
    74   (*generic context*)
    75   datatype context = Theory of theory | Proof of proof
    76   val theory_of: context -> theory
    77   val proof_of: context -> proof
    78 end;
    79 
    80 signature PRIVATE_CONTEXT =
    81 sig
    82   include CONTEXT
    83   structure TheoryData:
    84   sig
    85     val declare: string -> Object.T -> (Object.T -> Object.T) -> (Object.T -> Object.T) ->
    86       (Pretty.pp -> Object.T * Object.T -> Object.T) -> serial
    87     val init: serial -> theory -> theory
    88     val get: serial -> (Object.T -> 'a) -> theory -> 'a
    89     val put: serial -> ('a -> Object.T) -> 'a -> theory -> theory
    90   end
    91   structure ProofData:
    92   sig
    93     val declare: string -> (theory -> Object.T) -> serial
    94     val init: serial -> theory -> theory
    95     val get: serial -> (Object.T -> 'a) -> proof -> 'a
    96     val put: serial -> ('a -> Object.T) -> 'a -> proof -> proof
    97   end
    98 end;
    99 
   100 structure Context: PRIVATE_CONTEXT =
   101 struct
   102 
   103 (*** theory context ***)
   104 
   105 (** theory data **)
   106 
   107 (* data kinds and access methods *)
   108 
   109 local
   110 
   111 type kind =
   112  {name: string,
   113   empty: Object.T,
   114   copy: Object.T -> Object.T,
   115   extend: Object.T -> Object.T,
   116   merge: Pretty.pp -> Object.T * Object.T -> Object.T};
   117 
   118 val kinds = ref (Inttab.empty: kind Inttab.table);
   119 
   120 fun invoke meth_name meth_fn k =
   121   (case Inttab.lookup (! kinds) k of
   122     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   123       EXCEPTION (exn, "Theory data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   124   | NONE => sys_error ("Invalid theory data identifier " ^ string_of_int k));
   125 
   126 in
   127 
   128 fun invoke_name k    = invoke "name" (K o #name) k ();
   129 fun invoke_empty k   = invoke "empty" (K o #empty) k ();
   130 val invoke_copy      = invoke "copy" #copy;
   131 val invoke_extend    = invoke "extend" #extend;
   132 fun invoke_merge pp  = invoke "merge" (fn kind => #merge kind pp);
   133 
   134 fun declare_theory_data name empty copy extend merge =
   135   let
   136     val k = serial ();
   137     val kind = {name = name, empty = empty, copy = copy, extend = extend, merge = merge};
   138     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   139       warning ("Duplicate declaration of theory data " ^ quote name));
   140     val _ = change kinds (Inttab.update (k, kind));
   141   in k end;
   142 
   143 val copy_data = Inttab.map' invoke_copy;
   144 val extend_data = Inttab.map' invoke_extend;
   145 fun merge_data pp = Inttab.join (SOME oo invoke_merge pp) o pairself extend_data;
   146 
   147 end;
   148 
   149 
   150 
   151 (** datatype theory **)
   152 
   153 datatype theory =
   154   Theory of
   155    (*identity*)
   156    {self: theory ref option,            (*dynamic self reference -- follows theory changes*)
   157     id: serial * string,                (*identifier of this theory*)
   158     ids: string Inttab.table,           (*identifiers of ancestors*)
   159     iids: string Inttab.table} *        (*identifiers of intermediate checkpoints*)
   160    (*data*)
   161    {theory: Object.T Inttab.table,      (*theory data record*)
   162     proof: unit Inttab.table} *         (*proof data kinds*)
   163    (*ancestry*)
   164    {parents: theory list,               (*immediate predecessors*)
   165     ancestors: theory list} *           (*all predecessors*)
   166    (*history*)
   167    {name: string,                       (*prospective name of finished theory*)
   168     version: int,                       (*checkpoint counter*)
   169     intermediates: theory list};        (*intermediate checkpoints*)
   170 
   171 exception THEORY of string * theory list;
   172 
   173 fun rep_theory (Theory args) = args;
   174 
   175 val identity_of = #1 o rep_theory;
   176 val data_of     = #2 o rep_theory;
   177 val ancestry_of = #3 o rep_theory;
   178 val history_of  = #4 o rep_theory;
   179 
   180 fun make_identity self id ids iids = {self = self, id = id, ids = ids, iids = iids};
   181 fun make_data theory proof = {theory = theory, proof = proof};
   182 fun make_ancestry parents ancestors = {parents = parents, ancestors = ancestors};
   183 fun make_history name vers ints = {name = name, version = vers, intermediates = ints};
   184 
   185 fun map_theory f {theory, proof} = make_data (f theory) proof;
   186 fun map_proof f {theory, proof} = make_data theory (f proof);
   187 
   188 val the_self = the o #self o identity_of;
   189 val parents_of = #parents o ancestry_of;
   190 val ancestors_of = #ancestors o ancestry_of;
   191 val theory_name = #name o history_of;
   192 
   193 
   194 (* staleness *)
   195 
   196 fun eq_id ((i: int, _), (j, _)) = (i = j);
   197 
   198 fun is_stale
   199     (Theory ({self = SOME (ref (Theory ({id = id', ...}, _, _, _))), id, ...}, _, _, _)) =
   200       not (eq_id (id, id'))
   201   | is_stale (Theory ({self = NONE, ...}, _, _, _)) = true;
   202 
   203 fun vitalize (thy as Theory ({self = SOME r, ...}, _, _, _)) = (r := thy; thy)
   204   | vitalize (thy as Theory ({self = NONE, id, ids, iids}, data, ancestry, history)) =
   205       let
   206         val r = ref thy;
   207         val thy' = Theory (make_identity (SOME r) id ids iids, data, ancestry, history);
   208       in r := thy'; thy' end;
   209 
   210 
   211 (* names *)
   212 
   213 val ProtoPureN = "ProtoPure";
   214 val PureN = "Pure";
   215 val CPureN = "CPure";
   216 
   217 val draftN = "#";
   218 fun draft_id (_, name) = (name = draftN);
   219 val is_draft = draft_id o #id o identity_of;
   220 
   221 fun exists_name name (Theory ({id, ids, iids, ...}, _, _, _)) =
   222   name = #2 id orelse
   223   Inttab.exists (equal name o #2) ids orelse
   224   Inttab.exists (equal name o #2) iids;
   225 
   226 fun names_of (Theory ({id, ids, iids, ...}, _, _, _)) =
   227   rev (#2 id :: Inttab.fold (cons o #2) iids (Inttab.fold (cons o #2) ids []));
   228 
   229 fun pretty_thy thy =
   230   Pretty.str_list "{" "}" (names_of thy @ (if is_stale thy then ["!"] else []));
   231 
   232 val string_of_thy = Pretty.string_of o pretty_thy;
   233 val pprint_thy = Pretty.pprint o pretty_thy;
   234 
   235 fun pretty_abbrev_thy thy =
   236   let
   237     val names = names_of thy;
   238     val n = length names;
   239     val abbrev = if n > 5 then "..." :: List.drop (names, n - 5) else names;
   240   in Pretty.str_list "{" "}" abbrev end;
   241 
   242 val str_of_thy = Pretty.str_of o pretty_abbrev_thy;
   243 
   244 
   245 (* consistency *)    (*exception TERM*)
   246 
   247 fun check_thy thy =
   248   if is_stale thy then
   249     raise TERM ("Stale theory encountered:\n" ^ string_of_thy thy, [])
   250   else thy;
   251 
   252 fun check_ins id ids =
   253   if draft_id id orelse Inttab.defined ids (#1 id) then ids
   254   else if Inttab.exists (equal (#2 id) o #2) ids then
   255     raise TERM ("Different versions of theory component " ^ quote (#2 id), [])
   256   else Inttab.update id ids;
   257 
   258 fun check_insert intermediate id (ids, iids) =
   259   let val ids' = check_ins id ids and iids' = check_ins id iids
   260   in if intermediate then (ids, iids') else (ids', iids) end;
   261 
   262 fun check_merge
   263     (Theory ({id = id1, ids = ids1, iids = iids1, ...}, _, _, history1))
   264     (Theory ({id = id2, ids = ids2, iids = iids2, ...}, _, _, history2)) =
   265   (Inttab.fold check_ins ids2 ids1, Inttab.fold check_ins iids2 iids1)
   266   |> check_insert (#version history1 > 0) id1
   267   |> check_insert (#version history2 > 0) id2;
   268 
   269 
   270 (* equality and inclusion *)
   271 
   272 val eq_thy = eq_id o pairself (#id o identity_of o check_thy);
   273 
   274 fun proper_subthy
   275     (Theory ({id = (i, _), ...}, _, _, _), Theory ({ids, iids, ...}, _, _, _)) =
   276   Inttab.defined ids i orelse Inttab.defined iids i;
   277 
   278 fun subthy thys = eq_thy thys orelse proper_subthy thys;
   279 
   280 fun joinable (thy1, thy2) = subthy (thy1, thy2) orelse subthy (thy2, thy1);
   281 
   282 
   283 (* theory references *)
   284 
   285 (*theory_ref provides a safe way to store dynamic references to a
   286   theory in external data structures -- a plain theory value would
   287   become stale as the self reference moves on*)
   288 
   289 datatype theory_ref = TheoryRef of theory ref;
   290 
   291 val self_ref = TheoryRef o the_self o check_thy;
   292 fun deref (TheoryRef (ref thy)) = thy;
   293 
   294 
   295 (* trivial merge *)    (*exception TERM*)
   296 
   297 fun merge (thy1, thy2) =
   298   if eq_thy (thy1, thy2) then thy1
   299   else if proper_subthy (thy2, thy1) then thy1
   300   else if proper_subthy (thy1, thy2) then thy2
   301   else (check_merge thy1 thy2;
   302     raise TERM (cat_lines ["Attempt to perform non-trivial merge of theories:",
   303       str_of_thy thy1, str_of_thy thy2], []));
   304 
   305 fun merge_refs (ref1, ref2) =
   306   if ref1 = ref2 then ref1
   307   else self_ref (merge (deref ref1, deref ref2));
   308 
   309 
   310 
   311 (** build theories **)
   312 
   313 (* primitives *)
   314 
   315 fun create_thy name self id ids iids data ancestry history =
   316   let
   317     val {version, name = _, intermediates = _} = history;
   318     val intermediate = version > 0;
   319     val (ids', iids') = check_insert intermediate id (ids, iids);
   320     val id' = (serial (), name);
   321     val _ = check_insert intermediate id' (ids', iids');
   322     val identity' = make_identity self id' ids' iids';
   323   in vitalize (Theory (identity', data, ancestry, history)) end;
   324 
   325 fun change_thy name f (thy as Theory ({self, id, ids, iids}, data, ancestry, history)) =
   326   let
   327     val _ = check_thy thy;
   328     val (self', data', ancestry') =
   329       if is_draft thy then (self, data, ancestry)    (*destructive change!*)
   330       else if #version history > 0
   331       then (NONE, map_theory copy_data data, ancestry)
   332       else (NONE, map_theory extend_data data, make_ancestry [thy] (thy :: #ancestors ancestry));
   333     val data'' = f data';
   334   in create_thy name self' id ids iids data'' ancestry' history end;
   335 
   336 fun name_thy name = change_thy name I;
   337 val modify_thy = change_thy draftN;
   338 val extend_thy = modify_thy I;
   339 
   340 fun copy_thy (thy as Theory ({id, ids, iids, ...}, data, ancestry, history)) =
   341   (check_thy thy;
   342     create_thy draftN NONE id ids iids (map_theory copy_data data) ancestry history);
   343 
   344 val pre_pure_thy = create_thy draftN NONE (serial (), draftN) Inttab.empty Inttab.empty
   345   (make_data Inttab.empty Inttab.empty) (make_ancestry [] []) (make_history ProtoPureN 0 []);
   346 
   347 
   348 (* named theory nodes *)
   349 
   350 fun merge_thys pp (thy1, thy2) =
   351   if exists_name CPureN thy1 <> exists_name CPureN thy2 then
   352     error "Cannot merge Pure and CPure developments"
   353   else
   354     let
   355       val (ids, iids) = check_merge thy1 thy2;
   356       val data1 = data_of thy1 and data2 = data_of thy2;
   357       val data = make_data
   358         (merge_data (pp thy1) (#theory data1, #theory data2))
   359         (Inttab.merge (K true) (#proof data1, #proof data2));
   360       val ancestry = make_ancestry [] [];
   361       val history = make_history "" 0 [];
   362     in create_thy draftN NONE (serial (), draftN) ids iids data ancestry history end;
   363 
   364 fun maximal_thys thys =
   365   thys |> filter (fn thy => not (exists (fn thy' => proper_subthy (thy, thy')) thys));
   366 
   367 fun begin_thy pp name imports =
   368   if name = draftN then error ("Illegal theory name: " ^ quote draftN)
   369   else
   370     let
   371       val parents =
   372         maximal_thys (gen_distinct eq_thy (map check_thy imports));
   373       val ancestors = gen_distinct eq_thy (parents @ List.concat (map ancestors_of parents));
   374       val Theory ({id, ids, iids, ...}, data, _, _) =
   375         (case parents of
   376           [] => error "No parent theories"
   377         | [thy] => extend_thy thy
   378         | thy :: thys => Library.foldl (merge_thys pp) (thy, thys));
   379       val ancestry = make_ancestry parents ancestors;
   380       val history = make_history name 0 [];
   381     in create_thy draftN NONE id ids iids data ancestry history end;
   382 
   383 
   384 (* undoable checkpoints *)
   385 
   386 fun checkpoint_thy thy =
   387   if not (is_draft thy) then thy
   388   else
   389     let
   390       val {name, version, intermediates} = history_of thy;
   391       val thy' as Theory (identity', data', ancestry', _) =
   392         name_thy (name ^ ":" ^ string_of_int version) thy;
   393       val history' = make_history name (version + 1) (thy' :: intermediates);
   394     in vitalize (Theory (identity', data', ancestry', history')) end;
   395 
   396 fun finish_thy thy =
   397   let
   398     val {name, version, intermediates} = history_of thy;
   399     val rs = map (the_self o check_thy) intermediates;
   400     val thy' as Theory ({self, id, ids, ...}, data', ancestry', _) = name_thy name thy;
   401     val identity' = make_identity self id ids Inttab.empty;
   402     val history' = make_history name 0 [];
   403     val thy'' = vitalize (Theory (identity', data', ancestry', history'));
   404     val _ = List.app (fn r => r := thy'') rs;
   405   in thy'' end;
   406 
   407 
   408 (* theory data *)
   409 
   410 fun dest_data name_of tab =
   411   map name_of (Inttab.keys tab)
   412   |> map (rpair ()) |> Symtab.make_multi |> Symtab.dest
   413   |> map (apsnd length)
   414   |> map (fn (name, 1) => name | (name, n) => name ^ enclose "[" "]" (string_of_int n));
   415 
   416 val theory_data_of = dest_data invoke_name o #theory o data_of;
   417 
   418 structure TheoryData =
   419 struct
   420 
   421 val declare = declare_theory_data;
   422 
   423 fun get k dest thy =
   424   (case Inttab.lookup (#theory (data_of thy)) k of
   425     SOME x => (dest x handle Match =>
   426       error ("Failed to access theory data " ^ quote (invoke_name k)))
   427   | NONE => error ("Uninitialized theory data " ^ quote (invoke_name k)));
   428 
   429 fun put k mk x = modify_thy (map_theory (Inttab.update (k, mk x)));
   430 fun init k = put k I (invoke_empty k);
   431 
   432 end;
   433 
   434 
   435 
   436 (*** ML theory context ***)
   437 
   438 local
   439   val current_theory = ref (NONE: theory option);
   440 in
   441   fun get_context () = ! current_theory;
   442   fun set_context opt_thy = current_theory := opt_thy;
   443   fun setmp opt_thy f x = Library.setmp current_theory opt_thy f x;
   444 end;
   445 
   446 fun the_context () =
   447   (case get_context () of
   448     SOME thy => thy
   449   | _ => error "Unknown theory context");
   450 
   451 fun context thy = set_context (SOME thy);
   452 fun reset_context () = set_context NONE;
   453 
   454 fun pass opt_thy f x =
   455   setmp opt_thy (fn x => let val y = f x in (y, get_context ()) end) x;
   456 
   457 fun pass_theory thy f x =
   458   (case pass (SOME thy) f x of
   459     (y, SOME thy') => (y, thy')
   460   | (_, NONE) => error "Lost theory context in ML");
   461 
   462 fun save f x = setmp (get_context ()) f x;
   463 
   464 
   465 (* map context *)
   466 
   467 nonfix >>;
   468 fun >> f = set_context (SOME (f (the_context ())));
   469 
   470 
   471 (* use ML text *)
   472 
   473 val ml_output = (writeln, error_msg);
   474 
   475 fun use_output verbose txt = use_text ml_output verbose (Symbol.escape txt);
   476 
   477 fun use_mltext txt verbose opt_thy = setmp opt_thy (fn () => use_output verbose txt) ();
   478 fun use_mltext_theory txt verbose thy = #2 (pass_theory thy (use_output verbose) txt);
   479 
   480 fun use_context txt = use_mltext_theory ("Context.>> (" ^ txt ^ ");") false;
   481 
   482 fun use_let bind body txt =
   483   use_context ("let " ^ bind ^ " = " ^ txt ^ " in\n" ^ body ^ " end");
   484 
   485 
   486 (* delayed theory setup *)
   487 
   488 local
   489   val setup_fns = ref ([]: (theory -> theory) list);
   490 in
   491   fun add_setup fns = setup_fns := ! setup_fns @ fns;
   492   fun setup () = let val fns = ! setup_fns in setup_fns := []; fns end;
   493 end;
   494 
   495 
   496 
   497 (*** proof context ***)
   498 
   499 (* datatype proof *)
   500 
   501 datatype proof = Proof of theory_ref * Object.T Inttab.table;
   502 
   503 exception PROOF of string * proof;
   504 
   505 fun theory_of_proof (Proof (thy_ref, _)) = deref thy_ref;
   506 fun data_of_proof (Proof (_, data)) = data;
   507 fun map_prf f (Proof (thy_ref, data)) = Proof (thy_ref, f data);
   508 
   509 fun transfer_proof thy' (prf as Proof (thy_ref, data)) =
   510   if not (subthy (deref thy_ref, thy')) then
   511     raise PROOF ("transfer proof context: no a super theory", prf)
   512   else Proof (self_ref thy', data);
   513 
   514 
   515 (* proof data kinds *)
   516 
   517 local
   518 
   519 type kind =
   520  {name: string,
   521   init: theory -> Object.T};
   522 
   523 val kinds = ref (Inttab.empty: kind Inttab.table);
   524 
   525 fun invoke meth_name meth_fn k =
   526   (case Inttab.lookup (! kinds) k of
   527     SOME kind => meth_fn kind |> transform_failure (fn exn =>
   528       EXCEPTION (exn, "Proof data method " ^ #name kind ^ "." ^ meth_name ^ " failed"))
   529   | NONE => sys_error ("Invalid proof data identifier " ^ string_of_int k));
   530 
   531 fun invoke_name k = invoke "name" (K o #name) k ();
   532 val invoke_init   = invoke "init" #init;
   533 
   534 in
   535 
   536 val proof_data_of = dest_data invoke_name o #proof o data_of;
   537 
   538 fun init_proof thy =
   539   Proof (self_ref thy, Inttab.map' (fn k => fn _ => invoke_init k thy) (#proof (data_of thy)));
   540 
   541 structure ProofData =
   542 struct
   543 
   544 fun declare name init =
   545   let
   546     val k = serial ();
   547     val kind = {name = name, init = init};
   548     val _ = conditional (Inttab.exists (equal name o #name o #2) (! kinds)) (fn () =>
   549       warning ("Duplicate declaration of proof data " ^ quote name));
   550     val _ = change kinds (Inttab.update (k, kind));
   551   in k end;
   552 
   553 fun init k = modify_thy (map_proof (Inttab.update (k, ())));
   554 
   555 fun get k dest prf =
   556   (case Inttab.lookup (data_of_proof prf) k of
   557     SOME x => (dest x handle Match =>
   558       error ("Failed to access proof data " ^ quote (invoke_name k)))
   559   | NONE => error ("Uninitialized proof data " ^ quote (invoke_name k)));
   560 
   561 fun put k mk x = map_prf (Inttab.update (k, mk x));
   562 
   563 end;
   564 
   565 end;
   566 
   567 
   568 (*** generic context ***)
   569 
   570 datatype context = Theory of theory | Proof of proof;
   571 
   572 fun theory_of (Theory thy) = thy
   573   | theory_of (Proof prf) = theory_of_proof prf;
   574 
   575 fun proof_of (Theory thy) = init_proof thy
   576   | proof_of (Proof prf) = prf;
   577 
   578 end;
   579 
   580 structure BasicContext: BASIC_CONTEXT = Context;
   581 open BasicContext;
   582 
   583 
   584 
   585 (*** type-safe interfaces for data declarations ***)
   586 
   587 (** theory data **)
   588 
   589 signature THEORY_DATA_ARGS =
   590 sig
   591   val name: string
   592   type T
   593   val empty: T
   594   val copy: T -> T
   595   val extend: T -> T
   596   val merge: Pretty.pp -> T * T -> T
   597   val print: theory -> T -> unit
   598 end;
   599 
   600 signature THEORY_DATA =
   601 sig
   602   type T
   603   val init: theory -> theory
   604   val print: theory -> unit
   605   val get: theory -> T
   606   val get_sg: theory -> T    (*obsolete*)
   607   val put: T -> theory -> theory
   608   val map: (T -> T) -> theory -> theory
   609 end;
   610 
   611 functor TheoryDataFun(Data: THEORY_DATA_ARGS): THEORY_DATA =
   612 struct
   613 
   614 structure TheoryData = Context.TheoryData;
   615 
   616 type T = Data.T;
   617 exception Data of T;
   618 
   619 val kind = TheoryData.declare Data.name
   620   (Data Data.empty)
   621   (fn Data x => Data (Data.copy x))
   622   (fn Data x => Data (Data.extend x))
   623   (fn pp => fn (Data x1, Data x2) => Data (Data.merge pp (x1, x2)));
   624 
   625 val init = TheoryData.init kind;
   626 val get = TheoryData.get kind (fn Data x => x);
   627 val get_sg = get;
   628 fun print thy = Data.print thy (get thy);
   629 val put = TheoryData.put kind Data;
   630 fun map f thy = put (f (get thy)) thy;
   631 
   632 end;
   633 
   634 
   635 
   636 (** proof data **)
   637 
   638 signature PROOF_DATA_ARGS =
   639 sig
   640   val name: string
   641   type T
   642   val init: theory -> T
   643   val print: Context.proof -> T -> unit
   644 end;
   645 
   646 signature PROOF_DATA =
   647 sig
   648   type T
   649   val init: theory -> theory
   650   val print: Context.proof -> unit
   651   val get: Context.proof -> T
   652   val put: T -> Context.proof -> Context.proof
   653   val map: (T -> T) -> Context.proof -> Context.proof
   654 end;
   655 
   656 functor ProofDataFun(Data: PROOF_DATA_ARGS): PROOF_DATA =
   657 struct
   658 
   659 structure ProofData = Context.ProofData;
   660 
   661 type T = Data.T;
   662 exception Data of T;
   663 
   664 val kind = ProofData.declare Data.name (Data o Data.init);
   665 
   666 val init = ProofData.init kind;
   667 val get = ProofData.get kind (fn Data x => x);
   668 fun print prf = Data.print prf (get prf);
   669 val put = ProofData.put kind Data;
   670 fun map f prf = put (f (get prf)) prf;
   671 
   672 end;
   673 
   674 (*hide private interface*)
   675 structure Context: CONTEXT = Context;