src/HOL/Complex.thy
author wenzelm
Fri Dec 17 17:43:54 2010 +0100 (2010-12-17)
changeset 41229 d797baa3d57c
parent 37887 2ae085b07f2f
child 41959 b460124855b8
permissions -rw-r--r--
replaced command 'nonterminals' by slightly modernized version 'nonterminal';
     1 (*  Title:       Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 header {* Complex Numbers: Rectangular and Polar Representations *}
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 datatype complex = Complex real real
    14 
    15 primrec
    16   Re :: "complex \<Rightarrow> real"
    17 where
    18   Re: "Re (Complex x y) = x"
    19 
    20 primrec
    21   Im :: "complex \<Rightarrow> real"
    22 where
    23   Im: "Im (Complex x y) = y"
    24 
    25 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"
    26   by (induct z) simp
    27 
    28 lemma complex_equality [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    29   by (induct x, induct y) simp
    30 
    31 lemma expand_complex_eq: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    32   by (induct x, induct y) simp
    33 
    34 lemmas complex_Re_Im_cancel_iff = expand_complex_eq
    35 
    36 
    37 subsection {* Addition and Subtraction *}
    38 
    39 instantiation complex :: ab_group_add
    40 begin
    41 
    42 definition
    43   complex_zero_def: "0 = Complex 0 0"
    44 
    45 definition
    46   complex_add_def: "x + y = Complex (Re x + Re y) (Im x + Im y)"
    47 
    48 definition
    49   complex_minus_def: "- x = Complex (- Re x) (- Im x)"
    50 
    51 definition
    52   complex_diff_def: "x - (y\<Colon>complex) = x + - y"
    53 
    54 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
    55   by (simp add: complex_zero_def)
    56 
    57 lemma complex_Re_zero [simp]: "Re 0 = 0"
    58   by (simp add: complex_zero_def)
    59 
    60 lemma complex_Im_zero [simp]: "Im 0 = 0"
    61   by (simp add: complex_zero_def)
    62 
    63 lemma complex_add [simp]:
    64   "Complex a b + Complex c d = Complex (a + c) (b + d)"
    65   by (simp add: complex_add_def)
    66 
    67 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"
    68   by (simp add: complex_add_def)
    69 
    70 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"
    71   by (simp add: complex_add_def)
    72 
    73 lemma complex_minus [simp]:
    74   "- (Complex a b) = Complex (- a) (- b)"
    75   by (simp add: complex_minus_def)
    76 
    77 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"
    78   by (simp add: complex_minus_def)
    79 
    80 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"
    81   by (simp add: complex_minus_def)
    82 
    83 lemma complex_diff [simp]:
    84   "Complex a b - Complex c d = Complex (a - c) (b - d)"
    85   by (simp add: complex_diff_def)
    86 
    87 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"
    88   by (simp add: complex_diff_def)
    89 
    90 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"
    91   by (simp add: complex_diff_def)
    92 
    93 instance
    94   by intro_classes (simp_all add: complex_add_def complex_diff_def)
    95 
    96 end
    97 
    98 
    99 
   100 subsection {* Multiplication and Division *}
   101 
   102 instantiation complex :: field_inverse_zero
   103 begin
   104 
   105 definition
   106   complex_one_def: "1 = Complex 1 0"
   107 
   108 definition
   109   complex_mult_def: "x * y =
   110     Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"
   111 
   112 definition
   113   complex_inverse_def: "inverse x =
   114     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"
   115 
   116 definition
   117   complex_divide_def: "x / (y\<Colon>complex) = x * inverse y"
   118 
   119 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"
   120   by (simp add: complex_one_def)
   121 
   122 lemma complex_Re_one [simp]: "Re 1 = 1"
   123   by (simp add: complex_one_def)
   124 
   125 lemma complex_Im_one [simp]: "Im 1 = 0"
   126   by (simp add: complex_one_def)
   127 
   128 lemma complex_mult [simp]:
   129   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   130   by (simp add: complex_mult_def)
   131 
   132 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"
   133   by (simp add: complex_mult_def)
   134 
   135 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"
   136   by (simp add: complex_mult_def)
   137 
   138 lemma complex_inverse [simp]:
   139   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"
   140   by (simp add: complex_inverse_def)
   141 
   142 lemma complex_Re_inverse:
   143   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   144   by (simp add: complex_inverse_def)
   145 
   146 lemma complex_Im_inverse:
   147   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"
   148   by (simp add: complex_inverse_def)
   149 
   150 instance
   151   by intro_classes (simp_all add: complex_mult_def
   152   right_distrib left_distrib right_diff_distrib left_diff_distrib
   153   complex_inverse_def complex_divide_def
   154   power2_eq_square add_divide_distrib [symmetric]
   155   expand_complex_eq)
   156 
   157 end
   158 
   159 
   160 subsection {* Numerals and Arithmetic *}
   161 
   162 instantiation complex :: number_ring
   163 begin
   164 
   165 definition number_of_complex where
   166   complex_number_of_def: "number_of w = (of_int w \<Colon> complex)"
   167 
   168 instance
   169   by intro_classes (simp only: complex_number_of_def)
   170 
   171 end
   172 
   173 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   174 by (induct n) simp_all
   175 
   176 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   177 by (induct n) simp_all
   178 
   179 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   180 by (cases z rule: int_diff_cases) simp
   181 
   182 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   183 by (cases z rule: int_diff_cases) simp
   184 
   185 lemma complex_Re_number_of [simp]: "Re (number_of v) = number_of v"
   186 unfolding number_of_eq by (rule complex_Re_of_int)
   187 
   188 lemma complex_Im_number_of [simp]: "Im (number_of v) = 0"
   189 unfolding number_of_eq by (rule complex_Im_of_int)
   190 
   191 lemma Complex_eq_number_of [simp]:
   192   "(Complex a b = number_of w) = (a = number_of w \<and> b = 0)"
   193 by (simp add: expand_complex_eq)
   194 
   195 
   196 subsection {* Scalar Multiplication *}
   197 
   198 instantiation complex :: real_field
   199 begin
   200 
   201 definition
   202   complex_scaleR_def: "scaleR r x = Complex (r * Re x) (r * Im x)"
   203 
   204 lemma complex_scaleR [simp]:
   205   "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   206   unfolding complex_scaleR_def by simp
   207 
   208 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"
   209   unfolding complex_scaleR_def by simp
   210 
   211 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"
   212   unfolding complex_scaleR_def by simp
   213 
   214 instance
   215 proof
   216   fix a b :: real and x y :: complex
   217   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   218     by (simp add: expand_complex_eq right_distrib)
   219   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   220     by (simp add: expand_complex_eq left_distrib)
   221   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   222     by (simp add: expand_complex_eq mult_assoc)
   223   show "scaleR 1 x = x"
   224     by (simp add: expand_complex_eq)
   225   show "scaleR a x * y = scaleR a (x * y)"
   226     by (simp add: expand_complex_eq algebra_simps)
   227   show "x * scaleR a y = scaleR a (x * y)"
   228     by (simp add: expand_complex_eq algebra_simps)
   229 qed
   230 
   231 end
   232 
   233 
   234 subsection{* Properties of Embedding from Reals *}
   235 
   236 abbreviation
   237   complex_of_real :: "real \<Rightarrow> complex" where
   238     "complex_of_real \<equiv> of_real"
   239 
   240 lemma complex_of_real_def: "complex_of_real r = Complex r 0"
   241 by (simp add: of_real_def complex_scaleR_def)
   242 
   243 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   244 by (simp add: complex_of_real_def)
   245 
   246 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   247 by (simp add: complex_of_real_def)
   248 
   249 lemma Complex_add_complex_of_real [simp]:
   250      "Complex x y + complex_of_real r = Complex (x+r) y"
   251 by (simp add: complex_of_real_def)
   252 
   253 lemma complex_of_real_add_Complex [simp]:
   254      "complex_of_real r + Complex x y = Complex (r+x) y"
   255 by (simp add: complex_of_real_def)
   256 
   257 lemma Complex_mult_complex_of_real:
   258      "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   259 by (simp add: complex_of_real_def)
   260 
   261 lemma complex_of_real_mult_Complex:
   262      "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   263 by (simp add: complex_of_real_def)
   264 
   265 
   266 subsection {* Vector Norm *}
   267 
   268 instantiation complex :: real_normed_field
   269 begin
   270 
   271 definition complex_norm_def:
   272   "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   273 
   274 abbreviation
   275   cmod :: "complex \<Rightarrow> real" where
   276   "cmod \<equiv> norm"
   277 
   278 definition complex_sgn_def:
   279   "sgn x = x /\<^sub>R cmod x"
   280 
   281 definition dist_complex_def:
   282   "dist x y = cmod (x - y)"
   283 
   284 definition open_complex_def:
   285   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   286 
   287 lemmas cmod_def = complex_norm_def
   288 
   289 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"
   290   by (simp add: complex_norm_def)
   291 
   292 instance proof
   293   fix r :: real and x y :: complex and S :: "complex set"
   294   show "0 \<le> norm x"
   295     by (induct x) simp
   296   show "(norm x = 0) = (x = 0)"
   297     by (induct x) simp
   298   show "norm (x + y) \<le> norm x + norm y"
   299     by (induct x, induct y)
   300        (simp add: real_sqrt_sum_squares_triangle_ineq)
   301   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   302     by (induct x)
   303        (simp add: power_mult_distrib right_distrib [symmetric] real_sqrt_mult)
   304   show "norm (x * y) = norm x * norm y"
   305     by (induct x, induct y)
   306        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   307   show "sgn x = x /\<^sub>R cmod x"
   308     by (rule complex_sgn_def)
   309   show "dist x y = cmod (x - y)"
   310     by (rule dist_complex_def)
   311   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   312     by (rule open_complex_def)
   313 qed
   314 
   315 end
   316 
   317 lemma cmod_unit_one [simp]: "cmod (Complex (cos a) (sin a)) = 1"
   318 by simp
   319 
   320 lemma cmod_complex_polar [simp]:
   321      "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"
   322 by (simp add: norm_mult)
   323 
   324 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   325 unfolding complex_norm_def
   326 by (rule real_sqrt_sum_squares_ge1)
   327 
   328 lemma complex_mod_minus_le_complex_mod [simp]: "- cmod x \<le> cmod x"
   329 by (rule order_trans [OF _ norm_ge_zero], simp)
   330 
   331 lemma complex_mod_triangle_ineq2 [simp]: "cmod(b + a) - cmod b \<le> cmod a"
   332 by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)
   333 
   334 lemmas real_sum_squared_expand = power2_sum [where 'a=real]
   335 
   336 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   337 by (cases x) simp
   338 
   339 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   340 by (cases x) simp
   341 
   342 subsection {* Completeness of the Complexes *}
   343 
   344 interpretation Re: bounded_linear "Re"
   345 apply (unfold_locales, simp, simp)
   346 apply (rule_tac x=1 in exI)
   347 apply (simp add: complex_norm_def)
   348 done
   349 
   350 interpretation Im: bounded_linear "Im"
   351 apply (unfold_locales, simp, simp)
   352 apply (rule_tac x=1 in exI)
   353 apply (simp add: complex_norm_def)
   354 done
   355 
   356 lemma tendsto_Complex [tendsto_intros]:
   357   assumes "(f ---> a) net" and "(g ---> b) net"
   358   shows "((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) net"
   359 proof (rule tendstoI)
   360   fix r :: real assume "0 < r"
   361   hence "0 < r / sqrt 2" by (simp add: divide_pos_pos)
   362   have "eventually (\<lambda>x. dist (f x) a < r / sqrt 2) net"
   363     using `(f ---> a) net` and `0 < r / sqrt 2` by (rule tendstoD)
   364   moreover
   365   have "eventually (\<lambda>x. dist (g x) b < r / sqrt 2) net"
   366     using `(g ---> b) net` and `0 < r / sqrt 2` by (rule tendstoD)
   367   ultimately
   368   show "eventually (\<lambda>x. dist (Complex (f x) (g x)) (Complex a b) < r) net"
   369     by (rule eventually_elim2)
   370        (simp add: dist_norm real_sqrt_sum_squares_less)
   371 qed
   372 
   373 lemma LIMSEQ_Complex:
   374   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. Complex (X n) (Y n)) ----> Complex a b"
   375 by (rule tendsto_Complex)
   376 
   377 instance complex :: banach
   378 proof
   379   fix X :: "nat \<Rightarrow> complex"
   380   assume X: "Cauchy X"
   381   from Re.Cauchy [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"
   382     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   383   from Im.Cauchy [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"
   384     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
   385   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   386     using LIMSEQ_Complex [OF 1 2] by simp
   387   thus "convergent X"
   388     by (rule convergentI)
   389 qed
   390 
   391 
   392 subsection {* The Complex Number @{term "\<i>"} *}
   393 
   394 definition
   395   "ii" :: complex  ("\<i>") where
   396   i_def: "ii \<equiv> Complex 0 1"
   397 
   398 lemma complex_Re_i [simp]: "Re ii = 0"
   399 by (simp add: i_def)
   400 
   401 lemma complex_Im_i [simp]: "Im ii = 1"
   402 by (simp add: i_def)
   403 
   404 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   405 by (simp add: i_def)
   406 
   407 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   408 by (simp add: expand_complex_eq)
   409 
   410 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   411 by (simp add: expand_complex_eq)
   412 
   413 lemma complex_i_not_number_of [simp]: "ii \<noteq> number_of w"
   414 by (simp add: expand_complex_eq)
   415 
   416 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"
   417 by (simp add: expand_complex_eq)
   418 
   419 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"
   420 by (simp add: expand_complex_eq)
   421 
   422 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"
   423 by (simp add: i_def complex_of_real_def)
   424 
   425 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"
   426 by (simp add: i_def complex_of_real_def)
   427 
   428 lemma i_squared [simp]: "ii * ii = -1"
   429 by (simp add: i_def)
   430 
   431 lemma power2_i [simp]: "ii\<twosuperior> = -1"
   432 by (simp add: power2_eq_square)
   433 
   434 lemma inverse_i [simp]: "inverse ii = - ii"
   435 by (rule inverse_unique, simp)
   436 
   437 
   438 subsection {* Complex Conjugation *}
   439 
   440 definition
   441   cnj :: "complex \<Rightarrow> complex" where
   442   "cnj z = Complex (Re z) (- Im z)"
   443 
   444 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"
   445 by (simp add: cnj_def)
   446 
   447 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"
   448 by (simp add: cnj_def)
   449 
   450 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"
   451 by (simp add: cnj_def)
   452 
   453 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   454 by (simp add: expand_complex_eq)
   455 
   456 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   457 by (simp add: cnj_def)
   458 
   459 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   460 by (simp add: expand_complex_eq)
   461 
   462 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   463 by (simp add: expand_complex_eq)
   464 
   465 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"
   466 by (simp add: expand_complex_eq)
   467 
   468 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"
   469 by (simp add: expand_complex_eq)
   470 
   471 lemma complex_cnj_minus: "cnj (- x) = - cnj x"
   472 by (simp add: expand_complex_eq)
   473 
   474 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   475 by (simp add: expand_complex_eq)
   476 
   477 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"
   478 by (simp add: expand_complex_eq)
   479 
   480 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"
   481 by (simp add: complex_inverse_def)
   482 
   483 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"
   484 by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)
   485 
   486 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"
   487 by (induct n, simp_all add: complex_cnj_mult)
   488 
   489 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   490 by (simp add: expand_complex_eq)
   491 
   492 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   493 by (simp add: expand_complex_eq)
   494 
   495 lemma complex_cnj_number_of [simp]: "cnj (number_of w) = number_of w"
   496 by (simp add: expand_complex_eq)
   497 
   498 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"
   499 by (simp add: expand_complex_eq)
   500 
   501 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   502 by (simp add: complex_norm_def)
   503 
   504 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   505 by (simp add: expand_complex_eq)
   506 
   507 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   508 by (simp add: expand_complex_eq)
   509 
   510 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   511 by (simp add: expand_complex_eq)
   512 
   513 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   514 by (simp add: expand_complex_eq)
   515 
   516 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"
   517 by (simp add: expand_complex_eq power2_eq_square)
   518 
   519 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"
   520 by (simp add: norm_mult power2_eq_square)
   521 
   522 interpretation cnj: bounded_linear "cnj"
   523 apply (unfold_locales)
   524 apply (rule complex_cnj_add)
   525 apply (rule complex_cnj_scaleR)
   526 apply (rule_tac x=1 in exI, simp)
   527 done
   528 
   529 
   530 subsection{*The Functions @{term sgn} and @{term arg}*}
   531 
   532 text {*------------ Argand -------------*}
   533 
   534 definition
   535   arg :: "complex => real" where
   536   "arg z = (SOME a. Re(sgn z) = cos a & Im(sgn z) = sin a & -pi < a & a \<le> pi)"
   537 
   538 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   539 by (simp add: complex_sgn_def divide_inverse scaleR_conv_of_real mult_commute)
   540 
   541 lemma i_mult_eq: "ii * ii = complex_of_real (-1)"
   542 by (simp add: i_def complex_of_real_def)
   543 
   544 lemma i_mult_eq2 [simp]: "ii * ii = -(1::complex)"
   545 by (simp add: i_def complex_one_def)
   546 
   547 lemma complex_eq_cancel_iff2 [simp]:
   548      "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   549 by (simp add: complex_of_real_def)
   550 
   551 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   552 by (simp add: complex_sgn_def divide_inverse)
   553 
   554 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   555 by (simp add: complex_sgn_def divide_inverse)
   556 
   557 lemma complex_inverse_complex_split:
   558      "inverse(complex_of_real x + ii * complex_of_real y) =
   559       complex_of_real(x/(x ^ 2 + y ^ 2)) -
   560       ii * complex_of_real(y/(x ^ 2 + y ^ 2))"
   561 by (simp add: complex_of_real_def i_def diff_minus divide_inverse)
   562 
   563 (*----------------------------------------------------------------------------*)
   564 (* Many of the theorems below need to be moved elsewhere e.g. Transc. Also *)
   565 (* many of the theorems are not used - so should they be kept?                *)
   566 (*----------------------------------------------------------------------------*)
   567 
   568 lemma cos_arg_i_mult_zero_pos:
   569    "0 < y ==> cos (arg(Complex 0 y)) = 0"
   570 apply (simp add: arg_def abs_if)
   571 apply (rule_tac a = "pi/2" in someI2, auto)
   572 apply (rule order_less_trans [of _ 0], auto)
   573 done
   574 
   575 lemma cos_arg_i_mult_zero_neg:
   576    "y < 0 ==> cos (arg(Complex 0 y)) = 0"
   577 apply (simp add: arg_def abs_if)
   578 apply (rule_tac a = "- pi/2" in someI2, auto)
   579 apply (rule order_trans [of _ 0], auto)
   580 done
   581 
   582 lemma cos_arg_i_mult_zero [simp]:
   583      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"
   584 by (auto simp add: linorder_neq_iff cos_arg_i_mult_zero_pos cos_arg_i_mult_zero_neg)
   585 
   586 
   587 subsection{*Finally! Polar Form for Complex Numbers*}
   588 
   589 definition
   590 
   591   (* abbreviation for (cos a + i sin a) *)
   592   cis :: "real => complex" where
   593   "cis a = Complex (cos a) (sin a)"
   594 
   595 definition
   596   (* abbreviation for r*(cos a + i sin a) *)
   597   rcis :: "[real, real] => complex" where
   598   "rcis r a = complex_of_real r * cis a"
   599 
   600 definition
   601   (* e ^ (x + iy) *)
   602   expi :: "complex => complex" where
   603   "expi z = complex_of_real(exp (Re z)) * cis (Im z)"
   604 
   605 lemma complex_split_polar:
   606      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"
   607 apply (induct z)
   608 apply (auto simp add: polar_Ex complex_of_real_mult_Complex)
   609 done
   610 
   611 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   612 apply (induct z)
   613 apply (simp add: rcis_def cis_def polar_Ex complex_of_real_mult_Complex)
   614 done
   615 
   616 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   617 by (simp add: rcis_def cis_def)
   618 
   619 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   620 by (simp add: rcis_def cis_def)
   621 
   622 lemma sin_cos_squared_add2_mult: "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior>"
   623 proof -
   624   have "(r * cos a)\<twosuperior> + (r * sin a)\<twosuperior> = r\<twosuperior> * ((cos a)\<twosuperior> + (sin a)\<twosuperior>)"
   625     by (simp only: power_mult_distrib right_distrib)
   626   thus ?thesis by simp
   627 qed
   628 
   629 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   630 by (simp add: rcis_def cis_def sin_cos_squared_add2_mult)
   631 
   632 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   633 by (simp add: cmod_def power2_eq_square)
   634 
   635 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   636 by simp
   637 
   638 
   639 (*---------------------------------------------------------------------------*)
   640 (*  (r1 * cis a) * (r2 * cis b) = r1 * r2 * cis (a + b)                      *)
   641 (*---------------------------------------------------------------------------*)
   642 
   643 lemma cis_rcis_eq: "cis a = rcis 1 a"
   644 by (simp add: rcis_def)
   645 
   646 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   647 by (simp add: rcis_def cis_def cos_add sin_add right_distrib right_diff_distrib
   648               complex_of_real_def)
   649 
   650 lemma cis_mult: "cis a * cis b = cis (a + b)"
   651 by (simp add: cis_rcis_eq rcis_mult)
   652 
   653 lemma cis_zero [simp]: "cis 0 = 1"
   654 by (simp add: cis_def complex_one_def)
   655 
   656 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   657 by (simp add: rcis_def)
   658 
   659 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   660 by (simp add: rcis_def)
   661 
   662 lemma complex_of_real_minus_one:
   663    "complex_of_real (-(1::real)) = -(1::complex)"
   664 by (simp add: complex_of_real_def complex_one_def)
   665 
   666 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   667 by (simp add: mult_assoc [symmetric])
   668 
   669 
   670 lemma cis_real_of_nat_Suc_mult:
   671    "cis (real (Suc n) * a) = cis a * cis (real n * a)"
   672 by (simp add: cis_def real_of_nat_Suc left_distrib cos_add sin_add right_distrib)
   673 
   674 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   675 apply (induct_tac "n")
   676 apply (auto simp add: cis_real_of_nat_Suc_mult)
   677 done
   678 
   679 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   680 by (simp add: rcis_def power_mult_distrib DeMoivre)
   681 
   682 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   683 by (simp add: cis_def complex_inverse_complex_split diff_minus)
   684 
   685 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   686 by (simp add: divide_inverse rcis_def)
   687 
   688 lemma cis_divide: "cis a / cis b = cis (a - b)"
   689 by (simp add: complex_divide_def cis_mult diff_minus)
   690 
   691 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   692 apply (simp add: complex_divide_def)
   693 apply (case_tac "r2=0", simp)
   694 apply (simp add: rcis_inverse rcis_mult diff_minus)
   695 done
   696 
   697 lemma Re_cis [simp]: "Re(cis a) = cos a"
   698 by (simp add: cis_def)
   699 
   700 lemma Im_cis [simp]: "Im(cis a) = sin a"
   701 by (simp add: cis_def)
   702 
   703 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   704 by (auto simp add: DeMoivre)
   705 
   706 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   707 by (auto simp add: DeMoivre)
   708 
   709 lemma expi_add: "expi(a + b) = expi(a) * expi(b)"
   710 by (simp add: expi_def exp_add cis_mult [symmetric] mult_ac)
   711 
   712 lemma expi_zero [simp]: "expi (0::complex) = 1"
   713 by (simp add: expi_def)
   714 
   715 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"
   716 apply (insert rcis_Ex [of z])
   717 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])
   718 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   719 done
   720 
   721 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"
   722 by (simp add: expi_def cis_def)
   723 
   724 end