src/HOL/Algebra/FiniteProduct.thy
author haftmann
Mon Mar 01 13:40:23 2010 +0100 (2010-03-01)
changeset 35416 d8d7d1b785af
parent 35054 a5db9779b026
child 35847 19f1f7066917
permissions -rw-r--r--
replaced a couple of constsdefs by definitions (also some old primrecs by modern ones)
     1 (*  Title:      HOL/Algebra/FiniteProduct.thy
     2     Author:     Clemens Ballarin, started 19 November 2002
     3 
     4 This file is largely based on HOL/Finite_Set.thy.
     5 *)
     6 
     7 theory FiniteProduct imports Group begin
     8 
     9 
    10 subsection {* Product Operator for Commutative Monoids *}
    11 
    12 subsubsection {* Inductive Definition of a Relation for Products over Sets *}
    13 
    14 text {* Instantiation of locale @{text LC} of theory @{text Finite_Set} is not
    15   possible, because here we have explicit typing rules like 
    16   @{text "x \<in> carrier G"}.  We introduce an explicit argument for the domain
    17   @{text D}. *}
    18 
    19 inductive_set
    20   foldSetD :: "['a set, 'b => 'a => 'a, 'a] => ('b set * 'a) set"
    21   for D :: "'a set" and f :: "'b => 'a => 'a" and e :: 'a
    22   where
    23     emptyI [intro]: "e \<in> D ==> ({}, e) \<in> foldSetD D f e"
    24   | insertI [intro]: "[| x ~: A; f x y \<in> D; (A, y) \<in> foldSetD D f e |] ==>
    25                       (insert x A, f x y) \<in> foldSetD D f e"
    26 
    27 inductive_cases empty_foldSetDE [elim!]: "({}, x) \<in> foldSetD D f e"
    28 
    29 definition foldD :: "['a set, 'b => 'a => 'a, 'a, 'b set] => 'a" where
    30   "foldD D f e A == THE x. (A, x) \<in> foldSetD D f e"
    31 
    32 lemma foldSetD_closed:
    33   "[| (A, z) \<in> foldSetD D f e ; e \<in> D; !!x y. [| x \<in> A; y \<in> D |] ==> f x y \<in> D 
    34       |] ==> z \<in> D";
    35   by (erule foldSetD.cases) auto
    36 
    37 lemma Diff1_foldSetD:
    38   "[| (A - {x}, y) \<in> foldSetD D f e; x \<in> A; f x y \<in> D |] ==>
    39    (A, f x y) \<in> foldSetD D f e"
    40   apply (erule insert_Diff [THEN subst], rule foldSetD.intros)
    41     apply auto
    42   done
    43 
    44 lemma foldSetD_imp_finite [simp]: "(A, x) \<in> foldSetD D f e ==> finite A"
    45   by (induct set: foldSetD) auto
    46 
    47 lemma finite_imp_foldSetD:
    48   "[| finite A; e \<in> D; !!x y. [| x \<in> A; y \<in> D |] ==> f x y \<in> D |] ==>
    49    EX x. (A, x) \<in> foldSetD D f e"
    50 proof (induct set: finite)
    51   case empty then show ?case by auto
    52 next
    53   case (insert x F)
    54   then obtain y where y: "(F, y) \<in> foldSetD D f e" by auto
    55   with insert have "y \<in> D" by (auto dest: foldSetD_closed)
    56   with y and insert have "(insert x F, f x y) \<in> foldSetD D f e"
    57     by (intro foldSetD.intros) auto
    58   then show ?case ..
    59 qed
    60 
    61 
    62 text {* Left-Commutative Operations *}
    63 
    64 locale LCD =
    65   fixes B :: "'b set"
    66   and D :: "'a set"
    67   and f :: "'b => 'a => 'a"    (infixl "\<cdot>" 70)
    68   assumes left_commute:
    69     "[| x \<in> B; y \<in> B; z \<in> D |] ==> x \<cdot> (y \<cdot> z) = y \<cdot> (x \<cdot> z)"
    70   and f_closed [simp, intro!]: "!!x y. [| x \<in> B; y \<in> D |] ==> f x y \<in> D"
    71 
    72 lemma (in LCD) foldSetD_closed [dest]:
    73   "(A, z) \<in> foldSetD D f e ==> z \<in> D";
    74   by (erule foldSetD.cases) auto
    75 
    76 lemma (in LCD) Diff1_foldSetD:
    77   "[| (A - {x}, y) \<in> foldSetD D f e; x \<in> A; A \<subseteq> B |] ==>
    78   (A, f x y) \<in> foldSetD D f e"
    79   apply (subgoal_tac "x \<in> B")
    80    prefer 2 apply fast
    81   apply (erule insert_Diff [THEN subst], rule foldSetD.intros)
    82     apply auto
    83   done
    84 
    85 lemma (in LCD) foldSetD_imp_finite [simp]:
    86   "(A, x) \<in> foldSetD D f e ==> finite A"
    87   by (induct set: foldSetD) auto
    88 
    89 lemma (in LCD) finite_imp_foldSetD:
    90   "[| finite A; A \<subseteq> B; e \<in> D |] ==> EX x. (A, x) \<in> foldSetD D f e"
    91 proof (induct set: finite)
    92   case empty then show ?case by auto
    93 next
    94   case (insert x F)
    95   then obtain y where y: "(F, y) \<in> foldSetD D f e" by auto
    96   with insert have "y \<in> D" by auto
    97   with y and insert have "(insert x F, f x y) \<in> foldSetD D f e"
    98     by (intro foldSetD.intros) auto
    99   then show ?case ..
   100 qed
   101 
   102 lemma (in LCD) foldSetD_determ_aux:
   103   "e \<in> D ==> \<forall>A x. A \<subseteq> B & card A < n --> (A, x) \<in> foldSetD D f e -->
   104     (\<forall>y. (A, y) \<in> foldSetD D f e --> y = x)"
   105   apply (induct n)
   106    apply (auto simp add: less_Suc_eq) (* slow *)
   107   apply (erule foldSetD.cases)
   108    apply blast
   109   apply (erule foldSetD.cases)
   110    apply blast
   111   apply clarify
   112   txt {* force simplification of @{text "card A < card (insert ...)"}. *}
   113   apply (erule rev_mp)
   114   apply (simp add: less_Suc_eq_le)
   115   apply (rule impI)
   116   apply (rename_tac xa Aa ya xb Ab yb, case_tac "xa = xb")
   117    apply (subgoal_tac "Aa = Ab")
   118     prefer 2 apply (blast elim!: equalityE)
   119    apply blast
   120   txt {* case @{prop "xa \<notin> xb"}. *}
   121   apply (subgoal_tac "Aa - {xb} = Ab - {xa} & xb \<in> Aa & xa \<in> Ab")
   122    prefer 2 apply (blast elim!: equalityE)
   123   apply clarify
   124   apply (subgoal_tac "Aa = insert xb Ab - {xa}")
   125    prefer 2 apply blast
   126   apply (subgoal_tac "card Aa \<le> card Ab")
   127    prefer 2
   128    apply (rule Suc_le_mono [THEN subst])
   129    apply (simp add: card_Suc_Diff1)
   130   apply (rule_tac A1 = "Aa - {xb}" in finite_imp_foldSetD [THEN exE])
   131      apply (blast intro: foldSetD_imp_finite finite_Diff)
   132     apply best
   133    apply assumption
   134   apply (frule (1) Diff1_foldSetD)
   135    apply best
   136   apply (subgoal_tac "ya = f xb x")
   137    prefer 2
   138    apply (subgoal_tac "Aa \<subseteq> B")
   139     prefer 2 apply best (* slow *)
   140    apply (blast del: equalityCE)
   141   apply (subgoal_tac "(Ab - {xa}, x) \<in> foldSetD D f e")
   142    prefer 2 apply simp
   143   apply (subgoal_tac "yb = f xa x")
   144    prefer 2 
   145    apply (blast del: equalityCE dest: Diff1_foldSetD)
   146   apply (simp (no_asm_simp))
   147   apply (rule left_commute)
   148     apply assumption
   149    apply best (* slow *)
   150   apply best
   151   done
   152 
   153 lemma (in LCD) foldSetD_determ:
   154   "[| (A, x) \<in> foldSetD D f e; (A, y) \<in> foldSetD D f e; e \<in> D; A \<subseteq> B |]
   155   ==> y = x"
   156   by (blast intro: foldSetD_determ_aux [rule_format])
   157 
   158 lemma (in LCD) foldD_equality:
   159   "[| (A, y) \<in> foldSetD D f e; e \<in> D; A \<subseteq> B |] ==> foldD D f e A = y"
   160   by (unfold foldD_def) (blast intro: foldSetD_determ)
   161 
   162 lemma foldD_empty [simp]:
   163   "e \<in> D ==> foldD D f e {} = e"
   164   by (unfold foldD_def) blast
   165 
   166 lemma (in LCD) foldD_insert_aux:
   167   "[| x ~: A; x \<in> B; e \<in> D; A \<subseteq> B |] ==>
   168     ((insert x A, v) \<in> foldSetD D f e) =
   169     (EX y. (A, y) \<in> foldSetD D f e & v = f x y)"
   170   apply auto
   171   apply (rule_tac A1 = A in finite_imp_foldSetD [THEN exE])
   172      apply (fastsimp dest: foldSetD_imp_finite)
   173     apply assumption
   174    apply assumption
   175   apply (blast intro: foldSetD_determ)
   176   done
   177 
   178 lemma (in LCD) foldD_insert:
   179     "[| finite A; x ~: A; x \<in> B; e \<in> D; A \<subseteq> B |] ==>
   180      foldD D f e (insert x A) = f x (foldD D f e A)"
   181   apply (unfold foldD_def)
   182   apply (simp add: foldD_insert_aux)
   183   apply (rule the_equality)
   184    apply (auto intro: finite_imp_foldSetD
   185      cong add: conj_cong simp add: foldD_def [symmetric] foldD_equality)
   186   done
   187 
   188 lemma (in LCD) foldD_closed [simp]:
   189   "[| finite A; e \<in> D; A \<subseteq> B |] ==> foldD D f e A \<in> D"
   190 proof (induct set: finite)
   191   case empty then show ?case by (simp add: foldD_empty)
   192 next
   193   case insert then show ?case by (simp add: foldD_insert)
   194 qed
   195 
   196 lemma (in LCD) foldD_commute:
   197   "[| finite A; x \<in> B; e \<in> D; A \<subseteq> B |] ==>
   198    f x (foldD D f e A) = foldD D f (f x e) A"
   199   apply (induct set: finite)
   200    apply simp
   201   apply (auto simp add: left_commute foldD_insert)
   202   done
   203 
   204 lemma Int_mono2:
   205   "[| A \<subseteq> C; B \<subseteq> C |] ==> A Int B \<subseteq> C"
   206   by blast
   207 
   208 lemma (in LCD) foldD_nest_Un_Int:
   209   "[| finite A; finite C; e \<in> D; A \<subseteq> B; C \<subseteq> B |] ==>
   210    foldD D f (foldD D f e C) A = foldD D f (foldD D f e (A Int C)) (A Un C)"
   211   apply (induct set: finite)
   212    apply simp
   213   apply (simp add: foldD_insert foldD_commute Int_insert_left insert_absorb
   214     Int_mono2)
   215   done
   216 
   217 lemma (in LCD) foldD_nest_Un_disjoint:
   218   "[| finite A; finite B; A Int B = {}; e \<in> D; A \<subseteq> B; C \<subseteq> B |]
   219     ==> foldD D f e (A Un B) = foldD D f (foldD D f e B) A"
   220   by (simp add: foldD_nest_Un_Int)
   221 
   222 -- {* Delete rules to do with @{text foldSetD} relation. *}
   223 
   224 declare foldSetD_imp_finite [simp del]
   225   empty_foldSetDE [rule del]
   226   foldSetD.intros [rule del]
   227 declare (in LCD)
   228   foldSetD_closed [rule del]
   229 
   230 
   231 text {* Commutative Monoids *}
   232 
   233 text {*
   234   We enter a more restrictive context, with @{text "f :: 'a => 'a => 'a"}
   235   instead of @{text "'b => 'a => 'a"}.
   236 *}
   237 
   238 locale ACeD =
   239   fixes D :: "'a set"
   240     and f :: "'a => 'a => 'a"    (infixl "\<cdot>" 70)
   241     and e :: 'a
   242   assumes ident [simp]: "x \<in> D ==> x \<cdot> e = x"
   243     and commute: "[| x \<in> D; y \<in> D |] ==> x \<cdot> y = y \<cdot> x"
   244     and assoc: "[| x \<in> D; y \<in> D; z \<in> D |] ==> (x \<cdot> y) \<cdot> z = x \<cdot> (y \<cdot> z)"
   245     and e_closed [simp]: "e \<in> D"
   246     and f_closed [simp]: "[| x \<in> D; y \<in> D |] ==> x \<cdot> y \<in> D"
   247 
   248 lemma (in ACeD) left_commute:
   249   "[| x \<in> D; y \<in> D; z \<in> D |] ==> x \<cdot> (y \<cdot> z) = y \<cdot> (x \<cdot> z)"
   250 proof -
   251   assume D: "x \<in> D" "y \<in> D" "z \<in> D"
   252   then have "x \<cdot> (y \<cdot> z) = (y \<cdot> z) \<cdot> x" by (simp add: commute)
   253   also from D have "... = y \<cdot> (z \<cdot> x)" by (simp add: assoc)
   254   also from D have "z \<cdot> x = x \<cdot> z" by (simp add: commute)
   255   finally show ?thesis .
   256 qed
   257 
   258 lemmas (in ACeD) AC = assoc commute left_commute
   259 
   260 lemma (in ACeD) left_ident [simp]: "x \<in> D ==> e \<cdot> x = x"
   261 proof -
   262   assume "x \<in> D"
   263   then have "x \<cdot> e = x" by (rule ident)
   264   with `x \<in> D` show ?thesis by (simp add: commute)
   265 qed
   266 
   267 lemma (in ACeD) foldD_Un_Int:
   268   "[| finite A; finite B; A \<subseteq> D; B \<subseteq> D |] ==>
   269     foldD D f e A \<cdot> foldD D f e B =
   270     foldD D f e (A Un B) \<cdot> foldD D f e (A Int B)"
   271   apply (induct set: finite)
   272    apply (simp add: left_commute LCD.foldD_closed [OF LCD.intro [of D]])
   273   apply (simp add: AC insert_absorb Int_insert_left
   274     LCD.foldD_insert [OF LCD.intro [of D]]
   275     LCD.foldD_closed [OF LCD.intro [of D]]
   276     Int_mono2)
   277   done
   278 
   279 lemma (in ACeD) foldD_Un_disjoint:
   280   "[| finite A; finite B; A Int B = {}; A \<subseteq> D; B \<subseteq> D |] ==>
   281     foldD D f e (A Un B) = foldD D f e A \<cdot> foldD D f e B"
   282   by (simp add: foldD_Un_Int
   283     left_commute LCD.foldD_closed [OF LCD.intro [of D]])
   284 
   285 
   286 subsubsection {* Products over Finite Sets *}
   287 
   288 constdefs (structure G)
   289   finprod :: "[('b, 'm) monoid_scheme, 'a => 'b, 'a set] => 'b"
   290   "finprod G f A == if finite A
   291       then foldD (carrier G) (mult G o f) \<one> A
   292       else undefined"
   293 
   294 syntax
   295   "_finprod" :: "index => idt => 'a set => 'b => 'b"
   296       ("(3\<Otimes>__:_. _)" [1000, 0, 51, 10] 10)
   297 syntax (xsymbols)
   298   "_finprod" :: "index => idt => 'a set => 'b => 'b"
   299       ("(3\<Otimes>__\<in>_. _)" [1000, 0, 51, 10] 10)
   300 syntax (HTML output)
   301   "_finprod" :: "index => idt => 'a set => 'b => 'b"
   302       ("(3\<Otimes>__\<in>_. _)" [1000, 0, 51, 10] 10)
   303 translations
   304   "\<Otimes>\<index>i:A. b" == "CONST finprod \<struct>\<index> (%i. b) A"
   305   -- {* Beware of argument permutation! *}
   306 
   307 lemma (in comm_monoid) finprod_empty [simp]: 
   308   "finprod G f {} = \<one>"
   309   by (simp add: finprod_def)
   310 
   311 declare funcsetI [intro]
   312   funcset_mem [dest]
   313 
   314 context comm_monoid begin
   315 
   316 lemma finprod_insert [simp]:
   317   "[| finite F; a \<notin> F; f \<in> F -> carrier G; f a \<in> carrier G |] ==>
   318    finprod G f (insert a F) = f a \<otimes> finprod G f F"
   319   apply (rule trans)
   320    apply (simp add: finprod_def)
   321   apply (rule trans)
   322    apply (rule LCD.foldD_insert [OF LCD.intro [of "insert a F"]])
   323          apply simp
   324          apply (rule m_lcomm)
   325            apply fast
   326           apply fast
   327          apply assumption
   328         apply (fastsimp intro: m_closed)
   329        apply simp+
   330    apply fast
   331   apply (auto simp add: finprod_def)
   332   done
   333 
   334 lemma finprod_one [simp]:
   335   "finite A ==> (\<Otimes>i:A. \<one>) = \<one>"
   336 proof (induct set: finite)
   337   case empty show ?case by simp
   338 next
   339   case (insert a A)
   340   have "(%i. \<one>) \<in> A -> carrier G" by auto
   341   with insert show ?case by simp
   342 qed
   343 
   344 lemma finprod_closed [simp]:
   345   fixes A
   346   assumes fin: "finite A" and f: "f \<in> A -> carrier G" 
   347   shows "finprod G f A \<in> carrier G"
   348 using fin f
   349 proof induct
   350   case empty show ?case by simp
   351 next
   352   case (insert a A)
   353   then have a: "f a \<in> carrier G" by fast
   354   from insert have A: "f \<in> A -> carrier G" by fast
   355   from insert A a show ?case by simp
   356 qed
   357 
   358 lemma funcset_Int_left [simp, intro]:
   359   "[| f \<in> A -> C; f \<in> B -> C |] ==> f \<in> A Int B -> C"
   360   by fast
   361 
   362 lemma funcset_Un_left [iff]:
   363   "(f \<in> A Un B -> C) = (f \<in> A -> C & f \<in> B -> C)"
   364   by fast
   365 
   366 lemma finprod_Un_Int:
   367   "[| finite A; finite B; g \<in> A -> carrier G; g \<in> B -> carrier G |] ==>
   368      finprod G g (A Un B) \<otimes> finprod G g (A Int B) =
   369      finprod G g A \<otimes> finprod G g B"
   370 -- {* The reversed orientation looks more natural, but LOOPS as a simprule! *}
   371 proof (induct set: finite)
   372   case empty then show ?case by (simp add: finprod_closed)
   373 next
   374   case (insert a A)
   375   then have a: "g a \<in> carrier G" by fast
   376   from insert have A: "g \<in> A -> carrier G" by fast
   377   from insert A a show ?case
   378     by (simp add: m_ac Int_insert_left insert_absorb finprod_closed
   379           Int_mono2) 
   380 qed
   381 
   382 lemma finprod_Un_disjoint:
   383   "[| finite A; finite B; A Int B = {};
   384       g \<in> A -> carrier G; g \<in> B -> carrier G |]
   385    ==> finprod G g (A Un B) = finprod G g A \<otimes> finprod G g B"
   386   apply (subst finprod_Un_Int [symmetric])
   387       apply (auto simp add: finprod_closed)
   388   done
   389 
   390 lemma finprod_multf:
   391   "[| finite A; f \<in> A -> carrier G; g \<in> A -> carrier G |] ==>
   392    finprod G (%x. f x \<otimes> g x) A = (finprod G f A \<otimes> finprod G g A)"
   393 proof (induct set: finite)
   394   case empty show ?case by simp
   395 next
   396   case (insert a A) then
   397   have fA: "f \<in> A -> carrier G" by fast
   398   from insert have fa: "f a \<in> carrier G" by fast
   399   from insert have gA: "g \<in> A -> carrier G" by fast
   400   from insert have ga: "g a \<in> carrier G" by fast
   401   from insert have fgA: "(%x. f x \<otimes> g x) \<in> A -> carrier G"
   402     by (simp add: Pi_def)
   403   show ?case
   404     by (simp add: insert fA fa gA ga fgA m_ac)
   405 qed
   406 
   407 lemma finprod_cong':
   408   "[| A = B; g \<in> B -> carrier G;
   409       !!i. i \<in> B ==> f i = g i |] ==> finprod G f A = finprod G g B"
   410 proof -
   411   assume prems: "A = B" "g \<in> B -> carrier G"
   412     "!!i. i \<in> B ==> f i = g i"
   413   show ?thesis
   414   proof (cases "finite B")
   415     case True
   416     then have "!!A. [| A = B; g \<in> B -> carrier G;
   417       !!i. i \<in> B ==> f i = g i |] ==> finprod G f A = finprod G g B"
   418     proof induct
   419       case empty thus ?case by simp
   420     next
   421       case (insert x B)
   422       then have "finprod G f A = finprod G f (insert x B)" by simp
   423       also from insert have "... = f x \<otimes> finprod G f B"
   424       proof (intro finprod_insert)
   425         show "finite B" by fact
   426       next
   427         show "x ~: B" by fact
   428       next
   429         assume "x ~: B" "!!i. i \<in> insert x B \<Longrightarrow> f i = g i"
   430           "g \<in> insert x B \<rightarrow> carrier G"
   431         thus "f \<in> B -> carrier G" by fastsimp
   432       next
   433         assume "x ~: B" "!!i. i \<in> insert x B \<Longrightarrow> f i = g i"
   434           "g \<in> insert x B \<rightarrow> carrier G"
   435         thus "f x \<in> carrier G" by fastsimp
   436       qed
   437       also from insert have "... = g x \<otimes> finprod G g B" by fastsimp
   438       also from insert have "... = finprod G g (insert x B)"
   439       by (intro finprod_insert [THEN sym]) auto
   440       finally show ?case .
   441     qed
   442     with prems show ?thesis by simp
   443   next
   444     case False with prems show ?thesis by (simp add: finprod_def)
   445   qed
   446 qed
   447 
   448 lemma finprod_cong:
   449   "[| A = B; f \<in> B -> carrier G = True;
   450       !!i. i \<in> B ==> f i = g i |] ==> finprod G f A = finprod G g B"
   451   (* This order of prems is slightly faster (3%) than the last two swapped. *)
   452   by (rule finprod_cong') force+
   453 
   454 text {*Usually, if this rule causes a failed congruence proof error,
   455   the reason is that the premise @{text "g \<in> B -> carrier G"} cannot be shown.
   456   Adding @{thm [source] Pi_def} to the simpset is often useful.
   457   For this reason, @{thm [source] comm_monoid.finprod_cong}
   458   is not added to the simpset by default.
   459 *}
   460 
   461 end
   462 
   463 declare funcsetI [rule del]
   464   funcset_mem [rule del]
   465 
   466 context comm_monoid begin
   467 
   468 lemma finprod_0 [simp]:
   469   "f \<in> {0::nat} -> carrier G ==> finprod G f {..0} = f 0"
   470 by (simp add: Pi_def)
   471 
   472 lemma finprod_Suc [simp]:
   473   "f \<in> {..Suc n} -> carrier G ==>
   474    finprod G f {..Suc n} = (f (Suc n) \<otimes> finprod G f {..n})"
   475 by (simp add: Pi_def atMost_Suc)
   476 
   477 lemma finprod_Suc2:
   478   "f \<in> {..Suc n} -> carrier G ==>
   479    finprod G f {..Suc n} = (finprod G (%i. f (Suc i)) {..n} \<otimes> f 0)"
   480 proof (induct n)
   481   case 0 thus ?case by (simp add: Pi_def)
   482 next
   483   case Suc thus ?case by (simp add: m_assoc Pi_def)
   484 qed
   485 
   486 lemma finprod_mult [simp]:
   487   "[| f \<in> {..n} -> carrier G; g \<in> {..n} -> carrier G |] ==>
   488      finprod G (%i. f i \<otimes> g i) {..n::nat} =
   489      finprod G f {..n} \<otimes> finprod G g {..n}"
   490   by (induct n) (simp_all add: m_ac Pi_def)
   491 
   492 (* The following two were contributed by Jeremy Avigad. *)
   493 
   494 lemma finprod_reindex:
   495   assumes fin: "finite A"
   496     shows "f : (h ` A) \<rightarrow> carrier G \<Longrightarrow> 
   497         inj_on h A ==> finprod G f (h ` A) = finprod G (%x. f (h x)) A"
   498   using fin apply induct
   499   apply (auto simp add: finprod_insert Pi_def)
   500 done
   501 
   502 lemma finprod_const:
   503   assumes fin [simp]: "finite A"
   504       and a [simp]: "a : carrier G"
   505     shows "finprod G (%x. a) A = a (^) card A"
   506   using fin apply induct
   507   apply force
   508   apply (subst finprod_insert)
   509   apply auto
   510   apply (subst m_comm)
   511   apply auto
   512 done
   513 
   514 (* The following lemma was contributed by Jesus Aransay. *)
   515 
   516 lemma finprod_singleton:
   517   assumes i_in_A: "i \<in> A" and fin_A: "finite A" and f_Pi: "f \<in> A \<rightarrow> carrier G"
   518   shows "(\<Otimes>j\<in>A. if i = j then f j else \<one>) = f i"
   519   using i_in_A finprod_insert [of "A - {i}" i "(\<lambda>j. if i = j then f j else \<one>)"]
   520     fin_A f_Pi finprod_one [of "A - {i}"]
   521     finprod_cong [of "A - {i}" "A - {i}" "(\<lambda>j. if i = j then f j else \<one>)" "(\<lambda>i. \<one>)"] 
   522   unfolding Pi_def simp_implies_def by (force simp add: insert_absorb)
   523 
   524 end
   525 
   526 end