src/Pure/sign.ML
author wenzelm
Fri Apr 08 14:20:57 2011 +0200 (2011-04-08)
changeset 42287 d98eb048a2e4
parent 42284 326f57825e1a
child 42288 2074b31650e6
permissions -rw-r--r--
discontinued special treatment of structure Mixfix;
eliminated slightly odd no_syn convenience;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: Name_Space.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    16   val naming_of: theory -> Name_Space.naming
    17   val full_name: theory -> binding -> string
    18   val full_name_path: theory -> string -> binding -> string
    19   val full_bname: theory -> bstring -> string
    20   val full_bname_path: theory -> string -> bstring -> string
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val set_defsort: sort -> theory -> theory
    29   val defaultS: theory -> sort
    30   val subsort: theory -> sort * sort -> bool
    31   val of_sort: theory -> typ * sort -> bool
    32   val inter_sort: theory -> sort * sort -> sort
    33   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    34   val is_logtype: theory -> string -> bool
    35   val typ_instance: theory -> typ * typ -> bool
    36   val typ_equiv: theory -> typ * typ -> bool
    37   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    38   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    39   val consts_of: theory -> Consts.T
    40   val the_const_constraint: theory -> string -> typ
    41   val const_type: theory -> string -> typ option
    42   val the_const_type: theory -> string -> typ
    43   val declared_tyname: theory -> string -> bool
    44   val declared_const: theory -> string -> bool
    45   val const_monomorphic: theory -> string -> bool
    46   val const_typargs: theory -> string * typ -> typ list
    47   val const_instance: theory -> string * typ list -> typ
    48   val mk_const: theory -> string * typ list -> term
    49   val class_space: theory -> Name_Space.T
    50   val type_space: theory -> Name_Space.T
    51   val const_space: theory -> Name_Space.T
    52   val class_alias: binding -> class -> theory -> theory
    53   val type_alias: binding -> string -> theory -> theory
    54   val const_alias: binding -> string -> theory -> theory
    55   val intern_class: theory -> xstring -> string
    56   val extern_class: theory -> string -> xstring
    57   val intern_type: theory -> xstring -> string
    58   val extern_type: theory -> string -> xstring
    59   val intern_const: theory -> xstring -> string
    60   val extern_const: theory -> string -> xstring
    61   val arity_number: theory -> string -> int
    62   val arity_sorts: theory -> string -> sort -> sort list
    63   val certify_class: theory -> class -> class
    64   val certify_sort: theory -> sort -> sort
    65   val certify_typ: theory -> typ -> typ
    66   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    67   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    68   val certify_term: theory -> term -> term * typ * int
    69   val cert_term: theory -> term -> term
    70   val cert_prop: theory -> term -> term
    71   val no_frees: Proof.context -> term -> term
    72   val no_vars: Proof.context -> term -> term
    73   val add_types: (binding * int * mixfix) list -> theory -> theory
    74   val add_nonterminals: binding list -> theory -> theory
    75   val add_type_abbrev: binding * string list * typ -> theory -> theory
    76   val add_syntax: (string * string * mixfix) list -> theory -> theory
    77   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    78   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    79   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    80   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    81   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    82   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    83   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    84   val declare_const: (binding * typ) * mixfix -> theory -> term * theory
    85   val add_consts: (binding * string * mixfix) list -> theory -> theory
    86   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    87   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    88   val revert_abbrev: string -> string -> theory -> theory
    89   val add_const_constraint: string * typ option -> theory -> theory
    90   val primitive_class: binding * class list -> theory -> theory
    91   val primitive_classrel: class * class -> theory -> theory
    92   val primitive_arity: arity -> theory -> theory
    93   val add_trfuns:
    94     (string * (Ast.ast list -> Ast.ast)) list *
    95     (string * (term list -> term)) list *
    96     (string * (term list -> term)) list *
    97     (string * (Ast.ast list -> Ast.ast)) list -> theory -> theory
    98   val add_trfunsT: (string * (typ -> term list -> term)) list -> theory -> theory
    99   val add_advanced_trfuns:
   100     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list *
   101     (string * (Proof.context -> term list -> term)) list *
   102     (string * (Proof.context -> term list -> term)) list *
   103     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   104   val add_advanced_trfunsT:
   105     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
   106   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   107   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   108   val new_group: theory -> theory
   109   val reset_group: theory -> theory
   110   val add_path: string -> theory -> theory
   111   val root_path: theory -> theory
   112   val parent_path: theory -> theory
   113   val mandatory_path: string -> theory -> theory
   114   val qualified_path: bool -> binding -> theory -> theory
   115   val local_path: theory -> theory
   116   val restore_naming: theory -> theory -> theory
   117   val hide_class: bool -> string -> theory -> theory
   118   val hide_type: bool -> string -> theory -> theory
   119   val hide_const: bool -> string -> theory -> theory
   120 end
   121 
   122 structure Sign: SIGN =
   123 struct
   124 
   125 (** datatype sign **)
   126 
   127 datatype sign = Sign of
   128  {naming: Name_Space.naming,    (*common naming conventions*)
   129   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   130   tsig: Type.tsig,              (*order-sorted signature of types*)
   131   consts: Consts.T};            (*polymorphic constants*)
   132 
   133 fun make_sign (naming, syn, tsig, consts) =
   134   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   135 
   136 structure Data = Theory_Data_PP
   137 (
   138   type T = sign;
   139   fun extend (Sign {syn, tsig, consts, ...}) =
   140     make_sign (Name_Space.default_naming, syn, tsig, consts);
   141 
   142   val empty =
   143     make_sign (Name_Space.default_naming, Syntax.basic_syntax, Type.empty_tsig, Consts.empty);
   144 
   145   fun merge pp (sign1, sign2) =
   146     let
   147       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   148       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   149 
   150       val naming = Name_Space.default_naming;
   151       val syn = Syntax.merge_syntaxes syn1 syn2;
   152       val tsig = Type.merge_tsig pp (tsig1, tsig2);
   153       val consts = Consts.merge (consts1, consts2);
   154     in make_sign (naming, syn, tsig, consts) end;
   155 );
   156 
   157 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   158 
   159 fun map_sign f = Data.map (fn Sign {naming, syn, tsig, consts} =>
   160   make_sign (f (naming, syn, tsig, consts)));
   161 
   162 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   163 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   164 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   165 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   166 
   167 
   168 (* naming *)
   169 
   170 val naming_of = #naming o rep_sg;
   171 
   172 val full_name = Name_Space.full_name o naming_of;
   173 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   174 
   175 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   176 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   177 
   178 
   179 (* syntax *)
   180 
   181 val syn_of = #syn o rep_sg;
   182 
   183 
   184 (* type signature *)
   185 
   186 val tsig_of = #tsig o rep_sg;
   187 
   188 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   189 val all_classes = Sorts.all_classes o classes_of;
   190 val super_classes = Sorts.super_classes o classes_of;
   191 val minimize_sort = Sorts.minimize_sort o classes_of;
   192 val complete_sort = Sorts.complete_sort o classes_of;
   193 
   194 val set_defsort = map_tsig o Type.set_defsort;
   195 val defaultS = Type.defaultS o tsig_of;
   196 val subsort = Type.subsort o tsig_of;
   197 val of_sort = Type.of_sort o tsig_of;
   198 val inter_sort = Type.inter_sort o tsig_of;
   199 val witness_sorts = Type.witness_sorts o tsig_of;
   200 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   201 
   202 val typ_instance = Type.typ_instance o tsig_of;
   203 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   204 val typ_match = Type.typ_match o tsig_of;
   205 val typ_unify = Type.unify o tsig_of;
   206 
   207 
   208 (* polymorphic constants *)
   209 
   210 val consts_of = #consts o rep_sg;
   211 val the_const_constraint = Consts.the_constraint o consts_of;
   212 val the_const_type = Consts.the_type o consts_of;
   213 val const_type = try o the_const_type;
   214 val const_monomorphic = Consts.is_monomorphic o consts_of;
   215 val const_typargs = Consts.typargs o consts_of;
   216 val const_instance = Consts.instance o consts_of;
   217 
   218 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   219 
   220 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   221 val declared_const = can o the_const_constraint;
   222 
   223 
   224 
   225 (** intern / extern names **)
   226 
   227 val class_space = Type.class_space o tsig_of;
   228 val type_space = Type.type_space o tsig_of;
   229 val const_space = Consts.space_of o consts_of;
   230 
   231 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   232 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   233 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   234 
   235 val intern_class = Name_Space.intern o class_space;
   236 val extern_class = Name_Space.extern o class_space;
   237 val intern_type = Name_Space.intern o type_space;
   238 val extern_type = Name_Space.extern o type_space;
   239 val intern_const = Name_Space.intern o const_space;
   240 val extern_const = Name_Space.extern o const_space;
   241 
   242 
   243 
   244 (** certify entities **)    (*exception TYPE*)
   245 
   246 (* certify wrt. type signature *)
   247 
   248 val arity_number = Type.arity_number o tsig_of;
   249 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   250 
   251 val certify_class         = Type.cert_class o tsig_of;
   252 val certify_sort          = Type.cert_sort o tsig_of;
   253 val certify_typ           = Type.cert_typ o tsig_of;
   254 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   255 
   256 
   257 (* certify term/prop *)
   258 
   259 local
   260 
   261 fun type_check pp tm =
   262   let
   263     fun err_appl bs t T u U =
   264       let
   265         val xs = map Free bs;           (*we do not rename here*)
   266         val t' = subst_bounds (xs, t);
   267         val u' = subst_bounds (xs, u);
   268         val msg = Type.appl_error pp t' T u' U;
   269       in raise TYPE (msg, [T, U], [t', u']) end;
   270 
   271     fun typ_of (_, Const (_, T)) = T
   272       | typ_of (_, Free  (_, T)) = T
   273       | typ_of (_, Var (_, T)) = T
   274       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   275           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   276       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   277       | typ_of (bs, t $ u) =
   278           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   279             (case T of
   280               Type ("fun", [T1, T2]) =>
   281                 if T1 = U then T2 else err_appl bs t T u U
   282             | _ => err_appl bs t T u U)
   283           end;
   284   in typ_of ([], tm) end;
   285 
   286 fun err msg = raise TYPE (msg, [], []);
   287 
   288 fun check_vars (t $ u) = (check_vars t; check_vars u)
   289   | check_vars (Abs (_, _, t)) = check_vars t
   290   | check_vars (Free (x, _)) =
   291       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   292   | check_vars (Var (xi as (_, i), _)) =
   293       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   294   | check_vars _ = ();
   295 
   296 in
   297 
   298 fun certify' prop pp do_expand consts thy tm =
   299   let
   300     val _ = check_vars tm;
   301     val tm' = Term.map_types (certify_typ thy) tm;
   302     val T = type_check pp tm';
   303     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   304     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   305   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   306 
   307 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   308 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   309 val cert_term = #1 oo certify_term;
   310 fun cert_prop thy = #1 o certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   311 
   312 end;
   313 
   314 
   315 (* specifications *)
   316 
   317 fun no_variables kind add addT mk mkT ctxt tm =
   318   (case (add tm [], addT tm []) of
   319     ([], []) => tm
   320   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   321       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   322        Pretty.commas
   323         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   324 
   325 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   326 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   327 
   328 
   329 
   330 (** signature extension functions **)  (*exception ERROR/TYPE*)
   331 
   332 (* add type constructors *)
   333 
   334 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   335   let
   336     fun type_syntax (b, n, mx) =
   337       (Syntax.mark_type (Name_Space.full_name naming b), Mixfix.make_type n, mx);
   338     val syn' = Syntax.update_type_gram true Syntax.mode_default (map type_syntax types) syn;
   339     val tsig' = fold (fn (a, n, _) => Type.add_type naming (a, n)) types tsig;
   340   in (naming, syn', tsig', consts) end);
   341 
   342 
   343 (* add nonterminals *)
   344 
   345 fun add_nonterminals ns = map_sign (fn (naming, syn, tsig, consts) =>
   346   (naming, syn, fold (Type.add_nonterminal naming) ns tsig, consts));
   347 
   348 
   349 (* add type abbreviations *)
   350 
   351 fun add_type_abbrev abbr = map_sign (fn (naming, syn, tsig, consts) =>
   352   (naming, syn, Type.add_abbrev naming abbr tsig, consts));
   353 
   354 
   355 (* modify syntax *)
   356 
   357 fun gen_syntax change_gram parse_typ mode args thy =
   358   let
   359     val ctxt = ProofContext.init_global thy;
   360     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   361       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   362   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   363 
   364 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   365 
   366 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   367 val add_modesyntax_i = gen_add_syntax (K I);
   368 val add_syntax = add_modesyntax Syntax.mode_default;
   369 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   370 val del_modesyntax = gen_syntax (Syntax.update_const_gram false) Syntax.parse_typ;
   371 val del_modesyntax_i = gen_syntax (Syntax.update_const_gram false) (K I);
   372 
   373 fun type_notation add mode args =
   374   let
   375     fun type_syntax (Type (c, args), mx) =
   376           SOME (Syntax.mark_type c, Mixfix.make_type (length args), mx)
   377       | type_syntax _ = NONE;
   378   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   379 
   380 fun notation add mode args thy =
   381   let
   382     fun const_syntax (Const (c, _), mx) =
   383           (case try (Consts.type_scheme (consts_of thy)) c of
   384             SOME T => SOME (Syntax.mark_const c, T, mx)
   385           | NONE => NONE)
   386       | const_syntax _ = NONE;
   387   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   388 
   389 
   390 (* add constants *)
   391 
   392 local
   393 
   394 fun gen_add_consts parse_typ raw_args thy =
   395   let
   396     val ctxt = ProofContext.init_global thy;
   397     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   398     fun prep (b, raw_T, mx) =
   399       let
   400         val c = full_name thy b;
   401         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   402           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   403         val T' = Logic.varifyT_global T;
   404       in ((b, T'), (Syntax.mark_const c, T', mx), Const (c, T)) end;
   405     val args = map prep raw_args;
   406   in
   407     thy
   408     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   409     |> add_syntax_i (map #2 args)
   410     |> pair (map #3 args)
   411   end;
   412 
   413 in
   414 
   415 fun add_consts args = snd o gen_add_consts Syntax.parse_typ args;
   416 fun add_consts_i args = snd o gen_add_consts (K I) args;
   417 
   418 fun declare_const ((b, T), mx) thy =
   419   let
   420     val pos = Binding.pos_of b;
   421     val ([const as Const (c, _)], thy') = gen_add_consts (K I) [(b, T, mx)] thy;
   422     val _ = Position.report pos (Markup.const_decl c);
   423   in (const, thy') end;
   424 
   425 end;
   426 
   427 
   428 (* abbreviations *)
   429 
   430 fun add_abbrev mode (b, raw_t) thy =
   431   let
   432     val ctxt = Syntax.init_pretty_global thy;
   433     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   434     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   435       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   436     val (res, consts') = consts_of thy
   437       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of thy) (naming_of thy) mode (b, t);
   438   in (res, thy |> map_consts (K consts')) end;
   439 
   440 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   441 
   442 
   443 (* add constraints *)
   444 
   445 fun add_const_constraint (c, opt_T) thy =
   446   let
   447     fun prepT raw_T =
   448       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   449       in cert_term thy (Const (c, T)); T end
   450       handle TYPE (msg, _, _) => error msg;
   451   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   452 
   453 
   454 (* primitive classes and arities *)
   455 
   456 fun primitive_class (bclass, classes) thy =
   457   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   458     let
   459       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   460     in (naming, syn, tsig', consts) end)
   461   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   462 
   463 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   464 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   465 
   466 
   467 (* add translation functions *)
   468 
   469 local
   470 
   471 fun mk trs = map Syntax.mk_trfun trs;
   472 
   473 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   474   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   475 
   476 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   477 
   478 in
   479 
   480 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax_Trans.non_typed_tr';
   481 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   482 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax_Trans.non_typed_tr'';
   483 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   484 
   485 end;
   486 
   487 
   488 (* translation rules *)
   489 
   490 val add_trrules = map_syn o Syntax.update_trrules;
   491 val del_trrules = map_syn o Syntax.remove_trrules;
   492 
   493 
   494 (* naming *)
   495 
   496 val new_group = map_naming Name_Space.new_group;
   497 val reset_group = map_naming Name_Space.reset_group;
   498 
   499 val add_path = map_naming o Name_Space.add_path;
   500 val root_path = map_naming Name_Space.root_path;
   501 val parent_path = map_naming Name_Space.parent_path;
   502 val mandatory_path = map_naming o Name_Space.mandatory_path;
   503 val qualified_path = map_naming oo Name_Space.qualified_path;
   504 
   505 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   506 
   507 val restore_naming = map_naming o K o naming_of;
   508 
   509 
   510 (* hide names *)
   511 
   512 val hide_class = map_tsig oo Type.hide_class;
   513 val hide_type = map_tsig oo Type.hide_type;
   514 val hide_const = map_consts oo Consts.hide;
   515 
   516 end;