src/HOL/Complete_Lattice.thy
author haftmann
Thu Jul 14 00:16:41 2011 +0200 (2011-07-14)
changeset 43817 d53350bc65a4
parent 43814 58791b75cf1f
child 43818 fcc5d3ffb6f5
permissions -rw-r--r--
tuned notation
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices, with special focus on sets *}
     4 
     5 theory Complete_Lattice
     6 imports Set
     7 begin
     8 
     9 lemma ball_conj_distrib:
    10   "(\<forall>x\<in>A. P x \<and> Q x) \<longleftrightarrow> ((\<forall>x\<in>A. P x) \<and> (\<forall>x\<in>A. Q x))"
    11   by blast
    12 
    13 lemma bex_disj_distrib:
    14   "(\<exists>x\<in>A. P x \<or> Q x) \<longleftrightarrow> ((\<exists>x\<in>A. P x) \<or> (\<exists>x\<in>A. Q x))"
    15   by blast
    16 
    17 notation
    18   less_eq (infix "\<sqsubseteq>" 50) and
    19   less (infix "\<sqsubset>" 50) and
    20   inf (infixl "\<sqinter>" 70) and
    21   sup (infixl "\<squnion>" 65) and
    22   top ("\<top>") and
    23   bot ("\<bottom>")
    24 
    25 
    26 subsection {* Syntactic infimum and supremum operations *}
    27 
    28 class Inf =
    29   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    30 
    31 class Sup =
    32   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    33 
    34 subsection {* Abstract complete lattices *}
    35 
    36 class complete_lattice = bounded_lattice + Inf + Sup +
    37   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    38      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    39   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    40      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    41 begin
    42 
    43 lemma dual_complete_lattice:
    44   "class.complete_lattice Sup Inf (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) \<top> \<bottom>"
    45   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    46     (unfold_locales, (fact bot_least top_greatest
    47         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    48 
    49 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
    50   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    51 
    52 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
    53   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    54 
    55 lemma Inf_empty [simp]:
    56   "\<Sqinter>{} = \<top>"
    57   by (auto intro: antisym Inf_greatest)
    58 
    59 lemma Sup_empty [simp]:
    60   "\<Squnion>{} = \<bottom>"
    61   by (auto intro: antisym Sup_least)
    62 
    63 lemma Inf_UNIV [simp]:
    64   "\<Sqinter>UNIV = \<bottom>"
    65   by (simp add: Sup_Inf Sup_empty [symmetric])
    66 
    67 lemma Sup_UNIV [simp]:
    68   "\<Squnion>UNIV = \<top>"
    69   by (simp add: Inf_Sup Inf_empty [symmetric])
    70 
    71 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
    72   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
    73 
    74 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
    75   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
    76 
    77 lemma Inf_singleton [simp]:
    78   "\<Sqinter>{a} = a"
    79   by (auto intro: antisym Inf_lower Inf_greatest)
    80 
    81 lemma Sup_singleton [simp]:
    82   "\<Squnion>{a} = a"
    83   by (auto intro: antisym Sup_upper Sup_least)
    84 
    85 lemma Inf_binary:
    86   "\<Sqinter>{a, b} = a \<sqinter> b"
    87   by (simp add: Inf_empty Inf_insert)
    88 
    89 lemma Sup_binary:
    90   "\<Squnion>{a, b} = a \<squnion> b"
    91   by (simp add: Sup_empty Sup_insert)
    92 
    93 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
    94   by (auto intro: Inf_greatest dest: Inf_lower)
    95 
    96 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
    97   by (auto intro: Sup_least dest: Sup_upper)
    98 
    99 lemma Inf_mono:
   100   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
   101   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   102 proof (rule Inf_greatest)
   103   fix b assume "b \<in> B"
   104   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
   105   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
   106   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
   107 qed
   108 
   109 lemma Sup_mono:
   110   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   111   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   112 proof (rule Sup_least)
   113   fix a assume "a \<in> A"
   114   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   115   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   116   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   117 qed
   118 
   119 lemma top_le:
   120   "\<top> \<sqsubseteq> x \<Longrightarrow> x = \<top>"
   121   by (rule antisym) auto
   122 
   123 lemma le_bot:
   124   "x \<sqsubseteq> \<bottom> \<Longrightarrow> x = \<bottom>"
   125   by (rule antisym) auto
   126 
   127 lemma not_less_bot[simp]: "\<not> (x \<sqsubset> \<bottom>)"
   128   using bot_least[of x] by (auto simp: le_less)
   129 
   130 lemma not_top_less[simp]: "\<not> (\<top> \<sqsubset> x)"
   131   using top_greatest[of x] by (auto simp: le_less)
   132 
   133 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   134   using Sup_upper[of u A] by auto
   135 
   136 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   137   using Inf_lower[of u A] by auto
   138 
   139 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   140   "INFI A f = \<Sqinter> (f ` A)"
   141 
   142 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   143   "SUPR A f = \<Squnion> (f ` A)"
   144 
   145 end
   146 
   147 syntax
   148   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
   149   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
   150   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
   151   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
   152 
   153 syntax (xsymbols)
   154   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   155   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   156   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   157   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   158 
   159 translations
   160   "INF x y. B"   == "INF x. INF y. B"
   161   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
   162   "INF x. B"     == "INF x:CONST UNIV. B"
   163   "INF x:A. B"   == "CONST INFI A (%x. B)"
   164   "SUP x y. B"   == "SUP x. SUP y. B"
   165   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
   166   "SUP x. B"     == "SUP x:CONST UNIV. B"
   167   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   168 
   169 print_translation {*
   170   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   171     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   172 *} -- {* to avoid eta-contraction of body *}
   173 
   174 context complete_lattice
   175 begin
   176 
   177 lemma SUP_cong: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> SUPR A f = SUPR A g"
   178   by (simp add: SUPR_def cong: image_cong)
   179 
   180 lemma INF_cong: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> INFI A f = INFI A g"
   181   by (simp add: INFI_def cong: image_cong)
   182 
   183 lemma le_SUPI: "i \<in> A \<Longrightarrow> M i \<sqsubseteq> (\<Squnion>i\<in>A. M i)"
   184   by (auto simp add: SUPR_def intro: Sup_upper)
   185 
   186 lemma le_SUPI2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> M i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. M i)"
   187   using le_SUPI[of i A M] by auto
   188 
   189 lemma SUP_leI: "(\<And>i. i \<in> A \<Longrightarrow> M i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. M i) \<sqsubseteq> u"
   190   by (auto simp add: SUPR_def intro: Sup_least)
   191 
   192 lemma INF_leI: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. M i) \<sqsubseteq> M i"
   193   by (auto simp add: INFI_def intro: Inf_lower)
   194 
   195 lemma INF_leI2: "i \<in> A \<Longrightarrow> M i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. M i) \<sqsubseteq> u"
   196   using INF_leI[of i A M] by auto
   197 
   198 lemma le_INFI: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> M i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. M i)"
   199   by (auto simp add: INFI_def intro: Inf_greatest)
   200 
   201 lemma SUP_le_iff: "(\<Squnion>i\<in>A. M i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i \<in> A. M i \<sqsubseteq> u)"
   202   unfolding SUPR_def by (auto simp add: Sup_le_iff)
   203 
   204 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. M i) \<longleftrightarrow> (\<forall>i \<in> A. u \<sqsubseteq> M i)"
   205   unfolding INFI_def by (auto simp add: le_Inf_iff)
   206 
   207 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. M) = M"
   208   by (auto intro: antisym INF_leI le_INFI)
   209 
   210 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. M) = M"
   211   by (auto intro: antisym SUP_leI le_SUPI)
   212 
   213 lemma INF_mono:
   214   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   215   by (force intro!: Inf_mono simp: INFI_def)
   216 
   217 lemma SUP_mono:
   218   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   219   by (force intro!: Sup_mono simp: SUPR_def)
   220 
   221 lemma INF_subset:  "A \<subseteq> B \<Longrightarrow> INFI B f \<sqsubseteq> INFI A f"
   222   by (intro INF_mono) auto
   223 
   224 lemma SUP_subset:  "A \<subseteq> B \<Longrightarrow> SUPR A f \<sqsubseteq> SUPR B f"
   225   by (intro SUP_mono) auto
   226 
   227 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   228   by (iprover intro: INF_leI le_INFI order_trans antisym)
   229 
   230 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   231   by (iprover intro: SUP_leI le_SUPI order_trans antisym)
   232 
   233 end
   234 
   235 lemma Inf_less_iff:
   236   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   237   shows "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   238   unfolding not_le [symmetric] le_Inf_iff by auto
   239 
   240 lemma less_Sup_iff:
   241   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   242   shows "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   243   unfolding not_le [symmetric] Sup_le_iff by auto
   244 
   245 lemma INF_less_iff:
   246   fixes a :: "'a::{complete_lattice,linorder}"
   247   shows "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   248   unfolding INFI_def Inf_less_iff by auto
   249 
   250 lemma less_SUP_iff:
   251   fixes a :: "'a::{complete_lattice,linorder}"
   252   shows "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   253   unfolding SUPR_def less_Sup_iff by auto
   254 
   255 subsection {* @{typ bool} and @{typ "_ \<Rightarrow> _"} as complete lattice *}
   256 
   257 instantiation bool :: complete_lattice
   258 begin
   259 
   260 definition
   261   "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   262 
   263 definition
   264   "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   265 
   266 instance proof
   267 qed (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
   268 
   269 end
   270 
   271 lemma INFI_bool_eq [simp]:
   272   "INFI = Ball"
   273 proof (rule ext)+
   274   fix A :: "'a set"
   275   fix P :: "'a \<Rightarrow> bool"
   276   show "(\<Sqinter>x\<in>A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P x)"
   277     by (auto simp add: Ball_def INFI_def Inf_bool_def)
   278 qed
   279 
   280 lemma SUPR_bool_eq [simp]:
   281   "SUPR = Bex"
   282 proof (rule ext)+
   283   fix A :: "'a set"
   284   fix P :: "'a \<Rightarrow> bool"
   285   show "(\<Squnion>x\<in>A. P x) \<longleftrightarrow> (\<exists>x\<in>A. P x)"
   286     by (auto simp add: Bex_def SUPR_def Sup_bool_def)
   287 qed
   288 
   289 instantiation "fun" :: (type, complete_lattice) complete_lattice
   290 begin
   291 
   292 definition
   293   "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   294 
   295 lemma Inf_apply:
   296   "(\<Sqinter>A) x = \<Sqinter>{y. \<exists>f\<in>A. y = f x}"
   297   by (simp add: Inf_fun_def)
   298 
   299 definition
   300   "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   301 
   302 lemma Sup_apply:
   303   "(\<Squnion>A) x = \<Squnion>{y. \<exists>f\<in>A. y = f x}"
   304   by (simp add: Sup_fun_def)
   305 
   306 instance proof
   307 qed (auto simp add: le_fun_def Inf_apply Sup_apply
   308   intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   309 
   310 end
   311 
   312 lemma INFI_apply:
   313   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   314   by (auto intro: arg_cong [of _ _ Inf] simp add: INFI_def Inf_apply)
   315 
   316 lemma SUPR_apply:
   317   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   318   by (auto intro: arg_cong [of _ _ Sup] simp add: SUPR_def Sup_apply)
   319 
   320 
   321 subsection {* Inter *}
   322 
   323 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   324   "Inter S \<equiv> \<Sqinter>S"
   325   
   326 notation (xsymbols)
   327   Inter  ("\<Inter>_" [90] 90)
   328 
   329 lemma Inter_eq:
   330   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   331 proof (rule set_eqI)
   332   fix x
   333   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   334     by auto
   335   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   336     by (simp add: Inf_fun_def Inf_bool_def) (simp add: mem_def)
   337 qed
   338 
   339 lemma Inter_iff [simp,no_atp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   340   by (unfold Inter_eq) blast
   341 
   342 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   343   by (simp add: Inter_eq)
   344 
   345 text {*
   346   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   347   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   348   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   349 *}
   350 
   351 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   352   by auto
   353 
   354 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   355   -- {* ``Classical'' elimination rule -- does not require proving
   356     @{prop "X \<in> C"}. *}
   357   by (unfold Inter_eq) blast
   358 
   359 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   360   by (fact Inf_lower)
   361 
   362 lemma (in complete_lattice) Inf_less_eq:
   363   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   364     and "A \<noteq> {}"
   365   shows "\<Sqinter>A \<sqsubseteq> u"
   366 proof -
   367   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   368   moreover with assms have "v \<sqsubseteq> u" by blast
   369   ultimately show ?thesis by (rule Inf_lower2)
   370 qed
   371 
   372 lemma Inter_subset:
   373   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   374   by (fact Inf_less_eq)
   375 
   376 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   377   by (fact Inf_greatest)
   378 
   379 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
   380   by (fact Inf_binary [symmetric])
   381 
   382 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
   383   by (fact Inf_empty)
   384 
   385 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
   386   by (fact Inf_UNIV)
   387 
   388 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   389   by (fact Inf_insert)
   390 
   391 lemma (in complete_lattice) Inf_inter_less: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   392   by (auto intro: Inf_greatest Inf_lower)
   393 
   394 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   395   by (fact Inf_inter_less)
   396 
   397 lemma (in complete_lattice) Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   398   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   399 
   400 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   401   by (fact Inf_union_distrib)
   402 
   403 lemma (in complete_lattice) Inf_top_conv [no_atp]:
   404   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   405   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   406 proof -
   407   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   408   proof
   409     assume "\<forall>x\<in>A. x = \<top>"
   410     then have "A = {} \<or> A = {\<top>}" by auto
   411     then show "\<Sqinter>A = \<top>" by auto
   412   next
   413     assume "\<Sqinter>A = \<top>"
   414     show "\<forall>x\<in>A. x = \<top>"
   415     proof (rule ccontr)
   416       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   417       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   418       then obtain B where "A = insert x B" by blast
   419       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by (simp add: Inf_insert)
   420     qed
   421   qed
   422   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   423 qed
   424 
   425 lemma Inter_UNIV_conv [simp,no_atp]:
   426   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   427   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   428   by (fact Inf_top_conv)+
   429 
   430 lemma (in complete_lattice) Inf_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   431   by (auto intro: Inf_greatest Inf_lower)
   432 
   433 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   434   by (fact Inf_anti_mono)
   435 
   436 
   437 subsection {* Intersections of families *}
   438 
   439 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   440   "INTER \<equiv> INFI"
   441 
   442 syntax
   443   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   444   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   445 
   446 syntax (xsymbols)
   447   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   448   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   449 
   450 syntax (latex output)
   451   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   452   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   453 
   454 translations
   455   "INT x y. B"  == "INT x. INT y. B"
   456   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   457   "INT x. B"    == "INT x:CONST UNIV. B"
   458   "INT x:A. B"  == "CONST INTER A (%x. B)"
   459 
   460 print_translation {*
   461   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   462 *} -- {* to avoid eta-contraction of body *}
   463 
   464 lemma INTER_eq_Inter_image:
   465   "(\<Inter>x\<in>A. B x) = \<Inter>(B`A)"
   466   by (fact INFI_def)
   467   
   468 lemma Inter_def:
   469   "\<Inter>S = (\<Inter>x\<in>S. x)"
   470   by (simp add: INTER_eq_Inter_image image_def)
   471 
   472 lemma INTER_def:
   473   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   474   by (auto simp add: INTER_eq_Inter_image Inter_eq)
   475 
   476 lemma Inter_image_eq [simp]:
   477   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   478   by (rule sym) (fact INFI_def)
   479 
   480 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
   481   by (unfold INTER_def) blast
   482 
   483 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
   484   by (unfold INTER_def) blast
   485 
   486 lemma INT_D [elim, Pure.elim]: "b : (\<Inter>x\<in>A. B x) \<Longrightarrow> a:A \<Longrightarrow> b: B a"
   487   by auto
   488 
   489 lemma INT_E [elim]: "b : (\<Inter>x\<in>A. B x) \<Longrightarrow> (b: B a \<Longrightarrow> R) \<Longrightarrow> (a~:A \<Longrightarrow> R) \<Longrightarrow> R"
   490   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   491   by (unfold INTER_def) blast
   492 
   493 lemma INT_cong [cong]:
   494     "A = B \<Longrightarrow> (\<And>x. x:B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Inter>x\<in>A. C x) = (\<Inter>x\<in>B. D x)"
   495   by (simp add: INTER_def)
   496 
   497 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   498   by blast
   499 
   500 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   501   by blast
   502 
   503 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   504   by (fact INF_leI)
   505 
   506 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
   507   by (fact le_INFI)
   508 
   509 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
   510   by blast
   511 
   512 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   513   by blast
   514 
   515 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
   516   by (fact le_INF_iff)
   517 
   518 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   519   by blast
   520 
   521 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   522   by blast
   523 
   524 lemma INT_insert_distrib:
   525     "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   526   by blast
   527 
   528 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   529   by auto
   530 
   531 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
   532   -- {* Look: it has an \emph{existential} quantifier *}
   533   by blast
   534 
   535 lemma INTER_UNIV_conv[simp]:
   536  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   537  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   538 by blast+
   539 
   540 lemma INT_bool_eq: "(\<Inter>b. A b) = (A True \<inter> A False)"
   541   by (auto intro: bool_induct)
   542 
   543 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   544   by blast
   545 
   546 lemma INT_anti_mono:
   547   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
   548     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   549   -- {* The last inclusion is POSITIVE! *}
   550   by (blast dest: subsetD)
   551 
   552 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
   553   by blast
   554 
   555 
   556 subsection {* Union *}
   557 
   558 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   559   "Union S \<equiv> \<Squnion>S"
   560 
   561 notation (xsymbols)
   562   Union  ("\<Union>_" [90] 90)
   563 
   564 lemma Union_eq:
   565   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   566 proof (rule set_eqI)
   567   fix x
   568   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   569     by auto
   570   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   571     by (simp add: Sup_fun_def Sup_bool_def) (simp add: mem_def)
   572 qed
   573 
   574 lemma Union_iff [simp, no_atp]:
   575   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   576   by (unfold Union_eq) blast
   577 
   578 lemma UnionI [intro]:
   579   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   580   -- {* The order of the premises presupposes that @{term C} is rigid;
   581     @{term A} may be flexible. *}
   582   by auto
   583 
   584 lemma UnionE [elim!]:
   585   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
   586   by auto
   587 
   588 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
   589   by (iprover intro: subsetI UnionI)
   590 
   591 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
   592   by (iprover intro: subsetI elim: UnionE dest: subsetD)
   593 
   594 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
   595   by blast
   596 
   597 lemma Union_empty [simp]: "\<Union>{} = {}"
   598   by blast
   599 
   600 lemma Union_UNIV [simp]: "\<Union>UNIV = UNIV"
   601   by blast
   602 
   603 lemma Union_insert [simp]: "\<Union>insert a B = a \<union> \<Union>B"
   604   by blast
   605 
   606 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
   607   by blast
   608 
   609 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   610   by blast
   611 
   612 lemma Union_empty_conv [simp,no_atp]: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   613   by blast
   614 
   615 lemma empty_Union_conv [simp,no_atp]: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   616   by blast
   617 
   618 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
   619   by blast
   620 
   621 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   622   by blast
   623 
   624 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   625   by blast
   626 
   627 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
   628   by blast
   629 
   630 
   631 subsection {* Unions of families *}
   632 
   633 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   634   "UNION \<equiv> SUPR"
   635 
   636 syntax
   637   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   638   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
   639 
   640 syntax (xsymbols)
   641   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   642   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
   643 
   644 syntax (latex output)
   645   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   646   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   647 
   648 translations
   649   "UN x y. B"   == "UN x. UN y. B"
   650   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   651   "UN x. B"     == "UN x:CONST UNIV. B"
   652   "UN x:A. B"   == "CONST UNION A (%x. B)"
   653 
   654 text {*
   655   Note the difference between ordinary xsymbol syntax of indexed
   656   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   657   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   658   former does not make the index expression a subscript of the
   659   union/intersection symbol because this leads to problems with nested
   660   subscripts in Proof General.
   661 *}
   662 
   663 print_translation {*
   664   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
   665 *} -- {* to avoid eta-contraction of body *}
   666 
   667 lemma UNION_eq_Union_image:
   668   "(\<Union>x\<in>A. B x) = \<Union>(B ` A)"
   669   by (fact SUPR_def)
   670 
   671 lemma Union_def:
   672   "\<Union>S = (\<Union>x\<in>S. x)"
   673   by (simp add: UNION_eq_Union_image image_def)
   674 
   675 lemma UNION_def [no_atp]:
   676   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
   677   by (auto simp add: UNION_eq_Union_image Union_eq)
   678   
   679 lemma Union_image_eq [simp]:
   680   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
   681   by (rule sym) (fact UNION_eq_Union_image)
   682   
   683 lemma UN_iff [simp]: "(b: (\<Union>x\<in>A. B x)) = (\<exists>x\<in>A. b: B x)"
   684   by (unfold UNION_def) blast
   685 
   686 lemma UN_I [intro]: "a:A \<Longrightarrow> b: B a \<Longrightarrow> b: (\<Union>x\<in>A. B x)"
   687   -- {* The order of the premises presupposes that @{term A} is rigid;
   688     @{term b} may be flexible. *}
   689   by auto
   690 
   691 lemma UN_E [elim!]: "b : (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x:A \<Longrightarrow> b: B x \<Longrightarrow> R) \<Longrightarrow> R"
   692   by (unfold UNION_def) blast
   693 
   694 lemma UN_cong [cong]:
   695     "A = B \<Longrightarrow> (\<And>x. x:B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
   696   by (simp add: UNION_def)
   697 
   698 lemma strong_UN_cong:
   699     "A = B \<Longrightarrow> (\<And>x. x:B =simp=> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
   700   by (simp add: UNION_def simp_implies_def)
   701 
   702 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
   703   by blast
   704 
   705 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
   706   by (fact le_SUPI)
   707 
   708 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
   709   by (iprover intro: subsetI elim: UN_E dest: subsetD)
   710 
   711 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
   712   by blast
   713 
   714 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
   715   by blast
   716 
   717 lemma UN_empty [simp,no_atp]: "(\<Union>x\<in>{}. B x) = {}"
   718   by blast
   719 
   720 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
   721   by blast
   722 
   723 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
   724   by blast
   725 
   726 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
   727   by auto
   728 
   729 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
   730   by blast
   731 
   732 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
   733   by blast
   734 
   735 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
   736   by blast
   737 
   738 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
   739   by (fact SUP_le_iff)
   740 
   741 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
   742   by blast
   743 
   744 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
   745   by auto
   746 
   747 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
   748   by blast
   749 
   750 lemma UNION_empty_conv[simp]:
   751   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
   752   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
   753 by blast+
   754 
   755 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
   756   by blast
   757 
   758 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
   759   by blast
   760 
   761 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
   762   by blast
   763 
   764 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
   765   by (auto simp add: split_if_mem2)
   766 
   767 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
   768   by (auto intro: bool_contrapos)
   769 
   770 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
   771   by blast
   772 
   773 lemma UN_mono:
   774   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
   775     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
   776   by (blast dest: subsetD)
   777 
   778 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
   779   by blast
   780 
   781 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
   782   by blast
   783 
   784 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
   785   -- {* NOT suitable for rewriting *}
   786   by blast
   787 
   788 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
   789   by blast
   790 
   791 
   792 subsection {* Distributive laws *}
   793 
   794 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
   795   by blast
   796 
   797 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
   798   by blast
   799 
   800 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)"
   801   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
   802   -- {* Union of a family of unions *}
   803   by blast
   804 
   805 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
   806   -- {* Equivalent version *}
   807   by blast
   808 
   809 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
   810   by blast
   811 
   812 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)"
   813   by blast
   814 
   815 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
   816   -- {* Equivalent version *}
   817   by blast
   818 
   819 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
   820   -- {* Halmos, Naive Set Theory, page 35. *}
   821   by blast
   822 
   823 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
   824   by blast
   825 
   826 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
   827   by blast
   828 
   829 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
   830   by blast
   831 
   832 
   833 subsection {* Complement *}
   834 
   835 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
   836   by blast
   837 
   838 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
   839   by blast
   840 
   841 
   842 subsection {* Miniscoping and maxiscoping *}
   843 
   844 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
   845            and Intersections. *}
   846 
   847 lemma UN_simps [simp]:
   848   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
   849   "\<And>A B C. (\<Union>x\<in>C. A x Un B)   = ((if C={} then {} else (\<Union>x\<in>C. A x) Un B))"
   850   "\<And>A B C. (\<Union>x\<in>C. A Un B x)   = ((if C={} then {} else A Un (\<Union>x\<in>C. B x)))"
   851   "\<And>A B C. (\<Union>x\<in>C. A x Int B)  = ((\<Union>x\<in>C. A x) Int B)"
   852   "\<And>A B C. (\<Union>x\<in>C. A Int B x)  = (A Int (\<Union>x\<in>C. B x))"
   853   "\<And>A B C. (\<Union>x\<in>C. A x - B)    = ((\<Union>x\<in>C. A x) - B)"
   854   "\<And>A B C. (\<Union>x\<in>C. A - B x)    = (A - (\<Inter>x\<in>C. B x))"
   855   "\<And>A B. (UN x: \<Union>A. B x) = (UN y:A. UN x:y. B x)"
   856   "\<And>A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
   857   "\<And>A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
   858   by auto
   859 
   860 lemma INT_simps [simp]:
   861   "\<And>A B C. (\<Inter>x\<in>C. A x Int B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) Int B)"
   862   "\<And>A B C. (\<Inter>x\<in>C. A Int B x) = (if C={} then UNIV else A Int (\<Inter>x\<in>C. B x))"
   863   "\<And>A B C. (\<Inter>x\<in>C. A x - B)   = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
   864   "\<And>A B C. (\<Inter>x\<in>C. A - B x)   = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
   865   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
   866   "\<And>A B C. (\<Inter>x\<in>C. A x Un B)  = ((\<Inter>x\<in>C. A x) Un B)"
   867   "\<And>A B C. (\<Inter>x\<in>C. A Un B x)  = (A Un (\<Inter>x\<in>C. B x))"
   868   "\<And>A B. (INT x: \<Union>A. B x) = (\<Inter>y\<in>A. INT x:y. B x)"
   869   "\<And>A B C. (INT z: UNION A B. C z) = (\<Inter>x\<in>A. INT z: B(x). C z)"
   870   "\<And>A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
   871   by auto
   872 
   873 lemma ball_simps [simp,no_atp]:
   874   "\<And>A P Q. (\<forall>x\<in>A. P x | Q) = ((\<forall>x\<in>A. P x) | Q)"
   875   "\<And>A P Q. (\<forall>x\<in>A. P | Q x) = (P | (\<forall>x\<in>A. Q x))"
   876   "\<And>A P Q. (\<forall>x\<in>A. P --> Q x) = (P --> (\<forall>x\<in>A. Q x))"
   877   "\<And>A P Q. (\<forall>x\<in>A. P x --> Q) = ((\<exists>x\<in>A. P x) --> Q)"
   878   "\<And>P. (ALL x:{}. P x) = True"
   879   "\<And>P. (ALL x:UNIV. P x) = (ALL x. P x)"
   880   "\<And>a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
   881   "\<And>A P. (ALL x:\<Union>A. P x) = (ALL y:A. ALL x:y. P x)"
   882   "\<And>A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
   883   "\<And>P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
   884   "\<And>A P f. (ALL x:f`A. P x) = (\<forall>x\<in>A. P (f x))"
   885   "\<And>A P. (~(\<forall>x\<in>A. P x)) = (\<exists>x\<in>A. ~P x)"
   886   by auto
   887 
   888 lemma bex_simps [simp,no_atp]:
   889   "\<And>A P Q. (\<exists>x\<in>A. P x & Q) = ((\<exists>x\<in>A. P x) & Q)"
   890   "\<And>A P Q. (\<exists>x\<in>A. P & Q x) = (P & (\<exists>x\<in>A. Q x))"
   891   "\<And>P. (EX x:{}. P x) = False"
   892   "\<And>P. (EX x:UNIV. P x) = (EX x. P x)"
   893   "\<And>a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
   894   "\<And>A P. (EX x:\<Union>A. P x) = (EX y:A. EX x:y. P x)"
   895   "\<And>A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
   896   "\<And>P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
   897   "\<And>A P f. (EX x:f`A. P x) = (\<exists>x\<in>A. P (f x))"
   898   "\<And>A P. (~(\<exists>x\<in>A. P x)) = (\<forall>x\<in>A. ~P x)"
   899   by auto
   900 
   901 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
   902 
   903 lemma UN_extend_simps:
   904   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
   905   "\<And>A B C. (\<Union>x\<in>C. A x) Un B    = (if C={} then B else (\<Union>x\<in>C. A x Un B))"
   906   "\<And>A B C. A Un (\<Union>x\<in>C. B x)   = (if C={} then A else (\<Union>x\<in>C. A Un B x))"
   907   "\<And>A B C. ((\<Union>x\<in>C. A x) Int B) = (\<Union>x\<in>C. A x Int B)"
   908   "\<And>A B C. (A Int (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A Int B x)"
   909   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
   910   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
   911   "\<And>A B. (UN y:A. UN x:y. B x) = (UN x: \<Union>A. B x)"
   912   "\<And>A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
   913   "\<And>A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
   914   by auto
   915 
   916 lemma INT_extend_simps:
   917   "\<And>A B C. (\<Inter>x\<in>C. A x) Int B = (if C={} then B else (\<Inter>x\<in>C. A x Int B))"
   918   "\<And>A B C. A Int (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A Int B x))"
   919   "\<And>A B C. (\<Inter>x\<in>C. A x) - B   = (if C={} then UNIV-B else (\<Inter>x\<in>C. A x - B))"
   920   "\<And>A B C. A - (\<Union>x\<in>C. B x)   = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
   921   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
   922   "\<And>A B C. ((\<Inter>x\<in>C. A x) Un B)  = (\<Inter>x\<in>C. A x Un B)"
   923   "\<And>A B C. A Un (\<Inter>x\<in>C. B x)  = (\<Inter>x\<in>C. A Un B x)"
   924   "\<And>A B. (\<Inter>y\<in>A. INT x:y. B x) = (INT x: \<Union>A. B x)"
   925   "\<And>A B C. (\<Inter>x\<in>A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
   926   "\<And>A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
   927   by auto
   928 
   929 
   930 no_notation
   931   less_eq  (infix "\<sqsubseteq>" 50) and
   932   less (infix "\<sqsubset>" 50) and
   933   bot ("\<bottom>") and
   934   top ("\<top>") and
   935   inf  (infixl "\<sqinter>" 70) and
   936   sup  (infixl "\<squnion>" 65) and
   937   Inf  ("\<Sqinter>_" [900] 900) and
   938   Sup  ("\<Squnion>_" [900] 900)
   939 
   940 no_syntax (xsymbols)
   941   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   942   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   943   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   944   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   945 
   946 lemmas mem_simps =
   947   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   948   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   949   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   950 
   951 end