src/HOL/Library/Mapping.thy
author bulwahn
Fri Oct 21 11:17:14 2011 +0200 (2011-10-21)
changeset 45231 d85a2fdc586c
parent 41505 6d19301074cf
child 49834 b27bbb021df1
permissions -rw-r--r--
replacing code_inline by code_unfold, removing obsolete code_unfold, code_inline del now that the ancient code generator is removed
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* An abstract view on maps for code generation. *}
     4 
     5 theory Mapping
     6 imports Main
     7 begin
     8 
     9 subsection {* Type definition and primitive operations *}
    10 
    11 typedef (open) ('a, 'b) mapping = "UNIV :: ('a \<rightharpoonup> 'b) set"
    12   morphisms lookup Mapping ..
    13 
    14 lemma lookup_Mapping [simp]:
    15   "lookup (Mapping f) = f"
    16   by (rule Mapping_inverse) rule
    17 
    18 lemma Mapping_lookup [simp]:
    19   "Mapping (lookup m) = m"
    20   by (fact lookup_inverse)
    21 
    22 lemma Mapping_inject [simp]:
    23   "Mapping f = Mapping g \<longleftrightarrow> f = g"
    24   by (simp add: Mapping_inject)
    25 
    26 lemma mapping_eq_iff:
    27   "m = n \<longleftrightarrow> lookup m = lookup n"
    28   by (simp add: lookup_inject)
    29 
    30 lemma mapping_eqI:
    31   "lookup m = lookup n \<Longrightarrow> m = n"
    32   by (simp add: mapping_eq_iff)
    33 
    34 definition empty :: "('a, 'b) mapping" where
    35   "empty = Mapping (\<lambda>_. None)"
    36 
    37 definition update :: "'a \<Rightarrow> 'b \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping" where
    38   "update k v m = Mapping ((lookup m)(k \<mapsto> v))"
    39 
    40 definition delete :: "'a \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping" where
    41   "delete k m = Mapping ((lookup m)(k := None))"
    42 
    43 
    44 subsection {* Functorial structure *}
    45 
    46 definition map :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('c, 'd) mapping" where
    47   "map f g m = Mapping (Option.map g \<circ> lookup m \<circ> f)"
    48 
    49 lemma lookup_map [simp]:
    50   "lookup (map f g m) = Option.map g \<circ> lookup m \<circ> f"
    51   by (simp add: map_def)
    52 
    53 enriched_type map: map
    54   by (simp_all add: mapping_eq_iff fun_eq_iff Option.map.compositionality Option.map.id)
    55 
    56 
    57 subsection {* Derived operations *}
    58 
    59 definition keys :: "('a, 'b) mapping \<Rightarrow> 'a set" where
    60   "keys m = dom (lookup m)"
    61 
    62 definition ordered_keys :: "('a\<Colon>linorder, 'b) mapping \<Rightarrow> 'a list" where
    63   "ordered_keys m = (if finite (keys m) then sorted_list_of_set (keys m) else [])"
    64 
    65 definition is_empty :: "('a, 'b) mapping \<Rightarrow> bool" where
    66   "is_empty m \<longleftrightarrow> keys m = {}"
    67 
    68 definition size :: "('a, 'b) mapping \<Rightarrow> nat" where
    69   "size m = (if finite (keys m) then card (keys m) else 0)"
    70 
    71 definition replace :: "'a \<Rightarrow> 'b \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping" where
    72   "replace k v m = (if k \<in> keys m then update k v m else m)"
    73 
    74 definition default :: "'a \<Rightarrow> 'b \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping" where
    75   "default k v m = (if k \<in> keys m then m else update k v m)"
    76 
    77 definition map_entry :: "'a \<Rightarrow> ('b \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping" where
    78   "map_entry k f m = (case lookup m k of None \<Rightarrow> m
    79     | Some v \<Rightarrow> update k (f v) m)" 
    80 
    81 definition map_default :: "'a \<Rightarrow> 'b \<Rightarrow> ('b \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) mapping \<Rightarrow> ('a, 'b) mapping" where
    82   "map_default k v f m = map_entry k f (default k v m)" 
    83 
    84 definition tabulate :: "'a list \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a, 'b) mapping" where
    85   "tabulate ks f = Mapping (map_of (List.map (\<lambda>k. (k, f k)) ks))"
    86 
    87 definition bulkload :: "'a list \<Rightarrow> (nat, 'a) mapping" where
    88   "bulkload xs = Mapping (\<lambda>k. if k < length xs then Some (xs ! k) else None)"
    89 
    90 
    91 subsection {* Properties *}
    92 
    93 lemma keys_is_none_lookup [code_unfold]:
    94   "k \<in> keys m \<longleftrightarrow> \<not> (Option.is_none (lookup m k))"
    95   by (auto simp add: keys_def is_none_def)
    96 
    97 lemma lookup_empty [simp]:
    98   "lookup empty = Map.empty"
    99   by (simp add: empty_def)
   100 
   101 lemma lookup_update [simp]:
   102   "lookup (update k v m) = (lookup m) (k \<mapsto> v)"
   103   by (simp add: update_def)
   104 
   105 lemma lookup_delete [simp]:
   106   "lookup (delete k m) = (lookup m) (k := None)"
   107   by (simp add: delete_def)
   108 
   109 lemma lookup_map_entry [simp]:
   110   "lookup (map_entry k f m) = (lookup m) (k := Option.map f (lookup m k))"
   111   by (cases "lookup m k") (simp_all add: map_entry_def fun_eq_iff)
   112 
   113 lemma lookup_tabulate [simp]:
   114   "lookup (tabulate ks f) = (Some o f) |` set ks"
   115   by (induct ks) (auto simp add: tabulate_def restrict_map_def fun_eq_iff)
   116 
   117 lemma lookup_bulkload [simp]:
   118   "lookup (bulkload xs) = (\<lambda>k. if k < length xs then Some (xs ! k) else None)"
   119   by (simp add: bulkload_def)
   120 
   121 lemma update_update:
   122   "update k v (update k w m) = update k v m"
   123   "k \<noteq> l \<Longrightarrow> update k v (update l w m) = update l w (update k v m)"
   124   by (rule mapping_eqI, simp add: fun_upd_twist)+
   125 
   126 lemma update_delete [simp]:
   127   "update k v (delete k m) = update k v m"
   128   by (rule mapping_eqI) simp
   129 
   130 lemma delete_update:
   131   "delete k (update k v m) = delete k m"
   132   "k \<noteq> l \<Longrightarrow> delete k (update l v m) = update l v (delete k m)"
   133   by (rule mapping_eqI, simp add: fun_upd_twist)+
   134 
   135 lemma delete_empty [simp]:
   136   "delete k empty = empty"
   137   by (rule mapping_eqI) simp
   138 
   139 lemma replace_update:
   140   "k \<notin> keys m \<Longrightarrow> replace k v m = m"
   141   "k \<in> keys m \<Longrightarrow> replace k v m = update k v m"
   142   by (rule mapping_eqI) (auto simp add: replace_def fun_upd_twist)+
   143 
   144 lemma size_empty [simp]:
   145   "size empty = 0"
   146   by (simp add: size_def keys_def)
   147 
   148 lemma size_update:
   149   "finite (keys m) \<Longrightarrow> size (update k v m) =
   150     (if k \<in> keys m then size m else Suc (size m))"
   151   by (auto simp add: size_def insert_dom keys_def)
   152 
   153 lemma size_delete:
   154   "size (delete k m) = (if k \<in> keys m then size m - 1 else size m)"
   155   by (simp add: size_def keys_def)
   156 
   157 lemma size_tabulate [simp]:
   158   "size (tabulate ks f) = length (remdups ks)"
   159   by (simp add: size_def distinct_card [of "remdups ks", symmetric] comp_def keys_def)
   160 
   161 lemma bulkload_tabulate:
   162   "bulkload xs = tabulate [0..<length xs] (nth xs)"
   163   by (rule mapping_eqI) (simp add: fun_eq_iff)
   164 
   165 lemma is_empty_empty: (*FIXME*)
   166   "is_empty m \<longleftrightarrow> m = Mapping Map.empty"
   167   by (cases m) (simp add: is_empty_def keys_def)
   168 
   169 lemma is_empty_empty' [simp]:
   170   "is_empty empty"
   171   by (simp add: is_empty_empty empty_def) 
   172 
   173 lemma is_empty_update [simp]:
   174   "\<not> is_empty (update k v m)"
   175   by (simp add: is_empty_empty update_def)
   176 
   177 lemma is_empty_delete:
   178   "is_empty (delete k m) \<longleftrightarrow> is_empty m \<or> keys m = {k}"
   179   by (auto simp add: delete_def is_empty_def keys_def simp del: dom_eq_empty_conv)
   180 
   181 lemma is_empty_replace [simp]:
   182   "is_empty (replace k v m) \<longleftrightarrow> is_empty m"
   183   by (auto simp add: replace_def) (simp add: is_empty_def)
   184 
   185 lemma is_empty_default [simp]:
   186   "\<not> is_empty (default k v m)"
   187   by (auto simp add: default_def) (simp add: is_empty_def)
   188 
   189 lemma is_empty_map_entry [simp]:
   190   "is_empty (map_entry k f m) \<longleftrightarrow> is_empty m"
   191   by (cases "lookup m k")
   192     (auto simp add: map_entry_def, simp add: is_empty_empty)
   193 
   194 lemma is_empty_map_default [simp]:
   195   "\<not> is_empty (map_default k v f m)"
   196   by (simp add: map_default_def)
   197 
   198 lemma keys_empty [simp]:
   199   "keys empty = {}"
   200   by (simp add: keys_def)
   201 
   202 lemma keys_update [simp]:
   203   "keys (update k v m) = insert k (keys m)"
   204   by (simp add: keys_def)
   205 
   206 lemma keys_delete [simp]:
   207   "keys (delete k m) = keys m - {k}"
   208   by (simp add: keys_def)
   209 
   210 lemma keys_replace [simp]:
   211   "keys (replace k v m) = keys m"
   212   by (auto simp add: keys_def replace_def)
   213 
   214 lemma keys_default [simp]:
   215   "keys (default k v m) = insert k (keys m)"
   216   by (auto simp add: keys_def default_def)
   217 
   218 lemma keys_map_entry [simp]:
   219   "keys (map_entry k f m) = keys m"
   220   by (auto simp add: keys_def)
   221 
   222 lemma keys_map_default [simp]:
   223   "keys (map_default k v f m) = insert k (keys m)"
   224   by (simp add: map_default_def)
   225 
   226 lemma keys_tabulate [simp]:
   227   "keys (tabulate ks f) = set ks"
   228   by (simp add: tabulate_def keys_def map_of_map_restrict o_def)
   229 
   230 lemma keys_bulkload [simp]:
   231   "keys (bulkload xs) = {0..<length xs}"
   232   by (simp add: keys_tabulate bulkload_tabulate)
   233 
   234 lemma distinct_ordered_keys [simp]:
   235   "distinct (ordered_keys m)"
   236   by (simp add: ordered_keys_def)
   237 
   238 lemma ordered_keys_infinite [simp]:
   239   "\<not> finite (keys m) \<Longrightarrow> ordered_keys m = []"
   240   by (simp add: ordered_keys_def)
   241 
   242 lemma ordered_keys_empty [simp]:
   243   "ordered_keys empty = []"
   244   by (simp add: ordered_keys_def)
   245 
   246 lemma ordered_keys_update [simp]:
   247   "k \<in> keys m \<Longrightarrow> ordered_keys (update k v m) = ordered_keys m"
   248   "finite (keys m) \<Longrightarrow> k \<notin> keys m \<Longrightarrow> ordered_keys (update k v m) = insort k (ordered_keys m)"
   249   by (simp_all add: ordered_keys_def) (auto simp only: sorted_list_of_set_insert [symmetric] insert_absorb)
   250 
   251 lemma ordered_keys_delete [simp]:
   252   "ordered_keys (delete k m) = remove1 k (ordered_keys m)"
   253 proof (cases "finite (keys m)")
   254   case False then show ?thesis by simp
   255 next
   256   case True note fin = True
   257   show ?thesis
   258   proof (cases "k \<in> keys m")
   259     case False with fin have "k \<notin> set (sorted_list_of_set (keys m))" by simp
   260     with False show ?thesis by (simp add: ordered_keys_def remove1_idem)
   261   next
   262     case True with fin show ?thesis by (simp add: ordered_keys_def sorted_list_of_set_remove)
   263   qed
   264 qed
   265 
   266 lemma ordered_keys_replace [simp]:
   267   "ordered_keys (replace k v m) = ordered_keys m"
   268   by (simp add: replace_def)
   269 
   270 lemma ordered_keys_default [simp]:
   271   "k \<in> keys m \<Longrightarrow> ordered_keys (default k v m) = ordered_keys m"
   272   "finite (keys m) \<Longrightarrow> k \<notin> keys m \<Longrightarrow> ordered_keys (default k v m) = insort k (ordered_keys m)"
   273   by (simp_all add: default_def)
   274 
   275 lemma ordered_keys_map_entry [simp]:
   276   "ordered_keys (map_entry k f m) = ordered_keys m"
   277   by (simp add: ordered_keys_def)
   278 
   279 lemma ordered_keys_map_default [simp]:
   280   "k \<in> keys m \<Longrightarrow> ordered_keys (map_default k v f m) = ordered_keys m"
   281   "finite (keys m) \<Longrightarrow> k \<notin> keys m \<Longrightarrow> ordered_keys (map_default k v f m) = insort k (ordered_keys m)"
   282   by (simp_all add: map_default_def)
   283 
   284 lemma ordered_keys_tabulate [simp]:
   285   "ordered_keys (tabulate ks f) = sort (remdups ks)"
   286   by (simp add: ordered_keys_def sorted_list_of_set_sort_remdups)
   287 
   288 lemma ordered_keys_bulkload [simp]:
   289   "ordered_keys (bulkload ks) = [0..<length ks]"
   290   by (simp add: ordered_keys_def)
   291 
   292 
   293 subsection {* Code generator setup *}
   294 
   295 code_datatype empty update
   296 
   297 instantiation mapping :: (type, type) equal
   298 begin
   299 
   300 definition [code del]:
   301   "HOL.equal m n \<longleftrightarrow> lookup m = lookup n"
   302 
   303 instance proof
   304 qed (simp add: equal_mapping_def mapping_eq_iff)
   305 
   306 end
   307 
   308 
   309 hide_const (open) empty is_empty lookup update delete ordered_keys keys size
   310   replace default map_entry map_default tabulate bulkload map
   311 
   312 end