src/HOL/HOL.thy
author wenzelm
Fri Mar 28 19:43:54 2008 +0100 (2008-03-28)
changeset 26462 dac4e2bce00d
parent 26411 cd74690f3bfb
child 26496 49ae9456eba9
permissions -rw-r--r--
avoid rebinding of existing facts;
     1 (*  Title:      HOL/HOL.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* The basis of Higher-Order Logic *}
     7 
     8 theory HOL
     9 imports CPure
    10 uses
    11   ("hologic.ML")
    12   "~~/src/Tools/IsaPlanner/zipper.ML"
    13   "~~/src/Tools/IsaPlanner/isand.ML"
    14   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    15   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    16   "~~/src/Provers/project_rule.ML"
    17   "~~/src/Provers/hypsubst.ML"
    18   "~~/src/Provers/splitter.ML"
    19   "~~/src/Provers/classical.ML"
    20   "~~/src/Provers/blast.ML"
    21   "~~/src/Provers/clasimp.ML"
    22   "~~/src/Provers/eqsubst.ML"
    23   "~~/src/Provers/quantifier1.ML"
    24   ("simpdata.ML")
    25   "~~/src/Tools/random_word.ML"
    26   "~~/src/Tools/induct.ML"
    27   "~~/src/Tools/code/code_name.ML"
    28   "~~/src/Tools/code/code_funcgr.ML"
    29   "~~/src/Tools/code/code_thingol.ML"
    30   "~~/src/Tools/code/code_target.ML"
    31   "~~/src/Tools/code/code_package.ML"
    32   "~~/src/Tools/nbe.ML"
    33 begin
    34 
    35 subsection {* Primitive logic *}
    36 
    37 subsubsection {* Core syntax *}
    38 
    39 classes type
    40 defaultsort type
    41 setup {* ObjectLogic.add_base_sort @{sort type} *}
    42 
    43 arities
    44   "fun" :: (type, type) type
    45   itself :: (type) type
    46 
    47 global
    48 
    49 typedecl bool
    50 
    51 judgment
    52   Trueprop      :: "bool => prop"                   ("(_)" 5)
    53 
    54 consts
    55   Not           :: "bool => bool"                   ("~ _" [40] 40)
    56   True          :: bool
    57   False         :: bool
    58   arbitrary     :: 'a
    59 
    60   The           :: "('a => bool) => 'a"
    61   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    62   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    63   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    64   Let           :: "['a, 'a => 'b] => 'b"
    65 
    66   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    67   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    68   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    69   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    70 
    71 local
    72 
    73 consts
    74   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    75 
    76 
    77 subsubsection {* Additional concrete syntax *}
    78 
    79 notation (output)
    80   "op ="  (infix "=" 50)
    81 
    82 abbreviation
    83   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    84   "x ~= y == ~ (x = y)"
    85 
    86 notation (output)
    87   not_equal  (infix "~=" 50)
    88 
    89 notation (xsymbols)
    90   Not  ("\<not> _" [40] 40) and
    91   "op &"  (infixr "\<and>" 35) and
    92   "op |"  (infixr "\<or>" 30) and
    93   "op -->"  (infixr "\<longrightarrow>" 25) and
    94   not_equal  (infix "\<noteq>" 50)
    95 
    96 notation (HTML output)
    97   Not  ("\<not> _" [40] 40) and
    98   "op &"  (infixr "\<and>" 35) and
    99   "op |"  (infixr "\<or>" 30) and
   100   not_equal  (infix "\<noteq>" 50)
   101 
   102 abbreviation (iff)
   103   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   104   "A <-> B == A = B"
   105 
   106 notation (xsymbols)
   107   iff  (infixr "\<longleftrightarrow>" 25)
   108 
   109 
   110 nonterminals
   111   letbinds  letbind
   112   case_syn  cases_syn
   113 
   114 syntax
   115   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   116 
   117   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   118   ""            :: "letbind => letbinds"                 ("_")
   119   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   120   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   121 
   122   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   123   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   124   ""            :: "case_syn => cases_syn"               ("_")
   125   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   126 
   127 translations
   128   "THE x. P"              == "The (%x. P)"
   129   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   130   "let x = a in e"        == "Let a (%x. e)"
   131 
   132 print_translation {*
   133 (* To avoid eta-contraction of body: *)
   134 [("The", fn [Abs abs] =>
   135      let val (x,t) = atomic_abs_tr' abs
   136      in Syntax.const "_The" $ x $ t end)]
   137 *}
   138 
   139 syntax (xsymbols)
   140   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   141 
   142 notation (xsymbols)
   143   All  (binder "\<forall>" 10) and
   144   Ex  (binder "\<exists>" 10) and
   145   Ex1  (binder "\<exists>!" 10)
   146 
   147 notation (HTML output)
   148   All  (binder "\<forall>" 10) and
   149   Ex  (binder "\<exists>" 10) and
   150   Ex1  (binder "\<exists>!" 10)
   151 
   152 notation (HOL)
   153   All  (binder "! " 10) and
   154   Ex  (binder "? " 10) and
   155   Ex1  (binder "?! " 10)
   156 
   157 
   158 subsubsection {* Axioms and basic definitions *}
   159 
   160 axioms
   161   eq_reflection:  "(x=y) ==> (x==y)"
   162 
   163   refl:           "t = (t::'a)"
   164 
   165   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   166     -- {*Extensionality is built into the meta-logic, and this rule expresses
   167          a related property.  It is an eta-expanded version of the traditional
   168          rule, and similar to the ABS rule of HOL*}
   169 
   170   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   171 
   172   impI:           "(P ==> Q) ==> P-->Q"
   173   mp:             "[| P-->Q;  P |] ==> Q"
   174 
   175 
   176 defs
   177   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   178   All_def:      "All(P)    == (P = (%x. True))"
   179   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   180   False_def:    "False     == (!P. P)"
   181   not_def:      "~ P       == P-->False"
   182   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   183   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   184   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   185 
   186 axioms
   187   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   188   True_or_False:  "(P=True) | (P=False)"
   189 
   190 defs
   191   Let_def:      "Let s f == f(s)"
   192   if_def:       "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   193 
   194 finalconsts
   195   "op ="
   196   "op -->"
   197   The
   198   arbitrary
   199 
   200 axiomatization
   201   undefined :: 'a
   202 
   203 axiomatization where
   204   undefined_fun: "undefined x = undefined"
   205 
   206 
   207 subsubsection {* Generic classes and algebraic operations *}
   208 
   209 class default = type +
   210   fixes default :: 'a
   211 
   212 class zero = type + 
   213   fixes zero :: 'a  ("0")
   214 
   215 class one = type +
   216   fixes one  :: 'a  ("1")
   217 
   218 hide (open) const zero one
   219 
   220 class plus = type +
   221   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
   222 
   223 class minus = type +
   224   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
   225 
   226 class uminus = type +
   227   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
   228 
   229 class times = type +
   230   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
   231 
   232 class inverse = type +
   233   fixes inverse :: "'a \<Rightarrow> 'a"
   234     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
   235 
   236 class abs = type +
   237   fixes abs :: "'a \<Rightarrow> 'a"
   238 begin
   239 
   240 notation (xsymbols)
   241   abs  ("\<bar>_\<bar>")
   242 
   243 notation (HTML output)
   244   abs  ("\<bar>_\<bar>")
   245 
   246 end
   247 
   248 class sgn = type +
   249   fixes sgn :: "'a \<Rightarrow> 'a"
   250 
   251 class ord = type +
   252   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   253     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   254 begin
   255 
   256 notation
   257   less_eq  ("op <=") and
   258   less_eq  ("(_/ <= _)" [51, 51] 50) and
   259   less  ("op <") and
   260   less  ("(_/ < _)"  [51, 51] 50)
   261   
   262 notation (xsymbols)
   263   less_eq  ("op \<le>") and
   264   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   265 
   266 notation (HTML output)
   267   less_eq  ("op \<le>") and
   268   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
   269 
   270 abbreviation (input)
   271   greater_eq  (infix ">=" 50) where
   272   "x >= y \<equiv> y <= x"
   273 
   274 notation (input)
   275   greater_eq  (infix "\<ge>" 50)
   276 
   277 abbreviation (input)
   278   greater  (infix ">" 50) where
   279   "x > y \<equiv> y < x"
   280 
   281 definition
   282   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   283   "Least P == (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> less_eq x y))"
   284 
   285 end
   286 
   287 syntax
   288   "_index1"  :: index    ("\<^sub>1")
   289 translations
   290   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
   291 
   292 typed_print_translation {*
   293 let
   294   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
   295     if T = dummyT orelse not (! show_types) andalso can Term.dest_Type T then raise Match
   296     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
   297 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
   298 *} -- {* show types that are presumably too general *}
   299 
   300 
   301 subsection {* Fundamental rules *}
   302 
   303 subsubsection {* Equality *}
   304 
   305 text {* Thanks to Stephan Merz *}
   306 lemma subst:
   307   assumes eq: "s = t" and p: "P s"
   308   shows "P t"
   309 proof -
   310   from eq have meta: "s \<equiv> t"
   311     by (rule eq_reflection)
   312   from p show ?thesis
   313     by (unfold meta)
   314 qed
   315 
   316 lemma sym: "s = t ==> t = s"
   317   by (erule subst) (rule refl)
   318 
   319 lemma ssubst: "t = s ==> P s ==> P t"
   320   by (drule sym) (erule subst)
   321 
   322 lemma trans: "[| r=s; s=t |] ==> r=t"
   323   by (erule subst)
   324 
   325 lemma meta_eq_to_obj_eq: 
   326   assumes meq: "A == B"
   327   shows "A = B"
   328   by (unfold meq) (rule refl)
   329 
   330 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   331      (* a = b
   332         |   |
   333         c = d   *)
   334 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   335 apply (rule trans)
   336 apply (rule trans)
   337 apply (rule sym)
   338 apply assumption+
   339 done
   340 
   341 text {* For calculational reasoning: *}
   342 
   343 lemma forw_subst: "a = b ==> P b ==> P a"
   344   by (rule ssubst)
   345 
   346 lemma back_subst: "P a ==> a = b ==> P b"
   347   by (rule subst)
   348 
   349 
   350 subsubsection {*Congruence rules for application*}
   351 
   352 (*similar to AP_THM in Gordon's HOL*)
   353 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   354 apply (erule subst)
   355 apply (rule refl)
   356 done
   357 
   358 (*similar to AP_TERM in Gordon's HOL and FOL's subst_context*)
   359 lemma arg_cong: "x=y ==> f(x)=f(y)"
   360 apply (erule subst)
   361 apply (rule refl)
   362 done
   363 
   364 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   365 apply (erule ssubst)+
   366 apply (rule refl)
   367 done
   368 
   369 lemma cong: "[| f = g; (x::'a) = y |] ==> f(x) = g(y)"
   370 apply (erule subst)+
   371 apply (rule refl)
   372 done
   373 
   374 
   375 subsubsection {*Equality of booleans -- iff*}
   376 
   377 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   378   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   379 
   380 lemma iffD2: "[| P=Q; Q |] ==> P"
   381   by (erule ssubst)
   382 
   383 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   384   by (erule iffD2)
   385 
   386 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   387   by (drule sym) (rule iffD2)
   388 
   389 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   390   by (drule sym) (rule rev_iffD2)
   391 
   392 lemma iffE:
   393   assumes major: "P=Q"
   394     and minor: "[| P --> Q; Q --> P |] ==> R"
   395   shows R
   396   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   397 
   398 
   399 subsubsection {*True*}
   400 
   401 lemma TrueI: "True"
   402   unfolding True_def by (rule refl)
   403 
   404 lemma eqTrueI: "P ==> P = True"
   405   by (iprover intro: iffI TrueI)
   406 
   407 lemma eqTrueE: "P = True ==> P"
   408   by (erule iffD2) (rule TrueI)
   409 
   410 
   411 subsubsection {*Universal quantifier*}
   412 
   413 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   414   unfolding All_def by (iprover intro: ext eqTrueI assms)
   415 
   416 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   417 apply (unfold All_def)
   418 apply (rule eqTrueE)
   419 apply (erule fun_cong)
   420 done
   421 
   422 lemma allE:
   423   assumes major: "ALL x. P(x)"
   424     and minor: "P(x) ==> R"
   425   shows R
   426   by (iprover intro: minor major [THEN spec])
   427 
   428 lemma all_dupE:
   429   assumes major: "ALL x. P(x)"
   430     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   431   shows R
   432   by (iprover intro: minor major major [THEN spec])
   433 
   434 
   435 subsubsection {* False *}
   436 
   437 text {*
   438   Depends upon @{text spec}; it is impossible to do propositional
   439   logic before quantifiers!
   440 *}
   441 
   442 lemma FalseE: "False ==> P"
   443   apply (unfold False_def)
   444   apply (erule spec)
   445   done
   446 
   447 lemma False_neq_True: "False = True ==> P"
   448   by (erule eqTrueE [THEN FalseE])
   449 
   450 
   451 subsubsection {* Negation *}
   452 
   453 lemma notI:
   454   assumes "P ==> False"
   455   shows "~P"
   456   apply (unfold not_def)
   457   apply (iprover intro: impI assms)
   458   done
   459 
   460 lemma False_not_True: "False ~= True"
   461   apply (rule notI)
   462   apply (erule False_neq_True)
   463   done
   464 
   465 lemma True_not_False: "True ~= False"
   466   apply (rule notI)
   467   apply (drule sym)
   468   apply (erule False_neq_True)
   469   done
   470 
   471 lemma notE: "[| ~P;  P |] ==> R"
   472   apply (unfold not_def)
   473   apply (erule mp [THEN FalseE])
   474   apply assumption
   475   done
   476 
   477 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   478   by (erule notE [THEN notI]) (erule meta_mp)
   479 
   480 
   481 subsubsection {*Implication*}
   482 
   483 lemma impE:
   484   assumes "P-->Q" "P" "Q ==> R"
   485   shows "R"
   486 by (iprover intro: assms mp)
   487 
   488 (* Reduces Q to P-->Q, allowing substitution in P. *)
   489 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   490 by (iprover intro: mp)
   491 
   492 lemma contrapos_nn:
   493   assumes major: "~Q"
   494       and minor: "P==>Q"
   495   shows "~P"
   496 by (iprover intro: notI minor major [THEN notE])
   497 
   498 (*not used at all, but we already have the other 3 combinations *)
   499 lemma contrapos_pn:
   500   assumes major: "Q"
   501       and minor: "P ==> ~Q"
   502   shows "~P"
   503 by (iprover intro: notI minor major notE)
   504 
   505 lemma not_sym: "t ~= s ==> s ~= t"
   506   by (erule contrapos_nn) (erule sym)
   507 
   508 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   509   by (erule subst, erule ssubst, assumption)
   510 
   511 (*still used in HOLCF*)
   512 lemma rev_contrapos:
   513   assumes pq: "P ==> Q"
   514       and nq: "~Q"
   515   shows "~P"
   516 apply (rule nq [THEN contrapos_nn])
   517 apply (erule pq)
   518 done
   519 
   520 subsubsection {*Existential quantifier*}
   521 
   522 lemma exI: "P x ==> EX x::'a. P x"
   523 apply (unfold Ex_def)
   524 apply (iprover intro: allI allE impI mp)
   525 done
   526 
   527 lemma exE:
   528   assumes major: "EX x::'a. P(x)"
   529       and minor: "!!x. P(x) ==> Q"
   530   shows "Q"
   531 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   532 apply (iprover intro: impI [THEN allI] minor)
   533 done
   534 
   535 
   536 subsubsection {*Conjunction*}
   537 
   538 lemma conjI: "[| P; Q |] ==> P&Q"
   539 apply (unfold and_def)
   540 apply (iprover intro: impI [THEN allI] mp)
   541 done
   542 
   543 lemma conjunct1: "[| P & Q |] ==> P"
   544 apply (unfold and_def)
   545 apply (iprover intro: impI dest: spec mp)
   546 done
   547 
   548 lemma conjunct2: "[| P & Q |] ==> Q"
   549 apply (unfold and_def)
   550 apply (iprover intro: impI dest: spec mp)
   551 done
   552 
   553 lemma conjE:
   554   assumes major: "P&Q"
   555       and minor: "[| P; Q |] ==> R"
   556   shows "R"
   557 apply (rule minor)
   558 apply (rule major [THEN conjunct1])
   559 apply (rule major [THEN conjunct2])
   560 done
   561 
   562 lemma context_conjI:
   563   assumes "P" "P ==> Q" shows "P & Q"
   564 by (iprover intro: conjI assms)
   565 
   566 
   567 subsubsection {*Disjunction*}
   568 
   569 lemma disjI1: "P ==> P|Q"
   570 apply (unfold or_def)
   571 apply (iprover intro: allI impI mp)
   572 done
   573 
   574 lemma disjI2: "Q ==> P|Q"
   575 apply (unfold or_def)
   576 apply (iprover intro: allI impI mp)
   577 done
   578 
   579 lemma disjE:
   580   assumes major: "P|Q"
   581       and minorP: "P ==> R"
   582       and minorQ: "Q ==> R"
   583   shows "R"
   584 by (iprover intro: minorP minorQ impI
   585                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   586 
   587 
   588 subsubsection {*Classical logic*}
   589 
   590 lemma classical:
   591   assumes prem: "~P ==> P"
   592   shows "P"
   593 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   594 apply assumption
   595 apply (rule notI [THEN prem, THEN eqTrueI])
   596 apply (erule subst)
   597 apply assumption
   598 done
   599 
   600 lemmas ccontr = FalseE [THEN classical, standard]
   601 
   602 (*notE with premises exchanged; it discharges ~R so that it can be used to
   603   make elimination rules*)
   604 lemma rev_notE:
   605   assumes premp: "P"
   606       and premnot: "~R ==> ~P"
   607   shows "R"
   608 apply (rule ccontr)
   609 apply (erule notE [OF premnot premp])
   610 done
   611 
   612 (*Double negation law*)
   613 lemma notnotD: "~~P ==> P"
   614 apply (rule classical)
   615 apply (erule notE)
   616 apply assumption
   617 done
   618 
   619 lemma contrapos_pp:
   620   assumes p1: "Q"
   621       and p2: "~P ==> ~Q"
   622   shows "P"
   623 by (iprover intro: classical p1 p2 notE)
   624 
   625 
   626 subsubsection {*Unique existence*}
   627 
   628 lemma ex1I:
   629   assumes "P a" "!!x. P(x) ==> x=a"
   630   shows "EX! x. P(x)"
   631 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   632 
   633 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   634 lemma ex_ex1I:
   635   assumes ex_prem: "EX x. P(x)"
   636       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   637   shows "EX! x. P(x)"
   638 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   639 
   640 lemma ex1E:
   641   assumes major: "EX! x. P(x)"
   642       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   643   shows "R"
   644 apply (rule major [unfolded Ex1_def, THEN exE])
   645 apply (erule conjE)
   646 apply (iprover intro: minor)
   647 done
   648 
   649 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   650 apply (erule ex1E)
   651 apply (rule exI)
   652 apply assumption
   653 done
   654 
   655 
   656 subsubsection {*THE: definite description operator*}
   657 
   658 lemma the_equality:
   659   assumes prema: "P a"
   660       and premx: "!!x. P x ==> x=a"
   661   shows "(THE x. P x) = a"
   662 apply (rule trans [OF _ the_eq_trivial])
   663 apply (rule_tac f = "The" in arg_cong)
   664 apply (rule ext)
   665 apply (rule iffI)
   666  apply (erule premx)
   667 apply (erule ssubst, rule prema)
   668 done
   669 
   670 lemma theI:
   671   assumes "P a" and "!!x. P x ==> x=a"
   672   shows "P (THE x. P x)"
   673 by (iprover intro: assms the_equality [THEN ssubst])
   674 
   675 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   676 apply (erule ex1E)
   677 apply (erule theI)
   678 apply (erule allE)
   679 apply (erule mp)
   680 apply assumption
   681 done
   682 
   683 (*Easier to apply than theI: only one occurrence of P*)
   684 lemma theI2:
   685   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   686   shows "Q (THE x. P x)"
   687 by (iprover intro: assms theI)
   688 
   689 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   690 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   691            elim:allE impE)
   692 
   693 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   694 apply (rule the_equality)
   695 apply  assumption
   696 apply (erule ex1E)
   697 apply (erule all_dupE)
   698 apply (drule mp)
   699 apply  assumption
   700 apply (erule ssubst)
   701 apply (erule allE)
   702 apply (erule mp)
   703 apply assumption
   704 done
   705 
   706 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   707 apply (rule the_equality)
   708 apply (rule refl)
   709 apply (erule sym)
   710 done
   711 
   712 
   713 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   714 
   715 lemma disjCI:
   716   assumes "~Q ==> P" shows "P|Q"
   717 apply (rule classical)
   718 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   719 done
   720 
   721 lemma excluded_middle: "~P | P"
   722 by (iprover intro: disjCI)
   723 
   724 text {*
   725   case distinction as a natural deduction rule.
   726   Note that @{term "~P"} is the second case, not the first
   727 *}
   728 lemma case_split_thm:
   729   assumes prem1: "P ==> Q"
   730       and prem2: "~P ==> Q"
   731   shows "Q"
   732 apply (rule excluded_middle [THEN disjE])
   733 apply (erule prem2)
   734 apply (erule prem1)
   735 done
   736 lemmas case_split = case_split_thm [case_names True False]
   737 
   738 (*Classical implies (-->) elimination. *)
   739 lemma impCE:
   740   assumes major: "P-->Q"
   741       and minor: "~P ==> R" "Q ==> R"
   742   shows "R"
   743 apply (rule excluded_middle [of P, THEN disjE])
   744 apply (iprover intro: minor major [THEN mp])+
   745 done
   746 
   747 (*This version of --> elimination works on Q before P.  It works best for
   748   those cases in which P holds "almost everywhere".  Can't install as
   749   default: would break old proofs.*)
   750 lemma impCE':
   751   assumes major: "P-->Q"
   752       and minor: "Q ==> R" "~P ==> R"
   753   shows "R"
   754 apply (rule excluded_middle [of P, THEN disjE])
   755 apply (iprover intro: minor major [THEN mp])+
   756 done
   757 
   758 (*Classical <-> elimination. *)
   759 lemma iffCE:
   760   assumes major: "P=Q"
   761       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   762   shows "R"
   763 apply (rule major [THEN iffE])
   764 apply (iprover intro: minor elim: impCE notE)
   765 done
   766 
   767 lemma exCI:
   768   assumes "ALL x. ~P(x) ==> P(a)"
   769   shows "EX x. P(x)"
   770 apply (rule ccontr)
   771 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   772 done
   773 
   774 
   775 subsubsection {* Intuitionistic Reasoning *}
   776 
   777 lemma impE':
   778   assumes 1: "P --> Q"
   779     and 2: "Q ==> R"
   780     and 3: "P --> Q ==> P"
   781   shows R
   782 proof -
   783   from 3 and 1 have P .
   784   with 1 have Q by (rule impE)
   785   with 2 show R .
   786 qed
   787 
   788 lemma allE':
   789   assumes 1: "ALL x. P x"
   790     and 2: "P x ==> ALL x. P x ==> Q"
   791   shows Q
   792 proof -
   793   from 1 have "P x" by (rule spec)
   794   from this and 1 show Q by (rule 2)
   795 qed
   796 
   797 lemma notE':
   798   assumes 1: "~ P"
   799     and 2: "~ P ==> P"
   800   shows R
   801 proof -
   802   from 2 and 1 have P .
   803   with 1 show R by (rule notE)
   804 qed
   805 
   806 lemma TrueE: "True ==> P ==> P" .
   807 lemma notFalseE: "~ False ==> P ==> P" .
   808 
   809 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   810   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   811   and [Pure.elim 2] = allE notE' impE'
   812   and [Pure.intro] = exI disjI2 disjI1
   813 
   814 lemmas [trans] = trans
   815   and [sym] = sym not_sym
   816   and [Pure.elim?] = iffD1 iffD2 impE
   817 
   818 use "hologic.ML"
   819 
   820 
   821 subsubsection {* Atomizing meta-level connectives *}
   822 
   823 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   824 proof
   825   assume "!!x. P x"
   826   then show "ALL x. P x" ..
   827 next
   828   assume "ALL x. P x"
   829   then show "!!x. P x" by (rule allE)
   830 qed
   831 
   832 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   833 proof
   834   assume r: "A ==> B"
   835   show "A --> B" by (rule impI) (rule r)
   836 next
   837   assume "A --> B" and A
   838   then show B by (rule mp)
   839 qed
   840 
   841 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   842 proof
   843   assume r: "A ==> False"
   844   show "~A" by (rule notI) (rule r)
   845 next
   846   assume "~A" and A
   847   then show False by (rule notE)
   848 qed
   849 
   850 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   851 proof
   852   assume "x == y"
   853   show "x = y" by (unfold `x == y`) (rule refl)
   854 next
   855   assume "x = y"
   856   then show "x == y" by (rule eq_reflection)
   857 qed
   858 
   859 lemma atomize_conj [atomize]:
   860   includes meta_conjunction_syntax
   861   shows "(A && B) == Trueprop (A & B)"
   862 proof
   863   assume conj: "A && B"
   864   show "A & B"
   865   proof (rule conjI)
   866     from conj show A by (rule conjunctionD1)
   867     from conj show B by (rule conjunctionD2)
   868   qed
   869 next
   870   assume conj: "A & B"
   871   show "A && B"
   872   proof -
   873     from conj show A ..
   874     from conj show B ..
   875   qed
   876 qed
   877 
   878 lemmas [symmetric, rulify] = atomize_all atomize_imp
   879   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   880 
   881 
   882 subsection {* Package setup *}
   883 
   884 subsubsection {* Classical Reasoner setup *}
   885 
   886 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   887   by (rule classical) iprover
   888 
   889 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   890   by (rule classical) iprover
   891 
   892 lemma thin_refl:
   893   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   894 
   895 ML {*
   896 structure Hypsubst = HypsubstFun(
   897 struct
   898   structure Simplifier = Simplifier
   899   val dest_eq = HOLogic.dest_eq
   900   val dest_Trueprop = HOLogic.dest_Trueprop
   901   val dest_imp = HOLogic.dest_imp
   902   val eq_reflection = @{thm eq_reflection}
   903   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   904   val imp_intr = @{thm impI}
   905   val rev_mp = @{thm rev_mp}
   906   val subst = @{thm subst}
   907   val sym = @{thm sym}
   908   val thin_refl = @{thm thin_refl};
   909 end);
   910 open Hypsubst;
   911 
   912 structure Classical = ClassicalFun(
   913 struct
   914   val imp_elim = @{thm imp_elim}
   915   val not_elim = @{thm notE}
   916   val swap = @{thm swap}
   917   val classical = @{thm classical}
   918   val sizef = Drule.size_of_thm
   919   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   920 end);
   921 
   922 structure BasicClassical: BASIC_CLASSICAL = Classical; 
   923 open BasicClassical;
   924 
   925 ML_Context.value_antiq "claset"
   926   (Scan.succeed ("claset", "Classical.local_claset_of (ML_Context.the_local_context ())"));
   927 
   928 structure ResAtpset = NamedThmsFun(val name = "atp" val description = "ATP rules");
   929 
   930 structure ResBlacklist = NamedThmsFun(val name = "noatp" val description = "Theorems blacklisted for ATP");
   931 *}
   932 
   933 text {*ResBlacklist holds theorems blacklisted to sledgehammer. 
   934   These theorems typically produce clauses that are prolific (match too many equality or
   935   membership literals) and relate to seldom-used facts. Some duplicate other rules.*}
   936 
   937 setup {*
   938 let
   939   (*prevent substitution on bool*)
   940   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   941     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   942       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   943 in
   944   Hypsubst.hypsubst_setup
   945   #> ContextRules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   946   #> Classical.setup
   947   #> ResAtpset.setup
   948   #> ResBlacklist.setup
   949 end
   950 *}
   951 
   952 declare iffI [intro!]
   953   and notI [intro!]
   954   and impI [intro!]
   955   and disjCI [intro!]
   956   and conjI [intro!]
   957   and TrueI [intro!]
   958   and refl [intro!]
   959 
   960 declare iffCE [elim!]
   961   and FalseE [elim!]
   962   and impCE [elim!]
   963   and disjE [elim!]
   964   and conjE [elim!]
   965   and conjE [elim!]
   966 
   967 declare ex_ex1I [intro!]
   968   and allI [intro!]
   969   and the_equality [intro]
   970   and exI [intro]
   971 
   972 declare exE [elim!]
   973   allE [elim]
   974 
   975 ML {* val HOL_cs = @{claset} *}
   976 
   977 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   978   apply (erule swap)
   979   apply (erule (1) meta_mp)
   980   done
   981 
   982 declare ex_ex1I [rule del, intro! 2]
   983   and ex1I [intro]
   984 
   985 lemmas [intro?] = ext
   986   and [elim?] = ex1_implies_ex
   987 
   988 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   989 lemma alt_ex1E [elim!]:
   990   assumes major: "\<exists>!x. P x"
   991       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   992   shows R
   993 apply (rule ex1E [OF major])
   994 apply (rule prem)
   995 apply (tactic {* ares_tac @{thms allI} 1 *})+
   996 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   997 apply iprover
   998 done
   999 
  1000 ML {*
  1001 structure Blast = BlastFun
  1002 (
  1003   type claset = Classical.claset
  1004   val equality_name = @{const_name "op ="}
  1005   val not_name = @{const_name Not}
  1006   val notE = @{thm notE}
  1007   val ccontr = @{thm ccontr}
  1008   val contr_tac = Classical.contr_tac
  1009   val dup_intr = Classical.dup_intr
  1010   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
  1011   val claset = Classical.claset
  1012   val rep_cs = Classical.rep_cs
  1013   val cla_modifiers = Classical.cla_modifiers
  1014   val cla_meth' = Classical.cla_meth'
  1015 );
  1016 val Blast_tac = Blast.Blast_tac;
  1017 val blast_tac = Blast.blast_tac;
  1018 *}
  1019 
  1020 setup Blast.setup
  1021 
  1022 
  1023 subsubsection {* Simplifier *}
  1024 
  1025 lemma eta_contract_eq: "(%s. f s) = f" ..
  1026 
  1027 lemma simp_thms:
  1028   shows not_not: "(~ ~ P) = P"
  1029   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
  1030   and
  1031     "(P ~= Q) = (P = (~Q))"
  1032     "(P | ~P) = True"    "(~P | P) = True"
  1033     "(x = x) = True"
  1034   and not_True_eq_False: "(\<not> True) = False"
  1035   and not_False_eq_True: "(\<not> False) = True"
  1036   and
  1037     "(~P) ~= P"  "P ~= (~P)"
  1038     "(True=P) = P"
  1039   and eq_True: "(P = True) = P"
  1040   and "(False=P) = (~P)"
  1041   and eq_False: "(P = False) = (\<not> P)"
  1042   and
  1043     "(True --> P) = P"  "(False --> P) = True"
  1044     "(P --> True) = True"  "(P --> P) = True"
  1045     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
  1046     "(P & True) = P"  "(True & P) = P"
  1047     "(P & False) = False"  "(False & P) = False"
  1048     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
  1049     "(P & ~P) = False"    "(~P & P) = False"
  1050     "(P | True) = True"  "(True | P) = True"
  1051     "(P | False) = P"  "(False | P) = P"
  1052     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
  1053     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
  1054     -- {* needed for the one-point-rule quantifier simplification procs *}
  1055     -- {* essential for termination!! *} and
  1056     "!!P. (EX x. x=t & P(x)) = P(t)"
  1057     "!!P. (EX x. t=x & P(x)) = P(t)"
  1058     "!!P. (ALL x. x=t --> P(x)) = P(t)"
  1059     "!!P. (ALL x. t=x --> P(x)) = P(t)"
  1060   by (blast, blast, blast, blast, blast, iprover+)
  1061 
  1062 lemma disj_absorb: "(A | A) = A"
  1063   by blast
  1064 
  1065 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
  1066   by blast
  1067 
  1068 lemma conj_absorb: "(A & A) = A"
  1069   by blast
  1070 
  1071 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
  1072   by blast
  1073 
  1074 lemma eq_ac:
  1075   shows eq_commute: "(a=b) = (b=a)"
  1076     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
  1077     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
  1078 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
  1079 
  1080 lemma conj_comms:
  1081   shows conj_commute: "(P&Q) = (Q&P)"
  1082     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
  1083 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
  1084 
  1085 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
  1086 
  1087 lemma disj_comms:
  1088   shows disj_commute: "(P|Q) = (Q|P)"
  1089     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
  1090 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
  1091 
  1092 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
  1093 
  1094 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1095 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1096 
  1097 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1098 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1099 
  1100 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1101 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1102 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1103 
  1104 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1105 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1106 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1107 
  1108 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1109 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1110 
  1111 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1112   by iprover
  1113 
  1114 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1115 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1116 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1117 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1118 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1119 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1120   by blast
  1121 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1122 
  1123 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1124 
  1125 
  1126 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1127   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1128   -- {* cases boil down to the same thing. *}
  1129   by blast
  1130 
  1131 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1132 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1133 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1134 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1135 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1136 
  1137 declare All_def [noatp]
  1138 
  1139 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1140 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1141 
  1142 text {*
  1143   \medskip The @{text "&"} congruence rule: not included by default!
  1144   May slow rewrite proofs down by as much as 50\% *}
  1145 
  1146 lemma conj_cong:
  1147     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1148   by iprover
  1149 
  1150 lemma rev_conj_cong:
  1151     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1152   by iprover
  1153 
  1154 text {* The @{text "|"} congruence rule: not included by default! *}
  1155 
  1156 lemma disj_cong:
  1157     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1158   by blast
  1159 
  1160 
  1161 text {* \medskip if-then-else rules *}
  1162 
  1163 lemma if_True: "(if True then x else y) = x"
  1164   by (unfold if_def) blast
  1165 
  1166 lemma if_False: "(if False then x else y) = y"
  1167   by (unfold if_def) blast
  1168 
  1169 lemma if_P: "P ==> (if P then x else y) = x"
  1170   by (unfold if_def) blast
  1171 
  1172 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1173   by (unfold if_def) blast
  1174 
  1175 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1176   apply (rule case_split [of Q])
  1177    apply (simplesubst if_P)
  1178     prefer 3 apply (simplesubst if_not_P, blast+)
  1179   done
  1180 
  1181 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1182 by (simplesubst split_if, blast)
  1183 
  1184 lemmas if_splits [noatp] = split_if split_if_asm
  1185 
  1186 lemma if_cancel: "(if c then x else x) = x"
  1187 by (simplesubst split_if, blast)
  1188 
  1189 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1190 by (simplesubst split_if, blast)
  1191 
  1192 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1193   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1194   by (rule split_if)
  1195 
  1196 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1197   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1198   apply (simplesubst split_if, blast)
  1199   done
  1200 
  1201 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1202 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1203 
  1204 text {* \medskip let rules for simproc *}
  1205 
  1206 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1207   by (unfold Let_def)
  1208 
  1209 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1210   by (unfold Let_def)
  1211 
  1212 text {*
  1213   The following copy of the implication operator is useful for
  1214   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1215   its premise.
  1216 *}
  1217 
  1218 constdefs
  1219   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1220   [code func del]: "simp_implies \<equiv> op ==>"
  1221 
  1222 lemma simp_impliesI:
  1223   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1224   shows "PROP P =simp=> PROP Q"
  1225   apply (unfold simp_implies_def)
  1226   apply (rule PQ)
  1227   apply assumption
  1228   done
  1229 
  1230 lemma simp_impliesE:
  1231   assumes PQ: "PROP P =simp=> PROP Q"
  1232   and P: "PROP P"
  1233   and QR: "PROP Q \<Longrightarrow> PROP R"
  1234   shows "PROP R"
  1235   apply (rule QR)
  1236   apply (rule PQ [unfolded simp_implies_def])
  1237   apply (rule P)
  1238   done
  1239 
  1240 lemma simp_implies_cong:
  1241   assumes PP' :"PROP P == PROP P'"
  1242   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1243   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1244 proof (unfold simp_implies_def, rule equal_intr_rule)
  1245   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1246   and P': "PROP P'"
  1247   from PP' [symmetric] and P' have "PROP P"
  1248     by (rule equal_elim_rule1)
  1249   then have "PROP Q" by (rule PQ)
  1250   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1251 next
  1252   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1253   and P: "PROP P"
  1254   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1255   then have "PROP Q'" by (rule P'Q')
  1256   with P'QQ' [OF P', symmetric] show "PROP Q"
  1257     by (rule equal_elim_rule1)
  1258 qed
  1259 
  1260 lemma uncurry:
  1261   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1262   shows "P \<and> Q \<longrightarrow> R"
  1263   using assms by blast
  1264 
  1265 lemma iff_allI:
  1266   assumes "\<And>x. P x = Q x"
  1267   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1268   using assms by blast
  1269 
  1270 lemma iff_exI:
  1271   assumes "\<And>x. P x = Q x"
  1272   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1273   using assms by blast
  1274 
  1275 lemma all_comm:
  1276   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1277   by blast
  1278 
  1279 lemma ex_comm:
  1280   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1281   by blast
  1282 
  1283 use "simpdata.ML"
  1284 ML {* open Simpdata *}
  1285 
  1286 setup {*
  1287   Simplifier.method_setup Splitter.split_modifiers
  1288   #> (fn thy => (change_simpset_of thy (fn _ => Simpdata.simpset_simprocs); thy))
  1289   #> Splitter.setup
  1290   #> Clasimp.setup
  1291   #> EqSubst.setup
  1292 *}
  1293 
  1294 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1295 
  1296 simproc_setup neq ("x = y") = {* fn _ =>
  1297 let
  1298   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1299   fun is_neq eq lhs rhs thm =
  1300     (case Thm.prop_of thm of
  1301       _ $ (Not $ (eq' $ l' $ r')) =>
  1302         Not = HOLogic.Not andalso eq' = eq andalso
  1303         r' aconv lhs andalso l' aconv rhs
  1304     | _ => false);
  1305   fun proc ss ct =
  1306     (case Thm.term_of ct of
  1307       eq $ lhs $ rhs =>
  1308         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1309           SOME thm => SOME (thm RS neq_to_EQ_False)
  1310         | NONE => NONE)
  1311      | _ => NONE);
  1312 in proc end;
  1313 *}
  1314 
  1315 simproc_setup let_simp ("Let x f") = {*
  1316 let
  1317   val (f_Let_unfold, x_Let_unfold) =
  1318     let val [(_$(f$x)$_)] = prems_of @{thm Let_unfold}
  1319     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1320   val (f_Let_folded, x_Let_folded) =
  1321     let val [(_$(f$x)$_)] = prems_of @{thm Let_folded}
  1322     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1323   val g_Let_folded =
  1324     let val [(_$_$(g$_))] = prems_of @{thm Let_folded} in cterm_of @{theory} g end;
  1325 
  1326   fun proc _ ss ct =
  1327     let
  1328       val ctxt = Simplifier.the_context ss;
  1329       val thy = ProofContext.theory_of ctxt;
  1330       val t = Thm.term_of ct;
  1331       val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1332     in Option.map (hd o Variable.export ctxt' ctxt o single)
  1333       (case t' of Const ("Let",_) $ x $ f => (* x and f are already in normal form *)
  1334         if is_Free x orelse is_Bound x orelse is_Const x
  1335         then SOME @{thm Let_def}
  1336         else
  1337           let
  1338             val n = case f of (Abs (x,_,_)) => x | _ => "x";
  1339             val cx = cterm_of thy x;
  1340             val {T=xT,...} = rep_cterm cx;
  1341             val cf = cterm_of thy f;
  1342             val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1343             val (_$_$g) = prop_of fx_g;
  1344             val g' = abstract_over (x,g);
  1345           in (if (g aconv g')
  1346                then
  1347                   let
  1348                     val rl =
  1349                       cterm_instantiate [(f_Let_unfold,cf),(x_Let_unfold,cx)] @{thm Let_unfold};
  1350                   in SOME (rl OF [fx_g]) end
  1351                else if Term.betapply (f,x) aconv g then NONE (*avoid identity conversion*)
  1352                else let
  1353                      val abs_g'= Abs (n,xT,g');
  1354                      val g'x = abs_g'$x;
  1355                      val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1356                      val rl = cterm_instantiate
  1357                                [(f_Let_folded,cterm_of thy f),(x_Let_folded,cx),
  1358                                 (g_Let_folded,cterm_of thy abs_g')]
  1359                                @{thm Let_folded};
  1360                    in SOME (rl OF [transitive fx_g g_g'x])
  1361                    end)
  1362           end
  1363       | _ => NONE)
  1364     end
  1365 in proc end *}
  1366 
  1367 
  1368 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1369 proof
  1370   assume "True \<Longrightarrow> PROP P"
  1371   from this [OF TrueI] show "PROP P" .
  1372 next
  1373   assume "PROP P"
  1374   then show "PROP P" .
  1375 qed
  1376 
  1377 lemma ex_simps:
  1378   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1379   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1380   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1381   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1382   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1383   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1384   -- {* Miniscoping: pushing in existential quantifiers. *}
  1385   by (iprover | blast)+
  1386 
  1387 lemma all_simps:
  1388   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1389   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1390   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1391   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1392   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1393   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1394   -- {* Miniscoping: pushing in universal quantifiers. *}
  1395   by (iprover | blast)+
  1396 
  1397 lemmas [simp] =
  1398   triv_forall_equality (*prunes params*)
  1399   True_implies_equals  (*prune asms `True'*)
  1400   if_True
  1401   if_False
  1402   if_cancel
  1403   if_eq_cancel
  1404   imp_disjL
  1405   (*In general it seems wrong to add distributive laws by default: they
  1406     might cause exponential blow-up.  But imp_disjL has been in for a while
  1407     and cannot be removed without affecting existing proofs.  Moreover,
  1408     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1409     grounds that it allows simplification of R in the two cases.*)
  1410   conj_assoc
  1411   disj_assoc
  1412   de_Morgan_conj
  1413   de_Morgan_disj
  1414   imp_disj1
  1415   imp_disj2
  1416   not_imp
  1417   disj_not1
  1418   not_all
  1419   not_ex
  1420   cases_simp
  1421   the_eq_trivial
  1422   the_sym_eq_trivial
  1423   ex_simps
  1424   all_simps
  1425   simp_thms
  1426 
  1427 lemmas [cong] = imp_cong simp_implies_cong
  1428 lemmas [split] = split_if
  1429 
  1430 ML {* val HOL_ss = @{simpset} *}
  1431 
  1432 text {* Simplifies x assuming c and y assuming ~c *}
  1433 lemma if_cong:
  1434   assumes "b = c"
  1435       and "c \<Longrightarrow> x = u"
  1436       and "\<not> c \<Longrightarrow> y = v"
  1437   shows "(if b then x else y) = (if c then u else v)"
  1438   unfolding if_def using assms by simp
  1439 
  1440 text {* Prevents simplification of x and y:
  1441   faster and allows the execution of functional programs. *}
  1442 lemma if_weak_cong [cong]:
  1443   assumes "b = c"
  1444   shows "(if b then x else y) = (if c then x else y)"
  1445   using assms by (rule arg_cong)
  1446 
  1447 text {* Prevents simplification of t: much faster *}
  1448 lemma let_weak_cong:
  1449   assumes "a = b"
  1450   shows "(let x = a in t x) = (let x = b in t x)"
  1451   using assms by (rule arg_cong)
  1452 
  1453 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1454 lemma eq_cong2:
  1455   assumes "u = u'"
  1456   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1457   using assms by simp
  1458 
  1459 lemma if_distrib:
  1460   "f (if c then x else y) = (if c then f x else f y)"
  1461   by simp
  1462 
  1463 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1464   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1465 lemma restrict_to_left:
  1466   assumes "x = y"
  1467   shows "(x = z) = (y = z)"
  1468   using assms by simp
  1469 
  1470 
  1471 subsubsection {* Generic cases and induction *}
  1472 
  1473 text {* Rule projections: *}
  1474 
  1475 ML {*
  1476 structure ProjectRule = ProjectRuleFun
  1477 (
  1478   val conjunct1 = @{thm conjunct1};
  1479   val conjunct2 = @{thm conjunct2};
  1480   val mp = @{thm mp};
  1481 )
  1482 *}
  1483 
  1484 constdefs
  1485   induct_forall where "induct_forall P == \<forall>x. P x"
  1486   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1487   induct_equal where "induct_equal x y == x = y"
  1488   induct_conj where "induct_conj A B == A \<and> B"
  1489 
  1490 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1491   by (unfold atomize_all induct_forall_def)
  1492 
  1493 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1494   by (unfold atomize_imp induct_implies_def)
  1495 
  1496 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1497   by (unfold atomize_eq induct_equal_def)
  1498 
  1499 lemma induct_conj_eq:
  1500   includes meta_conjunction_syntax
  1501   shows "(A && B) == Trueprop (induct_conj A B)"
  1502   by (unfold atomize_conj induct_conj_def)
  1503 
  1504 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1505 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1506 lemmas induct_rulify_fallback =
  1507   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1508 
  1509 
  1510 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1511     induct_conj (induct_forall A) (induct_forall B)"
  1512   by (unfold induct_forall_def induct_conj_def) iprover
  1513 
  1514 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1515     induct_conj (induct_implies C A) (induct_implies C B)"
  1516   by (unfold induct_implies_def induct_conj_def) iprover
  1517 
  1518 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1519 proof
  1520   assume r: "induct_conj A B ==> PROP C" and A B
  1521   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1522 next
  1523   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1524   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1525 qed
  1526 
  1527 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1528 
  1529 hide const induct_forall induct_implies induct_equal induct_conj
  1530 
  1531 text {* Method setup. *}
  1532 
  1533 ML {*
  1534   structure Induct = InductFun
  1535   (
  1536     val cases_default = @{thm case_split}
  1537     val atomize = @{thms induct_atomize}
  1538     val rulify = @{thms induct_rulify}
  1539     val rulify_fallback = @{thms induct_rulify_fallback}
  1540   );
  1541 *}
  1542 
  1543 setup Induct.setup
  1544 
  1545 
  1546 subsection {* Other simple lemmas and lemma duplicates *}
  1547 
  1548 lemma Let_0 [simp]: "Let 0 f = f 0"
  1549   unfolding Let_def ..
  1550 
  1551 lemma Let_1 [simp]: "Let 1 f = f 1"
  1552   unfolding Let_def ..
  1553 
  1554 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1555   by blast+
  1556 
  1557 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1558   apply (rule iffI)
  1559   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1560   apply (fast dest!: theI')
  1561   apply (fast intro: ext the1_equality [symmetric])
  1562   apply (erule ex1E)
  1563   apply (rule allI)
  1564   apply (rule ex1I)
  1565   apply (erule spec)
  1566   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1567   apply (erule impE)
  1568   apply (rule allI)
  1569   apply (rule_tac P = "xa = x" in case_split_thm)
  1570   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1571   done
  1572 
  1573 lemma mk_left_commute:
  1574   fixes f (infix "\<otimes>" 60)
  1575   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1576           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1577   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1578   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1579 
  1580 lemmas eq_sym_conv = eq_commute
  1581 
  1582 lemma nnf_simps:
  1583   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1584   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1585   "(\<not> \<not>(P)) = P"
  1586 by blast+
  1587 
  1588 
  1589 subsection {* Basic ML bindings *}
  1590 
  1591 ML {*
  1592 val FalseE = @{thm FalseE}
  1593 val Let_def = @{thm Let_def}
  1594 val TrueI = @{thm TrueI}
  1595 val allE = @{thm allE}
  1596 val allI = @{thm allI}
  1597 val all_dupE = @{thm all_dupE}
  1598 val arg_cong = @{thm arg_cong}
  1599 val box_equals = @{thm box_equals}
  1600 val ccontr = @{thm ccontr}
  1601 val classical = @{thm classical}
  1602 val conjE = @{thm conjE}
  1603 val conjI = @{thm conjI}
  1604 val conjunct1 = @{thm conjunct1}
  1605 val conjunct2 = @{thm conjunct2}
  1606 val disjCI = @{thm disjCI}
  1607 val disjE = @{thm disjE}
  1608 val disjI1 = @{thm disjI1}
  1609 val disjI2 = @{thm disjI2}
  1610 val eq_reflection = @{thm eq_reflection}
  1611 val ex1E = @{thm ex1E}
  1612 val ex1I = @{thm ex1I}
  1613 val ex1_implies_ex = @{thm ex1_implies_ex}
  1614 val exE = @{thm exE}
  1615 val exI = @{thm exI}
  1616 val excluded_middle = @{thm excluded_middle}
  1617 val ext = @{thm ext}
  1618 val fun_cong = @{thm fun_cong}
  1619 val iffD1 = @{thm iffD1}
  1620 val iffD2 = @{thm iffD2}
  1621 val iffI = @{thm iffI}
  1622 val impE = @{thm impE}
  1623 val impI = @{thm impI}
  1624 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1625 val mp = @{thm mp}
  1626 val notE = @{thm notE}
  1627 val notI = @{thm notI}
  1628 val not_all = @{thm not_all}
  1629 val not_ex = @{thm not_ex}
  1630 val not_iff = @{thm not_iff}
  1631 val not_not = @{thm not_not}
  1632 val not_sym = @{thm not_sym}
  1633 val refl = @{thm refl}
  1634 val rev_mp = @{thm rev_mp}
  1635 val spec = @{thm spec}
  1636 val ssubst = @{thm ssubst}
  1637 val subst = @{thm subst}
  1638 val sym = @{thm sym}
  1639 val trans = @{thm trans}
  1640 *}
  1641 
  1642 
  1643 subsection {* Code generator basic setup -- see further @{text Code_Setup.thy} *}
  1644 
  1645 setup "CodeName.setup #> CodeTarget.setup #> Nbe.setup"
  1646 
  1647 class eq (attach "op =") = type
  1648 
  1649 lemma [code func]:
  1650   shows "False \<and> x \<longleftrightarrow> False"
  1651     and "True \<and> x \<longleftrightarrow> x"
  1652     and "x \<and> False \<longleftrightarrow> False"
  1653     and "x \<and> True \<longleftrightarrow> x" by simp_all
  1654 
  1655 lemma [code func]:
  1656   shows "False \<or> x \<longleftrightarrow> x"
  1657     and "True \<or> x \<longleftrightarrow> True"
  1658     and "x \<or> False \<longleftrightarrow> x"
  1659     and "x \<or> True \<longleftrightarrow> True" by simp_all
  1660 
  1661 lemma [code func]:
  1662   shows "\<not> True \<longleftrightarrow> False"
  1663     and "\<not> False \<longleftrightarrow> True" by (rule HOL.simp_thms)+
  1664 
  1665 code_datatype Trueprop "prop"
  1666 
  1667 code_datatype "TYPE('a\<Colon>{})"
  1668 
  1669 lemma Let_case_cert:
  1670   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1671   shows "CASE x \<equiv> f x"
  1672   using assms by simp_all
  1673 
  1674 lemma If_case_cert:
  1675   includes meta_conjunction_syntax
  1676   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1677   shows "(CASE True \<equiv> f) && (CASE False \<equiv> g)"
  1678   using assms by simp_all
  1679 
  1680 setup {*
  1681   Code.add_case @{thm Let_case_cert}
  1682   #> Code.add_case @{thm If_case_cert}
  1683   #> Code.add_undefined @{const_name undefined}
  1684 *}
  1685 
  1686 
  1687 subsection {* Legacy tactics and ML bindings *}
  1688 
  1689 ML {*
  1690 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  1691 
  1692 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1693 local
  1694   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  1695     | wrong_prem (Bound _) = true
  1696     | wrong_prem _ = false;
  1697   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1698 in
  1699   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  1700   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  1701 end;
  1702 
  1703 val all_conj_distrib = thm "all_conj_distrib";
  1704 val all_simps = thms "all_simps";
  1705 val atomize_not = thm "atomize_not";
  1706 val case_split = thm "case_split";
  1707 val case_split_thm = thm "case_split_thm"
  1708 val cases_simp = thm "cases_simp";
  1709 val choice_eq = thm "choice_eq"
  1710 val cong = thm "cong"
  1711 val conj_comms = thms "conj_comms";
  1712 val conj_cong = thm "conj_cong";
  1713 val de_Morgan_conj = thm "de_Morgan_conj";
  1714 val de_Morgan_disj = thm "de_Morgan_disj";
  1715 val disj_assoc = thm "disj_assoc";
  1716 val disj_comms = thms "disj_comms";
  1717 val disj_cong = thm "disj_cong";
  1718 val eq_ac = thms "eq_ac";
  1719 val eq_cong2 = thm "eq_cong2"
  1720 val Eq_FalseI = thm "Eq_FalseI";
  1721 val Eq_TrueI = thm "Eq_TrueI";
  1722 val Ex1_def = thm "Ex1_def"
  1723 val ex_disj_distrib = thm "ex_disj_distrib";
  1724 val ex_simps = thms "ex_simps";
  1725 val if_cancel = thm "if_cancel";
  1726 val if_eq_cancel = thm "if_eq_cancel";
  1727 val if_False = thm "if_False";
  1728 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  1729 val iff = thm "iff"
  1730 val if_splits = thms "if_splits";
  1731 val if_True = thm "if_True";
  1732 val if_weak_cong = thm "if_weak_cong"
  1733 val imp_all = thm "imp_all";
  1734 val imp_cong = thm "imp_cong";
  1735 val imp_conjL = thm "imp_conjL";
  1736 val imp_conjR = thm "imp_conjR";
  1737 val imp_conv_disj = thm "imp_conv_disj";
  1738 val simp_implies_def = thm "simp_implies_def";
  1739 val simp_thms = thms "simp_thms";
  1740 val split_if = thm "split_if";
  1741 val the1_equality = thm "the1_equality"
  1742 val theI = thm "theI"
  1743 val theI' = thm "theI'"
  1744 val True_implies_equals = thm "True_implies_equals";
  1745 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  1746 
  1747 *}
  1748 
  1749 end