src/Pure/library.ML
author wenzelm
Fri Jul 01 14:41:58 2005 +0200 (2005-07-01)
changeset 16654 d964cbaa6c1c
parent 16535 86c9eada525b
child 16676 671bd433b9eb
permissions -rw-r--r--
low-level tuning of fold, fold_rev, foldl_map;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |>> |>>> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 infix 3 oo ooo oooo;
    16 
    17 signature BASIC_LIBRARY =
    18 sig
    19   (*functions*)
    20   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    21   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val |> : 'a * ('a -> 'b) -> 'b
    25   val |>> : ('a * 'b) * ('a -> 'c) -> 'c * 'b
    26   val |>>> : ('a * 'b) * ('a -> 'c * 'd) -> 'c * ('b * 'd)
    27   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    28   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    29   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    30   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    31   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    32   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    33 
    34   (*old options -- invalidated*)
    35   datatype invalid = None of invalid
    36   exception OPTION of invalid
    37 
    38   (*options*)
    39   val the: 'a option -> 'a
    40   val if_none: 'a option -> 'a -> 'a
    41   val is_some: 'a option -> bool
    42   val is_none: 'a option -> bool
    43 
    44   exception ERROR
    45   val try: ('a -> 'b) -> 'a -> 'b option
    46   val can: ('a -> 'b) -> 'a -> bool
    47   datatype 'a result = Result of 'a | Exn of exn
    48   val capture: ('a -> 'b) -> 'a -> 'b result
    49   val release: 'a result -> 'a
    50   val get_result: 'a result -> 'a option
    51   val get_exn: 'a result -> exn option
    52 
    53   (*pairs*)
    54   val pair: 'a -> 'b -> 'a * 'b
    55   val rpair: 'a -> 'b -> 'b * 'a
    56   val fst: 'a * 'b -> 'a
    57   val snd: 'a * 'b -> 'b
    58   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    59   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    60   val swap: 'a * 'b -> 'b * 'a
    61   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    62   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    63   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    64 
    65   (*booleans*)
    66   val equal: ''a -> ''a -> bool
    67   val not_equal: ''a -> ''a -> bool
    68   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    69   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val exists: ('a -> bool) -> 'a list -> bool
    71   val forall: ('a -> bool) -> 'a list -> bool
    72   val set: bool ref -> bool
    73   val reset: bool ref -> bool
    74   val toggle: bool ref -> bool
    75   val change: 'a ref -> ('a -> 'a) -> unit
    76   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    77   val conditional: bool -> (unit -> unit) -> unit
    78 
    79   (*lists*)
    80   exception UnequalLengths
    81   val cons: 'a -> 'a list -> 'a list
    82   val single: 'a -> 'a list
    83   val append: 'a list -> 'a list -> 'a list
    84   val apply: ('a -> 'a) list -> 'a -> 'a
    85   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    86   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    87   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    88   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    89   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    90   val unflat: 'a list list -> 'b list -> 'b list list
    91   val splitAt: int * 'a list -> 'a list * 'a list
    92   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    93   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
    94   val split_last: 'a list -> 'a list * 'a
    95   val nth_update: 'a -> int * 'a list -> 'a list
    96   val find_index: ('a -> bool) -> 'a list -> int
    97   val find_index_eq: ''a -> ''a list -> int
    98   val find_first: ('a -> bool) -> 'a list -> 'a option
    99   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   100   val separate: 'a -> 'a list -> 'a list
   101   val replicate: int -> 'a -> 'a list
   102   val multiply: 'a list * 'a list list -> 'a list list
   103   val product: 'a list -> 'b list -> ('a * 'b) list
   104   val filter: ('a -> bool) -> 'a list -> 'a list
   105   val filter_out: ('a -> bool) -> 'a list -> 'a list
   106   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   107   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   108   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   109   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   110   val ~~ : 'a list * 'b list -> ('a * 'b) list
   111   val split_list: ('a * 'b) list -> 'a list * 'b list
   112   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   113   val prefix: ''a list * ''a list -> bool
   114   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118 
   119   (*integers*)
   120   val gcd: IntInf.int * IntInf.int -> IntInf.int
   121   val lcm: IntInf.int * IntInf.int -> IntInf.int
   122   val inc: int ref -> int
   123   val dec: int ref -> int
   124   val upto: int * int -> int list
   125   val downto: int * int -> int list
   126   val downto0: int list * int -> bool
   127   val radixpand: int * int -> int list
   128   val radixstring: int * string * int -> string
   129   val string_of_int: int -> string
   130   val string_of_indexname: string * int -> string
   131   val read_radixint: int * string list -> int * string list
   132   val read_int: string list -> int * string list
   133   val oct_char: string -> string
   134 
   135   (*rational numbers*)
   136   type rat
   137   exception RAT of string
   138   val rep_rat: rat -> IntInf.int * IntInf.int
   139   val ratadd: rat * rat -> rat
   140   val ratmul: rat * rat -> rat
   141   val ratinv: rat -> rat
   142   val int_ratdiv: IntInf.int * IntInf.int -> rat
   143   val ratneg: rat -> rat
   144   val rat_of_int: int -> rat
   145   val rat_of_intinf: IntInf.int -> rat
   146 
   147   (*strings*)
   148   val nth_elem_string: int * string -> string
   149   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   150   val exists_string: (string -> bool) -> string -> bool
   151   val forall_string: (string -> bool) -> string -> bool
   152   val enclose: string -> string -> string -> string
   153   val unenclose: string -> string
   154   val quote: string -> string
   155   val space_implode: string -> string list -> string
   156   val commas: string list -> string
   157   val commas_quote: string list -> string
   158   val cat_lines: string list -> string
   159   val space_explode: string -> string -> string list
   160   val split_lines: string -> string list
   161   val prefix_lines: string -> string -> string
   162   val untabify: string list -> string list
   163   val suffix: string -> string -> string
   164   val unsuffix: string -> string -> string
   165   val unprefix: string -> string -> string
   166   val replicate_string: int -> string -> string
   167   val translate_string: (string -> string) -> string -> string
   168 
   169   (*lists as sets -- see also Pure/General/ord_list.ML*)
   170   val mem: ''a * ''a list -> bool
   171   val mem_int: int * int list -> bool
   172   val mem_string: string * string list -> bool
   173   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   174   val ins: ''a * ''a list -> ''a list
   175   val ins_int: int * int list -> int list
   176   val ins_string: string * string list -> string list
   177   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   178   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   179   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   180   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   181   val union: ''a list * ''a list -> ''a list
   182   val union_int: int list * int list -> int list
   183   val union_string: string list * string list -> string list
   184   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   185   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   186   val inter: ''a list * ''a list -> ''a list
   187   val inter_int: int list * int list -> int list
   188   val inter_string: string list * string list -> string list
   189   val subset: ''a list * ''a list -> bool
   190   val subset_int: int list * int list -> bool
   191   val subset_string: string list * string list -> bool
   192   val eq_set: ''a list * ''a list -> bool
   193   val eq_set_string: string list * string list -> bool
   194   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   195   val \ : ''a list * ''a -> ''a list
   196   val \\ : ''a list * ''a list -> ''a list
   197   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   198   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   199   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   200   val distinct: ''a list -> ''a list
   201   val findrep: ''a list -> ''a list
   202   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   203   val duplicates: ''a list -> ''a list
   204 
   205   (*association lists*)
   206   val assoc: (''a * 'b) list * ''a -> 'b option
   207   val assoc_int: (int * 'a) list * int -> 'a option
   208   val assoc_string: (string * 'a) list * string -> 'a option
   209   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   210   val assocs: (''a * 'b list) list -> ''a -> 'b list
   211   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   212   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   213   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   214   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   215 
   216   (*lists as tables*)
   217   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   218   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   219   val merge_lists: ''a list -> ''a list -> ''a list
   220   val merge_lists': ''a list -> ''a list -> ''a list
   221   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   222   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   223 
   224   (*balanced trees*)
   225   exception Balance
   226   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   227   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   228   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   229 
   230   (*orders*)
   231   val rev_order: order -> order
   232   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   233   val int_ord: int * int -> order
   234   val string_ord: string * string -> order
   235   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   236   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   237   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   238   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   239   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   240   val sort_strings: string list -> string list
   241   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   242   val unique_strings: string list -> string list
   243 
   244   (*random numbers*)
   245   exception RANDOM
   246   val random: unit -> real
   247   val random_range: int -> int -> int
   248   val one_of: 'a list -> 'a
   249   val frequency: (int * 'a) list -> 'a
   250 
   251   (*current directory*)
   252   val cd: string -> unit
   253   val pwd: unit -> string
   254 
   255   (*misc*)
   256   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   257   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   258   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   259   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   260   val gensym: string -> string
   261   val scanwords: (string -> bool) -> string list -> string list
   262   type stamp
   263   val stamp: unit -> stamp
   264   type serial
   265   val serial: unit -> serial
   266   structure Object: sig type T end
   267 end;
   268 
   269 signature LIBRARY =
   270 sig
   271   include BASIC_LIBRARY
   272   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   273   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   274   val take: int * 'a list -> 'a list
   275   val drop: int * 'a list -> 'a list
   276   val nth_elem: int * 'a list -> 'a
   277   val last_elem: 'a list -> 'a
   278   val flat: 'a list list -> 'a list
   279   val seq: ('a -> unit) -> 'a list -> unit
   280   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   281   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   282 end;
   283 
   284 structure Library: LIBRARY =
   285 struct
   286 
   287 
   288 (** functions **)
   289 
   290 (*handy combinators*)
   291 fun curry f x y = f (x, y);
   292 fun uncurry f (x, y) = f x y;
   293 fun I x = x;
   294 fun K x y = x;
   295 
   296 (*reverse apply*)
   297 fun (x |> f) = f x;
   298 fun ((x, y) |>> f) = (f x, y);
   299 fun ((x, y) |>>> f) = let val (x', z) = f x in (x', (y, z)) end;
   300 
   301 (*application of (infix) operator to its left or right argument*)
   302 fun apl (x, f) y = f (x, y);
   303 fun apr (f, y) x = f (x, y);
   304 
   305 (*function exponentiation: f(...(f x)...) with n applications of f*)
   306 fun funpow n f x =
   307   let fun rep (0, x) = x
   308         | rep (n, x) = rep (n - 1, f x)
   309   in rep (n, x) end;
   310 
   311 (*concatenation: 2 and 3 args*)
   312 fun (f oo g) x y = f (g x y);
   313 fun (f ooo g) x y z = f (g x y z);
   314 fun (f oooo g) x y z w = f (g x y z w);
   315 
   316 
   317 
   318 (** options **)
   319 
   320 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   321 datatype invalid = None of invalid;
   322 exception OPTION of invalid;
   323 
   324 val the = Option.valOf;
   325 
   326 (*strict!*)
   327 fun if_none NONE y = y
   328   | if_none (SOME x) _ = x;
   329 
   330 fun is_some (SOME _) = true
   331   | is_some NONE = false;
   332 
   333 fun is_none (SOME _) = false
   334   | is_none NONE = true;
   335 
   336 
   337 (* exception handling *)
   338 
   339 exception ERROR;
   340 
   341 fun try f x = SOME (f x)
   342   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   343 
   344 fun can f x = is_some (try f x);
   345 
   346 
   347 datatype 'a result =
   348   Result of 'a |
   349   Exn of exn;
   350 
   351 fun capture f x = Result (f x) handle e => Exn e;
   352 
   353 fun release (Result y) = y
   354   | release (Exn e) = raise e;
   355 
   356 fun get_result (Result x) = SOME x
   357   | get_result _ = NONE;
   358 
   359 fun get_exn (Exn exn) = SOME exn
   360   | get_exn _ = NONE;
   361 
   362 
   363 
   364 (** pairs **)
   365 
   366 fun pair x y = (x, y);
   367 fun rpair x y = (y, x);
   368 
   369 fun fst (x, y) = x;
   370 fun snd (x, y) = y;
   371 
   372 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   373 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   374 
   375 fun swap (x, y) = (y, x);
   376 
   377 (*apply function to components*)
   378 fun apfst f (x, y) = (f x, y);
   379 fun apsnd f (x, y) = (x, f y);
   380 fun pairself f (x, y) = (f x, f y);
   381 
   382 
   383 
   384 (** booleans **)
   385 
   386 (* equality *)
   387 
   388 fun equal x y = x = y;
   389 fun not_equal x y = x <> y;
   390 
   391 
   392 (* operators for combining predicates *)
   393 
   394 fun (p orf q) = fn x => p x orelse q x;
   395 fun (p andf q) = fn x => p x andalso q x;
   396 
   397 
   398 (* predicates on lists *)
   399 
   400 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   401 fun exists (pred: 'a -> bool) : 'a list -> bool =
   402   let fun boolf [] = false
   403         | boolf (x :: xs) = pred x orelse boolf xs
   404   in boolf end;
   405 
   406 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   407 fun forall (pred: 'a -> bool) : 'a list -> bool =
   408   let fun boolf [] = true
   409         | boolf (x :: xs) = pred x andalso boolf xs
   410   in boolf end;
   411 
   412 
   413 (* flags *)
   414 
   415 fun set flag = (flag := true; true);
   416 fun reset flag = (flag := false; false);
   417 fun toggle flag = (flag := not (! flag); ! flag);
   418 
   419 fun change r f = r := f (! r);
   420 
   421 (*temporarily set flag, handling exceptions*)
   422 fun setmp flag value f x =
   423   let
   424     val orig_value = ! flag;
   425     fun return y = (flag := orig_value; y);
   426   in
   427     flag := value;
   428     return (f x handle exn => (return (); raise exn))
   429   end;
   430 
   431 
   432 (* conditional execution *)
   433 
   434 fun conditional b f = if b then f () else ();
   435 
   436 
   437 
   438 (** lists **)
   439 
   440 exception UnequalLengths;
   441 
   442 fun cons x xs = x :: xs;
   443 fun single x = [x];
   444 
   445 fun append xs ys = xs @ ys;
   446 
   447 fun apply [] x = x
   448   | apply (f :: fs) x = apply fs (f x);
   449 
   450 
   451 (* fold *)
   452 
   453 fun fold f =
   454   let
   455     fun fold_aux [] y = y
   456       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   457   in fold_aux end;
   458 
   459 fun fold_rev f =
   460   let
   461     fun fold_aux [] y = y
   462       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   463   in fold_aux end;
   464 
   465 fun foldl_map f =
   466   let
   467     fun fold_aux (x, []) = (x, [])
   468       | fold_aux (x, y :: ys) =
   469           let
   470             val (x', y') = f (x, y);
   471             val (x'', ys') = fold_aux (x', ys);
   472           in (x'', y' :: ys') end;
   473   in fold_aux end;
   474 
   475 (*the following versions of fold are designed to fit nicely with infixes*)
   476 
   477 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   478     for operators that associate to the left (TAIL RECURSIVE)*)
   479 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   480   let fun itl (e, [])  = e
   481         | itl (e, a::l) = itl (f(e, a), l)
   482   in  itl end;
   483 
   484 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   485     for operators that associate to the right (not tail recursive)*)
   486 fun foldr f (l, e) =
   487   let fun itr [] = e
   488         | itr (a::l) = f(a, itr l)
   489   in  itr l  end;
   490 
   491 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   492     for n > 0, operators that associate to the right (not tail recursive)*)
   493 fun foldr1 f l =
   494   let fun itr [x] = x
   495         | itr (x::l) = f(x, itr l)
   496   in  itr l  end;
   497 
   498 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   499 
   500 
   501 (* basic list functions *)
   502 
   503 (*take the first n elements from a list*)
   504 fun take (n, []) = []
   505   | take (n, x :: xs) =
   506       if n > 0 then x :: take (n - 1, xs) else [];
   507 
   508 (*drop the first n elements from a list*)
   509 fun drop (n, []) = []
   510   | drop (n, x :: xs) =
   511       if n > 0 then drop (n - 1, xs) else x :: xs;
   512 
   513 fun splitAt(n,[]) = ([],[])
   514   | splitAt(n,xs as x::ys) =
   515       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   516       else ([],xs)
   517 
   518 fun dropwhile P [] = []
   519   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   520 
   521 (*return nth element of a list, where 0 designates the first element;
   522   raise EXCEPTION if list too short*)
   523 fun nth_elem (i,xs) = List.nth(xs,i);
   524 
   525 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   526   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   527   | map_nth_elem _ _ [] = raise Subscript;
   528 
   529 (*last element of a list*)
   530 val last_elem = List.last;
   531 
   532 (*rear decomposition*)
   533 fun split_last [] = raise Empty
   534   | split_last [x] = ([], x)
   535   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   536 
   537 (*update nth element*)
   538 fun nth_update x n_xs =
   539     (case splitAt n_xs of
   540       (_,[]) => raise Subscript
   541     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   542 
   543 (*find the position of an element in a list*)
   544 fun find_index pred =
   545   let fun find _ [] = ~1
   546         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   547   in find 0 end;
   548 
   549 fun find_index_eq x = find_index (equal x);
   550 
   551 (*find first element satisfying predicate*)
   552 fun find_first _ [] = NONE
   553   | find_first pred (x :: xs) =
   554       if pred x then SOME x else find_first pred xs;
   555 
   556 (*get first element by lookup function*)
   557 fun get_first _ [] = NONE
   558   | get_first f (x :: xs) =
   559       (case f x of
   560         NONE => get_first f xs
   561       | some => some);
   562 
   563 (*flatten a list of lists to a list*)
   564 val flat = List.concat;
   565 
   566 fun unflat (xs :: xss) ys =
   567       let val (ps,qs) = splitAt(length xs,ys)
   568       in ps :: unflat xss qs end
   569   | unflat [] [] = []
   570   | unflat _ _ = raise UnequalLengths;
   571 
   572 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   573   (proc x1; ...; proc xn) for side effects*)
   574 val seq = List.app;
   575 
   576 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   577 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   578   | separate _ xs = xs;
   579 
   580 (*make the list [x, x, ..., x] of length n*)
   581 fun replicate n (x: 'a) : 'a list =
   582   let fun rep (0, xs) = xs
   583         | rep (n, xs) = rep (n - 1, x :: xs)
   584   in
   585     if n < 0 then raise Subscript
   586     else rep (n, [])
   587   end;
   588 
   589 fun translate_string f = String.translate (f o String.str);
   590 
   591 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   592 fun multiply ([], _) = []
   593   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   594 
   595 (*direct product*)
   596 fun product _ [] = []
   597   | product [] _ = []
   598   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   599 
   600 
   601 (* filter *)
   602 
   603 (*copy the list preserving elements that satisfy the predicate*)
   604 val filter = List.filter;
   605 fun filter_out f = filter (not o f);
   606 val mapfilter = List.mapPartial;
   607 
   608 
   609 (* lists of pairs *)
   610 
   611 exception UnequalLengths;
   612 
   613 fun map2 _ ([], []) = []
   614   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   615   | map2 _ _ = raise UnequalLengths;
   616 
   617 fun exists2 _ ([], []) = false
   618   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   619   | exists2 _ _ = raise UnequalLengths;
   620 
   621 fun forall2 _ ([], []) = true
   622   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   623   | forall2 _ _ = raise UnequalLengths;
   624 
   625 fun seq2 _ ([], []) = ()
   626   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   627   | seq2 _ _ = raise UnequalLengths;
   628 
   629 (*combine two lists forming a list of pairs:
   630   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   631 fun [] ~~ [] = []
   632   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   633   | _ ~~ _ = raise UnequalLengths;
   634 
   635 (*inverse of ~~; the old 'split':
   636   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   637 val split_list = ListPair.unzip;
   638 
   639 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   640 
   641 
   642 (* prefixes, suffixes *)
   643 
   644 fun [] prefix _ = true
   645   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   646   | _ prefix _ = false;
   647 
   648 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   649    where xi is the first element that does not satisfy the predicate*)
   650 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   651   let fun take (rxs, []) = (rev rxs, [])
   652         | take (rxs, x :: xs) =
   653             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   654   in  take([], xs)  end;
   655 
   656 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   657    where xi is the last element that does not satisfy the predicate*)
   658 fun take_suffix _ [] = ([], [])
   659   | take_suffix pred (x :: xs) =
   660       (case take_suffix pred xs of
   661         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   662       | (prfx, sffx) => (x :: prfx, sffx));
   663 
   664 fun prefixes1 [] = []
   665   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   666 
   667 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   668 
   669 
   670 
   671 (** integers **)
   672 
   673 fun gcd (x, y) =
   674   let fun gxd x y : IntInf.int =
   675     if y = 0 then x else gxd y (x mod y)
   676   in if x < y then gxd y x else gxd x y end;
   677 
   678 fun lcm (x, y) = (x * y) div gcd (x, y);
   679 
   680 fun inc i = (i := ! i + 1; ! i);
   681 fun dec i = (i := ! i - 1; ! i);
   682 
   683 
   684 (* lists of integers *)
   685 
   686 (*make the list [from, from + 1, ..., to]*)
   687 fun (from upto to) =
   688   if from > to then [] else from :: ((from + 1) upto to);
   689 
   690 (*make the list [from, from - 1, ..., to]*)
   691 fun (from downto to) =
   692   if from < to then [] else from :: ((from - 1) downto to);
   693 
   694 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   695 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   696   | downto0 ([], n) = n = ~1;
   697 
   698 
   699 (* convert integers to strings *)
   700 
   701 (*expand the number in the given base;
   702   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   703 fun radixpand (base, num) : int list =
   704   let
   705     fun radix (n, tail) =
   706       if n < base then n :: tail
   707       else radix (n div base, (n mod base) :: tail)
   708   in radix (num, []) end;
   709 
   710 (*expands a number into a string of characters starting from "zerochar";
   711   example: radixstring (2, "0", 8) gives "1000"*)
   712 fun radixstring (base, zerochar, num) =
   713   let val offset = ord zerochar;
   714       fun chrof n = chr (offset + n)
   715   in implode (map chrof (radixpand (base, num))) end;
   716 
   717 
   718 val string_of_int = Int.toString;
   719 
   720 fun string_of_indexname (a,0) = a
   721   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   722 
   723 
   724 (* read integers *)
   725 
   726 fun read_radixint (radix: int, cs) : int * string list =
   727   let val zero = ord"0"
   728       val limit = zero+radix
   729       fun scan (num,[]) = (num,[])
   730         | scan (num, c::cs) =
   731               if  zero <= ord c  andalso  ord c < limit
   732               then scan(radix*num + ord c - zero, cs)
   733               else (num, c::cs)
   734   in  scan(0,cs)  end;
   735 
   736 fun read_int cs = read_radixint (10, cs);
   737 
   738 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   739 
   740 
   741 
   742 (** strings **)
   743 
   744 (* functions tuned for strings, avoiding explode *)
   745 
   746 fun nth_elem_string (i, str) =
   747   (case try String.substring (str, i, 1) of
   748     SOME s => s
   749   | NONE => raise Subscript);
   750 
   751 fun fold_string f str x0 =
   752   let
   753     val n = size str;
   754     fun iter (x, i) =
   755       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   756   in iter (x0, 0) end;
   757 
   758 fun exists_string pred str =
   759   let
   760     val n = size str;
   761     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   762   in ex 0 end;
   763 
   764 fun forall_string pred = not o exists_string (not o pred);
   765 
   766 (*enclose in brackets*)
   767 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   768 fun unenclose str = String.substring (str, 1, size str - 2);
   769 
   770 (*simple quoting (does not escape special chars)*)
   771 val quote = enclose "\"" "\"";
   772 
   773 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   774 fun space_implode a bs = implode (separate a bs);
   775 
   776 val commas = space_implode ", ";
   777 val commas_quote = commas o map quote;
   778 
   779 (*concatenate messages, one per line, into a string*)
   780 val cat_lines = space_implode "\n";
   781 
   782 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   783 fun space_explode _ "" = []
   784   | space_explode sep str =
   785       let
   786         fun expl chs =
   787           (case take_prefix (not_equal sep) chs of
   788             (cs, []) => [implode cs]
   789           | (cs, _ :: cs') => implode cs :: expl cs');
   790       in expl (explode str) end;
   791 
   792 val split_lines = space_explode "\n";
   793 
   794 fun prefix_lines "" txt = txt
   795   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   796 
   797 fun untabify chs =
   798   let
   799     val tab_width = 8;
   800 
   801     fun untab (_, "\n") = (0, ["\n"])
   802       | untab (pos, "\t") =
   803           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   804       | untab (pos, c) = (pos + 1, [c]);
   805   in
   806     if not (exists (equal "\t") chs) then chs
   807     else flat (#2 (foldl_map untab (0, chs)))
   808   end;
   809 
   810 fun suffix sffx s = s ^ sffx;
   811 
   812 fun unsuffix sffx s =
   813   let val m = size sffx; val n = size s - m in
   814     if n >= 0 andalso String.substring (s, n, m) = sffx then String.substring (s, 0, n)
   815     else raise Fail "unsuffix"
   816   end;
   817 
   818 fun unprefix prfx s =
   819   let val m = size prfx; val n = size s - m in
   820     if String.isPrefix prfx s then String.substring (s, m, n)
   821     else raise Fail "unprefix"
   822   end;
   823 
   824 fun replicate_string 0 _ = ""
   825   | replicate_string 1 a = a
   826   | replicate_string k a =
   827       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   828       else replicate_string (k div 2) (a ^ a) ^ a;
   829 
   830 
   831 
   832 (** lists as sets -- see also Pure/General/ord_list.ML **)
   833 
   834 (*membership in a list*)
   835 fun x mem [] = false
   836   | x mem (y :: ys) = x = y orelse x mem ys;
   837 
   838 (*membership in a list, optimized version for ints*)
   839 fun (x:int) mem_int [] = false
   840   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   841 
   842 (*membership in a list, optimized version for strings*)
   843 fun (x:string) mem_string [] = false
   844   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   845 
   846 (*generalized membership test*)
   847 fun gen_mem eq (x, []) = false
   848   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   849 
   850 (*member, insert, and remove -- with canonical argument order*)
   851 fun member eq xs x = gen_mem eq (x, xs);
   852 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   853 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   854 
   855 (*insertion into list if not already there*)
   856 fun (x ins xs) = if x mem xs then xs else x :: xs;
   857 
   858 (*insertion into list, optimized version for ints*)
   859 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   860 
   861 (*insertion into list, optimized version for strings*)
   862 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   863 
   864 (*generalized insertion*)
   865 fun gen_ins eq (x, xs) = insert eq x xs;
   866 
   867 (*union of sets represented as lists: no repetitions*)
   868 fun xs union [] = xs
   869   | [] union ys = ys
   870   | (x :: xs) union ys = xs union (x ins ys);
   871 
   872 (*union of sets, optimized version for ints*)
   873 fun (xs:int list) union_int [] = xs
   874   | [] union_int ys = ys
   875   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   876 
   877 (*union of sets, optimized version for strings*)
   878 fun (xs:string list) union_string [] = xs
   879   | [] union_string ys = ys
   880   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   881 
   882 (*generalized union*)
   883 fun gen_union eq (xs, []) = xs
   884   | gen_union eq ([], ys) = ys
   885   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   886 
   887 
   888 (*intersection*)
   889 fun [] inter ys = []
   890   | (x :: xs) inter ys =
   891       if x mem ys then x :: (xs inter ys) else xs inter ys;
   892 
   893 (*intersection, optimized version for ints*)
   894 fun ([]:int list) inter_int ys = []
   895   | (x :: xs) inter_int ys =
   896       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   897 
   898 (*intersection, optimized version for strings *)
   899 fun ([]:string list) inter_string ys = []
   900   | (x :: xs) inter_string ys =
   901       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   902 
   903 (*generalized intersection*)
   904 fun gen_inter eq ([], ys) = []
   905   | gen_inter eq (x::xs, ys) =
   906       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   907                            else      gen_inter eq (xs, ys);
   908 
   909 
   910 (*subset*)
   911 fun [] subset ys = true
   912   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   913 
   914 (*subset, optimized version for ints*)
   915 fun ([]: int list) subset_int ys = true
   916   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   917 
   918 (*subset, optimized version for strings*)
   919 fun ([]: string list) subset_string ys = true
   920   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   921 
   922 (*set equality*)
   923 fun eq_set (xs, ys) =
   924   xs = ys orelse (xs subset ys andalso ys subset xs);
   925 
   926 (*set equality for strings*)
   927 fun eq_set_string ((xs: string list), ys) =
   928   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   929 
   930 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   931 
   932 
   933 (*removing an element from a list WITHOUT duplicates*)
   934 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   935   | [] \ x = [];
   936 
   937 fun ys \\ xs = foldl (op \) (ys,xs);
   938 
   939 (*removing an element from a list -- possibly WITH duplicates*)
   940 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   941 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   942 
   943 (*makes a list of the distinct members of the input; preserves order, takes
   944   first of equal elements*)
   945 fun gen_distinct eq lst =
   946   let
   947     val memb = gen_mem eq;
   948 
   949     fun dist (rev_seen, []) = rev rev_seen
   950       | dist (rev_seen, x :: xs) =
   951           if memb (x, rev_seen) then dist (rev_seen, xs)
   952           else dist (x :: rev_seen, xs);
   953   in
   954     dist ([], lst)
   955   end;
   956 
   957 fun distinct l = gen_distinct (op =) l;
   958 
   959 
   960 (*returns the tail beginning with the first repeated element, or []*)
   961 fun findrep [] = []
   962   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   963 
   964 
   965 (*returns a list containing all repeated elements exactly once; preserves
   966   order, takes first of equal elements*)
   967 fun gen_duplicates eq lst =
   968   let
   969     val memb = gen_mem eq;
   970 
   971     fun dups (rev_dups, []) = rev rev_dups
   972       | dups (rev_dups, x :: xs) =
   973           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   974             dups (rev_dups, xs)
   975           else dups (x :: rev_dups, xs);
   976   in
   977     dups ([], lst)
   978   end;
   979 
   980 fun duplicates l = gen_duplicates (op =) l;
   981 
   982 
   983 
   984 (** association lists **)
   985 
   986 (*association list lookup*)
   987 fun assoc ([], key) = NONE
   988   | assoc ((keyi, xi) :: pairs, key) =
   989       if key = keyi then SOME xi else assoc (pairs, key);
   990 
   991 (*association list lookup, optimized version for ints*)
   992 fun assoc_int ([], (key:int)) = NONE
   993   | assoc_int ((keyi, xi) :: pairs, key) =
   994       if key = keyi then SOME xi else assoc_int (pairs, key);
   995 
   996 (*association list lookup, optimized version for strings*)
   997 fun assoc_string ([], (key:string)) = NONE
   998   | assoc_string ((keyi, xi) :: pairs, key) =
   999       if key = keyi then SOME xi else assoc_string (pairs, key);
  1000 
  1001 (*association list lookup, optimized version for string*ints*)
  1002 fun assoc_string_int ([], (key:string*int)) = NONE
  1003   | assoc_string_int ((keyi, xi) :: pairs, key) =
  1004       if key = keyi then SOME xi else assoc_string_int (pairs, key);
  1005 
  1006 fun assocs ps x =
  1007   (case assoc (ps, x) of
  1008     NONE => []
  1009   | SOME ys => ys);
  1010 
  1011 (*two-fold association list lookup*)
  1012 fun assoc2 (aal, (key1, key2)) =
  1013   (case assoc (aal, key1) of
  1014     SOME al => assoc (al, key2)
  1015   | NONE => NONE);
  1016 
  1017 (*generalized association list lookup*)
  1018 fun gen_assoc eq ([], key) = NONE
  1019   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1020       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1021 
  1022 (*association list update*)
  1023 fun overwrite (al, p as (key, _)) =
  1024   let fun over ((q as (keyi, _)) :: pairs) =
  1025             if keyi = key then p :: pairs else q :: (over pairs)
  1026         | over [] = [p]
  1027   in over al end;
  1028 
  1029 fun gen_overwrite eq (al, p as (key, _)) =
  1030   let fun over ((q as (keyi, _)) :: pairs) =
  1031             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1032         | over [] = [p]
  1033   in over al end;
  1034 
  1035 
  1036 (* lists as tables *)
  1037 
  1038 fun gen_merge_lists _ xs [] = xs
  1039   | gen_merge_lists _ [] ys = ys
  1040   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1041 
  1042 fun gen_merge_lists' _ xs [] = xs
  1043   | gen_merge_lists' _ [] ys = ys
  1044   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1045 
  1046 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1047 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1048 fun merge_alists al = gen_merge_lists eq_fst al;
  1049 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1050 
  1051 
  1052 
  1053 (** balanced trees **)
  1054 
  1055 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1056 
  1057 (*balanced folding; avoids deep nesting*)
  1058 fun fold_bal f [x] = x
  1059   | fold_bal f [] = raise Balance
  1060   | fold_bal f xs =
  1061       let val (ps,qs) = splitAt(length xs div 2, xs)
  1062       in  f (fold_bal f ps, fold_bal f qs)  end;
  1063 
  1064 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1065 fun access_bal (f, g, x) n i =
  1066   let fun acc n i =     (*1<=i<=n*)
  1067           if n=1 then x else
  1068           let val n2 = n div 2
  1069           in  if i<=n2 then f (acc n2 i)
  1070                        else g (acc (n-n2) (i-n2))
  1071           end
  1072   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1073 
  1074 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1075 fun accesses_bal (f, g, x) n =
  1076   let fun acc n =
  1077           if n=1 then [x] else
  1078           let val n2 = n div 2
  1079               val acc2 = acc n2
  1080           in  if n-n2=n2 then map f acc2 @ map g acc2
  1081                          else map f acc2 @ map g (acc (n-n2)) end
  1082   in  if 1<=n then acc n else raise Balance  end;
  1083 
  1084 
  1085 
  1086 (** orders **)
  1087 
  1088 fun rev_order LESS = GREATER
  1089   | rev_order EQUAL = EQUAL
  1090   | rev_order GREATER = LESS;
  1091 
  1092 (*assume rel is a linear strict order*)
  1093 fun make_ord rel (x, y) =
  1094   if rel (x, y) then LESS
  1095   else if rel (y, x) then GREATER
  1096   else EQUAL;
  1097 
  1098 val int_ord = Int.compare;
  1099 val string_ord = String.compare;
  1100 
  1101 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1102   | option_ord _ (NONE, NONE) = EQUAL
  1103   | option_ord _ (NONE, SOME _) = LESS
  1104   | option_ord _ (SOME _, NONE) = GREATER;
  1105 
  1106 (*lexicographic product*)
  1107 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1108   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1109 
  1110 (*dictionary order -- in general NOT well-founded!*)
  1111 fun dict_ord _ ([], []) = EQUAL
  1112   | dict_ord _ ([], _ :: _) = LESS
  1113   | dict_ord _ (_ :: _, []) = GREATER
  1114   | dict_ord elem_ord (x :: xs, y :: ys) =
  1115       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1116 
  1117 (*lexicographic product of lists*)
  1118 fun list_ord elem_ord (xs, ys) =
  1119   prod_ord int_ord (dict_ord elem_ord) ((length xs, xs), (length ys, ys));
  1120 
  1121 
  1122 (* sorting *)
  1123 
  1124 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1125 fun sort ord =
  1126   let
  1127     fun qsort xs =
  1128       let val len = length xs in
  1129         if len <= 1 then xs
  1130         else
  1131           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1132             qsort lts @ eqs @ qsort gts
  1133           end
  1134       end
  1135     and part _ [] = ([], [], [])
  1136       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1137     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1138       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1139       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1140   in qsort end;
  1141 
  1142 (*sort strings*)
  1143 val sort_strings = sort string_ord;
  1144 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1145 
  1146 fun unique_strings ([]: string list) = []
  1147   | unique_strings [x] = [x]
  1148   | unique_strings (x :: y :: ys) =
  1149       if x = y then unique_strings (y :: ys)
  1150       else x :: unique_strings (y :: ys);
  1151 
  1152 
  1153 (** random numbers **)
  1154 
  1155 exception RANDOM;
  1156 
  1157 fun rmod x y = x - y * Real.realFloor (x / y);
  1158 
  1159 local
  1160   val a = 16807.0;
  1161   val m = 2147483647.0;
  1162   val random_seed = ref 1.0;
  1163 in
  1164 
  1165 fun random () =
  1166   let val r = rmod (a * !random_seed) m
  1167   in (random_seed := r; r) end;
  1168 
  1169 end;
  1170 
  1171 fun random_range l h =
  1172   if h < l orelse l < 0 then raise RANDOM
  1173   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1174 
  1175 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1176 
  1177 fun frequency xs =
  1178   let
  1179     val sum = foldl op + (0, map fst xs);
  1180     fun pick n ((k, x) :: xs) =
  1181       if n <= k then x else pick (n - k) xs
  1182   in pick (random_range 1 sum) xs end;
  1183 
  1184 
  1185 (** current directory **)
  1186 
  1187 val cd = OS.FileSys.chDir;
  1188 val pwd = OS.FileSys.getDir;
  1189 
  1190 
  1191 
  1192 (** rational numbers **)
  1193 
  1194 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1195 
  1196 exception RAT of string;
  1197 
  1198 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1199 
  1200 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1201   let val absp = abs p
  1202       val m = gcd(absp,q)
  1203   in Rat(a = (0 <= p), absp div m, q div m) end;
  1204 
  1205 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1206   let val den = lcm(q,s)
  1207       val p = p*(den div q) and r = r*(den div s)
  1208       val num = (if a then p else ~p) + (if b then r else ~r)
  1209   in ratnorm(true,num,den) end;
  1210 
  1211 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1212 
  1213 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1214 
  1215 fun int_ratdiv(p,q) =
  1216   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1217 
  1218 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1219 
  1220 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1221 
  1222 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1223 
  1224 
  1225 (** misc **)
  1226 
  1227 (*use the keyfun to make a list of (x, key) pairs*)
  1228 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1229   let fun keypair x = (x, keyfun x)
  1230   in map keypair end;
  1231 
  1232 (*given a list of (x, key) pairs and a searchkey
  1233   return the list of xs from each pair whose key equals searchkey*)
  1234 fun keyfilter [] searchkey = []
  1235   | keyfilter ((x, key) :: pairs) searchkey =
  1236       if key = searchkey then x :: keyfilter pairs searchkey
  1237       else keyfilter pairs searchkey;
  1238 
  1239 
  1240 (*Partition list into elements that satisfy predicate and those that don't.
  1241   Preserves order of elements in both lists.*)
  1242 val partition = List.partition;
  1243 
  1244 
  1245 fun partition_eq (eq:'a * 'a -> bool) =
  1246     let fun part [] = []
  1247           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1248                            in (x::xs)::(part xs') end
  1249     in part end;
  1250 
  1251 
  1252 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1253    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1254 fun partition_list p i j =
  1255   let fun part k xs =
  1256             if k>j then
  1257               (case xs of [] => []
  1258                          | _ => raise Fail "partition_list")
  1259             else
  1260             let val (ns, rest) = partition (p k) xs;
  1261             in  ns :: part(k+1)rest  end
  1262   in  part i end;
  1263 
  1264 
  1265 (* generating identifiers *)
  1266 
  1267 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1268 local
  1269 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1270 fun char i =      if i<26 then chr (ord "A" + i)
  1271              else if i<52 then chr (ord "a" + i - 26)
  1272              else if i<62 then chr (ord"0" + i - 52)
  1273              else if i=62 then "_"
  1274              else  (*i=63*)    "'";
  1275 
  1276 val charVec = Vector.tabulate (64, char);
  1277 
  1278 fun newid n =
  1279   let
  1280   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1281 
  1282 val seedr = ref 0;
  1283 
  1284 in
  1285 
  1286 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1287 
  1288 end;
  1289 
  1290 
  1291 (* lexical scanning *)
  1292 
  1293 (*scan a list of characters into "words" composed of "letters" (recognized by
  1294   is_let) and separated by any number of non-"letters"*)
  1295 fun scanwords is_let cs =
  1296   let fun scan1 [] = []
  1297         | scan1 cs =
  1298             let val (lets, rest) = take_prefix is_let cs
  1299             in implode lets :: scanwords is_let rest end;
  1300   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1301 
  1302 
  1303 (* stamps and serial numbers *)
  1304 
  1305 type stamp = unit ref;
  1306 val stamp: unit -> stamp = ref;
  1307 
  1308 type serial = int;
  1309 local val count = ref 0
  1310 in fun serial () = inc count end;
  1311 
  1312 
  1313 (* generic objects *)
  1314 
  1315 (*note that the builtin exception datatype may be extended by new
  1316   constructors at any time*)
  1317 structure Object = struct type T = exn end;
  1318 
  1319 end;
  1320 
  1321 structure BasicLibrary: BASIC_LIBRARY = Library;
  1322 open BasicLibrary;