src/HOL/Analysis/Product_Vector.thy
 author hoelzl Fri Sep 30 15:35:37 2016 +0200 (2016-09-30) changeset 63971 da89140186e2 parent 63040 src/HOL/Library/Product_Vector.thy@eb4ddd18d635 child 63972 c98d1dd7eba1 permissions -rw-r--r--
HOL-Analysis: move Product_Vector and Inner_Product from Library
```     1 (*  Title:      HOL/Analysis/Product_Vector.thy
```
```     2     Author:     Brian Huffman
```
```     3 *)
```
```     4
```
```     5 section \<open>Cartesian Products as Vector Spaces\<close>
```
```     6
```
```     7 theory Product_Vector
```
```     8 imports
```
```     9   Inner_Product
```
```    10   "~~/src/HOL/Library/Product_plus"
```
```    11 begin
```
```    12
```
```    13 subsection \<open>Product is a real vector space\<close>
```
```    14
```
```    15 instantiation prod :: (real_vector, real_vector) real_vector
```
```    16 begin
```
```    17
```
```    18 definition scaleR_prod_def:
```
```    19   "scaleR r A = (scaleR r (fst A), scaleR r (snd A))"
```
```    20
```
```    21 lemma fst_scaleR [simp]: "fst (scaleR r A) = scaleR r (fst A)"
```
```    22   unfolding scaleR_prod_def by simp
```
```    23
```
```    24 lemma snd_scaleR [simp]: "snd (scaleR r A) = scaleR r (snd A)"
```
```    25   unfolding scaleR_prod_def by simp
```
```    26
```
```    27 lemma scaleR_Pair [simp]: "scaleR r (a, b) = (scaleR r a, scaleR r b)"
```
```    28   unfolding scaleR_prod_def by simp
```
```    29
```
```    30 instance
```
```    31 proof
```
```    32   fix a b :: real and x y :: "'a \<times> 'b"
```
```    33   show "scaleR a (x + y) = scaleR a x + scaleR a y"
```
```    34     by (simp add: prod_eq_iff scaleR_right_distrib)
```
```    35   show "scaleR (a + b) x = scaleR a x + scaleR b x"
```
```    36     by (simp add: prod_eq_iff scaleR_left_distrib)
```
```    37   show "scaleR a (scaleR b x) = scaleR (a * b) x"
```
```    38     by (simp add: prod_eq_iff)
```
```    39   show "scaleR 1 x = x"
```
```    40     by (simp add: prod_eq_iff)
```
```    41 qed
```
```    42
```
```    43 end
```
```    44
```
```    45 subsection \<open>Product is a metric space\<close>
```
```    46
```
```    47 (* TODO: Product of uniform spaces and compatibility with metric_spaces! *)
```
```    48
```
```    49 instantiation prod :: (metric_space, metric_space) dist
```
```    50 begin
```
```    51
```
```    52 definition dist_prod_def[code del]:
```
```    53   "dist x y = sqrt ((dist (fst x) (fst y))\<^sup>2 + (dist (snd x) (snd y))\<^sup>2)"
```
```    54
```
```    55 instance ..
```
```    56 end
```
```    57
```
```    58 instantiation prod :: (metric_space, metric_space) uniformity_dist
```
```    59 begin
```
```    60
```
```    61 definition [code del]:
```
```    62   "(uniformity :: (('a \<times> 'b) \<times> ('a \<times> 'b)) filter) =
```
```    63     (INF e:{0 <..}. principal {(x, y). dist x y < e})"
```
```    64
```
```    65 instance
```
```    66   by standard (rule uniformity_prod_def)
```
```    67 end
```
```    68
```
```    69 declare uniformity_Abort[where 'a="'a :: metric_space \<times> 'b :: metric_space", code]
```
```    70
```
```    71 instantiation prod :: (metric_space, metric_space) metric_space
```
```    72 begin
```
```    73
```
```    74 lemma dist_Pair_Pair: "dist (a, b) (c, d) = sqrt ((dist a c)\<^sup>2 + (dist b d)\<^sup>2)"
```
```    75   unfolding dist_prod_def by simp
```
```    76
```
```    77 lemma dist_fst_le: "dist (fst x) (fst y) \<le> dist x y"
```
```    78   unfolding dist_prod_def by (rule real_sqrt_sum_squares_ge1)
```
```    79
```
```    80 lemma dist_snd_le: "dist (snd x) (snd y) \<le> dist x y"
```
```    81   unfolding dist_prod_def by (rule real_sqrt_sum_squares_ge2)
```
```    82
```
```    83 instance
```
```    84 proof
```
```    85   fix x y :: "'a \<times> 'b"
```
```    86   show "dist x y = 0 \<longleftrightarrow> x = y"
```
```    87     unfolding dist_prod_def prod_eq_iff by simp
```
```    88 next
```
```    89   fix x y z :: "'a \<times> 'b"
```
```    90   show "dist x y \<le> dist x z + dist y z"
```
```    91     unfolding dist_prod_def
```
```    92     by (intro order_trans [OF _ real_sqrt_sum_squares_triangle_ineq]
```
```    93         real_sqrt_le_mono add_mono power_mono dist_triangle2 zero_le_dist)
```
```    94 next
```
```    95   fix S :: "('a \<times> 'b) set"
```
```    96   have *: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
```
```    97   proof
```
```    98     assume "open S" show "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S"
```
```    99     proof
```
```   100       fix x assume "x \<in> S"
```
```   101       obtain A B where "open A" "open B" "x \<in> A \<times> B" "A \<times> B \<subseteq> S"
```
```   102         using \<open>open S\<close> and \<open>x \<in> S\<close> by (rule open_prod_elim)
```
```   103       obtain r where r: "0 < r" "\<forall>y. dist y (fst x) < r \<longrightarrow> y \<in> A"
```
```   104         using \<open>open A\<close> and \<open>x \<in> A \<times> B\<close> unfolding open_dist by auto
```
```   105       obtain s where s: "0 < s" "\<forall>y. dist y (snd x) < s \<longrightarrow> y \<in> B"
```
```   106         using \<open>open B\<close> and \<open>x \<in> A \<times> B\<close> unfolding open_dist by auto
```
```   107       let ?e = "min r s"
```
```   108       have "0 < ?e \<and> (\<forall>y. dist y x < ?e \<longrightarrow> y \<in> S)"
```
```   109       proof (intro allI impI conjI)
```
```   110         show "0 < min r s" by (simp add: r(1) s(1))
```
```   111       next
```
```   112         fix y assume "dist y x < min r s"
```
```   113         hence "dist y x < r" and "dist y x < s"
```
```   114           by simp_all
```
```   115         hence "dist (fst y) (fst x) < r" and "dist (snd y) (snd x) < s"
```
```   116           by (auto intro: le_less_trans dist_fst_le dist_snd_le)
```
```   117         hence "fst y \<in> A" and "snd y \<in> B"
```
```   118           by (simp_all add: r(2) s(2))
```
```   119         hence "y \<in> A \<times> B" by (induct y, simp)
```
```   120         with \<open>A \<times> B \<subseteq> S\<close> show "y \<in> S" ..
```
```   121       qed
```
```   122       thus "\<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" ..
```
```   123     qed
```
```   124   next
```
```   125     assume *: "\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S" show "open S"
```
```   126     proof (rule open_prod_intro)
```
```   127       fix x assume "x \<in> S"
```
```   128       then obtain e where "0 < e" and S: "\<forall>y. dist y x < e \<longrightarrow> y \<in> S"
```
```   129         using * by fast
```
```   130       define r where "r = e / sqrt 2"
```
```   131       define s where "s = e / sqrt 2"
```
```   132       from \<open>0 < e\<close> have "0 < r" and "0 < s"
```
```   133         unfolding r_def s_def by simp_all
```
```   134       from \<open>0 < e\<close> have "e = sqrt (r\<^sup>2 + s\<^sup>2)"
```
```   135         unfolding r_def s_def by (simp add: power_divide)
```
```   136       define A where "A = {y. dist (fst x) y < r}"
```
```   137       define B where "B = {y. dist (snd x) y < s}"
```
```   138       have "open A" and "open B"
```
```   139         unfolding A_def B_def by (simp_all add: open_ball)
```
```   140       moreover have "x \<in> A \<times> B"
```
```   141         unfolding A_def B_def mem_Times_iff
```
```   142         using \<open>0 < r\<close> and \<open>0 < s\<close> by simp
```
```   143       moreover have "A \<times> B \<subseteq> S"
```
```   144       proof (clarify)
```
```   145         fix a b assume "a \<in> A" and "b \<in> B"
```
```   146         hence "dist a (fst x) < r" and "dist b (snd x) < s"
```
```   147           unfolding A_def B_def by (simp_all add: dist_commute)
```
```   148         hence "dist (a, b) x < e"
```
```   149           unfolding dist_prod_def \<open>e = sqrt (r\<^sup>2 + s\<^sup>2)\<close>
```
```   150           by (simp add: add_strict_mono power_strict_mono)
```
```   151         thus "(a, b) \<in> S"
```
```   152           by (simp add: S)
```
```   153       qed
```
```   154       ultimately show "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S" by fast
```
```   155     qed
```
```   156   qed
```
```   157   show "open S = (\<forall>x\<in>S. \<forall>\<^sub>F (x', y) in uniformity. x' = x \<longrightarrow> y \<in> S)"
```
```   158     unfolding * eventually_uniformity_metric
```
```   159     by (simp del: split_paired_All add: dist_prod_def dist_commute)
```
```   160 qed
```
```   161
```
```   162 end
```
```   163
```
```   164 declare [[code abort: "dist::('a::metric_space*'b::metric_space)\<Rightarrow>('a*'b) \<Rightarrow> real"]]
```
```   165
```
```   166 lemma Cauchy_fst: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. fst (X n))"
```
```   167   unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_fst_le])
```
```   168
```
```   169 lemma Cauchy_snd: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. snd (X n))"
```
```   170   unfolding Cauchy_def by (fast elim: le_less_trans [OF dist_snd_le])
```
```   171
```
```   172 lemma Cauchy_Pair:
```
```   173   assumes "Cauchy X" and "Cauchy Y"
```
```   174   shows "Cauchy (\<lambda>n. (X n, Y n))"
```
```   175 proof (rule metric_CauchyI)
```
```   176   fix r :: real assume "0 < r"
```
```   177   hence "0 < r / sqrt 2" (is "0 < ?s") by simp
```
```   178   obtain M where M: "\<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < ?s"
```
```   179     using metric_CauchyD [OF \<open>Cauchy X\<close> \<open>0 < ?s\<close>] ..
```
```   180   obtain N where N: "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (Y m) (Y n) < ?s"
```
```   181     using metric_CauchyD [OF \<open>Cauchy Y\<close> \<open>0 < ?s\<close>] ..
```
```   182   have "\<forall>m\<ge>max M N. \<forall>n\<ge>max M N. dist (X m, Y m) (X n, Y n) < r"
```
```   183     using M N by (simp add: real_sqrt_sum_squares_less dist_Pair_Pair)
```
```   184   then show "\<exists>n0. \<forall>m\<ge>n0. \<forall>n\<ge>n0. dist (X m, Y m) (X n, Y n) < r" ..
```
```   185 qed
```
```   186
```
```   187 subsection \<open>Product is a complete metric space\<close>
```
```   188
```
```   189 instance prod :: (complete_space, complete_space) complete_space
```
```   190 proof
```
```   191   fix X :: "nat \<Rightarrow> 'a \<times> 'b" assume "Cauchy X"
```
```   192   have 1: "(\<lambda>n. fst (X n)) \<longlonglongrightarrow> lim (\<lambda>n. fst (X n))"
```
```   193     using Cauchy_fst [OF \<open>Cauchy X\<close>]
```
```   194     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
```
```   195   have 2: "(\<lambda>n. snd (X n)) \<longlonglongrightarrow> lim (\<lambda>n. snd (X n))"
```
```   196     using Cauchy_snd [OF \<open>Cauchy X\<close>]
```
```   197     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)
```
```   198   have "X \<longlonglongrightarrow> (lim (\<lambda>n. fst (X n)), lim (\<lambda>n. snd (X n)))"
```
```   199     using tendsto_Pair [OF 1 2] by simp
```
```   200   then show "convergent X"
```
```   201     by (rule convergentI)
```
```   202 qed
```
```   203
```
```   204 subsection \<open>Product is a normed vector space\<close>
```
```   205
```
```   206 instantiation prod :: (real_normed_vector, real_normed_vector) real_normed_vector
```
```   207 begin
```
```   208
```
```   209 definition norm_prod_def[code del]:
```
```   210   "norm x = sqrt ((norm (fst x))\<^sup>2 + (norm (snd x))\<^sup>2)"
```
```   211
```
```   212 definition sgn_prod_def:
```
```   213   "sgn (x::'a \<times> 'b) = scaleR (inverse (norm x)) x"
```
```   214
```
```   215 lemma norm_Pair: "norm (a, b) = sqrt ((norm a)\<^sup>2 + (norm b)\<^sup>2)"
```
```   216   unfolding norm_prod_def by simp
```
```   217
```
```   218 instance
```
```   219 proof
```
```   220   fix r :: real and x y :: "'a \<times> 'b"
```
```   221   show "norm x = 0 \<longleftrightarrow> x = 0"
```
```   222     unfolding norm_prod_def
```
```   223     by (simp add: prod_eq_iff)
```
```   224   show "norm (x + y) \<le> norm x + norm y"
```
```   225     unfolding norm_prod_def
```
```   226     apply (rule order_trans [OF _ real_sqrt_sum_squares_triangle_ineq])
```
```   227     apply (simp add: add_mono power_mono norm_triangle_ineq)
```
```   228     done
```
```   229   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
```
```   230     unfolding norm_prod_def
```
```   231     apply (simp add: power_mult_distrib)
```
```   232     apply (simp add: distrib_left [symmetric])
```
```   233     apply (simp add: real_sqrt_mult_distrib)
```
```   234     done
```
```   235   show "sgn x = scaleR (inverse (norm x)) x"
```
```   236     by (rule sgn_prod_def)
```
```   237   show "dist x y = norm (x - y)"
```
```   238     unfolding dist_prod_def norm_prod_def
```
```   239     by (simp add: dist_norm)
```
```   240 qed
```
```   241
```
```   242 end
```
```   243
```
```   244 declare [[code abort: "norm::('a::real_normed_vector*'b::real_normed_vector) \<Rightarrow> real"]]
```
```   245
```
```   246 instance prod :: (banach, banach) banach ..
```
```   247
```
```   248 subsubsection \<open>Pair operations are linear\<close>
```
```   249
```
```   250 lemma bounded_linear_fst: "bounded_linear fst"
```
```   251   using fst_add fst_scaleR
```
```   252   by (rule bounded_linear_intro [where K=1], simp add: norm_prod_def)
```
```   253
```
```   254 lemma bounded_linear_snd: "bounded_linear snd"
```
```   255   using snd_add snd_scaleR
```
```   256   by (rule bounded_linear_intro [where K=1], simp add: norm_prod_def)
```
```   257
```
```   258 lemmas bounded_linear_fst_comp = bounded_linear_fst[THEN bounded_linear_compose]
```
```   259
```
```   260 lemmas bounded_linear_snd_comp = bounded_linear_snd[THEN bounded_linear_compose]
```
```   261
```
```   262 lemma bounded_linear_Pair:
```
```   263   assumes f: "bounded_linear f"
```
```   264   assumes g: "bounded_linear g"
```
```   265   shows "bounded_linear (\<lambda>x. (f x, g x))"
```
```   266 proof
```
```   267   interpret f: bounded_linear f by fact
```
```   268   interpret g: bounded_linear g by fact
```
```   269   fix x y and r :: real
```
```   270   show "(f (x + y), g (x + y)) = (f x, g x) + (f y, g y)"
```
```   271     by (simp add: f.add g.add)
```
```   272   show "(f (r *\<^sub>R x), g (r *\<^sub>R x)) = r *\<^sub>R (f x, g x)"
```
```   273     by (simp add: f.scaleR g.scaleR)
```
```   274   obtain Kf where "0 < Kf" and norm_f: "\<And>x. norm (f x) \<le> norm x * Kf"
```
```   275     using f.pos_bounded by fast
```
```   276   obtain Kg where "0 < Kg" and norm_g: "\<And>x. norm (g x) \<le> norm x * Kg"
```
```   277     using g.pos_bounded by fast
```
```   278   have "\<forall>x. norm (f x, g x) \<le> norm x * (Kf + Kg)"
```
```   279     apply (rule allI)
```
```   280     apply (simp add: norm_Pair)
```
```   281     apply (rule order_trans [OF sqrt_add_le_add_sqrt], simp, simp)
```
```   282     apply (simp add: distrib_left)
```
```   283     apply (rule add_mono [OF norm_f norm_g])
```
```   284     done
```
```   285   then show "\<exists>K. \<forall>x. norm (f x, g x) \<le> norm x * K" ..
```
```   286 qed
```
```   287
```
```   288 subsubsection \<open>Frechet derivatives involving pairs\<close>
```
```   289
```
```   290 lemma has_derivative_Pair [derivative_intros]:
```
```   291   assumes f: "(f has_derivative f') (at x within s)" and g: "(g has_derivative g') (at x within s)"
```
```   292   shows "((\<lambda>x. (f x, g x)) has_derivative (\<lambda>h. (f' h, g' h))) (at x within s)"
```
```   293 proof (rule has_derivativeI_sandwich[of 1])
```
```   294   show "bounded_linear (\<lambda>h. (f' h, g' h))"
```
```   295     using f g by (intro bounded_linear_Pair has_derivative_bounded_linear)
```
```   296   let ?Rf = "\<lambda>y. f y - f x - f' (y - x)"
```
```   297   let ?Rg = "\<lambda>y. g y - g x - g' (y - x)"
```
```   298   let ?R = "\<lambda>y. ((f y, g y) - (f x, g x) - (f' (y - x), g' (y - x)))"
```
```   299
```
```   300   show "((\<lambda>y. norm (?Rf y) / norm (y - x) + norm (?Rg y) / norm (y - x)) \<longlongrightarrow> 0) (at x within s)"
```
```   301     using f g by (intro tendsto_add_zero) (auto simp: has_derivative_iff_norm)
```
```   302
```
```   303   fix y :: 'a assume "y \<noteq> x"
```
```   304   show "norm (?R y) / norm (y - x) \<le> norm (?Rf y) / norm (y - x) + norm (?Rg y) / norm (y - x)"
```
```   305     unfolding add_divide_distrib [symmetric]
```
```   306     by (simp add: norm_Pair divide_right_mono order_trans [OF sqrt_add_le_add_sqrt])
```
```   307 qed simp
```
```   308
```
```   309 lemmas has_derivative_fst [derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_fst]
```
```   310 lemmas has_derivative_snd [derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_snd]
```
```   311
```
```   312 lemma has_derivative_split [derivative_intros]:
```
```   313   "((\<lambda>p. f (fst p) (snd p)) has_derivative f') F \<Longrightarrow> ((\<lambda>(a, b). f a b) has_derivative f') F"
```
```   314   unfolding split_beta' .
```
```   315
```
```   316 subsection \<open>Product is an inner product space\<close>
```
```   317
```
```   318 instantiation prod :: (real_inner, real_inner) real_inner
```
```   319 begin
```
```   320
```
```   321 definition inner_prod_def:
```
```   322   "inner x y = inner (fst x) (fst y) + inner (snd x) (snd y)"
```
```   323
```
```   324 lemma inner_Pair [simp]: "inner (a, b) (c, d) = inner a c + inner b d"
```
```   325   unfolding inner_prod_def by simp
```
```   326
```
```   327 instance
```
```   328 proof
```
```   329   fix r :: real
```
```   330   fix x y z :: "'a::real_inner \<times> 'b::real_inner"
```
```   331   show "inner x y = inner y x"
```
```   332     unfolding inner_prod_def
```
```   333     by (simp add: inner_commute)
```
```   334   show "inner (x + y) z = inner x z + inner y z"
```
```   335     unfolding inner_prod_def
```
```   336     by (simp add: inner_add_left)
```
```   337   show "inner (scaleR r x) y = r * inner x y"
```
```   338     unfolding inner_prod_def
```
```   339     by (simp add: distrib_left)
```
```   340   show "0 \<le> inner x x"
```
```   341     unfolding inner_prod_def
```
```   342     by (intro add_nonneg_nonneg inner_ge_zero)
```
```   343   show "inner x x = 0 \<longleftrightarrow> x = 0"
```
```   344     unfolding inner_prod_def prod_eq_iff
```
```   345     by (simp add: add_nonneg_eq_0_iff)
```
```   346   show "norm x = sqrt (inner x x)"
```
```   347     unfolding norm_prod_def inner_prod_def
```
```   348     by (simp add: power2_norm_eq_inner)
```
```   349 qed
```
```   350
```
```   351 end
```
```   352
```
```   353 lemma inner_Pair_0: "inner x (0, b) = inner (snd x) b" "inner x (a, 0) = inner (fst x) a"
```
```   354     by (cases x, simp)+
```
```   355
```
```   356 lemma
```
```   357   fixes x :: "'a::real_normed_vector"
```
```   358   shows norm_Pair1 [simp]: "norm (0,x) = norm x"
```
```   359     and norm_Pair2 [simp]: "norm (x,0) = norm x"
```
```   360 by (auto simp: norm_Pair)
```
```   361
```
```   362 lemma norm_commute: "norm (x,y) = norm (y,x)"
```
```   363   by (simp add: norm_Pair)
```
```   364
```
```   365 lemma norm_fst_le: "norm x \<le> norm (x,y)"
```
```   366   by (metis dist_fst_le fst_conv fst_zero norm_conv_dist)
```
```   367
```
```   368 lemma norm_snd_le: "norm y \<le> norm (x,y)"
```
```   369   by (metis dist_snd_le snd_conv snd_zero norm_conv_dist)
```
```   370
```
```   371 end
```