src/HOL/Fun.thy
author haftmann
Wed Apr 09 08:10:11 2008 +0200 (2008-04-09)
changeset 26588 d83271bfaba5
parent 26357 19b153ebda0b
child 27106 ff27dc6e7d05
permissions -rw-r--r--
removed syntax from monad combinators; renamed mbind to scomp
     1 (*  Title:      HOL/Fun.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     4     Copyright   1994  University of Cambridge
     5 *)
     6 
     7 header {* Notions about functions *}
     8 
     9 theory Fun
    10 imports Set
    11 begin
    12 
    13 text{*As a simplification rule, it replaces all function equalities by
    14   first-order equalities.*}
    15 lemma expand_fun_eq: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
    16 apply (rule iffI)
    17 apply (simp (no_asm_simp))
    18 apply (rule ext)
    19 apply (simp (no_asm_simp))
    20 done
    21 
    22 lemma apply_inverse:
    23   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    24   by auto
    25 
    26 
    27 subsection {* The Identity Function @{text id} *}
    28 
    29 definition
    30   id :: "'a \<Rightarrow> 'a"
    31 where
    32   "id = (\<lambda>x. x)"
    33 
    34 lemma id_apply [simp]: "id x = x"
    35   by (simp add: id_def)
    36 
    37 lemma image_ident [simp]: "(%x. x) ` Y = Y"
    38 by blast
    39 
    40 lemma image_id [simp]: "id ` Y = Y"
    41 by (simp add: id_def)
    42 
    43 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
    44 by blast
    45 
    46 lemma vimage_id [simp]: "id -` A = A"
    47 by (simp add: id_def)
    48 
    49 
    50 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    51 
    52 definition
    53   comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55)
    54 where
    55   "f o g = (\<lambda>x. f (g x))"
    56 
    57 notation (xsymbols)
    58   comp  (infixl "\<circ>" 55)
    59 
    60 notation (HTML output)
    61   comp  (infixl "\<circ>" 55)
    62 
    63 text{*compatibility*}
    64 lemmas o_def = comp_def
    65 
    66 lemma o_apply [simp]: "(f o g) x = f (g x)"
    67 by (simp add: comp_def)
    68 
    69 lemma o_assoc: "f o (g o h) = f o g o h"
    70 by (simp add: comp_def)
    71 
    72 lemma id_o [simp]: "id o g = g"
    73 by (simp add: comp_def)
    74 
    75 lemma o_id [simp]: "f o id = f"
    76 by (simp add: comp_def)
    77 
    78 lemma image_compose: "(f o g) ` r = f`(g`r)"
    79 by (simp add: comp_def, blast)
    80 
    81 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
    82 by (unfold comp_def, blast)
    83 
    84 
    85 subsection {* The Forward Composition Operator @{text fcomp} *}
    86 
    87 definition
    88   fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o>" 60)
    89 where
    90   "f o> g = (\<lambda>x. g (f x))"
    91 
    92 lemma fcomp_apply:  "(f o> g) x = g (f x)"
    93   by (simp add: fcomp_def)
    94 
    95 lemma fcomp_assoc: "(f o> g) o> h = f o> (g o> h)"
    96   by (simp add: fcomp_def)
    97 
    98 lemma id_fcomp [simp]: "id o> g = g"
    99   by (simp add: fcomp_def)
   100 
   101 lemma fcomp_id [simp]: "f o> id = f"
   102   by (simp add: fcomp_def)
   103 
   104 no_notation fcomp (infixl "o>" 60)
   105 
   106 
   107 subsection {* Injectivity and Surjectivity *}
   108 
   109 constdefs
   110   inj_on :: "['a => 'b, 'a set] => bool"  -- "injective"
   111   "inj_on f A == ! x:A. ! y:A. f(x)=f(y) --> x=y"
   112 
   113 text{*A common special case: functions injective over the entire domain type.*}
   114 
   115 abbreviation
   116   "inj f == inj_on f UNIV"
   117 
   118 definition
   119   bij_betw :: "('a => 'b) => 'a set => 'b set => bool" where -- "bijective"
   120   "bij_betw f A B \<longleftrightarrow> inj_on f A & f ` A = B"
   121 
   122 constdefs
   123   surj :: "('a => 'b) => bool"                   (*surjective*)
   124   "surj f == ! y. ? x. y=f(x)"
   125 
   126   bij :: "('a => 'b) => bool"                    (*bijective*)
   127   "bij f == inj f & surj f"
   128 
   129 lemma injI:
   130   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   131   shows "inj f"
   132   using assms unfolding inj_on_def by auto
   133 
   134 text{*For Proofs in @{text "Tools/datatype_rep_proofs"}*}
   135 lemma datatype_injI:
   136     "(!! x. ALL y. f(x) = f(y) --> x=y) ==> inj(f)"
   137 by (simp add: inj_on_def)
   138 
   139 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   140   by (unfold inj_on_def, blast)
   141 
   142 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   143 by (simp add: inj_on_def)
   144 
   145 (*Useful with the simplifier*)
   146 lemma inj_eq: "inj(f) ==> (f(x) = f(y)) = (x=y)"
   147 by (force simp add: inj_on_def)
   148 
   149 lemma inj_on_id[simp]: "inj_on id A"
   150   by (simp add: inj_on_def) 
   151 
   152 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   153 by (simp add: inj_on_def) 
   154 
   155 lemma surj_id[simp]: "surj id"
   156 by (simp add: surj_def) 
   157 
   158 lemma bij_id[simp]: "bij id"
   159 by (simp add: bij_def inj_on_id surj_id) 
   160 
   161 lemma inj_onI:
   162     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   163 by (simp add: inj_on_def)
   164 
   165 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   166 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   167 
   168 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   169 by (unfold inj_on_def, blast)
   170 
   171 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   172 by (blast dest!: inj_onD)
   173 
   174 lemma comp_inj_on:
   175      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   176 by (simp add: comp_def inj_on_def)
   177 
   178 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   179 apply(simp add:inj_on_def image_def)
   180 apply blast
   181 done
   182 
   183 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   184   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   185 apply(unfold inj_on_def)
   186 apply blast
   187 done
   188 
   189 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   190 by (unfold inj_on_def, blast)
   191 
   192 lemma inj_singleton: "inj (%s. {s})"
   193 by (simp add: inj_on_def)
   194 
   195 lemma inj_on_empty[iff]: "inj_on f {}"
   196 by(simp add: inj_on_def)
   197 
   198 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   199 by (unfold inj_on_def, blast)
   200 
   201 lemma inj_on_Un:
   202  "inj_on f (A Un B) =
   203   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   204 apply(unfold inj_on_def)
   205 apply (blast intro:sym)
   206 done
   207 
   208 lemma inj_on_insert[iff]:
   209   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   210 apply(unfold inj_on_def)
   211 apply (blast intro:sym)
   212 done
   213 
   214 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   215 apply(unfold inj_on_def)
   216 apply (blast)
   217 done
   218 
   219 lemma surjI: "(!! x. g(f x) = x) ==> surj g"
   220 apply (simp add: surj_def)
   221 apply (blast intro: sym)
   222 done
   223 
   224 lemma surj_range: "surj f ==> range f = UNIV"
   225 by (auto simp add: surj_def)
   226 
   227 lemma surjD: "surj f ==> EX x. y = f x"
   228 by (simp add: surj_def)
   229 
   230 lemma surjE: "surj f ==> (!!x. y = f x ==> C) ==> C"
   231 by (simp add: surj_def, blast)
   232 
   233 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   234 apply (simp add: comp_def surj_def, clarify)
   235 apply (drule_tac x = y in spec, clarify)
   236 apply (drule_tac x = x in spec, blast)
   237 done
   238 
   239 lemma bijI: "[| inj f; surj f |] ==> bij f"
   240 by (simp add: bij_def)
   241 
   242 lemma bij_is_inj: "bij f ==> inj f"
   243 by (simp add: bij_def)
   244 
   245 lemma bij_is_surj: "bij f ==> surj f"
   246 by (simp add: bij_def)
   247 
   248 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   249 by (simp add: bij_betw_def)
   250 
   251 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   252 proof -
   253   have i: "inj_on f A" and s: "f ` A = B"
   254     using assms by(auto simp:bij_betw_def)
   255   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   256   { fix a b assume P: "?P b a"
   257     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   258     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   259     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   260   } note g = this
   261   have "inj_on ?g B"
   262   proof(rule inj_onI)
   263     fix x y assume "x:B" "y:B" "?g x = ?g y"
   264     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   265     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   266     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   267   qed
   268   moreover have "?g ` B = A"
   269   proof(auto simp:image_def)
   270     fix b assume "b:B"
   271     with s obtain a where P: "?P b a" unfolding image_def by blast
   272     thus "?g b \<in> A" using g[OF P] by auto
   273   next
   274     fix a assume "a:A"
   275     then obtain b where P: "?P b a" using s unfolding image_def by blast
   276     then have "b:B" using s unfolding image_def by blast
   277     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   278   qed
   279   ultimately show ?thesis by(auto simp:bij_betw_def)
   280 qed
   281 
   282 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   283 by (simp add: surj_range)
   284 
   285 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   286 by (simp add: inj_on_def, blast)
   287 
   288 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   289 apply (unfold surj_def)
   290 apply (blast intro: sym)
   291 done
   292 
   293 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   294 by (unfold inj_on_def, blast)
   295 
   296 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   297 apply (unfold bij_def)
   298 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   299 done
   300 
   301 lemma inj_on_image_Int:
   302    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   303 apply (simp add: inj_on_def, blast)
   304 done
   305 
   306 lemma inj_on_image_set_diff:
   307    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   308 apply (simp add: inj_on_def, blast)
   309 done
   310 
   311 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   312 by (simp add: inj_on_def, blast)
   313 
   314 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   315 by (simp add: inj_on_def, blast)
   316 
   317 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   318 by (blast dest: injD)
   319 
   320 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   321 by (simp add: inj_on_def, blast)
   322 
   323 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   324 by (blast dest: injD)
   325 
   326 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   327 lemma image_INT:
   328    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   329     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   330 apply (simp add: inj_on_def, blast)
   331 done
   332 
   333 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   334   it doesn't matter whether A is empty*)
   335 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   336 apply (simp add: bij_def)
   337 apply (simp add: inj_on_def surj_def, blast)
   338 done
   339 
   340 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   341 by (auto simp add: surj_def)
   342 
   343 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   344 by (auto simp add: inj_on_def)
   345 
   346 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   347 apply (simp add: bij_def)
   348 apply (rule equalityI)
   349 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   350 done
   351 
   352 
   353 subsection{*Function Updating*}
   354 
   355 constdefs
   356   fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)"
   357   "fun_upd f a b == % x. if x=a then b else f x"
   358 
   359 nonterminals
   360   updbinds updbind
   361 syntax
   362   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   363   ""         :: "updbind => updbinds"             ("_")
   364   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   365   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000,0] 900)
   366 
   367 translations
   368   "_Update f (_updbinds b bs)"  == "_Update (_Update f b) bs"
   369   "f(x:=y)"                     == "fun_upd f x y"
   370 
   371 (* Hint: to define the sum of two functions (or maps), use sum_case.
   372          A nice infix syntax could be defined (in Datatype.thy or below) by
   373 consts
   374   fun_sum :: "('a => 'c) => ('b => 'c) => (('a+'b) => 'c)" (infixr "'(+')"80)
   375 translations
   376  "fun_sum" == sum_case
   377 *)
   378 
   379 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   380 apply (simp add: fun_upd_def, safe)
   381 apply (erule subst)
   382 apply (rule_tac [2] ext, auto)
   383 done
   384 
   385 (* f x = y ==> f(x:=y) = f *)
   386 lemmas fun_upd_idem = fun_upd_idem_iff [THEN iffD2, standard]
   387 
   388 (* f(x := f x) = f *)
   389 lemmas fun_upd_triv = refl [THEN fun_upd_idem]
   390 declare fun_upd_triv [iff]
   391 
   392 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   393 by (simp add: fun_upd_def)
   394 
   395 (* fun_upd_apply supersedes these two,   but they are useful
   396    if fun_upd_apply is intentionally removed from the simpset *)
   397 lemma fun_upd_same: "(f(x:=y)) x = y"
   398 by simp
   399 
   400 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   401 by simp
   402 
   403 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   404 by (simp add: expand_fun_eq)
   405 
   406 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   407 by (rule ext, auto)
   408 
   409 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   410 by(fastsimp simp:inj_on_def image_def)
   411 
   412 lemma fun_upd_image:
   413      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   414 by auto
   415 
   416 
   417 subsection {* @{text override_on} *}
   418 
   419 definition
   420   override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
   421 where
   422   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   423 
   424 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   425 by(simp add:override_on_def)
   426 
   427 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   428 by(simp add:override_on_def)
   429 
   430 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   431 by(simp add:override_on_def)
   432 
   433 
   434 subsection {* @{text swap} *}
   435 
   436 definition
   437   swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   438 where
   439   "swap a b f = f (a := f b, b:= f a)"
   440 
   441 lemma swap_self: "swap a a f = f"
   442 by (simp add: swap_def)
   443 
   444 lemma swap_commute: "swap a b f = swap b a f"
   445 by (rule ext, simp add: fun_upd_def swap_def)
   446 
   447 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   448 by (rule ext, simp add: fun_upd_def swap_def)
   449 
   450 lemma inj_on_imp_inj_on_swap:
   451   "[|inj_on f A; a \<in> A; b \<in> A|] ==> inj_on (swap a b f) A"
   452 by (simp add: inj_on_def swap_def, blast)
   453 
   454 lemma inj_on_swap_iff [simp]:
   455   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A = inj_on f A"
   456 proof 
   457   assume "inj_on (swap a b f) A"
   458   with A have "inj_on (swap a b (swap a b f)) A" 
   459     by (iprover intro: inj_on_imp_inj_on_swap) 
   460   thus "inj_on f A" by simp 
   461 next
   462   assume "inj_on f A"
   463   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   464 qed
   465 
   466 lemma surj_imp_surj_swap: "surj f ==> surj (swap a b f)"
   467 apply (simp add: surj_def swap_def, clarify)
   468 apply (rule_tac P = "y = f b" in case_split_thm, blast)
   469 apply (rule_tac P = "y = f a" in case_split_thm, auto)
   470   --{*We don't yet have @{text case_tac}*}
   471 done
   472 
   473 lemma surj_swap_iff [simp]: "surj (swap a b f) = surj f"
   474 proof 
   475   assume "surj (swap a b f)"
   476   hence "surj (swap a b (swap a b f))" by (rule surj_imp_surj_swap) 
   477   thus "surj f" by simp 
   478 next
   479   assume "surj f"
   480   thus "surj (swap a b f)" by (rule surj_imp_surj_swap) 
   481 qed
   482 
   483 lemma bij_swap_iff: "bij (swap a b f) = bij f"
   484 by (simp add: bij_def)
   485 
   486 
   487 subsection {* Proof tool setup *} 
   488 
   489 text {* simplifies terms of the form
   490   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   491 
   492 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   493 let
   494   fun gen_fun_upd NONE T _ _ = NONE
   495     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   496   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   497   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   498     let
   499       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   500             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   501         | find t = NONE
   502     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   503 
   504   fun proc ss ct =
   505     let
   506       val ctxt = Simplifier.the_context ss
   507       val t = Thm.term_of ct
   508     in
   509       case find_double t of
   510         (T, NONE) => NONE
   511       | (T, SOME rhs) =>
   512           SOME (Goal.prove ctxt [] [] (Term.equals T $ t $ rhs)
   513             (fn _ =>
   514               rtac eq_reflection 1 THEN
   515               rtac ext 1 THEN
   516               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   517     end
   518 in proc end
   519 *}
   520 
   521 
   522 subsection {* Code generator setup *}
   523 
   524 types_code
   525   "fun"  ("(_ ->/ _)")
   526 attach (term_of) {*
   527 fun term_of_fun_type _ aT _ bT _ = Free ("<function>", aT --> bT);
   528 *}
   529 attach (test) {*
   530 fun gen_fun_type aF aT bG bT i =
   531   let
   532     val tab = ref [];
   533     fun mk_upd (x, (_, y)) t = Const ("Fun.fun_upd",
   534       (aT --> bT) --> aT --> bT --> aT --> bT) $ t $ aF x $ y ()
   535   in
   536     (fn x =>
   537        case AList.lookup op = (!tab) x of
   538          NONE =>
   539            let val p as (y, _) = bG i
   540            in (tab := (x, p) :: !tab; y) end
   541        | SOME (y, _) => y,
   542      fn () => Basics.fold mk_upd (!tab) (Const ("arbitrary", aT --> bT)))
   543   end;
   544 *}
   545 
   546 code_const "op \<circ>"
   547   (SML infixl 5 "o")
   548   (Haskell infixr 9 ".")
   549 
   550 code_const "id"
   551   (Haskell "id")
   552 
   553 end