src/Pure/thm.ML
author wenzelm
Thu Oct 16 22:44:33 2008 +0200 (2008-10-16)
changeset 28624 d983515e5cdf
parent 28446 a01de3b3fa2e
child 28648 4889b48919a0
permissions -rw-r--r--
added weaken_sorts;
strip_shyps: minimal list of minimized extra sorts;
tuned;
     1 (*  Title:      Pure/thm.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1994  University of Cambridge
     5 
     6 The very core of Isabelle's Meta Logic: certified types and terms,
     7 derivations, theorems, framework rules (including lifting and
     8 resolution), oracles.
     9 *)
    10 
    11 signature BASIC_THM =
    12   sig
    13   (*certified types*)
    14   type ctyp
    15   val rep_ctyp: ctyp ->
    16    {thy_ref: theory_ref,
    17     T: typ,
    18     maxidx: int,
    19     sorts: sort OrdList.T}
    20   val theory_of_ctyp: ctyp -> theory
    21   val typ_of: ctyp -> typ
    22   val ctyp_of: theory -> typ -> ctyp
    23 
    24   (*certified terms*)
    25   type cterm
    26   exception CTERM of string * cterm list
    27   val rep_cterm: cterm ->
    28    {thy_ref: theory_ref,
    29     t: term,
    30     T: typ,
    31     maxidx: int,
    32     sorts: sort OrdList.T}
    33   val crep_cterm: cterm ->
    34     {thy_ref: theory_ref, t: term, T: ctyp, maxidx: int, sorts: sort OrdList.T}
    35   val theory_of_cterm: cterm -> theory
    36   val term_of: cterm -> term
    37   val cterm_of: theory -> term -> cterm
    38   val ctyp_of_term: cterm -> ctyp
    39 
    40   (*theorems*)
    41   type thm
    42   type conv = cterm -> thm
    43   type attribute = Context.generic * thm -> Context.generic * thm
    44   val rep_thm: thm ->
    45    {thy_ref: theory_ref,
    46     tags: Properties.T,
    47     maxidx: int,
    48     shyps: sort OrdList.T,
    49     hyps: term OrdList.T,
    50     tpairs: (term * term) list,
    51     prop: term}
    52   val crep_thm: thm ->
    53    {thy_ref: theory_ref,
    54     tags: Properties.T,
    55     maxidx: int,
    56     shyps: sort OrdList.T,
    57     hyps: cterm OrdList.T,
    58     tpairs: (cterm * cterm) list,
    59     prop: cterm}
    60   exception THM of string * int * thm list
    61   val theory_of_thm: thm -> theory
    62   val prop_of: thm -> term
    63   val tpairs_of: thm -> (term * term) list
    64   val concl_of: thm -> term
    65   val prems_of: thm -> term list
    66   val nprems_of: thm -> int
    67   val cprop_of: thm -> cterm
    68   val cprem_of: thm -> int -> cterm
    69   val transfer: theory -> thm -> thm
    70   val weaken: cterm -> thm -> thm
    71   val weaken_sorts: sort list -> cterm -> cterm
    72   val extra_shyps: thm -> sort list
    73   val strip_shyps: thm -> thm
    74   val get_axiom_i: theory -> string -> thm
    75   val get_axiom: theory -> xstring -> thm
    76   val def_name: string -> string
    77   val def_name_optional: string -> string -> string
    78   val get_def: theory -> xstring -> thm
    79   val axioms_of: theory -> (string * thm) list
    80 
    81   (*meta rules*)
    82   val assume: cterm -> thm
    83   val implies_intr: cterm -> thm -> thm
    84   val implies_elim: thm -> thm -> thm
    85   val forall_intr: cterm -> thm -> thm
    86   val forall_elim: cterm -> thm -> thm
    87   val reflexive: cterm -> thm
    88   val symmetric: thm -> thm
    89   val transitive: thm -> thm -> thm
    90   val beta_conversion: bool -> conv
    91   val eta_conversion: conv
    92   val eta_long_conversion: conv
    93   val abstract_rule: string -> cterm -> thm -> thm
    94   val combination: thm -> thm -> thm
    95   val equal_intr: thm -> thm -> thm
    96   val equal_elim: thm -> thm -> thm
    97   val flexflex_rule: thm -> thm Seq.seq
    98   val generalize: string list * string list -> int -> thm -> thm
    99   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
   100   val instantiate_cterm: (ctyp * ctyp) list * (cterm * cterm) list -> cterm -> cterm
   101   val trivial: cterm -> thm
   102   val class_triv: theory -> class -> thm
   103   val unconstrainT: ctyp -> thm -> thm
   104   val dest_state: thm * int -> (term * term) list * term list * term * term
   105   val lift_rule: cterm -> thm -> thm
   106   val incr_indexes: int -> thm -> thm
   107   val assumption: int -> thm -> thm Seq.seq
   108   val eq_assumption: int -> thm -> thm
   109   val rotate_rule: int -> int -> thm -> thm
   110   val permute_prems: int -> int -> thm -> thm
   111   val rename_params_rule: string list * int -> thm -> thm
   112   val compose_no_flatten: bool -> thm * int -> int -> thm -> thm Seq.seq
   113   val bicompose: bool -> bool * thm * int -> int -> thm -> thm Seq.seq
   114   val biresolution: bool -> (bool * thm) list -> int -> thm -> thm Seq.seq
   115 end;
   116 
   117 signature THM =
   118 sig
   119   include BASIC_THM
   120   val dest_ctyp: ctyp -> ctyp list
   121   val dest_comb: cterm -> cterm * cterm
   122   val dest_fun: cterm -> cterm
   123   val dest_arg: cterm -> cterm
   124   val dest_fun2: cterm -> cterm
   125   val dest_arg1: cterm -> cterm
   126   val dest_abs: string option -> cterm -> cterm * cterm
   127   val adjust_maxidx_cterm: int -> cterm -> cterm
   128   val capply: cterm -> cterm -> cterm
   129   val cabs: cterm -> cterm -> cterm
   130   val rep_deriv: thm ->
   131    {oracle: bool,
   132     proof: Proofterm.proof,
   133     promises: (serial * thm Future.T) OrdList.T}
   134   val oracle_of: thm -> bool
   135   val major_prem_of: thm -> term
   136   val no_prems: thm -> bool
   137   val terms_of_tpairs: (term * term) list -> term list
   138   val maxidx_of: thm -> int
   139   val maxidx_thm: thm -> int -> int
   140   val hyps_of: thm -> term list
   141   val full_prop_of: thm -> term
   142   val get_name: thm -> string
   143   val put_name: string -> thm -> thm
   144   val get_tags: thm -> Properties.T
   145   val map_tags: (Properties.T -> Properties.T) -> thm -> thm
   146   val norm_proof: thm -> thm
   147   val adjust_maxidx_thm: int -> thm -> thm
   148   val rename_boundvars: term -> term -> thm -> thm
   149   val match: cterm * cterm -> (ctyp * ctyp) list * (cterm * cterm) list
   150   val first_order_match: cterm * cterm -> (ctyp * ctyp) list * (cterm * cterm) list
   151   val incr_indexes_cterm: int -> cterm -> cterm
   152   val varifyT: thm -> thm
   153   val varifyT': (string * sort) list -> thm -> ((string * sort) * indexname) list * thm
   154   val freezeT: thm -> thm
   155   val join_futures: theory -> unit
   156   val future: (unit -> thm) -> cterm -> thm
   157   val proof_of: thm -> Proofterm.proof
   158   val extern_oracles: theory -> xstring list
   159   val add_oracle: bstring * ('a -> cterm) -> theory -> (string * ('a -> thm)) * theory
   160 end;
   161 
   162 structure Thm:> THM =
   163 struct
   164 
   165 structure Pt = Proofterm;
   166 
   167 
   168 (*** Certified terms and types ***)
   169 
   170 (** certified types **)
   171 
   172 datatype ctyp = Ctyp of
   173  {thy_ref: theory_ref,
   174   T: typ,
   175   maxidx: int,
   176   sorts: sort OrdList.T};
   177 
   178 fun rep_ctyp (Ctyp args) = args;
   179 fun theory_of_ctyp (Ctyp {thy_ref, ...}) = Theory.deref thy_ref;
   180 fun typ_of (Ctyp {T, ...}) = T;
   181 
   182 fun ctyp_of thy raw_T =
   183   let
   184     val T = Sign.certify_typ thy raw_T;
   185     val maxidx = Term.maxidx_of_typ T;
   186     val sorts = Sorts.insert_typ T [];
   187   in Ctyp {thy_ref = Theory.check_thy thy, T = T, maxidx = maxidx, sorts = sorts} end;
   188 
   189 fun dest_ctyp (Ctyp {thy_ref, T = Type (s, Ts), maxidx, sorts}) =
   190       map (fn T => Ctyp {thy_ref = thy_ref, T = T, maxidx = maxidx, sorts = sorts}) Ts
   191   | dest_ctyp cT = raise TYPE ("dest_ctyp", [typ_of cT], []);
   192 
   193 
   194 
   195 (** certified terms **)
   196 
   197 (*certified terms with checked typ, maxidx, and sorts*)
   198 datatype cterm = Cterm of
   199  {thy_ref: theory_ref,
   200   t: term,
   201   T: typ,
   202   maxidx: int,
   203   sorts: sort OrdList.T};
   204 
   205 exception CTERM of string * cterm list;
   206 
   207 fun rep_cterm (Cterm args) = args;
   208 
   209 fun crep_cterm (Cterm {thy_ref, t, T, maxidx, sorts}) =
   210   {thy_ref = thy_ref, t = t, maxidx = maxidx, sorts = sorts,
   211     T = Ctyp {thy_ref = thy_ref, T = T, maxidx = maxidx, sorts = sorts}};
   212 
   213 fun theory_of_cterm (Cterm {thy_ref, ...}) = Theory.deref thy_ref;
   214 fun term_of (Cterm {t, ...}) = t;
   215 
   216 fun ctyp_of_term (Cterm {thy_ref, T, maxidx, sorts, ...}) =
   217   Ctyp {thy_ref = thy_ref, T = T, maxidx = maxidx, sorts = sorts};
   218 
   219 fun cterm_of thy tm =
   220   let
   221     val (t, T, maxidx) = Sign.certify_term thy tm;
   222     val sorts = Sorts.insert_term t [];
   223   in Cterm {thy_ref = Theory.check_thy thy, t = t, T = T, maxidx = maxidx, sorts = sorts} end;
   224 
   225 fun merge_thys0 (Cterm {thy_ref = r1, t = t1, ...}) (Cterm {thy_ref = r2, t = t2, ...}) =
   226   Theory.merge_refs (r1, r2);
   227 
   228 
   229 (* destructors *)
   230 
   231 fun dest_comb (ct as Cterm {t = c $ a, T, thy_ref, maxidx, sorts}) =
   232       let val A = Term.argument_type_of c 0 in
   233         (Cterm {t = c, T = A --> T, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts},
   234          Cterm {t = a, T = A, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts})
   235       end
   236   | dest_comb ct = raise CTERM ("dest_comb", [ct]);
   237 
   238 fun dest_fun (ct as Cterm {t = c $ _, T, thy_ref, maxidx, sorts}) =
   239       let val A = Term.argument_type_of c 0
   240       in Cterm {t = c, T = A --> T, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts} end
   241   | dest_fun ct = raise CTERM ("dest_fun", [ct]);
   242 
   243 fun dest_arg (ct as Cterm {t = c $ a, T = _, thy_ref, maxidx, sorts}) =
   244       let val A = Term.argument_type_of c 0
   245       in Cterm {t = a, T = A, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts} end
   246   | dest_arg ct = raise CTERM ("dest_arg", [ct]);
   247 
   248 
   249 fun dest_fun2 (Cterm {t = c $ a $ b, T, thy_ref, maxidx, sorts}) =
   250       let
   251         val A = Term.argument_type_of c 0;
   252         val B = Term.argument_type_of c 1;
   253       in Cterm {t = c, T = A --> B --> T, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts} end
   254   | dest_fun2 ct = raise CTERM ("dest_fun2", [ct]);
   255 
   256 fun dest_arg1 (Cterm {t = c $ a $ _, T = _, thy_ref, maxidx, sorts}) =
   257       let val A = Term.argument_type_of c 0
   258       in Cterm {t = a, T = A, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts} end
   259   | dest_arg1 ct = raise CTERM ("dest_arg1", [ct]);
   260 
   261 fun dest_abs a (ct as
   262         Cterm {t = Abs (x, T, t), T = Type ("fun", [_, U]), thy_ref, maxidx, sorts}) =
   263       let val (y', t') = Term.dest_abs (the_default x a, T, t) in
   264         (Cterm {t = Free (y', T), T = T, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts},
   265           Cterm {t = t', T = U, thy_ref = thy_ref, maxidx = maxidx, sorts = sorts})
   266       end
   267   | dest_abs _ ct = raise CTERM ("dest_abs", [ct]);
   268 
   269 
   270 (* constructors *)
   271 
   272 fun capply
   273   (cf as Cterm {t = f, T = Type ("fun", [dty, rty]), maxidx = maxidx1, sorts = sorts1, ...})
   274   (cx as Cterm {t = x, T, maxidx = maxidx2, sorts = sorts2, ...}) =
   275     if T = dty then
   276       Cterm {thy_ref = merge_thys0 cf cx,
   277         t = f $ x,
   278         T = rty,
   279         maxidx = Int.max (maxidx1, maxidx2),
   280         sorts = Sorts.union sorts1 sorts2}
   281       else raise CTERM ("capply: types don't agree", [cf, cx])
   282   | capply cf cx = raise CTERM ("capply: first arg is not a function", [cf, cx]);
   283 
   284 fun cabs
   285   (ct1 as Cterm {t = t1, T = T1, maxidx = maxidx1, sorts = sorts1, ...})
   286   (ct2 as Cterm {t = t2, T = T2, maxidx = maxidx2, sorts = sorts2, ...}) =
   287     let val t = Term.lambda t1 t2 in
   288       Cterm {thy_ref = merge_thys0 ct1 ct2,
   289         t = t, T = T1 --> T2,
   290         maxidx = Int.max (maxidx1, maxidx2),
   291         sorts = Sorts.union sorts1 sorts2}
   292     end;
   293 
   294 
   295 (* indexes *)
   296 
   297 fun adjust_maxidx_cterm i (ct as Cterm {thy_ref, t, T, maxidx, sorts}) =
   298   if maxidx = i then ct
   299   else if maxidx < i then
   300     Cterm {maxidx = i, thy_ref = thy_ref, t = t, T = T, sorts = sorts}
   301   else
   302     Cterm {maxidx = Int.max (maxidx_of_term t, i), thy_ref = thy_ref, t = t, T = T, sorts = sorts};
   303 
   304 fun incr_indexes_cterm i (ct as Cterm {thy_ref, t, T, maxidx, sorts}) =
   305   if i < 0 then raise CTERM ("negative increment", [ct])
   306   else if i = 0 then ct
   307   else Cterm {thy_ref = thy_ref, t = Logic.incr_indexes ([], i) t,
   308     T = Logic.incr_tvar i T, maxidx = maxidx + i, sorts = sorts};
   309 
   310 
   311 (* matching *)
   312 
   313 local
   314 
   315 fun gen_match match
   316     (ct1 as Cterm {t = t1, sorts = sorts1, ...},
   317      ct2 as Cterm {t = t2, sorts = sorts2, maxidx = maxidx2, ...}) =
   318   let
   319     val thy = Theory.deref (merge_thys0 ct1 ct2);
   320     val (Tinsts, tinsts) = match thy (t1, t2) (Vartab.empty, Vartab.empty);
   321     val sorts = Sorts.union sorts1 sorts2;
   322     fun mk_cTinst ((a, i), (S, T)) =
   323       (Ctyp {T = TVar ((a, i), S), thy_ref = Theory.check_thy thy, maxidx = i, sorts = sorts},
   324        Ctyp {T = T, thy_ref = Theory.check_thy thy, maxidx = maxidx2, sorts = sorts});
   325     fun mk_ctinst ((x, i), (T, t)) =
   326       let val T = Envir.typ_subst_TVars Tinsts T in
   327         (Cterm {t = Var ((x, i), T), T = T, thy_ref = Theory.check_thy thy,
   328           maxidx = i, sorts = sorts},
   329          Cterm {t = t, T = T, thy_ref = Theory.check_thy thy, maxidx = maxidx2, sorts = sorts})
   330       end;
   331   in (Vartab.fold (cons o mk_cTinst) Tinsts [], Vartab.fold (cons o mk_ctinst) tinsts []) end;
   332 
   333 in
   334 
   335 val match = gen_match Pattern.match;
   336 val first_order_match = gen_match Pattern.first_order_match;
   337 
   338 end;
   339 
   340 
   341 
   342 (*** Derivations and Theorems ***)
   343 
   344 datatype thm = Thm of
   345  deriv *                                        (*derivation*)
   346  {thy_ref: theory_ref,                          (*dynamic reference to theory*)
   347   tags: Properties.T,                           (*additional annotations/comments*)
   348   maxidx: int,                                  (*maximum index of any Var or TVar*)
   349   shyps: sort OrdList.T,                        (*sort hypotheses*)
   350   hyps: term OrdList.T,                         (*hypotheses*)
   351   tpairs: (term * term) list,                   (*flex-flex pairs*)
   352   prop: term}                                   (*conclusion*)
   353 and deriv = Deriv of
   354  {oracle: bool,                                 (*oracle occurrence flag*)
   355   proof: Pt.proof,                              (*proof term*)
   356   promises: (serial * thm Future.T) OrdList.T}; (*promised derivations*)
   357 
   358 type conv = cterm -> thm;
   359 
   360 (*attributes subsume any kind of rules or context modifiers*)
   361 type attribute = Context.generic * thm -> Context.generic * thm;
   362 
   363 (*errors involving theorems*)
   364 exception THM of string * int * thm list;
   365 
   366 fun rep_thm (Thm (_, args)) = args;
   367 
   368 fun crep_thm (Thm (_, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop})) =
   369   let fun cterm max t = Cterm {thy_ref = thy_ref, t = t, T = propT, maxidx = max, sorts = shyps} in
   370    {thy_ref = thy_ref, tags = tags, maxidx = maxidx, shyps = shyps,
   371     hyps = map (cterm ~1) hyps,
   372     tpairs = map (pairself (cterm maxidx)) tpairs,
   373     prop = cterm maxidx prop}
   374   end;
   375 
   376 fun terms_of_tpairs tpairs = fold_rev (fn (t, u) => cons t o cons u) tpairs [];
   377 
   378 fun eq_tpairs ((t, u), (t', u')) = t aconv t' andalso u aconv u';
   379 fun union_tpairs ts us = Library.merge eq_tpairs (ts, us);
   380 val maxidx_tpairs = fold (fn (t, u) => Term.maxidx_term t #> Term.maxidx_term u);
   381 
   382 fun attach_tpairs tpairs prop =
   383   Logic.list_implies (map Logic.mk_equals tpairs, prop);
   384 
   385 fun full_prop_of (Thm (_, {tpairs, prop, ...})) = attach_tpairs tpairs prop;
   386 
   387 val union_hyps = OrdList.union Term.fast_term_ord;
   388 val insert_hyps = OrdList.insert Term.fast_term_ord;
   389 val remove_hyps = OrdList.remove Term.fast_term_ord;
   390 
   391 
   392 (* merge theories of cterms/thms -- trivial absorption only *)
   393 
   394 fun merge_thys1 (Cterm {thy_ref = r1, ...}) (th as Thm (_, {thy_ref = r2, ...})) =
   395   Theory.merge_refs (r1, r2);
   396 
   397 fun merge_thys2 (th1 as Thm (_, {thy_ref = r1, ...})) (th2 as Thm (_, {thy_ref = r2, ...})) =
   398   Theory.merge_refs (r1, r2);
   399 
   400 
   401 (* basic components *)
   402 
   403 fun rep_deriv (Thm (Deriv args, _)) = args;
   404 val oracle_of = #oracle o rep_deriv;
   405 
   406 val theory_of_thm = Theory.deref o #thy_ref o rep_thm;
   407 val maxidx_of = #maxidx o rep_thm;
   408 fun maxidx_thm th i = Int.max (maxidx_of th, i);
   409 val hyps_of = #hyps o rep_thm;
   410 val prop_of = #prop o rep_thm;
   411 val tpairs_of = #tpairs o rep_thm;
   412 
   413 val concl_of = Logic.strip_imp_concl o prop_of;
   414 val prems_of = Logic.strip_imp_prems o prop_of;
   415 val nprems_of = Logic.count_prems o prop_of;
   416 fun no_prems th = nprems_of th = 0;
   417 
   418 fun major_prem_of th =
   419   (case prems_of th of
   420     prem :: _ => Logic.strip_assums_concl prem
   421   | [] => raise THM ("major_prem_of: rule with no premises", 0, [th]));
   422 
   423 (*the statement of any thm is a cterm*)
   424 fun cprop_of (Thm (_, {thy_ref, maxidx, shyps, prop, ...})) =
   425   Cterm {thy_ref = thy_ref, maxidx = maxidx, T = propT, t = prop, sorts = shyps};
   426 
   427 fun cprem_of (th as Thm (_, {thy_ref, maxidx, shyps, prop, ...})) i =
   428   Cterm {thy_ref = thy_ref, maxidx = maxidx, T = propT, sorts = shyps,
   429     t = Logic.nth_prem (i, prop) handle TERM _ => raise THM ("cprem_of", i, [th])};
   430 
   431 (*explicit transfer to a super theory*)
   432 fun transfer thy' thm =
   433   let
   434     val Thm (der, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop}) = thm;
   435     val thy = Theory.deref thy_ref;
   436     val _ = Theory.subthy (thy, thy') orelse raise THM ("transfer: not a super theory", 0, [thm]);
   437     val is_eq = Theory.eq_thy (thy, thy');
   438     val _ = Theory.check_thy thy;
   439   in
   440     if is_eq then thm
   441     else
   442       Thm (der,
   443        {thy_ref = Theory.check_thy thy',
   444         tags = tags,
   445         maxidx = maxidx,
   446         shyps = shyps,
   447         hyps = hyps,
   448         tpairs = tpairs,
   449         prop = prop})
   450   end;
   451 
   452 (*explicit weakening: maps |- B to A |- B*)
   453 fun weaken raw_ct th =
   454   let
   455     val ct as Cterm {t = A, T, sorts, maxidx = maxidxA, ...} = adjust_maxidx_cterm ~1 raw_ct;
   456     val Thm (der, {tags, maxidx, shyps, hyps, tpairs, prop, ...}) = th;
   457   in
   458     if T <> propT then
   459       raise THM ("weaken: assumptions must have type prop", 0, [])
   460     else if maxidxA <> ~1 then
   461       raise THM ("weaken: assumptions may not contain schematic variables", maxidxA, [])
   462     else
   463       Thm (der,
   464        {thy_ref = merge_thys1 ct th,
   465         tags = tags,
   466         maxidx = maxidx,
   467         shyps = Sorts.union sorts shyps,
   468         hyps = insert_hyps A hyps,
   469         tpairs = tpairs,
   470         prop = prop})
   471   end;
   472 
   473 fun weaken_sorts raw_sorts ct =
   474   let
   475     val Cterm {thy_ref, t, T, maxidx, sorts} = ct;
   476     val thy = Theory.deref thy_ref;
   477     val more_sorts = Sorts.make (map (Sign.certify_sort thy) raw_sorts);
   478     val sorts' = Sorts.union sorts more_sorts;
   479   in Cterm {thy_ref = Theory.check_thy thy, t = t, T = T, maxidx = maxidx, sorts = sorts'} end;
   480 
   481 
   482 
   483 (** sort contexts of theorems **)
   484 
   485 fun present_sorts (Thm (_, {hyps, tpairs, prop, ...})) =
   486   fold (fn (t, u) => Sorts.insert_term t o Sorts.insert_term u) tpairs
   487     (Sorts.insert_terms hyps (Sorts.insert_term prop []));
   488 
   489 (*remove extra sorts that are non-empty by virtue of type signature information*)
   490 fun strip_shyps (thm as Thm (_, {shyps = [], ...})) = thm
   491   | strip_shyps (thm as Thm (der, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop})) =
   492       let
   493         val thy = Theory.deref thy_ref;
   494         val present = present_sorts thm;
   495         val extra = Sorts.subtract present shyps;
   496         val extra' =
   497           Sorts.subtract (map #2 (Sign.witness_sorts thy present extra)) extra
   498           |> Sorts.minimal_sorts (Sign.classes_of thy);
   499         val shyps' = Sorts.union present extra';
   500       in
   501         Thm (der, {thy_ref = Theory.check_thy thy, tags = tags, maxidx = maxidx,
   502           shyps = shyps', hyps = hyps, tpairs = tpairs, prop = prop})
   503       end;
   504 
   505 (*dangling sort constraints of a thm*)
   506 fun extra_shyps (th as Thm (_, {shyps, ...})) = Sorts.subtract (present_sorts th) shyps;
   507 
   508 
   509 
   510 (** derivations **)
   511 
   512 fun make_deriv oracle promises proof =
   513   Deriv {oracle = oracle, promises = promises, proof = proof};
   514 
   515 val empty_deriv = make_deriv false [] Pt.min_proof;
   516 
   517 
   518 (* inference rules *)
   519 
   520 fun promise_ord ((i, _), (j, _)) = int_ord (j, i);
   521 
   522 fun deriv_rule2 f
   523     (Deriv {oracle = ora1, promises = ps1, proof = prf1})
   524     (Deriv {oracle = ora2, promises = ps2, proof = prf2}) =
   525   let
   526     val ora = ora1 orelse ora2;
   527     val ps = OrdList.union promise_ord ps1 ps2;
   528     val prf =
   529       (case ! Pt.proofs of
   530         2 => f prf1 prf2
   531       | 1 => MinProof (([], [], []) |> Pt.mk_min_proof prf1 |> Pt.mk_min_proof prf2)
   532       | 0 =>
   533           if ora then MinProof ([], [], [] |> Pt.add_oracles ora1 prf1 |> Pt.add_oracles ora2 prf2)
   534           else Pt.min_proof
   535       | i => error ("Illegal level of detail for proof objects: " ^ string_of_int i));
   536   in make_deriv ora ps prf end;
   537 
   538 fun deriv_rule1 f = deriv_rule2 (K f) empty_deriv;
   539 fun deriv_rule0 prf = deriv_rule1 I (make_deriv false [] prf);
   540 
   541 
   542 
   543 (** Axioms **)
   544 
   545 (*look up the named axiom in the theory or its ancestors*)
   546 fun get_axiom_i theory name =
   547   let
   548     fun get_ax thy =
   549       Symtab.lookup (Theory.axiom_table thy) name
   550       |> Option.map (fn prop =>
   551            let
   552              val der = deriv_rule0 (Pt.axm_proof name prop);
   553              val maxidx = maxidx_of_term prop;
   554              val shyps = Sorts.insert_term prop [];
   555            in
   556              Thm (der, {thy_ref = Theory.check_thy thy, tags = [],
   557                maxidx = maxidx, shyps = shyps, hyps = [], tpairs = [], prop = prop})
   558            end);
   559   in
   560     (case get_first get_ax (theory :: Theory.ancestors_of theory) of
   561       SOME thm => thm
   562     | NONE => raise THEORY ("No axiom " ^ quote name, [theory]))
   563   end;
   564 
   565 fun get_axiom thy =
   566   get_axiom_i thy o NameSpace.intern (Theory.axiom_space thy);
   567 
   568 fun def_name c = c ^ "_def";
   569 
   570 fun def_name_optional c "" = def_name c
   571   | def_name_optional _ name = name;
   572 
   573 fun get_def thy = get_axiom thy o def_name;
   574 
   575 
   576 (*return additional axioms of this theory node*)
   577 fun axioms_of thy =
   578   map (fn s => (s, get_axiom_i thy s)) (Symtab.keys (Theory.axiom_table thy));
   579 
   580 
   581 (* official name and additional tags *)
   582 
   583 fun get_name (Thm (Deriv {proof, ...}, {hyps, prop, ...})) = Pt.get_name hyps prop proof;
   584 
   585 fun put_name name thm =
   586   let
   587     val Thm (Deriv {oracle, promises, proof}, args as {thy_ref, hyps, prop, tpairs, ...}) = thm;
   588     val _ = null tpairs orelse raise THM ("name_thm: unsolved flex-flex constraints", 0, [thm]);
   589     val thy = Theory.deref thy_ref;
   590     val der' = make_deriv oracle promises (Pt.thm_proof thy name hyps prop proof);
   591     val _ = Theory.check_thy thy;
   592   in Thm (der', args) end;
   593 
   594 
   595 val get_tags = #tags o rep_thm;
   596 
   597 fun map_tags f (Thm (der, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop})) =
   598   Thm (der, {thy_ref = thy_ref, tags = f tags, maxidx = maxidx,
   599     shyps = shyps, hyps = hyps, tpairs = tpairs, prop = prop});
   600 
   601 
   602 fun norm_proof (Thm (der, args as {thy_ref, ...})) =
   603   let
   604     val thy = Theory.deref thy_ref;
   605     val der' = deriv_rule1 (Pt.rew_proof thy) der;
   606     val _ = Theory.check_thy thy;
   607   in Thm (der', args) end;
   608 
   609 fun adjust_maxidx_thm i (th as Thm (der, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop})) =
   610   if maxidx = i then th
   611   else if maxidx < i then
   612     Thm (der, {maxidx = i, thy_ref = thy_ref, tags = tags, shyps = shyps,
   613       hyps = hyps, tpairs = tpairs, prop = prop})
   614   else
   615     Thm (der, {maxidx = Int.max (maxidx_tpairs tpairs (maxidx_of_term prop), i), thy_ref = thy_ref,
   616       tags = tags, shyps = shyps, hyps = hyps, tpairs = tpairs, prop = prop});
   617 
   618 
   619 
   620 (*** Meta rules ***)
   621 
   622 (** primitive rules **)
   623 
   624 (*The assumption rule A |- A*)
   625 fun assume raw_ct =
   626   let val Cterm {thy_ref, t = prop, T, maxidx, sorts} = adjust_maxidx_cterm ~1 raw_ct in
   627     if T <> propT then
   628       raise THM ("assume: prop", 0, [])
   629     else if maxidx <> ~1 then
   630       raise THM ("assume: variables", maxidx, [])
   631     else Thm (deriv_rule0 (Pt.Hyp prop),
   632      {thy_ref = thy_ref,
   633       tags = [],
   634       maxidx = ~1,
   635       shyps = sorts,
   636       hyps = [prop],
   637       tpairs = [],
   638       prop = prop})
   639   end;
   640 
   641 (*Implication introduction
   642     [A]
   643      :
   644      B
   645   -------
   646   A ==> B
   647 *)
   648 fun implies_intr
   649     (ct as Cterm {t = A, T, maxidx = maxidxA, sorts, ...})
   650     (th as Thm (der, {maxidx, hyps, shyps, tpairs, prop, ...})) =
   651   if T <> propT then
   652     raise THM ("implies_intr: assumptions must have type prop", 0, [th])
   653   else
   654     Thm (deriv_rule1 (Pt.implies_intr_proof A) der,
   655      {thy_ref = merge_thys1 ct th,
   656       tags = [],
   657       maxidx = Int.max (maxidxA, maxidx),
   658       shyps = Sorts.union sorts shyps,
   659       hyps = remove_hyps A hyps,
   660       tpairs = tpairs,
   661       prop = Logic.mk_implies (A, prop)});
   662 
   663 
   664 (*Implication elimination
   665   A ==> B    A
   666   ------------
   667         B
   668 *)
   669 fun implies_elim thAB thA =
   670   let
   671     val Thm (derA, {maxidx = maxA, hyps = hypsA, shyps = shypsA, tpairs = tpairsA,
   672       prop = propA, ...}) = thA
   673     and Thm (der, {maxidx, hyps, shyps, tpairs, prop, ...}) = thAB;
   674     fun err () = raise THM ("implies_elim: major premise", 0, [thAB, thA]);
   675   in
   676     case prop of
   677       Const ("==>", _) $ A $ B =>
   678         if A aconv propA then
   679           Thm (deriv_rule2 (curry Pt.%%) der derA,
   680            {thy_ref = merge_thys2 thAB thA,
   681             tags = [],
   682             maxidx = Int.max (maxA, maxidx),
   683             shyps = Sorts.union shypsA shyps,
   684             hyps = union_hyps hypsA hyps,
   685             tpairs = union_tpairs tpairsA tpairs,
   686             prop = B})
   687         else err ()
   688     | _ => err ()
   689   end;
   690 
   691 (*Forall introduction.  The Free or Var x must not be free in the hypotheses.
   692     [x]
   693      :
   694      A
   695   ------
   696   !!x. A
   697 *)
   698 fun forall_intr
   699     (ct as Cterm {t = x, T, sorts, ...})
   700     (th as Thm (der, {maxidx, shyps, hyps, tpairs, prop, ...})) =
   701   let
   702     fun result a =
   703       Thm (deriv_rule1 (Pt.forall_intr_proof x a) der,
   704        {thy_ref = merge_thys1 ct th,
   705         tags = [],
   706         maxidx = maxidx,
   707         shyps = Sorts.union sorts shyps,
   708         hyps = hyps,
   709         tpairs = tpairs,
   710         prop = Term.all T $ Abs (a, T, abstract_over (x, prop))});
   711     fun check_occs a x ts =
   712       if exists (fn t => Logic.occs (x, t)) ts then
   713         raise THM ("forall_intr: variable " ^ quote a ^ " free in assumptions", 0, [th])
   714       else ();
   715   in
   716     case x of
   717       Free (a, _) => (check_occs a x hyps; check_occs a x (terms_of_tpairs tpairs); result a)
   718     | Var ((a, _), _) => (check_occs a x (terms_of_tpairs tpairs); result a)
   719     | _ => raise THM ("forall_intr: not a variable", 0, [th])
   720   end;
   721 
   722 (*Forall elimination
   723   !!x. A
   724   ------
   725   A[t/x]
   726 *)
   727 fun forall_elim
   728     (ct as Cterm {t, T, maxidx = maxt, sorts, ...})
   729     (th as Thm (der, {maxidx, shyps, hyps, tpairs, prop, ...})) =
   730   (case prop of
   731     Const ("all", Type ("fun", [Type ("fun", [qary, _]), _])) $ A =>
   732       if T <> qary then
   733         raise THM ("forall_elim: type mismatch", 0, [th])
   734       else
   735         Thm (deriv_rule1 (Pt.% o rpair (SOME t)) der,
   736          {thy_ref = merge_thys1 ct th,
   737           tags = [],
   738           maxidx = Int.max (maxidx, maxt),
   739           shyps = Sorts.union sorts shyps,
   740           hyps = hyps,
   741           tpairs = tpairs,
   742           prop = Term.betapply (A, t)})
   743   | _ => raise THM ("forall_elim: not quantified", 0, [th]));
   744 
   745 
   746 (* Equality *)
   747 
   748 (*Reflexivity
   749   t == t
   750 *)
   751 fun reflexive (ct as Cterm {thy_ref, t, T, maxidx, sorts}) =
   752   Thm (deriv_rule0 Pt.reflexive,
   753    {thy_ref = thy_ref,
   754     tags = [],
   755     maxidx = maxidx,
   756     shyps = sorts,
   757     hyps = [],
   758     tpairs = [],
   759     prop = Logic.mk_equals (t, t)});
   760 
   761 (*Symmetry
   762   t == u
   763   ------
   764   u == t
   765 *)
   766 fun symmetric (th as Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...})) =
   767   (case prop of
   768     (eq as Const ("==", Type (_, [T, _]))) $ t $ u =>
   769       Thm (deriv_rule1 Pt.symmetric der,
   770        {thy_ref = thy_ref,
   771         tags = [],
   772         maxidx = maxidx,
   773         shyps = shyps,
   774         hyps = hyps,
   775         tpairs = tpairs,
   776         prop = eq $ u $ t})
   777     | _ => raise THM ("symmetric", 0, [th]));
   778 
   779 (*Transitivity
   780   t1 == u    u == t2
   781   ------------------
   782        t1 == t2
   783 *)
   784 fun transitive th1 th2 =
   785   let
   786     val Thm (der1, {maxidx = max1, hyps = hyps1, shyps = shyps1, tpairs = tpairs1,
   787       prop = prop1, ...}) = th1
   788     and Thm (der2, {maxidx = max2, hyps = hyps2, shyps = shyps2, tpairs = tpairs2,
   789       prop = prop2, ...}) = th2;
   790     fun err msg = raise THM ("transitive: " ^ msg, 0, [th1, th2]);
   791   in
   792     case (prop1, prop2) of
   793       ((eq as Const ("==", Type (_, [T, _]))) $ t1 $ u, Const ("==", _) $ u' $ t2) =>
   794         if not (u aconv u') then err "middle term"
   795         else
   796           Thm (deriv_rule2 (Pt.transitive u T) der1 der2,
   797            {thy_ref = merge_thys2 th1 th2,
   798             tags = [],
   799             maxidx = Int.max (max1, max2),
   800             shyps = Sorts.union shyps1 shyps2,
   801             hyps = union_hyps hyps1 hyps2,
   802             tpairs = union_tpairs tpairs1 tpairs2,
   803             prop = eq $ t1 $ t2})
   804      | _ =>  err "premises"
   805   end;
   806 
   807 (*Beta-conversion
   808   (%x. t)(u) == t[u/x]
   809   fully beta-reduces the term if full = true
   810 *)
   811 fun beta_conversion full (Cterm {thy_ref, t, T, maxidx, sorts}) =
   812   let val t' =
   813     if full then Envir.beta_norm t
   814     else
   815       (case t of Abs (_, _, bodt) $ u => subst_bound (u, bodt)
   816       | _ => raise THM ("beta_conversion: not a redex", 0, []));
   817   in
   818     Thm (deriv_rule0 Pt.reflexive,
   819      {thy_ref = thy_ref,
   820       tags = [],
   821       maxidx = maxidx,
   822       shyps = sorts,
   823       hyps = [],
   824       tpairs = [],
   825       prop = Logic.mk_equals (t, t')})
   826   end;
   827 
   828 fun eta_conversion (Cterm {thy_ref, t, T, maxidx, sorts}) =
   829   Thm (deriv_rule0 Pt.reflexive,
   830    {thy_ref = thy_ref,
   831     tags = [],
   832     maxidx = maxidx,
   833     shyps = sorts,
   834     hyps = [],
   835     tpairs = [],
   836     prop = Logic.mk_equals (t, Envir.eta_contract t)});
   837 
   838 fun eta_long_conversion (Cterm {thy_ref, t, T, maxidx, sorts}) =
   839   Thm (deriv_rule0 Pt.reflexive,
   840    {thy_ref = thy_ref,
   841     tags = [],
   842     maxidx = maxidx,
   843     shyps = sorts,
   844     hyps = [],
   845     tpairs = [],
   846     prop = Logic.mk_equals (t, Pattern.eta_long [] t)});
   847 
   848 (*The abstraction rule.  The Free or Var x must not be free in the hypotheses.
   849   The bound variable will be named "a" (since x will be something like x320)
   850       t == u
   851   --------------
   852   %x. t == %x. u
   853 *)
   854 fun abstract_rule a
   855     (Cterm {t = x, T, sorts, ...})
   856     (th as Thm (der, {thy_ref, maxidx, hyps, shyps, tpairs, prop, ...})) =
   857   let
   858     val (t, u) = Logic.dest_equals prop
   859       handle TERM _ => raise THM ("abstract_rule: premise not an equality", 0, [th]);
   860     val result =
   861       Thm (deriv_rule1 (Pt.abstract_rule x a) der,
   862        {thy_ref = thy_ref,
   863         tags = [],
   864         maxidx = maxidx,
   865         shyps = Sorts.union sorts shyps,
   866         hyps = hyps,
   867         tpairs = tpairs,
   868         prop = Logic.mk_equals
   869           (Abs (a, T, abstract_over (x, t)), Abs (a, T, abstract_over (x, u)))});
   870     fun check_occs a x ts =
   871       if exists (fn t => Logic.occs (x, t)) ts then
   872         raise THM ("abstract_rule: variable " ^ quote a ^ " free in assumptions", 0, [th])
   873       else ();
   874   in
   875     case x of
   876       Free (a, _) => (check_occs a x hyps; check_occs a x (terms_of_tpairs tpairs); result)
   877     | Var ((a, _), _) => (check_occs a x (terms_of_tpairs tpairs); result)
   878     | _ => raise THM ("abstract_rule: not a variable", 0, [th])
   879   end;
   880 
   881 (*The combination rule
   882   f == g  t == u
   883   --------------
   884     f t == g u
   885 *)
   886 fun combination th1 th2 =
   887   let
   888     val Thm (der1, {maxidx = max1, shyps = shyps1, hyps = hyps1, tpairs = tpairs1,
   889       prop = prop1, ...}) = th1
   890     and Thm (der2, {maxidx = max2, shyps = shyps2, hyps = hyps2, tpairs = tpairs2,
   891       prop = prop2, ...}) = th2;
   892     fun chktypes fT tT =
   893       (case fT of
   894         Type ("fun", [T1, T2]) =>
   895           if T1 <> tT then
   896             raise THM ("combination: types", 0, [th1, th2])
   897           else ()
   898       | _ => raise THM ("combination: not function type", 0, [th1, th2]));
   899   in
   900     case (prop1, prop2) of
   901       (Const ("==", Type ("fun", [fT, _])) $ f $ g,
   902        Const ("==", Type ("fun", [tT, _])) $ t $ u) =>
   903         (chktypes fT tT;
   904           Thm (deriv_rule2 (Pt.combination f g t u fT) der1 der2,
   905            {thy_ref = merge_thys2 th1 th2,
   906             tags = [],
   907             maxidx = Int.max (max1, max2),
   908             shyps = Sorts.union shyps1 shyps2,
   909             hyps = union_hyps hyps1 hyps2,
   910             tpairs = union_tpairs tpairs1 tpairs2,
   911             prop = Logic.mk_equals (f $ t, g $ u)}))
   912      | _ => raise THM ("combination: premises", 0, [th1, th2])
   913   end;
   914 
   915 (*Equality introduction
   916   A ==> B  B ==> A
   917   ----------------
   918        A == B
   919 *)
   920 fun equal_intr th1 th2 =
   921   let
   922     val Thm (der1, {maxidx = max1, shyps = shyps1, hyps = hyps1, tpairs = tpairs1,
   923       prop = prop1, ...}) = th1
   924     and Thm (der2, {maxidx = max2, shyps = shyps2, hyps = hyps2, tpairs = tpairs2,
   925       prop = prop2, ...}) = th2;
   926     fun err msg = raise THM ("equal_intr: " ^ msg, 0, [th1, th2]);
   927   in
   928     case (prop1, prop2) of
   929       (Const("==>", _) $ A $ B, Const("==>", _) $ B' $ A') =>
   930         if A aconv A' andalso B aconv B' then
   931           Thm (deriv_rule2 (Pt.equal_intr A B) der1 der2,
   932            {thy_ref = merge_thys2 th1 th2,
   933             tags = [],
   934             maxidx = Int.max (max1, max2),
   935             shyps = Sorts.union shyps1 shyps2,
   936             hyps = union_hyps hyps1 hyps2,
   937             tpairs = union_tpairs tpairs1 tpairs2,
   938             prop = Logic.mk_equals (A, B)})
   939         else err "not equal"
   940     | _ =>  err "premises"
   941   end;
   942 
   943 (*The equal propositions rule
   944   A == B  A
   945   ---------
   946       B
   947 *)
   948 fun equal_elim th1 th2 =
   949   let
   950     val Thm (der1, {maxidx = max1, shyps = shyps1, hyps = hyps1,
   951       tpairs = tpairs1, prop = prop1, ...}) = th1
   952     and Thm (der2, {maxidx = max2, shyps = shyps2, hyps = hyps2,
   953       tpairs = tpairs2, prop = prop2, ...}) = th2;
   954     fun err msg = raise THM ("equal_elim: " ^ msg, 0, [th1, th2]);
   955   in
   956     case prop1 of
   957       Const ("==", _) $ A $ B =>
   958         if prop2 aconv A then
   959           Thm (deriv_rule2 (Pt.equal_elim A B) der1 der2,
   960            {thy_ref = merge_thys2 th1 th2,
   961             tags = [],
   962             maxidx = Int.max (max1, max2),
   963             shyps = Sorts.union shyps1 shyps2,
   964             hyps = union_hyps hyps1 hyps2,
   965             tpairs = union_tpairs tpairs1 tpairs2,
   966             prop = B})
   967         else err "not equal"
   968      | _ =>  err"major premise"
   969   end;
   970 
   971 
   972 
   973 (**** Derived rules ****)
   974 
   975 (*Smash unifies the list of term pairs leaving no flex-flex pairs.
   976   Instantiates the theorem and deletes trivial tpairs.  Resulting
   977   sequence may contain multiple elements if the tpairs are not all
   978   flex-flex.*)
   979 fun flexflex_rule (th as Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...})) =
   980   let val thy = Theory.deref thy_ref in
   981     Unify.smash_unifiers thy tpairs (Envir.empty maxidx)
   982     |> Seq.map (fn env =>
   983         if Envir.is_empty env then th
   984         else
   985           let
   986             val tpairs' = tpairs |> map (pairself (Envir.norm_term env))
   987               (*remove trivial tpairs, of the form t==t*)
   988               |> filter_out (op aconv);
   989             val der' = deriv_rule1 (Pt.norm_proof' env) der;
   990             val prop' = Envir.norm_term env prop;
   991             val maxidx = maxidx_tpairs tpairs' (maxidx_of_term prop');
   992             val shyps = Envir.insert_sorts env shyps;
   993           in
   994             Thm (der', {thy_ref = Theory.check_thy thy, tags = [], maxidx = maxidx,
   995               shyps = shyps, hyps = hyps, tpairs = tpairs', prop = prop'})
   996           end)
   997   end;
   998 
   999 
  1000 (*Generalization of fixed variables
  1001            A
  1002   --------------------
  1003   A[?'a/'a, ?x/x, ...]
  1004 *)
  1005 
  1006 fun generalize ([], []) _ th = th
  1007   | generalize (tfrees, frees) idx th =
  1008       let
  1009         val Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...}) = th;
  1010         val _ = idx <= maxidx andalso raise THM ("generalize: bad index", idx, [th]);
  1011 
  1012         val bad_type = if null tfrees then K false else
  1013           Term.exists_subtype (fn TFree (a, _) => member (op =) tfrees a | _ => false);
  1014         fun bad_term (Free (x, T)) = bad_type T orelse member (op =) frees x
  1015           | bad_term (Var (_, T)) = bad_type T
  1016           | bad_term (Const (_, T)) = bad_type T
  1017           | bad_term (Abs (_, T, t)) = bad_type T orelse bad_term t
  1018           | bad_term (t $ u) = bad_term t orelse bad_term u
  1019           | bad_term (Bound _) = false;
  1020         val _ = exists bad_term hyps andalso
  1021           raise THM ("generalize: variable free in assumptions", 0, [th]);
  1022 
  1023         val gen = TermSubst.generalize (tfrees, frees) idx;
  1024         val prop' = gen prop;
  1025         val tpairs' = map (pairself gen) tpairs;
  1026         val maxidx' = maxidx_tpairs tpairs' (maxidx_of_term prop');
  1027       in
  1028         Thm (deriv_rule1 (Pt.generalize (tfrees, frees) idx) der,
  1029          {thy_ref = thy_ref,
  1030           tags = [],
  1031           maxidx = maxidx',
  1032           shyps = shyps,
  1033           hyps = hyps,
  1034           tpairs = tpairs',
  1035           prop = prop'})
  1036       end;
  1037 
  1038 
  1039 (*Instantiation of schematic variables
  1040            A
  1041   --------------------
  1042   A[t1/v1, ..., tn/vn]
  1043 *)
  1044 
  1045 local
  1046 
  1047 fun pretty_typing thy t T = Pretty.block
  1048   [Syntax.pretty_term_global thy t, Pretty.str " ::", Pretty.brk 1, Syntax.pretty_typ_global thy T];
  1049 
  1050 fun add_inst (ct, cu) (thy_ref, sorts) =
  1051   let
  1052     val Cterm {t = t, T = T, ...} = ct;
  1053     val Cterm {t = u, T = U, sorts = sorts_u, maxidx = maxidx_u, ...} = cu;
  1054     val thy_ref' = Theory.merge_refs (thy_ref, merge_thys0 ct cu);
  1055     val sorts' = Sorts.union sorts_u sorts;
  1056   in
  1057     (case t of Var v =>
  1058       if T = U then ((v, (u, maxidx_u)), (thy_ref', sorts'))
  1059       else raise TYPE (Pretty.string_of (Pretty.block
  1060        [Pretty.str "instantiate: type conflict",
  1061         Pretty.fbrk, pretty_typing (Theory.deref thy_ref') t T,
  1062         Pretty.fbrk, pretty_typing (Theory.deref thy_ref') u U]), [T, U], [t, u])
  1063     | _ => raise TYPE (Pretty.string_of (Pretty.block
  1064        [Pretty.str "instantiate: not a variable",
  1065         Pretty.fbrk, Syntax.pretty_term_global (Theory.deref thy_ref') t]), [], [t]))
  1066   end;
  1067 
  1068 fun add_instT (cT, cU) (thy_ref, sorts) =
  1069   let
  1070     val Ctyp {T, thy_ref = thy_ref1, ...} = cT
  1071     and Ctyp {T = U, thy_ref = thy_ref2, sorts = sorts_U, maxidx = maxidx_U, ...} = cU;
  1072     val thy' = Theory.deref (Theory.merge_refs (thy_ref, Theory.merge_refs (thy_ref1, thy_ref2)));
  1073     val sorts' = Sorts.union sorts_U sorts;
  1074   in
  1075     (case T of TVar (v as (_, S)) =>
  1076       if Sign.of_sort thy' (U, S) then ((v, (U, maxidx_U)), (Theory.check_thy thy', sorts'))
  1077       else raise TYPE ("Type not of sort " ^ Syntax.string_of_sort_global thy' S, [U], [])
  1078     | _ => raise TYPE (Pretty.string_of (Pretty.block
  1079         [Pretty.str "instantiate: not a type variable",
  1080          Pretty.fbrk, Syntax.pretty_typ_global thy' T]), [T], []))
  1081   end;
  1082 
  1083 in
  1084 
  1085 (*Left-to-right replacements: ctpairs = [..., (vi, ti), ...].
  1086   Instantiates distinct Vars by terms of same type.
  1087   Does NOT normalize the resulting theorem!*)
  1088 fun instantiate ([], []) th = th
  1089   | instantiate (instT, inst) th =
  1090       let
  1091         val Thm (der, {thy_ref, hyps, shyps, tpairs, prop, ...}) = th;
  1092         val (inst', (instT', (thy_ref', shyps'))) =
  1093           (thy_ref, shyps) |> fold_map add_inst inst ||> fold_map add_instT instT;
  1094         val subst = TermSubst.instantiate_maxidx (instT', inst');
  1095         val (prop', maxidx1) = subst prop ~1;
  1096         val (tpairs', maxidx') =
  1097           fold_map (fn (t, u) => fn i => subst t i ||>> subst u) tpairs maxidx1;
  1098       in
  1099         Thm (deriv_rule1 (fn d => Pt.instantiate (map (apsnd #1) instT', map (apsnd #1) inst') d) der,
  1100          {thy_ref = thy_ref',
  1101           tags = [],
  1102           maxidx = maxidx',
  1103           shyps = shyps',
  1104           hyps = hyps,
  1105           tpairs = tpairs',
  1106           prop = prop'})
  1107       end
  1108       handle TYPE (msg, _, _) => raise THM (msg, 0, [th]);
  1109 
  1110 fun instantiate_cterm ([], []) ct = ct
  1111   | instantiate_cterm (instT, inst) ct =
  1112       let
  1113         val Cterm {thy_ref, t, T, sorts, ...} = ct;
  1114         val (inst', (instT', (thy_ref', sorts'))) =
  1115           (thy_ref, sorts) |> fold_map add_inst inst ||> fold_map add_instT instT;
  1116         val subst = TermSubst.instantiate_maxidx (instT', inst');
  1117         val substT = TermSubst.instantiateT_maxidx instT';
  1118         val (t', maxidx1) = subst t ~1;
  1119         val (T', maxidx') = substT T maxidx1;
  1120       in Cterm {thy_ref = thy_ref', t = t', T = T', sorts = sorts', maxidx = maxidx'} end
  1121       handle TYPE (msg, _, _) => raise CTERM (msg, [ct]);
  1122 
  1123 end;
  1124 
  1125 
  1126 (*The trivial implication A ==> A, justified by assume and forall rules.
  1127   A can contain Vars, not so for assume!*)
  1128 fun trivial (Cterm {thy_ref, t =A, T, maxidx, sorts}) =
  1129   if T <> propT then
  1130     raise THM ("trivial: the term must have type prop", 0, [])
  1131   else
  1132     Thm (deriv_rule0 (Pt.AbsP ("H", NONE, Pt.PBound 0)),
  1133      {thy_ref = thy_ref,
  1134       tags = [],
  1135       maxidx = maxidx,
  1136       shyps = sorts,
  1137       hyps = [],
  1138       tpairs = [],
  1139       prop = Logic.mk_implies (A, A)});
  1140 
  1141 (*Axiom-scheme reflecting signature contents: "OFCLASS(?'a::c, c_class)" *)
  1142 fun class_triv thy c =
  1143   let
  1144     val Cterm {t, maxidx, sorts, ...} =
  1145       cterm_of thy (Logic.mk_inclass (TVar ((Name.aT, 0), [c]), Sign.certify_class thy c))
  1146         handle TERM (msg, _) => raise THM ("class_triv: " ^ msg, 0, []);
  1147     val der = deriv_rule0 (Pt.PAxm ("Pure.class_triv:" ^ c, t, SOME []));
  1148   in
  1149     Thm (der, {thy_ref = Theory.check_thy thy, tags = [], maxidx = maxidx,
  1150       shyps = sorts, hyps = [], tpairs = [], prop = t})
  1151   end;
  1152 
  1153 (*Internalize sort constraints of type variable*)
  1154 fun unconstrainT
  1155     (Ctyp {thy_ref = thy_ref1, T, ...})
  1156     (th as Thm (_, {thy_ref = thy_ref2, maxidx, shyps, hyps, tpairs, prop, ...})) =
  1157   let
  1158     val ((x, i), S) = Term.dest_TVar T handle TYPE _ =>
  1159       raise THM ("unconstrainT: not a type variable", 0, [th]);
  1160     val T' = TVar ((x, i), []);
  1161     val unconstrain = Term.map_types (Term.map_atyps (fn U => if U = T then T' else U));
  1162     val constraints = map (curry Logic.mk_inclass T') S;
  1163   in
  1164     Thm (deriv_rule0 (Pt.PAxm ("Pure.unconstrainT", prop, SOME [])),
  1165      {thy_ref = Theory.merge_refs (thy_ref1, thy_ref2),
  1166       tags = [],
  1167       maxidx = Int.max (maxidx, i),
  1168       shyps = Sorts.remove_sort S shyps,
  1169       hyps = hyps,
  1170       tpairs = map (pairself unconstrain) tpairs,
  1171       prop = Logic.list_implies (constraints, unconstrain prop)})
  1172   end;
  1173 
  1174 (* Replace all TFrees not fixed or in the hyps by new TVars *)
  1175 fun varifyT' fixed (Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...})) =
  1176   let
  1177     val tfrees = List.foldr add_term_tfrees fixed hyps;
  1178     val prop1 = attach_tpairs tpairs prop;
  1179     val (al, prop2) = Type.varify tfrees prop1;
  1180     val (ts, prop3) = Logic.strip_prems (length tpairs, [], prop2);
  1181   in
  1182     (al, Thm (deriv_rule1 (Pt.varify_proof prop tfrees) der,
  1183      {thy_ref = thy_ref,
  1184       tags = [],
  1185       maxidx = Int.max (0, maxidx),
  1186       shyps = shyps,
  1187       hyps = hyps,
  1188       tpairs = rev (map Logic.dest_equals ts),
  1189       prop = prop3}))
  1190   end;
  1191 
  1192 val varifyT = #2 o varifyT' [];
  1193 
  1194 (* Replace all TVars by new TFrees *)
  1195 fun freezeT (Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...})) =
  1196   let
  1197     val prop1 = attach_tpairs tpairs prop;
  1198     val prop2 = Type.freeze prop1;
  1199     val (ts, prop3) = Logic.strip_prems (length tpairs, [], prop2);
  1200   in
  1201     Thm (deriv_rule1 (Pt.freezeT prop1) der,
  1202      {thy_ref = thy_ref,
  1203       tags = [],
  1204       maxidx = maxidx_of_term prop2,
  1205       shyps = shyps,
  1206       hyps = hyps,
  1207       tpairs = rev (map Logic.dest_equals ts),
  1208       prop = prop3})
  1209   end;
  1210 
  1211 
  1212 (*** Inference rules for tactics ***)
  1213 
  1214 (*Destruct proof state into constraints, other goals, goal(i), rest *)
  1215 fun dest_state (state as Thm (_, {prop,tpairs,...}), i) =
  1216   (case  Logic.strip_prems(i, [], prop) of
  1217       (B::rBs, C) => (tpairs, rev rBs, B, C)
  1218     | _ => raise THM("dest_state", i, [state]))
  1219   handle TERM _ => raise THM("dest_state", i, [state]);
  1220 
  1221 (*Increment variables and parameters of orule as required for
  1222   resolution with a goal.*)
  1223 fun lift_rule goal orule =
  1224   let
  1225     val Cterm {t = gprop, T, maxidx = gmax, sorts, ...} = goal;
  1226     val inc = gmax + 1;
  1227     val lift_abs = Logic.lift_abs inc gprop;
  1228     val lift_all = Logic.lift_all inc gprop;
  1229     val Thm (der, {maxidx, shyps, hyps, tpairs, prop, ...}) = orule;
  1230     val (As, B) = Logic.strip_horn prop;
  1231   in
  1232     if T <> propT then raise THM ("lift_rule: the term must have type prop", 0, [])
  1233     else
  1234       Thm (deriv_rule1 (Pt.lift_proof gprop inc prop) der,
  1235        {thy_ref = merge_thys1 goal orule,
  1236         tags = [],
  1237         maxidx = maxidx + inc,
  1238         shyps = Sorts.union shyps sorts,  (*sic!*)
  1239         hyps = hyps,
  1240         tpairs = map (pairself lift_abs) tpairs,
  1241         prop = Logic.list_implies (map lift_all As, lift_all B)})
  1242   end;
  1243 
  1244 fun incr_indexes i (thm as Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...})) =
  1245   if i < 0 then raise THM ("negative increment", 0, [thm])
  1246   else if i = 0 then thm
  1247   else
  1248     Thm (deriv_rule1 (Pt.map_proof_terms (Logic.incr_indexes ([], i)) (Logic.incr_tvar i)) der,
  1249      {thy_ref = thy_ref,
  1250       tags = [],
  1251       maxidx = maxidx + i,
  1252       shyps = shyps,
  1253       hyps = hyps,
  1254       tpairs = map (pairself (Logic.incr_indexes ([], i))) tpairs,
  1255       prop = Logic.incr_indexes ([], i) prop});
  1256 
  1257 (*Solve subgoal Bi of proof state B1...Bn/C by assumption. *)
  1258 fun assumption i state =
  1259   let
  1260     val Thm (der, {thy_ref, maxidx, shyps, hyps, prop, ...}) = state;
  1261     val thy = Theory.deref thy_ref;
  1262     val (tpairs, Bs, Bi, C) = dest_state (state, i);
  1263     fun newth n (env as Envir.Envir {maxidx, ...}, tpairs) =
  1264       Thm (deriv_rule1
  1265           ((if Envir.is_empty env then I else (Pt.norm_proof' env)) o
  1266             Pt.assumption_proof Bs Bi n) der,
  1267        {tags = [],
  1268         maxidx = maxidx,
  1269         shyps = Envir.insert_sorts env shyps,
  1270         hyps = hyps,
  1271         tpairs =
  1272           if Envir.is_empty env then tpairs
  1273           else map (pairself (Envir.norm_term env)) tpairs,
  1274         prop =
  1275           if Envir.is_empty env then (*avoid wasted normalizations*)
  1276             Logic.list_implies (Bs, C)
  1277           else (*normalize the new rule fully*)
  1278             Envir.norm_term env (Logic.list_implies (Bs, C)),
  1279         thy_ref = Theory.check_thy thy});
  1280     fun addprfs [] _ = Seq.empty
  1281       | addprfs ((t, u) :: apairs) n = Seq.make (fn () => Seq.pull
  1282           (Seq.mapp (newth n)
  1283             (Unify.unifiers (thy, Envir.empty maxidx, (t, u) :: tpairs))
  1284             (addprfs apairs (n + 1))))
  1285   in addprfs (Logic.assum_pairs (~1, Bi)) 1 end;
  1286 
  1287 (*Solve subgoal Bi of proof state B1...Bn/C by assumption.
  1288   Checks if Bi's conclusion is alpha-convertible to one of its assumptions*)
  1289 fun eq_assumption i state =
  1290   let
  1291     val Thm (der, {thy_ref, maxidx, shyps, hyps, prop, ...}) = state;
  1292     val (tpairs, Bs, Bi, C) = dest_state (state, i);
  1293   in
  1294     (case find_index Pattern.aeconv (Logic.assum_pairs (~1, Bi)) of
  1295       ~1 => raise THM ("eq_assumption", 0, [state])
  1296     | n =>
  1297         Thm (deriv_rule1 (Pt.assumption_proof Bs Bi (n + 1)) der,
  1298          {thy_ref = thy_ref,
  1299           tags = [],
  1300           maxidx = maxidx,
  1301           shyps = shyps,
  1302           hyps = hyps,
  1303           tpairs = tpairs,
  1304           prop = Logic.list_implies (Bs, C)}))
  1305   end;
  1306 
  1307 
  1308 (*For rotate_tac: fast rotation of assumptions of subgoal i*)
  1309 fun rotate_rule k i state =
  1310   let
  1311     val Thm (der, {thy_ref, maxidx, shyps, hyps, prop, ...}) = state;
  1312     val (tpairs, Bs, Bi, C) = dest_state (state, i);
  1313     val params = Term.strip_all_vars Bi
  1314     and rest   = Term.strip_all_body Bi;
  1315     val asms   = Logic.strip_imp_prems rest
  1316     and concl  = Logic.strip_imp_concl rest;
  1317     val n = length asms;
  1318     val m = if k < 0 then n + k else k;
  1319     val Bi' =
  1320       if 0 = m orelse m = n then Bi
  1321       else if 0 < m andalso m < n then
  1322         let val (ps, qs) = chop m asms
  1323         in list_all (params, Logic.list_implies (qs @ ps, concl)) end
  1324       else raise THM ("rotate_rule", k, [state]);
  1325   in
  1326     Thm (deriv_rule1 (Pt.rotate_proof Bs Bi m) der,
  1327      {thy_ref = thy_ref,
  1328       tags = [],
  1329       maxidx = maxidx,
  1330       shyps = shyps,
  1331       hyps = hyps,
  1332       tpairs = tpairs,
  1333       prop = Logic.list_implies (Bs @ [Bi'], C)})
  1334   end;
  1335 
  1336 
  1337 (*Rotates a rule's premises to the left by k, leaving the first j premises
  1338   unchanged.  Does nothing if k=0 or if k equals n-j, where n is the
  1339   number of premises.  Useful with etac and underlies defer_tac*)
  1340 fun permute_prems j k rl =
  1341   let
  1342     val Thm (der, {thy_ref, maxidx, shyps, hyps, tpairs, prop, ...}) = rl;
  1343     val prems = Logic.strip_imp_prems prop
  1344     and concl = Logic.strip_imp_concl prop;
  1345     val moved_prems = List.drop (prems, j)
  1346     and fixed_prems = List.take (prems, j)
  1347       handle Subscript => raise THM ("permute_prems: j", j, [rl]);
  1348     val n_j = length moved_prems;
  1349     val m = if k < 0 then n_j + k else k;
  1350     val prop' =
  1351       if 0 = m orelse m = n_j then prop
  1352       else if 0 < m andalso m < n_j then
  1353         let val (ps, qs) = chop m moved_prems
  1354         in Logic.list_implies (fixed_prems @ qs @ ps, concl) end
  1355       else raise THM ("permute_prems: k", k, [rl]);
  1356   in
  1357     Thm (deriv_rule1 (Pt.permute_prems_prf prems j m) der,
  1358      {thy_ref = thy_ref,
  1359       tags = [],
  1360       maxidx = maxidx,
  1361       shyps = shyps,
  1362       hyps = hyps,
  1363       tpairs = tpairs,
  1364       prop = prop'})
  1365   end;
  1366 
  1367 
  1368 (** User renaming of parameters in a subgoal **)
  1369 
  1370 (*Calls error rather than raising an exception because it is intended
  1371   for top-level use -- exception handling would not make sense here.
  1372   The names in cs, if distinct, are used for the innermost parameters;
  1373   preceding parameters may be renamed to make all params distinct.*)
  1374 fun rename_params_rule (cs, i) state =
  1375   let
  1376     val Thm (der, {thy_ref, tags, maxidx, shyps, hyps, ...}) = state;
  1377     val (tpairs, Bs, Bi, C) = dest_state (state, i);
  1378     val iparams = map #1 (Logic.strip_params Bi);
  1379     val short = length iparams - length cs;
  1380     val newnames =
  1381       if short < 0 then error "More names than abstractions!"
  1382       else Name.variant_list cs (Library.take (short, iparams)) @ cs;
  1383     val freenames = Term.fold_aterms (fn Free (x, _) => insert (op =) x | _ => I) Bi [];
  1384     val newBi = Logic.list_rename_params (newnames, Bi);
  1385   in
  1386     (case duplicates (op =) cs of
  1387       a :: _ => (warning ("Can't rename.  Bound variables not distinct: " ^ a); state)
  1388     | [] =>
  1389       (case cs inter_string freenames of
  1390         a :: _ => (warning ("Can't rename.  Bound/Free variable clash: " ^ a); state)
  1391       | [] =>
  1392         Thm (der,
  1393          {thy_ref = thy_ref,
  1394           tags = tags,
  1395           maxidx = maxidx,
  1396           shyps = shyps,
  1397           hyps = hyps,
  1398           tpairs = tpairs,
  1399           prop = Logic.list_implies (Bs @ [newBi], C)})))
  1400   end;
  1401 
  1402 
  1403 (*** Preservation of bound variable names ***)
  1404 
  1405 fun rename_boundvars pat obj (thm as Thm (der, {thy_ref, tags, maxidx, shyps, hyps, tpairs, prop})) =
  1406   (case Term.rename_abs pat obj prop of
  1407     NONE => thm
  1408   | SOME prop' => Thm (der,
  1409       {thy_ref = thy_ref,
  1410        tags = tags,
  1411        maxidx = maxidx,
  1412        hyps = hyps,
  1413        shyps = shyps,
  1414        tpairs = tpairs,
  1415        prop = prop'}));
  1416 
  1417 
  1418 (* strip_apply f (A, B) strips off all assumptions/parameters from A
  1419    introduced by lifting over B, and applies f to remaining part of A*)
  1420 fun strip_apply f =
  1421   let fun strip(Const("==>",_)$ A1 $ B1,
  1422                 Const("==>",_)$ _  $ B2) = Logic.mk_implies (A1, strip(B1,B2))
  1423         | strip((c as Const("all",_)) $ Abs(a,T,t1),
  1424                       Const("all",_)  $ Abs(_,_,t2)) = c$Abs(a,T,strip(t1,t2))
  1425         | strip(A,_) = f A
  1426   in strip end;
  1427 
  1428 (*Use the alist to rename all bound variables and some unknowns in a term
  1429   dpairs = current disagreement pairs;  tpairs = permanent ones (flexflex);
  1430   Preserves unknowns in tpairs and on lhs of dpairs. *)
  1431 fun rename_bvs([],_,_,_) = I
  1432   | rename_bvs(al,dpairs,tpairs,B) =
  1433       let
  1434         val add_var = fold_aterms (fn Var ((x, _), _) => insert (op =) x | _ => I);
  1435         val vids = []
  1436           |> fold (add_var o fst) dpairs
  1437           |> fold (add_var o fst) tpairs
  1438           |> fold (add_var o snd) tpairs;
  1439         (*unknowns appearing elsewhere be preserved!*)
  1440         fun rename(t as Var((x,i),T)) =
  1441               (case AList.lookup (op =) al x of
  1442                 SOME y =>
  1443                   if member (op =) vids x orelse member (op =) vids y then t
  1444                   else Var((y,i),T)
  1445               | NONE=> t)
  1446           | rename(Abs(x,T,t)) =
  1447               Abs (the_default x (AList.lookup (op =) al x), T, rename t)
  1448           | rename(f$t) = rename f $ rename t
  1449           | rename(t) = t;
  1450         fun strip_ren Ai = strip_apply rename (Ai,B)
  1451       in strip_ren end;
  1452 
  1453 (*Function to rename bounds/unknowns in the argument, lifted over B*)
  1454 fun rename_bvars(dpairs, tpairs, B) =
  1455         rename_bvs(List.foldr Term.match_bvars [] dpairs, dpairs, tpairs, B);
  1456 
  1457 
  1458 (*** RESOLUTION ***)
  1459 
  1460 (** Lifting optimizations **)
  1461 
  1462 (*strip off pairs of assumptions/parameters in parallel -- they are
  1463   identical because of lifting*)
  1464 fun strip_assums2 (Const("==>", _) $ _ $ B1,
  1465                    Const("==>", _) $ _ $ B2) = strip_assums2 (B1,B2)
  1466   | strip_assums2 (Const("all",_)$Abs(a,T,t1),
  1467                    Const("all",_)$Abs(_,_,t2)) =
  1468       let val (B1,B2) = strip_assums2 (t1,t2)
  1469       in  (Abs(a,T,B1), Abs(a,T,B2))  end
  1470   | strip_assums2 BB = BB;
  1471 
  1472 
  1473 (*Faster normalization: skip assumptions that were lifted over*)
  1474 fun norm_term_skip env 0 t = Envir.norm_term env t
  1475   | norm_term_skip env n (Const("all",_)$Abs(a,T,t)) =
  1476         let val Envir.Envir{iTs, ...} = env
  1477             val T' = Envir.typ_subst_TVars iTs T
  1478             (*Must instantiate types of parameters because they are flattened;
  1479               this could be a NEW parameter*)
  1480         in Term.all T' $ Abs(a, T', norm_term_skip env n t)  end
  1481   | norm_term_skip env n (Const("==>", _) $ A $ B) =
  1482         Logic.mk_implies (A, norm_term_skip env (n-1) B)
  1483   | norm_term_skip env n t = error"norm_term_skip: too few assumptions??";
  1484 
  1485 
  1486 (*Composition of object rule r=(A1...Am/B) with proof state s=(B1...Bn/C)
  1487   Unifies B with Bi, replacing subgoal i    (1 <= i <= n)
  1488   If match then forbid instantiations in proof state
  1489   If lifted then shorten the dpair using strip_assums2.
  1490   If eres_flg then simultaneously proves A1 by assumption.
  1491   nsubgoal is the number of new subgoals (written m above).
  1492   Curried so that resolution calls dest_state only once.
  1493 *)
  1494 local exception COMPOSE
  1495 in
  1496 fun bicompose_aux flatten match (state, (stpairs, Bs, Bi, C), lifted)
  1497                         (eres_flg, orule, nsubgoal) =
  1498  let val Thm (sder, {maxidx=smax, shyps=sshyps, hyps=shyps, ...}) = state
  1499      and Thm (rder, {maxidx=rmax, shyps=rshyps, hyps=rhyps,
  1500              tpairs=rtpairs, prop=rprop,...}) = orule
  1501          (*How many hyps to skip over during normalization*)
  1502      and nlift = Logic.count_prems (strip_all_body Bi) + (if eres_flg then ~1 else 0)
  1503      val thy = Theory.deref (merge_thys2 state orule);
  1504      (** Add new theorem with prop = '[| Bs; As |] ==> C' to thq **)
  1505      fun addth A (As, oldAs, rder', n) ((env as Envir.Envir {maxidx, ...}, tpairs), thq) =
  1506        let val normt = Envir.norm_term env;
  1507            (*perform minimal copying here by examining env*)
  1508            val (ntpairs, normp) =
  1509              if Envir.is_empty env then (tpairs, (Bs @ As, C))
  1510              else
  1511              let val ntps = map (pairself normt) tpairs
  1512              in if Envir.above env smax then
  1513                   (*no assignments in state; normalize the rule only*)
  1514                   if lifted
  1515                   then (ntps, (Bs @ map (norm_term_skip env nlift) As, C))
  1516                   else (ntps, (Bs @ map normt As, C))
  1517                 else if match then raise COMPOSE
  1518                 else (*normalize the new rule fully*)
  1519                   (ntps, (map normt (Bs @ As), normt C))
  1520              end
  1521            val th =
  1522              Thm (deriv_rule2
  1523                    ((if Envir.is_empty env then I
  1524                      else if Envir.above env smax then
  1525                        (fn f => fn der => f (Pt.norm_proof' env der))
  1526                      else
  1527                        curry op oo (Pt.norm_proof' env))
  1528                     (Pt.bicompose_proof flatten Bs oldAs As A n (nlift+1))) rder' sder,
  1529                 {tags = [],
  1530                  maxidx = maxidx,
  1531                  shyps = Envir.insert_sorts env (Sorts.union rshyps sshyps),
  1532                  hyps = union_hyps rhyps shyps,
  1533                  tpairs = ntpairs,
  1534                  prop = Logic.list_implies normp,
  1535                  thy_ref = Theory.check_thy thy})
  1536         in  Seq.cons th thq  end  handle COMPOSE => thq;
  1537      val (rAs,B) = Logic.strip_prems(nsubgoal, [], rprop)
  1538        handle TERM _ => raise THM("bicompose: rule", 0, [orule,state]);
  1539      (*Modify assumptions, deleting n-th if n>0 for e-resolution*)
  1540      fun newAs(As0, n, dpairs, tpairs) =
  1541        let val (As1, rder') =
  1542          if not lifted then (As0, rder)
  1543          else (map (rename_bvars(dpairs,tpairs,B)) As0,
  1544            deriv_rule1 (Pt.map_proof_terms
  1545              (rename_bvars (dpairs, tpairs, Bound 0)) I) rder);
  1546        in (map (if flatten then (Logic.flatten_params n) else I) As1, As1, rder', n)
  1547           handle TERM _ =>
  1548           raise THM("bicompose: 1st premise", 0, [orule])
  1549        end;
  1550      val env = Envir.empty(Int.max(rmax,smax));
  1551      val BBi = if lifted then strip_assums2(B,Bi) else (B,Bi);
  1552      val dpairs = BBi :: (rtpairs@stpairs);
  1553      (*elim-resolution: try each assumption in turn.  Initially n=1*)
  1554      fun tryasms (_, _, _, []) = Seq.empty
  1555        | tryasms (A, As, n, (t,u)::apairs) =
  1556           (case Seq.pull(Unify.unifiers(thy, env, (t,u)::dpairs))  of
  1557               NONE                   => tryasms (A, As, n+1, apairs)
  1558             | cell as SOME((_,tpairs),_) =>
  1559                 Seq.it_right (addth A (newAs(As, n, [BBi,(u,t)], tpairs)))
  1560                     (Seq.make(fn()=> cell),
  1561                      Seq.make(fn()=> Seq.pull (tryasms(A, As, n+1, apairs)))))
  1562      fun eres [] = raise THM("bicompose: no premises", 0, [orule,state])
  1563        | eres (A1::As) = tryasms(SOME A1, As, 1, Logic.assum_pairs(nlift+1,A1))
  1564      (*ordinary resolution*)
  1565      fun res(NONE) = Seq.empty
  1566        | res(cell as SOME((_,tpairs),_)) =
  1567              Seq.it_right (addth NONE (newAs(rev rAs, 0, [BBi], tpairs)))
  1568                        (Seq.make (fn()=> cell), Seq.empty)
  1569  in  if eres_flg then eres(rev rAs)
  1570      else res(Seq.pull(Unify.unifiers(thy, env, dpairs)))
  1571  end;
  1572 end;
  1573 
  1574 fun compose_no_flatten match (orule, nsubgoal) i state =
  1575   bicompose_aux false match (state, dest_state (state, i), false) (false, orule, nsubgoal);
  1576 
  1577 fun bicompose match arg i state =
  1578   bicompose_aux true match (state, dest_state (state,i), false) arg;
  1579 
  1580 (*Quick test whether rule is resolvable with the subgoal with hyps Hs
  1581   and conclusion B.  If eres_flg then checks 1st premise of rule also*)
  1582 fun could_bires (Hs, B, eres_flg, rule) =
  1583     let fun could_reshyp (A1::_) = exists (fn H => could_unify (A1, H)) Hs
  1584           | could_reshyp [] = false;  (*no premise -- illegal*)
  1585     in  could_unify(concl_of rule, B) andalso
  1586         (not eres_flg  orelse  could_reshyp (prems_of rule))
  1587     end;
  1588 
  1589 (*Bi-resolution of a state with a list of (flag,rule) pairs.
  1590   Puts the rule above:  rule/state.  Renames vars in the rules. *)
  1591 fun biresolution match brules i state =
  1592     let val (stpairs, Bs, Bi, C) = dest_state(state,i);
  1593         val lift = lift_rule (cprem_of state i);
  1594         val B = Logic.strip_assums_concl Bi;
  1595         val Hs = Logic.strip_assums_hyp Bi;
  1596         val compose = bicompose_aux true match (state, (stpairs, Bs, Bi, C), true);
  1597         fun res [] = Seq.empty
  1598           | res ((eres_flg, rule)::brules) =
  1599               if !Pattern.trace_unify_fail orelse
  1600                  could_bires (Hs, B, eres_flg, rule)
  1601               then Seq.make (*delay processing remainder till needed*)
  1602                   (fn()=> SOME(compose (eres_flg, lift rule, nprems_of rule),
  1603                                res brules))
  1604               else res brules
  1605     in  Seq.flat (res brules)  end;
  1606 
  1607 
  1608 
  1609 (*** Promises ***)
  1610 
  1611 (* pending future derivations *)
  1612 
  1613 structure Futures = TheoryDataFun
  1614 (
  1615   type T = thm Future.T list ref;
  1616   val empty : T = ref [];
  1617   val copy = I;  (*shared ref within whole theory body*)
  1618   fun extend _ : T = ref [];
  1619   fun merge _ _ : T = ref [];
  1620 );
  1621 
  1622 val _ = Context.>> (Context.map_theory Futures.init);
  1623 
  1624 fun add_future thy future = CRITICAL (fn () => change (Futures.get thy) (cons future));
  1625 
  1626 fun join_futures thy =
  1627   let
  1628     val futures = Futures.get thy;
  1629     fun joined () =
  1630      (Future.join_results (rev (! futures));
  1631       CRITICAL (fn () =>
  1632         let
  1633           val (finished, unfinished) = List.partition Future.is_finished (! futures);
  1634           val _ = futures := unfinished;
  1635         in finished end)
  1636       |> Future.join_results |> Exn.release_all |> null);
  1637   in while not (joined ()) do () end;
  1638 
  1639 
  1640 (* future rule *)
  1641 
  1642 fun future_result i orig_thy orig_shyps orig_prop raw_thm =
  1643   let
  1644     val _ = Theory.check_thy orig_thy;
  1645     val thm = strip_shyps (transfer orig_thy raw_thm);
  1646     val _ = Theory.check_thy orig_thy;
  1647     fun err msg = raise THM ("future_result: " ^ msg, 0, [thm]);
  1648 
  1649     val Thm (Deriv {promises, ...}, {shyps, hyps, tpairs, prop, ...}) = thm;
  1650     val _ = prop aconv orig_prop orelse err "bad prop";
  1651     val _ = null tpairs orelse err "bad tpairs";
  1652     val _ = null hyps orelse err "bad hyps";
  1653     val _ = Sorts.subset (shyps, orig_shyps) orelse err "bad shyps";
  1654     val _ = forall (fn (j, _) => j < i) promises orelse err "bad dependencies";
  1655   in thm end;
  1656 
  1657 fun future make_result ct =
  1658   let
  1659     val Cterm {thy_ref = thy_ref, t = prop, T, maxidx, sorts} = ct;
  1660     val thy = Context.reject_draft (Theory.deref thy_ref);
  1661     val _ = T <> propT andalso raise CTERM ("future: prop expected", [ct]);
  1662 
  1663     val i = serial ();
  1664     val future = Future.fork_background (future_result i thy sorts prop o make_result);
  1665     val _ = add_future thy future;
  1666   in
  1667     Thm (make_deriv false [(i, future)] (Pt.promise_proof i prop),
  1668      {thy_ref = thy_ref,
  1669       tags = [],
  1670       maxidx = maxidx,
  1671       shyps = sorts,
  1672       hyps = [],
  1673       tpairs = [],
  1674       prop = prop})
  1675   end;
  1676 
  1677 
  1678 (* join_deriv *)
  1679 
  1680 fun join_deriv (thm as Thm (Deriv {oracle, proof, promises}, args)) =
  1681   let
  1682     val _ = Exn.release_all (Future.join_results (rev (map #2 promises)));
  1683     val results = map (apsnd Future.join) promises;
  1684     val proofs = fold (fn (i, Thm (Deriv {proof = prf, ...}, _)) => Inttab.update (i, prf))
  1685       results Inttab.empty;
  1686     val ora = oracle orelse exists (oracle_of o #2) results;
  1687   in Thm (make_deriv ora [] (Pt.fulfill proofs proof), args) end;
  1688 
  1689 val proof_of = join_deriv #> (fn Thm (Deriv {proof, ...}, _) => proof);
  1690 
  1691 
  1692 
  1693 (*** Oracles ***)
  1694 
  1695 (* oracle rule *)
  1696 
  1697 fun invoke_oracle thy_ref1 name oracle arg =
  1698   let val Cterm {thy_ref = thy_ref2, t = prop, T, maxidx, sorts} = oracle arg in
  1699     if T <> propT then
  1700       raise THM ("Oracle's result must have type prop: " ^ name, 0, [])
  1701     else
  1702       Thm (make_deriv true [] (Pt.oracle_proof name prop),
  1703        {thy_ref = Theory.merge_refs (thy_ref1, thy_ref2),
  1704         tags = [],
  1705         maxidx = maxidx,
  1706         shyps = sorts,
  1707         hyps = [],
  1708         tpairs = [],
  1709         prop = prop})
  1710   end;
  1711 
  1712 
  1713 (* authentic derivation names *)
  1714 
  1715 fun err_dup_ora dup = error ("Duplicate oracle: " ^ quote dup);
  1716 
  1717 structure Oracles = TheoryDataFun
  1718 (
  1719   type T = stamp NameSpace.table;
  1720   val empty = NameSpace.empty_table;
  1721   val copy = I;
  1722   val extend = I;
  1723   fun merge _ oracles = NameSpace.merge_tables (op =) oracles
  1724     handle Symtab.DUP dup => err_dup_ora dup;
  1725 );
  1726 
  1727 val extern_oracles = map #1 o NameSpace.extern_table o Oracles.get;
  1728 
  1729 fun add_oracle (bname, oracle) thy =
  1730   let
  1731     val naming = Sign.naming_of thy;
  1732     val name = NameSpace.full naming bname;
  1733     val thy' = thy |> Oracles.map (fn (space, tab) =>
  1734       (NameSpace.declare naming name space,
  1735         Symtab.update_new (name, stamp ()) tab handle Symtab.DUP dup => err_dup_ora dup));
  1736   in ((name, invoke_oracle (Theory.check_thy thy') name oracle), thy') end;
  1737 
  1738 end;
  1739 
  1740 structure BasicThm: BASIC_THM = Thm;
  1741 open BasicThm;