src/HOL/Relation.thy
author haftmann
Sat Mar 17 08:00:18 2012 +0100 (2012-03-17)
changeset 46981 d54cea5b64e4
parent 46884 154dc6ec0041
child 46982 144d94446378
permissions -rw-r--r--
generalized INF_INT_eq, SUP_UN_eq
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory; Stefan Berghofer, TU Muenchen
     3 *)
     4 
     5 header {* Relations – as sets of pairs, and binary predicates *}
     6 
     7 theory Relation
     8 imports Datatype Finite_Set
     9 begin
    10 
    11 text {* A preliminary: classical rules for reasoning on predicates *}
    12 
    13 declare predicate1I [Pure.intro!, intro!]
    14 declare predicate1D [Pure.dest, dest]
    15 declare predicate2I [Pure.intro!, intro!]
    16 declare predicate2D [Pure.dest, dest]
    17 declare bot1E [elim!] 
    18 declare bot2E [elim!]
    19 declare top1I [intro!]
    20 declare top2I [intro!]
    21 declare inf1I [intro!]
    22 declare inf2I [intro!]
    23 declare inf1E [elim!]
    24 declare inf2E [elim!]
    25 declare sup1I1 [intro?]
    26 declare sup2I1 [intro?]
    27 declare sup1I2 [intro?]
    28 declare sup2I2 [intro?]
    29 declare sup1E [elim!]
    30 declare sup2E [elim!]
    31 declare sup1CI [intro!]
    32 declare sup2CI [intro!]
    33 declare INF1_I [intro!]
    34 declare INF2_I [intro!]
    35 declare INF1_D [elim]
    36 declare INF2_D [elim]
    37 declare INF1_E [elim]
    38 declare INF2_E [elim]
    39 declare SUP1_I [intro]
    40 declare SUP2_I [intro]
    41 declare SUP1_E [elim!]
    42 declare SUP2_E [elim!]
    43 
    44 subsection {* Fundamental *}
    45 
    46 subsubsection {* Relations as sets of pairs *}
    47 
    48 type_synonym 'a rel = "('a * 'a) set"
    49 
    50 lemma subrelI: -- {* Version of @{thm [source] subsetI} for binary relations *}
    51   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    52   by auto
    53 
    54 lemma lfp_induct2: -- {* Version of @{thm [source] lfp_induct} for binary relations *}
    55   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    56     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    57   using lfp_induct_set [of "(a, b)" f "prod_case P"] by auto
    58 
    59 
    60 subsubsection {* Conversions between set and predicate relations *}
    61 
    62 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    63   by (simp add: set_eq_iff fun_eq_iff)
    64 
    65 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    66   by (simp add: set_eq_iff fun_eq_iff)
    67 
    68 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    69   by (simp add: subset_iff le_fun_def)
    70 
    71 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    72   by (simp add: subset_iff le_fun_def)
    73 
    74 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    75   by (auto simp add: fun_eq_iff)
    76 
    77 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    78   by (auto simp add: fun_eq_iff)
    79 
    80 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    81   by (auto simp add: fun_eq_iff)
    82 
    83 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    84   by (auto simp add: fun_eq_iff)
    85 
    86 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
    87   by (simp add: inf_fun_def)
    88 
    89 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
    90   by (simp add: inf_fun_def)
    91 
    92 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
    93   by (simp add: sup_fun_def)
    94 
    95 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
    96   by (simp add: sup_fun_def)
    97 
    98 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
    99   by (simp add: fun_eq_iff)
   100 
   101 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   102   by (simp add: fun_eq_iff)
   103 
   104 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   105   by (simp add: fun_eq_iff)
   106 
   107 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   108   by (simp add: fun_eq_iff)
   109 
   110 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   111   by (simp add: fun_eq_iff)
   112 
   113 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   114   by (simp add: fun_eq_iff)
   115 
   116 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (prod_case ` S) Collect)"
   117   by (simp add: fun_eq_iff)
   118 
   119 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   120   by (simp add: fun_eq_iff)
   121 
   122 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   123   by (simp add: fun_eq_iff)
   124 
   125 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   126   by (simp add: fun_eq_iff)
   127 
   128 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (prod_case ` S) Collect)"
   129   by (simp add: fun_eq_iff)
   130 
   131 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   132   by (simp add: fun_eq_iff)
   133 
   134 
   135 subsection {* Properties of relations *}
   136 
   137 subsubsection {* Reflexivity *}
   138 
   139 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   140 where
   141   "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   142 
   143 abbreviation refl :: "'a rel \<Rightarrow> bool"
   144 where -- {* reflexivity over a type *}
   145   "refl \<equiv> refl_on UNIV"
   146 
   147 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   148 where
   149   "reflp r \<longleftrightarrow> refl {(x, y). r x y}"
   150 
   151 lemma reflp_refl_eq [pred_set_conv]:
   152   "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r" 
   153   by (simp add: refl_on_def reflp_def)
   154 
   155 lemma refl_onI: "r \<subseteq> A \<times> A ==> (!!x. x : A ==> (x, x) : r) ==> refl_on A r"
   156   by (unfold refl_on_def) (iprover intro!: ballI)
   157 
   158 lemma refl_onD: "refl_on A r ==> a : A ==> (a, a) : r"
   159   by (unfold refl_on_def) blast
   160 
   161 lemma refl_onD1: "refl_on A r ==> (x, y) : r ==> x : A"
   162   by (unfold refl_on_def) blast
   163 
   164 lemma refl_onD2: "refl_on A r ==> (x, y) : r ==> y : A"
   165   by (unfold refl_on_def) blast
   166 
   167 lemma reflpI:
   168   "(\<And>x. r x x) \<Longrightarrow> reflp r"
   169   by (auto intro: refl_onI simp add: reflp_def)
   170 
   171 lemma reflpE:
   172   assumes "reflp r"
   173   obtains "r x x"
   174   using assms by (auto dest: refl_onD simp add: reflp_def)
   175 
   176 lemma refl_on_Int: "refl_on A r ==> refl_on B s ==> refl_on (A \<inter> B) (r \<inter> s)"
   177   by (unfold refl_on_def) blast
   178 
   179 lemma reflp_inf:
   180   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   181   by (auto intro: reflpI elim: reflpE)
   182 
   183 lemma refl_on_Un: "refl_on A r ==> refl_on B s ==> refl_on (A \<union> B) (r \<union> s)"
   184   by (unfold refl_on_def) blast
   185 
   186 lemma reflp_sup:
   187   "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   188   by (auto intro: reflpI elim: reflpE)
   189 
   190 lemma refl_on_INTER:
   191   "ALL x:S. refl_on (A x) (r x) ==> refl_on (INTER S A) (INTER S r)"
   192   by (unfold refl_on_def) fast
   193 
   194 lemma refl_on_UNION:
   195   "ALL x:S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   196   by (unfold refl_on_def) blast
   197 
   198 lemma refl_on_empty [simp]: "refl_on {} {}"
   199   by (simp add:refl_on_def)
   200 
   201 lemma refl_on_def' [nitpick_unfold, code]:
   202   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   203   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   204 
   205 
   206 subsubsection {* Irreflexivity *}
   207 
   208 definition irrefl :: "'a rel \<Rightarrow> bool"
   209 where
   210   "irrefl r \<longleftrightarrow> (\<forall>x. (x, x) \<notin> r)"
   211 
   212 lemma irrefl_distinct [code]:
   213   "irrefl r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<noteq> y)"
   214   by (auto simp add: irrefl_def)
   215 
   216 
   217 subsubsection {* Symmetry *}
   218 
   219 definition sym :: "'a rel \<Rightarrow> bool"
   220 where
   221   "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   222 
   223 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   224 where
   225   "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   226 
   227 lemma symp_sym_eq [pred_set_conv]:
   228   "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r" 
   229   by (simp add: sym_def symp_def)
   230 
   231 lemma symI:
   232   "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   233   by (unfold sym_def) iprover
   234 
   235 lemma sympI:
   236   "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   237   by (fact symI [to_pred])
   238 
   239 lemma symE:
   240   assumes "sym r" and "(b, a) \<in> r"
   241   obtains "(a, b) \<in> r"
   242   using assms by (simp add: sym_def)
   243 
   244 lemma sympE:
   245   assumes "symp r" and "r b a"
   246   obtains "r a b"
   247   using assms by (rule symE [to_pred])
   248 
   249 lemma symD:
   250   assumes "sym r" and "(b, a) \<in> r"
   251   shows "(a, b) \<in> r"
   252   using assms by (rule symE)
   253 
   254 lemma sympD:
   255   assumes "symp r" and "r b a"
   256   shows "r a b"
   257   using assms by (rule symD [to_pred])
   258 
   259 lemma sym_Int:
   260   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   261   by (fast intro: symI elim: symE)
   262 
   263 lemma symp_inf:
   264   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   265   by (fact sym_Int [to_pred])
   266 
   267 lemma sym_Un:
   268   "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   269   by (fast intro: symI elim: symE)
   270 
   271 lemma symp_sup:
   272   "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   273   by (fact sym_Un [to_pred])
   274 
   275 lemma sym_INTER:
   276   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   277   by (fast intro: symI elim: symE)
   278 
   279 (* FIXME thm sym_INTER [to_pred] *)
   280 
   281 lemma sym_UNION:
   282   "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   283   by (fast intro: symI elim: symE)
   284 
   285 (* FIXME thm sym_UNION [to_pred] *)
   286 
   287 
   288 subsubsection {* Antisymmetry *}
   289 
   290 definition antisym :: "'a rel \<Rightarrow> bool"
   291 where
   292   "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   293 
   294 abbreviation antisymP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   295 where
   296   "antisymP r \<equiv> antisym {(x, y). r x y}"
   297 
   298 lemma antisymI:
   299   "(!!x y. (x, y) : r ==> (y, x) : r ==> x=y) ==> antisym r"
   300   by (unfold antisym_def) iprover
   301 
   302 lemma antisymD: "antisym r ==> (a, b) : r ==> (b, a) : r ==> a = b"
   303   by (unfold antisym_def) iprover
   304 
   305 lemma antisym_subset: "r \<subseteq> s ==> antisym s ==> antisym r"
   306   by (unfold antisym_def) blast
   307 
   308 lemma antisym_empty [simp]: "antisym {}"
   309   by (unfold antisym_def) blast
   310 
   311 
   312 subsubsection {* Transitivity *}
   313 
   314 definition trans :: "'a rel \<Rightarrow> bool"
   315 where
   316   "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   317 
   318 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   319 where
   320   "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   321 
   322 lemma transp_trans_eq [pred_set_conv]:
   323   "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r" 
   324   by (simp add: trans_def transp_def)
   325 
   326 abbreviation transP :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   327 where -- {* FIXME drop *}
   328   "transP r \<equiv> trans {(x, y). r x y}"
   329 
   330 lemma transI:
   331   "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   332   by (unfold trans_def) iprover
   333 
   334 lemma transpI:
   335   "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   336   by (fact transI [to_pred])
   337 
   338 lemma transE:
   339   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   340   obtains "(x, z) \<in> r"
   341   using assms by (unfold trans_def) iprover
   342 
   343 lemma transpE:
   344   assumes "transp r" and "r x y" and "r y z"
   345   obtains "r x z"
   346   using assms by (rule transE [to_pred])
   347 
   348 lemma transD:
   349   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   350   shows "(x, z) \<in> r"
   351   using assms by (rule transE)
   352 
   353 lemma transpD:
   354   assumes "transp r" and "r x y" and "r y z"
   355   shows "r x z"
   356   using assms by (rule transD [to_pred])
   357 
   358 lemma trans_Int:
   359   "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   360   by (fast intro: transI elim: transE)
   361 
   362 lemma transp_inf:
   363   "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   364   by (fact trans_Int [to_pred])
   365 
   366 lemma trans_INTER:
   367   "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   368   by (fast intro: transI elim: transD)
   369 
   370 (* FIXME thm trans_INTER [to_pred] *)
   371 
   372 lemma trans_join [code]:
   373   "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   374   by (auto simp add: trans_def)
   375 
   376 lemma transp_trans:
   377   "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   378   by (simp add: trans_def transp_def)
   379 
   380 
   381 subsubsection {* Totality *}
   382 
   383 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   384 where
   385   "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   386 
   387 abbreviation "total \<equiv> total_on UNIV"
   388 
   389 lemma total_on_empty [simp]: "total_on {} r"
   390   by (simp add: total_on_def)
   391 
   392 
   393 subsubsection {* Single valued relations *}
   394 
   395 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   396 where
   397   "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   398 
   399 abbreviation single_valuedP :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool" where
   400   "single_valuedP r \<equiv> single_valued {(x, y). r x y}"
   401 
   402 lemma single_valuedI:
   403   "ALL x y. (x,y):r --> (ALL z. (x,z):r --> y=z) ==> single_valued r"
   404   by (unfold single_valued_def)
   405 
   406 lemma single_valuedD:
   407   "single_valued r ==> (x, y) : r ==> (x, z) : r ==> y = z"
   408   by (simp add: single_valued_def)
   409 
   410 lemma single_valued_subset:
   411   "r \<subseteq> s ==> single_valued s ==> single_valued r"
   412   by (unfold single_valued_def) blast
   413 
   414 
   415 subsection {* Relation operations *}
   416 
   417 subsubsection {* The identity relation *}
   418 
   419 definition Id :: "'a rel"
   420 where
   421   "Id = {p. \<exists>x. p = (x, x)}"
   422 
   423 lemma IdI [intro]: "(a, a) : Id"
   424   by (simp add: Id_def)
   425 
   426 lemma IdE [elim!]: "p : Id ==> (!!x. p = (x, x) ==> P) ==> P"
   427   by (unfold Id_def) (iprover elim: CollectE)
   428 
   429 lemma pair_in_Id_conv [iff]: "((a, b) : Id) = (a = b)"
   430   by (unfold Id_def) blast
   431 
   432 lemma refl_Id: "refl Id"
   433   by (simp add: refl_on_def)
   434 
   435 lemma antisym_Id: "antisym Id"
   436   -- {* A strange result, since @{text Id} is also symmetric. *}
   437   by (simp add: antisym_def)
   438 
   439 lemma sym_Id: "sym Id"
   440   by (simp add: sym_def)
   441 
   442 lemma trans_Id: "trans Id"
   443   by (simp add: trans_def)
   444 
   445 lemma single_valued_Id [simp]: "single_valued Id"
   446   by (unfold single_valued_def) blast
   447 
   448 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   449   by (simp add:irrefl_def)
   450 
   451 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   452   unfolding antisym_def trans_def by blast
   453 
   454 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   455   by (simp add: total_on_def)
   456 
   457 
   458 subsubsection {* Diagonal: identity over a set *}
   459 
   460 definition Id_on  :: "'a set \<Rightarrow> 'a rel"
   461 where
   462   "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   463 
   464 lemma Id_on_empty [simp]: "Id_on {} = {}"
   465   by (simp add: Id_on_def) 
   466 
   467 lemma Id_on_eqI: "a = b ==> a : A ==> (a, b) : Id_on A"
   468   by (simp add: Id_on_def)
   469 
   470 lemma Id_onI [intro!,no_atp]: "a : A ==> (a, a) : Id_on A"
   471   by (rule Id_on_eqI) (rule refl)
   472 
   473 lemma Id_onE [elim!]:
   474   "c : Id_on A ==> (!!x. x : A ==> c = (x, x) ==> P) ==> P"
   475   -- {* The general elimination rule. *}
   476   by (unfold Id_on_def) (iprover elim!: UN_E singletonE)
   477 
   478 lemma Id_on_iff: "((x, y) : Id_on A) = (x = y & x : A)"
   479   by blast
   480 
   481 lemma Id_on_def' [nitpick_unfold]:
   482   "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   483   by auto
   484 
   485 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   486   by blast
   487 
   488 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   489   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   490 
   491 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   492   by (unfold antisym_def) blast
   493 
   494 lemma sym_Id_on [simp]: "sym (Id_on A)"
   495   by (rule symI) clarify
   496 
   497 lemma trans_Id_on [simp]: "trans (Id_on A)"
   498   by (fast intro: transI elim: transD)
   499 
   500 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   501   by (unfold single_valued_def) blast
   502 
   503 
   504 subsubsection {* Composition *}
   505 
   506 inductive_set rel_comp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set" (infixr "O" 75)
   507   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   508 where
   509   rel_compI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   510 
   511 abbreviation pred_comp (infixr "OO" 75) where
   512   "pred_comp \<equiv> rel_compp"
   513 
   514 lemmas pred_compI = rel_compp.intros
   515 
   516 text {*
   517   For historic reasons, the elimination rules are not wholly corresponding.
   518   Feel free to consolidate this.
   519 *}
   520 
   521 inductive_cases rel_compEpair: "(a, c) \<in> r O s"
   522 inductive_cases pred_compE [elim!]: "(r OO s) a c"
   523 
   524 lemma rel_compE [elim!]: "xz \<in> r O s \<Longrightarrow>
   525   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   526   by (cases xz) (simp, erule rel_compEpair, iprover)
   527 
   528 lemmas pred_comp_rel_comp_eq = rel_compp_rel_comp_eq
   529 
   530 lemma R_O_Id [simp]:
   531   "R O Id = R"
   532   by fast
   533 
   534 lemma Id_O_R [simp]:
   535   "Id O R = R"
   536   by fast
   537 
   538 lemma rel_comp_empty1 [simp]:
   539   "{} O R = {}"
   540   by blast
   541 
   542 lemma prod_comp_bot1 [simp]:
   543   "\<bottom> OO R = \<bottom>"
   544   by (fact rel_comp_empty1 [to_pred])
   545 
   546 lemma rel_comp_empty2 [simp]:
   547   "R O {} = {}"
   548   by blast
   549 
   550 lemma pred_comp_bot2 [simp]:
   551   "R OO \<bottom> = \<bottom>"
   552   by (fact rel_comp_empty2 [to_pred])
   553 
   554 lemma O_assoc:
   555   "(R O S) O T = R O (S O T)"
   556   by blast
   557 
   558 
   559 lemma pred_comp_assoc:
   560   "(r OO s) OO t = r OO (s OO t)"
   561   by (fact O_assoc [to_pred])
   562 
   563 lemma trans_O_subset:
   564   "trans r \<Longrightarrow> r O r \<subseteq> r"
   565   by (unfold trans_def) blast
   566 
   567 lemma transp_pred_comp_less_eq:
   568   "transp r \<Longrightarrow> r OO r \<le> r "
   569   by (fact trans_O_subset [to_pred])
   570 
   571 lemma rel_comp_mono:
   572   "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   573   by blast
   574 
   575 lemma pred_comp_mono:
   576   "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   577   by (fact rel_comp_mono [to_pred])
   578 
   579 lemma rel_comp_subset_Sigma:
   580   "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   581   by blast
   582 
   583 lemma rel_comp_distrib [simp]:
   584   "R O (S \<union> T) = (R O S) \<union> (R O T)" 
   585   by auto
   586 
   587 lemma pred_comp_distrib [simp]:
   588   "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   589   by (fact rel_comp_distrib [to_pred])
   590 
   591 lemma rel_comp_distrib2 [simp]:
   592   "(S \<union> T) O R = (S O R) \<union> (T O R)"
   593   by auto
   594 
   595 lemma pred_comp_distrib2 [simp]:
   596   "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   597   by (fact rel_comp_distrib2 [to_pred])
   598 
   599 lemma rel_comp_UNION_distrib:
   600   "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   601   by auto
   602 
   603 (* FIXME thm rel_comp_UNION_distrib [to_pred] *)
   604 
   605 lemma rel_comp_UNION_distrib2:
   606   "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   607   by auto
   608 
   609 (* FIXME thm rel_comp_UNION_distrib2 [to_pred] *)
   610 
   611 lemma single_valued_rel_comp:
   612   "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   613   by (unfold single_valued_def) blast
   614 
   615 lemma rel_comp_unfold:
   616   "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   617   by (auto simp add: set_eq_iff)
   618 
   619 
   620 subsubsection {* Converse *}
   621 
   622 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set" ("(_^-1)" [1000] 999)
   623   for r :: "('a \<times> 'b) set"
   624 where
   625   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r^-1"
   626 
   627 notation (xsymbols)
   628   converse  ("(_\<inverse>)" [1000] 999)
   629 
   630 notation
   631   conversep ("(_^--1)" [1000] 1000)
   632 
   633 notation (xsymbols)
   634   conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   635 
   636 lemma converseI [sym]:
   637   "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   638   by (fact converse.intros)
   639 
   640 lemma conversepI (* CANDIDATE [sym] *):
   641   "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   642   by (fact conversep.intros)
   643 
   644 lemma converseD [sym]:
   645   "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   646   by (erule converse.cases) iprover
   647 
   648 lemma conversepD (* CANDIDATE [sym] *):
   649   "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   650   by (fact converseD [to_pred])
   651 
   652 lemma converseE [elim!]:
   653   -- {* More general than @{text converseD}, as it ``splits'' the member of the relation. *}
   654   "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   655   by (cases yx) (simp, erule converse.cases, iprover)
   656 
   657 lemmas conversepE [elim!] = conversep.cases
   658 
   659 lemma converse_iff [iff]:
   660   "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   661   by (auto intro: converseI)
   662 
   663 lemma conversep_iff [iff]:
   664   "r\<inverse>\<inverse> a b = r b a"
   665   by (fact converse_iff [to_pred])
   666 
   667 lemma converse_converse [simp]:
   668   "(r\<inverse>)\<inverse> = r"
   669   by (simp add: set_eq_iff)
   670 
   671 lemma conversep_conversep [simp]:
   672   "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   673   by (fact converse_converse [to_pred])
   674 
   675 lemma converse_rel_comp: "(r O s)^-1 = s^-1 O r^-1"
   676   by blast
   677 
   678 lemma converse_pred_comp: "(r OO s)^--1 = s^--1 OO r^--1"
   679   by (iprover intro: order_antisym conversepI pred_compI
   680     elim: pred_compE dest: conversepD)
   681 
   682 lemma converse_Int: "(r \<inter> s)^-1 = r^-1 \<inter> s^-1"
   683   by blast
   684 
   685 lemma converse_meet: "(r \<sqinter> s)^--1 = r^--1 \<sqinter> s^--1"
   686   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   687 
   688 lemma converse_Un: "(r \<union> s)^-1 = r^-1 \<union> s^-1"
   689   by blast
   690 
   691 lemma converse_join: "(r \<squnion> s)^--1 = r^--1 \<squnion> s^--1"
   692   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   693 
   694 lemma converse_INTER: "(INTER S r)^-1 = (INT x:S. (r x)^-1)"
   695   by fast
   696 
   697 lemma converse_UNION: "(UNION S r)^-1 = (UN x:S. (r x)^-1)"
   698   by blast
   699 
   700 lemma converse_Id [simp]: "Id^-1 = Id"
   701   by blast
   702 
   703 lemma converse_Id_on [simp]: "(Id_on A)^-1 = Id_on A"
   704   by blast
   705 
   706 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   707   by (unfold refl_on_def) auto
   708 
   709 lemma sym_converse [simp]: "sym (converse r) = sym r"
   710   by (unfold sym_def) blast
   711 
   712 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   713   by (unfold antisym_def) blast
   714 
   715 lemma trans_converse [simp]: "trans (converse r) = trans r"
   716   by (unfold trans_def) blast
   717 
   718 lemma sym_conv_converse_eq: "sym r = (r^-1 = r)"
   719   by (unfold sym_def) fast
   720 
   721 lemma sym_Un_converse: "sym (r \<union> r^-1)"
   722   by (unfold sym_def) blast
   723 
   724 lemma sym_Int_converse: "sym (r \<inter> r^-1)"
   725   by (unfold sym_def) blast
   726 
   727 lemma total_on_converse [simp]: "total_on A (r^-1) = total_on A r"
   728   by (auto simp: total_on_def)
   729 
   730 lemma finite_converse [iff]: "finite (r^-1) = finite r"
   731   apply (subgoal_tac "r^-1 = (%(x,y). (y,x))`r")
   732    apply simp
   733    apply (rule iffI)
   734     apply (erule finite_imageD [unfolded inj_on_def])
   735     apply (simp split add: split_split)
   736    apply (erule finite_imageI)
   737   apply (simp add: set_eq_iff image_def, auto)
   738   apply (rule bexI)
   739    prefer 2 apply assumption
   740   apply simp
   741   done
   742 
   743 lemma conversep_noteq [simp]: "(op \<noteq>)^--1 = op \<noteq>"
   744   by (auto simp add: fun_eq_iff)
   745 
   746 lemma conversep_eq [simp]: "(op =)^--1 = op ="
   747   by (auto simp add: fun_eq_iff)
   748 
   749 lemma converse_unfold:
   750   "r\<inverse> = {(y, x). (x, y) \<in> r}"
   751   by (simp add: set_eq_iff)
   752 
   753 
   754 subsubsection {* Domain, range and field *}
   755 
   756 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set"
   757   for r :: "('a \<times> 'b) set"
   758 where
   759   DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   760 
   761 abbreviation (input) "DomainP \<equiv> Domainp"
   762 
   763 lemmas DomainPI = Domainp.DomainI
   764 
   765 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   766 inductive_cases DomainpE [elim!]: "Domainp r a"
   767 
   768 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set"
   769   for r :: "('a \<times> 'b) set"
   770 where
   771   RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   772 
   773 abbreviation (input) "RangeP \<equiv> Rangep"
   774 
   775 lemmas RangePI = Rangep.RangeI
   776 
   777 inductive_cases RangeE [elim!]: "b \<in> Range r"
   778 inductive_cases RangepE [elim!]: "Rangep r b"
   779 
   780 definition Field :: "'a rel \<Rightarrow> 'a set"
   781 where
   782   "Field r = Domain r \<union> Range r"
   783 
   784 lemma Domain_fst [code]:
   785   "Domain r = fst ` r"
   786   by force
   787 
   788 lemma Range_snd [code]:
   789   "Range r = snd ` r"
   790   by force
   791 
   792 lemma fst_eq_Domain: "fst ` R = Domain R"
   793   by force
   794 
   795 lemma snd_eq_Range: "snd ` R = Range R"
   796   by force
   797 
   798 lemma Domain_empty [simp]: "Domain {} = {}"
   799   by auto
   800 
   801 lemma Range_empty [simp]: "Range {} = {}"
   802   by auto
   803 
   804 lemma Field_empty [simp]: "Field {} = {}"
   805   by (simp add: Field_def)
   806 
   807 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   808   by auto
   809 
   810 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   811   by auto
   812 
   813 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   814   by blast
   815 
   816 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   817   by blast
   818 
   819 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   820   by (auto simp add: Field_def)
   821 
   822 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   823   by blast
   824 
   825 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   826   by blast
   827 
   828 lemma Domain_Id [simp]: "Domain Id = UNIV"
   829   by blast
   830 
   831 lemma Range_Id [simp]: "Range Id = UNIV"
   832   by blast
   833 
   834 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   835   by blast
   836 
   837 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   838   by blast
   839 
   840 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   841   by blast
   842 
   843 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   844   by blast
   845 
   846 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   847   by (auto simp: Field_def)
   848 
   849 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   850   by blast
   851 
   852 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   853   by blast
   854 
   855 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   856   by blast
   857 
   858 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   859   by blast
   860 
   861 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   862   by blast
   863 
   864 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   865   by blast
   866 
   867 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   868   by (auto simp: Field_def)
   869 
   870 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   871   by auto
   872 
   873 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   874   by blast
   875 
   876 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   877   by (auto simp: Field_def)
   878 
   879 lemma Domain_Collect_split [simp]: "Domain {(x, y). P x y} = {x. EX y. P x y}"
   880   by auto
   881 
   882 lemma Range_Collect_split [simp]: "Range {(x, y). P x y} = {y. EX x. P x y}"
   883   by auto
   884 
   885 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   886   by (induct set: finite) auto
   887 
   888 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   889   by (induct set: finite) auto
   890 
   891 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   892   by (simp add: Field_def finite_Domain finite_Range)
   893 
   894 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   895   by blast
   896 
   897 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   898   by blast
   899 
   900 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
   901   by (auto simp: Field_def Domain_def Range_def)
   902 
   903 lemma Domain_unfold:
   904   "Domain r = {x. \<exists>y. (x, y) \<in> r}"
   905   by blast
   906 
   907 lemma Domain_dprod [simp]: "Domain (dprod r s) = uprod (Domain r) (Domain s)"
   908   by auto
   909 
   910 lemma Domain_dsum [simp]: "Domain (dsum r s) = usum (Domain r) (Domain s)"
   911   by auto
   912 
   913 
   914 subsubsection {* Image of a set under a relation *}
   915 
   916 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set" (infixl "``" 90)
   917 where
   918   "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
   919 
   920 declare Image_def [no_atp]
   921 
   922 lemma Image_iff: "(b : r``A) = (EX x:A. (x, b) : r)"
   923   by (simp add: Image_def)
   924 
   925 lemma Image_singleton: "r``{a} = {b. (a, b) : r}"
   926   by (simp add: Image_def)
   927 
   928 lemma Image_singleton_iff [iff]: "(b : r``{a}) = ((a, b) : r)"
   929   by (rule Image_iff [THEN trans]) simp
   930 
   931 lemma ImageI [intro,no_atp]: "(a, b) : r ==> a : A ==> b : r``A"
   932   by (unfold Image_def) blast
   933 
   934 lemma ImageE [elim!]:
   935   "b : r `` A ==> (!!x. (x, b) : r ==> x : A ==> P) ==> P"
   936   by (unfold Image_def) (iprover elim!: CollectE bexE)
   937 
   938 lemma rev_ImageI: "a : A ==> (a, b) : r ==> b : r `` A"
   939   -- {* This version's more effective when we already have the required @{text a} *}
   940   by blast
   941 
   942 lemma Image_empty [simp]: "R``{} = {}"
   943   by blast
   944 
   945 lemma Image_Id [simp]: "Id `` A = A"
   946   by blast
   947 
   948 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
   949   by blast
   950 
   951 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
   952   by blast
   953 
   954 lemma Image_Int_eq:
   955   "single_valued (converse R) ==> R `` (A \<inter> B) = R `` A \<inter> R `` B"
   956   by (simp add: single_valued_def, blast) 
   957 
   958 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
   959   by blast
   960 
   961 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
   962   by blast
   963 
   964 lemma Image_subset: "r \<subseteq> A \<times> B ==> r``C \<subseteq> B"
   965   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
   966 
   967 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
   968   -- {* NOT suitable for rewriting *}
   969   by blast
   970 
   971 lemma Image_mono: "r' \<subseteq> r ==> A' \<subseteq> A ==> (r' `` A') \<subseteq> (r `` A)"
   972   by blast
   973 
   974 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
   975   by blast
   976 
   977 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
   978   by blast
   979 
   980 text{*Converse inclusion requires some assumptions*}
   981 lemma Image_INT_eq:
   982      "[|single_valued (r\<inverse>); A\<noteq>{}|] ==> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
   983 apply (rule equalityI)
   984  apply (rule Image_INT_subset) 
   985 apply  (simp add: single_valued_def, blast)
   986 done
   987 
   988 lemma Image_subset_eq: "(r``A \<subseteq> B) = (A \<subseteq> - ((r^-1) `` (-B)))"
   989   by blast
   990 
   991 lemma Image_Collect_split [simp]: "{(x, y). P x y} `` A = {y. EX x:A. P x y}"
   992   by auto
   993 
   994 
   995 subsubsection {* Inverse image *}
   996 
   997 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
   998 where
   999   "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1000 
  1001 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1002 where
  1003   "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1004 
  1005 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1006   by (simp add: inv_image_def inv_imagep_def)
  1007 
  1008 lemma sym_inv_image: "sym r ==> sym (inv_image r f)"
  1009   by (unfold sym_def inv_image_def) blast
  1010 
  1011 lemma trans_inv_image: "trans r ==> trans (inv_image r f)"
  1012   apply (unfold trans_def inv_image_def)
  1013   apply (simp (no_asm))
  1014   apply blast
  1015   done
  1016 
  1017 lemma in_inv_image[simp]: "((x,y) : inv_image r f) = ((f x, f y) : r)"
  1018   by (auto simp:inv_image_def)
  1019 
  1020 lemma converse_inv_image[simp]: "(inv_image R f)^-1 = inv_image (R^-1) f"
  1021   unfolding inv_image_def converse_unfold by auto
  1022 
  1023 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1024   by (simp add: inv_imagep_def)
  1025 
  1026 
  1027 subsubsection {* Powerset *}
  1028 
  1029 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1030 where
  1031   "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1032 
  1033 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1034   by (auto simp add: Powp_def fun_eq_iff)
  1035 
  1036 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1037 
  1038 end
  1039