src/HOL/Probability/Information.thy
author hoelzl
Wed Oct 10 12:12:25 2012 +0200 (2012-10-10)
changeset 49787 d8de705b48d4
parent 49786 f33d5f009627
child 49788 3c10763f5cb4
permissions -rw-r--r--
rule to show that conditional mutual information is non-negative in the continuous case
     1 (*  Title:      HOL/Probability/Information.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Armin Heller, TU München
     4 *)
     5 
     6 header {*Information theory*}
     7 
     8 theory Information
     9 imports
    10   Independent_Family
    11   Radon_Nikodym
    12   "~~/src/HOL/Library/Convex"
    13 begin
    14 
    15 lemma log_le: "1 < a \<Longrightarrow> 0 < x \<Longrightarrow> x \<le> y \<Longrightarrow> log a x \<le> log a y"
    16   by (subst log_le_cancel_iff) auto
    17 
    18 lemma log_less: "1 < a \<Longrightarrow> 0 < x \<Longrightarrow> x < y \<Longrightarrow> log a x < log a y"
    19   by (subst log_less_cancel_iff) auto
    20 
    21 lemma setsum_cartesian_product':
    22   "(\<Sum>x\<in>A \<times> B. f x) = (\<Sum>x\<in>A. setsum (\<lambda>y. f (x, y)) B)"
    23   unfolding setsum_cartesian_product by simp
    24 
    25 lemma split_pairs:
    26   "((A, B) = X) \<longleftrightarrow> (fst X = A \<and> snd X = B)" and
    27   "(X = (A, B)) \<longleftrightarrow> (fst X = A \<and> snd X = B)" by auto
    28 
    29 section "Information theory"
    30 
    31 locale information_space = prob_space +
    32   fixes b :: real assumes b_gt_1: "1 < b"
    33 
    34 context information_space
    35 begin
    36 
    37 text {* Introduce some simplification rules for logarithm of base @{term b}. *}
    38 
    39 lemma log_neg_const:
    40   assumes "x \<le> 0"
    41   shows "log b x = log b 0"
    42 proof -
    43   { fix u :: real
    44     have "x \<le> 0" by fact
    45     also have "0 < exp u"
    46       using exp_gt_zero .
    47     finally have "exp u \<noteq> x"
    48       by auto }
    49   then show "log b x = log b 0"
    50     by (simp add: log_def ln_def)
    51 qed
    52 
    53 lemma log_mult_eq:
    54   "log b (A * B) = (if 0 < A * B then log b \<bar>A\<bar> + log b \<bar>B\<bar> else log b 0)"
    55   using log_mult[of b "\<bar>A\<bar>" "\<bar>B\<bar>"] b_gt_1 log_neg_const[of "A * B"]
    56   by (auto simp: zero_less_mult_iff mult_le_0_iff)
    57 
    58 lemma log_inverse_eq:
    59   "log b (inverse B) = (if 0 < B then - log b B else log b 0)"
    60   using log_inverse[of b B] log_neg_const[of "inverse B"] b_gt_1 by simp
    61 
    62 lemma log_divide_eq:
    63   "log b (A / B) = (if 0 < A * B then log b \<bar>A\<bar> - log b \<bar>B\<bar> else log b 0)"
    64   unfolding divide_inverse log_mult_eq log_inverse_eq abs_inverse
    65   by (auto simp: zero_less_mult_iff mult_le_0_iff)
    66 
    67 lemmas log_simps = log_mult_eq log_inverse_eq log_divide_eq
    68 
    69 end
    70 
    71 subsection "Kullback$-$Leibler divergence"
    72 
    73 text {* The Kullback$-$Leibler divergence is also known as relative entropy or
    74 Kullback$-$Leibler distance. *}
    75 
    76 definition
    77   "entropy_density b M N = log b \<circ> real \<circ> RN_deriv M N"
    78 
    79 definition
    80   "KL_divergence b M N = integral\<^isup>L N (entropy_density b M N)"
    81 
    82 lemma (in information_space) measurable_entropy_density:
    83   assumes ac: "absolutely_continuous M N" "sets N = events"
    84   shows "entropy_density b M N \<in> borel_measurable M"
    85 proof -
    86   from borel_measurable_RN_deriv[OF ac] b_gt_1 show ?thesis
    87     unfolding entropy_density_def
    88     by (intro measurable_comp) auto
    89 qed
    90 
    91 lemma (in sigma_finite_measure) KL_density:
    92   fixes f :: "'a \<Rightarrow> real"
    93   assumes "1 < b"
    94   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
    95   shows "KL_divergence b M (density M f) = (\<integral>x. f x * log b (f x) \<partial>M)"
    96   unfolding KL_divergence_def
    97 proof (subst integral_density)
    98   show "entropy_density b M (density M (\<lambda>x. ereal (f x))) \<in> borel_measurable M"
    99     using f
   100     by (auto simp: comp_def entropy_density_def intro!: borel_measurable_log borel_measurable_RN_deriv_density)
   101   have "density M (RN_deriv M (density M f)) = density M f"
   102     using f by (intro density_RN_deriv_density) auto
   103   then have eq: "AE x in M. RN_deriv M (density M f) x = f x"
   104     using f
   105     by (intro density_unique)
   106        (auto intro!: borel_measurable_log borel_measurable_RN_deriv_density simp: RN_deriv_density_nonneg)
   107   show "(\<integral>x. f x * entropy_density b M (density M (\<lambda>x. ereal (f x))) x \<partial>M) = (\<integral>x. f x * log b (f x) \<partial>M)"
   108     apply (intro integral_cong_AE)
   109     using eq
   110     apply eventually_elim
   111     apply (auto simp: entropy_density_def)
   112     done
   113 qed fact+
   114 
   115 lemma (in sigma_finite_measure) KL_density_density:
   116   fixes f g :: "'a \<Rightarrow> real"
   117   assumes "1 < b"
   118   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
   119   assumes g: "g \<in> borel_measurable M" "AE x in M. 0 \<le> g x"
   120   assumes ac: "AE x in M. f x = 0 \<longrightarrow> g x = 0"
   121   shows "KL_divergence b (density M f) (density M g) = (\<integral>x. g x * log b (g x / f x) \<partial>M)"
   122 proof -
   123   interpret Mf: sigma_finite_measure "density M f"
   124     using f by (subst sigma_finite_iff_density_finite) auto
   125   have "KL_divergence b (density M f) (density M g) =
   126     KL_divergence b (density M f) (density (density M f) (\<lambda>x. g x / f x))"
   127     using f g ac by (subst density_density_divide) simp_all
   128   also have "\<dots> = (\<integral>x. (g x / f x) * log b (g x / f x) \<partial>density M f)"
   129     using f g `1 < b` by (intro Mf.KL_density) (auto simp: AE_density divide_nonneg_nonneg)
   130   also have "\<dots> = (\<integral>x. g x * log b (g x / f x) \<partial>M)"
   131     using ac f g `1 < b` by (subst integral_density) (auto intro!: integral_cong_AE)
   132   finally show ?thesis .
   133 qed
   134 
   135 lemma (in information_space) KL_gt_0:
   136   fixes D :: "'a \<Rightarrow> real"
   137   assumes "prob_space (density M D)"
   138   assumes D: "D \<in> borel_measurable M" "AE x in M. 0 \<le> D x"
   139   assumes int: "integrable M (\<lambda>x. D x * log b (D x))"
   140   assumes A: "density M D \<noteq> M"
   141   shows "0 < KL_divergence b M (density M D)"
   142 proof -
   143   interpret N: prob_space "density M D" by fact
   144 
   145   obtain A where "A \<in> sets M" "emeasure (density M D) A \<noteq> emeasure M A"
   146     using measure_eqI[of "density M D" M] `density M D \<noteq> M` by auto
   147 
   148   let ?D_set = "{x\<in>space M. D x \<noteq> 0}"
   149   have [simp, intro]: "?D_set \<in> sets M"
   150     using D by auto
   151 
   152   have D_neg: "(\<integral>\<^isup>+ x. ereal (- D x) \<partial>M) = 0"
   153     using D by (subst positive_integral_0_iff_AE) auto
   154 
   155   have "(\<integral>\<^isup>+ x. ereal (D x) \<partial>M) = emeasure (density M D) (space M)"
   156     using D by (simp add: emeasure_density cong: positive_integral_cong)
   157   then have D_pos: "(\<integral>\<^isup>+ x. ereal (D x) \<partial>M) = 1"
   158     using N.emeasure_space_1 by simp
   159 
   160   have "integrable M D" "integral\<^isup>L M D = 1"
   161     using D D_pos D_neg unfolding integrable_def lebesgue_integral_def by simp_all
   162 
   163   have "0 \<le> 1 - measure M ?D_set"
   164     using prob_le_1 by (auto simp: field_simps)
   165   also have "\<dots> = (\<integral> x. D x - indicator ?D_set x \<partial>M)"
   166     using `integrable M D` `integral\<^isup>L M D = 1`
   167     by (simp add: emeasure_eq_measure)
   168   also have "\<dots> < (\<integral> x. D x * (ln b * log b (D x)) \<partial>M)"
   169   proof (rule integral_less_AE)
   170     show "integrable M (\<lambda>x. D x - indicator ?D_set x)"
   171       using `integrable M D`
   172       by (intro integral_diff integral_indicator) auto
   173   next
   174     from integral_cmult(1)[OF int, of "ln b"]
   175     show "integrable M (\<lambda>x. D x * (ln b * log b (D x)))" 
   176       by (simp add: ac_simps)
   177   next
   178     show "emeasure M {x\<in>space M. D x \<noteq> 1 \<and> D x \<noteq> 0} \<noteq> 0"
   179     proof
   180       assume eq_0: "emeasure M {x\<in>space M. D x \<noteq> 1 \<and> D x \<noteq> 0} = 0"
   181       then have disj: "AE x in M. D x = 1 \<or> D x = 0"
   182         using D(1) by (auto intro!: AE_I[OF subset_refl] sets_Collect)
   183 
   184       have "emeasure M {x\<in>space M. D x = 1} = (\<integral>\<^isup>+ x. indicator {x\<in>space M. D x = 1} x \<partial>M)"
   185         using D(1) by auto
   186       also have "\<dots> = (\<integral>\<^isup>+ x. ereal (D x) \<partial>M)"
   187         using disj by (auto intro!: positive_integral_cong_AE simp: indicator_def one_ereal_def)
   188       finally have "AE x in M. D x = 1"
   189         using D D_pos by (intro AE_I_eq_1) auto
   190       then have "(\<integral>\<^isup>+x. indicator A x\<partial>M) = (\<integral>\<^isup>+x. ereal (D x) * indicator A x\<partial>M)"
   191         by (intro positive_integral_cong_AE) (auto simp: one_ereal_def[symmetric])
   192       also have "\<dots> = density M D A"
   193         using `A \<in> sets M` D by (simp add: emeasure_density)
   194       finally show False using `A \<in> sets M` `emeasure (density M D) A \<noteq> emeasure M A` by simp
   195     qed
   196     show "{x\<in>space M. D x \<noteq> 1 \<and> D x \<noteq> 0} \<in> sets M"
   197       using D(1) by (auto intro: sets_Collect_conj)
   198 
   199     show "AE t in M. t \<in> {x\<in>space M. D x \<noteq> 1 \<and> D x \<noteq> 0} \<longrightarrow>
   200       D t - indicator ?D_set t \<noteq> D t * (ln b * log b (D t))"
   201       using D(2)
   202     proof (eventually_elim, safe)
   203       fix t assume Dt: "t \<in> space M" "D t \<noteq> 1" "D t \<noteq> 0" "0 \<le> D t"
   204         and eq: "D t - indicator ?D_set t = D t * (ln b * log b (D t))"
   205 
   206       have "D t - 1 = D t - indicator ?D_set t"
   207         using Dt by simp
   208       also note eq
   209       also have "D t * (ln b * log b (D t)) = - D t * ln (1 / D t)"
   210         using b_gt_1 `D t \<noteq> 0` `0 \<le> D t`
   211         by (simp add: log_def ln_div less_le)
   212       finally have "ln (1 / D t) = 1 / D t - 1"
   213         using `D t \<noteq> 0` by (auto simp: field_simps)
   214       from ln_eq_minus_one[OF _ this] `D t \<noteq> 0` `0 \<le> D t` `D t \<noteq> 1`
   215       show False by auto
   216     qed
   217 
   218     show "AE t in M. D t - indicator ?D_set t \<le> D t * (ln b * log b (D t))"
   219       using D(2) AE_space
   220     proof eventually_elim
   221       fix t assume "t \<in> space M" "0 \<le> D t"
   222       show "D t - indicator ?D_set t \<le> D t * (ln b * log b (D t))"
   223       proof cases
   224         assume asm: "D t \<noteq> 0"
   225         then have "0 < D t" using `0 \<le> D t` by auto
   226         then have "0 < 1 / D t" by auto
   227         have "D t - indicator ?D_set t \<le> - D t * (1 / D t - 1)"
   228           using asm `t \<in> space M` by (simp add: field_simps)
   229         also have "- D t * (1 / D t - 1) \<le> - D t * ln (1 / D t)"
   230           using ln_le_minus_one `0 < 1 / D t` by (intro mult_left_mono_neg) auto
   231         also have "\<dots> = D t * (ln b * log b (D t))"
   232           using `0 < D t` b_gt_1
   233           by (simp_all add: log_def ln_div)
   234         finally show ?thesis by simp
   235       qed simp
   236     qed
   237   qed
   238   also have "\<dots> = (\<integral> x. ln b * (D x * log b (D x)) \<partial>M)"
   239     by (simp add: ac_simps)
   240   also have "\<dots> = ln b * (\<integral> x. D x * log b (D x) \<partial>M)"
   241     using int by (rule integral_cmult)
   242   finally show ?thesis
   243     using b_gt_1 D by (subst KL_density) (auto simp: zero_less_mult_iff)
   244 qed
   245 
   246 lemma (in sigma_finite_measure) KL_same_eq_0: "KL_divergence b M M = 0"
   247 proof -
   248   have "AE x in M. 1 = RN_deriv M M x"
   249   proof (rule RN_deriv_unique)
   250     show "(\<lambda>x. 1) \<in> borel_measurable M" "AE x in M. 0 \<le> (1 :: ereal)" by auto
   251     show "density M (\<lambda>x. 1) = M"
   252       apply (auto intro!: measure_eqI emeasure_density)
   253       apply (subst emeasure_density)
   254       apply auto
   255       done
   256   qed
   257   then have "AE x in M. log b (real (RN_deriv M M x)) = 0"
   258     by (elim AE_mp) simp
   259   from integral_cong_AE[OF this]
   260   have "integral\<^isup>L M (entropy_density b M M) = 0"
   261     by (simp add: entropy_density_def comp_def)
   262   then show "KL_divergence b M M = 0"
   263     unfolding KL_divergence_def
   264     by auto
   265 qed
   266 
   267 lemma (in information_space) KL_eq_0_iff_eq:
   268   fixes D :: "'a \<Rightarrow> real"
   269   assumes "prob_space (density M D)"
   270   assumes D: "D \<in> borel_measurable M" "AE x in M. 0 \<le> D x"
   271   assumes int: "integrable M (\<lambda>x. D x * log b (D x))"
   272   shows "KL_divergence b M (density M D) = 0 \<longleftrightarrow> density M D = M"
   273   using KL_same_eq_0[of b] KL_gt_0[OF assms]
   274   by (auto simp: less_le)
   275 
   276 lemma (in information_space) KL_eq_0_iff_eq_ac:
   277   fixes D :: "'a \<Rightarrow> real"
   278   assumes "prob_space N"
   279   assumes ac: "absolutely_continuous M N" "sets N = sets M"
   280   assumes int: "integrable N (entropy_density b M N)"
   281   shows "KL_divergence b M N = 0 \<longleftrightarrow> N = M"
   282 proof -
   283   interpret N: prob_space N by fact
   284   have "finite_measure N" by unfold_locales
   285   from real_RN_deriv[OF this ac] guess D . note D = this
   286   
   287   have "N = density M (RN_deriv M N)"
   288     using ac by (rule density_RN_deriv[symmetric])
   289   also have "\<dots> = density M D"
   290     using borel_measurable_RN_deriv[OF ac] D by (auto intro!: density_cong)
   291   finally have N: "N = density M D" .
   292 
   293   from absolutely_continuous_AE[OF ac(2,1) D(2)] D b_gt_1 ac measurable_entropy_density
   294   have "integrable N (\<lambda>x. log b (D x))"
   295     by (intro integrable_cong_AE[THEN iffD2, OF _ _ _ int])
   296        (auto simp: N entropy_density_def)
   297   with D b_gt_1 have "integrable M (\<lambda>x. D x * log b (D x))"
   298     by (subst integral_density(2)[symmetric]) (auto simp: N[symmetric] comp_def)
   299   with `prob_space N` D show ?thesis
   300     unfolding N
   301     by (intro KL_eq_0_iff_eq) auto
   302 qed
   303 
   304 lemma (in information_space) KL_nonneg:
   305   assumes "prob_space (density M D)"
   306   assumes D: "D \<in> borel_measurable M" "AE x in M. 0 \<le> D x"
   307   assumes int: "integrable M (\<lambda>x. D x * log b (D x))"
   308   shows "0 \<le> KL_divergence b M (density M D)"
   309   using KL_gt_0[OF assms] by (cases "density M D = M") (auto simp: KL_same_eq_0)
   310 
   311 lemma (in sigma_finite_measure) KL_density_density_nonneg:
   312   fixes f g :: "'a \<Rightarrow> real"
   313   assumes "1 < b"
   314   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x" "prob_space (density M f)"
   315   assumes g: "g \<in> borel_measurable M" "AE x in M. 0 \<le> g x" "prob_space (density M g)"
   316   assumes ac: "AE x in M. f x = 0 \<longrightarrow> g x = 0"
   317   assumes int: "integrable M (\<lambda>x. g x * log b (g x / f x))"
   318   shows "0 \<le> KL_divergence b (density M f) (density M g)"
   319 proof -
   320   interpret Mf: prob_space "density M f" by fact
   321   interpret Mf: information_space "density M f" b by default fact
   322   have eq: "density (density M f) (\<lambda>x. g x / f x) = density M g" (is "?DD = _")
   323     using f g ac by (subst density_density_divide) simp_all
   324 
   325   have "0 \<le> KL_divergence b (density M f) (density (density M f) (\<lambda>x. g x / f x))"
   326   proof (rule Mf.KL_nonneg)
   327     show "prob_space ?DD" unfolding eq by fact
   328     from f g show "(\<lambda>x. g x / f x) \<in> borel_measurable (density M f)"
   329       by auto
   330     show "AE x in density M f. 0 \<le> g x / f x"
   331       using f g by (auto simp: AE_density divide_nonneg_nonneg)
   332     show "integrable (density M f) (\<lambda>x. g x / f x * log b (g x / f x))"
   333       using `1 < b` f g ac
   334       by (subst integral_density)
   335          (auto intro!: integrable_cong_AE[THEN iffD2, OF _ _ _ int] measurable_If)
   336   qed
   337   also have "\<dots> = KL_divergence b (density M f) (density M g)"
   338     using f g ac by (subst density_density_divide) simp_all
   339   finally show ?thesis .
   340 qed
   341 
   342 subsection {* Mutual Information *}
   343 
   344 definition (in prob_space)
   345   "mutual_information b S T X Y =
   346     KL_divergence b (distr M S X \<Otimes>\<^isub>M distr M T Y) (distr M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x)))"
   347 
   348 lemma (in information_space) mutual_information_indep_vars:
   349   fixes S T X Y
   350   defines "P \<equiv> distr M S X \<Otimes>\<^isub>M distr M T Y"
   351   defines "Q \<equiv> distr M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))"
   352   shows "indep_var S X T Y \<longleftrightarrow>
   353     (random_variable S X \<and> random_variable T Y \<and>
   354       absolutely_continuous P Q \<and> integrable Q (entropy_density b P Q) \<and>
   355       mutual_information b S T X Y = 0)"
   356   unfolding indep_var_distribution_eq
   357 proof safe
   358   assume rv: "random_variable S X" "random_variable T Y"
   359 
   360   interpret X: prob_space "distr M S X"
   361     by (rule prob_space_distr) fact
   362   interpret Y: prob_space "distr M T Y"
   363     by (rule prob_space_distr) fact
   364   interpret XY: pair_prob_space "distr M S X" "distr M T Y" by default
   365   interpret P: information_space P b unfolding P_def by default (rule b_gt_1)
   366 
   367   interpret Q: prob_space Q unfolding Q_def
   368     by (rule prob_space_distr) (simp add: comp_def measurable_pair_iff rv)
   369 
   370   { assume "distr M S X \<Otimes>\<^isub>M distr M T Y = distr M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))"
   371     then have [simp]: "Q = P"  unfolding Q_def P_def by simp
   372 
   373     show ac: "absolutely_continuous P Q" by (simp add: absolutely_continuous_def)
   374     then have ed: "entropy_density b P Q \<in> borel_measurable P"
   375       by (rule P.measurable_entropy_density) simp
   376 
   377     have "AE x in P. 1 = RN_deriv P Q x"
   378     proof (rule P.RN_deriv_unique)
   379       show "density P (\<lambda>x. 1) = Q"
   380         unfolding `Q = P` by (intro measure_eqI) (auto simp: emeasure_density)
   381     qed auto
   382     then have ae_0: "AE x in P. entropy_density b P Q x = 0"
   383       by eventually_elim (auto simp: entropy_density_def)
   384     then have "integrable P (entropy_density b P Q) \<longleftrightarrow> integrable Q (\<lambda>x. 0)"
   385       using ed unfolding `Q = P` by (intro integrable_cong_AE) auto
   386     then show "integrable Q (entropy_density b P Q)" by simp
   387 
   388     show "mutual_information b S T X Y = 0"
   389       unfolding mutual_information_def KL_divergence_def P_def[symmetric] Q_def[symmetric] `Q = P`
   390       using ae_0 by (simp cong: integral_cong_AE) }
   391 
   392   { assume ac: "absolutely_continuous P Q"
   393     assume int: "integrable Q (entropy_density b P Q)"
   394     assume I_eq_0: "mutual_information b S T X Y = 0"
   395 
   396     have eq: "Q = P"
   397     proof (rule P.KL_eq_0_iff_eq_ac[THEN iffD1])
   398       show "prob_space Q" by unfold_locales
   399       show "absolutely_continuous P Q" by fact
   400       show "integrable Q (entropy_density b P Q)" by fact
   401       show "sets Q = sets P" by (simp add: P_def Q_def sets_pair_measure)
   402       show "KL_divergence b P Q = 0"
   403         using I_eq_0 unfolding mutual_information_def by (simp add: P_def Q_def)
   404     qed
   405     then show "distr M S X \<Otimes>\<^isub>M distr M T Y = distr M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))"
   406       unfolding P_def Q_def .. }
   407 qed
   408 
   409 abbreviation (in information_space)
   410   mutual_information_Pow ("\<I>'(_ ; _')") where
   411   "\<I>(X ; Y) \<equiv> mutual_information b (count_space (X`space M)) (count_space (Y`space M)) X Y"
   412 
   413 lemma (in information_space)
   414   fixes Pxy :: "'b \<times> 'c \<Rightarrow> real" and Px :: "'b \<Rightarrow> real" and Py :: "'c \<Rightarrow> real"
   415   assumes "sigma_finite_measure S" "sigma_finite_measure T"
   416   assumes Px: "distributed M S X Px" and Py: "distributed M T Y Py"
   417   assumes Pxy: "distributed M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x)) Pxy"
   418   defines "f \<equiv> \<lambda>x. Pxy x * log b (Pxy x / (Px (fst x) * Py (snd x)))"
   419   shows mutual_information_distr: "mutual_information b S T X Y = integral\<^isup>L (S \<Otimes>\<^isub>M T) f" (is "?M = ?R")
   420     and mutual_information_nonneg: "integrable (S \<Otimes>\<^isub>M T) f \<Longrightarrow> 0 \<le> mutual_information b S T X Y"
   421 proof -
   422   have X: "random_variable S X"
   423     using Px by (auto simp: distributed_def)
   424   have Y: "random_variable T Y"
   425     using Py by (auto simp: distributed_def)
   426   interpret S: sigma_finite_measure S by fact
   427   interpret T: sigma_finite_measure T by fact
   428   interpret ST: pair_sigma_finite S T ..
   429   interpret X: prob_space "distr M S X" using X by (rule prob_space_distr)
   430   interpret Y: prob_space "distr M T Y" using Y by (rule prob_space_distr)
   431   interpret XY: pair_prob_space "distr M S X" "distr M T Y" ..
   432   let ?P = "S \<Otimes>\<^isub>M T"
   433   let ?D = "distr M ?P (\<lambda>x. (X x, Y x))"
   434 
   435   { fix A assume "A \<in> sets S"
   436     with X Y have "emeasure (distr M S X) A = emeasure ?D (A \<times> space T)"
   437       by (auto simp: emeasure_distr measurable_Pair measurable_space
   438                intro!: arg_cong[where f="emeasure M"]) }
   439   note marginal_eq1 = this
   440   { fix A assume "A \<in> sets T"
   441     with X Y have "emeasure (distr M T Y) A = emeasure ?D (space S \<times> A)"
   442       by (auto simp: emeasure_distr measurable_Pair measurable_space
   443                intro!: arg_cong[where f="emeasure M"]) }
   444   note marginal_eq2 = this
   445 
   446   have eq: "(\<lambda>x. ereal (Px (fst x) * Py (snd x))) = (\<lambda>(x, y). ereal (Px x) * ereal (Py y))"
   447     by auto
   448 
   449   have distr_eq: "distr M S X \<Otimes>\<^isub>M distr M T Y = density ?P (\<lambda>x. ereal (Px (fst x) * Py (snd x)))"
   450     unfolding Px(1)[THEN distributed_distr_eq_density] Py(1)[THEN distributed_distr_eq_density] eq
   451   proof (subst pair_measure_density)
   452     show "(\<lambda>x. ereal (Px x)) \<in> borel_measurable S" "(\<lambda>y. ereal (Py y)) \<in> borel_measurable T"
   453       "AE x in S. 0 \<le> ereal (Px x)" "AE y in T. 0 \<le> ereal (Py y)"
   454       using Px Py by (auto simp: distributed_def)
   455     show "sigma_finite_measure (density S Px)" unfolding Px(1)[THEN distributed_distr_eq_density, symmetric] ..
   456     show "sigma_finite_measure (density T Py)" unfolding Py(1)[THEN distributed_distr_eq_density, symmetric] ..
   457   qed (fact | simp)+
   458   
   459   have M: "?M = KL_divergence b (density ?P (\<lambda>x. ereal (Px (fst x) * Py (snd x)))) (density ?P (\<lambda>x. ereal (Pxy x)))"
   460     unfolding mutual_information_def distr_eq Pxy(1)[THEN distributed_distr_eq_density] ..
   461 
   462   from Px Py have f: "(\<lambda>x. Px (fst x) * Py (snd x)) \<in> borel_measurable ?P"
   463     by (intro borel_measurable_times) (auto intro: distributed_real_measurable measurable_fst'' measurable_snd'')
   464   have PxPy_nonneg: "AE x in ?P. 0 \<le> Px (fst x) * Py (snd x)"
   465   proof (rule ST.AE_pair_measure)
   466     show "{x \<in> space ?P. 0 \<le> Px (fst x) * Py (snd x)} \<in> sets ?P"
   467       using f by auto
   468     show "AE x in S. AE y in T. 0 \<le> Px (fst (x, y)) * Py (snd (x, y))"
   469       using Px Py by (auto simp: zero_le_mult_iff dest!: distributed_real_AE)
   470   qed
   471 
   472   have "(AE x in ?P. Px (fst x) = 0 \<longrightarrow> Pxy x = 0)"
   473     by (rule subdensity_real[OF measurable_fst Pxy Px]) auto
   474   moreover
   475   have "(AE x in ?P. Py (snd x) = 0 \<longrightarrow> Pxy x = 0)"
   476     by (rule subdensity_real[OF measurable_snd Pxy Py]) auto
   477   ultimately have ac: "AE x in ?P. Px (fst x) * Py (snd x) = 0 \<longrightarrow> Pxy x = 0"
   478     by eventually_elim auto
   479 
   480   show "?M = ?R"
   481     unfolding M f_def
   482     using b_gt_1 f PxPy_nonneg Pxy[THEN distributed_real_measurable] Pxy[THEN distributed_real_AE] ac
   483     by (rule ST.KL_density_density)
   484 
   485   assume int: "integrable (S \<Otimes>\<^isub>M T) f"
   486   show "0 \<le> ?M" unfolding M
   487   proof (rule ST.KL_density_density_nonneg
   488     [OF b_gt_1 f PxPy_nonneg _ Pxy[THEN distributed_real_measurable] Pxy[THEN distributed_real_AE] _ ac int[unfolded f_def]])
   489     show "prob_space (density (S \<Otimes>\<^isub>M T) (\<lambda>x. ereal (Pxy x))) "
   490       unfolding distributed_distr_eq_density[OF Pxy, symmetric]
   491       using distributed_measurable[OF Pxy] by (rule prob_space_distr)
   492     show "prob_space (density (S \<Otimes>\<^isub>M T) (\<lambda>x. ereal (Px (fst x) * Py (snd x))))"
   493       unfolding distr_eq[symmetric] by unfold_locales
   494   qed
   495 qed
   496 
   497 lemma (in information_space)
   498   fixes Pxy :: "'b \<times> 'c \<Rightarrow> real" and Px :: "'b \<Rightarrow> real" and Py :: "'c \<Rightarrow> real"
   499   assumes "sigma_finite_measure S" "sigma_finite_measure T"
   500   assumes Px: "distributed M S X Px" and Py: "distributed M T Y Py"
   501   assumes Pxy: "distributed M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x)) Pxy"
   502   assumes ae: "AE x in S. AE y in T. Pxy (x, y) = Px x * Py y"
   503   shows mutual_information_eq_0: "mutual_information b S T X Y = 0"
   504 proof -
   505   interpret S: sigma_finite_measure S by fact
   506   interpret T: sigma_finite_measure T by fact
   507   interpret ST: pair_sigma_finite S T ..
   508 
   509   have "AE x in S \<Otimes>\<^isub>M T. Px (fst x) = 0 \<longrightarrow> Pxy x = 0"
   510     by (rule subdensity_real[OF measurable_fst Pxy Px]) auto
   511   moreover
   512   have "AE x in S \<Otimes>\<^isub>M T. Py (snd x) = 0 \<longrightarrow> Pxy x = 0"
   513     by (rule subdensity_real[OF measurable_snd Pxy Py]) auto
   514   moreover 
   515   have "AE x in S \<Otimes>\<^isub>M T. Pxy x = Px (fst x) * Py (snd x)"
   516     using distributed_real_measurable[OF Px] distributed_real_measurable[OF Py] distributed_real_measurable[OF Pxy]
   517     by (intro ST.AE_pair_measure) (auto simp: ae intro!: measurable_snd'' measurable_fst'')
   518   ultimately have "AE x in S \<Otimes>\<^isub>M T. Pxy x * log b (Pxy x / (Px (fst x) * Py (snd x))) = 0"
   519     by eventually_elim simp
   520   then have "(\<integral>x. Pxy x * log b (Pxy x / (Px (fst x) * Py (snd x))) \<partial>(S \<Otimes>\<^isub>M T)) = (\<integral>x. 0 \<partial>(S \<Otimes>\<^isub>M T))"
   521     by (rule integral_cong_AE)
   522   then show ?thesis
   523     by (subst mutual_information_distr[OF assms(1-5)]) simp
   524 qed
   525 
   526 lemma (in information_space) mutual_information_simple_distributed:
   527   assumes X: "simple_distributed M X Px" and Y: "simple_distributed M Y Py"
   528   assumes XY: "simple_distributed M (\<lambda>x. (X x, Y x)) Pxy"
   529   shows "\<I>(X ; Y) = (\<Sum>(x, y)\<in>(\<lambda>x. (X x, Y x))`space M. Pxy (x, y) * log b (Pxy (x, y) / (Px x * Py y)))"
   530 proof (subst mutual_information_distr[OF _ _ simple_distributed[OF X] simple_distributed[OF Y] simple_distributed_joint[OF XY]])
   531   note fin = simple_distributed_joint_finite[OF XY, simp]
   532   show "sigma_finite_measure (count_space (X ` space M))"
   533     by (simp add: sigma_finite_measure_count_space_finite)
   534   show "sigma_finite_measure (count_space (Y ` space M))"
   535     by (simp add: sigma_finite_measure_count_space_finite)
   536   let ?Pxy = "\<lambda>x. (if x \<in> (\<lambda>x. (X x, Y x)) ` space M then Pxy x else 0)"
   537   let ?f = "\<lambda>x. ?Pxy x * log b (?Pxy x / (Px (fst x) * Py (snd x)))"
   538   have "\<And>x. ?f x = (if x \<in> (\<lambda>x. (X x, Y x)) ` space M then Pxy x * log b (Pxy x / (Px (fst x) * Py (snd x))) else 0)"
   539     by auto
   540   with fin show "(\<integral> x. ?f x \<partial>(count_space (X ` space M) \<Otimes>\<^isub>M count_space (Y ` space M))) =
   541     (\<Sum>(x, y)\<in>(\<lambda>x. (X x, Y x)) ` space M. Pxy (x, y) * log b (Pxy (x, y) / (Px x * Py y)))"
   542     by (auto simp add: pair_measure_count_space lebesgue_integral_count_space_finite setsum_cases split_beta'
   543              intro!: setsum_cong)
   544 qed
   545 
   546 lemma (in information_space)
   547   fixes Pxy :: "'b \<times> 'c \<Rightarrow> real" and Px :: "'b \<Rightarrow> real" and Py :: "'c \<Rightarrow> real"
   548   assumes Px: "simple_distributed M X Px" and Py: "simple_distributed M Y Py"
   549   assumes Pxy: "simple_distributed M (\<lambda>x. (X x, Y x)) Pxy"
   550   assumes ae: "\<forall>x\<in>space M. Pxy (X x, Y x) = Px (X x) * Py (Y x)"
   551   shows mutual_information_eq_0_simple: "\<I>(X ; Y) = 0"
   552 proof (subst mutual_information_simple_distributed[OF Px Py Pxy])
   553   have "(\<Sum>(x, y)\<in>(\<lambda>x. (X x, Y x)) ` space M. Pxy (x, y) * log b (Pxy (x, y) / (Px x * Py y))) =
   554     (\<Sum>(x, y)\<in>(\<lambda>x. (X x, Y x)) ` space M. 0)"
   555     by (intro setsum_cong) (auto simp: ae)
   556   then show "(\<Sum>(x, y)\<in>(\<lambda>x. (X x, Y x)) ` space M.
   557     Pxy (x, y) * log b (Pxy (x, y) / (Px x * Py y))) = 0" by simp
   558 qed
   559 
   560 subsection {* Entropy *}
   561 
   562 definition (in prob_space) entropy :: "real \<Rightarrow> 'b measure \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> real" where
   563   "entropy b S X = - KL_divergence b S (distr M S X)"
   564 
   565 abbreviation (in information_space)
   566   entropy_Pow ("\<H>'(_')") where
   567   "\<H>(X) \<equiv> entropy b (count_space (X`space M)) X"
   568 
   569 lemma (in information_space) entropy_distr:
   570   fixes X :: "'a \<Rightarrow> 'b"
   571   assumes X: "distributed M MX X f"
   572   shows "entropy b MX X = - (\<integral>x. f x * log b (f x) \<partial>MX)"
   573   unfolding entropy_def KL_divergence_def entropy_density_def comp_def
   574 proof (subst integral_cong_AE)
   575   note D = distributed_measurable[OF X] distributed_borel_measurable[OF X] distributed_AE[OF X]
   576   interpret X: prob_space "distr M MX X"
   577     using D(1) by (rule prob_space_distr)
   578 
   579   have sf: "sigma_finite_measure (distr M MX X)" by default
   580   have ae: "AE x in MX. f x = RN_deriv MX (density MX f) x"
   581     using D
   582     by (intro RN_deriv_unique_sigma_finite)
   583        (auto intro: divide_nonneg_nonneg measure_nonneg
   584              simp: distributed_distr_eq_density[symmetric, OF X] sf)
   585   show "AE x in distr M MX X. log b (real (RN_deriv MX (distr M MX X) x)) =
   586     log b (f x)"
   587     unfolding distributed_distr_eq_density[OF X]
   588     apply (subst AE_density)
   589     using D apply simp
   590     using ae apply eventually_elim
   591     apply (subst (asm) eq_commute)
   592     apply auto
   593     done
   594   show "- (\<integral> x. log b (f x) \<partial>distr M MX X) = - (\<integral> x. f x * log b (f x) \<partial>MX)"
   595     unfolding distributed_distr_eq_density[OF X]
   596     using D
   597     by (subst integral_density)
   598        (auto simp: borel_measurable_ereal_iff)
   599 qed 
   600 
   601 lemma (in prob_space) distributed_imp_emeasure_nonzero:
   602   assumes X: "distributed M MX X Px"
   603   shows "emeasure MX {x \<in> space MX. Px x \<noteq> 0} \<noteq> 0"
   604 proof
   605   note Px = distributed_borel_measurable[OF X] distributed_AE[OF X]
   606   interpret X: prob_space "distr M MX X"
   607     using distributed_measurable[OF X] by (rule prob_space_distr)
   608 
   609   assume "emeasure MX {x \<in> space MX. Px x \<noteq> 0} = 0"
   610   with Px have "AE x in MX. Px x = 0"
   611     by (intro AE_I[OF subset_refl]) (auto simp: borel_measurable_ereal_iff)
   612   moreover
   613   from X.emeasure_space_1 have "(\<integral>\<^isup>+x. Px x \<partial>MX) = 1"
   614     unfolding distributed_distr_eq_density[OF X] using Px
   615     by (subst (asm) emeasure_density)
   616        (auto simp: borel_measurable_ereal_iff intro!: integral_cong cong: positive_integral_cong)
   617   ultimately show False
   618     by (simp add: positive_integral_cong_AE)
   619 qed
   620 
   621 lemma (in information_space) entropy_le:
   622   fixes Px :: "'b \<Rightarrow> real" and MX :: "'b measure"
   623   assumes X: "distributed M MX X Px"
   624   and fin: "emeasure MX {x \<in> space MX. Px x \<noteq> 0} \<noteq> \<infinity>"
   625   and int: "integrable MX (\<lambda>x. - Px x * log b (Px x))"
   626   shows "entropy b MX X \<le> log b (measure MX {x \<in> space MX. Px x \<noteq> 0})"
   627 proof -
   628   note Px = distributed_borel_measurable[OF X] distributed_AE[OF X]
   629   interpret X: prob_space "distr M MX X"
   630     using distributed_measurable[OF X] by (rule prob_space_distr)
   631 
   632   have " - log b (measure MX {x \<in> space MX. Px x \<noteq> 0}) = 
   633     - log b (\<integral> x. indicator {x \<in> space MX. Px x \<noteq> 0} x \<partial>MX)"
   634     using Px fin
   635     by (subst integral_indicator) (auto simp: measure_def borel_measurable_ereal_iff)
   636   also have "- log b (\<integral> x. indicator {x \<in> space MX. Px x \<noteq> 0} x \<partial>MX) = - log b (\<integral> x. 1 / Px x \<partial>distr M MX X)"
   637     unfolding distributed_distr_eq_density[OF X] using Px
   638     apply (intro arg_cong[where f="log b"] arg_cong[where f=uminus])
   639     by (subst integral_density) (auto simp: borel_measurable_ereal_iff intro!: integral_cong)
   640   also have "\<dots> \<le> (\<integral> x. - log b (1 / Px x) \<partial>distr M MX X)"
   641   proof (rule X.jensens_inequality[of "\<lambda>x. 1 / Px x" "{0<..}" 0 1 "\<lambda>x. - log b x"])
   642     show "AE x in distr M MX X. 1 / Px x \<in> {0<..}"
   643       unfolding distributed_distr_eq_density[OF X]
   644       using Px by (auto simp: AE_density)
   645     have [simp]: "\<And>x. x \<in> space MX \<Longrightarrow> ereal (if Px x = 0 then 0 else 1) = indicator {x \<in> space MX. Px x \<noteq> 0} x"
   646       by (auto simp: one_ereal_def)
   647     have "(\<integral>\<^isup>+ x. max 0 (ereal (- (if Px x = 0 then 0 else 1))) \<partial>MX) = (\<integral>\<^isup>+ x. 0 \<partial>MX)"
   648       by (intro positive_integral_cong) (auto split: split_max)
   649     then show "integrable (distr M MX X) (\<lambda>x. 1 / Px x)"
   650       unfolding distributed_distr_eq_density[OF X] using Px
   651       by (auto simp: positive_integral_density integrable_def borel_measurable_ereal_iff fin positive_integral_max_0
   652               cong: positive_integral_cong)
   653     have "integrable MX (\<lambda>x. Px x * log b (1 / Px x)) =
   654       integrable MX (\<lambda>x. - Px x * log b (Px x))"
   655       using Px
   656       by (intro integrable_cong_AE)
   657          (auto simp: borel_measurable_ereal_iff log_divide_eq
   658                   intro!: measurable_If)
   659     then show "integrable (distr M MX X) (\<lambda>x. - log b (1 / Px x))"
   660       unfolding distributed_distr_eq_density[OF X]
   661       using Px int
   662       by (subst integral_density) (auto simp: borel_measurable_ereal_iff)
   663   qed (auto simp: minus_log_convex[OF b_gt_1])
   664   also have "\<dots> = (\<integral> x. log b (Px x) \<partial>distr M MX X)"
   665     unfolding distributed_distr_eq_density[OF X] using Px
   666     by (intro integral_cong_AE) (auto simp: AE_density log_divide_eq)
   667   also have "\<dots> = - entropy b MX X"
   668     unfolding distributed_distr_eq_density[OF X] using Px
   669     by (subst entropy_distr[OF X]) (auto simp: borel_measurable_ereal_iff integral_density)
   670   finally show ?thesis
   671     by simp
   672 qed
   673 
   674 lemma (in information_space) entropy_le_space:
   675   fixes Px :: "'b \<Rightarrow> real" and MX :: "'b measure"
   676   assumes X: "distributed M MX X Px"
   677   and fin: "finite_measure MX"
   678   and int: "integrable MX (\<lambda>x. - Px x * log b (Px x))"
   679   shows "entropy b MX X \<le> log b (measure MX (space MX))"
   680 proof -
   681   note Px = distributed_borel_measurable[OF X] distributed_AE[OF X]
   682   interpret finite_measure MX by fact
   683   have "entropy b MX X \<le> log b (measure MX {x \<in> space MX. Px x \<noteq> 0})"
   684     using int X by (intro entropy_le) auto
   685   also have "\<dots> \<le> log b (measure MX (space MX))"
   686     using Px distributed_imp_emeasure_nonzero[OF X]
   687     by (intro log_le)
   688        (auto intro!: borel_measurable_ereal_iff finite_measure_mono b_gt_1
   689                      less_le[THEN iffD2] measure_nonneg simp: emeasure_eq_measure)
   690   finally show ?thesis .
   691 qed
   692 
   693 lemma (in prob_space) uniform_distributed_params:
   694   assumes X: "distributed M MX X (\<lambda>x. indicator A x / measure MX A)"
   695   shows "A \<in> sets MX" "measure MX A \<noteq> 0"
   696 proof -
   697   interpret X: prob_space "distr M MX X"
   698     using distributed_measurable[OF X] by (rule prob_space_distr)
   699 
   700   show "measure MX A \<noteq> 0"
   701   proof
   702     assume "measure MX A = 0"
   703     with X.emeasure_space_1 X.prob_space distributed_distr_eq_density[OF X]
   704     show False
   705       by (simp add: emeasure_density zero_ereal_def[symmetric])
   706   qed
   707   with measure_notin_sets[of A MX] show "A \<in> sets MX"
   708     by blast
   709 qed
   710 
   711 lemma (in information_space) entropy_uniform:
   712   assumes X: "distributed M MX X (\<lambda>x. indicator A x / measure MX A)" (is "distributed _ _ _ ?f")
   713   shows "entropy b MX X = log b (measure MX A)"
   714 proof (subst entropy_distr[OF X])
   715   have [simp]: "emeasure MX A \<noteq> \<infinity>"
   716     using uniform_distributed_params[OF X] by (auto simp add: measure_def)
   717   have eq: "(\<integral> x. indicator A x / measure MX A * log b (indicator A x / measure MX A) \<partial>MX) =
   718     (\<integral> x. (- log b (measure MX A) / measure MX A) * indicator A x \<partial>MX)"
   719     using measure_nonneg[of MX A] uniform_distributed_params[OF X]
   720     by (auto intro!: integral_cong split: split_indicator simp: log_divide_eq)
   721   show "- (\<integral> x. indicator A x / measure MX A * log b (indicator A x / measure MX A) \<partial>MX) =
   722     log b (measure MX A)"
   723     unfolding eq using uniform_distributed_params[OF X]
   724     by (subst lebesgue_integral_cmult) (auto simp: measure_def)
   725 qed
   726 
   727 lemma (in information_space) entropy_simple_distributed:
   728   "simple_distributed M X f \<Longrightarrow> \<H>(X) = - (\<Sum>x\<in>X`space M. f x * log b (f x))"
   729   by (subst entropy_distr[OF simple_distributed])
   730      (auto simp add: lebesgue_integral_count_space_finite)
   731 
   732 lemma (in information_space) entropy_le_card_not_0:
   733   assumes X: "simple_distributed M X f"
   734   shows "\<H>(X) \<le> log b (card (X ` space M \<inter> {x. f x \<noteq> 0}))"
   735 proof -
   736   let ?X = "count_space (X`space M)"
   737   have "\<H>(X) \<le> log b (measure ?X {x \<in> space ?X. f x \<noteq> 0})"
   738     by (rule entropy_le[OF simple_distributed[OF X]])
   739        (simp_all add: simple_distributed_finite[OF X] subset_eq integrable_count_space emeasure_count_space)
   740   also have "measure ?X {x \<in> space ?X. f x \<noteq> 0} = card (X ` space M \<inter> {x. f x \<noteq> 0})"
   741     by (simp_all add: simple_distributed_finite[OF X] subset_eq emeasure_count_space measure_def Int_def)
   742   finally show ?thesis .
   743 qed
   744 
   745 lemma (in information_space) entropy_le_card:
   746   assumes X: "simple_distributed M X f"
   747   shows "\<H>(X) \<le> log b (real (card (X ` space M)))"
   748 proof -
   749   let ?X = "count_space (X`space M)"
   750   have "\<H>(X) \<le> log b (measure ?X (space ?X))"
   751     by (rule entropy_le_space[OF simple_distributed[OF X]])
   752        (simp_all add: simple_distributed_finite[OF X] subset_eq integrable_count_space emeasure_count_space finite_measure_count_space)
   753   also have "measure ?X (space ?X) = card (X ` space M)"
   754     by (simp_all add: simple_distributed_finite[OF X] subset_eq emeasure_count_space measure_def)
   755   finally show ?thesis .
   756 qed
   757 
   758 subsection {* Conditional Mutual Information *}
   759 
   760 definition (in prob_space)
   761   "conditional_mutual_information b MX MY MZ X Y Z \<equiv>
   762     mutual_information b MX (MY \<Otimes>\<^isub>M MZ) X (\<lambda>x. (Y x, Z x)) -
   763     mutual_information b MX MZ X Z"
   764 
   765 abbreviation (in information_space)
   766   conditional_mutual_information_Pow ("\<I>'( _ ; _ | _ ')") where
   767   "\<I>(X ; Y | Z) \<equiv> conditional_mutual_information b
   768     (count_space (X ` space M)) (count_space (Y ` space M)) (count_space (Z ` space M)) X Y Z"
   769 
   770 lemma (in pair_sigma_finite) borel_measurable_positive_integral_fst:
   771   "(\<lambda>(x, y). f x y) \<in> borel_measurable (M1 \<Otimes>\<^isub>M M2) \<Longrightarrow> (\<lambda>x. \<integral>\<^isup>+ y. f x y \<partial>M2) \<in> borel_measurable M1"
   772   using positive_integral_fst_measurable(1)[of "\<lambda>(x, y). f x y"] by simp
   773 
   774 lemma (in pair_sigma_finite) borel_measurable_positive_integral_snd:
   775   assumes "(\<lambda>(x, y). f x y) \<in> borel_measurable (M2 \<Otimes>\<^isub>M M1)" shows "(\<lambda>x. \<integral>\<^isup>+ y. f x y \<partial>M1) \<in> borel_measurable M2"
   776 proof -
   777   interpret Q: pair_sigma_finite M2 M1 by default
   778   from Q.borel_measurable_positive_integral_fst assms show ?thesis by simp
   779 qed
   780 
   781 lemma (in information_space)
   782   assumes S: "sigma_finite_measure S" and T: "sigma_finite_measure T" and P: "sigma_finite_measure P"
   783   assumes Px: "distributed M S X Px"
   784   assumes Pz: "distributed M P Z Pz"
   785   assumes Pyz: "distributed M (T \<Otimes>\<^isub>M P) (\<lambda>x. (Y x, Z x)) Pyz"
   786   assumes Pxz: "distributed M (S \<Otimes>\<^isub>M P) (\<lambda>x. (X x, Z x)) Pxz"
   787   assumes Pxyz: "distributed M (S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P) (\<lambda>x. (X x, Y x, Z x)) Pxyz"
   788   assumes I1: "integrable (S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P) (\<lambda>(x, y, z). Pxyz (x, y, z) * log b (Pxyz (x, y, z) / (Px x * Pyz (y, z))))"
   789   assumes I2: "integrable (S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P) (\<lambda>(x, y, z). Pxyz (x, y, z) * log b (Pxz (x, z) / (Px x * Pz z)))"
   790   shows conditional_mutual_information_generic_eq: "conditional_mutual_information b S T P X Y Z
   791     = (\<integral>(x, y, z). Pxyz (x, y, z) * log b (Pxyz (x, y, z) / (Pxz (x, z) * (Pyz (y,z) / Pz z))) \<partial>(S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P))" (is "?eq")
   792     and conditional_mutual_information_generic_nonneg: "0 \<le> conditional_mutual_information b S T P X Y Z" (is "?nonneg")
   793 proof -
   794   interpret S: sigma_finite_measure S by fact
   795   interpret T: sigma_finite_measure T by fact
   796   interpret P: sigma_finite_measure P by fact
   797   interpret TP: pair_sigma_finite T P ..
   798   interpret SP: pair_sigma_finite S P ..
   799   interpret ST: pair_sigma_finite S T ..
   800   interpret SPT: pair_sigma_finite "S \<Otimes>\<^isub>M P" T ..
   801   interpret STP: pair_sigma_finite S "T \<Otimes>\<^isub>M P" ..
   802   interpret TPS: pair_sigma_finite "T \<Otimes>\<^isub>M P" S ..
   803   have TP: "sigma_finite_measure (T \<Otimes>\<^isub>M P)" ..
   804   have SP: "sigma_finite_measure (S \<Otimes>\<^isub>M P)" ..
   805   have YZ: "random_variable (T \<Otimes>\<^isub>M P) (\<lambda>x. (Y x, Z x))"
   806     using Pyz by (simp add: distributed_measurable)
   807 
   808   have Pxyz_f: "\<And>M f. f \<in> measurable M (S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P) \<Longrightarrow> (\<lambda>x. Pxyz (f x)) \<in> borel_measurable M"
   809     using measurable_comp[OF _ Pxyz[THEN distributed_real_measurable]] by (auto simp: comp_def)
   810 
   811   { fix f g h M
   812     assume f: "f \<in> measurable M S" and g: "g \<in> measurable M P" and h: "h \<in> measurable M (S \<Otimes>\<^isub>M P)"
   813     from measurable_comp[OF h Pxz[THEN distributed_real_measurable]]
   814          measurable_comp[OF f Px[THEN distributed_real_measurable]]
   815          measurable_comp[OF g Pz[THEN distributed_real_measurable]]
   816     have "(\<lambda>x. log b (Pxz (h x) / (Px (f x) * Pz (g x)))) \<in> borel_measurable M"
   817       by (simp add: comp_def b_gt_1) }
   818   note borel_log = this
   819 
   820   have measurable_cut: "(\<lambda>(x, y, z). (x, z)) \<in> measurable (S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P) (S \<Otimes>\<^isub>M P)"
   821     by (auto simp add: split_beta' comp_def intro!: measurable_Pair measurable_snd')
   822   
   823   from Pxz Pxyz have distr_eq: "distr M (S \<Otimes>\<^isub>M P) (\<lambda>x. (X x, Z x)) =
   824     distr (distr M (S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P) (\<lambda>x. (X x, Y x, Z x))) (S \<Otimes>\<^isub>M P) (\<lambda>(x, y, z). (x, z))"
   825     by (subst distr_distr[OF measurable_cut]) (auto dest: distributed_measurable simp: comp_def)
   826 
   827   have "mutual_information b S P X Z =
   828     (\<integral>x. Pxz x * log b (Pxz x / (Px (fst x) * Pz (snd x))) \<partial>(S \<Otimes>\<^isub>M P))"
   829     by (rule mutual_information_distr[OF S P Px Pz Pxz])
   830   also have "\<dots> = (\<integral>(x,y,z). Pxyz (x,y,z) * log b (Pxz (x,z) / (Px x * Pz z)) \<partial>(S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P))"
   831     using b_gt_1 Pxz Px Pz
   832     by (subst distributed_transform_integral[OF Pxyz Pxz, where T="\<lambda>(x, y, z). (x, z)"])
   833        (auto simp: split_beta' intro!: measurable_Pair measurable_snd' measurable_snd'' measurable_fst'' borel_measurable_times
   834              dest!: distributed_real_measurable)
   835   finally have mi_eq:
   836     "mutual_information b S P X Z = (\<integral>(x,y,z). Pxyz (x,y,z) * log b (Pxz (x,z) / (Px x * Pz z)) \<partial>(S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P))" .
   837   
   838   have ae1: "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P. Px (fst x) = 0 \<longrightarrow> Pxyz x = 0"
   839     by (intro subdensity_real[of fst, OF _ Pxyz Px]) auto
   840   moreover have ae2: "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P. Pz (snd (snd x)) = 0 \<longrightarrow> Pxyz x = 0"
   841     by (intro subdensity_real[of "\<lambda>x. snd (snd x)", OF _ Pxyz Pz]) (auto intro: measurable_snd')
   842   moreover have ae3: "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P. Pxz (fst x, snd (snd x)) = 0 \<longrightarrow> Pxyz x = 0"
   843     by (intro subdensity_real[of "\<lambda>x. (fst x, snd (snd x))", OF _ Pxyz Pxz]) (auto intro: measurable_Pair measurable_snd')
   844   moreover have ae4: "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P. Pyz (snd x) = 0 \<longrightarrow> Pxyz x = 0"
   845     by (intro subdensity_real[of snd, OF _ Pxyz Pyz]) (auto intro: measurable_Pair)
   846   moreover have ae5: "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P. 0 \<le> Px (fst x)"
   847     using Px by (intro STP.AE_pair_measure) (auto simp: comp_def intro!: measurable_fst'' dest: distributed_real_AE distributed_real_measurable)
   848   moreover have ae6: "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P. 0 \<le> Pyz (snd x)"
   849     using Pyz by (intro STP.AE_pair_measure) (auto simp: comp_def intro!: measurable_snd'' dest: distributed_real_AE distributed_real_measurable)
   850   moreover have ae7: "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P. 0 \<le> Pz (snd (snd x))"
   851     using Pz Pz[THEN distributed_real_measurable] by (auto intro!: measurable_snd'' TP.AE_pair_measure STP.AE_pair_measure AE_I2[of S] dest: distributed_real_AE)
   852   moreover have ae8: "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P. 0 \<le> Pxz (fst x, snd (snd x))"
   853     using Pxz[THEN distributed_real_AE, THEN SP.AE_pair]
   854     using measurable_comp[OF measurable_Pair[OF measurable_fst measurable_comp[OF measurable_snd measurable_snd]] Pxz[THEN distributed_real_measurable], of T]
   855     using measurable_comp[OF measurable_snd measurable_Pair2[OF Pxz[THEN distributed_real_measurable]], of _ T]
   856     by (auto intro!: TP.AE_pair_measure STP.AE_pair_measure simp: comp_def)
   857   moreover note Pxyz[THEN distributed_real_AE]
   858   ultimately have ae: "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P.
   859     Pxyz x * log b (Pxyz x / (Px (fst x) * Pyz (snd x))) -
   860     Pxyz x * log b (Pxz (fst x, snd (snd x)) / (Px (fst x) * Pz (snd (snd x)))) =
   861     Pxyz x * log b (Pxyz x * Pz (snd (snd x)) / (Pxz (fst x, snd (snd x)) * Pyz (snd x))) "
   862   proof eventually_elim
   863     case (goal1 x)
   864     show ?case
   865     proof cases
   866       assume "Pxyz x \<noteq> 0"
   867       with goal1 have "0 < Px (fst x)" "0 < Pz (snd (snd x))" "0 < Pxz (fst x, snd (snd x))" "0 < Pyz (snd x)" "0 < Pxyz x"
   868         by auto
   869       then show ?thesis
   870         using b_gt_1 by (simp add: log_simps mult_pos_pos less_imp_le field_simps)
   871     qed simp
   872   qed
   873   with I1 I2 show ?eq
   874     unfolding conditional_mutual_information_def
   875     apply (subst mi_eq)
   876     apply (subst mutual_information_distr[OF S TP Px Pyz Pxyz])
   877     apply (subst integral_diff(2)[symmetric])
   878     apply (auto intro!: integral_cong_AE simp: split_beta' simp del: integral_diff)
   879     done
   880 
   881   let ?P = "density (S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P) Pxyz"
   882   interpret P: prob_space ?P
   883     unfolding distributed_distr_eq_density[OF Pxyz, symmetric]
   884     using distributed_measurable[OF Pxyz] by (rule prob_space_distr)
   885 
   886   let ?Q = "density (T \<Otimes>\<^isub>M P) Pyz"
   887   interpret Q: prob_space ?Q
   888     unfolding distributed_distr_eq_density[OF Pyz, symmetric]
   889     using distributed_measurable[OF Pyz] by (rule prob_space_distr)
   890 
   891   let ?f = "\<lambda>(x, y, z). Pxz (x, z) * (Pyz (y, z) / Pz z) / Pxyz (x, y, z)"
   892 
   893   from subdensity_real[of snd, OF _ Pyz Pz]
   894   have aeX1: "AE x in T \<Otimes>\<^isub>M P. Pz (snd x) = 0 \<longrightarrow> Pyz x = 0" by (auto simp: comp_def)
   895   have aeX2: "AE x in T \<Otimes>\<^isub>M P. 0 \<le> Pz (snd x)"
   896     using Pz by (intro TP.AE_pair_measure) (auto simp: comp_def intro!: measurable_snd'' dest: distributed_real_AE distributed_real_measurable)
   897 
   898   have aeX3: "AE y in T \<Otimes>\<^isub>M P. (\<integral>\<^isup>+ x. ereal (Pxz (x, snd y)) \<partial>S) = ereal (Pz (snd y))"
   899     using Pz distributed_marginal_eq_joint[OF P S Px Pz Pxz]
   900     apply (intro TP.AE_pair_measure)
   901     apply (auto simp: comp_def measurable_split_conv
   902                 intro!: measurable_snd'' borel_measurable_ereal_eq borel_measurable_ereal
   903                         SP.borel_measurable_positive_integral_snd measurable_compose[OF _ Pxz[THEN distributed_real_measurable]]
   904                         measurable_Pair
   905                 dest: distributed_real_AE distributed_real_measurable)
   906     done
   907 
   908   note M = borel_measurable_divide borel_measurable_diff borel_measurable_times borel_measurable_ereal
   909            measurable_compose[OF _ measurable_snd]
   910            measurable_Pair
   911            measurable_compose[OF _ Pxyz[THEN distributed_real_measurable]]
   912            measurable_compose[OF _ Pxz[THEN distributed_real_measurable]]
   913            measurable_compose[OF _ Pyz[THEN distributed_real_measurable]]
   914            measurable_compose[OF _ Pz[THEN distributed_real_measurable]]
   915            measurable_compose[OF _ Px[THEN distributed_real_measurable]]
   916            STP.borel_measurable_positive_integral_snd
   917   have "(\<integral>\<^isup>+ x. ?f x \<partial>?P) \<le> (\<integral>\<^isup>+ (x, y, z). Pxz (x, z) * (Pyz (y, z) / Pz z) \<partial>(S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P))"
   918     apply (subst positive_integral_density)
   919     apply (rule distributed_borel_measurable[OF Pxyz])
   920     apply (rule distributed_AE[OF Pxyz])
   921     apply (auto simp add: borel_measurable_ereal_iff split_beta' intro!: M) []
   922     apply (rule positive_integral_mono_AE)
   923     using ae5 ae6 ae7 ae8
   924     apply eventually_elim
   925     apply (auto intro!: divide_nonneg_nonneg mult_nonneg_nonneg)
   926     done
   927   also have "\<dots> = (\<integral>\<^isup>+(y, z). \<integral>\<^isup>+ x. ereal (Pxz (x, z)) * ereal (Pyz (y, z) / Pz z) \<partial>S \<partial>T \<Otimes>\<^isub>M P)"
   928     by (subst STP.positive_integral_snd_measurable[symmetric])
   929        (auto simp add: borel_measurable_ereal_iff split_beta' intro!: M)
   930   also have "\<dots> = (\<integral>\<^isup>+x. ereal (Pyz x) * 1 \<partial>T \<Otimes>\<^isub>M P)"
   931     apply (rule positive_integral_cong_AE)
   932     using aeX1 aeX2 aeX3 distributed_AE[OF Pyz] AE_space
   933     apply eventually_elim
   934   proof (case_tac x, simp del: times_ereal.simps add: space_pair_measure)
   935     fix a b assume "Pz b = 0 \<longrightarrow> Pyz (a, b) = 0" "0 \<le> Pz b" "a \<in> space T \<and> b \<in> space P"
   936       "(\<integral>\<^isup>+ x. ereal (Pxz (x, b)) \<partial>S) = ereal (Pz b)" "0 \<le> Pyz (a, b)" 
   937     then show "(\<integral>\<^isup>+ x. ereal (Pxz (x, b)) * ereal (Pyz (a, b) / Pz b) \<partial>S) = ereal (Pyz (a, b))"
   938       apply (subst positive_integral_multc)
   939       apply (auto intro!: borel_measurable_ereal divide_nonneg_nonneg
   940                           measurable_compose[OF _ Pxz[THEN distributed_real_measurable]] measurable_Pair
   941                   split: prod.split)
   942       done
   943   qed
   944   also have "\<dots> = 1"
   945     using Q.emeasure_space_1 distributed_AE[OF Pyz] distributed_distr_eq_density[OF Pyz]
   946     by (subst positive_integral_density[symmetric]) (auto intro!: M)
   947   finally have le1: "(\<integral>\<^isup>+ x. ?f x \<partial>?P) \<le> 1" .
   948   also have "\<dots> < \<infinity>" by simp
   949   finally have fin: "(\<integral>\<^isup>+ x. ?f x \<partial>?P) \<noteq> \<infinity>" by simp
   950 
   951   have pos: "(\<integral>\<^isup>+ x. ?f x \<partial>?P) \<noteq> 0"
   952     apply (subst positive_integral_density)
   953     apply (rule distributed_borel_measurable[OF Pxyz])
   954     apply (rule distributed_AE[OF Pxyz])
   955     apply (auto simp add: borel_measurable_ereal_iff split_beta' intro!: M) []
   956     apply (simp add: split_beta')
   957   proof
   958     let ?g = "\<lambda>x. ereal (if Pxyz x = 0 then 0 else Pxz (fst x, snd (snd x)) * Pyz (snd x) / Pz (snd (snd x)))"
   959     assume "(\<integral>\<^isup>+ x. ?g x \<partial>(S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P)) = 0"
   960     then have "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P. ?g x \<le> 0"
   961       by (intro positive_integral_0_iff_AE[THEN iffD1]) (auto intro!: M borel_measurable_ereal measurable_If)
   962     then have "AE x in S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P. Pxyz x = 0"
   963       using ae1 ae2 ae3 ae4 ae5 ae6 ae7 ae8 Pxyz[THEN distributed_real_AE]
   964       by eventually_elim (auto split: split_if_asm simp: mult_le_0_iff divide_le_0_iff)
   965     then have "(\<integral>\<^isup>+ x. ereal (Pxyz x) \<partial>S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P) = 0"
   966       by (subst positive_integral_cong_AE[of _ "\<lambda>x. 0"]) auto
   967     with P.emeasure_space_1 show False
   968       by (subst (asm) emeasure_density) (auto intro!: M cong: positive_integral_cong)
   969   qed
   970 
   971   have neg: "(\<integral>\<^isup>+ x. - ?f x \<partial>?P) = 0"
   972     apply (rule positive_integral_0_iff_AE[THEN iffD2])
   973     apply (auto intro!: M simp: split_beta') []
   974     apply (subst AE_density)
   975     apply (auto intro!: M simp: split_beta') []
   976     using ae5 ae6 ae7 ae8
   977     apply eventually_elim
   978     apply (auto intro!: mult_nonneg_nonneg divide_nonneg_nonneg)
   979     done
   980 
   981   have I3: "integrable (S \<Otimes>\<^isub>M T \<Otimes>\<^isub>M P) (\<lambda>(x, y, z). Pxyz (x, y, z) * log b (Pxyz (x, y, z) / (Pxz (x, z) * (Pyz (y,z) / Pz z))))"
   982     apply (rule integrable_cong_AE[THEN iffD1, OF _ _ _ integral_diff(1)[OF I1 I2]])
   983     using ae
   984     apply (auto intro!: M simp: split_beta')
   985     done
   986 
   987   have "- log b 1 \<le> - log b (integral\<^isup>L ?P ?f)"
   988   proof (intro le_imp_neg_le log_le[OF b_gt_1])
   989     show "0 < integral\<^isup>L ?P ?f"
   990       using neg pos fin positive_integral_positive[of ?P ?f]
   991       by (cases "(\<integral>\<^isup>+ x. ?f x \<partial>?P)") (auto simp add: lebesgue_integral_def less_le split_beta')
   992     show "integral\<^isup>L ?P ?f \<le> 1"
   993       using neg le1 fin positive_integral_positive[of ?P ?f]
   994       by (cases "(\<integral>\<^isup>+ x. ?f x \<partial>?P)") (auto simp add: lebesgue_integral_def split_beta' one_ereal_def)
   995   qed
   996   also have "- log b (integral\<^isup>L ?P ?f) \<le> (\<integral> x. - log b (?f x) \<partial>?P)"
   997   proof (rule P.jensens_inequality[where a=0 and b=1 and I="{0<..}"])
   998     show "AE x in ?P. ?f x \<in> {0<..}"
   999       unfolding AE_density[OF distributed_borel_measurable[OF Pxyz]]
  1000       using ae1 ae2 ae3 ae4 ae5 ae6 ae7 ae8 Pxyz[THEN distributed_real_AE]
  1001       by eventually_elim (auto simp: divide_pos_pos mult_pos_pos)
  1002     show "integrable ?P ?f"
  1003       unfolding integrable_def 
  1004       using fin neg by (auto intro!: M simp: split_beta')
  1005     show "integrable ?P (\<lambda>x. - log b (?f x))"
  1006       apply (subst integral_density)
  1007       apply (auto intro!: M) []
  1008       apply (auto intro!: M distributed_real_AE[OF Pxyz]) []
  1009       apply (auto intro!: M borel_measurable_uminus borel_measurable_log simp: split_beta') []
  1010       apply (rule integrable_cong_AE[THEN iffD1, OF _ _ _ I3])
  1011       apply (auto intro!: M borel_measurable_uminus borel_measurable_log simp: split_beta') []
  1012       apply (auto intro!: M borel_measurable_uminus borel_measurable_log simp: split_beta') []
  1013       using ae1 ae2 ae3 ae4 ae5 ae6 ae7 ae8 Pxyz[THEN distributed_real_AE]
  1014       apply eventually_elim
  1015       apply (auto simp: log_divide_eq log_mult_eq zero_le_mult_iff zero_less_mult_iff zero_less_divide_iff field_simps)
  1016       done
  1017   qed (auto simp: b_gt_1 minus_log_convex)
  1018   also have "\<dots> = conditional_mutual_information b S T P X Y Z"
  1019     unfolding `?eq`
  1020     apply (subst integral_density)
  1021     apply (auto intro!: M) []
  1022     apply (auto intro!: M distributed_real_AE[OF Pxyz]) []
  1023     apply (auto intro!: M borel_measurable_uminus borel_measurable_log simp: split_beta') []
  1024     apply (intro integral_cong_AE)
  1025     using ae1 ae2 ae3 ae4 ae5 ae6 ae7 ae8 Pxyz[THEN distributed_real_AE]
  1026     apply eventually_elim
  1027     apply (auto simp: log_divide_eq zero_less_mult_iff zero_less_divide_iff field_simps)
  1028     done
  1029   finally show ?nonneg
  1030     by simp
  1031 qed
  1032 
  1033 lemma (in information_space) conditional_mutual_information_eq:
  1034   assumes Pz: "simple_distributed M Z Pz"
  1035   assumes Pyz: "simple_distributed M (\<lambda>x. (Y x, Z x)) Pyz"
  1036   assumes Pxz: "simple_distributed M (\<lambda>x. (X x, Z x)) Pxz"
  1037   assumes Pxyz: "simple_distributed M (\<lambda>x. (X x, Y x, Z x)) Pxyz"
  1038   shows "\<I>(X ; Y | Z) =
  1039    (\<Sum>(x, y, z)\<in>(\<lambda>x. (X x, Y x, Z x))`space M. Pxyz (x, y, z) * log b (Pxyz (x, y, z) / (Pxz (x, z) * (Pyz (y,z) / Pz z))))"
  1040 proof (subst conditional_mutual_information_generic_eq[OF _ _ _ _
  1041     simple_distributed[OF Pz] simple_distributed_joint[OF Pyz] simple_distributed_joint[OF Pxz]
  1042     simple_distributed_joint2[OF Pxyz]])
  1043   note simple_distributed_joint2_finite[OF Pxyz, simp]
  1044   show "sigma_finite_measure (count_space (X ` space M))"
  1045     by (simp add: sigma_finite_measure_count_space_finite)
  1046   show "sigma_finite_measure (count_space (Y ` space M))"
  1047     by (simp add: sigma_finite_measure_count_space_finite)
  1048   show "sigma_finite_measure (count_space (Z ` space M))"
  1049     by (simp add: sigma_finite_measure_count_space_finite)
  1050   have "count_space (X ` space M) \<Otimes>\<^isub>M count_space (Y ` space M) \<Otimes>\<^isub>M count_space (Z ` space M) =
  1051       count_space (X`space M \<times> Y`space M \<times> Z`space M)"
  1052     (is "?P = ?C")
  1053     by (simp add: pair_measure_count_space)
  1054 
  1055   let ?Px = "\<lambda>x. measure M (X -` {x} \<inter> space M)"
  1056   have "(\<lambda>x. (X x, Z x)) \<in> measurable M (count_space (X ` space M) \<Otimes>\<^isub>M count_space (Z ` space M))"
  1057     using simple_distributed_joint[OF Pxz] by (rule distributed_measurable)
  1058   from measurable_comp[OF this measurable_fst]
  1059   have "random_variable (count_space (X ` space M)) X"
  1060     by (simp add: comp_def)
  1061   then have "simple_function M X"    
  1062     unfolding simple_function_def by auto
  1063   then have "simple_distributed M X ?Px"
  1064     by (rule simple_distributedI) auto
  1065   then show "distributed M (count_space (X ` space M)) X ?Px"
  1066     by (rule simple_distributed)
  1067 
  1068   let ?f = "(\<lambda>x. if x \<in> (\<lambda>x. (X x, Y x, Z x)) ` space M then Pxyz x else 0)"
  1069   let ?g = "(\<lambda>x. if x \<in> (\<lambda>x. (Y x, Z x)) ` space M then Pyz x else 0)"
  1070   let ?h = "(\<lambda>x. if x \<in> (\<lambda>x. (X x, Z x)) ` space M then Pxz x else 0)"
  1071   show
  1072       "integrable ?P (\<lambda>(x, y, z). ?f (x, y, z) * log b (?f (x, y, z) / (?Px x * ?g (y, z))))"
  1073       "integrable ?P (\<lambda>(x, y, z). ?f (x, y, z) * log b (?h (x, z) / (?Px x * Pz z)))"
  1074     by (auto intro!: integrable_count_space simp: pair_measure_count_space)
  1075   let ?i = "\<lambda>x y z. ?f (x, y, z) * log b (?f (x, y, z) / (?h (x, z) * (?g (y, z) / Pz z)))"
  1076   let ?j = "\<lambda>x y z. Pxyz (x, y, z) * log b (Pxyz (x, y, z) / (Pxz (x, z) * (Pyz (y,z) / Pz z)))"
  1077   have "(\<lambda>(x, y, z). ?i x y z) = (\<lambda>x. if x \<in> (\<lambda>x. (X x, Y x, Z x)) ` space M then ?j (fst x) (fst (snd x)) (snd (snd x)) else 0)"
  1078     by (auto intro!: ext)
  1079   then show "(\<integral> (x, y, z). ?i x y z \<partial>?P) = (\<Sum>(x, y, z)\<in>(\<lambda>x. (X x, Y x, Z x)) ` space M. ?j x y z)"
  1080     by (auto intro!: setsum_cong simp add: `?P = ?C` lebesgue_integral_count_space_finite simple_distributed_finite setsum_cases split_beta')
  1081 qed
  1082 
  1083 lemma (in information_space) conditional_mutual_information_nonneg:
  1084   assumes X: "simple_function M X" and Y: "simple_function M Y" and Z: "simple_function M Z"
  1085   shows "0 \<le> \<I>(X ; Y | Z)"
  1086 proof -
  1087   have [simp]: "count_space (X ` space M) \<Otimes>\<^isub>M count_space (Y ` space M) \<Otimes>\<^isub>M count_space (Z ` space M) =
  1088       count_space (X`space M \<times> Y`space M \<times> Z`space M)"
  1089     by (simp add: pair_measure_count_space X Y Z simple_functionD)
  1090   note sf = sigma_finite_measure_count_space_finite[OF simple_functionD(1)]
  1091   note sd = simple_distributedI[OF _ refl]
  1092   note sp = simple_function_Pair
  1093   show ?thesis
  1094    apply (rule conditional_mutual_information_generic_nonneg[OF sf[OF X] sf[OF Y] sf[OF Z]])
  1095    apply (rule simple_distributed[OF sd[OF X]])
  1096    apply (rule simple_distributed[OF sd[OF Z]])
  1097    apply (rule simple_distributed_joint[OF sd[OF sp[OF Y Z]]])
  1098    apply (rule simple_distributed_joint[OF sd[OF sp[OF X Z]]])
  1099    apply (rule simple_distributed_joint2[OF sd[OF sp[OF X sp[OF Y Z]]]])
  1100    apply (auto intro!: integrable_count_space simp: X Y Z simple_functionD)
  1101    done
  1102 qed
  1103 
  1104 subsection {* Conditional Entropy *}
  1105 
  1106 definition (in prob_space)
  1107   "conditional_entropy b S T X Y = entropy b (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x)) - entropy b T Y"
  1108 
  1109 abbreviation (in information_space)
  1110   conditional_entropy_Pow ("\<H>'(_ | _')") where
  1111   "\<H>(X | Y) \<equiv> conditional_entropy b (count_space (X`space M)) (count_space (Y`space M)) X Y"
  1112 
  1113 lemma (in information_space) conditional_entropy_generic_eq:
  1114   fixes Px :: "'b \<Rightarrow> real" and Py :: "'c \<Rightarrow> real"
  1115   assumes S: "sigma_finite_measure S" and T: "sigma_finite_measure T"
  1116   assumes Px: "distributed M S X Px"
  1117   assumes Py: "distributed M T Y Py"
  1118   assumes Pxy: "distributed M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x)) Pxy"
  1119   assumes I1: "integrable (S \<Otimes>\<^isub>M T) (\<lambda>x. Pxy x * log b (Pxy x))"
  1120   assumes I2: "integrable (S \<Otimes>\<^isub>M T) (\<lambda>x. Pxy x * log b (Py (snd x)))"
  1121   shows "conditional_entropy b S T X Y = - (\<integral>(x, y). Pxy (x, y) * log b (Pxy (x, y) / Py y) \<partial>(S \<Otimes>\<^isub>M T))"
  1122 proof -
  1123   interpret S: sigma_finite_measure S by fact
  1124   interpret T: sigma_finite_measure T by fact
  1125   interpret ST: pair_sigma_finite S T ..
  1126   have ST: "sigma_finite_measure (S \<Otimes>\<^isub>M T)" ..
  1127 
  1128   interpret Pxy: prob_space "density (S \<Otimes>\<^isub>M T) Pxy"
  1129     unfolding Pxy[THEN distributed_distr_eq_density, symmetric]
  1130     using Pxy[THEN distributed_measurable] by (rule prob_space_distr)
  1131 
  1132   from Py Pxy have distr_eq: "distr M T Y =
  1133     distr (distr M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))) T snd"
  1134     by (subst distr_distr[OF measurable_snd]) (auto dest: distributed_measurable simp: comp_def)
  1135 
  1136   have "entropy b T Y = - (\<integral>y. Py y * log b (Py y) \<partial>T)"
  1137     by (rule entropy_distr[OF Py])
  1138   also have "\<dots> = - (\<integral>(x,y). Pxy (x,y) * log b (Py y) \<partial>(S \<Otimes>\<^isub>M T))"
  1139     using b_gt_1 Py[THEN distributed_real_measurable]
  1140     by (subst distributed_transform_integral[OF Pxy Py, where T=snd]) (auto intro!: integral_cong)
  1141   finally have e_eq: "entropy b T Y = - (\<integral>(x,y). Pxy (x,y) * log b (Py y) \<partial>(S \<Otimes>\<^isub>M T))" .
  1142   
  1143   have "AE x in S \<Otimes>\<^isub>M T. Px (fst x) = 0 \<longrightarrow> Pxy x = 0"
  1144     by (intro subdensity_real[of fst, OF _ Pxy Px]) (auto intro: measurable_Pair)
  1145   moreover have "AE x in S \<Otimes>\<^isub>M T. Py (snd x) = 0 \<longrightarrow> Pxy x = 0"
  1146     by (intro subdensity_real[of snd, OF _ Pxy Py]) (auto intro: measurable_Pair)
  1147   moreover have "AE x in S \<Otimes>\<^isub>M T. 0 \<le> Px (fst x)"
  1148     using Px by (intro ST.AE_pair_measure) (auto simp: comp_def intro!: measurable_fst'' dest: distributed_real_AE distributed_real_measurable)
  1149   moreover have "AE x in S \<Otimes>\<^isub>M T. 0 \<le> Py (snd x)"
  1150     using Py by (intro ST.AE_pair_measure) (auto simp: comp_def intro!: measurable_snd'' dest: distributed_real_AE distributed_real_measurable)
  1151   moreover note Pxy[THEN distributed_real_AE]
  1152   ultimately have pos: "AE x in S \<Otimes>\<^isub>M T. 0 \<le> Pxy x \<and> 0 \<le> Px (fst x) \<and> 0 \<le> Py (snd x) \<and>
  1153     (Pxy x = 0 \<or> (Pxy x \<noteq> 0 \<longrightarrow> 0 < Pxy x \<and> 0 < Px (fst x) \<and> 0 < Py (snd x)))"
  1154     by eventually_elim auto
  1155 
  1156   from pos have "AE x in S \<Otimes>\<^isub>M T.
  1157      Pxy x * log b (Pxy x) - Pxy x * log b (Py (snd x)) = Pxy x * log b (Pxy x / Py (snd x))"
  1158     by eventually_elim (auto simp: log_simps mult_pos_pos field_simps b_gt_1)
  1159   with I1 I2 show ?thesis
  1160     unfolding conditional_entropy_def
  1161     apply (subst e_eq)
  1162     apply (subst entropy_distr[OF Pxy])
  1163     unfolding minus_diff_minus
  1164     apply (subst integral_diff(2)[symmetric])
  1165     apply (auto intro!: integral_cong_AE simp: split_beta' simp del: integral_diff)
  1166     done
  1167 qed
  1168 
  1169 lemma (in information_space) conditional_entropy_eq:
  1170   assumes Y: "simple_distributed M Y Py" and X: "simple_function M X"
  1171   assumes XY: "simple_distributed M (\<lambda>x. (X x, Y x)) Pxy"
  1172     shows "\<H>(X | Y) = - (\<Sum>(x, y)\<in>(\<lambda>x. (X x, Y x)) ` space M. Pxy (x, y) * log b (Pxy (x, y) / Py y))"
  1173 proof (subst conditional_entropy_generic_eq[OF _ _
  1174   simple_distributed[OF simple_distributedI[OF X refl]] simple_distributed[OF Y] simple_distributed_joint[OF XY]])
  1175   have [simp]: "finite (X`space M)" using X by (simp add: simple_function_def)
  1176   note Y[THEN simple_distributed_finite, simp]
  1177   show "sigma_finite_measure (count_space (X ` space M))"
  1178     by (simp add: sigma_finite_measure_count_space_finite)
  1179   show "sigma_finite_measure (count_space (Y ` space M))"
  1180     by (simp add: sigma_finite_measure_count_space_finite)
  1181   let ?f = "(\<lambda>x. if x \<in> (\<lambda>x. (X x, Y x)) ` space M then Pxy x else 0)"
  1182   have "count_space (X ` space M) \<Otimes>\<^isub>M count_space (Y ` space M) = count_space (X`space M \<times> Y`space M)"
  1183     (is "?P = ?C")
  1184     using X Y by (simp add: simple_distributed_finite pair_measure_count_space)
  1185   with X Y show
  1186       "integrable ?P (\<lambda>x. ?f x * log b (?f x))"
  1187       "integrable ?P (\<lambda>x. ?f x * log b (Py (snd x)))"
  1188     by (auto intro!: integrable_count_space simp: simple_distributed_finite)
  1189   have eq: "(\<lambda>(x, y). ?f (x, y) * log b (?f (x, y) / Py y)) =
  1190     (\<lambda>x. if x \<in> (\<lambda>x. (X x, Y x)) ` space M then Pxy x * log b (Pxy x / Py (snd x)) else 0)"
  1191     by auto
  1192   from X Y show "- (\<integral> (x, y). ?f (x, y) * log b (?f (x, y) / Py y) \<partial>?P) =
  1193     - (\<Sum>(x, y)\<in>(\<lambda>x. (X x, Y x)) ` space M. Pxy (x, y) * log b (Pxy (x, y) / Py y))"
  1194     by (auto intro!: setsum_cong simp add: `?P = ?C` lebesgue_integral_count_space_finite simple_distributed_finite eq setsum_cases split_beta')
  1195 qed
  1196 
  1197 lemma (in information_space) conditional_mutual_information_eq_conditional_entropy:
  1198   assumes X: "simple_function M X" and Y: "simple_function M Y"
  1199   shows "\<I>(X ; X | Y) = \<H>(X | Y)"
  1200 proof -
  1201   def Py \<equiv> "\<lambda>x. if x \<in> Y`space M then measure M (Y -` {x} \<inter> space M) else 0"
  1202   def Pxy \<equiv> "\<lambda>x. if x \<in> (\<lambda>x. (X x, Y x))`space M then measure M ((\<lambda>x. (X x, Y x)) -` {x} \<inter> space M) else 0"
  1203   def Pxxy \<equiv> "\<lambda>x. if x \<in> (\<lambda>x. (X x, X x, Y x))`space M then measure M ((\<lambda>x. (X x, X x, Y x)) -` {x} \<inter> space M) else 0"
  1204   let ?M = "X`space M \<times> X`space M \<times> Y`space M"
  1205 
  1206   note XY = simple_function_Pair[OF X Y]
  1207   note XXY = simple_function_Pair[OF X XY]
  1208   have Py: "simple_distributed M Y Py"
  1209     using Y by (rule simple_distributedI) (auto simp: Py_def)
  1210   have Pxy: "simple_distributed M (\<lambda>x. (X x, Y x)) Pxy"
  1211     using XY by (rule simple_distributedI) (auto simp: Pxy_def)
  1212   have Pxxy: "simple_distributed M (\<lambda>x. (X x, X x, Y x)) Pxxy"
  1213     using XXY by (rule simple_distributedI) (auto simp: Pxxy_def)
  1214   have eq: "(\<lambda>x. (X x, X x, Y x)) ` space M = (\<lambda>(x, y). (x, x, y)) ` (\<lambda>x. (X x, Y x)) ` space M"
  1215     by auto
  1216   have inj: "\<And>A. inj_on (\<lambda>(x, y). (x, x, y)) A"
  1217     by (auto simp: inj_on_def)
  1218   have Pxxy_eq: "\<And>x y. Pxxy (x, x, y) = Pxy (x, y)"
  1219     by (auto simp: Pxxy_def Pxy_def intro!: arg_cong[where f=prob])
  1220   have "AE x in count_space ((\<lambda>x. (X x, Y x))`space M). Py (snd x) = 0 \<longrightarrow> Pxy x = 0"
  1221     by (intro subdensity_real[of snd, OF _ Pxy[THEN simple_distributed] Py[THEN simple_distributed]]) (auto intro: measurable_Pair)
  1222   then show ?thesis
  1223     apply (subst conditional_mutual_information_eq[OF Py Pxy Pxy Pxxy])
  1224     apply (subst conditional_entropy_eq[OF Py X Pxy])
  1225     apply (auto intro!: setsum_cong simp: Pxxy_eq setsum_negf[symmetric] eq setsum_reindex[OF inj]
  1226                 log_simps zero_less_mult_iff zero_le_mult_iff field_simps mult_less_0_iff AE_count_space)
  1227     using Py[THEN simple_distributed, THEN distributed_real_AE] Pxy[THEN simple_distributed, THEN distributed_real_AE]
  1228     apply (auto simp add: not_le[symmetric] AE_count_space)
  1229     done
  1230 qed
  1231 
  1232 lemma (in information_space) conditional_entropy_nonneg:
  1233   assumes X: "simple_function M X" and Y: "simple_function M Y" shows "0 \<le> \<H>(X | Y)"
  1234   using conditional_mutual_information_eq_conditional_entropy[OF X Y] conditional_mutual_information_nonneg[OF X X Y]
  1235   by simp
  1236 
  1237 subsection {* Equalities *}
  1238 
  1239 lemma (in information_space) mutual_information_eq_entropy_conditional_entropy_distr:
  1240   fixes Px :: "'b \<Rightarrow> real" and Py :: "'c \<Rightarrow> real" and Pxy :: "('b \<times> 'c) \<Rightarrow> real"
  1241   assumes S: "sigma_finite_measure S" and T: "sigma_finite_measure T"
  1242   assumes Px: "distributed M S X Px" and Py: "distributed M T Y Py"
  1243   assumes Pxy: "distributed M (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x)) Pxy"
  1244   assumes Ix: "integrable(S \<Otimes>\<^isub>M T) (\<lambda>x. Pxy x * log b (Px (fst x)))"
  1245   assumes Iy: "integrable(S \<Otimes>\<^isub>M T) (\<lambda>x. Pxy x * log b (Py (snd x)))"
  1246   assumes Ixy: "integrable(S \<Otimes>\<^isub>M T) (\<lambda>x. Pxy x * log b (Pxy x))"
  1247   shows  "mutual_information b S T X Y = entropy b S X + entropy b T Y - entropy b (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x))"
  1248 proof -
  1249   have X: "entropy b S X = - (\<integral>x. Pxy x * log b (Px (fst x)) \<partial>(S \<Otimes>\<^isub>M T))"
  1250     using b_gt_1 Px[THEN distributed_real_measurable]
  1251     apply (subst entropy_distr[OF Px])
  1252     apply (subst distributed_transform_integral[OF Pxy Px, where T=fst])
  1253     apply (auto intro!: integral_cong)
  1254     done
  1255 
  1256   have Y: "entropy b T Y = - (\<integral>x. Pxy x * log b (Py (snd x)) \<partial>(S \<Otimes>\<^isub>M T))"
  1257     using b_gt_1 Py[THEN distributed_real_measurable]
  1258     apply (subst entropy_distr[OF Py])
  1259     apply (subst distributed_transform_integral[OF Pxy Py, where T=snd])
  1260     apply (auto intro!: integral_cong)
  1261     done
  1262 
  1263   interpret S: sigma_finite_measure S by fact
  1264   interpret T: sigma_finite_measure T by fact
  1265   interpret ST: pair_sigma_finite S T ..
  1266   have ST: "sigma_finite_measure (S \<Otimes>\<^isub>M T)" ..
  1267 
  1268   have XY: "entropy b (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x)) = - (\<integral>x. Pxy x * log b (Pxy x) \<partial>(S \<Otimes>\<^isub>M T))"
  1269     by (subst entropy_distr[OF Pxy]) (auto intro!: integral_cong)
  1270   
  1271   have "AE x in S \<Otimes>\<^isub>M T. Px (fst x) = 0 \<longrightarrow> Pxy x = 0"
  1272     by (intro subdensity_real[of fst, OF _ Pxy Px]) (auto intro: measurable_Pair)
  1273   moreover have "AE x in S \<Otimes>\<^isub>M T. Py (snd x) = 0 \<longrightarrow> Pxy x = 0"
  1274     by (intro subdensity_real[of snd, OF _ Pxy Py]) (auto intro: measurable_Pair)
  1275   moreover have "AE x in S \<Otimes>\<^isub>M T. 0 \<le> Px (fst x)"
  1276     using Px by (intro ST.AE_pair_measure) (auto simp: comp_def intro!: measurable_fst'' dest: distributed_real_AE distributed_real_measurable)
  1277   moreover have "AE x in S \<Otimes>\<^isub>M T. 0 \<le> Py (snd x)"
  1278     using Py by (intro ST.AE_pair_measure) (auto simp: comp_def intro!: measurable_snd'' dest: distributed_real_AE distributed_real_measurable)
  1279   moreover note Pxy[THEN distributed_real_AE]
  1280   ultimately have "AE x in S \<Otimes>\<^isub>M T. Pxy x * log b (Pxy x) - Pxy x * log b (Px (fst x)) - Pxy x * log b (Py (snd x)) = 
  1281     Pxy x * log b (Pxy x / (Px (fst x) * Py (snd x)))"
  1282     (is "AE x in _. ?f x = ?g x")
  1283   proof eventually_elim
  1284     case (goal1 x)
  1285     show ?case
  1286     proof cases
  1287       assume "Pxy x \<noteq> 0"
  1288       with goal1 have "0 < Px (fst x)" "0 < Py (snd x)" "0 < Pxy x"
  1289         by auto
  1290       then show ?thesis
  1291         using b_gt_1 by (simp add: log_simps mult_pos_pos less_imp_le field_simps)
  1292     qed simp
  1293   qed
  1294 
  1295   have "entropy b S X + entropy b T Y - entropy b (S \<Otimes>\<^isub>M T) (\<lambda>x. (X x, Y x)) = integral\<^isup>L (S \<Otimes>\<^isub>M T) ?f"
  1296     unfolding X Y XY
  1297     apply (subst integral_diff)
  1298     apply (intro integral_diff Ixy Ix Iy)+
  1299     apply (subst integral_diff)
  1300     apply (intro integral_diff Ixy Ix Iy)+
  1301     apply (simp add: field_simps)
  1302     done
  1303   also have "\<dots> = integral\<^isup>L (S \<Otimes>\<^isub>M T) ?g"
  1304     using `AE x in _. ?f x = ?g x` by (rule integral_cong_AE)
  1305   also have "\<dots> = mutual_information b S T X Y"
  1306     by (rule mutual_information_distr[OF S T Px Py Pxy, symmetric])
  1307   finally show ?thesis ..
  1308 qed
  1309 
  1310 lemma (in information_space) mutual_information_eq_entropy_conditional_entropy:
  1311   assumes sf_X: "simple_function M X" and sf_Y: "simple_function M Y"
  1312   shows  "\<I>(X ; Y) = \<H>(X) - \<H>(X | Y)"
  1313 proof -
  1314   have X: "simple_distributed M X (\<lambda>x. measure M (X -` {x} \<inter> space M))"
  1315     using sf_X by (rule simple_distributedI) auto
  1316   have Y: "simple_distributed M Y (\<lambda>x. measure M (Y -` {x} \<inter> space M))"
  1317     using sf_Y by (rule simple_distributedI) auto
  1318   have sf_XY: "simple_function M (\<lambda>x. (X x, Y x))"
  1319     using sf_X sf_Y by (rule simple_function_Pair)
  1320   then have XY: "simple_distributed M (\<lambda>x. (X x, Y x)) (\<lambda>x. measure M ((\<lambda>x. (X x, Y x)) -` {x} \<inter> space M))"
  1321     by (rule simple_distributedI) auto
  1322   from simple_distributed_joint_finite[OF this, simp]
  1323   have eq: "count_space (X ` space M) \<Otimes>\<^isub>M count_space (Y ` space M) = count_space (X ` space M \<times> Y ` space M)"
  1324     by (simp add: pair_measure_count_space)
  1325 
  1326   have "\<I>(X ; Y) = \<H>(X) + \<H>(Y) - entropy b (count_space (X`space M) \<Otimes>\<^isub>M count_space (Y`space M)) (\<lambda>x. (X x, Y x))"
  1327     using sigma_finite_measure_count_space_finite sigma_finite_measure_count_space_finite simple_distributed[OF X] simple_distributed[OF Y] simple_distributed_joint[OF XY]
  1328     by (rule mutual_information_eq_entropy_conditional_entropy_distr) (auto simp: eq integrable_count_space)
  1329   then show ?thesis
  1330     unfolding conditional_entropy_def by simp
  1331 qed
  1332 
  1333 lemma (in information_space) mutual_information_nonneg_simple:
  1334   assumes sf_X: "simple_function M X" and sf_Y: "simple_function M Y"
  1335   shows  "0 \<le> \<I>(X ; Y)"
  1336 proof -
  1337   have X: "simple_distributed M X (\<lambda>x. measure M (X -` {x} \<inter> space M))"
  1338     using sf_X by (rule simple_distributedI) auto
  1339   have Y: "simple_distributed M Y (\<lambda>x. measure M (Y -` {x} \<inter> space M))"
  1340     using sf_Y by (rule simple_distributedI) auto
  1341 
  1342   have sf_XY: "simple_function M (\<lambda>x. (X x, Y x))"
  1343     using sf_X sf_Y by (rule simple_function_Pair)
  1344   then have XY: "simple_distributed M (\<lambda>x. (X x, Y x)) (\<lambda>x. measure M ((\<lambda>x. (X x, Y x)) -` {x} \<inter> space M))"
  1345     by (rule simple_distributedI) auto
  1346 
  1347   from simple_distributed_joint_finite[OF this, simp]
  1348   have eq: "count_space (X ` space M) \<Otimes>\<^isub>M count_space (Y ` space M) = count_space (X ` space M \<times> Y ` space M)"
  1349     by (simp add: pair_measure_count_space)
  1350 
  1351   show ?thesis
  1352     by (rule mutual_information_nonneg[OF _ _ simple_distributed[OF X] simple_distributed[OF Y] simple_distributed_joint[OF XY]])
  1353        (simp_all add: eq integrable_count_space sigma_finite_measure_count_space_finite)
  1354 qed
  1355 
  1356 lemma (in information_space) conditional_entropy_less_eq_entropy:
  1357   assumes X: "simple_function M X" and Z: "simple_function M Z"
  1358   shows "\<H>(X | Z) \<le> \<H>(X)"
  1359 proof -
  1360   have "0 \<le> \<I>(X ; Z)" using X Z by (rule mutual_information_nonneg_simple)
  1361   also have "\<I>(X ; Z) = \<H>(X) - \<H>(X | Z)" using mutual_information_eq_entropy_conditional_entropy[OF assms] .
  1362   finally show ?thesis by auto
  1363 qed
  1364 
  1365 lemma (in information_space) entropy_chain_rule:
  1366   assumes X: "simple_function M X" and Y: "simple_function M Y"
  1367   shows  "\<H>(\<lambda>x. (X x, Y x)) = \<H>(X) + \<H>(Y|X)"
  1368 proof -
  1369   note XY = simple_distributedI[OF simple_function_Pair[OF X Y] refl]
  1370   note YX = simple_distributedI[OF simple_function_Pair[OF Y X] refl]
  1371   note simple_distributed_joint_finite[OF this, simp]
  1372   let ?f = "\<lambda>x. prob ((\<lambda>x. (X x, Y x)) -` {x} \<inter> space M)"
  1373   let ?g = "\<lambda>x. prob ((\<lambda>x. (Y x, X x)) -` {x} \<inter> space M)"
  1374   let ?h = "\<lambda>x. if x \<in> (\<lambda>x. (Y x, X x)) ` space M then prob ((\<lambda>x. (Y x, X x)) -` {x} \<inter> space M) else 0"
  1375   have "\<H>(\<lambda>x. (X x, Y x)) = - (\<Sum>x\<in>(\<lambda>x. (X x, Y x)) ` space M. ?f x * log b (?f x))"
  1376     using XY by (rule entropy_simple_distributed)
  1377   also have "\<dots> = - (\<Sum>x\<in>(\<lambda>(x, y). (y, x)) ` (\<lambda>x. (X x, Y x)) ` space M. ?g x * log b (?g x))"
  1378     by (subst (2) setsum_reindex) (auto simp: inj_on_def intro!: setsum_cong arg_cong[where f="\<lambda>A. prob A * log b (prob A)"])
  1379   also have "\<dots> = - (\<Sum>x\<in>(\<lambda>x. (Y x, X x)) ` space M. ?h x * log b (?h x))"
  1380     by (auto intro!: setsum_cong)
  1381   also have "\<dots> = entropy b (count_space (Y ` space M) \<Otimes>\<^isub>M count_space (X ` space M)) (\<lambda>x. (Y x, X x))"
  1382     by (subst entropy_distr[OF simple_distributed_joint[OF YX]])
  1383        (auto simp: pair_measure_count_space sigma_finite_measure_count_space_finite lebesgue_integral_count_space_finite
  1384              cong del: setsum_cong  intro!: setsum_mono_zero_left)
  1385   finally have "\<H>(\<lambda>x. (X x, Y x)) = entropy b (count_space (Y ` space M) \<Otimes>\<^isub>M count_space (X ` space M)) (\<lambda>x. (Y x, X x))" .
  1386   then show ?thesis
  1387     unfolding conditional_entropy_def by simp
  1388 qed
  1389 
  1390 lemma (in information_space) entropy_partition:
  1391   assumes X: "simple_function M X"
  1392   shows "\<H>(X) = \<H>(f \<circ> X) + \<H>(X|f \<circ> X)"
  1393 proof -
  1394   note fX = simple_function_compose[OF X, of f]  
  1395   have eq: "(\<lambda>x. ((f \<circ> X) x, X x)) ` space M = (\<lambda>x. (f x, x)) ` X ` space M" by auto
  1396   have inj: "\<And>A. inj_on (\<lambda>x. (f x, x)) A"
  1397     by (auto simp: inj_on_def)
  1398   show ?thesis
  1399     apply (subst entropy_chain_rule[symmetric, OF fX X])
  1400     apply (subst entropy_simple_distributed[OF simple_distributedI[OF simple_function_Pair[OF fX X] refl]])
  1401     apply (subst entropy_simple_distributed[OF simple_distributedI[OF X refl]])
  1402     unfolding eq
  1403     apply (subst setsum_reindex[OF inj])
  1404     apply (auto intro!: setsum_cong arg_cong[where f="\<lambda>A. prob A * log b (prob A)"])
  1405     done
  1406 qed
  1407 
  1408 corollary (in information_space) entropy_data_processing:
  1409   assumes X: "simple_function M X" shows "\<H>(f \<circ> X) \<le> \<H>(X)"
  1410 proof -
  1411   note fX = simple_function_compose[OF X, of f]
  1412   from X have "\<H>(X) = \<H>(f\<circ>X) + \<H>(X|f\<circ>X)" by (rule entropy_partition)
  1413   then show "\<H>(f \<circ> X) \<le> \<H>(X)"
  1414     by (auto intro: conditional_entropy_nonneg[OF X fX])
  1415 qed
  1416 
  1417 corollary (in information_space) entropy_of_inj:
  1418   assumes X: "simple_function M X" and inj: "inj_on f (X`space M)"
  1419   shows "\<H>(f \<circ> X) = \<H>(X)"
  1420 proof (rule antisym)
  1421   show "\<H>(f \<circ> X) \<le> \<H>(X)" using entropy_data_processing[OF X] .
  1422 next
  1423   have sf: "simple_function M (f \<circ> X)"
  1424     using X by auto
  1425   have "\<H>(X) = \<H>(the_inv_into (X`space M) f \<circ> (f \<circ> X))"
  1426     unfolding o_assoc
  1427     apply (subst entropy_simple_distributed[OF simple_distributedI[OF X refl]])
  1428     apply (subst entropy_simple_distributed[OF simple_distributedI[OF simple_function_compose[OF X]], where f="\<lambda>x. prob (X -` {x} \<inter> space M)"])
  1429     apply (auto intro!: setsum_cong arg_cong[where f=prob] image_eqI simp: the_inv_into_f_f[OF inj] comp_def)
  1430     done
  1431   also have "... \<le> \<H>(f \<circ> X)"
  1432     using entropy_data_processing[OF sf] .
  1433   finally show "\<H>(X) \<le> \<H>(f \<circ> X)" .
  1434 qed
  1435 
  1436 end