src/HOL/SEQ.thy
author wenzelm
Tue May 04 20:26:53 2010 +0200 (2010-05-04)
changeset 36650 d65f07abfa7c
parent 36647 edc381bf7200
child 36663 f75b13ed4898
permissions -rw-r--r--
fixed proof (cf. edc381bf7200);
     1 (*  Title:      HOL/SEQ.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge
     3     Author:     Lawrence C Paulson
     4     Author:     Jeremy Avigad
     5     Author:     Brian Huffman
     6 
     7 Convergence of sequences and series.
     8 *)
     9 
    10 header {* Sequences and Convergence *}
    11 
    12 theory SEQ
    13 imports Limits
    14 begin
    15 
    16 definition
    17   Zseq :: "[nat \<Rightarrow> 'a::real_normed_vector] \<Rightarrow> bool" where
    18     --{*Standard definition of sequence converging to zero*}
    19   [code del]: "Zseq X = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. norm (X n) < r)"
    20 
    21 definition
    22   LIMSEQ :: "[nat \<Rightarrow> 'a::metric_space, 'a] \<Rightarrow> bool"
    23     ("((_)/ ----> (_))" [60, 60] 60) where
    24     --{*Standard definition of convergence of sequence*}
    25   [code del]: "X ----> L = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
    26 
    27 definition
    28   lim :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> 'a" where
    29     --{*Standard definition of limit using choice operator*}
    30   "lim X = (THE L. X ----> L)"
    31 
    32 definition
    33   convergent :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    34     --{*Standard definition of convergence*}
    35   "convergent X = (\<exists>L. X ----> L)"
    36 
    37 definition
    38   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
    39     --{*Standard definition for bounded sequence*}
    40   [code del]: "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
    41 
    42 definition
    43   monoseq :: "(nat=>real)=>bool" where
    44     --{*Definition of monotonicity. 
    45         The use of disjunction here complicates proofs considerably. 
    46         One alternative is to add a Boolean argument to indicate the direction. 
    47         Another is to develop the notions of increasing and decreasing first.*}
    48   [code del]: "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    49 
    50 definition
    51   incseq :: "(nat=>real)=>bool" where
    52     --{*Increasing sequence*}
    53   [code del]: "incseq X = (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
    54 
    55 definition
    56   decseq :: "(nat=>real)=>bool" where
    57     --{*Increasing sequence*}
    58   [code del]: "decseq X = (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
    59 
    60 definition
    61   subseq :: "(nat => nat) => bool" where
    62     --{*Definition of subsequence*}
    63   [code del]:   "subseq f = (\<forall>m. \<forall>n>m. (f m) < (f n))"
    64 
    65 definition
    66   Cauchy :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    67     --{*Standard definition of the Cauchy condition*}
    68   [code del]: "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
    69 
    70 
    71 subsection {* Bounded Sequences *}
    72 
    73 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
    74 unfolding Bseq_def
    75 proof (intro exI conjI allI)
    76   show "0 < max K 1" by simp
    77 next
    78   fix n::nat
    79   have "norm (X n) \<le> K" by (rule K)
    80   thus "norm (X n) \<le> max K 1" by simp
    81 qed
    82 
    83 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    84 unfolding Bseq_def by auto
    85 
    86 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
    87 proof (rule BseqI')
    88   let ?A = "norm ` X ` {..N}"
    89   have 1: "finite ?A" by simp
    90   fix n::nat
    91   show "norm (X n) \<le> max K (Max ?A)"
    92   proof (cases rule: linorder_le_cases)
    93     assume "n \<ge> N"
    94     hence "norm (X n) \<le> K" using K by simp
    95     thus "norm (X n) \<le> max K (Max ?A)" by simp
    96   next
    97     assume "n \<le> N"
    98     hence "norm (X n) \<in> ?A" by simp
    99     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
   100     thus "norm (X n) \<le> max K (Max ?A)" by simp
   101   qed
   102 qed
   103 
   104 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
   105 unfolding Bseq_def by auto
   106 
   107 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
   108 apply (erule BseqE)
   109 apply (rule_tac N="k" and K="K" in BseqI2')
   110 apply clarify
   111 apply (drule_tac x="n - k" in spec, simp)
   112 done
   113 
   114 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially"
   115 unfolding Bfun_def eventually_sequentially
   116 apply (rule iffI)
   117 apply (simp add: Bseq_def)
   118 apply (auto intro: BseqI2')
   119 done
   120 
   121 
   122 subsection {* Sequences That Converge to Zero *}
   123 
   124 lemma ZseqI:
   125   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r) \<Longrightarrow> Zseq X"
   126 unfolding Zseq_def by simp
   127 
   128 lemma ZseqD:
   129   "\<lbrakk>Zseq X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r"
   130 unfolding Zseq_def by simp
   131 
   132 lemma Zseq_conv_Zfun: "Zseq X \<longleftrightarrow> Zfun X sequentially"
   133 unfolding Zseq_def Zfun_def eventually_sequentially ..
   134 
   135 lemma Zseq_zero: "Zseq (\<lambda>n. 0)"
   136 unfolding Zseq_def by simp
   137 
   138 lemma Zseq_const_iff: "Zseq (\<lambda>n. k) = (k = 0)"
   139 unfolding Zseq_def by force
   140 
   141 lemma Zseq_norm_iff: "Zseq (\<lambda>n. norm (X n)) = Zseq (\<lambda>n. X n)"
   142 unfolding Zseq_def by simp
   143 
   144 lemma Zseq_imp_Zseq:
   145   assumes X: "Zseq X"
   146   assumes Y: "\<And>n. norm (Y n) \<le> norm (X n) * K"
   147   shows "Zseq (\<lambda>n. Y n)"
   148 using X Y Zfun_imp_Zfun [of X sequentially Y K]
   149 unfolding Zseq_conv_Zfun by simp
   150 
   151 lemma Zseq_le: "\<lbrakk>Zseq Y; \<forall>n. norm (X n) \<le> norm (Y n)\<rbrakk> \<Longrightarrow> Zseq X"
   152 by (erule_tac K="1" in Zseq_imp_Zseq, simp)
   153 
   154 lemma Zseq_add:
   155   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n + Y n)"
   156 unfolding Zseq_conv_Zfun by (rule Zfun_add)
   157 
   158 lemma Zseq_minus: "Zseq X \<Longrightarrow> Zseq (\<lambda>n. - X n)"
   159 unfolding Zseq_def by simp
   160 
   161 lemma Zseq_diff: "\<lbrakk>Zseq X; Zseq Y\<rbrakk> \<Longrightarrow> Zseq (\<lambda>n. X n - Y n)"
   162 by (simp only: diff_minus Zseq_add Zseq_minus)
   163 
   164 lemma (in bounded_linear) Zseq:
   165   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. f (X n))"
   166 unfolding Zseq_conv_Zfun by (rule Zfun)
   167 
   168 lemma (in bounded_bilinear) Zseq:
   169   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   170 unfolding Zseq_conv_Zfun by (rule Zfun)
   171 
   172 lemma (in bounded_bilinear) Zseq_prod_Bseq:
   173   "Zseq X \<Longrightarrow> Bseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   174 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   175 by (rule Zfun_prod_Bfun)
   176 
   177 lemma (in bounded_bilinear) Bseq_prod_Zseq:
   178   "Bseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   179 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   180 by (rule Bfun_prod_Zfun)
   181 
   182 lemma (in bounded_bilinear) Zseq_left:
   183   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. X n ** a)"
   184 by (rule bounded_linear_left [THEN bounded_linear.Zseq])
   185 
   186 lemma (in bounded_bilinear) Zseq_right:
   187   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. a ** X n)"
   188 by (rule bounded_linear_right [THEN bounded_linear.Zseq])
   189 
   190 lemmas Zseq_mult = mult.Zseq
   191 lemmas Zseq_mult_right = mult.Zseq_right
   192 lemmas Zseq_mult_left = mult.Zseq_left
   193 
   194 
   195 subsection {* Limits of Sequences *}
   196 
   197 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
   198   by simp
   199 
   200 lemma LIMSEQ_conv_tendsto: "(X ----> L) \<longleftrightarrow> (X ---> L) sequentially"
   201 unfolding LIMSEQ_def tendsto_iff eventually_sequentially ..
   202 
   203 lemma LIMSEQ_iff:
   204   fixes L :: "'a::real_normed_vector"
   205   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   206 unfolding LIMSEQ_def dist_norm ..
   207 
   208 lemma LIMSEQ_iff_nz: "X ----> L = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
   209   by (auto simp add: LIMSEQ_def) (metis Suc_leD zero_less_Suc)  
   210 
   211 lemma LIMSEQ_Zseq_iff: "((\<lambda>n. X n) ----> L) = Zseq (\<lambda>n. X n - L)"
   212 by (simp only: LIMSEQ_iff Zseq_def)
   213 
   214 lemma metric_LIMSEQ_I:
   215   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> L"
   216 by (simp add: LIMSEQ_def)
   217 
   218 lemma metric_LIMSEQ_D:
   219   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
   220 by (simp add: LIMSEQ_def)
   221 
   222 lemma LIMSEQ_I:
   223   fixes L :: "'a::real_normed_vector"
   224   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   225 by (simp add: LIMSEQ_iff)
   226 
   227 lemma LIMSEQ_D:
   228   fixes L :: "'a::real_normed_vector"
   229   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   230 by (simp add: LIMSEQ_iff)
   231 
   232 lemma LIMSEQ_const: "(\<lambda>n. k) ----> k"
   233 by (simp add: LIMSEQ_def)
   234 
   235 lemma LIMSEQ_const_iff: "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
   236 apply (safe intro!: LIMSEQ_const)
   237 apply (rule ccontr)
   238 apply (drule_tac r="dist k l" in metric_LIMSEQ_D)
   239 apply (simp add: zero_less_dist_iff)
   240 apply auto
   241 done
   242 
   243 lemma LIMSEQ_norm:
   244   fixes a :: "'a::real_normed_vector"
   245   shows "X ----> a \<Longrightarrow> (\<lambda>n. norm (X n)) ----> norm a"
   246 unfolding LIMSEQ_conv_tendsto by (rule tendsto_norm)
   247 
   248 lemma LIMSEQ_ignore_initial_segment:
   249   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   250 apply (rule metric_LIMSEQ_I)
   251 apply (drule (1) metric_LIMSEQ_D)
   252 apply (erule exE, rename_tac N)
   253 apply (rule_tac x=N in exI)
   254 apply simp
   255 done
   256 
   257 lemma LIMSEQ_offset:
   258   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   259 apply (rule metric_LIMSEQ_I)
   260 apply (drule (1) metric_LIMSEQ_D)
   261 apply (erule exE, rename_tac N)
   262 apply (rule_tac x="N + k" in exI)
   263 apply clarify
   264 apply (drule_tac x="n - k" in spec)
   265 apply (simp add: le_diff_conv2)
   266 done
   267 
   268 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   269 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   270 
   271 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   272 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   273 
   274 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   275 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   276 
   277 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   278   unfolding LIMSEQ_def
   279   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   280 
   281 lemma LIMSEQ_add:
   282   fixes a b :: "'a::real_normed_vector"
   283   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) ----> a + b"
   284 unfolding LIMSEQ_conv_tendsto by (rule tendsto_add)
   285 
   286 lemma LIMSEQ_minus:
   287   fixes a :: "'a::real_normed_vector"
   288   shows "X ----> a \<Longrightarrow> (\<lambda>n. - X n) ----> - a"
   289 unfolding LIMSEQ_conv_tendsto by (rule tendsto_minus)
   290 
   291 lemma LIMSEQ_minus_cancel:
   292   fixes a :: "'a::real_normed_vector"
   293   shows "(\<lambda>n. - X n) ----> - a \<Longrightarrow> X ----> a"
   294 by (drule LIMSEQ_minus, simp)
   295 
   296 lemma LIMSEQ_diff:
   297   fixes a b :: "'a::real_normed_vector"
   298   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) ----> a - b"
   299 unfolding LIMSEQ_conv_tendsto by (rule tendsto_diff)
   300 
   301 lemma LIMSEQ_unique: "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   302 apply (rule ccontr)
   303 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   304 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   305 apply (clarify, rename_tac M N)
   306 apply (subgoal_tac "dist a b < dist a b / 2 + dist a b / 2", simp)
   307 apply (subgoal_tac "dist a b \<le> dist (X (max M N)) a + dist (X (max M N)) b")
   308 apply (erule le_less_trans, rule add_strict_mono, simp, simp)
   309 apply (subst dist_commute, rule dist_triangle)
   310 done
   311 
   312 lemma (in bounded_linear) LIMSEQ:
   313   "X ----> a \<Longrightarrow> (\<lambda>n. f (X n)) ----> f a"
   314 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   315 
   316 lemma (in bounded_bilinear) LIMSEQ:
   317   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n ** Y n) ----> a ** b"
   318 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   319 
   320 lemma LIMSEQ_mult:
   321   fixes a b :: "'a::real_normed_algebra"
   322   shows "[| X ----> a; Y ----> b |] ==> (%n. X n * Y n) ----> a * b"
   323 by (rule mult.LIMSEQ)
   324 
   325 lemma increasing_LIMSEQ:
   326   fixes f :: "nat \<Rightarrow> real"
   327   assumes inc: "!!n. f n \<le> f (Suc n)"
   328       and bdd: "!!n. f n \<le> l"
   329       and en: "!!e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
   330   shows "f ----> l"
   331 proof (auto simp add: LIMSEQ_def)
   332   fix e :: real
   333   assume e: "0 < e"
   334   then obtain N where "l \<le> f N + e/2"
   335     by (metis half_gt_zero e en that)
   336   hence N: "l < f N + e" using e
   337     by simp
   338   { fix k
   339     have [simp]: "!!n. \<bar>f n - l\<bar> = l - f n"
   340       by (simp add: bdd) 
   341     have "\<bar>f (N+k) - l\<bar> < e"
   342     proof (induct k)
   343       case 0 show ?case using N
   344         by simp   
   345     next
   346       case (Suc k) thus ?case using N inc [of "N+k"]
   347         by simp
   348     qed 
   349   } note 1 = this
   350   { fix n
   351     have "N \<le> n \<Longrightarrow> \<bar>f n - l\<bar> < e" using 1 [of "n-N"]
   352       by simp 
   353   } note [intro] = this
   354   show " \<exists>no. \<forall>n\<ge>no. dist (f n) l < e"
   355     by (auto simp add: dist_real_def) 
   356   qed
   357 
   358 lemma Bseq_inverse_lemma:
   359   fixes x :: "'a::real_normed_div_algebra"
   360   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   361 apply (subst nonzero_norm_inverse, clarsimp)
   362 apply (erule (1) le_imp_inverse_le)
   363 done
   364 
   365 lemma Bseq_inverse:
   366   fixes a :: "'a::real_normed_div_algebra"
   367   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
   368 unfolding LIMSEQ_conv_tendsto Bseq_conv_Bfun
   369 by (rule Bfun_inverse)
   370 
   371 lemma LIMSEQ_inverse:
   372   fixes a :: "'a::real_normed_div_algebra"
   373   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> inverse a"
   374 unfolding LIMSEQ_conv_tendsto
   375 by (rule tendsto_inverse)
   376 
   377 lemma LIMSEQ_divide:
   378   fixes a b :: "'a::real_normed_field"
   379   shows "\<lbrakk>X ----> a; Y ----> b; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. X n / Y n) ----> a / b"
   380 by (simp add: LIMSEQ_mult LIMSEQ_inverse divide_inverse)
   381 
   382 lemma LIMSEQ_pow:
   383   fixes a :: "'a::{power, real_normed_algebra}"
   384   shows "X ----> a \<Longrightarrow> (\<lambda>n. (X n) ^ m) ----> a ^ m"
   385 by (induct m) (simp_all add: LIMSEQ_const LIMSEQ_mult)
   386 
   387 lemma LIMSEQ_setsum:
   388   fixes L :: "'a \<Rightarrow> 'b::real_normed_vector"
   389   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   390   shows "(\<lambda>m. \<Sum>n\<in>S. X n m) ----> (\<Sum>n\<in>S. L n)"
   391 using n unfolding LIMSEQ_conv_tendsto by (rule tendsto_setsum)
   392 
   393 lemma LIMSEQ_setprod:
   394   fixes L :: "'a \<Rightarrow> 'b::{real_normed_algebra,comm_ring_1}"
   395   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   396   shows "(\<lambda>m. \<Prod>n\<in>S. X n m) ----> (\<Prod>n\<in>S. L n)"
   397 proof (cases "finite S")
   398   case True
   399   thus ?thesis using n
   400   proof (induct)
   401     case empty
   402     show ?case
   403       by (simp add: LIMSEQ_const)
   404   next
   405     case insert
   406     thus ?case
   407       by (simp add: LIMSEQ_mult)
   408   qed
   409 next
   410   case False
   411   thus ?thesis
   412     by (simp add: setprod_def LIMSEQ_const)
   413 qed
   414 
   415 lemma LIMSEQ_add_const:
   416   fixes a :: "'a::real_normed_vector"
   417   shows "f ----> a ==> (%n.(f n + b)) ----> a + b"
   418 by (simp add: LIMSEQ_add LIMSEQ_const)
   419 
   420 (* FIXME: delete *)
   421 lemma LIMSEQ_add_minus:
   422   fixes a b :: "'a::real_normed_vector"
   423   shows "[| X ----> a; Y ----> b |] ==> (%n. X n + -Y n) ----> a + -b"
   424 by (simp only: LIMSEQ_add LIMSEQ_minus)
   425 
   426 lemma LIMSEQ_diff_const:
   427   fixes a b :: "'a::real_normed_vector"
   428   shows "f ----> a ==> (%n.(f n  - b)) ----> a - b"
   429 by (simp add: LIMSEQ_diff LIMSEQ_const)
   430 
   431 lemma LIMSEQ_diff_approach_zero:
   432   fixes L :: "'a::real_normed_vector"
   433   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
   434 by (drule (1) LIMSEQ_add, simp)
   435 
   436 lemma LIMSEQ_diff_approach_zero2:
   437   fixes L :: "'a::real_normed_vector"
   438   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L"
   439 by (drule (1) LIMSEQ_diff, simp)
   440 
   441 text{*A sequence tends to zero iff its abs does*}
   442 lemma LIMSEQ_norm_zero:
   443   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   444   shows "((\<lambda>n. norm (X n)) ----> 0) \<longleftrightarrow> (X ----> 0)"
   445 by (simp add: LIMSEQ_iff)
   446 
   447 lemma LIMSEQ_rabs_zero: "((%n. \<bar>f n\<bar>) ----> 0) = (f ----> (0::real))"
   448 by (simp add: LIMSEQ_iff)
   449 
   450 lemma LIMSEQ_imp_rabs: "f ----> (l::real) ==> (%n. \<bar>f n\<bar>) ----> \<bar>l\<bar>"
   451 by (drule LIMSEQ_norm, simp)
   452 
   453 text{*An unbounded sequence's inverse tends to 0*}
   454 
   455 lemma LIMSEQ_inverse_zero:
   456   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   457 apply (rule LIMSEQ_I)
   458 apply (drule_tac x="inverse r" in spec, safe)
   459 apply (rule_tac x="N" in exI, safe)
   460 apply (drule_tac x="n" in spec, safe)
   461 apply (frule positive_imp_inverse_positive)
   462 apply (frule (1) less_imp_inverse_less)
   463 apply (subgoal_tac "0 < X n", simp)
   464 apply (erule (1) order_less_trans)
   465 done
   466 
   467 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   468 
   469 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   470 apply (rule LIMSEQ_inverse_zero, safe)
   471 apply (cut_tac x = r in reals_Archimedean2)
   472 apply (safe, rule_tac x = n in exI)
   473 apply (auto simp add: real_of_nat_Suc)
   474 done
   475 
   476 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   477 infinity is now easily proved*}
   478 
   479 lemma LIMSEQ_inverse_real_of_nat_add:
   480      "(%n. r + inverse(real(Suc n))) ----> r"
   481 by (cut_tac LIMSEQ_add [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   482 
   483 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   484      "(%n. r + -inverse(real(Suc n))) ----> r"
   485 by (cut_tac LIMSEQ_add_minus [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   486 
   487 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   488      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   489 by (cut_tac b=1 in
   490         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat_add_minus], auto)
   491 
   492 lemma LIMSEQ_le_const:
   493   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   494 apply (rule ccontr, simp only: linorder_not_le)
   495 apply (drule_tac r="a - x" in LIMSEQ_D, simp)
   496 apply clarsimp
   497 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI1)
   498 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI2)
   499 apply simp
   500 done
   501 
   502 lemma LIMSEQ_le_const2:
   503   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   504 apply (subgoal_tac "- a \<le> - x", simp)
   505 apply (rule LIMSEQ_le_const)
   506 apply (erule LIMSEQ_minus)
   507 apply simp
   508 done
   509 
   510 lemma LIMSEQ_le:
   511   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::real)"
   512 apply (subgoal_tac "0 \<le> y - x", simp)
   513 apply (rule LIMSEQ_le_const)
   514 apply (erule (1) LIMSEQ_diff)
   515 apply (simp add: le_diff_eq)
   516 done
   517 
   518 
   519 subsection {* Convergence *}
   520 
   521 lemma limI: "X ----> L ==> lim X = L"
   522 apply (simp add: lim_def)
   523 apply (blast intro: LIMSEQ_unique)
   524 done
   525 
   526 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   527 by (simp add: convergent_def)
   528 
   529 lemma convergentI: "(X ----> L) ==> convergent X"
   530 by (auto simp add: convergent_def)
   531 
   532 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   533 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   534 
   535 lemma convergent_const: "convergent (\<lambda>n. c)"
   536 by (rule convergentI, rule LIMSEQ_const)
   537 
   538 lemma convergent_add:
   539   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
   540   assumes "convergent (\<lambda>n. X n)"
   541   assumes "convergent (\<lambda>n. Y n)"
   542   shows "convergent (\<lambda>n. X n + Y n)"
   543 using assms unfolding convergent_def by (fast intro: LIMSEQ_add)
   544 
   545 lemma convergent_setsum:
   546   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
   547   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
   548   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
   549 proof (cases "finite A")
   550   case True from this and assms show ?thesis
   551     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
   552 qed (simp add: convergent_const)
   553 
   554 lemma (in bounded_linear) convergent:
   555   assumes "convergent (\<lambda>n. X n)"
   556   shows "convergent (\<lambda>n. f (X n))"
   557 using assms unfolding convergent_def by (fast intro: LIMSEQ)
   558 
   559 lemma (in bounded_bilinear) convergent:
   560   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
   561   shows "convergent (\<lambda>n. X n ** Y n)"
   562 using assms unfolding convergent_def by (fast intro: LIMSEQ)
   563 
   564 lemma convergent_minus_iff:
   565   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   566   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
   567 apply (simp add: convergent_def)
   568 apply (auto dest: LIMSEQ_minus)
   569 apply (drule LIMSEQ_minus, auto)
   570 done
   571 
   572 lemma lim_le:
   573   fixes x :: real
   574   assumes f: "convergent f" and fn_le: "!!n. f n \<le> x"
   575   shows "lim f \<le> x"
   576 proof (rule classical)
   577   assume "\<not> lim f \<le> x"
   578   hence 0: "0 < lim f - x" by arith
   579   have 1: "f----> lim f"
   580     by (metis convergent_LIMSEQ_iff f) 
   581   thus ?thesis
   582     proof (simp add: LIMSEQ_iff)
   583       assume "\<forall>r>0. \<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < r"
   584       hence "\<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   585         by (metis 0)
   586       from this obtain no where "\<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   587         by blast
   588       thus "lim f \<le> x"
   589         by (metis add_cancel_end add_minus_cancel diff_def linorder_linear 
   590                   linorder_not_le minus_diff_eq abs_diff_less_iff fn_le) 
   591     qed
   592 qed
   593 
   594 text{* Given a binary function @{text "f:: nat \<Rightarrow> 'a \<Rightarrow> 'a"}, its values are uniquely determined by a function g *}
   595 
   596 lemma nat_function_unique: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
   597   unfolding Ex1_def
   598   apply (rule_tac x="nat_rec e f" in exI)
   599   apply (rule conjI)+
   600 apply (rule def_nat_rec_0, simp)
   601 apply (rule allI, rule def_nat_rec_Suc, simp)
   602 apply (rule allI, rule impI, rule ext)
   603 apply (erule conjE)
   604 apply (induct_tac x)
   605 apply simp
   606 apply (erule_tac x="n" in allE)
   607 apply (simp)
   608 done
   609 
   610 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   611 
   612 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   613 apply (simp add: subseq_def)
   614 apply (auto dest!: less_imp_Suc_add)
   615 apply (induct_tac k)
   616 apply (auto intro: less_trans)
   617 done
   618 
   619 lemma monoseq_Suc:
   620    "monoseq X = ((\<forall>n. X n \<le> X (Suc n))
   621                  | (\<forall>n. X (Suc n) \<le> X n))"
   622 apply (simp add: monoseq_def)
   623 apply (auto dest!: le_imp_less_or_eq)
   624 apply (auto intro!: lessI [THEN less_imp_le] dest!: less_imp_Suc_add)
   625 apply (induct_tac "ka")
   626 apply (auto intro: order_trans)
   627 apply (erule contrapos_np)
   628 apply (induct_tac "k")
   629 apply (auto intro: order_trans)
   630 done
   631 
   632 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   633 by (simp add: monoseq_def)
   634 
   635 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   636 by (simp add: monoseq_def)
   637 
   638 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   639 by (simp add: monoseq_Suc)
   640 
   641 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   642 by (simp add: monoseq_Suc)
   643 
   644 lemma monoseq_minus: assumes "monoseq a"
   645   shows "monoseq (\<lambda> n. - a n)"
   646 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   647   case True
   648   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   649   thus ?thesis by (rule monoI2)
   650 next
   651   case False
   652   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   653   thus ?thesis by (rule monoI1)
   654 qed
   655 
   656 lemma monoseq_le: assumes "monoseq a" and "a ----> x"
   657   shows "((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> 
   658          ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   659 proof -
   660   { fix x n fix a :: "nat \<Rightarrow> real"
   661     assume "a ----> x" and "\<forall> m. \<forall> n \<ge> m. a m \<le> a n"
   662     hence monotone: "\<And> m n. m \<le> n \<Longrightarrow> a m \<le> a n" by auto
   663     have "a n \<le> x"
   664     proof (rule ccontr)
   665       assume "\<not> a n \<le> x" hence "x < a n" by auto
   666       hence "0 < a n - x" by auto
   667       from `a ----> x`[THEN LIMSEQ_D, OF this]
   668       obtain no where "\<And>n'. no \<le> n' \<Longrightarrow> norm (a n' - x) < a n - x" by blast
   669       hence "norm (a (max no n) - x) < a n - x" by auto
   670       moreover
   671       { fix n' have "n \<le> n' \<Longrightarrow> x < a n'" using monotone[where m=n and n=n'] and `x < a n` by auto }
   672       hence "x < a (max no n)" by auto
   673       ultimately
   674       have "a (max no n) < a n" by auto
   675       with monotone[where m=n and n="max no n"]
   676       show False by (auto simp:max_def split:split_if_asm)
   677     qed
   678   } note top_down = this
   679   { fix x n m fix a :: "nat \<Rightarrow> real"
   680     assume "a ----> x" and "monoseq a" and "a m < x"
   681     have "a n \<le> x \<and> (\<forall> m. \<forall> n \<ge> m. a m \<le> a n)"
   682     proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   683       case True with top_down and `a ----> x` show ?thesis by auto
   684     next
   685       case False with `monoseq a`[unfolded monoseq_def] have "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" by auto
   686       hence "- a m \<le> - x" using top_down[OF LIMSEQ_minus[OF `a ----> x`]] by blast
   687       hence False using `a m < x` by auto
   688       thus ?thesis ..
   689     qed
   690   } note when_decided = this
   691 
   692   show ?thesis
   693   proof (cases "\<exists> m. a m \<noteq> x")
   694     case True then obtain m where "a m \<noteq> x" by auto
   695     show ?thesis
   696     proof (cases "a m < x")
   697       case True with when_decided[OF `a ----> x` `monoseq a`, where m2=m]
   698       show ?thesis by blast
   699     next
   700       case False hence "- a m < - x" using `a m \<noteq> x` by auto
   701       with when_decided[OF LIMSEQ_minus[OF `a ----> x`] monoseq_minus[OF `monoseq a`], where m2=m]
   702       show ?thesis by auto
   703     qed
   704   qed auto
   705 qed
   706 
   707 text{* for any sequence, there is a mootonic subsequence *}
   708 lemma seq_monosub: "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
   709 proof-
   710   {assume H: "\<forall>n. \<exists>p >n. \<forall> m\<ge>p. s m \<le> s p"
   711     let ?P = "\<lambda> p n. p > n \<and> (\<forall>m \<ge> p. s m \<le> s p)"
   712     from nat_function_unique[of "SOME p. ?P p 0" "\<lambda>p n. SOME p. ?P p n"]
   713     obtain f where f: "f 0 = (SOME p. ?P p 0)" "\<forall>n. f (Suc n) = (SOME p. ?P p (f n))" by blast
   714     have "?P (f 0) 0"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p 0"]
   715       using H apply - 
   716       apply (erule allE[where x=0], erule exE, rule_tac x="p" in exI) 
   717       unfolding order_le_less by blast 
   718     hence f0: "f 0 > 0" "\<forall>m \<ge> f 0. s m \<le> s (f 0)" by blast+
   719     {fix n
   720       have "?P (f (Suc n)) (f n)" 
   721         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   722         using H apply - 
   723       apply (erule allE[where x="f n"], erule exE, rule_tac x="p" in exI) 
   724       unfolding order_le_less by blast 
   725     hence "f (Suc n) > f n" "\<forall>m \<ge> f (Suc n). s m \<le> s (f (Suc n))" by blast+}
   726   note fSuc = this
   727     {fix p q assume pq: "p \<ge> f q"
   728       have "s p \<le> s(f(q))"  using f0(2)[rule_format, of p] pq fSuc
   729         by (cases q, simp_all) }
   730     note pqth = this
   731     {fix q
   732       have "f (Suc q) > f q" apply (induct q) 
   733         using f0(1) fSuc(1)[of 0] apply simp by (rule fSuc(1))}
   734     note fss = this
   735     from fss have th1: "subseq f" unfolding subseq_Suc_iff ..
   736     {fix a b 
   737       have "f a \<le> f (a + b)"
   738       proof(induct b)
   739         case 0 thus ?case by simp
   740       next
   741         case (Suc b)
   742         from fSuc(1)[of "a + b"] Suc.hyps show ?case by simp
   743       qed}
   744     note fmon0 = this
   745     have "monoseq (\<lambda>n. s (f n))" 
   746     proof-
   747       {fix n
   748         have "s (f n) \<ge> s (f (Suc n))" 
   749         proof(cases n)
   750           case 0
   751           assume n0: "n = 0"
   752           from fSuc(1)[of 0] have th0: "f 0 \<le> f (Suc 0)" by simp
   753           from f0(2)[rule_format, OF th0] show ?thesis  using n0 by simp
   754         next
   755           case (Suc m)
   756           assume m: "n = Suc m"
   757           from fSuc(1)[of n] m have th0: "f (Suc m) \<le> f (Suc (Suc m))" by simp
   758           from m fSuc(2)[rule_format, OF th0] show ?thesis by simp 
   759         qed}
   760       thus "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc by blast 
   761     qed
   762     with th1 have ?thesis by blast}
   763   moreover
   764   {fix N assume N: "\<forall>p >N. \<exists> m\<ge>p. s m > s p"
   765     {fix p assume p: "p \<ge> Suc N" 
   766       hence pN: "p > N" by arith with N obtain m where m: "m \<ge> p" "s m > s p" by blast
   767       have "m \<noteq> p" using m(2) by auto 
   768       with m have "\<exists>m>p. s p < s m" by - (rule exI[where x=m], auto)}
   769     note th0 = this
   770     let ?P = "\<lambda>m x. m > x \<and> s x < s m"
   771     from nat_function_unique[of "SOME x. ?P x (Suc N)" "\<lambda>m x. SOME y. ?P y x"]
   772     obtain f where f: "f 0 = (SOME x. ?P x (Suc N))" 
   773       "\<forall>n. f (Suc n) = (SOME m. ?P m (f n))" by blast
   774     have "?P (f 0) (Suc N)"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p (Suc N)"]
   775       using N apply - 
   776       apply (erule allE[where x="Suc N"], clarsimp)
   777       apply (rule_tac x="m" in exI)
   778       apply auto
   779       apply (subgoal_tac "Suc N \<noteq> m")
   780       apply simp
   781       apply (rule ccontr, simp)
   782       done
   783     hence f0: "f 0 > Suc N" "s (Suc N) < s (f 0)" by blast+
   784     {fix n
   785       have "f n > N \<and> ?P (f (Suc n)) (f n)"
   786         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   787       proof (induct n)
   788         case 0 thus ?case
   789           using f0 N apply auto 
   790           apply (erule allE[where x="f 0"], clarsimp) 
   791           apply (rule_tac x="m" in exI, simp)
   792           by (subgoal_tac "f 0 \<noteq> m", auto)
   793       next
   794         case (Suc n)
   795         from Suc.hyps have Nfn: "N < f n" by blast
   796         from Suc.hyps obtain m where m: "m > f n" "s (f n) < s m" by blast
   797         with Nfn have mN: "m > N" by arith
   798         note key = Suc.hyps[unfolded some_eq_ex[of "\<lambda>p. ?P p (f n)", symmetric] f(2)[rule_format, of n, symmetric]]
   799         
   800         from key have th0: "f (Suc n) > N" by simp
   801         from N[rule_format, OF th0]
   802         obtain m' where m': "m' \<ge> f (Suc n)" "s (f (Suc n)) < s m'" by blast
   803         have "m' \<noteq> f (Suc (n))" apply (rule ccontr) using m'(2) by auto
   804         hence "m' > f (Suc n)" using m'(1) by simp
   805         with key m'(2) show ?case by auto
   806       qed}
   807     note fSuc = this
   808     {fix n
   809       have "f n \<ge> Suc N \<and> f(Suc n) > f n \<and> s(f n) < s(f(Suc n))" using fSuc[of n] by auto 
   810       hence "f n \<ge> Suc N" "f(Suc n) > f n" "s(f n) < s(f(Suc n))" by blast+}
   811     note thf = this
   812     have sqf: "subseq f" unfolding subseq_Suc_iff using thf by simp
   813     have "monoseq (\<lambda>n. s (f n))"  unfolding monoseq_Suc using thf
   814       apply -
   815       apply (rule disjI1)
   816       apply auto
   817       apply (rule order_less_imp_le)
   818       apply blast
   819       done
   820     then have ?thesis  using sqf by blast}
   821   ultimately show ?thesis unfolding linorder_not_less[symmetric] by blast
   822 qed
   823 
   824 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   825 proof(induct n)
   826   case 0 thus ?case by simp
   827 next
   828   case (Suc n)
   829   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   830   have "n < f (Suc n)" by arith 
   831   thus ?case by arith
   832 qed
   833 
   834 lemma LIMSEQ_subseq_LIMSEQ:
   835   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
   836 apply (auto simp add: LIMSEQ_def) 
   837 apply (drule_tac x=r in spec, clarify)  
   838 apply (rule_tac x=no in exI, clarify) 
   839 apply (blast intro: seq_suble le_trans dest!: spec) 
   840 done
   841 
   842 subsection {* Bounded Monotonic Sequences *}
   843 
   844 
   845 text{*Bounded Sequence*}
   846 
   847 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   848 by (simp add: Bseq_def)
   849 
   850 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   851 by (auto simp add: Bseq_def)
   852 
   853 lemma lemma_NBseq_def:
   854      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) =
   855       (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   856 proof auto
   857   fix K :: real
   858   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   859   then have "K \<le> real (Suc n)" by auto
   860   assume "\<forall>m. norm (X m) \<le> K"
   861   have "\<forall>m. norm (X m) \<le> real (Suc n)"
   862   proof
   863     fix m :: 'a
   864     from `\<forall>m. norm (X m) \<le> K` have "norm (X m) \<le> K" ..
   865     with `K \<le> real (Suc n)` show "norm (X m) \<le> real (Suc n)" by auto
   866   qed
   867   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   868 next
   869   fix N :: nat
   870   have "real (Suc N) > 0" by (simp add: real_of_nat_Suc)
   871   moreover assume "\<forall>n. norm (X n) \<le> real (Suc N)"
   872   ultimately show "\<exists>K>0. \<forall>n. norm (X n) \<le> K" by blast
   873 qed
   874 
   875 
   876 text{* alternative definition for Bseq *}
   877 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   878 apply (simp add: Bseq_def)
   879 apply (simp (no_asm) add: lemma_NBseq_def)
   880 done
   881 
   882 lemma lemma_NBseq_def2:
   883      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   884 apply (subst lemma_NBseq_def, auto)
   885 apply (rule_tac x = "Suc N" in exI)
   886 apply (rule_tac [2] x = N in exI)
   887 apply (auto simp add: real_of_nat_Suc)
   888  prefer 2 apply (blast intro: order_less_imp_le)
   889 apply (drule_tac x = n in spec, simp)
   890 done
   891 
   892 (* yet another definition for Bseq *)
   893 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   894 by (simp add: Bseq_def lemma_NBseq_def2)
   895 
   896 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   897 
   898 lemma Bseq_isUb:
   899   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   900 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   901 
   902 
   903 text{* Use completeness of reals (supremum property)
   904    to show that any bounded sequence has a least upper bound*}
   905 
   906 lemma Bseq_isLub:
   907   "!!(X::nat=>real). Bseq X ==>
   908    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   909 by (blast intro: reals_complete Bseq_isUb)
   910 
   911 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   912 
   913 lemma lemma_converg1:
   914      "!!(X::nat=>real). [| \<forall>m. \<forall> n \<ge> m. X m \<le> X n;
   915                   isLub (UNIV::real set) {x. \<exists>n. X n = x} (X ma)
   916                |] ==> \<forall>n \<ge> ma. X n = X ma"
   917 apply safe
   918 apply (drule_tac y = "X n" in isLubD2)
   919 apply (blast dest: order_antisym)+
   920 done
   921 
   922 text{* The best of both worlds: Easier to prove this result as a standard
   923    theorem and then use equivalence to "transfer" it into the
   924    equivalent nonstandard form if needed!*}
   925 
   926 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   927 apply (simp add: LIMSEQ_def)
   928 apply (rule_tac x = "X m" in exI, safe)
   929 apply (rule_tac x = m in exI, safe)
   930 apply (drule spec, erule impE, auto)
   931 done
   932 
   933 lemma lemma_converg2:
   934    "!!(X::nat=>real).
   935     [| \<forall>m. X m ~= U;  isLub UNIV {x. \<exists>n. X n = x} U |] ==> \<forall>m. X m < U"
   936 apply safe
   937 apply (drule_tac y = "X m" in isLubD2)
   938 apply (auto dest!: order_le_imp_less_or_eq)
   939 done
   940 
   941 lemma lemma_converg3: "!!(X ::nat=>real). \<forall>m. X m \<le> U ==> isUb UNIV {x. \<exists>n. X n = x} U"
   942 by (rule setleI [THEN isUbI], auto)
   943 
   944 text{* FIXME: @{term "U - T < U"} is redundant *}
   945 lemma lemma_converg4: "!!(X::nat=> real).
   946                [| \<forall>m. X m ~= U;
   947                   isLub UNIV {x. \<exists>n. X n = x} U;
   948                   0 < T;
   949                   U + - T < U
   950                |] ==> \<exists>m. U + -T < X m & X m < U"
   951 apply (drule lemma_converg2, assumption)
   952 apply (rule ccontr, simp)
   953 apply (simp add: linorder_not_less)
   954 apply (drule lemma_converg3)
   955 apply (drule isLub_le_isUb, assumption)
   956 apply (auto dest: order_less_le_trans)
   957 done
   958 
   959 text{*A standard proof of the theorem for monotone increasing sequence*}
   960 
   961 lemma Bseq_mono_convergent:
   962      "[| Bseq X; \<forall>m. \<forall>n \<ge> m. X m \<le> X n |] ==> convergent (X::nat=>real)"
   963 apply (simp add: convergent_def)
   964 apply (frule Bseq_isLub, safe)
   965 apply (case_tac "\<exists>m. X m = U", auto)
   966 apply (blast dest: lemma_converg1 Bmonoseq_LIMSEQ)
   967 (* second case *)
   968 apply (rule_tac x = U in exI)
   969 apply (subst LIMSEQ_iff, safe)
   970 apply (frule lemma_converg2, assumption)
   971 apply (drule lemma_converg4, auto)
   972 apply (rule_tac x = m in exI, safe)
   973 apply (subgoal_tac "X m \<le> X n")
   974  prefer 2 apply blast
   975 apply (drule_tac x=n and P="%m. X m < U" in spec, arith)
   976 done
   977 
   978 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   979 by (simp add: Bseq_def)
   980 
   981 text{*Main monotonicity theorem*}
   982 lemma Bseq_monoseq_convergent: "[| Bseq X; monoseq X |] ==> convergent X"
   983 apply (simp add: monoseq_def, safe)
   984 apply (rule_tac [2] convergent_minus_iff [THEN ssubst])
   985 apply (drule_tac [2] Bseq_minus_iff [THEN ssubst])
   986 apply (auto intro!: Bseq_mono_convergent)
   987 done
   988 
   989 subsubsection{*Increasing and Decreasing Series*}
   990 
   991 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   992   by (simp add: incseq_def monoseq_def) 
   993 
   994 lemma incseq_le: assumes inc: "incseq X" and lim: "X ----> L" shows "X n \<le> L"
   995   using monoseq_le [OF incseq_imp_monoseq [OF inc] lim]
   996 proof
   997   assume "(\<forall>n. X n \<le> L) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n)"
   998   thus ?thesis by simp
   999 next
  1000   assume "(\<forall>n. L \<le> X n) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X n \<le> X m)"
  1001   hence const: "(!!m n. m \<le> n \<Longrightarrow> X n = X m)" using inc
  1002     by (auto simp add: incseq_def intro: order_antisym)
  1003   have X: "!!n. X n = X 0"
  1004     by (blast intro: const [of 0]) 
  1005   have "X = (\<lambda>n. X 0)"
  1006     by (blast intro: ext X)
  1007   hence "L = X 0" using LIMSEQ_const [of "X 0"]
  1008     by (auto intro: LIMSEQ_unique lim) 
  1009   thus ?thesis
  1010     by (blast intro: eq_refl X)
  1011 qed
  1012 
  1013 lemma incseq_SucI:
  1014   assumes "\<And>n. X n \<le> X (Suc n)"
  1015   shows "incseq X" unfolding incseq_def
  1016 proof safe
  1017   fix m n :: nat
  1018   { fix d m :: nat
  1019     have "X m \<le> X (m + d)"
  1020     proof (induct d)
  1021       case (Suc d)
  1022       also have "X (m + d) \<le> X (m + Suc d)"
  1023         using assms by simp
  1024       finally show ?case .
  1025     qed simp }
  1026   note this[of m "n - m"]
  1027   moreover assume "m \<le> n"
  1028   ultimately show "X m \<le> X n" by simp
  1029 qed
  1030 
  1031 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1032   by (simp add: decseq_def monoseq_def)
  1033 
  1034 lemma decseq_eq_incseq: "decseq X = incseq (\<lambda>n. - X n)" 
  1035   by (simp add: decseq_def incseq_def)
  1036 
  1037 
  1038 lemma decseq_le: assumes dec: "decseq X" and lim: "X ----> L" shows "L \<le> X n"
  1039 proof -
  1040   have inc: "incseq (\<lambda>n. - X n)" using dec
  1041     by (simp add: decseq_eq_incseq)
  1042   have "- X n \<le> - L" 
  1043     by (blast intro: incseq_le [OF inc] LIMSEQ_minus lim) 
  1044   thus ?thesis
  1045     by simp
  1046 qed
  1047 
  1048 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
  1049 
  1050 text{*alternative formulation for boundedness*}
  1051 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
  1052 apply (unfold Bseq_def, safe)
  1053 apply (rule_tac [2] x = "k + norm x" in exI)
  1054 apply (rule_tac x = K in exI, simp)
  1055 apply (rule exI [where x = 0], auto)
  1056 apply (erule order_less_le_trans, simp)
  1057 apply (drule_tac x=n in spec, fold diff_def)
  1058 apply (drule order_trans [OF norm_triangle_ineq2])
  1059 apply simp
  1060 done
  1061 
  1062 text{*alternative formulation for boundedness*}
  1063 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
  1064 apply safe
  1065 apply (simp add: Bseq_def, safe)
  1066 apply (rule_tac x = "K + norm (X N)" in exI)
  1067 apply auto
  1068 apply (erule order_less_le_trans, simp)
  1069 apply (rule_tac x = N in exI, safe)
  1070 apply (drule_tac x = n in spec)
  1071 apply (rule order_trans [OF norm_triangle_ineq], simp)
  1072 apply (auto simp add: Bseq_iff2)
  1073 done
  1074 
  1075 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
  1076 apply (simp add: Bseq_def)
  1077 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
  1078 apply (drule_tac x = n in spec, arith)
  1079 done
  1080 
  1081 
  1082 subsection {* Cauchy Sequences *}
  1083 
  1084 lemma metric_CauchyI:
  1085   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1086 by (simp add: Cauchy_def)
  1087 
  1088 lemma metric_CauchyD:
  1089   "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1090 by (simp add: Cauchy_def)
  1091 
  1092 lemma Cauchy_iff:
  1093   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1094   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1095 unfolding Cauchy_def dist_norm ..
  1096 
  1097 lemma Cauchy_iff2:
  1098      "Cauchy X =
  1099       (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1100 apply (simp add: Cauchy_iff, auto)
  1101 apply (drule reals_Archimedean, safe)
  1102 apply (drule_tac x = n in spec, auto)
  1103 apply (rule_tac x = M in exI, auto)
  1104 apply (drule_tac x = m in spec, simp)
  1105 apply (drule_tac x = na in spec, auto)
  1106 done
  1107 
  1108 lemma CauchyI:
  1109   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1110   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1111 by (simp add: Cauchy_iff)
  1112 
  1113 lemma CauchyD:
  1114   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1115   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1116 by (simp add: Cauchy_iff)
  1117 
  1118 lemma Cauchy_subseq_Cauchy:
  1119   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1120 apply (auto simp add: Cauchy_def)
  1121 apply (drule_tac x=e in spec, clarify)
  1122 apply (rule_tac x=M in exI, clarify)
  1123 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1124 done
  1125 
  1126 subsubsection {* Cauchy Sequences are Bounded *}
  1127 
  1128 text{*A Cauchy sequence is bounded -- this is the standard
  1129   proof mechanization rather than the nonstandard proof*}
  1130 
  1131 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1132           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1133 apply (clarify, drule spec, drule (1) mp)
  1134 apply (simp only: norm_minus_commute)
  1135 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1136 apply simp
  1137 done
  1138 
  1139 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
  1140 apply (simp add: Cauchy_iff)
  1141 apply (drule spec, drule mp, rule zero_less_one, safe)
  1142 apply (drule_tac x="M" in spec, simp)
  1143 apply (drule lemmaCauchy)
  1144 apply (rule_tac k="M" in Bseq_offset)
  1145 apply (simp add: Bseq_def)
  1146 apply (rule_tac x="1 + norm (X M)" in exI)
  1147 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
  1148 apply (simp add: order_less_imp_le)
  1149 done
  1150 
  1151 subsubsection {* Cauchy Sequences are Convergent *}
  1152 
  1153 class complete_space =
  1154   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1155 
  1156 class banach = real_normed_vector + complete_space
  1157 
  1158 theorem LIMSEQ_imp_Cauchy:
  1159   assumes X: "X ----> a" shows "Cauchy X"
  1160 proof (rule metric_CauchyI)
  1161   fix e::real assume "0 < e"
  1162   hence "0 < e/2" by simp
  1163   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1164   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1165   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1166   proof (intro exI allI impI)
  1167     fix m assume "N \<le> m"
  1168     hence m: "dist (X m) a < e/2" using N by fast
  1169     fix n assume "N \<le> n"
  1170     hence n: "dist (X n) a < e/2" using N by fast
  1171     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1172       by (rule dist_triangle2)
  1173     also from m n have "\<dots> < e" by simp
  1174     finally show "dist (X m) (X n) < e" .
  1175   qed
  1176 qed
  1177 
  1178 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1179 unfolding convergent_def
  1180 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1181 
  1182 lemma Cauchy_convergent_iff:
  1183   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1184   shows "Cauchy X = convergent X"
  1185 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1186 
  1187 lemma convergent_subseq_convergent:
  1188   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1189   shows "\<lbrakk> convergent X; subseq f \<rbrakk> \<Longrightarrow> convergent (X o f)"
  1190   by (simp add: Cauchy_subseq_Cauchy Cauchy_convergent_iff [symmetric])
  1191 
  1192 text {*
  1193 Proof that Cauchy sequences converge based on the one from
  1194 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
  1195 *}
  1196 
  1197 text {*
  1198   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1199   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1200 *}
  1201 
  1202 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
  1203 by (simp add: isUbI setleI)
  1204 
  1205 locale real_Cauchy =
  1206   fixes X :: "nat \<Rightarrow> real"
  1207   assumes X: "Cauchy X"
  1208   fixes S :: "real set"
  1209   defines S_def: "S \<equiv> {x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1210 
  1211 lemma real_CauchyI:
  1212   assumes "Cauchy X"
  1213   shows "real_Cauchy X"
  1214   proof qed (fact assms)
  1215 
  1216 lemma (in real_Cauchy) mem_S: "\<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  1217 by (unfold S_def, auto)
  1218 
  1219 lemma (in real_Cauchy) bound_isUb:
  1220   assumes N: "\<forall>n\<ge>N. X n < x"
  1221   shows "isUb UNIV S x"
  1222 proof (rule isUb_UNIV_I)
  1223   fix y::real assume "y \<in> S"
  1224   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1225     by (simp add: S_def)
  1226   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1227   hence "y < X (max M N)" by simp
  1228   also have "\<dots> < x" using N by simp
  1229   finally show "y \<le> x"
  1230     by (rule order_less_imp_le)
  1231 qed
  1232 
  1233 lemma (in real_Cauchy) isLub_ex: "\<exists>u. isLub UNIV S u"
  1234 proof (rule reals_complete)
  1235   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
  1236     using CauchyD [OF X zero_less_one] by auto
  1237   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
  1238   show "\<exists>x. x \<in> S"
  1239   proof
  1240     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1241       by (simp add: abs_diff_less_iff)
  1242     thus "X N - 1 \<in> S" by (rule mem_S)
  1243   qed
  1244   show "\<exists>u. isUb UNIV S u"
  1245   proof
  1246     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1247       by (simp add: abs_diff_less_iff)
  1248     thus "isUb UNIV S (X N + 1)"
  1249       by (rule bound_isUb)
  1250   qed
  1251 qed
  1252 
  1253 lemma (in real_Cauchy) isLub_imp_LIMSEQ:
  1254   assumes x: "isLub UNIV S x"
  1255   shows "X ----> x"
  1256 proof (rule LIMSEQ_I)
  1257   fix r::real assume "0 < r"
  1258   hence r: "0 < r/2" by simp
  1259   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
  1260     using CauchyD [OF X r] by auto
  1261   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
  1262   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1263     by (simp only: real_norm_def abs_diff_less_iff)
  1264 
  1265   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1266   hence "X N - r/2 \<in> S" by (rule mem_S)
  1267   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1268 
  1269   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1270   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1271   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1272 
  1273   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
  1274   proof (intro exI allI impI)
  1275     fix n assume n: "N \<le> n"
  1276     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1277     thus "norm (X n - x) < r" using 1 2
  1278       by (simp add: abs_diff_less_iff)
  1279   qed
  1280 qed
  1281 
  1282 lemma (in real_Cauchy) LIMSEQ_ex: "\<exists>x. X ----> x"
  1283 proof -
  1284   obtain x where "isLub UNIV S x"
  1285     using isLub_ex by fast
  1286   hence "X ----> x"
  1287     by (rule isLub_imp_LIMSEQ)
  1288   thus ?thesis ..
  1289 qed
  1290 
  1291 lemma real_Cauchy_convergent:
  1292   fixes X :: "nat \<Rightarrow> real"
  1293   shows "Cauchy X \<Longrightarrow> convergent X"
  1294 unfolding convergent_def
  1295 by (rule real_Cauchy.LIMSEQ_ex)
  1296  (rule real_CauchyI)
  1297 
  1298 instance real :: banach
  1299 by intro_classes (rule real_Cauchy_convergent)
  1300 
  1301 
  1302 subsection {* Power Sequences *}
  1303 
  1304 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1305 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1306   also fact that bounded and monotonic sequence converges.*}
  1307 
  1308 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1309 apply (simp add: Bseq_def)
  1310 apply (rule_tac x = 1 in exI)
  1311 apply (simp add: power_abs)
  1312 apply (auto dest: power_mono)
  1313 done
  1314 
  1315 lemma monoseq_realpow: "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1316 apply (clarify intro!: mono_SucI2)
  1317 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1318 done
  1319 
  1320 lemma convergent_realpow:
  1321   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1322 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1323 
  1324 lemma LIMSEQ_inverse_realpow_zero_lemma:
  1325   fixes x :: real
  1326   assumes x: "0 \<le> x"
  1327   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1328 apply (induct n)
  1329 apply simp
  1330 apply simp
  1331 apply (rule order_trans)
  1332 prefer 2
  1333 apply (erule mult_left_mono)
  1334 apply (rule add_increasing [OF x], simp)
  1335 apply (simp add: real_of_nat_Suc)
  1336 apply (simp add: ring_distribs)
  1337 apply (simp add: mult_nonneg_nonneg x)
  1338 done
  1339 
  1340 lemma LIMSEQ_inverse_realpow_zero:
  1341   "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1342 proof (rule LIMSEQ_inverse_zero [rule_format])
  1343   fix y :: real
  1344   assume x: "1 < x"
  1345   hence "0 < x - 1" by simp
  1346   hence "\<forall>y. \<exists>N::nat. y < real N * (x - 1)"
  1347     by (rule reals_Archimedean3)
  1348   hence "\<exists>N::nat. y < real N * (x - 1)" ..
  1349   then obtain N::nat where "y < real N * (x - 1)" ..
  1350   also have "\<dots> \<le> real N * (x - 1) + 1" by simp
  1351   also have "\<dots> \<le> (x - 1 + 1) ^ N"
  1352     by (rule LIMSEQ_inverse_realpow_zero_lemma, cut_tac x, simp)
  1353   also have "\<dots> = x ^ N" by simp
  1354   finally have "y < x ^ N" .
  1355   hence "\<forall>n\<ge>N. y < x ^ n"
  1356     apply clarify
  1357     apply (erule order_less_le_trans)
  1358     apply (erule power_increasing)
  1359     apply (rule order_less_imp_le [OF x])
  1360     done
  1361   thus "\<exists>N. \<forall>n\<ge>N. y < x ^ n" ..
  1362 qed
  1363 
  1364 lemma LIMSEQ_realpow_zero:
  1365   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1366 proof (cases)
  1367   assume "x = 0"
  1368   hence "(\<lambda>n. x ^ Suc n) ----> 0" by (simp add: LIMSEQ_const)
  1369   thus ?thesis by (rule LIMSEQ_imp_Suc)
  1370 next
  1371   assume "0 \<le> x" and "x \<noteq> 0"
  1372   hence x0: "0 < x" by simp
  1373   assume x1: "x < 1"
  1374   from x0 x1 have "1 < inverse x"
  1375     by (rule real_inverse_gt_one)
  1376   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1377     by (rule LIMSEQ_inverse_realpow_zero)
  1378   thus ?thesis by (simp add: power_inverse)
  1379 qed
  1380 
  1381 lemma LIMSEQ_power_zero:
  1382   fixes x :: "'a::{real_normed_algebra_1}"
  1383   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1384 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1385 apply (simp only: LIMSEQ_Zseq_iff, erule Zseq_le)
  1386 apply (simp add: power_abs norm_power_ineq)
  1387 done
  1388 
  1389 lemma LIMSEQ_divide_realpow_zero:
  1390   "1 < (x::real) ==> (%n. a / (x ^ n)) ----> 0"
  1391 apply (cut_tac a = a and x1 = "inverse x" in
  1392         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_realpow_zero])
  1393 apply (auto simp add: divide_inverse power_inverse)
  1394 apply (simp add: inverse_eq_divide pos_divide_less_eq)
  1395 done
  1396 
  1397 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1398 
  1399 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < (1::real) ==> (%n. \<bar>c\<bar> ^ n) ----> 0"
  1400 by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1401 
  1402 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < (1::real) ==> (%n. c ^ n) ----> 0"
  1403 apply (rule LIMSEQ_rabs_zero [THEN iffD1])
  1404 apply (auto intro: LIMSEQ_rabs_realpow_zero simp add: power_abs)
  1405 done
  1406 
  1407 end