src/ZF/Sum.thy
author haftmann
Mon Mar 01 13:40:23 2010 +0100 (2010-03-01)
changeset 35416 d8d7d1b785af
parent 32960 69916a850301
child 38514 bd9c4e8281ec
permissions -rw-r--r--
replaced a couple of constsdefs by definitions (also some old primrecs by modern ones)
     1 (*  Title:      ZF/sum.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1993  University of Cambridge
     4 *)
     5 
     6 header{*Disjoint Sums*}
     7 
     8 theory Sum imports Bool equalities begin
     9 
    10 text{*And the "Part" primitive for simultaneous recursive type definitions*}
    11 
    12 global
    13 
    14 definition sum :: "[i,i]=>i" (infixr "+" 65) where
    15      "A+B == {0}*A Un {1}*B"
    16 
    17 definition Inl :: "i=>i" where
    18      "Inl(a) == <0,a>"
    19 
    20 definition Inr :: "i=>i" where
    21      "Inr(b) == <1,b>"
    22 
    23 definition "case" :: "[i=>i, i=>i, i]=>i" where
    24      "case(c,d) == (%<y,z>. cond(y, d(z), c(z)))"
    25 
    26   (*operator for selecting out the various summands*)
    27 definition Part :: "[i,i=>i] => i" where
    28      "Part(A,h) == {x: A. EX z. x = h(z)}"
    29 
    30 local
    31 
    32 subsection{*Rules for the @{term Part} Primitive*}
    33 
    34 lemma Part_iff: 
    35     "a : Part(A,h) <-> a:A & (EX y. a=h(y))"
    36 apply (unfold Part_def)
    37 apply (rule separation)
    38 done
    39 
    40 lemma Part_eqI [intro]: 
    41     "[| a : A;  a=h(b) |] ==> a : Part(A,h)"
    42 by (unfold Part_def, blast)
    43 
    44 lemmas PartI = refl [THEN [2] Part_eqI]
    45 
    46 lemma PartE [elim!]: 
    47     "[| a : Part(A,h);  !!z. [| a : A;  a=h(z) |] ==> P   
    48      |] ==> P"
    49 apply (unfold Part_def, blast)
    50 done
    51 
    52 lemma Part_subset: "Part(A,h) <= A"
    53 apply (unfold Part_def)
    54 apply (rule Collect_subset)
    55 done
    56 
    57 
    58 subsection{*Rules for Disjoint Sums*}
    59 
    60 lemmas sum_defs = sum_def Inl_def Inr_def case_def
    61 
    62 lemma Sigma_bool: "Sigma(bool,C) = C(0) + C(1)"
    63 by (unfold bool_def sum_def, blast)
    64 
    65 (** Introduction rules for the injections **)
    66 
    67 lemma InlI [intro!,simp,TC]: "a : A ==> Inl(a) : A+B"
    68 by (unfold sum_defs, blast)
    69 
    70 lemma InrI [intro!,simp,TC]: "b : B ==> Inr(b) : A+B"
    71 by (unfold sum_defs, blast)
    72 
    73 (** Elimination rules **)
    74 
    75 lemma sumE [elim!]:
    76     "[| u: A+B;   
    77         !!x. [| x:A;  u=Inl(x) |] ==> P;  
    78         !!y. [| y:B;  u=Inr(y) |] ==> P  
    79      |] ==> P"
    80 by (unfold sum_defs, blast) 
    81 
    82 (** Injection and freeness equivalences, for rewriting **)
    83 
    84 lemma Inl_iff [iff]: "Inl(a)=Inl(b) <-> a=b"
    85 by (simp add: sum_defs)
    86 
    87 lemma Inr_iff [iff]: "Inr(a)=Inr(b) <-> a=b"
    88 by (simp add: sum_defs)
    89 
    90 lemma Inl_Inr_iff [simp]: "Inl(a)=Inr(b) <-> False"
    91 by (simp add: sum_defs)
    92 
    93 lemma Inr_Inl_iff [simp]: "Inr(b)=Inl(a) <-> False"
    94 by (simp add: sum_defs)
    95 
    96 lemma sum_empty [simp]: "0+0 = 0"
    97 by (simp add: sum_defs)
    98 
    99 (*Injection and freeness rules*)
   100 
   101 lemmas Inl_inject = Inl_iff [THEN iffD1, standard]
   102 lemmas Inr_inject = Inr_iff [THEN iffD1, standard]
   103 lemmas Inl_neq_Inr = Inl_Inr_iff [THEN iffD1, THEN FalseE, elim!]
   104 lemmas Inr_neq_Inl = Inr_Inl_iff [THEN iffD1, THEN FalseE, elim!]
   105 
   106 
   107 lemma InlD: "Inl(a): A+B ==> a: A"
   108 by blast
   109 
   110 lemma InrD: "Inr(b): A+B ==> b: B"
   111 by blast
   112 
   113 lemma sum_iff: "u: A+B <-> (EX x. x:A & u=Inl(x)) | (EX y. y:B & u=Inr(y))"
   114 by blast
   115 
   116 lemma Inl_in_sum_iff [simp]: "(Inl(x) \<in> A+B) <-> (x \<in> A)";
   117 by auto
   118 
   119 lemma Inr_in_sum_iff [simp]: "(Inr(y) \<in> A+B) <-> (y \<in> B)";
   120 by auto
   121 
   122 lemma sum_subset_iff: "A+B <= C+D <-> A<=C & B<=D"
   123 by blast
   124 
   125 lemma sum_equal_iff: "A+B = C+D <-> A=C & B=D"
   126 by (simp add: extension sum_subset_iff, blast)
   127 
   128 lemma sum_eq_2_times: "A+A = 2*A"
   129 by (simp add: sum_def, blast)
   130 
   131 
   132 subsection{*The Eliminator: @{term case}*}
   133 
   134 lemma case_Inl [simp]: "case(c, d, Inl(a)) = c(a)"
   135 by (simp add: sum_defs)
   136 
   137 lemma case_Inr [simp]: "case(c, d, Inr(b)) = d(b)"
   138 by (simp add: sum_defs)
   139 
   140 lemma case_type [TC]:
   141     "[| u: A+B;  
   142         !!x. x: A ==> c(x): C(Inl(x));    
   143         !!y. y: B ==> d(y): C(Inr(y))  
   144      |] ==> case(c,d,u) : C(u)"
   145 by auto
   146 
   147 lemma expand_case: "u: A+B ==>    
   148         R(case(c,d,u)) <->  
   149         ((ALL x:A. u = Inl(x) --> R(c(x))) &  
   150         (ALL y:B. u = Inr(y) --> R(d(y))))"
   151 by auto
   152 
   153 lemma case_cong:
   154   "[| z: A+B;    
   155       !!x. x:A ==> c(x)=c'(x);   
   156       !!y. y:B ==> d(y)=d'(y)    
   157    |] ==> case(c,d,z) = case(c',d',z)"
   158 by auto 
   159 
   160 lemma case_case: "z: A+B ==>    
   161         case(c, d, case(%x. Inl(c'(x)), %y. Inr(d'(y)), z)) =  
   162         case(%x. c(c'(x)), %y. d(d'(y)), z)"
   163 by auto
   164 
   165 
   166 subsection{*More Rules for @{term "Part(A,h)"}*}
   167 
   168 lemma Part_mono: "A<=B ==> Part(A,h)<=Part(B,h)"
   169 by blast
   170 
   171 lemma Part_Collect: "Part(Collect(A,P), h) = Collect(Part(A,h), P)"
   172 by blast
   173 
   174 lemmas Part_CollectE =
   175      Part_Collect [THEN equalityD1, THEN subsetD, THEN CollectE, standard]
   176 
   177 lemma Part_Inl: "Part(A+B,Inl) = {Inl(x). x: A}"
   178 by blast
   179 
   180 lemma Part_Inr: "Part(A+B,Inr) = {Inr(y). y: B}"
   181 by blast
   182 
   183 lemma PartD1: "a : Part(A,h) ==> a : A"
   184 by (simp add: Part_def)
   185 
   186 lemma Part_id: "Part(A,%x. x) = A"
   187 by blast
   188 
   189 lemma Part_Inr2: "Part(A+B, %x. Inr(h(x))) = {Inr(y). y: Part(B,h)}"
   190 by blast
   191 
   192 lemma Part_sum_equality: "C <= A+B ==> Part(C,Inl) Un Part(C,Inr) = C"
   193 by blast
   194 
   195 end