src/HOL/Map.thy
author paulson
Wed Dec 21 12:02:57 2005 +0100 (2005-12-21)
changeset 18447 da548623916a
parent 17782 b3846df9d643
child 18576 8d98b7711e47
permissions -rw-r--r--
removed or modified some instances of [iff]
     1 (*  Title:      HOL/Map.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     4     Copyright   1997-2003 TU Muenchen
     5 
     6 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     7 *)
     8 
     9 header {* Maps *}
    10 
    11 theory Map
    12 imports List
    13 begin
    14 
    15 types ('a,'b) "~=>" = "'a => 'b option" (infixr 0)
    16 translations (type) "a ~=> b " <= (type) "a => b option"
    17 
    18 consts
    19 chg_map	:: "('b => 'b) => 'a => ('a ~=> 'b) => ('a ~=> 'b)"
    20 map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)" (infixl "++" 100)
    21 restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" (infixl "|`"  110)
    22 dom	:: "('a ~=> 'b) => 'a set"
    23 ran	:: "('a ~=> 'b) => 'b set"
    24 map_of	:: "('a * 'b)list => 'a ~=> 'b"
    25 map_upds:: "('a ~=> 'b) => 'a list => 'b list => 
    26 	    ('a ~=> 'b)"
    27 map_upd_s::"('a ~=> 'b) => 'a set => 'b => 
    28 	    ('a ~=> 'b)"			 ("_/'(_{|->}_/')" [900,0,0]900)
    29 map_subst::"('a ~=> 'b) => 'b => 'b => 
    30 	    ('a ~=> 'b)"			 ("_/'(_~>_/')"    [900,0,0]900)
    31 map_le  :: "('a ~=> 'b) => ('a ~=> 'b) => bool" (infix "\<subseteq>\<^sub>m" 50)
    32 
    33 constdefs
    34   map_comp :: "('b ~=> 'c)  => ('a ~=> 'b) => ('a ~=> 'c)" (infixl "o'_m" 55)
    35   "f o_m g  == (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    36 
    37 nonterminals
    38   maplets maplet
    39 
    40 syntax
    41   empty	    ::  "'a ~=> 'b"
    42   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    43   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    44   ""         :: "maplet => maplets"             ("_")
    45   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    46   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    47   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    48 
    49 syntax (xsymbols)
    50   "~=>"     :: "[type, type] => type"    (infixr "\<rightharpoonup>" 0)
    51 
    52   map_comp :: "('b ~=> 'c)  => ('a ~=> 'b) => ('a ~=> 'c)" (infixl "\<circ>\<^sub>m" 55)
    53 
    54   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    55   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    56 
    57   map_upd_s  :: "('a ~=> 'b) => 'a set => 'b => ('a ~=> 'b)"
    58 				    		 ("_/'(_/{\<mapsto>}/_')" [900,0,0]900)
    59   map_subst :: "('a ~=> 'b) => 'b => 'b => 
    60 	        ('a ~=> 'b)"			 ("_/'(_\<leadsto>_/')"    [900,0,0]900)
    61  "@chg_map" :: "('a ~=> 'b) => 'a => ('b => 'b) => ('a ~=> 'b)"
    62 					  ("_/'(_/\<mapsto>\<lambda>_. _')"  [900,0,0,0] 900)
    63 
    64 syntax (latex output)
    65   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    66   --"requires amssymb!"
    67 
    68 translations
    69   "empty"    => "%_. None"
    70   "empty"    <= "%x. None"
    71 
    72   "m(x\<mapsto>\<lambda>y. f)" == "chg_map (\<lambda>y. f) x m"
    73 
    74   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    75   "_MapUpd m (_maplet  x y)"    == "m(x:=Some y)"
    76   "_MapUpd m (_maplets x y)"    == "map_upds m x y"
    77   "_Map ms"                     == "_MapUpd empty ms"
    78   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    79   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    80 
    81 defs
    82 chg_map_def:  "chg_map f a m == case m a of None => m | Some b => m(a|->f b)"
    83 
    84 map_add_def:   "m1++m2 == %x. case m2 x of None => m1 x | Some y => Some y"
    85 restrict_map_def: "m|`A == %x. if x : A then m x else None"
    86 
    87 map_upds_def: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    88 map_upd_s_def: "m(as{|->}b) == %x. if x : as then Some b else m x"
    89 map_subst_def: "m(a~>b)     == %x. if m x = Some a then Some b else m x"
    90 
    91 dom_def: "dom(m) == {a. m a ~= None}"
    92 ran_def: "ran(m) == {b. EX a. m a = Some b}"
    93 
    94 map_le_def: "m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2  ==  ALL a : dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a"
    95 
    96 primrec
    97   "map_of [] = empty"
    98   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
    99 
   100 
   101 subsection {* @{term [source] empty} *}
   102 
   103 lemma empty_upd_none[simp]: "empty(x := None) = empty"
   104 apply (rule ext)
   105 apply (simp (no_asm))
   106 done
   107 
   108 
   109 (* FIXME: what is this sum_case nonsense?? *)
   110 lemma sum_case_empty_empty[simp]: "sum_case empty empty = empty"
   111 apply (rule ext)
   112 apply (simp (no_asm) split add: sum.split)
   113 done
   114 
   115 subsection {* @{term [source] map_upd} *}
   116 
   117 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   118 apply (rule ext)
   119 apply (simp (no_asm_simp))
   120 done
   121 
   122 lemma map_upd_nonempty[simp]: "t(k|->x) ~= empty"
   123 apply safe
   124 apply (drule_tac x = k in fun_cong)
   125 apply (simp (no_asm_use))
   126 done
   127 
   128 lemma map_upd_eqD1: "m(a\<mapsto>x) = n(a\<mapsto>y) \<Longrightarrow> x = y"
   129 by (drule fun_cong [of _ _ a], auto)
   130 
   131 lemma map_upd_Some_unfold: 
   132   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   133 by auto
   134 
   135 lemma image_map_upd[simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   136 by fastsimp
   137 
   138 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   139 apply (unfold image_def)
   140 apply (simp (no_asm_use) add: full_SetCompr_eq)
   141 apply (rule finite_subset)
   142 prefer 2 apply assumption
   143 apply auto
   144 done
   145 
   146 
   147 (* FIXME: what is this sum_case nonsense?? *)
   148 subsection {* @{term [source] sum_case} and @{term [source] empty}/@{term [source] map_upd} *}
   149 
   150 lemma sum_case_map_upd_empty[simp]:
   151  "sum_case (m(k|->y)) empty =  (sum_case m empty)(Inl k|->y)"
   152 apply (rule ext)
   153 apply (simp (no_asm) split add: sum.split)
   154 done
   155 
   156 lemma sum_case_empty_map_upd[simp]:
   157  "sum_case empty (m(k|->y)) =  (sum_case empty m)(Inr k|->y)"
   158 apply (rule ext)
   159 apply (simp (no_asm) split add: sum.split)
   160 done
   161 
   162 lemma sum_case_map_upd_map_upd[simp]:
   163  "sum_case (m1(k1|->y1)) (m2(k2|->y2)) = (sum_case (m1(k1|->y1)) m2)(Inr k2|->y2)"
   164 apply (rule ext)
   165 apply (simp (no_asm) split add: sum.split)
   166 done
   167 
   168 
   169 subsection {* @{term [source] chg_map} *}
   170 
   171 lemma chg_map_new[simp]: "m a = None   ==> chg_map f a m = m"
   172 by (unfold chg_map_def, auto)
   173 
   174 lemma chg_map_upd[simp]: "m a = Some b ==> chg_map f a m = m(a|->f b)"
   175 by (unfold chg_map_def, auto)
   176 
   177 lemma chg_map_other [simp]: "a \<noteq> b \<Longrightarrow> chg_map f a m b = m b"
   178 by (auto simp: chg_map_def split add: option.split)
   179 
   180 
   181 subsection {* @{term [source] map_of} *}
   182 
   183 lemma map_of_eq_None_iff:
   184  "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   185 by (induct xys) simp_all
   186 
   187 lemma map_of_is_SomeD:
   188  "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   189 apply(induct xys)
   190  apply simp
   191 apply(clarsimp split:if_splits)
   192 done
   193 
   194 lemma map_of_eq_Some_iff[simp]:
   195  "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   196 apply(induct xys)
   197  apply(simp)
   198 apply(auto simp:map_of_eq_None_iff[symmetric])
   199 done
   200 
   201 lemma Some_eq_map_of_iff[simp]:
   202  "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   203 by(auto simp del:map_of_eq_Some_iff simp add:map_of_eq_Some_iff[symmetric])
   204 
   205 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   206   \<Longrightarrow> map_of xys x = Some y"
   207 apply (induct xys)
   208  apply simp
   209 apply force
   210 done
   211 
   212 lemma map_of_zip_is_None[simp]:
   213   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   214 by (induct rule:list_induct2, simp_all)
   215 
   216 lemma finite_range_map_of: "finite (range (map_of xys))"
   217 apply (induct xys)
   218 apply  (simp_all (no_asm) add: image_constant)
   219 apply (rule finite_subset)
   220 prefer 2 apply assumption
   221 apply auto
   222 done
   223 
   224 lemma map_of_SomeD [rule_format]: "map_of xs k = Some y --> (k,y):set xs"
   225 by (induct "xs", auto)
   226 
   227 lemma map_of_mapk_SomeI [rule_format]:
   228      "inj f ==> map_of t k = Some x -->  
   229         map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   230 apply (induct "t")
   231 apply  (auto simp add: inj_eq)
   232 done
   233 
   234 lemma weak_map_of_SomeI [rule_format]:
   235      "(k, x) : set l --> (\<exists>x. map_of l k = Some x)"
   236 by (induct "l", auto)
   237 
   238 lemma map_of_filter_in: 
   239 "[| map_of xs k = Some z; P k z |] ==> map_of (filter (split P) xs) k = Some z"
   240 apply (rule mp)
   241 prefer 2 apply assumption
   242 apply (erule thin_rl)
   243 apply (induct "xs", auto)
   244 done
   245 
   246 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = option_map f (map_of xs x)"
   247 by (induct "xs", auto)
   248 
   249 
   250 subsection {* @{term [source] option_map} related *}
   251 
   252 lemma option_map_o_empty[simp]: "option_map f o empty = empty"
   253 apply (rule ext)
   254 apply (simp (no_asm))
   255 done
   256 
   257 lemma option_map_o_map_upd[simp]:
   258  "option_map f o m(a|->b) = (option_map f o m)(a|->f b)"
   259 apply (rule ext)
   260 apply (simp (no_asm))
   261 done
   262 
   263 subsection {* @{term [source] map_comp} related *}
   264 
   265 lemma map_comp_empty [simp]: 
   266   "m \<circ>\<^sub>m empty = empty"
   267   "empty \<circ>\<^sub>m m = empty"
   268   by (auto simp add: map_comp_def intro: ext split: option.splits)
   269 
   270 lemma map_comp_simps [simp]: 
   271   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   272   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'" 
   273   by (auto simp add: map_comp_def)
   274 
   275 lemma map_comp_Some_iff:
   276   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)" 
   277   by (auto simp add: map_comp_def split: option.splits)
   278 
   279 lemma map_comp_None_iff:
   280   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) " 
   281   by (auto simp add: map_comp_def split: option.splits)
   282 
   283 subsection {* @{text "++"} *}
   284 
   285 lemma map_add_empty[simp]: "m ++ empty = m"
   286 apply (unfold map_add_def)
   287 apply (simp (no_asm))
   288 done
   289 
   290 lemma empty_map_add[simp]: "empty ++ m = m"
   291 apply (unfold map_add_def)
   292 apply (rule ext)
   293 apply (simp split add: option.split)
   294 done
   295 
   296 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   297 apply(rule ext)
   298 apply(simp add: map_add_def split:option.split)
   299 done
   300 
   301 lemma map_add_Some_iff: 
   302  "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   303 apply (unfold map_add_def)
   304 apply (simp (no_asm) split add: option.split)
   305 done
   306 
   307 lemmas map_add_SomeD = map_add_Some_iff [THEN iffD1, standard]
   308 declare map_add_SomeD [dest!]
   309 
   310 lemma map_add_find_right[simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   311 by (subst map_add_Some_iff, fast)
   312 
   313 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   314 apply (unfold map_add_def)
   315 apply (simp (no_asm) split add: option.split)
   316 done
   317 
   318 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   319 apply (unfold map_add_def)
   320 apply (rule ext, auto)
   321 done
   322 
   323 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   324 by(simp add:map_upds_def)
   325 
   326 lemma map_of_append[simp]: "map_of (xs@ys) = map_of ys ++ map_of xs"
   327 apply (unfold map_add_def)
   328 apply (induct "xs")
   329 apply (simp (no_asm))
   330 apply (rule ext)
   331 apply (simp (no_asm_simp) split add: option.split)
   332 done
   333 
   334 declare fun_upd_apply [simp del]
   335 lemma finite_range_map_of_map_add:
   336  "finite (range f) ==> finite (range (f ++ map_of l))"
   337 apply (induct "l", auto)
   338 apply (erule finite_range_updI)
   339 done
   340 declare fun_upd_apply [simp]
   341 
   342 lemma inj_on_map_add_dom[iff]:
   343  "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   344 by(fastsimp simp add:map_add_def dom_def inj_on_def split:option.splits)
   345 
   346 subsection {* @{term [source] restrict_map} *}
   347 
   348 lemma restrict_map_to_empty[simp]: "m|`{} = empty"
   349 by(simp add: restrict_map_def)
   350 
   351 lemma restrict_map_empty[simp]: "empty|`D = empty"
   352 by(simp add: restrict_map_def)
   353 
   354 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   355 by (auto simp: restrict_map_def)
   356 
   357 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   358 by (auto simp: restrict_map_def)
   359 
   360 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   361 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   362 
   363 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   364 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   365 
   366 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   367 by (rule ext, auto simp: restrict_map_def)
   368 
   369 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   370 by (rule ext, auto simp: restrict_map_def)
   371 
   372 lemma restrict_fun_upd[simp]:
   373  "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   374 by(simp add: restrict_map_def expand_fun_eq)
   375 
   376 lemma fun_upd_None_restrict[simp]:
   377   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   378 by(simp add: restrict_map_def expand_fun_eq)
   379 
   380 lemma fun_upd_restrict:
   381  "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   382 by(simp add: restrict_map_def expand_fun_eq)
   383 
   384 lemma fun_upd_restrict_conv[simp]:
   385  "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   386 by(simp add: restrict_map_def expand_fun_eq)
   387 
   388 
   389 subsection {* @{term [source] map_upds} *}
   390 
   391 lemma map_upds_Nil1[simp]: "m([] [|->] bs) = m"
   392 by(simp add:map_upds_def)
   393 
   394 lemma map_upds_Nil2[simp]: "m(as [|->] []) = m"
   395 by(simp add:map_upds_def)
   396 
   397 lemma map_upds_Cons[simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   398 by(simp add:map_upds_def)
   399 
   400 lemma map_upds_append1[simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   401   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   402 apply(induct xs)
   403  apply(clarsimp simp add:neq_Nil_conv)
   404 apply (case_tac ys, simp, simp)
   405 done
   406 
   407 lemma map_upds_list_update2_drop[simp]:
   408  "\<And>m ys i. \<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   409      \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   410 apply (induct xs, simp)
   411 apply (case_tac ys, simp)
   412 apply(simp split:nat.split)
   413 done
   414 
   415 lemma map_upd_upds_conv_if: "!!x y ys f.
   416  (f(x|->y))(xs [|->] ys) =
   417  (if x : set(take (length ys) xs) then f(xs [|->] ys)
   418                                   else (f(xs [|->] ys))(x|->y))"
   419 apply (induct xs, simp)
   420 apply(case_tac ys)
   421  apply(auto split:split_if simp:fun_upd_twist)
   422 done
   423 
   424 lemma map_upds_twist [simp]:
   425  "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   426 apply(insert set_take_subset)
   427 apply (fastsimp simp add: map_upd_upds_conv_if)
   428 done
   429 
   430 lemma map_upds_apply_nontin[simp]:
   431  "!!ys. x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   432 apply (induct xs, simp)
   433 apply(case_tac ys)
   434  apply(auto simp: map_upd_upds_conv_if)
   435 done
   436 
   437 lemma fun_upds_append_drop[simp]:
   438   "!!m ys. size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   439 apply(induct xs)
   440  apply (simp)
   441 apply(case_tac ys)
   442 apply simp_all
   443 done
   444 
   445 lemma fun_upds_append2_drop[simp]:
   446   "!!m ys. size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   447 apply(induct xs)
   448  apply (simp)
   449 apply(case_tac ys)
   450 apply simp_all
   451 done
   452 
   453 
   454 lemma restrict_map_upds[simp]: "!!m ys.
   455  \<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   456  \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   457 apply (induct xs, simp)
   458 apply (case_tac ys, simp)
   459 apply(simp add:Diff_insert[symmetric] insert_absorb)
   460 apply(simp add: map_upd_upds_conv_if)
   461 done
   462 
   463 
   464 subsection {* @{term [source] map_upd_s} *}
   465 
   466 lemma map_upd_s_apply [simp]: 
   467   "(m(as{|->}b)) x = (if x : as then Some b else m x)"
   468 by (simp add: map_upd_s_def)
   469 
   470 lemma map_subst_apply [simp]: 
   471   "(m(a~>b)) x = (if m x = Some a then Some b else m x)" 
   472 by (simp add: map_subst_def)
   473 
   474 subsection {* @{term [source] dom} *}
   475 
   476 lemma domI: "m a = Some b ==> a : dom m"
   477 by (unfold dom_def, auto)
   478 (* declare domI [intro]? *)
   479 
   480 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   481 apply (case_tac "m a") 
   482 apply (auto simp add: dom_def) 
   483 done
   484 
   485 lemma domIff[iff]: "(a : dom m) = (m a ~= None)"
   486 by (unfold dom_def, auto)
   487 declare domIff [simp del]
   488 
   489 lemma dom_empty[simp]: "dom empty = {}"
   490 apply (unfold dom_def)
   491 apply (simp (no_asm))
   492 done
   493 
   494 lemma dom_fun_upd[simp]:
   495  "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   496 by (simp add:dom_def) blast
   497 
   498 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   499 apply(induct xys)
   500 apply(auto simp del:fun_upd_apply)
   501 done
   502 
   503 lemma dom_map_of_conv_image_fst:
   504   "dom(map_of xys) = fst ` (set xys)"
   505 by(force simp: dom_map_of)
   506 
   507 lemma dom_map_of_zip[simp]: "[| length xs = length ys; distinct xs |] ==>
   508   dom(map_of(zip xs ys)) = set xs"
   509 by(induct rule: list_induct2, simp_all)
   510 
   511 lemma finite_dom_map_of: "finite (dom (map_of l))"
   512 apply (unfold dom_def)
   513 apply (induct "l")
   514 apply (auto simp add: insert_Collect [symmetric])
   515 done
   516 
   517 lemma dom_map_upds[simp]:
   518  "!!m ys. dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   519 apply (induct xs, simp)
   520 apply (case_tac ys, auto)
   521 done
   522 
   523 lemma dom_map_add[simp]: "dom(m++n) = dom n Un dom m"
   524 by (unfold dom_def, auto)
   525 
   526 lemma dom_override_on[simp]:
   527  "dom(override_on f g A) =
   528  (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   529 by(auto simp add: dom_def override_on_def)
   530 
   531 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   532 apply(rule ext)
   533 apply(force simp: map_add_def dom_def not_None_eq  split:option.split) 
   534 done
   535 
   536 subsection {* @{term [source] ran} *}
   537 
   538 lemma ranI: "m a = Some b ==> b : ran m" 
   539 by (auto simp add: ran_def)
   540 (* declare ranI [intro]? *)
   541 
   542 lemma ran_empty[simp]: "ran empty = {}"
   543 apply (unfold ran_def)
   544 apply (simp (no_asm))
   545 done
   546 
   547 lemma ran_map_upd[simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   548 apply (unfold ran_def, auto)
   549 apply (subgoal_tac "~ (aa = a) ")
   550 apply auto
   551 done
   552 
   553 subsection {* @{text "map_le"} *}
   554 
   555 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   556 by(simp add:map_le_def)
   557 
   558 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   559 by(force simp add:map_le_def)
   560 
   561 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   562 by(fastsimp simp add:map_le_def)
   563 
   564 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   565 by(force simp add:map_le_def)
   566 
   567 lemma map_le_upds[simp]:
   568  "!!f g bs. f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   569 apply (induct as, simp)
   570 apply (case_tac bs, auto)
   571 done
   572 
   573 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   574   by (fastsimp simp add: map_le_def dom_def)
   575 
   576 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   577   by (simp add: map_le_def)
   578 
   579 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   580   by (auto simp add: map_le_def dom_def)
   581 
   582 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   583   apply (unfold map_le_def)
   584   apply (rule ext)
   585   apply (case_tac "x \<in> dom f", simp)
   586   apply (case_tac "x \<in> dom g", simp, fastsimp)
   587 done
   588 
   589 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   590   by (fastsimp simp add: map_le_def not_None_eq)
   591 
   592 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   593 by(fastsimp simp add:map_add_def map_le_def expand_fun_eq split:option.splits)
   594 
   595 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   596 by (fastsimp simp add: map_le_def map_add_def dom_def not_None_eq)
   597 
   598 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   599 by (clarsimp simp add: map_le_def map_add_def dom_def split:option.splits)
   600 
   601 end