src/HOL/Complete_Lattice.thy
author wenzelm
Fri Dec 17 17:43:54 2010 +0100 (2010-12-17)
changeset 41229 d797baa3d57c
parent 41082 9ff94e7cc3b3
child 41971 a54e8e95fe96
permissions -rw-r--r--
replaced command 'nonterminals' by slightly modernized version 'nonterminal';
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices, with special focus on sets *}
     4 
     5 theory Complete_Lattice
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50) and
    12   inf (infixl "\<sqinter>" 70) and
    13   sup (infixl "\<squnion>" 65) and
    14   top ("\<top>") and
    15   bot ("\<bottom>")
    16 
    17 
    18 subsection {* Syntactic infimum and supremum operations *}
    19 
    20 class Inf =
    21   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    22 
    23 class Sup =
    24   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    25 
    26 subsection {* Abstract complete lattices *}
    27 
    28 class complete_lattice = bounded_lattice + Inf + Sup +
    29   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    30      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    31   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    32      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    33 begin
    34 
    35 lemma dual_complete_lattice:
    36   "class.complete_lattice Sup Inf (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) \<top> \<bottom>"
    37   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    38     (unfold_locales, (fact bot_least top_greatest
    39         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    40 
    41 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
    42   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    43 
    44 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
    45   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    46 
    47 lemma Inf_empty [simp]:
    48   "\<Sqinter>{} = \<top>"
    49   by (auto intro: antisym Inf_greatest)
    50 
    51 lemma Sup_empty [simp]:
    52   "\<Squnion>{} = \<bottom>"
    53   by (auto intro: antisym Sup_least)
    54 
    55 lemma Inf_UNIV [simp]:
    56   "\<Sqinter>UNIV = \<bottom>"
    57   by (simp add: Sup_Inf Sup_empty [symmetric])
    58 
    59 lemma Sup_UNIV [simp]:
    60   "\<Squnion>UNIV = \<top>"
    61   by (simp add: Inf_Sup Inf_empty [symmetric])
    62 
    63 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
    64   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
    65 
    66 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
    67   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
    68 
    69 lemma Inf_singleton [simp]:
    70   "\<Sqinter>{a} = a"
    71   by (auto intro: antisym Inf_lower Inf_greatest)
    72 
    73 lemma Sup_singleton [simp]:
    74   "\<Squnion>{a} = a"
    75   by (auto intro: antisym Sup_upper Sup_least)
    76 
    77 lemma Inf_binary:
    78   "\<Sqinter>{a, b} = a \<sqinter> b"
    79   by (simp add: Inf_empty Inf_insert)
    80 
    81 lemma Sup_binary:
    82   "\<Squnion>{a, b} = a \<squnion> b"
    83   by (simp add: Sup_empty Sup_insert)
    84 
    85 lemma le_Inf_iff: "b \<sqsubseteq> Inf A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
    86   by (auto intro: Inf_greatest dest: Inf_lower)
    87 
    88 lemma Sup_le_iff: "Sup A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
    89   by (auto intro: Sup_least dest: Sup_upper)
    90 
    91 lemma Inf_mono:
    92   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<le> b"
    93   shows "Inf A \<le> Inf B"
    94 proof (rule Inf_greatest)
    95   fix b assume "b \<in> B"
    96   with assms obtain a where "a \<in> A" and "a \<le> b" by blast
    97   from `a \<in> A` have "Inf A \<le> a" by (rule Inf_lower)
    98   with `a \<le> b` show "Inf A \<le> b" by auto
    99 qed
   100 
   101 lemma Sup_mono:
   102   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<le> b"
   103   shows "Sup A \<le> Sup B"
   104 proof (rule Sup_least)
   105   fix a assume "a \<in> A"
   106   with assms obtain b where "b \<in> B" and "a \<le> b" by blast
   107   from `b \<in> B` have "b \<le> Sup B" by (rule Sup_upper)
   108   with `a \<le> b` show "a \<le> Sup B" by auto
   109 qed
   110 
   111 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   112   "INFI A f = \<Sqinter> (f ` A)"
   113 
   114 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   115   "SUPR A f = \<Squnion> (f ` A)"
   116 
   117 end
   118 
   119 syntax
   120   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
   121   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
   122   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
   123   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
   124 
   125 syntax (xsymbols)
   126   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   127   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   128   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   129   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   130 
   131 translations
   132   "INF x y. B"   == "INF x. INF y. B"
   133   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
   134   "INF x. B"     == "INF x:CONST UNIV. B"
   135   "INF x:A. B"   == "CONST INFI A (%x. B)"
   136   "SUP x y. B"   == "SUP x. SUP y. B"
   137   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
   138   "SUP x. B"     == "SUP x:CONST UNIV. B"
   139   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   140 
   141 print_translation {*
   142   [Syntax.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   143     Syntax.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   144 *} -- {* to avoid eta-contraction of body *}
   145 
   146 context complete_lattice
   147 begin
   148 
   149 lemma le_SUPI: "i : A \<Longrightarrow> M i \<sqsubseteq> (SUP i:A. M i)"
   150   by (auto simp add: SUPR_def intro: Sup_upper)
   151 
   152 lemma SUP_leI: "(\<And>i. i : A \<Longrightarrow> M i \<sqsubseteq> u) \<Longrightarrow> (SUP i:A. M i) \<sqsubseteq> u"
   153   by (auto simp add: SUPR_def intro: Sup_least)
   154 
   155 lemma INF_leI: "i : A \<Longrightarrow> (INF i:A. M i) \<sqsubseteq> M i"
   156   by (auto simp add: INFI_def intro: Inf_lower)
   157 
   158 lemma le_INFI: "(\<And>i. i : A \<Longrightarrow> u \<sqsubseteq> M i) \<Longrightarrow> u \<sqsubseteq> (INF i:A. M i)"
   159   by (auto simp add: INFI_def intro: Inf_greatest)
   160 
   161 lemma SUP_le_iff: "(SUP i:A. M i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i \<in> A. M i \<sqsubseteq> u)"
   162   unfolding SUPR_def by (auto simp add: Sup_le_iff)
   163 
   164 lemma le_INF_iff: "u \<sqsubseteq> (INF i:A. M i) \<longleftrightarrow> (\<forall>i \<in> A. u \<sqsubseteq> M i)"
   165   unfolding INFI_def by (auto simp add: le_Inf_iff)
   166 
   167 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
   168   by (auto intro: antisym INF_leI le_INFI)
   169 
   170 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
   171   by (auto intro: antisym SUP_leI le_SUPI)
   172 
   173 lemma INF_mono:
   174   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<le> g m) \<Longrightarrow> (INF n:A. f n) \<le> (INF n:B. g n)"
   175   by (force intro!: Inf_mono simp: INFI_def)
   176 
   177 lemma SUP_mono:
   178   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<le> g m) \<Longrightarrow> (SUP n:A. f n) \<le> (SUP n:B. g n)"
   179   by (force intro!: Sup_mono simp: SUPR_def)
   180 
   181 lemma INF_subset:  "A \<subseteq> B \<Longrightarrow> INFI B f \<le> INFI A f"
   182   by (intro INF_mono) auto
   183 
   184 lemma SUP_subset:  "A \<subseteq> B \<Longrightarrow> SUPR A f \<le> SUPR B f"
   185   by (intro SUP_mono) auto
   186 
   187 lemma INF_commute: "(INF i:A. INF j:B. f i j) = (INF j:B. INF i:A. f i j)"
   188   by (iprover intro: INF_leI le_INFI order_trans antisym)
   189 
   190 lemma SUP_commute: "(SUP i:A. SUP j:B. f i j) = (SUP j:B. SUP i:A. f i j)"
   191   by (iprover intro: SUP_leI le_SUPI order_trans antisym)
   192 
   193 end
   194 
   195 lemma Inf_less_iff:
   196   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   197   shows "Inf S < a \<longleftrightarrow> (\<exists>x\<in>S. x < a)"
   198   unfolding not_le[symmetric] le_Inf_iff by auto
   199 
   200 lemma less_Sup_iff:
   201   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   202   shows "a < Sup S \<longleftrightarrow> (\<exists>x\<in>S. a < x)"
   203   unfolding not_le[symmetric] Sup_le_iff by auto
   204 
   205 lemma INF_less_iff:
   206   fixes a :: "'a::{complete_lattice,linorder}"
   207   shows "(INF i:A. f i) < a \<longleftrightarrow> (\<exists>x\<in>A. f x < a)"
   208   unfolding INFI_def Inf_less_iff by auto
   209 
   210 lemma less_SUP_iff:
   211   fixes a :: "'a::{complete_lattice,linorder}"
   212   shows "a < (SUP i:A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a < f x)"
   213   unfolding SUPR_def less_Sup_iff by auto
   214 
   215 subsection {* @{typ bool} and @{typ "_ \<Rightarrow> _"} as complete lattice *}
   216 
   217 instantiation bool :: complete_lattice
   218 begin
   219 
   220 definition
   221   "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   222 
   223 definition
   224   "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   225 
   226 instance proof
   227 qed (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
   228 
   229 end
   230 
   231 lemma INFI_bool_eq [simp]:
   232   "INFI = Ball"
   233 proof (rule ext)+
   234   fix A :: "'a set"
   235   fix P :: "'a \<Rightarrow> bool"
   236   show "(INF x:A. P x) \<longleftrightarrow> (\<forall>x \<in> A. P x)"
   237     by (auto simp add: Ball_def INFI_def Inf_bool_def)
   238 qed
   239 
   240 lemma SUPR_bool_eq [simp]:
   241   "SUPR = Bex"
   242 proof (rule ext)+
   243   fix A :: "'a set"
   244   fix P :: "'a \<Rightarrow> bool"
   245   show "(SUP x:A. P x) \<longleftrightarrow> (\<exists>x \<in> A. P x)"
   246     by (auto simp add: Bex_def SUPR_def Sup_bool_def)
   247 qed
   248 
   249 instantiation "fun" :: (type, complete_lattice) complete_lattice
   250 begin
   251 
   252 definition
   253   "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   254 
   255 lemma Inf_apply:
   256   "(\<Sqinter>A) x = \<Sqinter>{y. \<exists>f\<in>A. y = f x}"
   257   by (simp add: Inf_fun_def)
   258 
   259 definition
   260   "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   261 
   262 lemma Sup_apply:
   263   "(\<Squnion>A) x = \<Squnion>{y. \<exists>f\<in>A. y = f x}"
   264   by (simp add: Sup_fun_def)
   265 
   266 instance proof
   267 qed (auto simp add: le_fun_def Inf_apply Sup_apply
   268   intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   269 
   270 end
   271 
   272 lemma INFI_apply:
   273   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   274   by (auto intro: arg_cong [of _ _ Inf] simp add: INFI_def Inf_apply)
   275 
   276 lemma SUPR_apply:
   277   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   278   by (auto intro: arg_cong [of _ _ Sup] simp add: SUPR_def Sup_apply)
   279 
   280 
   281 subsection {* Inter *}
   282 
   283 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   284   "Inter S \<equiv> \<Sqinter>S"
   285   
   286 notation (xsymbols)
   287   Inter  ("\<Inter>_" [90] 90)
   288 
   289 lemma Inter_eq:
   290   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   291 proof (rule set_eqI)
   292   fix x
   293   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   294     by auto
   295   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   296     by (simp add: Inf_fun_def Inf_bool_def) (simp add: mem_def)
   297 qed
   298 
   299 lemma Inter_iff [simp,no_atp]: "(A : Inter C) = (ALL X:C. A:X)"
   300   by (unfold Inter_eq) blast
   301 
   302 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   303   by (simp add: Inter_eq)
   304 
   305 text {*
   306   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   307   contains @{term A} as an element, but @{prop "A:X"} can hold when
   308   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   309 *}
   310 
   311 lemma InterD [elim, Pure.elim]: "A : Inter C ==> X:C ==> A:X"
   312   by auto
   313 
   314 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   315   -- {* ``Classical'' elimination rule -- does not require proving
   316     @{prop "X:C"}. *}
   317   by (unfold Inter_eq) blast
   318 
   319 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
   320   by blast
   321 
   322 lemma Inter_subset:
   323   "[| !!X. X \<in> A ==> X \<subseteq> B; A ~= {} |] ==> \<Inter>A \<subseteq> B"
   324   by blast
   325 
   326 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
   327   by (iprover intro: InterI subsetI dest: subsetD)
   328 
   329 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
   330   by blast
   331 
   332 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
   333   by (fact Inf_empty)
   334 
   335 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
   336   by blast
   337 
   338 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   339   by blast
   340 
   341 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   342   by blast
   343 
   344 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   345   by blast
   346 
   347 lemma Inter_UNIV_conv [simp,no_atp]:
   348   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
   349   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
   350   by blast+
   351 
   352 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
   353   by blast
   354 
   355 
   356 subsection {* Intersections of families *}
   357 
   358 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   359   "INTER \<equiv> INFI"
   360 
   361 syntax
   362   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   363   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   364 
   365 syntax (xsymbols)
   366   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   367   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   368 
   369 syntax (latex output)
   370   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   371   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   372 
   373 translations
   374   "INT x y. B"  == "INT x. INT y. B"
   375   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   376   "INT x. B"    == "INT x:CONST UNIV. B"
   377   "INT x:A. B"  == "CONST INTER A (%x. B)"
   378 
   379 print_translation {*
   380   [Syntax.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   381 *} -- {* to avoid eta-contraction of body *}
   382 
   383 lemma INTER_eq_Inter_image:
   384   "(\<Inter>x\<in>A. B x) = \<Inter>(B`A)"
   385   by (fact INFI_def)
   386   
   387 lemma Inter_def:
   388   "\<Inter>S = (\<Inter>x\<in>S. x)"
   389   by (simp add: INTER_eq_Inter_image image_def)
   390 
   391 lemma INTER_def:
   392   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   393   by (auto simp add: INTER_eq_Inter_image Inter_eq)
   394 
   395 lemma Inter_image_eq [simp]:
   396   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   397   by (rule sym) (fact INTER_eq_Inter_image)
   398 
   399 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   400   by (unfold INTER_def) blast
   401 
   402 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   403   by (unfold INTER_def) blast
   404 
   405 lemma INT_D [elim, Pure.elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   406   by auto
   407 
   408 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   409   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   410   by (unfold INTER_def) blast
   411 
   412 lemma INT_cong [cong]:
   413     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   414   by (simp add: INTER_def)
   415 
   416 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   417   by blast
   418 
   419 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   420   by blast
   421 
   422 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   423   by (fact INF_leI)
   424 
   425 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   426   by (fact le_INFI)
   427 
   428 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
   429   by blast
   430 
   431 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   432   by blast
   433 
   434 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
   435   by (fact le_INF_iff)
   436 
   437 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   438   by blast
   439 
   440 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   441   by blast
   442 
   443 lemma INT_insert_distrib:
   444     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   445   by blast
   446 
   447 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   448   by auto
   449 
   450 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
   451   -- {* Look: it has an \emph{existential} quantifier *}
   452   by blast
   453 
   454 lemma INTER_UNIV_conv[simp]:
   455  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   456  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   457 by blast+
   458 
   459 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
   460   by (auto intro: bool_induct)
   461 
   462 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   463   by blast
   464 
   465 lemma INT_anti_mono:
   466   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
   467     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   468   -- {* The last inclusion is POSITIVE! *}
   469   by (blast dest: subsetD)
   470 
   471 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
   472   by blast
   473 
   474 
   475 subsection {* Union *}
   476 
   477 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   478   "Union S \<equiv> \<Squnion>S"
   479 
   480 notation (xsymbols)
   481   Union  ("\<Union>_" [90] 90)
   482 
   483 lemma Union_eq:
   484   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   485 proof (rule set_eqI)
   486   fix x
   487   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   488     by auto
   489   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   490     by (simp add: Sup_fun_def Sup_bool_def) (simp add: mem_def)
   491 qed
   492 
   493 lemma Union_iff [simp, no_atp]:
   494   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   495   by (unfold Union_eq) blast
   496 
   497 lemma UnionI [intro]:
   498   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   499   -- {* The order of the premises presupposes that @{term C} is rigid;
   500     @{term A} may be flexible. *}
   501   by auto
   502 
   503 lemma UnionE [elim!]:
   504   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A\<in>X \<Longrightarrow> X\<in>C \<Longrightarrow> R) \<Longrightarrow> R"
   505   by auto
   506 
   507 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   508   by (iprover intro: subsetI UnionI)
   509 
   510 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   511   by (iprover intro: subsetI elim: UnionE dest: subsetD)
   512 
   513 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
   514   by blast
   515 
   516 lemma Union_empty [simp]: "Union({}) = {}"
   517   by blast
   518 
   519 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
   520   by blast
   521 
   522 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
   523   by blast
   524 
   525 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
   526   by blast
   527 
   528 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   529   by blast
   530 
   531 lemma Union_empty_conv [simp,no_atp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
   532   by blast
   533 
   534 lemma empty_Union_conv [simp,no_atp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
   535   by blast
   536 
   537 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
   538   by blast
   539 
   540 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   541   by blast
   542 
   543 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   544   by blast
   545 
   546 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
   547   by blast
   548 
   549 
   550 subsection {* Unions of families *}
   551 
   552 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   553   "UNION \<equiv> SUPR"
   554 
   555 syntax
   556   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   557   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
   558 
   559 syntax (xsymbols)
   560   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   561   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
   562 
   563 syntax (latex output)
   564   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   565   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   566 
   567 translations
   568   "UN x y. B"   == "UN x. UN y. B"
   569   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   570   "UN x. B"     == "UN x:CONST UNIV. B"
   571   "UN x:A. B"   == "CONST UNION A (%x. B)"
   572 
   573 text {*
   574   Note the difference between ordinary xsymbol syntax of indexed
   575   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   576   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   577   former does not make the index expression a subscript of the
   578   union/intersection symbol because this leads to problems with nested
   579   subscripts in Proof General.
   580 *}
   581 
   582 print_translation {*
   583   [Syntax.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
   584 *} -- {* to avoid eta-contraction of body *}
   585 
   586 lemma UNION_eq_Union_image:
   587   "(\<Union>x\<in>A. B x) = \<Union>(B`A)"
   588   by (fact SUPR_def)
   589 
   590 lemma Union_def:
   591   "\<Union>S = (\<Union>x\<in>S. x)"
   592   by (simp add: UNION_eq_Union_image image_def)
   593 
   594 lemma UNION_def [no_atp]:
   595   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
   596   by (auto simp add: UNION_eq_Union_image Union_eq)
   597   
   598 lemma Union_image_eq [simp]:
   599   "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
   600   by (rule sym) (fact UNION_eq_Union_image)
   601   
   602 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   603   by (unfold UNION_def) blast
   604 
   605 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   606   -- {* The order of the premises presupposes that @{term A} is rigid;
   607     @{term b} may be flexible. *}
   608   by auto
   609 
   610 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   611   by (unfold UNION_def) blast
   612 
   613 lemma UN_cong [cong]:
   614     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   615   by (simp add: UNION_def)
   616 
   617 lemma strong_UN_cong:
   618     "A = B ==> (!!x. x:B =simp=> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   619   by (simp add: UNION_def simp_implies_def)
   620 
   621 lemma image_eq_UN: "f`A = (UN x:A. {f x})"
   622   by blast
   623 
   624 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   625   by (fact le_SUPI)
   626 
   627 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   628   by (iprover intro: subsetI elim: UN_E dest: subsetD)
   629 
   630 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
   631   by blast
   632 
   633 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
   634   by blast
   635 
   636 lemma UN_empty [simp,no_atp]: "(\<Union>x\<in>{}. B x) = {}"
   637   by blast
   638 
   639 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
   640   by blast
   641 
   642 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
   643   by blast
   644 
   645 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
   646   by auto
   647 
   648 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
   649   by blast
   650 
   651 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
   652   by blast
   653 
   654 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
   655   by blast
   656 
   657 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
   658   by (fact SUP_le_iff)
   659 
   660 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
   661   by blast
   662 
   663 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
   664   by auto
   665 
   666 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
   667   by blast
   668 
   669 lemma UNION_empty_conv[simp]:
   670   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
   671   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
   672 by blast+
   673 
   674 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
   675   by blast
   676 
   677 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
   678   by blast
   679 
   680 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
   681   by blast
   682 
   683 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
   684   by (auto simp add: split_if_mem2)
   685 
   686 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
   687   by (auto intro: bool_contrapos)
   688 
   689 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
   690   by blast
   691 
   692 lemma UN_mono:
   693   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
   694     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
   695   by (blast dest: subsetD)
   696 
   697 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
   698   by blast
   699 
   700 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
   701   by blast
   702 
   703 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
   704   -- {* NOT suitable for rewriting *}
   705   by blast
   706 
   707 lemma image_UN: "(f ` (UNION A B)) = (UN x:A.(f ` (B x)))"
   708 by blast
   709 
   710 
   711 subsection {* Distributive laws *}
   712 
   713 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
   714   by blast
   715 
   716 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
   717   by blast
   718 
   719 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
   720   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
   721   -- {* Union of a family of unions *}
   722   by blast
   723 
   724 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
   725   -- {* Equivalent version *}
   726   by blast
   727 
   728 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
   729   by blast
   730 
   731 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
   732   by blast
   733 
   734 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
   735   -- {* Equivalent version *}
   736   by blast
   737 
   738 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
   739   -- {* Halmos, Naive Set Theory, page 35. *}
   740   by blast
   741 
   742 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
   743   by blast
   744 
   745 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
   746   by blast
   747 
   748 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
   749   by blast
   750 
   751 
   752 subsection {* Complement *}
   753 
   754 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
   755   by blast
   756 
   757 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
   758   by blast
   759 
   760 
   761 subsection {* Miniscoping and maxiscoping *}
   762 
   763 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
   764            and Intersections. *}
   765 
   766 lemma UN_simps [simp]:
   767   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
   768   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
   769   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
   770   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
   771   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
   772   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
   773   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
   774   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
   775   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
   776   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
   777   by auto
   778 
   779 lemma INT_simps [simp]:
   780   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
   781   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
   782   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
   783   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
   784   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
   785   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
   786   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
   787   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
   788   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
   789   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
   790   by auto
   791 
   792 lemma ball_simps [simp,no_atp]:
   793   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
   794   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
   795   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
   796   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
   797   "!!P. (ALL x:{}. P x) = True"
   798   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
   799   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
   800   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
   801   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
   802   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
   803   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
   804   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
   805   by auto
   806 
   807 lemma bex_simps [simp,no_atp]:
   808   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
   809   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
   810   "!!P. (EX x:{}. P x) = False"
   811   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
   812   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
   813   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
   814   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
   815   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
   816   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
   817   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
   818   by auto
   819 
   820 lemma ball_conj_distrib:
   821   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
   822   by blast
   823 
   824 lemma bex_disj_distrib:
   825   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
   826   by blast
   827 
   828 
   829 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
   830 
   831 lemma UN_extend_simps:
   832   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
   833   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
   834   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
   835   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
   836   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
   837   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
   838   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
   839   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
   840   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
   841   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
   842   by auto
   843 
   844 lemma INT_extend_simps:
   845   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
   846   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
   847   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
   848   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
   849   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
   850   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
   851   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
   852   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
   853   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
   854   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
   855   by auto
   856 
   857 
   858 no_notation
   859   less_eq  (infix "\<sqsubseteq>" 50) and
   860   less (infix "\<sqsubset>" 50) and
   861   bot ("\<bottom>") and
   862   top ("\<top>") and
   863   inf  (infixl "\<sqinter>" 70) and
   864   sup  (infixl "\<squnion>" 65) and
   865   Inf  ("\<Sqinter>_" [900] 900) and
   866   Sup  ("\<Squnion>_" [900] 900)
   867 
   868 no_syntax (xsymbols)
   869   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   870   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   871   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   872   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   873 
   874 lemmas mem_simps =
   875   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   876   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   877   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   878 
   879 end