src/Pure/library.ML
author haftmann
Sun Aug 28 09:18:22 2005 +0200 (2005-08-28)
changeset 17153 d871853e13e0
parent 17141 4b0dc89de43b
child 17257 0ab67cb765da
permissions -rw-r--r--
added 'these', removed assoc2
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |-> ||> ||>> |>> |>>> #> #-> ~~ \ \\ ins ins_string ins_int
    12   orf andf prefix upto downto mem mem_int mem_string union union_int
    13   union_string inter inter_int inter_string subset subset_int
    14   subset_string;
    15 
    16 infix 2 ?;
    17 
    18 infix 3 oo ooo oooo;
    19 
    20 signature BASIC_LIBRARY =
    21 sig
    22   (*functions*)
    23   val I: 'a -> 'a
    24   val K: 'a -> 'b -> 'a
    25   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    26   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    27   val |> : 'a * ('a -> 'b) -> 'b
    28   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    29   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    30   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    31   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    32   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    33   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    34   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    35   val ? : ('a -> bool) * ('a -> 'a) -> 'a -> 'a
    36   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    37   val tap: ('b -> 'a) -> 'b -> 'b
    38   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    39   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    40   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    41   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    42   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    43   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    44 
    45   (*old options -- invalidated*)
    46   datatype invalid = None of invalid
    47   exception OPTION of invalid
    48 
    49   (*options*)
    50   val the: 'a option -> 'a
    51   val these: 'a list option -> 'a list
    52   val if_none: 'a option -> 'a -> 'a
    53   val is_some: 'a option -> bool
    54   val is_none: 'a option -> bool
    55 
    56   exception ERROR
    57   val try: ('a -> 'b) -> 'a -> 'b option
    58   val can: ('a -> 'b) -> 'a -> bool
    59   datatype 'a result = Result of 'a | Exn of exn
    60   val capture: ('a -> 'b) -> 'a -> 'b result
    61   val release: 'a result -> 'a
    62   val get_result: 'a result -> 'a option
    63   val get_exn: 'a result -> exn option
    64 
    65   (*pairs*)
    66   val pair: 'a -> 'b -> 'a * 'b
    67   val rpair: 'a -> 'b -> 'b * 'a
    68   val fst: 'a * 'b -> 'a
    69   val snd: 'a * 'b -> 'b
    70   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    71   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    72   val swap: 'a * 'b -> 'b * 'a
    73   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    74   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    75   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    76 
    77   (*booleans*)
    78   val equal: ''a -> ''a -> bool
    79   val not_equal: ''a -> ''a -> bool
    80   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    81   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    82   val exists: ('a -> bool) -> 'a list -> bool
    83   val forall: ('a -> bool) -> 'a list -> bool
    84   val set: bool ref -> bool
    85   val reset: bool ref -> bool
    86   val toggle: bool ref -> bool
    87   val change: 'a ref -> ('a -> 'a) -> unit
    88   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    89   val conditional: bool -> (unit -> unit) -> unit
    90 
    91   (*lists*)
    92   exception UnequalLengths
    93   val cons: 'a -> 'a list -> 'a list
    94   val single: 'a -> 'a list
    95   val append: 'a list -> 'a list -> 'a list
    96   val apply: ('a -> 'a) list -> 'a -> 'a
    97   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    98   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    99   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
   100   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   101   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
   102   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
   103   val unflat: 'a list list -> 'b list -> 'b list list
   104   val splitAt: int * 'a list -> 'a list * 'a list
   105   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   106   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
   107   val split_last: 'a list -> 'a list * 'a
   108   val nth_update: 'a -> int * 'a list -> 'a list
   109   val find_index: ('a -> bool) -> 'a list -> int
   110   val find_index_eq: ''a -> ''a list -> int
   111   val find_first: ('a -> bool) -> 'a list -> 'a option
   112   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   113   val separate: 'a -> 'a list -> 'a list
   114   val replicate: int -> 'a -> 'a list
   115   val multiply: 'a list * 'a list list -> 'a list list
   116   val product: 'a list -> 'b list -> ('a * 'b) list
   117   val filter: ('a -> bool) -> 'a list -> 'a list
   118   val filter_out: ('a -> bool) -> 'a list -> 'a list
   119   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   120   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   121   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   122   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   123   val ~~ : 'a list * 'b list -> ('a * 'b) list
   124   val split_list: ('a * 'b) list -> 'a list * 'b list
   125   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   126   val prefix: ''a list * ''a list -> bool
   127   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   128   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   129   val prefixes1: 'a list -> 'a list list
   130   val suffixes1: 'a list -> 'a list list
   131 
   132   (*integers*)
   133   val gcd: IntInf.int * IntInf.int -> IntInf.int
   134   val lcm: IntInf.int * IntInf.int -> IntInf.int
   135   val inc: int ref -> int
   136   val dec: int ref -> int
   137   val upto: int * int -> int list
   138   val downto: int * int -> int list
   139   val downto0: int list * int -> bool
   140   val radixpand: int * int -> int list
   141   val radixstring: int * string * int -> string
   142   val string_of_int: int -> string
   143   val string_of_indexname: string * int -> string
   144   val read_radixint: int * string list -> int * string list
   145   val read_int: string list -> int * string list
   146   val oct_char: string -> string
   147 
   148   (*rational numbers*)
   149   type rat
   150   exception RAT of string
   151   val rep_rat: rat -> IntInf.int * IntInf.int
   152   val ratge0: rat -> bool
   153   val ratgt0: rat -> bool
   154   val ratle: rat * rat -> bool
   155   val ratlt: rat * rat -> bool
   156   val ratadd: rat * rat -> rat
   157   val ratmul: rat * rat -> rat
   158   val ratinv: rat -> rat
   159   val int_ratdiv: IntInf.int * IntInf.int -> rat
   160   val ratneg: rat -> rat
   161   val rat_of_int: int -> rat
   162   val rat_of_intinf: IntInf.int -> rat
   163   val rat0: rat
   164 
   165   (*strings*)
   166   val nth_elem_string: int * string -> string
   167   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   168   val exists_string: (string -> bool) -> string -> bool
   169   val forall_string: (string -> bool) -> string -> bool
   170   val enclose: string -> string -> string -> string
   171   val unenclose: string -> string
   172   val quote: string -> string
   173   val space_implode: string -> string list -> string
   174   val commas: string list -> string
   175   val commas_quote: string list -> string
   176   val cat_lines: string list -> string
   177   val space_explode: string -> string -> string list
   178   val split_lines: string -> string list
   179   val prefix_lines: string -> string -> string
   180   val untabify: string list -> string list
   181   val suffix: string -> string -> string
   182   val unsuffix: string -> string -> string
   183   val unprefix: string -> string -> string
   184   val replicate_string: int -> string -> string
   185   val translate_string: (string -> string) -> string -> string
   186 
   187   (*lists as sets -- see also Pure/General/ord_list.ML*)
   188   val mem: ''a * ''a list -> bool
   189   val mem_int: int * int list -> bool
   190   val mem_string: string * string list -> bool
   191   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   192   val ins: ''a * ''a list -> ''a list
   193   val ins_int: int * int list -> int list
   194   val ins_string: string * string list -> string list
   195   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   196   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   197   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   198   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   199   val union: ''a list * ''a list -> ''a list
   200   val union_int: int list * int list -> int list
   201   val union_string: string list * string list -> string list
   202   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   203   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   204   val inter: ''a list * ''a list -> ''a list
   205   val inter_int: int list * int list -> int list
   206   val inter_string: string list * string list -> string list
   207   val subset: ''a list * ''a list -> bool
   208   val subset_int: int list * int list -> bool
   209   val subset_string: string list * string list -> bool
   210   val eq_set: ''a list * ''a list -> bool
   211   val eq_set_string: string list * string list -> bool
   212   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   213   val \ : ''a list * ''a -> ''a list
   214   val \\ : ''a list * ''a list -> ''a list
   215   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   216   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   217   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   218   val distinct: ''a list -> ''a list
   219   val findrep: ''a list -> ''a list
   220   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   221   val duplicates: ''a list -> ''a list
   222   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   223 
   224   (*association lists -- see also Pure/General/alist.ML*)
   225   val assoc: (''a * 'b) list * ''a -> 'b option
   226   val assoc_int: (int * 'a) list * int -> 'a option
   227   val assoc_string: (string * 'a) list * string -> 'a option
   228   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   229   val assocs: (''a * 'b list) list -> ''a -> 'b list
   230   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   231   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   232   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   233 
   234   (*lists as tables*)
   235   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   236   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   237   val merge_lists: ''a list -> ''a list -> ''a list
   238   val merge_lists': ''a list -> ''a list -> ''a list
   239   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   240   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   241 
   242   (*balanced trees*)
   243   exception Balance
   244   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   245   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   246   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   247 
   248   (*orders*)
   249   val rev_order: order -> order
   250   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   251   val int_ord: int * int -> order
   252   val string_ord: string * string -> order
   253   val fast_string_ord: string * string -> order
   254   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   255   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   256   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   257   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   258   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   259   val sort_strings: string list -> string list
   260   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   261   val unique_strings: string list -> string list
   262 
   263   (*random numbers*)
   264   exception RANDOM
   265   val random: unit -> real
   266   val random_range: int -> int -> int
   267   val one_of: 'a list -> 'a
   268   val frequency: (int * 'a) list -> 'a
   269 
   270   (*current directory*)
   271   val cd: string -> unit
   272   val pwd: unit -> string
   273 
   274   (*misc*)
   275   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   276   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   277   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   278   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   279   val gensym: string -> string
   280   val scanwords: (string -> bool) -> string list -> string list
   281   type stamp
   282   val stamp: unit -> stamp
   283   type serial
   284   val serial: unit -> serial
   285   structure Object: sig type T end
   286 end;
   287 
   288 signature LIBRARY =
   289 sig
   290   include BASIC_LIBRARY
   291   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   292   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   293   val take: int * 'a list -> 'a list
   294   val drop: int * 'a list -> 'a list
   295   val nth_elem: int * 'a list -> 'a
   296   val last_elem: 'a list -> 'a
   297   val flat: 'a list list -> 'a list
   298   val seq: ('a -> unit) -> 'a list -> unit
   299   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   300   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   301 end;
   302 
   303 structure Library: LIBRARY =
   304 struct
   305 
   306 
   307 (** functions **)
   308 
   309 fun I x = x;
   310 fun K x = fn _ => x;
   311 fun curry f x y = f (x, y);
   312 fun uncurry f (x, y) = f x y;
   313 
   314 (*reverse application and structured results*)
   315 fun x |> f = f x;
   316 fun (x, y) |-> f = f x y;
   317 fun (x, y) |>> f = (f x, y);
   318 fun (x, y) ||> f = (x, f y);
   319 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   320 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   321 
   322 (*reverse composition*)
   323 fun f #> g = g o f;
   324 fun f #-> g = uncurry g o f;
   325 
   326 (*conditional application*)
   327 fun b ? f = fn x => if b x then f x else x
   328 
   329 (*view results*)
   330 fun `f = fn x => (f x, x);
   331 fun tap f x = (f x; x);
   332 
   333 (*composition with multiple args*)
   334 fun (f oo g) x y = f (g x y);
   335 fun (f ooo g) x y z = f (g x y z);
   336 fun (f oooo g) x y z w = f (g x y z w);
   337 
   338 (*function exponentiation: f(...(f x)...) with n applications of f*)
   339 fun funpow n f x =
   340   let fun rep (0, x) = x
   341         | rep (n, x) = rep (n - 1, f x)
   342   in rep (n, x) end;
   343 
   344 (*application of (infix) operator to its left or right argument*)
   345 fun apl (x, f) y = f (x, y);
   346 fun apr (f, y) x = f (x, y);
   347 
   348 
   349 (** options **)
   350 
   351 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   352 datatype invalid = None of invalid;
   353 exception OPTION of invalid;
   354 
   355 val the = Option.valOf;
   356 fun these (SOME x) = x
   357   | these _ = []
   358 
   359 (*strict!*)
   360 fun if_none NONE y = y
   361   | if_none (SOME x) _ = x;
   362 
   363 fun is_some (SOME _) = true
   364   | is_some NONE = false;
   365 
   366 fun is_none (SOME _) = false
   367   | is_none NONE = true;
   368 
   369 
   370 (* exception handling *)
   371 
   372 exception ERROR;
   373 
   374 fun try f x = SOME (f x)
   375   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   376 
   377 fun can f x = is_some (try f x);
   378 
   379 
   380 datatype 'a result =
   381   Result of 'a |
   382   Exn of exn;
   383 
   384 fun capture f x = Result (f x) handle e => Exn e;
   385 
   386 fun release (Result y) = y
   387   | release (Exn e) = raise e;
   388 
   389 fun get_result (Result x) = SOME x
   390   | get_result _ = NONE;
   391 
   392 fun get_exn (Exn exn) = SOME exn
   393   | get_exn _ = NONE;
   394 
   395 
   396 
   397 (** pairs **)
   398 
   399 fun pair x y = (x, y);
   400 fun rpair x y = (y, x);
   401 
   402 fun fst (x, y) = x;
   403 fun snd (x, y) = y;
   404 
   405 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   406 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   407 
   408 fun swap (x, y) = (y, x);
   409 
   410 (*apply function to components*)
   411 fun apfst f (x, y) = (f x, y);
   412 fun apsnd f (x, y) = (x, f y);
   413 fun pairself f (x, y) = (f x, f y);
   414 
   415 
   416 
   417 (** booleans **)
   418 
   419 (* equality *)
   420 
   421 fun equal x y = x = y;
   422 fun not_equal x y = x <> y;
   423 
   424 
   425 (* operators for combining predicates *)
   426 
   427 fun p orf q = fn x => p x orelse q x;
   428 fun p andf q = fn x => p x andalso q x;
   429 
   430 
   431 (* predicates on lists *)
   432 
   433 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   434 fun exists (pred: 'a -> bool) : 'a list -> bool =
   435   let fun boolf [] = false
   436         | boolf (x :: xs) = pred x orelse boolf xs
   437   in boolf end;
   438 
   439 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   440 fun forall (pred: 'a -> bool) : 'a list -> bool =
   441   let fun boolf [] = true
   442         | boolf (x :: xs) = pred x andalso boolf xs
   443   in boolf end;
   444 
   445 
   446 (* flags *)
   447 
   448 fun set flag = (flag := true; true);
   449 fun reset flag = (flag := false; false);
   450 fun toggle flag = (flag := not (! flag); ! flag);
   451 
   452 fun change r f = r := f (! r);
   453 
   454 (*temporarily set flag, handling exceptions*)
   455 fun setmp flag value f x =
   456   let
   457     val orig_value = ! flag;
   458     fun return y = (flag := orig_value; y);
   459   in
   460     flag := value;
   461     return (f x handle exn => (return (); raise exn))
   462   end;
   463 
   464 
   465 (* conditional execution *)
   466 
   467 fun conditional b f = if b then f () else ();
   468 
   469 
   470 
   471 (** lists **)
   472 
   473 exception UnequalLengths;
   474 
   475 fun cons x xs = x :: xs;
   476 fun single x = [x];
   477 
   478 fun append xs ys = xs @ ys;
   479 
   480 fun apply [] x = x
   481   | apply (f :: fs) x = apply fs (f x);
   482 
   483 
   484 (* fold *)
   485 
   486 fun fold f =
   487   let
   488     fun fold_aux [] y = y
   489       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   490   in fold_aux end;
   491 
   492 fun fold_rev f =
   493   let
   494     fun fold_aux [] y = y
   495       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   496   in fold_aux end;
   497 
   498 fun fold_map f =
   499   let
   500     fun fold_aux [] y = ([], y)
   501       | fold_aux (x :: xs) y =
   502           let
   503             val (x', y') = f x y;
   504             val (xs', y'') = fold_aux xs y';
   505           in (x' :: xs', y'') end;
   506   in fold_aux end;
   507 
   508 (*the following versions of fold are designed to fit nicely with infixes*)
   509 
   510 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   511     for operators that associate to the left (TAIL RECURSIVE)*)
   512 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   513   let fun itl (e, [])  = e
   514         | itl (e, a::l) = itl (f(e, a), l)
   515   in  itl end;
   516 
   517 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   518     for operators that associate to the right (not tail recursive)*)
   519 fun foldr f (l, e) =
   520   let fun itr [] = e
   521         | itr (a::l) = f(a, itr l)
   522   in  itr l  end;
   523 
   524 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   525     for n > 0, operators that associate to the right (not tail recursive)*)
   526 fun foldr1 f l =
   527   let fun itr [x] = x
   528         | itr (x::l) = f(x, itr l)
   529   in  itr l  end;
   530 
   531 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   532 
   533 fun foldl_map f =
   534   let
   535     fun fold_aux (x, []) = (x, [])
   536       | fold_aux (x, y :: ys) =
   537           let
   538             val (x', y') = f (x, y);
   539             val (x'', ys') = fold_aux (x', ys);
   540           in (x'', y' :: ys') end;
   541   in fold_aux end;
   542 
   543 
   544 (* basic list functions *)
   545 
   546 (*take the first n elements from a list*)
   547 fun take (n, []) = []
   548   | take (n, x :: xs) =
   549       if n > 0 then x :: take (n - 1, xs) else [];
   550 
   551 (*drop the first n elements from a list*)
   552 fun drop (n, []) = []
   553   | drop (n, x :: xs) =
   554       if n > 0 then drop (n - 1, xs) else x :: xs;
   555 
   556 fun splitAt(n,[]) = ([],[])
   557   | splitAt(n,xs as x::ys) =
   558       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   559       else ([],xs)
   560 
   561 fun dropwhile P [] = []
   562   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   563 
   564 (*return nth element of a list, where 0 designates the first element;
   565   raise EXCEPTION if list too short*)
   566 fun nth_elem (i,xs) = List.nth(xs,i);
   567 
   568 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   569   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   570   | map_nth_elem _ _ [] = raise Subscript;
   571 
   572 (*last element of a list*)
   573 val last_elem = List.last;
   574 
   575 (*rear decomposition*)
   576 fun split_last [] = raise Empty
   577   | split_last [x] = ([], x)
   578   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   579 
   580 (*update nth element*)
   581 fun nth_update x n_xs =
   582     (case splitAt n_xs of
   583       (_,[]) => raise Subscript
   584     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   585 
   586 (*find the position of an element in a list*)
   587 fun find_index pred =
   588   let fun find _ [] = ~1
   589         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   590   in find 0 end;
   591 
   592 fun find_index_eq x = find_index (equal x);
   593 
   594 (*find first element satisfying predicate*)
   595 fun find_first _ [] = NONE
   596   | find_first pred (x :: xs) =
   597       if pred x then SOME x else find_first pred xs;
   598 
   599 (*get first element by lookup function*)
   600 fun get_first _ [] = NONE
   601   | get_first f (x :: xs) =
   602       (case f x of
   603         NONE => get_first f xs
   604       | some => some);
   605 
   606 (*flatten a list of lists to a list*)
   607 val flat = List.concat;
   608 
   609 fun unflat (xs :: xss) ys =
   610       let val (ps,qs) = splitAt(length xs,ys)
   611       in ps :: unflat xss qs end
   612   | unflat [] [] = []
   613   | unflat _ _ = raise UnequalLengths;
   614 
   615 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   616   (proc x1; ...; proc xn) for side effects*)
   617 val seq = List.app;
   618 
   619 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   620 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   621   | separate _ xs = xs;
   622 
   623 (*make the list [x, x, ..., x] of length n*)
   624 fun replicate n (x: 'a) : 'a list =
   625   let fun rep (0, xs) = xs
   626         | rep (n, xs) = rep (n - 1, x :: xs)
   627   in
   628     if n < 0 then raise Subscript
   629     else rep (n, [])
   630   end;
   631 
   632 fun translate_string f = String.translate (f o String.str);
   633 
   634 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   635 fun multiply ([], _) = []
   636   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   637 
   638 (*direct product*)
   639 fun product _ [] = []
   640   | product [] _ = []
   641   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   642 
   643 
   644 (* filter *)
   645 
   646 (*copy the list preserving elements that satisfy the predicate*)
   647 val filter = List.filter;
   648 fun filter_out f = filter (not o f);
   649 val mapfilter = List.mapPartial;
   650 
   651 
   652 (* lists of pairs *)
   653 
   654 exception UnequalLengths;
   655 
   656 fun map2 _ ([], []) = []
   657   | map2 f (x :: xs, y :: ys) = f (x, y) :: map2 f (xs, ys)
   658   | map2 _ _ = raise UnequalLengths;
   659 
   660 fun exists2 _ ([], []) = false
   661   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   662   | exists2 _ _ = raise UnequalLengths;
   663 
   664 fun forall2 _ ([], []) = true
   665   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   666   | forall2 _ _ = raise UnequalLengths;
   667 
   668 fun seq2 _ ([], []) = ()
   669   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   670   | seq2 _ _ = raise UnequalLengths;
   671 
   672 (*combine two lists forming a list of pairs:
   673   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   674 fun [] ~~ [] = []
   675   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   676   | _ ~~ _ = raise UnequalLengths;
   677 
   678 (*inverse of ~~; the old 'split':
   679   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   680 val split_list = ListPair.unzip;
   681 
   682 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   683 
   684 
   685 (* prefixes, suffixes *)
   686 
   687 fun [] prefix _ = true
   688   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   689   | _ prefix _ = false;
   690 
   691 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   692    where xi is the first element that does not satisfy the predicate*)
   693 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   694   let fun take (rxs, []) = (rev rxs, [])
   695         | take (rxs, x :: xs) =
   696             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   697   in  take([], xs)  end;
   698 
   699 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   700    where xi is the last element that does not satisfy the predicate*)
   701 fun take_suffix _ [] = ([], [])
   702   | take_suffix pred (x :: xs) =
   703       (case take_suffix pred xs of
   704         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   705       | (prfx, sffx) => (x :: prfx, sffx));
   706 
   707 fun prefixes1 [] = []
   708   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   709 
   710 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   711 
   712 
   713 
   714 (** integers **)
   715 
   716 fun gcd (x, y) =
   717   let fun gxd x y : IntInf.int =
   718     if y = 0 then x else gxd y (x mod y)
   719   in if x < y then gxd y x else gxd x y end;
   720 
   721 fun lcm (x, y) = (x * y) div gcd (x, y);
   722 
   723 fun inc i = (i := ! i + 1; ! i);
   724 fun dec i = (i := ! i - 1; ! i);
   725 
   726 
   727 (* lists of integers *)
   728 
   729 (*make the list [from, from + 1, ..., to]*)
   730 fun (from upto to) =
   731   if from > to then [] else from :: ((from + 1) upto to);
   732 
   733 (*make the list [from, from - 1, ..., to]*)
   734 fun (from downto to) =
   735   if from < to then [] else from :: ((from - 1) downto to);
   736 
   737 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   738 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   739   | downto0 ([], n) = n = ~1;
   740 
   741 
   742 (* convert integers to strings *)
   743 
   744 (*expand the number in the given base;
   745   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   746 fun radixpand (base, num) : int list =
   747   let
   748     fun radix (n, tail) =
   749       if n < base then n :: tail
   750       else radix (n div base, (n mod base) :: tail)
   751   in radix (num, []) end;
   752 
   753 (*expands a number into a string of characters starting from "zerochar";
   754   example: radixstring (2, "0", 8) gives "1000"*)
   755 fun radixstring (base, zerochar, num) =
   756   let val offset = ord zerochar;
   757       fun chrof n = chr (offset + n)
   758   in implode (map chrof (radixpand (base, num))) end;
   759 
   760 
   761 val string_of_int = Int.toString;
   762 
   763 fun string_of_indexname (a,0) = a
   764   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   765 
   766 
   767 (* read integers *)
   768 
   769 fun read_radixint (radix: int, cs) : int * string list =
   770   let val zero = ord"0"
   771       val limit = zero+radix
   772       fun scan (num,[]) = (num,[])
   773         | scan (num, c::cs) =
   774               if  zero <= ord c  andalso  ord c < limit
   775               then scan(radix*num + ord c - zero, cs)
   776               else (num, c::cs)
   777   in  scan(0,cs)  end;
   778 
   779 fun read_int cs = read_radixint (10, cs);
   780 
   781 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   782 
   783 
   784 
   785 (** strings **)
   786 
   787 (* functions tuned for strings, avoiding explode *)
   788 
   789 fun nth_elem_string (i, str) =
   790   (case try String.substring (str, i, 1) of
   791     SOME s => s
   792   | NONE => raise Subscript);
   793 
   794 fun fold_string f str x0 =
   795   let
   796     val n = size str;
   797     fun iter (x, i) =
   798       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   799   in iter (x0, 0) end;
   800 
   801 fun exists_string pred str =
   802   let
   803     val n = size str;
   804     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   805   in ex 0 end;
   806 
   807 fun forall_string pred = not o exists_string (not o pred);
   808 
   809 (*enclose in brackets*)
   810 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   811 fun unenclose str = String.substring (str, 1, size str - 2);
   812 
   813 (*simple quoting (does not escape special chars)*)
   814 val quote = enclose "\"" "\"";
   815 
   816 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   817 fun space_implode a bs = implode (separate a bs);
   818 
   819 val commas = space_implode ", ";
   820 val commas_quote = commas o map quote;
   821 
   822 (*concatenate messages, one per line, into a string*)
   823 val cat_lines = space_implode "\n";
   824 
   825 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   826 fun space_explode _ "" = []
   827   | space_explode sep str =
   828       let
   829         fun expl chs =
   830           (case take_prefix (not_equal sep) chs of
   831             (cs, []) => [implode cs]
   832           | (cs, _ :: cs') => implode cs :: expl cs');
   833       in expl (explode str) end;
   834 
   835 val split_lines = space_explode "\n";
   836 
   837 fun prefix_lines "" txt = txt
   838   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   839 
   840 fun untabify chs =
   841   let
   842     val tab_width = 8;
   843 
   844     fun untab (_, "\n") = (0, ["\n"])
   845       | untab (pos, "\t") =
   846           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   847       | untab (pos, c) = (pos + 1, [c]);
   848   in
   849     if not (exists (equal "\t") chs) then chs
   850     else flat (#2 (foldl_map untab (0, chs)))
   851   end;
   852 
   853 fun suffix sffx s = s ^ sffx;
   854 
   855 fun unsuffix sffx s =
   856   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   857   else raise Fail "unsuffix";
   858 
   859 fun unprefix prfx s =
   860   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   861   else raise Fail "unprefix";
   862 
   863 fun replicate_string 0 _ = ""
   864   | replicate_string 1 a = a
   865   | replicate_string k a =
   866       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   867       else replicate_string (k div 2) (a ^ a) ^ a;
   868 
   869 
   870 
   871 (** lists as sets -- see also Pure/General/ord_list.ML **)
   872 
   873 (*membership in a list*)
   874 fun x mem [] = false
   875   | x mem (y :: ys) = x = y orelse x mem ys;
   876 
   877 (*membership in a list, optimized version for ints*)
   878 fun (x:int) mem_int [] = false
   879   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   880 
   881 (*membership in a list, optimized version for strings*)
   882 fun (x:string) mem_string [] = false
   883   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   884 
   885 (*generalized membership test*)
   886 fun gen_mem eq (x, []) = false
   887   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   888 
   889 (*member, insert, and remove -- with canonical argument order*)
   890 fun member eq xs x = gen_mem eq (x, xs);
   891 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   892 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   893 
   894 (*insertion into list if not already there*)
   895 fun (x ins xs) = if x mem xs then xs else x :: xs;
   896 
   897 (*insertion into list, optimized version for ints*)
   898 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   899 
   900 (*insertion into list, optimized version for strings*)
   901 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   902 
   903 (*generalized insertion*)
   904 fun gen_ins eq (x, xs) = insert eq x xs;
   905 
   906 (*union of sets represented as lists: no repetitions*)
   907 fun xs union [] = xs
   908   | [] union ys = ys
   909   | (x :: xs) union ys = xs union (x ins ys);
   910 
   911 (*union of sets, optimized version for ints*)
   912 fun (xs:int list) union_int [] = xs
   913   | [] union_int ys = ys
   914   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   915 
   916 (*union of sets, optimized version for strings*)
   917 fun (xs:string list) union_string [] = xs
   918   | [] union_string ys = ys
   919   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   920 
   921 (*generalized union*)
   922 fun gen_union eq (xs, []) = xs
   923   | gen_union eq ([], ys) = ys
   924   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   925 
   926 
   927 (*intersection*)
   928 fun [] inter ys = []
   929   | (x :: xs) inter ys =
   930       if x mem ys then x :: (xs inter ys) else xs inter ys;
   931 
   932 (*intersection, optimized version for ints*)
   933 fun ([]:int list) inter_int ys = []
   934   | (x :: xs) inter_int ys =
   935       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   936 
   937 (*intersection, optimized version for strings *)
   938 fun ([]:string list) inter_string ys = []
   939   | (x :: xs) inter_string ys =
   940       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   941 
   942 (*generalized intersection*)
   943 fun gen_inter eq ([], ys) = []
   944   | gen_inter eq (x::xs, ys) =
   945       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   946                            else      gen_inter eq (xs, ys);
   947 
   948 
   949 (*subset*)
   950 fun [] subset ys = true
   951   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   952 
   953 (*subset, optimized version for ints*)
   954 fun ([]: int list) subset_int ys = true
   955   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   956 
   957 (*subset, optimized version for strings*)
   958 fun ([]: string list) subset_string ys = true
   959   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   960 
   961 (*set equality*)
   962 fun eq_set (xs, ys) =
   963   xs = ys orelse (xs subset ys andalso ys subset xs);
   964 
   965 (*set equality for strings*)
   966 fun eq_set_string ((xs: string list), ys) =
   967   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   968 
   969 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   970 
   971 
   972 (*removing an element from a list WITHOUT duplicates*)
   973 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   974   | [] \ x = [];
   975 
   976 fun ys \\ xs = foldl (op \) (ys,xs);
   977 
   978 (*removing an element from a list -- possibly WITH duplicates*)
   979 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   980 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   981 
   982 (*makes a list of the distinct members of the input; preserves order, takes
   983   first of equal elements*)
   984 fun gen_distinct eq lst =
   985   let
   986     val memb = gen_mem eq;
   987 
   988     fun dist (rev_seen, []) = rev rev_seen
   989       | dist (rev_seen, x :: xs) =
   990           if memb (x, rev_seen) then dist (rev_seen, xs)
   991           else dist (x :: rev_seen, xs);
   992   in
   993     dist ([], lst)
   994   end;
   995 
   996 fun distinct l = gen_distinct (op =) l;
   997 
   998 (*returns the tail beginning with the first repeated element, or []*)
   999 fun findrep [] = []
  1000   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
  1001 
  1002 
  1003 (*returns a list containing all repeated elements exactly once; preserves
  1004   order, takes first of equal elements*)
  1005 fun gen_duplicates eq lst =
  1006   let
  1007     val memb = gen_mem eq;
  1008 
  1009     fun dups (rev_dups, []) = rev rev_dups
  1010       | dups (rev_dups, x :: xs) =
  1011           if memb (x, rev_dups) orelse not (memb (x, xs)) then
  1012             dups (rev_dups, xs)
  1013           else dups (x :: rev_dups, xs);
  1014   in
  1015     dups ([], lst)
  1016   end;
  1017 
  1018 fun duplicates l = gen_duplicates (op =) l;
  1019 
  1020 fun has_duplicates eq =
  1021   let
  1022     fun dups [] = false
  1023       | dups (x :: xs) = member eq xs x orelse dups xs;
  1024   in dups end;
  1025 
  1026 
  1027 
  1028 (** association lists **)
  1029 
  1030 (*association list lookup*)
  1031 fun assoc ([], key) = NONE
  1032   | assoc ((keyi, xi) :: pairs, key) =
  1033       if key = keyi then SOME xi else assoc (pairs, key);
  1034 
  1035 (*association list lookup, optimized version for ints*)
  1036 fun assoc_int ([], (key:int)) = NONE
  1037   | assoc_int ((keyi, xi) :: pairs, key) =
  1038       if key = keyi then SOME xi else assoc_int (pairs, key);
  1039 
  1040 (*association list lookup, optimized version for strings*)
  1041 fun assoc_string ([], (key:string)) = NONE
  1042   | assoc_string ((keyi, xi) :: pairs, key) =
  1043       if key = keyi then SOME xi else assoc_string (pairs, key);
  1044 
  1045 (*association list lookup, optimized version for string*ints*)
  1046 fun assoc_string_int ([], (key:string*int)) = NONE
  1047   | assoc_string_int ((keyi, xi) :: pairs, key) =
  1048       if key = keyi then SOME xi else assoc_string_int (pairs, key);
  1049 
  1050 fun assocs z = curry (these o assoc) z
  1051 
  1052 (*generalized association list lookup*)
  1053 fun gen_assoc eq ([], key) = NONE
  1054   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1055       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1056 
  1057 (*association list update*)
  1058 fun overwrite (al, p as (key, _)) =
  1059   let fun over ((q as (keyi, _)) :: pairs) =
  1060             if keyi = key then p :: pairs else q :: (over pairs)
  1061         | over [] = [p]
  1062   in over al end;
  1063 
  1064 fun gen_overwrite eq (al, p as (key, _)) =
  1065   let fun over ((q as (keyi, _)) :: pairs) =
  1066             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1067         | over [] = [p]
  1068   in over al end;
  1069 
  1070 
  1071 (* lists as tables *)
  1072 
  1073 fun gen_merge_lists _ xs [] = xs
  1074   | gen_merge_lists _ [] ys = ys
  1075   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1076 
  1077 fun gen_merge_lists' _ xs [] = xs
  1078   | gen_merge_lists' _ [] ys = ys
  1079   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1080 
  1081 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1082 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1083 fun merge_alists al = gen_merge_lists eq_fst al;
  1084 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1085 
  1086 
  1087 
  1088 (** balanced trees **)
  1089 
  1090 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1091 
  1092 (*balanced folding; avoids deep nesting*)
  1093 fun fold_bal f [x] = x
  1094   | fold_bal f [] = raise Balance
  1095   | fold_bal f xs =
  1096       let val (ps,qs) = splitAt(length xs div 2, xs)
  1097       in  f (fold_bal f ps, fold_bal f qs)  end;
  1098 
  1099 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1100 fun access_bal (f, g, x) n i =
  1101   let fun acc n i =     (*1<=i<=n*)
  1102           if n=1 then x else
  1103           let val n2 = n div 2
  1104           in  if i<=n2 then f (acc n2 i)
  1105                        else g (acc (n-n2) (i-n2))
  1106           end
  1107   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1108 
  1109 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1110 fun accesses_bal (f, g, x) n =
  1111   let fun acc n =
  1112           if n=1 then [x] else
  1113           let val n2 = n div 2
  1114               val acc2 = acc n2
  1115           in  if n-n2=n2 then map f acc2 @ map g acc2
  1116                          else map f acc2 @ map g (acc (n-n2)) end
  1117   in  if 1<=n then acc n else raise Balance  end;
  1118 
  1119 
  1120 
  1121 (** orders **)
  1122 
  1123 fun rev_order LESS = GREATER
  1124   | rev_order EQUAL = EQUAL
  1125   | rev_order GREATER = LESS;
  1126 
  1127 (*assume rel is a linear strict order*)
  1128 fun make_ord rel (x, y) =
  1129   if rel (x, y) then LESS
  1130   else if rel (y, x) then GREATER
  1131   else EQUAL;
  1132 
  1133 val int_ord = Int.compare;
  1134 val string_ord = String.compare;
  1135 
  1136 fun fast_string_ord (s1, s2) =
  1137   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1138 
  1139 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1140   | option_ord _ (NONE, NONE) = EQUAL
  1141   | option_ord _ (NONE, SOME _) = LESS
  1142   | option_ord _ (SOME _, NONE) = GREATER;
  1143 
  1144 (*lexicographic product*)
  1145 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1146   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1147 
  1148 (*dictionary order -- in general NOT well-founded!*)
  1149 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1150       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1151   | dict_ord _ ([], []) = EQUAL
  1152   | dict_ord _ ([], _ :: _) = LESS
  1153   | dict_ord _ (_ :: _, []) = GREATER;
  1154 
  1155 (*lexicographic product of lists*)
  1156 fun list_ord elem_ord (xs, ys) =
  1157   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1158 
  1159 
  1160 (* sorting *)
  1161 
  1162 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1163 fun sort ord =
  1164   let
  1165     fun qsort [] = []
  1166       | qsort (xs as [_]) = xs
  1167       | qsort (xs as [x, y]) = if ord (x, y) = GREATER then [y, x] else xs
  1168       | qsort xs =
  1169           let val (lts, eqs, gts) = part (nth_elem (length xs div 2, xs)) xs
  1170           in qsort lts @ eqs @ qsort gts end
  1171     and part _ [] = ([], [], [])
  1172       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1173     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1174       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1175       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1176   in qsort end;
  1177 
  1178 (*sort strings*)
  1179 val sort_strings = sort string_ord;
  1180 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1181 
  1182 fun unique_strings ([]: string list) = []
  1183   | unique_strings [x] = [x]
  1184   | unique_strings (x :: y :: ys) =
  1185       if x = y then unique_strings (y :: ys)
  1186       else x :: unique_strings (y :: ys);
  1187 
  1188 
  1189 (** random numbers **)
  1190 
  1191 exception RANDOM;
  1192 
  1193 fun rmod x y = x - y * Real.realFloor (x / y);
  1194 
  1195 local
  1196   val a = 16807.0;
  1197   val m = 2147483647.0;
  1198   val random_seed = ref 1.0;
  1199 in
  1200 
  1201 fun random () =
  1202   let val r = rmod (a * !random_seed) m
  1203   in (random_seed := r; r) end;
  1204 
  1205 end;
  1206 
  1207 fun random_range l h =
  1208   if h < l orelse l < 0 then raise RANDOM
  1209   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1210 
  1211 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1212 
  1213 fun frequency xs =
  1214   let
  1215     val sum = foldl op + (0, map fst xs);
  1216     fun pick n ((k, x) :: xs) =
  1217       if n <= k then x else pick (n - k) xs
  1218   in pick (random_range 1 sum) xs end;
  1219 
  1220 
  1221 (** current directory **)
  1222 
  1223 val cd = OS.FileSys.chDir;
  1224 val pwd = OS.FileSys.getDir;
  1225 
  1226 
  1227 
  1228 (** rational numbers **)
  1229 (* Keep them normalized! *)
  1230 
  1231 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1232 
  1233 exception RAT of string;
  1234 
  1235 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1236 
  1237 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1238   let val absp = abs p
  1239       val m = gcd(absp,q)
  1240   in Rat(a = (0 <= p), absp div m, q div m) end;
  1241 
  1242 fun ratcommon(p,q,r,s) =
  1243   let val den = lcm(q,s)
  1244   in (p*(den div q), r*(den div s), den) end
  1245 
  1246 fun ratge0(Rat(a,p,q)) = a;
  1247 fun ratgt0(Rat(a,p,q)) = a andalso p > 0;
  1248 
  1249 fun ratle(Rat(a,p,q),Rat(b,r,s)) =
  1250   not a andalso b orelse
  1251   a = b andalso
  1252     let val (p,r,_) = ratcommon(p,q,r,s)
  1253     in if a then p <= r else r <= p end
  1254 
  1255 fun ratlt(Rat(a,p,q),Rat(b,r,s)) =
  1256   not a andalso b orelse
  1257   a = b andalso
  1258     let val (p,r,_) = ratcommon(p,q,r,s)
  1259     in if a then p < r else r < p end
  1260 
  1261 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1262   let val (p,r,den) = ratcommon(p,q,r,s)
  1263       val num = (if a then p else ~p) + (if b then r else ~r)
  1264   in ratnorm(true,num,den) end;
  1265 
  1266 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1267 
  1268 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1269 
  1270 fun int_ratdiv(p,q) =
  1271   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1272 
  1273 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1274 
  1275 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1276 
  1277 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1278 
  1279 val rat0 = rat_of_int 0; 
  1280 
  1281 (** misc **)
  1282 
  1283 (*use the keyfun to make a list of (x, key) pairs*)
  1284 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1285   let fun keypair x = (x, keyfun x)
  1286   in map keypair end;
  1287 
  1288 (*given a list of (x, key) pairs and a searchkey
  1289   return the list of xs from each pair whose key equals searchkey*)
  1290 fun keyfilter [] searchkey = []
  1291   | keyfilter ((x, key) :: pairs) searchkey =
  1292       if key = searchkey then x :: keyfilter pairs searchkey
  1293       else keyfilter pairs searchkey;
  1294 
  1295 
  1296 (*Partition list into elements that satisfy predicate and those that don't.
  1297   Preserves order of elements in both lists.*)
  1298 val partition = List.partition;
  1299 
  1300 fun partition_eq (eq:'a * 'a -> bool) =
  1301   let
  1302     fun part [] = []
  1303       | part (x :: ys) =
  1304           let val (xs, xs') = partition (fn y => eq (x, y)) ys
  1305           in (x::xs)::(part xs') end
  1306   in part end;
  1307 
  1308 
  1309 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1310    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1311 fun partition_list p i j =
  1312   let fun part k xs =
  1313             if k>j then
  1314               (case xs of [] => []
  1315                          | _ => raise Fail "partition_list")
  1316             else
  1317             let val (ns, rest) = partition (p k) xs;
  1318             in  ns :: part(k+1)rest  end
  1319   in  part i end;
  1320 
  1321 
  1322 (* generating identifiers *)
  1323 
  1324 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1325 local
  1326 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1327 fun char i =      if i<26 then chr (ord "A" + i)
  1328              else if i<52 then chr (ord "a" + i - 26)
  1329              else if i<62 then chr (ord"0" + i - 52)
  1330              else if i=62 then "_"
  1331              else  (*i=63*)    "'";
  1332 
  1333 val charVec = Vector.tabulate (64, char);
  1334 
  1335 fun newid n =
  1336   let
  1337   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1338 
  1339 val seedr = ref 0;
  1340 
  1341 in
  1342 
  1343 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1344 
  1345 end;
  1346 
  1347 
  1348 (* lexical scanning *)
  1349 
  1350 (*scan a list of characters into "words" composed of "letters" (recognized by
  1351   is_let) and separated by any number of non-"letters"*)
  1352 fun scanwords is_let cs =
  1353   let fun scan1 [] = []
  1354         | scan1 cs =
  1355             let val (lets, rest) = take_prefix is_let cs
  1356             in implode lets :: scanwords is_let rest end;
  1357   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1358 
  1359 
  1360 (* stamps and serial numbers *)
  1361 
  1362 type stamp = unit ref;
  1363 val stamp: unit -> stamp = ref;
  1364 
  1365 type serial = int;
  1366 local val count = ref 0
  1367 in fun serial () = inc count end;
  1368 
  1369 
  1370 (* generic objects *)
  1371 
  1372 (*note that the builtin exception datatype may be extended by new
  1373   constructors at any time*)
  1374 structure Object = struct type T = exn end;
  1375 
  1376 end;
  1377 
  1378 structure BasicLibrary: BASIC_LIBRARY = Library;
  1379 open BasicLibrary;