src/HOL/Nat.thy
author wenzelm
Fri Dec 17 17:43:54 2010 +0100 (2010-12-17)
changeset 41229 d797baa3d57c
parent 39793 4bd217def154
child 43595 7ae4a23b5be6
permissions -rw-r--r--
replaced command 'nonterminals' by slightly modernized version 'nonterminal';
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 uses
    13   "~~/src/Tools/rat.ML"
    14   "~~/src/Provers/Arith/cancel_sums.ML"
    15   "Tools/arith_data.ML"
    16   ("Tools/nat_arith.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 subsection {* Type nat *}
    34 
    35 text {* Type definition *}
    36 
    37 inductive Nat :: "ind \<Rightarrow> bool"
    38 where
    39     Zero_RepI: "Nat Zero_Rep"
    40   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    41 
    42 typedef (open Nat) nat = Nat
    43   by (rule exI, unfold mem_def, rule Nat.Zero_RepI)
    44 
    45 definition Suc :: "nat => nat" where
    46   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    47 
    48 instantiation nat :: zero
    49 begin
    50 
    51 definition Zero_nat_def:
    52   "0 = Abs_Nat Zero_Rep"
    53 
    54 instance ..
    55 
    56 end
    57 
    58 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    59   by (simp add: Zero_nat_def Suc_def Abs_Nat_inject [unfolded mem_def]
    60     Rep_Nat [unfolded mem_def] Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def])
    61 
    62 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    63   by (rule not_sym, rule Suc_not_Zero not_sym)
    64 
    65 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    66   by (rule iffI, rule Suc_Rep_inject) simp_all
    67 
    68 rep_datatype "0 \<Colon> nat" Suc
    69   apply (unfold Zero_nat_def Suc_def)
    70      apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    71      apply (erule Rep_Nat [unfolded mem_def, THEN Nat.induct])
    72      apply (iprover elim: Abs_Nat_inverse [unfolded mem_def, THEN subst])
    73     apply (simp_all add: Abs_Nat_inject [unfolded mem_def] Rep_Nat [unfolded mem_def]
    74       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def]
    75       Suc_Rep_not_Zero_Rep [unfolded mem_def, symmetric]
    76       Suc_Rep_inject' Rep_Nat_inject)
    77   done
    78 
    79 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    80   -- {* for backward compatibility -- names of variables differ *}
    81   fixes n
    82   assumes "P 0"
    83     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    84   shows "P n"
    85   using assms by (rule nat.induct)
    86 
    87 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    88 
    89 lemmas nat_rec_0 = nat.recs(1)
    90   and nat_rec_Suc = nat.recs(2)
    91 
    92 lemmas nat_case_0 = nat.cases(1)
    93   and nat_case_Suc = nat.cases(2)
    94    
    95 
    96 text {* Injectiveness and distinctness lemmas *}
    97 
    98 lemma inj_Suc[simp]: "inj_on Suc N"
    99   by (simp add: inj_on_def)
   100 
   101 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   102 by (rule notE, rule Suc_not_Zero)
   103 
   104 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   105 by (rule Suc_neq_Zero, erule sym)
   106 
   107 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   108 by (rule inj_Suc [THEN injD])
   109 
   110 lemma n_not_Suc_n: "n \<noteq> Suc n"
   111 by (induct n) simp_all
   112 
   113 lemma Suc_n_not_n: "Suc n \<noteq> n"
   114 by (rule not_sym, rule n_not_Suc_n)
   115 
   116 text {* A special form of induction for reasoning
   117   about @{term "m < n"} and @{term "m - n"} *}
   118 
   119 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   120     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   121   apply (rule_tac x = m in spec)
   122   apply (induct n)
   123   prefer 2
   124   apply (rule allI)
   125   apply (induct_tac x, iprover+)
   126   done
   127 
   128 
   129 subsection {* Arithmetic operators *}
   130 
   131 instantiation nat :: "{minus, comm_monoid_add}"
   132 begin
   133 
   134 primrec plus_nat
   135 where
   136   add_0:      "0 + n = (n\<Colon>nat)"
   137   | add_Suc:  "Suc m + n = Suc (m + n)"
   138 
   139 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   140   by (induct m) simp_all
   141 
   142 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   143   by (induct m) simp_all
   144 
   145 declare add_0 [code]
   146 
   147 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   148   by simp
   149 
   150 primrec minus_nat
   151 where
   152   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   153 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   154 
   155 declare diff_Suc [simp del]
   156 
   157 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   158   by (induct n) (simp_all add: diff_Suc)
   159 
   160 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   161   by (induct n) (simp_all add: diff_Suc)
   162 
   163 instance proof
   164   fix n m q :: nat
   165   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   166   show "n + m = m + n" by (induct n) simp_all
   167   show "0 + n = n" by simp
   168 qed
   169 
   170 end
   171 
   172 hide_fact (open) add_0 add_0_right diff_0
   173 
   174 instantiation nat :: comm_semiring_1_cancel
   175 begin
   176 
   177 definition
   178   One_nat_def [simp]: "1 = Suc 0"
   179 
   180 primrec times_nat
   181 where
   182   mult_0:     "0 * n = (0\<Colon>nat)"
   183   | mult_Suc: "Suc m * n = n + (m * n)"
   184 
   185 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   186   by (induct m) simp_all
   187 
   188 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   189   by (induct m) (simp_all add: add_left_commute)
   190 
   191 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   192   by (induct m) (simp_all add: add_assoc)
   193 
   194 instance proof
   195   fix n m q :: nat
   196   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   197   show "1 * n = n" unfolding One_nat_def by simp
   198   show "n * m = m * n" by (induct n) simp_all
   199   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   200   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   201   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   202 qed
   203 
   204 end
   205 
   206 subsubsection {* Addition *}
   207 
   208 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   209   by (rule add_assoc)
   210 
   211 lemma nat_add_commute: "m + n = n + (m::nat)"
   212   by (rule add_commute)
   213 
   214 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   215   by (rule add_left_commute)
   216 
   217 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   218   by (rule add_left_cancel)
   219 
   220 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   221   by (rule add_right_cancel)
   222 
   223 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   224 
   225 lemma add_is_0 [iff]:
   226   fixes m n :: nat
   227   shows "(m + n = 0) = (m = 0 & n = 0)"
   228   by (cases m) simp_all
   229 
   230 lemma add_is_1:
   231   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   232   by (cases m) simp_all
   233 
   234 lemma one_is_add:
   235   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   236   by (rule trans, rule eq_commute, rule add_is_1)
   237 
   238 lemma add_eq_self_zero:
   239   fixes m n :: nat
   240   shows "m + n = m \<Longrightarrow> n = 0"
   241   by (induct m) simp_all
   242 
   243 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   244   apply (induct k)
   245    apply simp
   246   apply(drule comp_inj_on[OF _ inj_Suc])
   247   apply (simp add:o_def)
   248   done
   249 
   250 
   251 subsubsection {* Difference *}
   252 
   253 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   254   by (induct m) simp_all
   255 
   256 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   257   by (induct i j rule: diff_induct) simp_all
   258 
   259 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   260   by (simp add: diff_diff_left)
   261 
   262 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   263   by (simp add: diff_diff_left add_commute)
   264 
   265 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   266   by (induct n) simp_all
   267 
   268 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   269   by (simp add: diff_add_inverse add_commute [of m n])
   270 
   271 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   272   by (induct k) simp_all
   273 
   274 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   275   by (simp add: diff_cancel add_commute)
   276 
   277 lemma diff_add_0: "n - (n + m) = (0::nat)"
   278   by (induct n) simp_all
   279 
   280 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   281   unfolding One_nat_def by simp
   282 
   283 text {* Difference distributes over multiplication *}
   284 
   285 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   286 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   287 
   288 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   289 by (simp add: diff_mult_distrib mult_commute [of k])
   290   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   291 
   292 
   293 subsubsection {* Multiplication *}
   294 
   295 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   296   by (rule mult_assoc)
   297 
   298 lemma nat_mult_commute: "m * n = n * (m::nat)"
   299   by (rule mult_commute)
   300 
   301 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   302   by (rule right_distrib)
   303 
   304 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   305   by (induct m) auto
   306 
   307 lemmas nat_distrib =
   308   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   309 
   310 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   311   apply (induct m)
   312    apply simp
   313   apply (induct n)
   314    apply auto
   315   done
   316 
   317 lemma one_eq_mult_iff [simp,no_atp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   318   apply (rule trans)
   319   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   320   done
   321 
   322 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   323   unfolding One_nat_def by (rule mult_eq_1_iff)
   324 
   325 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   326   unfolding One_nat_def by (rule one_eq_mult_iff)
   327 
   328 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   329 proof -
   330   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   331   proof (induct n arbitrary: m)
   332     case 0 then show "m = 0" by simp
   333   next
   334     case (Suc n) then show "m = Suc n"
   335       by (cases m) (simp_all add: eq_commute [of "0"])
   336   qed
   337   then show ?thesis by auto
   338 qed
   339 
   340 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   341   by (simp add: mult_commute)
   342 
   343 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   344   by (subst mult_cancel1) simp
   345 
   346 
   347 subsection {* Orders on @{typ nat} *}
   348 
   349 subsubsection {* Operation definition *}
   350 
   351 instantiation nat :: linorder
   352 begin
   353 
   354 primrec less_eq_nat where
   355   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   356   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   357 
   358 declare less_eq_nat.simps [simp del]
   359 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   360 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   361 
   362 definition less_nat where
   363   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   364 
   365 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   366   by (simp add: less_eq_nat.simps(2))
   367 
   368 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   369   unfolding less_eq_Suc_le ..
   370 
   371 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   372   by (induct n) (simp_all add: less_eq_nat.simps(2))
   373 
   374 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   375   by (simp add: less_eq_Suc_le)
   376 
   377 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   378   by simp
   379 
   380 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   381   by (simp add: less_eq_Suc_le)
   382 
   383 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   384   by (simp add: less_eq_Suc_le)
   385 
   386 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   387   by (induct m arbitrary: n)
   388     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   389 
   390 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   391   by (cases n) (auto intro: le_SucI)
   392 
   393 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   394   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   395 
   396 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   397   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   398 
   399 instance
   400 proof
   401   fix n m :: nat
   402   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   403   proof (induct n arbitrary: m)
   404     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   405   next
   406     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   407   qed
   408 next
   409   fix n :: nat show "n \<le> n" by (induct n) simp_all
   410 next
   411   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   412   then show "n = m"
   413     by (induct n arbitrary: m)
   414       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   415 next
   416   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   417   then show "n \<le> q"
   418   proof (induct n arbitrary: m q)
   419     case 0 show ?case by simp
   420   next
   421     case (Suc n) then show ?case
   422       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   423         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   424         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   425   qed
   426 next
   427   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   428     by (induct n arbitrary: m)
   429       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   430 qed
   431 
   432 end
   433 
   434 instantiation nat :: bot
   435 begin
   436 
   437 definition bot_nat :: nat where
   438   "bot_nat = 0"
   439 
   440 instance proof
   441 qed (simp add: bot_nat_def)
   442 
   443 end
   444 
   445 subsubsection {* Introduction properties *}
   446 
   447 lemma lessI [iff]: "n < Suc n"
   448   by (simp add: less_Suc_eq_le)
   449 
   450 lemma zero_less_Suc [iff]: "0 < Suc n"
   451   by (simp add: less_Suc_eq_le)
   452 
   453 
   454 subsubsection {* Elimination properties *}
   455 
   456 lemma less_not_refl: "~ n < (n::nat)"
   457   by (rule order_less_irrefl)
   458 
   459 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   460   by (rule not_sym) (rule less_imp_neq) 
   461 
   462 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   463   by (rule less_imp_neq)
   464 
   465 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   466   by (rule notE, rule less_not_refl)
   467 
   468 lemma less_zeroE: "(n::nat) < 0 ==> R"
   469   by (rule notE) (rule not_less0)
   470 
   471 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   472   unfolding less_Suc_eq_le le_less ..
   473 
   474 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   475   by (simp add: less_Suc_eq)
   476 
   477 lemma less_one [iff, no_atp]: "(n < (1::nat)) = (n = 0)"
   478   unfolding One_nat_def by (rule less_Suc0)
   479 
   480 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   481   by simp
   482 
   483 text {* "Less than" is antisymmetric, sort of *}
   484 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   485   unfolding not_less less_Suc_eq_le by (rule antisym)
   486 
   487 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   488   by (rule linorder_neq_iff)
   489 
   490 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   491   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   492   shows "P n m"
   493   apply (rule less_linear [THEN disjE])
   494   apply (erule_tac [2] disjE)
   495   apply (erule lessCase)
   496   apply (erule sym [THEN eqCase])
   497   apply (erule major)
   498   done
   499 
   500 
   501 subsubsection {* Inductive (?) properties *}
   502 
   503 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   504   unfolding less_eq_Suc_le [of m] le_less by simp 
   505 
   506 lemma lessE:
   507   assumes major: "i < k"
   508   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   509   shows P
   510 proof -
   511   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   512     unfolding less_eq_Suc_le by (induct k) simp_all
   513   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   514     by (clarsimp simp add: less_le)
   515   with p1 p2 show P by auto
   516 qed
   517 
   518 lemma less_SucE: assumes major: "m < Suc n"
   519   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   520   apply (rule major [THEN lessE])
   521   apply (rule eq, blast)
   522   apply (rule less, blast)
   523   done
   524 
   525 lemma Suc_lessE: assumes major: "Suc i < k"
   526   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   527   apply (rule major [THEN lessE])
   528   apply (erule lessI [THEN minor])
   529   apply (erule Suc_lessD [THEN minor], assumption)
   530   done
   531 
   532 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   533   by simp
   534 
   535 lemma less_trans_Suc:
   536   assumes le: "i < j" shows "j < k ==> Suc i < k"
   537   apply (induct k, simp_all)
   538   apply (insert le)
   539   apply (simp add: less_Suc_eq)
   540   apply (blast dest: Suc_lessD)
   541   done
   542 
   543 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   544 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   545   unfolding not_less less_Suc_eq_le ..
   546 
   547 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   548   unfolding not_le Suc_le_eq ..
   549 
   550 text {* Properties of "less than or equal" *}
   551 
   552 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   553   unfolding less_Suc_eq_le .
   554 
   555 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   556   unfolding not_le less_Suc_eq_le ..
   557 
   558 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   559   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   560 
   561 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   562   by (drule le_Suc_eq [THEN iffD1], iprover+)
   563 
   564 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   565   unfolding Suc_le_eq .
   566 
   567 text {* Stronger version of @{text Suc_leD} *}
   568 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   569   unfolding Suc_le_eq .
   570 
   571 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   572   unfolding less_eq_Suc_le by (rule Suc_leD)
   573 
   574 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   575 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   576 
   577 
   578 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   579 
   580 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   581   unfolding le_less .
   582 
   583 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   584   by (rule le_less)
   585 
   586 text {* Useful with @{text blast}. *}
   587 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   588   by auto
   589 
   590 lemma le_refl: "n \<le> (n::nat)"
   591   by simp
   592 
   593 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   594   by (rule order_trans)
   595 
   596 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   597   by (rule antisym)
   598 
   599 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   600   by (rule less_le)
   601 
   602 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   603   unfolding less_le ..
   604 
   605 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   606   by (rule linear)
   607 
   608 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   609 
   610 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   611   unfolding less_Suc_eq_le by auto
   612 
   613 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   614   unfolding not_less by (rule le_less_Suc_eq)
   615 
   616 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   617 
   618 text {* These two rules ease the use of primitive recursion.
   619 NOTE USE OF @{text "=="} *}
   620 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   621 by simp
   622 
   623 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   624 by simp
   625 
   626 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   627 by (cases n) simp_all
   628 
   629 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   630 by (cases n) simp_all
   631 
   632 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   633 by (cases n) simp_all
   634 
   635 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   636 by (cases n) simp_all
   637 
   638 text {* This theorem is useful with @{text blast} *}
   639 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   640 by (rule neq0_conv[THEN iffD1], iprover)
   641 
   642 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   643 by (fast intro: not0_implies_Suc)
   644 
   645 lemma not_gr0 [iff,no_atp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   646 using neq0_conv by blast
   647 
   648 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   649 by (induct m') simp_all
   650 
   651 text {* Useful in certain inductive arguments *}
   652 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   653 by (cases m) simp_all
   654 
   655 
   656 subsubsection {* @{term min} and @{term max} *}
   657 
   658 lemma mono_Suc: "mono Suc"
   659 by (rule monoI) simp
   660 
   661 lemma min_0L [simp]: "min 0 n = (0::nat)"
   662 by (rule min_leastL) simp
   663 
   664 lemma min_0R [simp]: "min n 0 = (0::nat)"
   665 by (rule min_leastR) simp
   666 
   667 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   668 by (simp add: mono_Suc min_of_mono)
   669 
   670 lemma min_Suc1:
   671    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   672 by (simp split: nat.split)
   673 
   674 lemma min_Suc2:
   675    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   676 by (simp split: nat.split)
   677 
   678 lemma max_0L [simp]: "max 0 n = (n::nat)"
   679 by (rule max_leastL) simp
   680 
   681 lemma max_0R [simp]: "max n 0 = (n::nat)"
   682 by (rule max_leastR) simp
   683 
   684 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   685 by (simp add: mono_Suc max_of_mono)
   686 
   687 lemma max_Suc1:
   688    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   689 by (simp split: nat.split)
   690 
   691 lemma max_Suc2:
   692    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   693 by (simp split: nat.split)
   694 
   695 
   696 subsubsection {* Monotonicity of Addition *}
   697 
   698 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   699 by (simp add: diff_Suc split: nat.split)
   700 
   701 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   702 unfolding One_nat_def by (rule Suc_pred)
   703 
   704 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   705 by (induct k) simp_all
   706 
   707 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   708 by (induct k) simp_all
   709 
   710 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   711 by(auto dest:gr0_implies_Suc)
   712 
   713 text {* strict, in 1st argument *}
   714 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   715 by (induct k) simp_all
   716 
   717 text {* strict, in both arguments *}
   718 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   719   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   720   apply (induct j, simp_all)
   721   done
   722 
   723 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   724 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   725   apply (induct n)
   726   apply (simp_all add: order_le_less)
   727   apply (blast elim!: less_SucE
   728                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   729   done
   730 
   731 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   732 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   733 apply(auto simp: gr0_conv_Suc)
   734 apply (induct_tac m)
   735 apply (simp_all add: add_less_mono)
   736 done
   737 
   738 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   739 instance nat :: linordered_semidom
   740 proof
   741   fix i j k :: nat
   742   show "0 < (1::nat)" by simp
   743   show "i \<le> j ==> k + i \<le> k + j" by simp
   744   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   745 qed
   746 
   747 instance nat :: no_zero_divisors
   748 proof
   749   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   750 qed
   751 
   752 lemma nat_mult_1: "(1::nat) * n = n"
   753 by simp
   754 
   755 lemma nat_mult_1_right: "n * (1::nat) = n"
   756 by simp
   757 
   758 
   759 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   760 
   761 text {* Complete induction, aka course-of-values induction *}
   762 
   763 instance nat :: wellorder proof
   764   fix P and n :: nat
   765   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   766   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   767   proof (induct n)
   768     case (0 n)
   769     have "P 0" by (rule step) auto
   770     thus ?case using 0 by auto
   771   next
   772     case (Suc m n)
   773     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   774     thus ?case
   775     proof
   776       assume "n \<le> m" thus "P n" by (rule Suc(1))
   777     next
   778       assume n: "n = Suc m"
   779       show "P n"
   780         by (rule step) (rule Suc(1), simp add: n le_simps)
   781     qed
   782   qed
   783   then show "P n" by auto
   784 qed
   785 
   786 lemma Least_Suc:
   787      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   788   apply (case_tac "n", auto)
   789   apply (frule LeastI)
   790   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   791   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   792   apply (erule_tac [2] Least_le)
   793   apply (case_tac "LEAST x. P x", auto)
   794   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   795   apply (blast intro: order_antisym)
   796   done
   797 
   798 lemma Least_Suc2:
   799    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   800   apply (erule (1) Least_Suc [THEN ssubst])
   801   apply simp
   802   done
   803 
   804 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   805   apply (cases n)
   806    apply blast
   807   apply (rule_tac x="LEAST k. P(k)" in exI)
   808   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   809   done
   810 
   811 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   812   unfolding One_nat_def
   813   apply (cases n)
   814    apply blast
   815   apply (frule (1) ex_least_nat_le)
   816   apply (erule exE)
   817   apply (case_tac k)
   818    apply simp
   819   apply (rename_tac k1)
   820   apply (rule_tac x=k1 in exI)
   821   apply (auto simp add: less_eq_Suc_le)
   822   done
   823 
   824 lemma nat_less_induct:
   825   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   826   using assms less_induct by blast
   827 
   828 lemma measure_induct_rule [case_names less]:
   829   fixes f :: "'a \<Rightarrow> nat"
   830   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   831   shows "P a"
   832 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   833 
   834 text {* old style induction rules: *}
   835 lemma measure_induct:
   836   fixes f :: "'a \<Rightarrow> nat"
   837   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   838   by (rule measure_induct_rule [of f P a]) iprover
   839 
   840 lemma full_nat_induct:
   841   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   842   shows "P n"
   843   by (rule less_induct) (auto intro: step simp:le_simps)
   844 
   845 text{*An induction rule for estabilishing binary relations*}
   846 lemma less_Suc_induct:
   847   assumes less:  "i < j"
   848      and  step:  "!!i. P i (Suc i)"
   849      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   850   shows "P i j"
   851 proof -
   852   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   853   have "P i (Suc (i + k))"
   854   proof (induct k)
   855     case 0
   856     show ?case by (simp add: step)
   857   next
   858     case (Suc k)
   859     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   860     hence "i < Suc (i + k)" by (simp add: add_commute)
   861     from trans[OF this lessI Suc step]
   862     show ?case by simp
   863   qed
   864   thus "P i j" by (simp add: j)
   865 qed
   866 
   867 text {* The method of infinite descent, frequently used in number theory.
   868 Provided by Roelof Oosterhuis.
   869 $P(n)$ is true for all $n\in\mathbb{N}$ if
   870 \begin{itemize}
   871   \item case ``0'': given $n=0$ prove $P(n)$,
   872   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   873         a smaller integer $m$ such that $\neg P(m)$.
   874 \end{itemize} *}
   875 
   876 text{* A compact version without explicit base case: *}
   877 lemma infinite_descent:
   878   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   879 by (induct n rule: less_induct, auto)
   880 
   881 lemma infinite_descent0[case_names 0 smaller]: 
   882   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   883 by (rule infinite_descent) (case_tac "n>0", auto)
   884 
   885 text {*
   886 Infinite descent using a mapping to $\mathbb{N}$:
   887 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   888 \begin{itemize}
   889 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   890 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   891 \end{itemize}
   892 NB: the proof also shows how to use the previous lemma. *}
   893 
   894 corollary infinite_descent0_measure [case_names 0 smaller]:
   895   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   896     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   897   shows "P x"
   898 proof -
   899   obtain n where "n = V x" by auto
   900   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   901   proof (induct n rule: infinite_descent0)
   902     case 0 -- "i.e. $V(x) = 0$"
   903     with A0 show "P x" by auto
   904   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   905     case (smaller n)
   906     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   907     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   908     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   909     then show ?case by auto
   910   qed
   911   ultimately show "P x" by auto
   912 qed
   913 
   914 text{* Again, without explicit base case: *}
   915 lemma infinite_descent_measure:
   916 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   917 proof -
   918   from assms obtain n where "n = V x" by auto
   919   moreover have "!!x. V x = n \<Longrightarrow> P x"
   920   proof (induct n rule: infinite_descent, auto)
   921     fix x assume "\<not> P x"
   922     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   923   qed
   924   ultimately show "P x" by auto
   925 qed
   926 
   927 text {* A [clumsy] way of lifting @{text "<"}
   928   monotonicity to @{text "\<le>"} monotonicity *}
   929 lemma less_mono_imp_le_mono:
   930   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   931 by (simp add: order_le_less) (blast)
   932 
   933 
   934 text {* non-strict, in 1st argument *}
   935 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   936 by (rule add_right_mono)
   937 
   938 text {* non-strict, in both arguments *}
   939 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   940 by (rule add_mono)
   941 
   942 lemma le_add2: "n \<le> ((m + n)::nat)"
   943 by (insert add_right_mono [of 0 m n], simp)
   944 
   945 lemma le_add1: "n \<le> ((n + m)::nat)"
   946 by (simp add: add_commute, rule le_add2)
   947 
   948 lemma less_add_Suc1: "i < Suc (i + m)"
   949 by (rule le_less_trans, rule le_add1, rule lessI)
   950 
   951 lemma less_add_Suc2: "i < Suc (m + i)"
   952 by (rule le_less_trans, rule le_add2, rule lessI)
   953 
   954 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   955 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   956 
   957 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   958 by (rule le_trans, assumption, rule le_add1)
   959 
   960 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   961 by (rule le_trans, assumption, rule le_add2)
   962 
   963 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   964 by (rule less_le_trans, assumption, rule le_add1)
   965 
   966 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   967 by (rule less_le_trans, assumption, rule le_add2)
   968 
   969 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   970 apply (rule le_less_trans [of _ "i+j"])
   971 apply (simp_all add: le_add1)
   972 done
   973 
   974 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   975 apply (rule notI)
   976 apply (drule add_lessD1)
   977 apply (erule less_irrefl [THEN notE])
   978 done
   979 
   980 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   981 by (simp add: add_commute)
   982 
   983 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   984 apply (rule order_trans [of _ "m+k"])
   985 apply (simp_all add: le_add1)
   986 done
   987 
   988 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   989 apply (simp add: add_commute)
   990 apply (erule add_leD1)
   991 done
   992 
   993 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   994 by (blast dest: add_leD1 add_leD2)
   995 
   996 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   997 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   998 by (force simp del: add_Suc_right
   999     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1000 
  1001 
  1002 subsubsection {* More results about difference *}
  1003 
  1004 text {* Addition is the inverse of subtraction:
  1005   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1006 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1007 by (induct m n rule: diff_induct) simp_all
  1008 
  1009 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1010 by (simp add: add_diff_inverse linorder_not_less)
  1011 
  1012 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1013 by (simp add: add_commute)
  1014 
  1015 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1016 by (induct m n rule: diff_induct) simp_all
  1017 
  1018 lemma diff_less_Suc: "m - n < Suc m"
  1019 apply (induct m n rule: diff_induct)
  1020 apply (erule_tac [3] less_SucE)
  1021 apply (simp_all add: less_Suc_eq)
  1022 done
  1023 
  1024 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1025 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1026 
  1027 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1028   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1029 
  1030 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1031 by (rule le_less_trans, rule diff_le_self)
  1032 
  1033 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1034 by (cases n) (auto simp add: le_simps)
  1035 
  1036 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1037 by (induct j k rule: diff_induct) simp_all
  1038 
  1039 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1040 by (simp add: add_commute diff_add_assoc)
  1041 
  1042 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1043 by (auto simp add: diff_add_inverse2)
  1044 
  1045 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1046 by (induct m n rule: diff_induct) simp_all
  1047 
  1048 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1049 by (rule iffD2, rule diff_is_0_eq)
  1050 
  1051 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1052 by (induct m n rule: diff_induct) simp_all
  1053 
  1054 lemma less_imp_add_positive:
  1055   assumes "i < j"
  1056   shows "\<exists>k::nat. 0 < k & i + k = j"
  1057 proof
  1058   from assms show "0 < j - i & i + (j - i) = j"
  1059     by (simp add: order_less_imp_le)
  1060 qed
  1061 
  1062 text {* a nice rewrite for bounded subtraction *}
  1063 lemma nat_minus_add_max:
  1064   fixes n m :: nat
  1065   shows "n - m + m = max n m"
  1066     by (simp add: max_def not_le order_less_imp_le)
  1067 
  1068 lemma nat_diff_split:
  1069   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1070     -- {* elimination of @{text -} on @{text nat} *}
  1071 by (cases "a < b")
  1072   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1073     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1074 
  1075 lemma nat_diff_split_asm:
  1076   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1077     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1078 by (auto split: nat_diff_split)
  1079 
  1080 
  1081 subsubsection {* Monotonicity of Multiplication *}
  1082 
  1083 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1084 by (simp add: mult_right_mono)
  1085 
  1086 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1087 by (simp add: mult_left_mono)
  1088 
  1089 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1090 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1091 by (simp add: mult_mono)
  1092 
  1093 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1094 by (simp add: mult_strict_right_mono)
  1095 
  1096 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1097       there are no negative numbers.*}
  1098 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1099   apply (induct m)
  1100    apply simp
  1101   apply (case_tac n)
  1102    apply simp_all
  1103   done
  1104 
  1105 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1106   apply (induct m)
  1107    apply simp
  1108   apply (case_tac n)
  1109    apply simp_all
  1110   done
  1111 
  1112 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1113   apply (safe intro!: mult_less_mono1)
  1114   apply (case_tac k, auto)
  1115   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1116   apply (blast intro: mult_le_mono1)
  1117   done
  1118 
  1119 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1120 by (simp add: mult_commute [of k])
  1121 
  1122 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1123 by (simp add: linorder_not_less [symmetric], auto)
  1124 
  1125 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1126 by (simp add: linorder_not_less [symmetric], auto)
  1127 
  1128 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1129 by (subst mult_less_cancel1) simp
  1130 
  1131 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1132 by (subst mult_le_cancel1) simp
  1133 
  1134 lemma le_square: "m \<le> m * (m::nat)"
  1135   by (cases m) (auto intro: le_add1)
  1136 
  1137 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1138   by (cases m) (auto intro: le_add1)
  1139 
  1140 text {* Lemma for @{text gcd} *}
  1141 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1142   apply (drule sym)
  1143   apply (rule disjCI)
  1144   apply (rule nat_less_cases, erule_tac [2] _)
  1145    apply (drule_tac [2] mult_less_mono2)
  1146     apply (auto)
  1147   done
  1148 
  1149 text {* the lattice order on @{typ nat} *}
  1150 
  1151 instantiation nat :: distrib_lattice
  1152 begin
  1153 
  1154 definition
  1155   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1156 
  1157 definition
  1158   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1159 
  1160 instance by intro_classes
  1161   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1162     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1163 
  1164 end
  1165 
  1166 
  1167 subsection {* Natural operation of natural numbers on functions *}
  1168 
  1169 text {*
  1170   We use the same logical constant for the power operations on
  1171   functions and relations, in order to share the same syntax.
  1172 *}
  1173 
  1174 consts compow :: "nat \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
  1175 
  1176 abbreviation compower :: "('a \<Rightarrow> 'b) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'b" (infixr "^^" 80) where
  1177   "f ^^ n \<equiv> compow n f"
  1178 
  1179 notation (latex output)
  1180   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1181 
  1182 notation (HTML output)
  1183   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1184 
  1185 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1186 
  1187 overloading
  1188   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1189 begin
  1190 
  1191 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1192     "funpow 0 f = id"
  1193   | "funpow (Suc n) f = f o funpow n f"
  1194 
  1195 end
  1196 
  1197 text {* for code generation *}
  1198 
  1199 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1200   funpow_code_def [code_post]: "funpow = compow"
  1201 
  1202 lemmas [code_unfold] = funpow_code_def [symmetric]
  1203 
  1204 lemma [code]:
  1205   "funpow (Suc n) f = f o funpow n f"
  1206   "funpow 0 f = id"
  1207   by (simp_all add: funpow_code_def)
  1208 
  1209 hide_const (open) funpow
  1210 
  1211 lemma funpow_add:
  1212   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1213   by (induct m) simp_all
  1214 
  1215 lemma funpow_mult:
  1216   fixes f :: "'a \<Rightarrow> 'a"
  1217   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1218   by (induct n) (simp_all add: funpow_add)
  1219 
  1220 lemma funpow_swap1:
  1221   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1222 proof -
  1223   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1224   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1225   also have "\<dots> = (f ^^ n) (f x)" by simp
  1226   finally show ?thesis .
  1227 qed
  1228 
  1229 lemma comp_funpow:
  1230   fixes f :: "'a \<Rightarrow> 'a"
  1231   shows "comp f ^^ n = comp (f ^^ n)"
  1232   by (induct n) simp_all
  1233 
  1234 
  1235 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1236 
  1237 context semiring_1
  1238 begin
  1239 
  1240 definition of_nat :: "nat \<Rightarrow> 'a" where
  1241   "of_nat n = (plus 1 ^^ n) 0"
  1242 
  1243 lemma of_nat_simps [simp]:
  1244   shows of_nat_0: "of_nat 0 = 0"
  1245     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1246   by (simp_all add: of_nat_def)
  1247 
  1248 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1249   by (simp add: of_nat_def)
  1250 
  1251 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1252   by (induct m) (simp_all add: add_ac)
  1253 
  1254 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1255   by (induct m) (simp_all add: add_ac left_distrib)
  1256 
  1257 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1258   "of_nat_aux inc 0 i = i"
  1259   | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1260 
  1261 lemma of_nat_code:
  1262   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1263 proof (induct n)
  1264   case 0 then show ?case by simp
  1265 next
  1266   case (Suc n)
  1267   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1268     by (induct n) simp_all
  1269   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1270     by simp
  1271   with Suc show ?case by (simp add: add_commute)
  1272 qed
  1273 
  1274 end
  1275 
  1276 declare of_nat_code [code, code_unfold, code_inline del]
  1277 
  1278 text{*Class for unital semirings with characteristic zero.
  1279  Includes non-ordered rings like the complex numbers.*}
  1280 
  1281 class semiring_char_0 = semiring_1 +
  1282   assumes inj_of_nat: "inj of_nat"
  1283 begin
  1284 
  1285 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1286   by (auto intro: inj_of_nat injD)
  1287 
  1288 text{*Special cases where either operand is zero*}
  1289 
  1290 lemma of_nat_0_eq_iff [simp, no_atp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1291   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1292 
  1293 lemma of_nat_eq_0_iff [simp, no_atp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1294   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1295 
  1296 end
  1297 
  1298 context linordered_semidom
  1299 begin
  1300 
  1301 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1302   by (induct m) simp_all
  1303 
  1304 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1305   apply (induct m n rule: diff_induct, simp_all)
  1306   apply (rule add_pos_nonneg [OF zero_less_one zero_le_imp_of_nat])
  1307   done
  1308 
  1309 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1310   apply (induct m n rule: diff_induct, simp_all)
  1311   apply (insert zero_le_imp_of_nat)
  1312   apply (force simp add: not_less [symmetric])
  1313   done
  1314 
  1315 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1316   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1317 
  1318 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1319   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1320 
  1321 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1322 
  1323 subclass semiring_char_0 proof
  1324 qed (auto intro!: injI simp add: eq_iff)
  1325 
  1326 text{*Special cases where either operand is zero*}
  1327 
  1328 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1329   by (rule of_nat_le_iff [of 0, simplified])
  1330 
  1331 lemma of_nat_le_0_iff [simp, no_atp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1332   by (rule of_nat_le_iff [of _ 0, simplified])
  1333 
  1334 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1335   by (rule of_nat_less_iff [of 0, simplified])
  1336 
  1337 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1338   by (rule of_nat_less_iff [of _ 0, simplified])
  1339 
  1340 end
  1341 
  1342 context ring_1
  1343 begin
  1344 
  1345 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1346 by (simp add: algebra_simps of_nat_add [symmetric])
  1347 
  1348 end
  1349 
  1350 context linordered_idom
  1351 begin
  1352 
  1353 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1354   unfolding abs_if by auto
  1355 
  1356 end
  1357 
  1358 lemma of_nat_id [simp]: "of_nat n = n"
  1359   by (induct n) simp_all
  1360 
  1361 lemma of_nat_eq_id [simp]: "of_nat = id"
  1362   by (auto simp add: fun_eq_iff)
  1363 
  1364 
  1365 subsection {* The Set of Natural Numbers *}
  1366 
  1367 context semiring_1
  1368 begin
  1369 
  1370 definition Nats  :: "'a set" where
  1371   "Nats = range of_nat"
  1372 
  1373 notation (xsymbols)
  1374   Nats  ("\<nat>")
  1375 
  1376 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1377   by (simp add: Nats_def)
  1378 
  1379 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1380 apply (simp add: Nats_def)
  1381 apply (rule range_eqI)
  1382 apply (rule of_nat_0 [symmetric])
  1383 done
  1384 
  1385 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1386 apply (simp add: Nats_def)
  1387 apply (rule range_eqI)
  1388 apply (rule of_nat_1 [symmetric])
  1389 done
  1390 
  1391 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1392 apply (auto simp add: Nats_def)
  1393 apply (rule range_eqI)
  1394 apply (rule of_nat_add [symmetric])
  1395 done
  1396 
  1397 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1398 apply (auto simp add: Nats_def)
  1399 apply (rule range_eqI)
  1400 apply (rule of_nat_mult [symmetric])
  1401 done
  1402 
  1403 lemma Nats_cases [cases set: Nats]:
  1404   assumes "x \<in> \<nat>"
  1405   obtains (of_nat) n where "x = of_nat n"
  1406   unfolding Nats_def
  1407 proof -
  1408   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1409   then obtain n where "x = of_nat n" ..
  1410   then show thesis ..
  1411 qed
  1412 
  1413 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1414   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1415   by (rule Nats_cases) auto
  1416 
  1417 end
  1418 
  1419 
  1420 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1421 
  1422 lemma subst_equals:
  1423   assumes 1: "t = s" and 2: "u = t"
  1424   shows "u = s"
  1425   using 2 1 by (rule trans)
  1426 
  1427 setup Arith_Data.setup
  1428 
  1429 use "Tools/nat_arith.ML"
  1430 declaration {* K Nat_Arith.setup *}
  1431 
  1432 use "Tools/lin_arith.ML"
  1433 setup {* Lin_Arith.global_setup *}
  1434 declaration {* K Lin_Arith.setup *}
  1435 
  1436 lemmas [arith_split] = nat_diff_split split_min split_max
  1437 
  1438 context order
  1439 begin
  1440 
  1441 lemma lift_Suc_mono_le:
  1442   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1443   shows "f n \<le> f n'"
  1444 proof (cases "n < n'")
  1445   case True
  1446   thus ?thesis
  1447     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1448 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1449 
  1450 lemma lift_Suc_mono_less:
  1451   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1452   shows "f n < f n'"
  1453 using `n < n'`
  1454 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1455 
  1456 lemma lift_Suc_mono_less_iff:
  1457   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1458 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1459          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1460 
  1461 end
  1462 
  1463 lemma mono_iff_le_Suc: "mono f = (\<forall>n. f n \<le> f (Suc n))"
  1464   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1465 
  1466 lemma mono_nat_linear_lb:
  1467   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1468 apply(induct_tac k)
  1469  apply simp
  1470 apply(erule_tac x="m+n" in meta_allE)
  1471 apply(erule_tac x="Suc(m+n)" in meta_allE)
  1472 apply simp
  1473 done
  1474 
  1475 
  1476 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1477 
  1478 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1479 by arith
  1480 
  1481 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1482 by arith
  1483 
  1484 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1485 by arith
  1486 
  1487 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1488 by arith
  1489 
  1490 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1491 by arith
  1492 
  1493 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1494 by arith
  1495 
  1496 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1497   second premise n\<le>m*)
  1498 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1499 by arith
  1500 
  1501 text {* Simplification of relational expressions involving subtraction *}
  1502 
  1503 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1504 by (simp split add: nat_diff_split)
  1505 
  1506 hide_fact (open) diff_diff_eq
  1507 
  1508 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1509 by (auto split add: nat_diff_split)
  1510 
  1511 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1512 by (auto split add: nat_diff_split)
  1513 
  1514 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1515 by (auto split add: nat_diff_split)
  1516 
  1517 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1518 
  1519 (* Monotonicity of subtraction in first argument *)
  1520 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1521 by (simp split add: nat_diff_split)
  1522 
  1523 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1524 by (simp split add: nat_diff_split)
  1525 
  1526 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1527 by (simp split add: nat_diff_split)
  1528 
  1529 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1530 by (simp split add: nat_diff_split)
  1531 
  1532 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1533 by auto
  1534 
  1535 lemma inj_on_diff_nat: 
  1536   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1537   shows "inj_on (\<lambda>n. n - k) N"
  1538 proof (rule inj_onI)
  1539   fix x y
  1540   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1541   with k_le_n have "x - k + k = y - k + k" by auto
  1542   with a k_le_n show "x = y" by auto
  1543 qed
  1544 
  1545 text{*Rewriting to pull differences out*}
  1546 
  1547 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1548 by arith
  1549 
  1550 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1551 by arith
  1552 
  1553 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1554 by arith
  1555 
  1556 text{*Lemmas for ex/Factorization*}
  1557 
  1558 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1559 by (cases m) auto
  1560 
  1561 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1562 by (cases m) auto
  1563 
  1564 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1565 by (cases m) auto
  1566 
  1567 text {* Specialized induction principles that work "backwards": *}
  1568 
  1569 lemma inc_induct[consumes 1, case_names base step]:
  1570   assumes less: "i <= j"
  1571   assumes base: "P j"
  1572   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1573   shows "P i"
  1574   using less
  1575 proof (induct d=="j - i" arbitrary: i)
  1576   case (0 i)
  1577   hence "i = j" by simp
  1578   with base show ?case by simp
  1579 next
  1580   case (Suc d i)
  1581   hence "i < j" "P (Suc i)"
  1582     by simp_all
  1583   thus "P i" by (rule step)
  1584 qed
  1585 
  1586 lemma strict_inc_induct[consumes 1, case_names base step]:
  1587   assumes less: "i < j"
  1588   assumes base: "!!i. j = Suc i ==> P i"
  1589   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1590   shows "P i"
  1591   using less
  1592 proof (induct d=="j - i - 1" arbitrary: i)
  1593   case (0 i)
  1594   with `i < j` have "j = Suc i" by simp
  1595   with base show ?case by simp
  1596 next
  1597   case (Suc d i)
  1598   hence "i < j" "P (Suc i)"
  1599     by simp_all
  1600   thus "P i" by (rule step)
  1601 qed
  1602 
  1603 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1604   using inc_induct[of "k - i" k P, simplified] by blast
  1605 
  1606 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1607   using inc_induct[of 0 k P] by blast
  1608 
  1609 (*The others are
  1610       i - j - k = i - (j + k),
  1611       k \<le> j ==> j - k + i = j + i - k,
  1612       k \<le> j ==> i + (j - k) = i + j - k *)
  1613 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1614 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1615 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1616 
  1617 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1618 Least_Suc}, since there appears to be no need.*}
  1619 
  1620 
  1621 subsection {* The divides relation on @{typ nat} *}
  1622 
  1623 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1624 unfolding dvd_def by simp
  1625 
  1626 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1627 by (simp add: dvd_def)
  1628 
  1629 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1630 by (simp add: dvd_def)
  1631 
  1632 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1633   unfolding dvd_def
  1634   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc)
  1635 
  1636 text {* @{term "op dvd"} is a partial order *}
  1637 
  1638 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1639   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1640 
  1641 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1642 unfolding dvd_def
  1643 by (blast intro: diff_mult_distrib2 [symmetric])
  1644 
  1645 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1646   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1647   apply (blast intro: dvd_add)
  1648   done
  1649 
  1650 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1651 by (drule_tac m = m in dvd_diff_nat, auto)
  1652 
  1653 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1654   apply (rule iffI)
  1655    apply (erule_tac [2] dvd_add)
  1656    apply (rule_tac [2] dvd_refl)
  1657   apply (subgoal_tac "n = (n+k) -k")
  1658    prefer 2 apply simp
  1659   apply (erule ssubst)
  1660   apply (erule dvd_diff_nat)
  1661   apply (rule dvd_refl)
  1662   done
  1663 
  1664 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1665   unfolding dvd_def
  1666   apply (erule exE)
  1667   apply (simp add: mult_ac)
  1668   done
  1669 
  1670 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1671   apply auto
  1672    apply (subgoal_tac "m*n dvd m*1")
  1673    apply (drule dvd_mult_cancel, auto)
  1674   done
  1675 
  1676 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1677   apply (subst mult_commute)
  1678   apply (erule dvd_mult_cancel1)
  1679   done
  1680 
  1681 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1682 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1683 
  1684 lemma nat_dvd_not_less:
  1685   fixes m n :: nat
  1686   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1687 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1688 
  1689 
  1690 subsection {* size of a datatype value *}
  1691 
  1692 class size =
  1693   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1694 
  1695 
  1696 subsection {* code module namespace *}
  1697 
  1698 code_modulename SML
  1699   Nat Arith
  1700 
  1701 code_modulename OCaml
  1702   Nat Arith
  1703 
  1704 code_modulename Haskell
  1705   Nat Arith
  1706 
  1707 end