src/HOL/Multivariate_Analysis/Topology_Euclidean_Space.thy
author huffman
Wed Aug 24 15:06:13 2011 -0700 (2011-08-24)
changeset 44516 d9a496ae5d9d
parent 44457 d366fa5551ef
child 44517 68e8eb0ce8aa
permissions -rw-r--r--
move everything related to 'norm' method into new theory file Norm_Arith.thy
     1 (*  title:      HOL/Library/Topology_Euclidian_Space.thy
     2     Author:     Amine Chaieb, University of Cambridge
     3     Author:     Robert Himmelmann, TU Muenchen
     4     Author:     Brian Huffman, Portland State University
     5 *)
     6 
     7 header {* Elementary topology in Euclidean space. *}
     8 
     9 theory Topology_Euclidean_Space
    10 imports SEQ Linear_Algebra "~~/src/HOL/Library/Glbs" Norm_Arith
    11 begin
    12 
    13 (* to be moved elsewhere *)
    14 
    15 lemma euclidean_dist_l2:"dist x (y::'a::euclidean_space) = setL2 (\<lambda>i. dist(x$$i) (y$$i)) {..<DIM('a)}"
    16   unfolding dist_norm norm_eq_sqrt_inner setL2_def apply(subst euclidean_inner)
    17   by(auto simp add:power2_eq_square)
    18 
    19 lemma dist_nth_le: "dist (x $$ i) (y $$ i) \<le> dist x (y::'a::euclidean_space)"
    20   apply(subst(2) euclidean_dist_l2) apply(cases "i<DIM('a)")
    21   apply(rule member_le_setL2) by auto
    22 
    23 subsection {* General notion of a topologies as values *}
    24 
    25 definition "istopology L \<longleftrightarrow> L {} \<and> (\<forall>S T. L S \<longrightarrow> L T \<longrightarrow> L (S \<inter> T)) \<and> (\<forall>K. Ball K L \<longrightarrow> L (\<Union> K))"
    26 typedef (open) 'a topology = "{L::('a set) \<Rightarrow> bool. istopology L}"
    27   morphisms "openin" "topology"
    28   unfolding istopology_def by blast
    29 
    30 lemma istopology_open_in[intro]: "istopology(openin U)"
    31   using openin[of U] by blast
    32 
    33 lemma topology_inverse': "istopology U \<Longrightarrow> openin (topology U) = U"
    34   using topology_inverse[unfolded mem_Collect_eq] .
    35 
    36 lemma topology_inverse_iff: "istopology U \<longleftrightarrow> openin (topology U) = U"
    37   using topology_inverse[of U] istopology_open_in[of "topology U"] by auto
    38 
    39 lemma topology_eq: "T1 = T2 \<longleftrightarrow> (\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S)"
    40 proof-
    41   {assume "T1=T2" hence "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S" by simp}
    42   moreover
    43   {assume H: "\<forall>S. openin T1 S \<longleftrightarrow> openin T2 S"
    44     hence "openin T1 = openin T2" by (simp add: fun_eq_iff)
    45     hence "topology (openin T1) = topology (openin T2)" by simp
    46     hence "T1 = T2" unfolding openin_inverse .}
    47   ultimately show ?thesis by blast
    48 qed
    49 
    50 text{* Infer the "universe" from union of all sets in the topology. *}
    51 
    52 definition "topspace T =  \<Union>{S. openin T S}"
    53 
    54 subsubsection {* Main properties of open sets *}
    55 
    56 lemma openin_clauses:
    57   fixes U :: "'a topology"
    58   shows "openin U {}"
    59   "\<And>S T. openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S\<inter>T)"
    60   "\<And>K. (\<forall>S \<in> K. openin U S) \<Longrightarrow> openin U (\<Union>K)"
    61   using openin[of U] unfolding istopology_def mem_Collect_eq
    62   by fast+
    63 
    64 lemma openin_subset[intro]: "openin U S \<Longrightarrow> S \<subseteq> topspace U"
    65   unfolding topspace_def by blast
    66 lemma openin_empty[simp]: "openin U {}" by (simp add: openin_clauses)
    67 
    68 lemma openin_Int[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<inter> T)"
    69   using openin_clauses by simp
    70 
    71 lemma openin_Union[intro]: "(\<forall>S \<in>K. openin U S) \<Longrightarrow> openin U (\<Union> K)"
    72   using openin_clauses by simp
    73 
    74 lemma openin_Un[intro]: "openin U S \<Longrightarrow> openin U T \<Longrightarrow> openin U (S \<union> T)"
    75   using openin_Union[of "{S,T}" U] by auto
    76 
    77 lemma openin_topspace[intro, simp]: "openin U (topspace U)" by (simp add: openin_Union topspace_def)
    78 
    79 lemma openin_subopen: "openin U S \<longleftrightarrow> (\<forall>x \<in> S. \<exists>T. openin U T \<and> x \<in> T \<and> T \<subseteq> S)" (is "?lhs \<longleftrightarrow> ?rhs")
    80 proof
    81   assume ?lhs then show ?rhs by auto
    82 next
    83   assume H: ?rhs
    84   let ?t = "\<Union>{T. openin U T \<and> T \<subseteq> S}"
    85   have "openin U ?t" by (simp add: openin_Union)
    86   also have "?t = S" using H by auto
    87   finally show "openin U S" .
    88 qed
    89 
    90 subsubsection {* Closed sets *}
    91 
    92 definition "closedin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> openin U (topspace U - S)"
    93 
    94 lemma closedin_subset: "closedin U S \<Longrightarrow> S \<subseteq> topspace U" by (metis closedin_def)
    95 lemma closedin_empty[simp]: "closedin U {}" by (simp add: closedin_def)
    96 lemma closedin_topspace[intro,simp]:
    97   "closedin U (topspace U)" by (simp add: closedin_def)
    98 lemma closedin_Un[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<union> T)"
    99   by (auto simp add: Diff_Un closedin_def)
   100 
   101 lemma Diff_Inter[intro]: "A - \<Inter>S = \<Union> {A - s|s. s\<in>S}" by auto
   102 lemma closedin_Inter[intro]: assumes Ke: "K \<noteq> {}" and Kc: "\<forall>S \<in>K. closedin U S"
   103   shows "closedin U (\<Inter> K)"  using Ke Kc unfolding closedin_def Diff_Inter by auto
   104 
   105 lemma closedin_Int[intro]: "closedin U S \<Longrightarrow> closedin U T \<Longrightarrow> closedin U (S \<inter> T)"
   106   using closedin_Inter[of "{S,T}" U] by auto
   107 
   108 lemma Diff_Diff_Int: "A - (A - B) = A \<inter> B" by blast
   109 lemma openin_closedin_eq: "openin U S \<longleftrightarrow> S \<subseteq> topspace U \<and> closedin U (topspace U - S)"
   110   apply (auto simp add: closedin_def Diff_Diff_Int inf_absorb2)
   111   apply (metis openin_subset subset_eq)
   112   done
   113 
   114 lemma openin_closedin:  "S \<subseteq> topspace U \<Longrightarrow> (openin U S \<longleftrightarrow> closedin U (topspace U - S))"
   115   by (simp add: openin_closedin_eq)
   116 
   117 lemma openin_diff[intro]: assumes oS: "openin U S" and cT: "closedin U T" shows "openin U (S - T)"
   118 proof-
   119   have "S - T = S \<inter> (topspace U - T)" using openin_subset[of U S]  oS cT
   120     by (auto simp add: topspace_def openin_subset)
   121   then show ?thesis using oS cT by (auto simp add: closedin_def)
   122 qed
   123 
   124 lemma closedin_diff[intro]: assumes oS: "closedin U S" and cT: "openin U T" shows "closedin U (S - T)"
   125 proof-
   126   have "S - T = S \<inter> (topspace U - T)" using closedin_subset[of U S]  oS cT
   127     by (auto simp add: topspace_def )
   128   then show ?thesis using oS cT by (auto simp add: openin_closedin_eq)
   129 qed
   130 
   131 subsubsection {* Subspace topology *}
   132 
   133 definition "subtopology U V = topology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   134 
   135 lemma istopology_subtopology: "istopology (\<lambda>T. \<exists>S. T = S \<inter> V \<and> openin U S)"
   136   (is "istopology ?L")
   137 proof-
   138   have "?L {}" by blast
   139   {fix A B assume A: "?L A" and B: "?L B"
   140     from A B obtain Sa and Sb where Sa: "openin U Sa" "A = Sa \<inter> V" and Sb: "openin U Sb" "B = Sb \<inter> V" by blast
   141     have "A\<inter>B = (Sa \<inter> Sb) \<inter> V" "openin U (Sa \<inter> Sb)"  using Sa Sb by blast+
   142     then have "?L (A \<inter> B)" by blast}
   143   moreover
   144   {fix K assume K: "K \<subseteq> Collect ?L"
   145     have th0: "Collect ?L = (\<lambda>S. S \<inter> V) ` Collect (openin U)"
   146       apply (rule set_eqI)
   147       apply (simp add: Ball_def image_iff)
   148       by metis
   149     from K[unfolded th0 subset_image_iff]
   150     obtain Sk where Sk: "Sk \<subseteq> Collect (openin U)" "K = (\<lambda>S. S \<inter> V) ` Sk" by blast
   151     have "\<Union>K = (\<Union>Sk) \<inter> V" using Sk by auto
   152     moreover have "openin U (\<Union> Sk)" using Sk by (auto simp add: subset_eq)
   153     ultimately have "?L (\<Union>K)" by blast}
   154   ultimately show ?thesis
   155     unfolding subset_eq mem_Collect_eq istopology_def by blast
   156 qed
   157 
   158 lemma openin_subtopology:
   159   "openin (subtopology U V) S \<longleftrightarrow> (\<exists> T. (openin U T) \<and> (S = T \<inter> V))"
   160   unfolding subtopology_def topology_inverse'[OF istopology_subtopology]
   161   by auto
   162 
   163 lemma topspace_subtopology: "topspace(subtopology U V) = topspace U \<inter> V"
   164   by (auto simp add: topspace_def openin_subtopology)
   165 
   166 lemma closedin_subtopology:
   167   "closedin (subtopology U V) S \<longleftrightarrow> (\<exists>T. closedin U T \<and> S = T \<inter> V)"
   168   unfolding closedin_def topspace_subtopology
   169   apply (simp add: openin_subtopology)
   170   apply (rule iffI)
   171   apply clarify
   172   apply (rule_tac x="topspace U - T" in exI)
   173   by auto
   174 
   175 lemma openin_subtopology_refl: "openin (subtopology U V) V \<longleftrightarrow> V \<subseteq> topspace U"
   176   unfolding openin_subtopology
   177   apply (rule iffI, clarify)
   178   apply (frule openin_subset[of U])  apply blast
   179   apply (rule exI[where x="topspace U"])
   180   by auto
   181 
   182 lemma subtopology_superset: assumes UV: "topspace U \<subseteq> V"
   183   shows "subtopology U V = U"
   184 proof-
   185   {fix S
   186     {fix T assume T: "openin U T" "S = T \<inter> V"
   187       from T openin_subset[OF T(1)] UV have eq: "S = T" by blast
   188       have "openin U S" unfolding eq using T by blast}
   189     moreover
   190     {assume S: "openin U S"
   191       hence "\<exists>T. openin U T \<and> S = T \<inter> V"
   192         using openin_subset[OF S] UV by auto}
   193     ultimately have "(\<exists>T. openin U T \<and> S = T \<inter> V) \<longleftrightarrow> openin U S" by blast}
   194   then show ?thesis unfolding topology_eq openin_subtopology by blast
   195 qed
   196 
   197 lemma subtopology_topspace[simp]: "subtopology U (topspace U) = U"
   198   by (simp add: subtopology_superset)
   199 
   200 lemma subtopology_UNIV[simp]: "subtopology U UNIV = U"
   201   by (simp add: subtopology_superset)
   202 
   203 subsubsection {* The standard Euclidean topology *}
   204 
   205 definition
   206   euclidean :: "'a::topological_space topology" where
   207   "euclidean = topology open"
   208 
   209 lemma open_openin: "open S \<longleftrightarrow> openin euclidean S"
   210   unfolding euclidean_def
   211   apply (rule cong[where x=S and y=S])
   212   apply (rule topology_inverse[symmetric])
   213   apply (auto simp add: istopology_def)
   214   done
   215 
   216 lemma topspace_euclidean: "topspace euclidean = UNIV"
   217   apply (simp add: topspace_def)
   218   apply (rule set_eqI)
   219   by (auto simp add: open_openin[symmetric])
   220 
   221 lemma topspace_euclidean_subtopology[simp]: "topspace (subtopology euclidean S) = S"
   222   by (simp add: topspace_euclidean topspace_subtopology)
   223 
   224 lemma closed_closedin: "closed S \<longleftrightarrow> closedin euclidean S"
   225   by (simp add: closed_def closedin_def topspace_euclidean open_openin Compl_eq_Diff_UNIV)
   226 
   227 lemma open_subopen: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S)"
   228   by (simp add: open_openin openin_subopen[symmetric])
   229 
   230 text {* Basic "localization" results are handy for connectedness. *}
   231 
   232 lemma openin_open: "openin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. open T \<and> (S = U \<inter> T))"
   233   by (auto simp add: openin_subtopology open_openin[symmetric])
   234 
   235 lemma openin_open_Int[intro]: "open S \<Longrightarrow> openin (subtopology euclidean U) (U \<inter> S)"
   236   by (auto simp add: openin_open)
   237 
   238 lemma open_openin_trans[trans]:
   239  "open S \<Longrightarrow> open T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> openin (subtopology euclidean S) T"
   240   by (metis Int_absorb1  openin_open_Int)
   241 
   242 lemma open_subset:  "S \<subseteq> T \<Longrightarrow> open S \<Longrightarrow> openin (subtopology euclidean T) S"
   243   by (auto simp add: openin_open)
   244 
   245 lemma closedin_closed: "closedin (subtopology euclidean U) S \<longleftrightarrow> (\<exists>T. closed T \<and> S = U \<inter> T)"
   246   by (simp add: closedin_subtopology closed_closedin Int_ac)
   247 
   248 lemma closedin_closed_Int: "closed S ==> closedin (subtopology euclidean U) (U \<inter> S)"
   249   by (metis closedin_closed)
   250 
   251 lemma closed_closedin_trans: "closed S \<Longrightarrow> closed T \<Longrightarrow> T \<subseteq> S \<Longrightarrow> closedin (subtopology euclidean S) T"
   252   apply (subgoal_tac "S \<inter> T = T" )
   253   apply auto
   254   apply (frule closedin_closed_Int[of T S])
   255   by simp
   256 
   257 lemma closed_subset: "S \<subseteq> T \<Longrightarrow> closed S \<Longrightarrow> closedin (subtopology euclidean T) S"
   258   by (auto simp add: closedin_closed)
   259 
   260 lemma openin_euclidean_subtopology_iff:
   261   fixes S U :: "'a::metric_space set"
   262   shows "openin (subtopology euclidean U) S
   263   \<longleftrightarrow> S \<subseteq> U \<and> (\<forall>x\<in>S. \<exists>e>0. \<forall>x'\<in>U. dist x' x < e \<longrightarrow> x'\<in> S)" (is "?lhs \<longleftrightarrow> ?rhs")
   264 proof
   265   assume ?lhs thus ?rhs unfolding openin_open open_dist by blast
   266 next
   267   def T \<equiv> "{x. \<exists>a\<in>S. \<exists>d>0. (\<forall>y\<in>U. dist y a < d \<longrightarrow> y \<in> S) \<and> dist x a < d}"
   268   have 1: "\<forall>x\<in>T. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> T"
   269     unfolding T_def
   270     apply clarsimp
   271     apply (rule_tac x="d - dist x a" in exI)
   272     apply (clarsimp simp add: less_diff_eq)
   273     apply (erule rev_bexI)
   274     apply (rule_tac x=d in exI, clarify)
   275     apply (erule le_less_trans [OF dist_triangle])
   276     done
   277   assume ?rhs hence 2: "S = U \<inter> T"
   278     unfolding T_def
   279     apply auto
   280     apply (drule (1) bspec, erule rev_bexI)
   281     apply auto
   282     done
   283   from 1 2 show ?lhs
   284     unfolding openin_open open_dist by fast
   285 qed
   286 
   287 text {* These "transitivity" results are handy too *}
   288 
   289 lemma openin_trans[trans]: "openin (subtopology euclidean T) S \<Longrightarrow> openin (subtopology euclidean U) T
   290   \<Longrightarrow> openin (subtopology euclidean U) S"
   291   unfolding open_openin openin_open by blast
   292 
   293 lemma openin_open_trans: "openin (subtopology euclidean T) S \<Longrightarrow> open T \<Longrightarrow> open S"
   294   by (auto simp add: openin_open intro: openin_trans)
   295 
   296 lemma closedin_trans[trans]:
   297  "closedin (subtopology euclidean T) S \<Longrightarrow>
   298            closedin (subtopology euclidean U) T
   299            ==> closedin (subtopology euclidean U) S"
   300   by (auto simp add: closedin_closed closed_closedin closed_Inter Int_assoc)
   301 
   302 lemma closedin_closed_trans: "closedin (subtopology euclidean T) S \<Longrightarrow> closed T \<Longrightarrow> closed S"
   303   by (auto simp add: closedin_closed intro: closedin_trans)
   304 
   305 
   306 subsection {* Open and closed balls *}
   307 
   308 definition
   309   ball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set" where
   310   "ball x e = {y. dist x y < e}"
   311 
   312 definition
   313   cball :: "'a::metric_space \<Rightarrow> real \<Rightarrow> 'a set" where
   314   "cball x e = {y. dist x y \<le> e}"
   315 
   316 lemma mem_ball[simp]: "y \<in> ball x e \<longleftrightarrow> dist x y < e" by (simp add: ball_def)
   317 lemma mem_cball[simp]: "y \<in> cball x e \<longleftrightarrow> dist x y \<le> e" by (simp add: cball_def)
   318 
   319 lemma mem_ball_0 [simp]:
   320   fixes x :: "'a::real_normed_vector"
   321   shows "x \<in> ball 0 e \<longleftrightarrow> norm x < e"
   322   by (simp add: dist_norm)
   323 
   324 lemma mem_cball_0 [simp]:
   325   fixes x :: "'a::real_normed_vector"
   326   shows "x \<in> cball 0 e \<longleftrightarrow> norm x \<le> e"
   327   by (simp add: dist_norm)
   328 
   329 lemma centre_in_cball[simp]: "x \<in> cball x e \<longleftrightarrow> 0\<le> e"  by simp
   330 lemma ball_subset_cball[simp,intro]: "ball x e \<subseteq> cball x e" by (simp add: subset_eq)
   331 lemma subset_ball[intro]: "d <= e ==> ball x d \<subseteq> ball x e" by (simp add: subset_eq)
   332 lemma subset_cball[intro]: "d <= e ==> cball x d \<subseteq> cball x e" by (simp add: subset_eq)
   333 lemma ball_max_Un: "ball a (max r s) = ball a r \<union> ball a s"
   334   by (simp add: set_eq_iff) arith
   335 
   336 lemma ball_min_Int: "ball a (min r s) = ball a r \<inter> ball a s"
   337   by (simp add: set_eq_iff)
   338 
   339 lemma diff_less_iff: "(a::real) - b > 0 \<longleftrightarrow> a > b"
   340   "(a::real) - b < 0 \<longleftrightarrow> a < b"
   341   "a - b < c \<longleftrightarrow> a < c +b" "a - b > c \<longleftrightarrow> a > c +b" by arith+
   342 lemma diff_le_iff: "(a::real) - b \<ge> 0 \<longleftrightarrow> a \<ge> b" "(a::real) - b \<le> 0 \<longleftrightarrow> a \<le> b"
   343   "a - b \<le> c \<longleftrightarrow> a \<le> c +b" "a - b \<ge> c \<longleftrightarrow> a \<ge> c +b"  by arith+
   344 
   345 lemma open_ball[intro, simp]: "open (ball x e)"
   346   unfolding open_dist ball_def mem_Collect_eq Ball_def
   347   unfolding dist_commute
   348   apply clarify
   349   apply (rule_tac x="e - dist xa x" in exI)
   350   using dist_triangle_alt[where z=x]
   351   apply (clarsimp simp add: diff_less_iff)
   352   apply atomize
   353   apply (erule_tac x="y" in allE)
   354   apply (erule_tac x="xa" in allE)
   355   by arith
   356 
   357 lemma centre_in_ball[simp]: "x \<in> ball x e \<longleftrightarrow> e > 0" by (metis mem_ball dist_self)
   358 lemma open_contains_ball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. ball x e \<subseteq> S)"
   359   unfolding open_dist subset_eq mem_ball Ball_def dist_commute ..
   360 
   361 lemma openE[elim?]:
   362   assumes "open S" "x\<in>S" 
   363   obtains e where "e>0" "ball x e \<subseteq> S"
   364   using assms unfolding open_contains_ball by auto
   365 
   366 lemma open_contains_ball_eq: "open S \<Longrightarrow> \<forall>x. x\<in>S \<longleftrightarrow> (\<exists>e>0. ball x e \<subseteq> S)"
   367   by (metis open_contains_ball subset_eq centre_in_ball)
   368 
   369 lemma ball_eq_empty[simp]: "ball x e = {} \<longleftrightarrow> e \<le> 0"
   370   unfolding mem_ball set_eq_iff
   371   apply (simp add: not_less)
   372   by (metis zero_le_dist order_trans dist_self)
   373 
   374 lemma ball_empty[intro]: "e \<le> 0 ==> ball x e = {}" by simp
   375 
   376 
   377 subsection{* Connectedness *}
   378 
   379 definition "connected S \<longleftrightarrow>
   380   ~(\<exists>e1 e2. open e1 \<and> open e2 \<and> S \<subseteq> (e1 \<union> e2) \<and> (e1 \<inter> e2 \<inter> S = {})
   381   \<and> ~(e1 \<inter> S = {}) \<and> ~(e2 \<inter> S = {}))"
   382 
   383 lemma connected_local:
   384  "connected S \<longleftrightarrow> ~(\<exists>e1 e2.
   385                  openin (subtopology euclidean S) e1 \<and>
   386                  openin (subtopology euclidean S) e2 \<and>
   387                  S \<subseteq> e1 \<union> e2 \<and>
   388                  e1 \<inter> e2 = {} \<and>
   389                  ~(e1 = {}) \<and>
   390                  ~(e2 = {}))"
   391 unfolding connected_def openin_open by (safe, blast+)
   392 
   393 lemma exists_diff:
   394   fixes P :: "'a set \<Rightarrow> bool"
   395   shows "(\<exists>S. P(- S)) \<longleftrightarrow> (\<exists>S. P S)" (is "?lhs \<longleftrightarrow> ?rhs")
   396 proof-
   397   {assume "?lhs" hence ?rhs by blast }
   398   moreover
   399   {fix S assume H: "P S"
   400     have "S = - (- S)" by auto
   401     with H have "P (- (- S))" by metis }
   402   ultimately show ?thesis by metis
   403 qed
   404 
   405 lemma connected_clopen: "connected S \<longleftrightarrow>
   406         (\<forall>T. openin (subtopology euclidean S) T \<and>
   407             closedin (subtopology euclidean S) T \<longrightarrow> T = {} \<or> T = S)" (is "?lhs \<longleftrightarrow> ?rhs")
   408 proof-
   409   have " \<not> connected S \<longleftrightarrow> (\<exists>e1 e2. open e1 \<and> open (- e2) \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
   410     unfolding connected_def openin_open closedin_closed
   411     apply (subst exists_diff) by blast
   412   hence th0: "connected S \<longleftrightarrow> \<not> (\<exists>e2 e1. closed e2 \<and> open e1 \<and> S \<subseteq> e1 \<union> (- e2) \<and> e1 \<inter> (- e2) \<inter> S = {} \<and> e1 \<inter> S \<noteq> {} \<and> (- e2) \<inter> S \<noteq> {})"
   413     (is " _ \<longleftrightarrow> \<not> (\<exists>e2 e1. ?P e2 e1)") apply (simp add: closed_def) by metis
   414 
   415   have th1: "?rhs \<longleftrightarrow> \<not> (\<exists>t' t. closed t'\<and>t = S\<inter>t' \<and> t\<noteq>{} \<and> t\<noteq>S \<and> (\<exists>t'. open t' \<and> t = S \<inter> t'))"
   416     (is "_ \<longleftrightarrow> \<not> (\<exists>t' t. ?Q t' t)")
   417     unfolding connected_def openin_open closedin_closed by auto
   418   {fix e2
   419     {fix e1 have "?P e2 e1 \<longleftrightarrow> (\<exists>t.  closed e2 \<and> t = S\<inter>e2 \<and> open e1 \<and> t = S\<inter>e1 \<and> t\<noteq>{} \<and> t\<noteq>S)"
   420         by auto}
   421     then have "(\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)" by metis}
   422   then have "\<forall>e2. (\<exists>e1. ?P e2 e1) \<longleftrightarrow> (\<exists>t. ?Q e2 t)" by blast
   423   then show ?thesis unfolding th0 th1 by simp
   424 qed
   425 
   426 lemma connected_empty[simp, intro]: "connected {}"
   427   by (simp add: connected_def)
   428 
   429 
   430 subsection{* Limit points *}
   431 
   432 definition (in topological_space)
   433   islimpt:: "'a \<Rightarrow> 'a set \<Rightarrow> bool" (infixr "islimpt" 60) where
   434   "x islimpt S \<longleftrightarrow> (\<forall>T. x\<in>T \<longrightarrow> open T \<longrightarrow> (\<exists>y\<in>S. y\<in>T \<and> y\<noteq>x))"
   435 
   436 lemma islimptI:
   437   assumes "\<And>T. x \<in> T \<Longrightarrow> open T \<Longrightarrow> \<exists>y\<in>S. y \<in> T \<and> y \<noteq> x"
   438   shows "x islimpt S"
   439   using assms unfolding islimpt_def by auto
   440 
   441 lemma islimptE:
   442   assumes "x islimpt S" and "x \<in> T" and "open T"
   443   obtains y where "y \<in> S" and "y \<in> T" and "y \<noteq> x"
   444   using assms unfolding islimpt_def by auto
   445 
   446 lemma islimpt_subset: "x islimpt S \<Longrightarrow> S \<subseteq> T ==> x islimpt T" by (auto simp add: islimpt_def)
   447 
   448 lemma islimpt_approachable:
   449   fixes x :: "'a::metric_space"
   450   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e)"
   451   unfolding islimpt_def
   452   apply auto
   453   apply(erule_tac x="ball x e" in allE)
   454   apply auto
   455   apply(rule_tac x=y in bexI)
   456   apply (auto simp add: dist_commute)
   457   apply (simp add: open_dist, drule (1) bspec)
   458   apply (clarify, drule spec, drule (1) mp, auto)
   459   done
   460 
   461 lemma islimpt_approachable_le:
   462   fixes x :: "'a::metric_space"
   463   shows "x islimpt S \<longleftrightarrow> (\<forall>e>0. \<exists>x'\<in> S. x' \<noteq> x \<and> dist x' x <= e)"
   464   unfolding islimpt_approachable
   465   using approachable_lt_le[where f="\<lambda>x'. dist x' x" and P="\<lambda>x'. \<not> (x'\<in>S \<and> x'\<noteq>x)"]
   466   by metis 
   467 
   468 text {* A perfect space has no isolated points. *}
   469 
   470 class perfect_space = topological_space +
   471   assumes islimpt_UNIV [simp, intro]: "x islimpt UNIV"
   472 
   473 lemma perfect_choose_dist:
   474   fixes x :: "'a::{perfect_space, metric_space}"
   475   shows "0 < r \<Longrightarrow> \<exists>a. a \<noteq> x \<and> dist a x < r"
   476 using islimpt_UNIV [of x]
   477 by (simp add: islimpt_approachable)
   478 
   479 instance euclidean_space \<subseteq> perfect_space
   480 proof
   481   fix x :: 'a
   482   { fix e :: real assume "0 < e"
   483     def y \<equiv> "x + scaleR (e/2) (sgn (basis 0))"
   484     from `0 < e` have "y \<noteq> x"
   485       unfolding y_def by (simp add: sgn_zero_iff DIM_positive)
   486     from `0 < e` have "dist y x < e"
   487       unfolding y_def by (simp add: dist_norm norm_sgn)
   488     from `y \<noteq> x` and `dist y x < e`
   489     have "\<exists>y\<in>UNIV. y \<noteq> x \<and> dist y x < e" by auto
   490   }
   491   then show "x islimpt UNIV" unfolding islimpt_approachable by blast
   492 qed
   493 
   494 lemma closed_limpt: "closed S \<longleftrightarrow> (\<forall>x. x islimpt S \<longrightarrow> x \<in> S)"
   495   unfolding closed_def
   496   apply (subst open_subopen)
   497   apply (simp add: islimpt_def subset_eq)
   498   by (metis ComplE ComplI)
   499 
   500 lemma islimpt_EMPTY[simp]: "\<not> x islimpt {}"
   501   unfolding islimpt_def by auto
   502 
   503 lemma finite_set_avoid:
   504   fixes a :: "'a::metric_space"
   505   assumes fS: "finite S" shows  "\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<longrightarrow> d <= dist a x"
   506 proof(induct rule: finite_induct[OF fS])
   507   case 1 thus ?case by (auto intro: zero_less_one)
   508 next
   509   case (2 x F)
   510   from 2 obtain d where d: "d >0" "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> d \<le> dist a x" by blast
   511   {assume "x = a" hence ?case using d by auto  }
   512   moreover
   513   {assume xa: "x\<noteq>a"
   514     let ?d = "min d (dist a x)"
   515     have dp: "?d > 0" using xa d(1) using dist_nz by auto
   516     from d have d': "\<forall>x\<in>F. x\<noteq>a \<longrightarrow> ?d \<le> dist a x" by auto
   517     with dp xa have ?case by(auto intro!: exI[where x="?d"]) }
   518   ultimately show ?case by blast
   519 qed
   520 
   521 lemma islimpt_finite:
   522   fixes S :: "'a::metric_space set"
   523   assumes fS: "finite S" shows "\<not> a islimpt S"
   524   unfolding islimpt_approachable
   525   using finite_set_avoid[OF fS, of a] by (metis dist_commute  not_le)
   526 
   527 lemma islimpt_Un: "x islimpt (S \<union> T) \<longleftrightarrow> x islimpt S \<or> x islimpt T"
   528   apply (rule iffI)
   529   defer
   530   apply (metis Un_upper1 Un_upper2 islimpt_subset)
   531   unfolding islimpt_def
   532   apply (rule ccontr, clarsimp, rename_tac A B)
   533   apply (drule_tac x="A \<inter> B" in spec)
   534   apply (auto simp add: open_Int)
   535   done
   536 
   537 lemma discrete_imp_closed:
   538   fixes S :: "'a::metric_space set"
   539   assumes e: "0 < e" and d: "\<forall>x \<in> S. \<forall>y \<in> S. dist y x < e \<longrightarrow> y = x"
   540   shows "closed S"
   541 proof-
   542   {fix x assume C: "\<forall>e>0. \<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e"
   543     from e have e2: "e/2 > 0" by arith
   544     from C[rule_format, OF e2] obtain y where y: "y \<in> S" "y\<noteq>x" "dist y x < e/2" by blast
   545     let ?m = "min (e/2) (dist x y) "
   546     from e2 y(2) have mp: "?m > 0" by (simp add: dist_nz[THEN sym])
   547     from C[rule_format, OF mp] obtain z where z: "z \<in> S" "z\<noteq>x" "dist z x < ?m" by blast
   548     have th: "dist z y < e" using z y
   549       by (intro dist_triangle_lt [where z=x], simp)
   550     from d[rule_format, OF y(1) z(1) th] y z
   551     have False by (auto simp add: dist_commute)}
   552   then show ?thesis by (metis islimpt_approachable closed_limpt [where 'a='a])
   553 qed
   554 
   555 
   556 subsection {* Interior of a Set *}
   557 
   558 definition "interior S = {x. \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S}"
   559 
   560 lemma interior_eq: "interior S = S \<longleftrightarrow> open S"
   561   apply (simp add: set_eq_iff interior_def)
   562   apply (subst (2) open_subopen) by (safe, blast+)
   563 
   564 lemma interior_open: "open S ==> (interior S = S)" by (metis interior_eq)
   565 
   566 lemma interior_empty[simp]: "interior {} = {}" by (simp add: interior_def)
   567 
   568 lemma open_interior[simp, intro]: "open(interior S)"
   569   apply (simp add: interior_def)
   570   apply (subst open_subopen) by blast
   571 
   572 lemma interior_interior[simp]: "interior(interior S) = interior S" by (metis interior_eq open_interior)
   573 lemma interior_subset: "interior S \<subseteq> S" by (auto simp add: interior_def)
   574 lemma subset_interior: "S \<subseteq> T ==> (interior S) \<subseteq> (interior T)" by (auto simp add: interior_def)
   575 lemma interior_maximal: "T \<subseteq> S \<Longrightarrow> open T ==> T \<subseteq> (interior S)" by (auto simp add: interior_def)
   576 lemma interior_unique: "T \<subseteq> S \<Longrightarrow> open T  \<Longrightarrow> (\<forall>T'. T' \<subseteq> S \<and> open T' \<longrightarrow> T' \<subseteq> T) \<Longrightarrow> interior S = T"
   577   by (metis equalityI interior_maximal interior_subset open_interior)
   578 lemma mem_interior: "x \<in> interior S \<longleftrightarrow> (\<exists>e. 0 < e \<and> ball x e \<subseteq> S)"
   579   apply (simp add: interior_def)
   580   by (metis open_contains_ball centre_in_ball open_ball subset_trans)
   581 
   582 lemma open_subset_interior: "open S ==> S \<subseteq> interior T \<longleftrightarrow> S \<subseteq> T"
   583   by (metis interior_maximal interior_subset subset_trans)
   584 
   585 lemma interior_inter[simp]: "interior(S \<inter> T) = interior S \<inter> interior T"
   586   apply (rule equalityI, simp)
   587   apply (metis Int_lower1 Int_lower2 subset_interior)
   588   by (metis Int_mono interior_subset open_Int open_interior open_subset_interior)
   589 
   590 lemma interior_limit_point [intro]:
   591   fixes x :: "'a::perfect_space"
   592   assumes x: "x \<in> interior S" shows "x islimpt S"
   593   using x islimpt_UNIV [of x]
   594   unfolding interior_def islimpt_def
   595   apply (clarsimp, rename_tac T T')
   596   apply (drule_tac x="T \<inter> T'" in spec)
   597   apply (auto simp add: open_Int)
   598   done
   599 
   600 lemma interior_closed_Un_empty_interior:
   601   assumes cS: "closed S" and iT: "interior T = {}"
   602   shows "interior(S \<union> T) = interior S"
   603 proof
   604   show "interior S \<subseteq> interior (S\<union>T)"
   605     by (rule subset_interior, blast)
   606 next
   607   show "interior (S \<union> T) \<subseteq> interior S"
   608   proof
   609     fix x assume "x \<in> interior (S \<union> T)"
   610     then obtain R where "open R" "x \<in> R" "R \<subseteq> S \<union> T"
   611       unfolding interior_def by fast
   612     show "x \<in> interior S"
   613     proof (rule ccontr)
   614       assume "x \<notin> interior S"
   615       with `x \<in> R` `open R` obtain y where "y \<in> R - S"
   616         unfolding interior_def set_eq_iff by fast
   617       from `open R` `closed S` have "open (R - S)" by (rule open_Diff)
   618       from `R \<subseteq> S \<union> T` have "R - S \<subseteq> T" by fast
   619       from `y \<in> R - S` `open (R - S)` `R - S \<subseteq> T` `interior T = {}`
   620       show "False" unfolding interior_def by fast
   621     qed
   622   qed
   623 qed
   624 
   625 lemma interior_Times: "interior (A \<times> B) = interior A \<times> interior B"
   626 proof (rule interior_unique)
   627   show "interior A \<times> interior B \<subseteq> A \<times> B"
   628     by (intro Sigma_mono interior_subset)
   629   show "open (interior A \<times> interior B)"
   630     by (intro open_Times open_interior)
   631   show "\<forall>T. T \<subseteq> A \<times> B \<and> open T \<longrightarrow> T \<subseteq> interior A \<times> interior B"
   632     apply (simp add: open_prod_def, clarify)
   633     apply (drule (1) bspec, clarify, rename_tac C D)
   634     apply (simp add: interior_def, rule conjI)
   635     apply (rule_tac x=C in exI, clarsimp)
   636     apply (rule SigmaD1, erule subsetD, erule subsetD, erule (1) SigmaI)
   637     apply (rule_tac x=D in exI, clarsimp)
   638     apply (rule SigmaD2, erule subsetD, erule subsetD, erule (1) SigmaI)
   639     done
   640 qed
   641 
   642 
   643 subsection {* Closure of a Set *}
   644 
   645 definition "closure S = S \<union> {x | x. x islimpt S}"
   646 
   647 lemma closure_interior: "closure S = - interior (- S)"
   648 proof-
   649   { fix x
   650     have "x\<in>- interior (- S) \<longleftrightarrow> x \<in> closure S"  (is "?lhs = ?rhs")
   651     proof
   652       let ?exT = "\<lambda> y. (\<exists>T. open T \<and> y \<in> T \<and> T \<subseteq> - S)"
   653       assume "?lhs"
   654       hence *:"\<not> ?exT x"
   655         unfolding interior_def
   656         by simp
   657       { assume "\<not> ?rhs"
   658         hence False using *
   659           unfolding closure_def islimpt_def
   660           by blast
   661       }
   662       thus "?rhs"
   663         by blast
   664     next
   665       assume "?rhs" thus "?lhs"
   666         unfolding closure_def interior_def islimpt_def
   667         by blast
   668     qed
   669   }
   670   thus ?thesis
   671     by blast
   672 qed
   673 
   674 lemma interior_closure: "interior S = - (closure (- S))"
   675 proof-
   676   { fix x
   677     have "x \<in> interior S \<longleftrightarrow> x \<in> - (closure (- S))"
   678       unfolding interior_def closure_def islimpt_def
   679       by auto
   680   }
   681   thus ?thesis
   682     by blast
   683 qed
   684 
   685 lemma closed_closure[simp, intro]: "closed (closure S)"
   686 proof-
   687   have "closed (- interior (-S))" by blast
   688   thus ?thesis using closure_interior[of S] by simp
   689 qed
   690 
   691 lemma closure_hull: "closure S = closed hull S"
   692 proof-
   693   have "S \<subseteq> closure S"
   694     unfolding closure_def
   695     by blast
   696   moreover
   697   have "closed (closure S)"
   698     using closed_closure[of S]
   699     by assumption
   700   moreover
   701   { fix t
   702     assume *:"S \<subseteq> t" "closed t"
   703     { fix x
   704       assume "x islimpt S"
   705       hence "x islimpt t" using *(1)
   706         using islimpt_subset[of x, of S, of t]
   707         by blast
   708     }
   709     with * have "closure S \<subseteq> t"
   710       unfolding closure_def
   711       using closed_limpt[of t]
   712       by auto
   713   }
   714   ultimately show ?thesis
   715     using hull_unique[of S, of "closure S", of closed]
   716     by simp
   717 qed
   718 
   719 lemma closure_eq: "closure S = S \<longleftrightarrow> closed S"
   720   unfolding closure_hull
   721   using hull_eq[of closed, OF  closed_Inter, of S]
   722   by metis
   723 
   724 lemma closure_closed[simp]: "closed S \<Longrightarrow> closure S = S"
   725   using closure_eq[of S]
   726   by simp
   727 
   728 lemma closure_closure[simp]: "closure (closure S) = closure S"
   729   unfolding closure_hull
   730   using hull_hull[of closed S]
   731   by assumption
   732 
   733 lemma closure_subset: "S \<subseteq> closure S"
   734   unfolding closure_hull
   735   using hull_subset[of S closed]
   736   by assumption
   737 
   738 lemma subset_closure: "S \<subseteq> T \<Longrightarrow> closure S \<subseteq> closure T"
   739   unfolding closure_hull
   740   using hull_mono[of S T closed]
   741   by assumption
   742 
   743 lemma closure_minimal: "S \<subseteq> T \<Longrightarrow>  closed T \<Longrightarrow> closure S \<subseteq> T"
   744   using hull_minimal[of S T closed]
   745   unfolding closure_hull
   746   by simp
   747 
   748 lemma closure_unique: "S \<subseteq> T \<and> closed T \<and> (\<forall> T'. S \<subseteq> T' \<and> closed T' \<longrightarrow> T \<subseteq> T') \<Longrightarrow> closure S = T"
   749   using hull_unique[of S T closed]
   750   unfolding closure_hull
   751   by simp
   752 
   753 lemma closure_empty[simp]: "closure {} = {}"
   754   using closed_empty closure_closed[of "{}"]
   755   by simp
   756 
   757 lemma closure_univ[simp]: "closure UNIV = UNIV"
   758   using closure_closed[of UNIV]
   759   by simp
   760 
   761 lemma closure_eq_empty: "closure S = {} \<longleftrightarrow> S = {}"
   762   using closure_empty closure_subset[of S]
   763   by blast
   764 
   765 lemma closure_subset_eq: "closure S \<subseteq> S \<longleftrightarrow> closed S"
   766   using closure_eq[of S] closure_subset[of S]
   767   by simp
   768 
   769 lemma open_inter_closure_eq_empty:
   770   "open S \<Longrightarrow> (S \<inter> closure T) = {} \<longleftrightarrow> S \<inter> T = {}"
   771   using open_subset_interior[of S "- T"]
   772   using interior_subset[of "- T"]
   773   unfolding closure_interior
   774   by auto
   775 
   776 lemma open_inter_closure_subset:
   777   "open S \<Longrightarrow> (S \<inter> (closure T)) \<subseteq> closure(S \<inter> T)"
   778 proof
   779   fix x
   780   assume as: "open S" "x \<in> S \<inter> closure T"
   781   { assume *:"x islimpt T"
   782     have "x islimpt (S \<inter> T)"
   783     proof (rule islimptI)
   784       fix A
   785       assume "x \<in> A" "open A"
   786       with as have "x \<in> A \<inter> S" "open (A \<inter> S)"
   787         by (simp_all add: open_Int)
   788       with * obtain y where "y \<in> T" "y \<in> A \<inter> S" "y \<noteq> x"
   789         by (rule islimptE)
   790       hence "y \<in> S \<inter> T" "y \<in> A \<and> y \<noteq> x"
   791         by simp_all
   792       thus "\<exists>y\<in>(S \<inter> T). y \<in> A \<and> y \<noteq> x" ..
   793     qed
   794   }
   795   then show "x \<in> closure (S \<inter> T)" using as
   796     unfolding closure_def
   797     by blast
   798 qed
   799 
   800 lemma closure_complement: "closure(- S) = - interior(S)"
   801 proof-
   802   have "S = - (- S)"
   803     by auto
   804   thus ?thesis
   805     unfolding closure_interior
   806     by auto
   807 qed
   808 
   809 lemma interior_complement: "interior(- S) = - closure(S)"
   810   unfolding closure_interior
   811   by blast
   812 
   813 lemma closure_Times: "closure (A \<times> B) = closure A \<times> closure B"
   814 proof (intro closure_unique conjI)
   815   show "A \<times> B \<subseteq> closure A \<times> closure B"
   816     by (intro Sigma_mono closure_subset)
   817   show "closed (closure A \<times> closure B)"
   818     by (intro closed_Times closed_closure)
   819   show "\<forall>T. A \<times> B \<subseteq> T \<and> closed T \<longrightarrow> closure A \<times> closure B \<subseteq> T"
   820     apply (simp add: closed_def open_prod_def, clarify)
   821     apply (rule ccontr)
   822     apply (drule_tac x="(a, b)" in bspec, simp, clarify, rename_tac C D)
   823     apply (simp add: closure_interior interior_def)
   824     apply (drule_tac x=C in spec)
   825     apply (drule_tac x=D in spec)
   826     apply auto
   827     done
   828 qed
   829 
   830 
   831 subsection {* Frontier (aka boundary) *}
   832 
   833 definition "frontier S = closure S - interior S"
   834 
   835 lemma frontier_closed: "closed(frontier S)"
   836   by (simp add: frontier_def closed_Diff)
   837 
   838 lemma frontier_closures: "frontier S = (closure S) \<inter> (closure(- S))"
   839   by (auto simp add: frontier_def interior_closure)
   840 
   841 lemma frontier_straddle:
   842   fixes a :: "'a::metric_space"
   843   shows "a \<in> frontier S \<longleftrightarrow> (\<forall>e>0. (\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e))" (is "?lhs \<longleftrightarrow> ?rhs")
   844 proof
   845   assume "?lhs"
   846   { fix e::real
   847     assume "e > 0"
   848     let ?rhse = "(\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e)"
   849     { assume "a\<in>S"
   850       have "\<exists>x\<in>S. dist a x < e" using `e>0` `a\<in>S` by(rule_tac x=a in bexI) auto
   851       moreover have "\<exists>x. x \<notin> S \<and> dist a x < e" using `?lhs` `a\<in>S`
   852         unfolding frontier_closures closure_def islimpt_def using `e>0`
   853         by (auto, erule_tac x="ball a e" in allE, auto)
   854       ultimately have ?rhse by auto
   855     }
   856     moreover
   857     { assume "a\<notin>S"
   858       hence ?rhse using `?lhs`
   859         unfolding frontier_closures closure_def islimpt_def
   860         using open_ball[of a e] `e > 0`
   861           by simp (metis centre_in_ball mem_ball open_ball) 
   862     }
   863     ultimately have ?rhse by auto
   864   }
   865   thus ?rhs by auto
   866 next
   867   assume ?rhs
   868   moreover
   869   { fix T assume "a\<notin>S" and
   870     as:"\<forall>e>0. (\<exists>x\<in>S. dist a x < e) \<and> (\<exists>x. x \<notin> S \<and> dist a x < e)" "a \<notin> S" "a \<in> T" "open T"
   871     from `open T` `a \<in> T` have "\<exists>e>0. ball a e \<subseteq> T" unfolding open_contains_ball[of T] by auto
   872     then obtain e where "e>0" "ball a e \<subseteq> T" by auto
   873     then obtain y where y:"y\<in>S" "dist a y < e"  using as(1) by auto
   874     have "\<exists>y\<in>S. y \<in> T \<and> y \<noteq> a"
   875       using `dist a y < e` `ball a e \<subseteq> T` unfolding ball_def using `y\<in>S` `a\<notin>S` by auto
   876   }
   877   hence "a \<in> closure S" unfolding closure_def islimpt_def using `?rhs` by auto
   878   moreover
   879   { fix T assume "a \<in> T"  "open T" "a\<in>S"
   880     then obtain e where "e>0" and balle: "ball a e \<subseteq> T" unfolding open_contains_ball using `?rhs` by auto
   881     obtain x where "x \<notin> S" "dist a x < e" using `?rhs` using `e>0` by auto
   882     hence "\<exists>y\<in>- S. y \<in> T \<and> y \<noteq> a" using balle `a\<in>S` unfolding ball_def by (rule_tac x=x in bexI)auto
   883   }
   884   hence "a islimpt (- S) \<or> a\<notin>S" unfolding islimpt_def by auto
   885   ultimately show ?lhs unfolding frontier_closures using closure_def[of "- S"] by auto
   886 qed
   887 
   888 lemma frontier_subset_closed: "closed S \<Longrightarrow> frontier S \<subseteq> S"
   889   by (metis frontier_def closure_closed Diff_subset)
   890 
   891 lemma frontier_empty[simp]: "frontier {} = {}"
   892   by (simp add: frontier_def)
   893 
   894 lemma frontier_subset_eq: "frontier S \<subseteq> S \<longleftrightarrow> closed S"
   895 proof-
   896   { assume "frontier S \<subseteq> S"
   897     hence "closure S \<subseteq> S" using interior_subset unfolding frontier_def by auto
   898     hence "closed S" using closure_subset_eq by auto
   899   }
   900   thus ?thesis using frontier_subset_closed[of S] ..
   901 qed
   902 
   903 lemma frontier_complement: "frontier(- S) = frontier S"
   904   by (auto simp add: frontier_def closure_complement interior_complement)
   905 
   906 lemma frontier_disjoint_eq: "frontier S \<inter> S = {} \<longleftrightarrow> open S"
   907   using frontier_complement frontier_subset_eq[of "- S"]
   908   unfolding open_closed by auto
   909 
   910 
   911 subsection {* Filters and the ``eventually true'' quantifier *}
   912 
   913 definition
   914   at_infinity :: "'a::real_normed_vector filter" where
   915   "at_infinity = Abs_filter (\<lambda>P. \<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x)"
   916 
   917 definition
   918   indirection :: "'a::real_normed_vector \<Rightarrow> 'a \<Rightarrow> 'a filter"
   919     (infixr "indirection" 70) where
   920   "a indirection v = (at a) within {b. \<exists>c\<ge>0. b - a = scaleR c v}"
   921 
   922 text{* Prove That They are all filters. *}
   923 
   924 lemma eventually_at_infinity:
   925   "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. norm x >= b \<longrightarrow> P x)"
   926 unfolding at_infinity_def
   927 proof (rule eventually_Abs_filter, rule is_filter.intro)
   928   fix P Q :: "'a \<Rightarrow> bool"
   929   assume "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<exists>s. \<forall>x. s \<le> norm x \<longrightarrow> Q x"
   930   then obtain r s where
   931     "\<forall>x. r \<le> norm x \<longrightarrow> P x" and "\<forall>x. s \<le> norm x \<longrightarrow> Q x" by auto
   932   then have "\<forall>x. max r s \<le> norm x \<longrightarrow> P x \<and> Q x" by simp
   933   then show "\<exists>r. \<forall>x. r \<le> norm x \<longrightarrow> P x \<and> Q x" ..
   934 qed auto
   935 
   936 text {* Identify Trivial limits, where we can't approach arbitrarily closely. *}
   937 
   938 lemma trivial_limit_within:
   939   shows "trivial_limit (at a within S) \<longleftrightarrow> \<not> a islimpt S"
   940 proof
   941   assume "trivial_limit (at a within S)"
   942   thus "\<not> a islimpt S"
   943     unfolding trivial_limit_def
   944     unfolding eventually_within eventually_at_topological
   945     unfolding islimpt_def
   946     apply (clarsimp simp add: set_eq_iff)
   947     apply (rename_tac T, rule_tac x=T in exI)
   948     apply (clarsimp, drule_tac x=y in bspec, simp_all)
   949     done
   950 next
   951   assume "\<not> a islimpt S"
   952   thus "trivial_limit (at a within S)"
   953     unfolding trivial_limit_def
   954     unfolding eventually_within eventually_at_topological
   955     unfolding islimpt_def
   956     apply clarsimp
   957     apply (rule_tac x=T in exI)
   958     apply auto
   959     done
   960 qed
   961 
   962 lemma trivial_limit_at_iff: "trivial_limit (at a) \<longleftrightarrow> \<not> a islimpt UNIV"
   963   using trivial_limit_within [of a UNIV]
   964   by (simp add: within_UNIV)
   965 
   966 lemma trivial_limit_at:
   967   fixes a :: "'a::perfect_space"
   968   shows "\<not> trivial_limit (at a)"
   969   by (simp add: trivial_limit_at_iff)
   970 
   971 lemma trivial_limit_at_infinity:
   972   "\<not> trivial_limit (at_infinity :: ('a::{real_normed_vector,perfect_space}) filter)"
   973   unfolding trivial_limit_def eventually_at_infinity
   974   apply clarsimp
   975   apply (subgoal_tac "\<exists>x::'a. x \<noteq> 0", clarify)
   976    apply (rule_tac x="scaleR (b / norm x) x" in exI, simp)
   977   apply (cut_tac islimpt_UNIV [of "0::'a", unfolded islimpt_def])
   978   apply (drule_tac x=UNIV in spec, simp)
   979   done
   980 
   981 text {* Some property holds "sufficiently close" to the limit point. *}
   982 
   983 lemma eventually_at: (* FIXME: this replaces Limits.eventually_at *)
   984   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
   985 unfolding eventually_at dist_nz by auto
   986 
   987 lemma eventually_within: "eventually P (at a within S) \<longleftrightarrow>
   988         (\<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
   989 unfolding eventually_within eventually_at dist_nz by auto
   990 
   991 lemma eventually_within_le: "eventually P (at a within S) \<longleftrightarrow>
   992         (\<exists>d>0. \<forall>x\<in>S. 0 < dist x a \<and> dist x a <= d \<longrightarrow> P x)" (is "?lhs = ?rhs")
   993 unfolding eventually_within
   994 by auto (metis Rats_dense_in_nn_real order_le_less_trans order_refl) 
   995 
   996 lemma eventually_happens: "eventually P net ==> trivial_limit net \<or> (\<exists>x. P x)"
   997   unfolding trivial_limit_def
   998   by (auto elim: eventually_rev_mp)
   999 
  1000 lemma trivial_limit_eventually: "trivial_limit net \<Longrightarrow> eventually P net"
  1001   unfolding trivial_limit_def by (auto elim: eventually_rev_mp)
  1002 
  1003 lemma trivial_limit_eq: "trivial_limit net \<longleftrightarrow> (\<forall>P. eventually P net)"
  1004   by (simp add: filter_eq_iff)
  1005 
  1006 text{* Combining theorems for "eventually" *}
  1007 
  1008 lemma eventually_rev_mono:
  1009   "eventually P net \<Longrightarrow> (\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually Q net"
  1010 using eventually_mono [of P Q] by fast
  1011 
  1012 lemma not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> ~(trivial_limit net) ==> ~(eventually (\<lambda>x. P x) net)"
  1013   by (simp add: eventually_False)
  1014 
  1015 
  1016 subsection {* Limits *}
  1017 
  1018 text{* Notation Lim to avoid collition with lim defined in analysis *}
  1019 
  1020 definition Lim :: "'a filter \<Rightarrow> ('a \<Rightarrow> 'b::t2_space) \<Rightarrow> 'b"
  1021   where "Lim A f = (THE l. (f ---> l) A)"
  1022 
  1023 lemma Lim:
  1024  "(f ---> l) net \<longleftrightarrow>
  1025         trivial_limit net \<or>
  1026         (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) net)"
  1027   unfolding tendsto_iff trivial_limit_eq by auto
  1028 
  1029 text{* Show that they yield usual definitions in the various cases. *}
  1030 
  1031 lemma Lim_within_le: "(f ---> l)(at a within S) \<longleftrightarrow>
  1032            (\<forall>e>0. \<exists>d>0. \<forall>x\<in>S. 0 < dist x a  \<and> dist x a  <= d \<longrightarrow> dist (f x) l < e)"
  1033   by (auto simp add: tendsto_iff eventually_within_le)
  1034 
  1035 lemma Lim_within: "(f ---> l) (at a within S) \<longleftrightarrow>
  1036         (\<forall>e >0. \<exists>d>0. \<forall>x \<in> S. 0 < dist x a  \<and> dist x a  < d  \<longrightarrow> dist (f x) l < e)"
  1037   by (auto simp add: tendsto_iff eventually_within)
  1038 
  1039 lemma Lim_at: "(f ---> l) (at a) \<longleftrightarrow>
  1040         (\<forall>e >0. \<exists>d>0. \<forall>x. 0 < dist x a  \<and> dist x a  < d  \<longrightarrow> dist (f x) l < e)"
  1041   by (auto simp add: tendsto_iff eventually_at)
  1042 
  1043 lemma Lim_at_iff_LIM: "(f ---> l) (at a) \<longleftrightarrow> f -- a --> l"
  1044   unfolding Lim_at LIM_def by (simp only: zero_less_dist_iff)
  1045 
  1046 lemma Lim_at_infinity:
  1047   "(f ---> l) at_infinity \<longleftrightarrow> (\<forall>e>0. \<exists>b. \<forall>x. norm x >= b \<longrightarrow> dist (f x) l < e)"
  1048   by (auto simp add: tendsto_iff eventually_at_infinity)
  1049 
  1050 lemma Lim_sequentially:
  1051  "(S ---> l) sequentially \<longleftrightarrow>
  1052           (\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (S n) l < e)"
  1053   by (rule LIMSEQ_def) (* FIXME: redundant *)
  1054 
  1055 lemma Lim_eventually: "eventually (\<lambda>x. f x = l) net \<Longrightarrow> (f ---> l) net"
  1056   by (rule topological_tendstoI, auto elim: eventually_rev_mono)
  1057 
  1058 text{* The expected monotonicity property. *}
  1059 
  1060 lemma Lim_within_empty: "(f ---> l) (net within {})"
  1061   unfolding tendsto_def Limits.eventually_within by simp
  1062 
  1063 lemma Lim_within_subset: "(f ---> l) (net within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (net within T)"
  1064   unfolding tendsto_def Limits.eventually_within
  1065   by (auto elim!: eventually_elim1)
  1066 
  1067 lemma Lim_Un: assumes "(f ---> l) (net within S)" "(f ---> l) (net within T)"
  1068   shows "(f ---> l) (net within (S \<union> T))"
  1069   using assms unfolding tendsto_def Limits.eventually_within
  1070   apply clarify
  1071   apply (drule spec, drule (1) mp, drule (1) mp)
  1072   apply (drule spec, drule (1) mp, drule (1) mp)
  1073   apply (auto elim: eventually_elim2)
  1074   done
  1075 
  1076 lemma Lim_Un_univ:
  1077  "(f ---> l) (net within S) \<Longrightarrow> (f ---> l) (net within T) \<Longrightarrow>  S \<union> T = UNIV
  1078         ==> (f ---> l) net"
  1079   by (metis Lim_Un within_UNIV)
  1080 
  1081 text{* Interrelations between restricted and unrestricted limits. *}
  1082 
  1083 lemma Lim_at_within: "(f ---> l) net ==> (f ---> l)(net within S)"
  1084   (* FIXME: rename *)
  1085   unfolding tendsto_def Limits.eventually_within
  1086   apply (clarify, drule spec, drule (1) mp, drule (1) mp)
  1087   by (auto elim!: eventually_elim1)
  1088 
  1089 lemma eventually_within_interior:
  1090   assumes "x \<in> interior S"
  1091   shows "eventually P (at x within S) \<longleftrightarrow> eventually P (at x)" (is "?lhs = ?rhs")
  1092 proof-
  1093   from assms obtain T where T: "open T" "x \<in> T" "T \<subseteq> S"
  1094     unfolding interior_def by fast
  1095   { assume "?lhs"
  1096     then obtain A where "open A" "x \<in> A" "\<forall>y\<in>A. y \<noteq> x \<longrightarrow> y \<in> S \<longrightarrow> P y"
  1097       unfolding Limits.eventually_within Limits.eventually_at_topological
  1098       by auto
  1099     with T have "open (A \<inter> T)" "x \<in> A \<inter> T" "\<forall>y\<in>(A \<inter> T). y \<noteq> x \<longrightarrow> P y"
  1100       by auto
  1101     then have "?rhs"
  1102       unfolding Limits.eventually_at_topological by auto
  1103   } moreover
  1104   { assume "?rhs" hence "?lhs"
  1105       unfolding Limits.eventually_within
  1106       by (auto elim: eventually_elim1)
  1107   } ultimately
  1108   show "?thesis" ..
  1109 qed
  1110 
  1111 lemma at_within_interior:
  1112   "x \<in> interior S \<Longrightarrow> at x within S = at x"
  1113   by (simp add: filter_eq_iff eventually_within_interior)
  1114 
  1115 lemma at_within_open:
  1116   "\<lbrakk>x \<in> S; open S\<rbrakk> \<Longrightarrow> at x within S = at x"
  1117   by (simp only: at_within_interior interior_open)
  1118 
  1119 lemma Lim_within_open:
  1120   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1121   assumes"a \<in> S" "open S"
  1122   shows "(f ---> l)(at a within S) \<longleftrightarrow> (f ---> l)(at a)"
  1123   using assms by (simp only: at_within_open)
  1124 
  1125 lemma Lim_within_LIMSEQ:
  1126   fixes a :: real and L :: "'a::metric_space"
  1127   assumes "\<forall>S. (\<forall>n. S n \<noteq> a \<and> S n \<in> T) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
  1128   shows "(X ---> L) (at a within T)"
  1129 proof (rule ccontr)
  1130   assume "\<not> (X ---> L) (at a within T)"
  1131   hence "\<exists>r>0. \<forall>s>0. \<exists>x\<in>T. x \<noteq> a \<and> \<bar>x - a\<bar> < s \<and> r \<le> dist (X x) L"
  1132     unfolding tendsto_iff eventually_within dist_norm by (simp add: not_less[symmetric])
  1133   then obtain r where r: "r > 0" "\<And>s. s > 0 \<Longrightarrow> \<exists>x\<in>T-{a}. \<bar>x - a\<bar> < s \<and> dist (X x) L \<ge> r" by blast
  1134 
  1135   let ?F = "\<lambda>n::nat. SOME x. x \<in> T \<and> x \<noteq> a \<and> \<bar>x - a\<bar> < inverse (real (Suc n)) \<and> dist (X x) L \<ge> r"
  1136   have "\<And>n. \<exists>x. x \<in> T \<and> x \<noteq> a \<and> \<bar>x - a\<bar> < inverse (real (Suc n)) \<and> dist (X x) L \<ge> r"
  1137     using r by (simp add: Bex_def)
  1138   hence F: "\<And>n. ?F n \<in> T \<and> ?F n \<noteq> a \<and> \<bar>?F n - a\<bar> < inverse (real (Suc n)) \<and> dist (X (?F n)) L \<ge> r"
  1139     by (rule someI_ex)
  1140   hence F1: "\<And>n. ?F n \<in> T \<and> ?F n \<noteq> a"
  1141     and F2: "\<And>n. \<bar>?F n - a\<bar> < inverse (real (Suc n))"
  1142     and F3: "\<And>n. dist (X (?F n)) L \<ge> r"
  1143     by fast+
  1144 
  1145   have "?F ----> a"
  1146   proof (rule LIMSEQ_I, unfold real_norm_def)
  1147       fix e::real
  1148       assume "0 < e"
  1149         (* choose no such that inverse (real (Suc n)) < e *)
  1150       then have "\<exists>no. inverse (real (Suc no)) < e" by (rule reals_Archimedean)
  1151       then obtain m where nodef: "inverse (real (Suc m)) < e" by auto
  1152       show "\<exists>no. \<forall>n. no \<le> n --> \<bar>?F n - a\<bar> < e"
  1153       proof (intro exI allI impI)
  1154         fix n
  1155         assume mlen: "m \<le> n"
  1156         have "\<bar>?F n - a\<bar> < inverse (real (Suc n))"
  1157           by (rule F2)
  1158         also have "inverse (real (Suc n)) \<le> inverse (real (Suc m))"
  1159           using mlen by auto
  1160         also from nodef have
  1161           "inverse (real (Suc m)) < e" .
  1162         finally show "\<bar>?F n - a\<bar> < e" .
  1163       qed
  1164   qed
  1165   moreover note `\<forall>S. (\<forall>n. S n \<noteq> a \<and> S n \<in> T) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L`
  1166   ultimately have "(\<lambda>n. X (?F n)) ----> L" using F1 by simp
  1167   
  1168   moreover have "\<not> ((\<lambda>n. X (?F n)) ----> L)"
  1169   proof -
  1170     {
  1171       fix no::nat
  1172       obtain n where "n = no + 1" by simp
  1173       then have nolen: "no \<le> n" by simp
  1174         (* We prove this by showing that for any m there is an n\<ge>m such that |X (?F n) - L| \<ge> r *)
  1175       have "dist (X (?F n)) L \<ge> r"
  1176         by (rule F3)
  1177       with nolen have "\<exists>n. no \<le> n \<and> dist (X (?F n)) L \<ge> r" by fast
  1178     }
  1179     then have "(\<forall>no. \<exists>n. no \<le> n \<and> dist (X (?F n)) L \<ge> r)" by simp
  1180     with r have "\<exists>e>0. (\<forall>no. \<exists>n. no \<le> n \<and> dist (X (?F n)) L \<ge> e)" by auto
  1181     thus ?thesis by (unfold LIMSEQ_def, auto simp add: not_less)
  1182   qed
  1183   ultimately show False by simp
  1184 qed
  1185 
  1186 lemma Lim_right_bound:
  1187   fixes f :: "real \<Rightarrow> real"
  1188   assumes mono: "\<And>a b. a \<in> I \<Longrightarrow> b \<in> I \<Longrightarrow> x < a \<Longrightarrow> a \<le> b \<Longrightarrow> f a \<le> f b"
  1189   assumes bnd: "\<And>a. a \<in> I \<Longrightarrow> x < a \<Longrightarrow> K \<le> f a"
  1190   shows "(f ---> Inf (f ` ({x<..} \<inter> I))) (at x within ({x<..} \<inter> I))"
  1191 proof cases
  1192   assume "{x<..} \<inter> I = {}" then show ?thesis by (simp add: Lim_within_empty)
  1193 next
  1194   assume [simp]: "{x<..} \<inter> I \<noteq> {}"
  1195   show ?thesis
  1196   proof (rule Lim_within_LIMSEQ, safe)
  1197     fix S assume S: "\<forall>n. S n \<noteq> x \<and> S n \<in> {x <..} \<inter> I" "S ----> x"
  1198     
  1199     show "(\<lambda>n. f (S n)) ----> Inf (f ` ({x<..} \<inter> I))"
  1200     proof (rule LIMSEQ_I, rule ccontr)
  1201       fix r :: real assume "0 < r"
  1202       with Inf_close[of "f ` ({x<..} \<inter> I)" r]
  1203       obtain y where y: "x < y" "y \<in> I" "f y < Inf (f ` ({x <..} \<inter> I)) + r" by auto
  1204       from `x < y` have "0 < y - x" by auto
  1205       from S(2)[THEN LIMSEQ_D, OF this]
  1206       obtain N where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>S n - x\<bar> < y - x" by auto
  1207       
  1208       assume "\<not> (\<exists>N. \<forall>n\<ge>N. norm (f (S n) - Inf (f ` ({x<..} \<inter> I))) < r)"
  1209       moreover have "\<And>n. Inf (f ` ({x<..} \<inter> I)) \<le> f (S n)"
  1210         using S bnd by (intro Inf_lower[where z=K]) auto
  1211       ultimately obtain n where n: "N \<le> n" "r + Inf (f ` ({x<..} \<inter> I)) \<le> f (S n)"
  1212         by (auto simp: not_less field_simps)
  1213       with N[OF n(1)] mono[OF _ `y \<in> I`, of "S n"] S(1)[THEN spec, of n] y
  1214       show False by auto
  1215     qed
  1216   qed
  1217 qed
  1218 
  1219 text{* Another limit point characterization. *}
  1220 
  1221 lemma islimpt_sequential:
  1222   fixes x :: "'a::metric_space"
  1223   shows "x islimpt S \<longleftrightarrow> (\<exists>f. (\<forall>n::nat. f n \<in> S -{x}) \<and> (f ---> x) sequentially)"
  1224     (is "?lhs = ?rhs")
  1225 proof
  1226   assume ?lhs
  1227   then obtain f where f:"\<forall>y. y>0 \<longrightarrow> f y \<in> S \<and> f y \<noteq> x \<and> dist (f y) x < y"
  1228     unfolding islimpt_approachable using choice[of "\<lambda>e y. e>0 \<longrightarrow> y\<in>S \<and> y\<noteq>x \<and> dist y x < e"] by auto
  1229   { fix n::nat
  1230     have "f (inverse (real n + 1)) \<in> S - {x}" using f by auto
  1231   }
  1232   moreover
  1233   { fix e::real assume "e>0"
  1234     hence "\<exists>N::nat. inverse (real (N + 1)) < e" using real_arch_inv[of e] apply (auto simp add: Suc_pred') apply(rule_tac x="n - 1" in exI) by auto
  1235     then obtain N::nat where "inverse (real (N + 1)) < e" by auto
  1236     hence "\<forall>n\<ge>N. inverse (real n + 1) < e" by (auto, metis Suc_le_mono le_SucE less_imp_inverse_less nat_le_real_less order_less_trans real_of_nat_Suc real_of_nat_Suc_gt_zero)
  1237     moreover have "\<forall>n\<ge>N. dist (f (inverse (real n + 1))) x < (inverse (real n + 1))" using f `e>0` by auto
  1238     ultimately have "\<exists>N::nat. \<forall>n\<ge>N. dist (f (inverse (real n + 1))) x < e" apply(rule_tac x=N in exI) apply auto apply(erule_tac x=n in allE)+ by auto
  1239   }
  1240   hence " ((\<lambda>n. f (inverse (real n + 1))) ---> x) sequentially"
  1241     unfolding Lim_sequentially using f by auto
  1242   ultimately show ?rhs apply (rule_tac x="(\<lambda>n::nat. f (inverse (real n + 1)))" in exI) by auto
  1243 next
  1244   assume ?rhs
  1245   then obtain f::"nat\<Rightarrow>'a"  where f:"(\<forall>n. f n \<in> S - {x})" "(\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (f n) x < e)" unfolding Lim_sequentially by auto
  1246   { fix e::real assume "e>0"
  1247     then obtain N where "dist (f N) x < e" using f(2) by auto
  1248     moreover have "f N\<in>S" "f N \<noteq> x" using f(1) by auto
  1249     ultimately have "\<exists>x'\<in>S. x' \<noteq> x \<and> dist x' x < e" by auto
  1250   }
  1251   thus ?lhs unfolding islimpt_approachable by auto
  1252 qed
  1253 
  1254 lemma Lim_inv: (* TODO: delete *)
  1255   fixes f :: "'a \<Rightarrow> real" and A :: "'a filter"
  1256   assumes "(f ---> l) A" and "l \<noteq> 0"
  1257   shows "((inverse o f) ---> inverse l) A"
  1258   unfolding o_def using assms by (rule tendsto_inverse)
  1259 
  1260 lemma Lim_null:
  1261   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1262   shows "(f ---> l) net \<longleftrightarrow> ((\<lambda>x. f(x) - l) ---> 0) net"
  1263   by (simp add: Lim dist_norm)
  1264 
  1265 lemma Lim_null_comparison:
  1266   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1267   assumes "eventually (\<lambda>x. norm (f x) \<le> g x) net" "(g ---> 0) net"
  1268   shows "(f ---> 0) net"
  1269 proof (rule metric_tendsto_imp_tendsto)
  1270   show "(g ---> 0) net" by fact
  1271   show "eventually (\<lambda>x. dist (f x) 0 \<le> dist (g x) 0) net"
  1272     using assms(1) by (rule eventually_elim1, simp add: dist_norm)
  1273 qed
  1274 
  1275 lemma Lim_transform_bound:
  1276   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1277   fixes g :: "'a \<Rightarrow> 'c::real_normed_vector"
  1278   assumes "eventually (\<lambda>n. norm(f n) <= norm(g n)) net"  "(g ---> 0) net"
  1279   shows "(f ---> 0) net"
  1280   using assms(1) tendsto_norm_zero [OF assms(2)]
  1281   by (rule Lim_null_comparison)
  1282 
  1283 text{* Deducing things about the limit from the elements. *}
  1284 
  1285 lemma Lim_in_closed_set:
  1286   assumes "closed S" "eventually (\<lambda>x. f(x) \<in> S) net" "\<not>(trivial_limit net)" "(f ---> l) net"
  1287   shows "l \<in> S"
  1288 proof (rule ccontr)
  1289   assume "l \<notin> S"
  1290   with `closed S` have "open (- S)" "l \<in> - S"
  1291     by (simp_all add: open_Compl)
  1292   with assms(4) have "eventually (\<lambda>x. f x \<in> - S) net"
  1293     by (rule topological_tendstoD)
  1294   with assms(2) have "eventually (\<lambda>x. False) net"
  1295     by (rule eventually_elim2) simp
  1296   with assms(3) show "False"
  1297     by (simp add: eventually_False)
  1298 qed
  1299 
  1300 text{* Need to prove closed(cball(x,e)) before deducing this as a corollary. *}
  1301 
  1302 lemma Lim_dist_ubound:
  1303   assumes "\<not>(trivial_limit net)" "(f ---> l) net" "eventually (\<lambda>x. dist a (f x) <= e) net"
  1304   shows "dist a l <= e"
  1305 proof-
  1306   have "dist a l \<in> {..e}"
  1307   proof (rule Lim_in_closed_set)
  1308     show "closed {..e}" by simp
  1309     show "eventually (\<lambda>x. dist a (f x) \<in> {..e}) net" by (simp add: assms)
  1310     show "\<not> trivial_limit net" by fact
  1311     show "((\<lambda>x. dist a (f x)) ---> dist a l) net" by (intro tendsto_intros assms)
  1312   qed
  1313   thus ?thesis by simp
  1314 qed
  1315 
  1316 lemma Lim_norm_ubound:
  1317   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1318   assumes "\<not>(trivial_limit net)" "(f ---> l) net" "eventually (\<lambda>x. norm(f x) <= e) net"
  1319   shows "norm(l) <= e"
  1320 proof-
  1321   have "norm l \<in> {..e}"
  1322   proof (rule Lim_in_closed_set)
  1323     show "closed {..e}" by simp
  1324     show "eventually (\<lambda>x. norm (f x) \<in> {..e}) net" by (simp add: assms)
  1325     show "\<not> trivial_limit net" by fact
  1326     show "((\<lambda>x. norm (f x)) ---> norm l) net" by (intro tendsto_intros assms)
  1327   qed
  1328   thus ?thesis by simp
  1329 qed
  1330 
  1331 lemma Lim_norm_lbound:
  1332   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  1333   assumes "\<not> (trivial_limit net)"  "(f ---> l) net"  "eventually (\<lambda>x. e <= norm(f x)) net"
  1334   shows "e \<le> norm l"
  1335 proof-
  1336   have "norm l \<in> {e..}"
  1337   proof (rule Lim_in_closed_set)
  1338     show "closed {e..}" by simp
  1339     show "eventually (\<lambda>x. norm (f x) \<in> {e..}) net" by (simp add: assms)
  1340     show "\<not> trivial_limit net" by fact
  1341     show "((\<lambda>x. norm (f x)) ---> norm l) net" by (intro tendsto_intros assms)
  1342   qed
  1343   thus ?thesis by simp
  1344 qed
  1345 
  1346 text{* Uniqueness of the limit, when nontrivial. *}
  1347 
  1348 lemma tendsto_Lim:
  1349   fixes f :: "'a \<Rightarrow> 'b::t2_space"
  1350   shows "~(trivial_limit net) \<Longrightarrow> (f ---> l) net ==> Lim net f = l"
  1351   unfolding Lim_def using tendsto_unique[of net f] by auto
  1352 
  1353 text{* Limit under bilinear function *}
  1354 
  1355 lemma Lim_bilinear:
  1356   assumes "(f ---> l) net" and "(g ---> m) net" and "bounded_bilinear h"
  1357   shows "((\<lambda>x. h (f x) (g x)) ---> (h l m)) net"
  1358 using `bounded_bilinear h` `(f ---> l) net` `(g ---> m) net`
  1359 by (rule bounded_bilinear.tendsto)
  1360 
  1361 text{* These are special for limits out of the same vector space. *}
  1362 
  1363 lemma Lim_within_id: "(id ---> a) (at a within s)"
  1364   unfolding tendsto_def Limits.eventually_within eventually_at_topological
  1365   by auto
  1366 
  1367 lemma Lim_at_id: "(id ---> a) (at a)"
  1368 apply (subst within_UNIV[symmetric]) by (simp add: Lim_within_id)
  1369 
  1370 lemma Lim_at_zero:
  1371   fixes a :: "'a::real_normed_vector"
  1372   fixes l :: "'b::topological_space"
  1373   shows "(f ---> l) (at a) \<longleftrightarrow> ((\<lambda>x. f(a + x)) ---> l) (at 0)" (is "?lhs = ?rhs")
  1374   using LIM_offset_zero LIM_offset_zero_cancel ..
  1375 
  1376 text{* It's also sometimes useful to extract the limit point from the filter. *}
  1377 
  1378 definition
  1379   netlimit :: "'a::t2_space filter \<Rightarrow> 'a" where
  1380   "netlimit net = (SOME a. ((\<lambda>x. x) ---> a) net)"
  1381 
  1382 lemma netlimit_within:
  1383   assumes "\<not> trivial_limit (at a within S)"
  1384   shows "netlimit (at a within S) = a"
  1385 unfolding netlimit_def
  1386 apply (rule some_equality)
  1387 apply (rule Lim_at_within)
  1388 apply (rule LIM_ident)
  1389 apply (erule tendsto_unique [OF assms])
  1390 apply (rule Lim_at_within)
  1391 apply (rule LIM_ident)
  1392 done
  1393 
  1394 lemma netlimit_at:
  1395   fixes a :: "'a::{perfect_space,t2_space}"
  1396   shows "netlimit (at a) = a"
  1397   apply (subst within_UNIV[symmetric])
  1398   using netlimit_within[of a UNIV]
  1399   by (simp add: trivial_limit_at within_UNIV)
  1400 
  1401 lemma lim_within_interior:
  1402   "x \<in> interior S \<Longrightarrow> (f ---> l) (at x within S) \<longleftrightarrow> (f ---> l) (at x)"
  1403   by (simp add: at_within_interior)
  1404 
  1405 lemma netlimit_within_interior:
  1406   fixes x :: "'a::{t2_space,perfect_space}"
  1407   assumes "x \<in> interior S"
  1408   shows "netlimit (at x within S) = x"
  1409 using assms by (simp add: at_within_interior netlimit_at)
  1410 
  1411 text{* Transformation of limit. *}
  1412 
  1413 lemma Lim_transform:
  1414   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
  1415   assumes "((\<lambda>x. f x - g x) ---> 0) net" "(f ---> l) net"
  1416   shows "(g ---> l) net"
  1417   using tendsto_diff [OF assms(2) assms(1)] by simp
  1418 
  1419 lemma Lim_transform_eventually:
  1420   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f ---> l) net \<Longrightarrow> (g ---> l) net"
  1421   apply (rule topological_tendstoI)
  1422   apply (drule (2) topological_tendstoD)
  1423   apply (erule (1) eventually_elim2, simp)
  1424   done
  1425 
  1426 lemma Lim_transform_within:
  1427   assumes "0 < d" and "\<forall>x'\<in>S. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1428   and "(f ---> l) (at x within S)"
  1429   shows "(g ---> l) (at x within S)"
  1430 proof (rule Lim_transform_eventually)
  1431   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1432     unfolding eventually_within
  1433     using assms(1,2) by auto
  1434   show "(f ---> l) (at x within S)" by fact
  1435 qed
  1436 
  1437 lemma Lim_transform_at:
  1438   assumes "0 < d" and "\<forall>x'. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1439   and "(f ---> l) (at x)"
  1440   shows "(g ---> l) (at x)"
  1441 proof (rule Lim_transform_eventually)
  1442   show "eventually (\<lambda>x. f x = g x) (at x)"
  1443     unfolding eventually_at
  1444     using assms(1,2) by auto
  1445   show "(f ---> l) (at x)" by fact
  1446 qed
  1447 
  1448 text{* Common case assuming being away from some crucial point like 0. *}
  1449 
  1450 lemma Lim_transform_away_within:
  1451   fixes a b :: "'a::t1_space"
  1452   assumes "a \<noteq> b" and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1453   and "(f ---> l) (at a within S)"
  1454   shows "(g ---> l) (at a within S)"
  1455 proof (rule Lim_transform_eventually)
  1456   show "(f ---> l) (at a within S)" by fact
  1457   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1458     unfolding Limits.eventually_within eventually_at_topological
  1459     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1460 qed
  1461 
  1462 lemma Lim_transform_away_at:
  1463   fixes a b :: "'a::t1_space"
  1464   assumes ab: "a\<noteq>b" and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1465   and fl: "(f ---> l) (at a)"
  1466   shows "(g ---> l) (at a)"
  1467   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl
  1468   by (auto simp add: within_UNIV)
  1469 
  1470 text{* Alternatively, within an open set. *}
  1471 
  1472 lemma Lim_transform_within_open:
  1473   assumes "open S" and "a \<in> S" and "\<forall>x\<in>S. x \<noteq> a \<longrightarrow> f x = g x"
  1474   and "(f ---> l) (at a)"
  1475   shows "(g ---> l) (at a)"
  1476 proof (rule Lim_transform_eventually)
  1477   show "eventually (\<lambda>x. f x = g x) (at a)"
  1478     unfolding eventually_at_topological
  1479     using assms(1,2,3) by auto
  1480   show "(f ---> l) (at a)" by fact
  1481 qed
  1482 
  1483 text{* A congruence rule allowing us to transform limits assuming not at point. *}
  1484 
  1485 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1486 
  1487 lemma Lim_cong_within(*[cong add]*):
  1488   assumes "a = b" "x = y" "S = T"
  1489   assumes "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1490   shows "(f ---> x) (at a within S) \<longleftrightarrow> (g ---> y) (at b within T)"
  1491   unfolding tendsto_def Limits.eventually_within eventually_at_topological
  1492   using assms by simp
  1493 
  1494 lemma Lim_cong_at(*[cong add]*):
  1495   assumes "a = b" "x = y"
  1496   assumes "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1497   shows "((\<lambda>x. f x) ---> x) (at a) \<longleftrightarrow> ((g ---> y) (at a))"
  1498   unfolding tendsto_def eventually_at_topological
  1499   using assms by simp
  1500 
  1501 text{* Useful lemmas on closure and set of possible sequential limits.*}
  1502 
  1503 lemma closure_sequential:
  1504   fixes l :: "'a::metric_space"
  1505   shows "l \<in> closure S \<longleftrightarrow> (\<exists>x. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially)" (is "?lhs = ?rhs")
  1506 proof
  1507   assume "?lhs" moreover
  1508   { assume "l \<in> S"
  1509     hence "?rhs" using tendsto_const[of l sequentially] by auto
  1510   } moreover
  1511   { assume "l islimpt S"
  1512     hence "?rhs" unfolding islimpt_sequential by auto
  1513   } ultimately
  1514   show "?rhs" unfolding closure_def by auto
  1515 next
  1516   assume "?rhs"
  1517   thus "?lhs" unfolding closure_def unfolding islimpt_sequential by auto
  1518 qed
  1519 
  1520 lemma closed_sequential_limits:
  1521   fixes S :: "'a::metric_space set"
  1522   shows "closed S \<longleftrightarrow> (\<forall>x l. (\<forall>n. x n \<in> S) \<and> (x ---> l) sequentially \<longrightarrow> l \<in> S)"
  1523   unfolding closed_limpt
  1524   using closure_sequential [where 'a='a] closure_closed [where 'a='a] closed_limpt [where 'a='a] islimpt_sequential [where 'a='a] mem_delete [where 'a='a]
  1525   by metis
  1526 
  1527 lemma closure_approachable:
  1528   fixes S :: "'a::metric_space set"
  1529   shows "x \<in> closure S \<longleftrightarrow> (\<forall>e>0. \<exists>y\<in>S. dist y x < e)"
  1530   apply (auto simp add: closure_def islimpt_approachable)
  1531   by (metis dist_self)
  1532 
  1533 lemma closed_approachable:
  1534   fixes S :: "'a::metric_space set"
  1535   shows "closed S ==> (\<forall>e>0. \<exists>y\<in>S. dist y x < e) \<longleftrightarrow> x \<in> S"
  1536   by (metis closure_closed closure_approachable)
  1537 
  1538 text{* Some other lemmas about sequences. *}
  1539 
  1540 lemma sequentially_offset:
  1541   assumes "eventually (\<lambda>i. P i) sequentially"
  1542   shows "eventually (\<lambda>i. P (i + k)) sequentially"
  1543   using assms unfolding eventually_sequentially by (metis trans_le_add1)
  1544 
  1545 lemma seq_offset:
  1546   assumes "(f ---> l) sequentially"
  1547   shows "((\<lambda>i. f (i + k)) ---> l) sequentially"
  1548   using assms unfolding tendsto_def
  1549   by clarify (rule sequentially_offset, simp)
  1550 
  1551 lemma seq_offset_neg:
  1552   "(f ---> l) sequentially ==> ((\<lambda>i. f(i - k)) ---> l) sequentially"
  1553   apply (rule topological_tendstoI)
  1554   apply (drule (2) topological_tendstoD)
  1555   apply (simp only: eventually_sequentially)
  1556   apply (subgoal_tac "\<And>N k (n::nat). N + k <= n ==> N <= n - k")
  1557   apply metis
  1558   by arith
  1559 
  1560 lemma seq_offset_rev:
  1561   "((\<lambda>i. f(i + k)) ---> l) sequentially ==> (f ---> l) sequentially"
  1562   apply (rule topological_tendstoI)
  1563   apply (drule (2) topological_tendstoD)
  1564   apply (simp only: eventually_sequentially)
  1565   apply (subgoal_tac "\<And>N k (n::nat). N + k <= n ==> N <= n - k \<and> (n - k) + k = n")
  1566   by metis arith
  1567 
  1568 lemma seq_harmonic: "((\<lambda>n. inverse (real n)) ---> 0) sequentially"
  1569 proof-
  1570   { fix e::real assume "e>0"
  1571     hence "\<exists>N::nat. \<forall>n::nat\<ge>N. inverse (real n) < e"
  1572       using real_arch_inv[of e] apply auto apply(rule_tac x=n in exI)
  1573       by (metis le_imp_inverse_le not_less real_of_nat_gt_zero_cancel_iff real_of_nat_less_iff xt1(7))
  1574   }
  1575   thus ?thesis unfolding Lim_sequentially dist_norm by simp
  1576 qed
  1577 
  1578 subsection {* More properties of closed balls *}
  1579 
  1580 lemma closed_cball: "closed (cball x e)"
  1581 unfolding cball_def closed_def
  1582 unfolding Collect_neg_eq [symmetric] not_le
  1583 apply (clarsimp simp add: open_dist, rename_tac y)
  1584 apply (rule_tac x="dist x y - e" in exI, clarsimp)
  1585 apply (rename_tac x')
  1586 apply (cut_tac x=x and y=x' and z=y in dist_triangle)
  1587 apply simp
  1588 done
  1589 
  1590 lemma open_contains_cball: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0.  cball x e \<subseteq> S)"
  1591 proof-
  1592   { fix x and e::real assume "x\<in>S" "e>0" "ball x e \<subseteq> S"
  1593     hence "\<exists>d>0. cball x d \<subseteq> S" unfolding subset_eq by (rule_tac x="e/2" in exI, auto)
  1594   } moreover
  1595   { fix x and e::real assume "x\<in>S" "e>0" "cball x e \<subseteq> S"
  1596     hence "\<exists>d>0. ball x d \<subseteq> S" unfolding subset_eq apply(rule_tac x="e/2" in exI) by auto
  1597   } ultimately
  1598   show ?thesis unfolding open_contains_ball by auto
  1599 qed
  1600 
  1601 lemma open_contains_cball_eq: "open S ==> (\<forall>x. x \<in> S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S))"
  1602   by (metis open_contains_cball subset_eq order_less_imp_le centre_in_cball)
  1603 
  1604 lemma mem_interior_cball: "x \<in> interior S \<longleftrightarrow> (\<exists>e>0. cball x e \<subseteq> S)"
  1605   apply (simp add: interior_def, safe)
  1606   apply (force simp add: open_contains_cball)
  1607   apply (rule_tac x="ball x e" in exI)
  1608   apply (simp add: subset_trans [OF ball_subset_cball])
  1609   done
  1610 
  1611 lemma islimpt_ball:
  1612   fixes x y :: "'a::{real_normed_vector,perfect_space}"
  1613   shows "y islimpt ball x e \<longleftrightarrow> 0 < e \<and> y \<in> cball x e" (is "?lhs = ?rhs")
  1614 proof
  1615   assume "?lhs"
  1616   { assume "e \<le> 0"
  1617     hence *:"ball x e = {}" using ball_eq_empty[of x e] by auto
  1618     have False using `?lhs` unfolding * using islimpt_EMPTY[of y] by auto
  1619   }
  1620   hence "e > 0" by (metis not_less)
  1621   moreover
  1622   have "y \<in> cball x e" using closed_cball[of x e] islimpt_subset[of y "ball x e" "cball x e"] ball_subset_cball[of x e] `?lhs` unfolding closed_limpt by auto
  1623   ultimately show "?rhs" by auto
  1624 next
  1625   assume "?rhs" hence "e>0"  by auto
  1626   { fix d::real assume "d>0"
  1627     have "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1628     proof(cases "d \<le> dist x y")
  1629       case True thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1630       proof(cases "x=y")
  1631         case True hence False using `d \<le> dist x y` `d>0` by auto
  1632         thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d" by auto
  1633       next
  1634         case False
  1635 
  1636         have "dist x (y - (d / (2 * dist y x)) *\<^sub>R (y - x))
  1637               = norm (x - y + (d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  1638           unfolding mem_cball mem_ball dist_norm diff_diff_eq2 diff_add_eq[THEN sym] by auto
  1639         also have "\<dots> = \<bar>- 1 + d / (2 * norm (x - y))\<bar> * norm (x - y)"
  1640           using scaleR_left_distrib[of "- 1" "d / (2 * norm (y - x))", THEN sym, of "y - x"]
  1641           unfolding scaleR_minus_left scaleR_one
  1642           by (auto simp add: norm_minus_commute)
  1643         also have "\<dots> = \<bar>- norm (x - y) + d / 2\<bar>"
  1644           unfolding abs_mult_pos[of "norm (x - y)", OF norm_ge_zero[of "x - y"]]
  1645           unfolding left_distrib using `x\<noteq>y`[unfolded dist_nz, unfolded dist_norm] by auto
  1646         also have "\<dots> \<le> e - d/2" using `d \<le> dist x y` and `d>0` and `?rhs` by(auto simp add: dist_norm)
  1647         finally have "y - (d / (2 * dist y x)) *\<^sub>R (y - x) \<in> ball x e" using `d>0` by auto
  1648 
  1649         moreover
  1650 
  1651         have "(d / (2*dist y x)) *\<^sub>R (y - x) \<noteq> 0"
  1652           using `x\<noteq>y`[unfolded dist_nz] `d>0` unfolding scaleR_eq_0_iff by (auto simp add: dist_commute)
  1653         moreover
  1654         have "dist (y - (d / (2 * dist y x)) *\<^sub>R (y - x)) y < d" unfolding dist_norm apply simp unfolding norm_minus_cancel
  1655           using `d>0` `x\<noteq>y`[unfolded dist_nz] dist_commute[of x y]
  1656           unfolding dist_norm by auto
  1657         ultimately show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d" by (rule_tac  x="y - (d / (2*dist y x)) *\<^sub>R (y - x)" in bexI) auto
  1658       qed
  1659     next
  1660       case False hence "d > dist x y" by auto
  1661       show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1662       proof(cases "x=y")
  1663         case True
  1664         obtain z where **: "z \<noteq> y" "dist z y < min e d"
  1665           using perfect_choose_dist[of "min e d" y]
  1666           using `d > 0` `e>0` by auto
  1667         show "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1668           unfolding `x = y`
  1669           using `z \<noteq> y` **
  1670           by (rule_tac x=z in bexI, auto simp add: dist_commute)
  1671       next
  1672         case False thus "\<exists>x'\<in>ball x e. x' \<noteq> y \<and> dist x' y < d"
  1673           using `d>0` `d > dist x y` `?rhs` by(rule_tac x=x in bexI, auto)
  1674       qed
  1675     qed  }
  1676   thus "?lhs" unfolding mem_cball islimpt_approachable mem_ball by auto
  1677 qed
  1678 
  1679 lemma closure_ball_lemma:
  1680   fixes x y :: "'a::real_normed_vector"
  1681   assumes "x \<noteq> y" shows "y islimpt ball x (dist x y)"
  1682 proof (rule islimptI)
  1683   fix T assume "y \<in> T" "open T"
  1684   then obtain r where "0 < r" "\<forall>z. dist z y < r \<longrightarrow> z \<in> T"
  1685     unfolding open_dist by fast
  1686   (* choose point between x and y, within distance r of y. *)
  1687   def k \<equiv> "min 1 (r / (2 * dist x y))"
  1688   def z \<equiv> "y + scaleR k (x - y)"
  1689   have z_def2: "z = x + scaleR (1 - k) (y - x)"
  1690     unfolding z_def by (simp add: algebra_simps)
  1691   have "dist z y < r"
  1692     unfolding z_def k_def using `0 < r`
  1693     by (simp add: dist_norm min_def)
  1694   hence "z \<in> T" using `\<forall>z. dist z y < r \<longrightarrow> z \<in> T` by simp
  1695   have "dist x z < dist x y"
  1696     unfolding z_def2 dist_norm
  1697     apply (simp add: norm_minus_commute)
  1698     apply (simp only: dist_norm [symmetric])
  1699     apply (subgoal_tac "\<bar>1 - k\<bar> * dist x y < 1 * dist x y", simp)
  1700     apply (rule mult_strict_right_mono)
  1701     apply (simp add: k_def divide_pos_pos zero_less_dist_iff `0 < r` `x \<noteq> y`)
  1702     apply (simp add: zero_less_dist_iff `x \<noteq> y`)
  1703     done
  1704   hence "z \<in> ball x (dist x y)" by simp
  1705   have "z \<noteq> y"
  1706     unfolding z_def k_def using `x \<noteq> y` `0 < r`
  1707     by (simp add: min_def)
  1708   show "\<exists>z\<in>ball x (dist x y). z \<in> T \<and> z \<noteq> y"
  1709     using `z \<in> ball x (dist x y)` `z \<in> T` `z \<noteq> y`
  1710     by fast
  1711 qed
  1712 
  1713 lemma closure_ball:
  1714   fixes x :: "'a::real_normed_vector"
  1715   shows "0 < e \<Longrightarrow> closure (ball x e) = cball x e"
  1716 apply (rule equalityI)
  1717 apply (rule closure_minimal)
  1718 apply (rule ball_subset_cball)
  1719 apply (rule closed_cball)
  1720 apply (rule subsetI, rename_tac y)
  1721 apply (simp add: le_less [where 'a=real])
  1722 apply (erule disjE)
  1723 apply (rule subsetD [OF closure_subset], simp)
  1724 apply (simp add: closure_def)
  1725 apply clarify
  1726 apply (rule closure_ball_lemma)
  1727 apply (simp add: zero_less_dist_iff)
  1728 done
  1729 
  1730 (* In a trivial vector space, this fails for e = 0. *)
  1731 lemma interior_cball:
  1732   fixes x :: "'a::{real_normed_vector, perfect_space}"
  1733   shows "interior (cball x e) = ball x e"
  1734 proof(cases "e\<ge>0")
  1735   case False note cs = this
  1736   from cs have "ball x e = {}" using ball_empty[of e x] by auto moreover
  1737   { fix y assume "y \<in> cball x e"
  1738     hence False unfolding mem_cball using dist_nz[of x y] cs by auto  }
  1739   hence "cball x e = {}" by auto
  1740   hence "interior (cball x e) = {}" using interior_empty by auto
  1741   ultimately show ?thesis by blast
  1742 next
  1743   case True note cs = this
  1744   have "ball x e \<subseteq> cball x e" using ball_subset_cball by auto moreover
  1745   { fix S y assume as: "S \<subseteq> cball x e" "open S" "y\<in>S"
  1746     then obtain d where "d>0" and d:"\<forall>x'. dist x' y < d \<longrightarrow> x' \<in> S" unfolding open_dist by blast
  1747 
  1748     then obtain xa where xa_y: "xa \<noteq> y" and xa: "dist xa y < d"
  1749       using perfect_choose_dist [of d] by auto
  1750     have "xa\<in>S" using d[THEN spec[where x=xa]] using xa by(auto simp add: dist_commute)
  1751     hence xa_cball:"xa \<in> cball x e" using as(1) by auto
  1752 
  1753     hence "y \<in> ball x e" proof(cases "x = y")
  1754       case True
  1755       hence "e>0" using xa_y[unfolded dist_nz] xa_cball[unfolded mem_cball] by (auto simp add: dist_commute)
  1756       thus "y \<in> ball x e" using `x = y ` by simp
  1757     next
  1758       case False
  1759       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) y < d" unfolding dist_norm
  1760         using `d>0` norm_ge_zero[of "y - x"] `x \<noteq> y` by auto
  1761       hence *:"y + (d / 2 / dist y x) *\<^sub>R (y - x) \<in> cball x e" using d as(1)[unfolded subset_eq] by blast
  1762       have "y - x \<noteq> 0" using `x \<noteq> y` by auto
  1763       hence **:"d / (2 * norm (y - x)) > 0" unfolding zero_less_norm_iff[THEN sym]
  1764         using `d>0` divide_pos_pos[of d "2*norm (y - x)"] by auto
  1765 
  1766       have "dist (y + (d / 2 / dist y x) *\<^sub>R (y - x)) x = norm (y + (d / (2 * norm (y - x))) *\<^sub>R y - (d / (2 * norm (y - x))) *\<^sub>R x - x)"
  1767         by (auto simp add: dist_norm algebra_simps)
  1768       also have "\<dots> = norm ((1 + d / (2 * norm (y - x))) *\<^sub>R (y - x))"
  1769         by (auto simp add: algebra_simps)
  1770       also have "\<dots> = \<bar>1 + d / (2 * norm (y - x))\<bar> * norm (y - x)"
  1771         using ** by auto
  1772       also have "\<dots> = (dist y x) + d/2"using ** by (auto simp add: left_distrib dist_norm)
  1773       finally have "e \<ge> dist x y +d/2" using *[unfolded mem_cball] by (auto simp add: dist_commute)
  1774       thus "y \<in> ball x e" unfolding mem_ball using `d>0` by auto
  1775     qed  }
  1776   hence "\<forall>S \<subseteq> cball x e. open S \<longrightarrow> S \<subseteq> ball x e" by auto
  1777   ultimately show ?thesis using interior_unique[of "ball x e" "cball x e"] using open_ball[of x e] by auto
  1778 qed
  1779 
  1780 lemma frontier_ball:
  1781   fixes a :: "'a::real_normed_vector"
  1782   shows "0 < e ==> frontier(ball a e) = {x. dist a x = e}"
  1783   apply (simp add: frontier_def closure_ball interior_open order_less_imp_le)
  1784   apply (simp add: set_eq_iff)
  1785   by arith
  1786 
  1787 lemma frontier_cball:
  1788   fixes a :: "'a::{real_normed_vector, perfect_space}"
  1789   shows "frontier(cball a e) = {x. dist a x = e}"
  1790   apply (simp add: frontier_def interior_cball closed_cball order_less_imp_le)
  1791   apply (simp add: set_eq_iff)
  1792   by arith
  1793 
  1794 lemma cball_eq_empty: "(cball x e = {}) \<longleftrightarrow> e < 0"
  1795   apply (simp add: set_eq_iff not_le)
  1796   by (metis zero_le_dist dist_self order_less_le_trans)
  1797 lemma cball_empty: "e < 0 ==> cball x e = {}" by (simp add: cball_eq_empty)
  1798 
  1799 lemma cball_eq_sing:
  1800   fixes x :: "'a::{metric_space,perfect_space}"
  1801   shows "(cball x e = {x}) \<longleftrightarrow> e = 0"
  1802 proof (rule linorder_cases)
  1803   assume e: "0 < e"
  1804   obtain a where "a \<noteq> x" "dist a x < e"
  1805     using perfect_choose_dist [OF e] by auto
  1806   hence "a \<noteq> x" "dist x a \<le> e" by (auto simp add: dist_commute)
  1807   with e show ?thesis by (auto simp add: set_eq_iff)
  1808 qed auto
  1809 
  1810 lemma cball_sing:
  1811   fixes x :: "'a::metric_space"
  1812   shows "e = 0 ==> cball x e = {x}"
  1813   by (auto simp add: set_eq_iff)
  1814 
  1815 
  1816 subsection {* Boundedness *}
  1817 
  1818   (* FIXME: This has to be unified with BSEQ!! *)
  1819 definition (in metric_space)
  1820   bounded :: "'a set \<Rightarrow> bool" where
  1821   "bounded S \<longleftrightarrow> (\<exists>x e. \<forall>y\<in>S. dist x y \<le> e)"
  1822 
  1823 lemma bounded_any_center: "bounded S \<longleftrightarrow> (\<exists>e. \<forall>y\<in>S. dist a y \<le> e)"
  1824 unfolding bounded_def
  1825 apply safe
  1826 apply (rule_tac x="dist a x + e" in exI, clarify)
  1827 apply (drule (1) bspec)
  1828 apply (erule order_trans [OF dist_triangle add_left_mono])
  1829 apply auto
  1830 done
  1831 
  1832 lemma bounded_iff: "bounded S \<longleftrightarrow> (\<exists>a. \<forall>x\<in>S. norm x \<le> a)"
  1833 unfolding bounded_any_center [where a=0]
  1834 by (simp add: dist_norm)
  1835 
  1836 lemma bounded_empty[simp]: "bounded {}" by (simp add: bounded_def)
  1837 lemma bounded_subset: "bounded T \<Longrightarrow> S \<subseteq> T ==> bounded S"
  1838   by (metis bounded_def subset_eq)
  1839 
  1840 lemma bounded_interior[intro]: "bounded S ==> bounded(interior S)"
  1841   by (metis bounded_subset interior_subset)
  1842 
  1843 lemma bounded_closure[intro]: assumes "bounded S" shows "bounded(closure S)"
  1844 proof-
  1845   from assms obtain x and a where a: "\<forall>y\<in>S. dist x y \<le> a" unfolding bounded_def by auto
  1846   { fix y assume "y \<in> closure S"
  1847     then obtain f where f: "\<forall>n. f n \<in> S"  "(f ---> y) sequentially"
  1848       unfolding closure_sequential by auto
  1849     have "\<forall>n. f n \<in> S \<longrightarrow> dist x (f n) \<le> a" using a by simp
  1850     hence "eventually (\<lambda>n. dist x (f n) \<le> a) sequentially"
  1851       by (rule eventually_mono, simp add: f(1))
  1852     have "dist x y \<le> a"
  1853       apply (rule Lim_dist_ubound [of sequentially f])
  1854       apply (rule trivial_limit_sequentially)
  1855       apply (rule f(2))
  1856       apply fact
  1857       done
  1858   }
  1859   thus ?thesis unfolding bounded_def by auto
  1860 qed
  1861 
  1862 lemma bounded_cball[simp,intro]: "bounded (cball x e)"
  1863   apply (simp add: bounded_def)
  1864   apply (rule_tac x=x in exI)
  1865   apply (rule_tac x=e in exI)
  1866   apply auto
  1867   done
  1868 
  1869 lemma bounded_ball[simp,intro]: "bounded(ball x e)"
  1870   by (metis ball_subset_cball bounded_cball bounded_subset)
  1871 
  1872 lemma finite_imp_bounded[intro]:
  1873   fixes S :: "'a::metric_space set" assumes "finite S" shows "bounded S"
  1874 proof-
  1875   { fix a and F :: "'a set" assume as:"bounded F"
  1876     then obtain x e where "\<forall>y\<in>F. dist x y \<le> e" unfolding bounded_def by auto
  1877     hence "\<forall>y\<in>(insert a F). dist x y \<le> max e (dist x a)" by auto
  1878     hence "bounded (insert a F)" unfolding bounded_def by (intro exI)
  1879   }
  1880   thus ?thesis using finite_induct[of S bounded]  using bounded_empty assms by auto
  1881 qed
  1882 
  1883 lemma bounded_Un[simp]: "bounded (S \<union> T) \<longleftrightarrow> bounded S \<and> bounded T"
  1884   apply (auto simp add: bounded_def)
  1885   apply (rename_tac x y r s)
  1886   apply (rule_tac x=x in exI)
  1887   apply (rule_tac x="max r (dist x y + s)" in exI)
  1888   apply (rule ballI, rename_tac z, safe)
  1889   apply (drule (1) bspec, simp)
  1890   apply (drule (1) bspec)
  1891   apply (rule min_max.le_supI2)
  1892   apply (erule order_trans [OF dist_triangle add_left_mono])
  1893   done
  1894 
  1895 lemma bounded_Union[intro]: "finite F \<Longrightarrow> (\<forall>S\<in>F. bounded S) \<Longrightarrow> bounded(\<Union>F)"
  1896   by (induct rule: finite_induct[of F], auto)
  1897 
  1898 lemma bounded_pos: "bounded S \<longleftrightarrow> (\<exists>b>0. \<forall>x\<in> S. norm x <= b)"
  1899   apply (simp add: bounded_iff)
  1900   apply (subgoal_tac "\<And>x (y::real). 0 < 1 + abs y \<and> (x <= y \<longrightarrow> x <= 1 + abs y)")
  1901   by metis arith
  1902 
  1903 lemma bounded_Int[intro]: "bounded S \<or> bounded T \<Longrightarrow> bounded (S \<inter> T)"
  1904   by (metis Int_lower1 Int_lower2 bounded_subset)
  1905 
  1906 lemma bounded_diff[intro]: "bounded S ==> bounded (S - T)"
  1907 apply (metis Diff_subset bounded_subset)
  1908 done
  1909 
  1910 lemma bounded_insert[intro]:"bounded(insert x S) \<longleftrightarrow> bounded S"
  1911   by (metis Diff_cancel Un_empty_right Un_insert_right bounded_Un bounded_subset finite.emptyI finite_imp_bounded infinite_remove subset_insertI)
  1912 
  1913 lemma not_bounded_UNIV[simp, intro]:
  1914   "\<not> bounded (UNIV :: 'a::{real_normed_vector, perfect_space} set)"
  1915 proof(auto simp add: bounded_pos not_le)
  1916   obtain x :: 'a where "x \<noteq> 0"
  1917     using perfect_choose_dist [OF zero_less_one] by fast
  1918   fix b::real  assume b: "b >0"
  1919   have b1: "b +1 \<ge> 0" using b by simp
  1920   with `x \<noteq> 0` have "b < norm (scaleR (b + 1) (sgn x))"
  1921     by (simp add: norm_sgn)
  1922   then show "\<exists>x::'a. b < norm x" ..
  1923 qed
  1924 
  1925 lemma bounded_linear_image:
  1926   assumes "bounded S" "bounded_linear f"
  1927   shows "bounded(f ` S)"
  1928 proof-
  1929   from assms(1) obtain b where b:"b>0" "\<forall>x\<in>S. norm x \<le> b" unfolding bounded_pos by auto
  1930   from assms(2) obtain B where B:"B>0" "\<forall>x. norm (f x) \<le> B * norm x" using bounded_linear.pos_bounded by (auto simp add: mult_ac)
  1931   { fix x assume "x\<in>S"
  1932     hence "norm x \<le> b" using b by auto
  1933     hence "norm (f x) \<le> B * b" using B(2) apply(erule_tac x=x in allE)
  1934       by (metis B(1) B(2) order_trans mult_le_cancel_left_pos)
  1935   }
  1936   thus ?thesis unfolding bounded_pos apply(rule_tac x="b*B" in exI)
  1937     using b B mult_pos_pos [of b B] by (auto simp add: mult_commute)
  1938 qed
  1939 
  1940 lemma bounded_scaling:
  1941   fixes S :: "'a::real_normed_vector set"
  1942   shows "bounded S \<Longrightarrow> bounded ((\<lambda>x. c *\<^sub>R x) ` S)"
  1943   apply (rule bounded_linear_image, assumption)
  1944   apply (rule bounded_linear_scaleR_right)
  1945   done
  1946 
  1947 lemma bounded_translation:
  1948   fixes S :: "'a::real_normed_vector set"
  1949   assumes "bounded S" shows "bounded ((\<lambda>x. a + x) ` S)"
  1950 proof-
  1951   from assms obtain b where b:"b>0" "\<forall>x\<in>S. norm x \<le> b" unfolding bounded_pos by auto
  1952   { fix x assume "x\<in>S"
  1953     hence "norm (a + x) \<le> b + norm a" using norm_triangle_ineq[of a x] b by auto
  1954   }
  1955   thus ?thesis unfolding bounded_pos using norm_ge_zero[of a] b(1) using add_strict_increasing[of b 0 "norm a"]
  1956     by (auto intro!: add exI[of _ "b + norm a"])
  1957 qed
  1958 
  1959 
  1960 text{* Some theorems on sups and infs using the notion "bounded". *}
  1961 
  1962 lemma bounded_real:
  1963   fixes S :: "real set"
  1964   shows "bounded S \<longleftrightarrow>  (\<exists>a. \<forall>x\<in>S. abs x <= a)"
  1965   by (simp add: bounded_iff)
  1966 
  1967 lemma bounded_has_Sup:
  1968   fixes S :: "real set"
  1969   assumes "bounded S" "S \<noteq> {}"
  1970   shows "\<forall>x\<in>S. x <= Sup S" and "\<forall>b. (\<forall>x\<in>S. x <= b) \<longrightarrow> Sup S <= b"
  1971 proof
  1972   fix x assume "x\<in>S"
  1973   thus "x \<le> Sup S"
  1974     by (metis SupInf.Sup_upper abs_le_D1 assms(1) bounded_real)
  1975 next
  1976   show "\<forall>b. (\<forall>x\<in>S. x \<le> b) \<longrightarrow> Sup S \<le> b" using assms
  1977     by (metis SupInf.Sup_least)
  1978 qed
  1979 
  1980 lemma Sup_insert:
  1981   fixes S :: "real set"
  1982   shows "bounded S ==> Sup(insert x S) = (if S = {} then x else max x (Sup S))" 
  1983 by auto (metis Int_absorb Sup_insert_nonempty assms bounded_has_Sup(1) disjoint_iff_not_equal) 
  1984 
  1985 lemma Sup_insert_finite:
  1986   fixes S :: "real set"
  1987   shows "finite S \<Longrightarrow> Sup(insert x S) = (if S = {} then x else max x (Sup S))"
  1988   apply (rule Sup_insert)
  1989   apply (rule finite_imp_bounded)
  1990   by simp
  1991 
  1992 lemma bounded_has_Inf:
  1993   fixes S :: "real set"
  1994   assumes "bounded S"  "S \<noteq> {}"
  1995   shows "\<forall>x\<in>S. x >= Inf S" and "\<forall>b. (\<forall>x\<in>S. x >= b) \<longrightarrow> Inf S >= b"
  1996 proof
  1997   fix x assume "x\<in>S"
  1998   from assms(1) obtain a where a:"\<forall>x\<in>S. \<bar>x\<bar> \<le> a" unfolding bounded_real by auto
  1999   thus "x \<ge> Inf S" using `x\<in>S`
  2000     by (metis Inf_lower_EX abs_le_D2 minus_le_iff)
  2001 next
  2002   show "\<forall>b. (\<forall>x\<in>S. x >= b) \<longrightarrow> Inf S \<ge> b" using assms
  2003     by (metis SupInf.Inf_greatest)
  2004 qed
  2005 
  2006 lemma Inf_insert:
  2007   fixes S :: "real set"
  2008   shows "bounded S ==> Inf(insert x S) = (if S = {} then x else min x (Inf S))" 
  2009 by auto (metis Int_absorb Inf_insert_nonempty bounded_has_Inf(1) disjoint_iff_not_equal) 
  2010 lemma Inf_insert_finite:
  2011   fixes S :: "real set"
  2012   shows "finite S ==> Inf(insert x S) = (if S = {} then x else min x (Inf S))"
  2013   by (rule Inf_insert, rule finite_imp_bounded, simp)
  2014 
  2015 (* TODO: Move this to RComplete.thy -- would need to include Glb into RComplete *)
  2016 lemma real_isGlb_unique: "[| isGlb R S x; isGlb R S y |] ==> x = (y::real)"
  2017   apply (frule isGlb_isLb)
  2018   apply (frule_tac x = y in isGlb_isLb)
  2019   apply (blast intro!: order_antisym dest!: isGlb_le_isLb)
  2020   done
  2021 
  2022 
  2023 subsection {* Equivalent versions of compactness *}
  2024 
  2025 subsubsection{* Sequential compactness *}
  2026 
  2027 definition
  2028   compact :: "'a::metric_space set \<Rightarrow> bool" where (* TODO: generalize *)
  2029   "compact S \<longleftrightarrow>
  2030    (\<forall>f. (\<forall>n. f n \<in> S) \<longrightarrow>
  2031        (\<exists>l\<in>S. \<exists>r. subseq r \<and> ((f o r) ---> l) sequentially))"
  2032 
  2033 lemma compactI:
  2034   assumes "\<And>f. \<forall>n. f n \<in> S \<Longrightarrow> \<exists>l\<in>S. \<exists>r. subseq r \<and> ((f o r) ---> l) sequentially"
  2035   shows "compact S"
  2036   unfolding compact_def using assms by fast
  2037 
  2038 lemma compactE:
  2039   assumes "compact S" "\<forall>n. f n \<in> S"
  2040   obtains l r where "l \<in> S" "subseq r" "((f \<circ> r) ---> l) sequentially"
  2041   using assms unfolding compact_def by fast
  2042 
  2043 text {*
  2044   A metric space (or topological vector space) is said to have the
  2045   Heine-Borel property if every closed and bounded subset is compact.
  2046 *}
  2047 
  2048 class heine_borel = metric_space +
  2049   assumes bounded_imp_convergent_subsequence:
  2050     "bounded s \<Longrightarrow> \<forall>n. f n \<in> s
  2051       \<Longrightarrow> \<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2052 
  2053 lemma bounded_closed_imp_compact:
  2054   fixes s::"'a::heine_borel set"
  2055   assumes "bounded s" and "closed s" shows "compact s"
  2056 proof (unfold compact_def, clarify)
  2057   fix f :: "nat \<Rightarrow> 'a" assume f: "\<forall>n. f n \<in> s"
  2058   obtain l r where r: "subseq r" and l: "((f \<circ> r) ---> l) sequentially"
  2059     using bounded_imp_convergent_subsequence [OF `bounded s` `\<forall>n. f n \<in> s`] by auto
  2060   from f have fr: "\<forall>n. (f \<circ> r) n \<in> s" by simp
  2061   have "l \<in> s" using `closed s` fr l
  2062     unfolding closed_sequential_limits by blast
  2063   show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2064     using `l \<in> s` r l by blast
  2065 qed
  2066 
  2067 lemma subseq_bigger: assumes "subseq r" shows "n \<le> r n"
  2068 proof(induct n)
  2069   show "0 \<le> r 0" by auto
  2070 next
  2071   fix n assume "n \<le> r n"
  2072   moreover have "r n < r (Suc n)"
  2073     using assms [unfolded subseq_def] by auto
  2074   ultimately show "Suc n \<le> r (Suc n)" by auto
  2075 qed
  2076 
  2077 lemma eventually_subseq:
  2078   assumes r: "subseq r"
  2079   shows "eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  2080 unfolding eventually_sequentially
  2081 by (metis subseq_bigger [OF r] le_trans)
  2082 
  2083 lemma lim_subseq:
  2084   "subseq r \<Longrightarrow> (s ---> l) sequentially \<Longrightarrow> ((s o r) ---> l) sequentially"
  2085 unfolding tendsto_def eventually_sequentially o_def
  2086 by (metis subseq_bigger le_trans)
  2087 
  2088 lemma num_Axiom: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
  2089   unfolding Ex1_def
  2090   apply (rule_tac x="nat_rec e f" in exI)
  2091   apply (rule conjI)+
  2092 apply (rule def_nat_rec_0, simp)
  2093 apply (rule allI, rule def_nat_rec_Suc, simp)
  2094 apply (rule allI, rule impI, rule ext)
  2095 apply (erule conjE)
  2096 apply (induct_tac x)
  2097 apply simp
  2098 apply (erule_tac x="n" in allE)
  2099 apply (simp)
  2100 done
  2101 
  2102 lemma convergent_bounded_increasing: fixes s ::"nat\<Rightarrow>real"
  2103   assumes "incseq s" and "\<forall>n. abs(s n) \<le> b"
  2104   shows "\<exists> l. \<forall>e::real>0. \<exists> N. \<forall>n \<ge> N.  abs(s n - l) < e"
  2105 proof-
  2106   have "isUb UNIV (range s) b" using assms(2) and abs_le_D1 unfolding isUb_def and setle_def by auto
  2107   then obtain t where t:"isLub UNIV (range s) t" using reals_complete[of "range s" ] by auto
  2108   { fix e::real assume "e>0" and as:"\<forall>N. \<exists>n\<ge>N. \<not> \<bar>s n - t\<bar> < e"
  2109     { fix n::nat
  2110       obtain N where "N\<ge>n" and n:"\<bar>s N - t\<bar> \<ge> e" using as[THEN spec[where x=n]] by auto
  2111       have "t \<ge> s N" using isLub_isUb[OF t, unfolded isUb_def setle_def] by auto
  2112       with n have "s N \<le> t - e" using `e>0` by auto
  2113       hence "s n \<le> t - e" using assms(1)[unfolded incseq_def, THEN spec[where x=n], THEN spec[where x=N]] using `n\<le>N` by auto  }
  2114     hence "isUb UNIV (range s) (t - e)" unfolding isUb_def and setle_def by auto
  2115     hence False using isLub_le_isUb[OF t, of "t - e"] and `e>0` by auto  }
  2116   thus ?thesis by blast
  2117 qed
  2118 
  2119 lemma convergent_bounded_monotone: fixes s::"nat \<Rightarrow> real"
  2120   assumes "\<forall>n. abs(s n) \<le> b" and "monoseq s"
  2121   shows "\<exists>l. \<forall>e::real>0. \<exists>N. \<forall>n\<ge>N. abs(s n - l) < e"
  2122   using convergent_bounded_increasing[of s b] assms using convergent_bounded_increasing[of "\<lambda>n. - s n" b]
  2123   unfolding monoseq_def incseq_def
  2124   apply auto unfolding minus_add_distrib[THEN sym, unfolded diff_minus[THEN sym]]
  2125   unfolding abs_minus_cancel by(rule_tac x="-l" in exI)auto
  2126 
  2127 (* TODO: merge this lemma with the ones above *)
  2128 lemma bounded_increasing_convergent: fixes s::"nat \<Rightarrow> real"
  2129   assumes "bounded {s n| n::nat. True}"  "\<forall>n. (s n) \<le>(s(Suc n))"
  2130   shows "\<exists>l. (s ---> l) sequentially"
  2131 proof-
  2132   obtain a where a:"\<forall>n. \<bar> (s n)\<bar> \<le>  a" using assms(1)[unfolded bounded_iff] by auto
  2133   { fix m::nat
  2134     have "\<And> n. n\<ge>m \<longrightarrow>  (s m) \<le> (s n)"
  2135       apply(induct_tac n) apply simp using assms(2) apply(erule_tac x="na" in allE)
  2136       apply(case_tac "m \<le> na") unfolding not_less_eq_eq by(auto simp add: not_less_eq_eq)  }
  2137   hence "\<forall>m n. m \<le> n \<longrightarrow> (s m) \<le> (s n)" by auto
  2138   then obtain l where "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. \<bar> (s n) - l\<bar> < e" using convergent_bounded_monotone[OF a]
  2139     unfolding monoseq_def by auto
  2140   thus ?thesis unfolding Lim_sequentially apply(rule_tac x="l" in exI)
  2141     unfolding dist_norm  by auto
  2142 qed
  2143 
  2144 lemma compact_real_lemma:
  2145   assumes "\<forall>n::nat. abs(s n) \<le> b"
  2146   shows "\<exists>(l::real) r. subseq r \<and> ((s \<circ> r) ---> l) sequentially"
  2147 proof-
  2148   obtain r where r:"subseq r" "monoseq (\<lambda>n. s (r n))"
  2149     using seq_monosub[of s] by auto
  2150   thus ?thesis using convergent_bounded_monotone[of "\<lambda>n. s (r n)" b] and assms
  2151     unfolding tendsto_iff dist_norm eventually_sequentially by auto
  2152 qed
  2153 
  2154 instance real :: heine_borel
  2155 proof
  2156   fix s :: "real set" and f :: "nat \<Rightarrow> real"
  2157   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2158   then obtain b where b: "\<forall>n. abs (f n) \<le> b"
  2159     unfolding bounded_iff by auto
  2160   obtain l :: real and r :: "nat \<Rightarrow> nat" where
  2161     r: "subseq r" and l: "((f \<circ> r) ---> l) sequentially"
  2162     using compact_real_lemma [OF b] by auto
  2163   thus "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2164     by auto
  2165 qed
  2166 
  2167 lemma bounded_component: "bounded s \<Longrightarrow> bounded ((\<lambda>x. x $$ i) ` s)"
  2168   apply (erule bounded_linear_image)
  2169   apply (rule bounded_linear_euclidean_component)
  2170   done
  2171 
  2172 lemma compact_lemma:
  2173   fixes f :: "nat \<Rightarrow> 'a::euclidean_space"
  2174   assumes "bounded s" and "\<forall>n. f n \<in> s"
  2175   shows "\<forall>d. \<exists>l::'a. \<exists> r. subseq r \<and>
  2176         (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  2177 proof
  2178   fix d'::"nat set" def d \<equiv> "d' \<inter> {..<DIM('a)}"
  2179   have "finite d" "d\<subseteq>{..<DIM('a)}" unfolding d_def by auto
  2180   hence "\<exists>l::'a. \<exists>r. subseq r \<and>
  2181       (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  2182   proof(induct d) case empty thus ?case unfolding subseq_def by auto
  2183   next case (insert k d) have k[intro]:"k<DIM('a)" using insert by auto
  2184     have s': "bounded ((\<lambda>x. x $$ k) ` s)" using `bounded s` by (rule bounded_component)
  2185     obtain l1::"'a" and r1 where r1:"subseq r1" and
  2186       lr1:"\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) $$ i) (l1 $$ i) < e) sequentially"
  2187       using insert(3) using insert(4) by auto
  2188     have f': "\<forall>n. f (r1 n) $$ k \<in> (\<lambda>x. x $$ k) ` s" using `\<forall>n. f n \<in> s` by simp
  2189     obtain l2 r2 where r2:"subseq r2" and lr2:"((\<lambda>i. f (r1 (r2 i)) $$ k) ---> l2) sequentially"
  2190       using bounded_imp_convergent_subsequence[OF s' f'] unfolding o_def by auto
  2191     def r \<equiv> "r1 \<circ> r2" have r:"subseq r"
  2192       using r1 and r2 unfolding r_def o_def subseq_def by auto
  2193     moreover
  2194     def l \<equiv> "(\<chi>\<chi> i. if i = k then l2 else l1$$i)::'a"
  2195     { fix e::real assume "e>0"
  2196       from lr1 `e>0` have N1:"eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 n) $$ i) (l1 $$ i) < e) sequentially" by blast
  2197       from lr2 `e>0` have N2:"eventually (\<lambda>n. dist (f (r1 (r2 n)) $$ k) l2 < e) sequentially" by (rule tendstoD)
  2198       from r2 N1 have N1': "eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r1 (r2 n)) $$ i) (l1 $$ i) < e) sequentially"
  2199         by (rule eventually_subseq)
  2200       have "eventually (\<lambda>n. \<forall>i\<in>(insert k d). dist (f (r n) $$ i) (l $$ i) < e) sequentially"
  2201         using N1' N2 apply(rule eventually_elim2) unfolding l_def r_def o_def
  2202         using insert.prems by auto
  2203     }
  2204     ultimately show ?case by auto
  2205   qed
  2206   thus "\<exists>l::'a. \<exists>r. subseq r \<and>
  2207       (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d'. dist (f (r n) $$ i) (l $$ i) < e) sequentially)"
  2208     apply safe apply(rule_tac x=l in exI,rule_tac x=r in exI) apply safe
  2209     apply(erule_tac x=e in allE) unfolding d_def eventually_sequentially apply safe 
  2210     apply(rule_tac x=N in exI) apply safe apply(erule_tac x=n in allE,safe)
  2211     apply(erule_tac x=i in ballE) 
  2212   proof- fix i and r::"nat=>nat" and n::nat and e::real and l::'a
  2213     assume "i\<in>d'" "i \<notin> d' \<inter> {..<DIM('a)}" and e:"e>0"
  2214     hence *:"i\<ge>DIM('a)" by auto
  2215     thus "dist (f (r n) $$ i) (l $$ i) < e" using e by auto
  2216   qed
  2217 qed
  2218 
  2219 instance euclidean_space \<subseteq> heine_borel
  2220 proof
  2221   fix s :: "'a set" and f :: "nat \<Rightarrow> 'a"
  2222   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2223   then obtain l::'a and r where r: "subseq r"
  2224     and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>UNIV. dist (f (r n) $$ i) (l $$ i) < e) sequentially"
  2225     using compact_lemma [OF s f] by blast
  2226   let ?d = "{..<DIM('a)}"
  2227   { fix e::real assume "e>0"
  2228     hence "0 < e / (real_of_nat (card ?d))"
  2229       using DIM_positive using divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
  2230     with l have "eventually (\<lambda>n. \<forall>i. dist (f (r n) $$ i) (l $$ i) < e / (real_of_nat (card ?d))) sequentially"
  2231       by simp
  2232     moreover
  2233     { fix n assume n: "\<forall>i. dist (f (r n) $$ i) (l $$ i) < e / (real_of_nat (card ?d))"
  2234       have "dist (f (r n)) l \<le> (\<Sum>i\<in>?d. dist (f (r n) $$ i) (l $$ i))"
  2235         apply(subst euclidean_dist_l2) using zero_le_dist by (rule setL2_le_setsum)
  2236       also have "\<dots> < (\<Sum>i\<in>?d. e / (real_of_nat (card ?d)))"
  2237         apply(rule setsum_strict_mono) using n by auto
  2238       finally have "dist (f (r n)) l < e" unfolding setsum_constant
  2239         using DIM_positive[where 'a='a] by auto
  2240     }
  2241     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
  2242       by (rule eventually_elim1)
  2243   }
  2244   hence *:"((f \<circ> r) ---> l) sequentially" unfolding o_def tendsto_iff by simp
  2245   with r show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" by auto
  2246 qed
  2247 
  2248 lemma bounded_fst: "bounded s \<Longrightarrow> bounded (fst ` s)"
  2249 unfolding bounded_def
  2250 apply clarify
  2251 apply (rule_tac x="a" in exI)
  2252 apply (rule_tac x="e" in exI)
  2253 apply clarsimp
  2254 apply (drule (1) bspec)
  2255 apply (simp add: dist_Pair_Pair)
  2256 apply (erule order_trans [OF real_sqrt_sum_squares_ge1])
  2257 done
  2258 
  2259 lemma bounded_snd: "bounded s \<Longrightarrow> bounded (snd ` s)"
  2260 unfolding bounded_def
  2261 apply clarify
  2262 apply (rule_tac x="b" in exI)
  2263 apply (rule_tac x="e" in exI)
  2264 apply clarsimp
  2265 apply (drule (1) bspec)
  2266 apply (simp add: dist_Pair_Pair)
  2267 apply (erule order_trans [OF real_sqrt_sum_squares_ge2])
  2268 done
  2269 
  2270 instance prod :: (heine_borel, heine_borel) heine_borel
  2271 proof
  2272   fix s :: "('a * 'b) set" and f :: "nat \<Rightarrow> 'a * 'b"
  2273   assume s: "bounded s" and f: "\<forall>n. f n \<in> s"
  2274   from s have s1: "bounded (fst ` s)" by (rule bounded_fst)
  2275   from f have f1: "\<forall>n. fst (f n) \<in> fst ` s" by simp
  2276   obtain l1 r1 where r1: "subseq r1"
  2277     and l1: "((\<lambda>n. fst (f (r1 n))) ---> l1) sequentially"
  2278     using bounded_imp_convergent_subsequence [OF s1 f1]
  2279     unfolding o_def by fast
  2280   from s have s2: "bounded (snd ` s)" by (rule bounded_snd)
  2281   from f have f2: "\<forall>n. snd (f (r1 n)) \<in> snd ` s" by simp
  2282   obtain l2 r2 where r2: "subseq r2"
  2283     and l2: "((\<lambda>n. snd (f (r1 (r2 n)))) ---> l2) sequentially"
  2284     using bounded_imp_convergent_subsequence [OF s2 f2]
  2285     unfolding o_def by fast
  2286   have l1': "((\<lambda>n. fst (f (r1 (r2 n)))) ---> l1) sequentially"
  2287     using lim_subseq [OF r2 l1] unfolding o_def .
  2288   have l: "((f \<circ> (r1 \<circ> r2)) ---> (l1, l2)) sequentially"
  2289     using tendsto_Pair [OF l1' l2] unfolding o_def by simp
  2290   have r: "subseq (r1 \<circ> r2)"
  2291     using r1 r2 unfolding subseq_def by simp
  2292   show "\<exists>l r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2293     using l r by fast
  2294 qed
  2295 
  2296 subsubsection{* Completeness *}
  2297 
  2298 lemma cauchy_def:
  2299   "Cauchy s \<longleftrightarrow> (\<forall>e>0. \<exists>N. \<forall>m n. m \<ge> N \<and> n \<ge> N --> dist(s m)(s n) < e)"
  2300 unfolding Cauchy_def by blast
  2301 
  2302 definition
  2303   complete :: "'a::metric_space set \<Rightarrow> bool" where
  2304   "complete s \<longleftrightarrow> (\<forall>f. (\<forall>n. f n \<in> s) \<and> Cauchy f
  2305                       --> (\<exists>l \<in> s. (f ---> l) sequentially))"
  2306 
  2307 lemma cauchy: "Cauchy s \<longleftrightarrow> (\<forall>e>0.\<exists> N::nat. \<forall>n\<ge>N. dist(s n)(s N) < e)" (is "?lhs = ?rhs")
  2308 proof-
  2309   { assume ?rhs
  2310     { fix e::real
  2311       assume "e>0"
  2312       with `?rhs` obtain N where N:"\<forall>n\<ge>N. dist (s n) (s N) < e/2"
  2313         by (erule_tac x="e/2" in allE) auto
  2314       { fix n m
  2315         assume nm:"N \<le> m \<and> N \<le> n"
  2316         hence "dist (s m) (s n) < e" using N
  2317           using dist_triangle_half_l[of "s m" "s N" "e" "s n"]
  2318           by blast
  2319       }
  2320       hence "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"
  2321         by blast
  2322     }
  2323     hence ?lhs
  2324       unfolding cauchy_def
  2325       by blast
  2326   }
  2327   thus ?thesis
  2328     unfolding cauchy_def
  2329     using dist_triangle_half_l
  2330     by blast
  2331 qed
  2332 
  2333 lemma convergent_imp_cauchy:
  2334  "(s ---> l) sequentially ==> Cauchy s"
  2335 proof(simp only: cauchy_def, rule, rule)
  2336   fix e::real assume "e>0" "(s ---> l) sequentially"
  2337   then obtain N::nat where N:"\<forall>n\<ge>N. dist (s n) l < e/2" unfolding Lim_sequentially by(erule_tac x="e/2" in allE) auto
  2338   thus "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"  using dist_triangle_half_l[of _ l e _] by (rule_tac x=N in exI) auto
  2339 qed
  2340 
  2341 lemma cauchy_imp_bounded: assumes "Cauchy s" shows "bounded (range s)"
  2342 proof-
  2343   from assms obtain N::nat where "\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < 1" unfolding cauchy_def apply(erule_tac x= 1 in allE) by auto
  2344   hence N:"\<forall>n. N \<le> n \<longrightarrow> dist (s N) (s n) < 1" by auto
  2345   moreover
  2346   have "bounded (s ` {0..N})" using finite_imp_bounded[of "s ` {1..N}"] by auto
  2347   then obtain a where a:"\<forall>x\<in>s ` {0..N}. dist (s N) x \<le> a"
  2348     unfolding bounded_any_center [where a="s N"] by auto
  2349   ultimately show "?thesis"
  2350     unfolding bounded_any_center [where a="s N"]
  2351     apply(rule_tac x="max a 1" in exI) apply auto
  2352     apply(erule_tac x=y in allE) apply(erule_tac x=y in ballE) by auto
  2353 qed
  2354 
  2355 lemma compact_imp_complete: assumes "compact s" shows "complete s"
  2356 proof-
  2357   { fix f assume as: "(\<forall>n::nat. f n \<in> s)" "Cauchy f"
  2358     from as(1) obtain l r where lr: "l\<in>s" "subseq r" "((f \<circ> r) ---> l) sequentially" using assms unfolding compact_def by blast
  2359 
  2360     note lr' = subseq_bigger [OF lr(2)]
  2361 
  2362     { fix e::real assume "e>0"
  2363       from as(2) obtain N where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (f m) (f n) < e/2" unfolding cauchy_def using `e>0` apply (erule_tac x="e/2" in allE) by auto
  2364       from lr(3)[unfolded Lim_sequentially, THEN spec[where x="e/2"]] obtain M where M:"\<forall>n\<ge>M. dist ((f \<circ> r) n) l < e/2" using `e>0` by auto
  2365       { fix n::nat assume n:"n \<ge> max N M"
  2366         have "dist ((f \<circ> r) n) l < e/2" using n M by auto
  2367         moreover have "r n \<ge> N" using lr'[of n] n by auto
  2368         hence "dist (f n) ((f \<circ> r) n) < e / 2" using N using n by auto
  2369         ultimately have "dist (f n) l < e" using dist_triangle_half_r[of "f (r n)" "f n" e l] by (auto simp add: dist_commute)  }
  2370       hence "\<exists>N. \<forall>n\<ge>N. dist (f n) l < e" by blast  }
  2371     hence "\<exists>l\<in>s. (f ---> l) sequentially" using `l\<in>s` unfolding Lim_sequentially by auto  }
  2372   thus ?thesis unfolding complete_def by auto
  2373 qed
  2374 
  2375 instance heine_borel < complete_space
  2376 proof
  2377   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  2378   hence "bounded (range f)"
  2379     by (rule cauchy_imp_bounded)
  2380   hence "compact (closure (range f))"
  2381     using bounded_closed_imp_compact [of "closure (range f)"] by auto
  2382   hence "complete (closure (range f))"
  2383     by (rule compact_imp_complete)
  2384   moreover have "\<forall>n. f n \<in> closure (range f)"
  2385     using closure_subset [of "range f"] by auto
  2386   ultimately have "\<exists>l\<in>closure (range f). (f ---> l) sequentially"
  2387     using `Cauchy f` unfolding complete_def by auto
  2388   then show "convergent f"
  2389     unfolding convergent_def by auto
  2390 qed
  2391 
  2392 lemma complete_univ: "complete (UNIV :: 'a::complete_space set)"
  2393 proof(simp add: complete_def, rule, rule)
  2394   fix f :: "nat \<Rightarrow> 'a" assume "Cauchy f"
  2395   hence "convergent f" by (rule Cauchy_convergent)
  2396   thus "\<exists>l. f ----> l" unfolding convergent_def .  
  2397 qed
  2398 
  2399 lemma complete_imp_closed: assumes "complete s" shows "closed s"
  2400 proof -
  2401   { fix x assume "x islimpt s"
  2402     then obtain f where f: "\<forall>n. f n \<in> s - {x}" "(f ---> x) sequentially"
  2403       unfolding islimpt_sequential by auto
  2404     then obtain l where l: "l\<in>s" "(f ---> l) sequentially"
  2405       using `complete s`[unfolded complete_def] using convergent_imp_cauchy[of f x] by auto
  2406     hence "x \<in> s"  using tendsto_unique[of sequentially f l x] trivial_limit_sequentially f(2) by auto
  2407   }
  2408   thus "closed s" unfolding closed_limpt by auto
  2409 qed
  2410 
  2411 lemma complete_eq_closed:
  2412   fixes s :: "'a::complete_space set"
  2413   shows "complete s \<longleftrightarrow> closed s" (is "?lhs = ?rhs")
  2414 proof
  2415   assume ?lhs thus ?rhs by (rule complete_imp_closed)
  2416 next
  2417   assume ?rhs
  2418   { fix f assume as:"\<forall>n::nat. f n \<in> s" "Cauchy f"
  2419     then obtain l where "(f ---> l) sequentially" using complete_univ[unfolded complete_def, THEN spec[where x=f]] by auto
  2420     hence "\<exists>l\<in>s. (f ---> l) sequentially" using `?rhs`[unfolded closed_sequential_limits, THEN spec[where x=f], THEN spec[where x=l]] using as(1) by auto  }
  2421   thus ?lhs unfolding complete_def by auto
  2422 qed
  2423 
  2424 lemma convergent_eq_cauchy:
  2425   fixes s :: "nat \<Rightarrow> 'a::complete_space"
  2426   shows "(\<exists>l. (s ---> l) sequentially) \<longleftrightarrow> Cauchy s" (is "?lhs = ?rhs")
  2427 proof
  2428   assume ?lhs then obtain l where "(s ---> l) sequentially" by auto
  2429   thus ?rhs using convergent_imp_cauchy by auto
  2430 next
  2431   assume ?rhs thus ?lhs using complete_univ[unfolded complete_def, THEN spec[where x=s]] by auto
  2432 qed
  2433 
  2434 lemma convergent_imp_bounded:
  2435   fixes s :: "nat \<Rightarrow> 'a::metric_space"
  2436   shows "(s ---> l) sequentially ==> bounded (s ` (UNIV::(nat set)))"
  2437   using convergent_imp_cauchy[of s]
  2438   using cauchy_imp_bounded[of s]
  2439   unfolding image_def
  2440   by auto
  2441 
  2442 subsubsection{* Total boundedness *}
  2443 
  2444 fun helper_1::"('a::metric_space set) \<Rightarrow> real \<Rightarrow> nat \<Rightarrow> 'a" where
  2445   "helper_1 s e n = (SOME y::'a. y \<in> s \<and> (\<forall>m<n. \<not> (dist (helper_1 s e m) y < e)))"
  2446 declare helper_1.simps[simp del]
  2447 
  2448 lemma compact_imp_totally_bounded:
  2449   assumes "compact s"
  2450   shows "\<forall>e>0. \<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> (\<Union>((\<lambda>x. ball x e) ` k))"
  2451 proof(rule, rule, rule ccontr)
  2452   fix e::real assume "e>0" and assm:"\<not> (\<exists>k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k)"
  2453   def x \<equiv> "helper_1 s e"
  2454   { fix n
  2455     have "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)"
  2456     proof(induct_tac rule:nat_less_induct)
  2457       fix n  def Q \<equiv> "(\<lambda>y. y \<in> s \<and> (\<forall>m<n. \<not> dist (x m) y < e))"
  2458       assume as:"\<forall>m<n. x m \<in> s \<and> (\<forall>ma<m. \<not> dist (x ma) (x m) < e)"
  2459       have "\<not> s \<subseteq> (\<Union>x\<in>x ` {0..<n}. ball x e)" using assm apply simp apply(erule_tac x="x ` {0 ..< n}" in allE) using as by auto
  2460       then obtain z where z:"z\<in>s" "z \<notin> (\<Union>x\<in>x ` {0..<n}. ball x e)" unfolding subset_eq by auto
  2461       have "Q (x n)" unfolding x_def and helper_1.simps[of s e n]
  2462         apply(rule someI2[where a=z]) unfolding x_def[symmetric] and Q_def using z by auto
  2463       thus "x n \<in> s \<and> (\<forall>m<n. \<not> dist (x m) (x n) < e)" unfolding Q_def by auto
  2464     qed }
  2465   hence "\<forall>n::nat. x n \<in> s" and x:"\<forall>n. \<forall>m < n. \<not> (dist (x m) (x n) < e)" by blast+
  2466   then obtain l r where "l\<in>s" and r:"subseq r" and "((x \<circ> r) ---> l) sequentially" using assms(1)[unfolded compact_def, THEN spec[where x=x]] by auto
  2467   from this(3) have "Cauchy (x \<circ> r)" using convergent_imp_cauchy by auto
  2468   then obtain N::nat where N:"\<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist ((x \<circ> r) m) ((x \<circ> r) n) < e" unfolding cauchy_def using `e>0` by auto
  2469   show False
  2470     using N[THEN spec[where x=N], THEN spec[where x="N+1"]]
  2471     using r[unfolded subseq_def, THEN spec[where x=N], THEN spec[where x="N+1"]]
  2472     using x[THEN spec[where x="r (N+1)"], THEN spec[where x="r (N)"]] by auto
  2473 qed
  2474 
  2475 subsubsection{* Heine-Borel theorem *}
  2476 
  2477 text {* Following Burkill \& Burkill vol. 2. *}
  2478 
  2479 lemma heine_borel_lemma: fixes s::"'a::metric_space set"
  2480   assumes "compact s"  "s \<subseteq> (\<Union> t)"  "\<forall>b \<in> t. open b"
  2481   shows "\<exists>e>0. \<forall>x \<in> s. \<exists>b \<in> t. ball x e \<subseteq> b"
  2482 proof(rule ccontr)
  2483   assume "\<not> (\<exists>e>0. \<forall>x\<in>s. \<exists>b\<in>t. ball x e \<subseteq> b)"
  2484   hence cont:"\<forall>e>0. \<exists>x\<in>s. \<forall>xa\<in>t. \<not> (ball x e \<subseteq> xa)" by auto
  2485   { fix n::nat
  2486     have "1 / real (n + 1) > 0" by auto
  2487     hence "\<exists>x. x\<in>s \<and> (\<forall>xa\<in>t. \<not> (ball x (inverse (real (n+1))) \<subseteq> xa))" using cont unfolding Bex_def by auto }
  2488   hence "\<forall>n::nat. \<exists>x. x \<in> s \<and> (\<forall>xa\<in>t. \<not> ball x (inverse (real (n + 1))) \<subseteq> xa)" by auto
  2489   then obtain f where f:"\<forall>n::nat. f n \<in> s \<and> (\<forall>xa\<in>t. \<not> ball (f n) (inverse (real (n + 1))) \<subseteq> xa)"
  2490     using choice[of "\<lambda>n::nat. \<lambda>x. x\<in>s \<and> (\<forall>xa\<in>t. \<not> ball x (inverse (real (n + 1))) \<subseteq> xa)"] by auto
  2491 
  2492   then obtain l r where l:"l\<in>s" and r:"subseq r" and lr:"((f \<circ> r) ---> l) sequentially"
  2493     using assms(1)[unfolded compact_def, THEN spec[where x=f]] by auto
  2494 
  2495   obtain b where "l\<in>b" "b\<in>t" using assms(2) and l by auto
  2496   then obtain e where "e>0" and e:"\<forall>z. dist z l < e \<longrightarrow> z\<in>b"
  2497     using assms(3)[THEN bspec[where x=b]] unfolding open_dist by auto
  2498 
  2499   then obtain N1 where N1:"\<forall>n\<ge>N1. dist ((f \<circ> r) n) l < e / 2"
  2500     using lr[unfolded Lim_sequentially, THEN spec[where x="e/2"]] by auto
  2501 
  2502   obtain N2::nat where N2:"N2>0" "inverse (real N2) < e /2" using real_arch_inv[of "e/2"] and `e>0` by auto
  2503   have N2':"inverse (real (r (N1 + N2) +1 )) < e/2"
  2504     apply(rule order_less_trans) apply(rule less_imp_inverse_less) using N2
  2505     using subseq_bigger[OF r, of "N1 + N2"] by auto
  2506 
  2507   def x \<equiv> "(f (r (N1 + N2)))"
  2508   have x:"\<not> ball x (inverse (real (r (N1 + N2) + 1))) \<subseteq> b" unfolding x_def
  2509     using f[THEN spec[where x="r (N1 + N2)"]] using `b\<in>t` by auto
  2510   have "\<exists>y\<in>ball x (inverse (real (r (N1 + N2) + 1))). y\<notin>b" apply(rule ccontr) using x by auto
  2511   then obtain y where y:"y \<in> ball x (inverse (real (r (N1 + N2) + 1)))" "y \<notin> b" by auto
  2512 
  2513   have "dist x l < e/2" using N1 unfolding x_def o_def by auto
  2514   hence "dist y l < e" using y N2' using dist_triangle[of y l x]by (auto simp add:dist_commute)
  2515 
  2516   thus False using e and `y\<notin>b` by auto
  2517 qed
  2518 
  2519 lemma compact_imp_heine_borel: "compact s ==> (\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f)
  2520                \<longrightarrow> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f')))"
  2521 proof clarify
  2522   fix f assume "compact s" " \<forall>t\<in>f. open t" "s \<subseteq> \<Union>f"
  2523   then obtain e::real where "e>0" and "\<forall>x\<in>s. \<exists>b\<in>f. ball x e \<subseteq> b" using heine_borel_lemma[of s f] by auto
  2524   hence "\<forall>x\<in>s. \<exists>b. b\<in>f \<and> ball x e \<subseteq> b" by auto
  2525   hence "\<exists>bb. \<forall>x\<in>s. bb x \<in>f \<and> ball x e \<subseteq> bb x" using bchoice[of s "\<lambda>x b. b\<in>f \<and> ball x e \<subseteq> b"] by auto
  2526   then obtain  bb where bb:"\<forall>x\<in>s. (bb x) \<in> f \<and> ball x e \<subseteq> (bb x)" by blast
  2527 
  2528   from `compact s` have  "\<exists> k. finite k \<and> k \<subseteq> s \<and> s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k" using compact_imp_totally_bounded[of s] `e>0` by auto
  2529   then obtain k where k:"finite k" "k \<subseteq> s" "s \<subseteq> \<Union>(\<lambda>x. ball x e) ` k" by auto
  2530 
  2531   have "finite (bb ` k)" using k(1) by auto
  2532   moreover
  2533   { fix x assume "x\<in>s"
  2534     hence "x\<in>\<Union>(\<lambda>x. ball x e) ` k" using k(3)  unfolding subset_eq by auto
  2535     hence "\<exists>X\<in>bb ` k. x \<in> X" using bb k(2) by blast
  2536     hence "x \<in> \<Union>(bb ` k)" using  Union_iff[of x "bb ` k"] by auto
  2537   }
  2538   ultimately show "\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f'" using bb k(2) by (rule_tac x="bb ` k" in exI) auto
  2539 qed
  2540 
  2541 subsubsection {* Bolzano-Weierstrass property *}
  2542 
  2543 lemma heine_borel_imp_bolzano_weierstrass:
  2544   assumes "\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f) --> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f'))"
  2545           "infinite t"  "t \<subseteq> s"
  2546   shows "\<exists>x \<in> s. x islimpt t"
  2547 proof(rule ccontr)
  2548   assume "\<not> (\<exists>x \<in> s. x islimpt t)"
  2549   then obtain f where f:"\<forall>x\<in>s. x \<in> f x \<and> open (f x) \<and> (\<forall>y\<in>t. y \<in> f x \<longrightarrow> y = x)" unfolding islimpt_def
  2550     using bchoice[of s "\<lambda> x T. x \<in> T \<and> open T \<and> (\<forall>y\<in>t. y \<in> T \<longrightarrow> y = x)"] by auto
  2551   obtain g where g:"g\<subseteq>{t. \<exists>x. x \<in> s \<and> t = f x}" "finite g" "s \<subseteq> \<Union>g"
  2552     using assms(1)[THEN spec[where x="{t. \<exists>x. x\<in>s \<and> t = f x}"]] using f by auto
  2553   from g(1,3) have g':"\<forall>x\<in>g. \<exists>xa \<in> s. x = f xa" by auto
  2554   { fix x y assume "x\<in>t" "y\<in>t" "f x = f y"
  2555     hence "x \<in> f x"  "y \<in> f x \<longrightarrow> y = x" using f[THEN bspec[where x=x]] and `t\<subseteq>s` by auto
  2556     hence "x = y" using `f x = f y` and f[THEN bspec[where x=y]] and `y\<in>t` and `t\<subseteq>s` by auto  }
  2557   hence "inj_on f t" unfolding inj_on_def by simp
  2558   hence "infinite (f ` t)" using assms(2) using finite_imageD by auto
  2559   moreover
  2560   { fix x assume "x\<in>t" "f x \<notin> g"
  2561     from g(3) assms(3) `x\<in>t` obtain h where "h\<in>g" and "x\<in>h" by auto
  2562     then obtain y where "y\<in>s" "h = f y" using g'[THEN bspec[where x=h]] by auto
  2563     hence "y = x" using f[THEN bspec[where x=y]] and `x\<in>t` and `x\<in>h`[unfolded `h = f y`] by auto
  2564     hence False using `f x \<notin> g` `h\<in>g` unfolding `h = f y` by auto  }
  2565   hence "f ` t \<subseteq> g" by auto
  2566   ultimately show False using g(2) using finite_subset by auto
  2567 qed
  2568 
  2569 subsubsection {* Complete the chain of compactness variants *}
  2570 
  2571 lemma islimpt_range_imp_convergent_subsequence:
  2572   fixes f :: "nat \<Rightarrow> 'a::metric_space"
  2573   assumes "l islimpt (range f)"
  2574   shows "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2575 proof (intro exI conjI)
  2576   have *: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. 0 < dist (f n) l \<and> dist (f n) l < e"
  2577     using assms unfolding islimpt_def
  2578     by (drule_tac x="ball l e" in spec)
  2579        (auto simp add: zero_less_dist_iff dist_commute)
  2580 
  2581   def t \<equiv> "\<lambda>e. LEAST n. 0 < dist (f n) l \<and> dist (f n) l < e"
  2582   have f_t_neq: "\<And>e. 0 < e \<Longrightarrow> 0 < dist (f (t e)) l"
  2583     unfolding t_def by (rule LeastI2_ex [OF * conjunct1])
  2584   have f_t_closer: "\<And>e. 0 < e \<Longrightarrow> dist (f (t e)) l < e"
  2585     unfolding t_def by (rule LeastI2_ex [OF * conjunct2])
  2586   have t_le: "\<And>n e. 0 < dist (f n) l \<Longrightarrow> dist (f n) l < e \<Longrightarrow> t e \<le> n"
  2587     unfolding t_def by (simp add: Least_le)
  2588   have less_tD: "\<And>n e. n < t e \<Longrightarrow> 0 < dist (f n) l \<Longrightarrow> e \<le> dist (f n) l"
  2589     unfolding t_def by (drule not_less_Least) simp
  2590   have t_antimono: "\<And>e e'. 0 < e \<Longrightarrow> e \<le> e' \<Longrightarrow> t e' \<le> t e"
  2591     apply (rule t_le)
  2592     apply (erule f_t_neq)
  2593     apply (erule (1) less_le_trans [OF f_t_closer])
  2594     done
  2595   have t_dist_f_neq: "\<And>n. 0 < dist (f n) l \<Longrightarrow> t (dist (f n) l) \<noteq> n"
  2596     by (drule f_t_closer) auto
  2597   have t_less: "\<And>e. 0 < e \<Longrightarrow> t e < t (dist (f (t e)) l)"
  2598     apply (subst less_le)
  2599     apply (rule conjI)
  2600     apply (rule t_antimono)
  2601     apply (erule f_t_neq)
  2602     apply (erule f_t_closer [THEN less_imp_le])
  2603     apply (rule t_dist_f_neq [symmetric])
  2604     apply (erule f_t_neq)
  2605     done
  2606   have dist_f_t_less':
  2607     "\<And>e e'. 0 < e \<Longrightarrow> 0 < e' \<Longrightarrow> t e \<le> t e' \<Longrightarrow> dist (f (t e')) l < e"
  2608     apply (simp add: le_less)
  2609     apply (erule disjE)
  2610     apply (rule less_trans)
  2611     apply (erule f_t_closer)
  2612     apply (rule le_less_trans)
  2613     apply (erule less_tD)
  2614     apply (erule f_t_neq)
  2615     apply (erule f_t_closer)
  2616     apply (erule subst)
  2617     apply (erule f_t_closer)
  2618     done
  2619 
  2620   def r \<equiv> "nat_rec (t 1) (\<lambda>_ x. t (dist (f x) l))"
  2621   have r_simps: "r 0 = t 1" "\<And>n. r (Suc n) = t (dist (f (r n)) l)"
  2622     unfolding r_def by simp_all
  2623   have f_r_neq: "\<And>n. 0 < dist (f (r n)) l"
  2624     by (induct_tac n) (simp_all add: r_simps f_t_neq)
  2625 
  2626   show "subseq r"
  2627     unfolding subseq_Suc_iff
  2628     apply (rule allI)
  2629     apply (case_tac n)
  2630     apply (simp_all add: r_simps)
  2631     apply (rule t_less, rule zero_less_one)
  2632     apply (rule t_less, rule f_r_neq)
  2633     done
  2634   show "((f \<circ> r) ---> l) sequentially"
  2635     unfolding Lim_sequentially o_def
  2636     apply (clarify, rule_tac x="t e" in exI, clarify)
  2637     apply (drule le_trans, rule seq_suble [OF `subseq r`])
  2638     apply (case_tac n, simp_all add: r_simps dist_f_t_less' f_r_neq)
  2639     done
  2640 qed
  2641 
  2642 lemma finite_range_imp_infinite_repeats:
  2643   fixes f :: "nat \<Rightarrow> 'a"
  2644   assumes "finite (range f)"
  2645   shows "\<exists>k. infinite {n. f n = k}"
  2646 proof -
  2647   { fix A :: "'a set" assume "finite A"
  2648     hence "\<And>f. infinite {n. f n \<in> A} \<Longrightarrow> \<exists>k. infinite {n. f n = k}"
  2649     proof (induct)
  2650       case empty thus ?case by simp
  2651     next
  2652       case (insert x A)
  2653      show ?case
  2654       proof (cases "finite {n. f n = x}")
  2655         case True
  2656         with `infinite {n. f n \<in> insert x A}`
  2657         have "infinite {n. f n \<in> A}" by simp
  2658         thus "\<exists>k. infinite {n. f n = k}" by (rule insert)
  2659       next
  2660         case False thus "\<exists>k. infinite {n. f n = k}" ..
  2661       qed
  2662     qed
  2663   } note H = this
  2664   from assms show "\<exists>k. infinite {n. f n = k}"
  2665     by (rule H) simp
  2666 qed
  2667 
  2668 lemma bolzano_weierstrass_imp_compact:
  2669   fixes s :: "'a::metric_space set"
  2670   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2671   shows "compact s"
  2672 proof -
  2673   { fix f :: "nat \<Rightarrow> 'a" assume f: "\<forall>n. f n \<in> s"
  2674     have "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2675     proof (cases "finite (range f)")
  2676       case True
  2677       hence "\<exists>l. infinite {n. f n = l}"
  2678         by (rule finite_range_imp_infinite_repeats)
  2679       then obtain l where "infinite {n. f n = l}" ..
  2680       hence "\<exists>r. subseq r \<and> (\<forall>n. r n \<in> {n. f n = l})"
  2681         by (rule infinite_enumerate)
  2682       then obtain r where "subseq r" and fr: "\<forall>n. f (r n) = l" by auto
  2683       hence "subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2684         unfolding o_def by (simp add: fr tendsto_const)
  2685       hence "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2686         by - (rule exI)
  2687       from f have "\<forall>n. f (r n) \<in> s" by simp
  2688       hence "l \<in> s" by (simp add: fr)
  2689       thus "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2690         by (rule rev_bexI) fact
  2691     next
  2692       case False
  2693       with f assms have "\<exists>x\<in>s. x islimpt (range f)" by auto
  2694       then obtain l where "l \<in> s" "l islimpt (range f)" ..
  2695       have "\<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2696         using `l islimpt (range f)`
  2697         by (rule islimpt_range_imp_convergent_subsequence)
  2698       with `l \<in> s` show "\<exists>l\<in>s. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially" ..
  2699     qed
  2700   }
  2701   thus ?thesis unfolding compact_def by auto
  2702 qed
  2703 
  2704 primrec helper_2::"(real \<Rightarrow> 'a::metric_space) \<Rightarrow> nat \<Rightarrow> 'a" where
  2705   "helper_2 beyond 0 = beyond 0" |
  2706   "helper_2 beyond (Suc n) = beyond (dist undefined (helper_2 beyond n) + 1 )"
  2707 
  2708 lemma bolzano_weierstrass_imp_bounded: fixes s::"'a::metric_space set"
  2709   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2710   shows "bounded s"
  2711 proof(rule ccontr)
  2712   assume "\<not> bounded s"
  2713   then obtain beyond where "\<forall>a. beyond a \<in>s \<and> \<not> dist undefined (beyond a) \<le> a"
  2714     unfolding bounded_any_center [where a=undefined]
  2715     apply simp using choice[of "\<lambda>a x. x\<in>s \<and> \<not> dist undefined x \<le> a"] by auto
  2716   hence beyond:"\<And>a. beyond a \<in>s" "\<And>a. dist undefined (beyond a) > a"
  2717     unfolding linorder_not_le by auto
  2718   def x \<equiv> "helper_2 beyond"
  2719 
  2720   { fix m n ::nat assume "m<n"
  2721     hence "dist undefined (x m) + 1 < dist undefined (x n)"
  2722     proof(induct n)
  2723       case 0 thus ?case by auto
  2724     next
  2725       case (Suc n)
  2726       have *:"dist undefined (x n) + 1 < dist undefined (x (Suc n))"
  2727         unfolding x_def and helper_2.simps
  2728         using beyond(2)[of "dist undefined (helper_2 beyond n) + 1"] by auto
  2729       thus ?case proof(cases "m < n")
  2730         case True thus ?thesis using Suc and * by auto
  2731       next
  2732         case False hence "m = n" using Suc(2) by auto
  2733         thus ?thesis using * by auto
  2734       qed
  2735     qed  } note * = this
  2736   { fix m n ::nat assume "m\<noteq>n"
  2737     have "1 < dist (x m) (x n)"
  2738     proof(cases "m<n")
  2739       case True
  2740       hence "1 < dist undefined (x n) - dist undefined (x m)" using *[of m n] by auto
  2741       thus ?thesis using dist_triangle [of undefined "x n" "x m"] by arith
  2742     next
  2743       case False hence "n<m" using `m\<noteq>n` by auto
  2744       hence "1 < dist undefined (x m) - dist undefined (x n)" using *[of n m] by auto
  2745       thus ?thesis using dist_triangle2 [of undefined "x m" "x n"] by arith
  2746     qed  } note ** = this
  2747   { fix a b assume "x a = x b" "a \<noteq> b"
  2748     hence False using **[of a b] by auto  }
  2749   hence "inj x" unfolding inj_on_def by auto
  2750   moreover
  2751   { fix n::nat
  2752     have "x n \<in> s"
  2753     proof(cases "n = 0")
  2754       case True thus ?thesis unfolding x_def using beyond by auto
  2755     next
  2756       case False then obtain z where "n = Suc z" using not0_implies_Suc by auto
  2757       thus ?thesis unfolding x_def using beyond by auto
  2758     qed  }
  2759   ultimately have "infinite (range x) \<and> range x \<subseteq> s" unfolding x_def using range_inj_infinite[of "helper_2 beyond"] using beyond(1) by auto
  2760 
  2761   then obtain l where "l\<in>s" and l:"l islimpt range x" using assms[THEN spec[where x="range x"]] by auto
  2762   then obtain y where "x y \<noteq> l" and y:"dist (x y) l < 1/2" unfolding islimpt_approachable apply(erule_tac x="1/2" in allE) by auto
  2763   then obtain z where "x z \<noteq> l" and z:"dist (x z) l < dist (x y) l" using l[unfolded islimpt_approachable, THEN spec[where x="dist (x y) l"]]
  2764     unfolding dist_nz by auto
  2765   show False using y and z and dist_triangle_half_l[of "x y" l 1 "x z"] and **[of y z] by auto
  2766 qed
  2767 
  2768 lemma sequence_infinite_lemma:
  2769   fixes f :: "nat \<Rightarrow> 'a::t1_space"
  2770   assumes "\<forall>n. f n \<noteq> l" and "(f ---> l) sequentially"
  2771   shows "infinite (range f)"
  2772 proof
  2773   assume "finite (range f)"
  2774   hence "closed (range f)" by (rule finite_imp_closed)
  2775   hence "open (- range f)" by (rule open_Compl)
  2776   from assms(1) have "l \<in> - range f" by auto
  2777   from assms(2) have "eventually (\<lambda>n. f n \<in> - range f) sequentially"
  2778     using `open (- range f)` `l \<in> - range f` by (rule topological_tendstoD)
  2779   thus False unfolding eventually_sequentially by auto
  2780 qed
  2781 
  2782 lemma closure_insert:
  2783   fixes x :: "'a::t1_space"
  2784   shows "closure (insert x s) = insert x (closure s)"
  2785 apply (rule closure_unique)
  2786 apply (rule conjI [OF insert_mono [OF closure_subset]])
  2787 apply (rule conjI [OF closed_insert [OF closed_closure]])
  2788 apply (simp add: closure_minimal)
  2789 done
  2790 
  2791 lemma islimpt_insert:
  2792   fixes x :: "'a::t1_space"
  2793   shows "x islimpt (insert a s) \<longleftrightarrow> x islimpt s"
  2794 proof
  2795   assume *: "x islimpt (insert a s)"
  2796   show "x islimpt s"
  2797   proof (rule islimptI)
  2798     fix t assume t: "x \<in> t" "open t"
  2799     show "\<exists>y\<in>s. y \<in> t \<and> y \<noteq> x"
  2800     proof (cases "x = a")
  2801       case True
  2802       obtain y where "y \<in> insert a s" "y \<in> t" "y \<noteq> x"
  2803         using * t by (rule islimptE)
  2804       with `x = a` show ?thesis by auto
  2805     next
  2806       case False
  2807       with t have t': "x \<in> t - {a}" "open (t - {a})"
  2808         by (simp_all add: open_Diff)
  2809       obtain y where "y \<in> insert a s" "y \<in> t - {a}" "y \<noteq> x"
  2810         using * t' by (rule islimptE)
  2811       thus ?thesis by auto
  2812     qed
  2813   qed
  2814 next
  2815   assume "x islimpt s" thus "x islimpt (insert a s)"
  2816     by (rule islimpt_subset) auto
  2817 qed
  2818 
  2819 lemma islimpt_union_finite:
  2820   fixes x :: "'a::t1_space"
  2821   shows "finite s \<Longrightarrow> x islimpt (s \<union> t) \<longleftrightarrow> x islimpt t"
  2822 by (induct set: finite, simp_all add: islimpt_insert)
  2823  
  2824 lemma sequence_unique_limpt:
  2825   fixes f :: "nat \<Rightarrow> 'a::t2_space"
  2826   assumes "(f ---> l) sequentially" and "l' islimpt (range f)"
  2827   shows "l' = l"
  2828 proof (rule ccontr)
  2829   assume "l' \<noteq> l"
  2830   obtain s t where "open s" "open t" "l' \<in> s" "l \<in> t" "s \<inter> t = {}"
  2831     using hausdorff [OF `l' \<noteq> l`] by auto
  2832   have "eventually (\<lambda>n. f n \<in> t) sequentially"
  2833     using assms(1) `open t` `l \<in> t` by (rule topological_tendstoD)
  2834   then obtain N where "\<forall>n\<ge>N. f n \<in> t"
  2835     unfolding eventually_sequentially by auto
  2836 
  2837   have "UNIV = {..<N} \<union> {N..}" by auto
  2838   hence "l' islimpt (f ` ({..<N} \<union> {N..}))" using assms(2) by simp
  2839   hence "l' islimpt (f ` {..<N} \<union> f ` {N..})" by (simp add: image_Un)
  2840   hence "l' islimpt (f ` {N..})" by (simp add: islimpt_union_finite)
  2841   then obtain y where "y \<in> f ` {N..}" "y \<in> s" "y \<noteq> l'"
  2842     using `l' \<in> s` `open s` by (rule islimptE)
  2843   then obtain n where "N \<le> n" "f n \<in> s" "f n \<noteq> l'" by auto
  2844   with `\<forall>n\<ge>N. f n \<in> t` have "f n \<in> s \<inter> t" by simp
  2845   with `s \<inter> t = {}` show False by simp
  2846 qed
  2847 
  2848 lemma bolzano_weierstrass_imp_closed:
  2849   fixes s :: "'a::metric_space set" (* TODO: can this be generalized? *)
  2850   assumes "\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t)"
  2851   shows "closed s"
  2852 proof-
  2853   { fix x l assume as: "\<forall>n::nat. x n \<in> s" "(x ---> l) sequentially"
  2854     hence "l \<in> s"
  2855     proof(cases "\<forall>n. x n \<noteq> l")
  2856       case False thus "l\<in>s" using as(1) by auto
  2857     next
  2858       case True note cas = this
  2859       with as(2) have "infinite (range x)" using sequence_infinite_lemma[of x l] by auto
  2860       then obtain l' where "l'\<in>s" "l' islimpt (range x)" using assms[THEN spec[where x="range x"]] as(1) by auto
  2861       thus "l\<in>s" using sequence_unique_limpt[of x l l'] using as cas by auto
  2862     qed  }
  2863   thus ?thesis unfolding closed_sequential_limits by fast
  2864 qed
  2865 
  2866 text {* Hence express everything as an equivalence. *}
  2867 
  2868 lemma compact_eq_heine_borel:
  2869   fixes s :: "'a::metric_space set"
  2870   shows "compact s \<longleftrightarrow>
  2871            (\<forall>f. (\<forall>t \<in> f. open t) \<and> s \<subseteq> (\<Union> f)
  2872                --> (\<exists>f'. f' \<subseteq> f \<and> finite f' \<and> s \<subseteq> (\<Union> f')))" (is "?lhs = ?rhs")
  2873 proof
  2874   assume ?lhs thus ?rhs by (rule compact_imp_heine_borel)
  2875 next
  2876   assume ?rhs
  2877   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x\<in>s. x islimpt t)"
  2878     by (blast intro: heine_borel_imp_bolzano_weierstrass[of s])
  2879   thus ?lhs by (rule bolzano_weierstrass_imp_compact)
  2880 qed
  2881 
  2882 lemma compact_eq_bolzano_weierstrass:
  2883   fixes s :: "'a::metric_space set"
  2884   shows "compact s \<longleftrightarrow> (\<forall>t. infinite t \<and> t \<subseteq> s --> (\<exists>x \<in> s. x islimpt t))" (is "?lhs = ?rhs")
  2885 proof
  2886   assume ?lhs thus ?rhs unfolding compact_eq_heine_borel using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2887 next
  2888   assume ?rhs thus ?lhs by (rule bolzano_weierstrass_imp_compact)
  2889 qed
  2890 
  2891 lemma compact_eq_bounded_closed:
  2892   fixes s :: "'a::heine_borel set"
  2893   shows "compact s \<longleftrightarrow> bounded s \<and> closed s"  (is "?lhs = ?rhs")
  2894 proof
  2895   assume ?lhs thus ?rhs unfolding compact_eq_bolzano_weierstrass using bolzano_weierstrass_imp_bounded bolzano_weierstrass_imp_closed by auto
  2896 next
  2897   assume ?rhs thus ?lhs using bounded_closed_imp_compact by auto
  2898 qed
  2899 
  2900 lemma compact_imp_bounded:
  2901   fixes s :: "'a::metric_space set"
  2902   shows "compact s ==> bounded s"
  2903 proof -
  2904   assume "compact s"
  2905   hence "\<forall>f. (\<forall>t\<in>f. open t) \<and> s \<subseteq> \<Union>f \<longrightarrow> (\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f')"
  2906     by (rule compact_imp_heine_borel)
  2907   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x \<in> s. x islimpt t)"
  2908     using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2909   thus "bounded s"
  2910     by (rule bolzano_weierstrass_imp_bounded)
  2911 qed
  2912 
  2913 lemma compact_imp_closed:
  2914   fixes s :: "'a::metric_space set"
  2915   shows "compact s ==> closed s"
  2916 proof -
  2917   assume "compact s"
  2918   hence "\<forall>f. (\<forall>t\<in>f. open t) \<and> s \<subseteq> \<Union>f \<longrightarrow> (\<exists>f'\<subseteq>f. finite f' \<and> s \<subseteq> \<Union>f')"
  2919     by (rule compact_imp_heine_borel)
  2920   hence "\<forall>t. infinite t \<and> t \<subseteq> s \<longrightarrow> (\<exists>x \<in> s. x islimpt t)"
  2921     using heine_borel_imp_bolzano_weierstrass[of s] by auto
  2922   thus "closed s"
  2923     by (rule bolzano_weierstrass_imp_closed)
  2924 qed
  2925 
  2926 text{* In particular, some common special cases. *}
  2927 
  2928 lemma compact_empty[simp]:
  2929  "compact {}"
  2930   unfolding compact_def
  2931   by simp
  2932 
  2933 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  2934   unfolding subseq_def by simp (* TODO: move somewhere else *)
  2935 
  2936 lemma compact_union [intro]:
  2937   assumes "compact s" and "compact t"
  2938   shows "compact (s \<union> t)"
  2939 proof (rule compactI)
  2940   fix f :: "nat \<Rightarrow> 'a"
  2941   assume "\<forall>n. f n \<in> s \<union> t"
  2942   hence "infinite {n. f n \<in> s \<union> t}" by simp
  2943   hence "infinite {n. f n \<in> s} \<or> infinite {n. f n \<in> t}" by simp
  2944   thus "\<exists>l\<in>s \<union> t. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2945   proof
  2946     assume "infinite {n. f n \<in> s}"
  2947     from infinite_enumerate [OF this]
  2948     obtain q where "subseq q" "\<forall>n. (f \<circ> q) n \<in> s" by auto
  2949     obtain r l where "l \<in> s" "subseq r" "((f \<circ> q \<circ> r) ---> l) sequentially"
  2950       using `compact s` `\<forall>n. (f \<circ> q) n \<in> s` by (rule compactE)
  2951     hence "l \<in> s \<union> t" "subseq (q \<circ> r)" "((f \<circ> (q \<circ> r)) ---> l) sequentially"
  2952       using `subseq q` by (simp_all add: subseq_o o_assoc)
  2953     thus ?thesis by auto
  2954   next
  2955     assume "infinite {n. f n \<in> t}"
  2956     from infinite_enumerate [OF this]
  2957     obtain q where "subseq q" "\<forall>n. (f \<circ> q) n \<in> t" by auto
  2958     obtain r l where "l \<in> t" "subseq r" "((f \<circ> q \<circ> r) ---> l) sequentially"
  2959       using `compact t` `\<forall>n. (f \<circ> q) n \<in> t` by (rule compactE)
  2960     hence "l \<in> s \<union> t" "subseq (q \<circ> r)" "((f \<circ> (q \<circ> r)) ---> l) sequentially"
  2961       using `subseq q` by (simp_all add: subseq_o o_assoc)
  2962     thus ?thesis by auto
  2963   qed
  2964 qed
  2965 
  2966 lemma compact_inter_closed [intro]:
  2967   assumes "compact s" and "closed t"
  2968   shows "compact (s \<inter> t)"
  2969 proof (rule compactI)
  2970   fix f :: "nat \<Rightarrow> 'a"
  2971   assume "\<forall>n. f n \<in> s \<inter> t"
  2972   hence "\<forall>n. f n \<in> s" and "\<forall>n. f n \<in> t" by simp_all
  2973   obtain l r where "l \<in> s" "subseq r" "((f \<circ> r) ---> l) sequentially"
  2974     using `compact s` `\<forall>n. f n \<in> s` by (rule compactE)
  2975   moreover
  2976   from `closed t` `\<forall>n. f n \<in> t` `((f \<circ> r) ---> l) sequentially` have "l \<in> t"
  2977     unfolding closed_sequential_limits o_def by fast
  2978   ultimately show "\<exists>l\<in>s \<inter> t. \<exists>r. subseq r \<and> ((f \<circ> r) ---> l) sequentially"
  2979     by auto
  2980 qed
  2981 
  2982 lemma closed_inter_compact [intro]:
  2983   assumes "closed s" and "compact t"
  2984   shows "compact (s \<inter> t)"
  2985   using compact_inter_closed [of t s] assms
  2986   by (simp add: Int_commute)
  2987 
  2988 lemma compact_inter [intro]:
  2989   assumes "compact s" and "compact t"
  2990   shows "compact (s \<inter> t)"
  2991   using assms by (intro compact_inter_closed compact_imp_closed)
  2992 
  2993 lemma compact_sing [simp]: "compact {a}"
  2994   unfolding compact_def o_def subseq_def
  2995   by (auto simp add: tendsto_const)
  2996 
  2997 lemma compact_insert [simp]:
  2998   assumes "compact s" shows "compact (insert x s)"
  2999 proof -
  3000   have "compact ({x} \<union> s)"
  3001     using compact_sing assms by (rule compact_union)
  3002   thus ?thesis by simp
  3003 qed
  3004 
  3005 lemma finite_imp_compact:
  3006   shows "finite s \<Longrightarrow> compact s"
  3007   by (induct set: finite) simp_all
  3008 
  3009 lemma compact_cball[simp]:
  3010   fixes x :: "'a::heine_borel"
  3011   shows "compact(cball x e)"
  3012   using compact_eq_bounded_closed bounded_cball closed_cball
  3013   by blast
  3014 
  3015 lemma compact_frontier_bounded[intro]:
  3016   fixes s :: "'a::heine_borel set"
  3017   shows "bounded s ==> compact(frontier s)"
  3018   unfolding frontier_def
  3019   using compact_eq_bounded_closed
  3020   by blast
  3021 
  3022 lemma compact_frontier[intro]:
  3023   fixes s :: "'a::heine_borel set"
  3024   shows "compact s ==> compact (frontier s)"
  3025   using compact_eq_bounded_closed compact_frontier_bounded
  3026   by blast
  3027 
  3028 lemma frontier_subset_compact:
  3029   fixes s :: "'a::heine_borel set"
  3030   shows "compact s ==> frontier s \<subseteq> s"
  3031   using frontier_subset_closed compact_eq_bounded_closed
  3032   by blast
  3033 
  3034 lemma open_delete:
  3035   fixes s :: "'a::t1_space set"
  3036   shows "open s \<Longrightarrow> open (s - {x})"
  3037   by (simp add: open_Diff)
  3038 
  3039 text{* Finite intersection property. I could make it an equivalence in fact. *}
  3040 
  3041 lemma compact_imp_fip:
  3042   assumes "compact s"  "\<forall>t \<in> f. closed t"
  3043         "\<forall>f'. finite f' \<and> f' \<subseteq> f --> (s \<inter> (\<Inter> f') \<noteq> {})"
  3044   shows "s \<inter> (\<Inter> f) \<noteq> {}"
  3045 proof
  3046   assume as:"s \<inter> (\<Inter> f) = {}"
  3047   hence "s \<subseteq> \<Union> uminus ` f" by auto
  3048   moreover have "Ball (uminus ` f) open" using open_Diff closed_Diff using assms(2) by auto
  3049   ultimately obtain f' where f':"f' \<subseteq> uminus ` f"  "finite f'"  "s \<subseteq> \<Union>f'" using assms(1)[unfolded compact_eq_heine_borel, THEN spec[where x="(\<lambda>t. - t) ` f"]] by auto
  3050   hence "finite (uminus ` f') \<and> uminus ` f' \<subseteq> f" by(auto simp add: Diff_Diff_Int)
  3051   hence "s \<inter> \<Inter>uminus ` f' \<noteq> {}" using assms(3)[THEN spec[where x="uminus ` f'"]] by auto
  3052   thus False using f'(3) unfolding subset_eq and Union_iff by blast
  3053 qed
  3054 
  3055 
  3056 subsection {* Bounded closed nest property (proof does not use Heine-Borel) *}
  3057 
  3058 lemma bounded_closed_nest:
  3059   assumes "\<forall>n. closed(s n)" "\<forall>n. (s n \<noteq> {})"
  3060   "(\<forall>m n. m \<le> n --> s n \<subseteq> s m)"  "bounded(s 0)"
  3061   shows "\<exists>a::'a::heine_borel. \<forall>n::nat. a \<in> s(n)"
  3062 proof-
  3063   from assms(2) obtain x where x:"\<forall>n::nat. x n \<in> s n" using choice[of "\<lambda>n x. x\<in> s n"] by auto
  3064   from assms(4,1) have *:"compact (s 0)" using bounded_closed_imp_compact[of "s 0"] by auto
  3065 
  3066   then obtain l r where lr:"l\<in>s 0" "subseq r" "((x \<circ> r) ---> l) sequentially"
  3067     unfolding compact_def apply(erule_tac x=x in allE)  using x using assms(3) by blast
  3068 
  3069   { fix n::nat
  3070     { fix e::real assume "e>0"
  3071       with lr(3) obtain N where N:"\<forall>m\<ge>N. dist ((x \<circ> r) m) l < e" unfolding Lim_sequentially by auto
  3072       hence "dist ((x \<circ> r) (max N n)) l < e" by auto
  3073       moreover
  3074       have "r (max N n) \<ge> n" using lr(2) using subseq_bigger[of r "max N n"] by auto
  3075       hence "(x \<circ> r) (max N n) \<in> s n"
  3076         using x apply(erule_tac x=n in allE)
  3077         using x apply(erule_tac x="r (max N n)" in allE)
  3078         using assms(3) apply(erule_tac x=n in allE)apply( erule_tac x="r (max N n)" in allE) by auto
  3079       ultimately have "\<exists>y\<in>s n. dist y l < e" by auto
  3080     }
  3081     hence "l \<in> s n" using closed_approachable[of "s n" l] assms(1) by blast
  3082   }
  3083   thus ?thesis by auto
  3084 qed
  3085 
  3086 text {* Decreasing case does not even need compactness, just completeness. *}
  3087 
  3088 lemma decreasing_closed_nest:
  3089   assumes "\<forall>n. closed(s n)"
  3090           "\<forall>n. (s n \<noteq> {})"
  3091           "\<forall>m n. m \<le> n --> s n \<subseteq> s m"
  3092           "\<forall>e>0. \<exists>n. \<forall>x \<in> (s n). \<forall> y \<in> (s n). dist x y < e"
  3093   shows "\<exists>a::'a::heine_borel. \<forall>n::nat. a \<in> s n"
  3094 proof-
  3095   have "\<forall>n. \<exists> x. x\<in>s n" using assms(2) by auto
  3096   hence "\<exists>t. \<forall>n. t n \<in> s n" using choice[of "\<lambda> n x. x \<in> s n"] by auto
  3097   then obtain t where t: "\<forall>n. t n \<in> s n" by auto
  3098   { fix e::real assume "e>0"
  3099     then obtain N where N:"\<forall>x\<in>s N. \<forall>y\<in>s N. dist x y < e" using assms(4) by auto
  3100     { fix m n ::nat assume "N \<le> m \<and> N \<le> n"
  3101       hence "t m \<in> s N" "t n \<in> s N" using assms(3) t unfolding  subset_eq t by blast+
  3102       hence "dist (t m) (t n) < e" using N by auto
  3103     }
  3104     hence "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (t m) (t n) < e" by auto
  3105   }
  3106   hence  "Cauchy t" unfolding cauchy_def by auto
  3107   then obtain l where l:"(t ---> l) sequentially" using complete_univ unfolding complete_def by auto
  3108   { fix n::nat
  3109     { fix e::real assume "e>0"
  3110       then obtain N::nat where N:"\<forall>n\<ge>N. dist (t n) l < e" using l[unfolded Lim_sequentially] by auto
  3111       have "t (max n N) \<in> s n" using assms(3) unfolding subset_eq apply(erule_tac x=n in allE) apply (erule_tac x="max n N" in allE) using t by auto
  3112       hence "\<exists>y\<in>s n. dist y l < e" apply(rule_tac x="t (max n N)" in bexI) using N by auto
  3113     }
  3114     hence "l \<in> s n" using closed_approachable[of "s n" l] assms(1) by auto
  3115   }
  3116   then show ?thesis by auto
  3117 qed
  3118 
  3119 text {* Strengthen it to the intersection actually being a singleton. *}
  3120 
  3121 lemma decreasing_closed_nest_sing:
  3122   fixes s :: "nat \<Rightarrow> 'a::heine_borel set"
  3123   assumes "\<forall>n. closed(s n)"
  3124           "\<forall>n. s n \<noteq> {}"
  3125           "\<forall>m n. m \<le> n --> s n \<subseteq> s m"
  3126           "\<forall>e>0. \<exists>n. \<forall>x \<in> (s n). \<forall> y\<in>(s n). dist x y < e"
  3127   shows "\<exists>a. \<Inter>(range s) = {a}"
  3128 proof-
  3129   obtain a where a:"\<forall>n. a \<in> s n" using decreasing_closed_nest[of s] using assms by auto
  3130   { fix b assume b:"b \<in> \<Inter>(range s)"
  3131     { fix e::real assume "e>0"
  3132       hence "dist a b < e" using assms(4 )using b using a by blast
  3133     }
  3134     hence "dist a b = 0" by (metis dist_eq_0_iff dist_nz less_le)
  3135   }
  3136   with a have "\<Inter>(range s) = {a}" unfolding image_def by auto
  3137   thus ?thesis ..
  3138 qed
  3139 
  3140 text{* Cauchy-type criteria for uniform convergence. *}
  3141 
  3142 lemma uniformly_convergent_eq_cauchy: fixes s::"nat \<Rightarrow> 'b \<Rightarrow> 'a::heine_borel" shows
  3143  "(\<exists>l. \<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x --> dist(s n x)(l x) < e) \<longleftrightarrow>
  3144   (\<forall>e>0. \<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  --> dist (s m x) (s n x) < e)" (is "?lhs = ?rhs")
  3145 proof(rule)
  3146   assume ?lhs
  3147   then obtain l where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e" by auto
  3148   { fix e::real assume "e>0"
  3149     then obtain N::nat where N:"\<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l x) < e / 2" using l[THEN spec[where x="e/2"]] by auto
  3150     { fix n m::nat and x::"'b" assume "N \<le> m \<and> N \<le> n \<and> P x"
  3151       hence "dist (s m x) (s n x) < e"
  3152         using N[THEN spec[where x=m], THEN spec[where x=x]]
  3153         using N[THEN spec[where x=n], THEN spec[where x=x]]
  3154         using dist_triangle_half_l[of "s m x" "l x" e "s n x"] by auto  }
  3155     hence "\<exists>N. \<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x  --> dist (s m x) (s n x) < e"  by auto  }
  3156   thus ?rhs by auto
  3157 next
  3158   assume ?rhs
  3159   hence "\<forall>x. P x \<longrightarrow> Cauchy (\<lambda>n. s n x)" unfolding cauchy_def apply auto by (erule_tac x=e in allE)auto
  3160   then obtain l where l:"\<forall>x. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l x) sequentially" unfolding convergent_eq_cauchy[THEN sym]
  3161     using choice[of "\<lambda>x l. P x \<longrightarrow> ((\<lambda>n. s n x) ---> l) sequentially"] by auto
  3162   { fix e::real assume "e>0"
  3163     then obtain N where N:"\<forall>m n x. N \<le> m \<and> N \<le> n \<and> P x \<longrightarrow> dist (s m x) (s n x) < e/2"
  3164       using `?rhs`[THEN spec[where x="e/2"]] by auto
  3165     { fix x assume "P x"
  3166       then obtain M where M:"\<forall>n\<ge>M. dist (s n x) (l x) < e/2"
  3167         using l[THEN spec[where x=x], unfolded Lim_sequentially] using `e>0` by(auto elim!: allE[where x="e/2"])
  3168       fix n::nat assume "n\<ge>N"
  3169       hence "dist(s n x)(l x) < e"  using `P x`and N[THEN spec[where x=n], THEN spec[where x="N+M"], THEN spec[where x=x]]
  3170         using M[THEN spec[where x="N+M"]] and dist_triangle_half_l[of "s n x" "s (N+M) x" e "l x"] by (auto simp add: dist_commute)  }
  3171     hence "\<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist(s n x)(l x) < e" by auto }
  3172   thus ?lhs by auto
  3173 qed
  3174 
  3175 lemma uniformly_cauchy_imp_uniformly_convergent:
  3176   fixes s :: "nat \<Rightarrow> 'a \<Rightarrow> 'b::heine_borel"
  3177   assumes "\<forall>e>0.\<exists>N. \<forall>m (n::nat) x. N \<le> m \<and> N \<le> n \<and> P x --> dist(s m x)(s n x) < e"
  3178           "\<forall>x. P x --> (\<forall>e>0. \<exists>N. \<forall>n. N \<le> n --> dist(s n x)(l x) < e)"
  3179   shows "\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x --> dist(s n x)(l x) < e"
  3180 proof-
  3181   obtain l' where l:"\<forall>e>0. \<exists>N. \<forall>n x. N \<le> n \<and> P x \<longrightarrow> dist (s n x) (l' x) < e"
  3182     using assms(1) unfolding uniformly_convergent_eq_cauchy[THEN sym] by auto
  3183   moreover
  3184   { fix x assume "P x"
  3185     hence "l x = l' x" using tendsto_unique[OF trivial_limit_sequentially, of "\<lambda>n. s n x" "l x" "l' x"]
  3186       using l and assms(2) unfolding Lim_sequentially by blast  }
  3187   ultimately show ?thesis by auto
  3188 qed
  3189 
  3190 
  3191 subsection {* Continuity *}
  3192 
  3193 text {* Define continuity over a net to take in restrictions of the set. *}
  3194 
  3195 definition
  3196   continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  3197   where "continuous net f \<longleftrightarrow> (f ---> f(netlimit net)) net"
  3198 
  3199 lemma continuous_trivial_limit:
  3200  "trivial_limit net ==> continuous net f"
  3201   unfolding continuous_def tendsto_def trivial_limit_eq by auto
  3202 
  3203 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f(x)) (at x within s)"
  3204   unfolding continuous_def
  3205   unfolding tendsto_def
  3206   using netlimit_within[of x s]
  3207   by (cases "trivial_limit (at x within s)") (auto simp add: trivial_limit_eventually)
  3208 
  3209 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> (f ---> f(x)) (at x)"
  3210   using continuous_within [of x UNIV f] by (simp add: within_UNIV)
  3211 
  3212 lemma continuous_at_within:
  3213   assumes "continuous (at x) f"  shows "continuous (at x within s) f"
  3214   using assms unfolding continuous_at continuous_within
  3215   by (rule Lim_at_within)
  3216 
  3217 text{* Derive the epsilon-delta forms, which we often use as "definitions" *}
  3218 
  3219 lemma continuous_within_eps_delta:
  3220   "continuous (at x within s) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. \<forall>x'\<in> s.  dist x' x < d --> dist (f x') (f x) < e)"
  3221   unfolding continuous_within and Lim_within
  3222   apply auto unfolding dist_nz[THEN sym] apply(auto elim!:allE) apply(rule_tac x=d in exI) by auto
  3223 
  3224 lemma continuous_at_eps_delta: "continuous (at x) f \<longleftrightarrow>  (\<forall>e>0. \<exists>d>0.
  3225                            \<forall>x'. dist x' x < d --> dist(f x')(f x) < e)"
  3226   using continuous_within_eps_delta[of x UNIV f]
  3227   unfolding within_UNIV by blast
  3228 
  3229 text{* Versions in terms of open balls. *}
  3230 
  3231 lemma continuous_within_ball:
  3232  "continuous (at x within s) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0.
  3233                             f ` (ball x d \<inter> s) \<subseteq> ball (f x) e)" (is "?lhs = ?rhs")
  3234 proof
  3235   assume ?lhs
  3236   { fix e::real assume "e>0"
  3237     then obtain d where d: "d>0" "\<forall>xa\<in>s. 0 < dist xa x \<and> dist xa x < d \<longrightarrow> dist (f xa) (f x) < e"
  3238       using `?lhs`[unfolded continuous_within Lim_within] by auto
  3239     { fix y assume "y\<in>f ` (ball x d \<inter> s)"
  3240       hence "y \<in> ball (f x) e" using d(2) unfolding dist_nz[THEN sym]
  3241         apply (auto simp add: dist_commute) apply(erule_tac x=xa in ballE) apply auto using `e>0` by auto
  3242     }
  3243     hence "\<exists>d>0. f ` (ball x d \<inter> s) \<subseteq> ball (f x) e" using `d>0` unfolding subset_eq ball_def by (auto simp add: dist_commute)  }
  3244   thus ?rhs by auto
  3245 next
  3246   assume ?rhs thus ?lhs unfolding continuous_within Lim_within ball_def subset_eq
  3247     apply (auto simp add: dist_commute) apply(erule_tac x=e in allE) by auto
  3248 qed
  3249 
  3250 lemma continuous_at_ball:
  3251   "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0. f ` (ball x d) \<subseteq> ball (f x) e)" (is "?lhs = ?rhs")
  3252 proof
  3253   assume ?lhs thus ?rhs unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  3254     apply auto apply(erule_tac x=e in allE) apply auto apply(rule_tac x=d in exI) apply auto apply(erule_tac x=xa in allE) apply (auto simp add: dist_commute dist_nz)
  3255     unfolding dist_nz[THEN sym] by auto
  3256 next
  3257   assume ?rhs thus ?lhs unfolding continuous_at Lim_at subset_eq Ball_def Bex_def image_iff mem_ball
  3258     apply auto apply(erule_tac x=e in allE) apply auto apply(rule_tac x=d in exI) apply auto apply(erule_tac x="f xa" in allE) by (auto simp add: dist_commute dist_nz)
  3259 qed
  3260 
  3261 text{* Define setwise continuity in terms of limits within the set. *}
  3262 
  3263 definition
  3264   continuous_on ::
  3265     "'a set \<Rightarrow> ('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  3266 where
  3267   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  3268 
  3269 lemma continuous_on_topological:
  3270   "continuous_on s f \<longleftrightarrow>
  3271     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow>
  3272       (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  3273 unfolding continuous_on_def tendsto_def
  3274 unfolding Limits.eventually_within eventually_at_topological
  3275 by (intro ball_cong [OF refl] all_cong imp_cong ex_cong conj_cong refl) auto
  3276 
  3277 lemma continuous_on_iff:
  3278   "continuous_on s f \<longleftrightarrow>
  3279     (\<forall>x\<in>s. \<forall>e>0. \<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  3280 unfolding continuous_on_def Lim_within
  3281 apply (intro ball_cong [OF refl] all_cong ex_cong)
  3282 apply (rename_tac y, case_tac "y = x", simp)
  3283 apply (simp add: dist_nz)
  3284 done
  3285 
  3286 definition
  3287   uniformly_continuous_on ::
  3288     "'a set \<Rightarrow> ('a::metric_space \<Rightarrow> 'b::metric_space) \<Rightarrow> bool"
  3289 where
  3290   "uniformly_continuous_on s f \<longleftrightarrow>
  3291     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  3292 
  3293 text{* Some simple consequential lemmas. *}
  3294 
  3295 lemma uniformly_continuous_imp_continuous:
  3296  " uniformly_continuous_on s f ==> continuous_on s f"
  3297   unfolding uniformly_continuous_on_def continuous_on_iff by blast
  3298 
  3299 lemma continuous_at_imp_continuous_within:
  3300  "continuous (at x) f ==> continuous (at x within s) f"
  3301   unfolding continuous_within continuous_at using Lim_at_within by auto
  3302 
  3303 lemma Lim_trivial_limit: "trivial_limit net \<Longrightarrow> (f ---> l) net"
  3304 unfolding tendsto_def by (simp add: trivial_limit_eq)
  3305 
  3306 lemma continuous_at_imp_continuous_on:
  3307   assumes "\<forall>x\<in>s. continuous (at x) f"
  3308   shows "continuous_on s f"
  3309 unfolding continuous_on_def
  3310 proof
  3311   fix x assume "x \<in> s"
  3312   with assms have *: "(f ---> f (netlimit (at x))) (at x)"
  3313     unfolding continuous_def by simp
  3314   have "(f ---> f x) (at x)"
  3315   proof (cases "trivial_limit (at x)")
  3316     case True thus ?thesis
  3317       by (rule Lim_trivial_limit)
  3318   next
  3319     case False
  3320     hence 1: "netlimit (at x) = x"
  3321       using netlimit_within [of x UNIV]
  3322       by (simp add: within_UNIV)
  3323     with * show ?thesis by simp
  3324   qed
  3325   thus "(f ---> f x) (at x within s)"
  3326     by (rule Lim_at_within)
  3327 qed
  3328 
  3329 lemma continuous_on_eq_continuous_within:
  3330   "continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. continuous (at x within s) f)"
  3331 unfolding continuous_on_def continuous_def
  3332 apply (rule ball_cong [OF refl])
  3333 apply (case_tac "trivial_limit (at x within s)")
  3334 apply (simp add: Lim_trivial_limit)
  3335 apply (simp add: netlimit_within)
  3336 done
  3337 
  3338 lemmas continuous_on = continuous_on_def -- "legacy theorem name"
  3339 
  3340 lemma continuous_on_eq_continuous_at:
  3341   shows "open s ==> (continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. continuous (at x) f))"
  3342   by (auto simp add: continuous_on continuous_at Lim_within_open)
  3343 
  3344 lemma continuous_within_subset:
  3345  "continuous (at x within s) f \<Longrightarrow> t \<subseteq> s
  3346              ==> continuous (at x within t) f"
  3347   unfolding continuous_within by(metis Lim_within_subset)
  3348 
  3349 lemma continuous_on_subset:
  3350   shows "continuous_on s f \<Longrightarrow> t \<subseteq> s ==> continuous_on t f"
  3351   unfolding continuous_on by (metis subset_eq Lim_within_subset)
  3352 
  3353 lemma continuous_on_interior:
  3354   shows "continuous_on s f \<Longrightarrow> x \<in> interior s ==> continuous (at x) f"
  3355 unfolding interior_def
  3356 apply simp
  3357 by (meson continuous_on_eq_continuous_at continuous_on_subset)
  3358 
  3359 lemma continuous_on_eq:
  3360   "(\<forall>x \<in> s. f x = g x) \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on s g"
  3361   unfolding continuous_on_def tendsto_def Limits.eventually_within
  3362   by simp
  3363 
  3364 text {* Characterization of various kinds of continuity in terms of sequences. *}
  3365 
  3366 (* \<longrightarrow> could be generalized, but \<longleftarrow> requires metric space *)
  3367 lemma continuous_within_sequentially:
  3368   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  3369   shows "continuous (at a within s) f \<longleftrightarrow>
  3370                 (\<forall>x. (\<forall>n::nat. x n \<in> s) \<and> (x ---> a) sequentially
  3371                      --> ((f o x) ---> f a) sequentially)" (is "?lhs = ?rhs")
  3372 proof
  3373   assume ?lhs
  3374   { fix x::"nat \<Rightarrow> 'a" assume x:"\<forall>n. x n \<in> s" "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (x n) a < e"
  3375     fix e::real assume "e>0"
  3376     from `?lhs` obtain d where "d>0" and d:"\<forall>x\<in>s. 0 < dist x a \<and> dist x a < d \<longrightarrow> dist (f x) (f a) < e" unfolding continuous_within Lim_within using `e>0` by auto
  3377     from x(2) `d>0` obtain N where N:"\<forall>n\<ge>N. dist (x n) a < d" by auto
  3378     hence "\<exists>N. \<forall>n\<ge>N. dist ((f \<circ> x) n) (f a) < e"
  3379       apply(rule_tac  x=N in exI) using N d  apply auto using x(1)
  3380       apply(erule_tac x=n in allE) apply(erule_tac x=n in allE)
  3381       apply(erule_tac x="x n" in ballE)  apply auto unfolding dist_nz[THEN sym] apply auto using `e>0` by auto
  3382   }
  3383   thus ?rhs unfolding continuous_within unfolding Lim_sequentially by simp
  3384 next
  3385   assume ?rhs
  3386   { fix e::real assume "e>0"
  3387     assume "\<not> (\<exists>d>0. \<forall>x\<in>s. 0 < dist x a \<and> dist x a < d \<longrightarrow> dist (f x) (f a) < e)"
  3388     hence "\<forall>d. \<exists>x. d>0 \<longrightarrow> x\<in>s \<and> (0 < dist x a \<and> dist x a < d \<and> \<not> dist (f x) (f a) < e)" by blast
  3389     then obtain x where x:"\<forall>d>0. x d \<in> s \<and> (0 < dist (x d) a \<and> dist (x d) a < d \<and> \<not> dist (f (x d)) (f a) < e)"
  3390       using choice[of "\<lambda>d x.0<d \<longrightarrow> x\<in>s \<and> (0 < dist x a \<and> dist x a < d \<and> \<not> dist (f x) (f a) < e)"] by auto
  3391     { fix d::real assume "d>0"
  3392       hence "\<exists>N::nat. inverse (real (N + 1)) < d" using real_arch_inv[of d] by (auto, rule_tac x="n - 1" in exI)auto
  3393       then obtain N::nat where N:"inverse (real (N + 1)) < d" by auto
  3394       { fix n::nat assume n:"n\<ge>N"
  3395         hence "dist (x (inverse (real (n + 1)))) a < inverse (real (n + 1))" using x[THEN spec[where x="inverse (real (n + 1))"]] by auto
  3396         moreover have "inverse (real (n + 1)) < d" using N n by (auto, metis Suc_le_mono le_SucE less_imp_inverse_less nat_le_real_less order_less_trans real_of_nat_Suc real_of_nat_Suc_gt_zero)
  3397         ultimately have "dist (x (inverse (real (n + 1)))) a < d" by auto
  3398       }
  3399       hence "\<exists>N::nat. \<forall>n\<ge>N. dist (x (inverse (real (n + 1)))) a < d" by auto
  3400     }
  3401     hence "(\<forall>n::nat. x (inverse (real (n + 1))) \<in> s) \<and> (\<forall>e>0. \<exists>N::nat. \<forall>n\<ge>N. dist (x (inverse (real (n + 1)))) a < e)" using x by auto
  3402     hence "\<forall>e>0. \<exists>N::nat. \<forall>n\<ge>N. dist (f (x (inverse (real (n + 1))))) (f a) < e"  using `?rhs`[THEN spec[where x="\<lambda>n::nat. x (inverse (real (n+1)))"], unfolded Lim_sequentially] by auto
  3403     hence "False" apply(erule_tac x=e in allE) using `e>0` using x by auto
  3404   }
  3405   thus ?lhs  unfolding continuous_within unfolding Lim_within unfolding Lim_sequentially by blast
  3406 qed
  3407 
  3408 lemma continuous_at_sequentially:
  3409   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  3410   shows "continuous (at a) f \<longleftrightarrow> (\<forall>x. (x ---> a) sequentially
  3411                   --> ((f o x) ---> f a) sequentially)"
  3412   using continuous_within_sequentially[of a UNIV f] unfolding within_UNIV by auto
  3413 
  3414 lemma continuous_on_sequentially:
  3415   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  3416   shows "continuous_on s f \<longleftrightarrow>
  3417     (\<forall>x. \<forall>a \<in> s. (\<forall>n. x(n) \<in> s) \<and> (x ---> a) sequentially
  3418                     --> ((f o x) ---> f(a)) sequentially)" (is "?lhs = ?rhs")
  3419 proof
  3420   assume ?rhs thus ?lhs using continuous_within_sequentially[of _ s f] unfolding continuous_on_eq_continuous_within by auto
  3421 next
  3422   assume ?lhs thus ?rhs unfolding continuous_on_eq_continuous_within using continuous_within_sequentially[of _ s f] by auto
  3423 qed
  3424 
  3425 lemma uniformly_continuous_on_sequentially':
  3426   "uniformly_continuous_on s f \<longleftrightarrow> (\<forall>x y. (\<forall>n. x n \<in> s) \<and> (\<forall>n. y n \<in> s) \<and>
  3427                     ((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially
  3428                     \<longrightarrow> ((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially)" (is "?lhs = ?rhs")
  3429 proof
  3430   assume ?lhs
  3431   { fix x y assume x:"\<forall>n. x n \<in> s" and y:"\<forall>n. y n \<in> s" and xy:"((\<lambda>n. dist (x n) (y n)) ---> 0) sequentially"
  3432     { fix e::real assume "e>0"
  3433       then obtain d where "d>0" and d:"\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e"
  3434         using `?lhs`[unfolded uniformly_continuous_on_def, THEN spec[where x=e]] by auto
  3435       obtain N where N:"\<forall>n\<ge>N. dist (x n) (y n) < d" using xy[unfolded Lim_sequentially dist_norm] and `d>0` by auto
  3436       { fix n assume "n\<ge>N"
  3437         hence "dist (f (x n)) (f (y n)) < e"
  3438           using N[THEN spec[where x=n]] using d[THEN bspec[where x="x n"], THEN bspec[where x="y n"]] using x and y
  3439           unfolding dist_commute by simp  }
  3440       hence "\<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e"  by auto  }
  3441     hence "((\<lambda>n. dist (f(x n)) (f(y n))) ---> 0) sequentially" unfolding Lim_sequentially and dist_real_def by auto  }
  3442   thus ?rhs by auto
  3443 next
  3444   assume ?rhs
  3445   { assume "\<not> ?lhs"
  3446     then obtain e where "e>0" "\<forall>d>0. \<exists>x\<in>s. \<exists>x'\<in>s. dist x' x < d \<and> \<not> dist (f x') (f x) < e" unfolding uniformly_continuous_on_def by auto
  3447     then obtain fa where fa:"\<forall>x.  0 < x \<longrightarrow> fst (fa x) \<in> s \<and> snd (fa x) \<in> s \<and> dist (fst (fa x)) (snd (fa x)) < x \<and> \<not> dist (f (fst (fa x))) (f (snd (fa x))) < e"
  3448       using choice[of "\<lambda>d x. d>0 \<longrightarrow> fst x \<in> s \<and> snd x \<in> s \<and> dist (snd x) (fst x) < d \<and> \<not> dist (f (snd x)) (f (fst x)) < e"] unfolding Bex_def
  3449       by (auto simp add: dist_commute)
  3450     def x \<equiv> "\<lambda>n::nat. fst (fa (inverse (real n + 1)))"
  3451     def y \<equiv> "\<lambda>n::nat. snd (fa (inverse (real n + 1)))"
  3452     have xyn:"\<forall>n. x n \<in> s \<and> y n \<in> s" and xy0:"\<forall>n. dist (x n) (y n) < inverse (real n + 1)" and fxy:"\<forall>n. \<not> dist (f (x n)) (f (y n)) < e"
  3453       unfolding x_def and y_def using fa by auto
  3454     { fix e::real assume "e>0"
  3455       then obtain N::nat where "N \<noteq> 0" and N:"0 < inverse (real N) \<and> inverse (real N) < e" unfolding real_arch_inv[of e]   by auto
  3456       { fix n::nat assume "n\<ge>N"
  3457         hence "inverse (real n + 1) < inverse (real N)" using real_of_nat_ge_zero and `N\<noteq>0` by auto
  3458         also have "\<dots> < e" using N by auto
  3459         finally have "inverse (real n + 1) < e" by auto
  3460         hence "dist (x n) (y n) < e" using xy0[THEN spec[where x=n]] by auto  }
  3461       hence "\<exists>N. \<forall>n\<ge>N. dist (x n) (y n) < e" by auto  }
  3462     hence "\<forall>e>0. \<exists>N. \<forall>n\<ge>N. dist (f (x n)) (f (y n)) < e" using `?rhs`[THEN spec[where x=x], THEN spec[where x=y]] and xyn unfolding Lim_sequentially dist_real_def by auto
  3463     hence False using fxy and `e>0` by auto  }
  3464   thus ?lhs unfolding uniformly_continuous_on_def by blast
  3465 qed
  3466 
  3467 lemma uniformly_continuous_on_sequentially:
  3468   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector"
  3469   shows "uniformly_continuous_on s f \<longleftrightarrow> (\<forall>x y. (\<forall>n. x n \<in> s) \<and> (\<forall>n. y n \<in> s) \<and>
  3470                     ((\<lambda>n. x n - y n) ---> 0) sequentially
  3471                     \<longrightarrow> ((\<lambda>n. f(x n) - f(y n)) ---> 0) sequentially)" (is "?lhs = ?rhs")
  3472 (* BH: maybe the previous lemma should replace this one? *)
  3473 unfolding uniformly_continuous_on_sequentially'
  3474 unfolding dist_norm tendsto_norm_zero_iff ..
  3475 
  3476 text{* The usual transformation theorems. *}
  3477 
  3478 lemma continuous_transform_within:
  3479   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3480   assumes "0 < d" "x \<in> s" "\<forall>x' \<in> s. dist x' x < d --> f x' = g x'"
  3481           "continuous (at x within s) f"
  3482   shows "continuous (at x within s) g"
  3483 unfolding continuous_within
  3484 proof (rule Lim_transform_within)
  3485   show "0 < d" by fact
  3486   show "\<forall>x'\<in>s. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  3487     using assms(3) by auto
  3488   have "f x = g x"
  3489     using assms(1,2,3) by auto
  3490   thus "(f ---> g x) (at x within s)"
  3491     using assms(4) unfolding continuous_within by simp
  3492 qed
  3493 
  3494 lemma continuous_transform_at:
  3495   fixes f g :: "'a::metric_space \<Rightarrow> 'b::topological_space"
  3496   assumes "0 < d" "\<forall>x'. dist x' x < d --> f x' = g x'"
  3497           "continuous (at x) f"
  3498   shows "continuous (at x) g"
  3499   using continuous_transform_within [of d x UNIV f g] assms
  3500   by (simp add: within_UNIV)
  3501 
  3502 text{* Combination results for pointwise continuity. *}
  3503 
  3504 lemma continuous_const: "continuous net (\<lambda>x. c)"
  3505   by (auto simp add: continuous_def tendsto_const)
  3506 
  3507 lemma continuous_cmul:
  3508   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3509   shows "continuous net f ==> continuous net (\<lambda>x. c *\<^sub>R f x)"
  3510   by (auto simp add: continuous_def intro: tendsto_intros)
  3511 
  3512 lemma continuous_neg:
  3513   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3514   shows "continuous net f ==> continuous net (\<lambda>x. -(f x))"
  3515   by (auto simp add: continuous_def tendsto_minus)
  3516 
  3517 lemma continuous_add:
  3518   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3519   shows "continuous net f \<Longrightarrow> continuous net g \<Longrightarrow> continuous net (\<lambda>x. f x + g x)"
  3520   by (auto simp add: continuous_def tendsto_add)
  3521 
  3522 lemma continuous_sub:
  3523   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  3524   shows "continuous net f \<Longrightarrow> continuous net g \<Longrightarrow> continuous net (\<lambda>x. f x - g x)"
  3525   by (auto simp add: continuous_def tendsto_diff)
  3526 
  3527 
  3528 text{* Same thing for setwise continuity. *}
  3529 
  3530 lemma continuous_on_const:
  3531  "continuous_on s (\<lambda>x. c)"
  3532   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3533 
  3534 lemma continuous_on_cmul:
  3535   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3536   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. c *\<^sub>R (f x))"
  3537   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3538 
  3539 lemma continuous_on_neg:
  3540   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3541   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
  3542   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3543 
  3544 lemma continuous_on_add:
  3545   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3546   shows "continuous_on s f \<Longrightarrow> continuous_on s g
  3547            \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
  3548   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3549 
  3550 lemma continuous_on_sub:
  3551   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  3552   shows "continuous_on s f \<Longrightarrow> continuous_on s g
  3553            \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
  3554   unfolding continuous_on_def by (auto intro: tendsto_intros)
  3555 
  3556 text{* Same thing for uniform continuity, using sequential formulations. *}
  3557 
  3558 lemma uniformly_continuous_on_const:
  3559  "uniformly_continuous_on s (\<lambda>x. c)"
  3560   unfolding uniformly_continuous_on_def by simp
  3561 
  3562 lemma uniformly_continuous_on_cmul:
  3563   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3564   assumes "uniformly_continuous_on s f"
  3565   shows "uniformly_continuous_on s (\<lambda>x. c *\<^sub>R f(x))"
  3566 proof-
  3567   { fix x y assume "((\<lambda>n. f (x n) - f (y n)) ---> 0) sequentially"
  3568     hence "((\<lambda>n. c *\<^sub>R f (x n) - c *\<^sub>R f (y n)) ---> 0) sequentially"
  3569       using tendsto_scaleR [OF tendsto_const, of "(\<lambda>n. f (x n) - f (y n))" 0 sequentially c]
  3570       unfolding scaleR_zero_right scaleR_right_diff_distrib by auto
  3571   }
  3572   thus ?thesis using assms unfolding uniformly_continuous_on_sequentially'
  3573     unfolding dist_norm tendsto_norm_zero_iff by auto
  3574 qed
  3575 
  3576 lemma dist_minus:
  3577   fixes x y :: "'a::real_normed_vector"
  3578   shows "dist (- x) (- y) = dist x y"
  3579   unfolding dist_norm minus_diff_minus norm_minus_cancel ..
  3580 
  3581 lemma uniformly_continuous_on_neg:
  3582   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3583   shows "uniformly_continuous_on s f
  3584          ==> uniformly_continuous_on s (\<lambda>x. -(f x))"
  3585   unfolding uniformly_continuous_on_def dist_minus .
  3586 
  3587 lemma uniformly_continuous_on_add:
  3588   fixes f g :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3589   assumes "uniformly_continuous_on s f" "uniformly_continuous_on s g"
  3590   shows "uniformly_continuous_on s (\<lambda>x. f x + g x)"
  3591 proof-
  3592   {  fix x y assume "((\<lambda>n. f (x n) - f (y n)) ---> 0) sequentially"
  3593                     "((\<lambda>n. g (x n) - g (y n)) ---> 0) sequentially"
  3594     hence "((\<lambda>xa. f (x xa) - f (y xa) + (g (x xa) - g (y xa))) ---> 0 + 0) sequentially"
  3595       using tendsto_add[of "\<lambda> n. f (x n) - f (y n)" 0  sequentially "\<lambda> n. g (x n) - g (y n)" 0] by auto
  3596     hence "((\<lambda>n. f (x n) + g (x n) - (f (y n) + g (y n))) ---> 0) sequentially" unfolding Lim_sequentially and add_diff_add [symmetric] by auto  }
  3597   thus ?thesis using assms unfolding uniformly_continuous_on_sequentially'
  3598     unfolding dist_norm tendsto_norm_zero_iff by auto
  3599 qed
  3600 
  3601 lemma uniformly_continuous_on_sub:
  3602   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3603   shows "uniformly_continuous_on s f \<Longrightarrow> uniformly_continuous_on s g
  3604            ==> uniformly_continuous_on s  (\<lambda>x. f x - g x)"
  3605   unfolding ab_diff_minus
  3606   using uniformly_continuous_on_add[of s f "\<lambda>x. - g x"]
  3607   using uniformly_continuous_on_neg[of s g] by auto
  3608 
  3609 text{* Identity function is continuous in every sense. *}
  3610 
  3611 lemma continuous_within_id:
  3612  "continuous (at a within s) (\<lambda>x. x)"
  3613   unfolding continuous_within by (rule Lim_at_within [OF LIM_ident])
  3614 
  3615 lemma continuous_at_id:
  3616  "continuous (at a) (\<lambda>x. x)"
  3617   unfolding continuous_at by (rule LIM_ident)
  3618 
  3619 lemma continuous_on_id:
  3620  "continuous_on s (\<lambda>x. x)"
  3621   unfolding continuous_on_def by (auto intro: tendsto_ident_at_within)
  3622 
  3623 lemma uniformly_continuous_on_id:
  3624  "uniformly_continuous_on s (\<lambda>x. x)"
  3625   unfolding uniformly_continuous_on_def by auto
  3626 
  3627 text{* Continuity of all kinds is preserved under composition. *}
  3628 
  3629 lemma continuous_within_topological:
  3630   "continuous (at x within s) f \<longleftrightarrow>
  3631     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow>
  3632       (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  3633 unfolding continuous_within
  3634 unfolding tendsto_def Limits.eventually_within eventually_at_topological
  3635 by (intro ball_cong [OF refl] all_cong imp_cong ex_cong conj_cong refl) auto
  3636 
  3637 lemma continuous_within_compose:
  3638   assumes "continuous (at x within s) f"
  3639   assumes "continuous (at (f x) within f ` s) g"
  3640   shows "continuous (at x within s) (g o f)"
  3641 using assms unfolding continuous_within_topological by simp metis
  3642 
  3643 lemma continuous_at_compose:
  3644   assumes "continuous (at x) f"  "continuous (at (f x)) g"
  3645   shows "continuous (at x) (g o f)"
  3646 proof-
  3647   have " continuous (at (f x) within range f) g" using assms(2) using continuous_within_subset[of "f x" UNIV g "range f", unfolded within_UNIV] by auto
  3648   thus ?thesis using assms(1) using continuous_within_compose[of x UNIV f g, unfolded within_UNIV] by auto
  3649 qed
  3650 
  3651 lemma continuous_on_compose:
  3652   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  3653   unfolding continuous_on_topological by simp metis
  3654 
  3655 lemma uniformly_continuous_on_compose:
  3656   assumes "uniformly_continuous_on s f"  "uniformly_continuous_on (f ` s) g"
  3657   shows "uniformly_continuous_on s (g o f)"
  3658 proof-
  3659   { fix e::real assume "e>0"
  3660     then obtain d where "d>0" and d:"\<forall>x\<in>f ` s. \<forall>x'\<in>f ` s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e" using assms(2) unfolding uniformly_continuous_on_def by auto
  3661     obtain d' where "d'>0" "\<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d' \<longrightarrow> dist (f x') (f x) < d" using `d>0` using assms(1) unfolding uniformly_continuous_on_def by auto
  3662     hence "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist ((g \<circ> f) x') ((g \<circ> f) x) < e" using `d>0` using d by auto  }
  3663   thus ?thesis using assms unfolding uniformly_continuous_on_def by auto
  3664 qed
  3665 
  3666 text{* Continuity in terms of open preimages. *}
  3667 
  3668 lemma continuous_at_open:
  3669   shows "continuous (at x) f \<longleftrightarrow> (\<forall>t. open t \<and> f x \<in> t --> (\<exists>s. open s \<and> x \<in> s \<and> (\<forall>x' \<in> s. (f x') \<in> t)))"
  3670 unfolding continuous_within_topological [of x UNIV f, unfolded within_UNIV]
  3671 unfolding imp_conjL by (intro all_cong imp_cong ex_cong conj_cong refl) auto
  3672 
  3673 lemma continuous_on_open:
  3674   shows "continuous_on s f \<longleftrightarrow>
  3675         (\<forall>t. openin (subtopology euclidean (f ` s)) t
  3676             --> openin (subtopology euclidean s) {x \<in> s. f x \<in> t})" (is "?lhs = ?rhs")
  3677 proof (safe)
  3678   fix t :: "'b set"
  3679   assume 1: "continuous_on s f"
  3680   assume 2: "openin (subtopology euclidean (f ` s)) t"
  3681   from 2 obtain B where B: "open B" and t: "t = f ` s \<inter> B"
  3682     unfolding openin_open by auto
  3683   def U == "\<Union>{A. open A \<and> (\<forall>x\<in>s. x \<in> A \<longrightarrow> f x \<in> B)}"
  3684   have "open U" unfolding U_def by (simp add: open_Union)
  3685   moreover have "\<forall>x\<in>s. x \<in> U \<longleftrightarrow> f x \<in> t"
  3686   proof (intro ballI iffI)
  3687     fix x assume "x \<in> s" and "x \<in> U" thus "f x \<in> t"
  3688       unfolding U_def t by auto
  3689   next
  3690     fix x assume "x \<in> s" and "f x \<in> t"
  3691     hence "x \<in> s" and "f x \<in> B"
  3692       unfolding t by auto
  3693     with 1 B obtain A where "open A" "x \<in> A" "\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B"
  3694       unfolding t continuous_on_topological by metis
  3695     then show "x \<in> U"
  3696       unfolding U_def by auto
  3697   qed
  3698   ultimately have "open U \<and> {x \<in> s. f x \<in> t} = s \<inter> U" by auto
  3699   then show "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3700     unfolding openin_open by fast
  3701 next
  3702   assume "?rhs" show "continuous_on s f"
  3703   unfolding continuous_on_topological
  3704   proof (clarify)
  3705     fix x and B assume "x \<in> s" and "open B" and "f x \<in> B"
  3706     have "openin (subtopology euclidean (f ` s)) (f ` s \<inter> B)"
  3707       unfolding openin_open using `open B` by auto
  3708     then have "openin (subtopology euclidean s) {x \<in> s. f x \<in> f ` s \<inter> B}"
  3709       using `?rhs` by fast
  3710     then show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  3711       unfolding openin_open using `x \<in> s` and `f x \<in> B` by auto
  3712   qed
  3713 qed
  3714 
  3715 text {* Similarly in terms of closed sets. *}
  3716 
  3717 lemma continuous_on_closed:
  3718   shows "continuous_on s f \<longleftrightarrow>  (\<forall>t. closedin (subtopology euclidean (f ` s)) t  --> closedin (subtopology euclidean s) {x \<in> s. f x \<in> t})" (is "?lhs = ?rhs")
  3719 proof
  3720   assume ?lhs
  3721   { fix t
  3722     have *:"s - {x \<in> s. f x \<in> f ` s - t} = {x \<in> s. f x \<in> t}" by auto
  3723     have **:"f ` s - (f ` s - (f ` s - t)) = f ` s - t" by auto
  3724     assume as:"closedin (subtopology euclidean (f ` s)) t"
  3725     hence "closedin (subtopology euclidean (f ` s)) (f ` s - (f ` s - t))" unfolding closedin_def topspace_euclidean_subtopology unfolding ** by auto
  3726     hence "closedin (subtopology euclidean s) {x \<in> s. f x \<in> t}" using `?lhs`[unfolded continuous_on_open, THEN spec[where x="(f ` s) - t"]]
  3727       unfolding openin_closedin_eq topspace_euclidean_subtopology unfolding * by auto  }
  3728   thus ?rhs by auto
  3729 next
  3730   assume ?rhs
  3731   { fix t
  3732     have *:"s - {x \<in> s. f x \<in> f ` s - t} = {x \<in> s. f x \<in> t}" by auto
  3733     assume as:"openin (subtopology euclidean (f ` s)) t"
  3734     hence "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}" using `?rhs`[THEN spec[where x="(f ` s) - t"]]
  3735       unfolding openin_closedin_eq topspace_euclidean_subtopology *[THEN sym] closedin_subtopology by auto }
  3736   thus ?lhs unfolding continuous_on_open by auto
  3737 qed
  3738 
  3739 text {* Half-global and completely global cases. *}
  3740 
  3741 lemma continuous_open_in_preimage:
  3742   assumes "continuous_on s f"  "open t"
  3743   shows "openin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3744 proof-
  3745   have *:"\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)" by auto
  3746   have "openin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  3747     using openin_open_Int[of t "f ` s", OF assms(2)] unfolding openin_open by auto
  3748   thus ?thesis using assms(1)[unfolded continuous_on_open, THEN spec[where x="t \<inter> f ` s"]] using * by auto
  3749 qed
  3750 
  3751 lemma continuous_closed_in_preimage:
  3752   assumes "continuous_on s f"  "closed t"
  3753   shows "closedin (subtopology euclidean s) {x \<in> s. f x \<in> t}"
  3754 proof-
  3755   have *:"\<forall>x. x \<in> s \<and> f x \<in> t \<longleftrightarrow> x \<in> s \<and> f x \<in> (t \<inter> f ` s)" by auto
  3756   have "closedin (subtopology euclidean (f ` s)) (t \<inter> f ` s)"
  3757     using closedin_closed_Int[of t "f ` s", OF assms(2)] unfolding Int_commute by auto
  3758   thus ?thesis
  3759     using assms(1)[unfolded continuous_on_closed, THEN spec[where x="t \<inter> f ` s"]] using * by auto
  3760 qed
  3761 
  3762 lemma continuous_open_preimage:
  3763   assumes "continuous_on s f" "open s" "open t"
  3764   shows "open {x \<in> s. f x \<in> t}"
  3765 proof-
  3766   obtain T where T: "open T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  3767     using continuous_open_in_preimage[OF assms(1,3)] unfolding openin_open by auto
  3768   thus ?thesis using open_Int[of s T, OF assms(2)] by auto
  3769 qed
  3770 
  3771 lemma continuous_closed_preimage:
  3772   assumes "continuous_on s f" "closed s" "closed t"
  3773   shows "closed {x \<in> s. f x \<in> t}"
  3774 proof-
  3775   obtain T where T: "closed T" "{x \<in> s. f x \<in> t} = s \<inter> T"
  3776     using continuous_closed_in_preimage[OF assms(1,3)] unfolding closedin_closed by auto
  3777   thus ?thesis using closed_Int[of s T, OF assms(2)] by auto
  3778 qed
  3779 
  3780 lemma continuous_open_preimage_univ:
  3781   shows "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open {x. f x \<in> s}"
  3782   using continuous_open_preimage[of UNIV f s] open_UNIV continuous_at_imp_continuous_on by auto
  3783 
  3784 lemma continuous_closed_preimage_univ:
  3785   shows "(\<forall>x. continuous (at x) f) \<Longrightarrow> closed s ==> closed {x. f x \<in> s}"
  3786   using continuous_closed_preimage[of UNIV f s] closed_UNIV continuous_at_imp_continuous_on by auto
  3787 
  3788 lemma continuous_open_vimage:
  3789   shows "\<forall>x. continuous (at x) f \<Longrightarrow> open s \<Longrightarrow> open (f -` s)"
  3790   unfolding vimage_def by (rule continuous_open_preimage_univ)
  3791 
  3792 lemma continuous_closed_vimage:
  3793   shows "\<forall>x. continuous (at x) f \<Longrightarrow> closed s \<Longrightarrow> closed (f -` s)"
  3794   unfolding vimage_def by (rule continuous_closed_preimage_univ)
  3795 
  3796 lemma interior_image_subset:
  3797   assumes "\<forall>x. continuous (at x) f" "inj f"
  3798   shows "interior (f ` s) \<subseteq> f ` (interior s)"
  3799   apply rule unfolding interior_def mem_Collect_eq image_iff apply safe
  3800 proof- fix x T assume as:"open T" "x \<in> T" "T \<subseteq> f ` s" 
  3801   hence "x \<in> f ` s" by auto then guess y unfolding image_iff .. note y=this
  3802   thus "\<exists>xa\<in>{x. \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> s}. x = f xa" apply(rule_tac x=y in bexI) using assms as
  3803     apply safe apply(rule_tac x="{x. f x \<in> T}" in exI) apply(safe,rule continuous_open_preimage_univ)
  3804   proof- fix x assume "f x \<in> T" hence "f x \<in> f ` s" using as by auto
  3805     thus "x \<in> s" unfolding inj_image_mem_iff[OF assms(2)] . qed auto qed
  3806 
  3807 text {* Equality of continuous functions on closure and related results. *}
  3808 
  3809 lemma continuous_closed_in_preimage_constant:
  3810   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3811   shows "continuous_on s f ==> closedin (subtopology euclidean s) {x \<in> s. f x = a}"
  3812   using continuous_closed_in_preimage[of s f "{a}"] by auto
  3813 
  3814 lemma continuous_closed_preimage_constant:
  3815   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3816   shows "continuous_on s f \<Longrightarrow> closed s ==> closed {x \<in> s. f x = a}"
  3817   using continuous_closed_preimage[of s f "{a}"] by auto
  3818 
  3819 lemma continuous_constant_on_closure:
  3820   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3821   assumes "continuous_on (closure s) f"
  3822           "\<forall>x \<in> s. f x = a"
  3823   shows "\<forall>x \<in> (closure s). f x = a"
  3824     using continuous_closed_preimage_constant[of "closure s" f a]
  3825     assms closure_minimal[of s "{x \<in> closure s. f x = a}"] closure_subset unfolding subset_eq by auto
  3826 
  3827 lemma image_closure_subset:
  3828   assumes "continuous_on (closure s) f"  "closed t"  "(f ` s) \<subseteq> t"
  3829   shows "f ` (closure s) \<subseteq> t"
  3830 proof-
  3831   have "s \<subseteq> {x \<in> closure s. f x \<in> t}" using assms(3) closure_subset by auto
  3832   moreover have "closed {x \<in> closure s. f x \<in> t}"
  3833     using continuous_closed_preimage[OF assms(1)] and assms(2) by auto
  3834   ultimately have "closure s = {x \<in> closure s . f x \<in> t}"
  3835     using closure_minimal[of s "{x \<in> closure s. f x \<in> t}"] by auto
  3836   thus ?thesis by auto
  3837 qed
  3838 
  3839 lemma continuous_on_closure_norm_le:
  3840   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3841   assumes "continuous_on (closure s) f"  "\<forall>y \<in> s. norm(f y) \<le> b"  "x \<in> (closure s)"
  3842   shows "norm(f x) \<le> b"
  3843 proof-
  3844   have *:"f ` s \<subseteq> cball 0 b" using assms(2)[unfolded mem_cball_0[THEN sym]] by auto
  3845   show ?thesis
  3846     using image_closure_subset[OF assms(1) closed_cball[of 0 b] *] assms(3)
  3847     unfolding subset_eq apply(erule_tac x="f x" in ballE) by (auto simp add: dist_norm)
  3848 qed
  3849 
  3850 text {* Making a continuous function avoid some value in a neighbourhood. *}
  3851 
  3852 lemma continuous_within_avoid:
  3853   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* FIXME: generalize *)
  3854   assumes "continuous (at x within s) f"  "x \<in> s"  "f x \<noteq> a"
  3855   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e --> f y \<noteq> a"
  3856 proof-
  3857   obtain d where "d>0" and d:"\<forall>xa\<in>s. 0 < dist xa x \<and> dist xa x < d \<longrightarrow> dist (f xa) (f x) < dist (f x) a"
  3858     using assms(1)[unfolded continuous_within Lim_within, THEN spec[where x="dist (f x) a"]] assms(3)[unfolded dist_nz] by auto
  3859   { fix y assume " y\<in>s"  "dist x y < d"
  3860     hence "f y \<noteq> a" using d[THEN bspec[where x=y]] assms(3)[unfolded dist_nz]
  3861       apply auto unfolding dist_nz[THEN sym] by (auto simp add: dist_commute) }
  3862   thus ?thesis using `d>0` by auto
  3863 qed
  3864 
  3865 lemma continuous_at_avoid:
  3866   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* FIXME: generalize *)
  3867   assumes "continuous (at x) f"  "f x \<noteq> a"
  3868   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  3869 using assms using continuous_within_avoid[of x UNIV f a, unfolded within_UNIV] by auto
  3870 
  3871 lemma continuous_on_avoid:
  3872   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* TODO: generalize *)
  3873   assumes "continuous_on s f"  "x \<in> s"  "f x \<noteq> a"
  3874   shows "\<exists>e>0. \<forall>y \<in> s. dist x y < e \<longrightarrow> f y \<noteq> a"
  3875 using assms(1)[unfolded continuous_on_eq_continuous_within, THEN bspec[where x=x], OF assms(2)]  continuous_within_avoid[of x s f a]  assms(2,3) by auto
  3876 
  3877 lemma continuous_on_open_avoid:
  3878   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space" (* TODO: generalize *)
  3879   assumes "continuous_on s f"  "open s"  "x \<in> s"  "f x \<noteq> a"
  3880   shows "\<exists>e>0. \<forall>y. dist x y < e \<longrightarrow> f y \<noteq> a"
  3881 using assms(1)[unfolded continuous_on_eq_continuous_at[OF assms(2)], THEN bspec[where x=x], OF assms(3)]  continuous_at_avoid[of x f a]  assms(3,4) by auto
  3882 
  3883 text {* Proving a function is constant by proving open-ness of level set. *}
  3884 
  3885 lemma continuous_levelset_open_in_cases:
  3886   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3887   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  3888         openin (subtopology euclidean s) {x \<in> s. f x = a}
  3889         ==> (\<forall>x \<in> s. f x \<noteq> a) \<or> (\<forall>x \<in> s. f x = a)"
  3890 unfolding connected_clopen using continuous_closed_in_preimage_constant by auto
  3891 
  3892 lemma continuous_levelset_open_in:
  3893   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3894   shows "connected s \<Longrightarrow> continuous_on s f \<Longrightarrow>
  3895         openin (subtopology euclidean s) {x \<in> s. f x = a} \<Longrightarrow>
  3896         (\<exists>x \<in> s. f x = a)  ==> (\<forall>x \<in> s. f x = a)"
  3897 using continuous_levelset_open_in_cases[of s f ]
  3898 by meson
  3899 
  3900 lemma continuous_levelset_open:
  3901   fixes f :: "_ \<Rightarrow> 'b::t1_space"
  3902   assumes "connected s"  "continuous_on s f"  "open {x \<in> s. f x = a}"  "\<exists>x \<in> s.  f x = a"
  3903   shows "\<forall>x \<in> s. f x = a"
  3904 using continuous_levelset_open_in[OF assms(1,2), of a, unfolded openin_open] using assms (3,4) by fast
  3905 
  3906 text {* Some arithmetical combinations (more to prove). *}
  3907 
  3908 lemma open_scaling[intro]:
  3909   fixes s :: "'a::real_normed_vector set"
  3910   assumes "c \<noteq> 0"  "open s"
  3911   shows "open((\<lambda>x. c *\<^sub>R x) ` s)"
  3912 proof-
  3913   { fix x assume "x \<in> s"
  3914     then obtain e where "e>0" and e:"\<forall>x'. dist x' x < e \<longrightarrow> x' \<in> s" using assms(2)[unfolded open_dist, THEN bspec[where x=x]] by auto
  3915     have "e * abs c > 0" using assms(1)[unfolded zero_less_abs_iff[THEN sym]] using mult_pos_pos[OF `e>0`] by auto
  3916     moreover
  3917     { fix y assume "dist y (c *\<^sub>R x) < e * \<bar>c\<bar>"
  3918       hence "norm ((1 / c) *\<^sub>R y - x) < e" unfolding dist_norm
  3919         using norm_scaleR[of c "(1 / c) *\<^sub>R y - x", unfolded scaleR_right_diff_distrib, unfolded scaleR_scaleR] assms(1)
  3920           assms(1)[unfolded zero_less_abs_iff[THEN sym]] by (simp del:zero_less_abs_iff)
  3921       hence "y \<in> op *\<^sub>R c ` s" using rev_image_eqI[of "(1 / c) *\<^sub>R y" s y "op *\<^sub>R c"]  e[THEN spec[where x="(1 / c) *\<^sub>R y"]]  assms(1) unfolding dist_norm scaleR_scaleR by auto  }
  3922     ultimately have "\<exists>e>0. \<forall>x'. dist x' (c *\<^sub>R x) < e \<longrightarrow> x' \<in> op *\<^sub>R c ` s" apply(rule_tac x="e * abs c" in exI) by auto  }
  3923   thus ?thesis unfolding open_dist by auto
  3924 qed
  3925 
  3926 lemma minus_image_eq_vimage:
  3927   fixes A :: "'a::ab_group_add set"
  3928   shows "(\<lambda>x. - x) ` A = (\<lambda>x. - x) -` A"
  3929   by (auto intro!: image_eqI [where f="\<lambda>x. - x"])
  3930 
  3931 lemma open_negations:
  3932   fixes s :: "'a::real_normed_vector set"
  3933   shows "open s ==> open ((\<lambda> x. -x) ` s)"
  3934   unfolding scaleR_minus1_left [symmetric]
  3935   by (rule open_scaling, auto)
  3936 
  3937 lemma open_translation:
  3938   fixes s :: "'a::real_normed_vector set"
  3939   assumes "open s"  shows "open((\<lambda>x. a + x) ` s)"
  3940 proof-
  3941   { fix x have "continuous (at x) (\<lambda>x. x - a)" using continuous_sub[of "at x" "\<lambda>x. x" "\<lambda>x. a"] continuous_at_id[of x] continuous_const[of "at x" a] by auto  }
  3942   moreover have "{x. x - a \<in> s}  = op + a ` s" apply auto unfolding image_iff apply(rule_tac x="x - a" in bexI) by auto
  3943   ultimately show ?thesis using continuous_open_preimage_univ[of "\<lambda>x. x - a" s] using assms by auto
  3944 qed
  3945 
  3946 lemma open_affinity:
  3947   fixes s :: "'a::real_normed_vector set"
  3948   assumes "open s"  "c \<noteq> 0"
  3949   shows "open ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  3950 proof-
  3951   have *:"(\<lambda>x. a + c *\<^sub>R x) = (\<lambda>x. a + x) \<circ> (\<lambda>x. c *\<^sub>R x)" unfolding o_def ..
  3952   have "op + a ` op *\<^sub>R c ` s = (op + a \<circ> op *\<^sub>R c) ` s" by auto
  3953   thus ?thesis using assms open_translation[of "op *\<^sub>R c ` s" a] unfolding * by auto
  3954 qed
  3955 
  3956 lemma interior_translation:
  3957   fixes s :: "'a::real_normed_vector set"
  3958   shows "interior ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (interior s)"
  3959 proof (rule set_eqI, rule)
  3960   fix x assume "x \<in> interior (op + a ` s)"
  3961   then obtain e where "e>0" and e:"ball x e \<subseteq> op + a ` s" unfolding mem_interior by auto
  3962   hence "ball (x - a) e \<subseteq> s" unfolding subset_eq Ball_def mem_ball dist_norm apply auto apply(erule_tac x="a + xa" in allE) unfolding ab_group_add_class.diff_diff_eq[THEN sym] by auto
  3963   thus "x \<in> op + a ` interior s" unfolding image_iff apply(rule_tac x="x - a" in bexI) unfolding mem_interior using `e > 0` by auto
  3964 next
  3965   fix x assume "x \<in> op + a ` interior s"
  3966   then obtain y e where "e>0" and e:"ball y e \<subseteq> s" and y:"x = a + y" unfolding image_iff Bex_def mem_interior by auto
  3967   { fix z have *:"a + y - z = y + a - z" by auto
  3968     assume "z\<in>ball x e"
  3969     hence "z - a \<in> s" using e[unfolded subset_eq, THEN bspec[where x="z - a"]] unfolding mem_ball dist_norm y ab_group_add_class.diff_diff_eq2 * by auto
  3970     hence "z \<in> op + a ` s" unfolding image_iff by(auto intro!: bexI[where x="z - a"])  }
  3971   hence "ball x e \<subseteq> op + a ` s" unfolding subset_eq by auto
  3972   thus "x \<in> interior (op + a ` s)" unfolding mem_interior using `e>0` by auto
  3973 qed
  3974 
  3975 text {* We can now extend limit compositions to consider the scalar multiplier. *}
  3976 
  3977 lemma continuous_vmul:
  3978   fixes c :: "'a::metric_space \<Rightarrow> real" and v :: "'b::real_normed_vector"
  3979   shows "continuous net c ==> continuous net (\<lambda>x. c(x) *\<^sub>R v)"
  3980   unfolding continuous_def by (intro tendsto_intros)
  3981 
  3982 lemma continuous_mul:
  3983   fixes c :: "'a::metric_space \<Rightarrow> real"
  3984   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  3985   shows "continuous net c \<Longrightarrow> continuous net f
  3986              ==> continuous net (\<lambda>x. c(x) *\<^sub>R f x) "
  3987   unfolding continuous_def by (intro tendsto_intros)
  3988 
  3989 lemmas continuous_intros = continuous_add continuous_vmul continuous_cmul
  3990   continuous_const continuous_sub continuous_at_id continuous_within_id continuous_mul
  3991 
  3992 lemma continuous_on_vmul:
  3993   fixes c :: "'a::metric_space \<Rightarrow> real" and v :: "'b::real_normed_vector"
  3994   shows "continuous_on s c ==> continuous_on s (\<lambda>x. c(x) *\<^sub>R v)"
  3995   unfolding continuous_on_eq_continuous_within using continuous_vmul[of _ c] by auto
  3996 
  3997 lemma continuous_on_mul:
  3998   fixes c :: "'a::metric_space \<Rightarrow> real"
  3999   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  4000   shows "continuous_on s c \<Longrightarrow> continuous_on s f
  4001              ==> continuous_on s (\<lambda>x. c(x) *\<^sub>R f x)"
  4002   unfolding continuous_on_eq_continuous_within using continuous_mul[of _ c] by auto
  4003 
  4004 lemma continuous_on_mul_real:
  4005   fixes f :: "'a::metric_space \<Rightarrow> real"
  4006   fixes g :: "'a::metric_space \<Rightarrow> real"
  4007   shows "continuous_on s f \<Longrightarrow> continuous_on s g
  4008              ==> continuous_on s (\<lambda>x. f x * g x)"
  4009   using continuous_on_mul[of s f g] unfolding real_scaleR_def .
  4010 
  4011 lemmas continuous_on_intros = continuous_on_add continuous_on_const
  4012   continuous_on_id continuous_on_compose continuous_on_cmul continuous_on_neg
  4013   continuous_on_sub continuous_on_mul continuous_on_vmul continuous_on_mul_real
  4014   uniformly_continuous_on_add uniformly_continuous_on_const
  4015   uniformly_continuous_on_id uniformly_continuous_on_compose
  4016   uniformly_continuous_on_cmul uniformly_continuous_on_neg
  4017   uniformly_continuous_on_sub
  4018 
  4019 text {* And so we have continuity of inverse. *}
  4020 
  4021 lemma continuous_inv:
  4022   fixes f :: "'a::metric_space \<Rightarrow> real"
  4023   shows "continuous net f \<Longrightarrow> f(netlimit net) \<noteq> 0
  4024            ==> continuous net (inverse o f)"
  4025   unfolding continuous_def using Lim_inv by auto
  4026 
  4027 lemma continuous_at_within_inv:
  4028   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_field"
  4029   assumes "continuous (at a within s) f" "f a \<noteq> 0"
  4030   shows "continuous (at a within s) (inverse o f)"
  4031   using assms unfolding continuous_within o_def
  4032   by (intro tendsto_intros)
  4033 
  4034 lemma continuous_at_inv:
  4035   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_field"
  4036   shows "continuous (at a) f \<Longrightarrow> f a \<noteq> 0
  4037          ==> continuous (at a) (inverse o f) "
  4038   using within_UNIV[THEN sym, of "at a"] using continuous_at_within_inv[of a UNIV] by auto
  4039 
  4040 text {* Topological properties of linear functions. *}
  4041 
  4042 lemma linear_lim_0:
  4043   assumes "bounded_linear f" shows "(f ---> 0) (at (0))"
  4044 proof-
  4045   interpret f: bounded_linear f by fact
  4046   have "(f ---> f 0) (at 0)"
  4047     using tendsto_ident_at by (rule f.tendsto)
  4048   thus ?thesis unfolding f.zero .
  4049 qed
  4050 
  4051 lemma linear_continuous_at:
  4052   assumes "bounded_linear f"  shows "continuous (at a) f"
  4053   unfolding continuous_at using assms
  4054   apply (rule bounded_linear.tendsto)
  4055   apply (rule tendsto_ident_at)
  4056   done
  4057 
  4058 lemma linear_continuous_within:
  4059   shows "bounded_linear f ==> continuous (at x within s) f"
  4060   using continuous_at_imp_continuous_within[of x f s] using linear_continuous_at[of f] by auto
  4061 
  4062 lemma linear_continuous_on:
  4063   shows "bounded_linear f ==> continuous_on s f"
  4064   using continuous_at_imp_continuous_on[of s f] using linear_continuous_at[of f] by auto
  4065 
  4066 text {* Also bilinear functions, in composition form. *}
  4067 
  4068 lemma bilinear_continuous_at_compose:
  4069   shows "continuous (at x) f \<Longrightarrow> continuous (at x) g \<Longrightarrow> bounded_bilinear h
  4070         ==> continuous (at x) (\<lambda>x. h (f x) (g x))"
  4071   unfolding continuous_at using Lim_bilinear[of f "f x" "(at x)" g "g x" h] by auto
  4072 
  4073 lemma bilinear_continuous_within_compose:
  4074   shows "continuous (at x within s) f \<Longrightarrow> continuous (at x within s) g \<Longrightarrow> bounded_bilinear h
  4075         ==> continuous (at x within s) (\<lambda>x. h (f x) (g x))"
  4076   unfolding continuous_within using Lim_bilinear[of f "f x"] by auto
  4077 
  4078 lemma bilinear_continuous_on_compose:
  4079   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> bounded_bilinear h
  4080              ==> continuous_on s (\<lambda>x. h (f x) (g x))"
  4081   unfolding continuous_on_def
  4082   by (fast elim: bounded_bilinear.tendsto)
  4083 
  4084 text {* Preservation of compactness and connectedness under continuous function. *}
  4085 
  4086 lemma compact_continuous_image:
  4087   assumes "continuous_on s f"  "compact s"
  4088   shows "compact(f ` s)"
  4089 proof-
  4090   { fix x assume x:"\<forall>n::nat. x n \<in> f ` s"
  4091     then obtain y where y:"\<forall>n. y n \<in> s \<and> x n = f (y n)" unfolding image_iff Bex_def using choice[of "\<lambda>n xa. xa \<in> s \<and> x n = f xa"] by auto
  4092     then obtain l r where "l\<in>s" and r:"subseq r" and lr:"((y \<circ> r) ---> l) sequentially" using assms(2)[unfolded compact_def, THEN spec[where x=y]] by auto
  4093     { fix e::real assume "e>0"
  4094       then obtain d where "d>0" and d:"\<forall>x'\<in>s. dist x' l < d \<longrightarrow> dist (f x') (f l) < e" using assms(1)[unfolded continuous_on_iff, THEN bspec[where x=l], OF `l\<in>s`] by auto
  4095       then obtain N::nat where N:"\<forall>n\<ge>N. dist ((y \<circ> r) n) l < d" using lr[unfolded Lim_sequentially, THEN spec[where x=d]] by auto
  4096       { fix n::nat assume "n\<ge>N" hence "dist ((x \<circ> r) n) (f l) < e" using N[THEN spec[where x=n]] d[THEN bspec[where x="y (r n)"]] y[THEN spec[where x="r n"]] by auto  }
  4097       hence "\<exists>N. \<forall>n\<ge>N. dist ((x \<circ> r) n) (f l) < e" by auto  }
  4098     hence "\<exists>l\<in>f ` s. \<exists>r. subseq r \<and> ((x \<circ> r) ---> l) sequentially" unfolding Lim_sequentially using r lr `l\<in>s` by auto  }
  4099   thus ?thesis unfolding compact_def by auto
  4100 qed
  4101 
  4102 lemma connected_continuous_image:
  4103   assumes "continuous_on s f"  "connected s"
  4104   shows "connected(f ` s)"
  4105 proof-
  4106   { fix T assume as: "T \<noteq> {}"  "T \<noteq> f ` s"  "openin (subtopology euclidean (f ` s)) T"  "closedin (subtopology euclidean (f ` s)) T"
  4107     have "{x \<in> s. f x \<in> T} = {} \<or> {x \<in> s. f x \<in> T} = s"
  4108       using assms(1)[unfolded continuous_on_open, THEN spec[where x=T]]
  4109       using assms(1)[unfolded continuous_on_closed, THEN spec[where x=T]]
  4110       using assms(2)[unfolded connected_clopen, THEN spec[where x="{x \<in> s. f x \<in> T}"]] as(3,4) by auto
  4111     hence False using as(1,2)
  4112       using as(4)[unfolded closedin_def topspace_euclidean_subtopology] by auto }
  4113   thus ?thesis unfolding connected_clopen by auto
  4114 qed
  4115 
  4116 text {* Continuity implies uniform continuity on a compact domain. *}
  4117 
  4118 lemma compact_uniformly_continuous:
  4119   assumes "continuous_on s f"  "compact s"
  4120   shows "uniformly_continuous_on s f"
  4121 proof-
  4122     { fix x assume x:"x\<in>s"
  4123       hence "\<forall>xa. \<exists>y. 0 < xa \<longrightarrow> (y > 0 \<and> (\<forall>x'\<in>s. dist x' x < y \<longrightarrow> dist (f x') (f x) < xa))" using assms(1)[unfolded continuous_on_iff, THEN bspec[where x=x]] by auto
  4124       hence "\<exists>fa. \<forall>xa>0. \<forall>x'\<in>s. fa xa > 0 \<and> (dist x' x < fa xa \<longrightarrow> dist (f x') (f x) < xa)" using choice[of "\<lambda>e d. e>0 \<longrightarrow> d>0 \<and>(\<forall>x'\<in>s. (dist x' x < d \<longrightarrow> dist (f x') (f x) < e))"] by auto  }
  4125     then have "\<forall>x\<in>s. \<exists>y. \<forall>xa. 0 < xa \<longrightarrow> (\<forall>x'\<in>s. y xa > 0 \<and> (dist x' x < y xa \<longrightarrow> dist (f x') (f x) < xa))" by auto
  4126     then obtain d where d:"\<forall>e>0. \<forall>x\<in>s. \<forall>x'\<in>s. d x e > 0 \<and> (dist x' x < d x e \<longrightarrow> dist (f x') (f x) < e)"
  4127       using bchoice[of s "\<lambda>x fa. \<forall>xa>0. \<forall>x'\<in>s. fa xa > 0 \<and> (dist x' x < fa xa \<longrightarrow> dist (f x') (f x) < xa)"] by blast
  4128 
  4129   { fix e::real assume "e>0"
  4130 
  4131     { fix x assume "x\<in>s" hence "x \<in> ball x (d x (e / 2))" unfolding centre_in_ball using d[THEN spec[where x="e/2"]] using `e>0` by auto  }
  4132     hence "s \<subseteq> \<Union>{ball x (d x (e / 2)) |x. x \<in> s}" unfolding subset_eq by auto
  4133     moreover
  4134     { fix b assume "b\<in>{ball x (d x (e / 2)) |x. x \<in> s}" hence "open b" by auto  }
  4135     ultimately obtain ea where "ea>0" and ea:"\<forall>x\<in>s. \<exists>b\<in>{ball x (d x (e / 2)) |x. x \<in> s}. ball x ea \<subseteq> b" using heine_borel_lemma[OF assms(2), of "{ball x (d x (e / 2)) | x. x\<in>s }"] by auto
  4136 
  4137     { fix x y assume "x\<in>s" "y\<in>s" and as:"dist y x < ea"
  4138       obtain z where "z\<in>s" and z:"ball x ea \<subseteq> ball z (d z (e / 2))" using ea[THEN bspec[where x=x]] and `x\<in>s` by auto
  4139       hence "x\<in>ball z (d z (e / 2))" using `ea>0` unfolding subset_eq by auto
  4140       hence "dist (f z) (f x) < e / 2" using d[THEN spec[where x="e/2"]] and `e>0` and `x\<in>s` and `z\<in>s`
  4141         by (auto  simp add: dist_commute)
  4142       moreover have "y\<in>ball z (d z (e / 2))" using as and `ea>0` and z[unfolded subset_eq]
  4143         by (auto simp add: dist_commute)
  4144       hence "dist (f z) (f y) < e / 2" using d[THEN spec[where x="e/2"]] and `e>0` and `y\<in>s` and `z\<in>s`
  4145         by (auto  simp add: dist_commute)
  4146       ultimately have "dist (f y) (f x) < e" using dist_triangle_half_r[of "f z" "f x" e "f y"]
  4147         by (auto simp add: dist_commute)  }
  4148     then have "\<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e" using `ea>0` by auto  }
  4149   thus ?thesis unfolding uniformly_continuous_on_def by auto
  4150 qed
  4151 
  4152 text{* Continuity of inverse function on compact domain. *}
  4153 
  4154 lemma continuous_on_inverse:
  4155   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  4156     (* TODO: can this be generalized more? *)
  4157   assumes "continuous_on s f"  "compact s"  "\<forall>x \<in> s. g (f x) = x"
  4158   shows "continuous_on (f ` s) g"
  4159 proof-
  4160   have *:"g ` f ` s = s" using assms(3) by (auto simp add: image_iff)
  4161   { fix t assume t:"closedin (subtopology euclidean (g ` f ` s)) t"
  4162     then obtain T where T: "closed T" "t = s \<inter> T" unfolding closedin_closed unfolding * by auto
  4163     have "continuous_on (s \<inter> T) f" using continuous_on_subset[OF assms(1), of "s \<inter> t"]
  4164       unfolding T(2) and Int_left_absorb by auto
  4165     moreover have "compact (s \<inter> T)"
  4166       using assms(2) unfolding compact_eq_bounded_closed
  4167       using bounded_subset[of s "s \<inter> T"] and T(1) by auto
  4168     ultimately have "closed (f ` t)" using T(1) unfolding T(2)
  4169       using compact_continuous_image [of "s \<inter> T" f] unfolding compact_eq_bounded_closed by auto
  4170     moreover have "{x \<in> f ` s. g x \<in> t} = f ` s \<inter> f ` t" using assms(3) unfolding T(2) by auto
  4171     ultimately have "closedin (subtopology euclidean (f ` s)) {x \<in> f ` s. g x \<in> t}"
  4172       unfolding closedin_closed by auto  }
  4173   thus ?thesis unfolding continuous_on_closed by auto
  4174 qed
  4175 
  4176 text {* A uniformly convergent limit of continuous functions is continuous. *}
  4177 
  4178 lemma continuous_uniform_limit:
  4179   fixes f :: "'a \<Rightarrow> 'b::metric_space \<Rightarrow> 'c::metric_space"
  4180   assumes "\<not> trivial_limit F"
  4181   assumes "eventually (\<lambda>n. continuous_on s (f n)) F"
  4182   assumes "\<forall>e>0. eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e) F"
  4183   shows "continuous_on s g"
  4184 proof-
  4185   { fix x and e::real assume "x\<in>s" "e>0"
  4186     have "eventually (\<lambda>n. \<forall>x\<in>s. dist (f n x) (g x) < e / 3) F"
  4187       using `e>0` assms(3)[THEN spec[where x="e/3"]] by auto
  4188     from eventually_happens [OF eventually_conj [OF this assms(2)]]
  4189     obtain n where n:"\<forall>x\<in>s. dist (f n x) (g x) < e / 3"  "continuous_on s (f n)"
  4190       using assms(1) by blast
  4191     have "e / 3 > 0" using `e>0` by auto
  4192     then obtain d where "d>0" and d:"\<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f n x') (f n x) < e / 3"
  4193       using n(2)[unfolded continuous_on_iff, THEN bspec[where x=x], OF `x\<in>s`, THEN spec[where x="e/3"]] by blast
  4194     { fix y assume "y \<in> s" and "dist y x < d"
  4195       hence "dist (f n y) (f n x) < e / 3"
  4196         by (rule d [rule_format])
  4197       hence "dist (f n y) (g x) < 2 * e / 3"
  4198         using dist_triangle [of "f n y" "g x" "f n x"]
  4199         using n(1)[THEN bspec[where x=x], OF `x\<in>s`]
  4200         by auto
  4201       hence "dist (g y) (g x) < e"
  4202         using n(1)[THEN bspec[where x=y], OF `y\<in>s`]
  4203         using dist_triangle3 [of "g y" "g x" "f n y"]
  4204         by auto }
  4205     hence "\<exists>d>0. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (g x') (g x) < e"
  4206       using `d>0` by auto }
  4207   thus ?thesis unfolding continuous_on_iff by auto
  4208 qed
  4209 
  4210 
  4211 subsection {* Topological stuff lifted from and dropped to R *}
  4212 
  4213 lemma open_real:
  4214   fixes s :: "real set" shows
  4215  "open s \<longleftrightarrow>
  4216         (\<forall>x \<in> s. \<exists>e>0. \<forall>x'. abs(x' - x) < e --> x' \<in> s)" (is "?lhs = ?rhs")
  4217   unfolding open_dist dist_norm by simp
  4218 
  4219 lemma islimpt_approachable_real:
  4220   fixes s :: "real set"
  4221   shows "x islimpt s \<longleftrightarrow> (\<forall>e>0.  \<exists>x'\<in> s. x' \<noteq> x \<and> abs(x' - x) < e)"
  4222   unfolding islimpt_approachable dist_norm by simp
  4223 
  4224 lemma closed_real:
  4225   fixes s :: "real set"
  4226   shows "closed s \<longleftrightarrow>
  4227         (\<forall>x. (\<forall>e>0.  \<exists>x' \<in> s. x' \<noteq> x \<and> abs(x' - x) < e)
  4228             --> x \<in> s)"
  4229   unfolding closed_limpt islimpt_approachable dist_norm by simp
  4230 
  4231 lemma continuous_at_real_range:
  4232   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  4233   shows "continuous (at x) f \<longleftrightarrow> (\<forall>e>0. \<exists>d>0.
  4234         \<forall>x'. norm(x' - x) < d --> abs(f x' - f x) < e)"
  4235   unfolding continuous_at unfolding Lim_at
  4236   unfolding dist_nz[THEN sym] unfolding dist_norm apply auto
  4237   apply(erule_tac x=e in allE) apply auto apply (rule_tac x=d in exI) apply auto apply (erule_tac x=x' in allE) apply auto
  4238   apply(erule_tac x=e in allE) by auto
  4239 
  4240 lemma continuous_on_real_range:
  4241   fixes f :: "'a::real_normed_vector \<Rightarrow> real"
  4242   shows "continuous_on s f \<longleftrightarrow> (\<forall>x \<in> s. \<forall>e>0. \<exists>d>0. (\<forall>x' \<in> s. norm(x' - x) < d --> abs(f x' - f x) < e))"
  4243   unfolding continuous_on_iff dist_norm by simp
  4244 
  4245 lemma continuous_at_norm: "continuous (at x) norm"
  4246   unfolding continuous_at by (intro tendsto_intros)
  4247 
  4248 lemma continuous_on_norm: "continuous_on s norm"
  4249 unfolding continuous_on by (intro ballI tendsto_intros)
  4250 
  4251 lemma continuous_at_infnorm: "continuous (at x) infnorm"
  4252   unfolding continuous_at Lim_at o_def unfolding dist_norm
  4253   apply auto apply (rule_tac x=e in exI) apply auto
  4254   using order_trans[OF real_abs_sub_infnorm infnorm_le_norm, of _ x] by (metis xt1(7))
  4255 
  4256 text {* Hence some handy theorems on distance, diameter etc. of/from a set. *}
  4257 
  4258 lemma compact_attains_sup:
  4259   fixes s :: "real set"
  4260   assumes "compact s"  "s \<noteq> {}"
  4261   shows "\<exists>x \<in> s. \<forall>y \<in> s. y \<le> x"
  4262 proof-
  4263   from assms(1) have a:"bounded s" "closed s" unfolding compact_eq_bounded_closed by auto
  4264   { fix e::real assume as: "\<forall>x\<in>s. x \<le> Sup s" "Sup s \<notin> s"  "0 < e" "\<forall>x'\<in>s. x' = Sup s \<or> \<not> Sup s - x' < e"
  4265     have "isLub UNIV s (Sup s)" using Sup[OF assms(2)] unfolding setle_def using as(1) by auto
  4266     moreover have "isUb UNIV s (Sup s - e)" unfolding isUb_def unfolding setle_def using as(4,2) by auto
  4267     ultimately have False using isLub_le_isUb[of UNIV s "Sup s" "Sup s - e"] using `e>0` by auto  }
  4268   thus ?thesis using bounded_has_Sup(1)[OF a(1) assms(2)] using a(2)[unfolded closed_real, THEN spec[where x="Sup s"]]
  4269     apply(rule_tac x="Sup s" in bexI) by auto
  4270 qed
  4271 
  4272 lemma Inf:
  4273   fixes S :: "real set"
  4274   shows "S \<noteq> {} ==> (\<exists>b. b <=* S) ==> isGlb UNIV S (Inf S)"
  4275 by (auto simp add: isLb_def setle_def setge_def isGlb_def greatestP_def) 
  4276 
  4277 lemma compact_attains_inf:
  4278   fixes s :: "real set"
  4279   assumes "compact s" "s \<noteq> {}"  shows "\<exists>x \<in> s. \<forall>y \<in> s. x \<le> y"
  4280 proof-
  4281   from assms(1) have a:"bounded s" "closed s" unfolding compact_eq_bounded_closed by auto
  4282   { fix e::real assume as: "\<forall>x\<in>s. x \<ge> Inf s"  "Inf s \<notin> s"  "0 < e"
  4283       "\<forall>x'\<in>s. x' = Inf s \<or> \<not> abs (x' - Inf s) < e"
  4284     have "isGlb UNIV s (Inf s)" using Inf[OF assms(2)] unfolding setge_def using as(1) by auto
  4285     moreover
  4286     { fix x assume "x \<in> s"
  4287       hence *:"abs (x - Inf s) = x - Inf s" using as(1)[THEN bspec[where x=x]] by auto
  4288       have "Inf s + e \<le> x" using as(4)[THEN bspec[where x=x]] using as(2) `x\<in>s` unfolding * by auto }
  4289     hence "isLb UNIV s (Inf s + e)" unfolding isLb_def and setge_def by auto
  4290     ultimately have False using isGlb_le_isLb[of UNIV s "Inf s" "Inf s + e"] using `e>0` by auto  }
  4291   thus ?thesis using bounded_has_Inf(1)[OF a(1) assms(2)] using a(2)[unfolded closed_real, THEN spec[where x="Inf s"]]
  4292     apply(rule_tac x="Inf s" in bexI) by auto
  4293 qed
  4294 
  4295 lemma continuous_attains_sup:
  4296   fixes f :: "'a::metric_space \<Rightarrow> real"
  4297   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f
  4298         ==> (\<exists>x \<in> s. \<forall>y \<in> s.  f y \<le> f x)"
  4299   using compact_attains_sup[of "f ` s"]
  4300   using compact_continuous_image[of s f] by auto
  4301 
  4302 lemma continuous_attains_inf:
  4303   fixes f :: "'a::metric_space \<Rightarrow> real"
  4304   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f
  4305         \<Longrightarrow> (\<exists>x \<in> s. \<forall>y \<in> s. f x \<le> f y)"
  4306   using compact_attains_inf[of "f ` s"]
  4307   using compact_continuous_image[of s f] by auto
  4308 
  4309 lemma distance_attains_sup:
  4310   assumes "compact s" "s \<noteq> {}"
  4311   shows "\<exists>x \<in> s. \<forall>y \<in> s. dist a y \<le> dist a x"
  4312 proof (rule continuous_attains_sup [OF assms])
  4313   { fix x assume "x\<in>s"
  4314     have "(dist a ---> dist a x) (at x within s)"
  4315       by (intro tendsto_dist tendsto_const Lim_at_within LIM_ident)
  4316   }
  4317   thus "continuous_on s (dist a)"
  4318     unfolding continuous_on ..
  4319 qed
  4320 
  4321 text {* For \emph{minimal} distance, we only need closure, not compactness. *}
  4322 
  4323 lemma distance_attains_inf:
  4324   fixes a :: "'a::heine_borel"
  4325   assumes "closed s"  "s \<noteq> {}"
  4326   shows "\<exists>x \<in> s. \<forall>y \<in> s. dist a x \<le> dist a y"
  4327 proof-
  4328   from assms(2) obtain b where "b\<in>s" by auto
  4329   let ?B = "cball a (dist b a) \<inter> s"
  4330   have "b \<in> ?B" using `b\<in>s` by (simp add: dist_commute)
  4331   hence "?B \<noteq> {}" by auto
  4332   moreover
  4333   { fix x assume "x\<in>?B"
  4334     fix e::real assume "e>0"
  4335     { fix x' assume "x'\<in>?B" and as:"dist x' x < e"
  4336       from as have "\<bar>dist a x' - dist a x\<bar> < e"
  4337         unfolding abs_less_iff minus_diff_eq
  4338         using dist_triangle2 [of a x' x]
  4339         using dist_triangle [of a x x']
  4340         by arith
  4341     }
  4342     hence "\<exists>d>0. \<forall>x'\<in>?B. dist x' x < d \<longrightarrow> \<bar>dist a x' - dist a x\<bar> < e"
  4343       using `e>0` by auto
  4344   }
  4345   hence "continuous_on (cball a (dist b a) \<inter> s) (dist a)"
  4346     unfolding continuous_on Lim_within dist_norm real_norm_def
  4347     by fast
  4348   moreover have "compact ?B"
  4349     using compact_cball[of a "dist b a"]
  4350     unfolding compact_eq_bounded_closed
  4351     using bounded_Int and closed_Int and assms(1) by auto
  4352   ultimately obtain x where "x\<in>cball a (dist b a) \<inter> s" "\<forall>y\<in>cball a (dist b a) \<inter> s. dist a x \<le> dist a y"
  4353     using continuous_attains_inf[of ?B "dist a"] by fastsimp
  4354   thus ?thesis by fastsimp
  4355 qed
  4356 
  4357 
  4358 subsection {* Pasted sets *}
  4359 
  4360 lemma bounded_Times:
  4361   assumes "bounded s" "bounded t" shows "bounded (s \<times> t)"
  4362 proof-
  4363   obtain x y a b where "\<forall>z\<in>s. dist x z \<le> a" "\<forall>z\<in>t. dist y z \<le> b"
  4364     using assms [unfolded bounded_def] by auto
  4365   then have "\<forall>z\<in>s \<times> t. dist (x, y) z \<le> sqrt (a\<twosuperior> + b\<twosuperior>)"
  4366     by (auto simp add: dist_Pair_Pair real_sqrt_le_mono add_mono power_mono)
  4367   thus ?thesis unfolding bounded_any_center [where a="(x, y)"] by auto
  4368 qed
  4369 
  4370 lemma mem_Times_iff: "x \<in> A \<times> B \<longleftrightarrow> fst x \<in> A \<and> snd x \<in> B"
  4371 by (induct x) simp
  4372 
  4373 lemma compact_Times: "compact s \<Longrightarrow> compact t \<Longrightarrow> compact (s \<times> t)"
  4374 unfolding compact_def
  4375 apply clarify
  4376 apply (drule_tac x="fst \<circ> f" in spec)
  4377 apply (drule mp, simp add: mem_Times_iff)
  4378 apply (clarify, rename_tac l1 r1)
  4379 apply (drule_tac x="snd \<circ> f \<circ> r1" in spec)
  4380 apply (drule mp, simp add: mem_Times_iff)
  4381 apply (clarify, rename_tac l2 r2)
  4382 apply (rule_tac x="(l1, l2)" in rev_bexI, simp)
  4383 apply (rule_tac x="r1 \<circ> r2" in exI)
  4384 apply (rule conjI, simp add: subseq_def)
  4385 apply (drule_tac r=r2 in lim_subseq [COMP swap_prems_rl], assumption)
  4386 apply (drule (1) tendsto_Pair) back
  4387 apply (simp add: o_def)
  4388 done
  4389 
  4390 text{* Hence some useful properties follow quite easily. *}
  4391 
  4392 lemma compact_scaling:
  4393   fixes s :: "'a::real_normed_vector set"
  4394   assumes "compact s"  shows "compact ((\<lambda>x. c *\<^sub>R x) ` s)"
  4395 proof-
  4396   let ?f = "\<lambda>x. scaleR c x"
  4397   have *:"bounded_linear ?f" by (rule bounded_linear_scaleR_right)
  4398   show ?thesis using compact_continuous_image[of s ?f] continuous_at_imp_continuous_on[of s ?f]
  4399     using linear_continuous_at[OF *] assms by auto
  4400 qed
  4401 
  4402 lemma compact_negations:
  4403   fixes s :: "'a::real_normed_vector set"
  4404   assumes "compact s"  shows "compact ((\<lambda>x. -x) ` s)"
  4405   using compact_scaling [OF assms, of "- 1"] by auto
  4406 
  4407 lemma compact_sums:
  4408   fixes s t :: "'a::real_normed_vector set"
  4409   assumes "compact s"  "compact t"  shows "compact {x + y | x y. x \<in> s \<and> y \<in> t}"
  4410 proof-
  4411   have *:"{x + y | x y. x \<in> s \<and> y \<in> t} = (\<lambda>z. fst z + snd z) ` (s \<times> t)"
  4412     apply auto unfolding image_iff apply(rule_tac x="(xa, y)" in bexI) by auto
  4413   have "continuous_on (s \<times> t) (\<lambda>z. fst z + snd z)"
  4414     unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  4415   thus ?thesis unfolding * using compact_continuous_image compact_Times [OF assms] by auto
  4416 qed
  4417 
  4418 lemma compact_differences:
  4419   fixes s t :: "'a::real_normed_vector set"
  4420   assumes "compact s" "compact t"  shows "compact {x - y | x y. x \<in> s \<and> y \<in> t}"
  4421 proof-
  4422   have "{x - y | x y. x\<in>s \<and> y \<in> t} =  {x + y | x y. x \<in> s \<and> y \<in> (uminus ` t)}"
  4423     apply auto apply(rule_tac x= xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4424   thus ?thesis using compact_sums[OF assms(1) compact_negations[OF assms(2)]] by auto
  4425 qed
  4426 
  4427 lemma compact_translation:
  4428   fixes s :: "'a::real_normed_vector set"
  4429   assumes "compact s"  shows "compact ((\<lambda>x. a + x) ` s)"
  4430 proof-
  4431   have "{x + y |x y. x \<in> s \<and> y \<in> {a}} = (\<lambda>x. a + x) ` s" by auto
  4432   thus ?thesis using compact_sums[OF assms compact_sing[of a]] by auto
  4433 qed
  4434 
  4435 lemma compact_affinity:
  4436   fixes s :: "'a::real_normed_vector set"
  4437   assumes "compact s"  shows "compact ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  4438 proof-
  4439   have "op + a ` op *\<^sub>R c ` s = (\<lambda>x. a + c *\<^sub>R x) ` s" by auto
  4440   thus ?thesis using compact_translation[OF compact_scaling[OF assms], of a c] by auto
  4441 qed
  4442 
  4443 text {* Hence we get the following. *}
  4444 
  4445 lemma compact_sup_maxdistance:
  4446   fixes s :: "'a::real_normed_vector set"
  4447   assumes "compact s"  "s \<noteq> {}"
  4448   shows "\<exists>x\<in>s. \<exists>y\<in>s. \<forall>u\<in>s. \<forall>v\<in>s. norm(u - v) \<le> norm(x - y)"
  4449 proof-
  4450   have "{x - y | x y . x\<in>s \<and> y\<in>s} \<noteq> {}" using `s \<noteq> {}` by auto
  4451   then obtain x where x:"x\<in>{x - y |x y. x \<in> s \<and> y \<in> s}"  "\<forall>y\<in>{x - y |x y. x \<in> s \<and> y \<in> s}. norm y \<le> norm x"
  4452     using compact_differences[OF assms(1) assms(1)]
  4453     using distance_attains_sup[where 'a="'a", unfolded dist_norm, of "{x - y | x y . x\<in>s \<and> y\<in>s}" 0] by auto
  4454   from x(1) obtain a b where "a\<in>s" "b\<in>s" "x = a - b" by auto
  4455   thus ?thesis using x(2)[unfolded `x = a - b`] by blast
  4456 qed
  4457 
  4458 text {* We can state this in terms of diameter of a set. *}
  4459 
  4460 definition "diameter s = (if s = {} then 0::real else Sup {norm(x - y) | x y. x \<in> s \<and> y \<in> s})"
  4461   (* TODO: generalize to class metric_space *)
  4462 
  4463 lemma diameter_bounded:
  4464   assumes "bounded s"
  4465   shows "\<forall>x\<in>s. \<forall>y\<in>s. norm(x - y) \<le> diameter s"
  4466         "\<forall>d>0. d < diameter s --> (\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d)"
  4467 proof-
  4468   let ?D = "{norm (x - y) |x y. x \<in> s \<and> y \<in> s}"
  4469   obtain a where a:"\<forall>x\<in>s. norm x \<le> a" using assms[unfolded bounded_iff] by auto
  4470   { fix x y assume "x \<in> s" "y \<in> s"
  4471     hence "norm (x - y) \<le> 2 * a" using norm_triangle_ineq[of x "-y", unfolded norm_minus_cancel] a[THEN bspec[where x=x]] a[THEN bspec[where x=y]] by (auto simp add: field_simps)  }
  4472   note * = this
  4473   { fix x y assume "x\<in>s" "y\<in>s"  hence "s \<noteq> {}" by auto
  4474     have "norm(x - y) \<le> diameter s" unfolding diameter_def using `s\<noteq>{}` *[OF `x\<in>s` `y\<in>s`] `x\<in>s` `y\<in>s`
  4475       by simp (blast intro!: Sup_upper *) }
  4476   moreover
  4477   { fix d::real assume "d>0" "d < diameter s"
  4478     hence "s\<noteq>{}" unfolding diameter_def by auto
  4479     have "\<exists>d' \<in> ?D. d' > d"
  4480     proof(rule ccontr)
  4481       assume "\<not> (\<exists>d'\<in>{norm (x - y) |x y. x \<in> s \<and> y \<in> s}. d < d')"
  4482       hence "\<forall>d'\<in>?D. d' \<le> d" by auto (metis not_leE) 
  4483       thus False using `d < diameter s` `s\<noteq>{}` 
  4484         apply (auto simp add: diameter_def) 
  4485         apply (drule Sup_real_iff [THEN [2] rev_iffD2])
  4486         apply (auto, force) 
  4487         done
  4488     qed
  4489     hence "\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d" by auto  }
  4490   ultimately show "\<forall>x\<in>s. \<forall>y\<in>s. norm(x - y) \<le> diameter s"
  4491         "\<forall>d>0. d < diameter s --> (\<exists>x\<in>s. \<exists>y\<in>s. norm(x - y) > d)" by auto
  4492 qed
  4493 
  4494 lemma diameter_bounded_bound:
  4495  "bounded s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s ==> norm(x - y) \<le> diameter s"
  4496   using diameter_bounded by blast
  4497 
  4498 lemma diameter_compact_attained:
  4499   fixes s :: "'a::real_normed_vector set"
  4500   assumes "compact s"  "s \<noteq> {}"
  4501   shows "\<exists>x\<in>s. \<exists>y\<in>s. (norm(x - y) = diameter s)"
  4502 proof-
  4503   have b:"bounded s" using assms(1) by (rule compact_imp_bounded)
  4504   then obtain x y where xys:"x\<in>s" "y\<in>s" and xy:"\<forall>u\<in>s. \<forall>v\<in>s. norm (u - v) \<le> norm (x - y)" using compact_sup_maxdistance[OF assms] by auto
  4505   hence "diameter s \<le> norm (x - y)"
  4506     unfolding diameter_def by clarsimp (rule Sup_least, fast+)
  4507   thus ?thesis
  4508     by (metis b diameter_bounded_bound order_antisym xys)
  4509 qed
  4510 
  4511 text {* Related results with closure as the conclusion. *}
  4512 
  4513 lemma closed_scaling:
  4514   fixes s :: "'a::real_normed_vector set"
  4515   assumes "closed s" shows "closed ((\<lambda>x. c *\<^sub>R x) ` s)"
  4516 proof(cases "s={}")
  4517   case True thus ?thesis by auto
  4518 next
  4519   case False
  4520   show ?thesis
  4521   proof(cases "c=0")
  4522     have *:"(\<lambda>x. 0) ` s = {0}" using `s\<noteq>{}` by auto
  4523     case True thus ?thesis apply auto unfolding * by auto
  4524   next
  4525     case False
  4526     { fix x l assume as:"\<forall>n::nat. x n \<in> scaleR c ` s"  "(x ---> l) sequentially"
  4527       { fix n::nat have "scaleR (1 / c) (x n) \<in> s"
  4528           using as(1)[THEN spec[where x=n]]
  4529           using `c\<noteq>0` by auto
  4530       }
  4531       moreover
  4532       { fix e::real assume "e>0"
  4533         hence "0 < e *\<bar>c\<bar>"  using `c\<noteq>0` mult_pos_pos[of e "abs c"] by auto
  4534         then obtain N where "\<forall>n\<ge>N. dist (x n) l < e * \<bar>c\<bar>"
  4535           using as(2)[unfolded Lim_sequentially, THEN spec[where x="e * abs c"]] by auto
  4536         hence "\<exists>N. \<forall>n\<ge>N. dist (scaleR (1 / c) (x n)) (scaleR (1 / c) l) < e"
  4537           unfolding dist_norm unfolding scaleR_right_diff_distrib[THEN sym]
  4538           using mult_imp_div_pos_less[of "abs c" _ e] `c\<noteq>0` by auto  }
  4539       hence "((\<lambda>n. scaleR (1 / c) (x n)) ---> scaleR (1 / c) l) sequentially" unfolding Lim_sequentially by auto
  4540       ultimately have "l \<in> scaleR c ` s"
  4541         using assms[unfolded closed_sequential_limits, THEN spec[where x="\<lambda>n. scaleR (1/c) (x n)"], THEN spec[where x="scaleR (1/c) l"]]
  4542         unfolding image_iff using `c\<noteq>0` apply(rule_tac x="scaleR (1 / c) l" in bexI) by auto  }
  4543     thus ?thesis unfolding closed_sequential_limits by fast
  4544   qed
  4545 qed
  4546 
  4547 lemma closed_negations:
  4548   fixes s :: "'a::real_normed_vector set"
  4549   assumes "closed s"  shows "closed ((\<lambda>x. -x) ` s)"
  4550   using closed_scaling[OF assms, of "- 1"] by simp
  4551 
  4552 lemma compact_closed_sums:
  4553   fixes s :: "'a::real_normed_vector set"
  4554   assumes "compact s"  "closed t"  shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  4555 proof-
  4556   let ?S = "{x + y |x y. x \<in> s \<and> y \<in> t}"
  4557   { fix x l assume as:"\<forall>n. x n \<in> ?S"  "(x ---> l) sequentially"
  4558     from as(1) obtain f where f:"\<forall>n. x n = fst (f n) + snd (f n)"  "\<forall>n. fst (f n) \<in> s"  "\<forall>n. snd (f n) \<in> t"
  4559       using choice[of "\<lambda>n y. x n = (fst y) + (snd y) \<and> fst y \<in> s \<and> snd y \<in> t"] by auto
  4560     obtain l' r where "l'\<in>s" and r:"subseq r" and lr:"(((\<lambda>n. fst (f n)) \<circ> r) ---> l') sequentially"
  4561       using assms(1)[unfolded compact_def, THEN spec[where x="\<lambda> n. fst (f n)"]] using f(2) by auto
  4562     have "((\<lambda>n. snd (f (r n))) ---> l - l') sequentially"
  4563       using tendsto_diff[OF lim_subseq[OF r as(2)] lr] and f(1) unfolding o_def by auto
  4564     hence "l - l' \<in> t"
  4565       using assms(2)[unfolded closed_sequential_limits, THEN spec[where x="\<lambda> n. snd (f (r n))"], THEN spec[where x="l - l'"]]
  4566       using f(3) by auto
  4567     hence "l \<in> ?S" using `l' \<in> s` apply auto apply(rule_tac x=l' in exI) apply(rule_tac x="l - l'" in exI) by auto
  4568   }
  4569   thus ?thesis unfolding closed_sequential_limits by fast
  4570 qed
  4571 
  4572 lemma closed_compact_sums:
  4573   fixes s t :: "'a::real_normed_vector set"
  4574   assumes "closed s"  "compact t"
  4575   shows "closed {x + y | x y. x \<in> s \<and> y \<in> t}"
  4576 proof-
  4577   have "{x + y |x y. x \<in> t \<and> y \<in> s} = {x + y |x y. x \<in> s \<and> y \<in> t}" apply auto
  4578     apply(rule_tac x=y in exI) apply auto apply(rule_tac x=y in exI) by auto
  4579   thus ?thesis using compact_closed_sums[OF assms(2,1)] by simp
  4580 qed
  4581 
  4582 lemma compact_closed_differences:
  4583   fixes s t :: "'a::real_normed_vector set"
  4584   assumes "compact s"  "closed t"
  4585   shows "closed {x - y | x y. x \<in> s \<and> y \<in> t}"
  4586 proof-
  4587   have "{x + y |x y. x \<in> s \<and> y \<in> uminus ` t} =  {x - y |x y. x \<in> s \<and> y \<in> t}"
  4588     apply auto apply(rule_tac x=xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4589   thus ?thesis using compact_closed_sums[OF assms(1) closed_negations[OF assms(2)]] by auto
  4590 qed
  4591 
  4592 lemma closed_compact_differences:
  4593   fixes s t :: "'a::real_normed_vector set"
  4594   assumes "closed s" "compact t"
  4595   shows "closed {x - y | x y. x \<in> s \<and> y \<in> t}"
  4596 proof-
  4597   have "{x + y |x y. x \<in> s \<and> y \<in> uminus ` t} = {x - y |x y. x \<in> s \<and> y \<in> t}"
  4598     apply auto apply(rule_tac x=xa in exI) apply auto apply(rule_tac x=xa in exI) by auto
  4599  thus ?thesis using closed_compact_sums[OF assms(1) compact_negations[OF assms(2)]] by simp
  4600 qed
  4601 
  4602 lemma closed_translation:
  4603   fixes a :: "'a::real_normed_vector"
  4604   assumes "closed s"  shows "closed ((\<lambda>x. a + x) ` s)"
  4605 proof-
  4606   have "{a + y |y. y \<in> s} = (op + a ` s)" by auto
  4607   thus ?thesis using compact_closed_sums[OF compact_sing[of a] assms] by auto
  4608 qed
  4609 
  4610 lemma translation_Compl:
  4611   fixes a :: "'a::ab_group_add"
  4612   shows "(\<lambda>x. a + x) ` (- t) = - ((\<lambda>x. a + x) ` t)"
  4613   apply (auto simp add: image_iff) apply(rule_tac x="x - a" in bexI) by auto
  4614 
  4615 lemma translation_UNIV:
  4616   fixes a :: "'a::ab_group_add" shows "range (\<lambda>x. a + x) = UNIV"
  4617   apply (auto simp add: image_iff) apply(rule_tac x="x - a" in exI) by auto
  4618 
  4619 lemma translation_diff:
  4620   fixes a :: "'a::ab_group_add"
  4621   shows "(\<lambda>x. a + x) ` (s - t) = ((\<lambda>x. a + x) ` s) - ((\<lambda>x. a + x) ` t)"
  4622   by auto
  4623 
  4624 lemma closure_translation:
  4625   fixes a :: "'a::real_normed_vector"
  4626   shows "closure ((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (closure s)"
  4627 proof-
  4628   have *:"op + a ` (- s) = - op + a ` s"
  4629     apply auto unfolding image_iff apply(rule_tac x="x - a" in bexI) by auto
  4630   show ?thesis unfolding closure_interior translation_Compl
  4631     using interior_translation[of a "- s"] unfolding * by auto
  4632 qed
  4633 
  4634 lemma frontier_translation:
  4635   fixes a :: "'a::real_normed_vector"
  4636   shows "frontier((\<lambda>x. a + x) ` s) = (\<lambda>x. a + x) ` (frontier s)"
  4637   unfolding frontier_def translation_diff interior_translation closure_translation by auto
  4638 
  4639 
  4640 subsection {* Separation between points and sets *}
  4641 
  4642 lemma separate_point_closed:
  4643   fixes s :: "'a::heine_borel set"
  4644   shows "closed s \<Longrightarrow> a \<notin> s  ==> (\<exists>d>0. \<forall>x\<in>s. d \<le> dist a x)"
  4645 proof(cases "s = {}")
  4646   case True
  4647   thus ?thesis by(auto intro!: exI[where x=1])
  4648 next
  4649   case False
  4650   assume "closed s" "a \<notin> s"
  4651   then obtain x where "x\<in>s" "\<forall>y\<in>s. dist a x \<le> dist a y" using `s \<noteq> {}` distance_attains_inf [of s a] by blast
  4652   with `x\<in>s` show ?thesis using dist_pos_lt[of a x] and`a \<notin> s` by blast
  4653 qed
  4654 
  4655 lemma separate_compact_closed:
  4656   fixes s t :: "'a::{heine_borel, real_normed_vector} set"
  4657     (* TODO: does this generalize to heine_borel? *)
  4658   assumes "compact s" and "closed t" and "s \<inter> t = {}"
  4659   shows "\<exists>d>0. \<forall>x\<in>s. \<forall>y\<in>t. d \<le> dist x y"
  4660 proof-
  4661   have "0 \<notin> {x - y |x y. x \<in> s \<and> y \<in> t}" using assms(3) by auto
  4662   then obtain d where "d>0" and d:"\<forall>x\<in>{x - y |x y. x \<in> s \<and> y \<in> t}. d \<le> dist 0 x"
  4663     using separate_point_closed[OF compact_closed_differences[OF assms(1,2)], of 0] by auto
  4664   { fix x y assume "x\<in>s" "y\<in>t"
  4665     hence "x - y \<in> {x - y |x y. x \<in> s \<and> y \<in> t}" by auto
  4666     hence "d \<le> dist (x - y) 0" using d[THEN bspec[where x="x - y"]] using dist_commute
  4667       by (auto  simp add: dist_commute)
  4668     hence "d \<le> dist x y" unfolding dist_norm by auto  }
  4669   thus ?thesis using `d>0` by auto
  4670 qed
  4671 
  4672 lemma separate_closed_compact:
  4673   fixes s t :: "'a::{heine_borel, real_normed_vector} set"
  4674   assumes "closed s" and "compact t" and "s \<inter> t = {}"
  4675   shows "\<exists>d>0. \<forall>x\<in>s. \<forall>y\<in>t. d \<le> dist x y"
  4676 proof-
  4677   have *:"t \<inter> s = {}" using assms(3) by auto
  4678   show ?thesis using separate_compact_closed[OF assms(2,1) *]
  4679     apply auto apply(rule_tac x=d in exI) apply auto apply (erule_tac x=y in ballE)
  4680     by (auto simp add: dist_commute)
  4681 qed
  4682 
  4683 
  4684 subsection {* Intervals *}
  4685   
  4686 lemma interval: fixes a :: "'a::ordered_euclidean_space" shows
  4687   "{a <..< b} = {x::'a. \<forall>i<DIM('a). a$$i < x$$i \<and> x$$i < b$$i}" and
  4688   "{a .. b} = {x::'a. \<forall>i<DIM('a). a$$i \<le> x$$i \<and> x$$i \<le> b$$i}"
  4689   by(auto simp add:set_eq_iff eucl_le[where 'a='a] eucl_less[where 'a='a])
  4690 
  4691 lemma mem_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4692   "x \<in> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i < x$$i \<and> x$$i < b$$i)"
  4693   "x \<in> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i \<le> x$$i \<and> x$$i \<le> b$$i)"
  4694   using interval[of a b] by(auto simp add: set_eq_iff eucl_le[where 'a='a] eucl_less[where 'a='a])
  4695 
  4696 lemma interval_eq_empty: fixes a :: "'a::ordered_euclidean_space" shows
  4697  "({a <..< b} = {} \<longleftrightarrow> (\<exists>i<DIM('a). b$$i \<le> a$$i))" (is ?th1) and
  4698  "({a  ..  b} = {} \<longleftrightarrow> (\<exists>i<DIM('a). b$$i < a$$i))" (is ?th2)
  4699 proof-
  4700   { fix i x assume i:"i<DIM('a)" and as:"b$$i \<le> a$$i" and x:"x\<in>{a <..< b}"
  4701     hence "a $$ i < x $$ i \<and> x $$ i < b $$ i" unfolding mem_interval by auto
  4702     hence "a$$i < b$$i" by auto
  4703     hence False using as by auto  }
  4704   moreover
  4705   { assume as:"\<forall>i<DIM('a). \<not> (b$$i \<le> a$$i)"
  4706     let ?x = "(1/2) *\<^sub>R (a + b)"
  4707     { fix i assume i:"i<DIM('a)" 
  4708       have "a$$i < b$$i" using as[THEN spec[where x=i]] using i by auto
  4709       hence "a$$i < ((1/2) *\<^sub>R (a+b)) $$ i" "((1/2) *\<^sub>R (a+b)) $$ i < b$$i"
  4710         unfolding euclidean_simps by auto }
  4711     hence "{a <..< b} \<noteq> {}" using mem_interval(1)[of "?x" a b] by auto  }
  4712   ultimately show ?th1 by blast
  4713 
  4714   { fix i x assume i:"i<DIM('a)" and as:"b$$i < a$$i" and x:"x\<in>{a .. b}"
  4715     hence "a $$ i \<le> x $$ i \<and> x $$ i \<le> b $$ i" unfolding mem_interval by auto
  4716     hence "a$$i \<le> b$$i" by auto
  4717     hence False using as by auto  }
  4718   moreover
  4719   { assume as:"\<forall>i<DIM('a). \<not> (b$$i < a$$i)"
  4720     let ?x = "(1/2) *\<^sub>R (a + b)"
  4721     { fix i assume i:"i<DIM('a)"
  4722       have "a$$i \<le> b$$i" using as[THEN spec[where x=i]] by auto
  4723       hence "a$$i \<le> ((1/2) *\<^sub>R (a+b)) $$ i" "((1/2) *\<^sub>R (a+b)) $$ i \<le> b$$i"
  4724         unfolding euclidean_simps by auto }
  4725     hence "{a .. b} \<noteq> {}" using mem_interval(2)[of "?x" a b] by auto  }
  4726   ultimately show ?th2 by blast
  4727 qed
  4728 
  4729 lemma interval_ne_empty: fixes a :: "'a::ordered_euclidean_space" shows
  4730   "{a  ..  b} \<noteq> {} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i \<le> b$$i)" and
  4731   "{a <..< b} \<noteq> {} \<longleftrightarrow> (\<forall>i<DIM('a). a$$i < b$$i)"
  4732   unfolding interval_eq_empty[of a b] by fastsimp+
  4733 
  4734 lemma interval_sing: fixes a :: "'a::ordered_euclidean_space" shows
  4735  "{a .. a} = {a}" "{a<..<a} = {}"
  4736   apply(auto simp add: set_eq_iff euclidean_eq[where 'a='a] eucl_less[where 'a='a] eucl_le[where 'a='a])
  4737   apply (simp add: order_eq_iff) apply(rule_tac x=0 in exI) by (auto simp add: not_less less_imp_le)
  4738 
  4739 lemma subset_interval_imp: fixes a :: "'a::ordered_euclidean_space" shows
  4740  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c .. d} \<subseteq> {a .. b}" and
  4741  "(\<forall>i<DIM('a). a$$i < c$$i \<and> d$$i < b$$i) \<Longrightarrow> {c .. d} \<subseteq> {a<..<b}" and
  4742  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c<..<d} \<subseteq> {a .. b}" and
  4743  "(\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i) \<Longrightarrow> {c<..<d} \<subseteq> {a<..<b}"
  4744   unfolding subset_eq[unfolded Ball_def] unfolding mem_interval 
  4745   by (auto intro: order_trans less_le_trans le_less_trans less_imp_le) (* BH: Why doesn't just "auto" work here? *)
  4746 
  4747 lemma interval_open_subset_closed:  fixes a :: "'a::ordered_euclidean_space" shows
  4748  "{a<..<b} \<subseteq> {a .. b}"
  4749 proof(simp add: subset_eq, rule)
  4750   fix x
  4751   assume x:"x \<in>{a<..<b}"
  4752   { fix i assume "i<DIM('a)"
  4753     hence "a $$ i \<le> x $$ i"
  4754       using x order_less_imp_le[of "a$$i" "x$$i"] 
  4755       by(simp add: set_eq_iff eucl_less[where 'a='a] eucl_le[where 'a='a] euclidean_eq)
  4756   }
  4757   moreover
  4758   { fix i assume "i<DIM('a)"
  4759     hence "x $$ i \<le> b $$ i"
  4760       using x order_less_imp_le[of "x$$i" "b$$i"]
  4761       by(simp add: set_eq_iff eucl_less[where 'a='a] eucl_le[where 'a='a] euclidean_eq)
  4762   }
  4763   ultimately
  4764   show "a \<le> x \<and> x \<le> b"
  4765     by(simp add: set_eq_iff eucl_less[where 'a='a] eucl_le[where 'a='a] euclidean_eq)
  4766 qed
  4767 
  4768 lemma subset_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4769  "{c .. d} \<subseteq> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i \<le> d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th1) and
  4770  "{c .. d} \<subseteq> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i \<le> d$$i) --> (\<forall>i<DIM('a). a$$i < c$$i \<and> d$$i < b$$i)" (is ?th2) and
  4771  "{c<..<d} \<subseteq> {a .. b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i < d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th3) and
  4772  "{c<..<d} \<subseteq> {a<..<b} \<longleftrightarrow> (\<forall>i<DIM('a). c$$i < d$$i) --> (\<forall>i<DIM('a). a$$i \<le> c$$i \<and> d$$i \<le> b$$i)" (is ?th4)
  4773 proof-
  4774   show ?th1 unfolding subset_eq and Ball_def and mem_interval by (auto intro: order_trans)
  4775   show ?th2 unfolding subset_eq and Ball_def and mem_interval by (auto intro: le_less_trans less_le_trans order_trans less_imp_le)
  4776   { assume as: "{c<..<d} \<subseteq> {a .. b}" "\<forall>i<DIM('a). c$$i < d$$i"
  4777     hence "{c<..<d} \<noteq> {}" unfolding interval_eq_empty by auto
  4778     fix i assume i:"i<DIM('a)"
  4779     (** TODO combine the following two parts as done in the HOL_light version. **)
  4780     { let ?x = "(\<chi>\<chi> j. (if j=i then ((min (a$$j) (d$$j))+c$$j)/2 else (c$$j+d$$j)/2))::'a"
  4781       assume as2: "a$$i > c$$i"
  4782       { fix j assume j:"j<DIM('a)"
  4783         hence "c $$ j < ?x $$ j \<and> ?x $$ j < d $$ j"
  4784           apply(cases "j=i") using as(2)[THEN spec[where x=j]] i
  4785           by (auto simp add: as2)  }
  4786       hence "?x\<in>{c<..<d}" using i unfolding mem_interval by auto
  4787       moreover
  4788       have "?x\<notin>{a .. b}"
  4789         unfolding mem_interval apply auto apply(rule_tac x=i in exI)
  4790         using as(2)[THEN spec[where x=i]] and as2 i
  4791         by auto
  4792       ultimately have False using as by auto  }
  4793     hence "a$$i \<le> c$$i" by(rule ccontr)auto
  4794     moreover
  4795     { let ?x = "(\<chi>\<chi> j. (if j=i then ((max (b$$j) (c$$j))+d$$j)/2 else (c$$j+d$$j)/2))::'a"
  4796       assume as2: "b$$i < d$$i"
  4797       { fix j assume "j<DIM('a)"
  4798         hence "d $$ j > ?x $$ j \<and> ?x $$ j > c $$ j" 
  4799           apply(cases "j=i") using as(2)[THEN spec[where x=j]]
  4800           by (auto simp add: as2)  }
  4801       hence "?x\<in>{c<..<d}" unfolding mem_interval by auto
  4802       moreover
  4803       have "?x\<notin>{a .. b}"
  4804         unfolding mem_interval apply auto apply(rule_tac x=i in exI)
  4805         using as(2)[THEN spec[where x=i]] and as2 using i
  4806         by auto
  4807       ultimately have False using as by auto  }
  4808     hence "b$$i \<ge> d$$i" by(rule ccontr)auto
  4809     ultimately
  4810     have "a$$i \<le> c$$i \<and> d$$i \<le> b$$i" by auto
  4811   } note part1 = this
  4812   show ?th3 unfolding subset_eq and Ball_def and mem_interval 
  4813     apply(rule,rule,rule,rule) apply(rule part1) unfolding subset_eq and Ball_def and mem_interval
  4814     prefer 4 apply auto by(erule_tac x=i in allE,erule_tac x=i in allE,fastsimp)+ 
  4815   { assume as:"{c<..<d} \<subseteq> {a<..<b}" "\<forall>i<DIM('a). c$$i < d$$i"
  4816     fix i assume i:"i<DIM('a)"
  4817     from as(1) have "{c<..<d} \<subseteq> {a..b}" using interval_open_subset_closed[of a b] by auto
  4818     hence "a$$i \<le> c$$i \<and> d$$i \<le> b$$i" using part1 and as(2) using i by auto  } note * = this
  4819   show ?th4 unfolding subset_eq and Ball_def and mem_interval 
  4820     apply(rule,rule,rule,rule) apply(rule *) unfolding subset_eq and Ball_def and mem_interval prefer 4
  4821     apply auto by(erule_tac x=i in allE, simp)+ 
  4822 qed
  4823 
  4824 lemma disjoint_interval: fixes a::"'a::ordered_euclidean_space" shows
  4825   "{a .. b} \<inter> {c .. d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i < a$$i \<or> d$$i < c$$i \<or> b$$i < c$$i \<or> d$$i < a$$i))" (is ?th1) and
  4826   "{a .. b} \<inter> {c<..<d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i < a$$i \<or> d$$i \<le> c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th2) and
  4827   "{a<..<b} \<inter> {c .. d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i \<le> a$$i \<or> d$$i < c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th3) and
  4828   "{a<..<b} \<inter> {c<..<d} = {} \<longleftrightarrow> (\<exists>i<DIM('a). (b$$i \<le> a$$i \<or> d$$i \<le> c$$i \<or> b$$i \<le> c$$i \<or> d$$i \<le> a$$i))" (is ?th4)
  4829 proof-
  4830   let ?z = "(\<chi>\<chi> i. ((max (a$$i) (c$$i)) + (min (b$$i) (d$$i))) / 2)::'a"
  4831   note * = set_eq_iff Int_iff empty_iff mem_interval all_conj_distrib[THEN sym] eq_False
  4832   show ?th1 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4833     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4834   show ?th2 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4835     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4836   show ?th3 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4837     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4838   show ?th4 unfolding * apply safe apply(erule_tac x="?z" in allE)
  4839     unfolding not_all apply(erule exE,rule_tac x=x in exI) apply(erule_tac[2-] x=i in allE) by auto
  4840 qed
  4841 
  4842 lemma inter_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4843  "{a .. b} \<inter> {c .. d} =  {(\<chi>\<chi> i. max (a$$i) (c$$i)) .. (\<chi>\<chi> i. min (b$$i) (d$$i))}"
  4844   unfolding set_eq_iff and Int_iff and mem_interval
  4845   by auto
  4846 
  4847 (* Moved interval_open_subset_closed a bit upwards *)
  4848 
  4849 lemma open_interval[intro]:
  4850   fixes a b :: "'a::ordered_euclidean_space" shows "open {a<..<b}"
  4851 proof-
  4852   have "open (\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i<..<b$$i})"
  4853     by (intro open_INT finite_lessThan ballI continuous_open_vimage allI
  4854       linear_continuous_at bounded_linear_euclidean_component
  4855       open_real_greaterThanLessThan)
  4856   also have "(\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i<..<b$$i}) = {a<..<b}"
  4857     by (auto simp add: eucl_less [where 'a='a])
  4858   finally show "open {a<..<b}" .
  4859 qed
  4860 
  4861 lemma closed_interval[intro]:
  4862   fixes a b :: "'a::ordered_euclidean_space" shows "closed {a .. b}"
  4863 proof-
  4864   have "closed (\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i .. b$$i})"
  4865     by (intro closed_INT ballI continuous_closed_vimage allI
  4866       linear_continuous_at bounded_linear_euclidean_component
  4867       closed_real_atLeastAtMost)
  4868   also have "(\<Inter>i<DIM('a). (\<lambda>x. x$$i) -` {a$$i .. b$$i}) = {a .. b}"
  4869     by (auto simp add: eucl_le [where 'a='a])
  4870   finally show "closed {a .. b}" .
  4871 qed
  4872 
  4873 lemma interior_closed_interval[intro]: fixes a :: "'a::ordered_euclidean_space" shows
  4874  "interior {a .. b} = {a<..<b}" (is "?L = ?R")
  4875 proof(rule subset_antisym)
  4876   show "?R \<subseteq> ?L" using interior_maximal[OF interval_open_subset_closed open_interval] by auto
  4877 next
  4878   { fix x assume "\<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> {a..b}"
  4879     then obtain s where s:"open s" "x \<in> s" "s \<subseteq> {a..b}" by auto
  4880     then obtain e where "e>0" and e:"\<forall>x'. dist x' x < e \<longrightarrow> x' \<in> {a..b}" unfolding open_dist and subset_eq by auto
  4881     { fix i assume i:"i<DIM('a)"
  4882       have "dist (x - (e / 2) *\<^sub>R basis i) x < e"
  4883            "dist (x + (e / 2) *\<^sub>R basis i) x < e"
  4884         unfolding dist_norm apply auto
  4885         unfolding norm_minus_cancel using norm_basis and `e>0` by auto
  4886       hence "a $$ i \<le> (x - (e / 2) *\<^sub>R basis i) $$ i"
  4887                      "(x + (e / 2) *\<^sub>R basis i) $$ i \<le> b $$ i"
  4888         using e[THEN spec[where x="x - (e/2) *\<^sub>R basis i"]]
  4889         and   e[THEN spec[where x="x + (e/2) *\<^sub>R basis i"]]
  4890         unfolding mem_interval by (auto elim!: allE[where x=i])
  4891       hence "a $$ i < x $$ i" and "x $$ i < b $$ i" unfolding euclidean_simps
  4892         unfolding basis_component using `e>0` i by auto  }
  4893     hence "x \<in> {a<..<b}" unfolding mem_interval by auto  }
  4894   thus "?L \<subseteq> ?R" unfolding interior_def and subset_eq by auto
  4895 qed
  4896 
  4897 lemma bounded_closed_interval: fixes a :: "'a::ordered_euclidean_space" shows "bounded {a .. b}"
  4898 proof-
  4899   let ?b = "\<Sum>i<DIM('a). \<bar>a$$i\<bar> + \<bar>b$$i\<bar>"
  4900   { fix x::"'a" assume x:"\<forall>i<DIM('a). a $$ i \<le> x $$ i \<and> x $$ i \<le> b $$ i"
  4901     { fix i assume "i<DIM('a)"
  4902       hence "\<bar>x$$i\<bar> \<le> \<bar>a$$i\<bar> + \<bar>b$$i\<bar>" using x[THEN spec[where x=i]] by auto  }
  4903     hence "(\<Sum>i<DIM('a). \<bar>x $$ i\<bar>) \<le> ?b" apply-apply(rule setsum_mono) by auto
  4904     hence "norm x \<le> ?b" using norm_le_l1[of x] by auto  }
  4905   thus ?thesis unfolding interval and bounded_iff by auto
  4906 qed
  4907 
  4908 lemma bounded_interval: fixes a :: "'a::ordered_euclidean_space" shows
  4909  "bounded {a .. b} \<and> bounded {a<..<b}"
  4910   using bounded_closed_interval[of a b]
  4911   using interval_open_subset_closed[of a b]
  4912   using bounded_subset[of "{a..b}" "{a<..<b}"]
  4913   by simp
  4914 
  4915 lemma not_interval_univ: fixes a :: "'a::ordered_euclidean_space" shows
  4916  "({a .. b} \<noteq> UNIV) \<and> ({a<..<b} \<noteq> UNIV)"
  4917   using bounded_interval[of a b] by auto
  4918 
  4919 lemma compact_interval: fixes a :: "'a::ordered_euclidean_space" shows "compact {a .. b}"
  4920   using bounded_closed_imp_compact[of "{a..b}"] using bounded_interval[of a b]
  4921   by auto
  4922 
  4923 lemma open_interval_midpoint: fixes a :: "'a::ordered_euclidean_space"
  4924   assumes "{a<..<b} \<noteq> {}" shows "((1/2) *\<^sub>R (a + b)) \<in> {a<..<b}"
  4925 proof-
  4926   { fix i assume "i<DIM('a)"
  4927     hence "a $$ i < ((1 / 2) *\<^sub>R (a + b)) $$ i \<and> ((1 / 2) *\<^sub>R (a + b)) $$ i < b $$ i"
  4928       using assms[unfolded interval_ne_empty, THEN spec[where x=i]]
  4929       unfolding euclidean_simps by auto  }
  4930   thus ?thesis unfolding mem_interval by auto
  4931 qed
  4932 
  4933 lemma open_closed_interval_convex: fixes x :: "'a::ordered_euclidean_space"
  4934   assumes x:"x \<in> {a<..<b}" and y:"y \<in> {a .. b}" and e:"0 < e" "e \<le> 1"
  4935   shows "(e *\<^sub>R x + (1 - e) *\<^sub>R y) \<in> {a<..<b}"
  4936 proof-
  4937   { fix i assume i:"i<DIM('a)"
  4938     have "a $$ i = e * a$$i + (1 - e) * a$$i" unfolding left_diff_distrib by simp
  4939     also have "\<dots> < e * x $$ i + (1 - e) * y $$ i" apply(rule add_less_le_mono)
  4940       using e unfolding mult_less_cancel_left and mult_le_cancel_left apply simp_all
  4941       using x unfolding mem_interval using i apply simp
  4942       using y unfolding mem_interval using i apply simp
  4943       done
  4944     finally have "a $$ i < (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i" unfolding euclidean_simps by auto
  4945     moreover {
  4946     have "b $$ i = e * b$$i + (1 - e) * b$$i" unfolding left_diff_distrib by simp
  4947     also have "\<dots> > e * x $$ i + (1 - e) * y $$ i" apply(rule add_less_le_mono)
  4948       using e unfolding mult_less_cancel_left and mult_le_cancel_left apply simp_all
  4949       using x unfolding mem_interval using i apply simp
  4950       using y unfolding mem_interval using i apply simp
  4951       done
  4952     finally have "(e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i < b $$ i" unfolding euclidean_simps by auto
  4953     } ultimately have "a $$ i < (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i \<and> (e *\<^sub>R x + (1 - e) *\<^sub>R y) $$ i < b $$ i" by auto }
  4954   thus ?thesis unfolding mem_interval by auto
  4955 qed
  4956 
  4957 lemma closure_open_interval: fixes a :: "'a::ordered_euclidean_space"
  4958   assumes "{a<..<b} \<noteq> {}"
  4959   shows "closure {a<..<b} = {a .. b}"
  4960 proof-
  4961   have ab:"a < b" using assms[unfolded interval_ne_empty] apply(subst eucl_less) by auto
  4962   let ?c = "(1 / 2) *\<^sub>R (a + b)"
  4963   { fix x assume as:"x \<in> {a .. b}"
  4964     def f == "\<lambda>n::nat. x + (inverse (real n + 1)) *\<^sub>R (?c - x)"
  4965     { fix n assume fn:"f n < b \<longrightarrow> a < f n \<longrightarrow> f n = x" and xc:"x \<noteq> ?c"
  4966       have *:"0 < inverse (real n + 1)" "inverse (real n + 1) \<le> 1" unfolding inverse_le_1_iff by auto
  4967       have "(inverse (real n + 1)) *\<^sub>R ((1 / 2) *\<^sub>R (a + b)) + (1 - inverse (real n + 1)) *\<^sub>R x =
  4968         x + (inverse (real n + 1)) *\<^sub>R (((1 / 2) *\<^sub>R (a + b)) - x)"
  4969         by (auto simp add: algebra_simps)
  4970       hence "f n < b" and "a < f n" using open_closed_interval_convex[OF open_interval_midpoint[OF assms] as *] unfolding f_def by auto
  4971       hence False using fn unfolding f_def using xc by auto  }
  4972     moreover
  4973     { assume "\<not> (f ---> x) sequentially"
  4974       { fix e::real assume "e>0"
  4975         hence "\<exists>N::nat. inverse (real (N + 1)) < e" using real_arch_inv[of e] apply (auto simp add: Suc_pred') apply(rule_tac x="n - 1" in exI) by auto
  4976         then obtain N::nat where "inverse (real (N + 1)) < e" by auto
  4977         hence "\<forall>n\<ge>N. inverse (real n + 1) < e" by (auto, metis Suc_le_mono le_SucE less_imp_inverse_less nat_le_real_less order_less_trans real_of_nat_Suc real_of_nat_Suc_gt_zero)
  4978         hence "\<exists>N::nat. \<forall>n\<ge>N. inverse (real n + 1) < e" by auto  }
  4979       hence "((\<lambda>n. inverse (real n + 1)) ---> 0) sequentially"
  4980         unfolding Lim_sequentially by(auto simp add: dist_norm)
  4981       hence "(f ---> x) sequentially" unfolding f_def
  4982         using tendsto_add[OF tendsto_const, of "\<lambda>n::nat. (inverse (real n + 1)) *\<^sub>R ((1 / 2) *\<^sub>R (a + b) - x)" 0 sequentially x]
  4983         using tendsto_scaleR [OF _ tendsto_const, of "\<lambda>n::nat. inverse (real n + 1)" 0 sequentially "((1 / 2) *\<^sub>R (a + b) - x)"] by auto  }
  4984     ultimately have "x \<in> closure {a<..<b}"
  4985       using as and open_interval_midpoint[OF assms] unfolding closure_def unfolding islimpt_sequential by(cases "x=?c")auto  }
  4986   thus ?thesis using closure_minimal[OF interval_open_subset_closed closed_interval, of a b] by blast
  4987 qed
  4988 
  4989 lemma bounded_subset_open_interval_symmetric: fixes s::"('a::ordered_euclidean_space) set"
  4990   assumes "bounded s"  shows "\<exists>a. s \<subseteq> {-a<..<a}"
  4991 proof-
  4992   obtain b where "b>0" and b:"\<forall>x\<in>s. norm x \<le> b" using assms[unfolded bounded_pos] by auto
  4993   def a \<equiv> "(\<chi>\<chi> i. b+1)::'a"
  4994   { fix x assume "x\<in>s"
  4995     fix i assume i:"i<DIM('a)"
  4996     hence "(-a)$$i < x$$i" and "x$$i < a$$i" using b[THEN bspec[where x=x], OF `x\<in>s`]
  4997       and component_le_norm[of x i] unfolding euclidean_simps and a_def by auto  }
  4998   thus ?thesis by(auto intro: exI[where x=a] simp add: eucl_less[where 'a='a])
  4999 qed
  5000 
  5001 lemma bounded_subset_open_interval:
  5002   fixes s :: "('a::ordered_euclidean_space) set"
  5003   shows "bounded s ==> (\<exists>a b. s \<subseteq> {a<..<b})"
  5004   by (auto dest!: bounded_subset_open_interval_symmetric)
  5005 
  5006 lemma bounded_subset_closed_interval_symmetric:
  5007   fixes s :: "('a::ordered_euclidean_space) set"
  5008   assumes "bounded s" shows "\<exists>a. s \<subseteq> {-a .. a}"
  5009 proof-
  5010   obtain a where "s \<subseteq> {- a<..<a}" using bounded_subset_open_interval_symmetric[OF assms] by auto
  5011   thus ?thesis using interval_open_subset_closed[of "-a" a] by auto
  5012 qed
  5013 
  5014 lemma bounded_subset_closed_interval:
  5015   fixes s :: "('a::ordered_euclidean_space) set"
  5016   shows "bounded s ==> (\<exists>a b. s \<subseteq> {a .. b})"
  5017   using bounded_subset_closed_interval_symmetric[of s] by auto
  5018 
  5019 lemma frontier_closed_interval:
  5020   fixes a b :: "'a::ordered_euclidean_space"
  5021   shows "frontier {a .. b} = {a .. b} - {a<..<b}"
  5022   unfolding frontier_def unfolding interior_closed_interval and closure_closed[OF closed_interval] ..
  5023 
  5024 lemma frontier_open_interval:
  5025   fixes a b :: "'a::ordered_euclidean_space"
  5026   shows "frontier {a<..<b} = (if {a<..<b} = {} then {} else {a .. b} - {a<..<b})"
  5027 proof(cases "{a<..<b} = {}")
  5028   case True thus ?thesis using frontier_empty by auto
  5029 next
  5030   case False thus ?thesis unfolding frontier_def and closure_open_interval[OF False] and interior_open[OF open_interval] by auto
  5031 qed
  5032 
  5033 lemma inter_interval_mixed_eq_empty: fixes a :: "'a::ordered_euclidean_space"
  5034   assumes "{c<..<d} \<noteq> {}"  shows "{a<..<b} \<inter> {c .. d} = {} \<longleftrightarrow> {a<..<b} \<inter> {c<..<d} = {}"
  5035   unfolding closure_open_interval[OF assms, THEN sym] unfolding open_inter_closure_eq_empty[OF open_interval] ..
  5036 
  5037 
  5038 (* Some stuff for half-infinite intervals too; FIXME: notation?  *)
  5039 
  5040 lemma closed_interval_left: fixes b::"'a::euclidean_space"
  5041   shows "closed {x::'a. \<forall>i<DIM('a). x$$i \<le> b$$i}"
  5042 proof-
  5043   { fix i assume i:"i<DIM('a)"
  5044     fix x::"'a" assume x:"\<forall>e>0. \<exists>x'\<in>{x. \<forall>i<DIM('a). x $$ i \<le> b $$ i}. x' \<noteq> x \<and> dist x' x < e"
  5045     { assume "x$$i > b$$i"
  5046       then obtain y where "y $$ i \<le> b $$ i"  "y \<noteq> x"  "dist y x < x$$i - b$$i"
  5047         using x[THEN spec[where x="x$$i - b$$i"]] using i by auto
  5048       hence False using component_le_norm[of "y - x" i] unfolding dist_norm euclidean_simps using i 
  5049         by auto   }
  5050     hence "x$$i \<le> b$$i" by(rule ccontr)auto  }
  5051   thus ?thesis unfolding closed_limpt unfolding islimpt_approachable by blast
  5052 qed
  5053 
  5054 lemma closed_interval_right: fixes a::"'a::euclidean_space"
  5055   shows "closed {x::'a. \<forall>i<DIM('a). a$$i \<le> x$$i}"
  5056 proof-
  5057   { fix i assume i:"i<DIM('a)"
  5058     fix x::"'a" assume x:"\<forall>e>0. \<exists>x'\<in>{x. \<forall>i<DIM('a). a $$ i \<le> x $$ i}. x' \<noteq> x \<and> dist x' x < e"
  5059     { assume "a$$i > x$$i"
  5060       then obtain y where "a $$ i \<le> y $$ i"  "y \<noteq> x"  "dist y x < a$$i - x$$i"
  5061         using x[THEN spec[where x="a$$i - x$$i"]] i by auto
  5062       hence False using component_le_norm[of "y - x" i] unfolding dist_norm and euclidean_simps by auto   }
  5063     hence "a$$i \<le> x$$i" by(rule ccontr)auto  }
  5064   thus ?thesis unfolding closed_limpt unfolding islimpt_approachable by blast
  5065 qed
  5066 
  5067 text {* Intervals in general, including infinite and mixtures of open and closed. *}
  5068 
  5069 definition "is_interval (s::('a::euclidean_space) set) \<longleftrightarrow>
  5070   (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i<DIM('a). ((a$$i \<le> x$$i \<and> x$$i \<le> b$$i) \<or> (b$$i \<le> x$$i \<and> x$$i \<le> a$$i))) \<longrightarrow> x \<in> s)"
  5071 
  5072 lemma is_interval_interval: "is_interval {a .. b::'a::ordered_euclidean_space}" (is ?th1)
  5073   "is_interval {a<..<b}" (is ?th2) proof -
  5074   have *:"\<And>x y z::real. x < y \<Longrightarrow> y < z \<Longrightarrow> x < z" by auto
  5075   show ?th1 ?th2  unfolding is_interval_def mem_interval Ball_def atLeastAtMost_iff
  5076     by(meson order_trans le_less_trans less_le_trans *)+ qed
  5077 
  5078 lemma is_interval_empty:
  5079  "is_interval {}"
  5080   unfolding is_interval_def
  5081   by simp
  5082 
  5083 lemma is_interval_univ:
  5084  "is_interval UNIV"
  5085   unfolding is_interval_def
  5086   by simp
  5087 
  5088 
  5089 subsection {* Closure of halfspaces and hyperplanes *}
  5090 
  5091 lemma isCont_open_vimage:
  5092   assumes "\<And>x. isCont f x" and "open s" shows "open (f -` s)"
  5093 proof -
  5094   from assms(1) have "continuous_on UNIV f"
  5095     unfolding isCont_def continuous_on_def within_UNIV by simp
  5096   hence "open {x \<in> UNIV. f x \<in> s}"
  5097     using open_UNIV `open s` by (rule continuous_open_preimage)
  5098   thus "open (f -` s)"
  5099     by (simp add: vimage_def)
  5100 qed
  5101 
  5102 lemma isCont_closed_vimage:
  5103   assumes "\<And>x. isCont f x" and "closed s" shows "closed (f -` s)"
  5104   using assms unfolding closed_def vimage_Compl [symmetric]
  5105   by (rule isCont_open_vimage)
  5106 
  5107 lemma open_Collect_less:
  5108   fixes f g :: "'a::topological_space \<Rightarrow> real"
  5109   assumes f: "\<And>x. isCont f x"
  5110   assumes g: "\<And>x. isCont g x"
  5111   shows "open {x. f x < g x}"
  5112 proof -
  5113   have "open ((\<lambda>x. g x - f x) -` {0<..})"
  5114     using isCont_diff [OF g f] open_real_greaterThan
  5115     by (rule isCont_open_vimage)
  5116   also have "((\<lambda>x. g x - f x) -` {0<..}) = {x. f x < g x}"
  5117     by auto
  5118   finally show ?thesis .
  5119 qed
  5120 
  5121 lemma closed_Collect_le:
  5122   fixes f g :: "'a::topological_space \<Rightarrow> real"
  5123   assumes f: "\<And>x. isCont f x"
  5124   assumes g: "\<And>x. isCont g x"
  5125   shows "closed {x. f x \<le> g x}"
  5126 proof -
  5127   have "closed ((\<lambda>x. g x - f x) -` {0..})"
  5128     using isCont_diff [OF g f] closed_real_atLeast
  5129     by (rule isCont_closed_vimage)
  5130   also have "((\<lambda>x. g x - f x) -` {0..}) = {x. f x \<le> g x}"
  5131     by auto
  5132   finally show ?thesis .
  5133 qed
  5134 
  5135 lemma closed_Collect_eq:
  5136   fixes f g :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  5137   assumes f: "\<And>x. isCont f x"
  5138   assumes g: "\<And>x. isCont g x"
  5139   shows "closed {x. f x = g x}"
  5140 proof -
  5141   have "open {(x::'b, y::'b). x \<noteq> y}"
  5142     unfolding open_prod_def by (auto dest!: hausdorff)
  5143   hence "closed {(x::'b, y::'b). x = y}"
  5144     unfolding closed_def split_def Collect_neg_eq .
  5145   with isCont_Pair [OF f g]
  5146   have "closed ((\<lambda>x. (f x, g x)) -` {(x, y). x = y})"
  5147     by (rule isCont_closed_vimage)
  5148   also have "\<dots> = {x. f x = g x}" by auto
  5149   finally show ?thesis .
  5150 qed
  5151 
  5152 lemma Lim_inner:
  5153   assumes "(f ---> l) net"  shows "((\<lambda>y. inner a (f y)) ---> inner a l) net"
  5154   by (intro tendsto_intros assms)
  5155 
  5156 lemma continuous_at_inner: "continuous (at x) (inner a)"
  5157   unfolding continuous_at by (intro tendsto_intros)
  5158 
  5159 lemma continuous_at_euclidean_component[intro!, simp]: "continuous (at x) (\<lambda>x. x $$ i)"
  5160   unfolding euclidean_component_def by (rule continuous_at_inner)
  5161 
  5162 lemma continuous_on_inner:
  5163   fixes s :: "'a::real_inner set"
  5164   shows "continuous_on s (inner a)"
  5165   unfolding continuous_on by (rule ballI) (intro tendsto_intros)
  5166 
  5167 lemma closed_halfspace_le: "closed {x. inner a x \<le> b}"
  5168   by (simp add: closed_Collect_le)
  5169 
  5170 lemma closed_halfspace_ge: "closed {x. inner a x \<ge> b}"
  5171   by (simp add: closed_Collect_le)
  5172 
  5173 lemma closed_hyperplane: "closed {x. inner a x = b}"
  5174   by (simp add: closed_Collect_eq)
  5175 
  5176 lemma closed_halfspace_component_le:
  5177   shows "closed {x::'a::euclidean_space. x$$i \<le> a}"
  5178   by (simp add: closed_Collect_le)
  5179 
  5180 lemma closed_halfspace_component_ge:
  5181   shows "closed {x::'a::euclidean_space. x$$i \<ge> a}"
  5182   by (simp add: closed_Collect_le)
  5183 
  5184 text {* Openness of halfspaces. *}
  5185 
  5186 lemma open_halfspace_lt: "open {x. inner a x < b}"
  5187   by (simp add: open_Collect_less)
  5188 
  5189 lemma open_halfspace_gt: "open {x. inner a x > b}"
  5190   by (simp add: open_Collect_less)
  5191 
  5192 lemma open_halfspace_component_lt:
  5193   shows "open {x::'a::euclidean_space. x$$i < a}"
  5194   by (simp add: open_Collect_less)
  5195 
  5196 lemma open_halfspace_component_gt:
  5197   shows "open {x::'a::euclidean_space. x$$i > a}"
  5198   by (simp add: open_Collect_less)
  5199 
  5200 text{* Instantiation for intervals on @{text ordered_euclidean_space} *}
  5201 
  5202 lemma eucl_lessThan_eq_halfspaces:
  5203   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5204   shows "{..<a} = (\<Inter>i<DIM('a). {x. x $$ i < a $$ i})"
  5205  by (auto simp: eucl_less[where 'a='a])
  5206 
  5207 lemma eucl_greaterThan_eq_halfspaces:
  5208   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5209   shows "{a<..} = (\<Inter>i<DIM('a). {x. a $$ i < x $$ i})"
  5210  by (auto simp: eucl_less[where 'a='a])
  5211 
  5212 lemma eucl_atMost_eq_halfspaces:
  5213   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5214   shows "{.. a} = (\<Inter>i<DIM('a). {x. x $$ i \<le> a $$ i})"
  5215  by (auto simp: eucl_le[where 'a='a])
  5216 
  5217 lemma eucl_atLeast_eq_halfspaces:
  5218   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5219   shows "{a ..} = (\<Inter>i<DIM('a). {x. a $$ i \<le> x $$ i})"
  5220  by (auto simp: eucl_le[where 'a='a])
  5221 
  5222 lemma open_eucl_lessThan[simp, intro]:
  5223   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5224   shows "open {..< a}"
  5225   by (auto simp: eucl_lessThan_eq_halfspaces open_halfspace_component_lt)
  5226 
  5227 lemma open_eucl_greaterThan[simp, intro]:
  5228   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5229   shows "open {a <..}"
  5230   by (auto simp: eucl_greaterThan_eq_halfspaces open_halfspace_component_gt)
  5231 
  5232 lemma closed_eucl_atMost[simp, intro]:
  5233   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5234   shows "closed {.. a}"
  5235   unfolding eucl_atMost_eq_halfspaces
  5236   by (simp add: closed_INT closed_Collect_le)
  5237 
  5238 lemma closed_eucl_atLeast[simp, intro]:
  5239   fixes a :: "'a\<Colon>ordered_euclidean_space"
  5240   shows "closed {a ..}"
  5241   unfolding eucl_atLeast_eq_halfspaces
  5242   by (simp add: closed_INT closed_Collect_le)
  5243 
  5244 lemma open_vimage_euclidean_component: "open S \<Longrightarrow> open ((\<lambda>x. x $$ i) -` S)"
  5245   by (auto intro!: continuous_open_vimage)
  5246 
  5247 text {* This gives a simple derivation of limit component bounds. *}
  5248 
  5249 lemma Lim_component_le: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5250   assumes "(f ---> l) net" "\<not> (trivial_limit net)"  "eventually (\<lambda>x. f(x)$$i \<le> b) net"
  5251   shows "l$$i \<le> b"
  5252 proof-
  5253   { fix x have "x \<in> {x::'b. inner (basis i) x \<le> b} \<longleftrightarrow> x$$i \<le> b"
  5254       unfolding euclidean_component_def by auto  } note * = this
  5255   show ?thesis using Lim_in_closed_set[of "{x. inner (basis i) x \<le> b}" f net l] unfolding *
  5256     using closed_halfspace_le[of "(basis i)::'b" b] and assms(1,2,3) by auto
  5257 qed
  5258 
  5259 lemma Lim_component_ge: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5260   assumes "(f ---> l) net"  "\<not> (trivial_limit net)"  "eventually (\<lambda>x. b \<le> (f x)$$i) net"
  5261   shows "b \<le> l$$i"
  5262 proof-
  5263   { fix x have "x \<in> {x::'b. inner (basis i) x \<ge> b} \<longleftrightarrow> x$$i \<ge> b"
  5264       unfolding euclidean_component_def by auto  } note * = this
  5265   show ?thesis using Lim_in_closed_set[of "{x. inner (basis i) x \<ge> b}" f net l] unfolding *
  5266     using closed_halfspace_ge[of b "(basis i)"] and assms(1,2,3) by auto
  5267 qed
  5268 
  5269 lemma Lim_component_eq: fixes f :: "'a \<Rightarrow> 'b::euclidean_space"
  5270   assumes net:"(f ---> l) net" "~(trivial_limit net)" and ev:"eventually (\<lambda>x. f(x)$$i = b) net"
  5271   shows "l$$i = b"
  5272   using ev[unfolded order_eq_iff eventually_conj_iff] using Lim_component_ge[OF net, of b i] and Lim_component_le[OF net, of i b] by auto
  5273 text{* Limits relative to a union.                                               *}
  5274 
  5275 lemma eventually_within_Un:
  5276   "eventually P (net within (s \<union> t)) \<longleftrightarrow>
  5277     eventually P (net within s) \<and> eventually P (net within t)"
  5278   unfolding Limits.eventually_within
  5279   by (auto elim!: eventually_rev_mp)
  5280 
  5281 lemma Lim_within_union:
  5282  "(f ---> l) (net within (s \<union> t)) \<longleftrightarrow>
  5283   (f ---> l) (net within s) \<and> (f ---> l) (net within t)"
  5284   unfolding tendsto_def
  5285   by (auto simp add: eventually_within_Un)
  5286 
  5287 lemma Lim_topological:
  5288  "(f ---> l) net \<longleftrightarrow>
  5289         trivial_limit net \<or>
  5290         (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) net)"
  5291   unfolding tendsto_def trivial_limit_eq by auto
  5292 
  5293 lemma continuous_on_union:
  5294   assumes "closed s" "closed t" "continuous_on s f" "continuous_on t f"
  5295   shows "continuous_on (s \<union> t) f"
  5296   using assms unfolding continuous_on Lim_within_union
  5297   unfolding Lim_topological trivial_limit_within closed_limpt by auto
  5298 
  5299 lemma continuous_on_cases:
  5300   assumes "closed s" "closed t" "continuous_on s f" "continuous_on t g"
  5301           "\<forall>x. (x\<in>s \<and> \<not> P x) \<or> (x \<in> t \<and> P x) \<longrightarrow> f x = g x"
  5302   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)"
  5303 proof-
  5304   let ?h = "(\<lambda>x. if P x then f x else g x)"
  5305   have "\<forall>x\<in>s. f x = (if P x then f x else g x)" using assms(5) by auto
  5306   hence "continuous_on s ?h" using continuous_on_eq[of s f ?h] using assms(3) by auto
  5307   moreover
  5308   have "\<forall>x\<in>t. g x = (if P x then f x else g x)" using assms(5) by auto
  5309   hence "continuous_on t ?h" using continuous_on_eq[of t g ?h] using assms(4) by auto
  5310   ultimately show ?thesis using continuous_on_union[OF assms(1,2), of ?h] by auto
  5311 qed
  5312 
  5313 
  5314 text{* Some more convenient intermediate-value theorem formulations.             *}
  5315 
  5316 lemma connected_ivt_hyperplane:
  5317   assumes "connected s" "x \<in> s" "y \<in> s" "inner a x \<le> b" "b \<le> inner a y"
  5318   shows "\<exists>z \<in> s. inner a z = b"
  5319 proof(rule ccontr)
  5320   assume as:"\<not> (\<exists>z\<in>s. inner a z = b)"
  5321   let ?A = "{x. inner a x < b}"
  5322   let ?B = "{x. inner a x > b}"
  5323   have "open ?A" "open ?B" using open_halfspace_lt and open_halfspace_gt by auto
  5324   moreover have "?A \<inter> ?B = {}" by auto
  5325   moreover have "s \<subseteq> ?A \<union> ?B" using as by auto
  5326   ultimately show False using assms(1)[unfolded connected_def not_ex, THEN spec[where x="?A"], THEN spec[where x="?B"]] and assms(2-5) by auto
  5327 qed
  5328 
  5329 lemma connected_ivt_component: fixes x::"'a::euclidean_space" shows
  5330  "connected s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> x$$k \<le> a \<Longrightarrow> a \<le> y$$k \<Longrightarrow> (\<exists>z\<in>s.  z$$k = a)"
  5331   using connected_ivt_hyperplane[of s x y "(basis k)::'a" a]
  5332   unfolding euclidean_component_def by auto
  5333 
  5334 
  5335 subsection {* Homeomorphisms *}
  5336 
  5337 definition "homeomorphism s t f g \<equiv>
  5338      (\<forall>x\<in>s. (g(f x) = x)) \<and> (f ` s = t) \<and> continuous_on s f \<and>
  5339      (\<forall>y\<in>t. (f(g y) = y)) \<and> (g ` t = s) \<and> continuous_on t g"
  5340 
  5341 definition
  5342   homeomorphic :: "'a::metric_space set \<Rightarrow> 'b::metric_space set \<Rightarrow> bool"
  5343     (infixr "homeomorphic" 60) where
  5344   homeomorphic_def: "s homeomorphic t \<equiv> (\<exists>f g. homeomorphism s t f g)"
  5345 
  5346 lemma homeomorphic_refl: "s homeomorphic s"
  5347   unfolding homeomorphic_def
  5348   unfolding homeomorphism_def
  5349   using continuous_on_id
  5350   apply(rule_tac x = "(\<lambda>x. x)" in exI)
  5351   apply(rule_tac x = "(\<lambda>x. x)" in exI)
  5352   by blast
  5353 
  5354 lemma homeomorphic_sym:
  5355  "s homeomorphic t \<longleftrightarrow> t homeomorphic s"
  5356 unfolding homeomorphic_def
  5357 unfolding homeomorphism_def
  5358 by blast 
  5359 
  5360 lemma homeomorphic_trans:
  5361   assumes "s homeomorphic t" "t homeomorphic u" shows "s homeomorphic u"
  5362 proof-
  5363   obtain f1 g1 where fg1:"\<forall>x\<in>s. g1 (f1 x) = x"  "f1 ` s = t" "continuous_on s f1" "\<forall>y\<in>t. f1 (g1 y) = y" "g1 ` t = s" "continuous_on t g1"
  5364     using assms(1) unfolding homeomorphic_def homeomorphism_def by auto
  5365   obtain f2 g2 where fg2:"\<forall>x\<in>t. g2 (f2 x) = x"  "f2 ` t = u" "continuous_on t f2" "\<forall>y\<in>u. f2 (g2 y) = y" "g2 ` u = t" "continuous_on u g2"
  5366     using assms(2) unfolding homeomorphic_def homeomorphism_def by auto
  5367 
  5368   { fix x assume "x\<in>s" hence "(g1 \<circ> g2) ((f2 \<circ> f1) x) = x" using fg1(1)[THEN bspec[where x=x]] and fg2(1)[THEN bspec[where x="f1 x"]] and fg1(2) by auto }
  5369   moreover have "(f2 \<circ> f1) ` s = u" using fg1(2) fg2(2) by auto
  5370   moreover have "continuous_on s (f2 \<circ> f1)" using continuous_on_compose[OF fg1(3)] and fg2(3) unfolding fg1(2) by auto
  5371   moreover { fix y assume "y\<in>u" hence "(f2 \<circ> f1) ((g1 \<circ> g2) y) = y" using fg2(4)[THEN bspec[where x=y]] and fg1(4)[THEN bspec[where x="g2 y"]] and fg2(5) by auto }
  5372   moreover have "(g1 \<circ> g2) ` u = s" using fg1(5) fg2(5) by auto
  5373   moreover have "continuous_on u (g1 \<circ> g2)" using continuous_on_compose[OF fg2(6)] and fg1(6)  unfolding fg2(5) by auto
  5374   ultimately show ?thesis unfolding homeomorphic_def homeomorphism_def apply(rule_tac x="f2 \<circ> f1" in exI) apply(rule_tac x="g1 \<circ> g2" in exI) by auto
  5375 qed
  5376 
  5377 lemma homeomorphic_minimal:
  5378  "s homeomorphic t \<longleftrightarrow>
  5379     (\<exists>f g. (\<forall>x\<in>s. f(x) \<in> t \<and> (g(f(x)) = x)) \<and>
  5380            (\<forall>y\<in>t. g(y) \<in> s \<and> (f(g(y)) = y)) \<and>
  5381            continuous_on s f \<and> continuous_on t g)"
  5382 unfolding homeomorphic_def homeomorphism_def
  5383 apply auto apply (rule_tac x=f in exI) apply (rule_tac x=g in exI)
  5384 apply auto apply (rule_tac x=f in exI) apply (rule_tac x=g in exI) apply auto
  5385 unfolding image_iff
  5386 apply(erule_tac x="g x" in ballE) apply(erule_tac x="x" in ballE)
  5387 apply auto apply(rule_tac x="g x" in bexI) apply auto
  5388 apply(erule_tac x="f x" in ballE) apply(erule_tac x="x" in ballE)
  5389 apply auto apply(rule_tac x="f x" in bexI) by auto
  5390 
  5391 text {* Relatively weak hypotheses if a set is compact. *}
  5392 
  5393 lemma homeomorphism_compact:
  5394   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  5395     (* class constraint due to continuous_on_inverse *)
  5396   assumes "compact s" "continuous_on s f"  "f ` s = t"  "inj_on f s"
  5397   shows "\<exists>g. homeomorphism s t f g"
  5398 proof-
  5399   def g \<equiv> "\<lambda>x. SOME y. y\<in>s \<and> f y = x"
  5400   have g:"\<forall>x\<in>s. g (f x) = x" using assms(3) assms(4)[unfolded inj_on_def] unfolding g_def by auto
  5401   { fix y assume "y\<in>t"
  5402     then obtain x where x:"f x = y" "x\<in>s" using assms(3) by auto
  5403     hence "g (f x) = x" using g by auto
  5404     hence "f (g y) = y" unfolding x(1)[THEN sym] by auto  }
  5405   hence g':"\<forall>x\<in>t. f (g x) = x" by auto
  5406   moreover
  5407   { fix x
  5408     have "x\<in>s \<Longrightarrow> x \<in> g ` t" using g[THEN bspec[where x=x]] unfolding image_iff using assms(3) by(auto intro!: bexI[where x="f x"])
  5409     moreover
  5410     { assume "x\<in>g ` t"
  5411       then obtain y where y:"y\<in>t" "g y = x" by auto
  5412       then obtain x' where x':"x'\<in>s" "f x' = y" using assms(3) by auto
  5413       hence "x \<in> s" unfolding g_def using someI2[of "\<lambda>b. b\<in>s \<and> f b = y" x' "\<lambda>x. x\<in>s"] unfolding y(2)[THEN sym] and g_def by auto }
  5414     ultimately have "x\<in>s \<longleftrightarrow> x \<in> g ` t" ..  }
  5415   hence "g ` t = s" by auto
  5416   ultimately
  5417   show ?thesis unfolding homeomorphism_def homeomorphic_def
  5418     apply(rule_tac x=g in exI) using g and assms(3) and continuous_on_inverse[OF assms(2,1), of g, unfolded assms(3)] and assms(2) by auto
  5419 qed
  5420 
  5421 lemma homeomorphic_compact:
  5422   fixes f :: "'a::heine_borel \<Rightarrow> 'b::heine_borel"
  5423     (* class constraint due to continuous_on_inverse *)
  5424   shows "compact s \<Longrightarrow> continuous_on s f \<Longrightarrow> (f ` s = t) \<Longrightarrow> inj_on f s
  5425           \<Longrightarrow> s homeomorphic t"
  5426   unfolding homeomorphic_def by (metis homeomorphism_compact)
  5427 
  5428 text{* Preservation of topological properties.                                   *}
  5429 
  5430 lemma homeomorphic_compactness:
  5431  "s homeomorphic t ==> (compact s \<longleftrightarrow> compact t)"
  5432 unfolding homeomorphic_def homeomorphism_def
  5433 by (metis compact_continuous_image)
  5434 
  5435 text{* Results on translation, scaling etc.                                      *}
  5436 
  5437 lemma homeomorphic_scaling:
  5438   fixes s :: "'a::real_normed_vector set"
  5439   assumes "c \<noteq> 0"  shows "s homeomorphic ((\<lambda>x. c *\<^sub>R x) ` s)"
  5440   unfolding homeomorphic_minimal
  5441   apply(rule_tac x="\<lambda>x. c *\<^sub>R x" in exI)
  5442   apply(rule_tac x="\<lambda>x. (1 / c) *\<^sub>R x" in exI)
  5443   using assms apply auto
  5444   using continuous_on_cmul[OF continuous_on_id] by auto
  5445 
  5446 lemma homeomorphic_translation:
  5447   fixes s :: "'a::real_normed_vector set"
  5448   shows "s homeomorphic ((\<lambda>x. a + x) ` s)"
  5449   unfolding homeomorphic_minimal
  5450   apply(rule_tac x="\<lambda>x. a + x" in exI)
  5451   apply(rule_tac x="\<lambda>x. -a + x" in exI)
  5452   using continuous_on_add[OF continuous_on_const continuous_on_id] by auto
  5453 
  5454 lemma homeomorphic_affinity:
  5455   fixes s :: "'a::real_normed_vector set"
  5456   assumes "c \<noteq> 0"  shows "s homeomorphic ((\<lambda>x. a + c *\<^sub>R x) ` s)"
  5457 proof-
  5458   have *:"op + a ` op *\<^sub>R c ` s = (\<lambda>x. a + c *\<^sub>R x) ` s" by auto
  5459   show ?thesis
  5460     using homeomorphic_trans
  5461     using homeomorphic_scaling[OF assms, of s]
  5462     using homeomorphic_translation[of "(\<lambda>x. c *\<^sub>R x) ` s" a] unfolding * by auto
  5463 qed
  5464 
  5465 lemma homeomorphic_balls:
  5466   fixes a b ::"'a::real_normed_vector" (* FIXME: generalize to metric_space *)
  5467   assumes "0 < d"  "0 < e"
  5468   shows "(ball a d) homeomorphic  (ball b e)" (is ?th)
  5469         "(cball a d) homeomorphic (cball b e)" (is ?cth)
  5470 proof-
  5471   have *:"\<bar>e / d\<bar> > 0" "\<bar>d / e\<bar> >0" using assms using divide_pos_pos by auto
  5472   show ?th unfolding homeomorphic_minimal
  5473     apply(rule_tac x="\<lambda>x. b + (e/d) *\<^sub>R (x - a)" in exI)
  5474     apply(rule_tac x="\<lambda>x. a + (d/e) *\<^sub>R (x - b)" in exI)
  5475     using assms apply (auto simp add: dist_commute)
  5476     unfolding dist_norm
  5477     apply (auto simp add: pos_divide_less_eq mult_strict_left_mono)
  5478     unfolding continuous_on
  5479     by (intro ballI tendsto_intros, simp)+
  5480 next
  5481   have *:"\<bar>e / d\<bar> > 0" "\<bar>d / e\<bar> >0" using assms using divide_pos_pos by auto
  5482   show ?cth unfolding homeomorphic_minimal
  5483     apply(rule_tac x="\<lambda>x. b + (e/d) *\<^sub>R (x - a)" in exI)
  5484     apply(rule_tac x="\<lambda>x. a + (d/e) *\<^sub>R (x - b)" in exI)
  5485     using assms apply (auto simp add: dist_commute)
  5486     unfolding dist_norm
  5487     apply (auto simp add: pos_divide_le_eq)
  5488     unfolding continuous_on
  5489     by (intro ballI tendsto_intros, simp)+
  5490 qed
  5491 
  5492 text{* "Isometry" (up to constant bounds) of injective linear map etc.           *}
  5493 
  5494 lemma cauchy_isometric:
  5495   fixes x :: "nat \<Rightarrow> 'a::euclidean_space"
  5496   assumes e:"0 < e" and s:"subspace s" and f:"bounded_linear f" and normf:"\<forall>x\<in>s. norm(f x) \<ge> e * norm(x)" and xs:"\<forall>n::nat. x n \<in> s" and cf:"Cauchy(f o x)"
  5497   shows "Cauchy x"
  5498 proof-
  5499   interpret f: bounded_linear f by fact
  5500   { fix d::real assume "d>0"
  5501     then obtain N where N:"\<forall>n\<ge>N. norm (f (x n) - f (x N)) < e * d"
  5502       using cf[unfolded cauchy o_def dist_norm, THEN spec[where x="e*d"]] and e and mult_pos_pos[of e d] by auto
  5503     { fix n assume "n\<ge>N"
  5504       hence "norm (f (x n - x N)) < e * d" using N[THEN spec[where x=n]] unfolding f.diff[THEN sym] by auto
  5505       moreover have "e * norm (x n - x N) \<le> norm (f (x n - x N))"
  5506         using subspace_sub[OF s, of "x n" "x N"] using xs[THEN spec[where x=N]] and xs[THEN spec[where x=n]]
  5507         using normf[THEN bspec[where x="x n - x N"]] by auto
  5508       ultimately have "norm (x n - x N) < d" using `e>0`
  5509         using mult_left_less_imp_less[of e "norm (x n - x N)" d] by auto   }
  5510     hence "\<exists>N. \<forall>n\<ge>N. norm (x n - x N) < d" by auto }
  5511   thus ?thesis unfolding cauchy and dist_norm by auto
  5512 qed
  5513 
  5514 lemma complete_isometric_image:
  5515   fixes f :: "'a::euclidean_space => 'b::euclidean_space"
  5516   assumes "0 < e" and s:"subspace s" and f:"bounded_linear f" and normf:"\<forall>x\<in>s. norm(f x) \<ge> e * norm(x)" and cs:"complete s"
  5517   shows "complete(f ` s)"
  5518 proof-
  5519   { fix g assume as:"\<forall>n::nat. g n \<in> f ` s" and cfg:"Cauchy g"
  5520     then obtain x where "\<forall>n. x n \<in> s \<and> g n = f (x n)" 
  5521       using choice[of "\<lambda> n xa. xa \<in> s \<and> g n = f xa"] by auto
  5522     hence x:"\<forall>n. x n \<in> s"  "\<forall>n. g n = f (x n)" by auto
  5523     hence "f \<circ> x = g" unfolding fun_eq_iff by auto
  5524     then obtain l where "l\<in>s" and l:"(x ---> l) sequentially"
  5525       using cs[unfolded complete_def, THEN spec[where x="x"]]
  5526       using cauchy_isometric[OF `0<e` s f normf] and cfg and x(1) by auto
  5527     hence "\<exists>l\<in>f ` s. (g ---> l) sequentially"
  5528       using linear_continuous_at[OF f, unfolded continuous_at_sequentially, THEN spec[where x=x], of l]
  5529       unfolding `f \<circ> x = g` by auto  }
  5530   thus ?thesis unfolding complete_def by auto
  5531 qed
  5532 
  5533 lemma dist_0_norm:
  5534   fixes x :: "'a::real_normed_vector"
  5535   shows "dist 0 x = norm x"
  5536 unfolding dist_norm by simp
  5537 
  5538 lemma injective_imp_isometric: fixes f::"'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  5539   assumes s:"closed s"  "subspace s"  and f:"bounded_linear f" "\<forall>x\<in>s. (f x = 0) \<longrightarrow> (x = 0)"
  5540   shows "\<exists>e>0. \<forall>x\<in>s. norm (f x) \<ge> e * norm(x)"
  5541 proof(cases "s \<subseteq> {0::'a}")
  5542   case True
  5543   { fix x assume "x \<in> s"
  5544     hence "x = 0" using True by auto
  5545     hence "norm x \<le> norm (f x)" by auto  }
  5546   thus ?thesis by(auto intro!: exI[where x=1])
  5547 next
  5548   interpret f: bounded_linear f by fact
  5549   case False
  5550   then obtain a where a:"a\<noteq>0" "a\<in>s" by auto
  5551   from False have "s \<noteq> {}" by auto
  5552   let ?S = "{f x| x. (x \<in> s \<and> norm x = norm a)}"
  5553   let ?S' = "{x::'a. x\<in>s \<and> norm x = norm a}"
  5554   let ?S'' = "{x::'a. norm x = norm a}"
  5555 
  5556   have "?S'' = frontier(cball 0 (norm a))" unfolding frontier_cball and dist_norm by auto
  5557   hence "compact ?S''" using compact_frontier[OF compact_cball, of 0 "norm a"] by auto
  5558   moreover have "?S' = s \<inter> ?S''" by auto
  5559   ultimately have "compact ?S'" using closed_inter_compact[of s ?S''] using s(1) by auto
  5560   moreover have *:"f ` ?S' = ?S" by auto
  5561   ultimately have "compact ?S" using compact_continuous_image[OF linear_continuous_on[OF f(1)], of ?S'] by auto
  5562   hence "closed ?S" using compact_imp_closed by auto
  5563   moreover have "?S \<noteq> {}" using a by auto
  5564   ultimately obtain b' where "b'\<in>?S" "\<forall>y\<in>?S. norm b' \<le> norm y" using distance_attains_inf[of ?S 0] unfolding dist_0_norm by auto
  5565   then obtain b where "b\<in>s" and ba:"norm b = norm a" and b:"\<forall>x\<in>{x \<in> s. norm x = norm a}. norm (f b) \<le> norm (f x)" unfolding *[THEN sym] unfolding image_iff by auto
  5566 
  5567   let ?e = "norm (f b) / norm b"
  5568   have "norm b > 0" using ba and a and norm_ge_zero by auto
  5569   moreover have "norm (f b) > 0" using f(2)[THEN bspec[where x=b], OF `b\<in>s`] using `norm b >0` unfolding zero_less_norm_iff by auto
  5570   ultimately have "0 < norm (f b) / norm b" by(simp only: divide_pos_pos)
  5571   moreover
  5572   { fix x assume "x\<in>s"
  5573     hence "norm (f b) / norm b * norm x \<le> norm (f x)"
  5574     proof(cases "x=0")
  5575       case True thus "norm (f b) / norm b * norm x \<le> norm (f x)" by auto
  5576     next
  5577       case False
  5578       hence *:"0 < norm a / norm x" using `a\<noteq>0` unfolding zero_less_norm_iff[THEN sym] by(simp only: divide_pos_pos)
  5579       have "\<forall>c. \<forall>x\<in>s. c *\<^sub>R x \<in> s" using s[unfolded subspace_def] by auto
  5580       hence "(norm a / norm x) *\<^sub>R x \<in> {x \<in> s. norm x = norm a}" using `x\<in>s` and `x\<noteq>0` by auto
  5581       thus "norm (f b) / norm b * norm x \<le> norm (f x)" using b[THEN bspec[where x="(norm a / norm x) *\<^sub>R x"]]
  5582         unfolding f.scaleR and ba using `x\<noteq>0` `a\<noteq>0`
  5583         by (auto simp add: mult_commute pos_le_divide_eq pos_divide_le_eq)
  5584     qed }
  5585   ultimately
  5586   show ?thesis by auto
  5587 qed
  5588 
  5589 lemma closed_injective_image_subspace:
  5590   fixes f :: "'a::euclidean_space \<Rightarrow> 'b::euclidean_space"
  5591   assumes "subspace s" "bounded_linear f" "\<forall>x\<in>s. f x = 0 --> x = 0" "closed s"
  5592   shows "closed(f ` s)"
  5593 proof-
  5594   obtain e where "e>0" and e:"\<forall>x\<in>s. e * norm x \<le> norm (f x)" using injective_imp_isometric[OF assms(4,1,2,3)] by auto
  5595   show ?thesis using complete_isometric_image[OF `e>0` assms(1,2) e] and assms(4)
  5596     unfolding complete_eq_closed[THEN sym] by auto
  5597 qed
  5598 
  5599 
  5600 subsection {* Some properties of a canonical subspace *}
  5601 
  5602 lemma subspace_substandard:
  5603   "subspace {x::'a::euclidean_space. (\<forall>i<DIM('a). P i \<longrightarrow> x$$i = 0)}"
  5604   unfolding subspace_def by auto
  5605 
  5606 lemma closed_substandard:
  5607  "closed {x::'a::euclidean_space. \<forall>i<DIM('a). P i --> x$$i = 0}" (is "closed ?A")
  5608 proof-
  5609   let ?D = "{i. P i} \<inter> {..<DIM('a)}"
  5610   have "closed (\<Inter>i\<in>?D. {x::'a. x$$i = 0})"
  5611     by (simp add: closed_INT closed_Collect_eq)
  5612   also have "(\<Inter>i\<in>?D. {x::'a. x$$i = 0}) = ?A"
  5613     by auto
  5614   finally show "closed ?A" .
  5615 qed
  5616 
  5617 lemma dim_substandard: assumes "d\<subseteq>{..<DIM('a::euclidean_space)}"
  5618   shows "dim {x::'a::euclidean_space. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x$$i = 0} = card d" (is "dim ?A = _")
  5619 proof-
  5620   let ?D = "{..<DIM('a)}"
  5621   let ?B = "(basis::nat => 'a) ` d"
  5622   let ?bas = "basis::nat \<Rightarrow> 'a"
  5623   have "?B \<subseteq> ?A" by auto
  5624   moreover
  5625   { fix x::"'a" assume "x\<in>?A"
  5626     hence "finite d" "x\<in>?A" using assms by(auto intro:finite_subset)
  5627     hence "x\<in> span ?B"
  5628     proof(induct d arbitrary: x)
  5629       case empty hence "x=0" apply(subst euclidean_eq) by auto
  5630       thus ?case using subspace_0[OF subspace_span[of "{}"]] by auto
  5631     next
  5632       case (insert k F)
  5633       hence *:"\<forall>i<DIM('a). i \<notin> insert k F \<longrightarrow> x $$ i = 0" by auto
  5634       have **:"F \<subseteq> insert k F" by auto
  5635       def y \<equiv> "x - x$$k *\<^sub>R basis k"
  5636       have y:"x = y + (x$$k) *\<^sub>R basis k" unfolding y_def by auto
  5637       { fix i assume i':"i \<notin> F"
  5638         hence "y $$ i = 0" unfolding y_def 
  5639           using *[THEN spec[where x=i]] by auto }
  5640       hence "y \<in> span (basis ` F)" using insert(3) by auto
  5641       hence "y \<in> span (basis ` (insert k F))"
  5642         using span_mono[of "?bas ` F" "?bas ` (insert k F)"]
  5643         using image_mono[OF **, of basis] using assms by auto
  5644       moreover
  5645       have "basis k \<in> span (?bas ` (insert k F))" by(rule span_superset, auto)
  5646       hence "x$$k *\<^sub>R basis k \<in> span (?bas ` (insert k F))"
  5647         using span_mul by auto
  5648       ultimately
  5649       have "y + x$$k *\<^sub>R basis k \<in> span (?bas ` (insert k F))"
  5650         using span_add by auto
  5651       thus ?case using y by auto
  5652     qed
  5653   }
  5654   hence "?A \<subseteq> span ?B" by auto
  5655   moreover
  5656   { fix x assume "x \<in> ?B"
  5657     hence "x\<in>{(basis i)::'a |i. i \<in> ?D}" using assms by auto  }
  5658   hence "independent ?B" using independent_mono[OF independent_basis, of ?B] and assms by auto
  5659   moreover
  5660   have "d \<subseteq> ?D" unfolding subset_eq using assms by auto
  5661   hence *:"inj_on (basis::nat\<Rightarrow>'a) d" using subset_inj_on[OF basis_inj, of "d"] by auto
  5662   have "card ?B = card d" unfolding card_image[OF *] by auto
  5663   ultimately show ?thesis using dim_unique[of "basis ` d" ?A] by auto
  5664 qed
  5665 
  5666 text{* Hence closure and completeness of all subspaces.                          *}
  5667 
  5668 lemma closed_subspace_lemma: "n \<le> card (UNIV::'n::finite set) \<Longrightarrow> \<exists>A::'n set. card A = n"
  5669 apply (induct n)
  5670 apply (rule_tac x="{}" in exI, simp)
  5671 apply clarsimp
  5672 apply (subgoal_tac "\<exists>x. x \<notin> A")
  5673 apply (erule exE)
  5674 apply (rule_tac x="insert x A" in exI, simp)
  5675 apply (subgoal_tac "A \<noteq> UNIV", auto)
  5676 done
  5677 
  5678 lemma closed_subspace: fixes s::"('a::euclidean_space) set"
  5679   assumes "subspace s" shows "closed s"
  5680 proof-
  5681   have *:"dim s \<le> DIM('a)" using dim_subset_UNIV by auto
  5682   def d \<equiv> "{..<dim s}" have t:"card d = dim s" unfolding d_def by auto
  5683   let ?t = "{x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x$$i = 0}"
  5684   have "\<exists>f. linear f \<and> f ` {x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x $$ i = 0} = s \<and>
  5685       inj_on f {x::'a. \<forall>i<DIM('a). i \<notin> d \<longrightarrow> x $$ i = 0}"
  5686     apply(rule subspace_isomorphism[OF subspace_substandard[of "\<lambda>i. i \<notin> d"]])
  5687     using dim_substandard[of d,where 'a='a] and t unfolding d_def using * assms by auto
  5688   then guess f apply-by(erule exE conjE)+ note f = this
  5689   interpret f: bounded_linear f using f unfolding linear_conv_bounded_linear by auto
  5690   have "\<forall>x\<in>?t. f x = 0 \<longrightarrow> x = 0" using f.zero using f(3)[unfolded inj_on_def]
  5691     by(erule_tac x=0 in ballE) auto
  5692   moreover have "closed ?t" using closed_substandard .
  5693   moreover have "subspace ?t" using subspace_substandard .
  5694   ultimately show ?thesis using closed_injective_image_subspace[of ?t f]
  5695     unfolding f(2) using f(1) unfolding linear_conv_bounded_linear by auto
  5696 qed
  5697 
  5698 lemma complete_subspace:
  5699   fixes s :: "('a::euclidean_space) set" shows "subspace s ==> complete s"
  5700   using complete_eq_closed closed_subspace
  5701   by auto
  5702 
  5703 lemma dim_closure:
  5704   fixes s :: "('a::euclidean_space) set"
  5705   shows "dim(closure s) = dim s" (is "?dc = ?d")
  5706 proof-
  5707   have "?dc \<le> ?d" using closure_minimal[OF span_inc, of s]
  5708     using closed_subspace[OF subspace_span, of s]
  5709     using dim_subset[of "closure s" "span s"] unfolding dim_span by auto
  5710   thus ?thesis using dim_subset[OF closure_subset, of s] by auto
  5711 qed
  5712 
  5713 
  5714 subsection {* Affine transformations of intervals *}
  5715 
  5716 lemma real_affinity_le:
  5717  "0 < (m::'a::linordered_field) ==> (m * x + c \<le> y \<longleftrightarrow> x \<le> inverse(m) * y + -(c / m))"
  5718   by (simp add: field_simps inverse_eq_divide)
  5719 
  5720 lemma real_le_affinity:
  5721  "0 < (m::'a::linordered_field) ==> (y \<le> m * x + c \<longleftrightarrow> inverse(m) * y + -(c / m) \<le> x)"
  5722   by (simp add: field_simps inverse_eq_divide)
  5723 
  5724 lemma real_affinity_lt:
  5725  "0 < (m::'a::linordered_field) ==> (m * x + c < y \<longleftrightarrow> x < inverse(m) * y + -(c / m))"
  5726   by (simp add: field_simps inverse_eq_divide)
  5727 
  5728 lemma real_lt_affinity:
  5729  "0 < (m::'a::linordered_field) ==> (y < m * x + c \<longleftrightarrow> inverse(m) * y + -(c / m) < x)"
  5730   by (simp add: field_simps inverse_eq_divide)
  5731 
  5732 lemma real_affinity_eq:
  5733  "(m::'a::linordered_field) \<noteq> 0 ==> (m * x + c = y \<longleftrightarrow> x = inverse(m) * y + -(c / m))"
  5734   by (simp add: field_simps inverse_eq_divide)
  5735 
  5736 lemma real_eq_affinity:
  5737  "(m::'a::linordered_field) \<noteq> 0 ==> (y = m * x + c  \<longleftrightarrow> inverse(m) * y + -(c / m) = x)"