src/HOL/Divides.thy
author huffman
Tue Mar 27 14:49:56 2012 +0200 (2012-03-27)
changeset 47142 d64fa2ca54b8
parent 47141 02d6b816e4b3
child 47159 978c00c20a59
permissions -rw-r--r--
remove redundant lemmas
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Numeral Nat_Transfer
    10 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    11 begin
    12 
    13 subsection {* Syntactic division operations *}
    14 
    15 class div = dvd +
    16   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    17     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    18 
    19 
    20 subsection {* Abstract division in commutative semirings. *}
    21 
    22 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    23   assumes mod_div_equality: "a div b * b + a mod b = a"
    24     and div_by_0 [simp]: "a div 0 = 0"
    25     and div_0 [simp]: "0 div a = 0"
    26     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    27     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    28 begin
    29 
    30 text {* @{const div} and @{const mod} *}
    31 
    32 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    33   unfolding mult_commute [of b]
    34   by (rule mod_div_equality)
    35 
    36 lemma mod_div_equality': "a mod b + a div b * b = a"
    37   using mod_div_equality [of a b]
    38   by (simp only: add_ac)
    39 
    40 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    41   by (simp add: mod_div_equality)
    42 
    43 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    44   by (simp add: mod_div_equality2)
    45 
    46 lemma mod_by_0 [simp]: "a mod 0 = a"
    47   using mod_div_equality [of a zero] by simp
    48 
    49 lemma mod_0 [simp]: "0 mod a = 0"
    50   using mod_div_equality [of zero a] div_0 by simp
    51 
    52 lemma div_mult_self2 [simp]:
    53   assumes "b \<noteq> 0"
    54   shows "(a + b * c) div b = c + a div b"
    55   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    56 
    57 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    58 proof (cases "b = 0")
    59   case True then show ?thesis by simp
    60 next
    61   case False
    62   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    63     by (simp add: mod_div_equality)
    64   also from False div_mult_self1 [of b a c] have
    65     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    66       by (simp add: algebra_simps)
    67   finally have "a = a div b * b + (a + c * b) mod b"
    68     by (simp add: add_commute [of a] add_assoc left_distrib)
    69   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    70     by (simp add: mod_div_equality)
    71   then show ?thesis by simp
    72 qed
    73 
    74 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    75   by (simp add: mult_commute [of b])
    76 
    77 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    78   using div_mult_self2 [of b 0 a] by simp
    79 
    80 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    81   using div_mult_self1 [of b 0 a] by simp
    82 
    83 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    84   using mod_mult_self2 [of 0 b a] by simp
    85 
    86 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    87   using mod_mult_self1 [of 0 a b] by simp
    88 
    89 lemma div_by_1 [simp]: "a div 1 = a"
    90   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    91 
    92 lemma mod_by_1 [simp]: "a mod 1 = 0"
    93 proof -
    94   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    95   then have "a + a mod 1 = a + 0" by simp
    96   then show ?thesis by (rule add_left_imp_eq)
    97 qed
    98 
    99 lemma mod_self [simp]: "a mod a = 0"
   100   using mod_mult_self2_is_0 [of 1] by simp
   101 
   102 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   103   using div_mult_self2_is_id [of _ 1] by simp
   104 
   105 lemma div_add_self1 [simp]:
   106   assumes "b \<noteq> 0"
   107   shows "(b + a) div b = a div b + 1"
   108   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   109 
   110 lemma div_add_self2 [simp]:
   111   assumes "b \<noteq> 0"
   112   shows "(a + b) div b = a div b + 1"
   113   using assms div_add_self1 [of b a] by (simp add: add_commute)
   114 
   115 lemma mod_add_self1 [simp]:
   116   "(b + a) mod b = a mod b"
   117   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   118 
   119 lemma mod_add_self2 [simp]:
   120   "(a + b) mod b = a mod b"
   121   using mod_mult_self1 [of a 1 b] by simp
   122 
   123 lemma mod_div_decomp:
   124   fixes a b
   125   obtains q r where "q = a div b" and "r = a mod b"
   126     and "a = q * b + r"
   127 proof -
   128   from mod_div_equality have "a = a div b * b + a mod b" by simp
   129   moreover have "a div b = a div b" ..
   130   moreover have "a mod b = a mod b" ..
   131   note that ultimately show thesis by blast
   132 qed
   133 
   134 lemma dvd_eq_mod_eq_0 [code]: "a dvd b \<longleftrightarrow> b mod a = 0"
   135 proof
   136   assume "b mod a = 0"
   137   with mod_div_equality [of b a] have "b div a * a = b" by simp
   138   then have "b = a * (b div a)" unfolding mult_commute ..
   139   then have "\<exists>c. b = a * c" ..
   140   then show "a dvd b" unfolding dvd_def .
   141 next
   142   assume "a dvd b"
   143   then have "\<exists>c. b = a * c" unfolding dvd_def .
   144   then obtain c where "b = a * c" ..
   145   then have "b mod a = a * c mod a" by simp
   146   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   147   then show "b mod a = 0" by simp
   148 qed
   149 
   150 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   151 proof (cases "b = 0")
   152   assume "b = 0"
   153   thus ?thesis by simp
   154 next
   155   assume "b \<noteq> 0"
   156   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   157     by (rule div_mult_self1 [symmetric])
   158   also have "\<dots> = a div b"
   159     by (simp only: mod_div_equality')
   160   also have "\<dots> = a div b + 0"
   161     by simp
   162   finally show ?thesis
   163     by (rule add_left_imp_eq)
   164 qed
   165 
   166 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   167 proof -
   168   have "a mod b mod b = (a mod b + a div b * b) mod b"
   169     by (simp only: mod_mult_self1)
   170   also have "\<dots> = a mod b"
   171     by (simp only: mod_div_equality')
   172   finally show ?thesis .
   173 qed
   174 
   175 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   176 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   177 
   178 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   179 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   180 
   181 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   182 by (drule dvd_div_mult_self) (simp add: mult_commute)
   183 
   184 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   185 apply (cases "a = 0")
   186  apply simp
   187 apply (auto simp: dvd_def mult_assoc)
   188 done
   189 
   190 lemma div_dvd_div[simp]:
   191   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   192 apply (cases "a = 0")
   193  apply simp
   194 apply (unfold dvd_def)
   195 apply auto
   196  apply(blast intro:mult_assoc[symmetric])
   197 apply(fastforce simp add: mult_assoc)
   198 done
   199 
   200 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   201   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   202    apply (simp add: mod_div_equality)
   203   apply (simp only: dvd_add dvd_mult)
   204   done
   205 
   206 text {* Addition respects modular equivalence. *}
   207 
   208 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   209 proof -
   210   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   211     by (simp only: mod_div_equality)
   212   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   213     by (simp only: add_ac)
   214   also have "\<dots> = (a mod c + b) mod c"
   215     by (rule mod_mult_self1)
   216   finally show ?thesis .
   217 qed
   218 
   219 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   220 proof -
   221   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   222     by (simp only: mod_div_equality)
   223   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   224     by (simp only: add_ac)
   225   also have "\<dots> = (a + b mod c) mod c"
   226     by (rule mod_mult_self1)
   227   finally show ?thesis .
   228 qed
   229 
   230 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   231 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   232 
   233 lemma mod_add_cong:
   234   assumes "a mod c = a' mod c"
   235   assumes "b mod c = b' mod c"
   236   shows "(a + b) mod c = (a' + b') mod c"
   237 proof -
   238   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   239     unfolding assms ..
   240   thus ?thesis
   241     by (simp only: mod_add_eq [symmetric])
   242 qed
   243 
   244 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   245   \<Longrightarrow> (x + y) div z = x div z + y div z"
   246 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   247 
   248 text {* Multiplication respects modular equivalence. *}
   249 
   250 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   251 proof -
   252   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   253     by (simp only: mod_div_equality)
   254   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   255     by (simp only: algebra_simps)
   256   also have "\<dots> = (a mod c * b) mod c"
   257     by (rule mod_mult_self1)
   258   finally show ?thesis .
   259 qed
   260 
   261 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   262 proof -
   263   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   264     by (simp only: mod_div_equality)
   265   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   266     by (simp only: algebra_simps)
   267   also have "\<dots> = (a * (b mod c)) mod c"
   268     by (rule mod_mult_self1)
   269   finally show ?thesis .
   270 qed
   271 
   272 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   273 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   274 
   275 lemma mod_mult_cong:
   276   assumes "a mod c = a' mod c"
   277   assumes "b mod c = b' mod c"
   278   shows "(a * b) mod c = (a' * b') mod c"
   279 proof -
   280   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   281     unfolding assms ..
   282   thus ?thesis
   283     by (simp only: mod_mult_eq [symmetric])
   284 qed
   285 
   286 lemma mod_mod_cancel:
   287   assumes "c dvd b"
   288   shows "a mod b mod c = a mod c"
   289 proof -
   290   from `c dvd b` obtain k where "b = c * k"
   291     by (rule dvdE)
   292   have "a mod b mod c = a mod (c * k) mod c"
   293     by (simp only: `b = c * k`)
   294   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   295     by (simp only: mod_mult_self1)
   296   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   297     by (simp only: add_ac mult_ac)
   298   also have "\<dots> = a mod c"
   299     by (simp only: mod_div_equality)
   300   finally show ?thesis .
   301 qed
   302 
   303 lemma div_mult_div_if_dvd:
   304   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   305   apply (cases "y = 0", simp)
   306   apply (cases "z = 0", simp)
   307   apply (auto elim!: dvdE simp add: algebra_simps)
   308   apply (subst mult_assoc [symmetric])
   309   apply (simp add: no_zero_divisors)
   310   done
   311 
   312 lemma div_mult_swap:
   313   assumes "c dvd b"
   314   shows "a * (b div c) = (a * b) div c"
   315 proof -
   316   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   317     by (simp only: div_mult_div_if_dvd one_dvd)
   318   then show ?thesis by (simp add: mult_commute)
   319 qed
   320    
   321 lemma div_mult_mult2 [simp]:
   322   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   323   by (drule div_mult_mult1) (simp add: mult_commute)
   324 
   325 lemma div_mult_mult1_if [simp]:
   326   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   327   by simp_all
   328 
   329 lemma mod_mult_mult1:
   330   "(c * a) mod (c * b) = c * (a mod b)"
   331 proof (cases "c = 0")
   332   case True then show ?thesis by simp
   333 next
   334   case False
   335   from mod_div_equality
   336   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   337   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   338     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   339   with mod_div_equality show ?thesis by simp 
   340 qed
   341   
   342 lemma mod_mult_mult2:
   343   "(a * c) mod (b * c) = (a mod b) * c"
   344   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   345 
   346 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   347   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   348 
   349 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   350 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   351 
   352 lemma div_power:
   353   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   354 apply (induct n)
   355  apply simp
   356 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   357 done
   358 
   359 lemma dvd_div_eq_mult:
   360   assumes "a \<noteq> 0" and "a dvd b"  
   361   shows "b div a = c \<longleftrightarrow> b = c * a"
   362 proof
   363   assume "b = c * a"
   364   then show "b div a = c" by (simp add: assms)
   365 next
   366   assume "b div a = c"
   367   then have "b div a * a = c * a" by simp
   368   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   369   ultimately show "b = c * a" by simp
   370 qed
   371    
   372 lemma dvd_div_div_eq_mult:
   373   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   374   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   375   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   376 
   377 end
   378 
   379 class ring_div = semiring_div + comm_ring_1
   380 begin
   381 
   382 subclass ring_1_no_zero_divisors ..
   383 
   384 text {* Negation respects modular equivalence. *}
   385 
   386 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   387 proof -
   388   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   389     by (simp only: mod_div_equality)
   390   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   391     by (simp only: minus_add_distrib minus_mult_left add_ac)
   392   also have "\<dots> = (- (a mod b)) mod b"
   393     by (rule mod_mult_self1)
   394   finally show ?thesis .
   395 qed
   396 
   397 lemma mod_minus_cong:
   398   assumes "a mod b = a' mod b"
   399   shows "(- a) mod b = (- a') mod b"
   400 proof -
   401   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   402     unfolding assms ..
   403   thus ?thesis
   404     by (simp only: mod_minus_eq [symmetric])
   405 qed
   406 
   407 text {* Subtraction respects modular equivalence. *}
   408 
   409 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   410   unfolding diff_minus
   411   by (intro mod_add_cong mod_minus_cong) simp_all
   412 
   413 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   414   unfolding diff_minus
   415   by (intro mod_add_cong mod_minus_cong) simp_all
   416 
   417 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   418   unfolding diff_minus
   419   by (intro mod_add_cong mod_minus_cong) simp_all
   420 
   421 lemma mod_diff_cong:
   422   assumes "a mod c = a' mod c"
   423   assumes "b mod c = b' mod c"
   424   shows "(a - b) mod c = (a' - b') mod c"
   425   unfolding diff_minus using assms
   426   by (intro mod_add_cong mod_minus_cong)
   427 
   428 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   429 apply (case_tac "y = 0") apply simp
   430 apply (auto simp add: dvd_def)
   431 apply (subgoal_tac "-(y * k) = y * - k")
   432  apply (erule ssubst)
   433  apply (erule div_mult_self1_is_id)
   434 apply simp
   435 done
   436 
   437 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   438 apply (case_tac "y = 0") apply simp
   439 apply (auto simp add: dvd_def)
   440 apply (subgoal_tac "y * k = -y * -k")
   441  apply (erule ssubst)
   442  apply (rule div_mult_self1_is_id)
   443  apply simp
   444 apply simp
   445 done
   446 
   447 end
   448 
   449 
   450 subsection {* Division on @{typ nat} *}
   451 
   452 text {*
   453   We define @{const div} and @{const mod} on @{typ nat} by means
   454   of a characteristic relation with two input arguments
   455   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   456   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   457 *}
   458 
   459 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   460   "divmod_nat_rel m n qr \<longleftrightarrow>
   461     m = fst qr * n + snd qr \<and>
   462       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   463 
   464 text {* @{const divmod_nat_rel} is total: *}
   465 
   466 lemma divmod_nat_rel_ex:
   467   obtains q r where "divmod_nat_rel m n (q, r)"
   468 proof (cases "n = 0")
   469   case True  with that show thesis
   470     by (auto simp add: divmod_nat_rel_def)
   471 next
   472   case False
   473   have "\<exists>q r. m = q * n + r \<and> r < n"
   474   proof (induct m)
   475     case 0 with `n \<noteq> 0`
   476     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   477     then show ?case by blast
   478   next
   479     case (Suc m) then obtain q' r'
   480       where m: "m = q' * n + r'" and n: "r' < n" by auto
   481     then show ?case proof (cases "Suc r' < n")
   482       case True
   483       from m n have "Suc m = q' * n + Suc r'" by simp
   484       with True show ?thesis by blast
   485     next
   486       case False then have "n \<le> Suc r'" by auto
   487       moreover from n have "Suc r' \<le> n" by auto
   488       ultimately have "n = Suc r'" by auto
   489       with m have "Suc m = Suc q' * n + 0" by simp
   490       with `n \<noteq> 0` show ?thesis by blast
   491     qed
   492   qed
   493   with that show thesis
   494     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   495 qed
   496 
   497 text {* @{const divmod_nat_rel} is injective: *}
   498 
   499 lemma divmod_nat_rel_unique:
   500   assumes "divmod_nat_rel m n qr"
   501     and "divmod_nat_rel m n qr'"
   502   shows "qr = qr'"
   503 proof (cases "n = 0")
   504   case True with assms show ?thesis
   505     by (cases qr, cases qr')
   506       (simp add: divmod_nat_rel_def)
   507 next
   508   case False
   509   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   510   apply (rule leI)
   511   apply (subst less_iff_Suc_add)
   512   apply (auto simp add: add_mult_distrib)
   513   done
   514   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   515     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   516   moreover from this assms have "snd qr = snd qr'"
   517     by (simp add: divmod_nat_rel_def)
   518   ultimately show ?thesis by (cases qr, cases qr') simp
   519 qed
   520 
   521 text {*
   522   We instantiate divisibility on the natural numbers by
   523   means of @{const divmod_nat_rel}:
   524 *}
   525 
   526 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   527   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   528 
   529 lemma divmod_nat_rel_divmod_nat:
   530   "divmod_nat_rel m n (divmod_nat m n)"
   531 proof -
   532   from divmod_nat_rel_ex
   533     obtain qr where rel: "divmod_nat_rel m n qr" .
   534   then show ?thesis
   535   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   536 qed
   537 
   538 lemma divmod_nat_unique:
   539   assumes "divmod_nat_rel m n qr" 
   540   shows "divmod_nat m n = qr"
   541   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   542 
   543 instantiation nat :: semiring_div
   544 begin
   545 
   546 definition div_nat where
   547   "m div n = fst (divmod_nat m n)"
   548 
   549 lemma fst_divmod_nat [simp]:
   550   "fst (divmod_nat m n) = m div n"
   551   by (simp add: div_nat_def)
   552 
   553 definition mod_nat where
   554   "m mod n = snd (divmod_nat m n)"
   555 
   556 lemma snd_divmod_nat [simp]:
   557   "snd (divmod_nat m n) = m mod n"
   558   by (simp add: mod_nat_def)
   559 
   560 lemma divmod_nat_div_mod:
   561   "divmod_nat m n = (m div n, m mod n)"
   562   by (simp add: prod_eq_iff)
   563 
   564 lemma div_nat_unique:
   565   assumes "divmod_nat_rel m n (q, r)" 
   566   shows "m div n = q"
   567   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   568 
   569 lemma mod_nat_unique:
   570   assumes "divmod_nat_rel m n (q, r)" 
   571   shows "m mod n = r"
   572   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   573 
   574 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   575   using divmod_nat_rel_divmod_nat by (simp add: divmod_nat_div_mod)
   576 
   577 lemma divmod_nat_zero: "divmod_nat m 0 = (0, m)"
   578   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   579 
   580 lemma divmod_nat_zero_left: "divmod_nat 0 n = (0, 0)"
   581   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   582 
   583 lemma divmod_nat_base: "m < n \<Longrightarrow> divmod_nat m n = (0, m)"
   584   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   585 
   586 lemma divmod_nat_step:
   587   assumes "0 < n" and "n \<le> m"
   588   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   589 proof (rule divmod_nat_unique)
   590   have "divmod_nat_rel (m - n) n ((m - n) div n, (m - n) mod n)"
   591     by (rule divmod_nat_rel)
   592   thus "divmod_nat_rel m n (Suc ((m - n) div n), (m - n) mod n)"
   593     unfolding divmod_nat_rel_def using assms by auto
   594 qed
   595 
   596 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   597 
   598 lemma div_less [simp]:
   599   fixes m n :: nat
   600   assumes "m < n"
   601   shows "m div n = 0"
   602   using assms divmod_nat_base by (simp add: prod_eq_iff)
   603 
   604 lemma le_div_geq:
   605   fixes m n :: nat
   606   assumes "0 < n" and "n \<le> m"
   607   shows "m div n = Suc ((m - n) div n)"
   608   using assms divmod_nat_step by (simp add: prod_eq_iff)
   609 
   610 lemma mod_less [simp]:
   611   fixes m n :: nat
   612   assumes "m < n"
   613   shows "m mod n = m"
   614   using assms divmod_nat_base by (simp add: prod_eq_iff)
   615 
   616 lemma le_mod_geq:
   617   fixes m n :: nat
   618   assumes "n \<le> m"
   619   shows "m mod n = (m - n) mod n"
   620   using assms divmod_nat_step by (cases "n = 0") (simp_all add: prod_eq_iff)
   621 
   622 instance proof
   623   fix m n :: nat
   624   show "m div n * n + m mod n = m"
   625     using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   626 next
   627   fix m n q :: nat
   628   assume "n \<noteq> 0"
   629   then show "(q + m * n) div n = m + q div n"
   630     by (induct m) (simp_all add: le_div_geq)
   631 next
   632   fix m n q :: nat
   633   assume "m \<noteq> 0"
   634   hence "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   635     unfolding divmod_nat_rel_def
   636     by (auto split: split_if_asm, simp_all add: algebra_simps)
   637   moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   638   ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   639   thus "(m * n) div (m * q) = n div q" by (rule div_nat_unique)
   640 next
   641   fix n :: nat show "n div 0 = 0"
   642     by (simp add: div_nat_def divmod_nat_zero)
   643 next
   644   fix n :: nat show "0 div n = 0"
   645     by (simp add: div_nat_def divmod_nat_zero_left)
   646 qed
   647 
   648 end
   649 
   650 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   651   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   652   by (simp add: prod_eq_iff prod_case_beta not_less le_div_geq le_mod_geq)
   653 
   654 text {* Simproc for cancelling @{const div} and @{const mod} *}
   655 
   656 ML {*
   657 structure Cancel_Div_Mod_Nat = Cancel_Div_Mod
   658 (
   659   val div_name = @{const_name div};
   660   val mod_name = @{const_name mod};
   661   val mk_binop = HOLogic.mk_binop;
   662   val mk_sum = Nat_Arith.mk_sum;
   663   val dest_sum = Nat_Arith.dest_sum;
   664 
   665   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   666 
   667   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   668     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   669 )
   670 *}
   671 
   672 simproc_setup cancel_div_mod_nat ("(m::nat) + n") = {* K Cancel_Div_Mod_Nat.proc *}
   673 
   674 
   675 subsubsection {* Quotient *}
   676 
   677 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   678 by (simp add: le_div_geq linorder_not_less)
   679 
   680 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   681 by (simp add: div_geq)
   682 
   683 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   684 by simp
   685 
   686 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   687 by simp
   688 
   689 
   690 subsubsection {* Remainder *}
   691 
   692 lemma mod_less_divisor [simp]:
   693   fixes m n :: nat
   694   assumes "n > 0"
   695   shows "m mod n < (n::nat)"
   696   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   697 
   698 lemma mod_less_eq_dividend [simp]:
   699   fixes m n :: nat
   700   shows "m mod n \<le> m"
   701 proof (rule add_leD2)
   702   from mod_div_equality have "m div n * n + m mod n = m" .
   703   then show "m div n * n + m mod n \<le> m" by auto
   704 qed
   705 
   706 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   707 by (simp add: le_mod_geq linorder_not_less)
   708 
   709 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   710 by (simp add: le_mod_geq)
   711 
   712 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   713 by (induct m) (simp_all add: mod_geq)
   714 
   715 lemma mod_mult_distrib: "(m mod n) * (k\<Colon>nat) = (m * k) mod (n * k)"
   716   by (fact mod_mult_mult2 [symmetric]) (* FIXME: generalize *)
   717 
   718 lemma mod_mult_distrib2: "(k::nat) * (m mod n) = (k*m) mod (k*n)"
   719   by (fact mod_mult_mult1 [symmetric]) (* FIXME: generalize *)
   720 
   721 (* a simple rearrangement of mod_div_equality: *)
   722 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   723   using mod_div_equality2 [of n m] by arith
   724 
   725 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   726   apply (drule mod_less_divisor [where m = m])
   727   apply simp
   728   done
   729 
   730 subsubsection {* Quotient and Remainder *}
   731 
   732 lemma divmod_nat_rel_mult1_eq:
   733   "divmod_nat_rel b c (q, r)
   734    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   735 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   736 
   737 lemma div_mult1_eq:
   738   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   739 by (blast intro: divmod_nat_rel_mult1_eq [THEN div_nat_unique] divmod_nat_rel)
   740 
   741 lemma divmod_nat_rel_add1_eq:
   742   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br)
   743    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   744 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   745 
   746 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   747 lemma div_add1_eq:
   748   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   749 by (blast intro: divmod_nat_rel_add1_eq [THEN div_nat_unique] divmod_nat_rel)
   750 
   751 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   752   apply (cut_tac m = q and n = c in mod_less_divisor)
   753   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   754   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   755   apply (simp add: add_mult_distrib2)
   756   done
   757 
   758 lemma divmod_nat_rel_mult2_eq:
   759   "divmod_nat_rel a b (q, r)
   760    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   761 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   762 
   763 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   764 by (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_nat_unique])
   765 
   766 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   767 by (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_nat_unique])
   768 
   769 
   770 subsubsection {* Further Facts about Quotient and Remainder *}
   771 
   772 lemma div_1 [simp]: "m div Suc 0 = m"
   773 by (induct m) (simp_all add: div_geq)
   774 
   775 (* Monotonicity of div in first argument *)
   776 lemma div_le_mono [rule_format (no_asm)]:
   777     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   778 apply (case_tac "k=0", simp)
   779 apply (induct "n" rule: nat_less_induct, clarify)
   780 apply (case_tac "n<k")
   781 (* 1  case n<k *)
   782 apply simp
   783 (* 2  case n >= k *)
   784 apply (case_tac "m<k")
   785 (* 2.1  case m<k *)
   786 apply simp
   787 (* 2.2  case m>=k *)
   788 apply (simp add: div_geq diff_le_mono)
   789 done
   790 
   791 (* Antimonotonicity of div in second argument *)
   792 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   793 apply (subgoal_tac "0<n")
   794  prefer 2 apply simp
   795 apply (induct_tac k rule: nat_less_induct)
   796 apply (rename_tac "k")
   797 apply (case_tac "k<n", simp)
   798 apply (subgoal_tac "~ (k<m) ")
   799  prefer 2 apply simp
   800 apply (simp add: div_geq)
   801 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   802  prefer 2
   803  apply (blast intro: div_le_mono diff_le_mono2)
   804 apply (rule le_trans, simp)
   805 apply (simp)
   806 done
   807 
   808 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   809 apply (case_tac "n=0", simp)
   810 apply (subgoal_tac "m div n \<le> m div 1", simp)
   811 apply (rule div_le_mono2)
   812 apply (simp_all (no_asm_simp))
   813 done
   814 
   815 (* Similar for "less than" *)
   816 lemma div_less_dividend [simp]:
   817   "\<lbrakk>(1::nat) < n; 0 < m\<rbrakk> \<Longrightarrow> m div n < m"
   818 apply (induct m rule: nat_less_induct)
   819 apply (rename_tac "m")
   820 apply (case_tac "m<n", simp)
   821 apply (subgoal_tac "0<n")
   822  prefer 2 apply simp
   823 apply (simp add: div_geq)
   824 apply (case_tac "n<m")
   825  apply (subgoal_tac "(m-n) div n < (m-n) ")
   826   apply (rule impI less_trans_Suc)+
   827 apply assumption
   828   apply (simp_all)
   829 done
   830 
   831 text{*A fact for the mutilated chess board*}
   832 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   833 apply (case_tac "n=0", simp)
   834 apply (induct "m" rule: nat_less_induct)
   835 apply (case_tac "Suc (na) <n")
   836 (* case Suc(na) < n *)
   837 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   838 (* case n \<le> Suc(na) *)
   839 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   840 apply (auto simp add: Suc_diff_le le_mod_geq)
   841 done
   842 
   843 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   844 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   845 
   846 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   847 
   848 (*Loses information, namely we also have r<d provided d is nonzero*)
   849 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   850   apply (cut_tac a = m in mod_div_equality)
   851   apply (simp only: add_ac)
   852   apply (blast intro: sym)
   853   done
   854 
   855 lemma split_div:
   856  "P(n div k :: nat) =
   857  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   858  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   859 proof
   860   assume P: ?P
   861   show ?Q
   862   proof (cases)
   863     assume "k = 0"
   864     with P show ?Q by simp
   865   next
   866     assume not0: "k \<noteq> 0"
   867     thus ?Q
   868     proof (simp, intro allI impI)
   869       fix i j
   870       assume n: "n = k*i + j" and j: "j < k"
   871       show "P i"
   872       proof (cases)
   873         assume "i = 0"
   874         with n j P show "P i" by simp
   875       next
   876         assume "i \<noteq> 0"
   877         with not0 n j P show "P i" by(simp add:add_ac)
   878       qed
   879     qed
   880   qed
   881 next
   882   assume Q: ?Q
   883   show ?P
   884   proof (cases)
   885     assume "k = 0"
   886     with Q show ?P by simp
   887   next
   888     assume not0: "k \<noteq> 0"
   889     with Q have R: ?R by simp
   890     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   891     show ?P by simp
   892   qed
   893 qed
   894 
   895 lemma split_div_lemma:
   896   assumes "0 < n"
   897   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   898 proof
   899   assume ?rhs
   900   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   901   then have A: "n * q \<le> m" by simp
   902   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   903   then have "m < m + (n - (m mod n))" by simp
   904   then have "m < n + (m - (m mod n))" by simp
   905   with nq have "m < n + n * q" by simp
   906   then have B: "m < n * Suc q" by simp
   907   from A B show ?lhs ..
   908 next
   909   assume P: ?lhs
   910   then have "divmod_nat_rel m n (q, m - n * q)"
   911     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   912   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   913   have "(q, m - n * q) = (m div n, m mod n)" by auto
   914   then show ?rhs by simp
   915 qed
   916 
   917 theorem split_div':
   918   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   919    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   920   apply (case_tac "0 < n")
   921   apply (simp only: add: split_div_lemma)
   922   apply simp_all
   923   done
   924 
   925 lemma split_mod:
   926  "P(n mod k :: nat) =
   927  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   928  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   929 proof
   930   assume P: ?P
   931   show ?Q
   932   proof (cases)
   933     assume "k = 0"
   934     with P show ?Q by simp
   935   next
   936     assume not0: "k \<noteq> 0"
   937     thus ?Q
   938     proof (simp, intro allI impI)
   939       fix i j
   940       assume "n = k*i + j" "j < k"
   941       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   942     qed
   943   qed
   944 next
   945   assume Q: ?Q
   946   show ?P
   947   proof (cases)
   948     assume "k = 0"
   949     with Q show ?P by simp
   950   next
   951     assume not0: "k \<noteq> 0"
   952     with Q have R: ?R by simp
   953     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   954     show ?P by simp
   955   qed
   956 qed
   957 
   958 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
   959   using mod_div_equality [of m n] by arith
   960 
   961 lemma div_mod_equality': "(m::nat) div n * n = m - m mod n"
   962   using mod_div_equality [of m n] by arith
   963 (* FIXME: very similar to mult_div_cancel *)
   964 
   965 
   966 subsubsection {* An ``induction'' law for modulus arithmetic. *}
   967 
   968 lemma mod_induct_0:
   969   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
   970   and base: "P i" and i: "i<p"
   971   shows "P 0"
   972 proof (rule ccontr)
   973   assume contra: "\<not>(P 0)"
   974   from i have p: "0<p" by simp
   975   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
   976   proof
   977     fix k
   978     show "?A k"
   979     proof (induct k)
   980       show "?A 0" by simp  -- "by contradiction"
   981     next
   982       fix n
   983       assume ih: "?A n"
   984       show "?A (Suc n)"
   985       proof (clarsimp)
   986         assume y: "P (p - Suc n)"
   987         have n: "Suc n < p"
   988         proof (rule ccontr)
   989           assume "\<not>(Suc n < p)"
   990           hence "p - Suc n = 0"
   991             by simp
   992           with y contra show "False"
   993             by simp
   994         qed
   995         hence n2: "Suc (p - Suc n) = p-n" by arith
   996         from p have "p - Suc n < p" by arith
   997         with y step have z: "P ((Suc (p - Suc n)) mod p)"
   998           by blast
   999         show "False"
  1000         proof (cases "n=0")
  1001           case True
  1002           with z n2 contra show ?thesis by simp
  1003         next
  1004           case False
  1005           with p have "p-n < p" by arith
  1006           with z n2 False ih show ?thesis by simp
  1007         qed
  1008       qed
  1009     qed
  1010   qed
  1011   moreover
  1012   from i obtain k where "0<k \<and> i+k=p"
  1013     by (blast dest: less_imp_add_positive)
  1014   hence "0<k \<and> i=p-k" by auto
  1015   moreover
  1016   note base
  1017   ultimately
  1018   show "False" by blast
  1019 qed
  1020 
  1021 lemma mod_induct:
  1022   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1023   and base: "P i" and i: "i<p" and j: "j<p"
  1024   shows "P j"
  1025 proof -
  1026   have "\<forall>j<p. P j"
  1027   proof
  1028     fix j
  1029     show "j<p \<longrightarrow> P j" (is "?A j")
  1030     proof (induct j)
  1031       from step base i show "?A 0"
  1032         by (auto elim: mod_induct_0)
  1033     next
  1034       fix k
  1035       assume ih: "?A k"
  1036       show "?A (Suc k)"
  1037       proof
  1038         assume suc: "Suc k < p"
  1039         hence k: "k<p" by simp
  1040         with ih have "P k" ..
  1041         with step k have "P (Suc k mod p)"
  1042           by blast
  1043         moreover
  1044         from suc have "Suc k mod p = Suc k"
  1045           by simp
  1046         ultimately
  1047         show "P (Suc k)" by simp
  1048       qed
  1049     qed
  1050   qed
  1051   with j show ?thesis by blast
  1052 qed
  1053 
  1054 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1055   by (simp add: numeral_2_eq_2 le_div_geq)
  1056 
  1057 lemma mod2_Suc_Suc [simp]: "Suc (Suc m) mod 2 = m mod 2"
  1058   by (simp add: numeral_2_eq_2 le_mod_geq)
  1059 
  1060 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1061 by (simp add: nat_mult_2 [symmetric])
  1062 
  1063 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1064 proof -
  1065   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1066   moreover have "m mod 2 < 2" by simp
  1067   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1068   then show ?thesis by auto
  1069 qed
  1070 
  1071 text{*These lemmas collapse some needless occurrences of Suc:
  1072     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1073     We already have some rules to simplify operands smaller than 3.*}
  1074 
  1075 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1076 by (simp add: Suc3_eq_add_3)
  1077 
  1078 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1079 by (simp add: Suc3_eq_add_3)
  1080 
  1081 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1082 by (simp add: Suc3_eq_add_3)
  1083 
  1084 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1085 by (simp add: Suc3_eq_add_3)
  1086 
  1087 lemmas Suc_div_eq_add3_div_numeral [simp] = Suc_div_eq_add3_div [of _ "numeral v"] for v
  1088 lemmas Suc_mod_eq_add3_mod_numeral [simp] = Suc_mod_eq_add3_mod [of _ "numeral v"] for v
  1089 
  1090 
  1091 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1092 apply (induct "m")
  1093 apply (simp_all add: mod_Suc)
  1094 done
  1095 
  1096 declare Suc_times_mod_eq [of "numeral w", simp] for w
  1097 
  1098 lemma Suc_div_le_mono [simp]: "n div k \<le> (Suc n) div k"
  1099 by (simp add: div_le_mono)
  1100 
  1101 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1102 by (cases n) simp_all
  1103 
  1104 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1105 proof -
  1106   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1107   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1108 qed
  1109 
  1110   (* Potential use of algebra : Equality modulo n*)
  1111 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1112 by (simp add: mult_ac add_ac)
  1113 
  1114 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1115 proof -
  1116   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1117   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1118   finally show ?thesis .
  1119 qed
  1120 
  1121 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1122 apply (subst mod_Suc [of m]) 
  1123 apply (subst mod_Suc [of "m mod n"], simp) 
  1124 done
  1125 
  1126 lemma mod_2_not_eq_zero_eq_one_nat:
  1127   fixes n :: nat
  1128   shows "n mod 2 \<noteq> 0 \<longleftrightarrow> n mod 2 = 1"
  1129   by simp
  1130 
  1131 
  1132 subsection {* Division on @{typ int} *}
  1133 
  1134 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1135     --{*definition of quotient and remainder*}
  1136   "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1137     (if 0 < b then 0 \<le> r \<and> r < b else if b < 0 then b < r \<and> r \<le> 0 else q = 0))"
  1138 
  1139 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1140     --{*for the division algorithm*}
  1141     "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1142                          else (2 * q, r))"
  1143 
  1144 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1145 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1146   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1147      else adjust b (posDivAlg a (2 * b)))"
  1148 by auto
  1149 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1150   (auto simp add: mult_2)
  1151 
  1152 text{*algorithm for the case @{text "a<0, b>0"}*}
  1153 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1154   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1155      else adjust b (negDivAlg a (2 * b)))"
  1156 by auto
  1157 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1158   (auto simp add: mult_2)
  1159 
  1160 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1161 
  1162 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1163     --{*The full division algorithm considers all possible signs for a, b
  1164        including the special case @{text "a=0, b<0"} because 
  1165        @{term negDivAlg} requires @{term "a<0"}.*}
  1166   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1167                   else if a = 0 then (0, 0)
  1168                        else apsnd uminus (negDivAlg (-a) (-b))
  1169                else 
  1170                   if 0 < b then negDivAlg a b
  1171                   else apsnd uminus (posDivAlg (-a) (-b)))"
  1172 
  1173 instantiation int :: Divides.div
  1174 begin
  1175 
  1176 definition div_int where
  1177   "a div b = fst (divmod_int a b)"
  1178 
  1179 lemma fst_divmod_int [simp]:
  1180   "fst (divmod_int a b) = a div b"
  1181   by (simp add: div_int_def)
  1182 
  1183 definition mod_int where
  1184   "a mod b = snd (divmod_int a b)"
  1185 
  1186 lemma snd_divmod_int [simp]:
  1187   "snd (divmod_int a b) = a mod b"
  1188   by (simp add: mod_int_def)
  1189 
  1190 instance ..
  1191 
  1192 end
  1193 
  1194 lemma divmod_int_mod_div:
  1195   "divmod_int p q = (p div q, p mod q)"
  1196   by (simp add: prod_eq_iff)
  1197 
  1198 text{*
  1199 Here is the division algorithm in ML:
  1200 
  1201 \begin{verbatim}
  1202     fun posDivAlg (a,b) =
  1203       if a<b then (0,a)
  1204       else let val (q,r) = posDivAlg(a, 2*b)
  1205                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1206            end
  1207 
  1208     fun negDivAlg (a,b) =
  1209       if 0\<le>a+b then (~1,a+b)
  1210       else let val (q,r) = negDivAlg(a, 2*b)
  1211                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1212            end;
  1213 
  1214     fun negateSnd (q,r:int) = (q,~r);
  1215 
  1216     fun divmod (a,b) = if 0\<le>a then 
  1217                           if b>0 then posDivAlg (a,b) 
  1218                            else if a=0 then (0,0)
  1219                                 else negateSnd (negDivAlg (~a,~b))
  1220                        else 
  1221                           if 0<b then negDivAlg (a,b)
  1222                           else        negateSnd (posDivAlg (~a,~b));
  1223 \end{verbatim}
  1224 *}
  1225 
  1226 
  1227 subsubsection {* Uniqueness and Monotonicity of Quotients and Remainders *}
  1228 
  1229 lemma unique_quotient_lemma:
  1230      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1231       ==> q' \<le> (q::int)"
  1232 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1233  prefer 2 apply (simp add: right_diff_distrib)
  1234 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1235 apply (erule_tac [2] order_le_less_trans)
  1236  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1237 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1238  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1239 apply (simp add: mult_less_cancel_left)
  1240 done
  1241 
  1242 lemma unique_quotient_lemma_neg:
  1243      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1244       ==> q \<le> (q'::int)"
  1245 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1246     auto)
  1247 
  1248 lemma unique_quotient:
  1249      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1250       ==> q = q'"
  1251 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1252 apply (blast intro: order_antisym
  1253              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1254              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1255 done
  1256 
  1257 
  1258 lemma unique_remainder:
  1259      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1260       ==> r = r'"
  1261 apply (subgoal_tac "q = q'")
  1262  apply (simp add: divmod_int_rel_def)
  1263 apply (blast intro: unique_quotient)
  1264 done
  1265 
  1266 
  1267 subsubsection {* Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends *}
  1268 
  1269 text{*And positive divisors*}
  1270 
  1271 lemma adjust_eq [simp]:
  1272      "adjust b (q, r) = 
  1273       (let diff = r - b in  
  1274         if 0 \<le> diff then (2 * q + 1, diff)   
  1275                      else (2*q, r))"
  1276   by (simp add: Let_def adjust_def)
  1277 
  1278 declare posDivAlg.simps [simp del]
  1279 
  1280 text{*use with a simproc to avoid repeatedly proving the premise*}
  1281 lemma posDivAlg_eqn:
  1282      "0 < b ==>  
  1283       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1284 by (rule posDivAlg.simps [THEN trans], simp)
  1285 
  1286 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1287 theorem posDivAlg_correct:
  1288   assumes "0 \<le> a" and "0 < b"
  1289   shows "divmod_int_rel a b (posDivAlg a b)"
  1290   using assms
  1291   apply (induct a b rule: posDivAlg.induct)
  1292   apply auto
  1293   apply (simp add: divmod_int_rel_def)
  1294   apply (subst posDivAlg_eqn, simp add: right_distrib)
  1295   apply (case_tac "a < b")
  1296   apply simp_all
  1297   apply (erule splitE)
  1298   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1299   done
  1300 
  1301 
  1302 subsubsection {* Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends *}
  1303 
  1304 text{*And positive divisors*}
  1305 
  1306 declare negDivAlg.simps [simp del]
  1307 
  1308 text{*use with a simproc to avoid repeatedly proving the premise*}
  1309 lemma negDivAlg_eqn:
  1310      "0 < b ==>  
  1311       negDivAlg a b =       
  1312        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1313 by (rule negDivAlg.simps [THEN trans], simp)
  1314 
  1315 (*Correctness of negDivAlg: it computes quotients correctly
  1316   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1317 lemma negDivAlg_correct:
  1318   assumes "a < 0" and "b > 0"
  1319   shows "divmod_int_rel a b (negDivAlg a b)"
  1320   using assms
  1321   apply (induct a b rule: negDivAlg.induct)
  1322   apply (auto simp add: linorder_not_le)
  1323   apply (simp add: divmod_int_rel_def)
  1324   apply (subst negDivAlg_eqn, assumption)
  1325   apply (case_tac "a + b < (0\<Colon>int)")
  1326   apply simp_all
  1327   apply (erule splitE)
  1328   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1329   done
  1330 
  1331 
  1332 subsubsection {* Existence Shown by Proving the Division Algorithm to be Correct *}
  1333 
  1334 (*the case a=0*)
  1335 lemma divmod_int_rel_0: "divmod_int_rel 0 b (0, 0)"
  1336 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1337 
  1338 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1339 by (subst posDivAlg.simps, auto)
  1340 
  1341 lemma posDivAlg_0_right [simp]: "posDivAlg a 0 = (0, a)"
  1342 by (subst posDivAlg.simps, auto)
  1343 
  1344 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1345 by (subst negDivAlg.simps, auto)
  1346 
  1347 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (apsnd uminus qr)"
  1348 by (auto simp add: divmod_int_rel_def)
  1349 
  1350 lemma divmod_int_correct: "divmod_int_rel a b (divmod_int a b)"
  1351 apply (cases "b = 0", simp add: divmod_int_def divmod_int_rel_def)
  1352 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1353                     posDivAlg_correct negDivAlg_correct)
  1354 
  1355 lemma divmod_int_unique:
  1356   assumes "divmod_int_rel a b qr" 
  1357   shows "divmod_int a b = qr"
  1358   using assms divmod_int_correct [of a b]
  1359   using unique_quotient [of a b] unique_remainder [of a b]
  1360   by (metis pair_collapse)
  1361 
  1362 lemma divmod_int_rel_div_mod: "divmod_int_rel a b (a div b, a mod b)"
  1363   using divmod_int_correct by (simp add: divmod_int_mod_div)
  1364 
  1365 lemma div_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a div b = q"
  1366   by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1367 
  1368 lemma mod_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a mod b = r"
  1369   by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1370 
  1371 instance int :: ring_div
  1372 proof
  1373   fix a b :: int
  1374   show "a div b * b + a mod b = a"
  1375     using divmod_int_rel_div_mod [of a b]
  1376     unfolding divmod_int_rel_def by (simp add: mult_commute)
  1377 next
  1378   fix a b c :: int
  1379   assume "b \<noteq> 0"
  1380   hence "divmod_int_rel (a + c * b) b (c + a div b, a mod b)"
  1381     using divmod_int_rel_div_mod [of a b]
  1382     unfolding divmod_int_rel_def by (auto simp: algebra_simps)
  1383   thus "(a + c * b) div b = c + a div b"
  1384     by (rule div_int_unique)
  1385 next
  1386   fix a b c :: int
  1387   assume "c \<noteq> 0"
  1388   hence "\<And>q r. divmod_int_rel a b (q, r)
  1389     \<Longrightarrow> divmod_int_rel (c * a) (c * b) (q, c * r)"
  1390     unfolding divmod_int_rel_def
  1391     by - (rule linorder_cases [of 0 b], auto simp: algebra_simps
  1392       mult_less_0_iff zero_less_mult_iff mult_strict_right_mono
  1393       mult_strict_right_mono_neg zero_le_mult_iff mult_le_0_iff)
  1394   hence "divmod_int_rel (c * a) (c * b) (a div b, c * (a mod b))"
  1395     using divmod_int_rel_div_mod [of a b] .
  1396   thus "(c * a) div (c * b) = a div b"
  1397     by (rule div_int_unique)
  1398 next
  1399   fix a :: int show "a div 0 = 0"
  1400     by (rule div_int_unique, simp add: divmod_int_rel_def)
  1401 next
  1402   fix a :: int show "0 div a = 0"
  1403     by (rule div_int_unique, auto simp add: divmod_int_rel_def)
  1404 qed
  1405 
  1406 text{*Basic laws about division and remainder*}
  1407 
  1408 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1409   by (fact mod_div_equality2 [symmetric])
  1410 
  1411 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
  1412   by (fact div_mod_equality2)
  1413 
  1414 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
  1415   by (fact div_mod_equality)
  1416 
  1417 text {* Tool setup *}
  1418 
  1419 (* FIXME: Theorem list add_0s doesn't exist, because Numeral0 has gone. *)
  1420 lemmas add_0s = add_0_left add_0_right
  1421 
  1422 ML {*
  1423 structure Cancel_Div_Mod_Int = Cancel_Div_Mod
  1424 (
  1425   val div_name = @{const_name div};
  1426   val mod_name = @{const_name mod};
  1427   val mk_binop = HOLogic.mk_binop;
  1428   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1429   val dest_sum = Arith_Data.dest_sum;
  1430 
  1431   val div_mod_eqs = map mk_meta_eq [@{thm zdiv_zmod_equality}, @{thm zdiv_zmod_equality2}];
  1432 
  1433   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1434     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1435 )
  1436 *}
  1437 
  1438 simproc_setup cancel_div_mod_int ("(k::int) + l") = {* K Cancel_Div_Mod_Int.proc *}
  1439 
  1440 lemma pos_mod_conj: "(0::int) < b \<Longrightarrow> 0 \<le> a mod b \<and> a mod b < b"
  1441   using divmod_int_correct [of a b]
  1442   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1443 
  1444 lemmas pos_mod_sign [simp] = pos_mod_conj [THEN conjunct1]
  1445    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2]
  1446 
  1447 lemma neg_mod_conj: "b < (0::int) \<Longrightarrow> a mod b \<le> 0 \<and> b < a mod b"
  1448   using divmod_int_correct [of a b]
  1449   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1450 
  1451 lemmas neg_mod_sign [simp] = neg_mod_conj [THEN conjunct1]
  1452    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2]
  1453 
  1454 
  1455 subsubsection {* General Properties of div and mod *}
  1456 
  1457 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1458 apply (rule div_int_unique)
  1459 apply (auto simp add: divmod_int_rel_def)
  1460 done
  1461 
  1462 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1463 apply (rule div_int_unique)
  1464 apply (auto simp add: divmod_int_rel_def)
  1465 done
  1466 
  1467 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1468 apply (rule div_int_unique)
  1469 apply (auto simp add: divmod_int_rel_def)
  1470 done
  1471 
  1472 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1473 
  1474 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1475 apply (rule_tac q = 0 in mod_int_unique)
  1476 apply (auto simp add: divmod_int_rel_def)
  1477 done
  1478 
  1479 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1480 apply (rule_tac q = 0 in mod_int_unique)
  1481 apply (auto simp add: divmod_int_rel_def)
  1482 done
  1483 
  1484 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1485 apply (rule_tac q = "-1" in mod_int_unique)
  1486 apply (auto simp add: divmod_int_rel_def)
  1487 done
  1488 
  1489 text{*There is no @{text mod_neg_pos_trivial}.*}
  1490 
  1491 
  1492 (*Simpler laws such as -a div b = -(a div b) FAIL, but see just below*)
  1493 lemma zdiv_zminus_zminus [simp]: "(-a) div (-b) = a div (b::int)"
  1494   using div_mult_mult1 [of "-1" a b] by simp (* FIXME: generalize *)
  1495 
  1496 (*Simpler laws such as -a mod b = -(a mod b) FAIL, but see just below*)
  1497 lemma zmod_zminus_zminus [simp]: "(-a) mod (-b) = - (a mod (b::int))"
  1498   using mod_mult_mult1 [of "-1" a b] by simp (* FIXME: generalize *)
  1499 
  1500 
  1501 subsubsection {* Laws for div and mod with Unary Minus *}
  1502 
  1503 lemma zminus1_lemma:
  1504      "divmod_int_rel a b (q, r) ==> b \<noteq> 0
  1505       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1506                           if r=0 then 0 else b-r)"
  1507 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1508 
  1509 
  1510 lemma zdiv_zminus1_eq_if:
  1511      "b \<noteq> (0::int)  
  1512       ==> (-a) div b =  
  1513           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1514 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN div_int_unique])
  1515 
  1516 lemma zmod_zminus1_eq_if:
  1517      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1518 apply (case_tac "b = 0", simp)
  1519 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN mod_int_unique])
  1520 done
  1521 
  1522 lemma zmod_zminus1_not_zero:
  1523   fixes k l :: int
  1524   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1525   unfolding zmod_zminus1_eq_if by auto
  1526 
  1527 lemma zdiv_zminus2: "a div (-b) = (-a::int) div b"
  1528   using zdiv_zminus_zminus [of "-a" b] by simp (* FIXME: generalize *)
  1529 
  1530 lemma zmod_zminus2: "a mod (-b) = - ((-a::int) mod b)"
  1531   using zmod_zminus_zminus [of "-a" b] by simp (* FIXME: generalize*)
  1532 
  1533 lemma zdiv_zminus2_eq_if:
  1534      "b \<noteq> (0::int)  
  1535       ==> a div (-b) =  
  1536           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1537 by (simp add: zdiv_zminus1_eq_if zdiv_zminus2)
  1538 
  1539 lemma zmod_zminus2_eq_if:
  1540      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1541 by (simp add: zmod_zminus1_eq_if zmod_zminus2)
  1542 
  1543 lemma zmod_zminus2_not_zero:
  1544   fixes k l :: int
  1545   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1546   unfolding zmod_zminus2_eq_if by auto 
  1547 
  1548 
  1549 subsubsection {* Computation of Division and Remainder *}
  1550 
  1551 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1552 by (simp add: div_int_def divmod_int_def)
  1553 
  1554 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1555 by (simp add: mod_int_def divmod_int_def)
  1556 
  1557 text{*a positive, b positive *}
  1558 
  1559 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1560 by (simp add: div_int_def divmod_int_def)
  1561 
  1562 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1563 by (simp add: mod_int_def divmod_int_def)
  1564 
  1565 text{*a negative, b positive *}
  1566 
  1567 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1568 by (simp add: div_int_def divmod_int_def)
  1569 
  1570 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1571 by (simp add: mod_int_def divmod_int_def)
  1572 
  1573 text{*a positive, b negative *}
  1574 
  1575 lemma div_pos_neg:
  1576      "[| 0 < a;  b < 0 |] ==> a div b = fst (apsnd uminus (negDivAlg (-a) (-b)))"
  1577 by (simp add: div_int_def divmod_int_def)
  1578 
  1579 lemma mod_pos_neg:
  1580      "[| 0 < a;  b < 0 |] ==> a mod b = snd (apsnd uminus (negDivAlg (-a) (-b)))"
  1581 by (simp add: mod_int_def divmod_int_def)
  1582 
  1583 text{*a negative, b negative *}
  1584 
  1585 lemma div_neg_neg:
  1586      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (apsnd uminus (posDivAlg (-a) (-b)))"
  1587 by (simp add: div_int_def divmod_int_def)
  1588 
  1589 lemma mod_neg_neg:
  1590      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (apsnd uminus (posDivAlg (-a) (-b)))"
  1591 by (simp add: mod_int_def divmod_int_def)
  1592 
  1593 text {*Simplify expresions in which div and mod combine numerical constants*}
  1594 
  1595 lemma int_div_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a div b = q"
  1596   by (rule div_int_unique [of a b q r]) (simp add: divmod_int_rel_def)
  1597 
  1598 lemma int_div_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a div b = q"
  1599   by (rule div_int_unique [of a b q r],
  1600     simp add: divmod_int_rel_def)
  1601 
  1602 lemma int_mod_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a mod b = r"
  1603   by (rule mod_int_unique [of a b q r],
  1604     simp add: divmod_int_rel_def)
  1605 
  1606 lemma int_mod_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a mod b = r"
  1607   by (rule mod_int_unique [of a b q r],
  1608     simp add: divmod_int_rel_def)
  1609 
  1610 (* simprocs adapted from HOL/ex/Binary.thy *)
  1611 ML {*
  1612 local
  1613   val mk_number = HOLogic.mk_number HOLogic.intT
  1614   val plus = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"}
  1615   val times = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"}
  1616   val zero = @{term "0 :: int"}
  1617   val less = @{term "op < :: int \<Rightarrow> int \<Rightarrow> bool"}
  1618   val le = @{term "op \<le> :: int \<Rightarrow> int \<Rightarrow> bool"}
  1619   val simps = @{thms arith_simps} @ @{thms rel_simps} @
  1620     map (fn th => th RS sym) [@{thm numeral_1_eq_1}]
  1621   fun prove ctxt goal = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop goal)
  1622     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps simps))));
  1623   fun binary_proc proc ss ct =
  1624     (case Thm.term_of ct of
  1625       _ $ t $ u =>
  1626       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1627         SOME args => proc (Simplifier.the_context ss) args
  1628       | NONE => NONE)
  1629     | _ => NONE);
  1630 in
  1631   fun divmod_proc posrule negrule =
  1632     binary_proc (fn ctxt => fn ((a, t), (b, u)) =>
  1633       if b = 0 then NONE else let
  1634         val (q, r) = pairself mk_number (Integer.div_mod a b)
  1635         val goal1 = HOLogic.mk_eq (t, plus $ (times $ u $ q) $ r)
  1636         val (goal2, goal3, rule) = if b > 0
  1637           then (le $ zero $ r, less $ r $ u, posrule RS eq_reflection)
  1638           else (le $ r $ zero, less $ u $ r, negrule RS eq_reflection)
  1639       in SOME (rule OF map (prove ctxt) [goal1, goal2, goal3]) end)
  1640 end
  1641 *}
  1642 
  1643 simproc_setup binary_int_div
  1644   ("numeral m div numeral n :: int" |
  1645    "numeral m div neg_numeral n :: int" |
  1646    "neg_numeral m div numeral n :: int" |
  1647    "neg_numeral m div neg_numeral n :: int") =
  1648   {* K (divmod_proc @{thm int_div_pos_eq} @{thm int_div_neg_eq}) *}
  1649 
  1650 simproc_setup binary_int_mod
  1651   ("numeral m mod numeral n :: int" |
  1652    "numeral m mod neg_numeral n :: int" |
  1653    "neg_numeral m mod numeral n :: int" |
  1654    "neg_numeral m mod neg_numeral n :: int") =
  1655   {* K (divmod_proc @{thm int_mod_pos_eq} @{thm int_mod_neg_eq}) *}
  1656 
  1657 lemmas posDivAlg_eqn_numeral [simp] =
  1658     posDivAlg_eqn [of "numeral v" "numeral w", OF zero_less_numeral] for v w
  1659 
  1660 lemmas negDivAlg_eqn_numeral [simp] =
  1661     negDivAlg_eqn [of "numeral v" "neg_numeral w", OF zero_less_numeral] for v w
  1662 
  1663 
  1664 text{*Special-case simplification *}
  1665 
  1666 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
  1667 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
  1668 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
  1669 apply (auto simp del: neg_mod_sign neg_mod_bound)
  1670 done (* FIXME: generalize *)
  1671 
  1672 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
  1673 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
  1674 (* FIXME: generalize *)
  1675 
  1676 (** The last remaining special cases for constant arithmetic:
  1677     1 div z and 1 mod z **)
  1678 
  1679 lemmas div_pos_pos_1_numeral [simp] =
  1680   div_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1681 
  1682 lemmas div_pos_neg_1_numeral [simp] =
  1683   div_pos_neg [OF zero_less_one, of "neg_numeral w",
  1684   OF neg_numeral_less_zero] for w
  1685 
  1686 lemmas mod_pos_pos_1_numeral [simp] =
  1687   mod_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1688 
  1689 lemmas mod_pos_neg_1_numeral [simp] =
  1690   mod_pos_neg [OF zero_less_one, of "neg_numeral w",
  1691   OF neg_numeral_less_zero] for w
  1692 
  1693 lemmas posDivAlg_eqn_1_numeral [simp] =
  1694     posDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1695 
  1696 lemmas negDivAlg_eqn_1_numeral [simp] =
  1697     negDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1698 
  1699 
  1700 subsubsection {* Monotonicity in the First Argument (Dividend) *}
  1701 
  1702 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1703 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1704 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1705 apply (rule unique_quotient_lemma)
  1706 apply (erule subst)
  1707 apply (erule subst, simp_all)
  1708 done
  1709 
  1710 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1711 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1712 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1713 apply (rule unique_quotient_lemma_neg)
  1714 apply (erule subst)
  1715 apply (erule subst, simp_all)
  1716 done
  1717 
  1718 
  1719 subsubsection {* Monotonicity in the Second Argument (Divisor) *}
  1720 
  1721 lemma q_pos_lemma:
  1722      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1723 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1724  apply (simp add: zero_less_mult_iff)
  1725 apply (simp add: right_distrib)
  1726 done
  1727 
  1728 lemma zdiv_mono2_lemma:
  1729      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1730          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1731       ==> q \<le> (q'::int)"
  1732 apply (frule q_pos_lemma, assumption+) 
  1733 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1734  apply (simp add: mult_less_cancel_left)
  1735 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1736  prefer 2 apply simp
  1737 apply (simp (no_asm_simp) add: right_distrib)
  1738 apply (subst add_commute, rule add_less_le_mono, arith)
  1739 apply (rule mult_right_mono, auto)
  1740 done
  1741 
  1742 lemma zdiv_mono2:
  1743      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1744 apply (subgoal_tac "b \<noteq> 0")
  1745  prefer 2 apply arith
  1746 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1747 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1748 apply (rule zdiv_mono2_lemma)
  1749 apply (erule subst)
  1750 apply (erule subst, simp_all)
  1751 done
  1752 
  1753 lemma q_neg_lemma:
  1754      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1755 apply (subgoal_tac "b'*q' < 0")
  1756  apply (simp add: mult_less_0_iff, arith)
  1757 done
  1758 
  1759 lemma zdiv_mono2_neg_lemma:
  1760      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1761          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1762       ==> q' \<le> (q::int)"
  1763 apply (frule q_neg_lemma, assumption+) 
  1764 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1765  apply (simp add: mult_less_cancel_left)
  1766 apply (simp add: right_distrib)
  1767 apply (subgoal_tac "b*q' \<le> b'*q'")
  1768  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1769 done
  1770 
  1771 lemma zdiv_mono2_neg:
  1772      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1773 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1774 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1775 apply (rule zdiv_mono2_neg_lemma)
  1776 apply (erule subst)
  1777 apply (erule subst, simp_all)
  1778 done
  1779 
  1780 
  1781 subsubsection {* More Algebraic Laws for div and mod *}
  1782 
  1783 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1784 
  1785 lemma zmult1_lemma:
  1786      "[| divmod_int_rel b c (q, r) |]  
  1787       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1788 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib mult_ac)
  1789 
  1790 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1791 apply (case_tac "c = 0", simp)
  1792 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN div_int_unique])
  1793 done
  1794 
  1795 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
  1796   by (fact mod_mult_right_eq) (* FIXME: delete *)
  1797 
  1798 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1799 
  1800 lemma zadd1_lemma:
  1801      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br) |]  
  1802       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1803 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib)
  1804 
  1805 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1806 lemma zdiv_zadd1_eq:
  1807      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1808 apply (case_tac "c = 0", simp)
  1809 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] div_int_unique)
  1810 done
  1811 
  1812 lemma posDivAlg_div_mod:
  1813   assumes "k \<ge> 0"
  1814   and "l \<ge> 0"
  1815   shows "posDivAlg k l = (k div l, k mod l)"
  1816 proof (cases "l = 0")
  1817   case True then show ?thesis by (simp add: posDivAlg.simps)
  1818 next
  1819   case False with assms posDivAlg_correct
  1820     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1821     by simp
  1822   from div_int_unique [OF this] mod_int_unique [OF this]
  1823   show ?thesis by simp
  1824 qed
  1825 
  1826 lemma negDivAlg_div_mod:
  1827   assumes "k < 0"
  1828   and "l > 0"
  1829   shows "negDivAlg k l = (k div l, k mod l)"
  1830 proof -
  1831   from assms have "l \<noteq> 0" by simp
  1832   from assms negDivAlg_correct
  1833     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1834     by simp
  1835   from div_int_unique [OF this] mod_int_unique [OF this]
  1836   show ?thesis by simp
  1837 qed
  1838 
  1839 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1840 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1841 
  1842 (* REVISIT: should this be generalized to all semiring_div types? *)
  1843 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1844 
  1845 lemma zmod_zdiv_equality':
  1846   "(m\<Colon>int) mod n = m - (m div n) * n"
  1847   using mod_div_equality [of m n] by arith
  1848 
  1849 
  1850 subsubsection {* Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1851 
  1852 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1853   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1854   to cause particular problems.*)
  1855 
  1856 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1857 
  1858 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1859 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1860  apply (simp add: algebra_simps)
  1861 apply (rule order_le_less_trans)
  1862  apply (erule_tac [2] mult_strict_right_mono)
  1863  apply (rule mult_left_mono_neg)
  1864   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1865  apply (simp)
  1866 apply (simp)
  1867 done
  1868 
  1869 lemma zmult2_lemma_aux2:
  1870      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1871 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1872  apply arith
  1873 apply (simp add: mult_le_0_iff)
  1874 done
  1875 
  1876 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1877 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1878 apply arith
  1879 apply (simp add: zero_le_mult_iff)
  1880 done
  1881 
  1882 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1883 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1884  apply (simp add: right_diff_distrib)
  1885 apply (rule order_less_le_trans)
  1886  apply (erule mult_strict_right_mono)
  1887  apply (rule_tac [2] mult_left_mono)
  1888   apply simp
  1889  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1890 apply simp
  1891 done
  1892 
  1893 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r); 0 < c |]  
  1894       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1895 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  1896                    zero_less_mult_iff right_distrib [symmetric] 
  1897                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4 mult_less_0_iff split: split_if_asm)
  1898 
  1899 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  1900 apply (case_tac "b = 0", simp)
  1901 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN div_int_unique])
  1902 done
  1903 
  1904 lemma zmod_zmult2_eq:
  1905      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  1906 apply (case_tac "b = 0", simp)
  1907 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN mod_int_unique])
  1908 done
  1909 
  1910 lemma div_pos_geq:
  1911   fixes k l :: int
  1912   assumes "0 < l" and "l \<le> k"
  1913   shows "k div l = (k - l) div l + 1"
  1914 proof -
  1915   have "k = (k - l) + l" by simp
  1916   then obtain j where k: "k = j + l" ..
  1917   with assms show ?thesis by simp
  1918 qed
  1919 
  1920 lemma mod_pos_geq:
  1921   fixes k l :: int
  1922   assumes "0 < l" and "l \<le> k"
  1923   shows "k mod l = (k - l) mod l"
  1924 proof -
  1925   have "k = (k - l) + l" by simp
  1926   then obtain j where k: "k = j + l" ..
  1927   with assms show ?thesis by simp
  1928 qed
  1929 
  1930 
  1931 subsubsection {* Splitting Rules for div and mod *}
  1932 
  1933 text{*The proofs of the two lemmas below are essentially identical*}
  1934 
  1935 lemma split_pos_lemma:
  1936  "0<k ==> 
  1937     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  1938 apply (rule iffI, clarify)
  1939  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1940  apply (subst mod_add_eq) 
  1941  apply (subst zdiv_zadd1_eq) 
  1942  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  1943 txt{*converse direction*}
  1944 apply (drule_tac x = "n div k" in spec) 
  1945 apply (drule_tac x = "n mod k" in spec, simp)
  1946 done
  1947 
  1948 lemma split_neg_lemma:
  1949  "k<0 ==>
  1950     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  1951 apply (rule iffI, clarify)
  1952  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1953  apply (subst mod_add_eq) 
  1954  apply (subst zdiv_zadd1_eq) 
  1955  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  1956 txt{*converse direction*}
  1957 apply (drule_tac x = "n div k" in spec) 
  1958 apply (drule_tac x = "n mod k" in spec, simp)
  1959 done
  1960 
  1961 lemma split_zdiv:
  1962  "P(n div k :: int) =
  1963   ((k = 0 --> P 0) & 
  1964    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  1965    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  1966 apply (case_tac "k=0", simp)
  1967 apply (simp only: linorder_neq_iff)
  1968 apply (erule disjE) 
  1969  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  1970                       split_neg_lemma [of concl: "%x y. P x"])
  1971 done
  1972 
  1973 lemma split_zmod:
  1974  "P(n mod k :: int) =
  1975   ((k = 0 --> P n) & 
  1976    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  1977    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  1978 apply (case_tac "k=0", simp)
  1979 apply (simp only: linorder_neq_iff)
  1980 apply (erule disjE) 
  1981  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  1982                       split_neg_lemma [of concl: "%x y. P y"])
  1983 done
  1984 
  1985 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  1986   when these are applied to some constant that is of the form
  1987   @{term "numeral k"}: *}
  1988 declare split_zdiv [of _ _ "numeral k", arith_split] for k
  1989 declare split_zmod [of _ _ "numeral k", arith_split] for k
  1990 
  1991 
  1992 subsubsection {* Speeding up the Division Algorithm with Shifting *}
  1993 
  1994 text{*computing div by shifting *}
  1995 
  1996 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  1997 proof cases
  1998   assume "a=0"
  1999     thus ?thesis by simp
  2000 next
  2001   assume "a\<noteq>0" and le_a: "0\<le>a"   
  2002   hence a_pos: "1 \<le> a" by arith
  2003   hence one_less_a2: "1 < 2 * a" by arith
  2004   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
  2005     unfolding mult_le_cancel_left
  2006     by (simp add: add1_zle_eq add_commute [of 1])
  2007   with a_pos have "0 \<le> b mod a" by simp
  2008   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
  2009     by (simp add: mod_pos_pos_trivial one_less_a2)
  2010   with  le_2a
  2011   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
  2012     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
  2013                   right_distrib) 
  2014   thus ?thesis
  2015     by (subst zdiv_zadd1_eq,
  2016         simp add: mod_mult_mult1 one_less_a2
  2017                   div_pos_pos_trivial)
  2018 qed
  2019 
  2020 lemma neg_zdiv_mult_2: 
  2021   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2022 proof -
  2023   have R: "1 + - (2 * (b + 1)) = - (1 + 2 * b)" by simp
  2024   have "(1 + 2 * (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a)"
  2025     by (rule pos_zdiv_mult_2, simp add: A)
  2026   thus ?thesis
  2027     by (simp only: R zdiv_zminus_zminus diff_minus
  2028       minus_add_distrib [symmetric] mult_minus_right)
  2029 qed
  2030 
  2031 (* FIXME: add rules for negative numerals *)
  2032 lemma zdiv_numeral_Bit0 [simp]:
  2033   "numeral (Num.Bit0 v) div numeral (Num.Bit0 w) =
  2034     numeral v div (numeral w :: int)"
  2035   unfolding numeral.simps unfolding mult_2 [symmetric]
  2036   by (rule div_mult_mult1, simp)
  2037 
  2038 lemma zdiv_numeral_Bit1 [simp]:
  2039   "numeral (Num.Bit1 v) div numeral (Num.Bit0 w) =  
  2040     (numeral v div (numeral w :: int))"
  2041   unfolding numeral.simps
  2042   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2043   by (rule pos_zdiv_mult_2, simp)
  2044 
  2045 
  2046 subsubsection {* Computing mod by Shifting (proofs resemble those for div) *}
  2047 
  2048 lemma pos_zmod_mult_2:
  2049   fixes a b :: int
  2050   assumes "0 \<le> a"
  2051   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2052 proof (cases "0 < a")
  2053   case False with assms show ?thesis by simp
  2054 next
  2055   case True
  2056   then have "b mod a < a" by (rule pos_mod_bound)
  2057   then have "1 + b mod a \<le> a" by simp
  2058   then have A: "2 * (1 + b mod a) \<le> 2 * a" by simp
  2059   from `0 < a` have "0 \<le> b mod a" by (rule pos_mod_sign)
  2060   then have B: "0 \<le> 1 + 2 * (b mod a)" by simp
  2061   have "((1\<Colon>int) mod ((2\<Colon>int) * a) + (2\<Colon>int) * b mod ((2\<Colon>int) * a)) mod ((2\<Colon>int) * a) = (1\<Colon>int) + (2\<Colon>int) * (b mod a)"
  2062     using `0 < a` and A
  2063     by (auto simp add: mod_mult_mult1 mod_pos_pos_trivial ring_distribs intro!: mod_pos_pos_trivial B)
  2064   then show ?thesis by (subst mod_add_eq)
  2065 qed
  2066 
  2067 lemma neg_zmod_mult_2:
  2068   fixes a b :: int
  2069   assumes "a \<le> 0"
  2070   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2071 proof -
  2072   from assms have "0 \<le> - a" by auto
  2073   then have "(1 + 2 * (- b - 1)) mod (2 * (- a)) = 1 + 2 * ((- b - 1) mod (- a))"
  2074     by (rule pos_zmod_mult_2)
  2075   then show ?thesis by (simp add: zmod_zminus2 algebra_simps)
  2076      (simp add: diff_minus add_ac)
  2077 qed
  2078 
  2079 (* FIXME: add rules for negative numerals *)
  2080 lemma zmod_numeral_Bit0 [simp]:
  2081   "numeral (Num.Bit0 v) mod numeral (Num.Bit0 w) =  
  2082     (2::int) * (numeral v mod numeral w)"
  2083   unfolding numeral_Bit0 [of v] numeral_Bit0 [of w]
  2084   unfolding mult_2 [symmetric] by (rule mod_mult_mult1)
  2085 
  2086 lemma zmod_numeral_Bit1 [simp]:
  2087   "numeral (Num.Bit1 v) mod numeral (Num.Bit0 w) =
  2088     2 * (numeral v mod numeral w) + (1::int)"
  2089   unfolding numeral_Bit1 [of v] numeral_Bit0 [of w]
  2090   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2091   by (rule pos_zmod_mult_2, simp)
  2092 
  2093 lemma zdiv_eq_0_iff:
  2094  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2095 proof
  2096   assume ?L
  2097   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2098   with `?L` show ?R by blast
  2099 next
  2100   assume ?R thus ?L
  2101     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2102 qed
  2103 
  2104 
  2105 subsubsection {* Quotients of Signs *}
  2106 
  2107 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2108 apply (subgoal_tac "a div b \<le> -1", force)
  2109 apply (rule order_trans)
  2110 apply (rule_tac a' = "-1" in zdiv_mono1)
  2111 apply (auto simp add: div_eq_minus1)
  2112 done
  2113 
  2114 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2115 by (drule zdiv_mono1_neg, auto)
  2116 
  2117 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2118 by (drule zdiv_mono1, auto)
  2119 
  2120 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2121 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2122 They should all be simp rules unless that causes too much search. *}
  2123 
  2124 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2125 apply auto
  2126 apply (drule_tac [2] zdiv_mono1)
  2127 apply (auto simp add: linorder_neq_iff)
  2128 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2129 apply (blast intro: div_neg_pos_less0)
  2130 done
  2131 
  2132 lemma neg_imp_zdiv_nonneg_iff:
  2133   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2134 apply (subst zdiv_zminus_zminus [symmetric])
  2135 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2136 done
  2137 
  2138 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2139 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2140 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2141 
  2142 lemma pos_imp_zdiv_pos_iff:
  2143   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2144 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2145 by arith
  2146 
  2147 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2148 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2149 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2150 
  2151 lemma nonneg1_imp_zdiv_pos_iff:
  2152   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2153 apply rule
  2154  apply rule
  2155   using div_pos_pos_trivial[of a b]apply arith
  2156  apply(cases "b=0")apply simp
  2157  using div_nonneg_neg_le0[of a b]apply arith
  2158 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2159 done
  2160 
  2161 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2162 apply (rule split_zmod[THEN iffD2])
  2163 apply(fastforce dest: q_pos_lemma intro: split_mult_pos_le)
  2164 done
  2165 
  2166 
  2167 subsubsection {* The Divides Relation *}
  2168 
  2169 lemmas zdvd_iff_zmod_eq_0_numeral [simp] =
  2170   dvd_eq_mod_eq_0 [of "numeral x::int" "numeral y::int"]
  2171   dvd_eq_mod_eq_0 [of "numeral x::int" "neg_numeral y::int"]
  2172   dvd_eq_mod_eq_0 [of "neg_numeral x::int" "numeral y::int"]
  2173   dvd_eq_mod_eq_0 [of "neg_numeral x::int" "neg_numeral y::int"] for x y
  2174 
  2175 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  2176   by (rule dvd_mod) (* TODO: remove *)
  2177 
  2178 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  2179   by (rule dvd_mod_imp_dvd) (* TODO: remove *)
  2180 
  2181 lemmas dvd_eq_mod_eq_0_numeral [simp] =
  2182   dvd_eq_mod_eq_0 [of "numeral x" "numeral y"] for x y
  2183 
  2184 
  2185 subsubsection {* Further properties *}
  2186 
  2187 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2188   using zmod_zdiv_equality[where a="m" and b="n"]
  2189   by (simp add: algebra_simps) (* FIXME: generalize *)
  2190 
  2191 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  2192 apply (induct "y", auto)
  2193 apply (rule mod_mult_right_eq [THEN trans])
  2194 apply (simp (no_asm_simp))
  2195 apply (rule mod_mult_eq [symmetric])
  2196 done (* FIXME: generalize *)
  2197 
  2198 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2199 apply (subst split_div, auto)
  2200 apply (subst split_zdiv, auto)
  2201 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2202 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2203 done
  2204 
  2205 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2206 apply (subst split_mod, auto)
  2207 apply (subst split_zmod, auto)
  2208 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2209        in unique_remainder)
  2210 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2211 done
  2212 
  2213 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2214 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2215 
  2216 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  2217 apply (subgoal_tac "m mod n = 0")
  2218  apply (simp add: zmult_div_cancel)
  2219 apply (simp only: dvd_eq_mod_eq_0)
  2220 done
  2221 
  2222 text{*Suggested by Matthias Daum*}
  2223 lemma int_power_div_base:
  2224      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2225 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2226  apply (erule ssubst)
  2227  apply (simp only: power_add)
  2228  apply simp_all
  2229 done
  2230 
  2231 text {* by Brian Huffman *}
  2232 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2233 by (rule mod_minus_eq [symmetric])
  2234 
  2235 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2236 by (rule mod_diff_left_eq [symmetric])
  2237 
  2238 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2239 by (rule mod_diff_right_eq [symmetric])
  2240 
  2241 lemmas zmod_simps =
  2242   mod_add_left_eq  [symmetric]
  2243   mod_add_right_eq [symmetric]
  2244   mod_mult_right_eq[symmetric]
  2245   mod_mult_left_eq [symmetric]
  2246   zpower_zmod
  2247   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2248 
  2249 text {* Distributive laws for function @{text nat}. *}
  2250 
  2251 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2252 apply (rule linorder_cases [of y 0])
  2253 apply (simp add: div_nonneg_neg_le0)
  2254 apply simp
  2255 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2256 done
  2257 
  2258 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2259 lemma nat_mod_distrib:
  2260   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2261 apply (case_tac "y = 0", simp)
  2262 apply (simp add: nat_eq_iff zmod_int)
  2263 done
  2264 
  2265 text  {* transfer setup *}
  2266 
  2267 lemma transfer_nat_int_functions:
  2268     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2269     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2270   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2271 
  2272 lemma transfer_nat_int_function_closures:
  2273     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2274     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2275   apply (cases "y = 0")
  2276   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2277   apply (cases "y = 0")
  2278   apply auto
  2279 done
  2280 
  2281 declare transfer_morphism_nat_int [transfer add return:
  2282   transfer_nat_int_functions
  2283   transfer_nat_int_function_closures
  2284 ]
  2285 
  2286 lemma transfer_int_nat_functions:
  2287     "(int x) div (int y) = int (x div y)"
  2288     "(int x) mod (int y) = int (x mod y)"
  2289   by (auto simp add: zdiv_int zmod_int)
  2290 
  2291 lemma transfer_int_nat_function_closures:
  2292     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2293     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2294   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2295 
  2296 declare transfer_morphism_int_nat [transfer add return:
  2297   transfer_int_nat_functions
  2298   transfer_int_nat_function_closures
  2299 ]
  2300 
  2301 text{*Suggested by Matthias Daum*}
  2302 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2303 apply (subgoal_tac "nat x div nat k < nat x")
  2304  apply (simp add: nat_div_distrib [symmetric])
  2305 apply (rule Divides.div_less_dividend, simp_all)
  2306 done
  2307 
  2308 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2309 proof
  2310   assume H: "x mod n = y mod n"
  2311   hence "x mod n - y mod n = 0" by simp
  2312   hence "(x mod n - y mod n) mod n = 0" by simp 
  2313   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2314   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2315 next
  2316   assume H: "n dvd x - y"
  2317   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2318   hence "x = n*k + y" by simp
  2319   hence "x mod n = (n*k + y) mod n" by simp
  2320   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2321 qed
  2322 
  2323 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2324   shows "\<exists>q. x = y + n * q"
  2325 proof-
  2326   from xy have th: "int x - int y = int (x - y)" by simp 
  2327   from xyn have "int x mod int n = int y mod int n" 
  2328     by (simp add: zmod_int [symmetric])
  2329   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2330   hence "n dvd x - y" by (simp add: th zdvd_int)
  2331   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2332 qed
  2333 
  2334 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2335   (is "?lhs = ?rhs")
  2336 proof
  2337   assume H: "x mod n = y mod n"
  2338   {assume xy: "x \<le> y"
  2339     from H have th: "y mod n = x mod n" by simp
  2340     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2341       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2342   moreover
  2343   {assume xy: "y \<le> x"
  2344     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2345       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2346   ultimately  show ?rhs using linear[of x y] by blast  
  2347 next
  2348   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2349   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2350   thus  ?lhs by simp
  2351 qed
  2352 
  2353 lemma div_nat_numeral [simp]:
  2354   "(numeral v :: nat) div numeral v' = nat (numeral v div numeral v')"
  2355   by (simp add: nat_div_distrib)
  2356 
  2357 lemma one_div_nat_numeral [simp]:
  2358   "Suc 0 div numeral v' = nat (1 div numeral v')"
  2359   by (subst nat_div_distrib, simp_all)
  2360 
  2361 lemma mod_nat_numeral [simp]:
  2362   "(numeral v :: nat) mod numeral v' = nat (numeral v mod numeral v')"
  2363   by (simp add: nat_mod_distrib)
  2364 
  2365 lemma one_mod_nat_numeral [simp]:
  2366   "Suc 0 mod numeral v' = nat (1 mod numeral v')"
  2367   by (subst nat_mod_distrib) simp_all
  2368 
  2369 lemma mod_2_not_eq_zero_eq_one_int:
  2370   fixes k :: int
  2371   shows "k mod 2 \<noteq> 0 \<longleftrightarrow> k mod 2 = 1"
  2372   by auto
  2373 
  2374 
  2375 subsubsection {* Tools setup *}
  2376 
  2377 text {* Nitpick *}
  2378 
  2379 lemmas [nitpick_unfold] = dvd_eq_mod_eq_0 mod_div_equality' zmod_zdiv_equality'
  2380 
  2381 
  2382 subsubsection {* Code generation *}
  2383 
  2384 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2385   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2386 
  2387 lemma pdivmod_posDivAlg [code]:
  2388   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2389 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2390 
  2391 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2392   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2393     then pdivmod k l
  2394     else (let (r, s) = pdivmod k l in
  2395        if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2396 proof -
  2397   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2398   show ?thesis
  2399     by (simp add: divmod_int_mod_div pdivmod_def)
  2400       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2401       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2402 qed
  2403 
  2404 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2405   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2406     then pdivmod k l
  2407     else (let (r, s) = pdivmod k l in
  2408       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2409 proof -
  2410   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2411     by (auto simp add: not_less sgn_if)
  2412   then show ?thesis by (simp add: divmod_int_pdivmod)
  2413 qed
  2414 
  2415 code_modulename SML
  2416   Divides Arith
  2417 
  2418 code_modulename OCaml
  2419   Divides Arith
  2420 
  2421 code_modulename Haskell
  2422   Divides Arith
  2423 
  2424 end