src/HOL/Library/FuncSet.thy
author haftmann
Tue Jun 23 11:31:28 2009 +0200 (2009-06-23)
changeset 31769 d5f39775edd2
parent 31731 7ffc1a901eea
child 31770 ba52fcfaec28
permissions -rw-r--r--
lemma funcset_id by Jeremy Avigad
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson
     3 *)
     4 
     5 header {* Pi and Function Sets *}
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition
    12   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    13   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    14 
    15 definition
    16   extensional :: "'a set => ('a => 'b) set" where
    17   "extensional A = {f. \<forall>x. x~:A --> f x = undefined}"
    18 
    19 definition
    20   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    21   "restrict f A = (%x. if x \<in> A then f x else undefined)"
    22 
    23 abbreviation
    24   funcset :: "['a set, 'b set] => ('a => 'b) set"
    25     (infixr "->" 60) where
    26   "A -> B == Pi A (%_. B)"
    27 
    28 notation (xsymbols)
    29   funcset  (infixr "\<rightarrow>" 60)
    30 
    31 syntax
    32   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    33   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    34 
    35 syntax (xsymbols)
    36   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    37   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    38 
    39 syntax (HTML output)
    40   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    41   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    42 
    43 translations
    44   "PI x:A. B" == "CONST Pi A (%x. B)"
    45   "%x:A. f" == "CONST restrict (%x. f) A"
    46 
    47 definition
    48   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    49   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    50 
    51 
    52 subsection{*Basic Properties of @{term Pi}*}
    53 
    54 lemma Pi_I: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_I'[simp]: "(!!x. x : A --> f x : B x) ==> f : Pi A B"
    58 by(simp add:Pi_def)
    59 
    60 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    61   by (simp add: Pi_def)
    62 
    63 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    64   by (simp add: Pi_def)
    65 
    66 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    67   by (auto intro: Pi_I)
    68 
    69 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    70   by (simp add: Pi_def)
    71 
    72 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    73   by (auto simp add: Pi_def)
    74 
    75 lemma Pi_eq_empty: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    76 apply (simp add: Pi_def, auto)
    77 txt{*Converse direction requires Axiom of Choice to exhibit a function
    78 picking an element from each non-empty @{term "B x"}*}
    79 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    80 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    81 done
    82 
    83 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    84   by (simp add: Pi_def)
    85 
    86 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    87   by (simp add: Pi_def)
    88 (*
    89 lemma funcset_id [simp]: "(%x. x): A -> A"
    90   by (simp add: Pi_def)
    91 *)
    92 text{*Covariance of Pi-sets in their second argument*}
    93 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
    94   by (simp add: Pi_def, blast)
    95 
    96 text{*Contravariance of Pi-sets in their first argument*}
    97 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
    98   by (simp add: Pi_def, blast)
    99 
   100 
   101 subsection{*Composition With a Restricted Domain: @{term compose}*}
   102 
   103 lemma funcset_compose:
   104     "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
   105   by (simp add: Pi_def compose_def restrict_def)
   106 
   107 lemma compose_assoc:
   108     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   109       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   110   by (simp add: expand_fun_eq Pi_def compose_def restrict_def)
   111 
   112 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   113   by (simp add: compose_def restrict_def)
   114 
   115 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   116   by (auto simp add: image_def compose_eq)
   117 
   118 
   119 subsection{*Bounded Abstraction: @{term restrict}*}
   120 
   121 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   122   by (simp add: Pi_def restrict_def)
   123 
   124 lemma restrictI: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   125   by (simp add: Pi_def restrict_def)
   126 
   127 lemma restrict_apply [simp]:
   128     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   129   by (simp add: restrict_def)
   130 
   131 lemma restrict_ext:
   132     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   133   by (simp add: expand_fun_eq Pi_def Pi_def restrict_def)
   134 
   135 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   136   by (simp add: inj_on_def restrict_def)
   137 
   138 lemma Id_compose:
   139     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   140   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   141 
   142 lemma compose_Id:
   143     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   144   by (auto simp add: expand_fun_eq compose_def extensional_def Pi_def)
   145 
   146 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   147   by (auto simp add: restrict_def)
   148 
   149 
   150 subsection{*Bijections Between Sets*}
   151 
   152 text{*The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   153 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   154 
   155 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   156   by (auto simp add: bij_betw_def inj_on_Inv Pi_def)
   157 
   158 lemma inj_on_compose:
   159     "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   160   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   161 
   162 lemma bij_betw_compose:
   163     "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   164   apply (simp add: bij_betw_def compose_eq inj_on_compose)
   165   apply (auto simp add: compose_def image_def)
   166   done
   167 
   168 lemma bij_betw_restrict_eq [simp]:
   169      "bij_betw (restrict f A) A B = bij_betw f A B"
   170   by (simp add: bij_betw_def)
   171 
   172 
   173 subsection{*Extensionality*}
   174 
   175 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = undefined"
   176   by (simp add: extensional_def)
   177 
   178 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   179   by (simp add: restrict_def extensional_def)
   180 
   181 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   182   by (simp add: compose_def)
   183 
   184 lemma extensionalityI:
   185     "[| f \<in> extensional A; g \<in> extensional A;
   186       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   187   by (force simp add: expand_fun_eq extensional_def)
   188 
   189 lemma Inv_funcset: "f ` A = B ==> (\<lambda>x\<in>B. Inv A f x) : B -> A"
   190   by (unfold Inv_def) (fast intro: restrict_in_funcset someI2)
   191 
   192 lemma compose_Inv_id:
   193     "bij_betw f A B ==> compose A (\<lambda>y\<in>B. Inv A f y) f = (\<lambda>x\<in>A. x)"
   194   apply (simp add: bij_betw_def compose_def)
   195   apply (rule restrict_ext, auto)
   196   apply (erule subst)
   197   apply (simp add: Inv_f_f)
   198   done
   199 
   200 lemma compose_id_Inv:
   201     "f ` A = B ==> compose B f (\<lambda>y\<in>B. Inv A f y) = (\<lambda>x\<in>B. x)"
   202   apply (simp add: compose_def)
   203   apply (rule restrict_ext)
   204   apply (simp add: f_Inv_f)
   205   done
   206 
   207 
   208 subsection{*Cardinality*}
   209 
   210 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   211   apply (rule card_inj_on_le)
   212     apply (auto simp add: Pi_def)
   213   done
   214 
   215 lemma card_bij:
   216      "[|f \<in> A\<rightarrow>B; inj_on f A;
   217         g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   218   by (blast intro: card_inj order_antisym)
   219 
   220 end