src/HOL/Code_Numeral.thy
author wenzelm
Fri Dec 17 17:43:54 2010 +0100 (2010-12-17)
changeset 41229 d797baa3d57c
parent 39818 ff9e9d5ac171
child 44821 a92f65e174cf
permissions -rw-r--r--
replaced command 'nonterminals' by slightly modernized version 'nonterminal';
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Type of target language numerals *}
     4 
     5 theory Code_Numeral
     6 imports Nat_Numeral Nat_Transfer Divides
     7 begin
     8 
     9 text {*
    10   Code numerals are isomorphic to HOL @{typ nat} but
    11   mapped to target-language builtin numerals.
    12 *}
    13 
    14 subsection {* Datatype of target language numerals *}
    15 
    16 typedef (open) code_numeral = "UNIV \<Colon> nat set"
    17   morphisms nat_of of_nat by rule
    18 
    19 lemma of_nat_nat_of [simp]:
    20   "of_nat (nat_of k) = k"
    21   by (rule nat_of_inverse)
    22 
    23 lemma nat_of_of_nat [simp]:
    24   "nat_of (of_nat n) = n"
    25   by (rule of_nat_inverse) (rule UNIV_I)
    26 
    27 lemma [measure_function]:
    28   "is_measure nat_of" by (rule is_measure_trivial)
    29 
    30 lemma code_numeral:
    31   "(\<And>n\<Colon>code_numeral. PROP P n) \<equiv> (\<And>n\<Colon>nat. PROP P (of_nat n))"
    32 proof
    33   fix n :: nat
    34   assume "\<And>n\<Colon>code_numeral. PROP P n"
    35   then show "PROP P (of_nat n)" .
    36 next
    37   fix n :: code_numeral
    38   assume "\<And>n\<Colon>nat. PROP P (of_nat n)"
    39   then have "PROP P (of_nat (nat_of n))" .
    40   then show "PROP P n" by simp
    41 qed
    42 
    43 lemma code_numeral_case:
    44   assumes "\<And>n. k = of_nat n \<Longrightarrow> P"
    45   shows P
    46   by (rule assms [of "nat_of k"]) simp
    47 
    48 lemma code_numeral_induct_raw:
    49   assumes "\<And>n. P (of_nat n)"
    50   shows "P k"
    51 proof -
    52   from assms have "P (of_nat (nat_of k))" .
    53   then show ?thesis by simp
    54 qed
    55 
    56 lemma nat_of_inject [simp]:
    57   "nat_of k = nat_of l \<longleftrightarrow> k = l"
    58   by (rule nat_of_inject)
    59 
    60 lemma of_nat_inject [simp]:
    61   "of_nat n = of_nat m \<longleftrightarrow> n = m"
    62   by (rule of_nat_inject) (rule UNIV_I)+
    63 
    64 instantiation code_numeral :: zero
    65 begin
    66 
    67 definition [simp, code del]:
    68   "0 = of_nat 0"
    69 
    70 instance ..
    71 
    72 end
    73 
    74 definition [simp]:
    75   "Suc_code_numeral k = of_nat (Suc (nat_of k))"
    76 
    77 rep_datatype "0 \<Colon> code_numeral" Suc_code_numeral
    78 proof -
    79   fix P :: "code_numeral \<Rightarrow> bool"
    80   fix k :: code_numeral
    81   assume "P 0" then have init: "P (of_nat 0)" by simp
    82   assume "\<And>k. P k \<Longrightarrow> P (Suc_code_numeral k)"
    83     then have "\<And>n. P (of_nat n) \<Longrightarrow> P (Suc_code_numeral (of_nat n))" .
    84     then have step: "\<And>n. P (of_nat n) \<Longrightarrow> P (of_nat (Suc n))" by simp
    85   from init step have "P (of_nat (nat_of k))"
    86     by (induct ("nat_of k")) simp_all
    87   then show "P k" by simp
    88 qed simp_all
    89 
    90 declare code_numeral_case [case_names nat, cases type: code_numeral]
    91 declare code_numeral.induct [case_names nat, induct type: code_numeral]
    92 
    93 lemma code_numeral_decr [termination_simp]:
    94   "k \<noteq> of_nat 0 \<Longrightarrow> nat_of k - Suc 0 < nat_of k"
    95   by (cases k) simp
    96 
    97 lemma [simp, code]:
    98   "code_numeral_size = nat_of"
    99 proof (rule ext)
   100   fix k
   101   have "code_numeral_size k = nat_size (nat_of k)"
   102     by (induct k rule: code_numeral.induct) (simp_all del: zero_code_numeral_def Suc_code_numeral_def, simp_all)
   103   also have "nat_size (nat_of k) = nat_of k" by (induct ("nat_of k")) simp_all
   104   finally show "code_numeral_size k = nat_of k" .
   105 qed
   106 
   107 lemma [simp, code]:
   108   "size = nat_of"
   109 proof (rule ext)
   110   fix k
   111   show "size k = nat_of k"
   112   by (induct k) (simp_all del: zero_code_numeral_def Suc_code_numeral_def, simp_all)
   113 qed
   114 
   115 lemmas [code del] = code_numeral.recs code_numeral.cases
   116 
   117 lemma [code]:
   118   "HOL.equal k l \<longleftrightarrow> HOL.equal (nat_of k) (nat_of l)"
   119   by (cases k, cases l) (simp add: equal)
   120 
   121 lemma [code nbe]:
   122   "HOL.equal (k::code_numeral) k \<longleftrightarrow> True"
   123   by (rule equal_refl)
   124 
   125 
   126 subsection {* Code numerals as datatype of ints *}
   127 
   128 instantiation code_numeral :: number
   129 begin
   130 
   131 definition
   132   "number_of = of_nat o nat"
   133 
   134 instance ..
   135 
   136 end
   137 
   138 lemma nat_of_number [simp]:
   139   "nat_of (number_of k) = number_of k"
   140   by (simp add: number_of_code_numeral_def nat_number_of_def number_of_is_id)
   141 
   142 code_datatype "number_of \<Colon> int \<Rightarrow> code_numeral"
   143 
   144 
   145 subsection {* Basic arithmetic *}
   146 
   147 instantiation code_numeral :: "{minus, linordered_semidom, semiring_div, linorder}"
   148 begin
   149 
   150 definition [simp, code del]:
   151   "(1\<Colon>code_numeral) = of_nat 1"
   152 
   153 definition [simp, code del]:
   154   "n + m = of_nat (nat_of n + nat_of m)"
   155 
   156 definition [simp, code del]:
   157   "n - m = of_nat (nat_of n - nat_of m)"
   158 
   159 definition [simp, code del]:
   160   "n * m = of_nat (nat_of n * nat_of m)"
   161 
   162 definition [simp, code del]:
   163   "n div m = of_nat (nat_of n div nat_of m)"
   164 
   165 definition [simp, code del]:
   166   "n mod m = of_nat (nat_of n mod nat_of m)"
   167 
   168 definition [simp, code del]:
   169   "n \<le> m \<longleftrightarrow> nat_of n \<le> nat_of m"
   170 
   171 definition [simp, code del]:
   172   "n < m \<longleftrightarrow> nat_of n < nat_of m"
   173 
   174 instance proof
   175 qed (auto simp add: code_numeral left_distrib intro: mult_commute)
   176 
   177 end
   178 
   179 lemma zero_code_numeral_code [code, code_unfold]:
   180   "(0\<Colon>code_numeral) = Numeral0"
   181   by (simp add: number_of_code_numeral_def Pls_def)
   182 lemma [code_post]: "Numeral0 = (0\<Colon>code_numeral)"
   183   using zero_code_numeral_code ..
   184 
   185 lemma one_code_numeral_code [code, code_unfold]:
   186   "(1\<Colon>code_numeral) = Numeral1"
   187   by (simp add: number_of_code_numeral_def Pls_def Bit1_def)
   188 lemma [code_post]: "Numeral1 = (1\<Colon>code_numeral)"
   189   using one_code_numeral_code ..
   190 
   191 lemma plus_code_numeral_code [code nbe]:
   192   "of_nat n + of_nat m = of_nat (n + m)"
   193   by simp
   194 
   195 definition subtract_code_numeral :: "code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral" where
   196   [simp, code del]: "subtract_code_numeral = op -"
   197 
   198 lemma subtract_code_numeral_code [code nbe]:
   199   "subtract_code_numeral (of_nat n) (of_nat m) = of_nat (n - m)"
   200   by simp
   201 
   202 lemma minus_code_numeral_code [code]:
   203   "n - m = subtract_code_numeral n m"
   204   by simp
   205 
   206 lemma times_code_numeral_code [code nbe]:
   207   "of_nat n * of_nat m = of_nat (n * m)"
   208   by simp
   209 
   210 lemma less_eq_code_numeral_code [code nbe]:
   211   "of_nat n \<le> of_nat m \<longleftrightarrow> n \<le> m"
   212   by simp
   213 
   214 lemma less_code_numeral_code [code nbe]:
   215   "of_nat n < of_nat m \<longleftrightarrow> n < m"
   216   by simp
   217 
   218 lemma code_numeral_zero_minus_one:
   219   "(0::code_numeral) - 1 = 0"
   220   by simp
   221 
   222 lemma Suc_code_numeral_minus_one:
   223   "Suc_code_numeral n - 1 = n"
   224   by simp
   225 
   226 lemma of_nat_code [code]:
   227   "of_nat = Nat.of_nat"
   228 proof
   229   fix n :: nat
   230   have "Nat.of_nat n = of_nat n"
   231     by (induct n) simp_all
   232   then show "of_nat n = Nat.of_nat n"
   233     by (rule sym)
   234 qed
   235 
   236 lemma code_numeral_not_eq_zero: "i \<noteq> of_nat 0 \<longleftrightarrow> i \<ge> 1"
   237   by (cases i) auto
   238 
   239 definition nat_of_aux :: "code_numeral \<Rightarrow> nat \<Rightarrow> nat" where
   240   "nat_of_aux i n = nat_of i + n"
   241 
   242 lemma nat_of_aux_code [code]:
   243   "nat_of_aux i n = (if i = 0 then n else nat_of_aux (i - 1) (Suc n))"
   244   by (auto simp add: nat_of_aux_def code_numeral_not_eq_zero)
   245 
   246 lemma nat_of_code [code]:
   247   "nat_of i = nat_of_aux i 0"
   248   by (simp add: nat_of_aux_def)
   249 
   250 definition div_mod_code_numeral :: "code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral \<times> code_numeral" where
   251   [code del]: "div_mod_code_numeral n m = (n div m, n mod m)"
   252 
   253 lemma [code]:
   254   "div_mod_code_numeral n m = (if m = 0 then (0, n) else (n div m, n mod m))"
   255   unfolding div_mod_code_numeral_def by auto
   256 
   257 lemma [code]:
   258   "n div m = fst (div_mod_code_numeral n m)"
   259   unfolding div_mod_code_numeral_def by simp
   260 
   261 lemma [code]:
   262   "n mod m = snd (div_mod_code_numeral n m)"
   263   unfolding div_mod_code_numeral_def by simp
   264 
   265 definition int_of :: "code_numeral \<Rightarrow> int" where
   266   "int_of = Nat.of_nat o nat_of"
   267 
   268 lemma int_of_code [code]:
   269   "int_of k = (if k = 0 then 0
   270     else (if k mod 2 = 0 then 2 * int_of (k div 2) else 2 * int_of (k div 2) + 1))"
   271 proof -
   272   have "(nat_of k div 2) * 2 + nat_of k mod 2 = nat_of k" 
   273     by (rule mod_div_equality)
   274   then have "int ((nat_of k div 2) * 2 + nat_of k mod 2) = int (nat_of k)" 
   275     by simp
   276   then have "int (nat_of k) = int (nat_of k div 2) * 2 + int (nat_of k mod 2)" 
   277     unfolding int_mult zadd_int [symmetric] by simp
   278   then show ?thesis by (auto simp add: int_of_def mult_ac)
   279 qed
   280 
   281 hide_const (open) of_nat nat_of int_of
   282 
   283 subsubsection {* Lazy Evaluation of an indexed function *}
   284 
   285 function iterate_upto :: "(code_numeral => 'a) => code_numeral => code_numeral => 'a Predicate.pred"
   286 where
   287   "iterate_upto f n m = Predicate.Seq (%u. if n > m then Predicate.Empty else Predicate.Insert (f n) (iterate_upto f (n + 1) m))"
   288 by pat_completeness auto
   289 
   290 termination by (relation "measure (%(f, n, m). Code_Numeral.nat_of (m + 1 - n))") auto
   291 
   292 hide_const (open) iterate_upto
   293 
   294 subsection {* Code generator setup *}
   295 
   296 text {* Implementation of code numerals by bounded integers *}
   297 
   298 code_type code_numeral
   299   (SML "int")
   300   (OCaml "Big'_int.big'_int")
   301   (Haskell "Integer")
   302   (Scala "BigInt")
   303 
   304 code_instance code_numeral :: equal
   305   (Haskell -)
   306 
   307 setup {*
   308   Numeral.add_code @{const_name number_code_numeral_inst.number_of_code_numeral}
   309     false Code_Printer.literal_naive_numeral "SML"
   310   #> fold (Numeral.add_code @{const_name number_code_numeral_inst.number_of_code_numeral}
   311     false Code_Printer.literal_numeral) ["OCaml", "Haskell", "Scala"]
   312 *}
   313 
   314 code_reserved SML Int int
   315 code_reserved Eval Integer
   316 
   317 code_const "op + \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral"
   318   (SML "Int.+/ ((_),/ (_))")
   319   (OCaml "Big'_int.add'_big'_int")
   320   (Haskell infixl 6 "+")
   321   (Scala infixl 7 "+")
   322   (Eval infixl 8 "+")
   323 
   324 code_const "subtract_code_numeral \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral"
   325   (SML "Int.max/ (_/ -/ _,/ 0 : int)")
   326   (OCaml "Big'_int.max'_big'_int/ (Big'_int.sub'_big'_int/ _/ _)/ Big'_int.zero'_big'_int")
   327   (Haskell "max/ (_/ -/ _)/ (0 :: Integer)")
   328   (Scala "!(_/ -/ _).max(0)")
   329   (Eval "Integer.max/ (_/ -/ _)/ 0")
   330 
   331 code_const "op * \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral"
   332   (SML "Int.*/ ((_),/ (_))")
   333   (OCaml "Big'_int.mult'_big'_int")
   334   (Haskell infixl 7 "*")
   335   (Scala infixl 8 "*")
   336   (Eval infixl 8 "*")
   337 
   338 code_const div_mod_code_numeral
   339   (SML "!(fn n => fn m =>/ if m = 0/ then (0, n) else/ (Int.div (n, m), Int.mod (n, m)))")
   340   (OCaml "Big'_int.quomod'_big'_int/ (Big'_int.abs'_big'_int _)/ (Big'_int.abs'_big'_int _)")
   341   (Haskell "divMod")
   342   (Scala "!((k: BigInt) => (l: BigInt) =>/ if (l == 0)/ (BigInt(0), k) else/ (k.abs '/% l.abs))")
   343   (Eval "!(fn n => fn m =>/ if m = 0/ then (0, n) else/ (Integer.div'_mod n m))")
   344 
   345 code_const "HOL.equal \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> bool"
   346   (SML "!((_ : Int.int) = _)")
   347   (OCaml "Big'_int.eq'_big'_int")
   348   (Haskell infix 4 "==")
   349   (Scala infixl 5 "==")
   350   (Eval "!((_ : int) = _)")
   351 
   352 code_const "op \<le> \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> bool"
   353   (SML "Int.<=/ ((_),/ (_))")
   354   (OCaml "Big'_int.le'_big'_int")
   355   (Haskell infix 4 "<=")
   356   (Scala infixl 4 "<=")
   357   (Eval infixl 6 "<=")
   358 
   359 code_const "op < \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> bool"
   360   (SML "Int.</ ((_),/ (_))")
   361   (OCaml "Big'_int.lt'_big'_int")
   362   (Haskell infix 4 "<")
   363   (Scala infixl 4 "<")
   364   (Eval infixl 6 "<")
   365 
   366 end