src/HOL/Analysis/Cartesian_Euclidean_Space.thy
author immler
Mon Feb 26 09:58:47 2018 +0100 (17 months ago)
changeset 67728 d97a28a006f9
parent 67719 bffb7482faaa
child 67731 184c293f0a33
permissions -rw-r--r--
generalized
     1 section \<open>Instantiates the finite Cartesian product of Euclidean spaces as a Euclidean space.\<close>
     2 
     3 theory Cartesian_Euclidean_Space
     4 imports Finite_Cartesian_Product Derivative
     5 begin
     6 
     7 lemma subspace_special_hyperplane: "subspace {x. x $ k = 0}"
     8   by (simp add: subspace_def)
     9 
    10 lemma sum_mult_product:
    11   "sum h {..<A * B :: nat} = (\<Sum>i\<in>{..<A}. \<Sum>j\<in>{..<B}. h (j + i * B))"
    12   unfolding sum_nat_group[of h B A, unfolded atLeast0LessThan, symmetric]
    13 proof (rule sum.cong, simp, rule sum.reindex_cong)
    14   fix i
    15   show "inj_on (\<lambda>j. j + i * B) {..<B}" by (auto intro!: inj_onI)
    16   show "{i * B..<i * B + B} = (\<lambda>j. j + i * B) ` {..<B}"
    17   proof safe
    18     fix j assume "j \<in> {i * B..<i * B + B}"
    19     then show "j \<in> (\<lambda>j. j + i * B) ` {..<B}"
    20       by (auto intro!: image_eqI[of _ _ "j - i * B"])
    21   qed simp
    22 qed simp
    23 
    24 subsection\<open>Basic componentwise operations on vectors.\<close>
    25 
    26 instantiation vec :: (times, finite) times
    27 begin
    28 
    29 definition "( * ) \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) * (y$i)))"
    30 instance ..
    31 
    32 end
    33 
    34 instantiation vec :: (one, finite) one
    35 begin
    36 
    37 definition "1 \<equiv> (\<chi> i. 1)"
    38 instance ..
    39 
    40 end
    41 
    42 instantiation vec :: (ord, finite) ord
    43 begin
    44 
    45 definition "x \<le> y \<longleftrightarrow> (\<forall>i. x$i \<le> y$i)"
    46 definition "x < (y::'a^'b) \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
    47 instance ..
    48 
    49 end
    50 
    51 text\<open>The ordering on one-dimensional vectors is linear.\<close>
    52 
    53 class cart_one =
    54   assumes UNIV_one: "card (UNIV :: 'a set) = Suc 0"
    55 begin
    56 
    57 subclass finite
    58 proof
    59   from UNIV_one show "finite (UNIV :: 'a set)"
    60     by (auto intro!: card_ge_0_finite)
    61 qed
    62 
    63 end
    64 
    65 instance vec:: (order, finite) order
    66   by standard (auto simp: less_eq_vec_def less_vec_def vec_eq_iff
    67       intro: order.trans order.antisym order.strict_implies_order)
    68 
    69 instance vec :: (linorder, cart_one) linorder
    70 proof
    71   obtain a :: 'b where all: "\<And>P. (\<forall>i. P i) \<longleftrightarrow> P a"
    72   proof -
    73     have "card (UNIV :: 'b set) = Suc 0" by (rule UNIV_one)
    74     then obtain b :: 'b where "UNIV = {b}" by (auto iff: card_Suc_eq)
    75     then have "\<And>P. (\<forall>i\<in>UNIV. P i) \<longleftrightarrow> P b" by auto
    76     then show thesis by (auto intro: that)
    77   qed
    78   fix x y :: "'a^'b::cart_one"
    79   note [simp] = less_eq_vec_def less_vec_def all vec_eq_iff field_simps
    80   show "x \<le> y \<or> y \<le> x" by auto
    81 qed
    82 
    83 text\<open>Constant Vectors\<close>
    84 
    85 definition "vec x = (\<chi> i. x)"
    86 
    87 lemma interval_cbox_cart: "{a::real^'n..b} = cbox a b"
    88   by (auto simp add: less_eq_vec_def mem_box Basis_vec_def inner_axis)
    89 
    90 text\<open>Also the scalar-vector multiplication.\<close>
    91 
    92 definition vector_scalar_mult:: "'a::times \<Rightarrow> 'a ^ 'n \<Rightarrow> 'a ^ 'n" (infixl "*s" 70)
    93   where "c *s x = (\<chi> i. c * (x$i))"
    94 
    95 
    96 subsection \<open>A naive proof procedure to lift really trivial arithmetic stuff from the basis of the vector space.\<close>
    97 
    98 lemma sum_cong_aux:
    99   "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> sum f A = sum g A"
   100   by (auto intro: sum.cong)
   101 
   102 hide_fact (open) sum_cong_aux
   103 
   104 method_setup vector = \<open>
   105 let
   106   val ss1 =
   107     simpset_of (put_simpset HOL_basic_ss @{context}
   108       addsimps [@{thm sum.distrib} RS sym,
   109       @{thm sum_subtractf} RS sym, @{thm sum_distrib_left},
   110       @{thm sum_distrib_right}, @{thm sum_negf} RS sym])
   111   val ss2 =
   112     simpset_of (@{context} addsimps
   113              [@{thm plus_vec_def}, @{thm times_vec_def},
   114               @{thm minus_vec_def}, @{thm uminus_vec_def},
   115               @{thm one_vec_def}, @{thm zero_vec_def}, @{thm vec_def},
   116               @{thm scaleR_vec_def},
   117               @{thm vec_lambda_beta}, @{thm vector_scalar_mult_def}])
   118   fun vector_arith_tac ctxt ths =
   119     simp_tac (put_simpset ss1 ctxt)
   120     THEN' (fn i => resolve_tac ctxt @{thms Cartesian_Euclidean_Space.sum_cong_aux} i
   121          ORELSE resolve_tac ctxt @{thms sum.neutral} i
   122          ORELSE simp_tac (put_simpset HOL_basic_ss ctxt addsimps [@{thm vec_eq_iff}]) i)
   123     (* THEN' TRY o clarify_tac HOL_cs  THEN' (TRY o rtac @{thm iffI}) *)
   124     THEN' asm_full_simp_tac (put_simpset ss2 ctxt addsimps ths)
   125 in
   126   Attrib.thms >> (fn ths => fn ctxt => SIMPLE_METHOD' (vector_arith_tac ctxt ths))
   127 end
   128 \<close> "lift trivial vector statements to real arith statements"
   129 
   130 lemma vec_0[simp]: "vec 0 = 0" by vector
   131 lemma vec_1[simp]: "vec 1 = 1" by vector
   132 
   133 lemma vec_inj[simp]: "vec x = vec y \<longleftrightarrow> x = y" by vector
   134 
   135 lemma vec_in_image_vec: "vec x \<in> (vec ` S) \<longleftrightarrow> x \<in> S" by auto
   136 
   137 lemma vec_add: "vec(x + y) = vec x + vec y"  by vector
   138 lemma vec_sub: "vec(x - y) = vec x - vec y" by vector
   139 lemma vec_cmul: "vec(c * x) = c *s vec x " by vector
   140 lemma vec_neg: "vec(- x) = - vec x " by vector
   141 
   142 lemma vec_sum:
   143   assumes "finite S"
   144   shows "vec(sum f S) = sum (vec \<circ> f) S"
   145   using assms
   146 proof induct
   147   case empty
   148   then show ?case by simp
   149 next
   150   case insert
   151   then show ?case by (auto simp add: vec_add)
   152 qed
   153 
   154 text\<open>Obvious "component-pushing".\<close>
   155 
   156 lemma vec_component [simp]: "vec x $ i = x"
   157   by vector
   158 
   159 lemma vector_mult_component [simp]: "(x * y)$i = x$i * y$i"
   160   by vector
   161 
   162 lemma vector_smult_component [simp]: "(c *s y)$i = c * (y$i)"
   163   by vector
   164 
   165 lemma cond_component: "(if b then x else y)$i = (if b then x$i else y$i)" by vector
   166 
   167 lemmas vector_component =
   168   vec_component vector_add_component vector_mult_component
   169   vector_smult_component vector_minus_component vector_uminus_component
   170   vector_scaleR_component cond_component
   171 
   172 
   173 subsection \<open>Some frequently useful arithmetic lemmas over vectors.\<close>
   174 
   175 instance vec :: (semigroup_mult, finite) semigroup_mult
   176   by standard (vector mult.assoc)
   177 
   178 instance vec :: (monoid_mult, finite) monoid_mult
   179   by standard vector+
   180 
   181 instance vec :: (ab_semigroup_mult, finite) ab_semigroup_mult
   182   by standard (vector mult.commute)
   183 
   184 instance vec :: (comm_monoid_mult, finite) comm_monoid_mult
   185   by standard vector
   186 
   187 instance vec :: (semiring, finite) semiring
   188   by standard (vector field_simps)+
   189 
   190 instance vec :: (semiring_0, finite) semiring_0
   191   by standard (vector field_simps)+
   192 instance vec :: (semiring_1, finite) semiring_1
   193   by standard vector
   194 instance vec :: (comm_semiring, finite) comm_semiring
   195   by standard (vector field_simps)+
   196 
   197 instance vec :: (comm_semiring_0, finite) comm_semiring_0 ..
   198 instance vec :: (cancel_comm_monoid_add, finite) cancel_comm_monoid_add ..
   199 instance vec :: (semiring_0_cancel, finite) semiring_0_cancel ..
   200 instance vec :: (comm_semiring_0_cancel, finite) comm_semiring_0_cancel ..
   201 instance vec :: (ring, finite) ring ..
   202 instance vec :: (semiring_1_cancel, finite) semiring_1_cancel ..
   203 instance vec :: (comm_semiring_1, finite) comm_semiring_1 ..
   204 
   205 instance vec :: (ring_1, finite) ring_1 ..
   206 
   207 instance vec :: (real_algebra, finite) real_algebra
   208   by standard (simp_all add: vec_eq_iff)
   209 
   210 instance vec :: (real_algebra_1, finite) real_algebra_1 ..
   211 
   212 lemma of_nat_index: "(of_nat n :: 'a::semiring_1 ^'n)$i = of_nat n"
   213 proof (induct n)
   214   case 0
   215   then show ?case by vector
   216 next
   217   case Suc
   218   then show ?case by vector
   219 qed
   220 
   221 lemma one_index [simp]: "(1 :: 'a :: one ^ 'n) $ i = 1"
   222   by vector
   223 
   224 lemma neg_one_index [simp]: "(- 1 :: 'a :: {one, uminus} ^ 'n) $ i = - 1"
   225   by vector
   226 
   227 instance vec :: (semiring_char_0, finite) semiring_char_0
   228 proof
   229   fix m n :: nat
   230   show "inj (of_nat :: nat \<Rightarrow> 'a ^ 'b)"
   231     by (auto intro!: injI simp add: vec_eq_iff of_nat_index)
   232 qed
   233 
   234 instance vec :: (numeral, finite) numeral ..
   235 instance vec :: (semiring_numeral, finite) semiring_numeral ..
   236 
   237 lemma numeral_index [simp]: "numeral w $ i = numeral w"
   238   by (induct w) (simp_all only: numeral.simps vector_add_component one_index)
   239 
   240 lemma neg_numeral_index [simp]: "- numeral w $ i = - numeral w"
   241   by (simp only: vector_uminus_component numeral_index)
   242 
   243 instance vec :: (comm_ring_1, finite) comm_ring_1 ..
   244 instance vec :: (ring_char_0, finite) ring_char_0 ..
   245 
   246 lemma vector_smult_assoc: "a *s (b *s x) = ((a::'a::semigroup_mult) * b) *s x"
   247   by (vector mult.assoc)
   248 lemma vector_sadd_rdistrib: "((a::'a::semiring) + b) *s x = a *s x + b *s x"
   249   by (vector field_simps)
   250 lemma vector_add_ldistrib: "(c::'a::semiring) *s (x + y) = c *s x + c *s y"
   251   by (vector field_simps)
   252 lemma vector_smult_lzero[simp]: "(0::'a::mult_zero) *s x = 0" by vector
   253 lemma vector_smult_lid[simp]: "(1::'a::monoid_mult) *s x = x" by vector
   254 lemma vector_ssub_ldistrib: "(c::'a::ring) *s (x - y) = c *s x - c *s y"
   255   by (vector field_simps)
   256 lemma vector_smult_rneg: "(c::'a::ring) *s -x = -(c *s x)" by vector
   257 lemma vector_smult_lneg: "- (c::'a::ring) *s x = -(c *s x)" by vector
   258 lemma vector_sneg_minus1: "-x = (-1::'a::ring_1) *s x" by vector
   259 lemma vector_smult_rzero[simp]: "c *s 0 = (0::'a::mult_zero ^ 'n)" by vector
   260 lemma vector_sub_rdistrib: "((a::'a::ring) - b) *s x = a *s x - b *s x"
   261   by (vector field_simps)
   262 
   263 lemma vec_eq[simp]: "(vec m = vec n) \<longleftrightarrow> (m = n)"
   264   by (simp add: vec_eq_iff)
   265 
   266 lemma norm_eq_0_imp: "norm x = 0 ==> x = (0::real ^'n)" by (metis norm_eq_zero)
   267 
   268 lemma norm_axis_1 [simp]: "norm (axis m (1::real)) = 1"
   269   by (simp add: inner_axis' norm_eq_1)
   270 
   271 lemma vector_mul_eq_0[simp]: "(a *s x = 0) \<longleftrightarrow> a = (0::'a::idom) \<or> x = 0"
   272   by vector
   273 
   274 lemma vector_mul_lcancel[simp]: "a *s x = a *s y \<longleftrightarrow> a = (0::real) \<or> x = y"
   275   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_ssub_ldistrib)
   276 
   277 lemma vector_mul_rcancel[simp]: "a *s x = b *s x \<longleftrightarrow> (a::real) = b \<or> x = 0"
   278   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_sub_rdistrib)
   279 
   280 lemma vector_mul_lcancel_imp: "a \<noteq> (0::real) ==>  a *s x = a *s y ==> (x = y)"
   281   by (metis vector_mul_lcancel)
   282 
   283 lemma vector_mul_rcancel_imp: "x \<noteq> 0 \<Longrightarrow> (a::real) *s x = b *s x ==> a = b"
   284   by (metis vector_mul_rcancel)
   285 
   286 lemma component_le_norm_cart: "\<bar>x$i\<bar> <= norm x"
   287   apply (simp add: norm_vec_def)
   288   apply (rule member_le_L2_set, simp_all)
   289   done
   290 
   291 lemma norm_bound_component_le_cart: "norm x <= e ==> \<bar>x$i\<bar> <= e"
   292   by (metis component_le_norm_cart order_trans)
   293 
   294 lemma norm_bound_component_lt_cart: "norm x < e ==> \<bar>x$i\<bar> < e"
   295   by (metis component_le_norm_cart le_less_trans)
   296 
   297 lemma norm_le_l1_cart: "norm x <= sum(\<lambda>i. \<bar>x$i\<bar>) UNIV"
   298   by (simp add: norm_vec_def L2_set_le_sum)
   299 
   300 lemma scalar_mult_eq_scaleR: "c *s x = c *\<^sub>R x"
   301   unfolding scaleR_vec_def vector_scalar_mult_def by simp
   302 
   303 lemma dist_mul[simp]: "dist (c *s x) (c *s y) = \<bar>c\<bar> * dist x y"
   304   unfolding dist_norm scalar_mult_eq_scaleR
   305   unfolding scaleR_right_diff_distrib[symmetric] by simp
   306 
   307 lemma sum_component [simp]:
   308   fixes f:: " 'a \<Rightarrow> ('b::comm_monoid_add) ^'n"
   309   shows "(sum f S)$i = sum (\<lambda>x. (f x)$i) S"
   310 proof (cases "finite S")
   311   case True
   312   then show ?thesis by induct simp_all
   313 next
   314   case False
   315   then show ?thesis by simp
   316 qed
   317 
   318 lemma sum_eq: "sum f S = (\<chi> i. sum (\<lambda>x. (f x)$i ) S)"
   319   by (simp add: vec_eq_iff)
   320 
   321 lemma sum_cmul:
   322   fixes f:: "'c \<Rightarrow> ('a::semiring_1)^'n"
   323   shows "sum (\<lambda>x. c *s f x) S = c *s sum f S"
   324   by (simp add: vec_eq_iff sum_distrib_left)
   325 
   326 lemma sum_norm_allsubsets_bound_cart:
   327   fixes f:: "'a \<Rightarrow> real ^'n"
   328   assumes fP: "finite P" and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (sum f Q) \<le> e"
   329   shows "sum (\<lambda>x. norm (f x)) P \<le> 2 * real CARD('n) *  e"
   330   using sum_norm_allsubsets_bound[OF assms]
   331   by simp
   332 
   333 subsection\<open>Closures and interiors of halfspaces\<close>
   334 
   335 lemma interior_halfspace_le [simp]:
   336   assumes "a \<noteq> 0"
   337     shows "interior {x. a \<bullet> x \<le> b} = {x. a \<bullet> x < b}"
   338 proof -
   339   have *: "a \<bullet> x < b" if x: "x \<in> S" and S: "S \<subseteq> {x. a \<bullet> x \<le> b}" and "open S" for S x
   340   proof -
   341     obtain e where "e>0" and e: "cball x e \<subseteq> S"
   342       using \<open>open S\<close> open_contains_cball x by blast
   343     then have "x + (e / norm a) *\<^sub>R a \<in> cball x e"
   344       by (simp add: dist_norm)
   345     then have "x + (e / norm a) *\<^sub>R a \<in> S"
   346       using e by blast
   347     then have "x + (e / norm a) *\<^sub>R a \<in> {x. a \<bullet> x \<le> b}"
   348       using S by blast
   349     moreover have "e * (a \<bullet> a) / norm a > 0"
   350       by (simp add: \<open>0 < e\<close> assms)
   351     ultimately show ?thesis
   352       by (simp add: algebra_simps)
   353   qed
   354   show ?thesis
   355     by (rule interior_unique) (auto simp: open_halfspace_lt *)
   356 qed
   357 
   358 lemma interior_halfspace_ge [simp]:
   359    "a \<noteq> 0 \<Longrightarrow> interior {x. a \<bullet> x \<ge> b} = {x. a \<bullet> x > b}"
   360 using interior_halfspace_le [of "-a" "-b"] by simp
   361 
   362 lemma interior_halfspace_component_le [simp]:
   363      "interior {x. x$k \<le> a} = {x :: (real,'n::finite) vec. x$k < a}" (is "?LE")
   364   and interior_halfspace_component_ge [simp]:
   365      "interior {x. x$k \<ge> a} = {x :: (real,'n::finite) vec. x$k > a}" (is "?GE")
   366 proof -
   367   have "axis k (1::real) \<noteq> 0"
   368     by (simp add: axis_def vec_eq_iff)
   369   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   370     by (simp add: cart_eq_inner_axis inner_commute)
   371   ultimately show ?LE ?GE
   372     using interior_halfspace_le [of "axis k (1::real)" a]
   373           interior_halfspace_ge [of "axis k (1::real)" a] by auto
   374 qed
   375 
   376 lemma closure_halfspace_lt [simp]:
   377   assumes "a \<noteq> 0"
   378     shows "closure {x. a \<bullet> x < b} = {x. a \<bullet> x \<le> b}"
   379 proof -
   380   have [simp]: "-{x. a \<bullet> x < b} = {x. a \<bullet> x \<ge> b}"
   381     by (force simp:)
   382   then show ?thesis
   383     using interior_halfspace_ge [of a b] assms
   384     by (force simp: closure_interior)
   385 qed
   386 
   387 lemma closure_halfspace_gt [simp]:
   388    "a \<noteq> 0 \<Longrightarrow> closure {x. a \<bullet> x > b} = {x. a \<bullet> x \<ge> b}"
   389 using closure_halfspace_lt [of "-a" "-b"] by simp
   390 
   391 lemma closure_halfspace_component_lt [simp]:
   392      "closure {x. x$k < a} = {x :: (real,'n::finite) vec. x$k \<le> a}" (is "?LE")
   393   and closure_halfspace_component_gt [simp]:
   394      "closure {x. x$k > a} = {x :: (real,'n::finite) vec. x$k \<ge> a}" (is "?GE")
   395 proof -
   396   have "axis k (1::real) \<noteq> 0"
   397     by (simp add: axis_def vec_eq_iff)
   398   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   399     by (simp add: cart_eq_inner_axis inner_commute)
   400   ultimately show ?LE ?GE
   401     using closure_halfspace_lt [of "axis k (1::real)" a]
   402           closure_halfspace_gt [of "axis k (1::real)" a] by auto
   403 qed
   404 
   405 lemma interior_hyperplane [simp]:
   406   assumes "a \<noteq> 0"
   407     shows "interior {x. a \<bullet> x = b} = {}"
   408 proof -
   409   have [simp]: "{x. a \<bullet> x = b} = {x. a \<bullet> x \<le> b} \<inter> {x. a \<bullet> x \<ge> b}"
   410     by (force simp:)
   411   then show ?thesis
   412     by (auto simp: assms)
   413 qed
   414 
   415 lemma frontier_halfspace_le:
   416   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   417     shows "frontier {x. a \<bullet> x \<le> b} = {x. a \<bullet> x = b}"
   418 proof (cases "a = 0")
   419   case True with assms show ?thesis by simp
   420 next
   421   case False then show ?thesis
   422     by (force simp: frontier_def closed_halfspace_le)
   423 qed
   424 
   425 lemma frontier_halfspace_ge:
   426   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   427     shows "frontier {x. a \<bullet> x \<ge> b} = {x. a \<bullet> x = b}"
   428 proof (cases "a = 0")
   429   case True with assms show ?thesis by simp
   430 next
   431   case False then show ?thesis
   432     by (force simp: frontier_def closed_halfspace_ge)
   433 qed
   434 
   435 lemma frontier_halfspace_lt:
   436   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   437     shows "frontier {x. a \<bullet> x < b} = {x. a \<bullet> x = b}"
   438 proof (cases "a = 0")
   439   case True with assms show ?thesis by simp
   440 next
   441   case False then show ?thesis
   442     by (force simp: frontier_def interior_open open_halfspace_lt)
   443 qed
   444 
   445 lemma frontier_halfspace_gt:
   446   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   447     shows "frontier {x. a \<bullet> x > b} = {x. a \<bullet> x = b}"
   448 proof (cases "a = 0")
   449   case True with assms show ?thesis by simp
   450 next
   451   case False then show ?thesis
   452     by (force simp: frontier_def interior_open open_halfspace_gt)
   453 qed
   454 
   455 lemma interior_standard_hyperplane:
   456    "interior {x :: (real,'n::finite) vec. x$k = a} = {}"
   457 proof -
   458   have "axis k (1::real) \<noteq> 0"
   459     by (simp add: axis_def vec_eq_iff)
   460   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   461     by (simp add: cart_eq_inner_axis inner_commute)
   462   ultimately show ?thesis
   463     using interior_hyperplane [of "axis k (1::real)" a]
   464     by force
   465 qed
   466 
   467 subsection \<open>Matrix operations\<close>
   468 
   469 text\<open>Matrix notation. NB: an MxN matrix is of type @{typ "'a^'n^'m"}, not @{typ "'a^'m^'n"}\<close>
   470 
   471 definition matrix_matrix_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'p^'n \<Rightarrow> 'a ^ 'p ^'m"
   472     (infixl "**" 70)
   473   where "m ** m' == (\<chi> i j. sum (\<lambda>k. ((m$i)$k) * ((m'$k)$j)) (UNIV :: 'n set)) ::'a ^ 'p ^'m"
   474 
   475 definition matrix_vector_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n \<Rightarrow> 'a ^ 'm"
   476     (infixl "*v" 70)
   477   where "m *v x \<equiv> (\<chi> i. sum (\<lambda>j. ((m$i)$j) * (x$j)) (UNIV ::'n set)) :: 'a^'m"
   478 
   479 definition vector_matrix_mult :: "'a ^ 'm \<Rightarrow> ('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n "
   480     (infixl "v*" 70)
   481   where "v v* m == (\<chi> j. sum (\<lambda>i. ((m$i)$j) * (v$i)) (UNIV :: 'm set)) :: 'a^'n"
   482 
   483 definition "(mat::'a::zero => 'a ^'n^'n) k = (\<chi> i j. if i = j then k else 0)"
   484 definition transpose where
   485   "(transpose::'a^'n^'m \<Rightarrow> 'a^'m^'n) A = (\<chi> i j. ((A$j)$i))"
   486 definition "(row::'m => 'a ^'n^'m \<Rightarrow> 'a ^'n) i A = (\<chi> j. ((A$i)$j))"
   487 definition "(column::'n =>'a^'n^'m =>'a^'m) j A = (\<chi> i. ((A$i)$j))"
   488 definition "rows(A::'a^'n^'m) = { row i A | i. i \<in> (UNIV :: 'm set)}"
   489 definition "columns(A::'a^'n^'m) = { column i A | i. i \<in> (UNIV :: 'n set)}"
   490 
   491 lemma mat_0[simp]: "mat 0 = 0" by (vector mat_def)
   492 lemma matrix_add_ldistrib: "(A ** (B + C)) = (A ** B) + (A ** C)"
   493   by (vector matrix_matrix_mult_def sum.distrib[symmetric] field_simps)
   494 
   495 lemma matrix_mul_lid [simp]:
   496   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   497   shows "mat 1 ** A = A"
   498   apply (simp add: matrix_matrix_mult_def mat_def)
   499   apply vector
   500   apply (auto simp only: if_distrib cond_application_beta sum.delta'[OF finite]
   501     mult_1_left mult_zero_left if_True UNIV_I)
   502   done
   503 
   504 
   505 lemma matrix_mul_rid [simp]:
   506   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   507   shows "A ** mat 1 = A"
   508   apply (simp add: matrix_matrix_mult_def mat_def)
   509   apply vector
   510   apply (auto simp only: if_distrib cond_application_beta sum.delta[OF finite]
   511     mult_1_right mult_zero_right if_True UNIV_I cong: if_cong)
   512   done
   513 
   514 lemma matrix_mul_assoc: "A ** (B ** C) = (A ** B) ** C"
   515   apply (vector matrix_matrix_mult_def sum_distrib_left sum_distrib_right mult.assoc)
   516   apply (subst sum.swap)
   517   apply simp
   518   done
   519 
   520 lemma matrix_vector_mul_assoc: "A *v (B *v x) = (A ** B) *v x"
   521   apply (vector matrix_matrix_mult_def matrix_vector_mult_def
   522     sum_distrib_left sum_distrib_right mult.assoc)
   523   apply (subst sum.swap)
   524   apply simp
   525   done
   526 
   527 lemma matrix_vector_mul_lid [simp]: "mat 1 *v x = (x::'a::semiring_1 ^ 'n)"
   528   apply (vector matrix_vector_mult_def mat_def)
   529   apply (simp add: if_distrib cond_application_beta sum.delta' cong del: if_weak_cong)
   530   done
   531 
   532 lemma matrix_transpose_mul:
   533     "transpose(A ** B) = transpose B ** transpose (A::'a::comm_semiring_1^_^_)"
   534   by (simp add: matrix_matrix_mult_def transpose_def vec_eq_iff mult.commute)
   535 
   536 lemma matrix_eq:
   537   fixes A B :: "'a::semiring_1 ^ 'n ^ 'm"
   538   shows "A = B \<longleftrightarrow>  (\<forall>x. A *v x = B *v x)" (is "?lhs \<longleftrightarrow> ?rhs")
   539   apply auto
   540   apply (subst vec_eq_iff)
   541   apply clarify
   542   apply (clarsimp simp add: matrix_vector_mult_def if_distrib cond_application_beta vec_eq_iff cong del: if_weak_cong)
   543   apply (erule_tac x="axis ia 1" in allE)
   544   apply (erule_tac x="i" in allE)
   545   apply (auto simp add: if_distrib cond_application_beta axis_def
   546     sum.delta[OF finite] cong del: if_weak_cong)
   547   done
   548 
   549 lemma matrix_vector_mul_component: "((A::real^_^_) *v x)$k = (A$k) \<bullet> x"
   550   by (simp add: matrix_vector_mult_def inner_vec_def)
   551 
   552 lemma dot_lmul_matrix: "((x::real ^_) v* A) \<bullet> y = x \<bullet> (A *v y)"
   553   apply (simp add: inner_vec_def matrix_vector_mult_def vector_matrix_mult_def sum_distrib_right sum_distrib_left ac_simps)
   554   apply (subst sum.swap)
   555   apply simp
   556   done
   557 
   558 lemma transpose_mat [simp]: "transpose (mat n) = mat n"
   559   by (vector transpose_def mat_def)
   560 
   561 lemma transpose_transpose [simp]: "transpose(transpose A) = A"
   562   by (vector transpose_def)
   563 
   564 lemma row_transpose [simp]:
   565   fixes A:: "'a::semiring_1^_^_"
   566   shows "row i (transpose A) = column i A"
   567   by (simp add: row_def column_def transpose_def vec_eq_iff)
   568 
   569 lemma column_transpose [simp]:
   570   fixes A:: "'a::semiring_1^_^_"
   571   shows "column i (transpose A) = row i A"
   572   by (simp add: row_def column_def transpose_def vec_eq_iff)
   573 
   574 lemma rows_transpose [simp]: "rows(transpose (A::'a::semiring_1^_^_)) = columns A"
   575   by (auto simp add: rows_def columns_def row_transpose intro: set_eqI)
   576 
   577 lemma columns_transpose [simp]: "columns(transpose (A::'a::semiring_1^_^_)) = rows A"
   578   by (metis transpose_transpose rows_transpose)
   579 
   580 lemma matrix_mult_transpose_dot_column:
   581   fixes A :: "real^'n^'n"
   582   shows "transpose A ** A = (\<chi> i j. (column i A) \<bullet> (column j A))"
   583   by (simp add: matrix_matrix_mult_def vec_eq_iff transpose_def column_def inner_vec_def)
   584 
   585 lemma matrix_mult_transpose_dot_row:
   586   fixes A :: "real^'n^'n"
   587   shows "A ** transpose A = (\<chi> i j. (row i A) \<bullet> (row j A))"
   588   by (simp add: matrix_matrix_mult_def vec_eq_iff transpose_def row_def inner_vec_def)
   589 
   590 text\<open>Two sometimes fruitful ways of looking at matrix-vector multiplication.\<close>
   591 
   592 lemma matrix_mult_dot: "A *v x = (\<chi> i. A$i \<bullet> x)"
   593   by (simp add: matrix_vector_mult_def inner_vec_def)
   594 
   595 lemma matrix_mult_sum:
   596   "(A::'a::comm_semiring_1^'n^'m) *v x = sum (\<lambda>i. (x$i) *s column i A) (UNIV:: 'n set)"
   597   by (simp add: matrix_vector_mult_def vec_eq_iff column_def mult.commute)
   598 
   599 lemma vector_componentwise:
   600   "(x::'a::ring_1^'n) = (\<chi> j. \<Sum>i\<in>UNIV. (x$i) * (axis i 1 :: 'a^'n) $ j)"
   601   by (simp add: axis_def if_distrib sum.If_cases vec_eq_iff)
   602 
   603 lemma basis_expansion: "sum (\<lambda>i. (x$i) *s axis i 1) UNIV = (x::('a::ring_1) ^'n)"
   604   by (auto simp add: axis_def vec_eq_iff if_distrib sum.If_cases cong del: if_weak_cong)
   605 
   606 lemma linear_componentwise_expansion:
   607   fixes f:: "real ^'m \<Rightarrow> real ^ _"
   608   assumes lf: "linear f"
   609   shows "(f x)$j = sum (\<lambda>i. (x$i) * (f (axis i 1)$j)) (UNIV :: 'm set)" (is "?lhs = ?rhs")
   610 proof -
   611   let ?M = "(UNIV :: 'm set)"
   612   let ?N = "(UNIV :: 'n set)"
   613   have "?rhs = (sum (\<lambda>i.(x$i) *\<^sub>R f (axis i 1) ) ?M)$j"
   614     unfolding sum_component by simp
   615   then show ?thesis
   616     unfolding linear_sum_mul[OF lf, symmetric]
   617     unfolding scalar_mult_eq_scaleR[symmetric]
   618     unfolding basis_expansion
   619     by simp
   620 qed
   621 
   622 subsection\<open>Inverse matrices  (not necessarily square)\<close>
   623 
   624 definition
   625   "invertible(A::'a::semiring_1^'n^'m) \<longleftrightarrow> (\<exists>A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   626 
   627 definition
   628   "matrix_inv(A:: 'a::semiring_1^'n^'m) =
   629     (SOME A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   630 
   631 text\<open>Correspondence between matrices and linear operators.\<close>
   632 
   633 definition matrix :: "('a::{plus,times, one, zero}^'m \<Rightarrow> 'a ^ 'n) \<Rightarrow> 'a^'m^'n"
   634   where "matrix f = (\<chi> i j. (f(axis j 1))$i)"
   635 
   636 lemma matrix_vector_mul_linear: "linear(\<lambda>x. A *v (x::real ^ _))"
   637   by (simp add: linear_iff matrix_vector_mult_def vec_eq_iff
   638       field_simps sum_distrib_left sum.distrib)
   639 
   640 lemma
   641   fixes A :: "real^'n^'m"
   642   shows matrix_vector_mult_linear_continuous_at [continuous_intros]: "isCont (( *v) A) z"
   643     and matrix_vector_mult_linear_continuous_on [continuous_intros]: "continuous_on S (( *v) A)"
   644   by (simp_all add: linear_linear linear_continuous_at linear_continuous_on matrix_vector_mul_linear)
   645 
   646 lemma matrix_vector_mult_add_distrib [algebra_simps]:
   647   "A *v (x + y) = A *v x + A *v y"
   648   by (vector matrix_vector_mult_def sum.distrib distrib_left)
   649 
   650 lemma matrix_vector_mult_diff_distrib [algebra_simps]:
   651   fixes A :: "'a::ring_1^'n^'m"
   652   shows "A *v (x - y) = A *v x - A *v y"
   653   by (vector matrix_vector_mult_def sum_subtractf right_diff_distrib)
   654 
   655 lemma matrix_vector_mult_scaleR[algebra_simps]:
   656   fixes A :: "real^'n^'m"
   657   shows "A *v (c *\<^sub>R x) = c *\<^sub>R (A *v x)"
   658   using linear_iff matrix_vector_mul_linear by blast
   659 
   660 lemma matrix_vector_mult_0_right [simp]: "A *v 0 = 0"
   661   by (simp add: matrix_vector_mult_def vec_eq_iff)
   662 
   663 lemma matrix_vector_mult_0 [simp]: "0 *v w = 0"
   664   by (simp add: matrix_vector_mult_def vec_eq_iff)
   665 
   666 lemma matrix_vector_mult_add_rdistrib [algebra_simps]:
   667   "(A + B) *v x = (A *v x) + (B *v x)"
   668   by (vector matrix_vector_mult_def sum.distrib distrib_right)
   669 
   670 lemma matrix_vector_mult_diff_rdistrib [algebra_simps]:
   671   fixes A :: "'a :: ring_1^'n^'m"
   672   shows "(A - B) *v x = (A *v x) - (B *v x)"
   673   by (vector matrix_vector_mult_def sum_subtractf left_diff_distrib)
   674 
   675 lemma matrix_works:
   676   assumes lf: "linear f"
   677   shows "matrix f *v x = f (x::real ^ 'n)"
   678   apply (simp add: matrix_def matrix_vector_mult_def vec_eq_iff mult.commute)
   679   by (simp add: linear_componentwise_expansion lf)
   680 
   681 lemma matrix_vector_mul: "linear f ==> f = (\<lambda>x. matrix f *v (x::real ^ 'n))"
   682   by (simp add: ext matrix_works)
   683 
   684 declare matrix_vector_mul [symmetric, simp]
   685 
   686 lemma matrix_of_matrix_vector_mul [simp]: "matrix(\<lambda>x. A *v (x :: real ^ 'n)) = A"
   687   by (simp add: matrix_eq matrix_vector_mul_linear matrix_works)
   688 
   689 lemma matrix_compose:
   690   assumes lf: "linear (f::real^'n \<Rightarrow> real^'m)"
   691     and lg: "linear (g::real^'m \<Rightarrow> real^_)"
   692   shows "matrix (g \<circ> f) = matrix g ** matrix f"
   693   using lf lg linear_compose[OF lf lg] matrix_works[OF linear_compose[OF lf lg]]
   694   by (simp add: matrix_eq matrix_works matrix_vector_mul_assoc[symmetric] o_def)
   695 
   696 lemma matrix_vector_column:
   697   "(A::'a::comm_semiring_1^'n^_) *v x = sum (\<lambda>i. (x$i) *s ((transpose A)$i)) (UNIV:: 'n set)"
   698   by (simp add: matrix_vector_mult_def transpose_def vec_eq_iff mult.commute)
   699 
   700 lemma adjoint_matrix: "adjoint(\<lambda>x. (A::real^'n^'m) *v x) = (\<lambda>x. transpose A *v x)"
   701   apply (rule adjoint_unique)
   702   apply (simp add: transpose_def inner_vec_def matrix_vector_mult_def
   703     sum_distrib_right sum_distrib_left)
   704   apply (subst sum.swap)
   705   apply (auto simp add: ac_simps)
   706   done
   707 
   708 lemma matrix_adjoint: assumes lf: "linear (f :: real^'n \<Rightarrow> real ^'m)"
   709   shows "matrix(adjoint f) = transpose(matrix f)"
   710   apply (subst matrix_vector_mul[OF lf])
   711   unfolding adjoint_matrix matrix_of_matrix_vector_mul
   712   apply rule
   713   done
   714 
   715 
   716 subsection\<open>Some bounds on components etc. relative to operator norm.\<close>
   717 
   718 lemma norm_column_le_onorm:
   719   fixes A :: "real^'n^'m"
   720   shows "norm(column i A) \<le> onorm(( *v) A)"
   721 proof -
   722   have bl: "bounded_linear (( *v) A)"
   723     by (simp add: linear_linear matrix_vector_mul_linear)
   724   have "norm (\<chi> j. A $ j $ i) \<le> norm (A *v axis i 1)"
   725     by (simp add: matrix_mult_dot cart_eq_inner_axis)
   726   also have "\<dots> \<le> onorm (( *v) A)"
   727     using onorm [OF bl, of "axis i 1"] by (auto simp: axis_in_Basis)
   728   finally have "norm (\<chi> j. A $ j $ i) \<le> onorm (( *v) A)" .
   729   then show ?thesis
   730     unfolding column_def .
   731 qed
   732 
   733 lemma matrix_component_le_onorm:
   734   fixes A :: "real^'n^'m"
   735   shows "\<bar>A $ i $ j\<bar> \<le> onorm(( *v) A)"
   736 proof -
   737   have "\<bar>A $ i $ j\<bar> \<le> norm (\<chi> n. (A $ n $ j))"
   738     by (metis (full_types, lifting) component_le_norm_cart vec_lambda_beta)
   739   also have "\<dots> \<le> onorm (( *v) A)"
   740     by (metis (no_types) column_def norm_column_le_onorm)
   741   finally show ?thesis .
   742 qed
   743 
   744 lemma component_le_onorm:
   745   fixes f :: "real^'m \<Rightarrow> real^'n"
   746   shows "linear f \<Longrightarrow> \<bar>matrix f $ i $ j\<bar> \<le> onorm f"
   747   by (metis matrix_component_le_onorm matrix_vector_mul)
   748 
   749 lemma onorm_le_matrix_component_sum:
   750   fixes A :: "real^'n^'m"
   751   shows "onorm(( *v) A) \<le> (\<Sum>i\<in>UNIV. \<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar>)"
   752 proof (rule onorm_le)
   753   fix x
   754   have "norm (A *v x) \<le> (\<Sum>i\<in>UNIV. \<bar>(A *v x) $ i\<bar>)"
   755     by (rule norm_le_l1_cart)
   756   also have "\<dots> \<le> (\<Sum>i\<in>UNIV. \<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar> * norm x)"
   757   proof (rule sum_mono)
   758     fix i
   759     have "\<bar>(A *v x) $ i\<bar> \<le> \<bar>\<Sum>j\<in>UNIV. A $ i $ j * x $ j\<bar>"
   760       by (simp add: matrix_vector_mult_def)
   761     also have "\<dots> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j * x $ j\<bar>)"
   762       by (rule sum_abs)
   763     also have "\<dots> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar> * norm x)"
   764       by (rule sum_mono) (simp add: abs_mult component_le_norm_cart mult_left_mono)
   765     finally show "\<bar>(A *v x) $ i\<bar> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar> * norm x)" .
   766   qed
   767   finally show "norm (A *v x) \<le> (\<Sum>i\<in>UNIV. \<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar>) * norm x"
   768     by (simp add: sum_distrib_right)
   769 qed
   770 
   771 lemma onorm_le_matrix_component:
   772   fixes A :: "real^'n^'m"
   773   assumes "\<And>i j. abs(A$i$j) \<le> B"
   774   shows "onorm(( *v) A) \<le> real (CARD('m)) * real (CARD('n)) * B"
   775 proof (rule onorm_le)
   776   fix x :: "(real, 'n) vec"
   777   have "norm (A *v x) \<le> (\<Sum>i\<in>UNIV. \<bar>(A *v x) $ i\<bar>)"
   778     by (rule norm_le_l1_cart)
   779   also have "\<dots> \<le> (\<Sum>i::'m \<in>UNIV. real (CARD('n)) * B * norm x)"
   780   proof (rule sum_mono)
   781     fix i
   782     have "\<bar>(A *v x) $ i\<bar> \<le> norm(A $ i) * norm x"
   783       by (simp add: matrix_mult_dot Cauchy_Schwarz_ineq2)
   784     also have "\<dots> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar>) * norm x"
   785       by (simp add: mult_right_mono norm_le_l1_cart)
   786     also have "\<dots> \<le> real (CARD('n)) * B * norm x"
   787       by (simp add: assms sum_bounded_above mult_right_mono)
   788     finally show "\<bar>(A *v x) $ i\<bar> \<le> real (CARD('n)) * B * norm x" .
   789   qed
   790   also have "\<dots> \<le> CARD('m) * real (CARD('n)) * B * norm x"
   791     by simp
   792   finally show "norm (A *v x) \<le> CARD('m) * real (CARD('n)) * B * norm x" .
   793 qed
   794 
   795 subsection \<open>lambda skolemization on cartesian products\<close>
   796 
   797 lemma lambda_skolem: "(\<forall>i. \<exists>x. P i x) \<longleftrightarrow>
   798    (\<exists>x::'a ^ 'n. \<forall>i. P i (x $ i))" (is "?lhs \<longleftrightarrow> ?rhs")
   799 proof -
   800   let ?S = "(UNIV :: 'n set)"
   801   { assume H: "?rhs"
   802     then have ?lhs by auto }
   803   moreover
   804   { assume H: "?lhs"
   805     then obtain f where f:"\<forall>i. P i (f i)" unfolding choice_iff by metis
   806     let ?x = "(\<chi> i. (f i)) :: 'a ^ 'n"
   807     { fix i
   808       from f have "P i (f i)" by metis
   809       then have "P i (?x $ i)" by auto
   810     }
   811     hence "\<forall>i. P i (?x$i)" by metis
   812     hence ?rhs by metis }
   813   ultimately show ?thesis by metis
   814 qed
   815 
   816 lemma rational_approximation:
   817   assumes "e > 0"
   818   obtains r::real where "r \<in> \<rat>" "\<bar>r - x\<bar> < e"
   819   using Rats_dense_in_real [of "x - e/2" "x + e/2"] assms by auto
   820 
   821 lemma matrix_rational_approximation:
   822   fixes A :: "real^'n^'m"
   823   assumes "e > 0"
   824   obtains B where "\<And>i j. B$i$j \<in> \<rat>" "onorm(\<lambda>x. (A - B) *v x) < e"
   825 proof -
   826   have "\<forall>i j. \<exists>q \<in> \<rat>. \<bar>q - A $ i $ j\<bar> < e / (2 * CARD('m) * CARD('n))"
   827     using assms by (force intro: rational_approximation [of "e / (2 * CARD('m) * CARD('n))"])
   828   then obtain B where B: "\<And>i j. B$i$j \<in> \<rat>" and Bclo: "\<And>i j. \<bar>B$i$j - A $ i $ j\<bar> < e / (2 * CARD('m) * CARD('n))"
   829     by (auto simp: lambda_skolem Bex_def)
   830   show ?thesis
   831   proof
   832     have "onorm (( *v) (A - B)) \<le> real CARD('m) * real CARD('n) *
   833     (e / (2 * real CARD('m) * real CARD('n)))"
   834       apply (rule onorm_le_matrix_component)
   835       using Bclo by (simp add: abs_minus_commute less_imp_le)
   836     also have "\<dots> < e"
   837       using \<open>0 < e\<close> by (simp add: divide_simps)
   838     finally show "onorm (( *v) (A - B)) < e" .
   839   qed (use B in auto)
   840 qed
   841 
   842 lemma vector_sub_project_orthogonal_cart: "(b::real^'n) \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *s b) = 0"
   843   unfolding inner_simps scalar_mult_eq_scaleR by auto
   844 
   845 lemma left_invertible_transpose:
   846   "(\<exists>(B). B ** transpose (A) = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). A ** B = mat 1)"
   847   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   848 
   849 lemma right_invertible_transpose:
   850   "(\<exists>(B). transpose (A) ** B = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). B ** A = mat 1)"
   851   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   852 
   853 lemma matrix_left_invertible_injective:
   854   "(\<exists>B. (B::real^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x y. A *v x = A *v y \<longrightarrow> x = y)"
   855 proof -
   856   { fix B:: "real^'m^'n" and x y assume B: "B ** A = mat 1" and xy: "A *v x = A*v y"
   857     from xy have "B*v (A *v x) = B *v (A*v y)" by simp
   858     hence "x = y"
   859       unfolding matrix_vector_mul_assoc B matrix_vector_mul_lid . }
   860   moreover
   861   { assume A: "\<forall>x y. A *v x = A *v y \<longrightarrow> x = y"
   862     hence i: "inj (( *v) A)" unfolding inj_on_def by auto
   863     from linear_injective_left_inverse[OF matrix_vector_mul_linear i]
   864     obtain g where g: "linear g" "g \<circ> ( *v) A = id" by blast
   865     have "matrix g ** A = mat 1"
   866       unfolding matrix_eq matrix_vector_mul_lid matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   867       using g(2) by (simp add: fun_eq_iff)
   868     then have "\<exists>B. (B::real ^'m^'n) ** A = mat 1" by blast }
   869   ultimately show ?thesis by blast
   870 qed
   871 
   872 lemma matrix_left_invertible_ker:
   873   "(\<exists>B. (B::real ^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x. A *v x = 0 \<longrightarrow> x = 0)"
   874   unfolding matrix_left_invertible_injective
   875   using linear_injective_0[OF matrix_vector_mul_linear, of A]
   876   by (simp add: inj_on_def)
   877 
   878 lemma matrix_right_invertible_surjective:
   879   "(\<exists>B. (A::real^'n^'m) ** (B::real^'m^'n) = mat 1) \<longleftrightarrow> surj (\<lambda>x. A *v x)"
   880 proof -
   881   { fix B :: "real ^'m^'n"
   882     assume AB: "A ** B = mat 1"
   883     { fix x :: "real ^ 'm"
   884       have "A *v (B *v x) = x"
   885         by (simp add: matrix_vector_mul_lid matrix_vector_mul_assoc AB) }
   886     hence "surj (( *v) A)" unfolding surj_def by metis }
   887   moreover
   888   { assume sf: "surj (( *v) A)"
   889     from linear_surjective_right_inverse[OF matrix_vector_mul_linear sf]
   890     obtain g:: "real ^'m \<Rightarrow> real ^'n" where g: "linear g" "( *v) A \<circ> g = id"
   891       by blast
   892 
   893     have "A ** (matrix g) = mat 1"
   894       unfolding matrix_eq  matrix_vector_mul_lid
   895         matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   896       using g(2) unfolding o_def fun_eq_iff id_def
   897       .
   898     hence "\<exists>B. A ** (B::real^'m^'n) = mat 1" by blast
   899   }
   900   ultimately show ?thesis unfolding surj_def by blast
   901 qed
   902 
   903 lemma matrix_left_invertible_independent_columns:
   904   fixes A :: "real^'n^'m"
   905   shows "(\<exists>(B::real ^'m^'n). B ** A = mat 1) \<longleftrightarrow>
   906       (\<forall>c. sum (\<lambda>i. c i *s column i A) (UNIV :: 'n set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   907     (is "?lhs \<longleftrightarrow> ?rhs")
   908 proof -
   909   let ?U = "UNIV :: 'n set"
   910   { assume k: "\<forall>x. A *v x = 0 \<longrightarrow> x = 0"
   911     { fix c i
   912       assume c: "sum (\<lambda>i. c i *s column i A) ?U = 0" and i: "i \<in> ?U"
   913       let ?x = "\<chi> i. c i"
   914       have th0:"A *v ?x = 0"
   915         using c
   916         unfolding matrix_mult_sum vec_eq_iff
   917         by auto
   918       from k[rule_format, OF th0] i
   919       have "c i = 0" by (vector vec_eq_iff)}
   920     hence ?rhs by blast }
   921   moreover
   922   { assume H: ?rhs
   923     { fix x assume x: "A *v x = 0"
   924       let ?c = "\<lambda>i. ((x$i ):: real)"
   925       from H[rule_format, of ?c, unfolded matrix_mult_sum[symmetric], OF x]
   926       have "x = 0" by vector }
   927   }
   928   ultimately show ?thesis unfolding matrix_left_invertible_ker by blast
   929 qed
   930 
   931 lemma matrix_right_invertible_independent_rows:
   932   fixes A :: "real^'n^'m"
   933   shows "(\<exists>(B::real^'m^'n). A ** B = mat 1) \<longleftrightarrow>
   934     (\<forall>c. sum (\<lambda>i. c i *s row i A) (UNIV :: 'm set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   935   unfolding left_invertible_transpose[symmetric]
   936     matrix_left_invertible_independent_columns
   937   by (simp add: column_transpose)
   938 
   939 lemma matrix_right_invertible_span_columns:
   940   "(\<exists>(B::real ^'n^'m). (A::real ^'m^'n) ** B = mat 1) \<longleftrightarrow>
   941     span (columns A) = UNIV" (is "?lhs = ?rhs")
   942 proof -
   943   let ?U = "UNIV :: 'm set"
   944   have fU: "finite ?U" by simp
   945   have lhseq: "?lhs \<longleftrightarrow> (\<forall>y. \<exists>(x::real^'m). sum (\<lambda>i. (x$i) *s column i A) ?U = y)"
   946     unfolding matrix_right_invertible_surjective matrix_mult_sum surj_def
   947     apply (subst eq_commute)
   948     apply rule
   949     done
   950   have rhseq: "?rhs \<longleftrightarrow> (\<forall>x. x \<in> span (columns A))" by blast
   951   { assume h: ?lhs
   952     { fix x:: "real ^'n"
   953       from h[unfolded lhseq, rule_format, of x] obtain y :: "real ^'m"
   954         where y: "sum (\<lambda>i. (y$i) *s column i A) ?U = x" by blast
   955       have "x \<in> span (columns A)"
   956         unfolding y[symmetric]
   957         apply (rule span_sum)
   958         unfolding scalar_mult_eq_scaleR
   959         apply (rule span_mul)
   960         apply (rule span_superset)
   961         unfolding columns_def
   962         apply blast
   963         done
   964     }
   965     then have ?rhs unfolding rhseq by blast }
   966   moreover
   967   { assume h:?rhs
   968     let ?P = "\<lambda>(y::real ^'n). \<exists>(x::real^'m). sum (\<lambda>i. (x$i) *s column i A) ?U = y"
   969     { fix y
   970       have "?P y"
   971       proof (rule span_induct_alt[of ?P "columns A", folded scalar_mult_eq_scaleR])
   972         show "\<exists>x::real ^ 'm. sum (\<lambda>i. (x$i) *s column i A) ?U = 0"
   973           by (rule exI[where x=0], simp)
   974       next
   975         fix c y1 y2
   976         assume y1: "y1 \<in> columns A" and y2: "?P y2"
   977         from y1 obtain i where i: "i \<in> ?U" "y1 = column i A"
   978           unfolding columns_def by blast
   979         from y2 obtain x:: "real ^'m" where
   980           x: "sum (\<lambda>i. (x$i) *s column i A) ?U = y2" by blast
   981         let ?x = "(\<chi> j. if j = i then c + (x$i) else (x$j))::real^'m"
   982         show "?P (c*s y1 + y2)"
   983         proof (rule exI[where x= "?x"], vector, auto simp add: i x[symmetric] if_distrib distrib_left cond_application_beta cong del: if_weak_cong)
   984           fix j
   985           have th: "\<forall>xa \<in> ?U. (if xa = i then (c + (x$i)) * ((column xa A)$j)
   986               else (x$xa) * ((column xa A$j))) = (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))"
   987             using i(1) by (simp add: field_simps)
   988           have "sum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
   989               else (x$xa) * ((column xa A$j))) ?U = sum (\<lambda>xa. (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))) ?U"
   990             apply (rule sum.cong[OF refl])
   991             using th apply blast
   992             done
   993           also have "\<dots> = sum (\<lambda>xa. if xa = i then c * ((column i A)$j) else 0) ?U + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
   994             by (simp add: sum.distrib)
   995           also have "\<dots> = c * ((column i A)$j) + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
   996             unfolding sum.delta[OF fU]
   997             using i(1) by simp
   998           finally show "sum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
   999             else (x$xa) * ((column xa A$j))) ?U = c * ((column i A)$j) + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U" .
  1000         qed
  1001       next
  1002         show "y \<in> span (columns A)"
  1003           unfolding h by blast
  1004       qed
  1005     }
  1006     then have ?lhs unfolding lhseq ..
  1007   }
  1008   ultimately show ?thesis by blast
  1009 qed
  1010 
  1011 lemma matrix_left_invertible_span_rows:
  1012   "(\<exists>(B::real^'m^'n). B ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> span (rows A) = UNIV"
  1013   unfolding right_invertible_transpose[symmetric]
  1014   unfolding columns_transpose[symmetric]
  1015   unfolding matrix_right_invertible_span_columns
  1016   ..
  1017 
  1018 text \<open>The same result in terms of square matrices.\<close>
  1019 
  1020 lemma matrix_left_right_inverse:
  1021   fixes A A' :: "real ^'n^'n"
  1022   shows "A ** A' = mat 1 \<longleftrightarrow> A' ** A = mat 1"
  1023 proof -
  1024   { fix A A' :: "real ^'n^'n"
  1025     assume AA': "A ** A' = mat 1"
  1026     have sA: "surj (( *v) A)"
  1027       unfolding surj_def
  1028       apply clarify
  1029       apply (rule_tac x="(A' *v y)" in exI)
  1030       apply (simp add: matrix_vector_mul_assoc AA' matrix_vector_mul_lid)
  1031       done
  1032     from linear_surjective_isomorphism[OF matrix_vector_mul_linear sA]
  1033     obtain f' :: "real ^'n \<Rightarrow> real ^'n"
  1034       where f': "linear f'" "\<forall>x. f' (A *v x) = x" "\<forall>x. A *v f' x = x" by blast
  1035     have th: "matrix f' ** A = mat 1"
  1036       by (simp add: matrix_eq matrix_works[OF f'(1)]
  1037           matrix_vector_mul_assoc[symmetric] matrix_vector_mul_lid f'(2)[rule_format])
  1038     hence "(matrix f' ** A) ** A' = mat 1 ** A'" by simp
  1039     hence "matrix f' = A'"
  1040       by (simp add: matrix_mul_assoc[symmetric] AA' matrix_mul_rid matrix_mul_lid)
  1041     hence "matrix f' ** A = A' ** A" by simp
  1042     hence "A' ** A = mat 1" by (simp add: th)
  1043   }
  1044   then show ?thesis by blast
  1045 qed
  1046 
  1047 text \<open>Considering an n-element vector as an n-by-1 or 1-by-n matrix.\<close>
  1048 
  1049 definition "rowvector v = (\<chi> i j. (v$j))"
  1050 
  1051 definition "columnvector v = (\<chi> i j. (v$i))"
  1052 
  1053 lemma transpose_columnvector: "transpose(columnvector v) = rowvector v"
  1054   by (simp add: transpose_def rowvector_def columnvector_def vec_eq_iff)
  1055 
  1056 lemma transpose_rowvector: "transpose(rowvector v) = columnvector v"
  1057   by (simp add: transpose_def columnvector_def rowvector_def vec_eq_iff)
  1058 
  1059 lemma dot_rowvector_columnvector: "columnvector (A *v v) = A ** columnvector v"
  1060   by (vector columnvector_def matrix_matrix_mult_def matrix_vector_mult_def)
  1061 
  1062 lemma dot_matrix_product:
  1063   "(x::real^'n) \<bullet> y = (((rowvector x ::real^'n^1) ** (columnvector y :: real^1^'n))$1)$1"
  1064   by (vector matrix_matrix_mult_def rowvector_def columnvector_def inner_vec_def)
  1065 
  1066 lemma dot_matrix_vector_mul:
  1067   fixes A B :: "real ^'n ^'n" and x y :: "real ^'n"
  1068   shows "(A *v x) \<bullet> (B *v y) =
  1069       (((rowvector x :: real^'n^1) ** ((transpose A ** B) ** (columnvector y :: real ^1^'n)))$1)$1"
  1070   unfolding dot_matrix_product transpose_columnvector[symmetric]
  1071     dot_rowvector_columnvector matrix_transpose_mul matrix_mul_assoc ..
  1072 
  1073 lemma infnorm_cart:"infnorm (x::real^'n) = Sup {\<bar>x$i\<bar> |i. i\<in>UNIV}"
  1074   by (simp add: infnorm_def inner_axis Basis_vec_def) (metis (lifting) inner_axis real_inner_1_right)
  1075 
  1076 lemma component_le_infnorm_cart: "\<bar>x$i\<bar> \<le> infnorm (x::real^'n)"
  1077   using Basis_le_infnorm[of "axis i 1" x]
  1078   by (simp add: Basis_vec_def axis_eq_axis inner_axis)
  1079 
  1080 lemma continuous_component[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x $ i)"
  1081   unfolding continuous_def by (rule tendsto_vec_nth)
  1082 
  1083 lemma continuous_on_component[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x $ i)"
  1084   unfolding continuous_on_def by (fast intro: tendsto_vec_nth)
  1085 
  1086 lemma continuous_on_vec_lambda[continuous_intros]:
  1087   "(\<And>i. continuous_on S (f i)) \<Longrightarrow> continuous_on S (\<lambda>x. \<chi> i. f i x)"
  1088   unfolding continuous_on_def by (auto intro: tendsto_vec_lambda)
  1089 
  1090 lemma closed_positive_orthant: "closed {x::real^'n. \<forall>i. 0 \<le>x$i}"
  1091   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1092 
  1093 lemma bounded_component_cart: "bounded s \<Longrightarrow> bounded ((\<lambda>x. x $ i) ` s)"
  1094   unfolding bounded_def
  1095   apply clarify
  1096   apply (rule_tac x="x $ i" in exI)
  1097   apply (rule_tac x="e" in exI)
  1098   apply clarify
  1099   apply (rule order_trans [OF dist_vec_nth_le], simp)
  1100   done
  1101 
  1102 lemma compact_lemma_cart:
  1103   fixes f :: "nat \<Rightarrow> 'a::heine_borel ^ 'n"
  1104   assumes f: "bounded (range f)"
  1105   shows "\<exists>l r. strict_mono r \<and>
  1106         (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $ i) (l $ i) < e) sequentially)"
  1107     (is "?th d")
  1108 proof -
  1109   have "\<forall>d' \<subseteq> d. ?th d'"
  1110     by (rule compact_lemma_general[where unproj=vec_lambda])
  1111       (auto intro!: f bounded_component_cart simp: vec_lambda_eta)
  1112   then show "?th d" by simp
  1113 qed
  1114 
  1115 instance vec :: (heine_borel, finite) heine_borel
  1116 proof
  1117   fix f :: "nat \<Rightarrow> 'a ^ 'b"
  1118   assume f: "bounded (range f)"
  1119   then obtain l r where r: "strict_mono r"
  1120       and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>UNIV. dist (f (r n) $ i) (l $ i) < e) sequentially"
  1121     using compact_lemma_cart [OF f] by blast
  1122   let ?d = "UNIV::'b set"
  1123   { fix e::real assume "e>0"
  1124     hence "0 < e / (real_of_nat (card ?d))"
  1125       using zero_less_card_finite divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
  1126     with l have "eventually (\<lambda>n. \<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))) sequentially"
  1127       by simp
  1128     moreover
  1129     { fix n
  1130       assume n: "\<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))"
  1131       have "dist (f (r n)) l \<le> (\<Sum>i\<in>?d. dist (f (r n) $ i) (l $ i))"
  1132         unfolding dist_vec_def using zero_le_dist by (rule L2_set_le_sum)
  1133       also have "\<dots> < (\<Sum>i\<in>?d. e / (real_of_nat (card ?d)))"
  1134         by (rule sum_strict_mono) (simp_all add: n)
  1135       finally have "dist (f (r n)) l < e" by simp
  1136     }
  1137     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
  1138       by (rule eventually_mono)
  1139   }
  1140   hence "((f \<circ> r) \<longlongrightarrow> l) sequentially" unfolding o_def tendsto_iff by simp
  1141   with r show "\<exists>l r. strict_mono r \<and> ((f \<circ> r) \<longlongrightarrow> l) sequentially" by auto
  1142 qed
  1143 
  1144 lemma interval_cart:
  1145   fixes a :: "real^'n"
  1146   shows "box a b = {x::real^'n. \<forall>i. a$i < x$i \<and> x$i < b$i}"
  1147     and "cbox a b = {x::real^'n. \<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i}"
  1148   by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def mem_box Basis_vec_def inner_axis)
  1149 
  1150 lemma mem_box_cart:
  1151   fixes a :: "real^'n"
  1152   shows "x \<in> box a b \<longleftrightarrow> (\<forall>i. a$i < x$i \<and> x$i < b$i)"
  1153     and "x \<in> cbox a b \<longleftrightarrow> (\<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i)"
  1154   using interval_cart[of a b] by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def)
  1155 
  1156 lemma interval_eq_empty_cart:
  1157   fixes a :: "real^'n"
  1158   shows "(box a b = {} \<longleftrightarrow> (\<exists>i. b$i \<le> a$i))" (is ?th1)
  1159     and "(cbox a b = {} \<longleftrightarrow> (\<exists>i. b$i < a$i))" (is ?th2)
  1160 proof -
  1161   { fix i x assume as:"b$i \<le> a$i" and x:"x\<in>box a b"
  1162     hence "a $ i < x $ i \<and> x $ i < b $ i" unfolding mem_box_cart by auto
  1163     hence "a$i < b$i" by auto
  1164     hence False using as by auto }
  1165   moreover
  1166   { assume as:"\<forall>i. \<not> (b$i \<le> a$i)"
  1167     let ?x = "(1/2) *\<^sub>R (a + b)"
  1168     { fix i
  1169       have "a$i < b$i" using as[THEN spec[where x=i]] by auto
  1170       hence "a$i < ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i < b$i"
  1171         unfolding vector_smult_component and vector_add_component
  1172         by auto }
  1173     hence "box a b \<noteq> {}" using mem_box_cart(1)[of "?x" a b] by auto }
  1174   ultimately show ?th1 by blast
  1175 
  1176   { fix i x assume as:"b$i < a$i" and x:"x\<in>cbox a b"
  1177     hence "a $ i \<le> x $ i \<and> x $ i \<le> b $ i" unfolding mem_box_cart by auto
  1178     hence "a$i \<le> b$i" by auto
  1179     hence False using as by auto }
  1180   moreover
  1181   { assume as:"\<forall>i. \<not> (b$i < a$i)"
  1182     let ?x = "(1/2) *\<^sub>R (a + b)"
  1183     { fix i
  1184       have "a$i \<le> b$i" using as[THEN spec[where x=i]] by auto
  1185       hence "a$i \<le> ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i \<le> b$i"
  1186         unfolding vector_smult_component and vector_add_component
  1187         by auto }
  1188     hence "cbox a b \<noteq> {}" using mem_box_cart(2)[of "?x" a b] by auto  }
  1189   ultimately show ?th2 by blast
  1190 qed
  1191 
  1192 lemma interval_ne_empty_cart:
  1193   fixes a :: "real^'n"
  1194   shows "cbox a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i \<le> b$i)"
  1195     and "box a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i < b$i)"
  1196   unfolding interval_eq_empty_cart[of a b] by (auto simp add: not_less not_le)
  1197     (* BH: Why doesn't just "auto" work here? *)
  1198 
  1199 lemma subset_interval_imp_cart:
  1200   fixes a :: "real^'n"
  1201   shows "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> cbox c d \<subseteq> cbox a b"
  1202     and "(\<forall>i. a$i < c$i \<and> d$i < b$i) \<Longrightarrow> cbox c d \<subseteq> box a b"
  1203     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> cbox a b"
  1204     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> box a b"
  1205   unfolding subset_eq[unfolded Ball_def] unfolding mem_box_cart
  1206   by (auto intro: order_trans less_le_trans le_less_trans less_imp_le) (* BH: Why doesn't just "auto" work here? *)
  1207 
  1208 lemma interval_sing:
  1209   fixes a :: "'a::linorder^'n"
  1210   shows "{a .. a} = {a} \<and> {a<..<a} = {}"
  1211   apply (auto simp add: set_eq_iff less_vec_def less_eq_vec_def vec_eq_iff)
  1212   done
  1213 
  1214 lemma subset_interval_cart:
  1215   fixes a :: "real^'n"
  1216   shows "cbox c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th1)
  1217     and "cbox c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i < c$i \<and> d$i < b$i)" (is ?th2)
  1218     and "box c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th3)
  1219     and "box c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th4)
  1220   using subset_box[of c d a b] by (simp_all add: Basis_vec_def inner_axis)
  1221 
  1222 lemma disjoint_interval_cart:
  1223   fixes a::"real^'n"
  1224   shows "cbox a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i < c$i \<or> b$i < c$i \<or> d$i < a$i))" (is ?th1)
  1225     and "cbox a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th2)
  1226     and "box a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i < c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th3)
  1227     and "box a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th4)
  1228   using disjoint_interval[of a b c d] by (simp_all add: Basis_vec_def inner_axis)
  1229 
  1230 lemma Int_interval_cart:
  1231   fixes a :: "real^'n"
  1232   shows "cbox a b \<inter> cbox c d =  {(\<chi> i. max (a$i) (c$i)) .. (\<chi> i. min (b$i) (d$i))}"
  1233   unfolding Int_interval
  1234   by (auto simp: mem_box less_eq_vec_def)
  1235     (auto simp: Basis_vec_def inner_axis)
  1236 
  1237 lemma closed_interval_left_cart:
  1238   fixes b :: "real^'n"
  1239   shows "closed {x::real^'n. \<forall>i. x$i \<le> b$i}"
  1240   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1241 
  1242 lemma closed_interval_right_cart:
  1243   fixes a::"real^'n"
  1244   shows "closed {x::real^'n. \<forall>i. a$i \<le> x$i}"
  1245   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1246 
  1247 lemma is_interval_cart:
  1248   "is_interval (s::(real^'n) set) \<longleftrightarrow>
  1249     (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i. ((a$i \<le> x$i \<and> x$i \<le> b$i) \<or> (b$i \<le> x$i \<and> x$i \<le> a$i))) \<longrightarrow> x \<in> s)"
  1250   by (simp add: is_interval_def Ball_def Basis_vec_def inner_axis imp_ex)
  1251 
  1252 lemma closed_halfspace_component_le_cart: "closed {x::real^'n. x$i \<le> a}"
  1253   by (simp add: closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1254 
  1255 lemma closed_halfspace_component_ge_cart: "closed {x::real^'n. x$i \<ge> a}"
  1256   by (simp add: closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1257 
  1258 lemma open_halfspace_component_lt_cart: "open {x::real^'n. x$i < a}"
  1259   by (simp add: open_Collect_less continuous_on_const continuous_on_id continuous_on_component)
  1260 
  1261 lemma open_halfspace_component_gt_cart: "open {x::real^'n. x$i  > a}"
  1262   by (simp add: open_Collect_less continuous_on_const continuous_on_id continuous_on_component)
  1263 
  1264 lemma Lim_component_le_cart:
  1265   fixes f :: "'a \<Rightarrow> real^'n"
  1266   assumes "(f \<longlongrightarrow> l) net" "\<not> (trivial_limit net)"  "eventually (\<lambda>x. f x $i \<le> b) net"
  1267   shows "l$i \<le> b"
  1268   by (rule tendsto_le[OF assms(2) tendsto_const tendsto_vec_nth, OF assms(1, 3)])
  1269 
  1270 lemma Lim_component_ge_cart:
  1271   fixes f :: "'a \<Rightarrow> real^'n"
  1272   assumes "(f \<longlongrightarrow> l) net"  "\<not> (trivial_limit net)"  "eventually (\<lambda>x. b \<le> (f x)$i) net"
  1273   shows "b \<le> l$i"
  1274   by (rule tendsto_le[OF assms(2) tendsto_vec_nth tendsto_const, OF assms(1, 3)])
  1275 
  1276 lemma Lim_component_eq_cart:
  1277   fixes f :: "'a \<Rightarrow> real^'n"
  1278   assumes net: "(f \<longlongrightarrow> l) net" "~(trivial_limit net)" and ev:"eventually (\<lambda>x. f(x)$i = b) net"
  1279   shows "l$i = b"
  1280   using ev[unfolded order_eq_iff eventually_conj_iff] and
  1281     Lim_component_ge_cart[OF net, of b i] and
  1282     Lim_component_le_cart[OF net, of i b] by auto
  1283 
  1284 lemma connected_ivt_component_cart:
  1285   fixes x :: "real^'n"
  1286   shows "connected s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> x$k \<le> a \<Longrightarrow> a \<le> y$k \<Longrightarrow> (\<exists>z\<in>s.  z$k = a)"
  1287   using connected_ivt_hyperplane[of s x y "axis k 1" a]
  1288   by (auto simp add: inner_axis inner_commute)
  1289 
  1290 lemma subspace_substandard_cart: "subspace {x::real^_. (\<forall>i. P i \<longrightarrow> x$i = 0)}"
  1291   unfolding subspace_def by auto
  1292 
  1293 lemma closed_substandard_cart:
  1294   "closed {x::'a::real_normed_vector ^ 'n. \<forall>i. P i \<longrightarrow> x$i = 0}"
  1295 proof -
  1296   { fix i::'n
  1297     have "closed {x::'a ^ 'n. P i \<longrightarrow> x$i = 0}"
  1298       by (cases "P i") (simp_all add: closed_Collect_eq continuous_on_const continuous_on_id continuous_on_component) }
  1299   thus ?thesis
  1300     unfolding Collect_all_eq by (simp add: closed_INT)
  1301 qed
  1302 
  1303 lemma dim_substandard_cart: "dim {x::real^'n. \<forall>i. i \<notin> d \<longrightarrow> x$i = 0} = card d"
  1304   (is "dim ?A = _")
  1305 proof -
  1306   let ?a = "\<lambda>x. axis x 1 :: real^'n"
  1307   have *: "{x. \<forall>i\<in>Basis. i \<notin> ?a ` d \<longrightarrow> x \<bullet> i = 0} = ?A"
  1308     by (auto simp: image_iff Basis_vec_def axis_eq_axis inner_axis)
  1309   have "?a ` d \<subseteq> Basis"
  1310     by (auto simp: Basis_vec_def)
  1311   thus ?thesis
  1312     using dim_substandard[of "?a ` d"] card_image[of ?a d]
  1313     by (auto simp: axis_eq_axis inj_on_def *)
  1314 qed
  1315 
  1316 lemma dim_subset_UNIV_cart:
  1317   fixes S :: "(real^'n) set"
  1318   shows "dim S \<le> CARD('n)"
  1319   by (metis dim_subset_UNIV DIM_cart DIM_real mult.right_neutral)
  1320 
  1321 lemma affinity_inverses:
  1322   assumes m0: "m \<noteq> (0::'a::field)"
  1323   shows "(\<lambda>x. m *s x + c) \<circ> (\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) = id"
  1324   "(\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) \<circ> (\<lambda>x. m *s x + c) = id"
  1325   using m0
  1326   apply (auto simp add: fun_eq_iff vector_add_ldistrib diff_conv_add_uminus simp del: add_uminus_conv_diff)
  1327   apply (simp_all add: vector_smult_lneg[symmetric] vector_smult_assoc vector_sneg_minus1 [symmetric])
  1328   done
  1329 
  1330 lemma vector_affinity_eq:
  1331   assumes m0: "(m::'a::field) \<noteq> 0"
  1332   shows "m *s x + c = y \<longleftrightarrow> x = inverse m *s y + -(inverse m *s c)"
  1333 proof
  1334   assume h: "m *s x + c = y"
  1335   hence "m *s x = y - c" by (simp add: field_simps)
  1336   hence "inverse m *s (m *s x) = inverse m *s (y - c)" by simp
  1337   then show "x = inverse m *s y + - (inverse m *s c)"
  1338     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1339 next
  1340   assume h: "x = inverse m *s y + - (inverse m *s c)"
  1341   show "m *s x + c = y" unfolding h
  1342     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1343 qed
  1344 
  1345 lemma vector_eq_affinity:
  1346     "(m::'a::field) \<noteq> 0 ==> (y = m *s x + c \<longleftrightarrow> inverse(m) *s y + -(inverse(m) *s c) = x)"
  1347   using vector_affinity_eq[where m=m and x=x and y=y and c=c]
  1348   by metis
  1349 
  1350 lemma vector_cart:
  1351   fixes f :: "real^'n \<Rightarrow> real"
  1352   shows "(\<chi> i. f (axis i 1)) = (\<Sum>i\<in>Basis. f i *\<^sub>R i)"
  1353   unfolding euclidean_eq_iff[where 'a="real^'n"]
  1354   by simp (simp add: Basis_vec_def inner_axis)
  1355 
  1356 lemma const_vector_cart:"((\<chi> i. d)::real^'n) = (\<Sum>i\<in>Basis. d *\<^sub>R i)"
  1357   by (rule vector_cart)
  1358 
  1359 subsection "Convex Euclidean Space"
  1360 
  1361 lemma Cart_1:"(1::real^'n) = \<Sum>Basis"
  1362   using const_vector_cart[of 1] by (simp add: one_vec_def)
  1363 
  1364 declare vector_add_ldistrib[simp] vector_ssub_ldistrib[simp] vector_smult_assoc[simp] vector_smult_rneg[simp]
  1365 declare vector_sadd_rdistrib[simp] vector_sub_rdistrib[simp]
  1366 
  1367 lemmas vector_component_simps = vector_minus_component vector_smult_component vector_add_component less_eq_vec_def vec_lambda_beta vector_uminus_component
  1368 
  1369 lemma convex_box_cart:
  1370   assumes "\<And>i. convex {x. P i x}"
  1371   shows "convex {x. \<forall>i. P i (x$i)}"
  1372   using assms unfolding convex_def by auto
  1373 
  1374 lemma convex_positive_orthant_cart: "convex {x::real^'n. (\<forall>i. 0 \<le> x$i)}"
  1375   by (rule convex_box_cart) (simp add: atLeast_def[symmetric])
  1376 
  1377 lemma unit_interval_convex_hull_cart:
  1378   "cbox (0::real^'n) 1 = convex hull {x. \<forall>i. (x$i = 0) \<or> (x$i = 1)}"
  1379   unfolding Cart_1 unit_interval_convex_hull[where 'a="real^'n"] box_real[symmetric]
  1380   by (rule arg_cong[where f="\<lambda>x. convex hull x"]) (simp add: Basis_vec_def inner_axis)
  1381 
  1382 lemma cube_convex_hull_cart:
  1383   assumes "0 < d"
  1384   obtains s::"(real^'n) set"
  1385     where "finite s" "cbox (x - (\<chi> i. d)) (x + (\<chi> i. d)) = convex hull s"
  1386 proof -
  1387   from assms obtain s where "finite s"
  1388     and "cbox (x - sum (( *\<^sub>R) d) Basis) (x + sum (( *\<^sub>R) d) Basis) = convex hull s"
  1389     by (rule cube_convex_hull)
  1390   with that[of s] show thesis
  1391     by (simp add: const_vector_cart)
  1392 qed
  1393 
  1394 
  1395 subsection "Derivative"
  1396 
  1397 definition "jacobian f net = matrix(frechet_derivative f net)"
  1398 
  1399 lemma jacobian_works:
  1400   "(f::(real^'a) \<Rightarrow> (real^'b)) differentiable net \<longleftrightarrow>
  1401     (f has_derivative (\<lambda>h. (jacobian f net) *v h)) net"
  1402   apply rule
  1403   unfolding jacobian_def
  1404   apply (simp only: matrix_works[OF linear_frechet_derivative]) defer
  1405   apply (rule differentiableI)
  1406   apply assumption
  1407   unfolding frechet_derivative_works
  1408   apply assumption
  1409   done
  1410 
  1411 
  1412 subsection \<open>Component of the differential must be zero if it exists at a local
  1413   maximum or minimum for that corresponding component.\<close>
  1414 
  1415 lemma differential_zero_maxmin_cart:
  1416   fixes f::"real^'a \<Rightarrow> real^'b"
  1417   assumes "0 < e" "((\<forall>y \<in> ball x e. (f y)$k \<le> (f x)$k) \<or> (\<forall>y\<in>ball x e. (f x)$k \<le> (f y)$k))"
  1418     "f differentiable (at x)"
  1419   shows "jacobian f (at x) $ k = 0"
  1420   using differential_zero_maxmin_component[of "axis k 1" e x f] assms
  1421     vector_cart[of "\<lambda>j. frechet_derivative f (at x) j $ k"]
  1422   by (simp add: Basis_vec_def axis_eq_axis inner_axis jacobian_def matrix_def)
  1423 
  1424 subsection \<open>Lemmas for working on @{typ "real^1"}\<close>
  1425 
  1426 lemma forall_1[simp]: "(\<forall>i::1. P i) \<longleftrightarrow> P 1"
  1427   by (metis (full_types) num1_eq_iff)
  1428 
  1429 lemma ex_1[simp]: "(\<exists>x::1. P x) \<longleftrightarrow> P 1"
  1430   by auto (metis (full_types) num1_eq_iff)
  1431 
  1432 lemma exhaust_2:
  1433   fixes x :: 2
  1434   shows "x = 1 \<or> x = 2"
  1435 proof (induct x)
  1436   case (of_int z)
  1437   then have "0 <= z" and "z < 2" by simp_all
  1438   then have "z = 0 | z = 1" by arith
  1439   then show ?case by auto
  1440 qed
  1441 
  1442 lemma forall_2: "(\<forall>i::2. P i) \<longleftrightarrow> P 1 \<and> P 2"
  1443   by (metis exhaust_2)
  1444 
  1445 lemma exhaust_3:
  1446   fixes x :: 3
  1447   shows "x = 1 \<or> x = 2 \<or> x = 3"
  1448 proof (induct x)
  1449   case (of_int z)
  1450   then have "0 <= z" and "z < 3" by simp_all
  1451   then have "z = 0 \<or> z = 1 \<or> z = 2" by arith
  1452   then show ?case by auto
  1453 qed
  1454 
  1455 lemma forall_3: "(\<forall>i::3. P i) \<longleftrightarrow> P 1 \<and> P 2 \<and> P 3"
  1456   by (metis exhaust_3)
  1457 
  1458 lemma UNIV_1 [simp]: "UNIV = {1::1}"
  1459   by (auto simp add: num1_eq_iff)
  1460 
  1461 lemma UNIV_2: "UNIV = {1::2, 2::2}"
  1462   using exhaust_2 by auto
  1463 
  1464 lemma UNIV_3: "UNIV = {1::3, 2::3, 3::3}"
  1465   using exhaust_3 by auto
  1466 
  1467 lemma sum_1: "sum f (UNIV::1 set) = f 1"
  1468   unfolding UNIV_1 by simp
  1469 
  1470 lemma sum_2: "sum f (UNIV::2 set) = f 1 + f 2"
  1471   unfolding UNIV_2 by simp
  1472 
  1473 lemma sum_3: "sum f (UNIV::3 set) = f 1 + f 2 + f 3"
  1474   unfolding UNIV_3 by (simp add: ac_simps)
  1475 
  1476 instantiation num1 :: cart_one
  1477 begin
  1478 
  1479 instance
  1480 proof
  1481   show "CARD(1) = Suc 0" by auto
  1482 qed
  1483 
  1484 end
  1485 
  1486 subsection\<open>The collapse of the general concepts to dimension one.\<close>
  1487 
  1488 lemma vector_one: "(x::'a ^1) = (\<chi> i. (x$1))"
  1489   by (simp add: vec_eq_iff)
  1490 
  1491 lemma forall_one: "(\<forall>(x::'a ^1). P x) \<longleftrightarrow> (\<forall>x. P(\<chi> i. x))"
  1492   apply auto
  1493   apply (erule_tac x= "x$1" in allE)
  1494   apply (simp only: vector_one[symmetric])
  1495   done
  1496 
  1497 lemma norm_vector_1: "norm (x :: _^1) = norm (x$1)"
  1498   by (simp add: norm_vec_def)
  1499 
  1500 lemma norm_real: "norm(x::real ^ 1) = \<bar>x$1\<bar>"
  1501   by (simp add: norm_vector_1)
  1502 
  1503 lemma dist_real: "dist(x::real ^ 1) y = \<bar>(x$1) - (y$1)\<bar>"
  1504   by (auto simp add: norm_real dist_norm)
  1505 
  1506 
  1507 subsection\<open>Explicit vector construction from lists.\<close>
  1508 
  1509 definition "vector l = (\<chi> i. foldr (\<lambda>x f n. fun_upd (f (n+1)) n x) l (\<lambda>n x. 0) 1 i)"
  1510 
  1511 lemma vector_1: "(vector[x]) $1 = x"
  1512   unfolding vector_def by simp
  1513 
  1514 lemma vector_2:
  1515  "(vector[x,y]) $1 = x"
  1516  "(vector[x,y] :: 'a^2)$2 = (y::'a::zero)"
  1517   unfolding vector_def by simp_all
  1518 
  1519 lemma vector_3:
  1520  "(vector [x,y,z] ::('a::zero)^3)$1 = x"
  1521  "(vector [x,y,z] ::('a::zero)^3)$2 = y"
  1522  "(vector [x,y,z] ::('a::zero)^3)$3 = z"
  1523   unfolding vector_def by simp_all
  1524 
  1525 lemma forall_vector_1: "(\<forall>v::'a::zero^1. P v) \<longleftrightarrow> (\<forall>x. P(vector[x]))"
  1526   by (metis vector_1 vector_one)
  1527 
  1528 lemma forall_vector_2: "(\<forall>v::'a::zero^2. P v) \<longleftrightarrow> (\<forall>x y. P(vector[x, y]))"
  1529   apply auto
  1530   apply (erule_tac x="v$1" in allE)
  1531   apply (erule_tac x="v$2" in allE)
  1532   apply (subgoal_tac "vector [v$1, v$2] = v")
  1533   apply simp
  1534   apply (vector vector_def)
  1535   apply (simp add: forall_2)
  1536   done
  1537 
  1538 lemma forall_vector_3: "(\<forall>v::'a::zero^3. P v) \<longleftrightarrow> (\<forall>x y z. P(vector[x, y, z]))"
  1539   apply auto
  1540   apply (erule_tac x="v$1" in allE)
  1541   apply (erule_tac x="v$2" in allE)
  1542   apply (erule_tac x="v$3" in allE)
  1543   apply (subgoal_tac "vector [v$1, v$2, v$3] = v")
  1544   apply simp
  1545   apply (vector vector_def)
  1546   apply (simp add: forall_3)
  1547   done
  1548 
  1549 lemma bounded_linear_component_cart[intro]: "bounded_linear (\<lambda>x::real^'n. x $ k)"
  1550   apply (rule bounded_linearI[where K=1])
  1551   using component_le_norm_cart[of _ k] unfolding real_norm_def by auto
  1552 
  1553 lemma interval_split_cart:
  1554   "{a..b::real^'n} \<inter> {x. x$k \<le> c} = {a .. (\<chi> i. if i = k then min (b$k) c else b$i)}"
  1555   "cbox a b \<inter> {x. x$k \<ge> c} = {(\<chi> i. if i = k then max (a$k) c else a$i) .. b}"
  1556   apply (rule_tac[!] set_eqI)
  1557   unfolding Int_iff mem_box_cart mem_Collect_eq interval_cbox_cart
  1558   unfolding vec_lambda_beta
  1559   by auto
  1560 
  1561 lemmas cartesian_euclidean_space_uniform_limit_intros[uniform_limit_intros] =
  1562   bounded_linear.uniform_limit[OF blinfun.bounded_linear_right]
  1563   bounded_linear.uniform_limit[OF bounded_linear_vec_nth]
  1564   bounded_linear.uniform_limit[OF bounded_linear_component_cart]
  1565 
  1566 end