src/HOL/SetInterval.thy
author bulwahn
Sat Jul 19 19:27:13 2008 +0200 (2008-07-19)
changeset 27656 d4f6e64ee7cc
parent 26105 ae06618225ec
child 28068 f6b2d1995171
permissions -rw-r--r--
added verification framework for the HeapMonad and quicksort as example for this framework
     1 (*  Title:      HOL/SetInterval.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Clemens Ballarin
     4                 Additions by Jeremy Avigad in March 2004
     5     Copyright   2000  TU Muenchen
     6 
     7 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     8 *)
     9 
    10 header {* Set intervals *}
    11 
    12 theory SetInterval
    13 imports Int
    14 begin
    15 
    16 context ord
    17 begin
    18 definition
    19   lessThan    :: "'a => 'a set"	("(1{..<_})") where
    20   "{..<u} == {x. x < u}"
    21 
    22 definition
    23   atMost      :: "'a => 'a set"	("(1{.._})") where
    24   "{..u} == {x. x \<le> u}"
    25 
    26 definition
    27   greaterThan :: "'a => 'a set"	("(1{_<..})") where
    28   "{l<..} == {x. l<x}"
    29 
    30 definition
    31   atLeast     :: "'a => 'a set"	("(1{_..})") where
    32   "{l..} == {x. l\<le>x}"
    33 
    34 definition
    35   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    36   "{l<..<u} == {l<..} Int {..<u}"
    37 
    38 definition
    39   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    40   "{l..<u} == {l..} Int {..<u}"
    41 
    42 definition
    43   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    44   "{l<..u} == {l<..} Int {..u}"
    45 
    46 definition
    47   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    48   "{l..u} == {l..} Int {..u}"
    49 
    50 end
    51 (*
    52 constdefs
    53   lessThan    :: "('a::ord) => 'a set"	("(1{..<_})")
    54   "{..<u} == {x. x<u}"
    55 
    56   atMost      :: "('a::ord) => 'a set"	("(1{.._})")
    57   "{..u} == {x. x<=u}"
    58 
    59   greaterThan :: "('a::ord) => 'a set"	("(1{_<..})")
    60   "{l<..} == {x. l<x}"
    61 
    62   atLeast     :: "('a::ord) => 'a set"	("(1{_..})")
    63   "{l..} == {x. l<=x}"
    64 
    65   greaterThanLessThan :: "['a::ord, 'a] => 'a set"  ("(1{_<..<_})")
    66   "{l<..<u} == {l<..} Int {..<u}"
    67 
    68   atLeastLessThan :: "['a::ord, 'a] => 'a set"      ("(1{_..<_})")
    69   "{l..<u} == {l..} Int {..<u}"
    70 
    71   greaterThanAtMost :: "['a::ord, 'a] => 'a set"    ("(1{_<.._})")
    72   "{l<..u} == {l<..} Int {..u}"
    73 
    74   atLeastAtMost :: "['a::ord, 'a] => 'a set"        ("(1{_.._})")
    75   "{l..u} == {l..} Int {..u}"
    76 *)
    77 
    78 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    79 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    80 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    81 
    82 syntax
    83   "@UNION_le"   :: "nat => nat => 'b set => 'b set"       ("(3UN _<=_./ _)" 10)
    84   "@UNION_less" :: "nat => nat => 'b set => 'b set"       ("(3UN _<_./ _)" 10)
    85   "@INTER_le"   :: "nat => nat => 'b set => 'b set"       ("(3INT _<=_./ _)" 10)
    86   "@INTER_less" :: "nat => nat => 'b set => 'b set"       ("(3INT _<_./ _)" 10)
    87 
    88 syntax (input)
    89   "@UNION_le"   :: "nat => nat => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" 10)
    90   "@UNION_less" :: "nat => nat => 'b set => 'b set"       ("(3\<Union> _<_./ _)" 10)
    91   "@INTER_le"   :: "nat => nat => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" 10)
    92   "@INTER_less" :: "nat => nat => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" 10)
    93 
    94 syntax (xsymbols)
    95   "@UNION_le"   :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Union>(00\<^bsub>_ \<le> _\<^esub>)/ _)" 10)
    96   "@UNION_less" :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Union>(00\<^bsub>_ < _\<^esub>)/ _)" 10)
    97   "@INTER_le"   :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Inter>(00\<^bsub>_ \<le> _\<^esub>)/ _)" 10)
    98   "@INTER_less" :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Inter>(00\<^bsub>_ < _\<^esub>)/ _)" 10)
    99 
   100 translations
   101   "UN i<=n. A"  == "UN i:{..n}. A"
   102   "UN i<n. A"   == "UN i:{..<n}. A"
   103   "INT i<=n. A" == "INT i:{..n}. A"
   104   "INT i<n. A"  == "INT i:{..<n}. A"
   105 
   106 
   107 subsection {* Various equivalences *}
   108 
   109 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
   110 by (simp add: lessThan_def)
   111 
   112 lemma Compl_lessThan [simp]:
   113     "!!k:: 'a::linorder. -lessThan k = atLeast k"
   114 apply (auto simp add: lessThan_def atLeast_def)
   115 done
   116 
   117 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
   118 by auto
   119 
   120 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
   121 by (simp add: greaterThan_def)
   122 
   123 lemma Compl_greaterThan [simp]:
   124     "!!k:: 'a::linorder. -greaterThan k = atMost k"
   125   by (auto simp add: greaterThan_def atMost_def)
   126 
   127 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   128 apply (subst Compl_greaterThan [symmetric])
   129 apply (rule double_complement)
   130 done
   131 
   132 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   133 by (simp add: atLeast_def)
   134 
   135 lemma Compl_atLeast [simp]:
   136     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   137   by (auto simp add: lessThan_def atLeast_def)
   138 
   139 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   140 by (simp add: atMost_def)
   141 
   142 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   143 by (blast intro: order_antisym)
   144 
   145 
   146 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   147 
   148 lemma atLeast_subset_iff [iff]:
   149      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   150 by (blast intro: order_trans)
   151 
   152 lemma atLeast_eq_iff [iff]:
   153      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   154 by (blast intro: order_antisym order_trans)
   155 
   156 lemma greaterThan_subset_iff [iff]:
   157      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   158 apply (auto simp add: greaterThan_def)
   159  apply (subst linorder_not_less [symmetric], blast)
   160 done
   161 
   162 lemma greaterThan_eq_iff [iff]:
   163      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   164 apply (rule iffI)
   165  apply (erule equalityE)
   166  apply (simp_all add: greaterThan_subset_iff)
   167 done
   168 
   169 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   170 by (blast intro: order_trans)
   171 
   172 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   173 by (blast intro: order_antisym order_trans)
   174 
   175 lemma lessThan_subset_iff [iff]:
   176      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   177 apply (auto simp add: lessThan_def)
   178  apply (subst linorder_not_less [symmetric], blast)
   179 done
   180 
   181 lemma lessThan_eq_iff [iff]:
   182      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   183 apply (rule iffI)
   184  apply (erule equalityE)
   185  apply (simp_all add: lessThan_subset_iff)
   186 done
   187 
   188 
   189 subsection {*Two-sided intervals*}
   190 
   191 context ord
   192 begin
   193 
   194 lemma greaterThanLessThan_iff [simp,noatp]:
   195   "(i : {l<..<u}) = (l < i & i < u)"
   196 by (simp add: greaterThanLessThan_def)
   197 
   198 lemma atLeastLessThan_iff [simp,noatp]:
   199   "(i : {l..<u}) = (l <= i & i < u)"
   200 by (simp add: atLeastLessThan_def)
   201 
   202 lemma greaterThanAtMost_iff [simp,noatp]:
   203   "(i : {l<..u}) = (l < i & i <= u)"
   204 by (simp add: greaterThanAtMost_def)
   205 
   206 lemma atLeastAtMost_iff [simp,noatp]:
   207   "(i : {l..u}) = (l <= i & i <= u)"
   208 by (simp add: atLeastAtMost_def)
   209 
   210 text {* The above four lemmas could be declared as iffs.
   211   If we do so, a call to blast in Hyperreal/Star.ML, lemma @{text STAR_Int}
   212   seems to take forever (more than one hour). *}
   213 end
   214 
   215 subsubsection{* Emptyness and singletons *}
   216 
   217 context order
   218 begin
   219 
   220 lemma atLeastAtMost_empty [simp]: "n < m ==> {m..n} = {}";
   221 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   222 
   223 lemma atLeastLessThan_empty[simp]: "n \<le> m ==> {m..<n} = {}"
   224 by (auto simp add: atLeastLessThan_def)
   225 
   226 lemma greaterThanAtMost_empty[simp]:"l \<le> k ==> {k<..l} = {}"
   227 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   228 
   229 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..l} = {}"
   230 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   231 
   232 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   233 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   234 
   235 end
   236 
   237 subsection {* Intervals of natural numbers *}
   238 
   239 subsubsection {* The Constant @{term lessThan} *}
   240 
   241 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   242 by (simp add: lessThan_def)
   243 
   244 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   245 by (simp add: lessThan_def less_Suc_eq, blast)
   246 
   247 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   248 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   249 
   250 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   251 by blast
   252 
   253 subsubsection {* The Constant @{term greaterThan} *}
   254 
   255 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   256 apply (simp add: greaterThan_def)
   257 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   258 done
   259 
   260 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   261 apply (simp add: greaterThan_def)
   262 apply (auto elim: linorder_neqE)
   263 done
   264 
   265 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   266 by blast
   267 
   268 subsubsection {* The Constant @{term atLeast} *}
   269 
   270 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   271 by (unfold atLeast_def UNIV_def, simp)
   272 
   273 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   274 apply (simp add: atLeast_def)
   275 apply (simp add: Suc_le_eq)
   276 apply (simp add: order_le_less, blast)
   277 done
   278 
   279 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   280   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   281 
   282 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   283 by blast
   284 
   285 subsubsection {* The Constant @{term atMost} *}
   286 
   287 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   288 by (simp add: atMost_def)
   289 
   290 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   291 apply (simp add: atMost_def)
   292 apply (simp add: less_Suc_eq order_le_less, blast)
   293 done
   294 
   295 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   296 by blast
   297 
   298 subsubsection {* The Constant @{term atLeastLessThan} *}
   299 
   300 text{*The orientation of the following rule is tricky. The lhs is
   301 defined in terms of the rhs.  Hence the chosen orientation makes sense
   302 in this theory --- the reverse orientation complicates proofs (eg
   303 nontermination). But outside, when the definition of the lhs is rarely
   304 used, the opposite orientation seems preferable because it reduces a
   305 specific concept to a more general one. *}
   306 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   307 by(simp add:lessThan_def atLeastLessThan_def)
   308 
   309 declare atLeast0LessThan[symmetric, code unfold]
   310 
   311 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   312 by (simp add: atLeastLessThan_def)
   313 
   314 subsubsection {* Intervals of nats with @{term Suc} *}
   315 
   316 text{*Not a simprule because the RHS is too messy.*}
   317 lemma atLeastLessThanSuc:
   318     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   319 by (auto simp add: atLeastLessThan_def)
   320 
   321 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   322 by (auto simp add: atLeastLessThan_def)
   323 (*
   324 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   325 by (induct k, simp_all add: atLeastLessThanSuc)
   326 
   327 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   328 by (auto simp add: atLeastLessThan_def)
   329 *)
   330 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   331   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   332 
   333 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   334   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   335     greaterThanAtMost_def)
   336 
   337 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   338   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   339     greaterThanLessThan_def)
   340 
   341 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   342 by (auto simp add: atLeastAtMost_def)
   343 
   344 subsubsection {* Image *}
   345 
   346 lemma image_add_atLeastAtMost:
   347   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   348 proof
   349   show "?A \<subseteq> ?B" by auto
   350 next
   351   show "?B \<subseteq> ?A"
   352   proof
   353     fix n assume a: "n : ?B"
   354     hence "n - k : {i..j}" by auto
   355     moreover have "n = (n - k) + k" using a by auto
   356     ultimately show "n : ?A" by blast
   357   qed
   358 qed
   359 
   360 lemma image_add_atLeastLessThan:
   361   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   362 proof
   363   show "?A \<subseteq> ?B" by auto
   364 next
   365   show "?B \<subseteq> ?A"
   366   proof
   367     fix n assume a: "n : ?B"
   368     hence "n - k : {i..<j}" by auto
   369     moreover have "n = (n - k) + k" using a by auto
   370     ultimately show "n : ?A" by blast
   371   qed
   372 qed
   373 
   374 corollary image_Suc_atLeastAtMost[simp]:
   375   "Suc ` {i..j} = {Suc i..Suc j}"
   376 using image_add_atLeastAtMost[where k=1] by simp
   377 
   378 corollary image_Suc_atLeastLessThan[simp]:
   379   "Suc ` {i..<j} = {Suc i..<Suc j}"
   380 using image_add_atLeastLessThan[where k=1] by simp
   381 
   382 lemma image_add_int_atLeastLessThan:
   383     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   384   apply (auto simp add: image_def)
   385   apply (rule_tac x = "x - l" in bexI)
   386   apply auto
   387   done
   388 
   389 
   390 subsubsection {* Finiteness *}
   391 
   392 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   393   by (induct k) (simp_all add: lessThan_Suc)
   394 
   395 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   396   by (induct k) (simp_all add: atMost_Suc)
   397 
   398 lemma finite_greaterThanLessThan [iff]:
   399   fixes l :: nat shows "finite {l<..<u}"
   400 by (simp add: greaterThanLessThan_def)
   401 
   402 lemma finite_atLeastLessThan [iff]:
   403   fixes l :: nat shows "finite {l..<u}"
   404 by (simp add: atLeastLessThan_def)
   405 
   406 lemma finite_greaterThanAtMost [iff]:
   407   fixes l :: nat shows "finite {l<..u}"
   408 by (simp add: greaterThanAtMost_def)
   409 
   410 lemma finite_atLeastAtMost [iff]:
   411   fixes l :: nat shows "finite {l..u}"
   412 by (simp add: atLeastAtMost_def)
   413 
   414 lemma bounded_nat_set_is_finite:
   415   "(ALL i:N. i < (n::nat)) ==> finite N"
   416   -- {* A bounded set of natural numbers is finite. *}
   417   apply (rule finite_subset)
   418    apply (rule_tac [2] finite_lessThan, auto)
   419   done
   420 
   421 text{* Any subset of an interval of natural numbers the size of the
   422 subset is exactly that interval. *}
   423 
   424 lemma subset_card_intvl_is_intvl:
   425   "A <= {k..<k+card A} \<Longrightarrow> A = {k..<k+card A}" (is "PROP ?P")
   426 proof cases
   427   assume "finite A"
   428   thus "PROP ?P"
   429   proof(induct A rule:finite_linorder_induct)
   430     case empty thus ?case by auto
   431   next
   432     case (insert A b)
   433     moreover hence "b ~: A" by auto
   434     moreover have "A <= {k..<k+card A}" and "b = k+card A"
   435       using `b ~: A` insert by fastsimp+
   436     ultimately show ?case by auto
   437   qed
   438 next
   439   assume "~finite A" thus "PROP ?P" by simp
   440 qed
   441 
   442 
   443 subsubsection {* Cardinality *}
   444 
   445 lemma card_lessThan [simp]: "card {..<u} = u"
   446   by (induct u, simp_all add: lessThan_Suc)
   447 
   448 lemma card_atMost [simp]: "card {..u} = Suc u"
   449   by (simp add: lessThan_Suc_atMost [THEN sym])
   450 
   451 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
   452   apply (subgoal_tac "card {l..<u} = card {..<u-l}")
   453   apply (erule ssubst, rule card_lessThan)
   454   apply (subgoal_tac "(%x. x + l) ` {..<u-l} = {l..<u}")
   455   apply (erule subst)
   456   apply (rule card_image)
   457   apply (simp add: inj_on_def)
   458   apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
   459   apply (rule_tac x = "x - l" in exI)
   460   apply arith
   461   done
   462 
   463 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
   464   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
   465 
   466 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
   467   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
   468 
   469 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
   470   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
   471 
   472 
   473 lemma ex_bij_betw_nat_finite:
   474   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
   475 apply(drule finite_imp_nat_seg_image_inj_on)
   476 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
   477 done
   478 
   479 lemma ex_bij_betw_finite_nat:
   480   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
   481 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
   482 
   483 
   484 subsection {* Intervals of integers *}
   485 
   486 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
   487   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
   488 
   489 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
   490   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
   491 
   492 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
   493     "{l+1..<u} = {l<..<u::int}"
   494   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
   495 
   496 subsubsection {* Finiteness *}
   497 
   498 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
   499     {(0::int)..<u} = int ` {..<nat u}"
   500   apply (unfold image_def lessThan_def)
   501   apply auto
   502   apply (rule_tac x = "nat x" in exI)
   503   apply (auto simp add: zless_nat_conj zless_nat_eq_int_zless [THEN sym])
   504   done
   505 
   506 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
   507   apply (case_tac "0 \<le> u")
   508   apply (subst image_atLeastZeroLessThan_int, assumption)
   509   apply (rule finite_imageI)
   510   apply auto
   511   done
   512 
   513 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
   514   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   515   apply (erule subst)
   516   apply (rule finite_imageI)
   517   apply (rule finite_atLeastZeroLessThan_int)
   518   apply (rule image_add_int_atLeastLessThan)
   519   done
   520 
   521 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
   522   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
   523 
   524 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
   525   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   526 
   527 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
   528   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   529 
   530 
   531 subsubsection {* Cardinality *}
   532 
   533 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
   534   apply (case_tac "0 \<le> u")
   535   apply (subst image_atLeastZeroLessThan_int, assumption)
   536   apply (subst card_image)
   537   apply (auto simp add: inj_on_def)
   538   done
   539 
   540 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
   541   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
   542   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
   543   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   544   apply (erule subst)
   545   apply (rule card_image)
   546   apply (simp add: inj_on_def)
   547   apply (rule image_add_int_atLeastLessThan)
   548   done
   549 
   550 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
   551   apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
   552   apply (auto simp add: compare_rls)
   553   done
   554 
   555 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
   556   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   557 
   558 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
   559   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   560 
   561 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
   562 proof -
   563   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
   564   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
   565 qed
   566 
   567 lemma card_less:
   568 assumes zero_in_M: "0 \<in> M"
   569 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
   570 proof -
   571   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
   572   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
   573 qed
   574 
   575 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
   576 apply (rule card_bij_eq [of "Suc" _ _ "\<lambda>x. x - 1"])
   577 apply simp
   578 apply fastsimp
   579 apply auto
   580 apply (rule inj_on_diff_nat)
   581 apply auto
   582 apply (case_tac x)
   583 apply auto
   584 apply (case_tac xa)
   585 apply auto
   586 apply (case_tac xa)
   587 apply auto
   588 apply (auto simp add: finite_M_bounded_by_nat)
   589 done
   590 
   591 lemma card_less_Suc:
   592   assumes zero_in_M: "0 \<in> M"
   593     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
   594 proof -
   595   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
   596   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
   597     by (auto simp only: insert_Diff)
   598   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
   599   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
   600     apply (subst card_insert)
   601     apply simp_all
   602     apply (subst b)
   603     apply (subst card_less_Suc2[symmetric])
   604     apply simp_all
   605     done
   606   with c show ?thesis by simp
   607 qed
   608 
   609 
   610 subsection {*Lemmas useful with the summation operator setsum*}
   611 
   612 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
   613 
   614 subsubsection {* Disjoint Unions *}
   615 
   616 text {* Singletons and open intervals *}
   617 
   618 lemma ivl_disj_un_singleton:
   619   "{l::'a::linorder} Un {l<..} = {l..}"
   620   "{..<u} Un {u::'a::linorder} = {..u}"
   621   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
   622   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
   623   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
   624   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
   625 by auto
   626 
   627 text {* One- and two-sided intervals *}
   628 
   629 lemma ivl_disj_un_one:
   630   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
   631   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
   632   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
   633   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
   634   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
   635   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
   636   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
   637   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
   638 by auto
   639 
   640 text {* Two- and two-sided intervals *}
   641 
   642 lemma ivl_disj_un_two:
   643   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
   644   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
   645   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
   646   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
   647   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
   648   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
   649   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
   650   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
   651 by auto
   652 
   653 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
   654 
   655 subsubsection {* Disjoint Intersections *}
   656 
   657 text {* Singletons and open intervals *}
   658 
   659 lemma ivl_disj_int_singleton:
   660   "{l::'a::order} Int {l<..} = {}"
   661   "{..<u} Int {u} = {}"
   662   "{l} Int {l<..<u} = {}"
   663   "{l<..<u} Int {u} = {}"
   664   "{l} Int {l<..u} = {}"
   665   "{l..<u} Int {u} = {}"
   666   by simp+
   667 
   668 text {* One- and two-sided intervals *}
   669 
   670 lemma ivl_disj_int_one:
   671   "{..l::'a::order} Int {l<..<u} = {}"
   672   "{..<l} Int {l..<u} = {}"
   673   "{..l} Int {l<..u} = {}"
   674   "{..<l} Int {l..u} = {}"
   675   "{l<..u} Int {u<..} = {}"
   676   "{l<..<u} Int {u..} = {}"
   677   "{l..u} Int {u<..} = {}"
   678   "{l..<u} Int {u..} = {}"
   679   by auto
   680 
   681 text {* Two- and two-sided intervals *}
   682 
   683 lemma ivl_disj_int_two:
   684   "{l::'a::order<..<m} Int {m..<u} = {}"
   685   "{l<..m} Int {m<..<u} = {}"
   686   "{l..<m} Int {m..<u} = {}"
   687   "{l..m} Int {m<..<u} = {}"
   688   "{l<..<m} Int {m..u} = {}"
   689   "{l<..m} Int {m<..u} = {}"
   690   "{l..<m} Int {m..u} = {}"
   691   "{l..m} Int {m<..u} = {}"
   692   by auto
   693 
   694 lemmas ivl_disj_int = ivl_disj_int_singleton ivl_disj_int_one ivl_disj_int_two
   695 
   696 subsubsection {* Some Differences *}
   697 
   698 lemma ivl_diff[simp]:
   699  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
   700 by(auto)
   701 
   702 
   703 subsubsection {* Some Subset Conditions *}
   704 
   705 lemma ivl_subset [simp,noatp]:
   706  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
   707 apply(auto simp:linorder_not_le)
   708 apply(rule ccontr)
   709 apply(insert linorder_le_less_linear[of i n])
   710 apply(clarsimp simp:linorder_not_le)
   711 apply(fastsimp)
   712 done
   713 
   714 
   715 subsection {* Summation indexed over intervals *}
   716 
   717 syntax
   718   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
   719   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
   720   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
   721   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
   722 syntax (xsymbols)
   723   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   724   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   725   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   726   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   727 syntax (HTML output)
   728   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   729   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   730   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   731   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   732 syntax (latex_sum output)
   733   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   734  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
   735   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   736  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
   737   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   738  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
   739   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   740  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
   741 
   742 translations
   743   "\<Sum>x=a..b. t" == "setsum (%x. t) {a..b}"
   744   "\<Sum>x=a..<b. t" == "setsum (%x. t) {a..<b}"
   745   "\<Sum>i\<le>n. t" == "setsum (\<lambda>i. t) {..n}"
   746   "\<Sum>i<n. t" == "setsum (\<lambda>i. t) {..<n}"
   747 
   748 text{* The above introduces some pretty alternative syntaxes for
   749 summation over intervals:
   750 \begin{center}
   751 \begin{tabular}{lll}
   752 Old & New & \LaTeX\\
   753 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
   754 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
   755 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
   756 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
   757 \end{tabular}
   758 \end{center}
   759 The left column shows the term before introduction of the new syntax,
   760 the middle column shows the new (default) syntax, and the right column
   761 shows a special syntax. The latter is only meaningful for latex output
   762 and has to be activated explicitly by setting the print mode to
   763 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
   764 antiquotations). It is not the default \LaTeX\ output because it only
   765 works well with italic-style formulae, not tt-style.
   766 
   767 Note that for uniformity on @{typ nat} it is better to use
   768 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
   769 not provide all lemmas available for @{term"{m..<n}"} also in the
   770 special form for @{term"{..<n}"}. *}
   771 
   772 text{* This congruence rule should be used for sums over intervals as
   773 the standard theorem @{text[source]setsum_cong} does not work well
   774 with the simplifier who adds the unsimplified premise @{term"x:B"} to
   775 the context. *}
   776 
   777 lemma setsum_ivl_cong:
   778  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
   779  setsum f {a..<b} = setsum g {c..<d}"
   780 by(rule setsum_cong, simp_all)
   781 
   782 (* FIXME why are the following simp rules but the corresponding eqns
   783 on intervals are not? *)
   784 
   785 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
   786 by (simp add:atMost_Suc add_ac)
   787 
   788 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
   789 by (simp add:lessThan_Suc add_ac)
   790 
   791 lemma setsum_cl_ivl_Suc[simp]:
   792   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
   793 by (auto simp:add_ac atLeastAtMostSuc_conv)
   794 
   795 lemma setsum_op_ivl_Suc[simp]:
   796   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
   797 by (auto simp:add_ac atLeastLessThanSuc)
   798 (*
   799 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
   800     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
   801 by (auto simp:add_ac atLeastAtMostSuc_conv)
   802 *)
   803 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   804   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
   805 by (simp add:setsum_Un_disjoint[symmetric] ivl_disj_int ivl_disj_un)
   806 
   807 lemma setsum_diff_nat_ivl:
   808 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   809 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   810   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
   811 using setsum_add_nat_ivl [of m n p f,symmetric]
   812 apply (simp add: add_ac)
   813 done
   814 
   815 subsection{* Shifting bounds *}
   816 
   817 lemma setsum_shift_bounds_nat_ivl:
   818   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
   819 by (induct "n", auto simp:atLeastLessThanSuc)
   820 
   821 lemma setsum_shift_bounds_cl_nat_ivl:
   822   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
   823 apply (insert setsum_reindex[OF inj_on_add_nat, where h=f and B = "{m..n}"])
   824 apply (simp add:image_add_atLeastAtMost o_def)
   825 done
   826 
   827 corollary setsum_shift_bounds_cl_Suc_ivl:
   828   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
   829 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k=1,simplified])
   830 
   831 corollary setsum_shift_bounds_Suc_ivl:
   832   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
   833 by (simp add:setsum_shift_bounds_nat_ivl[where k=1,simplified])
   834 
   835 lemma setsum_head:
   836   fixes n :: nat
   837   assumes mn: "m <= n" 
   838   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
   839 proof -
   840   from mn
   841   have "{m..n} = {m} \<union> {m<..n}"
   842     by (auto intro: ivl_disj_un_singleton)
   843   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
   844     by (simp add: atLeast0LessThan)
   845   also have "\<dots> = ?rhs" by simp
   846   finally show ?thesis .
   847 qed
   848 
   849 lemma setsum_head_upt:
   850   fixes m::nat
   851   assumes m: "0 < m"
   852   shows "(\<Sum>x<m. P x) = P 0 + (\<Sum>x\<in>{1..<m}. P x)"
   853 proof -
   854   have "(\<Sum>x<m. P x) = (\<Sum>x\<in>{0..<m}. P x)" 
   855     by (simp add: atLeast0LessThan)
   856   also 
   857   from m 
   858   have "\<dots> = (\<Sum>x\<in>{0..m - 1}. P x)"
   859     by (cases m) (auto simp add: atLeastLessThanSuc_atLeastAtMost)
   860   also
   861   have "\<dots> = P 0 + (\<Sum>x\<in>{0<..m - 1}. P x)"
   862     by (simp add: setsum_head)
   863   also 
   864   from m 
   865   have "{0<..m - 1} = {1..<m}" 
   866     by (cases m) (auto simp add: atLeastLessThanSuc_atLeastAtMost)
   867   finally show ?thesis .
   868 qed
   869 
   870 subsection {* The formula for geometric sums *}
   871 
   872 lemma geometric_sum:
   873   "x ~= 1 ==> (\<Sum>i=0..<n. x ^ i) =
   874   (x ^ n - 1) / (x - 1::'a::{field, recpower})"
   875 by (induct "n") (simp_all add:field_simps power_Suc)
   876 
   877 subsection {* The formula for arithmetic sums *}
   878 
   879 lemma gauss_sum:
   880   "((1::'a::comm_semiring_1) + 1)*(\<Sum>i\<in>{1..n}. of_nat i) =
   881    of_nat n*((of_nat n)+1)"
   882 proof (induct n)
   883   case 0
   884   show ?case by simp
   885 next
   886   case (Suc n)
   887   then show ?case by (simp add: ring_simps)
   888 qed
   889 
   890 theorem arith_series_general:
   891   "((1::'a::comm_semiring_1) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
   892   of_nat n * (a + (a + of_nat(n - 1)*d))"
   893 proof cases
   894   assume ngt1: "n > 1"
   895   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
   896   have
   897     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
   898      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
   899     by (rule setsum_addf)
   900   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
   901   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
   902     by (simp add: setsum_right_distrib setsum_head_upt mult_ac)
   903   also have "(1+1)*\<dots> = (1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..<n}. ?I i)"
   904     by (simp add: left_distrib right_distrib)
   905   also from ngt1 have "{1..<n} = {1..n - 1}"
   906     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)    
   907   also from ngt1 
   908   have "(1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..n - 1}. ?I i) = ((1+1)*?n*a + d*?I (n - 1)*?I n)"
   909     by (simp only: mult_ac gauss_sum [of "n - 1"])
   910        (simp add:  mult_ac trans [OF add_commute of_nat_Suc [symmetric]])
   911   finally show ?thesis by (simp add: mult_ac add_ac right_distrib)
   912 next
   913   assume "\<not>(n > 1)"
   914   hence "n = 1 \<or> n = 0" by auto
   915   thus ?thesis by (auto simp: mult_ac right_distrib)
   916 qed
   917 
   918 lemma arith_series_nat:
   919   "Suc (Suc 0) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
   920 proof -
   921   have
   922     "((1::nat) + 1) * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
   923     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
   924     by (rule arith_series_general)
   925   thus ?thesis by (auto simp add: of_nat_id)
   926 qed
   927 
   928 lemma arith_series_int:
   929   "(2::int) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
   930   of_nat n * (a + (a + of_nat(n - 1)*d))"
   931 proof -
   932   have
   933     "((1::int) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
   934     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
   935     by (rule arith_series_general)
   936   thus ?thesis by simp
   937 qed
   938 
   939 lemma sum_diff_distrib:
   940   fixes P::"nat\<Rightarrow>nat"
   941   shows
   942   "\<forall>x. Q x \<le> P x  \<Longrightarrow>
   943   (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x)"
   944 proof (induct n)
   945   case 0 show ?case by simp
   946 next
   947   case (Suc n)
   948 
   949   let ?lhs = "(\<Sum>x<n. P x) - (\<Sum>x<n. Q x)"
   950   let ?rhs = "\<Sum>x<n. P x - Q x"
   951 
   952   from Suc have "?lhs = ?rhs" by simp
   953   moreover
   954   from Suc have "?lhs + P n - Q n = ?rhs + (P n - Q n)" by simp
   955   moreover
   956   from Suc have
   957     "(\<Sum>x<n. P x) + P n - ((\<Sum>x<n. Q x) + Q n) = ?rhs + (P n - Q n)"
   958     by (subst diff_diff_left[symmetric],
   959         subst diff_add_assoc2)
   960        (auto simp: diff_add_assoc2 intro: setsum_mono)
   961   ultimately
   962   show ?case by simp
   963 qed
   964 
   965 end