src/HOL/Fun.thy
 author wenzelm Fri Dec 17 17:43:54 2010 +0100 (2010-12-17) changeset 41229 d797baa3d57c parent 40969 fb2d3ccda5a7 child 41505 6d19301074cf permissions -rw-r--r--
replaced command 'nonterminals' by slightly modernized version 'nonterminal';
```     1 (*  Title:      HOL/Fun.thy
```
```     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
```
```     3     Copyright   1994  University of Cambridge
```
```     4 *)
```
```     5
```
```     6 header {* Notions about functions *}
```
```     7
```
```     8 theory Fun
```
```     9 imports Complete_Lattice
```
```    10 uses ("Tools/type_lifting.ML")
```
```    11 begin
```
```    12
```
```    13 text{*As a simplification rule, it replaces all function equalities by
```
```    14   first-order equalities.*}
```
```    15 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
```
```    16 apply (rule iffI)
```
```    17 apply (simp (no_asm_simp))
```
```    18 apply (rule ext)
```
```    19 apply (simp (no_asm_simp))
```
```    20 done
```
```    21
```
```    22 lemma apply_inverse:
```
```    23   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
```
```    24   by auto
```
```    25
```
```    26
```
```    27 subsection {* The Identity Function @{text id} *}
```
```    28
```
```    29 definition
```
```    30   id :: "'a \<Rightarrow> 'a"
```
```    31 where
```
```    32   "id = (\<lambda>x. x)"
```
```    33
```
```    34 lemma id_apply [simp]: "id x = x"
```
```    35   by (simp add: id_def)
```
```    36
```
```    37 lemma image_ident [simp]: "(%x. x) ` Y = Y"
```
```    38 by blast
```
```    39
```
```    40 lemma image_id [simp]: "id ` Y = Y"
```
```    41 by (simp add: id_def)
```
```    42
```
```    43 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
```
```    44 by blast
```
```    45
```
```    46 lemma vimage_id [simp]: "id -` A = A"
```
```    47 by (simp add: id_def)
```
```    48
```
```    49
```
```    50 subsection {* The Composition Operator @{text "f \<circ> g"} *}
```
```    51
```
```    52 definition
```
```    53   comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55)
```
```    54 where
```
```    55   "f o g = (\<lambda>x. f (g x))"
```
```    56
```
```    57 notation (xsymbols)
```
```    58   comp  (infixl "\<circ>" 55)
```
```    59
```
```    60 notation (HTML output)
```
```    61   comp  (infixl "\<circ>" 55)
```
```    62
```
```    63 text{*compatibility*}
```
```    64 lemmas o_def = comp_def
```
```    65
```
```    66 lemma o_apply [simp]: "(f o g) x = f (g x)"
```
```    67 by (simp add: comp_def)
```
```    68
```
```    69 lemma o_assoc: "f o (g o h) = f o g o h"
```
```    70 by (simp add: comp_def)
```
```    71
```
```    72 lemma id_o [simp]: "id o g = g"
```
```    73 by (simp add: comp_def)
```
```    74
```
```    75 lemma o_id [simp]: "f o id = f"
```
```    76 by (simp add: comp_def)
```
```    77
```
```    78 lemma o_eq_dest:
```
```    79   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
```
```    80   by (simp only: o_def) (fact fun_cong)
```
```    81
```
```    82 lemma o_eq_elim:
```
```    83   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
```
```    84   by (erule meta_mp) (fact o_eq_dest)
```
```    85
```
```    86 lemma image_compose: "(f o g) ` r = f`(g`r)"
```
```    87 by (simp add: comp_def, blast)
```
```    88
```
```    89 lemma vimage_compose: "(g \<circ> f) -` x = f -` (g -` x)"
```
```    90   by auto
```
```    91
```
```    92 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
```
```    93 by (unfold comp_def, blast)
```
```    94
```
```    95
```
```    96 subsection {* The Forward Composition Operator @{text fcomp} *}
```
```    97
```
```    98 definition
```
```    99   fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60)
```
```   100 where
```
```   101   "f \<circ>> g = (\<lambda>x. g (f x))"
```
```   102
```
```   103 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
```
```   104   by (simp add: fcomp_def)
```
```   105
```
```   106 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
```
```   107   by (simp add: fcomp_def)
```
```   108
```
```   109 lemma id_fcomp [simp]: "id \<circ>> g = g"
```
```   110   by (simp add: fcomp_def)
```
```   111
```
```   112 lemma fcomp_id [simp]: "f \<circ>> id = f"
```
```   113   by (simp add: fcomp_def)
```
```   114
```
```   115 code_const fcomp
```
```   116   (Eval infixl 1 "#>")
```
```   117
```
```   118 no_notation fcomp (infixl "\<circ>>" 60)
```
```   119
```
```   120
```
```   121 subsection {* Mapping functions *}
```
```   122
```
```   123 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
```
```   124   "map_fun f g h = g \<circ> h \<circ> f"
```
```   125
```
```   126 lemma map_fun_apply [simp]:
```
```   127   "map_fun f g h x = g (h (f x))"
```
```   128   by (simp add: map_fun_def)
```
```   129
```
```   130
```
```   131 subsection {* Injectivity and Bijectivity *}
```
```   132
```
```   133 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
```
```   134   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
```
```   135
```
```   136 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
```
```   137   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
```
```   138
```
```   139 text{*A common special case: functions injective, surjective or bijective over
```
```   140 the entire domain type.*}
```
```   141
```
```   142 abbreviation
```
```   143   "inj f \<equiv> inj_on f UNIV"
```
```   144
```
```   145 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
```
```   146   "surj f \<equiv> (range f = UNIV)"
```
```   147
```
```   148 abbreviation
```
```   149   "bij f \<equiv> bij_betw f UNIV UNIV"
```
```   150
```
```   151 lemma injI:
```
```   152   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
```
```   153   shows "inj f"
```
```   154   using assms unfolding inj_on_def by auto
```
```   155
```
```   156 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
```
```   157   by (unfold inj_on_def, blast)
```
```   158
```
```   159 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
```
```   160 by (simp add: inj_on_def)
```
```   161
```
```   162 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
```
```   163 by (force simp add: inj_on_def)
```
```   164
```
```   165 lemma inj_on_cong:
```
```   166   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
```
```   167 unfolding inj_on_def by auto
```
```   168
```
```   169 lemma inj_on_strict_subset:
```
```   170   "\<lbrakk> inj_on f B; A < B \<rbrakk> \<Longrightarrow> f`A < f`B"
```
```   171 unfolding inj_on_def unfolding image_def by blast
```
```   172
```
```   173 lemma inj_comp:
```
```   174   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
```
```   175   by (simp add: inj_on_def)
```
```   176
```
```   177 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
```
```   178   by (simp add: inj_on_def fun_eq_iff)
```
```   179
```
```   180 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
```
```   181 by (simp add: inj_on_eq_iff)
```
```   182
```
```   183 lemma inj_on_id[simp]: "inj_on id A"
```
```   184   by (simp add: inj_on_def)
```
```   185
```
```   186 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
```
```   187 by (simp add: inj_on_def)
```
```   188
```
```   189 lemma inj_on_Int: "\<lbrakk>inj_on f A; inj_on f B\<rbrakk> \<Longrightarrow> inj_on f (A \<inter> B)"
```
```   190 unfolding inj_on_def by blast
```
```   191
```
```   192 lemma inj_on_INTER:
```
```   193   "\<lbrakk>I \<noteq> {}; \<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)\<rbrakk> \<Longrightarrow> inj_on f (\<Inter> i \<in> I. A i)"
```
```   194 unfolding inj_on_def by blast
```
```   195
```
```   196 lemma inj_on_Inter:
```
```   197   "\<lbrakk>S \<noteq> {}; \<And> A. A \<in> S \<Longrightarrow> inj_on f A\<rbrakk> \<Longrightarrow> inj_on f (Inter S)"
```
```   198 unfolding inj_on_def by blast
```
```   199
```
```   200 lemma inj_on_UNION_chain:
```
```   201   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
```
```   202          INJ: "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
```
```   203   shows "inj_on f (\<Union> i \<in> I. A i)"
```
```   204 proof(unfold inj_on_def UNION_def, auto)
```
```   205   fix i j x y
```
```   206   assume *: "i \<in> I" "j \<in> I" and **: "x \<in> A i" "y \<in> A j"
```
```   207          and ***: "f x = f y"
```
```   208   show "x = y"
```
```   209   proof-
```
```   210     {assume "A i \<le> A j"
```
```   211      with ** have "x \<in> A j" by auto
```
```   212      with INJ * ** *** have ?thesis
```
```   213      by(auto simp add: inj_on_def)
```
```   214     }
```
```   215     moreover
```
```   216     {assume "A j \<le> A i"
```
```   217      with ** have "y \<in> A i" by auto
```
```   218      with INJ * ** *** have ?thesis
```
```   219      by(auto simp add: inj_on_def)
```
```   220     }
```
```   221     ultimately show ?thesis using  CH * by blast
```
```   222   qed
```
```   223 qed
```
```   224
```
```   225 lemma surj_id: "surj id"
```
```   226 by simp
```
```   227
```
```   228 lemma bij_id[simp]: "bij id"
```
```   229 by (simp add: bij_betw_def)
```
```   230
```
```   231 lemma inj_onI:
```
```   232     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
```
```   233 by (simp add: inj_on_def)
```
```   234
```
```   235 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
```
```   236 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
```
```   237
```
```   238 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
```
```   239 by (unfold inj_on_def, blast)
```
```   240
```
```   241 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
```
```   242 by (blast dest!: inj_onD)
```
```   243
```
```   244 lemma comp_inj_on:
```
```   245      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
```
```   246 by (simp add: comp_def inj_on_def)
```
```   247
```
```   248 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
```
```   249 apply(simp add:inj_on_def image_def)
```
```   250 apply blast
```
```   251 done
```
```   252
```
```   253 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
```
```   254   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
```
```   255 apply(unfold inj_on_def)
```
```   256 apply blast
```
```   257 done
```
```   258
```
```   259 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
```
```   260 by (unfold inj_on_def, blast)
```
```   261
```
```   262 lemma inj_singleton: "inj (%s. {s})"
```
```   263 by (simp add: inj_on_def)
```
```   264
```
```   265 lemma inj_on_empty[iff]: "inj_on f {}"
```
```   266 by(simp add: inj_on_def)
```
```   267
```
```   268 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
```
```   269 by (unfold inj_on_def, blast)
```
```   270
```
```   271 lemma inj_on_Un:
```
```   272  "inj_on f (A Un B) =
```
```   273   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
```
```   274 apply(unfold inj_on_def)
```
```   275 apply (blast intro:sym)
```
```   276 done
```
```   277
```
```   278 lemma inj_on_insert[iff]:
```
```   279   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
```
```   280 apply(unfold inj_on_def)
```
```   281 apply (blast intro:sym)
```
```   282 done
```
```   283
```
```   284 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
```
```   285 apply(unfold inj_on_def)
```
```   286 apply (blast)
```
```   287 done
```
```   288
```
```   289 lemma comp_inj_on_iff:
```
```   290   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
```
```   291 by(auto simp add: comp_inj_on inj_on_def)
```
```   292
```
```   293 lemma inj_on_imageI2:
```
```   294   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
```
```   295 by(auto simp add: comp_inj_on inj_on_def)
```
```   296
```
```   297 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
```
```   298   by auto
```
```   299
```
```   300 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
```
```   301   using *[symmetric] by auto
```
```   302
```
```   303 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
```
```   304   by (simp add: surj_def)
```
```   305
```
```   306 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
```
```   307   by (simp add: surj_def, blast)
```
```   308
```
```   309 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
```
```   310 apply (simp add: comp_def surj_def, clarify)
```
```   311 apply (drule_tac x = y in spec, clarify)
```
```   312 apply (drule_tac x = x in spec, blast)
```
```   313 done
```
```   314
```
```   315 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
```
```   316   unfolding bij_betw_def by auto
```
```   317
```
```   318 lemma bij_betw_empty1:
```
```   319   assumes "bij_betw f {} A"
```
```   320   shows "A = {}"
```
```   321 using assms unfolding bij_betw_def by blast
```
```   322
```
```   323 lemma bij_betw_empty2:
```
```   324   assumes "bij_betw f A {}"
```
```   325   shows "A = {}"
```
```   326 using assms unfolding bij_betw_def by blast
```
```   327
```
```   328 lemma inj_on_imp_bij_betw:
```
```   329   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
```
```   330 unfolding bij_betw_def by simp
```
```   331
```
```   332 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
```
```   333   unfolding bij_betw_def ..
```
```   334
```
```   335 lemma bijI: "[| inj f; surj f |] ==> bij f"
```
```   336 by (simp add: bij_def)
```
```   337
```
```   338 lemma bij_is_inj: "bij f ==> inj f"
```
```   339 by (simp add: bij_def)
```
```   340
```
```   341 lemma bij_is_surj: "bij f ==> surj f"
```
```   342 by (simp add: bij_def)
```
```   343
```
```   344 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
```
```   345 by (simp add: bij_betw_def)
```
```   346
```
```   347 lemma bij_betw_trans:
```
```   348   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
```
```   349 by(auto simp add:bij_betw_def comp_inj_on)
```
```   350
```
```   351 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
```
```   352   by (rule bij_betw_trans)
```
```   353
```
```   354 lemma bij_betw_comp_iff:
```
```   355   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
```
```   356 by(auto simp add: bij_betw_def inj_on_def)
```
```   357
```
```   358 lemma bij_betw_comp_iff2:
```
```   359   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
```
```   360   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
```
```   361 using assms
```
```   362 proof(auto simp add: bij_betw_comp_iff)
```
```   363   assume *: "bij_betw (f' \<circ> f) A A''"
```
```   364   thus "bij_betw f A A'"
```
```   365   using IM
```
```   366   proof(auto simp add: bij_betw_def)
```
```   367     assume "inj_on (f' \<circ> f) A"
```
```   368     thus "inj_on f A" using inj_on_imageI2 by blast
```
```   369   next
```
```   370     fix a' assume **: "a' \<in> A'"
```
```   371     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
```
```   372     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
```
```   373     unfolding bij_betw_def by force
```
```   374     hence "f a \<in> A'" using IM by auto
```
```   375     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
```
```   376     thus "a' \<in> f ` A" using 1 by auto
```
```   377   qed
```
```   378 qed
```
```   379
```
```   380 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
```
```   381 proof -
```
```   382   have i: "inj_on f A" and s: "f ` A = B"
```
```   383     using assms by(auto simp:bij_betw_def)
```
```   384   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
```
```   385   { fix a b assume P: "?P b a"
```
```   386     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
```
```   387     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
```
```   388     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
```
```   389   } note g = this
```
```   390   have "inj_on ?g B"
```
```   391   proof(rule inj_onI)
```
```   392     fix x y assume "x:B" "y:B" "?g x = ?g y"
```
```   393     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
```
```   394     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
```
```   395     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
```
```   396   qed
```
```   397   moreover have "?g ` B = A"
```
```   398   proof(auto simp:image_def)
```
```   399     fix b assume "b:B"
```
```   400     with s obtain a where P: "?P b a" unfolding image_def by blast
```
```   401     thus "?g b \<in> A" using g[OF P] by auto
```
```   402   next
```
```   403     fix a assume "a:A"
```
```   404     then obtain b where P: "?P b a" using s unfolding image_def by blast
```
```   405     then have "b:B" using s unfolding image_def by blast
```
```   406     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
```
```   407   qed
```
```   408   ultimately show ?thesis by(auto simp:bij_betw_def)
```
```   409 qed
```
```   410
```
```   411 lemma bij_betw_cong:
```
```   412   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
```
```   413 unfolding bij_betw_def inj_on_def by force
```
```   414
```
```   415 lemma bij_betw_id[intro, simp]:
```
```   416   "bij_betw id A A"
```
```   417 unfolding bij_betw_def id_def by auto
```
```   418
```
```   419 lemma bij_betw_id_iff:
```
```   420   "bij_betw id A B \<longleftrightarrow> A = B"
```
```   421 by(auto simp add: bij_betw_def)
```
```   422
```
```   423 lemma bij_betw_combine:
```
```   424   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
```
```   425   shows "bij_betw f (A \<union> C) (B \<union> D)"
```
```   426   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
```
```   427
```
```   428 lemma bij_betw_UNION_chain:
```
```   429   assumes CH: "\<And> i j. \<lbrakk>i \<in> I; j \<in> I\<rbrakk> \<Longrightarrow> A i \<le> A j \<or> A j \<le> A i" and
```
```   430          BIJ: "\<And> i. i \<in> I \<Longrightarrow> bij_betw f (A i) (A' i)"
```
```   431   shows "bij_betw f (\<Union> i \<in> I. A i) (\<Union> i \<in> I. A' i)"
```
```   432 proof(unfold bij_betw_def, auto simp add: image_def)
```
```   433   have "\<And> i. i \<in> I \<Longrightarrow> inj_on f (A i)"
```
```   434   using BIJ bij_betw_def[of f] by auto
```
```   435   thus "inj_on f (\<Union> i \<in> I. A i)"
```
```   436   using CH inj_on_UNION_chain[of I A f] by auto
```
```   437 next
```
```   438   fix i x
```
```   439   assume *: "i \<in> I" "x \<in> A i"
```
```   440   hence "f x \<in> A' i" using BIJ bij_betw_def[of f] by auto
```
```   441   thus "\<exists>j \<in> I. f x \<in> A' j" using * by blast
```
```   442 next
```
```   443   fix i x'
```
```   444   assume *: "i \<in> I" "x' \<in> A' i"
```
```   445   hence "\<exists>x \<in> A i. x' = f x" using BIJ bij_betw_def[of f] by blast
```
```   446   thus "\<exists>j \<in> I. \<exists>x \<in> A j. x' = f x"
```
```   447   using * by blast
```
```   448 qed
```
```   449
```
```   450 lemma bij_betw_Disj_Un:
```
```   451   assumes DISJ: "A \<inter> B = {}" and DISJ': "A' \<inter> B' = {}" and
```
```   452           B1: "bij_betw f A A'" and B2: "bij_betw f B B'"
```
```   453   shows "bij_betw f (A \<union> B) (A' \<union> B')"
```
```   454 proof-
```
```   455   have 1: "inj_on f A \<and> inj_on f B"
```
```   456   using B1 B2 by (auto simp add: bij_betw_def)
```
```   457   have 2: "f`A = A' \<and> f`B = B'"
```
```   458   using B1 B2 by (auto simp add: bij_betw_def)
```
```   459   hence "f`(A - B) \<inter> f`(B - A) = {}"
```
```   460   using DISJ DISJ' by blast
```
```   461   hence "inj_on f (A \<union> B)"
```
```   462   using 1 by (auto simp add: inj_on_Un)
```
```   463   (*  *)
```
```   464   moreover
```
```   465   have "f`(A \<union> B) = A' \<union> B'"
```
```   466   using 2 by auto
```
```   467   ultimately show ?thesis
```
```   468   unfolding bij_betw_def by auto
```
```   469 qed
```
```   470
```
```   471 lemma bij_betw_subset:
```
```   472   assumes BIJ: "bij_betw f A A'" and
```
```   473           SUB: "B \<le> A" and IM: "f ` B = B'"
```
```   474   shows "bij_betw f B B'"
```
```   475 using assms
```
```   476 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
```
```   477
```
```   478 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
```
```   479 by simp
```
```   480
```
```   481 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
```
```   482 by (simp add: inj_on_def, blast)
```
```   483
```
```   484 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
```
```   485 by (blast intro: sym)
```
```   486
```
```   487 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
```
```   488 by (unfold inj_on_def, blast)
```
```   489
```
```   490 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
```
```   491 apply (unfold bij_def)
```
```   492 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
```
```   493 done
```
```   494
```
```   495 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
```
```   496 by(blast dest: inj_onD)
```
```   497
```
```   498 lemma inj_on_image_Int:
```
```   499    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
```
```   500 apply (simp add: inj_on_def, blast)
```
```   501 done
```
```   502
```
```   503 lemma inj_on_image_set_diff:
```
```   504    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
```
```   505 apply (simp add: inj_on_def, blast)
```
```   506 done
```
```   507
```
```   508 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
```
```   509 by (simp add: inj_on_def, blast)
```
```   510
```
```   511 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
```
```   512 by (simp add: inj_on_def, blast)
```
```   513
```
```   514 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
```
```   515 by (blast dest: injD)
```
```   516
```
```   517 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
```
```   518 by (simp add: inj_on_def, blast)
```
```   519
```
```   520 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
```
```   521 by (blast dest: injD)
```
```   522
```
```   523 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
```
```   524 lemma image_INT:
```
```   525    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
```
```   526     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
```
```   527 apply (simp add: inj_on_def, blast)
```
```   528 done
```
```   529
```
```   530 (*Compare with image_INT: no use of inj_on, and if f is surjective then
```
```   531   it doesn't matter whether A is empty*)
```
```   532 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
```
```   533 apply (simp add: bij_def)
```
```   534 apply (simp add: inj_on_def surj_def, blast)
```
```   535 done
```
```   536
```
```   537 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
```
```   538 by auto
```
```   539
```
```   540 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
```
```   541 by (auto simp add: inj_on_def)
```
```   542
```
```   543 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
```
```   544 apply (simp add: bij_def)
```
```   545 apply (rule equalityI)
```
```   546 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
```
```   547 done
```
```   548
```
```   549 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
```
```   550   by (auto intro!: inj_onI)
```
```   551
```
```   552 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
```
```   553   by (auto intro!: inj_onI dest: strict_mono_eq)
```
```   554
```
```   555 subsection{*Function Updating*}
```
```   556
```
```   557 definition
```
```   558   fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
```
```   559   "fun_upd f a b == % x. if x=a then b else f x"
```
```   560
```
```   561 nonterminal updbinds and updbind
```
```   562
```
```   563 syntax
```
```   564   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
```
```   565   ""         :: "updbind => updbinds"             ("_")
```
```   566   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
```
```   567   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
```
```   568
```
```   569 translations
```
```   570   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
```
```   571   "f(x:=y)" == "CONST fun_upd f x y"
```
```   572
```
```   573 (* Hint: to define the sum of two functions (or maps), use sum_case.
```
```   574          A nice infix syntax could be defined (in Datatype.thy or below) by
```
```   575 notation
```
```   576   sum_case  (infixr "'(+')"80)
```
```   577 *)
```
```   578
```
```   579 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
```
```   580 apply (simp add: fun_upd_def, safe)
```
```   581 apply (erule subst)
```
```   582 apply (rule_tac [2] ext, auto)
```
```   583 done
```
```   584
```
```   585 (* f x = y ==> f(x:=y) = f *)
```
```   586 lemmas fun_upd_idem = fun_upd_idem_iff [THEN iffD2, standard]
```
```   587
```
```   588 (* f(x := f x) = f *)
```
```   589 lemmas fun_upd_triv = refl [THEN fun_upd_idem]
```
```   590 declare fun_upd_triv [iff]
```
```   591
```
```   592 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
```
```   593 by (simp add: fun_upd_def)
```
```   594
```
```   595 (* fun_upd_apply supersedes these two,   but they are useful
```
```   596    if fun_upd_apply is intentionally removed from the simpset *)
```
```   597 lemma fun_upd_same: "(f(x:=y)) x = y"
```
```   598 by simp
```
```   599
```
```   600 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
```
```   601 by simp
```
```   602
```
```   603 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
```
```   604 by (simp add: fun_eq_iff)
```
```   605
```
```   606 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
```
```   607 by (rule ext, auto)
```
```   608
```
```   609 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
```
```   610 by (fastsimp simp:inj_on_def image_def)
```
```   611
```
```   612 lemma fun_upd_image:
```
```   613      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
```
```   614 by auto
```
```   615
```
```   616 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
```
```   617 by (auto intro: ext)
```
```   618
```
```   619
```
```   620 subsection {* @{text override_on} *}
```
```   621
```
```   622 definition
```
```   623   override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
```
```   624 where
```
```   625   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
```
```   626
```
```   627 lemma override_on_emptyset[simp]: "override_on f g {} = f"
```
```   628 by(simp add:override_on_def)
```
```   629
```
```   630 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
```
```   631 by(simp add:override_on_def)
```
```   632
```
```   633 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
```
```   634 by(simp add:override_on_def)
```
```   635
```
```   636
```
```   637 subsection {* @{text swap} *}
```
```   638
```
```   639 definition
```
```   640   swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
```
```   641 where
```
```   642   "swap a b f = f (a := f b, b:= f a)"
```
```   643
```
```   644 lemma swap_self [simp]: "swap a a f = f"
```
```   645 by (simp add: swap_def)
```
```   646
```
```   647 lemma swap_commute: "swap a b f = swap b a f"
```
```   648 by (rule ext, simp add: fun_upd_def swap_def)
```
```   649
```
```   650 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
```
```   651 by (rule ext, simp add: fun_upd_def swap_def)
```
```   652
```
```   653 lemma swap_triple:
```
```   654   assumes "a \<noteq> c" and "b \<noteq> c"
```
```   655   shows "swap a b (swap b c (swap a b f)) = swap a c f"
```
```   656   using assms by (simp add: fun_eq_iff swap_def)
```
```   657
```
```   658 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
```
```   659 by (rule ext, simp add: fun_upd_def swap_def)
```
```   660
```
```   661 lemma swap_image_eq [simp]:
```
```   662   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
```
```   663 proof -
```
```   664   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
```
```   665     using assms by (auto simp: image_iff swap_def)
```
```   666   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
```
```   667   with subset[of f] show ?thesis by auto
```
```   668 qed
```
```   669
```
```   670 lemma inj_on_imp_inj_on_swap:
```
```   671   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
```
```   672   by (simp add: inj_on_def swap_def, blast)
```
```   673
```
```   674 lemma inj_on_swap_iff [simp]:
```
```   675   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
```
```   676 proof
```
```   677   assume "inj_on (swap a b f) A"
```
```   678   with A have "inj_on (swap a b (swap a b f)) A"
```
```   679     by (iprover intro: inj_on_imp_inj_on_swap)
```
```   680   thus "inj_on f A" by simp
```
```   681 next
```
```   682   assume "inj_on f A"
```
```   683   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
```
```   684 qed
```
```   685
```
```   686 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
```
```   687   by simp
```
```   688
```
```   689 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
```
```   690   by simp
```
```   691
```
```   692 lemma bij_betw_swap_iff [simp]:
```
```   693   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
```
```   694   by (auto simp: bij_betw_def)
```
```   695
```
```   696 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
```
```   697   by simp
```
```   698
```
```   699 hide_const (open) swap
```
```   700
```
```   701 subsection {* Inversion of injective functions *}
```
```   702
```
```   703 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
```
```   704 "the_inv_into A f == %x. THE y. y : A & f y = x"
```
```   705
```
```   706 lemma the_inv_into_f_f:
```
```   707   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
```
```   708 apply (simp add: the_inv_into_def inj_on_def)
```
```   709 apply blast
```
```   710 done
```
```   711
```
```   712 lemma f_the_inv_into_f:
```
```   713   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
```
```   714 apply (simp add: the_inv_into_def)
```
```   715 apply (rule the1I2)
```
```   716  apply(blast dest: inj_onD)
```
```   717 apply blast
```
```   718 done
```
```   719
```
```   720 lemma the_inv_into_into:
```
```   721   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
```
```   722 apply (simp add: the_inv_into_def)
```
```   723 apply (rule the1I2)
```
```   724  apply(blast dest: inj_onD)
```
```   725 apply blast
```
```   726 done
```
```   727
```
```   728 lemma the_inv_into_onto[simp]:
```
```   729   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
```
```   730 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
```
```   731
```
```   732 lemma the_inv_into_f_eq:
```
```   733   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
```
```   734   apply (erule subst)
```
```   735   apply (erule the_inv_into_f_f, assumption)
```
```   736   done
```
```   737
```
```   738 lemma the_inv_into_comp:
```
```   739   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
```
```   740   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
```
```   741 apply (rule the_inv_into_f_eq)
```
```   742   apply (fast intro: comp_inj_on)
```
```   743  apply (simp add: f_the_inv_into_f the_inv_into_into)
```
```   744 apply (simp add: the_inv_into_into)
```
```   745 done
```
```   746
```
```   747 lemma inj_on_the_inv_into:
```
```   748   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
```
```   749 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
```
```   750
```
```   751 lemma bij_betw_the_inv_into:
```
```   752   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
```
```   753 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
```
```   754
```
```   755 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
```
```   756   "the_inv f \<equiv> the_inv_into UNIV f"
```
```   757
```
```   758 lemma the_inv_f_f:
```
```   759   assumes "inj f"
```
```   760   shows "the_inv f (f x) = x" using assms UNIV_I
```
```   761   by (rule the_inv_into_f_f)
```
```   762
```
```   763 subsection {* Cantor's Paradox *}
```
```   764
```
```   765 lemma Cantors_paradox:
```
```   766   "\<not>(\<exists>f. f ` A = Pow A)"
```
```   767 proof clarify
```
```   768   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
```
```   769   let ?X = "{a \<in> A. a \<notin> f a}"
```
```   770   have "?X \<in> Pow A" unfolding Pow_def by auto
```
```   771   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
```
```   772   thus False by best
```
```   773 qed
```
```   774
```
```   775 subsection {* Setup *}
```
```   776
```
```   777 subsubsection {* Proof tools *}
```
```   778
```
```   779 text {* simplifies terms of the form
```
```   780   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
```
```   781
```
```   782 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
```
```   783 let
```
```   784   fun gen_fun_upd NONE T _ _ = NONE
```
```   785     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) \$ f \$ x \$ y)
```
```   786   fun dest_fun_T1 (Type (_, T :: Ts)) = T
```
```   787   fun find_double (t as Const (@{const_name fun_upd},T) \$ f \$ x \$ y) =
```
```   788     let
```
```   789       fun find (Const (@{const_name fun_upd},T) \$ g \$ v \$ w) =
```
```   790             if v aconv x then SOME g else gen_fun_upd (find g) T v w
```
```   791         | find t = NONE
```
```   792     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
```
```   793
```
```   794   fun proc ss ct =
```
```   795     let
```
```   796       val ctxt = Simplifier.the_context ss
```
```   797       val t = Thm.term_of ct
```
```   798     in
```
```   799       case find_double t of
```
```   800         (T, NONE) => NONE
```
```   801       | (T, SOME rhs) =>
```
```   802           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
```
```   803             (fn _ =>
```
```   804               rtac eq_reflection 1 THEN
```
```   805               rtac ext 1 THEN
```
```   806               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
```
```   807     end
```
```   808 in proc end
```
```   809 *}
```
```   810
```
```   811
```
```   812 subsubsection {* Code generator *}
```
```   813
```
```   814 types_code
```
```   815   "fun"  ("(_ ->/ _)")
```
```   816 attach (term_of) {*
```
```   817 fun term_of_fun_type _ aT _ bT _ = Free ("<function>", aT --> bT);
```
```   818 *}
```
```   819 attach (test) {*
```
```   820 fun gen_fun_type aF aT bG bT i =
```
```   821   let
```
```   822     val tab = Unsynchronized.ref [];
```
```   823     fun mk_upd (x, (_, y)) t = Const ("Fun.fun_upd",
```
```   824       (aT --> bT) --> aT --> bT --> aT --> bT) \$ t \$ aF x \$ y ()
```
```   825   in
```
```   826     (fn x =>
```
```   827        case AList.lookup op = (!tab) x of
```
```   828          NONE =>
```
```   829            let val p as (y, _) = bG i
```
```   830            in (tab := (x, p) :: !tab; y) end
```
```   831        | SOME (y, _) => y,
```
```   832      fn () => Basics.fold mk_upd (!tab) (Const ("HOL.undefined", aT --> bT)))
```
```   833   end;
```
```   834 *}
```
```   835
```
```   836 code_const "op \<circ>"
```
```   837   (SML infixl 5 "o")
```
```   838   (Haskell infixr 9 ".")
```
```   839
```
```   840 code_const "id"
```
```   841   (Haskell "id")
```
```   842
```
```   843
```
```   844 subsubsection {* Functorial structure of types *}
```
```   845
```
```   846 use "Tools/type_lifting.ML"
```
```   847
```
```   848 end
```