src/Pure/sign.ML
author wenzelm
Sat Apr 16 15:47:52 2011 +0200 (2011-04-16)
changeset 42360 da8817d01e7c
parent 42359 6ca5407863ed
child 42375 774df7c59508
permissions -rw-r--r--
modernized structure Proof_Context;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: Name_Space.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    16   val naming_of: theory -> Name_Space.naming
    17   val full_name: theory -> binding -> string
    18   val full_name_path: theory -> string -> binding -> string
    19   val full_bname: theory -> bstring -> string
    20   val full_bname_path: theory -> string -> bstring -> string
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val set_defsort: sort -> theory -> theory
    29   val defaultS: theory -> sort
    30   val subsort: theory -> sort * sort -> bool
    31   val of_sort: theory -> typ * sort -> bool
    32   val inter_sort: theory -> sort * sort -> sort
    33   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    34   val is_logtype: theory -> string -> bool
    35   val typ_instance: theory -> typ * typ -> bool
    36   val typ_equiv: theory -> typ * typ -> bool
    37   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    38   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    39   val consts_of: theory -> Consts.T
    40   val the_const_constraint: theory -> string -> typ
    41   val const_type: theory -> string -> typ option
    42   val the_const_type: theory -> string -> typ
    43   val declared_tyname: theory -> string -> bool
    44   val declared_const: theory -> string -> bool
    45   val const_monomorphic: theory -> string -> bool
    46   val const_typargs: theory -> string * typ -> typ list
    47   val const_instance: theory -> string * typ list -> typ
    48   val mk_const: theory -> string * typ list -> term
    49   val class_space: theory -> Name_Space.T
    50   val type_space: theory -> Name_Space.T
    51   val const_space: theory -> Name_Space.T
    52   val intern_class: theory -> xstring -> string
    53   val intern_type: theory -> xstring -> string
    54   val intern_const: theory -> xstring -> string
    55   val class_alias: binding -> class -> theory -> theory
    56   val type_alias: binding -> string -> theory -> theory
    57   val const_alias: binding -> string -> theory -> theory
    58   val arity_number: theory -> string -> int
    59   val arity_sorts: theory -> string -> sort -> sort list
    60   val certify_class: theory -> class -> class
    61   val certify_sort: theory -> sort -> sort
    62   val certify_typ: theory -> typ -> typ
    63   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    64   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    65   val certify_term: theory -> term -> term * typ * int
    66   val cert_term: theory -> term -> term
    67   val cert_prop: theory -> term -> term
    68   val no_frees: Proof.context -> term -> term
    69   val no_vars: Proof.context -> term -> term
    70   val add_types: (binding * int * mixfix) list -> theory -> theory
    71   val add_nonterminals: binding list -> theory -> theory
    72   val add_type_abbrev: binding * string list * typ -> theory -> theory
    73   val add_syntax: (string * string * mixfix) list -> theory -> theory
    74   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    75   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    76   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    77   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    78   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    79   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    80   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    81   val declare_const: (binding * typ) * mixfix -> theory -> term * theory
    82   val add_consts: (binding * string * mixfix) list -> theory -> theory
    83   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    84   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    85   val revert_abbrev: string -> string -> theory -> theory
    86   val add_const_constraint: string * typ option -> theory -> theory
    87   val primitive_class: binding * class list -> theory -> theory
    88   val primitive_classrel: class * class -> theory -> theory
    89   val primitive_arity: arity -> theory -> theory
    90   val add_trfuns:
    91     (string * (Ast.ast list -> Ast.ast)) list *
    92     (string * (term list -> term)) list *
    93     (string * (term list -> term)) list *
    94     (string * (Ast.ast list -> Ast.ast)) list -> theory -> theory
    95   val add_trfunsT: (string * (typ -> term list -> term)) list -> theory -> theory
    96   val add_advanced_trfuns:
    97     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list *
    98     (string * (Proof.context -> term list -> term)) list *
    99     (string * (Proof.context -> term list -> term)) list *
   100     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   101   val add_advanced_trfunsT:
   102     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
   103   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   104   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   105   val new_group: theory -> theory
   106   val reset_group: theory -> theory
   107   val add_path: string -> theory -> theory
   108   val root_path: theory -> theory
   109   val parent_path: theory -> theory
   110   val mandatory_path: string -> theory -> theory
   111   val qualified_path: bool -> binding -> theory -> theory
   112   val local_path: theory -> theory
   113   val restore_naming: theory -> theory -> theory
   114   val hide_class: bool -> string -> theory -> theory
   115   val hide_type: bool -> string -> theory -> theory
   116   val hide_const: bool -> string -> theory -> theory
   117 end
   118 
   119 structure Sign: SIGN =
   120 struct
   121 
   122 (** datatype sign **)
   123 
   124 datatype sign = Sign of
   125  {naming: Name_Space.naming,    (*common naming conventions*)
   126   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   127   tsig: Type.tsig,              (*order-sorted signature of types*)
   128   consts: Consts.T};            (*polymorphic constants*)
   129 
   130 fun make_sign (naming, syn, tsig, consts) =
   131   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   132 
   133 structure Data = Theory_Data_PP
   134 (
   135   type T = sign;
   136   fun extend (Sign {syn, tsig, consts, ...}) =
   137     make_sign (Name_Space.default_naming, syn, tsig, consts);
   138 
   139   val empty =
   140     make_sign (Name_Space.default_naming, Syntax.empty_syntax, Type.empty_tsig, Consts.empty);
   141 
   142   fun merge pp (sign1, sign2) =
   143     let
   144       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   145       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   146 
   147       val naming = Name_Space.default_naming;
   148       val syn = Syntax.merge_syntaxes syn1 syn2;
   149       val tsig = Type.merge_tsig pp (tsig1, tsig2);
   150       val consts = Consts.merge (consts1, consts2);
   151     in make_sign (naming, syn, tsig, consts) end;
   152 );
   153 
   154 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   155 
   156 fun map_sign f = Data.map (fn Sign {naming, syn, tsig, consts} =>
   157   make_sign (f (naming, syn, tsig, consts)));
   158 
   159 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   160 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   161 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   162 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   163 
   164 
   165 (* naming *)
   166 
   167 val naming_of = #naming o rep_sg;
   168 
   169 val full_name = Name_Space.full_name o naming_of;
   170 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   171 
   172 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   173 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   174 
   175 
   176 (* syntax *)
   177 
   178 val syn_of = #syn o rep_sg;
   179 
   180 
   181 (* type signature *)
   182 
   183 val tsig_of = #tsig o rep_sg;
   184 
   185 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   186 val all_classes = Sorts.all_classes o classes_of;
   187 val super_classes = Sorts.super_classes o classes_of;
   188 val minimize_sort = Sorts.minimize_sort o classes_of;
   189 val complete_sort = Sorts.complete_sort o classes_of;
   190 
   191 val set_defsort = map_tsig o Type.set_defsort;
   192 val defaultS = Type.defaultS o tsig_of;
   193 val subsort = Type.subsort o tsig_of;
   194 val of_sort = Type.of_sort o tsig_of;
   195 val inter_sort = Type.inter_sort o tsig_of;
   196 val witness_sorts = Type.witness_sorts o tsig_of;
   197 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   198 
   199 val typ_instance = Type.typ_instance o tsig_of;
   200 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   201 val typ_match = Type.typ_match o tsig_of;
   202 val typ_unify = Type.unify o tsig_of;
   203 
   204 
   205 (* polymorphic constants *)
   206 
   207 val consts_of = #consts o rep_sg;
   208 val the_const_constraint = Consts.the_constraint o consts_of;
   209 val the_const_type = Consts.the_type o consts_of;
   210 val const_type = try o the_const_type;
   211 val const_monomorphic = Consts.is_monomorphic o consts_of;
   212 val const_typargs = Consts.typargs o consts_of;
   213 val const_instance = Consts.instance o consts_of;
   214 
   215 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   216 
   217 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   218 val declared_const = can o the_const_constraint;
   219 
   220 
   221 
   222 (** name spaces **)
   223 
   224 val class_space = Type.class_space o tsig_of;
   225 val type_space = Type.type_space o tsig_of;
   226 val const_space = Consts.space_of o consts_of;
   227 
   228 val intern_class = Name_Space.intern o class_space;
   229 val intern_type = Name_Space.intern o type_space;
   230 val intern_const = Name_Space.intern o const_space;
   231 
   232 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   233 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   234 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   235 
   236 
   237 
   238 (** certify entities **)    (*exception TYPE*)
   239 
   240 (* certify wrt. type signature *)
   241 
   242 val arity_number = Type.arity_number o tsig_of;
   243 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   244 
   245 val certify_class         = Type.cert_class o tsig_of;
   246 val certify_sort          = Type.cert_sort o tsig_of;
   247 val certify_typ           = Type.cert_typ o tsig_of;
   248 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   249 
   250 
   251 (* certify term/prop *)
   252 
   253 local
   254 
   255 fun type_check pp tm =
   256   let
   257     fun err_appl bs t T u U =
   258       let
   259         val xs = map Free bs;           (*we do not rename here*)
   260         val t' = subst_bounds (xs, t);
   261         val u' = subst_bounds (xs, u);
   262         val msg = Type.appl_error pp t' T u' U;
   263       in raise TYPE (msg, [T, U], [t', u']) end;
   264 
   265     fun typ_of (_, Const (_, T)) = T
   266       | typ_of (_, Free  (_, T)) = T
   267       | typ_of (_, Var (_, T)) = T
   268       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   269           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   270       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   271       | typ_of (bs, t $ u) =
   272           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   273             (case T of
   274               Type ("fun", [T1, T2]) =>
   275                 if T1 = U then T2 else err_appl bs t T u U
   276             | _ => err_appl bs t T u U)
   277           end;
   278   in typ_of ([], tm) end;
   279 
   280 fun err msg = raise TYPE (msg, [], []);
   281 
   282 fun check_vars (t $ u) = (check_vars t; check_vars u)
   283   | check_vars (Abs (_, _, t)) = check_vars t
   284   | check_vars (Free (x, _)) =
   285       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   286   | check_vars (Var (xi as (_, i), _)) =
   287       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   288   | check_vars _ = ();
   289 
   290 in
   291 
   292 fun certify' prop pp do_expand consts thy tm =
   293   let
   294     val _ = check_vars tm;
   295     val tm' = Term.map_types (certify_typ thy) tm;
   296     val T = type_check pp tm';
   297     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   298     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   299   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   300 
   301 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   302 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   303 val cert_term = #1 oo certify_term;
   304 fun cert_prop thy = #1 o certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   305 
   306 end;
   307 
   308 
   309 (* specifications *)
   310 
   311 fun no_variables kind add addT mk mkT ctxt tm =
   312   (case (add tm [], addT tm []) of
   313     ([], []) => tm
   314   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   315       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   316        Pretty.commas
   317         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   318 
   319 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   320 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   321 
   322 
   323 
   324 (** signature extension functions **)  (*exception ERROR/TYPE*)
   325 
   326 (* add type constructors *)
   327 
   328 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   329   let
   330     fun type_syntax (b, n, mx) =
   331       (Lexicon.mark_type (Name_Space.full_name naming b), Mixfix.make_type n, mx);
   332     val syn' = Syntax.update_type_gram true Syntax.mode_default (map type_syntax types) syn;
   333     val tsig' = fold (fn (a, n, _) => Type.add_type naming (a, n)) types tsig;
   334   in (naming, syn', tsig', consts) end);
   335 
   336 
   337 (* add nonterminals *)
   338 
   339 fun add_nonterminals ns = map_sign (fn (naming, syn, tsig, consts) =>
   340   (naming, syn, fold (Type.add_nonterminal naming) ns tsig, consts));
   341 
   342 
   343 (* add type abbreviations *)
   344 
   345 fun add_type_abbrev abbr = map_sign (fn (naming, syn, tsig, consts) =>
   346   (naming, syn, Type.add_abbrev naming abbr tsig, consts));
   347 
   348 
   349 (* modify syntax *)
   350 
   351 fun gen_syntax change_gram parse_typ mode args thy =
   352   let
   353     val ctxt = Proof_Context.init_global thy;
   354     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   355       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   356   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   357 
   358 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   359 
   360 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   361 val add_modesyntax_i = gen_add_syntax (K I);
   362 val add_syntax = add_modesyntax Syntax.mode_default;
   363 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   364 val del_modesyntax = gen_syntax (Syntax.update_const_gram false) Syntax.parse_typ;
   365 val del_modesyntax_i = gen_syntax (Syntax.update_const_gram false) (K I);
   366 
   367 fun type_notation add mode args =
   368   let
   369     fun type_syntax (Type (c, args), mx) =
   370           SOME (Lexicon.mark_type c, Mixfix.make_type (length args), mx)
   371       | type_syntax _ = NONE;
   372   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   373 
   374 fun notation add mode args thy =
   375   let
   376     fun const_syntax (Const (c, _), mx) =
   377           (case try (Consts.type_scheme (consts_of thy)) c of
   378             SOME T => SOME (Lexicon.mark_const c, T, mx)
   379           | NONE => NONE)
   380       | const_syntax _ = NONE;
   381   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   382 
   383 
   384 (* add constants *)
   385 
   386 local
   387 
   388 fun gen_add_consts parse_typ raw_args thy =
   389   let
   390     val ctxt = Proof_Context.init_global thy;
   391     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   392     fun prep (b, raw_T, mx) =
   393       let
   394         val c = full_name thy b;
   395         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   396           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   397         val T' = Logic.varifyT_global T;
   398       in ((b, T'), (Lexicon.mark_const c, T', mx), Const (c, T)) end;
   399     val args = map prep raw_args;
   400   in
   401     thy
   402     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   403     |> add_syntax_i (map #2 args)
   404     |> pair (map #3 args)
   405   end;
   406 
   407 in
   408 
   409 fun add_consts args = snd o gen_add_consts Syntax.parse_typ args;
   410 fun add_consts_i args = snd o gen_add_consts (K I) args;
   411 
   412 fun declare_const ((b, T), mx) thy =
   413   let
   414     val pos = Binding.pos_of b;
   415     val ([const as Const (c, _)], thy') = gen_add_consts (K I) [(b, T, mx)] thy;
   416     val _ = Position.report pos (Markup.const_decl c);
   417   in (const, thy') end;
   418 
   419 end;
   420 
   421 
   422 (* abbreviations *)
   423 
   424 fun add_abbrev mode (b, raw_t) thy =
   425   let
   426     val ctxt = Syntax.init_pretty_global thy;
   427     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   428     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   429       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   430     val (res, consts') = consts_of thy
   431       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of thy) (naming_of thy) mode (b, t);
   432   in (res, thy |> map_consts (K consts')) end;
   433 
   434 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   435 
   436 
   437 (* add constraints *)
   438 
   439 fun add_const_constraint (c, opt_T) thy =
   440   let
   441     fun prepT raw_T =
   442       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   443       in cert_term thy (Const (c, T)); T end
   444       handle TYPE (msg, _, _) => error msg;
   445   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   446 
   447 
   448 (* primitive classes and arities *)
   449 
   450 fun primitive_class (bclass, classes) thy =
   451   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   452     let
   453       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   454     in (naming, syn, tsig', consts) end)
   455   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   456 
   457 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   458 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   459 
   460 
   461 (* add translation functions *)
   462 
   463 local
   464 
   465 fun mk trs = map Syntax_Ext.mk_trfun trs;
   466 
   467 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   468   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   469 
   470 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   471 
   472 in
   473 
   474 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax_Trans.non_typed_tr';
   475 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   476 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax_Trans.non_typed_tr'';
   477 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   478 
   479 end;
   480 
   481 
   482 (* translation rules *)
   483 
   484 val add_trrules = map_syn o Syntax.update_trrules;
   485 val del_trrules = map_syn o Syntax.remove_trrules;
   486 
   487 
   488 (* naming *)
   489 
   490 val new_group = map_naming Name_Space.new_group;
   491 val reset_group = map_naming Name_Space.reset_group;
   492 
   493 val add_path = map_naming o Name_Space.add_path;
   494 val root_path = map_naming Name_Space.root_path;
   495 val parent_path = map_naming Name_Space.parent_path;
   496 val mandatory_path = map_naming o Name_Space.mandatory_path;
   497 val qualified_path = map_naming oo Name_Space.qualified_path;
   498 
   499 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   500 
   501 val restore_naming = map_naming o K o naming_of;
   502 
   503 
   504 (* hide names *)
   505 
   506 val hide_class = map_tsig oo Type.hide_class;
   507 val hide_type = map_tsig oo Type.hide_type;
   508 val hide_const = map_consts oo Consts.hide;
   509 
   510 end;