src/Pure/Tools/find_consts.ML
author wenzelm
Sat Apr 16 15:47:52 2011 +0200 (2011-04-16)
changeset 42360 da8817d01e7c
parent 42012 2c3fe3cbebae
child 46713 e6e1ec6d5c1c
permissions -rw-r--r--
modernized structure Proof_Context;
     1 (*  Title:      Pure/Tools/find_consts.ML
     2     Author:     Timothy Bourke and Gerwin Klein, NICTA
     3 
     4 Hoogle-like (http://www-users.cs.york.ac.uk/~ndm/hoogle) searching by
     5 type over constants, but matching is not fuzzy.
     6 *)
     7 
     8 signature FIND_CONSTS =
     9 sig
    10   datatype criterion =
    11       Strict of string
    12     | Loose of string
    13     | Name of string
    14   val find_consts : Proof.context -> (bool * criterion) list -> unit
    15 end;
    16 
    17 structure Find_Consts : FIND_CONSTS =
    18 struct
    19 
    20 (* search criteria *)
    21 
    22 datatype criterion =
    23     Strict of string
    24   | Loose of string
    25   | Name of string;
    26 
    27 
    28 (* matching types/consts *)
    29 
    30 fun matches_subtype thy typat =
    31   Term.exists_subtype (fn ty => Sign.typ_instance thy (ty, typat));
    32 
    33 fun check_const pred (nm, (ty, _)) =
    34   if pred (nm, ty) then SOME (Term.size_of_typ ty) else NONE;
    35 
    36 fun opt_not f (c as (_, (ty, _))) =
    37   if is_some (f c) then NONE else SOME (Term.size_of_typ ty);
    38 
    39 fun filter_const _ NONE = NONE
    40   | filter_const f (SOME (c, r)) =
    41       (case f c of
    42         NONE => NONE
    43       | SOME i => SOME (c, Int.min (r, i)));
    44 
    45 
    46 (* pretty results *)
    47 
    48 fun pretty_criterion (b, c) =
    49   let
    50     fun prfx s = if b then s else "-" ^ s;
    51   in
    52     (case c of
    53       Strict pat => Pretty.str (prfx "strict: " ^ quote pat)
    54     | Loose pat => Pretty.str (prfx (quote pat))
    55     | Name name => Pretty.str (prfx "name: " ^ quote name))
    56   end;
    57 
    58 fun pretty_const ctxt (nm, ty) =
    59   let
    60     val ty' = Logic.unvarifyT_global ty;
    61   in
    62     Pretty.block
    63      [Pretty.str nm, Pretty.str " ::", Pretty.brk 1,
    64       Pretty.quote (Syntax.pretty_typ ctxt ty')]
    65   end;
    66 
    67 
    68 (* find_consts *)
    69 
    70 fun find_consts ctxt raw_criteria =
    71   let
    72     val start = Timing.start ();
    73 
    74     val thy = Proof_Context.theory_of ctxt;
    75     val low_ranking = 10000;
    76 
    77     fun user_visible consts (nm, _) =
    78       if Consts.is_concealed consts nm then NONE else SOME low_ranking;
    79 
    80     fun make_pattern crit =
    81       let
    82         val raw_T = Syntax.parse_typ ctxt crit;
    83         val t =
    84           Syntax.check_term
    85             (Proof_Context.set_mode Proof_Context.mode_pattern ctxt)
    86             (Term.dummy_pattern raw_T);
    87       in Term.type_of t end;
    88 
    89     fun make_match (Strict arg) =
    90           let val qty = make_pattern arg; in
    91             fn (_, (ty, _)) =>
    92               let
    93                 val tye = Sign.typ_match thy (qty, ty) Vartab.empty;
    94                 val sub_size =
    95                   Vartab.fold (fn (_, (_, t)) => fn n => Term.size_of_typ t + n) tye 0;
    96               in SOME sub_size end handle Type.TYPE_MATCH => NONE
    97           end
    98       | make_match (Loose arg) =
    99           check_const (matches_subtype thy (make_pattern arg) o snd)
   100       | make_match (Name arg) = check_const (match_string arg o fst);
   101 
   102     fun make_criterion (b, crit) = (if b then I else opt_not) (make_match crit);
   103     val criteria = map make_criterion raw_criteria;
   104 
   105     val consts = Sign.consts_of thy;
   106     val (_, consts_tab) = #constants (Consts.dest consts);
   107     fun eval_entry c =
   108       fold filter_const (user_visible consts :: criteria)
   109         (SOME (c, low_ranking));
   110 
   111     val matches =
   112       Symtab.fold (cons o eval_entry) consts_tab []
   113       |> map_filter I
   114       |> sort (rev_order o int_ord o pairself snd)
   115       |> map (apsnd fst o fst);
   116 
   117     val end_msg = " in " ^ Time.toString (#cpu (Timing.result start)) ^ " secs";
   118   in
   119     Pretty.big_list "searched for:" (map pretty_criterion raw_criteria) ::
   120     Pretty.str "" ::
   121     Pretty.str
   122      (if null matches
   123       then "nothing found" ^ end_msg
   124       else "found " ^ string_of_int (length matches) ^ " constant(s)" ^ end_msg ^ ":") ::
   125     Pretty.str "" ::
   126     map (pretty_const ctxt) matches
   127   end |> Pretty.chunks |> Pretty.writeln;
   128 
   129 
   130 (* command syntax *)
   131 
   132 local
   133 
   134 val criterion =
   135   Parse.reserved "strict" |-- Parse.!!! (Parse.$$$ ":" |-- Parse.xname) >> Strict ||
   136   Parse.reserved "name" |-- Parse.!!! (Parse.$$$ ":" |-- Parse.xname) >> Name ||
   137   Parse.xname >> Loose;
   138 
   139 in
   140 
   141 val _ =
   142   Outer_Syntax.improper_command "find_consts" "search constants by type pattern" Keyword.diag
   143     (Scan.repeat ((Scan.option Parse.minus >> is_none) -- criterion)
   144       >> (fn spec => Toplevel.no_timing o
   145         Toplevel.keep (fn state => find_consts (Toplevel.context_of state) spec)));
   146 
   147 end;
   148 
   149 end;
   150