src/Pure/Isar/class.ML
author haftmann
Thu Oct 04 19:41:50 2007 +0200 (2007-10-04)
changeset 24836 dab06e93ec28
parent 24770 695a8e087b9f
child 24847 bc15dcaed517
permissions -rw-r--r--
intermediate cleanup
     1 (*  Title:      Pure/Isar/class.ML
     2     ID:         $Id$
     3     Author:     Florian Haftmann, TU Muenchen
     4 
     5 Type classes derived from primitive axclasses and locales.
     6 *)
     7 
     8 signature CLASS =
     9 sig
    10   val fork_mixfix: bool -> string option -> mixfix -> mixfix * mixfix
    11 
    12   val axclass_cmd: bstring * xstring list
    13     -> ((bstring * Attrib.src list) * string list) list
    14     -> theory -> class * theory
    15   val classrel_cmd: xstring * xstring -> theory -> Proof.state
    16   val class: bool -> bstring -> class list -> Element.context_i Locale.element list
    17     -> string list -> theory -> string * Proof.context
    18   val class_cmd: bool -> bstring -> xstring list -> Element.context Locale.element list
    19     -> xstring list -> theory -> string * Proof.context
    20   val add_const_in_class: string -> (string * term) * Syntax.mixfix
    21     -> theory -> theory
    22   val interpretation_in_class: class * class -> theory -> Proof.state
    23   val interpretation_in_class_cmd: xstring * xstring -> theory -> Proof.state
    24   val prove_interpretation_in_class: tactic -> class * class -> theory -> theory
    25   val intro_classes_tac: thm list -> tactic
    26   val default_intro_classes_tac: thm list -> tactic
    27   val class_of_locale: theory -> string -> class option
    28   val print_classes: theory -> unit
    29 
    30   val instance_arity: (theory -> theory) -> arity list -> theory -> Proof.state
    31   val instance: arity list -> ((bstring * Attrib.src list) * term) list
    32     -> (thm list -> theory -> theory)
    33     -> theory -> Proof.state
    34   val instance_cmd: (bstring * xstring list * xstring) list
    35     -> ((bstring * Attrib.src list) * xstring) list
    36     -> (thm list -> theory -> theory)
    37     -> theory -> Proof.state
    38   val prove_instance: tactic -> arity list
    39     -> ((bstring * Attrib.src list) * term) list
    40     -> theory -> thm list * theory
    41   val unoverload: theory -> conv
    42   val overload: theory -> conv
    43   val unoverload_const: theory -> string * typ -> string
    44   val inst_const: theory -> string * string -> string
    45   val param_const: theory -> string -> (string * string) option
    46   val params_of_sort: theory -> sort -> (string * (string * typ)) list
    47 
    48   (*experimental*)
    49   val init_ref: (sort -> Proof.context -> Proof.context) ref
    50   val init: sort -> Proof.context -> Proof.context;
    51   val init_exp: sort -> Proof.context -> Proof.context;
    52   val local_syntax: theory -> class -> bool
    53   val add_abbrev_in_class: string -> (string * term) * Syntax.mixfix
    54     -> theory -> term * theory
    55 end;
    56 
    57 structure Class : CLASS =
    58 struct
    59 
    60 (** auxiliary **)
    61 
    62 fun fork_mixfix is_loc some_class mx =
    63   let
    64     val mx' = Syntax.unlocalize_mixfix mx;
    65     val mx_global = if is_some some_class orelse (is_loc andalso mx = mx')
    66       then NoSyn else mx';
    67     val mx_local = if is_loc then mx else NoSyn;
    68   in (mx_global, mx_local) end;
    69 
    70 fun prove_interpretation tac prfx_atts expr insts =
    71   Locale.interpretation_i I prfx_atts expr insts
    72   #> Proof.global_terminal_proof
    73       (Method.Basic (K (Method.SIMPLE_METHOD tac), Position.none), NONE)
    74   #> ProofContext.theory_of;
    75 
    76 fun prove_interpretation_in tac after_qed (name, expr) =
    77   Locale.interpretation_in_locale
    78       (ProofContext.theory after_qed) (name, expr)
    79   #> Proof.global_terminal_proof
    80       (Method.Basic (K (Method.SIMPLE_METHOD tac), Position.none), NONE)
    81   #> ProofContext.theory_of;
    82 
    83 fun OF_LAST thm1 thm2 =
    84   let
    85     val n = (length o Logic.strip_imp_prems o prop_of) thm2;
    86   in (thm1 RSN (n, thm2)) end;
    87 
    88 fun strip_all_ofclass thy sort =
    89   let
    90     val typ = TVar ((AxClass.param_tyvarname, 0), sort);
    91     fun prem_inclass t =
    92       case Logic.strip_imp_prems t
    93        of ofcls :: _ => try Logic.dest_inclass ofcls
    94         | [] => NONE;
    95     fun strip_ofclass class thm =
    96       thm OF (fst o AxClass.of_sort thy (typ, [class])) AxClass.cache;
    97     fun strip thm = case (prem_inclass o Thm.prop_of) thm
    98      of SOME (_, class) => thm |> strip_ofclass class |> strip
    99       | NONE => thm;
   100   in strip end;
   101 
   102 
   103 (** axclass command **)
   104 
   105 fun axclass_cmd (class, raw_superclasses) raw_specs thy =
   106   let
   107     val ctxt = ProofContext.init thy;
   108     val superclasses = map (Sign.read_class thy) raw_superclasses;
   109     val name_atts = map ((apsnd o map) (Attrib.attribute thy) o fst)
   110       raw_specs;
   111     val axiomss = ProofContext.read_propp (ctxt, map (map (rpair []) o snd)
   112           raw_specs)
   113       |> snd
   114       |> (map o map) fst;
   115   in
   116     AxClass.define_class (class, superclasses) []
   117       (name_atts ~~ axiomss) thy
   118   end;
   119 
   120 local
   121 
   122 fun gen_instance mk_prop add_thm after_qed insts thy =
   123   let
   124     fun after_qed' results =
   125       ProofContext.theory ((fold o fold) add_thm results #> after_qed);
   126   in
   127     thy
   128     |> ProofContext.init
   129     |> Proof.theorem_i NONE after_qed' ((map (fn t => [(t, [])])
   130         o maps (mk_prop thy)) insts)
   131   end;
   132 
   133 in
   134 
   135 val instance_arity =
   136   gen_instance (Logic.mk_arities oo Sign.cert_arity) AxClass.add_arity;
   137 val classrel =
   138   gen_instance (single oo (Logic.mk_classrel oo AxClass.cert_classrel))
   139     AxClass.add_classrel I o single;
   140 val classrel_cmd =
   141   gen_instance (single oo (Logic.mk_classrel oo AxClass.read_classrel))
   142     AxClass.add_classrel I o single;
   143 
   144 end; (*local*)
   145 
   146 
   147 (** explicit constants for overloaded definitions **)
   148 
   149 structure InstData = TheoryDataFun
   150 (
   151   type T = (string * thm) Symtab.table Symtab.table * (string * string) Symtab.table;
   152     (*constant name ~> type constructor ~> (constant name, equation),
   153         constant name ~> (constant name, type constructor)*)
   154   val empty = (Symtab.empty, Symtab.empty);
   155   val copy = I;
   156   val extend = I;
   157   fun merge _ ((taba1, tabb1), (taba2, tabb2)) =
   158     (Symtab.join (K (Symtab.merge (K true))) (taba1, taba2),
   159       Symtab.merge (K true) (tabb1, tabb2));
   160 );
   161 
   162 fun inst_thms f thy = (Symtab.fold (Symtab.fold (cons o f o snd o snd) o snd) o fst)
   163     (InstData.get thy) [];
   164 fun add_inst (c, tyco) inst = (InstData.map o apfst
   165       o Symtab.map_default (c, Symtab.empty)) (Symtab.update_new (tyco, inst))
   166   #> (InstData.map o apsnd) (Symtab.update_new (fst inst, (c, tyco)));
   167 
   168 fun unoverload thy = MetaSimplifier.rewrite false (inst_thms I thy);
   169 fun overload thy = MetaSimplifier.rewrite false (inst_thms symmetric thy);
   170 
   171 fun inst_const thy (c, tyco) =
   172   (fst o the o Symtab.lookup ((the o Symtab.lookup (fst (InstData.get thy))) c)) tyco;
   173 fun unoverload_const thy (c_ty as (c, _)) =
   174   case AxClass.class_of_param thy c
   175    of SOME class => (case Sign.const_typargs thy c_ty
   176        of [Type (tyco, _)] => (case Symtab.lookup
   177            ((the o Symtab.lookup (fst (InstData.get thy))) c) tyco
   178              of SOME (c, _) => c
   179               | NONE => c)
   180         | [_] => c)
   181     | NONE => c;
   182 
   183 val param_const = Symtab.lookup o snd o InstData.get;
   184 
   185 fun add_inst_def (class, tyco) (c, ty) thy =
   186   let
   187     val tyco_base = NameSpace.base tyco;
   188     val name_inst = NameSpace.base class ^ "_" ^ tyco_base ^ "_inst";
   189     val c_inst_base = NameSpace.base c ^ "_" ^ tyco_base;
   190   in
   191     thy
   192     |> Sign.sticky_prefix name_inst
   193     |> PureThy.simple_def ("", [])
   194          (((c_inst_base, ty, Syntax.NoSyn), []), Const (c, ty))
   195     |-> (fn (c_inst, thm) => add_inst (c, tyco) (c_inst, symmetric thm))
   196     |> Sign.restore_naming thy
   197   end;
   198 
   199 fun add_inst_def' (class, tyco) (c, ty) thy =
   200   if case Symtab.lookup (fst (InstData.get thy)) c
   201    of NONE => true
   202     | SOME tab => is_none (Symtab.lookup tab tyco)
   203   then add_inst_def (class, tyco) (c, Logic.unvarifyT ty) thy
   204   else thy;
   205 
   206 fun add_def ((class, tyco), ((name, prop), atts)) thy =
   207   let
   208     val ((lhs as Const (c, ty), args), rhs) =
   209       (apfst Term.strip_comb o Logic.dest_equals) prop;
   210     fun (*add_inst' def ([], (Const (c_inst, ty))) =
   211           if forall (fn TFree _ => true | _ => false) (Sign.const_typargs thy (c_inst, ty))
   212           then add_inst (c, tyco) (c_inst, def)
   213           else add_inst_def (class, tyco) (c, ty)
   214       |*) add_inst' _ t = add_inst_def (class, tyco) (c, ty);
   215   in
   216     thy
   217     |> PureThy.add_defs_i true [((name, prop), map (Attrib.attribute thy) atts)]
   218     |-> (fn [def] => add_inst' def (args, rhs) #> pair def)
   219   end;
   220 
   221 
   222 (** instances with implicit parameter handling **)
   223 
   224 local
   225 
   226 fun gen_read_def thy prep_att parse_prop ((raw_name, raw_atts), raw_t) =
   227   let
   228     val ctxt = ProofContext.init thy;
   229     val t = parse_prop ctxt raw_t |> Syntax.check_prop ctxt;
   230     val ((c, ty), _) = Sign.cert_def (Sign.pp thy) t;
   231     val atts = map (prep_att thy) raw_atts;
   232     val insts = Consts.typargs (Sign.consts_of thy) (c, ty);
   233     val name = case raw_name
   234      of "" => NONE
   235       | _ => SOME raw_name;
   236   in (c, (insts, ((name, t), atts))) end;
   237 
   238 fun read_def_cmd thy = gen_read_def thy Attrib.intern_src Syntax.parse_prop;
   239 fun read_def thy = gen_read_def thy (K I) (K I);
   240 
   241 fun gen_instance prep_arity read_def do_proof raw_arities raw_defs after_qed theory =
   242   let
   243     val arities = map (prep_arity theory) raw_arities;
   244     val _ = if null arities then error "at least one arity must be given" else ();
   245     val _ = case (duplicates (op =) o map #1) arities
   246      of [] => ()
   247       | dupl_tycos => error ("type constructors occur more than once in arities: "
   248           ^ (commas o map quote) dupl_tycos);
   249     fun get_remove_constraint c thy =
   250       let
   251         val ty = Sign.the_const_constraint thy c;
   252       in
   253         thy
   254         |> Sign.add_const_constraint (c, NONE)
   255         |> pair (c, Logic.unvarifyT ty)
   256       end;
   257     fun get_consts_class tyco ty class =
   258       let
   259         val cs = (these o Option.map snd o try (AxClass.params_of_class theory)) class;
   260         val subst_ty = map_type_tfree (K ty);
   261       in
   262         map (fn (c, ty) => (c, ((class, tyco), subst_ty ty))) cs
   263       end;
   264     fun get_consts_sort (tyco, asorts, sort) =
   265       let
   266         val ty = Type (tyco, map (fn (v, sort) => TVar ((v, 0), sort))
   267           (Name.names Name.context "'a" asorts))
   268       in maps (get_consts_class tyco ty) (Sign.complete_sort theory sort) end;
   269     val cs = maps get_consts_sort arities;
   270     fun mk_typnorm thy (ty, ty_sc) =
   271       case try (Sign.typ_match thy (Logic.varifyT ty_sc, ty)) Vartab.empty
   272        of SOME env => SOME (Logic.varifyT #> Envir.typ_subst_TVars env #> Logic.unvarifyT)
   273         | NONE => NONE;
   274     fun read_defs defs cs thy_read =
   275       let
   276         fun read raw_def cs =
   277           let
   278             val (c, (inst, ((name_opt, t), atts))) = read_def thy_read raw_def;
   279             val ty = Consts.instance (Sign.consts_of thy_read) (c, inst);
   280             val ((class, tyco), ty') = case AList.lookup (op =) cs c
   281              of NONE => error ("illegal definition for constant " ^ quote c)
   282               | SOME class_ty => class_ty;
   283             val name = case name_opt
   284              of NONE => Thm.def_name (Logic.name_arity (tyco, [], c))
   285               | SOME name => name;
   286             val t' = case mk_typnorm thy_read (ty', ty)
   287              of NONE => error ("illegal definition for constant " ^
   288                   quote (c ^ "::" ^ setmp show_sorts true
   289                     (Sign.string_of_typ thy_read) ty))
   290               | SOME norm => map_types norm t
   291           in (((class, tyco), ((name, t'), atts)), AList.delete (op =) c cs) end;
   292       in fold_map read defs cs end;
   293     val (defs, other_cs) = read_defs raw_defs cs
   294       (fold Sign.primitive_arity arities (Theory.copy theory));
   295     fun after_qed' cs defs =
   296       fold Sign.add_const_constraint (map (apsnd SOME) cs)
   297       #> after_qed defs;
   298   in
   299     theory
   300     |> fold_map get_remove_constraint (map fst cs |> distinct (op =))
   301     ||>> fold_map add_def defs
   302     ||> fold (fn (c, ((class, tyco), ty)) => add_inst_def' (class, tyco) (c, ty)) other_cs
   303     |-> (fn (cs, defs) => do_proof (after_qed' cs defs) arities defs)
   304   end;
   305 
   306 fun tactic_proof tac f arities defs =
   307   fold (fn arity => AxClass.prove_arity arity tac) arities
   308   #> f
   309   #> pair defs;
   310 
   311 in
   312 
   313 val instance = gen_instance Sign.cert_arity read_def
   314   (fn f => fn arities => fn defs => instance_arity f arities);
   315 val instance_cmd = gen_instance Sign.read_arity read_def_cmd
   316   (fn f => fn arities => fn defs => instance_arity f arities);
   317 fun prove_instance tac arities defs =
   318   gen_instance Sign.cert_arity read_def
   319     (tactic_proof tac) arities defs (K I);
   320 
   321 end; (*local*)
   322 
   323 
   324 
   325 (** class data **)
   326 
   327 datatype class_data = ClassData of {
   328   locale: string,
   329   consts: (string * string) list
   330     (*locale parameter ~> constant name*),
   331   local_sort: sort,
   332   inst: typ Symtab.table * term Symtab.table
   333     (*canonical interpretation*),
   334   intro: thm,
   335   local_syntax: bool,
   336   defs: thm list,
   337   operations: (string * (term * int) option) list
   338     (*constant name ~> (locale term, instantiaton index of class typ)*)
   339 };
   340 
   341 fun rep_class_data (ClassData d) = d;
   342 fun mk_class_data ((locale, consts, local_sort, inst, intro, local_syntax), (defs, operations)) =
   343   ClassData { locale = locale, consts = consts, local_sort = local_sort, inst = inst, intro = intro,
   344     local_syntax = local_syntax, defs = defs, operations = operations };
   345 fun map_class_data f (ClassData { locale, consts, local_sort, inst, intro, local_syntax, defs, operations }) =
   346   mk_class_data (f ((locale, consts, local_sort, inst, intro, local_syntax), (defs, operations)))
   347 fun merge_class_data _ (ClassData { locale = locale, consts = consts, local_sort = local_sort, inst = inst,
   348     intro = intro, local_syntax = local_syntax, defs = defs1, operations = operations1 },
   349   ClassData { locale = _, consts = _, local_sort = _, inst = _, intro = _, local_syntax = _,
   350     defs = defs2, operations = operations2 }) =
   351   mk_class_data ((locale, consts, local_sort, inst, intro, local_syntax),
   352     (Thm.merge_thms (defs1, defs2), AList.merge (op =) (K true) (operations1, operations2)));
   353 
   354 fun merge_pair f1 f2 ((x1, y1), (x2, y2)) = (f1 (x1, x2), f2 (y1, y2));
   355 
   356 structure ClassData = TheoryDataFun
   357 (
   358   type T = class_data Graph.T * class Symtab.table
   359     (*locale name ~> class name*);
   360   val empty = (Graph.empty, Symtab.empty);
   361   val copy = I;
   362   val extend = I;
   363   fun merge _ = merge_pair (Graph.join merge_class_data) (Symtab.merge (K true));
   364 );
   365 
   366 
   367 (* queries *)
   368 
   369 val lookup_class_data = Option.map rep_class_data oo try o Graph.get_node
   370   o fst o ClassData.get;
   371 fun class_of_locale thy = Symtab.lookup ((snd o ClassData.get) thy);
   372 
   373 fun the_class_data thy class = case lookup_class_data thy class
   374  of NONE => error ("undeclared class " ^ quote class)
   375   | SOME data => data;
   376 
   377 val ancestry = Graph.all_succs o fst o ClassData.get;
   378 
   379 fun params_of_sort thy =
   380   let
   381     fun params class =
   382       let
   383         val const_typs = (#params o AxClass.get_definition thy) class;
   384         val const_names = (#consts o the_class_data thy) class;
   385       in
   386         (map o apsnd) (fn c => (c, (the o AList.lookup (op =) const_typs) c)) const_names
   387       end;
   388   in maps params o ancestry thy end;
   389 
   390 fun these_defs thy = maps (these o Option.map #defs o lookup_class_data thy) o ancestry thy;
   391 
   392 fun these_intros thy =
   393   Graph.fold (fn (_, (data, _)) => insert Thm.eq_thm ((#intro o rep_class_data) data))
   394     ((fst o ClassData.get) thy) [];
   395 
   396 fun these_operations thy =
   397   maps (#operations o the_class_data thy) o ancestry thy;
   398 
   399 fun local_operation thy = Option.join oo AList.lookup (op =) o these_operations thy;
   400 
   401 fun local_syntax thy = #local_syntax o the_class_data thy;
   402 
   403 fun print_classes thy =
   404   let
   405     val algebra = Sign.classes_of thy;
   406     val arities =
   407       Symtab.empty
   408       |> Symtab.fold (fn (tyco, arities) => fold (fn (class, _) =>
   409            Symtab.map_default (class, []) (insert (op =) tyco)) arities)
   410              ((#arities o Sorts.rep_algebra) algebra);
   411     val the_arities = these o Symtab.lookup arities;
   412     fun mk_arity class tyco =
   413       let
   414         val Ss = Sorts.mg_domain algebra tyco [class];
   415       in Sign.pretty_arity thy (tyco, Ss, [class]) end;
   416     fun mk_param (c, ty) = Pretty.str (Sign.extern_const thy c ^ " :: "
   417       ^ setmp show_sorts false (Sign.string_of_typ thy o Type.strip_sorts) ty);
   418     fun mk_entry class = (Pretty.block o Pretty.fbreaks o map_filter I) [
   419       (SOME o Pretty.str) ("class " ^ class ^ ":"),
   420       (SOME o Pretty.block) [Pretty.str "supersort: ",
   421         (Sign.pretty_sort thy o Sign.minimize_sort thy o Sign.super_classes thy) class],
   422       Option.map (Pretty.str o prefix "locale: " o #locale) (lookup_class_data thy class),
   423       ((fn [] => NONE | ps => (SOME o Pretty.block o Pretty.fbreaks) (Pretty.str "parameters:" :: ps)) o map mk_param
   424         o these o Option.map #params o try (AxClass.get_definition thy)) class,
   425       (SOME o Pretty.block o Pretty.breaks) [
   426         Pretty.str "instances:",
   427         Pretty.list "" "" (map (mk_arity class) (the_arities class))
   428       ]
   429     ]
   430   in
   431     (Pretty.writeln o Pretty.chunks o separate (Pretty.str "")
   432       o map mk_entry o Sorts.all_classes) algebra
   433   end;
   434 
   435 
   436 (* updaters *)
   437 
   438 fun add_class_data ((class, superclasses), (locale, consts, local_sort, inst, intro, local_syntax)) =
   439   ClassData.map (fn (gr, tab) => (
   440     gr
   441     |> Graph.new_node (class, mk_class_data ((locale, (map o apfst) fst consts, local_sort, inst,
   442          intro, local_syntax), ([], map (apsnd (SOME o rpair 0 o Free) o swap) consts)))
   443     |> fold (curry Graph.add_edge class) superclasses,
   444     tab
   445     |> Symtab.update (locale, class)
   446   ));
   447 
   448 fun register_const (class, (entry, def)) =
   449   (ClassData.map o apfst o Graph.map_node class o map_class_data o apsnd)
   450     (fn (defs, operations) => (def :: defs, apsnd SOME entry :: operations));
   451 
   452 fun register_abbrev class abbrev =
   453   (ClassData.map o apfst o Graph.map_node class o map_class_data o apsnd o apsnd)
   454     (cons (abbrev, NONE));
   455 
   456 
   457 (** rule calculation, tactics and methods **)
   458 
   459 fun class_intro thy locale class sups =
   460   let
   461     fun class_elim class =
   462       case (map Drule.unconstrainTs o #axioms o AxClass.get_definition thy) class
   463        of [thm] => SOME thm
   464         | [] => NONE;
   465     val pred_intro = case Locale.intros thy locale
   466      of ([ax_intro], [intro]) => intro |> OF_LAST ax_intro |> SOME
   467       | ([intro], []) => SOME intro
   468       | ([], [intro]) => SOME intro
   469       | _ => NONE;
   470     val pred_intro' = pred_intro
   471       |> Option.map (fn intro => intro OF map_filter class_elim sups);
   472     val class_intro = (#intro o AxClass.get_definition thy) class;
   473     val raw_intro = case pred_intro'
   474      of SOME pred_intro => class_intro |> OF_LAST pred_intro
   475       | NONE => class_intro;
   476     val sort = Sign.super_classes thy class;
   477     val typ = TVar ((AxClass.param_tyvarname, 0), sort);
   478     val defs = these_defs thy sups;
   479   in
   480     raw_intro
   481     |> Drule.instantiate' [SOME (Thm.ctyp_of thy typ)] []
   482     |> strip_all_ofclass thy sort
   483     |> Thm.strip_shyps
   484     |> MetaSimplifier.rewrite_rule defs
   485     |> Drule.unconstrainTs
   486   end;
   487 
   488 fun class_interpretation class facts defs thy =
   489   let
   490     val { locale, inst, ... } = the_class_data thy class;
   491     val tac = (ALLGOALS o ProofContext.fact_tac) facts;
   492     val prfx = Logic.const_of_class (NameSpace.base class);
   493   in
   494     prove_interpretation tac ((false, prfx), []) (Locale.Locale locale)
   495       (inst, defs) thy
   496   end;
   497 
   498 fun interpretation_in_rule thy (class1, class2) =
   499   let
   500     fun mk_axioms class =
   501       let
   502         val { locale, inst = (_, insttab), ... } = the_class_data thy class;
   503       in
   504         Locale.global_asms_of thy locale
   505         |> maps snd
   506         |> (map o map_aterms) (fn Free (s, _) => (the o Symtab.lookup insttab) s | t => t)
   507         |> (map o map_types o map_atyps) (fn TFree _ => TFree ("'a", [class1]) | T => T)
   508         |> map (ObjectLogic.ensure_propT thy)
   509       end;
   510     val (prems, concls) = pairself mk_axioms (class1, class2);
   511   in
   512     Goal.prove_global thy [] prems (Logic.mk_conjunction_list concls)
   513       (Locale.intro_locales_tac true (ProofContext.init thy))
   514   end;
   515 
   516 fun intro_classes_tac facts st =
   517   let
   518     val thy = Thm.theory_of_thm st;
   519     val classes = Sign.all_classes thy;
   520     val class_trivs = map (Thm.class_triv thy) classes;
   521     val class_intros = these_intros thy;
   522     fun add_axclass_intro class =
   523       case try (AxClass.get_definition thy) class of SOME {intro, ...} => cons intro | _ => I;
   524     val axclass_intros = fold add_axclass_intro classes [];
   525   in
   526     st
   527     |> ((ALLGOALS (Method.insert_tac facts THEN'
   528           REPEAT_ALL_NEW (resolve_tac (class_trivs @ class_intros @ axclass_intros))))
   529             THEN Tactic.distinct_subgoals_tac)
   530   end;
   531 
   532 fun default_intro_classes_tac [] = intro_classes_tac []
   533   | default_intro_classes_tac _ = Tactical.no_tac;    (*no error message!*)
   534 
   535 fun default_tac rules ctxt facts =
   536   HEADGOAL (Method.some_rule_tac rules ctxt facts) ORELSE
   537     default_intro_classes_tac facts;
   538 
   539 val _ = Context.add_setup (Method.add_methods
   540  [("intro_classes", Method.no_args (Method.METHOD intro_classes_tac),
   541     "back-chain introduction rules of classes"),
   542   ("default", Method.thms_ctxt_args (Method.METHOD oo default_tac),
   543     "apply some intro/elim rule")]);
   544 
   545 
   546 (** classes and class target **)
   547 
   548 (* class context initialization - experimental *)
   549 
   550 fun get_remove_constraints sort ctxt =
   551   let
   552     val operations = these_operations (ProofContext.theory_of ctxt) sort;
   553     fun get_remove (c, _) ctxt =
   554       let
   555         val ty = ProofContext.the_const_constraint ctxt c;
   556         val _ = tracing c;
   557       in
   558         ctxt
   559         |> ProofContext.add_const_constraint (c, NONE)
   560         |> pair (c, ty)
   561       end;
   562   in
   563     ctxt
   564     |> fold_map get_remove operations
   565   end;
   566 
   567 fun sort_term_check thy sort constraints =
   568   let
   569     val local_operation = local_operation thy sort;
   570     fun default_typ consts c = case AList.lookup (op =) constraints c
   571      of SOME ty => SOME ty
   572       | NONE => try (Consts.the_constraint consts) c;
   573     fun infer_constraints ctxt ts =
   574         TypeInfer.infer_types (ProofContext.pp ctxt)
   575           (Sign.tsig_of (ProofContext.theory_of ctxt))
   576           I (default_typ (ProofContext.consts_of ctxt)) (K NONE)
   577           (Variable.names_of ctxt) (Variable.maxidx_of ctxt) NONE (map (rpair dummyT) ts)
   578         |> fst |> map fst
   579       handle TYPE (msg, _, _) => error msg;
   580     fun check_typ c idx ty = case (nth (Sign.const_typargs thy (c, ty)) idx) (*FIXME localize*)
   581      of TFree (v, _) => v = AxClass.param_tyvarname
   582       | TVar (vi, _) => TypeInfer.is_param vi (*FIXME substitute in all typs*)
   583       | _ => false;
   584     fun subst_operation (t as Const (c, ty)) = (case local_operation c
   585          of SOME (t', idx) => if check_typ c idx ty then t' else t
   586           | NONE => t)
   587       | subst_operation t = t;
   588     fun subst_operations ts ctxt =
   589       ts
   590       |> (map o map_aterms) subst_operation
   591       |> infer_constraints ctxt
   592       |> rpair ctxt; (*FIXME add constraints here*)
   593   in subst_operations end;
   594 
   595 fun init_exp sort ctxt =
   596   let
   597     val thy = ProofContext.theory_of ctxt;
   598     val local_sort = (#local_sort o the_class_data thy) (hd sort);
   599     val term_check = sort_term_check thy sort;
   600   in
   601     ctxt
   602     |> Variable.declare_term
   603         (Logic.mk_type (TFree (AxClass.param_tyvarname, local_sort)))
   604     |> get_remove_constraints sort
   605     |-> (fn constraints => Context.proof_map (Syntax.add_term_check 50 "class"
   606           (sort_term_check thy sort constraints)))
   607   end;
   608 
   609 val init_ref = ref (K I : sort -> Proof.context -> Proof.context);
   610 fun init class = ! init_ref class;
   611 
   612 
   613 (* class definition *)
   614 
   615 local
   616 
   617 fun read_param thy raw_t =  (* FIXME ProofContext.read_const (!?) *)
   618   let
   619     val t = Syntax.read_term_global thy raw_t
   620   in case try dest_Const t
   621    of SOME (c, _) => c
   622     | NONE => error ("Not a constant: " ^ Sign.string_of_term thy t)
   623   end;
   624 
   625 fun gen_class_spec prep_class prep_expr process_expr thy raw_supclasses raw_includes_elems =
   626   let
   627     val supclasses = map (prep_class thy) raw_supclasses;
   628     val sups = filter (is_some o lookup_class_data thy) supclasses
   629       |> Sign.minimize_sort thy;
   630     val supsort = Sign.minimize_sort thy supclasses;
   631     val local_sort = case sups
   632      of sup :: _ => (#local_sort o the_class_data thy) sup
   633       | [] => supsort;
   634     val suplocales = map (Locale.Locale o #locale o the_class_data thy) sups;
   635     val (raw_elems, includes) = fold_rev (fn Locale.Elem e => apfst (cons e)
   636       | Locale.Expr i => apsnd (cons (prep_expr thy i))) raw_includes_elems ([], []);
   637     val supexpr = Locale.Merge suplocales;
   638     val supparams = (map fst o Locale.parameters_of_expr thy) supexpr;
   639     val supconsts = AList.make (the o AList.lookup (op =) (params_of_sort thy sups))
   640       (map fst supparams);
   641     val mergeexpr = Locale.Merge (suplocales @ includes);
   642     val constrain = Element.Constrains ((map o apsnd o map_atyps)
   643       (fn TFree (_, sort) => TFree (AxClass.param_tyvarname, sort)) supparams);
   644   in
   645     ProofContext.init thy
   646     |> Locale.cert_expr supexpr [constrain]
   647     |> snd
   648     |> init supsort
   649     |> process_expr Locale.empty raw_elems
   650     |> fst
   651     |> (fn elems => ((((sups, supconsts), (supsort, local_sort, mergeexpr)),
   652           (*FIXME*) if null includes then constrain :: elems else elems)))
   653   end;
   654 
   655 val read_class_spec = gen_class_spec Sign.intern_class Locale.intern_expr Locale.read_expr;
   656 val check_class_spec = gen_class_spec (K I) (K I) Locale.cert_expr;
   657 
   658 fun gen_class prep_spec prep_param local_syntax bname
   659     raw_supclasses raw_includes_elems raw_other_consts thy =
   660   let
   661     val (((sups, supconsts), (supsort, local_sort, mergeexpr)), elems) =
   662       prep_spec thy raw_supclasses raw_includes_elems;
   663     val other_consts = map (prep_param thy) raw_other_consts;
   664     fun mk_instT class = Symtab.empty
   665       |> Symtab.update (AxClass.param_tyvarname, TFree (AxClass.param_tyvarname, [class]));
   666     fun mk_inst class param_names cs =
   667       Symtab.empty
   668       |> fold2 (fn v => fn (c, ty) => Symtab.update (v, Const
   669            (c, Term.map_type_tfree (fn (v, _) => TFree (v, [class])) ty))) param_names cs;
   670     fun extract_params thy name_locale =
   671       let
   672         val params = Locale.parameters_of thy name_locale;
   673         val local_sort = case AList.group (op =) ((maps typ_tfrees o map (snd o fst)) params)
   674          of [(_, local_sort :: _)] => local_sort
   675           | _ => Sign.defaultS thy
   676           | vs => error ("exactly one type variable required: " ^ commas (map fst vs));
   677         val _ = if Sign.subsort thy (supsort, local_sort) then () else error
   678           ("Sort " ^ Sign.string_of_sort thy local_sort
   679             ^ " is less general than permitted least general sort "
   680             ^ Sign.string_of_sort thy supsort);
   681       in
   682         (local_sort, (map fst params, params
   683         |> (map o apfst o apsnd o Term.map_type_tfree) (K (TFree (AxClass.param_tyvarname, local_sort)))
   684         |> (map o apsnd) (fork_mixfix true NONE #> fst)
   685         |> chop (length supconsts)
   686         |> snd))
   687       end;
   688     fun extract_assumes name_locale params thy cs =
   689       let
   690         val consts = supconsts @ (map (fst o fst) params ~~ cs);
   691         fun subst (Free (c, ty)) =
   692               Const ((fst o the o AList.lookup (op =) consts) c, ty)
   693           | subst t = t;
   694         fun prep_asm ((name, atts), ts) =
   695           ((NameSpace.base name, map (Attrib.attribute thy) atts),
   696             (map o map_aterms) subst ts);
   697       in
   698         Locale.global_asms_of thy name_locale
   699         |> map prep_asm
   700       end;
   701     fun note_intro name_axclass class_intro =
   702       PureThy.note_thmss_qualified "" ((Logic.const_of_class o NameSpace.base) name_axclass)
   703         [(("intro", []), [([class_intro], [])])]
   704       #> snd
   705   in
   706     thy
   707     |> Locale.add_locale_i (SOME "") bname mergeexpr elems
   708     |-> (fn name_locale => ProofContext.theory_result (
   709       `(fn thy => extract_params thy name_locale)
   710       #-> (fn (_, (globals, params)) =>
   711         AxClass.define_class_params (bname, supsort) params
   712           (extract_assumes name_locale params) other_consts
   713       #-> (fn (name_axclass, (consts, axioms)) =>
   714         `(fn thy => class_intro thy name_locale name_axclass sups)
   715       #-> (fn class_intro =>
   716         add_class_data ((name_axclass, sups),
   717           (name_locale, map fst params ~~ map fst consts, local_sort,
   718             (mk_instT name_axclass, mk_inst name_axclass (map fst globals)
   719               (map snd supconsts @ consts)), class_intro, local_syntax))
   720       #> note_intro name_axclass class_intro
   721       #> class_interpretation name_axclass axioms []
   722       #> pair name_axclass
   723       )))))
   724   end;
   725 
   726 in
   727 
   728 val class_cmd = gen_class read_class_spec read_param;
   729 val class = gen_class check_class_spec (K I);
   730 
   731 end; (*local*)
   732 
   733 
   734 (* definition in class target *)
   735 
   736 fun export_fixes thy class =
   737   let
   738     val consts = params_of_sort thy [class];
   739     fun subst_aterm (t as Free (v, ty)) = (case AList.lookup (op =) consts v
   740          of SOME (c, _) => Const (c, ty)
   741           | NONE => t)
   742       | subst_aterm t = t;
   743   in Term.map_aterms subst_aterm end;
   744 
   745 fun add_const_in_class class ((c, rhs), syn) thy =
   746   let
   747     val prfx = (Logic.const_of_class o NameSpace.base) class;
   748     fun mk_name c =
   749       let
   750         val n1 = Sign.full_name thy c;
   751         val n2 = NameSpace.qualifier n1;
   752         val n3 = NameSpace.base n1;
   753       in NameSpace.implode [n2, prfx, n3] end;
   754     val constrain_sort = curry (Sorts.inter_sort (Sign.classes_of thy)) [class];
   755     val rhs' = export_fixes thy class rhs;
   756     val subst_typ = Term.map_type_tfree (fn var as (w, sort) =>
   757       if w = AxClass.param_tyvarname then TFree (w, constrain_sort sort) else TFree var);
   758     val ty' = Term.fastype_of rhs';
   759     val ty'' = subst_typ ty';
   760     val c' = mk_name c;
   761     val def = (c, Logic.mk_equals (Const (c', ty'), rhs'));
   762     val (syn', _) = fork_mixfix true NONE syn;
   763     fun interpret def thy =
   764       let
   765         val def' = symmetric def;
   766         val def_eq = Thm.prop_of def';
   767         val typargs = Sign.const_typargs thy (c', fastype_of rhs);
   768         val typidx = find_index (fn TFree (w, _) => AxClass.param_tyvarname = w | _ => false) typargs;
   769       in
   770         thy
   771         |> class_interpretation class [def'] [def_eq]
   772         |> register_const (class, ((c', (rhs, typidx)), def'))
   773       end;
   774   in
   775     thy
   776     |> Sign.add_path prfx
   777     |> Sign.add_consts_authentic [] [(c, ty', syn')]
   778     |> Sign.parent_path
   779     |> Sign.sticky_prefix prfx
   780     |> PureThy.add_defs_i false [(def, [])]
   781     |-> (fn [def] => interpret def)
   782     |> Sign.add_const_constraint (c', SOME ty'')
   783     |> Sign.restore_naming thy
   784   end;
   785 
   786 fun add_abbrev_in_class class ((c, rhs), syn) thy =
   787   let
   788     val local_sort = (#local_sort o the_class_data thy) class;
   789     val subst_typ = Term.map_type_tfree (fn var as (w, sort) =>
   790       if w = AxClass.param_tyvarname then TFree (w, local_sort) else TFree var);
   791     val ty = fastype_of rhs;
   792     val rhs' = map_types subst_typ rhs;
   793   in
   794     thy
   795     |> Sign.parent_path (*FIXME*)
   796     |> Sign.add_abbrev Syntax.internalM [] (c, rhs)
   797     |-> (fn (lhs as Const (c', _), _) => register_abbrev class c'
   798       (*#> Sign.add_const_constraint (c', SOME ty)*)
   799       #> pair lhs)
   800     ||> Sign.restore_naming thy
   801   end;
   802 
   803 
   804 (* interpretation in class target *)
   805 
   806 local
   807 
   808 fun gen_interpretation_in_class prep_class do_proof (raw_class, raw_superclass) theory =
   809   let
   810     val class = prep_class theory raw_class;
   811     val superclass = prep_class theory raw_superclass;
   812     val loc_name = (#locale o the_class_data theory) class;
   813     val loc_expr = (Locale.Locale o #locale o the_class_data theory) superclass;
   814     fun prove_classrel (class, superclass) thy =
   815       let
   816         val classes = Sign.complete_sort thy [superclass]
   817           |> filter_out (fn class' => Sign.subsort thy ([class], [class']));
   818         fun instance_subclass (class1, class2) thy  =
   819           let
   820             val interp = interpretation_in_rule thy (class1, class2);
   821             val ax = #axioms (AxClass.get_definition thy class1);
   822             val intro = #intro (AxClass.get_definition thy class2)
   823               |> Drule.instantiate' [SOME (Thm.ctyp_of thy
   824                   (TVar ((AxClass.param_tyvarname, 0), [class1])))] [];
   825             val thm =
   826               intro
   827               |> OF_LAST (interp OF ax)
   828               |> strip_all_ofclass thy (Sign.super_classes thy class2);
   829           in
   830             thy |> AxClass.add_classrel thm
   831           end;
   832       in
   833         thy |> fold_rev (curry instance_subclass class) classes
   834       end;
   835   in
   836     theory
   837     |> do_proof (prove_classrel (class, superclass)) (loc_name, loc_expr)
   838   end;
   839 
   840 in
   841 
   842 val interpretation_in_class = gen_interpretation_in_class Sign.certify_class
   843   (Locale.interpretation_in_locale o ProofContext.theory);
   844 val interpretation_in_class_cmd = gen_interpretation_in_class Sign.read_class
   845   (Locale.interpretation_in_locale o ProofContext.theory);
   846 val prove_interpretation_in_class = gen_interpretation_in_class Sign.certify_class
   847   o prove_interpretation_in;
   848 
   849 end; (*local*)
   850 
   851 end;