src/HOL/Set.thy
author wenzelm
Mon Jul 06 21:24:30 2009 +0200 (2009-07-06)
changeset 31945 d5f186aa0bed
parent 31643 b040f1679f77
child 31991 37390299214a
permissions -rw-r--r--
structure Thm: less pervasive names;
     1 (*  Title:      HOL/Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3 *)
     4 
     5 header {* Set theory for higher-order logic *}
     6 
     7 theory Set
     8 imports Lattices
     9 begin
    10 
    11 text {* A set in HOL is simply a predicate. *}
    12 
    13 
    14 subsection {* Basic syntax *}
    15 
    16 global
    17 
    18 types 'a set = "'a => bool"
    19 
    20 consts
    21   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    22   "op :"        :: "'a => 'a set => bool"                -- "membership"
    23   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    24   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    25   Bex1          :: "'a set => ('a => bool) => bool"      -- "bounded unique existential quantifiers"
    26 
    27 local
    28 
    29 notation
    30   "op :"  ("op :") and
    31   "op :"  ("(_/ : _)" [50, 51] 50)
    32 
    33 abbreviation
    34   "not_mem x A == ~ (x : A)" -- "non-membership"
    35 
    36 notation
    37   not_mem  ("op ~:") and
    38   not_mem  ("(_/ ~: _)" [50, 51] 50)
    39 
    40 notation (xsymbols)
    41   "op :"  ("op \<in>") and
    42   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    43   not_mem  ("op \<notin>") and
    44   not_mem  ("(_/ \<notin> _)" [50, 51] 50)
    45 
    46 notation (HTML output)
    47   "op :"  ("op \<in>") and
    48   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    49   not_mem  ("op \<notin>") and
    50   not_mem  ("(_/ \<notin> _)" [50, 51] 50)
    51 
    52 syntax
    53   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    54 
    55 translations
    56   "{x. P}"      == "Collect (%x. P)"
    57 
    58 definition Int :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Int" 70) where
    59   "A Int B \<equiv> {x. x \<in> A \<and> x \<in> B}"
    60 
    61 definition Un :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Un" 65) where
    62   "A Un B \<equiv> {x. x \<in> A \<or> x \<in> B}"
    63 
    64 notation (xsymbols)
    65   "Int"  (infixl "\<inter>" 70) and
    66   "Un"  (infixl "\<union>" 65)
    67 
    68 notation (HTML output)
    69   "Int"  (infixl "\<inter>" 70) and
    70   "Un"  (infixl "\<union>" 65)
    71 
    72 definition empty :: "'a set" ("{}") where
    73   "empty \<equiv> {x. False}"
    74 
    75 definition insert :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a set" where
    76   "insert a B \<equiv> {x. x = a} \<union> B"
    77 
    78 definition UNIV :: "'a set" where
    79   "UNIV \<equiv> {x. True}"
    80 
    81 syntax
    82   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    83 
    84 translations
    85   "{x, xs}"     == "CONST insert x {xs}"
    86   "{x}"         == "CONST insert x {}"
    87 
    88 syntax
    89   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    90   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    91   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3EX! _:_./ _)" [0, 0, 10] 10)
    92   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST _:_./ _)" [0, 0, 10] 10)
    93 
    94 syntax (HOL)
    95   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    96   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    97   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3?! _:_./ _)" [0, 0, 10] 10)
    98 
    99 syntax (xsymbols)
   100   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   101   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   102   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   103   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST_\<in>_./ _)" [0, 0, 10] 10)
   104 
   105 syntax (HTML output)
   106   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   107   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   108   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   109 
   110 translations
   111   "ALL x:A. P"  == "Ball A (%x. P)"
   112   "EX x:A. P"   == "Bex A (%x. P)"
   113   "EX! x:A. P"  == "Bex1 A (%x. P)"
   114   "LEAST x:A. P" => "LEAST x. x:A & P"
   115 
   116 definition INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   117   "INTER A B \<equiv> {y. \<forall>x\<in>A. y \<in> B x}"
   118 
   119 definition UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   120   "UNION A B \<equiv> {y. \<exists>x\<in>A. y \<in> B x}"
   121 
   122 definition Inter :: "'a set set \<Rightarrow> 'a set" where
   123   "Inter S \<equiv> INTER S (\<lambda>x. x)"
   124 
   125 definition Union :: "'a set set \<Rightarrow> 'a set" where
   126   "Union S \<equiv> UNION S (\<lambda>x. x)"
   127 
   128 notation (xsymbols)
   129   Inter  ("\<Inter>_" [90] 90) and
   130   Union  ("\<Union>_" [90] 90)
   131 
   132 
   133 subsection {* Additional concrete syntax *}
   134 
   135 syntax
   136   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
   137   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ :/ _./ _})")
   138   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   139   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   140   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 10] 10)
   141   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 10] 10)
   142 
   143 syntax (xsymbols)
   144   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ \<in>/ _./ _})")
   145   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   146   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   147   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 10] 10)
   148   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 10] 10)
   149 
   150 syntax (latex output)
   151   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   152   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   153   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   154   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   155 
   156 translations
   157   "{x:A. P}"    => "{x. x:A & P}"
   158   "INT x y. B"  == "INT x. INT y. B"
   159   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   160   "INT x. B"    == "INT x:CONST UNIV. B"
   161   "INT x:A. B"  == "CONST INTER A (%x. B)"
   162   "UN x y. B"   == "UN x. UN y. B"
   163   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   164   "UN x. B"     == "UN x:CONST UNIV. B"
   165   "UN x:A. B"   == "CONST UNION A (%x. B)"
   166 
   167 text {*
   168   Note the difference between ordinary xsymbol syntax of indexed
   169   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   170   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   171   former does not make the index expression a subscript of the
   172   union/intersection symbol because this leads to problems with nested
   173   subscripts in Proof General.
   174 *}
   175 
   176 abbreviation
   177   subset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   178   "subset \<equiv> less"
   179 
   180 abbreviation
   181   subset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   182   "subset_eq \<equiv> less_eq"
   183 
   184 notation (output)
   185   subset  ("op <") and
   186   subset  ("(_/ < _)" [50, 51] 50) and
   187   subset_eq  ("op <=") and
   188   subset_eq  ("(_/ <= _)" [50, 51] 50)
   189 
   190 notation (xsymbols)
   191   subset  ("op \<subset>") and
   192   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   193   subset_eq  ("op \<subseteq>") and
   194   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   195 
   196 notation (HTML output)
   197   subset  ("op \<subset>") and
   198   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   199   subset_eq  ("op \<subseteq>") and
   200   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   201 
   202 abbreviation (input)
   203   supset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   204   "supset \<equiv> greater"
   205 
   206 abbreviation (input)
   207   supset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   208   "supset_eq \<equiv> greater_eq"
   209 
   210 notation (xsymbols)
   211   supset  ("op \<supset>") and
   212   supset  ("(_/ \<supset> _)" [50, 51] 50) and
   213   supset_eq  ("op \<supseteq>") and
   214   supset_eq  ("(_/ \<supseteq> _)" [50, 51] 50)
   215 
   216 
   217 
   218 subsubsection "Bounded quantifiers"
   219 
   220 syntax (output)
   221   "_setlessAll" :: "[idt, 'a, bool] => bool"  ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   222   "_setlessEx"  :: "[idt, 'a, bool] => bool"  ("(3EX _<_./ _)"  [0, 0, 10] 10)
   223   "_setleAll"   :: "[idt, 'a, bool] => bool"  ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   224   "_setleEx"    :: "[idt, 'a, bool] => bool"  ("(3EX _<=_./ _)" [0, 0, 10] 10)
   225   "_setleEx1"   :: "[idt, 'a, bool] => bool"  ("(3EX! _<=_./ _)" [0, 0, 10] 10)
   226 
   227 syntax (xsymbols)
   228   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   229   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   230   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   231   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   232   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   233 
   234 syntax (HOL output)
   235   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3! _<_./ _)"  [0, 0, 10] 10)
   236   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3? _<_./ _)"  [0, 0, 10] 10)
   237   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3! _<=_./ _)" [0, 0, 10] 10)
   238   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3? _<=_./ _)" [0, 0, 10] 10)
   239   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3?! _<=_./ _)" [0, 0, 10] 10)
   240 
   241 syntax (HTML output)
   242   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   243   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   244   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   245   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   246   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   247 
   248 translations
   249  "\<forall>A\<subset>B. P"   =>  "ALL A. A \<subset> B --> P"
   250  "\<exists>A\<subset>B. P"   =>  "EX A. A \<subset> B & P"
   251  "\<forall>A\<subseteq>B. P"   =>  "ALL A. A \<subseteq> B --> P"
   252  "\<exists>A\<subseteq>B. P"   =>  "EX A. A \<subseteq> B & P"
   253  "\<exists>!A\<subseteq>B. P"  =>  "EX! A. A \<subseteq> B & P"
   254 
   255 print_translation {*
   256 let
   257   val Type (set_type, _) = @{typ "'a set"};
   258   val All_binder = Syntax.binder_name @{const_syntax "All"};
   259   val Ex_binder = Syntax.binder_name @{const_syntax "Ex"};
   260   val impl = @{const_syntax "op -->"};
   261   val conj = @{const_syntax "op &"};
   262   val sbset = @{const_syntax "subset"};
   263   val sbset_eq = @{const_syntax "subset_eq"};
   264 
   265   val trans =
   266    [((All_binder, impl, sbset), "_setlessAll"),
   267     ((All_binder, impl, sbset_eq), "_setleAll"),
   268     ((Ex_binder, conj, sbset), "_setlessEx"),
   269     ((Ex_binder, conj, sbset_eq), "_setleEx")];
   270 
   271   fun mk v v' c n P =
   272     if v = v' andalso not (Term.exists_subterm (fn Free (x, _) => x = v | _ => false) n)
   273     then Syntax.const c $ Syntax.mark_bound v' $ n $ P else raise Match;
   274 
   275   fun tr' q = (q,
   276     fn [Const ("_bound", _) $ Free (v, Type (T, _)), Const (c, _) $ (Const (d, _) $ (Const ("_bound", _) $ Free (v', _)) $ n) $ P] =>
   277          if T = (set_type) then case AList.lookup (op =) trans (q, c, d)
   278           of NONE => raise Match
   279            | SOME l => mk v v' l n P
   280          else raise Match
   281      | _ => raise Match);
   282 in
   283   [tr' All_binder, tr' Ex_binder]
   284 end
   285 *}
   286 
   287 
   288 text {*
   289   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   290   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   291   only translated if @{text "[0..n] subset bvs(e)"}.
   292 *}
   293 
   294 parse_translation {*
   295   let
   296     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   297 
   298     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   299       | nvars _ = 1;
   300 
   301     fun setcompr_tr [e, idts, b] =
   302       let
   303         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   304         val P = Syntax.const "op &" $ eq $ b;
   305         val exP = ex_tr [idts, P];
   306       in Syntax.const "Collect" $ Term.absdummy (dummyT, exP) end;
   307 
   308   in [("@SetCompr", setcompr_tr)] end;
   309 *}
   310 
   311 (* To avoid eta-contraction of body: *)
   312 print_translation {*
   313 let
   314   fun btr' syn [A, Abs abs] =
   315     let val (x, t) = atomic_abs_tr' abs
   316     in Syntax.const syn $ x $ A $ t end
   317 in
   318 [(@{const_syntax Ball}, btr' "_Ball"), (@{const_syntax Bex}, btr' "_Bex"),
   319  (@{const_syntax UNION}, btr' "@UNION"),(@{const_syntax INTER}, btr' "@INTER")]
   320 end
   321 *}
   322 
   323 print_translation {*
   324 let
   325   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   326 
   327   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   328     let
   329       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   330         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   331             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   332             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   333         | check _ = false
   334 
   335         fun tr' (_ $ abs) =
   336           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   337           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   338     in if check (P, 0) then tr' P
   339        else let val (x as _ $ Free(xN,_), t) = atomic_abs_tr' abs
   340                 val M = Syntax.const "@Coll" $ x $ t
   341             in case t of
   342                  Const("op &",_)
   343                    $ (Const("op :",_) $ (Const("_bound",_) $ Free(yN,_)) $ A)
   344                    $ P =>
   345                    if xN=yN then Syntax.const "@Collect" $ x $ A $ P else M
   346                | _ => M
   347             end
   348     end;
   349   in [("Collect", setcompr_tr')] end;
   350 *}
   351 
   352 
   353 subsection {* Rules and definitions *}
   354 
   355 text {* Isomorphisms between predicates and sets. *}
   356 
   357 defs
   358   mem_def [code]: "x : S == S x"
   359   Collect_def [code]: "Collect P == P"
   360 
   361 defs
   362   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   363   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   364   Bex1_def:     "Bex1 A P       == EX! x. x:A & P(x)"
   365 
   366 instantiation "fun" :: (type, minus) minus
   367 begin
   368 
   369 definition
   370   fun_diff_def: "A - B = (%x. A x - B x)"
   371 
   372 instance ..
   373 
   374 end
   375 
   376 instantiation bool :: minus
   377 begin
   378 
   379 definition
   380   bool_diff_def: "A - B = (A & ~ B)"
   381 
   382 instance ..
   383 
   384 end
   385 
   386 instantiation "fun" :: (type, uminus) uminus
   387 begin
   388 
   389 definition
   390   fun_Compl_def: "- A = (%x. - A x)"
   391 
   392 instance ..
   393 
   394 end
   395 
   396 instantiation bool :: uminus
   397 begin
   398 
   399 definition
   400   bool_Compl_def: "- A = (~ A)"
   401 
   402 instance ..
   403 
   404 end
   405 
   406 definition Pow :: "'a set => 'a set set" where
   407   Pow_def: "Pow A = {B. B \<le> A}"
   408 
   409 definition image :: "('a => 'b) => 'a set => 'b set" (infixr "`" 90) where
   410   image_def: "f ` A = {y. EX x:A. y = f(x)}"
   411 
   412 abbreviation
   413   range :: "('a => 'b) => 'b set" where -- "of function"
   414   "range f == f ` UNIV"
   415 
   416 
   417 subsection {* Lemmas and proof tool setup *}
   418 
   419 subsubsection {* Relating predicates and sets *}
   420 
   421 lemma mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
   422   by (simp add: Collect_def mem_def)
   423 
   424 lemma Collect_mem_eq [simp]: "{x. x:A} = A"
   425   by (simp add: Collect_def mem_def)
   426 
   427 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   428   by simp
   429 
   430 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   431   by simp
   432 
   433 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   434   by simp
   435 
   436 lemmas CollectE = CollectD [elim_format]
   437 
   438 
   439 subsubsection {* Bounded quantifiers *}
   440 
   441 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   442   by (simp add: Ball_def)
   443 
   444 lemmas strip = impI allI ballI
   445 
   446 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   447   by (simp add: Ball_def)
   448 
   449 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   450   by (unfold Ball_def) blast
   451 
   452 ML {* bind_thm ("rev_ballE", Thm.permute_prems 1 1 @{thm ballE}) *}
   453 
   454 text {*
   455   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   456   @{prop "a:A"}; creates assumption @{prop "P a"}.
   457 *}
   458 
   459 ML {*
   460   fun ball_tac i = etac @{thm ballE} i THEN contr_tac (i + 1)
   461 *}
   462 
   463 text {*
   464   Gives better instantiation for bound:
   465 *}
   466 
   467 declaration {* fn _ =>
   468   Classical.map_cs (fn cs => cs addbefore ("bspec", datac @{thm bspec} 1))
   469 *}
   470 
   471 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   472   -- {* Normally the best argument order: @{prop "P x"} constrains the
   473     choice of @{prop "x:A"}. *}
   474   by (unfold Bex_def) blast
   475 
   476 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   477   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   478   by (unfold Bex_def) blast
   479 
   480 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   481   by (unfold Bex_def) blast
   482 
   483 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   484   by (unfold Bex_def) blast
   485 
   486 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   487   -- {* Trival rewrite rule. *}
   488   by (simp add: Ball_def)
   489 
   490 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   491   -- {* Dual form for existentials. *}
   492   by (simp add: Bex_def)
   493 
   494 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   495   by blast
   496 
   497 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   498   by blast
   499 
   500 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   501   by blast
   502 
   503 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   504   by blast
   505 
   506 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   507   by blast
   508 
   509 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   510   by blast
   511 
   512 ML {*
   513   local
   514     val unfold_bex_tac = unfold_tac @{thms "Bex_def"};
   515     fun prove_bex_tac ss = unfold_bex_tac ss THEN Quantifier1.prove_one_point_ex_tac;
   516     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   517 
   518     val unfold_ball_tac = unfold_tac @{thms "Ball_def"};
   519     fun prove_ball_tac ss = unfold_ball_tac ss THEN Quantifier1.prove_one_point_all_tac;
   520     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   521   in
   522     val defBEX_regroup = Simplifier.simproc (the_context ())
   523       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   524     val defBALL_regroup = Simplifier.simproc (the_context ())
   525       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   526   end;
   527 
   528   Addsimprocs [defBALL_regroup, defBEX_regroup];
   529 *}
   530 
   531 
   532 subsubsection {* Congruence rules *}
   533 
   534 lemma ball_cong:
   535   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   536     (ALL x:A. P x) = (ALL x:B. Q x)"
   537   by (simp add: Ball_def)
   538 
   539 lemma strong_ball_cong [cong]:
   540   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   541     (ALL x:A. P x) = (ALL x:B. Q x)"
   542   by (simp add: simp_implies_def Ball_def)
   543 
   544 lemma bex_cong:
   545   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   546     (EX x:A. P x) = (EX x:B. Q x)"
   547   by (simp add: Bex_def cong: conj_cong)
   548 
   549 lemma strong_bex_cong [cong]:
   550   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   551     (EX x:A. P x) = (EX x:B. Q x)"
   552   by (simp add: simp_implies_def Bex_def cong: conj_cong)
   553 
   554 
   555 subsubsection {* Subsets *}
   556 
   557 lemma subsetI [atp,intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   558   by (auto simp add: mem_def intro: predicate1I)
   559 
   560 text {*
   561   \medskip Map the type @{text "'a set => anything"} to just @{typ
   562   'a}; for overloading constants whose first argument has type @{typ
   563   "'a set"}.
   564 *}
   565 
   566 lemma subsetD [elim, intro?]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   567   -- {* Rule in Modus Ponens style. *}
   568   by (unfold mem_def) blast
   569 
   570 lemma rev_subsetD [intro?]: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   571   -- {* The same, with reversed premises for use with @{text erule} --
   572       cf @{text rev_mp}. *}
   573   by (rule subsetD)
   574 
   575 text {*
   576   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   577 *}
   578 
   579 ML {*
   580   fun impOfSubs th = th RSN (2, @{thm rev_subsetD})
   581 *}
   582 
   583 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   584   -- {* Classical elimination rule. *}
   585   by (unfold mem_def) blast
   586 
   587 lemma subset_eq: "A \<le> B = (\<forall>x\<in>A. x \<in> B)" by blast
   588 
   589 text {*
   590   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   591   creates the assumption @{prop "c \<in> B"}.
   592 *}
   593 
   594 ML {*
   595   fun set_mp_tac i = etac @{thm subsetCE} i THEN mp_tac i
   596 *}
   597 
   598 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   599   by blast
   600 
   601 lemma subset_refl [simp,atp]: "A \<subseteq> A"
   602   by fast
   603 
   604 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   605   by blast
   606 
   607 
   608 subsubsection {* Equality *}
   609 
   610 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   611   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   612    apply (rule Collect_mem_eq)
   613   apply (rule Collect_mem_eq)
   614   done
   615 
   616 (* Due to Brian Huffman *)
   617 lemma expand_set_eq: "(A = B) = (ALL x. (x:A) = (x:B))"
   618 by(auto intro:set_ext)
   619 
   620 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   621   -- {* Anti-symmetry of the subset relation. *}
   622   by (iprover intro: set_ext subsetD)
   623 
   624 text {*
   625   \medskip Equality rules from ZF set theory -- are they appropriate
   626   here?
   627 *}
   628 
   629 lemma equalityD1: "A = B ==> A \<subseteq> B"
   630   by (simp add: subset_refl)
   631 
   632 lemma equalityD2: "A = B ==> B \<subseteq> A"
   633   by (simp add: subset_refl)
   634 
   635 text {*
   636   \medskip Be careful when adding this to the claset as @{text
   637   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   638   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   639 *}
   640 
   641 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   642   by (simp add: subset_refl)
   643 
   644 lemma equalityCE [elim]:
   645     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   646   by blast
   647 
   648 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   649   by simp
   650 
   651 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   652   by simp
   653 
   654 
   655 subsubsection {* The universal set -- UNIV *}
   656 
   657 lemma UNIV_I [simp]: "x : UNIV"
   658   by (simp add: UNIV_def)
   659 
   660 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   661 
   662 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   663   by simp
   664 
   665 lemma subset_UNIV [simp]: "A \<subseteq> UNIV"
   666   by (rule subsetI) (rule UNIV_I)
   667 
   668 text {*
   669   \medskip Eta-contracting these two rules (to remove @{text P})
   670   causes them to be ignored because of their interaction with
   671   congruence rules.
   672 *}
   673 
   674 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   675   by (simp add: Ball_def)
   676 
   677 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   678   by (simp add: Bex_def)
   679 
   680 lemma UNIV_eq_I: "(\<And>x. x \<in> A) \<Longrightarrow> UNIV = A"
   681   by auto
   682 
   683 
   684 subsubsection {* The empty set *}
   685 
   686 lemma empty_iff [simp]: "(c : {}) = False"
   687   by (simp add: empty_def)
   688 
   689 lemma emptyE [elim!]: "a : {} ==> P"
   690   by simp
   691 
   692 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   693     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   694   by blast
   695 
   696 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   697   by blast
   698 
   699 lemma equals0D: "A = {} ==> a \<notin> A"
   700     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   701   by blast
   702 
   703 lemma ball_empty [simp]: "Ball {} P = True"
   704   by (simp add: Ball_def)
   705 
   706 lemma bex_empty [simp]: "Bex {} P = False"
   707   by (simp add: Bex_def)
   708 
   709 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   710   by (blast elim: equalityE)
   711 
   712 
   713 subsubsection {* The Powerset operator -- Pow *}
   714 
   715 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   716   by (simp add: Pow_def)
   717 
   718 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   719   by (simp add: Pow_def)
   720 
   721 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   722   by (simp add: Pow_def)
   723 
   724 lemma Pow_bottom: "{} \<in> Pow B"
   725   by simp
   726 
   727 lemma Pow_top: "A \<in> Pow A"
   728   by (simp add: subset_refl)
   729 
   730 
   731 subsubsection {* Set complement *}
   732 
   733 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   734   by (simp add: mem_def fun_Compl_def bool_Compl_def)
   735 
   736 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   737   by (unfold mem_def fun_Compl_def bool_Compl_def) blast
   738 
   739 text {*
   740   \medskip This form, with negated conclusion, works well with the
   741   Classical prover.  Negated assumptions behave like formulae on the
   742   right side of the notional turnstile ... *}
   743 
   744 lemma ComplD [dest!]: "c : -A ==> c~:A"
   745   by (simp add: mem_def fun_Compl_def bool_Compl_def)
   746 
   747 lemmas ComplE = ComplD [elim_format]
   748 
   749 lemma Compl_eq: "- A = {x. ~ x : A}" by blast
   750 
   751 
   752 subsubsection {* Binary union -- Un *}
   753 
   754 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   755   by (unfold Un_def) blast
   756 
   757 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   758   by simp
   759 
   760 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   761   by simp
   762 
   763 text {*
   764   \medskip Classical introduction rule: no commitment to @{prop A} vs
   765   @{prop B}.
   766 *}
   767 
   768 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   769   by auto
   770 
   771 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   772   by (unfold Un_def) blast
   773 
   774 
   775 subsubsection {* Binary intersection -- Int *}
   776 
   777 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   778   by (unfold Int_def) blast
   779 
   780 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   781   by simp
   782 
   783 lemma IntD1: "c : A Int B ==> c:A"
   784   by simp
   785 
   786 lemma IntD2: "c : A Int B ==> c:B"
   787   by simp
   788 
   789 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   790   by simp
   791 
   792 
   793 subsubsection {* Set difference *}
   794 
   795 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   796   by (simp add: mem_def fun_diff_def bool_diff_def)
   797 
   798 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   799   by simp
   800 
   801 lemma DiffD1: "c : A - B ==> c : A"
   802   by simp
   803 
   804 lemma DiffD2: "c : A - B ==> c : B ==> P"
   805   by simp
   806 
   807 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   808   by simp
   809 
   810 lemma set_diff_eq: "A - B = {x. x : A & ~ x : B}" by blast
   811 
   812 lemma Compl_eq_Diff_UNIV: "-A = (UNIV - A)"
   813 by blast
   814 
   815 
   816 subsubsection {* Augmenting a set -- @{const insert} *}
   817 
   818 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   819   by (unfold insert_def) blast
   820 
   821 lemma insertI1: "a : insert a B"
   822   by simp
   823 
   824 lemma insertI2: "a : B ==> a : insert b B"
   825   by simp
   826 
   827 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   828   by (unfold insert_def) blast
   829 
   830 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   831   -- {* Classical introduction rule. *}
   832   by auto
   833 
   834 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   835   by auto
   836 
   837 lemma set_insert:
   838   assumes "x \<in> A"
   839   obtains B where "A = insert x B" and "x \<notin> B"
   840 proof
   841   from assms show "A = insert x (A - {x})" by blast
   842 next
   843   show "x \<notin> A - {x}" by blast
   844 qed
   845 
   846 lemma insert_ident: "x ~: A ==> x ~: B ==> (insert x A = insert x B) = (A = B)"
   847 by auto
   848 
   849 subsubsection {* Singletons, using insert *}
   850 
   851 lemma singletonI [intro!,noatp]: "a : {a}"
   852     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   853   by (rule insertI1)
   854 
   855 lemma singletonD [dest!,noatp]: "b : {a} ==> b = a"
   856   by blast
   857 
   858 lemmas singletonE = singletonD [elim_format]
   859 
   860 lemma singleton_iff: "(b : {a}) = (b = a)"
   861   by blast
   862 
   863 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   864   by blast
   865 
   866 lemma singleton_insert_inj_eq [iff,noatp]:
   867      "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   868   by blast
   869 
   870 lemma singleton_insert_inj_eq' [iff,noatp]:
   871      "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   872   by blast
   873 
   874 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   875   by fast
   876 
   877 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   878   by blast
   879 
   880 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   881   by blast
   882 
   883 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   884   by blast
   885 
   886 lemma doubleton_eq_iff: "({a,b} = {c,d}) = (a=c & b=d | a=d & b=c)"
   887   by (blast elim: equalityE)
   888 
   889 
   890 subsubsection {* Unions of families *}
   891 
   892 text {*
   893   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   894 *}
   895 
   896 declare UNION_def [noatp]
   897 
   898 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   899   by (unfold UNION_def) blast
   900 
   901 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   902   -- {* The order of the premises presupposes that @{term A} is rigid;
   903     @{term b} may be flexible. *}
   904   by auto
   905 
   906 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   907   by (unfold UNION_def) blast
   908 
   909 lemma UN_cong [cong]:
   910     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   911   by (simp add: UNION_def)
   912 
   913 lemma strong_UN_cong:
   914     "A = B ==> (!!x. x:B =simp=> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   915   by (simp add: UNION_def simp_implies_def)
   916 
   917 
   918 subsubsection {* Intersections of families *}
   919 
   920 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   921 
   922 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   923   by (unfold INTER_def) blast
   924 
   925 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   926   by (unfold INTER_def) blast
   927 
   928 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   929   by auto
   930 
   931 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   932   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   933   by (unfold INTER_def) blast
   934 
   935 lemma INT_cong [cong]:
   936     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   937   by (simp add: INTER_def)
   938 
   939 
   940 subsubsection {* Union *}
   941 
   942 lemma Union_iff [simp,noatp]: "(A : Union C) = (EX X:C. A:X)"
   943   by (unfold Union_def) blast
   944 
   945 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   946   -- {* The order of the premises presupposes that @{term C} is rigid;
   947     @{term A} may be flexible. *}
   948   by auto
   949 
   950 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   951   by (unfold Union_def) blast
   952 
   953 
   954 subsubsection {* Inter *}
   955 
   956 lemma Inter_iff [simp,noatp]: "(A : Inter C) = (ALL X:C. A:X)"
   957   by (unfold Inter_def) blast
   958 
   959 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   960   by (simp add: Inter_def)
   961 
   962 text {*
   963   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   964   contains @{term A} as an element, but @{prop "A:X"} can hold when
   965   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   966 *}
   967 
   968 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   969   by auto
   970 
   971 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   972   -- {* ``Classical'' elimination rule -- does not require proving
   973     @{prop "X:C"}. *}
   974   by (unfold Inter_def) blast
   975 
   976 text {*
   977   \medskip Image of a set under a function.  Frequently @{term b} does
   978   not have the syntactic form of @{term "f x"}.
   979 *}
   980 
   981 declare image_def [noatp]
   982 
   983 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   984   by (unfold image_def) blast
   985 
   986 lemma imageI: "x : A ==> f x : f ` A"
   987   by (rule image_eqI) (rule refl)
   988 
   989 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   990   -- {* This version's more effective when we already have the
   991     required @{term x}. *}
   992   by (unfold image_def) blast
   993 
   994 lemma imageE [elim!]:
   995   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   996   -- {* The eta-expansion gives variable-name preservation. *}
   997   by (unfold image_def) blast
   998 
   999 lemma image_Un: "f`(A Un B) = f`A Un f`B"
  1000   by blast
  1001 
  1002 lemma image_eq_UN: "f`A = (UN x:A. {f x})"
  1003   by blast
  1004 
  1005 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
  1006   by blast
  1007 
  1008 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
  1009   -- {* This rewrite rule would confuse users if made default. *}
  1010   by blast
  1011 
  1012 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
  1013   apply safe
  1014    prefer 2 apply fast
  1015   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
  1016   done
  1017 
  1018 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
  1019   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
  1020     @{text hypsubst}, but breaks too many existing proofs. *}
  1021   by blast
  1022 
  1023 text {*
  1024   \medskip Range of a function -- just a translation for image!
  1025 *}
  1026 
  1027 lemma range_eqI: "b = f x ==> b \<in> range f"
  1028   by simp
  1029 
  1030 lemma rangeI: "f x \<in> range f"
  1031   by simp
  1032 
  1033 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
  1034   by blast
  1035 
  1036 
  1037 subsubsection {* Set reasoning tools *}
  1038 
  1039 text{* Elimination of @{text"{x. \<dots> & x=t & \<dots>}"}. *}
  1040 
  1041 lemma Collect_conv_if: "{x. x=a & P x} = (if P a then {a} else {})"
  1042 by auto
  1043 
  1044 lemma Collect_conv_if2: "{x. a=x & P x} = (if P a then {a} else {})"
  1045 by auto
  1046 
  1047 text {*
  1048 Simproc for pulling @{text "x=t"} in @{text "{x. \<dots> & x=t & \<dots>}"}
  1049 to the front (and similarly for @{text "t=x"}):
  1050 *}
  1051 
  1052 ML{*
  1053   local
  1054     val Coll_perm_tac = rtac @{thm Collect_cong} 1 THEN rtac @{thm iffI} 1 THEN
  1055     ALLGOALS(EVERY'[REPEAT_DETERM o (etac @{thm conjE}),
  1056                     DEPTH_SOLVE_1 o (ares_tac [@{thm conjI}])])
  1057   in
  1058     val defColl_regroup = Simplifier.simproc (the_context ())
  1059       "defined Collect" ["{x. P x & Q x}"]
  1060       (Quantifier1.rearrange_Coll Coll_perm_tac)
  1061   end;
  1062 
  1063   Addsimprocs [defColl_regroup];
  1064 *}
  1065 
  1066 text {*
  1067   Rewrite rules for boolean case-splitting: faster than @{text
  1068   "split_if [split]"}.
  1069 *}
  1070 
  1071 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
  1072   by (rule split_if)
  1073 
  1074 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
  1075   by (rule split_if)
  1076 
  1077 text {*
  1078   Split ifs on either side of the membership relation.  Not for @{text
  1079   "[simp]"} -- can cause goals to blow up!
  1080 *}
  1081 
  1082 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
  1083   by (rule split_if)
  1084 
  1085 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
  1086   by (rule split_if [where P="%S. a : S"])
  1087 
  1088 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
  1089 
  1090 (*Would like to add these, but the existing code only searches for the
  1091   outer-level constant, which in this case is just "op :"; we instead need
  1092   to use term-nets to associate patterns with rules.  Also, if a rule fails to
  1093   apply, then the formula should be kept.
  1094   [("HOL.uminus", Compl_iff RS iffD1), ("HOL.minus", [Diff_iff RS iffD1]),
  1095    ("Int", [IntD1,IntD2]),
  1096    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
  1097  *)
  1098 
  1099 ML {*
  1100   val mksimps_pairs = [(@{const_name Ball}, @{thms bspec})] @ mksimps_pairs;
  1101 *}
  1102 declaration {* fn _ =>
  1103   Simplifier.map_ss (fn ss => ss setmksimps (mksimps mksimps_pairs))
  1104 *}
  1105 
  1106 
  1107 subsubsection {* The ``proper subset'' relation *}
  1108 
  1109 lemma psubsetI [intro!,noatp]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
  1110   by (unfold less_le) blast
  1111 
  1112 lemma psubsetE [elim!,noatp]: 
  1113     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
  1114   by (unfold less_le) blast
  1115 
  1116 lemma psubset_insert_iff:
  1117   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
  1118   by (auto simp add: less_le subset_insert_iff)
  1119 
  1120 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
  1121   by (simp only: less_le)
  1122 
  1123 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
  1124   by (simp add: psubset_eq)
  1125 
  1126 lemma psubset_trans: "[| A \<subset> B; B \<subset> C |] ==> A \<subset> C"
  1127 apply (unfold less_le)
  1128 apply (auto dest: subset_antisym)
  1129 done
  1130 
  1131 lemma psubsetD: "[| A \<subset> B; c \<in> A |] ==> c \<in> B"
  1132 apply (unfold less_le)
  1133 apply (auto dest: subsetD)
  1134 done
  1135 
  1136 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
  1137   by (auto simp add: psubset_eq)
  1138 
  1139 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
  1140   by (auto simp add: psubset_eq)
  1141 
  1142 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
  1143   by (unfold less_le) blast
  1144 
  1145 lemma atomize_ball:
  1146     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
  1147   by (simp only: Ball_def atomize_all atomize_imp)
  1148 
  1149 lemmas [symmetric, rulify] = atomize_ball
  1150   and [symmetric, defn] = atomize_ball
  1151 
  1152 
  1153 subsection {* Further set-theory lemmas *}
  1154 
  1155 subsubsection {* Derived rules involving subsets. *}
  1156 
  1157 text {* @{text insert}. *}
  1158 
  1159 lemma subset_insertI: "B \<subseteq> insert a B"
  1160   by (rule subsetI) (erule insertI2)
  1161 
  1162 lemma subset_insertI2: "A \<subseteq> B \<Longrightarrow> A \<subseteq> insert b B"
  1163   by blast
  1164 
  1165 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
  1166   by blast
  1167 
  1168 
  1169 text {* \medskip Big Union -- least upper bound of a set. *}
  1170 
  1171 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
  1172   by (iprover intro: subsetI UnionI)
  1173 
  1174 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
  1175   by (iprover intro: subsetI elim: UnionE dest: subsetD)
  1176 
  1177 
  1178 text {* \medskip General union. *}
  1179 
  1180 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1181   by blast
  1182 
  1183 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
  1184   by (iprover intro: subsetI elim: UN_E dest: subsetD)
  1185 
  1186 
  1187 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
  1188 
  1189 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
  1190   by blast
  1191 
  1192 lemma Inter_subset:
  1193   "[| !!X. X \<in> A ==> X \<subseteq> B; A ~= {} |] ==> \<Inter>A \<subseteq> B"
  1194   by blast
  1195 
  1196 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
  1197   by (iprover intro: InterI subsetI dest: subsetD)
  1198 
  1199 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
  1200   by blast
  1201 
  1202 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
  1203   by (iprover intro: INT_I subsetI dest: subsetD)
  1204 
  1205 
  1206 text {* \medskip Finite Union -- the least upper bound of two sets. *}
  1207 
  1208 lemma Un_upper1: "A \<subseteq> A \<union> B"
  1209   by blast
  1210 
  1211 lemma Un_upper2: "B \<subseteq> A \<union> B"
  1212   by blast
  1213 
  1214 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
  1215   by blast
  1216 
  1217 
  1218 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
  1219 
  1220 lemma Int_lower1: "A \<inter> B \<subseteq> A"
  1221   by blast
  1222 
  1223 lemma Int_lower2: "A \<inter> B \<subseteq> B"
  1224   by blast
  1225 
  1226 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
  1227   by blast
  1228 
  1229 
  1230 text {* \medskip Set difference. *}
  1231 
  1232 lemma Diff_subset: "A - B \<subseteq> A"
  1233   by blast
  1234 
  1235 lemma Diff_subset_conv: "(A - B \<subseteq> C) = (A \<subseteq> B \<union> C)"
  1236 by blast
  1237 
  1238 
  1239 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
  1240 
  1241 text {* @{text "{}"}. *}
  1242 
  1243 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
  1244   -- {* supersedes @{text "Collect_False_empty"} *}
  1245   by auto
  1246 
  1247 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
  1248   by blast
  1249 
  1250 lemma not_psubset_empty [iff]: "\<not> (A < {})"
  1251   by (unfold less_le) blast
  1252 
  1253 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
  1254 by blast
  1255 
  1256 lemma empty_Collect_eq [simp]: "({} = Collect P) = (\<forall>x. \<not> P x)"
  1257 by blast
  1258 
  1259 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
  1260   by blast
  1261 
  1262 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1263   by blast
  1264 
  1265 lemma Collect_imp_eq: "{x. P x --> Q x} = -{x. P x} \<union> {x. Q x}"
  1266   by blast
  1267 
  1268 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1269   by blast
  1270 
  1271 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1272   by blast
  1273 
  1274 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1275   by blast
  1276 
  1277 lemma Collect_ex_eq [noatp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1278   by blast
  1279 
  1280 lemma Collect_bex_eq [noatp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1281   by blast
  1282 
  1283 
  1284 text {* \medskip @{text insert}. *}
  1285 
  1286 lemma insert_is_Un: "insert a A = {a} Un A"
  1287   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1288   by blast
  1289 
  1290 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1291   by blast
  1292 
  1293 lemmas empty_not_insert = insert_not_empty [symmetric, standard]
  1294 declare empty_not_insert [simp]
  1295 
  1296 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1297   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1298   -- {* with \emph{quadratic} running time *}
  1299   by blast
  1300 
  1301 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1302   by blast
  1303 
  1304 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1305   by blast
  1306 
  1307 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1308   by blast
  1309 
  1310 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1311   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1312   apply (rule_tac x = "A - {a}" in exI, blast)
  1313   done
  1314 
  1315 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1316   by auto
  1317 
  1318 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1319   by blast
  1320 
  1321 lemma insert_inter_insert[simp]: "insert a A \<inter> insert a B = insert a (A \<inter> B)"
  1322   by blast
  1323 
  1324 lemma insert_disjoint [simp,noatp]:
  1325  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1326  "({} = insert a A \<inter> B) = (a \<notin> B \<and> {} = A \<inter> B)"
  1327   by auto
  1328 
  1329 lemma disjoint_insert [simp,noatp]:
  1330  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1331  "({} = A \<inter> insert b B) = (b \<notin> A \<and> {} = A \<inter> B)"
  1332   by auto
  1333 
  1334 text {* \medskip @{text image}. *}
  1335 
  1336 lemma image_empty [simp]: "f`{} = {}"
  1337   by blast
  1338 
  1339 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1340   by blast
  1341 
  1342 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1343   by auto
  1344 
  1345 lemma image_constant_conv: "(%x. c) ` A = (if A = {} then {} else {c})"
  1346 by auto
  1347 
  1348 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1349 by blast
  1350 
  1351 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1352 by blast
  1353 
  1354 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1355 by blast
  1356 
  1357 lemma empty_is_image[iff]: "({} = f ` A) = (A = {})"
  1358 by blast
  1359 
  1360 
  1361 lemma image_Collect [noatp]: "f ` {x. P x} = {f x | x. P x}"
  1362   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS,
  1363       with its implicit quantifier and conjunction.  Also image enjoys better
  1364       equational properties than does the RHS. *}
  1365   by blast
  1366 
  1367 lemma if_image_distrib [simp]:
  1368   "(\<lambda>x. if P x then f x else g x) ` S
  1369     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1370   by (auto simp add: image_def)
  1371 
  1372 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1373   by (simp add: image_def)
  1374 
  1375 
  1376 text {* \medskip @{text range}. *}
  1377 
  1378 lemma full_SetCompr_eq [noatp]: "{u. \<exists>x. u = f x} = range f"
  1379   by auto
  1380 
  1381 lemma range_composition: "range (\<lambda>x. f (g x)) = f`range g"
  1382 by (subst image_image, simp)
  1383 
  1384 
  1385 text {* \medskip @{text Int} *}
  1386 
  1387 lemma Int_absorb [simp]: "A \<inter> A = A"
  1388   by blast
  1389 
  1390 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1391   by blast
  1392 
  1393 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1394   by blast
  1395 
  1396 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1397   by blast
  1398 
  1399 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1400   by blast
  1401 
  1402 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1403   -- {* Intersection is an AC-operator *}
  1404 
  1405 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1406   by blast
  1407 
  1408 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1409   by blast
  1410 
  1411 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1412   by blast
  1413 
  1414 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1415   by blast
  1416 
  1417 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1418   by blast
  1419 
  1420 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1421   by blast
  1422 
  1423 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1424   by blast
  1425 
  1426 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1427   by blast
  1428 
  1429 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1430   by blast
  1431 
  1432 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1433   by blast
  1434 
  1435 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1436   by blast
  1437 
  1438 lemma Int_UNIV [simp,noatp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1439   by blast
  1440 
  1441 lemma Int_subset_iff [simp]: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1442   by blast
  1443 
  1444 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1445   by blast
  1446 
  1447 
  1448 text {* \medskip @{text Un}. *}
  1449 
  1450 lemma Un_absorb [simp]: "A \<union> A = A"
  1451   by blast
  1452 
  1453 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1454   by blast
  1455 
  1456 lemma Un_commute: "A \<union> B = B \<union> A"
  1457   by blast
  1458 
  1459 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1460   by blast
  1461 
  1462 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1463   by blast
  1464 
  1465 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1466   -- {* Union is an AC-operator *}
  1467 
  1468 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1469   by blast
  1470 
  1471 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1472   by blast
  1473 
  1474 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1475   by blast
  1476 
  1477 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1478   by blast
  1479 
  1480 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1481   by blast
  1482 
  1483 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1484   by blast
  1485 
  1486 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1487   by blast
  1488 
  1489 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1490   by blast
  1491 
  1492 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1493   by blast
  1494 
  1495 lemma Int_insert_left:
  1496     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1497   by auto
  1498 
  1499 lemma Int_insert_right:
  1500     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1501   by auto
  1502 
  1503 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1504   by blast
  1505 
  1506 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1507   by blast
  1508 
  1509 lemma Un_Int_crazy:
  1510     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1511   by blast
  1512 
  1513 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1514   by blast
  1515 
  1516 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1517   by blast
  1518 
  1519 lemma Un_subset_iff [simp]: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1520   by blast
  1521 
  1522 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1523   by blast
  1524 
  1525 lemma Diff_Int2: "A \<inter> C - B \<inter> C = A \<inter> C - B"
  1526   by blast
  1527 
  1528 
  1529 text {* \medskip Set complement *}
  1530 
  1531 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1532   by blast
  1533 
  1534 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1535   by blast
  1536 
  1537 lemma Compl_partition: "A \<union> -A = UNIV"
  1538   by blast
  1539 
  1540 lemma Compl_partition2: "-A \<union> A = UNIV"
  1541   by blast
  1542 
  1543 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1544   by blast
  1545 
  1546 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1547   by blast
  1548 
  1549 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1550   by blast
  1551 
  1552 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1553   by blast
  1554 
  1555 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1556   by blast
  1557 
  1558 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1559   by blast
  1560 
  1561 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1562   -- {* Halmos, Naive Set Theory, page 16. *}
  1563   by blast
  1564 
  1565 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1566   by blast
  1567 
  1568 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1569   by blast
  1570 
  1571 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1572   by blast
  1573 
  1574 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1575   by blast
  1576 
  1577 
  1578 text {* \medskip @{text Union}. *}
  1579 
  1580 lemma Union_empty [simp]: "Union({}) = {}"
  1581   by blast
  1582 
  1583 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1584   by blast
  1585 
  1586 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1587   by blast
  1588 
  1589 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1590   by blast
  1591 
  1592 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1593   by blast
  1594 
  1595 lemma Union_empty_conv [simp,noatp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1596   by blast
  1597 
  1598 lemma empty_Union_conv [simp,noatp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1599   by blast
  1600 
  1601 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1602   by blast
  1603 
  1604 
  1605 text {* \medskip @{text Inter}. *}
  1606 
  1607 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1608   by blast
  1609 
  1610 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1611   by blast
  1612 
  1613 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1614   by blast
  1615 
  1616 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1617   by blast
  1618 
  1619 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1620   by blast
  1621 
  1622 lemma Inter_UNIV_conv [simp,noatp]:
  1623   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1624   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1625   by blast+
  1626 
  1627 
  1628 text {*
  1629   \medskip @{text UN} and @{text INT}.
  1630 
  1631   Basic identities: *}
  1632 
  1633 lemma UN_empty [simp,noatp]: "(\<Union>x\<in>{}. B x) = {}"
  1634   by blast
  1635 
  1636 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1637   by blast
  1638 
  1639 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1640   by blast
  1641 
  1642 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1643   by auto
  1644 
  1645 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1646   by blast
  1647 
  1648 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1649   by blast
  1650 
  1651 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1652   by blast
  1653 
  1654 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1655   by blast
  1656 
  1657 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1658   by blast
  1659 
  1660 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1661   by blast
  1662 
  1663 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1664   by blast
  1665 
  1666 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1667   by blast
  1668 
  1669 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1670   by blast
  1671 
  1672 lemma INT_insert_distrib:
  1673     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1674   by blast
  1675 
  1676 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1677   by blast
  1678 
  1679 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1680   by blast
  1681 
  1682 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1683   by blast
  1684 
  1685 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1686   by auto
  1687 
  1688 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1689   by auto
  1690 
  1691 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1692   by blast
  1693 
  1694 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1695   -- {* Look: it has an \emph{existential} quantifier *}
  1696   by blast
  1697 
  1698 lemma UNION_empty_conv[simp]:
  1699   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1700   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1701 by blast+
  1702 
  1703 lemma INTER_UNIV_conv[simp]:
  1704  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1705  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1706 by blast+
  1707 
  1708 
  1709 text {* \medskip Distributive laws: *}
  1710 
  1711 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1712   by blast
  1713 
  1714 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1715   by blast
  1716 
  1717 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1718   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1719   -- {* Union of a family of unions *}
  1720   by blast
  1721 
  1722 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1723   -- {* Equivalent version *}
  1724   by blast
  1725 
  1726 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1727   by blast
  1728 
  1729 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1730   by blast
  1731 
  1732 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1733   -- {* Equivalent version *}
  1734   by blast
  1735 
  1736 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1737   -- {* Halmos, Naive Set Theory, page 35. *}
  1738   by blast
  1739 
  1740 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1741   by blast
  1742 
  1743 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1744   by blast
  1745 
  1746 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1747   by blast
  1748 
  1749 
  1750 text {* \medskip Bounded quantifiers.
  1751 
  1752   The following are not added to the default simpset because
  1753   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1754 
  1755 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1756   by blast
  1757 
  1758 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1759   by blast
  1760 
  1761 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1762   by blast
  1763 
  1764 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1765   by blast
  1766 
  1767 
  1768 text {* \medskip Set difference. *}
  1769 
  1770 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1771   by blast
  1772 
  1773 lemma Diff_eq_empty_iff [simp,noatp]: "(A - B = {}) = (A \<subseteq> B)"
  1774   by blast
  1775 
  1776 lemma Diff_cancel [simp]: "A - A = {}"
  1777   by blast
  1778 
  1779 lemma Diff_idemp [simp]: "(A - B) - B = A - (B::'a set)"
  1780 by blast
  1781 
  1782 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1783   by (blast elim: equalityE)
  1784 
  1785 lemma empty_Diff [simp]: "{} - A = {}"
  1786   by blast
  1787 
  1788 lemma Diff_empty [simp]: "A - {} = A"
  1789   by blast
  1790 
  1791 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1792   by blast
  1793 
  1794 lemma Diff_insert0 [simp,noatp]: "x \<notin> A ==> A - insert x B = A - B"
  1795   by blast
  1796 
  1797 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1798   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1799   by blast
  1800 
  1801 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1802   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1803   by blast
  1804 
  1805 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1806   by auto
  1807 
  1808 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1809   by blast
  1810 
  1811 lemma insert_Diff_single[simp]: "insert a (A - {a}) = insert a A"
  1812 by blast
  1813 
  1814 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1815   by blast
  1816 
  1817 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1818   by auto
  1819 
  1820 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1821   by blast
  1822 
  1823 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1824   by blast
  1825 
  1826 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1827   by blast
  1828 
  1829 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1830   by blast
  1831 
  1832 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1833   by blast
  1834 
  1835 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1836   by blast
  1837 
  1838 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1839   by blast
  1840 
  1841 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1842   by blast
  1843 
  1844 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1845   by blast
  1846 
  1847 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1848   by blast
  1849 
  1850 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1851   by blast
  1852 
  1853 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1854   by auto
  1855 
  1856 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1857   by blast
  1858 
  1859 
  1860 text {* \medskip Quantification over type @{typ bool}. *}
  1861 
  1862 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1863   by (cases x) auto
  1864 
  1865 lemma all_bool_eq: "(\<forall>b. P b) \<longleftrightarrow> P True \<and> P False"
  1866   by (auto intro: bool_induct)
  1867 
  1868 lemma bool_contrapos: "P x \<Longrightarrow> \<not> P False \<Longrightarrow> P True"
  1869   by (cases x) auto
  1870 
  1871 lemma ex_bool_eq: "(\<exists>b. P b) \<longleftrightarrow> P True \<or> P False"
  1872   by (auto intro: bool_contrapos)
  1873 
  1874 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1875   by (auto simp add: split_if_mem2)
  1876 
  1877 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1878   by (auto intro: bool_contrapos)
  1879 
  1880 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1881   by (auto intro: bool_induct)
  1882 
  1883 text {* \medskip @{text Pow} *}
  1884 
  1885 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1886   by (auto simp add: Pow_def)
  1887 
  1888 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1889   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1890 
  1891 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1892   by (blast intro: exI [where ?x = "- u", standard])
  1893 
  1894 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1895   by blast
  1896 
  1897 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1898   by blast
  1899 
  1900 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1901   by blast
  1902 
  1903 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1904   by blast
  1905 
  1906 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1907   by blast
  1908 
  1909 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1910   by blast
  1911 
  1912 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1913   by blast
  1914 
  1915 
  1916 text {* \medskip Miscellany. *}
  1917 
  1918 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1919   by blast
  1920 
  1921 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1922   by blast
  1923 
  1924 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1925   by (unfold less_le) blast
  1926 
  1927 lemma all_not_in_conv [simp]: "(\<forall>x. x \<notin> A) = (A = {})"
  1928   by blast
  1929 
  1930 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1931   by blast
  1932 
  1933 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1934   by iprover
  1935 
  1936 
  1937 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1938            and Intersections. *}
  1939 
  1940 lemma UN_simps [simp]:
  1941   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1942   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1943   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1944   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1945   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1946   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1947   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1948   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1949   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1950   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1951   by auto
  1952 
  1953 lemma INT_simps [simp]:
  1954   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1955   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1956   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1957   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1958   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1959   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1960   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1961   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1962   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1963   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1964   by auto
  1965 
  1966 lemma ball_simps [simp,noatp]:
  1967   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1968   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1969   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1970   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1971   "!!P. (ALL x:{}. P x) = True"
  1972   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1973   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1974   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1975   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1976   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1977   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1978   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1979   by auto
  1980 
  1981 lemma bex_simps [simp,noatp]:
  1982   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1983   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1984   "!!P. (EX x:{}. P x) = False"
  1985   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1986   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1987   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1988   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1989   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1990   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1991   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1992   by auto
  1993 
  1994 lemma ball_conj_distrib:
  1995   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1996   by blast
  1997 
  1998 lemma bex_disj_distrib:
  1999   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  2000   by blast
  2001 
  2002 
  2003 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  2004 
  2005 lemma UN_extend_simps:
  2006   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  2007   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  2008   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  2009   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  2010   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  2011   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  2012   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  2013   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  2014   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  2015   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  2016   by auto
  2017 
  2018 lemma INT_extend_simps:
  2019   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  2020   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  2021   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  2022   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  2023   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  2024   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  2025   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  2026   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  2027   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  2028   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  2029   by auto
  2030 
  2031 
  2032 subsubsection {* Monotonicity of various operations *}
  2033 
  2034 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  2035   by blast
  2036 
  2037 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  2038   by blast
  2039 
  2040 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  2041   by blast
  2042 
  2043 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  2044   by blast
  2045 
  2046 lemma UN_mono:
  2047   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  2048     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  2049   by (blast dest: subsetD)
  2050 
  2051 lemma INT_anti_mono:
  2052   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  2053     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  2054   -- {* The last inclusion is POSITIVE! *}
  2055   by (blast dest: subsetD)
  2056 
  2057 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  2058   by blast
  2059 
  2060 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  2061   by blast
  2062 
  2063 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  2064   by blast
  2065 
  2066 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  2067   by blast
  2068 
  2069 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  2070   by blast
  2071 
  2072 text {* \medskip Monotonicity of implications. *}
  2073 
  2074 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  2075   apply (rule impI)
  2076   apply (erule subsetD, assumption)
  2077   done
  2078 
  2079 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  2080   by iprover
  2081 
  2082 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  2083   by iprover
  2084 
  2085 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  2086   by iprover
  2087 
  2088 lemma imp_refl: "P --> P" ..
  2089 
  2090 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  2091   by iprover
  2092 
  2093 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  2094   by iprover
  2095 
  2096 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  2097   by blast
  2098 
  2099 lemma Int_Collect_mono:
  2100     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  2101   by blast
  2102 
  2103 lemmas basic_monos =
  2104   subset_refl imp_refl disj_mono conj_mono
  2105   ex_mono Collect_mono in_mono
  2106 
  2107 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  2108   by iprover
  2109 
  2110 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  2111   by iprover
  2112 
  2113 
  2114 subsection {* Inverse image of a function *}
  2115 
  2116 constdefs
  2117   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  2118   [code del]: "f -` B == {x. f x : B}"
  2119 
  2120 
  2121 subsubsection {* Basic rules *}
  2122 
  2123 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  2124   by (unfold vimage_def) blast
  2125 
  2126 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  2127   by simp
  2128 
  2129 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  2130   by (unfold vimage_def) blast
  2131 
  2132 lemma vimageI2: "f a : A ==> a : f -` A"
  2133   by (unfold vimage_def) fast
  2134 
  2135 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  2136   by (unfold vimage_def) blast
  2137 
  2138 lemma vimageD: "a : f -` A ==> f a : A"
  2139   by (unfold vimage_def) fast
  2140 
  2141 
  2142 subsubsection {* Equations *}
  2143 
  2144 lemma vimage_empty [simp]: "f -` {} = {}"
  2145   by blast
  2146 
  2147 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  2148   by blast
  2149 
  2150 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  2151   by blast
  2152 
  2153 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  2154   by fast
  2155 
  2156 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  2157   by blast
  2158 
  2159 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  2160   by blast
  2161 
  2162 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  2163   by blast
  2164 
  2165 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  2166   by blast
  2167 
  2168 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  2169   by blast
  2170 
  2171 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  2172   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  2173   by blast
  2174 
  2175 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  2176   by blast
  2177 
  2178 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  2179   by blast
  2180 
  2181 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  2182   -- {* NOT suitable for rewriting *}
  2183   by blast
  2184 
  2185 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  2186   -- {* monotonicity *}
  2187   by blast
  2188 
  2189 lemma vimage_image_eq [noatp]: "f -` (f ` A) = {y. EX x:A. f x = f y}"
  2190 by (blast intro: sym)
  2191 
  2192 lemma image_vimage_subset: "f ` (f -` A) <= A"
  2193 by blast
  2194 
  2195 lemma image_vimage_eq [simp]: "f ` (f -` A) = A Int range f"
  2196 by blast
  2197 
  2198 lemma image_Int_subset: "f`(A Int B) <= f`A Int f`B"
  2199 by blast
  2200 
  2201 lemma image_diff_subset: "f`A - f`B <= f`(A - B)"
  2202 by blast
  2203 
  2204 lemma image_UN: "(f ` (UNION A B)) = (UN x:A.(f ` (B x)))"
  2205 by blast
  2206 
  2207 
  2208 subsection {* Getting the Contents of a Singleton Set *}
  2209 
  2210 definition contents :: "'a set \<Rightarrow> 'a" where
  2211   [code del]: "contents X = (THE x. X = {x})"
  2212 
  2213 lemma contents_eq [simp]: "contents {x} = x"
  2214   by (simp add: contents_def)
  2215 
  2216 
  2217 subsection {* Transitivity rules for calculational reasoning *}
  2218 
  2219 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  2220   by (rule subsetD)
  2221 
  2222 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  2223   by (rule subsetD)
  2224 
  2225 lemmas basic_trans_rules [trans] =
  2226   order_trans_rules set_rev_mp set_mp
  2227 
  2228 
  2229 subsection {* Least value operator *}
  2230 
  2231 lemma Least_mono:
  2232   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  2233     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  2234     -- {* Courtesy of Stephan Merz *}
  2235   apply clarify
  2236   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
  2237   apply (rule LeastI2_order)
  2238   apply (auto elim: monoD intro!: order_antisym)
  2239   done
  2240 
  2241 
  2242 subsection {* Rudimentary code generation *}
  2243 
  2244 lemma empty_code [code]: "{} x \<longleftrightarrow> False"
  2245   unfolding empty_def Collect_def ..
  2246 
  2247 lemma UNIV_code [code]: "UNIV x \<longleftrightarrow> True"
  2248   unfolding UNIV_def Collect_def ..
  2249 
  2250 lemma insert_code [code]: "insert y A x \<longleftrightarrow> y = x \<or> A x"
  2251   unfolding insert_def Collect_def mem_def Un_def by auto
  2252 
  2253 lemma inter_code [code]: "(A \<inter> B) x \<longleftrightarrow> A x \<and> B x"
  2254   unfolding Int_def Collect_def mem_def ..
  2255 
  2256 lemma union_code [code]: "(A \<union> B) x \<longleftrightarrow> A x \<or> B x"
  2257   unfolding Un_def Collect_def mem_def ..
  2258 
  2259 lemma vimage_code [code]: "(f -` A) x = A (f x)"
  2260   unfolding vimage_def Collect_def mem_def ..
  2261 
  2262 
  2263 subsection {* Complete lattices *}
  2264 
  2265 notation
  2266   less_eq  (infix "\<sqsubseteq>" 50) and
  2267   less (infix "\<sqsubset>" 50) and
  2268   inf  (infixl "\<sqinter>" 70) and
  2269   sup  (infixl "\<squnion>" 65)
  2270 
  2271 class complete_lattice = lattice + bot + top +
  2272   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
  2273     and Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
  2274   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
  2275      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
  2276   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
  2277      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
  2278 begin
  2279 
  2280 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<le> a}"
  2281   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
  2282 
  2283 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<le> b}"
  2284   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
  2285 
  2286 lemma Inf_Univ: "\<Sqinter>UNIV = \<Squnion>{}"
  2287   unfolding Sup_Inf by auto
  2288 
  2289 lemma Sup_Univ: "\<Squnion>UNIV = \<Sqinter>{}"
  2290   unfolding Inf_Sup by auto
  2291 
  2292 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
  2293   by (auto intro: antisym Inf_greatest Inf_lower)
  2294 
  2295 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
  2296   by (auto intro: antisym Sup_least Sup_upper)
  2297 
  2298 lemma Inf_singleton [simp]:
  2299   "\<Sqinter>{a} = a"
  2300   by (auto intro: antisym Inf_lower Inf_greatest)
  2301 
  2302 lemma Sup_singleton [simp]:
  2303   "\<Squnion>{a} = a"
  2304   by (auto intro: antisym Sup_upper Sup_least)
  2305 
  2306 lemma Inf_insert_simp:
  2307   "\<Sqinter>insert a A = (if A = {} then a else a \<sqinter> \<Sqinter>A)"
  2308   by (cases "A = {}") (simp_all, simp add: Inf_insert)
  2309 
  2310 lemma Sup_insert_simp:
  2311   "\<Squnion>insert a A = (if A = {} then a else a \<squnion> \<Squnion>A)"
  2312   by (cases "A = {}") (simp_all, simp add: Sup_insert)
  2313 
  2314 lemma Inf_binary:
  2315   "\<Sqinter>{a, b} = a \<sqinter> b"
  2316   by (simp add: Inf_insert_simp)
  2317 
  2318 lemma Sup_binary:
  2319   "\<Squnion>{a, b} = a \<squnion> b"
  2320   by (simp add: Sup_insert_simp)
  2321 
  2322 lemma bot_def:
  2323   "bot = \<Squnion>{}"
  2324   by (auto intro: antisym Sup_least)
  2325 
  2326 lemma top_def:
  2327   "top = \<Sqinter>{}"
  2328   by (auto intro: antisym Inf_greatest)
  2329 
  2330 lemma sup_bot [simp]:
  2331   "x \<squnion> bot = x"
  2332   using bot_least [of x] by (simp add: le_iff_sup sup_commute)
  2333 
  2334 lemma inf_top [simp]:
  2335   "x \<sqinter> top = x"
  2336   using top_greatest [of x] by (simp add: le_iff_inf inf_commute)
  2337 
  2338 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
  2339   "SUPR A f == \<Squnion> (f ` A)"
  2340 
  2341 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
  2342   "INFI A f == \<Sqinter> (f ` A)"
  2343 
  2344 end
  2345 
  2346 syntax
  2347   "_SUP1"     :: "pttrns => 'b => 'b"           ("(3SUP _./ _)" [0, 10] 10)
  2348   "_SUP"      :: "pttrn => 'a set => 'b => 'b"  ("(3SUP _:_./ _)" [0, 10] 10)
  2349   "_INF1"     :: "pttrns => 'b => 'b"           ("(3INF _./ _)" [0, 10] 10)
  2350   "_INF"      :: "pttrn => 'a set => 'b => 'b"  ("(3INF _:_./ _)" [0, 10] 10)
  2351 
  2352 translations
  2353   "SUP x y. B"   == "SUP x. SUP y. B"
  2354   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
  2355   "SUP x. B"     == "SUP x:CONST UNIV. B"
  2356   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
  2357   "INF x y. B"   == "INF x. INF y. B"
  2358   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
  2359   "INF x. B"     == "INF x:CONST UNIV. B"
  2360   "INF x:A. B"   == "CONST INFI A (%x. B)"
  2361 
  2362 (* To avoid eta-contraction of body: *)
  2363 print_translation {*
  2364 let
  2365   fun btr' syn (A :: Abs abs :: ts) =
  2366     let val (x,t) = atomic_abs_tr' abs
  2367     in list_comb (Syntax.const syn $ x $ A $ t, ts) end
  2368   val const_syntax_name = Sign.const_syntax_name @{theory} o fst o dest_Const
  2369 in
  2370 [(const_syntax_name @{term SUPR}, btr' "_SUP"),(const_syntax_name @{term "INFI"}, btr' "_INF")]
  2371 end
  2372 *}
  2373 
  2374 context complete_lattice
  2375 begin
  2376 
  2377 lemma le_SUPI: "i : A \<Longrightarrow> M i \<le> (SUP i:A. M i)"
  2378   by (auto simp add: SUPR_def intro: Sup_upper)
  2379 
  2380 lemma SUP_leI: "(\<And>i. i : A \<Longrightarrow> M i \<le> u) \<Longrightarrow> (SUP i:A. M i) \<le> u"
  2381   by (auto simp add: SUPR_def intro: Sup_least)
  2382 
  2383 lemma INF_leI: "i : A \<Longrightarrow> (INF i:A. M i) \<le> M i"
  2384   by (auto simp add: INFI_def intro: Inf_lower)
  2385 
  2386 lemma le_INFI: "(\<And>i. i : A \<Longrightarrow> u \<le> M i) \<Longrightarrow> u \<le> (INF i:A. M i)"
  2387   by (auto simp add: INFI_def intro: Inf_greatest)
  2388 
  2389 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
  2390   by (auto intro: antisym SUP_leI le_SUPI)
  2391 
  2392 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
  2393   by (auto intro: antisym INF_leI le_INFI)
  2394 
  2395 end
  2396 
  2397 
  2398 subsection {* Bool as complete lattice *}
  2399 
  2400 instantiation bool :: complete_lattice
  2401 begin
  2402 
  2403 definition
  2404   Inf_bool_def: "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
  2405 
  2406 definition
  2407   Sup_bool_def: "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
  2408 
  2409 instance
  2410   by intro_classes (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
  2411 
  2412 end
  2413 
  2414 lemma Inf_empty_bool [simp]:
  2415   "\<Sqinter>{}"
  2416   unfolding Inf_bool_def by auto
  2417 
  2418 lemma not_Sup_empty_bool [simp]:
  2419   "\<not> \<Squnion>{}"
  2420   unfolding Sup_bool_def by auto
  2421 
  2422 
  2423 subsection {* Fun as complete lattice *}
  2424 
  2425 instantiation "fun" :: (type, complete_lattice) complete_lattice
  2426 begin
  2427 
  2428 definition
  2429   Inf_fun_def [code del]: "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
  2430 
  2431 definition
  2432   Sup_fun_def [code del]: "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
  2433 
  2434 instance
  2435   by intro_classes
  2436     (auto simp add: Inf_fun_def Sup_fun_def le_fun_def
  2437       intro: Inf_lower Sup_upper Inf_greatest Sup_least)
  2438 
  2439 end
  2440 
  2441 lemma Inf_empty_fun:
  2442   "\<Sqinter>{} = (\<lambda>_. \<Sqinter>{})"
  2443   by rule (auto simp add: Inf_fun_def)
  2444 
  2445 lemma Sup_empty_fun:
  2446   "\<Squnion>{} = (\<lambda>_. \<Squnion>{})"
  2447   by rule (auto simp add: Sup_fun_def)
  2448 
  2449 
  2450 subsection {* Set as lattice *}
  2451 
  2452 lemma inf_set_eq: "A \<sqinter> B = A \<inter> B"
  2453   apply (rule subset_antisym)
  2454   apply (rule Int_greatest)
  2455   apply (rule inf_le1)
  2456   apply (rule inf_le2)
  2457   apply (rule inf_greatest)
  2458   apply (rule Int_lower1)
  2459   apply (rule Int_lower2)
  2460   done
  2461 
  2462 lemma sup_set_eq: "A \<squnion> B = A \<union> B"
  2463   apply (rule subset_antisym)
  2464   apply (rule sup_least)
  2465   apply (rule Un_upper1)
  2466   apply (rule Un_upper2)
  2467   apply (rule Un_least)
  2468   apply (rule sup_ge1)
  2469   apply (rule sup_ge2)
  2470   done
  2471 
  2472 lemma mono_Int: "mono f \<Longrightarrow> f (A \<inter> B) \<subseteq> f A \<inter> f B"
  2473   apply (fold inf_set_eq sup_set_eq)
  2474   apply (erule mono_inf)
  2475   done
  2476 
  2477 lemma mono_Un: "mono f \<Longrightarrow> f A \<union> f B \<subseteq> f (A \<union> B)"
  2478   apply (fold inf_set_eq sup_set_eq)
  2479   apply (erule mono_sup)
  2480   done
  2481 
  2482 lemma Inf_set_eq: "\<Sqinter>S = \<Inter>S"
  2483   apply (rule subset_antisym)
  2484   apply (rule Inter_greatest)
  2485   apply (erule Inf_lower)
  2486   apply (rule Inf_greatest)
  2487   apply (erule Inter_lower)
  2488   done
  2489 
  2490 lemma Sup_set_eq: "\<Squnion>S = \<Union>S"
  2491   apply (rule subset_antisym)
  2492   apply (rule Sup_least)
  2493   apply (erule Union_upper)
  2494   apply (rule Union_least)
  2495   apply (erule Sup_upper)
  2496   done
  2497   
  2498 lemma top_set_eq: "top = UNIV"
  2499   by (iprover intro!: subset_antisym subset_UNIV top_greatest)
  2500 
  2501 lemma bot_set_eq: "bot = {}"
  2502   by (iprover intro!: subset_antisym empty_subsetI bot_least)
  2503 
  2504 no_notation
  2505   less_eq  (infix "\<sqsubseteq>" 50) and
  2506   less (infix "\<sqsubset>" 50) and
  2507   inf  (infixl "\<sqinter>" 70) and
  2508   sup  (infixl "\<squnion>" 65) and
  2509   Inf  ("\<Sqinter>_" [900] 900) and
  2510   Sup  ("\<Squnion>_" [900] 900)
  2511 
  2512 
  2513 subsection {* Misc theorem and ML bindings *}
  2514 
  2515 lemmas equalityI = subset_antisym
  2516 lemmas mem_simps =
  2517   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  2518   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  2519   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  2520 
  2521 ML {*
  2522 val Ball_def = @{thm Ball_def}
  2523 val Bex_def = @{thm Bex_def}
  2524 val CollectD = @{thm CollectD}
  2525 val CollectE = @{thm CollectE}
  2526 val CollectI = @{thm CollectI}
  2527 val Collect_conj_eq = @{thm Collect_conj_eq}
  2528 val Collect_mem_eq = @{thm Collect_mem_eq}
  2529 val IntD1 = @{thm IntD1}
  2530 val IntD2 = @{thm IntD2}
  2531 val IntE = @{thm IntE}
  2532 val IntI = @{thm IntI}
  2533 val Int_Collect = @{thm Int_Collect}
  2534 val UNIV_I = @{thm UNIV_I}
  2535 val UNIV_witness = @{thm UNIV_witness}
  2536 val UnE = @{thm UnE}
  2537 val UnI1 = @{thm UnI1}
  2538 val UnI2 = @{thm UnI2}
  2539 val ballE = @{thm ballE}
  2540 val ballI = @{thm ballI}
  2541 val bexCI = @{thm bexCI}
  2542 val bexE = @{thm bexE}
  2543 val bexI = @{thm bexI}
  2544 val bex_triv = @{thm bex_triv}
  2545 val bspec = @{thm bspec}
  2546 val contra_subsetD = @{thm contra_subsetD}
  2547 val distinct_lemma = @{thm distinct_lemma}
  2548 val eq_to_mono = @{thm eq_to_mono}
  2549 val eq_to_mono2 = @{thm eq_to_mono2}
  2550 val equalityCE = @{thm equalityCE}
  2551 val equalityD1 = @{thm equalityD1}
  2552 val equalityD2 = @{thm equalityD2}
  2553 val equalityE = @{thm equalityE}
  2554 val equalityI = @{thm equalityI}
  2555 val imageE = @{thm imageE}
  2556 val imageI = @{thm imageI}
  2557 val image_Un = @{thm image_Un}
  2558 val image_insert = @{thm image_insert}
  2559 val insert_commute = @{thm insert_commute}
  2560 val insert_iff = @{thm insert_iff}
  2561 val mem_Collect_eq = @{thm mem_Collect_eq}
  2562 val rangeE = @{thm rangeE}
  2563 val rangeI = @{thm rangeI}
  2564 val range_eqI = @{thm range_eqI}
  2565 val subsetCE = @{thm subsetCE}
  2566 val subsetD = @{thm subsetD}
  2567 val subsetI = @{thm subsetI}
  2568 val subset_refl = @{thm subset_refl}
  2569 val subset_trans = @{thm subset_trans}
  2570 val vimageD = @{thm vimageD}
  2571 val vimageE = @{thm vimageE}
  2572 val vimageI = @{thm vimageI}
  2573 val vimageI2 = @{thm vimageI2}
  2574 val vimage_Collect = @{thm vimage_Collect}
  2575 val vimage_Int = @{thm vimage_Int}
  2576 val vimage_Un = @{thm vimage_Un}
  2577 *}
  2578 
  2579 end