src/HOL/Wellfounded.thy
author bulwahn
Fri Oct 21 11:17:14 2011 +0200 (2011-10-21)
changeset 45231 d85a2fdc586c
parent 45139 bdcaa3f3a2f4
child 45970 b6d0cff57d96
permissions -rw-r--r--
replacing code_inline by code_unfold, removing obsolete code_unfold, code_inline del now that the ancient code generator is removed
     1 (*  Title:      HOL/Wellfounded.thy
     2     Author:     Tobias Nipkow
     3     Author:     Lawrence C Paulson
     4     Author:     Konrad Slind
     5     Author:     Alexander Krauss
     6 *)
     7 
     8 header {*Well-founded Recursion*}
     9 
    10 theory Wellfounded
    11 imports Transitive_Closure
    12 uses ("Tools/Function/size.ML")
    13 begin
    14 
    15 subsection {* Basic Definitions *}
    16 
    17 definition wf :: "('a * 'a) set => bool" where
    18   "wf r \<longleftrightarrow> (!P. (!x. (!y. (y,x):r --> P(y)) --> P(x)) --> (!x. P(x)))"
    19 
    20 definition wfP :: "('a => 'a => bool) => bool" where
    21   "wfP r \<longleftrightarrow> wf {(x, y). r x y}"
    22 
    23 lemma wfP_wf_eq [pred_set_conv]: "wfP (\<lambda>x y. (x, y) \<in> r) = wf r"
    24   by (simp add: wfP_def)
    25 
    26 lemma wfUNIVI: 
    27    "(!!P x. (ALL x. (ALL y. (y,x) : r --> P(y)) --> P(x)) ==> P(x)) ==> wf(r)"
    28   unfolding wf_def by blast
    29 
    30 lemmas wfPUNIVI = wfUNIVI [to_pred]
    31 
    32 text{*Restriction to domain @{term A} and range @{term B}.  If @{term r} is
    33     well-founded over their intersection, then @{term "wf r"}*}
    34 lemma wfI: 
    35  "[| r \<subseteq> A <*> B; 
    36      !!x P. [|\<forall>x. (\<forall>y. (y,x) : r --> P y) --> P x;  x : A; x : B |] ==> P x |]
    37   ==>  wf r"
    38   unfolding wf_def by blast
    39 
    40 lemma wf_induct: 
    41     "[| wf(r);           
    42         !!x.[| ALL y. (y,x): r --> P(y) |] ==> P(x)  
    43      |]  ==>  P(a)"
    44   unfolding wf_def by blast
    45 
    46 lemmas wfP_induct = wf_induct [to_pred]
    47 
    48 lemmas wf_induct_rule = wf_induct [rule_format, consumes 1, case_names less, induct set: wf]
    49 
    50 lemmas wfP_induct_rule = wf_induct_rule [to_pred, induct set: wfP]
    51 
    52 lemma wf_not_sym: "wf r ==> (a, x) : r ==> (x, a) ~: r"
    53   by (induct a arbitrary: x set: wf) blast
    54 
    55 lemma wf_asym:
    56   assumes "wf r" "(a, x) \<in> r"
    57   obtains "(x, a) \<notin> r"
    58   by (drule wf_not_sym[OF assms])
    59 
    60 lemma wf_not_refl [simp]: "wf r ==> (a, a) ~: r"
    61   by (blast elim: wf_asym)
    62 
    63 lemma wf_irrefl: assumes "wf r" obtains "(a, a) \<notin> r"
    64 by (drule wf_not_refl[OF assms])
    65 
    66 lemma wf_wellorderI:
    67   assumes wf: "wf {(x::'a::ord, y). x < y}"
    68   assumes lin: "OFCLASS('a::ord, linorder_class)"
    69   shows "OFCLASS('a::ord, wellorder_class)"
    70 using lin by (rule wellorder_class.intro)
    71   (blast intro: class.wellorder_axioms.intro wf_induct_rule [OF wf])
    72 
    73 lemma (in wellorder) wf:
    74   "wf {(x, y). x < y}"
    75 unfolding wf_def by (blast intro: less_induct)
    76 
    77 
    78 subsection {* Basic Results *}
    79 
    80 text {* Point-free characterization of well-foundedness *}
    81 
    82 lemma wfE_pf:
    83   assumes wf: "wf R"
    84   assumes a: "A \<subseteq> R `` A"
    85   shows "A = {}"
    86 proof -
    87   { fix x
    88     from wf have "x \<notin> A"
    89     proof induct
    90       fix x assume "\<And>y. (y, x) \<in> R \<Longrightarrow> y \<notin> A"
    91       then have "x \<notin> R `` A" by blast
    92       with a show "x \<notin> A" by blast
    93     qed
    94   } thus ?thesis by auto
    95 qed
    96 
    97 lemma wfI_pf:
    98   assumes a: "\<And>A. A \<subseteq> R `` A \<Longrightarrow> A = {}"
    99   shows "wf R"
   100 proof (rule wfUNIVI)
   101   fix P :: "'a \<Rightarrow> bool" and x
   102   let ?A = "{x. \<not> P x}"
   103   assume "\<forall>x. (\<forall>y. (y, x) \<in> R \<longrightarrow> P y) \<longrightarrow> P x"
   104   then have "?A \<subseteq> R `` ?A" by blast
   105   with a show "P x" by blast
   106 qed
   107 
   108 text{*Minimal-element characterization of well-foundedness*}
   109 
   110 lemma wfE_min:
   111   assumes wf: "wf R" and Q: "x \<in> Q"
   112   obtains z where "z \<in> Q" "\<And>y. (y, z) \<in> R \<Longrightarrow> y \<notin> Q"
   113   using Q wfE_pf[OF wf, of Q] by blast
   114 
   115 lemma wfI_min:
   116   assumes a: "\<And>x Q. x \<in> Q \<Longrightarrow> \<exists>z\<in>Q. \<forall>y. (y, z) \<in> R \<longrightarrow> y \<notin> Q"
   117   shows "wf R"
   118 proof (rule wfI_pf)
   119   fix A assume b: "A \<subseteq> R `` A"
   120   { fix x assume "x \<in> A"
   121     from a[OF this] b have "False" by blast
   122   }
   123   thus "A = {}" by blast
   124 qed
   125 
   126 lemma wf_eq_minimal: "wf r = (\<forall>Q x. x\<in>Q --> (\<exists>z\<in>Q. \<forall>y. (y,z)\<in>r --> y\<notin>Q))"
   127 apply auto
   128 apply (erule wfE_min, assumption, blast)
   129 apply (rule wfI_min, auto)
   130 done
   131 
   132 lemmas wfP_eq_minimal = wf_eq_minimal [to_pred]
   133 
   134 text{* Well-foundedness of transitive closure *}
   135 
   136 lemma wf_trancl:
   137   assumes "wf r"
   138   shows "wf (r^+)"
   139 proof -
   140   {
   141     fix P and x
   142     assume induct_step: "!!x. (!!y. (y, x) : r^+ ==> P y) ==> P x"
   143     have "P x"
   144     proof (rule induct_step)
   145       fix y assume "(y, x) : r^+"
   146       with `wf r` show "P y"
   147       proof (induct x arbitrary: y)
   148         case (less x)
   149         note hyp = `\<And>x' y'. (x', x) : r ==> (y', x') : r^+ ==> P y'`
   150         from `(y, x) : r^+` show "P y"
   151         proof cases
   152           case base
   153           show "P y"
   154           proof (rule induct_step)
   155             fix y' assume "(y', y) : r^+"
   156             with `(y, x) : r` show "P y'" by (rule hyp [of y y'])
   157           qed
   158         next
   159           case step
   160           then obtain x' where "(x', x) : r" and "(y, x') : r^+" by simp
   161           then show "P y" by (rule hyp [of x' y])
   162         qed
   163       qed
   164     qed
   165   } then show ?thesis unfolding wf_def by blast
   166 qed
   167 
   168 lemmas wfP_trancl = wf_trancl [to_pred]
   169 
   170 lemma wf_converse_trancl: "wf (r^-1) ==> wf ((r^+)^-1)"
   171   apply (subst trancl_converse [symmetric])
   172   apply (erule wf_trancl)
   173   done
   174 
   175 text {* Well-foundedness of subsets *}
   176 
   177 lemma wf_subset: "[| wf(r);  p<=r |] ==> wf(p)"
   178   apply (simp (no_asm_use) add: wf_eq_minimal)
   179   apply fast
   180   done
   181 
   182 lemmas wfP_subset = wf_subset [to_pred]
   183 
   184 text {* Well-foundedness of the empty relation *}
   185 
   186 lemma wf_empty [iff]: "wf {}"
   187   by (simp add: wf_def)
   188 
   189 lemma wfP_empty [iff]:
   190   "wfP (\<lambda>x y. False)"
   191 proof -
   192   have "wfP bot" by (fact wf_empty [to_pred bot_empty_eq2])
   193   then show ?thesis by (simp add: bot_fun_def)
   194 qed
   195 
   196 lemma wf_Int1: "wf r ==> wf (r Int r')"
   197   apply (erule wf_subset)
   198   apply (rule Int_lower1)
   199   done
   200 
   201 lemma wf_Int2: "wf r ==> wf (r' Int r)"
   202   apply (erule wf_subset)
   203   apply (rule Int_lower2)
   204   done  
   205 
   206 text {* Exponentiation *}
   207 
   208 lemma wf_exp:
   209   assumes "wf (R ^^ n)"
   210   shows "wf R"
   211 proof (rule wfI_pf)
   212   fix A assume "A \<subseteq> R `` A"
   213   then have "A \<subseteq> (R ^^ n) `` A" by (induct n) force+
   214   with `wf (R ^^ n)`
   215   show "A = {}" by (rule wfE_pf)
   216 qed
   217 
   218 text {* Well-foundedness of insert *}
   219 
   220 lemma wf_insert [iff]: "wf(insert (y,x) r) = (wf(r) & (x,y) ~: r^*)"
   221 apply (rule iffI)
   222  apply (blast elim: wf_trancl [THEN wf_irrefl]
   223               intro: rtrancl_into_trancl1 wf_subset 
   224                      rtrancl_mono [THEN [2] rev_subsetD])
   225 apply (simp add: wf_eq_minimal, safe)
   226 apply (rule allE, assumption, erule impE, blast) 
   227 apply (erule bexE)
   228 apply (rename_tac "a", case_tac "a = x")
   229  prefer 2
   230 apply blast 
   231 apply (case_tac "y:Q")
   232  prefer 2 apply blast
   233 apply (rule_tac x = "{z. z:Q & (z,y) : r^*}" in allE)
   234  apply assumption
   235 apply (erule_tac V = "ALL Q. (EX x. x : Q) --> ?P Q" in thin_rl) 
   236   --{*essential for speed*}
   237 txt{*Blast with new substOccur fails*}
   238 apply (fast intro: converse_rtrancl_into_rtrancl)
   239 done
   240 
   241 text{*Well-foundedness of image*}
   242 
   243 lemma wf_map_pair_image: "[| wf r; inj f |] ==> wf(map_pair f f ` r)"
   244 apply (simp only: wf_eq_minimal, clarify)
   245 apply (case_tac "EX p. f p : Q")
   246 apply (erule_tac x = "{p. f p : Q}" in allE)
   247 apply (fast dest: inj_onD, blast)
   248 done
   249 
   250 
   251 subsection {* Well-Foundedness Results for Unions *}
   252 
   253 lemma wf_union_compatible:
   254   assumes "wf R" "wf S"
   255   assumes "R O S \<subseteq> R"
   256   shows "wf (R \<union> S)"
   257 proof (rule wfI_min)
   258   fix x :: 'a and Q 
   259   let ?Q' = "{x \<in> Q. \<forall>y. (y, x) \<in> R \<longrightarrow> y \<notin> Q}"
   260   assume "x \<in> Q"
   261   obtain a where "a \<in> ?Q'"
   262     by (rule wfE_min [OF `wf R` `x \<in> Q`]) blast
   263   with `wf S`
   264   obtain z where "z \<in> ?Q'" and zmin: "\<And>y. (y, z) \<in> S \<Longrightarrow> y \<notin> ?Q'" by (erule wfE_min)
   265   { 
   266     fix y assume "(y, z) \<in> S"
   267     then have "y \<notin> ?Q'" by (rule zmin)
   268 
   269     have "y \<notin> Q"
   270     proof 
   271       assume "y \<in> Q"
   272       with `y \<notin> ?Q'` 
   273       obtain w where "(w, y) \<in> R" and "w \<in> Q" by auto
   274       from `(w, y) \<in> R` `(y, z) \<in> S` have "(w, z) \<in> R O S" by (rule rel_compI)
   275       with `R O S \<subseteq> R` have "(w, z) \<in> R" ..
   276       with `z \<in> ?Q'` have "w \<notin> Q" by blast 
   277       with `w \<in> Q` show False by contradiction
   278     qed
   279   }
   280   with `z \<in> ?Q'` show "\<exists>z\<in>Q. \<forall>y. (y, z) \<in> R \<union> S \<longrightarrow> y \<notin> Q" by blast
   281 qed
   282 
   283 
   284 text {* Well-foundedness of indexed union with disjoint domains and ranges *}
   285 
   286 lemma wf_UN: "[| ALL i:I. wf(r i);  
   287          ALL i:I. ALL j:I. r i ~= r j --> Domain(r i) Int Range(r j) = {}  
   288       |] ==> wf(UN i:I. r i)"
   289 apply (simp only: wf_eq_minimal, clarify)
   290 apply (rename_tac A a, case_tac "EX i:I. EX a:A. EX b:A. (b,a) : r i")
   291  prefer 2
   292  apply force 
   293 apply clarify
   294 apply (drule bspec, assumption)  
   295 apply (erule_tac x="{a. a:A & (EX b:A. (b,a) : r i) }" in allE)
   296 apply (blast elim!: allE)  
   297 done
   298 
   299 lemma wfP_SUP:
   300   "\<forall>i. wfP (r i) \<Longrightarrow> \<forall>i j. r i \<noteq> r j \<longrightarrow> inf (DomainP (r i)) (RangeP (r j)) = bot \<Longrightarrow> wfP (SUPR UNIV r)"
   301   by (rule wf_UN [where I=UNIV and r="\<lambda>i. {(x, y). r i x y}", to_pred SUP_UN_eq2])
   302     (simp_all add: Collect_def)
   303 
   304 lemma wf_Union: 
   305  "[| ALL r:R. wf r;  
   306      ALL r:R. ALL s:R. r ~= s --> Domain r Int Range s = {}  
   307   |] ==> wf(Union R)"
   308   using wf_UN[of R "\<lambda>i. i"] by (simp add: SUP_def)
   309 
   310 (*Intuition: we find an (R u S)-min element of a nonempty subset A
   311              by case distinction.
   312   1. There is a step a -R-> b with a,b : A.
   313      Pick an R-min element z of the (nonempty) set {a:A | EX b:A. a -R-> b}.
   314      By definition, there is z':A s.t. z -R-> z'. Because z is R-min in the
   315      subset, z' must be R-min in A. Because z' has an R-predecessor, it cannot
   316      have an S-successor and is thus S-min in A as well.
   317   2. There is no such step.
   318      Pick an S-min element of A. In this case it must be an R-min
   319      element of A as well.
   320 
   321 *)
   322 lemma wf_Un:
   323      "[| wf r; wf s; Domain r Int Range s = {} |] ==> wf(r Un s)"
   324   using wf_union_compatible[of s r] 
   325   by (auto simp: Un_ac)
   326 
   327 lemma wf_union_merge: 
   328   "wf (R \<union> S) = wf (R O R \<union> S O R \<union> S)" (is "wf ?A = wf ?B")
   329 proof
   330   assume "wf ?A"
   331   with wf_trancl have wfT: "wf (?A^+)" .
   332   moreover have "?B \<subseteq> ?A^+"
   333     by (subst trancl_unfold, subst trancl_unfold) blast
   334   ultimately show "wf ?B" by (rule wf_subset)
   335 next
   336   assume "wf ?B"
   337 
   338   show "wf ?A"
   339   proof (rule wfI_min)
   340     fix Q :: "'a set" and x 
   341     assume "x \<in> Q"
   342 
   343     with `wf ?B`
   344     obtain z where "z \<in> Q" and "\<And>y. (y, z) \<in> ?B \<Longrightarrow> y \<notin> Q" 
   345       by (erule wfE_min)
   346     then have A1: "\<And>y. (y, z) \<in> R O R \<Longrightarrow> y \<notin> Q"
   347       and A2: "\<And>y. (y, z) \<in> S O R \<Longrightarrow> y \<notin> Q"
   348       and A3: "\<And>y. (y, z) \<in> S \<Longrightarrow> y \<notin> Q"
   349       by auto
   350     
   351     show "\<exists>z\<in>Q. \<forall>y. (y, z) \<in> ?A \<longrightarrow> y \<notin> Q"
   352     proof (cases "\<forall>y. (y, z) \<in> R \<longrightarrow> y \<notin> Q")
   353       case True
   354       with `z \<in> Q` A3 show ?thesis by blast
   355     next
   356       case False 
   357       then obtain z' where "z'\<in>Q" "(z', z) \<in> R" by blast
   358 
   359       have "\<forall>y. (y, z') \<in> ?A \<longrightarrow> y \<notin> Q"
   360       proof (intro allI impI)
   361         fix y assume "(y, z') \<in> ?A"
   362         then show "y \<notin> Q"
   363         proof
   364           assume "(y, z') \<in> R" 
   365           then have "(y, z) \<in> R O R" using `(z', z) \<in> R` ..
   366           with A1 show "y \<notin> Q" .
   367         next
   368           assume "(y, z') \<in> S" 
   369           then have "(y, z) \<in> S O R" using  `(z', z) \<in> R` ..
   370           with A2 show "y \<notin> Q" .
   371         qed
   372       qed
   373       with `z' \<in> Q` show ?thesis ..
   374     qed
   375   qed
   376 qed
   377 
   378 lemma wf_comp_self: "wf R = wf (R O R)"  -- {* special case *}
   379   by (rule wf_union_merge [where S = "{}", simplified])
   380 
   381 
   382 subsection {* Acyclic relations *}
   383 
   384 lemma wf_acyclic: "wf r ==> acyclic r"
   385 apply (simp add: acyclic_def)
   386 apply (blast elim: wf_trancl [THEN wf_irrefl])
   387 done
   388 
   389 lemmas wfP_acyclicP = wf_acyclic [to_pred]
   390 
   391 text{* Wellfoundedness of finite acyclic relations*}
   392 
   393 lemma finite_acyclic_wf [rule_format]: "finite r ==> acyclic r --> wf r"
   394 apply (erule finite_induct, blast)
   395 apply (simp (no_asm_simp) only: split_tupled_all)
   396 apply simp
   397 done
   398 
   399 lemma finite_acyclic_wf_converse: "[|finite r; acyclic r|] ==> wf (r^-1)"
   400 apply (erule finite_converse [THEN iffD2, THEN finite_acyclic_wf])
   401 apply (erule acyclic_converse [THEN iffD2])
   402 done
   403 
   404 lemma wf_iff_acyclic_if_finite: "finite r ==> wf r = acyclic r"
   405 by (blast intro: finite_acyclic_wf wf_acyclic)
   406 
   407 
   408 subsection {* @{typ nat} is well-founded *}
   409 
   410 lemma less_nat_rel: "op < = (\<lambda>m n. n = Suc m)^++"
   411 proof (rule ext, rule ext, rule iffI)
   412   fix n m :: nat
   413   assume "m < n"
   414   then show "(\<lambda>m n. n = Suc m)^++ m n"
   415   proof (induct n)
   416     case 0 then show ?case by auto
   417   next
   418     case (Suc n) then show ?case
   419       by (auto simp add: less_Suc_eq_le le_less intro: tranclp.trancl_into_trancl)
   420   qed
   421 next
   422   fix n m :: nat
   423   assume "(\<lambda>m n. n = Suc m)^++ m n"
   424   then show "m < n"
   425     by (induct n)
   426       (simp_all add: less_Suc_eq_le reflexive le_less)
   427 qed
   428 
   429 definition
   430   pred_nat :: "(nat * nat) set" where
   431   "pred_nat = {(m, n). n = Suc m}"
   432 
   433 definition
   434   less_than :: "(nat * nat) set" where
   435   "less_than = pred_nat^+"
   436 
   437 lemma less_eq: "(m, n) \<in> pred_nat^+ \<longleftrightarrow> m < n"
   438   unfolding less_nat_rel pred_nat_def trancl_def by simp
   439 
   440 lemma pred_nat_trancl_eq_le:
   441   "(m, n) \<in> pred_nat^* \<longleftrightarrow> m \<le> n"
   442   unfolding less_eq rtrancl_eq_or_trancl by auto
   443 
   444 lemma wf_pred_nat: "wf pred_nat"
   445   apply (unfold wf_def pred_nat_def, clarify)
   446   apply (induct_tac x, blast+)
   447   done
   448 
   449 lemma wf_less_than [iff]: "wf less_than"
   450   by (simp add: less_than_def wf_pred_nat [THEN wf_trancl])
   451 
   452 lemma trans_less_than [iff]: "trans less_than"
   453   by (simp add: less_than_def)
   454 
   455 lemma less_than_iff [iff]: "((x,y): less_than) = (x<y)"
   456   by (simp add: less_than_def less_eq)
   457 
   458 lemma wf_less: "wf {(x, y::nat). x < y}"
   459   using wf_less_than by (simp add: less_than_def less_eq [symmetric])
   460 
   461 
   462 subsection {* Accessible Part *}
   463 
   464 text {*
   465  Inductive definition of the accessible part @{term "acc r"} of a
   466  relation; see also \cite{paulin-tlca}.
   467 *}
   468 
   469 inductive_set
   470   acc :: "('a * 'a) set => 'a set"
   471   for r :: "('a * 'a) set"
   472   where
   473     accI: "(!!y. (y, x) : r ==> y : acc r) ==> x : acc r"
   474 
   475 abbreviation
   476   termip :: "('a => 'a => bool) => 'a => bool" where
   477   "termip r \<equiv> accp (r\<inverse>\<inverse>)"
   478 
   479 abbreviation
   480   termi :: "('a * 'a) set => 'a set" where
   481   "termi r \<equiv> acc (r\<inverse>)"
   482 
   483 lemmas accpI = accp.accI
   484 
   485 text {* Induction rules *}
   486 
   487 theorem accp_induct:
   488   assumes major: "accp r a"
   489   assumes hyp: "!!x. accp r x ==> \<forall>y. r y x --> P y ==> P x"
   490   shows "P a"
   491   apply (rule major [THEN accp.induct])
   492   apply (rule hyp)
   493    apply (rule accp.accI)
   494    apply fast
   495   apply fast
   496   done
   497 
   498 theorems accp_induct_rule = accp_induct [rule_format, induct set: accp]
   499 
   500 theorem accp_downward: "accp r b ==> r a b ==> accp r a"
   501   apply (erule accp.cases)
   502   apply fast
   503   done
   504 
   505 lemma not_accp_down:
   506   assumes na: "\<not> accp R x"
   507   obtains z where "R z x" and "\<not> accp R z"
   508 proof -
   509   assume a: "\<And>z. \<lbrakk>R z x; \<not> accp R z\<rbrakk> \<Longrightarrow> thesis"
   510 
   511   show thesis
   512   proof (cases "\<forall>z. R z x \<longrightarrow> accp R z")
   513     case True
   514     hence "\<And>z. R z x \<Longrightarrow> accp R z" by auto
   515     hence "accp R x"
   516       by (rule accp.accI)
   517     with na show thesis ..
   518   next
   519     case False then obtain z where "R z x" and "\<not> accp R z"
   520       by auto
   521     with a show thesis .
   522   qed
   523 qed
   524 
   525 lemma accp_downwards_aux: "r\<^sup>*\<^sup>* b a ==> accp r a --> accp r b"
   526   apply (erule rtranclp_induct)
   527    apply blast
   528   apply (blast dest: accp_downward)
   529   done
   530 
   531 theorem accp_downwards: "accp r a ==> r\<^sup>*\<^sup>* b a ==> accp r b"
   532   apply (blast dest: accp_downwards_aux)
   533   done
   534 
   535 theorem accp_wfPI: "\<forall>x. accp r x ==> wfP r"
   536   apply (rule wfPUNIVI)
   537   apply (rule_tac P=P in accp_induct)
   538    apply blast
   539   apply blast
   540   done
   541 
   542 theorem accp_wfPD: "wfP r ==> accp r x"
   543   apply (erule wfP_induct_rule)
   544   apply (rule accp.accI)
   545   apply blast
   546   done
   547 
   548 theorem wfP_accp_iff: "wfP r = (\<forall>x. accp r x)"
   549   apply (blast intro: accp_wfPI dest: accp_wfPD)
   550   done
   551 
   552 
   553 text {* Smaller relations have bigger accessible parts: *}
   554 
   555 lemma accp_subset:
   556   assumes sub: "R1 \<le> R2"
   557   shows "accp R2 \<le> accp R1"
   558 proof (rule predicate1I)
   559   fix x assume "accp R2 x"
   560   then show "accp R1 x"
   561   proof (induct x)
   562     fix x
   563     assume ih: "\<And>y. R2 y x \<Longrightarrow> accp R1 y"
   564     with sub show "accp R1 x"
   565       by (blast intro: accp.accI)
   566   qed
   567 qed
   568 
   569 
   570 text {* This is a generalized induction theorem that works on
   571   subsets of the accessible part. *}
   572 
   573 lemma accp_subset_induct:
   574   assumes subset: "D \<le> accp R"
   575     and dcl: "\<And>x z. \<lbrakk>D x; R z x\<rbrakk> \<Longrightarrow> D z"
   576     and "D x"
   577     and istep: "\<And>x. \<lbrakk>D x; (\<And>z. R z x \<Longrightarrow> P z)\<rbrakk> \<Longrightarrow> P x"
   578   shows "P x"
   579 proof -
   580   from subset and `D x`
   581   have "accp R x" ..
   582   then show "P x" using `D x`
   583   proof (induct x)
   584     fix x
   585     assume "D x"
   586       and "\<And>y. R y x \<Longrightarrow> D y \<Longrightarrow> P y"
   587     with dcl and istep show "P x" by blast
   588   qed
   589 qed
   590 
   591 
   592 text {* Set versions of the above theorems *}
   593 
   594 lemmas acc_induct = accp_induct [to_set]
   595 
   596 lemmas acc_induct_rule = acc_induct [rule_format, induct set: acc]
   597 
   598 lemmas acc_downward = accp_downward [to_set]
   599 
   600 lemmas not_acc_down = not_accp_down [to_set]
   601 
   602 lemmas acc_downwards_aux = accp_downwards_aux [to_set]
   603 
   604 lemmas acc_downwards = accp_downwards [to_set]
   605 
   606 lemmas acc_wfI = accp_wfPI [to_set]
   607 
   608 lemmas acc_wfD = accp_wfPD [to_set]
   609 
   610 lemmas wf_acc_iff = wfP_accp_iff [to_set]
   611 
   612 lemmas acc_subset = accp_subset [to_set pred_subset_eq]
   613 
   614 lemmas acc_subset_induct = accp_subset_induct [to_set pred_subset_eq]
   615 
   616 
   617 subsection {* Tools for building wellfounded relations *}
   618 
   619 text {* Inverse Image *}
   620 
   621 lemma wf_inv_image [simp,intro!]: "wf(r) ==> wf(inv_image r (f::'a=>'b))"
   622 apply (simp (no_asm_use) add: inv_image_def wf_eq_minimal)
   623 apply clarify
   624 apply (subgoal_tac "EX (w::'b) . w : {w. EX (x::'a) . x: Q & (f x = w) }")
   625 prefer 2 apply (blast del: allE)
   626 apply (erule allE)
   627 apply (erule (1) notE impE)
   628 apply blast
   629 done
   630 
   631 text {* Measure functions into @{typ nat} *}
   632 
   633 definition measure :: "('a => nat) => ('a * 'a)set"
   634 where "measure = inv_image less_than"
   635 
   636 lemma in_measure[simp]: "((x,y) : measure f) = (f x < f y)"
   637   by (simp add:measure_def)
   638 
   639 lemma wf_measure [iff]: "wf (measure f)"
   640 apply (unfold measure_def)
   641 apply (rule wf_less_than [THEN wf_inv_image])
   642 done
   643 
   644 lemma wf_if_measure: fixes f :: "'a \<Rightarrow> nat"
   645 shows "(!!x. P x \<Longrightarrow> f(g x) < f x) \<Longrightarrow> wf {(y,x). P x \<and> y = g x}"
   646 apply(insert wf_measure[of f])
   647 apply(simp only: measure_def inv_image_def less_than_def less_eq)
   648 apply(erule wf_subset)
   649 apply auto
   650 done
   651 
   652 
   653 text{* Lexicographic combinations *}
   654 
   655 definition lex_prod :: "('a \<times>'a) set \<Rightarrow> ('b \<times> 'b) set \<Rightarrow> (('a \<times> 'b) \<times> ('a \<times> 'b)) set" (infixr "<*lex*>" 80) where
   656   "ra <*lex*> rb = {((a, b), (a', b')). (a, a') \<in> ra \<or> a = a' \<and> (b, b') \<in> rb}"
   657 
   658 lemma wf_lex_prod [intro!]: "[| wf(ra); wf(rb) |] ==> wf(ra <*lex*> rb)"
   659 apply (unfold wf_def lex_prod_def) 
   660 apply (rule allI, rule impI)
   661 apply (simp (no_asm_use) only: split_paired_All)
   662 apply (drule spec, erule mp) 
   663 apply (rule allI, rule impI)
   664 apply (drule spec, erule mp, blast) 
   665 done
   666 
   667 lemma in_lex_prod[simp]: 
   668   "(((a,b),(a',b')): r <*lex*> s) = ((a,a'): r \<or> (a = a' \<and> (b, b') : s))"
   669   by (auto simp:lex_prod_def)
   670 
   671 text{* @{term "op <*lex*>"} preserves transitivity *}
   672 
   673 lemma trans_lex_prod [intro!]: 
   674     "[| trans R1; trans R2 |] ==> trans (R1 <*lex*> R2)"
   675 by (unfold trans_def lex_prod_def, blast) 
   676 
   677 text {* lexicographic combinations with measure functions *}
   678 
   679 definition 
   680   mlex_prod :: "('a \<Rightarrow> nat) \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" (infixr "<*mlex*>" 80)
   681 where
   682   "f <*mlex*> R = inv_image (less_than <*lex*> R) (%x. (f x, x))"
   683 
   684 lemma wf_mlex: "wf R \<Longrightarrow> wf (f <*mlex*> R)"
   685 unfolding mlex_prod_def
   686 by auto
   687 
   688 lemma mlex_less: "f x < f y \<Longrightarrow> (x, y) \<in> f <*mlex*> R"
   689 unfolding mlex_prod_def by simp
   690 
   691 lemma mlex_leq: "f x \<le> f y \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> (x, y) \<in> f <*mlex*> R"
   692 unfolding mlex_prod_def by auto
   693 
   694 text {* proper subset relation on finite sets *}
   695 
   696 definition finite_psubset  :: "('a set * 'a set) set"
   697 where "finite_psubset = {(A,B). A < B & finite B}"
   698 
   699 lemma wf_finite_psubset[simp]: "wf(finite_psubset)"
   700 apply (unfold finite_psubset_def)
   701 apply (rule wf_measure [THEN wf_subset])
   702 apply (simp add: measure_def inv_image_def less_than_def less_eq)
   703 apply (fast elim!: psubset_card_mono)
   704 done
   705 
   706 lemma trans_finite_psubset: "trans finite_psubset"
   707 by (simp add: finite_psubset_def less_le trans_def, blast)
   708 
   709 lemma in_finite_psubset[simp]: "(A, B) \<in> finite_psubset = (A < B & finite B)"
   710 unfolding finite_psubset_def by auto
   711 
   712 text {* max- and min-extension of order to finite sets *}
   713 
   714 inductive_set max_ext :: "('a \<times> 'a) set \<Rightarrow> ('a set \<times> 'a set) set" 
   715 for R :: "('a \<times> 'a) set"
   716 where
   717   max_extI[intro]: "finite X \<Longrightarrow> finite Y \<Longrightarrow> Y \<noteq> {} \<Longrightarrow> (\<And>x. x \<in> X \<Longrightarrow> \<exists>y\<in>Y. (x, y) \<in> R) \<Longrightarrow> (X, Y) \<in> max_ext R"
   718 
   719 lemma max_ext_wf:
   720   assumes wf: "wf r"
   721   shows "wf (max_ext r)"
   722 proof (rule acc_wfI, intro allI)
   723   fix M show "M \<in> acc (max_ext r)" (is "_ \<in> ?W")
   724   proof cases
   725     assume "finite M"
   726     thus ?thesis
   727     proof (induct M)
   728       show "{} \<in> ?W"
   729         by (rule accI) (auto elim: max_ext.cases)
   730     next
   731       fix M a assume "M \<in> ?W" "finite M"
   732       with wf show "insert a M \<in> ?W"
   733       proof (induct arbitrary: M)
   734         fix M a
   735         assume "M \<in> ?W"  and  [intro]: "finite M"
   736         assume hyp: "\<And>b M. (b, a) \<in> r \<Longrightarrow> M \<in> ?W \<Longrightarrow> finite M \<Longrightarrow> insert b M \<in> ?W"
   737         {
   738           fix N M :: "'a set"
   739           assume "finite N" "finite M"
   740           then
   741           have "\<lbrakk>M \<in> ?W ; (\<And>y. y \<in> N \<Longrightarrow> (y, a) \<in> r)\<rbrakk> \<Longrightarrow>  N \<union> M \<in> ?W"
   742             by (induct N arbitrary: M) (auto simp: hyp)
   743         }
   744         note add_less = this
   745         
   746         show "insert a M \<in> ?W"
   747         proof (rule accI)
   748           fix N assume Nless: "(N, insert a M) \<in> max_ext r"
   749           hence asm1: "\<And>x. x \<in> N \<Longrightarrow> (x, a) \<in> r \<or> (\<exists>y \<in> M. (x, y) \<in> r)"
   750             by (auto elim!: max_ext.cases)
   751 
   752           let ?N1 = "{ n \<in> N. (n, a) \<in> r }"
   753           let ?N2 = "{ n \<in> N. (n, a) \<notin> r }"
   754           have N: "?N1 \<union> ?N2 = N" by (rule set_eqI) auto
   755           from Nless have "finite N" by (auto elim: max_ext.cases)
   756           then have finites: "finite ?N1" "finite ?N2" by auto
   757           
   758           have "?N2 \<in> ?W"
   759           proof cases
   760             assume [simp]: "M = {}"
   761             have Mw: "{} \<in> ?W" by (rule accI) (auto elim: max_ext.cases)
   762 
   763             from asm1 have "?N2 = {}" by auto
   764             with Mw show "?N2 \<in> ?W" by (simp only:)
   765           next
   766             assume "M \<noteq> {}"
   767             have N2: "(?N2, M) \<in> max_ext r" 
   768               by (rule max_extI[OF _ _ `M \<noteq> {}`]) (insert asm1, auto intro: finites)
   769             
   770             with `M \<in> ?W` show "?N2 \<in> ?W" by (rule acc_downward)
   771           qed
   772           with finites have "?N1 \<union> ?N2 \<in> ?W" 
   773             by (rule add_less) simp
   774           then show "N \<in> ?W" by (simp only: N)
   775         qed
   776       qed
   777     qed
   778   next
   779     assume [simp]: "\<not> finite M"
   780     show ?thesis
   781       by (rule accI) (auto elim: max_ext.cases)
   782   qed
   783 qed
   784 
   785 lemma max_ext_additive: 
   786  "(A, B) \<in> max_ext R \<Longrightarrow> (C, D) \<in> max_ext R \<Longrightarrow>
   787   (A \<union> C, B \<union> D) \<in> max_ext R"
   788 by (force elim!: max_ext.cases)
   789 
   790 
   791 definition min_ext :: "('a \<times> 'a) set \<Rightarrow> ('a set \<times> 'a set) set"  where
   792   "min_ext r = {(X, Y) | X Y. X \<noteq> {} \<and> (\<forall>y \<in> Y. (\<exists>x \<in> X. (x, y) \<in> r))}"
   793 
   794 lemma min_ext_wf:
   795   assumes "wf r"
   796   shows "wf (min_ext r)"
   797 proof (rule wfI_min)
   798   fix Q :: "'a set set"
   799   fix x
   800   assume nonempty: "x \<in> Q"
   801   show "\<exists>m \<in> Q. (\<forall> n. (n, m) \<in> min_ext r \<longrightarrow> n \<notin> Q)"
   802   proof cases
   803     assume "Q = {{}}" thus ?thesis by (simp add: min_ext_def)
   804   next
   805     assume "Q \<noteq> {{}}"
   806     with nonempty
   807     obtain e x where "x \<in> Q" "e \<in> x" by force
   808     then have eU: "e \<in> \<Union>Q" by auto
   809     with `wf r` 
   810     obtain z where z: "z \<in> \<Union>Q" "\<And>y. (y, z) \<in> r \<Longrightarrow> y \<notin> \<Union>Q" 
   811       by (erule wfE_min)
   812     from z obtain m where "m \<in> Q" "z \<in> m" by auto
   813     from `m \<in> Q`
   814     show ?thesis
   815     proof (rule, intro bexI allI impI)
   816       fix n
   817       assume smaller: "(n, m) \<in> min_ext r"
   818       with `z \<in> m` obtain y where y: "y \<in> n" "(y, z) \<in> r" by (auto simp: min_ext_def)
   819       then show "n \<notin> Q" using z(2) by auto
   820     qed      
   821   qed
   822 qed
   823 
   824 text{* Bounded increase must terminate: *}
   825 
   826 lemma wf_bounded_measure:
   827 fixes ub :: "'a \<Rightarrow> nat" and f :: "'a \<Rightarrow> nat"
   828 assumes "!!a b. (b,a) : r \<Longrightarrow> ub b \<le> ub a & ub a \<ge> f b & f b > f a"
   829 shows "wf r"
   830 apply(rule wf_subset[OF wf_measure[of "%a. ub a - f a"]])
   831 apply (auto dest: assms)
   832 done
   833 
   834 lemma wf_bounded_set:
   835 fixes ub :: "'a \<Rightarrow> 'b set" and f :: "'a \<Rightarrow> 'b set"
   836 assumes "!!a b. (b,a) : r \<Longrightarrow>
   837   finite(ub a) & ub b \<subseteq> ub a & ub a \<supseteq> f b & f b \<supset> f a"
   838 shows "wf r"
   839 apply(rule wf_bounded_measure[of r "%a. card(ub a)" "%a. card(f a)"])
   840 apply(drule assms)
   841 apply (blast intro: card_mono finite_subset psubset_card_mono dest: psubset_eq[THEN iffD2])
   842 done
   843 
   844 
   845 subsection {* size of a datatype value *}
   846 
   847 use "Tools/Function/size.ML"
   848 
   849 setup Size.setup
   850 
   851 lemma size_bool [code]:
   852   "size (b\<Colon>bool) = 0" by (cases b) auto
   853 
   854 lemma nat_size [simp, code]: "size (n\<Colon>nat) = n"
   855   by (induct n) simp_all
   856 
   857 declare "prod.size" [no_atp]
   858 
   859 lemma [code]:
   860   "size (P :: 'a Predicate.pred) = 0" by (cases P) simp
   861 
   862 lemma [code]:
   863   "pred_size f P = 0" by (cases P) simp
   864 
   865 end