src/HOL/Typerep.thy
author bulwahn
Fri Oct 21 11:17:14 2011 +0200 (2011-10-21)
changeset 45231 d85a2fdc586c
parent 43329 84472e198515
child 45693 bbd2c7ffc02c
permissions -rw-r--r--
replacing code_inline by code_unfold, removing obsolete code_unfold, code_inline del now that the ancient code generator is removed
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Reflecting Pure types into HOL *}
     4 
     5 theory Typerep
     6 imports Plain String
     7 begin
     8 
     9 datatype typerep = Typerep String.literal "typerep list"
    10 
    11 class typerep =
    12   fixes typerep :: "'a itself \<Rightarrow> typerep"
    13 begin
    14 
    15 definition typerep_of :: "'a \<Rightarrow> typerep" where
    16   [simp]: "typerep_of x = typerep TYPE('a)"
    17 
    18 end
    19 
    20 syntax
    21   "_TYPEREP" :: "type => logic"  ("(1TYPEREP/(1'(_')))")
    22 
    23 parse_translation {*
    24 let
    25   fun typerep_tr (*"_TYPEREP"*) [ty] =
    26         Syntax.const @{const_syntax typerep} $
    27           (Syntax.const @{syntax_const "_constrain"} $ Syntax.const @{const_syntax "TYPE"} $
    28             (Syntax.const @{type_syntax itself} $ ty))
    29     | typerep_tr (*"_TYPEREP"*) ts = raise TERM ("typerep_tr", ts);
    30 in [(@{syntax_const "_TYPEREP"}, typerep_tr)] end
    31 *}
    32 
    33 typed_print_translation (advanced) {*
    34 let
    35   fun typerep_tr' ctxt (*"typerep"*)
    36           (Type (@{type_name fun}, [Type (@{type_name itself}, [T]), _]))
    37           (Const (@{const_syntax TYPE}, _) :: ts) =
    38         Term.list_comb
    39           (Syntax.const @{syntax_const "_TYPEREP"} $ Syntax_Phases.term_of_typ ctxt T, ts)
    40     | typerep_tr' _ T ts = raise Match;
    41 in [(@{const_syntax typerep}, typerep_tr')] end
    42 *}
    43 
    44 setup {*
    45 let
    46 
    47 fun add_typerep tyco thy =
    48   let
    49     val sorts = replicate (Sign.arity_number thy tyco) @{sort typerep};
    50     val vs = Name.invent_names Name.context "'a" sorts;
    51     val ty = Type (tyco, map TFree vs);
    52     val lhs = Const (@{const_name typerep}, Term.itselfT ty --> @{typ typerep})
    53       $ Free ("T", Term.itselfT ty);
    54     val rhs = @{term Typerep} $ HOLogic.mk_literal tyco
    55       $ HOLogic.mk_list @{typ typerep} (map (HOLogic.mk_typerep o TFree) vs);
    56     val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs));
    57   in
    58     thy
    59     |> Class.instantiation ([tyco], vs, @{sort typerep})
    60     |> `(fn lthy => Syntax.check_term lthy eq)
    61     |-> (fn eq => Specification.definition (NONE, (Attrib.empty_binding, eq)))
    62     |> snd
    63     |> Class.prove_instantiation_exit (K (Class.intro_classes_tac []))
    64   end;
    65 
    66 fun ensure_typerep tyco thy = if not (can (Sorts.mg_domain (Sign.classes_of thy) tyco) @{sort typerep})
    67   andalso can (Sorts.mg_domain (Sign.classes_of thy) tyco) @{sort type}
    68   then add_typerep tyco thy else thy;
    69 
    70 in
    71 
    72 add_typerep @{type_name fun}
    73 #> Typedef.interpretation ensure_typerep
    74 #> Code.datatype_interpretation (ensure_typerep o fst)
    75 #> Code.abstype_interpretation (ensure_typerep o fst)
    76 
    77 end
    78 *}
    79 
    80 lemma [code]:
    81   "HOL.equal (Typerep tyco1 tys1) (Typerep tyco2 tys2) \<longleftrightarrow> HOL.equal tyco1 tyco2
    82      \<and> list_all2 HOL.equal tys1 tys2"
    83   by (auto simp add: eq_equal [symmetric] list_all2_eq [symmetric])
    84 
    85 lemma [code nbe]:
    86   "HOL.equal (x :: typerep) x \<longleftrightarrow> True"
    87   by (fact equal_refl)
    88 
    89 code_type typerep
    90   (Eval "Term.typ")
    91 
    92 code_const Typerep
    93   (Eval "Term.Type/ (_, _)")
    94 
    95 code_reserved Eval Term
    96 
    97 hide_const (open) typerep Typerep
    98 
    99 end