src/HOL/Fun.thy
author haftmann
Mon Mar 01 13:40:23 2010 +0100 (2010-03-01)
changeset 35416 d8d7d1b785af
parent 35115 446c5063e4fd
child 35580 0f74806cab22
permissions -rw-r--r--
replaced a couple of constsdefs by definitions (also some old primrecs by modern ones)
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattice
    10 begin
    11 
    12 text{*As a simplification rule, it replaces all function equalities by
    13   first-order equalities.*}
    14 lemma expand_fun_eq: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
    15 apply (rule iffI)
    16 apply (simp (no_asm_simp))
    17 apply (rule ext)
    18 apply (simp (no_asm_simp))
    19 done
    20 
    21 lemma apply_inverse:
    22   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    23   by auto
    24 
    25 
    26 subsection {* The Identity Function @{text id} *}
    27 
    28 definition
    29   id :: "'a \<Rightarrow> 'a"
    30 where
    31   "id = (\<lambda>x. x)"
    32 
    33 lemma id_apply [simp]: "id x = x"
    34   by (simp add: id_def)
    35 
    36 lemma image_ident [simp]: "(%x. x) ` Y = Y"
    37 by blast
    38 
    39 lemma image_id [simp]: "id ` Y = Y"
    40 by (simp add: id_def)
    41 
    42 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
    43 by blast
    44 
    45 lemma vimage_id [simp]: "id -` A = A"
    46 by (simp add: id_def)
    47 
    48 
    49 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    50 
    51 definition
    52   comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55)
    53 where
    54   "f o g = (\<lambda>x. f (g x))"
    55 
    56 notation (xsymbols)
    57   comp  (infixl "\<circ>" 55)
    58 
    59 notation (HTML output)
    60   comp  (infixl "\<circ>" 55)
    61 
    62 text{*compatibility*}
    63 lemmas o_def = comp_def
    64 
    65 lemma o_apply [simp]: "(f o g) x = f (g x)"
    66 by (simp add: comp_def)
    67 
    68 lemma o_assoc: "f o (g o h) = f o g o h"
    69 by (simp add: comp_def)
    70 
    71 lemma id_o [simp]: "id o g = g"
    72 by (simp add: comp_def)
    73 
    74 lemma o_id [simp]: "f o id = f"
    75 by (simp add: comp_def)
    76 
    77 lemma o_eq_dest:
    78   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    79   by (simp only: o_def) (fact fun_cong)
    80 
    81 lemma o_eq_elim:
    82   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    83   by (erule meta_mp) (fact o_eq_dest) 
    84 
    85 lemma image_compose: "(f o g) ` r = f`(g`r)"
    86 by (simp add: comp_def, blast)
    87 
    88 lemma vimage_compose: "(g \<circ> f) -` x = f -` (g -` x)"
    89   by auto
    90 
    91 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
    92 by (unfold comp_def, blast)
    93 
    94 
    95 subsection {* The Forward Composition Operator @{text fcomp} *}
    96 
    97 definition
    98   fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o>" 60)
    99 where
   100   "f o> g = (\<lambda>x. g (f x))"
   101 
   102 lemma fcomp_apply:  "(f o> g) x = g (f x)"
   103   by (simp add: fcomp_def)
   104 
   105 lemma fcomp_assoc: "(f o> g) o> h = f o> (g o> h)"
   106   by (simp add: fcomp_def)
   107 
   108 lemma id_fcomp [simp]: "id o> g = g"
   109   by (simp add: fcomp_def)
   110 
   111 lemma fcomp_id [simp]: "f o> id = f"
   112   by (simp add: fcomp_def)
   113 
   114 code_const fcomp
   115   (Eval infixl 1 "#>")
   116 
   117 no_notation fcomp (infixl "o>" 60)
   118 
   119 
   120 subsection {* Injectivity and Surjectivity *}
   121 
   122 definition
   123   inj_on :: "['a => 'b, 'a set] => bool" where
   124   -- "injective"
   125   "inj_on f A == ! x:A. ! y:A. f(x)=f(y) --> x=y"
   126 
   127 text{*A common special case: functions injective over the entire domain type.*}
   128 
   129 abbreviation
   130   "inj f == inj_on f UNIV"
   131 
   132 definition
   133   bij_betw :: "('a => 'b) => 'a set => 'b set => bool" where -- "bijective"
   134   [code del]: "bij_betw f A B \<longleftrightarrow> inj_on f A & f ` A = B"
   135 
   136 definition
   137   surj :: "('a => 'b) => bool" where
   138   -- "surjective"
   139   "surj f == ! y. ? x. y=f(x)"
   140 
   141 definition
   142   bij :: "('a => 'b) => bool" where
   143   -- "bijective"
   144   "bij f == inj f & surj f"
   145 
   146 lemma injI:
   147   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   148   shows "inj f"
   149   using assms unfolding inj_on_def by auto
   150 
   151 text{*For Proofs in @{text "Tools/Datatype/datatype_rep_proofs"}*}
   152 lemma datatype_injI:
   153     "(!! x. ALL y. f(x) = f(y) --> x=y) ==> inj(f)"
   154 by (simp add: inj_on_def)
   155 
   156 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   157   by (unfold inj_on_def, blast)
   158 
   159 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   160 by (simp add: inj_on_def)
   161 
   162 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   163 by (force simp add: inj_on_def)
   164 
   165 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   166 by (simp add: inj_on_eq_iff)
   167 
   168 lemma inj_on_id[simp]: "inj_on id A"
   169   by (simp add: inj_on_def) 
   170 
   171 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   172 by (simp add: inj_on_def) 
   173 
   174 lemma surj_id[simp]: "surj id"
   175 by (simp add: surj_def) 
   176 
   177 lemma bij_id[simp]: "bij id"
   178 by (simp add: bij_def)
   179 
   180 lemma inj_onI:
   181     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   182 by (simp add: inj_on_def)
   183 
   184 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   185 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   186 
   187 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   188 by (unfold inj_on_def, blast)
   189 
   190 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   191 by (blast dest!: inj_onD)
   192 
   193 lemma comp_inj_on:
   194      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   195 by (simp add: comp_def inj_on_def)
   196 
   197 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   198 apply(simp add:inj_on_def image_def)
   199 apply blast
   200 done
   201 
   202 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   203   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   204 apply(unfold inj_on_def)
   205 apply blast
   206 done
   207 
   208 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   209 by (unfold inj_on_def, blast)
   210 
   211 lemma inj_singleton: "inj (%s. {s})"
   212 by (simp add: inj_on_def)
   213 
   214 lemma inj_on_empty[iff]: "inj_on f {}"
   215 by(simp add: inj_on_def)
   216 
   217 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   218 by (unfold inj_on_def, blast)
   219 
   220 lemma inj_on_Un:
   221  "inj_on f (A Un B) =
   222   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   223 apply(unfold inj_on_def)
   224 apply (blast intro:sym)
   225 done
   226 
   227 lemma inj_on_insert[iff]:
   228   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   229 apply(unfold inj_on_def)
   230 apply (blast intro:sym)
   231 done
   232 
   233 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   234 apply(unfold inj_on_def)
   235 apply (blast)
   236 done
   237 
   238 lemma surjI: "(!! x. g(f x) = x) ==> surj g"
   239 apply (simp add: surj_def)
   240 apply (blast intro: sym)
   241 done
   242 
   243 lemma surj_range: "surj f ==> range f = UNIV"
   244 by (auto simp add: surj_def)
   245 
   246 lemma surjD: "surj f ==> EX x. y = f x"
   247 by (simp add: surj_def)
   248 
   249 lemma surjE: "surj f ==> (!!x. y = f x ==> C) ==> C"
   250 by (simp add: surj_def, blast)
   251 
   252 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   253 apply (simp add: comp_def surj_def, clarify)
   254 apply (drule_tac x = y in spec, clarify)
   255 apply (drule_tac x = x in spec, blast)
   256 done
   257 
   258 lemma bijI: "[| inj f; surj f |] ==> bij f"
   259 by (simp add: bij_def)
   260 
   261 lemma bij_is_inj: "bij f ==> inj f"
   262 by (simp add: bij_def)
   263 
   264 lemma bij_is_surj: "bij f ==> surj f"
   265 by (simp add: bij_def)
   266 
   267 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   268 by (simp add: bij_betw_def)
   269 
   270 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   271 by(fastsimp intro: comp_inj_on comp_surj simp: bij_def surj_range)
   272 
   273 lemma bij_betw_trans:
   274   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   275 by(auto simp add:bij_betw_def comp_inj_on)
   276 
   277 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   278 proof -
   279   have i: "inj_on f A" and s: "f ` A = B"
   280     using assms by(auto simp:bij_betw_def)
   281   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   282   { fix a b assume P: "?P b a"
   283     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   284     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   285     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   286   } note g = this
   287   have "inj_on ?g B"
   288   proof(rule inj_onI)
   289     fix x y assume "x:B" "y:B" "?g x = ?g y"
   290     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   291     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   292     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   293   qed
   294   moreover have "?g ` B = A"
   295   proof(auto simp:image_def)
   296     fix b assume "b:B"
   297     with s obtain a where P: "?P b a" unfolding image_def by blast
   298     thus "?g b \<in> A" using g[OF P] by auto
   299   next
   300     fix a assume "a:A"
   301     then obtain b where P: "?P b a" using s unfolding image_def by blast
   302     then have "b:B" using s unfolding image_def by blast
   303     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   304   qed
   305   ultimately show ?thesis by(auto simp:bij_betw_def)
   306 qed
   307 
   308 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   309 by (simp add: surj_range)
   310 
   311 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   312 by (simp add: inj_on_def, blast)
   313 
   314 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   315 apply (unfold surj_def)
   316 apply (blast intro: sym)
   317 done
   318 
   319 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   320 by (unfold inj_on_def, blast)
   321 
   322 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   323 apply (unfold bij_def)
   324 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   325 done
   326 
   327 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   328 by(blast dest: inj_onD)
   329 
   330 lemma inj_on_image_Int:
   331    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   332 apply (simp add: inj_on_def, blast)
   333 done
   334 
   335 lemma inj_on_image_set_diff:
   336    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   337 apply (simp add: inj_on_def, blast)
   338 done
   339 
   340 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   341 by (simp add: inj_on_def, blast)
   342 
   343 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   344 by (simp add: inj_on_def, blast)
   345 
   346 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   347 by (blast dest: injD)
   348 
   349 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   350 by (simp add: inj_on_def, blast)
   351 
   352 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   353 by (blast dest: injD)
   354 
   355 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   356 lemma image_INT:
   357    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   358     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   359 apply (simp add: inj_on_def, blast)
   360 done
   361 
   362 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   363   it doesn't matter whether A is empty*)
   364 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   365 apply (simp add: bij_def)
   366 apply (simp add: inj_on_def surj_def, blast)
   367 done
   368 
   369 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   370 by (auto simp add: surj_def)
   371 
   372 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   373 by (auto simp add: inj_on_def)
   374 
   375 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   376 apply (simp add: bij_def)
   377 apply (rule equalityI)
   378 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   379 done
   380 
   381 
   382 subsection{*Function Updating*}
   383 
   384 definition
   385   fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   386   "fun_upd f a b == % x. if x=a then b else f x"
   387 
   388 nonterminals
   389   updbinds updbind
   390 syntax
   391   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   392   ""         :: "updbind => updbinds"             ("_")
   393   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   394   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   395 
   396 translations
   397   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   398   "f(x:=y)" == "CONST fun_upd f x y"
   399 
   400 (* Hint: to define the sum of two functions (or maps), use sum_case.
   401          A nice infix syntax could be defined (in Datatype.thy or below) by
   402 notation
   403   sum_case  (infixr "'(+')"80)
   404 *)
   405 
   406 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   407 apply (simp add: fun_upd_def, safe)
   408 apply (erule subst)
   409 apply (rule_tac [2] ext, auto)
   410 done
   411 
   412 (* f x = y ==> f(x:=y) = f *)
   413 lemmas fun_upd_idem = fun_upd_idem_iff [THEN iffD2, standard]
   414 
   415 (* f(x := f x) = f *)
   416 lemmas fun_upd_triv = refl [THEN fun_upd_idem]
   417 declare fun_upd_triv [iff]
   418 
   419 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   420 by (simp add: fun_upd_def)
   421 
   422 (* fun_upd_apply supersedes these two,   but they are useful
   423    if fun_upd_apply is intentionally removed from the simpset *)
   424 lemma fun_upd_same: "(f(x:=y)) x = y"
   425 by simp
   426 
   427 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   428 by simp
   429 
   430 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   431 by (simp add: expand_fun_eq)
   432 
   433 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   434 by (rule ext, auto)
   435 
   436 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   437 by (fastsimp simp:inj_on_def image_def)
   438 
   439 lemma fun_upd_image:
   440      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   441 by auto
   442 
   443 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   444 by (auto intro: ext)
   445 
   446 
   447 subsection {* @{text override_on} *}
   448 
   449 definition
   450   override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
   451 where
   452   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   453 
   454 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   455 by(simp add:override_on_def)
   456 
   457 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   458 by(simp add:override_on_def)
   459 
   460 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   461 by(simp add:override_on_def)
   462 
   463 
   464 subsection {* @{text swap} *}
   465 
   466 definition
   467   swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   468 where
   469   "swap a b f = f (a := f b, b:= f a)"
   470 
   471 lemma swap_self [simp]: "swap a a f = f"
   472 by (simp add: swap_def)
   473 
   474 lemma swap_commute: "swap a b f = swap b a f"
   475 by (rule ext, simp add: fun_upd_def swap_def)
   476 
   477 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   478 by (rule ext, simp add: fun_upd_def swap_def)
   479 
   480 lemma swap_triple:
   481   assumes "a \<noteq> c" and "b \<noteq> c"
   482   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   483   using assms by (simp add: expand_fun_eq swap_def)
   484 
   485 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   486 by (rule ext, simp add: fun_upd_def swap_def)
   487 
   488 lemma inj_on_imp_inj_on_swap:
   489   "[|inj_on f A; a \<in> A; b \<in> A|] ==> inj_on (swap a b f) A"
   490 by (simp add: inj_on_def swap_def, blast)
   491 
   492 lemma inj_on_swap_iff [simp]:
   493   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A = inj_on f A"
   494 proof 
   495   assume "inj_on (swap a b f) A"
   496   with A have "inj_on (swap a b (swap a b f)) A" 
   497     by (iprover intro: inj_on_imp_inj_on_swap) 
   498   thus "inj_on f A" by simp 
   499 next
   500   assume "inj_on f A"
   501   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   502 qed
   503 
   504 lemma surj_imp_surj_swap: "surj f ==> surj (swap a b f)"
   505 apply (simp add: surj_def swap_def, clarify)
   506 apply (case_tac "y = f b", blast)
   507 apply (case_tac "y = f a", auto)
   508 done
   509 
   510 lemma surj_swap_iff [simp]: "surj (swap a b f) = surj f"
   511 proof 
   512   assume "surj (swap a b f)"
   513   hence "surj (swap a b (swap a b f))" by (rule surj_imp_surj_swap) 
   514   thus "surj f" by simp 
   515 next
   516   assume "surj f"
   517   thus "surj (swap a b f)" by (rule surj_imp_surj_swap) 
   518 qed
   519 
   520 lemma bij_swap_iff: "bij (swap a b f) = bij f"
   521 by (simp add: bij_def)
   522 
   523 hide (open) const swap
   524 
   525 
   526 subsection {* Inversion of injective functions *}
   527 
   528 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   529 "the_inv_into A f == %x. THE y. y : A & f y = x"
   530 
   531 lemma the_inv_into_f_f:
   532   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   533 apply (simp add: the_inv_into_def inj_on_def)
   534 apply blast
   535 done
   536 
   537 lemma f_the_inv_into_f:
   538   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   539 apply (simp add: the_inv_into_def)
   540 apply (rule the1I2)
   541  apply(blast dest: inj_onD)
   542 apply blast
   543 done
   544 
   545 lemma the_inv_into_into:
   546   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   547 apply (simp add: the_inv_into_def)
   548 apply (rule the1I2)
   549  apply(blast dest: inj_onD)
   550 apply blast
   551 done
   552 
   553 lemma the_inv_into_onto[simp]:
   554   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   555 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   556 
   557 lemma the_inv_into_f_eq:
   558   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   559   apply (erule subst)
   560   apply (erule the_inv_into_f_f, assumption)
   561   done
   562 
   563 lemma the_inv_into_comp:
   564   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   565   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   566 apply (rule the_inv_into_f_eq)
   567   apply (fast intro: comp_inj_on)
   568  apply (simp add: f_the_inv_into_f the_inv_into_into)
   569 apply (simp add: the_inv_into_into)
   570 done
   571 
   572 lemma inj_on_the_inv_into:
   573   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   574 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   575 
   576 lemma bij_betw_the_inv_into:
   577   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   578 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   579 
   580 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   581   "the_inv f \<equiv> the_inv_into UNIV f"
   582 
   583 lemma the_inv_f_f:
   584   assumes "inj f"
   585   shows "the_inv f (f x) = x" using assms UNIV_I
   586   by (rule the_inv_into_f_f)
   587 
   588 
   589 subsection {* Proof tool setup *} 
   590 
   591 text {* simplifies terms of the form
   592   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   593 
   594 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   595 let
   596   fun gen_fun_upd NONE T _ _ = NONE
   597     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   598   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   599   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   600     let
   601       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   602             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   603         | find t = NONE
   604     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   605 
   606   fun proc ss ct =
   607     let
   608       val ctxt = Simplifier.the_context ss
   609       val t = Thm.term_of ct
   610     in
   611       case find_double t of
   612         (T, NONE) => NONE
   613       | (T, SOME rhs) =>
   614           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   615             (fn _ =>
   616               rtac eq_reflection 1 THEN
   617               rtac ext 1 THEN
   618               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   619     end
   620 in proc end
   621 *}
   622 
   623 
   624 subsection {* Code generator setup *}
   625 
   626 types_code
   627   "fun"  ("(_ ->/ _)")
   628 attach (term_of) {*
   629 fun term_of_fun_type _ aT _ bT _ = Free ("<function>", aT --> bT);
   630 *}
   631 attach (test) {*
   632 fun gen_fun_type aF aT bG bT i =
   633   let
   634     val tab = Unsynchronized.ref [];
   635     fun mk_upd (x, (_, y)) t = Const ("Fun.fun_upd",
   636       (aT --> bT) --> aT --> bT --> aT --> bT) $ t $ aF x $ y ()
   637   in
   638     (fn x =>
   639        case AList.lookup op = (!tab) x of
   640          NONE =>
   641            let val p as (y, _) = bG i
   642            in (tab := (x, p) :: !tab; y) end
   643        | SOME (y, _) => y,
   644      fn () => Basics.fold mk_upd (!tab) (Const ("HOL.undefined", aT --> bT)))
   645   end;
   646 *}
   647 
   648 code_const "op \<circ>"
   649   (SML infixl 5 "o")
   650   (Haskell infixr 9 ".")
   651 
   652 code_const "id"
   653   (Haskell "id")
   654 
   655 end