src/HOL/Enum.thy
author wenzelm
Fri Dec 17 17:43:54 2010 +0100 (2010-12-17)
changeset 41229 d797baa3d57c
parent 41115 2c362ff5daf4
child 45117 3911cf09899a
permissions -rw-r--r--
replaced command 'nonterminals' by slightly modernized version 'nonterminal';
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Finite types as explicit enumerations *}
     4 
     5 theory Enum
     6 imports Map String
     7 begin
     8 
     9 subsection {* Class @{text enum} *}
    10 
    11 class enum =
    12   fixes enum :: "'a list"
    13   fixes enum_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    14   fixes enum_ex  :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    15   assumes UNIV_enum: "UNIV = set enum"
    16     and enum_distinct: "distinct enum"
    17   assumes enum_all : "enum_all P = (\<forall> x. P x)"
    18   assumes enum_ex  : "enum_ex P = (\<exists> x. P x)" 
    19 begin
    20 
    21 subclass finite proof
    22 qed (simp add: UNIV_enum)
    23 
    24 lemma enum_UNIV: "set enum = UNIV" unfolding UNIV_enum ..
    25 
    26 lemma in_enum: "x \<in> set enum"
    27   unfolding enum_UNIV by auto
    28 
    29 lemma enum_eq_I:
    30   assumes "\<And>x. x \<in> set xs"
    31   shows "set enum = set xs"
    32 proof -
    33   from assms UNIV_eq_I have "UNIV = set xs" by auto
    34   with enum_UNIV show ?thesis by simp
    35 qed
    36 
    37 end
    38 
    39 
    40 subsection {* Equality and order on functions *}
    41 
    42 instantiation "fun" :: (enum, equal) equal
    43 begin
    44 
    45 definition
    46   "HOL.equal f g \<longleftrightarrow> (\<forall>x \<in> set enum. f x = g x)"
    47 
    48 instance proof
    49 qed (simp_all add: equal_fun_def enum_UNIV fun_eq_iff)
    50 
    51 end
    52 
    53 lemma [code]:
    54   "HOL.equal f g \<longleftrightarrow> enum_all (%x. f x = g x)"
    55 by (auto simp add: equal enum_all fun_eq_iff)
    56 
    57 lemma [code nbe]:
    58   "HOL.equal (f :: _ \<Rightarrow> _) f \<longleftrightarrow> True"
    59   by (fact equal_refl)
    60 
    61 lemma order_fun [code]:
    62   fixes f g :: "'a\<Colon>enum \<Rightarrow> 'b\<Colon>order"
    63   shows "f \<le> g \<longleftrightarrow> enum_all (\<lambda>x. f x \<le> g x)"
    64     and "f < g \<longleftrightarrow> f \<le> g \<and> enum_ex (\<lambda>x. f x \<noteq> g x)"
    65   by (simp_all add: enum_all enum_ex fun_eq_iff le_fun_def order_less_le)
    66 
    67 
    68 subsection {* Quantifiers *}
    69 
    70 lemma all_code [code]: "(\<forall>x. P x) \<longleftrightarrow> enum_all P"
    71   by (simp add: enum_all)
    72 
    73 lemma exists_code [code]: "(\<exists>x. P x) \<longleftrightarrow> enum_ex P"
    74   by (simp add: enum_ex)
    75 
    76 lemma exists1_code[code]: "(\<exists>!x. P x) \<longleftrightarrow> list_ex1 P enum"
    77 unfolding list_ex1_iff enum_UNIV by auto
    78 
    79 
    80 subsection {* Default instances *}
    81 
    82 primrec n_lists :: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list list" where
    83   "n_lists 0 xs = [[]]"
    84   | "n_lists (Suc n) xs = concat (map (\<lambda>ys. map (\<lambda>y. y # ys) xs) (n_lists n xs))"
    85 
    86 lemma n_lists_Nil [simp]: "n_lists n [] = (if n = 0 then [[]] else [])"
    87   by (induct n) simp_all
    88 
    89 lemma length_n_lists: "length (n_lists n xs) = length xs ^ n"
    90   by (induct n) (auto simp add: length_concat o_def listsum_triv)
    91 
    92 lemma length_n_lists_elem: "ys \<in> set (n_lists n xs) \<Longrightarrow> length ys = n"
    93   by (induct n arbitrary: ys) auto
    94 
    95 lemma set_n_lists: "set (n_lists n xs) = {ys. length ys = n \<and> set ys \<subseteq> set xs}"
    96 proof (rule set_eqI)
    97   fix ys :: "'a list"
    98   show "ys \<in> set (n_lists n xs) \<longleftrightarrow> ys \<in> {ys. length ys = n \<and> set ys \<subseteq> set xs}"
    99   proof -
   100     have "ys \<in> set (n_lists n xs) \<Longrightarrow> length ys = n"
   101       by (induct n arbitrary: ys) auto
   102     moreover have "\<And>x. ys \<in> set (n_lists n xs) \<Longrightarrow> x \<in> set ys \<Longrightarrow> x \<in> set xs"
   103       by (induct n arbitrary: ys) auto
   104     moreover have "set ys \<subseteq> set xs \<Longrightarrow> ys \<in> set (n_lists (length ys) xs)"
   105       by (induct ys) auto
   106     ultimately show ?thesis by auto
   107   qed
   108 qed
   109 
   110 lemma distinct_n_lists:
   111   assumes "distinct xs"
   112   shows "distinct (n_lists n xs)"
   113 proof (rule card_distinct)
   114   from assms have card_length: "card (set xs) = length xs" by (rule distinct_card)
   115   have "card (set (n_lists n xs)) = card (set xs) ^ n"
   116   proof (induct n)
   117     case 0 then show ?case by simp
   118   next
   119     case (Suc n)
   120     moreover have "card (\<Union>ys\<in>set (n_lists n xs). (\<lambda>y. y # ys) ` set xs)
   121       = (\<Sum>ys\<in>set (n_lists n xs). card ((\<lambda>y. y # ys) ` set xs))"
   122       by (rule card_UN_disjoint) auto
   123     moreover have "\<And>ys. card ((\<lambda>y. y # ys) ` set xs) = card (set xs)"
   124       by (rule card_image) (simp add: inj_on_def)
   125     ultimately show ?case by auto
   126   qed
   127   also have "\<dots> = length xs ^ n" by (simp add: card_length)
   128   finally show "card (set (n_lists n xs)) = length (n_lists n xs)"
   129     by (simp add: length_n_lists)
   130 qed
   131 
   132 lemma map_of_zip_enum_is_Some:
   133   assumes "length ys = length (enum \<Colon> 'a\<Colon>enum list)"
   134   shows "\<exists>y. map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x = Some y"
   135 proof -
   136   from assms have "x \<in> set (enum \<Colon> 'a\<Colon>enum list) \<longleftrightarrow>
   137     (\<exists>y. map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x = Some y)"
   138     by (auto intro!: map_of_zip_is_Some)
   139   then show ?thesis using enum_UNIV by auto
   140 qed
   141 
   142 lemma map_of_zip_enum_inject:
   143   fixes xs ys :: "'b\<Colon>enum list"
   144   assumes length: "length xs = length (enum \<Colon> 'a\<Colon>enum list)"
   145       "length ys = length (enum \<Colon> 'a\<Colon>enum list)"
   146     and map_of: "the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys)"
   147   shows "xs = ys"
   148 proof -
   149   have "map_of (zip (enum \<Colon> 'a list) xs) = map_of (zip (enum \<Colon> 'a list) ys)"
   150   proof
   151     fix x :: 'a
   152     from length map_of_zip_enum_is_Some obtain y1 y2
   153       where "map_of (zip (enum \<Colon> 'a list) xs) x = Some y1"
   154         and "map_of (zip (enum \<Colon> 'a list) ys) x = Some y2" by blast
   155     moreover from map_of have "the (map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) x) = the (map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x)"
   156       by (auto dest: fun_cong)
   157     ultimately show "map_of (zip (enum \<Colon> 'a\<Colon>enum list) xs) x = map_of (zip (enum \<Colon> 'a\<Colon>enum list) ys) x"
   158       by simp
   159   qed
   160   with length enum_distinct show "xs = ys" by (rule map_of_zip_inject)
   161 qed
   162 
   163 definition
   164   all_n_lists :: "(('a :: enum) list \<Rightarrow> bool) \<Rightarrow> nat \<Rightarrow> bool"
   165 where
   166   "all_n_lists P n = (\<forall>xs \<in> set (n_lists n enum). P xs)"
   167 
   168 lemma [code]:
   169   "all_n_lists P n = (if n = 0 then P [] else enum_all (%x. all_n_lists (%xs. P (x # xs)) (n - 1)))"
   170 unfolding all_n_lists_def enum_all
   171 by (cases n) (auto simp add: enum_UNIV)
   172 
   173 definition
   174   ex_n_lists :: "(('a :: enum) list \<Rightarrow> bool) \<Rightarrow> nat \<Rightarrow> bool"
   175 where
   176   "ex_n_lists P n = (\<exists>xs \<in> set (n_lists n enum). P xs)"
   177 
   178 lemma [code]:
   179   "ex_n_lists P n = (if n = 0 then P [] else enum_ex (%x. ex_n_lists (%xs. P (x # xs)) (n - 1)))"
   180 unfolding ex_n_lists_def enum_ex
   181 by (cases n) (auto simp add: enum_UNIV)
   182 
   183 
   184 instantiation "fun" :: (enum, enum) enum
   185 begin
   186 
   187 definition
   188   "enum = map (\<lambda>ys. the o map_of (zip (enum\<Colon>'a list) ys)) (n_lists (length (enum\<Colon>'a\<Colon>enum list)) enum)"
   189 
   190 definition
   191   "enum_all P = all_n_lists (\<lambda>bs. P (the o map_of (zip enum bs))) (length (enum :: 'a list))"
   192 
   193 definition
   194   "enum_ex P = ex_n_lists (\<lambda>bs. P (the o map_of (zip enum bs))) (length (enum :: 'a list))"
   195 
   196 
   197 instance proof
   198   show "UNIV = set (enum \<Colon> ('a \<Rightarrow> 'b) list)"
   199   proof (rule UNIV_eq_I)
   200     fix f :: "'a \<Rightarrow> 'b"
   201     have "f = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum))"
   202       by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum)
   203     then show "f \<in> set enum"
   204       by (auto simp add: enum_fun_def set_n_lists intro: in_enum)
   205   qed
   206 next
   207   from map_of_zip_enum_inject
   208   show "distinct (enum \<Colon> ('a \<Rightarrow> 'b) list)"
   209     by (auto intro!: inj_onI simp add: enum_fun_def
   210       distinct_map distinct_n_lists enum_distinct set_n_lists enum_all)
   211 next
   212   fix P
   213   show "enum_all (P :: ('a \<Rightarrow> 'b) \<Rightarrow> bool) = (\<forall>x. P x)"
   214   proof
   215     assume "enum_all P"
   216     show "\<forall>x. P x"
   217     proof
   218       fix f :: "'a \<Rightarrow> 'b"
   219       have f: "f = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum))"
   220         by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum)
   221       from `enum_all P` have "P (the \<circ> map_of (zip enum (map f enum)))"
   222         unfolding enum_all_fun_def all_n_lists_def
   223         apply (simp add: set_n_lists)
   224         apply (erule_tac x="map f enum" in allE)
   225         apply (auto intro!: in_enum)
   226         done
   227       from this f show "P f" by auto
   228     qed
   229   next
   230     assume "\<forall>x. P x"
   231     from this show "enum_all P"
   232       unfolding enum_all_fun_def all_n_lists_def by auto
   233   qed
   234 next
   235   fix P
   236   show "enum_ex (P :: ('a \<Rightarrow> 'b) \<Rightarrow> bool) = (\<exists>x. P x)"
   237   proof
   238     assume "enum_ex P"
   239     from this show "\<exists>x. P x"
   240       unfolding enum_ex_fun_def ex_n_lists_def by auto
   241   next
   242     assume "\<exists>x. P x"
   243     from this obtain f where "P f" ..
   244     have f: "f = the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum))"
   245       by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum) 
   246     from `P f` this have "P (the \<circ> map_of (zip (enum \<Colon> 'a\<Colon>enum list) (map f enum)))"
   247       by auto
   248     from  this show "enum_ex P"
   249       unfolding enum_ex_fun_def ex_n_lists_def
   250       apply (auto simp add: set_n_lists)
   251       apply (rule_tac x="map f enum" in exI)
   252       apply (auto intro!: in_enum)
   253       done
   254   qed
   255 qed
   256 
   257 end
   258 
   259 lemma enum_fun_code [code]: "enum = (let enum_a = (enum \<Colon> 'a\<Colon>{enum, equal} list)
   260   in map (\<lambda>ys. the o map_of (zip enum_a ys)) (n_lists (length enum_a) enum))"
   261   by (simp add: enum_fun_def Let_def)
   262 
   263 lemma enum_all_fun_code [code]:
   264   "enum_all P = (let enum_a = (enum :: 'a::{enum, equal} list)
   265    in all_n_lists (\<lambda>bs. P (the o map_of (zip enum_a bs))) (length enum_a))"
   266   by (simp add: enum_all_fun_def Let_def)
   267 
   268 lemma enum_ex_fun_code [code]:
   269   "enum_ex P = (let enum_a = (enum :: 'a::{enum, equal} list)
   270    in ex_n_lists (\<lambda>bs. P (the o map_of (zip enum_a bs))) (length enum_a))"
   271   by (simp add: enum_ex_fun_def Let_def)
   272 
   273 instantiation unit :: enum
   274 begin
   275 
   276 definition
   277   "enum = [()]"
   278 
   279 definition
   280   "enum_all P = P ()"
   281 
   282 definition
   283   "enum_ex P = P ()"
   284 
   285 instance proof
   286 qed (auto simp add: enum_unit_def UNIV_unit enum_all_unit_def enum_ex_unit_def intro: unit.exhaust)
   287 
   288 end
   289 
   290 instantiation bool :: enum
   291 begin
   292 
   293 definition
   294   "enum = [False, True]"
   295 
   296 definition
   297   "enum_all P = (P False \<and> P True)"
   298 
   299 definition
   300   "enum_ex P = (P False \<or> P True)"
   301 
   302 instance proof
   303   fix P
   304   show "enum_all (P :: bool \<Rightarrow> bool) = (\<forall>x. P x)"
   305     unfolding enum_all_bool_def by (auto, case_tac x) auto
   306 next
   307   fix P
   308   show "enum_ex (P :: bool \<Rightarrow> bool) = (\<exists>x. P x)"
   309     unfolding enum_ex_bool_def by (auto, case_tac x) auto
   310 qed (auto simp add: enum_bool_def UNIV_bool)
   311 
   312 end
   313 
   314 primrec product :: "'a list \<Rightarrow> 'b list \<Rightarrow> ('a \<times> 'b) list" where
   315   "product [] _ = []"
   316   | "product (x#xs) ys = map (Pair x) ys @ product xs ys"
   317 
   318 lemma product_list_set:
   319   "set (product xs ys) = set xs \<times> set ys"
   320   by (induct xs) auto
   321 
   322 lemma distinct_product:
   323   assumes "distinct xs" and "distinct ys"
   324   shows "distinct (product xs ys)"
   325   using assms by (induct xs)
   326     (auto intro: inj_onI simp add: product_list_set distinct_map)
   327 
   328 instantiation prod :: (enum, enum) enum
   329 begin
   330 
   331 definition
   332   "enum = product enum enum"
   333 
   334 definition
   335   "enum_all P = enum_all (%x. enum_all (%y. P (x, y)))"
   336 
   337 definition
   338   "enum_ex P = enum_ex (%x. enum_ex (%y. P (x, y)))"
   339 
   340  
   341 instance by default
   342   (simp_all add: enum_prod_def product_list_set distinct_product
   343     enum_UNIV enum_distinct enum_all_prod_def enum_all enum_ex_prod_def enum_ex)
   344 
   345 end
   346 
   347 instantiation sum :: (enum, enum) enum
   348 begin
   349 
   350 definition
   351   "enum = map Inl enum @ map Inr enum"
   352 
   353 definition
   354   "enum_all P = (enum_all (%x. P (Inl x)) \<and> enum_all (%x. P (Inr x)))"
   355 
   356 definition
   357   "enum_ex P = (enum_ex (%x. P (Inl x)) \<or> enum_ex (%x. P (Inr x)))"
   358 
   359 instance proof
   360   fix P
   361   show "enum_all (P :: ('a + 'b) \<Rightarrow> bool) = (\<forall>x. P x)"
   362     unfolding enum_all_sum_def enum_all
   363     by (auto, case_tac x) auto
   364 next
   365   fix P
   366   show "enum_ex (P :: ('a + 'b) \<Rightarrow> bool) = (\<exists>x. P x)"
   367     unfolding enum_ex_sum_def enum_ex
   368     by (auto, case_tac x) auto
   369 qed (auto simp add: enum_UNIV enum_sum_def, case_tac x, auto intro: inj_onI simp add: distinct_map enum_distinct)
   370 
   371 end
   372 
   373 primrec sublists :: "'a list \<Rightarrow> 'a list list" where
   374   "sublists [] = [[]]"
   375   | "sublists (x#xs) = (let xss = sublists xs in map (Cons x) xss @ xss)"
   376 
   377 lemma length_sublists:
   378   "length (sublists xs) = Suc (Suc (0\<Colon>nat)) ^ length xs"
   379   by (induct xs) (simp_all add: Let_def)
   380 
   381 lemma sublists_powset:
   382   "set ` set (sublists xs) = Pow (set xs)"
   383 proof -
   384   have aux: "\<And>x A. set ` Cons x ` A = insert x ` set ` A"
   385     by (auto simp add: image_def)
   386   have "set (map set (sublists xs)) = Pow (set xs)"
   387     by (induct xs)
   388       (simp_all add: aux Let_def Pow_insert Un_commute comp_def del: map_map)
   389   then show ?thesis by simp
   390 qed
   391 
   392 lemma distinct_set_sublists:
   393   assumes "distinct xs"
   394   shows "distinct (map set (sublists xs))"
   395 proof (rule card_distinct)
   396   have "finite (set xs)" by rule
   397   then have "card (Pow (set xs)) = Suc (Suc 0) ^ card (set xs)" by (rule card_Pow)
   398   with assms distinct_card [of xs]
   399     have "card (Pow (set xs)) = Suc (Suc 0) ^ length xs" by simp
   400   then show "card (set (map set (sublists xs))) = length (map set (sublists xs))"
   401     by (simp add: sublists_powset length_sublists)
   402 qed
   403 
   404 instantiation nibble :: enum
   405 begin
   406 
   407 definition
   408   "enum = [Nibble0, Nibble1, Nibble2, Nibble3, Nibble4, Nibble5, Nibble6, Nibble7,
   409     Nibble8, Nibble9, NibbleA, NibbleB, NibbleC, NibbleD, NibbleE, NibbleF]"
   410 
   411 definition
   412   "enum_all P = (P Nibble0 \<and> P Nibble1 \<and> P Nibble2 \<and> P Nibble3 \<and> P Nibble4 \<and> P Nibble5 \<and> P Nibble6 \<and> P Nibble7
   413      \<and> P Nibble8 \<and> P Nibble9 \<and> P NibbleA \<and> P NibbleB \<and> P NibbleC \<and> P NibbleD \<and> P NibbleE \<and> P NibbleF)"
   414 
   415 definition
   416   "enum_ex P = (P Nibble0 \<or> P Nibble1 \<or> P Nibble2 \<or> P Nibble3 \<or> P Nibble4 \<or> P Nibble5 \<or> P Nibble6 \<or> P Nibble7
   417      \<or> P Nibble8 \<or> P Nibble9 \<or> P NibbleA \<or> P NibbleB \<or> P NibbleC \<or> P NibbleD \<or> P NibbleE \<or> P NibbleF)"
   418 
   419 instance proof
   420   fix P
   421   show "enum_all (P :: nibble \<Rightarrow> bool) = (\<forall>x. P x)"
   422     unfolding enum_all_nibble_def
   423     by (auto, case_tac x) auto
   424 next
   425   fix P
   426   show "enum_ex (P :: nibble \<Rightarrow> bool) = (\<exists>x. P x)"
   427     unfolding enum_ex_nibble_def
   428     by (auto, case_tac x) auto
   429 qed (simp_all add: enum_nibble_def UNIV_nibble)
   430 
   431 end
   432 
   433 instantiation char :: enum
   434 begin
   435 
   436 definition
   437   "enum = map (split Char) (product enum enum)"
   438 
   439 lemma enum_chars [code]:
   440   "enum = chars"
   441   unfolding enum_char_def chars_def enum_nibble_def by simp
   442 
   443 definition
   444   "enum_all P = list_all P chars"
   445 
   446 definition
   447   "enum_ex P = list_ex P chars"
   448 
   449 lemma set_enum_char: "set (enum :: char list) = UNIV"
   450     by (auto intro: char.exhaust simp add: enum_char_def product_list_set enum_UNIV full_SetCompr_eq [symmetric])
   451 
   452 instance proof
   453   fix P
   454   show "enum_all (P :: char \<Rightarrow> bool) = (\<forall>x. P x)"
   455     unfolding enum_all_char_def enum_chars[symmetric]
   456     by (auto simp add: list_all_iff set_enum_char)
   457 next
   458   fix P
   459   show "enum_ex (P :: char \<Rightarrow> bool) = (\<exists>x. P x)"
   460     unfolding enum_ex_char_def enum_chars[symmetric]
   461     by (auto simp add: list_ex_iff set_enum_char)
   462 next
   463   show "distinct (enum :: char list)"
   464     by (auto intro: inj_onI simp add: enum_char_def product_list_set distinct_map distinct_product enum_distinct)
   465 qed (auto simp add: set_enum_char)
   466 
   467 end
   468 
   469 instantiation option :: (enum) enum
   470 begin
   471 
   472 definition
   473   "enum = None # map Some enum"
   474 
   475 definition
   476   "enum_all P = (P None \<and> enum_all (%x. P (Some x)))"
   477 
   478 definition
   479   "enum_ex P = (P None \<or> enum_ex (%x. P (Some x)))"
   480 
   481 instance proof
   482   fix P
   483   show "enum_all (P :: 'a option \<Rightarrow> bool) = (\<forall>x. P x)"
   484     unfolding enum_all_option_def enum_all
   485     by (auto, case_tac x) auto
   486 next
   487   fix P
   488   show "enum_ex (P :: 'a option \<Rightarrow> bool) = (\<exists>x. P x)"
   489     unfolding enum_ex_option_def enum_ex
   490     by (auto, case_tac x) auto
   491 qed (auto simp add: enum_UNIV enum_option_def, rule option.exhaust, auto intro: simp add: distinct_map enum_distinct)
   492 
   493 end
   494 
   495 subsection {* Small finite types *}
   496 
   497 text {* We define small finite types for the use in Quickcheck *}
   498 
   499 datatype finite_1 = a\<^isub>1
   500 
   501 notation (output) a\<^isub>1  ("a\<^isub>1")
   502 
   503 instantiation finite_1 :: enum
   504 begin
   505 
   506 definition
   507   "enum = [a\<^isub>1]"
   508 
   509 definition
   510   "enum_all P = P a\<^isub>1"
   511 
   512 definition
   513   "enum_ex P = P a\<^isub>1"
   514 
   515 instance proof
   516   fix P
   517   show "enum_all (P :: finite_1 \<Rightarrow> bool) = (\<forall>x. P x)"
   518     unfolding enum_all_finite_1_def
   519     by (auto, case_tac x) auto
   520 next
   521   fix P
   522   show "enum_ex (P :: finite_1 \<Rightarrow> bool) = (\<exists>x. P x)"
   523     unfolding enum_ex_finite_1_def
   524     by (auto, case_tac x) auto
   525 qed (auto simp add: enum_finite_1_def intro: finite_1.exhaust)
   526 
   527 end
   528 
   529 instantiation finite_1 :: linorder
   530 begin
   531 
   532 definition less_eq_finite_1 :: "finite_1 \<Rightarrow> finite_1 \<Rightarrow> bool"
   533 where
   534   "less_eq_finite_1 x y = True"
   535 
   536 definition less_finite_1 :: "finite_1 \<Rightarrow> finite_1 \<Rightarrow> bool"
   537 where
   538   "less_finite_1 x y = False"
   539 
   540 instance
   541 apply (intro_classes)
   542 apply (auto simp add: less_finite_1_def less_eq_finite_1_def)
   543 apply (metis finite_1.exhaust)
   544 done
   545 
   546 end
   547 
   548 hide_const (open) a\<^isub>1
   549 
   550 datatype finite_2 = a\<^isub>1 | a\<^isub>2
   551 
   552 notation (output) a\<^isub>1  ("a\<^isub>1")
   553 notation (output) a\<^isub>2  ("a\<^isub>2")
   554 
   555 instantiation finite_2 :: enum
   556 begin
   557 
   558 definition
   559   "enum = [a\<^isub>1, a\<^isub>2]"
   560 
   561 definition
   562   "enum_all P = (P a\<^isub>1 \<and> P a\<^isub>2)"
   563 
   564 definition
   565   "enum_ex P = (P a\<^isub>1 \<or> P a\<^isub>2)"
   566 
   567 instance proof
   568   fix P
   569   show "enum_all (P :: finite_2 \<Rightarrow> bool) = (\<forall>x. P x)"
   570     unfolding enum_all_finite_2_def
   571     by (auto, case_tac x) auto
   572 next
   573   fix P
   574   show "enum_ex (P :: finite_2 \<Rightarrow> bool) = (\<exists>x. P x)"
   575     unfolding enum_ex_finite_2_def
   576     by (auto, case_tac x) auto
   577 qed (auto simp add: enum_finite_2_def intro: finite_2.exhaust)
   578 
   579 end
   580 
   581 instantiation finite_2 :: linorder
   582 begin
   583 
   584 definition less_finite_2 :: "finite_2 \<Rightarrow> finite_2 \<Rightarrow> bool"
   585 where
   586   "less_finite_2 x y = ((x = a\<^isub>1) & (y = a\<^isub>2))"
   587 
   588 definition less_eq_finite_2 :: "finite_2 \<Rightarrow> finite_2 \<Rightarrow> bool"
   589 where
   590   "less_eq_finite_2 x y = ((x = y) \<or> (x < y))"
   591 
   592 
   593 instance
   594 apply (intro_classes)
   595 apply (auto simp add: less_finite_2_def less_eq_finite_2_def)
   596 apply (metis finite_2.distinct finite_2.nchotomy)+
   597 done
   598 
   599 end
   600 
   601 hide_const (open) a\<^isub>1 a\<^isub>2
   602 
   603 
   604 datatype finite_3 = a\<^isub>1 | a\<^isub>2 | a\<^isub>3
   605 
   606 notation (output) a\<^isub>1  ("a\<^isub>1")
   607 notation (output) a\<^isub>2  ("a\<^isub>2")
   608 notation (output) a\<^isub>3  ("a\<^isub>3")
   609 
   610 instantiation finite_3 :: enum
   611 begin
   612 
   613 definition
   614   "enum = [a\<^isub>1, a\<^isub>2, a\<^isub>3]"
   615 
   616 definition
   617   "enum_all P = (P a\<^isub>1 \<and> P a\<^isub>2 \<and> P a\<^isub>3)"
   618 
   619 definition
   620   "enum_ex P = (P a\<^isub>1 \<or> P a\<^isub>2 \<or> P a\<^isub>3)"
   621 
   622 instance proof
   623   fix P
   624   show "enum_all (P :: finite_3 \<Rightarrow> bool) = (\<forall>x. P x)"
   625     unfolding enum_all_finite_3_def
   626     by (auto, case_tac x) auto
   627 next
   628   fix P
   629   show "enum_ex (P :: finite_3 \<Rightarrow> bool) = (\<exists>x. P x)"
   630     unfolding enum_ex_finite_3_def
   631     by (auto, case_tac x) auto
   632 qed (auto simp add: enum_finite_3_def intro: finite_3.exhaust)
   633 
   634 end
   635 
   636 instantiation finite_3 :: linorder
   637 begin
   638 
   639 definition less_finite_3 :: "finite_3 \<Rightarrow> finite_3 \<Rightarrow> bool"
   640 where
   641   "less_finite_3 x y = (case x of a\<^isub>1 => (y \<noteq> a\<^isub>1)
   642      | a\<^isub>2 => (y = a\<^isub>3)| a\<^isub>3 => False)"
   643 
   644 definition less_eq_finite_3 :: "finite_3 \<Rightarrow> finite_3 \<Rightarrow> bool"
   645 where
   646   "less_eq_finite_3 x y = ((x = y) \<or> (x < y))"
   647 
   648 
   649 instance proof (intro_classes)
   650 qed (auto simp add: less_finite_3_def less_eq_finite_3_def split: finite_3.split_asm)
   651 
   652 end
   653 
   654 hide_const (open) a\<^isub>1 a\<^isub>2 a\<^isub>3
   655 
   656 
   657 datatype finite_4 = a\<^isub>1 | a\<^isub>2 | a\<^isub>3 | a\<^isub>4
   658 
   659 notation (output) a\<^isub>1  ("a\<^isub>1")
   660 notation (output) a\<^isub>2  ("a\<^isub>2")
   661 notation (output) a\<^isub>3  ("a\<^isub>3")
   662 notation (output) a\<^isub>4  ("a\<^isub>4")
   663 
   664 instantiation finite_4 :: enum
   665 begin
   666 
   667 definition
   668   "enum = [a\<^isub>1, a\<^isub>2, a\<^isub>3, a\<^isub>4]"
   669 
   670 definition
   671   "enum_all P = (P a\<^isub>1 \<and> P a\<^isub>2 \<and> P a\<^isub>3 \<and> P a\<^isub>4)"
   672 
   673 definition
   674   "enum_ex P = (P a\<^isub>1 \<or> P a\<^isub>2 \<or> P a\<^isub>3 \<or> P a\<^isub>4)"
   675 
   676 instance proof
   677   fix P
   678   show "enum_all (P :: finite_4 \<Rightarrow> bool) = (\<forall>x. P x)"
   679     unfolding enum_all_finite_4_def
   680     by (auto, case_tac x) auto
   681 next
   682   fix P
   683   show "enum_ex (P :: finite_4 \<Rightarrow> bool) = (\<exists>x. P x)"
   684     unfolding enum_ex_finite_4_def
   685     by (auto, case_tac x) auto
   686 qed (auto simp add: enum_finite_4_def intro: finite_4.exhaust)
   687 
   688 end
   689 
   690 hide_const (open) a\<^isub>1 a\<^isub>2 a\<^isub>3 a\<^isub>4
   691 
   692 
   693 datatype finite_5 = a\<^isub>1 | a\<^isub>2 | a\<^isub>3 | a\<^isub>4 | a\<^isub>5
   694 
   695 notation (output) a\<^isub>1  ("a\<^isub>1")
   696 notation (output) a\<^isub>2  ("a\<^isub>2")
   697 notation (output) a\<^isub>3  ("a\<^isub>3")
   698 notation (output) a\<^isub>4  ("a\<^isub>4")
   699 notation (output) a\<^isub>5  ("a\<^isub>5")
   700 
   701 instantiation finite_5 :: enum
   702 begin
   703 
   704 definition
   705   "enum = [a\<^isub>1, a\<^isub>2, a\<^isub>3, a\<^isub>4, a\<^isub>5]"
   706 
   707 definition
   708   "enum_all P = (P a\<^isub>1 \<and> P a\<^isub>2 \<and> P a\<^isub>3 \<and> P a\<^isub>4 \<and> P a\<^isub>5)"
   709 
   710 definition
   711   "enum_ex P = (P a\<^isub>1 \<or> P a\<^isub>2 \<or> P a\<^isub>3 \<or> P a\<^isub>4 \<or> P a\<^isub>5)"
   712 
   713 instance proof
   714   fix P
   715   show "enum_all (P :: finite_5 \<Rightarrow> bool) = (\<forall>x. P x)"
   716     unfolding enum_all_finite_5_def
   717     by (auto, case_tac x) auto
   718 next
   719   fix P
   720   show "enum_ex (P :: finite_5 \<Rightarrow> bool) = (\<exists>x. P x)"
   721     unfolding enum_ex_finite_5_def
   722     by (auto, case_tac x) auto
   723 qed (auto simp add: enum_finite_5_def intro: finite_5.exhaust)
   724 
   725 end
   726 
   727 subsection {* An executable THE operator on finite types *}
   728 
   729 definition
   730   [code del]: "enum_the P = The P"
   731 
   732 lemma [code]:
   733   "The P = (case filter P enum of [x] => x | _ => enum_the P)"
   734 proof -
   735   {
   736     fix a
   737     assume filter_enum: "filter P enum = [a]"
   738     have "The P = a"
   739     proof (rule the_equality)
   740       fix x
   741       assume "P x"
   742       show "x = a"
   743       proof (rule ccontr)
   744         assume "x \<noteq> a"
   745         from filter_enum obtain us vs
   746           where enum_eq: "enum = us @ [a] @ vs"
   747           and "\<forall> x \<in> set us. \<not> P x"
   748           and "\<forall> x \<in> set vs. \<not> P x"
   749           and "P a"
   750           by (auto simp add: filter_eq_Cons_iff) (simp only: filter_empty_conv[symmetric])
   751         with `P x` in_enum[of x, unfolded enum_eq] `x \<noteq> a` show "False" by auto
   752       qed
   753     next
   754       from filter_enum show "P a" by (auto simp add: filter_eq_Cons_iff)
   755     qed
   756   }
   757   from this show ?thesis
   758     unfolding enum_the_def by (auto split: list.split)
   759 qed
   760 
   761 code_abort enum_the
   762 
   763 hide_const (open) a\<^isub>1 a\<^isub>2 a\<^isub>3 a\<^isub>4 a\<^isub>5
   764 
   765 
   766 hide_type (open) finite_1 finite_2 finite_3 finite_4 finite_5
   767 hide_const (open) enum enum_all enum_ex n_lists all_n_lists ex_n_lists product
   768 
   769 end