src/HOL/Finite_Set.thy
author wenzelm
Sat Jul 18 22:58:50 2015 +0200 (2015-07-18)
changeset 60758 d8d85a8172b5
parent 60595 804dfdc82835
child 60762 bf0c76ccee8d
permissions -rw-r--r--
isabelle update_cartouches;
     1 (*  Title:      HOL/Finite_Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3                 with contributions by Jeremy Avigad and Andrei Popescu
     4 *)
     5 
     6 section \<open>Finite sets\<close>
     7 
     8 theory Finite_Set
     9 imports Product_Type Sum_Type Nat
    10 begin
    11 
    12 subsection \<open>Predicate for finite sets\<close>
    13 
    14 inductive finite :: "'a set \<Rightarrow> bool"
    15   where
    16     emptyI [simp, intro!]: "finite {}"
    17   | insertI [simp, intro!]: "finite A \<Longrightarrow> finite (insert a A)"
    18 
    19 simproc_setup finite_Collect ("finite (Collect P)") = \<open>K Set_Comprehension_Pointfree.simproc\<close>
    20 
    21 declare [[simproc del: finite_Collect]]
    22 
    23 lemma finite_induct [case_names empty insert, induct set: finite]:
    24   -- \<open>Discharging @{text "x \<notin> F"} entails extra work.\<close>
    25   assumes "finite F"
    26   assumes "P {}"
    27     and insert: "\<And>x F. finite F \<Longrightarrow> x \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert x F)"
    28   shows "P F"
    29 using \<open>finite F\<close>
    30 proof induct
    31   show "P {}" by fact
    32   fix x F assume F: "finite F" and P: "P F"
    33   show "P (insert x F)"
    34   proof cases
    35     assume "x \<in> F"
    36     hence "insert x F = F" by (rule insert_absorb)
    37     with P show ?thesis by (simp only:)
    38   next
    39     assume "x \<notin> F"
    40     from F this P show ?thesis by (rule insert)
    41   qed
    42 qed
    43 
    44 lemma infinite_finite_induct [case_names infinite empty insert]:
    45   assumes infinite: "\<And>A. \<not> finite A \<Longrightarrow> P A"
    46   assumes empty: "P {}"
    47   assumes insert: "\<And>x F. finite F \<Longrightarrow> x \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert x F)"
    48   shows "P A"
    49 proof (cases "finite A")
    50   case False with infinite show ?thesis .
    51 next
    52   case True then show ?thesis by (induct A) (fact empty insert)+
    53 qed
    54 
    55 
    56 subsubsection \<open>Choice principles\<close>
    57 
    58 lemma ex_new_if_finite: -- "does not depend on def of finite at all"
    59   assumes "\<not> finite (UNIV :: 'a set)" and "finite A"
    60   shows "\<exists>a::'a. a \<notin> A"
    61 proof -
    62   from assms have "A \<noteq> UNIV" by blast
    63   then show ?thesis by blast
    64 qed
    65 
    66 text \<open>A finite choice principle. Does not need the SOME choice operator.\<close>
    67 
    68 lemma finite_set_choice:
    69   "finite A \<Longrightarrow> \<forall>x\<in>A. \<exists>y. P x y \<Longrightarrow> \<exists>f. \<forall>x\<in>A. P x (f x)"
    70 proof (induct rule: finite_induct)
    71   case empty then show ?case by simp
    72 next
    73   case (insert a A)
    74   then obtain f b where f: "ALL x:A. P x (f x)" and ab: "P a b" by auto
    75   show ?case (is "EX f. ?P f")
    76   proof
    77     show "?P(%x. if x = a then b else f x)" using f ab by auto
    78   qed
    79 qed
    80 
    81 
    82 subsubsection \<open>Finite sets are the images of initial segments of natural numbers\<close>
    83 
    84 lemma finite_imp_nat_seg_image_inj_on:
    85   assumes "finite A" 
    86   shows "\<exists>(n::nat) f. A = f ` {i. i < n} \<and> inj_on f {i. i < n}"
    87 using assms
    88 proof induct
    89   case empty
    90   show ?case
    91   proof
    92     show "\<exists>f. {} = f ` {i::nat. i < 0} \<and> inj_on f {i. i < 0}" by simp 
    93   qed
    94 next
    95   case (insert a A)
    96   have notinA: "a \<notin> A" by fact
    97   from insert.hyps obtain n f
    98     where "A = f ` {i::nat. i < n}" "inj_on f {i. i < n}" by blast
    99   hence "insert a A = f(n:=a) ` {i. i < Suc n}"
   100         "inj_on (f(n:=a)) {i. i < Suc n}" using notinA
   101     by (auto simp add: image_def Ball_def inj_on_def less_Suc_eq)
   102   thus ?case by blast
   103 qed
   104 
   105 lemma nat_seg_image_imp_finite:
   106   "A = f ` {i::nat. i < n} \<Longrightarrow> finite A"
   107 proof (induct n arbitrary: A)
   108   case 0 thus ?case by simp
   109 next
   110   case (Suc n)
   111   let ?B = "f ` {i. i < n}"
   112   have finB: "finite ?B" by(rule Suc.hyps[OF refl])
   113   show ?case
   114   proof cases
   115     assume "\<exists>k<n. f n = f k"
   116     hence "A = ?B" using Suc.prems by(auto simp:less_Suc_eq)
   117     thus ?thesis using finB by simp
   118   next
   119     assume "\<not>(\<exists> k<n. f n = f k)"
   120     hence "A = insert (f n) ?B" using Suc.prems by(auto simp:less_Suc_eq)
   121     thus ?thesis using finB by simp
   122   qed
   123 qed
   124 
   125 lemma finite_conv_nat_seg_image:
   126   "finite A \<longleftrightarrow> (\<exists>(n::nat) f. A = f ` {i::nat. i < n})"
   127   by (blast intro: nat_seg_image_imp_finite dest: finite_imp_nat_seg_image_inj_on)
   128 
   129 lemma finite_imp_inj_to_nat_seg:
   130   assumes "finite A"
   131   shows "\<exists>f n::nat. f ` A = {i. i < n} \<and> inj_on f A"
   132 proof -
   133   from finite_imp_nat_seg_image_inj_on[OF \<open>finite A\<close>]
   134   obtain f and n::nat where bij: "bij_betw f {i. i<n} A"
   135     by (auto simp:bij_betw_def)
   136   let ?f = "the_inv_into {i. i<n} f"
   137   have "inj_on ?f A & ?f ` A = {i. i<n}"
   138     by (fold bij_betw_def) (rule bij_betw_the_inv_into[OF bij])
   139   thus ?thesis by blast
   140 qed
   141 
   142 lemma finite_Collect_less_nat [iff]:
   143   "finite {n::nat. n < k}"
   144   by (fastforce simp: finite_conv_nat_seg_image)
   145 
   146 lemma finite_Collect_le_nat [iff]:
   147   "finite {n::nat. n \<le> k}"
   148   by (simp add: le_eq_less_or_eq Collect_disj_eq)
   149 
   150 
   151 subsubsection \<open>Finiteness and common set operations\<close>
   152 
   153 lemma rev_finite_subset:
   154   "finite B \<Longrightarrow> A \<subseteq> B \<Longrightarrow> finite A"
   155 proof (induct arbitrary: A rule: finite_induct)
   156   case empty
   157   then show ?case by simp
   158 next
   159   case (insert x F A)
   160   have A: "A \<subseteq> insert x F" and r: "A - {x} \<subseteq> F \<Longrightarrow> finite (A - {x})" by fact+
   161   show "finite A"
   162   proof cases
   163     assume x: "x \<in> A"
   164     with A have "A - {x} \<subseteq> F" by (simp add: subset_insert_iff)
   165     with r have "finite (A - {x})" .
   166     hence "finite (insert x (A - {x}))" ..
   167     also have "insert x (A - {x}) = A" using x by (rule insert_Diff)
   168     finally show ?thesis .
   169   next
   170     show ?thesis when "A \<subseteq> F"
   171       using that by fact
   172     assume "x \<notin> A"
   173     with A show "A \<subseteq> F" by (simp add: subset_insert_iff)
   174   qed
   175 qed
   176 
   177 lemma finite_subset:
   178   "A \<subseteq> B \<Longrightarrow> finite B \<Longrightarrow> finite A"
   179   by (rule rev_finite_subset)
   180 
   181 lemma finite_UnI:
   182   assumes "finite F" and "finite G"
   183   shows "finite (F \<union> G)"
   184   using assms by induct simp_all
   185 
   186 lemma finite_Un [iff]:
   187   "finite (F \<union> G) \<longleftrightarrow> finite F \<and> finite G"
   188   by (blast intro: finite_UnI finite_subset [of _ "F \<union> G"])
   189 
   190 lemma finite_insert [simp]: "finite (insert a A) \<longleftrightarrow> finite A"
   191 proof -
   192   have "finite {a} \<and> finite A \<longleftrightarrow> finite A" by simp
   193   then have "finite ({a} \<union> A) \<longleftrightarrow> finite A" by (simp only: finite_Un)
   194   then show ?thesis by simp
   195 qed
   196 
   197 lemma finite_Int [simp, intro]:
   198   "finite F \<or> finite G \<Longrightarrow> finite (F \<inter> G)"
   199   by (blast intro: finite_subset)
   200 
   201 lemma finite_Collect_conjI [simp, intro]:
   202   "finite {x. P x} \<or> finite {x. Q x} \<Longrightarrow> finite {x. P x \<and> Q x}"
   203   by (simp add: Collect_conj_eq)
   204 
   205 lemma finite_Collect_disjI [simp]:
   206   "finite {x. P x \<or> Q x} \<longleftrightarrow> finite {x. P x} \<and> finite {x. Q x}"
   207   by (simp add: Collect_disj_eq)
   208 
   209 lemma finite_Diff [simp, intro]:
   210   "finite A \<Longrightarrow> finite (A - B)"
   211   by (rule finite_subset, rule Diff_subset)
   212 
   213 lemma finite_Diff2 [simp]:
   214   assumes "finite B"
   215   shows "finite (A - B) \<longleftrightarrow> finite A"
   216 proof -
   217   have "finite A \<longleftrightarrow> finite((A - B) \<union> (A \<inter> B))" by (simp add: Un_Diff_Int)
   218   also have "\<dots> \<longleftrightarrow> finite (A - B)" using \<open>finite B\<close> by simp
   219   finally show ?thesis ..
   220 qed
   221 
   222 lemma finite_Diff_insert [iff]:
   223   "finite (A - insert a B) \<longleftrightarrow> finite (A - B)"
   224 proof -
   225   have "finite (A - B) \<longleftrightarrow> finite (A - B - {a})" by simp
   226   moreover have "A - insert a B = A - B - {a}" by auto
   227   ultimately show ?thesis by simp
   228 qed
   229 
   230 lemma finite_compl[simp]:
   231   "finite (A :: 'a set) \<Longrightarrow> finite (- A) \<longleftrightarrow> finite (UNIV :: 'a set)"
   232   by (simp add: Compl_eq_Diff_UNIV)
   233 
   234 lemma finite_Collect_not[simp]:
   235   "finite {x :: 'a. P x} \<Longrightarrow> finite {x. \<not> P x} \<longleftrightarrow> finite (UNIV :: 'a set)"
   236   by (simp add: Collect_neg_eq)
   237 
   238 lemma finite_Union [simp, intro]:
   239   "finite A \<Longrightarrow> (\<And>M. M \<in> A \<Longrightarrow> finite M) \<Longrightarrow> finite(\<Union>A)"
   240   by (induct rule: finite_induct) simp_all
   241 
   242 lemma finite_UN_I [intro]:
   243   "finite A \<Longrightarrow> (\<And>a. a \<in> A \<Longrightarrow> finite (B a)) \<Longrightarrow> finite (\<Union>a\<in>A. B a)"
   244   by (induct rule: finite_induct) simp_all
   245 
   246 lemma finite_UN [simp]:
   247   "finite A \<Longrightarrow> finite (UNION A B) \<longleftrightarrow> (\<forall>x\<in>A. finite (B x))"
   248   by (blast intro: finite_subset)
   249 
   250 lemma finite_Inter [intro]:
   251   "\<exists>A\<in>M. finite A \<Longrightarrow> finite (\<Inter>M)"
   252   by (blast intro: Inter_lower finite_subset)
   253 
   254 lemma finite_INT [intro]:
   255   "\<exists>x\<in>I. finite (A x) \<Longrightarrow> finite (\<Inter>x\<in>I. A x)"
   256   by (blast intro: INT_lower finite_subset)
   257 
   258 lemma finite_imageI [simp, intro]:
   259   "finite F \<Longrightarrow> finite (h ` F)"
   260   by (induct rule: finite_induct) simp_all
   261 
   262 lemma finite_image_set [simp]:
   263   "finite {x. P x} \<Longrightarrow> finite { f x | x. P x }"
   264   by (simp add: image_Collect [symmetric])
   265 
   266 lemma finite_image_set2:
   267   "finite {x. P x} \<Longrightarrow> finite {y. Q y} \<Longrightarrow> finite {f x y | x y. P x \<and> Q y}"
   268   by (rule finite_subset [where B = "\<Union>x \<in> {x. P x}. \<Union>y \<in> {y. Q y}. {f x y}"]) auto
   269 
   270 lemma finite_imageD:
   271   assumes "finite (f ` A)" and "inj_on f A"
   272   shows "finite A"
   273 using assms
   274 proof (induct "f ` A" arbitrary: A)
   275   case empty then show ?case by simp
   276 next
   277   case (insert x B)
   278   then have B_A: "insert x B = f ` A" by simp
   279   then obtain y where "x = f y" and "y \<in> A" by blast
   280   from B_A \<open>x \<notin> B\<close> have "B = f ` A - {x}" by blast
   281   with B_A \<open>x \<notin> B\<close> \<open>x = f y\<close> \<open>inj_on f A\<close> \<open>y \<in> A\<close> have "B = f ` (A - {y})" 
   282     by (simp add: inj_on_image_set_diff Set.Diff_subset)
   283   moreover from \<open>inj_on f A\<close> have "inj_on f (A - {y})" by (rule inj_on_diff)
   284   ultimately have "finite (A - {y})" by (rule insert.hyps)
   285   then show "finite A" by simp
   286 qed
   287 
   288 lemma finite_surj:
   289   "finite A \<Longrightarrow> B \<subseteq> f ` A \<Longrightarrow> finite B"
   290   by (erule finite_subset) (rule finite_imageI)
   291 
   292 lemma finite_range_imageI:
   293   "finite (range g) \<Longrightarrow> finite (range (\<lambda>x. f (g x)))"
   294   by (drule finite_imageI) (simp add: range_composition)
   295 
   296 lemma finite_subset_image:
   297   assumes "finite B"
   298   shows "B \<subseteq> f ` A \<Longrightarrow> \<exists>C\<subseteq>A. finite C \<and> B = f ` C"
   299 using assms
   300 proof induct
   301   case empty then show ?case by simp
   302 next
   303   case insert then show ?case
   304     by (clarsimp simp del: image_insert simp add: image_insert [symmetric])
   305        blast
   306 qed
   307 
   308 lemma finite_vimage_IntI:
   309   "finite F \<Longrightarrow> inj_on h A \<Longrightarrow> finite (h -` F \<inter> A)"
   310   apply (induct rule: finite_induct)
   311    apply simp_all
   312   apply (subst vimage_insert)
   313   apply (simp add: finite_subset [OF inj_on_vimage_singleton] Int_Un_distrib2)
   314   done
   315 
   316 lemma finite_vimageI:
   317   "finite F \<Longrightarrow> inj h \<Longrightarrow> finite (h -` F)"
   318   using finite_vimage_IntI[of F h UNIV] by auto
   319 
   320 lemma finite_vimageD': "\<lbrakk> finite (f -` A); A \<subseteq> range f \<rbrakk> \<Longrightarrow> finite A"
   321 by(auto simp add: subset_image_iff intro: finite_subset[rotated])
   322 
   323 lemma finite_vimageD: "\<lbrakk> finite (h -` F); surj h \<rbrakk> \<Longrightarrow> finite F"
   324 by(auto dest: finite_vimageD')
   325 
   326 lemma finite_vimage_iff: "bij h \<Longrightarrow> finite (h -` F) \<longleftrightarrow> finite F"
   327   unfolding bij_def by (auto elim: finite_vimageD finite_vimageI)
   328 
   329 lemma finite_Collect_bex [simp]:
   330   assumes "finite A"
   331   shows "finite {x. \<exists>y\<in>A. Q x y} \<longleftrightarrow> (\<forall>y\<in>A. finite {x. Q x y})"
   332 proof -
   333   have "{x. \<exists>y\<in>A. Q x y} = (\<Union>y\<in>A. {x. Q x y})" by auto
   334   with assms show ?thesis by simp
   335 qed
   336 
   337 lemma finite_Collect_bounded_ex [simp]:
   338   assumes "finite {y. P y}"
   339   shows "finite {x. \<exists>y. P y \<and> Q x y} \<longleftrightarrow> (\<forall>y. P y \<longrightarrow> finite {x. Q x y})"
   340 proof -
   341   have "{x. EX y. P y & Q x y} = (\<Union>y\<in>{y. P y}. {x. Q x y})" by auto
   342   with assms show ?thesis by simp
   343 qed
   344 
   345 lemma finite_Plus:
   346   "finite A \<Longrightarrow> finite B \<Longrightarrow> finite (A <+> B)"
   347   by (simp add: Plus_def)
   348 
   349 lemma finite_PlusD: 
   350   fixes A :: "'a set" and B :: "'b set"
   351   assumes fin: "finite (A <+> B)"
   352   shows "finite A" "finite B"
   353 proof -
   354   have "Inl ` A \<subseteq> A <+> B" by auto
   355   then have "finite (Inl ` A :: ('a + 'b) set)" using fin by (rule finite_subset)
   356   then show "finite A" by (rule finite_imageD) (auto intro: inj_onI)
   357 next
   358   have "Inr ` B \<subseteq> A <+> B" by auto
   359   then have "finite (Inr ` B :: ('a + 'b) set)" using fin by (rule finite_subset)
   360   then show "finite B" by (rule finite_imageD) (auto intro: inj_onI)
   361 qed
   362 
   363 lemma finite_Plus_iff [simp]:
   364   "finite (A <+> B) \<longleftrightarrow> finite A \<and> finite B"
   365   by (auto intro: finite_PlusD finite_Plus)
   366 
   367 lemma finite_Plus_UNIV_iff [simp]:
   368   "finite (UNIV :: ('a + 'b) set) \<longleftrightarrow> finite (UNIV :: 'a set) \<and> finite (UNIV :: 'b set)"
   369   by (subst UNIV_Plus_UNIV [symmetric]) (rule finite_Plus_iff)
   370 
   371 lemma finite_SigmaI [simp, intro]:
   372   "finite A \<Longrightarrow> (\<And>a. a\<in>A \<Longrightarrow> finite (B a)) ==> finite (SIGMA a:A. B a)"
   373   by (unfold Sigma_def) blast
   374 
   375 lemma finite_SigmaI2:
   376   assumes "finite {x\<in>A. B x \<noteq> {}}"
   377   and "\<And>a. a \<in> A \<Longrightarrow> finite (B a)"
   378   shows "finite (Sigma A B)"
   379 proof -
   380   from assms have "finite (Sigma {x\<in>A. B x \<noteq> {}} B)" by auto
   381   also have "Sigma {x:A. B x \<noteq> {}} B = Sigma A B" by auto
   382   finally show ?thesis .
   383 qed
   384 
   385 lemma finite_cartesian_product:
   386   "finite A \<Longrightarrow> finite B \<Longrightarrow> finite (A \<times> B)"
   387   by (rule finite_SigmaI)
   388 
   389 lemma finite_Prod_UNIV:
   390   "finite (UNIV :: 'a set) \<Longrightarrow> finite (UNIV :: 'b set) \<Longrightarrow> finite (UNIV :: ('a \<times> 'b) set)"
   391   by (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product)
   392 
   393 lemma finite_cartesian_productD1:
   394   assumes "finite (A \<times> B)" and "B \<noteq> {}"
   395   shows "finite A"
   396 proof -
   397   from assms obtain n f where "A \<times> B = f ` {i::nat. i < n}"
   398     by (auto simp add: finite_conv_nat_seg_image)
   399   then have "fst ` (A \<times> B) = fst ` f ` {i::nat. i < n}" by simp
   400   with \<open>B \<noteq> {}\<close> have "A = (fst \<circ> f) ` {i::nat. i < n}"
   401     by (simp add: image_comp)
   402   then have "\<exists>n f. A = f ` {i::nat. i < n}" by blast
   403   then show ?thesis
   404     by (auto simp add: finite_conv_nat_seg_image)
   405 qed
   406 
   407 lemma finite_cartesian_productD2:
   408   assumes "finite (A \<times> B)" and "A \<noteq> {}"
   409   shows "finite B"
   410 proof -
   411   from assms obtain n f where "A \<times> B = f ` {i::nat. i < n}"
   412     by (auto simp add: finite_conv_nat_seg_image)
   413   then have "snd ` (A \<times> B) = snd ` f ` {i::nat. i < n}" by simp
   414   with \<open>A \<noteq> {}\<close> have "B = (snd \<circ> f) ` {i::nat. i < n}"
   415     by (simp add: image_comp)
   416   then have "\<exists>n f. B = f ` {i::nat. i < n}" by blast
   417   then show ?thesis
   418     by (auto simp add: finite_conv_nat_seg_image)
   419 qed
   420 
   421 lemma finite_cartesian_product_iff:
   422   "finite (A \<times> B) \<longleftrightarrow> (A = {} \<or> B = {} \<or> (finite A \<and> finite B))"
   423   by (auto dest: finite_cartesian_productD1 finite_cartesian_productD2 finite_cartesian_product)
   424 
   425 lemma finite_prod: 
   426   "finite (UNIV :: ('a \<times> 'b) set) \<longleftrightarrow> finite (UNIV :: 'a set) \<and> finite (UNIV :: 'b set)"
   427   using finite_cartesian_product_iff[of UNIV UNIV] by simp
   428 
   429 lemma finite_Pow_iff [iff]:
   430   "finite (Pow A) \<longleftrightarrow> finite A"
   431 proof
   432   assume "finite (Pow A)"
   433   then have "finite ((%x. {x}) ` A)" by (blast intro: finite_subset)
   434   then show "finite A" by (rule finite_imageD [unfolded inj_on_def]) simp
   435 next
   436   assume "finite A"
   437   then show "finite (Pow A)"
   438     by induct (simp_all add: Pow_insert)
   439 qed
   440 
   441 corollary finite_Collect_subsets [simp, intro]:
   442   "finite A \<Longrightarrow> finite {B. B \<subseteq> A}"
   443   by (simp add: Pow_def [symmetric])
   444 
   445 lemma finite_set: "finite (UNIV :: 'a set set) \<longleftrightarrow> finite (UNIV :: 'a set)"
   446 by(simp only: finite_Pow_iff Pow_UNIV[symmetric])
   447 
   448 lemma finite_UnionD: "finite(\<Union>A) \<Longrightarrow> finite A"
   449   by (blast intro: finite_subset [OF subset_Pow_Union])
   450 
   451 lemma finite_set_of_finite_funs: assumes "finite A" "finite B"
   452 shows "finite{f. \<forall>x. (x \<in> A \<longrightarrow> f x \<in> B) \<and> (x \<notin> A \<longrightarrow> f x = d)}" (is "finite ?S")
   453 proof-
   454   let ?F = "\<lambda>f. {(a,b). a \<in> A \<and> b = f a}"
   455   have "?F ` ?S \<subseteq> Pow(A \<times> B)" by auto
   456   from finite_subset[OF this] assms have 1: "finite (?F ` ?S)" by simp
   457   have 2: "inj_on ?F ?S"
   458     by(fastforce simp add: inj_on_def set_eq_iff fun_eq_iff)
   459   show ?thesis by(rule finite_imageD[OF 1 2])
   460 qed
   461 
   462 lemma not_finite_existsD:
   463   assumes "\<not> finite {a. P a}"
   464   shows "\<exists>a. P a"
   465 proof (rule classical)
   466   assume "\<not> (\<exists>a. P a)"
   467   with assms show ?thesis by auto
   468 qed
   469 
   470 
   471 subsubsection \<open>Further induction rules on finite sets\<close>
   472 
   473 lemma finite_ne_induct [case_names singleton insert, consumes 2]:
   474   assumes "finite F" and "F \<noteq> {}"
   475   assumes "\<And>x. P {x}"
   476     and "\<And>x F. finite F \<Longrightarrow> F \<noteq> {} \<Longrightarrow> x \<notin> F \<Longrightarrow> P F  \<Longrightarrow> P (insert x F)"
   477   shows "P F"
   478 using assms
   479 proof induct
   480   case empty then show ?case by simp
   481 next
   482   case (insert x F) then show ?case by cases auto
   483 qed
   484 
   485 lemma finite_subset_induct [consumes 2, case_names empty insert]:
   486   assumes "finite F" and "F \<subseteq> A"
   487   assumes empty: "P {}"
   488     and insert: "\<And>a F. finite F \<Longrightarrow> a \<in> A \<Longrightarrow> a \<notin> F \<Longrightarrow> P F \<Longrightarrow> P (insert a F)"
   489   shows "P F"
   490 using \<open>finite F\<close> \<open>F \<subseteq> A\<close>
   491 proof induct
   492   show "P {}" by fact
   493 next
   494   fix x F
   495   assume "finite F" and "x \<notin> F" and
   496     P: "F \<subseteq> A \<Longrightarrow> P F" and i: "insert x F \<subseteq> A"
   497   show "P (insert x F)"
   498   proof (rule insert)
   499     from i show "x \<in> A" by blast
   500     from i have "F \<subseteq> A" by blast
   501     with P show "P F" .
   502     show "finite F" by fact
   503     show "x \<notin> F" by fact
   504   qed
   505 qed
   506 
   507 lemma finite_empty_induct:
   508   assumes "finite A"
   509   assumes "P A"
   510     and remove: "\<And>a A. finite A \<Longrightarrow> a \<in> A \<Longrightarrow> P A \<Longrightarrow> P (A - {a})"
   511   shows "P {}"
   512 proof -
   513   have "\<And>B. B \<subseteq> A \<Longrightarrow> P (A - B)"
   514   proof -
   515     fix B :: "'a set"
   516     assume "B \<subseteq> A"
   517     with \<open>finite A\<close> have "finite B" by (rule rev_finite_subset)
   518     from this \<open>B \<subseteq> A\<close> show "P (A - B)"
   519     proof induct
   520       case empty
   521       from \<open>P A\<close> show ?case by simp
   522     next
   523       case (insert b B)
   524       have "P (A - B - {b})"
   525       proof (rule remove)
   526         from \<open>finite A\<close> show "finite (A - B)" by induct auto
   527         from insert show "b \<in> A - B" by simp
   528         from insert show "P (A - B)" by simp
   529       qed
   530       also have "A - B - {b} = A - insert b B" by (rule Diff_insert [symmetric])
   531       finally show ?case .
   532     qed
   533   qed
   534   then have "P (A - A)" by blast
   535   then show ?thesis by simp
   536 qed
   537 
   538 lemma finite_update_induct [consumes 1, case_names const update]:
   539   assumes finite: "finite {a. f a \<noteq> c}"
   540   assumes const: "P (\<lambda>a. c)"
   541   assumes update: "\<And>a b f. finite {a. f a \<noteq> c} \<Longrightarrow> f a = c \<Longrightarrow> b \<noteq> c \<Longrightarrow> P f \<Longrightarrow> P (f(a := b))"
   542   shows "P f"
   543 using finite proof (induct "{a. f a \<noteq> c}" arbitrary: f)
   544   case empty with const show ?case by simp
   545 next
   546   case (insert a A)
   547   then have "A = {a'. (f(a := c)) a' \<noteq> c}" and "f a \<noteq> c"
   548     by auto
   549   with \<open>finite A\<close> have "finite {a'. (f(a := c)) a' \<noteq> c}"
   550     by simp
   551   have "(f(a := c)) a = c"
   552     by simp
   553   from insert \<open>A = {a'. (f(a := c)) a' \<noteq> c}\<close> have "P (f(a := c))"
   554     by simp
   555   with \<open>finite {a'. (f(a := c)) a' \<noteq> c}\<close> \<open>(f(a := c)) a = c\<close> \<open>f a \<noteq> c\<close> have "P ((f(a := c))(a := f a))"
   556     by (rule update)
   557   then show ?case by simp
   558 qed
   559 
   560 
   561 subsection \<open>Class @{text finite}\<close>
   562 
   563 class finite =
   564   assumes finite_UNIV: "finite (UNIV \<Colon> 'a set)"
   565 begin
   566 
   567 lemma finite [simp]: "finite (A \<Colon> 'a set)"
   568   by (rule subset_UNIV finite_UNIV finite_subset)+
   569 
   570 lemma finite_code [code]: "finite (A \<Colon> 'a set) \<longleftrightarrow> True"
   571   by simp
   572 
   573 end
   574 
   575 instance prod :: (finite, finite) finite
   576   by default (simp only: UNIV_Times_UNIV [symmetric] finite_cartesian_product finite)
   577 
   578 lemma inj_graph: "inj (%f. {(x, y). y = f x})"
   579   by (rule inj_onI, auto simp add: set_eq_iff fun_eq_iff)
   580 
   581 instance "fun" :: (finite, finite) finite
   582 proof
   583   show "finite (UNIV :: ('a => 'b) set)"
   584   proof (rule finite_imageD)
   585     let ?graph = "%f::'a => 'b. {(x, y). y = f x}"
   586     have "range ?graph \<subseteq> Pow UNIV" by simp
   587     moreover have "finite (Pow (UNIV :: ('a * 'b) set))"
   588       by (simp only: finite_Pow_iff finite)
   589     ultimately show "finite (range ?graph)"
   590       by (rule finite_subset)
   591     show "inj ?graph" by (rule inj_graph)
   592   qed
   593 qed
   594 
   595 instance bool :: finite
   596   by default (simp add: UNIV_bool)
   597 
   598 instance set :: (finite) finite
   599   by default (simp only: Pow_UNIV [symmetric] finite_Pow_iff finite)
   600 
   601 instance unit :: finite
   602   by default (simp add: UNIV_unit)
   603 
   604 instance sum :: (finite, finite) finite
   605   by default (simp only: UNIV_Plus_UNIV [symmetric] finite_Plus finite)
   606 
   607 
   608 subsection \<open>A basic fold functional for finite sets\<close>
   609 
   610 text \<open>The intended behaviour is
   611 @{text "fold f z {x\<^sub>1, ..., x\<^sub>n} = f x\<^sub>1 (\<dots> (f x\<^sub>n z)\<dots>)"}
   612 if @{text f} is ``left-commutative'':
   613 \<close>
   614 
   615 locale comp_fun_commute =
   616   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
   617   assumes comp_fun_commute: "f y \<circ> f x = f x \<circ> f y"
   618 begin
   619 
   620 lemma fun_left_comm: "f y (f x z) = f x (f y z)"
   621   using comp_fun_commute by (simp add: fun_eq_iff)
   622 
   623 lemma commute_left_comp:
   624   "f y \<circ> (f x \<circ> g) = f x \<circ> (f y \<circ> g)"
   625   by (simp add: o_assoc comp_fun_commute)
   626 
   627 end
   628 
   629 inductive fold_graph :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> bool"
   630 for f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b" and z :: 'b where
   631   emptyI [intro]: "fold_graph f z {} z" |
   632   insertI [intro]: "x \<notin> A \<Longrightarrow> fold_graph f z A y
   633       \<Longrightarrow> fold_graph f z (insert x A) (f x y)"
   634 
   635 inductive_cases empty_fold_graphE [elim!]: "fold_graph f z {} x"
   636 
   637 definition fold :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a set \<Rightarrow> 'b" where
   638   "fold f z A = (if finite A then (THE y. fold_graph f z A y) else z)"
   639 
   640 text\<open>A tempting alternative for the definiens is
   641 @{term "if finite A then THE y. fold_graph f z A y else e"}.
   642 It allows the removal of finiteness assumptions from the theorems
   643 @{text fold_comm}, @{text fold_reindex} and @{text fold_distrib}.
   644 The proofs become ugly. It is not worth the effort. (???)\<close>
   645 
   646 lemma finite_imp_fold_graph: "finite A \<Longrightarrow> \<exists>x. fold_graph f z A x"
   647 by (induct rule: finite_induct) auto
   648 
   649 
   650 subsubsection\<open>From @{const fold_graph} to @{term fold}\<close>
   651 
   652 context comp_fun_commute
   653 begin
   654 
   655 lemma fold_graph_finite:
   656   assumes "fold_graph f z A y"
   657   shows "finite A"
   658   using assms by induct simp_all
   659 
   660 lemma fold_graph_insertE_aux:
   661   "fold_graph f z A y \<Longrightarrow> a \<in> A \<Longrightarrow> \<exists>y'. y = f a y' \<and> fold_graph f z (A - {a}) y'"
   662 proof (induct set: fold_graph)
   663   case (insertI x A y) show ?case
   664   proof (cases "x = a")
   665     assume "x = a" with insertI show ?case by auto
   666   next
   667     assume "x \<noteq> a"
   668     then obtain y' where y: "y = f a y'" and y': "fold_graph f z (A - {a}) y'"
   669       using insertI by auto
   670     have "f x y = f a (f x y')"
   671       unfolding y by (rule fun_left_comm)
   672     moreover have "fold_graph f z (insert x A - {a}) (f x y')"
   673       using y' and \<open>x \<noteq> a\<close> and \<open>x \<notin> A\<close>
   674       by (simp add: insert_Diff_if fold_graph.insertI)
   675     ultimately show ?case by fast
   676   qed
   677 qed simp
   678 
   679 lemma fold_graph_insertE:
   680   assumes "fold_graph f z (insert x A) v" and "x \<notin> A"
   681   obtains y where "v = f x y" and "fold_graph f z A y"
   682 using assms by (auto dest: fold_graph_insertE_aux [OF _ insertI1])
   683 
   684 lemma fold_graph_determ:
   685   "fold_graph f z A x \<Longrightarrow> fold_graph f z A y \<Longrightarrow> y = x"
   686 proof (induct arbitrary: y set: fold_graph)
   687   case (insertI x A y v)
   688   from \<open>fold_graph f z (insert x A) v\<close> and \<open>x \<notin> A\<close>
   689   obtain y' where "v = f x y'" and "fold_graph f z A y'"
   690     by (rule fold_graph_insertE)
   691   from \<open>fold_graph f z A y'\<close> have "y' = y" by (rule insertI)
   692   with \<open>v = f x y'\<close> show "v = f x y" by simp
   693 qed fast
   694 
   695 lemma fold_equality:
   696   "fold_graph f z A y \<Longrightarrow> fold f z A = y"
   697   by (cases "finite A") (auto simp add: fold_def intro: fold_graph_determ dest: fold_graph_finite)
   698 
   699 lemma fold_graph_fold:
   700   assumes "finite A"
   701   shows "fold_graph f z A (fold f z A)"
   702 proof -
   703   from assms have "\<exists>x. fold_graph f z A x" by (rule finite_imp_fold_graph)
   704   moreover note fold_graph_determ
   705   ultimately have "\<exists>!x. fold_graph f z A x" by (rule ex_ex1I)
   706   then have "fold_graph f z A (The (fold_graph f z A))" by (rule theI')
   707   with assms show ?thesis by (simp add: fold_def)
   708 qed
   709 
   710 text \<open>The base case for @{text fold}:\<close>
   711 
   712 lemma (in -) fold_infinite [simp]:
   713   assumes "\<not> finite A"
   714   shows "fold f z A = z"
   715   using assms by (auto simp add: fold_def)
   716 
   717 lemma (in -) fold_empty [simp]:
   718   "fold f z {} = z"
   719   by (auto simp add: fold_def)
   720 
   721 text\<open>The various recursion equations for @{const fold}:\<close>
   722 
   723 lemma fold_insert [simp]:
   724   assumes "finite A" and "x \<notin> A"
   725   shows "fold f z (insert x A) = f x (fold f z A)"
   726 proof (rule fold_equality)
   727   fix z
   728   from \<open>finite A\<close> have "fold_graph f z A (fold f z A)" by (rule fold_graph_fold)
   729   with \<open>x \<notin> A\<close> have "fold_graph f z (insert x A) (f x (fold f z A))" by (rule fold_graph.insertI)
   730   then show "fold_graph f z (insert x A) (f x (fold f z A))" by simp
   731 qed
   732 
   733 declare (in -) empty_fold_graphE [rule del] fold_graph.intros [rule del]
   734   -- \<open>No more proofs involve these.\<close>
   735 
   736 lemma fold_fun_left_comm:
   737   "finite A \<Longrightarrow> f x (fold f z A) = fold f (f x z) A"
   738 proof (induct rule: finite_induct)
   739   case empty then show ?case by simp
   740 next
   741   case (insert y A) then show ?case
   742     by (simp add: fun_left_comm [of x])
   743 qed
   744 
   745 lemma fold_insert2:
   746   "finite A \<Longrightarrow> x \<notin> A \<Longrightarrow> fold f z (insert x A)  = fold f (f x z) A"
   747   by (simp add: fold_fun_left_comm)
   748 
   749 lemma fold_rec:
   750   assumes "finite A" and "x \<in> A"
   751   shows "fold f z A = f x (fold f z (A - {x}))"
   752 proof -
   753   have A: "A = insert x (A - {x})" using \<open>x \<in> A\<close> by blast
   754   then have "fold f z A = fold f z (insert x (A - {x}))" by simp
   755   also have "\<dots> = f x (fold f z (A - {x}))"
   756     by (rule fold_insert) (simp add: \<open>finite A\<close>)+
   757   finally show ?thesis .
   758 qed
   759 
   760 lemma fold_insert_remove:
   761   assumes "finite A"
   762   shows "fold f z (insert x A) = f x (fold f z (A - {x}))"
   763 proof -
   764   from \<open>finite A\<close> have "finite (insert x A)" by auto
   765   moreover have "x \<in> insert x A" by auto
   766   ultimately have "fold f z (insert x A) = f x (fold f z (insert x A - {x}))"
   767     by (rule fold_rec)
   768   then show ?thesis by simp
   769 qed
   770 
   771 lemma fold_set_union_disj:
   772   assumes "finite A" "finite B" "A \<inter> B = {}"
   773   shows "Finite_Set.fold f z (A \<union> B) = Finite_Set.fold f (Finite_Set.fold f z A) B"
   774 using assms(2,1,3) by induction simp_all
   775 
   776 end
   777 
   778 text\<open>Other properties of @{const fold}:\<close>
   779 
   780 lemma fold_image:
   781   assumes "inj_on g A"
   782   shows "fold f z (g ` A) = fold (f \<circ> g) z A"
   783 proof (cases "finite A")
   784   case False with assms show ?thesis by (auto dest: finite_imageD simp add: fold_def)
   785 next
   786   case True
   787   have "fold_graph f z (g ` A) = fold_graph (f \<circ> g) z A"
   788   proof
   789     fix w
   790     show "fold_graph f z (g ` A) w \<longleftrightarrow> fold_graph (f \<circ> g) z A w" (is "?P \<longleftrightarrow> ?Q")
   791     proof
   792       assume ?P then show ?Q using assms
   793       proof (induct "g ` A" w arbitrary: A)
   794         case emptyI then show ?case by (auto intro: fold_graph.emptyI)
   795       next
   796         case (insertI x A r B)
   797         from \<open>inj_on g B\<close> \<open>x \<notin> A\<close> \<open>insert x A = image g B\<close> obtain x' A' where
   798           "x' \<notin> A'" and [simp]: "B = insert x' A'" "x = g x'" "A = g ` A'"
   799           by (rule inj_img_insertE)
   800         from insertI.prems have "fold_graph (f o g) z A' r"
   801           by (auto intro: insertI.hyps)
   802         with \<open>x' \<notin> A'\<close> have "fold_graph (f \<circ> g) z (insert x' A') ((f \<circ> g) x' r)"
   803           by (rule fold_graph.insertI)
   804         then show ?case by simp
   805       qed
   806     next
   807       assume ?Q then show ?P using assms
   808       proof induct
   809         case emptyI thus ?case by (auto intro: fold_graph.emptyI)
   810       next
   811         case (insertI x A r)
   812         from \<open>x \<notin> A\<close> insertI.prems have "g x \<notin> g ` A" by auto
   813         moreover from insertI have "fold_graph f z (g ` A) r" by simp
   814         ultimately have "fold_graph f z (insert (g x) (g ` A)) (f (g x) r)"
   815           by (rule fold_graph.insertI)
   816         then show ?case by simp
   817       qed
   818     qed
   819   qed
   820   with True assms show ?thesis by (auto simp add: fold_def)
   821 qed
   822 
   823 lemma fold_cong:
   824   assumes "comp_fun_commute f" "comp_fun_commute g"
   825   assumes "finite A" and cong: "\<And>x. x \<in> A \<Longrightarrow> f x = g x"
   826     and "s = t" and "A = B"
   827   shows "fold f s A = fold g t B"
   828 proof -
   829   have "fold f s A = fold g s A"  
   830   using \<open>finite A\<close> cong proof (induct A)
   831     case empty then show ?case by simp
   832   next
   833     case (insert x A)
   834     interpret f: comp_fun_commute f by (fact \<open>comp_fun_commute f\<close>)
   835     interpret g: comp_fun_commute g by (fact \<open>comp_fun_commute g\<close>)
   836     from insert show ?case by simp
   837   qed
   838   with assms show ?thesis by simp
   839 qed
   840 
   841 
   842 text \<open>A simplified version for idempotent functions:\<close>
   843 
   844 locale comp_fun_idem = comp_fun_commute +
   845   assumes comp_fun_idem: "f x \<circ> f x = f x"
   846 begin
   847 
   848 lemma fun_left_idem: "f x (f x z) = f x z"
   849   using comp_fun_idem by (simp add: fun_eq_iff)
   850 
   851 lemma fold_insert_idem:
   852   assumes fin: "finite A"
   853   shows "fold f z (insert x A)  = f x (fold f z A)"
   854 proof cases
   855   assume "x \<in> A"
   856   then obtain B where "A = insert x B" and "x \<notin> B" by (rule set_insert)
   857   then show ?thesis using assms by (simp add: comp_fun_idem fun_left_idem)
   858 next
   859   assume "x \<notin> A" then show ?thesis using assms by simp
   860 qed
   861 
   862 declare fold_insert [simp del] fold_insert_idem [simp]
   863 
   864 lemma fold_insert_idem2:
   865   "finite A \<Longrightarrow> fold f z (insert x A) = fold f (f x z) A"
   866   by (simp add: fold_fun_left_comm)
   867 
   868 end
   869 
   870 
   871 subsubsection \<open>Liftings to @{text comp_fun_commute} etc.\<close>
   872 
   873 lemma (in comp_fun_commute) comp_comp_fun_commute:
   874   "comp_fun_commute (f \<circ> g)"
   875 proof
   876 qed (simp_all add: comp_fun_commute)
   877 
   878 lemma (in comp_fun_idem) comp_comp_fun_idem:
   879   "comp_fun_idem (f \<circ> g)"
   880   by (rule comp_fun_idem.intro, rule comp_comp_fun_commute, unfold_locales)
   881     (simp_all add: comp_fun_idem)
   882 
   883 lemma (in comp_fun_commute) comp_fun_commute_funpow:
   884   "comp_fun_commute (\<lambda>x. f x ^^ g x)"
   885 proof
   886   fix y x
   887   show "f y ^^ g y \<circ> f x ^^ g x = f x ^^ g x \<circ> f y ^^ g y"
   888   proof (cases "x = y")
   889     case True then show ?thesis by simp
   890   next
   891     case False show ?thesis
   892     proof (induct "g x" arbitrary: g)
   893       case 0 then show ?case by simp
   894     next
   895       case (Suc n g)
   896       have hyp1: "f y ^^ g y \<circ> f x = f x \<circ> f y ^^ g y"
   897       proof (induct "g y" arbitrary: g)
   898         case 0 then show ?case by simp
   899       next
   900         case (Suc n g)
   901         def h \<equiv> "\<lambda>z. g z - 1"
   902         with Suc have "n = h y" by simp
   903         with Suc have hyp: "f y ^^ h y \<circ> f x = f x \<circ> f y ^^ h y"
   904           by auto
   905         from Suc h_def have "g y = Suc (h y)" by simp
   906         then show ?case by (simp add: comp_assoc hyp)
   907           (simp add: o_assoc comp_fun_commute)
   908       qed
   909       def h \<equiv> "\<lambda>z. if z = x then g x - 1 else g z"
   910       with Suc have "n = h x" by simp
   911       with Suc have "f y ^^ h y \<circ> f x ^^ h x = f x ^^ h x \<circ> f y ^^ h y"
   912         by auto
   913       with False h_def have hyp2: "f y ^^ g y \<circ> f x ^^ h x = f x ^^ h x \<circ> f y ^^ g y" by simp
   914       from Suc h_def have "g x = Suc (h x)" by simp
   915       then show ?case by (simp del: funpow.simps add: funpow_Suc_right o_assoc hyp2)
   916         (simp add: comp_assoc hyp1)
   917     qed
   918   qed
   919 qed
   920 
   921 
   922 subsubsection \<open>Expressing set operations via @{const fold}\<close>
   923 
   924 lemma comp_fun_commute_const:
   925   "comp_fun_commute (\<lambda>_. f)"
   926 proof
   927 qed rule
   928 
   929 lemma comp_fun_idem_insert:
   930   "comp_fun_idem insert"
   931 proof
   932 qed auto
   933 
   934 lemma comp_fun_idem_remove:
   935   "comp_fun_idem Set.remove"
   936 proof
   937 qed auto
   938 
   939 lemma (in semilattice_inf) comp_fun_idem_inf:
   940   "comp_fun_idem inf"
   941 proof
   942 qed (auto simp add: inf_left_commute)
   943 
   944 lemma (in semilattice_sup) comp_fun_idem_sup:
   945   "comp_fun_idem sup"
   946 proof
   947 qed (auto simp add: sup_left_commute)
   948 
   949 lemma union_fold_insert:
   950   assumes "finite A"
   951   shows "A \<union> B = fold insert B A"
   952 proof -
   953   interpret comp_fun_idem insert by (fact comp_fun_idem_insert)
   954   from \<open>finite A\<close> show ?thesis by (induct A arbitrary: B) simp_all
   955 qed
   956 
   957 lemma minus_fold_remove:
   958   assumes "finite A"
   959   shows "B - A = fold Set.remove B A"
   960 proof -
   961   interpret comp_fun_idem Set.remove by (fact comp_fun_idem_remove)
   962   from \<open>finite A\<close> have "fold Set.remove B A = B - A" by (induct A arbitrary: B) auto
   963   then show ?thesis ..
   964 qed
   965 
   966 lemma comp_fun_commute_filter_fold:
   967   "comp_fun_commute (\<lambda>x A'. if P x then Set.insert x A' else A')"
   968 proof - 
   969   interpret comp_fun_idem Set.insert by (fact comp_fun_idem_insert)
   970   show ?thesis by default (auto simp: fun_eq_iff)
   971 qed
   972 
   973 lemma Set_filter_fold:
   974   assumes "finite A"
   975   shows "Set.filter P A = fold (\<lambda>x A'. if P x then Set.insert x A' else A') {} A"
   976 using assms
   977 by (induct A) 
   978   (auto simp add: Set.filter_def comp_fun_commute.fold_insert[OF comp_fun_commute_filter_fold])
   979 
   980 lemma inter_Set_filter:     
   981   assumes "finite B"
   982   shows "A \<inter> B = Set.filter (\<lambda>x. x \<in> A) B"
   983 using assms 
   984 by (induct B) (auto simp: Set.filter_def)
   985 
   986 lemma image_fold_insert:
   987   assumes "finite A"
   988   shows "image f A = fold (\<lambda>k A. Set.insert (f k) A) {} A"
   989 using assms
   990 proof -
   991   interpret comp_fun_commute "\<lambda>k A. Set.insert (f k) A" by default auto
   992   show ?thesis using assms by (induct A) auto
   993 qed
   994 
   995 lemma Ball_fold:
   996   assumes "finite A"
   997   shows "Ball A P = fold (\<lambda>k s. s \<and> P k) True A"
   998 using assms
   999 proof -
  1000   interpret comp_fun_commute "\<lambda>k s. s \<and> P k" by default auto
  1001   show ?thesis using assms by (induct A) auto
  1002 qed
  1003 
  1004 lemma Bex_fold:
  1005   assumes "finite A"
  1006   shows "Bex A P = fold (\<lambda>k s. s \<or> P k) False A"
  1007 using assms
  1008 proof -
  1009   interpret comp_fun_commute "\<lambda>k s. s \<or> P k" by default auto
  1010   show ?thesis using assms by (induct A) auto
  1011 qed
  1012 
  1013 lemma comp_fun_commute_Pow_fold: 
  1014   "comp_fun_commute (\<lambda>x A. A \<union> Set.insert x ` A)" 
  1015   by (clarsimp simp: fun_eq_iff comp_fun_commute_def) blast
  1016 
  1017 lemma Pow_fold:
  1018   assumes "finite A"
  1019   shows "Pow A = fold (\<lambda>x A. A \<union> Set.insert x ` A) {{}} A"
  1020 using assms
  1021 proof -
  1022   interpret comp_fun_commute "\<lambda>x A. A \<union> Set.insert x ` A" by (rule comp_fun_commute_Pow_fold)
  1023   show ?thesis using assms by (induct A) (auto simp: Pow_insert)
  1024 qed
  1025 
  1026 lemma fold_union_pair:
  1027   assumes "finite B"
  1028   shows "(\<Union>y\<in>B. {(x, y)}) \<union> A = fold (\<lambda>y. Set.insert (x, y)) A B"
  1029 proof -
  1030   interpret comp_fun_commute "\<lambda>y. Set.insert (x, y)" by default auto
  1031   show ?thesis using assms  by (induct B arbitrary: A) simp_all
  1032 qed
  1033 
  1034 lemma comp_fun_commute_product_fold: 
  1035   assumes "finite B"
  1036   shows "comp_fun_commute (\<lambda>x z. fold (\<lambda>y. Set.insert (x, y)) z B)" 
  1037 by default (auto simp: fold_union_pair[symmetric] assms)
  1038 
  1039 lemma product_fold:
  1040   assumes "finite A"
  1041   assumes "finite B"
  1042   shows "A \<times> B = fold (\<lambda>x z. fold (\<lambda>y. Set.insert (x, y)) z B) {} A"
  1043 using assms unfolding Sigma_def 
  1044 by (induct A) 
  1045   (simp_all add: comp_fun_commute.fold_insert[OF comp_fun_commute_product_fold] fold_union_pair)
  1046 
  1047 
  1048 context complete_lattice
  1049 begin
  1050 
  1051 lemma inf_Inf_fold_inf:
  1052   assumes "finite A"
  1053   shows "inf (Inf A) B = fold inf B A"
  1054 proof -
  1055   interpret comp_fun_idem inf by (fact comp_fun_idem_inf)
  1056   from \<open>finite A\<close> fold_fun_left_comm show ?thesis by (induct A arbitrary: B)
  1057     (simp_all add: inf_commute fun_eq_iff)
  1058 qed
  1059 
  1060 lemma sup_Sup_fold_sup:
  1061   assumes "finite A"
  1062   shows "sup (Sup A) B = fold sup B A"
  1063 proof -
  1064   interpret comp_fun_idem sup by (fact comp_fun_idem_sup)
  1065   from \<open>finite A\<close> fold_fun_left_comm show ?thesis by (induct A arbitrary: B)
  1066     (simp_all add: sup_commute fun_eq_iff)
  1067 qed
  1068 
  1069 lemma Inf_fold_inf:
  1070   assumes "finite A"
  1071   shows "Inf A = fold inf top A"
  1072   using assms inf_Inf_fold_inf [of A top] by (simp add: inf_absorb2)
  1073 
  1074 lemma Sup_fold_sup:
  1075   assumes "finite A"
  1076   shows "Sup A = fold sup bot A"
  1077   using assms sup_Sup_fold_sup [of A bot] by (simp add: sup_absorb2)
  1078 
  1079 lemma inf_INF_fold_inf:
  1080   assumes "finite A"
  1081   shows "inf B (INFIMUM A f) = fold (inf \<circ> f) B A" (is "?inf = ?fold") 
  1082 proof (rule sym)
  1083   interpret comp_fun_idem inf by (fact comp_fun_idem_inf)
  1084   interpret comp_fun_idem "inf \<circ> f" by (fact comp_comp_fun_idem)
  1085   from \<open>finite A\<close> show "?fold = ?inf"
  1086     by (induct A arbitrary: B)
  1087       (simp_all add: inf_left_commute)
  1088 qed
  1089 
  1090 lemma sup_SUP_fold_sup:
  1091   assumes "finite A"
  1092   shows "sup B (SUPREMUM A f) = fold (sup \<circ> f) B A" (is "?sup = ?fold") 
  1093 proof (rule sym)
  1094   interpret comp_fun_idem sup by (fact comp_fun_idem_sup)
  1095   interpret comp_fun_idem "sup \<circ> f" by (fact comp_comp_fun_idem)
  1096   from \<open>finite A\<close> show "?fold = ?sup"
  1097     by (induct A arbitrary: B)
  1098       (simp_all add: sup_left_commute)
  1099 qed
  1100 
  1101 lemma INF_fold_inf:
  1102   assumes "finite A"
  1103   shows "INFIMUM A f = fold (inf \<circ> f) top A"
  1104   using assms inf_INF_fold_inf [of A top] by simp
  1105 
  1106 lemma SUP_fold_sup:
  1107   assumes "finite A"
  1108   shows "SUPREMUM A f = fold (sup \<circ> f) bot A"
  1109   using assms sup_SUP_fold_sup [of A bot] by simp
  1110 
  1111 end
  1112 
  1113 
  1114 subsection \<open>Locales as mini-packages for fold operations\<close>
  1115 
  1116 subsubsection \<open>The natural case\<close>
  1117 
  1118 locale folding =
  1119   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1120   fixes z :: "'b"
  1121   assumes comp_fun_commute: "f y \<circ> f x = f x \<circ> f y"
  1122 begin
  1123 
  1124 interpretation fold?: comp_fun_commute f
  1125   by default (insert comp_fun_commute, simp add: fun_eq_iff)
  1126 
  1127 definition F :: "'a set \<Rightarrow> 'b"
  1128 where
  1129   eq_fold: "F A = fold f z A"
  1130 
  1131 lemma empty [simp]:
  1132   "F {} = z"
  1133   by (simp add: eq_fold)
  1134 
  1135 lemma infinite [simp]:
  1136   "\<not> finite A \<Longrightarrow> F A = z"
  1137   by (simp add: eq_fold)
  1138  
  1139 lemma insert [simp]:
  1140   assumes "finite A" and "x \<notin> A"
  1141   shows "F (insert x A) = f x (F A)"
  1142 proof -
  1143   from fold_insert assms
  1144   have "fold f z (insert x A) = f x (fold f z A)" by simp
  1145   with \<open>finite A\<close> show ?thesis by (simp add: eq_fold fun_eq_iff)
  1146 qed
  1147  
  1148 lemma remove:
  1149   assumes "finite A" and "x \<in> A"
  1150   shows "F A = f x (F (A - {x}))"
  1151 proof -
  1152   from \<open>x \<in> A\<close> obtain B where A: "A = insert x B" and "x \<notin> B"
  1153     by (auto dest: mk_disjoint_insert)
  1154   moreover from \<open>finite A\<close> A have "finite B" by simp
  1155   ultimately show ?thesis by simp
  1156 qed
  1157 
  1158 lemma insert_remove:
  1159   assumes "finite A"
  1160   shows "F (insert x A) = f x (F (A - {x}))"
  1161   using assms by (cases "x \<in> A") (simp_all add: remove insert_absorb)
  1162 
  1163 end
  1164 
  1165 
  1166 subsubsection \<open>With idempotency\<close>
  1167 
  1168 locale folding_idem = folding +
  1169   assumes comp_fun_idem: "f x \<circ> f x = f x"
  1170 begin
  1171 
  1172 declare insert [simp del]
  1173 
  1174 interpretation fold?: comp_fun_idem f
  1175   by default (insert comp_fun_commute comp_fun_idem, simp add: fun_eq_iff)
  1176 
  1177 lemma insert_idem [simp]:
  1178   assumes "finite A"
  1179   shows "F (insert x A) = f x (F A)"
  1180 proof -
  1181   from fold_insert_idem assms
  1182   have "fold f z (insert x A) = f x (fold f z A)" by simp
  1183   with \<open>finite A\<close> show ?thesis by (simp add: eq_fold fun_eq_iff)
  1184 qed
  1185 
  1186 end
  1187 
  1188 
  1189 subsection \<open>Finite cardinality\<close>
  1190 
  1191 text \<open>
  1192   The traditional definition
  1193   @{prop "card A \<equiv> LEAST n. EX f. A = {f i | i. i < n}"}
  1194   is ugly to work with.
  1195   But now that we have @{const fold} things are easy:
  1196 \<close>
  1197 
  1198 definition card :: "'a set \<Rightarrow> nat" where
  1199   "card = folding.F (\<lambda>_. Suc) 0"
  1200 
  1201 interpretation card!: folding "\<lambda>_. Suc" 0
  1202 where
  1203   "folding.F (\<lambda>_. Suc) 0 = card"
  1204 proof -
  1205   show "folding (\<lambda>_. Suc)" by default rule
  1206   then interpret card!: folding "\<lambda>_. Suc" 0 .
  1207   from card_def show "folding.F (\<lambda>_. Suc) 0 = card" by rule
  1208 qed
  1209 
  1210 lemma card_infinite:
  1211   "\<not> finite A \<Longrightarrow> card A = 0"
  1212   by (fact card.infinite)
  1213 
  1214 lemma card_empty:
  1215   "card {} = 0"
  1216   by (fact card.empty)
  1217 
  1218 lemma card_insert_disjoint:
  1219   "finite A \<Longrightarrow> x \<notin> A \<Longrightarrow> card (insert x A) = Suc (card A)"
  1220   by (fact card.insert)
  1221 
  1222 lemma card_insert_if:
  1223   "finite A \<Longrightarrow> card (insert x A) = (if x \<in> A then card A else Suc (card A))"
  1224   by auto (simp add: card.insert_remove card.remove)
  1225 
  1226 lemma card_ge_0_finite:
  1227   "card A > 0 \<Longrightarrow> finite A"
  1228   by (rule ccontr) simp
  1229 
  1230 lemma card_0_eq [simp]:
  1231   "finite A \<Longrightarrow> card A = 0 \<longleftrightarrow> A = {}"
  1232   by (auto dest: mk_disjoint_insert)
  1233 
  1234 lemma finite_UNIV_card_ge_0:
  1235   "finite (UNIV :: 'a set) \<Longrightarrow> card (UNIV :: 'a set) > 0"
  1236   by (rule ccontr) simp
  1237 
  1238 lemma card_eq_0_iff:
  1239   "card A = 0 \<longleftrightarrow> A = {} \<or> \<not> finite A"
  1240   by auto
  1241 
  1242 lemma card_gt_0_iff:
  1243   "0 < card A \<longleftrightarrow> A \<noteq> {} \<and> finite A"
  1244   by (simp add: neq0_conv [symmetric] card_eq_0_iff) 
  1245 
  1246 lemma card_Suc_Diff1:
  1247   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> Suc (card (A - {x})) = card A"
  1248 apply(rule_tac t = A in insert_Diff [THEN subst], assumption)
  1249 apply(simp del:insert_Diff_single)
  1250 done
  1251 
  1252 lemma card_Diff_singleton:
  1253   "finite A \<Longrightarrow> x \<in> A \<Longrightarrow> card (A - {x}) = card A - 1"
  1254   by (simp add: card_Suc_Diff1 [symmetric])
  1255 
  1256 lemma card_Diff_singleton_if:
  1257   "finite A \<Longrightarrow> card (A - {x}) = (if x \<in> A then card A - 1 else card A)"
  1258   by (simp add: card_Diff_singleton)
  1259 
  1260 lemma card_Diff_insert[simp]:
  1261   assumes "finite A" and "a \<in> A" and "a \<notin> B"
  1262   shows "card (A - insert a B) = card (A - B) - 1"
  1263 proof -
  1264   have "A - insert a B = (A - B) - {a}" using assms by blast
  1265   then show ?thesis using assms by(simp add: card_Diff_singleton)
  1266 qed
  1267 
  1268 lemma card_insert: "finite A ==> card (insert x A) = Suc (card (A - {x}))"
  1269   by (fact card.insert_remove)
  1270 
  1271 lemma card_insert_le: "finite A ==> card A <= card (insert x A)"
  1272 by (simp add: card_insert_if)
  1273 
  1274 lemma card_Collect_less_nat[simp]: "card{i::nat. i < n} = n"
  1275 by (induct n) (simp_all add:less_Suc_eq Collect_disj_eq)
  1276 
  1277 lemma card_Collect_le_nat[simp]: "card{i::nat. i <= n} = Suc n"
  1278 using card_Collect_less_nat[of "Suc n"] by(simp add: less_Suc_eq_le)
  1279 
  1280 lemma card_mono:
  1281   assumes "finite B" and "A \<subseteq> B"
  1282   shows "card A \<le> card B"
  1283 proof -
  1284   from assms have "finite A" by (auto intro: finite_subset)
  1285   then show ?thesis using assms proof (induct A arbitrary: B)
  1286     case empty then show ?case by simp
  1287   next
  1288     case (insert x A)
  1289     then have "x \<in> B" by simp
  1290     from insert have "A \<subseteq> B - {x}" and "finite (B - {x})" by auto
  1291     with insert.hyps have "card A \<le> card (B - {x})" by auto
  1292     with \<open>finite A\<close> \<open>x \<notin> A\<close> \<open>finite B\<close> \<open>x \<in> B\<close> show ?case by simp (simp only: card.remove)
  1293   qed
  1294 qed
  1295 
  1296 lemma card_seteq: "finite B ==> (!!A. A <= B ==> card B <= card A ==> A = B)"
  1297 apply (induct rule: finite_induct)
  1298 apply simp
  1299 apply clarify
  1300 apply (subgoal_tac "finite A & A - {x} <= F")
  1301  prefer 2 apply (blast intro: finite_subset, atomize)
  1302 apply (drule_tac x = "A - {x}" in spec)
  1303 apply (simp add: card_Diff_singleton_if split add: split_if_asm)
  1304 apply (case_tac "card A", auto)
  1305 done
  1306 
  1307 lemma psubset_card_mono: "finite B ==> A < B ==> card A < card B"
  1308 apply (simp add: psubset_eq linorder_not_le [symmetric])
  1309 apply (blast dest: card_seteq)
  1310 done
  1311 
  1312 lemma card_Un_Int:
  1313   assumes "finite A" and "finite B"
  1314   shows "card A + card B = card (A \<union> B) + card (A \<inter> B)"
  1315 using assms proof (induct A)
  1316   case empty then show ?case by simp
  1317 next
  1318  case (insert x A) then show ?case
  1319     by (auto simp add: insert_absorb Int_insert_left)
  1320 qed
  1321 
  1322 lemma card_Un_disjoint:
  1323   assumes "finite A" and "finite B"
  1324   assumes "A \<inter> B = {}"
  1325   shows "card (A \<union> B) = card A + card B"
  1326 using assms card_Un_Int [of A B] by simp
  1327 
  1328 lemma card_Un_le: "card (A \<union> B) \<le> card A + card B"
  1329 apply(cases "finite A")
  1330  apply(cases "finite B")
  1331   using le_iff_add card_Un_Int apply blast
  1332  apply simp
  1333 apply simp
  1334 done
  1335 
  1336 lemma card_Diff_subset:
  1337   assumes "finite B" and "B \<subseteq> A"
  1338   shows "card (A - B) = card A - card B"
  1339 proof (cases "finite A")
  1340   case False with assms show ?thesis by simp
  1341 next
  1342   case True with assms show ?thesis by (induct B arbitrary: A) simp_all
  1343 qed
  1344 
  1345 lemma card_Diff_subset_Int:
  1346   assumes AB: "finite (A \<inter> B)" shows "card (A - B) = card A - card (A \<inter> B)"
  1347 proof -
  1348   have "A - B = A - A \<inter> B" by auto
  1349   thus ?thesis
  1350     by (simp add: card_Diff_subset AB) 
  1351 qed
  1352 
  1353 lemma diff_card_le_card_Diff:
  1354 assumes "finite B" shows "card A - card B \<le> card(A - B)"
  1355 proof-
  1356   have "card A - card B \<le> card A - card (A \<inter> B)"
  1357     using card_mono[OF assms Int_lower2, of A] by arith
  1358   also have "\<dots> = card(A-B)" using assms by(simp add: card_Diff_subset_Int)
  1359   finally show ?thesis .
  1360 qed
  1361 
  1362 lemma card_Diff1_less: "finite A ==> x: A ==> card (A - {x}) < card A"
  1363 apply (rule Suc_less_SucD)
  1364 apply (simp add: card_Suc_Diff1 del:card_Diff_insert)
  1365 done
  1366 
  1367 lemma card_Diff2_less:
  1368   "finite A ==> x: A ==> y: A ==> card (A - {x} - {y}) < card A"
  1369 apply (case_tac "x = y")
  1370  apply (simp add: card_Diff1_less del:card_Diff_insert)
  1371 apply (rule less_trans)
  1372  prefer 2 apply (auto intro!: card_Diff1_less simp del:card_Diff_insert)
  1373 done
  1374 
  1375 lemma card_Diff1_le: "finite A ==> card (A - {x}) <= card A"
  1376 apply (case_tac "x : A")
  1377  apply (simp_all add: card_Diff1_less less_imp_le)
  1378 done
  1379 
  1380 lemma card_psubset: "finite B ==> A \<subseteq> B ==> card A < card B ==> A < B"
  1381 by (erule psubsetI, blast)
  1382 
  1383 lemma card_le_inj:
  1384   assumes fA: "finite A"
  1385     and fB: "finite B"
  1386     and c: "card A \<le> card B"
  1387   shows "\<exists>f. f ` A \<subseteq> B \<and> inj_on f A"
  1388   using fA fB c
  1389 proof (induct arbitrary: B rule: finite_induct)
  1390   case empty
  1391   then show ?case by simp
  1392 next
  1393   case (insert x s t)
  1394   then show ?case
  1395   proof (induct rule: finite_induct[OF "insert.prems"(1)])
  1396     case 1
  1397     then show ?case by simp
  1398   next
  1399     case (2 y t)
  1400     from "2.prems"(1,2,5) "2.hyps"(1,2) have cst: "card s \<le> card t"
  1401       by simp
  1402     from "2.prems"(3) [OF "2.hyps"(1) cst]
  1403     obtain f where "f ` s \<subseteq> t" "inj_on f s"
  1404       by blast
  1405     with "2.prems"(2) "2.hyps"(2) show ?case
  1406       apply -
  1407       apply (rule exI[where x = "\<lambda>z. if z = x then y else f z"])
  1408       apply (auto simp add: inj_on_def)
  1409       done
  1410   qed
  1411 qed
  1412 
  1413 lemma card_subset_eq:
  1414   assumes fB: "finite B"
  1415     and AB: "A \<subseteq> B"
  1416     and c: "card A = card B"
  1417   shows "A = B"
  1418 proof -
  1419   from fB AB have fA: "finite A"
  1420     by (auto intro: finite_subset)
  1421   from fA fB have fBA: "finite (B - A)"
  1422     by auto
  1423   have e: "A \<inter> (B - A) = {}"
  1424     by blast
  1425   have eq: "A \<union> (B - A) = B"
  1426     using AB by blast
  1427   from card_Un_disjoint[OF fA fBA e, unfolded eq c] have "card (B - A) = 0"
  1428     by arith
  1429   then have "B - A = {}"
  1430     unfolding card_eq_0_iff using fA fB by simp
  1431   with AB show "A = B"
  1432     by blast
  1433 qed
  1434 
  1435 lemma insert_partition:
  1436   "\<lbrakk> x \<notin> F; \<forall>c1 \<in> insert x F. \<forall>c2 \<in> insert x F. c1 \<noteq> c2 \<longrightarrow> c1 \<inter> c2 = {} \<rbrakk>
  1437   \<Longrightarrow> x \<inter> \<Union>F = {}"
  1438 by auto
  1439 
  1440 lemma finite_psubset_induct[consumes 1, case_names psubset]:
  1441   assumes fin: "finite A" 
  1442   and     major: "\<And>A. finite A \<Longrightarrow> (\<And>B. B \<subset> A \<Longrightarrow> P B) \<Longrightarrow> P A" 
  1443   shows "P A"
  1444 using fin
  1445 proof (induct A taking: card rule: measure_induct_rule)
  1446   case (less A)
  1447   have fin: "finite A" by fact
  1448   have ih: "\<And>B. \<lbrakk>card B < card A; finite B\<rbrakk> \<Longrightarrow> P B" by fact
  1449   { fix B 
  1450     assume asm: "B \<subset> A"
  1451     from asm have "card B < card A" using psubset_card_mono fin by blast
  1452     moreover
  1453     from asm have "B \<subseteq> A" by auto
  1454     then have "finite B" using fin finite_subset by blast
  1455     ultimately 
  1456     have "P B" using ih by simp
  1457   }
  1458   with fin show "P A" using major by blast
  1459 qed
  1460 
  1461 lemma finite_induct_select[consumes 1, case_names empty select]:
  1462   assumes "finite S"
  1463   assumes "P {}"
  1464   assumes select: "\<And>T. T \<subset> S \<Longrightarrow> P T \<Longrightarrow> \<exists>s\<in>S - T. P (insert s T)"
  1465   shows "P S"
  1466 proof -
  1467   have "0 \<le> card S" by simp
  1468   then have "\<exists>T \<subseteq> S. card T = card S \<and> P T"
  1469   proof (induct rule: dec_induct)
  1470     case base with \<open>P {}\<close> show ?case
  1471       by (intro exI[of _ "{}"]) auto
  1472   next
  1473     case (step n)
  1474     then obtain T where T: "T \<subseteq> S" "card T = n" "P T"
  1475       by auto
  1476     with \<open>n < card S\<close> have "T \<subset> S" "P T"
  1477       by auto
  1478     with select[of T] obtain s where "s \<in> S" "s \<notin> T" "P (insert s T)"
  1479       by auto
  1480     with step(2) T \<open>finite S\<close> show ?case
  1481       by (intro exI[of _ "insert s T"]) (auto dest: finite_subset)
  1482   qed
  1483   with \<open>finite S\<close> show "P S"
  1484     by (auto dest: card_subset_eq)
  1485 qed
  1486 
  1487 text\<open>main cardinality theorem\<close>
  1488 lemma card_partition [rule_format]:
  1489   "finite C ==>
  1490      finite (\<Union>C) -->
  1491      (\<forall>c\<in>C. card c = k) -->
  1492      (\<forall>c1 \<in> C. \<forall>c2 \<in> C. c1 \<noteq> c2 --> c1 \<inter> c2 = {}) -->
  1493      k * card(C) = card (\<Union>C)"
  1494 apply (erule finite_induct, simp)
  1495 apply (simp add: card_Un_disjoint insert_partition 
  1496        finite_subset [of _ "\<Union>(insert x F)"])
  1497 done
  1498 
  1499 lemma card_eq_UNIV_imp_eq_UNIV:
  1500   assumes fin: "finite (UNIV :: 'a set)"
  1501   and card: "card A = card (UNIV :: 'a set)"
  1502   shows "A = (UNIV :: 'a set)"
  1503 proof
  1504   show "A \<subseteq> UNIV" by simp
  1505   show "UNIV \<subseteq> A"
  1506   proof
  1507     fix x
  1508     show "x \<in> A"
  1509     proof (rule ccontr)
  1510       assume "x \<notin> A"
  1511       then have "A \<subset> UNIV" by auto
  1512       with fin have "card A < card (UNIV :: 'a set)" by (fact psubset_card_mono)
  1513       with card show False by simp
  1514     qed
  1515   qed
  1516 qed
  1517 
  1518 text\<open>The form of a finite set of given cardinality\<close>
  1519 
  1520 lemma card_eq_SucD:
  1521 assumes "card A = Suc k"
  1522 shows "\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={})"
  1523 proof -
  1524   have fin: "finite A" using assms by (auto intro: ccontr)
  1525   moreover have "card A \<noteq> 0" using assms by auto
  1526   ultimately obtain b where b: "b \<in> A" by auto
  1527   show ?thesis
  1528   proof (intro exI conjI)
  1529     show "A = insert b (A-{b})" using b by blast
  1530     show "b \<notin> A - {b}" by blast
  1531     show "card (A - {b}) = k" and "k = 0 \<longrightarrow> A - {b} = {}"
  1532       using assms b fin by(fastforce dest:mk_disjoint_insert)+
  1533   qed
  1534 qed
  1535 
  1536 lemma card_Suc_eq:
  1537   "(card A = Suc k) =
  1538    (\<exists>b B. A = insert b B & b \<notin> B & card B = k & (k=0 \<longrightarrow> B={}))"
  1539  apply(auto elim!: card_eq_SucD)
  1540  apply(subst card.insert)
  1541  apply(auto simp add: intro:ccontr)
  1542  done
  1543 
  1544 lemma card_le_Suc_iff: "finite A \<Longrightarrow>
  1545   Suc n \<le> card A = (\<exists>a B. A = insert a B \<and> a \<notin> B \<and> n \<le> card B \<and> finite B)"
  1546 by (fastforce simp: card_Suc_eq less_eq_nat.simps(2) insert_eq_iff
  1547   dest: subset_singletonD split: nat.splits if_splits)
  1548 
  1549 lemma finite_fun_UNIVD2:
  1550   assumes fin: "finite (UNIV :: ('a \<Rightarrow> 'b) set)"
  1551   shows "finite (UNIV :: 'b set)"
  1552 proof -
  1553   from fin have "\<And>arbitrary. finite (range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary))"
  1554     by (rule finite_imageI)
  1555   moreover have "\<And>arbitrary. UNIV = range (\<lambda>f :: 'a \<Rightarrow> 'b. f arbitrary)"
  1556     by (rule UNIV_eq_I) auto
  1557   ultimately show "finite (UNIV :: 'b set)" by simp
  1558 qed
  1559 
  1560 lemma card_UNIV_unit [simp]: "card (UNIV :: unit set) = 1"
  1561   unfolding UNIV_unit by simp
  1562 
  1563 lemma infinite_arbitrarily_large:
  1564   assumes "\<not> finite A"
  1565   shows "\<exists>B. finite B \<and> card B = n \<and> B \<subseteq> A"
  1566 proof (induction n)
  1567   case 0 show ?case by (intro exI[of _ "{}"]) auto
  1568 next 
  1569   case (Suc n)
  1570   then guess B .. note B = this
  1571   with \<open>\<not> finite A\<close> have "A \<noteq> B" by auto
  1572   with B have "B \<subset> A" by auto
  1573   hence "\<exists>x. x \<in> A - B" by (elim psubset_imp_ex_mem)
  1574   then guess x .. note x = this
  1575   with B have "finite (insert x B) \<and> card (insert x B) = Suc n \<and> insert x B \<subseteq> A"
  1576     by auto
  1577   thus "\<exists>B. finite B \<and> card B = Suc n \<and> B \<subseteq> A" ..
  1578 qed
  1579 
  1580 subsubsection \<open>Cardinality of image\<close>
  1581 
  1582 lemma card_image_le: "finite A ==> card (f ` A) \<le> card A"
  1583   by (induct rule: finite_induct) (simp_all add: le_SucI card_insert_if)
  1584 
  1585 lemma card_image:
  1586   assumes "inj_on f A"
  1587   shows "card (f ` A) = card A"
  1588 proof (cases "finite A")
  1589   case True then show ?thesis using assms by (induct A) simp_all
  1590 next
  1591   case False then have "\<not> finite (f ` A)" using assms by (auto dest: finite_imageD)
  1592   with False show ?thesis by simp
  1593 qed
  1594 
  1595 lemma bij_betw_same_card: "bij_betw f A B \<Longrightarrow> card A = card B"
  1596 by(auto simp: card_image bij_betw_def)
  1597 
  1598 lemma endo_inj_surj: "finite A ==> f ` A \<subseteq> A ==> inj_on f A ==> f ` A = A"
  1599 by (simp add: card_seteq card_image)
  1600 
  1601 lemma eq_card_imp_inj_on:
  1602   assumes "finite A" "card(f ` A) = card A" shows "inj_on f A"
  1603 using assms
  1604 proof (induct rule:finite_induct)
  1605   case empty show ?case by simp
  1606 next
  1607   case (insert x A)
  1608   then show ?case using card_image_le [of A f]
  1609     by (simp add: card_insert_if split: if_splits)
  1610 qed
  1611 
  1612 lemma inj_on_iff_eq_card: "finite A \<Longrightarrow> inj_on f A \<longleftrightarrow> card(f ` A) = card A"
  1613   by (blast intro: card_image eq_card_imp_inj_on)
  1614 
  1615 lemma card_inj_on_le:
  1616   assumes "inj_on f A" "f ` A \<subseteq> B" "finite B" shows "card A \<le> card B"
  1617 proof -
  1618   have "finite A" using assms
  1619     by (blast intro: finite_imageD dest: finite_subset)
  1620   then show ?thesis using assms 
  1621    by (force intro: card_mono simp: card_image [symmetric])
  1622 qed
  1623 
  1624 lemma surj_card_le: "finite A \<Longrightarrow> B \<subseteq> f ` A \<Longrightarrow> card B \<le> card A"
  1625   by (blast intro: card_image_le card_mono le_trans)
  1626 
  1627 lemma card_bij_eq:
  1628   "[|inj_on f A; f ` A \<subseteq> B; inj_on g B; g ` B \<subseteq> A;
  1629      finite A; finite B |] ==> card A = card B"
  1630 by (auto intro: le_antisym card_inj_on_le)
  1631 
  1632 lemma bij_betw_finite:
  1633   assumes "bij_betw f A B"
  1634   shows "finite A \<longleftrightarrow> finite B"
  1635 using assms unfolding bij_betw_def
  1636 using finite_imageD[of f A] by auto
  1637 
  1638 lemma inj_on_finite:
  1639 assumes "inj_on f A" "f ` A \<le> B" "finite B"
  1640 shows "finite A"
  1641 using assms finite_imageD finite_subset by blast
  1642 
  1643 lemma card_vimage_inj: "\<lbrakk> inj f; A \<subseteq> range f \<rbrakk> \<Longrightarrow> card (f -` A) = card A"
  1644 by(auto 4 3 simp add: subset_image_iff inj_vimage_image_eq intro: card_image[symmetric, OF subset_inj_on])
  1645 
  1646 subsubsection \<open>Pigeonhole Principles\<close>
  1647 
  1648 lemma pigeonhole: "card A > card(f ` A) \<Longrightarrow> ~ inj_on f A "
  1649 by (auto dest: card_image less_irrefl_nat)
  1650 
  1651 lemma pigeonhole_infinite:
  1652 assumes  "~ finite A" and "finite(f`A)"
  1653 shows "EX a0:A. ~finite{a:A. f a = f a0}"
  1654 proof -
  1655   have "finite(f`A) \<Longrightarrow> ~ finite A \<Longrightarrow> EX a0:A. ~finite{a:A. f a = f a0}"
  1656   proof(induct "f`A" arbitrary: A rule: finite_induct)
  1657     case empty thus ?case by simp
  1658   next
  1659     case (insert b F)
  1660     show ?case
  1661     proof cases
  1662       assume "finite{a:A. f a = b}"
  1663       hence "~ finite(A - {a:A. f a = b})" using \<open>\<not> finite A\<close> by simp
  1664       also have "A - {a:A. f a = b} = {a:A. f a \<noteq> b}" by blast
  1665       finally have "~ finite({a:A. f a \<noteq> b})" .
  1666       from insert(3)[OF _ this]
  1667       show ?thesis using insert(2,4) by simp (blast intro: rev_finite_subset)
  1668     next
  1669       assume 1: "~finite{a:A. f a = b}"
  1670       hence "{a \<in> A. f a = b} \<noteq> {}" by force
  1671       thus ?thesis using 1 by blast
  1672     qed
  1673   qed
  1674   from this[OF assms(2,1)] show ?thesis .
  1675 qed
  1676 
  1677 lemma pigeonhole_infinite_rel:
  1678 assumes "~finite A" and "finite B" and "ALL a:A. EX b:B. R a b"
  1679 shows "EX b:B. ~finite{a:A. R a b}"
  1680 proof -
  1681    let ?F = "%a. {b:B. R a b}"
  1682    from finite_Pow_iff[THEN iffD2, OF \<open>finite B\<close>]
  1683    have "finite(?F ` A)" by(blast intro: rev_finite_subset)
  1684    from pigeonhole_infinite[where f = ?F, OF assms(1) this]
  1685    obtain a0 where "a0\<in>A" and 1: "\<not> finite {a\<in>A. ?F a = ?F a0}" ..
  1686    obtain b0 where "b0 : B" and "R a0 b0" using \<open>a0:A\<close> assms(3) by blast
  1687    { assume "finite{a:A. R a b0}"
  1688      then have "finite {a\<in>A. ?F a = ?F a0}"
  1689        using \<open>b0 : B\<close> \<open>R a0 b0\<close> by(blast intro: rev_finite_subset)
  1690    }
  1691    with 1 \<open>b0 : B\<close> show ?thesis by blast
  1692 qed
  1693 
  1694 
  1695 subsubsection \<open>Cardinality of sums\<close>
  1696 
  1697 lemma card_Plus:
  1698   assumes "finite A" and "finite B"
  1699   shows "card (A <+> B) = card A + card B"
  1700 proof -
  1701   have "Inl`A \<inter> Inr`B = {}" by fast
  1702   with assms show ?thesis
  1703     unfolding Plus_def
  1704     by (simp add: card_Un_disjoint card_image)
  1705 qed
  1706 
  1707 lemma card_Plus_conv_if:
  1708   "card (A <+> B) = (if finite A \<and> finite B then card A + card B else 0)"
  1709   by (auto simp add: card_Plus)
  1710 
  1711 text \<open>Relates to equivalence classes.  Based on a theorem of F. Kamm\"uller.\<close>
  1712 
  1713 lemma dvd_partition:
  1714   assumes f: "finite (\<Union>C)" and "\<forall>c\<in>C. k dvd card c" "\<forall>c1\<in>C. \<forall>c2\<in>C. c1 \<noteq> c2 \<longrightarrow> c1 \<inter> c2 = {}"
  1715     shows "k dvd card (\<Union>C)"
  1716 proof -
  1717   have "finite C" 
  1718     by (rule finite_UnionD [OF f])
  1719   then show ?thesis using assms
  1720   proof (induct rule: finite_induct)
  1721     case empty show ?case by simp
  1722   next
  1723     case (insert c C)
  1724     then show ?case 
  1725       apply simp
  1726       apply (subst card_Un_disjoint)
  1727       apply (auto simp add: disjoint_eq_subset_Compl)
  1728       done
  1729   qed
  1730 qed
  1731 
  1732 subsubsection \<open>Relating injectivity and surjectivity\<close>
  1733 
  1734 lemma finite_surj_inj: assumes "finite A" "A \<subseteq> f ` A" shows "inj_on f A"
  1735 proof -
  1736   have "f ` A = A" 
  1737     by (rule card_seteq [THEN sym]) (auto simp add: assms card_image_le)
  1738   then show ?thesis using assms
  1739     by (simp add: eq_card_imp_inj_on)
  1740 qed
  1741 
  1742 lemma finite_UNIV_surj_inj: fixes f :: "'a \<Rightarrow> 'a"
  1743 shows "finite(UNIV:: 'a set) \<Longrightarrow> surj f \<Longrightarrow> inj f"
  1744 by (blast intro: finite_surj_inj subset_UNIV)
  1745 
  1746 lemma finite_UNIV_inj_surj: fixes f :: "'a \<Rightarrow> 'a"
  1747 shows "finite(UNIV:: 'a set) \<Longrightarrow> inj f \<Longrightarrow> surj f"
  1748 by(fastforce simp:surj_def dest!: endo_inj_surj)
  1749 
  1750 corollary infinite_UNIV_nat [iff]:
  1751   "\<not> finite (UNIV :: nat set)"
  1752 proof
  1753   assume "finite (UNIV :: nat set)"
  1754   with finite_UNIV_inj_surj [of Suc]
  1755   show False by simp (blast dest: Suc_neq_Zero surjD)
  1756 qed
  1757 
  1758 lemma infinite_UNIV_char_0:
  1759   "\<not> finite (UNIV :: 'a::semiring_char_0 set)"
  1760 proof
  1761   assume "finite (UNIV :: 'a set)"
  1762   with subset_UNIV have "finite (range of_nat :: 'a set)"
  1763     by (rule finite_subset)
  1764   moreover have "inj (of_nat :: nat \<Rightarrow> 'a)"
  1765     by (simp add: inj_on_def)
  1766   ultimately have "finite (UNIV :: nat set)"
  1767     by (rule finite_imageD)
  1768   then show False
  1769     by simp
  1770 qed
  1771 
  1772 hide_const (open) Finite_Set.fold
  1773 
  1774 end