src/HOL/Set.thy
author haftmann
Thu Mar 05 08:23:11 2009 +0100 (2009-03-05)
changeset 30304 d8e4cd2ac2a1
parent 29901 f4b3f8fbf599
child 30352 047f183c43b0
permissions -rw-r--r--
set operations Int, Un, INTER, UNION, Inter, Union, empty, UNIV are now proper qualified constants with authentic syntax
     1 (*  Title:      HOL/Set.thy
     2     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     3 *)
     4 
     5 header {* Set theory for higher-order logic *}
     6 
     7 theory Set
     8 imports Lattices
     9 begin
    10 
    11 text {* A set in HOL is simply a predicate. *}
    12 
    13 
    14 subsection {* Basic syntax *}
    15 
    16 global
    17 
    18 types 'a set = "'a => bool"
    19 
    20 consts
    21   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    22   "op :"        :: "'a => 'a set => bool"                -- "membership"
    23   insert        :: "'a => 'a set => 'a set"
    24   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    25   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    26   Bex1          :: "'a set => ('a => bool) => bool"      -- "bounded unique existential quantifiers"
    27   Pow           :: "'a set => 'a set set"                -- "powerset"
    28   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    29 
    30 local
    31 
    32 notation
    33   "op :"  ("op :") and
    34   "op :"  ("(_/ : _)" [50, 51] 50)
    35 
    36 abbreviation
    37   "not_mem x A == ~ (x : A)" -- "non-membership"
    38 
    39 notation
    40   not_mem  ("op ~:") and
    41   not_mem  ("(_/ ~: _)" [50, 51] 50)
    42 
    43 notation (xsymbols)
    44   "op :"  ("op \<in>") and
    45   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    46   not_mem  ("op \<notin>") and
    47   not_mem  ("(_/ \<notin> _)" [50, 51] 50)
    48 
    49 notation (HTML output)
    50   "op :"  ("op \<in>") and
    51   "op :"  ("(_/ \<in> _)" [50, 51] 50) and
    52   not_mem  ("op \<notin>") and
    53   not_mem  ("(_/ \<notin> _)" [50, 51] 50)
    54 
    55 syntax
    56   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    57 
    58 translations
    59   "{x. P}"      == "Collect (%x. P)"
    60 
    61 definition empty :: "'a set" ("{}") where
    62   "empty \<equiv> {x. False}"
    63 
    64 definition UNIV :: "'a set" where
    65   "UNIV \<equiv> {x. True}"
    66 
    67 syntax
    68   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    69 
    70 translations
    71   "{x, xs}"     == "insert x {xs}"
    72   "{x}"         == "insert x {}"
    73 
    74 definition Int :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Int" 70) where
    75   "A Int B \<equiv> {x. x \<in> A \<and> x \<in> B}"
    76 
    77 definition Un :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "Un" 65) where
    78   "A Un B \<equiv> {x. x \<in> A \<or> x \<in> B}"
    79 
    80 notation (xsymbols)
    81   "Int"  (infixl "\<inter>" 70) and
    82   "Un"  (infixl "\<union>" 65)
    83 
    84 notation (HTML output)
    85   "Int"  (infixl "\<inter>" 70) and
    86   "Un"  (infixl "\<union>" 65)
    87 
    88 syntax
    89   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    90   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    91   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3EX! _:_./ _)" [0, 0, 10] 10)
    92   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST _:_./ _)" [0, 0, 10] 10)
    93 
    94 syntax (HOL)
    95   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    96   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    97   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3?! _:_./ _)" [0, 0, 10] 10)
    98 
    99 syntax (xsymbols)
   100   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   101   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   102   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   103   "_Bleast"     :: "id => 'a set => bool => 'a"           ("(3LEAST_\<in>_./ _)" [0, 0, 10] 10)
   104 
   105 syntax (HTML output)
   106   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   107   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   108   "_Bex1"       :: "pttrn => 'a set => bool => bool"      ("(3\<exists>!_\<in>_./ _)" [0, 0, 10] 10)
   109 
   110 translations
   111   "ALL x:A. P"  == "Ball A (%x. P)"
   112   "EX x:A. P"   == "Bex A (%x. P)"
   113   "EX! x:A. P"  == "Bex1 A (%x. P)"
   114   "LEAST x:A. P" => "LEAST x. x:A & P"
   115 
   116 definition INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   117   "INTER A B \<equiv> {y. \<forall>x\<in>A. y \<in> B x}"
   118 
   119 definition UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   120   "UNION A B \<equiv> {y. \<exists>x\<in>A. y \<in> B x}"
   121 
   122 definition Inter :: "'a set set \<Rightarrow> 'a set" where
   123   "Inter S \<equiv> INTER S (\<lambda>x. x)"
   124 
   125 definition Union :: "'a set set \<Rightarrow> 'a set" where
   126   "Union S \<equiv> UNION S (\<lambda>x. x)"
   127 
   128 notation (xsymbols)
   129   Inter  ("\<Inter>_" [90] 90) and
   130   Union  ("\<Union>_" [90] 90)
   131 
   132 
   133 subsection {* Additional concrete syntax *}
   134 
   135 syntax
   136   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
   137   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ :/ _./ _})")
   138   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   139   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   140   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 10] 10)
   141   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 10] 10)
   142 
   143 syntax (xsymbols)
   144   "@Collect"    :: "idt => 'a set => bool => 'a set"      ("(1{_ \<in>/ _./ _})")
   145   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   146   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   147   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 10] 10)
   148   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 10] 10)
   149 
   150 syntax (latex output)
   151   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   152   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   153   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   154   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 10] 10)
   155 
   156 translations
   157   "{x:A. P}"    => "{x. x:A & P}"
   158   "INT x y. B"  == "INT x. INT y. B"
   159   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   160   "INT x. B"    == "INT x:CONST UNIV. B"
   161   "INT x:A. B"  == "CONST INTER A (%x. B)"
   162   "UN x y. B"   == "UN x. UN y. B"
   163   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   164   "UN x. B"     == "UN x:CONST UNIV. B"
   165   "UN x:A. B"   == "CONST UNION A (%x. B)"
   166 
   167 text {*
   168   Note the difference between ordinary xsymbol syntax of indexed
   169   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   170   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   171   former does not make the index expression a subscript of the
   172   union/intersection symbol because this leads to problems with nested
   173   subscripts in Proof General.
   174 *}
   175 
   176 abbreviation
   177   subset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   178   "subset \<equiv> less"
   179 
   180 abbreviation
   181   subset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   182   "subset_eq \<equiv> less_eq"
   183 
   184 notation (output)
   185   subset  ("op <") and
   186   subset  ("(_/ < _)" [50, 51] 50) and
   187   subset_eq  ("op <=") and
   188   subset_eq  ("(_/ <= _)" [50, 51] 50)
   189 
   190 notation (xsymbols)
   191   subset  ("op \<subset>") and
   192   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   193   subset_eq  ("op \<subseteq>") and
   194   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   195 
   196 notation (HTML output)
   197   subset  ("op \<subset>") and
   198   subset  ("(_/ \<subset> _)" [50, 51] 50) and
   199   subset_eq  ("op \<subseteq>") and
   200   subset_eq  ("(_/ \<subseteq> _)" [50, 51] 50)
   201 
   202 abbreviation (input)
   203   supset :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   204   "supset \<equiv> greater"
   205 
   206 abbreviation (input)
   207   supset_eq :: "'a set \<Rightarrow> 'a set \<Rightarrow> bool" where
   208   "supset_eq \<equiv> greater_eq"
   209 
   210 notation (xsymbols)
   211   supset  ("op \<supset>") and
   212   supset  ("(_/ \<supset> _)" [50, 51] 50) and
   213   supset_eq  ("op \<supseteq>") and
   214   supset_eq  ("(_/ \<supseteq> _)" [50, 51] 50)
   215 
   216 abbreviation
   217   range :: "('a => 'b) => 'b set" where -- "of function"
   218   "range f == f ` UNIV"
   219 
   220 
   221 subsubsection "Bounded quantifiers"
   222 
   223 syntax (output)
   224   "_setlessAll" :: "[idt, 'a, bool] => bool"  ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   225   "_setlessEx"  :: "[idt, 'a, bool] => bool"  ("(3EX _<_./ _)"  [0, 0, 10] 10)
   226   "_setleAll"   :: "[idt, 'a, bool] => bool"  ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   227   "_setleEx"    :: "[idt, 'a, bool] => bool"  ("(3EX _<=_./ _)" [0, 0, 10] 10)
   228   "_setleEx1"   :: "[idt, 'a, bool] => bool"  ("(3EX! _<=_./ _)" [0, 0, 10] 10)
   229 
   230 syntax (xsymbols)
   231   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   232   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   233   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   234   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   235   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   236 
   237 syntax (HOL output)
   238   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3! _<_./ _)"  [0, 0, 10] 10)
   239   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3? _<_./ _)"  [0, 0, 10] 10)
   240   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3! _<=_./ _)" [0, 0, 10] 10)
   241   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3? _<=_./ _)" [0, 0, 10] 10)
   242   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3?! _<=_./ _)" [0, 0, 10] 10)
   243 
   244 syntax (HTML output)
   245   "_setlessAll" :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subset>_./ _)"  [0, 0, 10] 10)
   246   "_setlessEx"  :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subset>_./ _)"  [0, 0, 10] 10)
   247   "_setleAll"   :: "[idt, 'a, bool] => bool"   ("(3\<forall>_\<subseteq>_./ _)" [0, 0, 10] 10)
   248   "_setleEx"    :: "[idt, 'a, bool] => bool"   ("(3\<exists>_\<subseteq>_./ _)" [0, 0, 10] 10)
   249   "_setleEx1"   :: "[idt, 'a, bool] => bool"   ("(3\<exists>!_\<subseteq>_./ _)" [0, 0, 10] 10)
   250 
   251 translations
   252  "\<forall>A\<subset>B. P"   =>  "ALL A. A \<subset> B --> P"
   253  "\<exists>A\<subset>B. P"   =>  "EX A. A \<subset> B & P"
   254  "\<forall>A\<subseteq>B. P"   =>  "ALL A. A \<subseteq> B --> P"
   255  "\<exists>A\<subseteq>B. P"   =>  "EX A. A \<subseteq> B & P"
   256  "\<exists>!A\<subseteq>B. P"  =>  "EX! A. A \<subseteq> B & P"
   257 
   258 print_translation {*
   259 let
   260   val Type (set_type, _) = @{typ "'a set"};
   261   val All_binder = Syntax.binder_name @{const_syntax "All"};
   262   val Ex_binder = Syntax.binder_name @{const_syntax "Ex"};
   263   val impl = @{const_syntax "op -->"};
   264   val conj = @{const_syntax "op &"};
   265   val sbset = @{const_syntax "subset"};
   266   val sbset_eq = @{const_syntax "subset_eq"};
   267 
   268   val trans =
   269    [((All_binder, impl, sbset), "_setlessAll"),
   270     ((All_binder, impl, sbset_eq), "_setleAll"),
   271     ((Ex_binder, conj, sbset), "_setlessEx"),
   272     ((Ex_binder, conj, sbset_eq), "_setleEx")];
   273 
   274   fun mk v v' c n P =
   275     if v = v' andalso not (Term.exists_subterm (fn Free (x, _) => x = v | _ => false) n)
   276     then Syntax.const c $ Syntax.mark_bound v' $ n $ P else raise Match;
   277 
   278   fun tr' q = (q,
   279     fn [Const ("_bound", _) $ Free (v, Type (T, _)), Const (c, _) $ (Const (d, _) $ (Const ("_bound", _) $ Free (v', _)) $ n) $ P] =>
   280          if T = (set_type) then case AList.lookup (op =) trans (q, c, d)
   281           of NONE => raise Match
   282            | SOME l => mk v v' l n P
   283          else raise Match
   284      | _ => raise Match);
   285 in
   286   [tr' All_binder, tr' Ex_binder]
   287 end
   288 *}
   289 
   290 
   291 text {*
   292   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   293   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   294   only translated if @{text "[0..n] subset bvs(e)"}.
   295 *}
   296 
   297 parse_translation {*
   298   let
   299     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   300 
   301     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   302       | nvars _ = 1;
   303 
   304     fun setcompr_tr [e, idts, b] =
   305       let
   306         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   307         val P = Syntax.const "op &" $ eq $ b;
   308         val exP = ex_tr [idts, P];
   309       in Syntax.const "Collect" $ Term.absdummy (dummyT, exP) end;
   310 
   311   in [("@SetCompr", setcompr_tr)] end;
   312 *}
   313 
   314 (* To avoid eta-contraction of body: *)
   315 print_translation {*
   316 let
   317   fun btr' syn [A, Abs abs] =
   318     let val (x, t) = atomic_abs_tr' abs
   319     in Syntax.const syn $ x $ A $ t end
   320 in
   321 [(@{const_syntax Ball}, btr' "_Ball"), (@{const_syntax Bex}, btr' "_Bex"),
   322  (@{const_syntax UNION}, btr' "@UNION"),(@{const_syntax INTER}, btr' "@INTER")]
   323 end
   324 *}
   325 
   326 print_translation {*
   327 let
   328   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   329 
   330   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   331     let
   332       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   333         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   334             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   335             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   336         | check _ = false
   337 
   338         fun tr' (_ $ abs) =
   339           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   340           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   341     in if check (P, 0) then tr' P
   342        else let val (x as _ $ Free(xN,_), t) = atomic_abs_tr' abs
   343                 val M = Syntax.const "@Coll" $ x $ t
   344             in case t of
   345                  Const("op &",_)
   346                    $ (Const("op :",_) $ (Const("_bound",_) $ Free(yN,_)) $ A)
   347                    $ P =>
   348                    if xN=yN then Syntax.const "@Collect" $ x $ A $ P else M
   349                | _ => M
   350             end
   351     end;
   352   in [("Collect", setcompr_tr')] end;
   353 *}
   354 
   355 
   356 subsection {* Rules and definitions *}
   357 
   358 text {* Isomorphisms between predicates and sets. *}
   359 
   360 defs
   361   mem_def [code]: "x : S == S x"
   362   Collect_def [code]: "Collect P == P"
   363 
   364 defs
   365   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   366   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   367   Bex1_def:     "Bex1 A P       == EX! x. x:A & P(x)"
   368 
   369 instantiation "fun" :: (type, minus) minus
   370 begin
   371 
   372 definition
   373   fun_diff_def: "A - B = (%x. A x - B x)"
   374 
   375 instance ..
   376 
   377 end
   378 
   379 instantiation bool :: minus
   380 begin
   381 
   382 definition
   383   bool_diff_def: "A - B = (A & ~ B)"
   384 
   385 instance ..
   386 
   387 end
   388 
   389 instantiation "fun" :: (type, uminus) uminus
   390 begin
   391 
   392 definition
   393   fun_Compl_def: "- A = (%x. - A x)"
   394 
   395 instance ..
   396 
   397 end
   398 
   399 instantiation bool :: uminus
   400 begin
   401 
   402 definition
   403   bool_Compl_def: "- A = (~ A)"
   404 
   405 instance ..
   406 
   407 end
   408 
   409 defs
   410   Pow_def:      "Pow A          == {B. B <= A}"
   411   insert_def:   "insert a B     == {x. x=a} Un B"
   412   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   413 
   414 
   415 subsection {* Lemmas and proof tool setup *}
   416 
   417 subsubsection {* Relating predicates and sets *}
   418 
   419 lemma mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
   420   by (simp add: Collect_def mem_def)
   421 
   422 lemma Collect_mem_eq [simp]: "{x. x:A} = A"
   423   by (simp add: Collect_def mem_def)
   424 
   425 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   426   by simp
   427 
   428 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   429   by simp
   430 
   431 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   432   by simp
   433 
   434 lemmas CollectE = CollectD [elim_format]
   435 
   436 
   437 subsubsection {* Bounded quantifiers *}
   438 
   439 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   440   by (simp add: Ball_def)
   441 
   442 lemmas strip = impI allI ballI
   443 
   444 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   445   by (simp add: Ball_def)
   446 
   447 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   448   by (unfold Ball_def) blast
   449 
   450 ML {* bind_thm ("rev_ballE", permute_prems 1 1 @{thm ballE}) *}
   451 
   452 text {*
   453   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   454   @{prop "a:A"}; creates assumption @{prop "P a"}.
   455 *}
   456 
   457 ML {*
   458   fun ball_tac i = etac @{thm ballE} i THEN contr_tac (i + 1)
   459 *}
   460 
   461 text {*
   462   Gives better instantiation for bound:
   463 *}
   464 
   465 declaration {* fn _ =>
   466   Classical.map_cs (fn cs => cs addbefore ("bspec", datac @{thm bspec} 1))
   467 *}
   468 
   469 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   470   -- {* Normally the best argument order: @{prop "P x"} constrains the
   471     choice of @{prop "x:A"}. *}
   472   by (unfold Bex_def) blast
   473 
   474 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   475   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   476   by (unfold Bex_def) blast
   477 
   478 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   479   by (unfold Bex_def) blast
   480 
   481 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   482   by (unfold Bex_def) blast
   483 
   484 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   485   -- {* Trival rewrite rule. *}
   486   by (simp add: Ball_def)
   487 
   488 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   489   -- {* Dual form for existentials. *}
   490   by (simp add: Bex_def)
   491 
   492 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   493   by blast
   494 
   495 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   496   by blast
   497 
   498 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   499   by blast
   500 
   501 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   502   by blast
   503 
   504 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   505   by blast
   506 
   507 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   508   by blast
   509 
   510 ML {*
   511   local
   512     val unfold_bex_tac = unfold_tac @{thms "Bex_def"};
   513     fun prove_bex_tac ss = unfold_bex_tac ss THEN Quantifier1.prove_one_point_ex_tac;
   514     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   515 
   516     val unfold_ball_tac = unfold_tac @{thms "Ball_def"};
   517     fun prove_ball_tac ss = unfold_ball_tac ss THEN Quantifier1.prove_one_point_all_tac;
   518     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   519   in
   520     val defBEX_regroup = Simplifier.simproc (the_context ())
   521       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   522     val defBALL_regroup = Simplifier.simproc (the_context ())
   523       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   524   end;
   525 
   526   Addsimprocs [defBALL_regroup, defBEX_regroup];
   527 *}
   528 
   529 
   530 subsubsection {* Congruence rules *}
   531 
   532 lemma ball_cong:
   533   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   534     (ALL x:A. P x) = (ALL x:B. Q x)"
   535   by (simp add: Ball_def)
   536 
   537 lemma strong_ball_cong [cong]:
   538   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   539     (ALL x:A. P x) = (ALL x:B. Q x)"
   540   by (simp add: simp_implies_def Ball_def)
   541 
   542 lemma bex_cong:
   543   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   544     (EX x:A. P x) = (EX x:B. Q x)"
   545   by (simp add: Bex_def cong: conj_cong)
   546 
   547 lemma strong_bex_cong [cong]:
   548   "A = B ==> (!!x. x:B =simp=> P x = Q x) ==>
   549     (EX x:A. P x) = (EX x:B. Q x)"
   550   by (simp add: simp_implies_def Bex_def cong: conj_cong)
   551 
   552 
   553 subsubsection {* Subsets *}
   554 
   555 lemma subsetI [atp,intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   556   by (auto simp add: mem_def intro: predicate1I)
   557 
   558 text {*
   559   \medskip Map the type @{text "'a set => anything"} to just @{typ
   560   'a}; for overloading constants whose first argument has type @{typ
   561   "'a set"}.
   562 *}
   563 
   564 lemma subsetD [elim]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   565   -- {* Rule in Modus Ponens style. *}
   566   by (unfold mem_def) blast
   567 
   568 declare subsetD [intro?] -- FIXME
   569 
   570 lemma rev_subsetD: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   571   -- {* The same, with reversed premises for use with @{text erule} --
   572       cf @{text rev_mp}. *}
   573   by (rule subsetD)
   574 
   575 declare rev_subsetD [intro?] -- FIXME
   576 
   577 text {*
   578   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   579 *}
   580 
   581 ML {*
   582   fun impOfSubs th = th RSN (2, @{thm rev_subsetD})
   583 *}
   584 
   585 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   586   -- {* Classical elimination rule. *}
   587   by (unfold mem_def) blast
   588 
   589 lemma subset_eq: "A \<le> B = (\<forall>x\<in>A. x \<in> B)" by blast
   590 
   591 text {*
   592   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   593   creates the assumption @{prop "c \<in> B"}.
   594 *}
   595 
   596 ML {*
   597   fun set_mp_tac i = etac @{thm subsetCE} i THEN mp_tac i
   598 *}
   599 
   600 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   601   by blast
   602 
   603 lemma subset_refl [simp,atp]: "A \<subseteq> A"
   604   by fast
   605 
   606 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   607   by blast
   608 
   609 
   610 subsubsection {* Equality *}
   611 
   612 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   613   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   614    apply (rule Collect_mem_eq)
   615   apply (rule Collect_mem_eq)
   616   done
   617 
   618 (* Due to Brian Huffman *)
   619 lemma expand_set_eq: "(A = B) = (ALL x. (x:A) = (x:B))"
   620 by(auto intro:set_ext)
   621 
   622 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   623   -- {* Anti-symmetry of the subset relation. *}
   624   by (iprover intro: set_ext subsetD)
   625 
   626 lemmas equalityI [intro!] = subset_antisym
   627 
   628 text {*
   629   \medskip Equality rules from ZF set theory -- are they appropriate
   630   here?
   631 *}
   632 
   633 lemma equalityD1: "A = B ==> A \<subseteq> B"
   634   by (simp add: subset_refl)
   635 
   636 lemma equalityD2: "A = B ==> B \<subseteq> A"
   637   by (simp add: subset_refl)
   638 
   639 text {*
   640   \medskip Be careful when adding this to the claset as @{text
   641   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   642   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   643 *}
   644 
   645 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   646   by (simp add: subset_refl)
   647 
   648 lemma equalityCE [elim]:
   649     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   650   by blast
   651 
   652 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   653   by simp
   654 
   655 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   656   by simp
   657 
   658 
   659 subsubsection {* The universal set -- UNIV *}
   660 
   661 lemma UNIV_I [simp]: "x : UNIV"
   662   by (simp add: UNIV_def)
   663 
   664 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   665 
   666 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   667   by simp
   668 
   669 lemma subset_UNIV [simp]: "A \<subseteq> UNIV"
   670   by (rule subsetI) (rule UNIV_I)
   671 
   672 text {*
   673   \medskip Eta-contracting these two rules (to remove @{text P})
   674   causes them to be ignored because of their interaction with
   675   congruence rules.
   676 *}
   677 
   678 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   679   by (simp add: Ball_def)
   680 
   681 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   682   by (simp add: Bex_def)
   683 
   684 lemma UNIV_eq_I: "(\<And>x. x \<in> A) \<Longrightarrow> UNIV = A"
   685   by auto
   686 
   687 
   688 subsubsection {* The empty set *}
   689 
   690 lemma empty_iff [simp]: "(c : {}) = False"
   691   by (simp add: empty_def)
   692 
   693 lemma emptyE [elim!]: "a : {} ==> P"
   694   by simp
   695 
   696 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   697     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   698   by blast
   699 
   700 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   701   by blast
   702 
   703 lemma equals0D: "A = {} ==> a \<notin> A"
   704     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   705   by blast
   706 
   707 lemma ball_empty [simp]: "Ball {} P = True"
   708   by (simp add: Ball_def)
   709 
   710 lemma bex_empty [simp]: "Bex {} P = False"
   711   by (simp add: Bex_def)
   712 
   713 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   714   by (blast elim: equalityE)
   715 
   716 
   717 subsubsection {* The Powerset operator -- Pow *}
   718 
   719 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   720   by (simp add: Pow_def)
   721 
   722 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   723   by (simp add: Pow_def)
   724 
   725 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   726   by (simp add: Pow_def)
   727 
   728 lemma Pow_bottom: "{} \<in> Pow B"
   729   by simp
   730 
   731 lemma Pow_top: "A \<in> Pow A"
   732   by (simp add: subset_refl)
   733 
   734 
   735 subsubsection {* Set complement *}
   736 
   737 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   738   by (simp add: mem_def fun_Compl_def bool_Compl_def)
   739 
   740 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   741   by (unfold mem_def fun_Compl_def bool_Compl_def) blast
   742 
   743 text {*
   744   \medskip This form, with negated conclusion, works well with the
   745   Classical prover.  Negated assumptions behave like formulae on the
   746   right side of the notional turnstile ... *}
   747 
   748 lemma ComplD [dest!]: "c : -A ==> c~:A"
   749   by (simp add: mem_def fun_Compl_def bool_Compl_def)
   750 
   751 lemmas ComplE = ComplD [elim_format]
   752 
   753 lemma Compl_eq: "- A = {x. ~ x : A}" by blast
   754 
   755 
   756 subsubsection {* Binary union -- Un *}
   757 
   758 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   759   by (unfold Un_def) blast
   760 
   761 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   762   by simp
   763 
   764 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   765   by simp
   766 
   767 text {*
   768   \medskip Classical introduction rule: no commitment to @{prop A} vs
   769   @{prop B}.
   770 *}
   771 
   772 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   773   by auto
   774 
   775 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   776   by (unfold Un_def) blast
   777 
   778 
   779 subsubsection {* Binary intersection -- Int *}
   780 
   781 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   782   by (unfold Int_def) blast
   783 
   784 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   785   by simp
   786 
   787 lemma IntD1: "c : A Int B ==> c:A"
   788   by simp
   789 
   790 lemma IntD2: "c : A Int B ==> c:B"
   791   by simp
   792 
   793 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   794   by simp
   795 
   796 
   797 subsubsection {* Set difference *}
   798 
   799 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   800   by (simp add: mem_def fun_diff_def bool_diff_def)
   801 
   802 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   803   by simp
   804 
   805 lemma DiffD1: "c : A - B ==> c : A"
   806   by simp
   807 
   808 lemma DiffD2: "c : A - B ==> c : B ==> P"
   809   by simp
   810 
   811 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   812   by simp
   813 
   814 lemma set_diff_eq: "A - B = {x. x : A & ~ x : B}" by blast
   815 
   816 lemma Compl_eq_Diff_UNIV: "-A = (UNIV - A)"
   817 by blast
   818 
   819 
   820 subsubsection {* Augmenting a set -- insert *}
   821 
   822 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   823   by (unfold insert_def) blast
   824 
   825 lemma insertI1: "a : insert a B"
   826   by simp
   827 
   828 lemma insertI2: "a : B ==> a : insert b B"
   829   by simp
   830 
   831 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   832   by (unfold insert_def) blast
   833 
   834 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   835   -- {* Classical introduction rule. *}
   836   by auto
   837 
   838 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   839   by auto
   840 
   841 lemma set_insert:
   842   assumes "x \<in> A"
   843   obtains B where "A = insert x B" and "x \<notin> B"
   844 proof
   845   from assms show "A = insert x (A - {x})" by blast
   846 next
   847   show "x \<notin> A - {x}" by blast
   848 qed
   849 
   850 lemma insert_ident: "x ~: A ==> x ~: B ==> (insert x A = insert x B) = (A = B)"
   851 by auto
   852 
   853 subsubsection {* Singletons, using insert *}
   854 
   855 lemma singletonI [intro!,noatp]: "a : {a}"
   856     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   857   by (rule insertI1)
   858 
   859 lemma singletonD [dest!,noatp]: "b : {a} ==> b = a"
   860   by blast
   861 
   862 lemmas singletonE = singletonD [elim_format]
   863 
   864 lemma singleton_iff: "(b : {a}) = (b = a)"
   865   by blast
   866 
   867 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   868   by blast
   869 
   870 lemma singleton_insert_inj_eq [iff,noatp]:
   871      "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   872   by blast
   873 
   874 lemma singleton_insert_inj_eq' [iff,noatp]:
   875      "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   876   by blast
   877 
   878 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   879   by fast
   880 
   881 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   882   by blast
   883 
   884 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   885   by blast
   886 
   887 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   888   by blast
   889 
   890 lemma doubleton_eq_iff: "({a,b} = {c,d}) = (a=c & b=d | a=d & b=c)"
   891   by (blast elim: equalityE)
   892 
   893 
   894 subsubsection {* Unions of families *}
   895 
   896 text {*
   897   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   898 *}
   899 
   900 declare UNION_def [noatp]
   901 
   902 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   903   by (unfold UNION_def) blast
   904 
   905 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   906   -- {* The order of the premises presupposes that @{term A} is rigid;
   907     @{term b} may be flexible. *}
   908   by auto
   909 
   910 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   911   by (unfold UNION_def) blast
   912 
   913 lemma UN_cong [cong]:
   914     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   915   by (simp add: UNION_def)
   916 
   917 lemma strong_UN_cong:
   918     "A = B ==> (!!x. x:B =simp=> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   919   by (simp add: UNION_def simp_implies_def)
   920 
   921 
   922 subsubsection {* Intersections of families *}
   923 
   924 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   925 
   926 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   927   by (unfold INTER_def) blast
   928 
   929 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   930   by (unfold INTER_def) blast
   931 
   932 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   933   by auto
   934 
   935 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   936   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   937   by (unfold INTER_def) blast
   938 
   939 lemma INT_cong [cong]:
   940     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   941   by (simp add: INTER_def)
   942 
   943 
   944 subsubsection {* Union *}
   945 
   946 lemma Union_iff [simp,noatp]: "(A : Union C) = (EX X:C. A:X)"
   947   by (unfold Union_def) blast
   948 
   949 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   950   -- {* The order of the premises presupposes that @{term C} is rigid;
   951     @{term A} may be flexible. *}
   952   by auto
   953 
   954 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   955   by (unfold Union_def) blast
   956 
   957 
   958 subsubsection {* Inter *}
   959 
   960 lemma Inter_iff [simp,noatp]: "(A : Inter C) = (ALL X:C. A:X)"
   961   by (unfold Inter_def) blast
   962 
   963 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   964   by (simp add: Inter_def)
   965 
   966 text {*
   967   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   968   contains @{term A} as an element, but @{prop "A:X"} can hold when
   969   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   970 *}
   971 
   972 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   973   by auto
   974 
   975 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   976   -- {* ``Classical'' elimination rule -- does not require proving
   977     @{prop "X:C"}. *}
   978   by (unfold Inter_def) blast
   979 
   980 text {*
   981   \medskip Image of a set under a function.  Frequently @{term b} does
   982   not have the syntactic form of @{term "f x"}.
   983 *}
   984 
   985 declare image_def [noatp]
   986 
   987 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   988   by (unfold image_def) blast
   989 
   990 lemma imageI: "x : A ==> f x : f ` A"
   991   by (rule image_eqI) (rule refl)
   992 
   993 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   994   -- {* This version's more effective when we already have the
   995     required @{term x}. *}
   996   by (unfold image_def) blast
   997 
   998 lemma imageE [elim!]:
   999   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
  1000   -- {* The eta-expansion gives variable-name preservation. *}
  1001   by (unfold image_def) blast
  1002 
  1003 lemma image_Un: "f`(A Un B) = f`A Un f`B"
  1004   by blast
  1005 
  1006 lemma image_eq_UN: "f`A = (UN x:A. {f x})"
  1007   by blast
  1008 
  1009 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
  1010   by blast
  1011 
  1012 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
  1013   -- {* This rewrite rule would confuse users if made default. *}
  1014   by blast
  1015 
  1016 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
  1017   apply safe
  1018    prefer 2 apply fast
  1019   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
  1020   done
  1021 
  1022 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
  1023   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
  1024     @{text hypsubst}, but breaks too many existing proofs. *}
  1025   by blast
  1026 
  1027 text {*
  1028   \medskip Range of a function -- just a translation for image!
  1029 *}
  1030 
  1031 lemma range_eqI: "b = f x ==> b \<in> range f"
  1032   by simp
  1033 
  1034 lemma rangeI: "f x \<in> range f"
  1035   by simp
  1036 
  1037 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
  1038   by blast
  1039 
  1040 
  1041 subsubsection {* Set reasoning tools *}
  1042 
  1043 text {*
  1044   Rewrite rules for boolean case-splitting: faster than @{text
  1045   "split_if [split]"}.
  1046 *}
  1047 
  1048 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
  1049   by (rule split_if)
  1050 
  1051 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
  1052   by (rule split_if)
  1053 
  1054 text {*
  1055   Split ifs on either side of the membership relation.  Not for @{text
  1056   "[simp]"} -- can cause goals to blow up!
  1057 *}
  1058 
  1059 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
  1060   by (rule split_if)
  1061 
  1062 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
  1063   by (rule split_if [where P="%S. a : S"])
  1064 
  1065 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
  1066 
  1067 lemmas mem_simps =
  1068   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
  1069   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
  1070   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
  1071 
  1072 (*Would like to add these, but the existing code only searches for the
  1073   outer-level constant, which in this case is just "op :"; we instead need
  1074   to use term-nets to associate patterns with rules.  Also, if a rule fails to
  1075   apply, then the formula should be kept.
  1076   [("HOL.uminus", Compl_iff RS iffD1), ("HOL.minus", [Diff_iff RS iffD1]),
  1077    ("Int", [IntD1,IntD2]),
  1078    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
  1079  *)
  1080 
  1081 ML {*
  1082   val mksimps_pairs = [(@{const_name Ball}, @{thms bspec})] @ mksimps_pairs;
  1083 *}
  1084 declaration {* fn _ =>
  1085   Simplifier.map_ss (fn ss => ss setmksimps (mksimps mksimps_pairs))
  1086 *}
  1087 
  1088 
  1089 subsubsection {* The ``proper subset'' relation *}
  1090 
  1091 lemma psubsetI [intro!,noatp]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
  1092   by (unfold less_le) blast
  1093 
  1094 lemma psubsetE [elim!,noatp]: 
  1095     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
  1096   by (unfold less_le) blast
  1097 
  1098 lemma psubset_insert_iff:
  1099   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
  1100   by (auto simp add: less_le subset_insert_iff)
  1101 
  1102 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
  1103   by (simp only: less_le)
  1104 
  1105 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
  1106   by (simp add: psubset_eq)
  1107 
  1108 lemma psubset_trans: "[| A \<subset> B; B \<subset> C |] ==> A \<subset> C"
  1109 apply (unfold less_le)
  1110 apply (auto dest: subset_antisym)
  1111 done
  1112 
  1113 lemma psubsetD: "[| A \<subset> B; c \<in> A |] ==> c \<in> B"
  1114 apply (unfold less_le)
  1115 apply (auto dest: subsetD)
  1116 done
  1117 
  1118 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
  1119   by (auto simp add: psubset_eq)
  1120 
  1121 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
  1122   by (auto simp add: psubset_eq)
  1123 
  1124 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
  1125   by (unfold less_le) blast
  1126 
  1127 lemma atomize_ball:
  1128     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
  1129   by (simp only: Ball_def atomize_all atomize_imp)
  1130 
  1131 lemmas [symmetric, rulify] = atomize_ball
  1132   and [symmetric, defn] = atomize_ball
  1133 
  1134 
  1135 subsection {* Further set-theory lemmas *}
  1136 
  1137 subsubsection {* Derived rules involving subsets. *}
  1138 
  1139 text {* @{text insert}. *}
  1140 
  1141 lemma subset_insertI: "B \<subseteq> insert a B"
  1142   by (rule subsetI) (erule insertI2)
  1143 
  1144 lemma subset_insertI2: "A \<subseteq> B \<Longrightarrow> A \<subseteq> insert b B"
  1145   by blast
  1146 
  1147 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
  1148   by blast
  1149 
  1150 
  1151 text {* \medskip Big Union -- least upper bound of a set. *}
  1152 
  1153 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
  1154   by (iprover intro: subsetI UnionI)
  1155 
  1156 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
  1157   by (iprover intro: subsetI elim: UnionE dest: subsetD)
  1158 
  1159 
  1160 text {* \medskip General union. *}
  1161 
  1162 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
  1163   by blast
  1164 
  1165 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
  1166   by (iprover intro: subsetI elim: UN_E dest: subsetD)
  1167 
  1168 
  1169 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
  1170 
  1171 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
  1172   by blast
  1173 
  1174 lemma Inter_subset:
  1175   "[| !!X. X \<in> A ==> X \<subseteq> B; A ~= {} |] ==> \<Inter>A \<subseteq> B"
  1176   by blast
  1177 
  1178 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
  1179   by (iprover intro: InterI subsetI dest: subsetD)
  1180 
  1181 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
  1182   by blast
  1183 
  1184 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
  1185   by (iprover intro: INT_I subsetI dest: subsetD)
  1186 
  1187 
  1188 text {* \medskip Finite Union -- the least upper bound of two sets. *}
  1189 
  1190 lemma Un_upper1: "A \<subseteq> A \<union> B"
  1191   by blast
  1192 
  1193 lemma Un_upper2: "B \<subseteq> A \<union> B"
  1194   by blast
  1195 
  1196 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
  1197   by blast
  1198 
  1199 
  1200 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
  1201 
  1202 lemma Int_lower1: "A \<inter> B \<subseteq> A"
  1203   by blast
  1204 
  1205 lemma Int_lower2: "A \<inter> B \<subseteq> B"
  1206   by blast
  1207 
  1208 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
  1209   by blast
  1210 
  1211 
  1212 text {* \medskip Set difference. *}
  1213 
  1214 lemma Diff_subset: "A - B \<subseteq> A"
  1215   by blast
  1216 
  1217 lemma Diff_subset_conv: "(A - B \<subseteq> C) = (A \<subseteq> B \<union> C)"
  1218 by blast
  1219 
  1220 
  1221 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
  1222 
  1223 text {* @{text "{}"}. *}
  1224 
  1225 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
  1226   -- {* supersedes @{text "Collect_False_empty"} *}
  1227   by auto
  1228 
  1229 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
  1230   by blast
  1231 
  1232 lemma not_psubset_empty [iff]: "\<not> (A < {})"
  1233   by (unfold less_le) blast
  1234 
  1235 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
  1236 by blast
  1237 
  1238 lemma empty_Collect_eq [simp]: "({} = Collect P) = (\<forall>x. \<not> P x)"
  1239 by blast
  1240 
  1241 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
  1242   by blast
  1243 
  1244 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1245   by blast
  1246 
  1247 lemma Collect_imp_eq: "{x. P x --> Q x} = -{x. P x} \<union> {x. Q x}"
  1248   by blast
  1249 
  1250 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1251   by blast
  1252 
  1253 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1254   by blast
  1255 
  1256 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1257   by blast
  1258 
  1259 lemma Collect_ex_eq [noatp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1260   by blast
  1261 
  1262 lemma Collect_bex_eq [noatp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1263   by blast
  1264 
  1265 
  1266 text {* \medskip @{text insert}. *}
  1267 
  1268 lemma insert_is_Un: "insert a A = {a} Un A"
  1269   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1270   by blast
  1271 
  1272 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1273   by blast
  1274 
  1275 lemmas empty_not_insert = insert_not_empty [symmetric, standard]
  1276 declare empty_not_insert [simp]
  1277 
  1278 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1279   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1280   -- {* with \emph{quadratic} running time *}
  1281   by blast
  1282 
  1283 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1284   by blast
  1285 
  1286 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1287   by blast
  1288 
  1289 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1290   by blast
  1291 
  1292 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1293   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1294   apply (rule_tac x = "A - {a}" in exI, blast)
  1295   done
  1296 
  1297 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1298   by auto
  1299 
  1300 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1301   by blast
  1302 
  1303 lemma insert_inter_insert[simp]: "insert a A \<inter> insert a B = insert a (A \<inter> B)"
  1304   by blast
  1305 
  1306 lemma insert_disjoint [simp,noatp]:
  1307  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1308  "({} = insert a A \<inter> B) = (a \<notin> B \<and> {} = A \<inter> B)"
  1309   by auto
  1310 
  1311 lemma disjoint_insert [simp,noatp]:
  1312  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1313  "({} = A \<inter> insert b B) = (b \<notin> A \<and> {} = A \<inter> B)"
  1314   by auto
  1315 
  1316 text {* \medskip @{text image}. *}
  1317 
  1318 lemma image_empty [simp]: "f`{} = {}"
  1319   by blast
  1320 
  1321 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1322   by blast
  1323 
  1324 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1325   by auto
  1326 
  1327 lemma image_constant_conv: "(%x. c) ` A = (if A = {} then {} else {c})"
  1328 by auto
  1329 
  1330 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1331   by blast
  1332 
  1333 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1334   by blast
  1335 
  1336 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1337   by blast
  1338 
  1339 
  1340 lemma image_Collect [noatp]: "f ` {x. P x} = {f x | x. P x}"
  1341   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS,
  1342       with its implicit quantifier and conjunction.  Also image enjoys better
  1343       equational properties than does the RHS. *}
  1344   by blast
  1345 
  1346 lemma if_image_distrib [simp]:
  1347   "(\<lambda>x. if P x then f x else g x) ` S
  1348     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1349   by (auto simp add: image_def)
  1350 
  1351 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1352   by (simp add: image_def)
  1353 
  1354 
  1355 text {* \medskip @{text range}. *}
  1356 
  1357 lemma full_SetCompr_eq [noatp]: "{u. \<exists>x. u = f x} = range f"
  1358   by auto
  1359 
  1360 lemma range_composition: "range (\<lambda>x. f (g x)) = f`range g"
  1361 by (subst image_image, simp)
  1362 
  1363 
  1364 text {* \medskip @{text Int} *}
  1365 
  1366 lemma Int_absorb [simp]: "A \<inter> A = A"
  1367   by blast
  1368 
  1369 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1370   by blast
  1371 
  1372 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1373   by blast
  1374 
  1375 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1376   by blast
  1377 
  1378 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1379   by blast
  1380 
  1381 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1382   -- {* Intersection is an AC-operator *}
  1383 
  1384 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1385   by blast
  1386 
  1387 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1388   by blast
  1389 
  1390 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1391   by blast
  1392 
  1393 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1394   by blast
  1395 
  1396 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1397   by blast
  1398 
  1399 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1400   by blast
  1401 
  1402 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1403   by blast
  1404 
  1405 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1406   by blast
  1407 
  1408 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1409   by blast
  1410 
  1411 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1412   by blast
  1413 
  1414 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1415   by blast
  1416 
  1417 lemma Int_UNIV [simp,noatp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1418   by blast
  1419 
  1420 lemma Int_subset_iff [simp]: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1421   by blast
  1422 
  1423 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1424   by blast
  1425 
  1426 
  1427 text {* \medskip @{text Un}. *}
  1428 
  1429 lemma Un_absorb [simp]: "A \<union> A = A"
  1430   by blast
  1431 
  1432 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1433   by blast
  1434 
  1435 lemma Un_commute: "A \<union> B = B \<union> A"
  1436   by blast
  1437 
  1438 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1439   by blast
  1440 
  1441 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1442   by blast
  1443 
  1444 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1445   -- {* Union is an AC-operator *}
  1446 
  1447 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1448   by blast
  1449 
  1450 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1451   by blast
  1452 
  1453 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1454   by blast
  1455 
  1456 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1457   by blast
  1458 
  1459 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1460   by blast
  1461 
  1462 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1463   by blast
  1464 
  1465 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1466   by blast
  1467 
  1468 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1469   by blast
  1470 
  1471 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1472   by blast
  1473 
  1474 lemma Int_insert_left:
  1475     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1476   by auto
  1477 
  1478 lemma Int_insert_right:
  1479     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1480   by auto
  1481 
  1482 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1483   by blast
  1484 
  1485 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1486   by blast
  1487 
  1488 lemma Un_Int_crazy:
  1489     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1490   by blast
  1491 
  1492 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1493   by blast
  1494 
  1495 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1496   by blast
  1497 
  1498 lemma Un_subset_iff [simp]: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1499   by blast
  1500 
  1501 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1502   by blast
  1503 
  1504 lemma Diff_Int2: "A \<inter> C - B \<inter> C = A \<inter> C - B"
  1505   by blast
  1506 
  1507 
  1508 text {* \medskip Set complement *}
  1509 
  1510 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1511   by blast
  1512 
  1513 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1514   by blast
  1515 
  1516 lemma Compl_partition: "A \<union> -A = UNIV"
  1517   by blast
  1518 
  1519 lemma Compl_partition2: "-A \<union> A = UNIV"
  1520   by blast
  1521 
  1522 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1523   by blast
  1524 
  1525 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1526   by blast
  1527 
  1528 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1529   by blast
  1530 
  1531 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1532   by blast
  1533 
  1534 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1535   by blast
  1536 
  1537 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1538   by blast
  1539 
  1540 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1541   -- {* Halmos, Naive Set Theory, page 16. *}
  1542   by blast
  1543 
  1544 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1545   by blast
  1546 
  1547 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1548   by blast
  1549 
  1550 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1551   by blast
  1552 
  1553 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1554   by blast
  1555 
  1556 
  1557 text {* \medskip @{text Union}. *}
  1558 
  1559 lemma Union_empty [simp]: "Union({}) = {}"
  1560   by blast
  1561 
  1562 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1563   by blast
  1564 
  1565 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1566   by blast
  1567 
  1568 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1569   by blast
  1570 
  1571 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1572   by blast
  1573 
  1574 lemma Union_empty_conv [simp,noatp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1575   by blast
  1576 
  1577 lemma empty_Union_conv [simp,noatp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1578   by blast
  1579 
  1580 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1581   by blast
  1582 
  1583 
  1584 text {* \medskip @{text Inter}. *}
  1585 
  1586 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1587   by blast
  1588 
  1589 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1590   by blast
  1591 
  1592 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1593   by blast
  1594 
  1595 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1596   by blast
  1597 
  1598 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1599   by blast
  1600 
  1601 lemma Inter_UNIV_conv [simp,noatp]:
  1602   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1603   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1604   by blast+
  1605 
  1606 
  1607 text {*
  1608   \medskip @{text UN} and @{text INT}.
  1609 
  1610   Basic identities: *}
  1611 
  1612 lemma UN_empty [simp,noatp]: "(\<Union>x\<in>{}. B x) = {}"
  1613   by blast
  1614 
  1615 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1616   by blast
  1617 
  1618 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1619   by blast
  1620 
  1621 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1622   by auto
  1623 
  1624 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1625   by blast
  1626 
  1627 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1628   by blast
  1629 
  1630 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1631   by blast
  1632 
  1633 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1634   by blast
  1635 
  1636 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1637   by blast
  1638 
  1639 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1640   by blast
  1641 
  1642 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1643   by blast
  1644 
  1645 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1646   by blast
  1647 
  1648 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1649   by blast
  1650 
  1651 lemma INT_insert_distrib:
  1652     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1653   by blast
  1654 
  1655 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1656   by blast
  1657 
  1658 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1659   by blast
  1660 
  1661 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1662   by blast
  1663 
  1664 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1665   by auto
  1666 
  1667 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1668   by auto
  1669 
  1670 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1671   by blast
  1672 
  1673 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1674   -- {* Look: it has an \emph{existential} quantifier *}
  1675   by blast
  1676 
  1677 lemma UNION_empty_conv[simp]:
  1678   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1679   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1680 by blast+
  1681 
  1682 lemma INTER_UNIV_conv[simp]:
  1683  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1684  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1685 by blast+
  1686 
  1687 
  1688 text {* \medskip Distributive laws: *}
  1689 
  1690 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1691   by blast
  1692 
  1693 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1694   by blast
  1695 
  1696 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1697   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1698   -- {* Union of a family of unions *}
  1699   by blast
  1700 
  1701 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1702   -- {* Equivalent version *}
  1703   by blast
  1704 
  1705 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1706   by blast
  1707 
  1708 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1709   by blast
  1710 
  1711 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1712   -- {* Equivalent version *}
  1713   by blast
  1714 
  1715 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1716   -- {* Halmos, Naive Set Theory, page 35. *}
  1717   by blast
  1718 
  1719 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1720   by blast
  1721 
  1722 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1723   by blast
  1724 
  1725 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1726   by blast
  1727 
  1728 
  1729 text {* \medskip Bounded quantifiers.
  1730 
  1731   The following are not added to the default simpset because
  1732   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1733 
  1734 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1735   by blast
  1736 
  1737 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1738   by blast
  1739 
  1740 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1741   by blast
  1742 
  1743 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1744   by blast
  1745 
  1746 
  1747 text {* \medskip Set difference. *}
  1748 
  1749 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1750   by blast
  1751 
  1752 lemma Diff_eq_empty_iff [simp,noatp]: "(A - B = {}) = (A \<subseteq> B)"
  1753   by blast
  1754 
  1755 lemma Diff_cancel [simp]: "A - A = {}"
  1756   by blast
  1757 
  1758 lemma Diff_idemp [simp]: "(A - B) - B = A - (B::'a set)"
  1759 by blast
  1760 
  1761 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1762   by (blast elim: equalityE)
  1763 
  1764 lemma empty_Diff [simp]: "{} - A = {}"
  1765   by blast
  1766 
  1767 lemma Diff_empty [simp]: "A - {} = A"
  1768   by blast
  1769 
  1770 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1771   by blast
  1772 
  1773 lemma Diff_insert0 [simp,noatp]: "x \<notin> A ==> A - insert x B = A - B"
  1774   by blast
  1775 
  1776 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1777   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1778   by blast
  1779 
  1780 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1781   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1782   by blast
  1783 
  1784 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1785   by auto
  1786 
  1787 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1788   by blast
  1789 
  1790 lemma insert_Diff_single[simp]: "insert a (A - {a}) = insert a A"
  1791 by blast
  1792 
  1793 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1794   by blast
  1795 
  1796 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1797   by auto
  1798 
  1799 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1800   by blast
  1801 
  1802 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1803   by blast
  1804 
  1805 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1806   by blast
  1807 
  1808 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1809   by blast
  1810 
  1811 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1812   by blast
  1813 
  1814 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1815   by blast
  1816 
  1817 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1818   by blast
  1819 
  1820 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1821   by blast
  1822 
  1823 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1824   by blast
  1825 
  1826 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1827   by blast
  1828 
  1829 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1830   by blast
  1831 
  1832 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1833   by auto
  1834 
  1835 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1836   by blast
  1837 
  1838 
  1839 text {* \medskip Quantification over type @{typ bool}. *}
  1840 
  1841 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1842   by (cases x) auto
  1843 
  1844 lemma all_bool_eq: "(\<forall>b. P b) \<longleftrightarrow> P True \<and> P False"
  1845   by (auto intro: bool_induct)
  1846 
  1847 lemma bool_contrapos: "P x \<Longrightarrow> \<not> P False \<Longrightarrow> P True"
  1848   by (cases x) auto
  1849 
  1850 lemma ex_bool_eq: "(\<exists>b. P b) \<longleftrightarrow> P True \<or> P False"
  1851   by (auto intro: bool_contrapos)
  1852 
  1853 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1854   by (auto simp add: split_if_mem2)
  1855 
  1856 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1857   by (auto intro: bool_contrapos)
  1858 
  1859 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1860   by (auto intro: bool_induct)
  1861 
  1862 text {* \medskip @{text Pow} *}
  1863 
  1864 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1865   by (auto simp add: Pow_def)
  1866 
  1867 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1868   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1869 
  1870 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1871   by (blast intro: exI [where ?x = "- u", standard])
  1872 
  1873 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1874   by blast
  1875 
  1876 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1877   by blast
  1878 
  1879 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1880   by blast
  1881 
  1882 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1883   by blast
  1884 
  1885 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1886   by blast
  1887 
  1888 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1889   by blast
  1890 
  1891 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1892   by blast
  1893 
  1894 
  1895 text {* \medskip Miscellany. *}
  1896 
  1897 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1898   by blast
  1899 
  1900 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1901   by blast
  1902 
  1903 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1904   by (unfold less_le) blast
  1905 
  1906 lemma all_not_in_conv [simp]: "(\<forall>x. x \<notin> A) = (A = {})"
  1907   by blast
  1908 
  1909 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1910   by blast
  1911 
  1912 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1913   by iprover
  1914 
  1915 
  1916 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1917            and Intersections. *}
  1918 
  1919 lemma UN_simps [simp]:
  1920   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1921   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1922   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1923   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1924   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1925   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1926   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1927   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1928   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1929   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1930   by auto
  1931 
  1932 lemma INT_simps [simp]:
  1933   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1934   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1935   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1936   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1937   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1938   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1939   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1940   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1941   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1942   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1943   by auto
  1944 
  1945 lemma ball_simps [simp,noatp]:
  1946   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1947   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1948   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1949   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1950   "!!P. (ALL x:{}. P x) = True"
  1951   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1952   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1953   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1954   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1955   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1956   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1957   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1958   by auto
  1959 
  1960 lemma bex_simps [simp,noatp]:
  1961   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1962   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1963   "!!P. (EX x:{}. P x) = False"
  1964   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1965   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1966   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1967   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1968   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1969   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1970   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1971   by auto
  1972 
  1973 lemma ball_conj_distrib:
  1974   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1975   by blast
  1976 
  1977 lemma bex_disj_distrib:
  1978   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1979   by blast
  1980 
  1981 
  1982 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1983 
  1984 lemma UN_extend_simps:
  1985   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  1986   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  1987   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  1988   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  1989   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  1990   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  1991   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  1992   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  1993   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  1994   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  1995   by auto
  1996 
  1997 lemma INT_extend_simps:
  1998   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  1999   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  2000   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  2001   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  2002   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  2003   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  2004   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  2005   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  2006   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  2007   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  2008   by auto
  2009 
  2010 
  2011 subsubsection {* Monotonicity of various operations *}
  2012 
  2013 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  2014   by blast
  2015 
  2016 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  2017   by blast
  2018 
  2019 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  2020   by blast
  2021 
  2022 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  2023   by blast
  2024 
  2025 lemma UN_mono:
  2026   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  2027     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  2028   by (blast dest: subsetD)
  2029 
  2030 lemma INT_anti_mono:
  2031   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  2032     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  2033   -- {* The last inclusion is POSITIVE! *}
  2034   by (blast dest: subsetD)
  2035 
  2036 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  2037   by blast
  2038 
  2039 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  2040   by blast
  2041 
  2042 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  2043   by blast
  2044 
  2045 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  2046   by blast
  2047 
  2048 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  2049   by blast
  2050 
  2051 text {* \medskip Monotonicity of implications. *}
  2052 
  2053 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  2054   apply (rule impI)
  2055   apply (erule subsetD, assumption)
  2056   done
  2057 
  2058 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  2059   by iprover
  2060 
  2061 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  2062   by iprover
  2063 
  2064 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  2065   by iprover
  2066 
  2067 lemma imp_refl: "P --> P" ..
  2068 
  2069 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  2070   by iprover
  2071 
  2072 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  2073   by iprover
  2074 
  2075 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  2076   by blast
  2077 
  2078 lemma Int_Collect_mono:
  2079     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  2080   by blast
  2081 
  2082 lemmas basic_monos =
  2083   subset_refl imp_refl disj_mono conj_mono
  2084   ex_mono Collect_mono in_mono
  2085 
  2086 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  2087   by iprover
  2088 
  2089 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  2090   by iprover
  2091 
  2092 
  2093 subsection {* Inverse image of a function *}
  2094 
  2095 constdefs
  2096   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  2097   [code del]: "f -` B == {x. f x : B}"
  2098 
  2099 
  2100 subsubsection {* Basic rules *}
  2101 
  2102 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  2103   by (unfold vimage_def) blast
  2104 
  2105 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  2106   by simp
  2107 
  2108 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  2109   by (unfold vimage_def) blast
  2110 
  2111 lemma vimageI2: "f a : A ==> a : f -` A"
  2112   by (unfold vimage_def) fast
  2113 
  2114 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  2115   by (unfold vimage_def) blast
  2116 
  2117 lemma vimageD: "a : f -` A ==> f a : A"
  2118   by (unfold vimage_def) fast
  2119 
  2120 
  2121 subsubsection {* Equations *}
  2122 
  2123 lemma vimage_empty [simp]: "f -` {} = {}"
  2124   by blast
  2125 
  2126 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  2127   by blast
  2128 
  2129 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  2130   by blast
  2131 
  2132 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  2133   by fast
  2134 
  2135 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  2136   by blast
  2137 
  2138 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  2139   by blast
  2140 
  2141 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  2142   by blast
  2143 
  2144 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  2145   by blast
  2146 
  2147 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  2148   by blast
  2149 
  2150 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  2151   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  2152   by blast
  2153 
  2154 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  2155   by blast
  2156 
  2157 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  2158   by blast
  2159 
  2160 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  2161   -- {* NOT suitable for rewriting *}
  2162   by blast
  2163 
  2164 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  2165   -- {* monotonicity *}
  2166   by blast
  2167 
  2168 lemma vimage_image_eq [noatp]: "f -` (f ` A) = {y. EX x:A. f x = f y}"
  2169 by (blast intro: sym)
  2170 
  2171 lemma image_vimage_subset: "f ` (f -` A) <= A"
  2172 by blast
  2173 
  2174 lemma image_vimage_eq [simp]: "f ` (f -` A) = A Int range f"
  2175 by blast
  2176 
  2177 lemma image_Int_subset: "f`(A Int B) <= f`A Int f`B"
  2178 by blast
  2179 
  2180 lemma image_diff_subset: "f`A - f`B <= f`(A - B)"
  2181 by blast
  2182 
  2183 lemma image_UN: "(f ` (UNION A B)) = (UN x:A.(f ` (B x)))"
  2184 by blast
  2185 
  2186 
  2187 subsection {* Getting the Contents of a Singleton Set *}
  2188 
  2189 definition contents :: "'a set \<Rightarrow> 'a" where
  2190   [code del]: "contents X = (THE x. X = {x})"
  2191 
  2192 lemma contents_eq [simp]: "contents {x} = x"
  2193   by (simp add: contents_def)
  2194 
  2195 
  2196 subsection {* Transitivity rules for calculational reasoning *}
  2197 
  2198 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  2199   by (rule subsetD)
  2200 
  2201 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  2202   by (rule subsetD)
  2203 
  2204 lemmas basic_trans_rules [trans] =
  2205   order_trans_rules set_rev_mp set_mp
  2206 
  2207 
  2208 subsection {* Least value operator *}
  2209 
  2210 lemma Least_mono:
  2211   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  2212     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  2213     -- {* Courtesy of Stephan Merz *}
  2214   apply clarify
  2215   apply (erule_tac P = "%x. x : S" in LeastI2_order, fast)
  2216   apply (rule LeastI2_order)
  2217   apply (auto elim: monoD intro!: order_antisym)
  2218   done
  2219 
  2220 
  2221 subsection {* Rudimentary code generation *}
  2222 
  2223 lemma empty_code [code]: "{} x \<longleftrightarrow> False"
  2224   unfolding empty_def Collect_def ..
  2225 
  2226 lemma UNIV_code [code]: "UNIV x \<longleftrightarrow> True"
  2227   unfolding UNIV_def Collect_def ..
  2228 
  2229 lemma insert_code [code]: "insert y A x \<longleftrightarrow> y = x \<or> A x"
  2230   unfolding insert_def Collect_def mem_def Un_def by auto
  2231 
  2232 lemma inter_code [code]: "(A \<inter> B) x \<longleftrightarrow> A x \<and> B x"
  2233   unfolding Int_def Collect_def mem_def ..
  2234 
  2235 lemma union_code [code]: "(A \<union> B) x \<longleftrightarrow> A x \<or> B x"
  2236   unfolding Un_def Collect_def mem_def ..
  2237 
  2238 lemma vimage_code [code]: "(f -` A) x = A (f x)"
  2239   unfolding vimage_def Collect_def mem_def ..
  2240 
  2241 
  2242 subsection {* Complete lattices *}
  2243 
  2244 notation
  2245   less_eq  (infix "\<sqsubseteq>" 50) and
  2246   less (infix "\<sqsubset>" 50) and
  2247   inf  (infixl "\<sqinter>" 70) and
  2248   sup  (infixl "\<squnion>" 65)
  2249 
  2250 class complete_lattice = lattice + bot + top +
  2251   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
  2252     and Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
  2253   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
  2254      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
  2255   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
  2256      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
  2257 begin
  2258 
  2259 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<le> a}"
  2260   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
  2261 
  2262 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<le> b}"
  2263   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
  2264 
  2265 lemma Inf_Univ: "\<Sqinter>UNIV = \<Squnion>{}"
  2266   unfolding Sup_Inf by auto
  2267 
  2268 lemma Sup_Univ: "\<Squnion>UNIV = \<Sqinter>{}"
  2269   unfolding Inf_Sup by auto
  2270 
  2271 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
  2272   by (auto intro: antisym Inf_greatest Inf_lower)
  2273 
  2274 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
  2275   by (auto intro: antisym Sup_least Sup_upper)
  2276 
  2277 lemma Inf_singleton [simp]:
  2278   "\<Sqinter>{a} = a"
  2279   by (auto intro: antisym Inf_lower Inf_greatest)
  2280 
  2281 lemma Sup_singleton [simp]:
  2282   "\<Squnion>{a} = a"
  2283   by (auto intro: antisym Sup_upper Sup_least)
  2284 
  2285 lemma Inf_insert_simp:
  2286   "\<Sqinter>insert a A = (if A = {} then a else a \<sqinter> \<Sqinter>A)"
  2287   by (cases "A = {}") (simp_all, simp add: Inf_insert)
  2288 
  2289 lemma Sup_insert_simp:
  2290   "\<Squnion>insert a A = (if A = {} then a else a \<squnion> \<Squnion>A)"
  2291   by (cases "A = {}") (simp_all, simp add: Sup_insert)
  2292 
  2293 lemma Inf_binary:
  2294   "\<Sqinter>{a, b} = a \<sqinter> b"
  2295   by (simp add: Inf_insert_simp)
  2296 
  2297 lemma Sup_binary:
  2298   "\<Squnion>{a, b} = a \<squnion> b"
  2299   by (simp add: Sup_insert_simp)
  2300 
  2301 lemma bot_def:
  2302   "bot = \<Squnion>{}"
  2303   by (auto intro: antisym Sup_least)
  2304 
  2305 lemma top_def:
  2306   "top = \<Sqinter>{}"
  2307   by (auto intro: antisym Inf_greatest)
  2308 
  2309 lemma sup_bot [simp]:
  2310   "x \<squnion> bot = x"
  2311   using bot_least [of x] by (simp add: le_iff_sup sup_commute)
  2312 
  2313 lemma inf_top [simp]:
  2314   "x \<sqinter> top = x"
  2315   using top_greatest [of x] by (simp add: le_iff_inf inf_commute)
  2316 
  2317 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
  2318   "SUPR A f == \<Squnion> (f ` A)"
  2319 
  2320 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
  2321   "INFI A f == \<Sqinter> (f ` A)"
  2322 
  2323 end
  2324 
  2325 syntax
  2326   "_SUP1"     :: "pttrns => 'b => 'b"           ("(3SUP _./ _)" [0, 10] 10)
  2327   "_SUP"      :: "pttrn => 'a set => 'b => 'b"  ("(3SUP _:_./ _)" [0, 10] 10)
  2328   "_INF1"     :: "pttrns => 'b => 'b"           ("(3INF _./ _)" [0, 10] 10)
  2329   "_INF"      :: "pttrn => 'a set => 'b => 'b"  ("(3INF _:_./ _)" [0, 10] 10)
  2330 
  2331 translations
  2332   "SUP x y. B"   == "SUP x. SUP y. B"
  2333   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
  2334   "SUP x. B"     == "SUP x:CONST UNIV. B"
  2335   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
  2336   "INF x y. B"   == "INF x. INF y. B"
  2337   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
  2338   "INF x. B"     == "INF x:CONST UNIV. B"
  2339   "INF x:A. B"   == "CONST INFI A (%x. B)"
  2340 
  2341 (* To avoid eta-contraction of body: *)
  2342 print_translation {*
  2343 let
  2344   fun btr' syn (A :: Abs abs :: ts) =
  2345     let val (x,t) = atomic_abs_tr' abs
  2346     in list_comb (Syntax.const syn $ x $ A $ t, ts) end
  2347   val const_syntax_name = Sign.const_syntax_name @{theory} o fst o dest_Const
  2348 in
  2349 [(const_syntax_name @{term SUPR}, btr' "_SUP"),(const_syntax_name @{term "INFI"}, btr' "_INF")]
  2350 end
  2351 *}
  2352 
  2353 context complete_lattice
  2354 begin
  2355 
  2356 lemma le_SUPI: "i : A \<Longrightarrow> M i \<le> (SUP i:A. M i)"
  2357   by (auto simp add: SUPR_def intro: Sup_upper)
  2358 
  2359 lemma SUP_leI: "(\<And>i. i : A \<Longrightarrow> M i \<le> u) \<Longrightarrow> (SUP i:A. M i) \<le> u"
  2360   by (auto simp add: SUPR_def intro: Sup_least)
  2361 
  2362 lemma INF_leI: "i : A \<Longrightarrow> (INF i:A. M i) \<le> M i"
  2363   by (auto simp add: INFI_def intro: Inf_lower)
  2364 
  2365 lemma le_INFI: "(\<And>i. i : A \<Longrightarrow> u \<le> M i) \<Longrightarrow> u \<le> (INF i:A. M i)"
  2366   by (auto simp add: INFI_def intro: Inf_greatest)
  2367 
  2368 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
  2369   by (auto intro: antisym SUP_leI le_SUPI)
  2370 
  2371 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
  2372   by (auto intro: antisym INF_leI le_INFI)
  2373 
  2374 end
  2375 
  2376 
  2377 subsection {* Bool as complete lattice *}
  2378 
  2379 instantiation bool :: complete_lattice
  2380 begin
  2381 
  2382 definition
  2383   Inf_bool_def: "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
  2384 
  2385 definition
  2386   Sup_bool_def: "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
  2387 
  2388 instance
  2389   by intro_classes (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
  2390 
  2391 end
  2392 
  2393 lemma Inf_empty_bool [simp]:
  2394   "\<Sqinter>{}"
  2395   unfolding Inf_bool_def by auto
  2396 
  2397 lemma not_Sup_empty_bool [simp]:
  2398   "\<not> Sup {}"
  2399   unfolding Sup_bool_def by auto
  2400 
  2401 
  2402 subsection {* Fun as complete lattice *}
  2403 
  2404 instantiation "fun" :: (type, complete_lattice) complete_lattice
  2405 begin
  2406 
  2407 definition
  2408   Inf_fun_def [code del]: "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
  2409 
  2410 definition
  2411   Sup_fun_def [code del]: "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
  2412 
  2413 instance
  2414   by intro_classes
  2415     (auto simp add: Inf_fun_def Sup_fun_def le_fun_def
  2416       intro: Inf_lower Sup_upper Inf_greatest Sup_least)
  2417 
  2418 end
  2419 
  2420 lemma Inf_empty_fun:
  2421   "\<Sqinter>{} = (\<lambda>_. \<Sqinter>{})"
  2422   by rule (auto simp add: Inf_fun_def)
  2423 
  2424 lemma Sup_empty_fun:
  2425   "\<Squnion>{} = (\<lambda>_. \<Squnion>{})"
  2426   by rule (auto simp add: Sup_fun_def)
  2427 
  2428 
  2429 subsection {* Set as lattice *}
  2430 
  2431 lemma inf_set_eq: "A \<sqinter> B = A \<inter> B"
  2432   apply (rule subset_antisym)
  2433   apply (rule Int_greatest)
  2434   apply (rule inf_le1)
  2435   apply (rule inf_le2)
  2436   apply (rule inf_greatest)
  2437   apply (rule Int_lower1)
  2438   apply (rule Int_lower2)
  2439   done
  2440 
  2441 lemma sup_set_eq: "A \<squnion> B = A \<union> B"
  2442   apply (rule subset_antisym)
  2443   apply (rule sup_least)
  2444   apply (rule Un_upper1)
  2445   apply (rule Un_upper2)
  2446   apply (rule Un_least)
  2447   apply (rule sup_ge1)
  2448   apply (rule sup_ge2)
  2449   done
  2450 
  2451 lemma mono_Int: "mono f \<Longrightarrow> f (A \<inter> B) \<subseteq> f A \<inter> f B"
  2452   apply (fold inf_set_eq sup_set_eq)
  2453   apply (erule mono_inf)
  2454   done
  2455 
  2456 lemma mono_Un: "mono f \<Longrightarrow> f A \<union> f B \<subseteq> f (A \<union> B)"
  2457   apply (fold inf_set_eq sup_set_eq)
  2458   apply (erule mono_sup)
  2459   done
  2460 
  2461 lemma Inf_set_eq: "\<Sqinter>S = \<Inter>S"
  2462   apply (rule subset_antisym)
  2463   apply (rule Inter_greatest)
  2464   apply (erule Inf_lower)
  2465   apply (rule Inf_greatest)
  2466   apply (erule Inter_lower)
  2467   done
  2468 
  2469 lemma Sup_set_eq: "\<Squnion>S = \<Union>S"
  2470   apply (rule subset_antisym)
  2471   apply (rule Sup_least)
  2472   apply (erule Union_upper)
  2473   apply (rule Union_least)
  2474   apply (erule Sup_upper)
  2475   done
  2476   
  2477 lemma top_set_eq: "top = UNIV"
  2478   by (iprover intro!: subset_antisym subset_UNIV top_greatest)
  2479 
  2480 lemma bot_set_eq: "bot = {}"
  2481   by (iprover intro!: subset_antisym empty_subsetI bot_least)
  2482 
  2483 no_notation
  2484   less_eq  (infix "\<sqsubseteq>" 50) and
  2485   less (infix "\<sqsubset>" 50) and
  2486   inf  (infixl "\<sqinter>" 70) and
  2487   sup  (infixl "\<squnion>" 65) and
  2488   Inf  ("\<Sqinter>_" [900] 900) and
  2489   Sup  ("\<Squnion>_" [900] 900)
  2490 
  2491 
  2492 subsection {* Basic ML bindings *}
  2493 
  2494 ML {*
  2495 val Ball_def = @{thm Ball_def}
  2496 val Bex_def = @{thm Bex_def}
  2497 val CollectD = @{thm CollectD}
  2498 val CollectE = @{thm CollectE}
  2499 val CollectI = @{thm CollectI}
  2500 val Collect_conj_eq = @{thm Collect_conj_eq}
  2501 val Collect_mem_eq = @{thm Collect_mem_eq}
  2502 val IntD1 = @{thm IntD1}
  2503 val IntD2 = @{thm IntD2}
  2504 val IntE = @{thm IntE}
  2505 val IntI = @{thm IntI}
  2506 val Int_Collect = @{thm Int_Collect}
  2507 val UNIV_I = @{thm UNIV_I}
  2508 val UNIV_witness = @{thm UNIV_witness}
  2509 val UnE = @{thm UnE}
  2510 val UnI1 = @{thm UnI1}
  2511 val UnI2 = @{thm UnI2}
  2512 val ballE = @{thm ballE}
  2513 val ballI = @{thm ballI}
  2514 val bexCI = @{thm bexCI}
  2515 val bexE = @{thm bexE}
  2516 val bexI = @{thm bexI}
  2517 val bex_triv = @{thm bex_triv}
  2518 val bspec = @{thm bspec}
  2519 val contra_subsetD = @{thm contra_subsetD}
  2520 val distinct_lemma = @{thm distinct_lemma}
  2521 val eq_to_mono = @{thm eq_to_mono}
  2522 val eq_to_mono2 = @{thm eq_to_mono2}
  2523 val equalityCE = @{thm equalityCE}
  2524 val equalityD1 = @{thm equalityD1}
  2525 val equalityD2 = @{thm equalityD2}
  2526 val equalityE = @{thm equalityE}
  2527 val equalityI = @{thm equalityI}
  2528 val imageE = @{thm imageE}
  2529 val imageI = @{thm imageI}
  2530 val image_Un = @{thm image_Un}
  2531 val image_insert = @{thm image_insert}
  2532 val insert_commute = @{thm insert_commute}
  2533 val insert_iff = @{thm insert_iff}
  2534 val mem_Collect_eq = @{thm mem_Collect_eq}
  2535 val rangeE = @{thm rangeE}
  2536 val rangeI = @{thm rangeI}
  2537 val range_eqI = @{thm range_eqI}
  2538 val subsetCE = @{thm subsetCE}
  2539 val subsetD = @{thm subsetD}
  2540 val subsetI = @{thm subsetI}
  2541 val subset_refl = @{thm subset_refl}
  2542 val subset_trans = @{thm subset_trans}
  2543 val vimageD = @{thm vimageD}
  2544 val vimageE = @{thm vimageE}
  2545 val vimageI = @{thm vimageI}
  2546 val vimageI2 = @{thm vimageI2}
  2547 val vimage_Collect = @{thm vimage_Collect}
  2548 val vimage_Int = @{thm vimage_Int}
  2549 val vimage_Un = @{thm vimage_Un}
  2550 *}
  2551 
  2552 end