src/Pure/drule.ML
author wenzelm
Sat Apr 12 17:00:38 2008 +0200 (2008-04-12)
changeset 26627 dac6d56b7c8d
parent 26487 49850ac120e3
child 26653 60e0cf6bef89
permissions -rw-r--r--
rep_cterm/rep_thm: no longer dereference theory_ref;
replaced Drule.close_derivation/Goal.close_result by Thm.close_derivation (removed obsolete compression);
     1 (*  Title:      Pure/drule.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1993  University of Cambridge
     5 
     6 Derived rules and other operations on theorems.
     7 *)
     8 
     9 infix 0 RS RSN RL RLN MRS MRL OF COMP INCR_COMP COMP_INCR;
    10 
    11 signature BASIC_DRULE =
    12 sig
    13   val mk_implies: cterm * cterm -> cterm
    14   val list_implies: cterm list * cterm -> cterm
    15   val strip_imp_prems: cterm -> cterm list
    16   val strip_imp_concl: cterm -> cterm
    17   val cprems_of: thm -> cterm list
    18   val cterm_fun: (term -> term) -> (cterm -> cterm)
    19   val ctyp_fun: (typ -> typ) -> (ctyp -> ctyp)
    20   val read_insts: theory -> (indexname -> typ option) * (indexname -> sort option) ->
    21     (indexname -> typ option) * (indexname -> sort option) -> string list ->
    22     (indexname * string) list -> (ctyp * ctyp) list * (cterm * cterm) list
    23   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    24   val forall_intr_list: cterm list -> thm -> thm
    25   val forall_intr_frees: thm -> thm
    26   val forall_intr_vars: thm -> thm
    27   val forall_elim_list: cterm list -> thm -> thm
    28   val forall_elim_var: int -> thm -> thm
    29   val forall_elim_vars: int -> thm -> thm
    30   val gen_all: thm -> thm
    31   val lift_all: cterm -> thm -> thm
    32   val freeze_thaw: thm -> thm * (thm -> thm)
    33   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    34   val implies_elim_list: thm -> thm list -> thm
    35   val implies_intr_list: cterm list -> thm -> thm
    36   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    37   val zero_var_indexes_list: thm list -> thm list
    38   val zero_var_indexes: thm -> thm
    39   val implies_intr_hyps: thm -> thm
    40   val standard: thm -> thm
    41   val standard': thm -> thm
    42   val rotate_prems: int -> thm -> thm
    43   val rearrange_prems: int list -> thm -> thm
    44   val RSN: thm * (int * thm) -> thm
    45   val RS: thm * thm -> thm
    46   val RLN: thm list * (int * thm list) -> thm list
    47   val RL: thm list * thm list -> thm list
    48   val MRS: thm list * thm -> thm
    49   val MRL: thm list list * thm list -> thm list
    50   val OF: thm * thm list -> thm
    51   val compose: thm * int * thm -> thm list
    52   val COMP: thm * thm -> thm
    53   val INCR_COMP: thm * thm -> thm
    54   val COMP_INCR: thm * thm -> thm
    55   val read_instantiate_sg: theory -> (string*string)list -> thm -> thm
    56   val read_instantiate: (string*string)list -> thm -> thm
    57   val cterm_instantiate: (cterm*cterm)list -> thm -> thm
    58   val size_of_thm: thm -> int
    59   val reflexive_thm: thm
    60   val symmetric_thm: thm
    61   val transitive_thm: thm
    62   val symmetric_fun: thm -> thm
    63   val extensional: thm -> thm
    64   val equals_cong: thm
    65   val imp_cong: thm
    66   val swap_prems_eq: thm
    67   val asm_rl: thm
    68   val cut_rl: thm
    69   val revcut_rl: thm
    70   val thin_rl: thm
    71   val triv_forall_equality: thm
    72   val distinct_prems_rl: thm
    73   val swap_prems_rl: thm
    74   val equal_intr_rule: thm
    75   val equal_elim_rule1: thm
    76   val equal_elim_rule2: thm
    77   val instantiate': ctyp option list -> cterm option list -> thm -> thm
    78 end;
    79 
    80 signature DRULE =
    81 sig
    82   include BASIC_DRULE
    83   val generalize: string list * string list -> thm -> thm
    84   val list_comb: cterm * cterm list -> cterm
    85   val strip_comb: cterm -> cterm * cterm list
    86   val strip_type: ctyp -> ctyp list * ctyp
    87   val beta_conv: cterm -> cterm -> cterm
    88   val add_used: thm -> string list -> string list
    89   val flexflex_unique: thm -> thm
    90   val store_thm: bstring -> thm -> thm
    91   val store_standard_thm: bstring -> thm -> thm
    92   val store_thm_open: bstring -> thm -> thm
    93   val store_standard_thm_open: bstring -> thm -> thm
    94   val compose_single: thm * int * thm -> thm
    95   val imp_cong_rule: thm -> thm -> thm
    96   val arg_cong_rule: cterm -> thm -> thm
    97   val binop_cong_rule: cterm -> thm -> thm -> thm
    98   val fun_cong_rule: thm -> cterm -> thm
    99   val beta_eta_conversion: cterm -> thm
   100   val eta_long_conversion: cterm -> thm
   101   val eta_contraction_rule: thm -> thm
   102   val norm_hhf_eq: thm
   103   val is_norm_hhf: term -> bool
   104   val norm_hhf: theory -> term -> term
   105   val norm_hhf_cterm: cterm -> cterm
   106   val protect: cterm -> cterm
   107   val protectI: thm
   108   val protectD: thm
   109   val protect_cong: thm
   110   val implies_intr_protected: cterm list -> thm -> thm
   111   val termI: thm
   112   val mk_term: cterm -> thm
   113   val dest_term: thm -> cterm
   114   val cterm_rule: (thm -> thm) -> cterm -> cterm
   115   val term_rule: theory -> (thm -> thm) -> term -> term
   116   val dummy_thm: thm
   117   val sort_triv: theory -> typ * sort -> thm list
   118   val unconstrainTs: thm -> thm
   119   val with_subgoal: int -> (thm -> thm) -> thm -> thm
   120   val rename_bvars: (string * string) list -> thm -> thm
   121   val rename_bvars': string option list -> thm -> thm
   122   val incr_type_indexes: int -> thm -> thm
   123   val incr_indexes: thm -> thm -> thm
   124   val incr_indexes2: thm -> thm -> thm -> thm
   125   val remdups_rl: thm
   126   val multi_resolve: thm list -> thm -> thm Seq.seq
   127   val multi_resolves: thm list -> thm list -> thm Seq.seq
   128   val abs_def: thm -> thm
   129   val read_instantiate_sg': theory -> (indexname * string) list -> thm -> thm
   130   val read_instantiate': (indexname * string) list -> thm -> thm
   131 end;
   132 
   133 structure Drule: DRULE =
   134 struct
   135 
   136 
   137 (** some cterm->cterm operations: faster than calling cterm_of! **)
   138 
   139 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   140 fun strip_imp_prems ct =
   141   let val (cA, cB) = Thm.dest_implies ct
   142   in cA :: strip_imp_prems cB end
   143   handle TERM _ => [];
   144 
   145 (* A1==>...An==>B  goes to B, where B is not an implication *)
   146 fun strip_imp_concl ct =
   147   (case Thm.term_of ct of
   148     Const ("==>", _) $ _ $ _ => strip_imp_concl (Thm.dest_arg ct)
   149   | _ => ct);
   150 
   151 (*The premises of a theorem, as a cterm list*)
   152 val cprems_of = strip_imp_prems o cprop_of;
   153 
   154 fun cterm_fun f ct = Thm.cterm_of (Thm.theory_of_cterm ct) (f (Thm.term_of ct));
   155 fun ctyp_fun f cT = Thm.ctyp_of (Thm.theory_of_ctyp cT) (f (Thm.typ_of cT));
   156 
   157 fun certify t = Thm.cterm_of (Context.the_theory (Context.the_thread_data ())) t;
   158 
   159 val implies = certify Term.implies;
   160 fun mk_implies (A, B) = Thm.capply (Thm.capply implies A) B;
   161 
   162 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   163 fun list_implies([], B) = B
   164   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   165 
   166 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   167 fun list_comb (f, []) = f
   168   | list_comb (f, t::ts) = list_comb (Thm.capply f t, ts);
   169 
   170 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   171 fun strip_comb ct =
   172   let
   173     fun stripc (p as (ct, cts)) =
   174       let val (ct1, ct2) = Thm.dest_comb ct
   175       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   176   in stripc (ct, []) end;
   177 
   178 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   179 fun strip_type cT = (case Thm.typ_of cT of
   180     Type ("fun", _) =>
   181       let
   182         val [cT1, cT2] = Thm.dest_ctyp cT;
   183         val (cTs, cT') = strip_type cT2
   184       in (cT1 :: cTs, cT') end
   185   | _ => ([], cT));
   186 
   187 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   188   of the meta-equality returned by the beta_conversion rule.*)
   189 fun beta_conv x y =
   190   Thm.dest_arg (cprop_of (Thm.beta_conversion false (Thm.capply x y)));
   191 
   192 
   193 
   194 (** reading of instantiations **)
   195 
   196 fun absent ixn =
   197   error("No such variable in term: " ^ Term.string_of_vname ixn);
   198 
   199 fun inst_failure ixn =
   200   error("Instantiation of " ^ Term.string_of_vname ixn ^ " fails");
   201 
   202 fun read_insts thy (rtypes,rsorts) (types,sorts) used insts =
   203 let
   204     fun is_tv ((a, _), _) =
   205       (case Symbol.explode a of "'" :: _ => true | _ => false);
   206     val (tvs, vs) = List.partition is_tv insts;
   207     fun sort_of ixn = case rsorts ixn of SOME S => S | NONE => absent ixn;
   208     fun readT (ixn, st) =
   209         let val S = sort_of ixn;
   210             val T = Sign.read_def_typ (thy,sorts) st;
   211         in if Sign.typ_instance thy (T, TVar(ixn,S)) then (ixn,T)
   212            else inst_failure ixn
   213         end
   214     val tye = map readT tvs;
   215     fun mkty(ixn,st) = (case rtypes ixn of
   216                           SOME T => (ixn,(st,typ_subst_TVars tye T))
   217                         | NONE => absent ixn);
   218     val ixnsTs = map mkty vs;
   219     val ixns = map fst ixnsTs
   220     and sTs  = map snd ixnsTs
   221     val (cts,tye2) = Thm.read_def_cterms(thy,types,sorts) used false sTs;
   222     fun mkcVar(ixn,T) =
   223         let val U = typ_subst_TVars tye2 T
   224         in cterm_of thy (Var(ixn,U)) end
   225     val ixnTs = ListPair.zip(ixns, map snd sTs)
   226 in (map (fn (ixn, T) => (ctyp_of thy (TVar (ixn, sort_of ixn)),
   227       ctyp_of thy T)) (tye2 @ tye),
   228     ListPair.zip(map mkcVar ixnTs,cts))
   229 end;
   230 
   231 
   232 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   233      Used for establishing default types (of variables) and sorts (of
   234      type variables) when reading another term.
   235      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   236 ***)
   237 
   238 fun types_sorts thm =
   239   let
   240     val vars = Thm.fold_terms Term.add_vars thm [];
   241     val frees = Thm.fold_terms Term.add_frees thm [];
   242     val tvars = Thm.fold_terms Term.add_tvars thm [];
   243     val tfrees = Thm.fold_terms Term.add_tfrees thm [];
   244     fun types (a, i) =
   245       if i < 0 then AList.lookup (op =) frees a else AList.lookup (op =) vars (a, i);
   246     fun sorts (a, i) =
   247       if i < 0 then AList.lookup (op =) tfrees a else AList.lookup (op =) tvars (a, i);
   248   in (types, sorts) end;
   249 
   250 val add_used =
   251   (Thm.fold_terms o fold_types o fold_atyps)
   252     (fn TFree (a, _) => insert (op =) a
   253       | TVar ((a, _), _) => insert (op =) a
   254       | _ => I);
   255 
   256 
   257 
   258 (** Standardization of rules **)
   259 
   260 (* type classes and sorts *)
   261 
   262 fun sort_triv thy (T, S) =
   263   let
   264     val certT = Thm.ctyp_of thy;
   265     val cT = certT T;
   266     fun class_triv c =
   267       Thm.class_triv thy c
   268       |> Thm.instantiate ([(certT (TVar ((Name.aT, 0), [c])), cT)], []);
   269   in map class_triv S end;
   270 
   271 fun unconstrainTs th =
   272   fold (Thm.unconstrainT o Thm.ctyp_of (Thm.theory_of_thm th) o TVar)
   273     (Thm.fold_terms Term.add_tvars th []) th;
   274 
   275 (*Generalization over a list of variables*)
   276 val forall_intr_list = fold_rev forall_intr;
   277 
   278 (*Generalization over all suitable Free variables*)
   279 fun forall_intr_frees th =
   280     let
   281       val thy = Thm.theory_of_thm th;
   282       val {prop, hyps, tpairs, ...} = rep_thm th;
   283       val fixed = fold Term.add_frees (Thm.terms_of_tpairs tpairs @ hyps) [];
   284       val frees = Term.fold_aterms (fn Free v =>
   285         if member (op =) fixed v then I else insert (op =) v | _ => I) prop [];
   286     in fold (forall_intr o cterm_of thy o Free) frees th end;
   287 
   288 (*Generalization over Vars -- canonical order*)
   289 fun forall_intr_vars th =
   290   fold forall_intr
   291     (map (Thm.cterm_of (Thm.theory_of_thm th) o Var) (Thm.fold_terms Term.add_vars th [])) th;
   292 
   293 val forall_elim_var = PureThy.forall_elim_var;
   294 val forall_elim_vars = PureThy.forall_elim_vars;
   295 
   296 fun outer_params t =
   297   let val vs = Term.strip_all_vars t
   298   in Name.variant_list [] (map (Name.clean o #1) vs) ~~ map #2 vs end;
   299 
   300 (*generalize outermost parameters*)
   301 fun gen_all th =
   302   let
   303     val thy = Thm.theory_of_thm th;
   304     val {prop, maxidx, ...} = Thm.rep_thm th;
   305     val cert = Thm.cterm_of thy;
   306     fun elim (x, T) = Thm.forall_elim (cert (Var ((x, maxidx + 1), T)));
   307   in fold elim (outer_params prop) th end;
   308 
   309 (*lift vars wrt. outermost goal parameters
   310   -- reverses the effect of gen_all modulo higher-order unification*)
   311 fun lift_all goal th =
   312   let
   313     val thy = Theory.merge (Thm.theory_of_cterm goal, Thm.theory_of_thm th);
   314     val cert = Thm.cterm_of thy;
   315     val maxidx = Thm.maxidx_of th;
   316     val ps = outer_params (Thm.term_of goal)
   317       |> map (fn (x, T) => Var ((x, maxidx + 1), Logic.incr_tvar (maxidx + 1) T));
   318     val Ts = map Term.fastype_of ps;
   319     val inst = Thm.fold_terms Term.add_vars th [] |> map (fn (xi, T) =>
   320       (cert (Var (xi, T)), cert (Term.list_comb (Var (xi, Ts ---> T), ps))));
   321   in
   322     th |> Thm.instantiate ([], inst)
   323     |> fold_rev (Thm.forall_intr o cert) ps
   324   end;
   325 
   326 (*direct generalization*)
   327 fun generalize names th = Thm.generalize names (Thm.maxidx_of th + 1) th;
   328 
   329 (*specialization over a list of cterms*)
   330 val forall_elim_list = fold forall_elim;
   331 
   332 (*maps A1,...,An |- B  to  [| A1;...;An |] ==> B*)
   333 val implies_intr_list = fold_rev implies_intr;
   334 
   335 (*maps [| A1;...;An |] ==> B and [A1,...,An]  to  B*)
   336 fun implies_elim_list impth ths = fold Thm.elim_implies ths impth;
   337 
   338 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   339 fun zero_var_indexes_list [] = []
   340   | zero_var_indexes_list ths =
   341       let
   342         val thy = Theory.merge_list (map Thm.theory_of_thm ths);
   343         val certT = Thm.ctyp_of thy and cert = Thm.cterm_of thy;
   344         val (instT, inst) = TermSubst.zero_var_indexes_inst (map Thm.full_prop_of ths);
   345         val cinstT = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   346         val cinst = map (fn (v, t) => (cert (Var v), cert t)) inst;
   347       in map (Thm.adjust_maxidx_thm ~1 o Thm.instantiate (cinstT, cinst)) ths end;
   348 
   349 val zero_var_indexes = singleton zero_var_indexes_list;
   350 
   351 
   352 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   353     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   354 
   355 (*Discharge all hypotheses.*)
   356 fun implies_intr_hyps th =
   357   fold Thm.implies_intr (#hyps (Thm.crep_thm th)) th;
   358 
   359 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   360   This step can lose information.*)
   361 fun flexflex_unique th =
   362   if null (tpairs_of th) then th else
   363     case distinct Thm.eq_thm (Seq.list_of (flexflex_rule th)) of
   364       [th] => th
   365     | []   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   366     |  _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   367 
   368 
   369 (* legacy standard operations *)
   370 
   371 val standard' =
   372   implies_intr_hyps
   373   #> forall_intr_frees
   374   #> `Thm.maxidx_of
   375   #-> (fn maxidx =>
   376     forall_elim_vars (maxidx + 1)
   377     #> Thm.strip_shyps
   378     #> zero_var_indexes
   379     #> Thm.varifyT);
   380 
   381 val standard =
   382   flexflex_unique
   383   #> standard'
   384   #> Thm.close_derivation;
   385 
   386 
   387 (*Convert all Vars in a theorem to Frees.  Also return a function for
   388   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   389   Similar code in type/freeze_thaw*)
   390 
   391 fun freeze_thaw_robust th =
   392  let val fth = Thm.freezeT th
   393      val thy = Thm.theory_of_thm fth
   394      val {prop, tpairs, ...} = rep_thm fth
   395  in
   396    case List.foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   397        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   398      | vars =>
   399          let fun newName (Var(ix,_)) = (ix, gensym (string_of_indexname ix))
   400              val alist = map newName vars
   401              fun mk_inst (Var(v,T)) =
   402                  (cterm_of thy (Var(v,T)),
   403                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   404              val insts = map mk_inst vars
   405              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   406                  th' |> forall_intr_list (map #2 insts)
   407                      |> forall_elim_list (map (Thm.incr_indexes_cterm i o #1) insts)
   408          in  (Thm.instantiate ([],insts) fth, thaw)  end
   409  end;
   410 
   411 (*Basic version of the function above. No option to rename Vars apart in thaw.
   412   The Frees created from Vars have nice names. FIXME: does not check for
   413   clashes with variables in the assumptions, so delete and use freeze_thaw_robust instead?*)
   414 fun freeze_thaw th =
   415  let val fth = Thm.freezeT th
   416      val thy = Thm.theory_of_thm fth
   417      val {prop, tpairs, ...} = rep_thm fth
   418  in
   419    case List.foldr add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   420        [] => (fth, fn x => x)
   421      | vars =>
   422          let fun newName (Var(ix,_), (pairs,used)) =
   423                    let val v = Name.variant used (string_of_indexname ix)
   424                    in  ((ix,v)::pairs, v::used)  end;
   425              val (alist, _) = List.foldr newName ([], Library.foldr add_term_names
   426                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   427              fun mk_inst (Var(v,T)) =
   428                  (cterm_of thy (Var(v,T)),
   429                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   430              val insts = map mk_inst vars
   431              fun thaw th' =
   432                  th' |> forall_intr_list (map #2 insts)
   433                      |> forall_elim_list (map #1 insts)
   434          in  (Thm.instantiate ([],insts) fth, thaw)  end
   435  end;
   436 
   437 (*Rotates a rule's premises to the left by k*)
   438 fun rotate_prems 0 = I
   439   | rotate_prems k = permute_prems 0 k;
   440 
   441 fun with_subgoal i f = rotate_prems (i - 1) #> f #> rotate_prems (1 - i);
   442 
   443 (* permute prems, where the i-th position in the argument list (counting from 0)
   444    gives the position within the original thm to be transferred to position i.
   445    Any remaining trailing positions are left unchanged. *)
   446 val rearrange_prems = let
   447   fun rearr new []      thm = thm
   448   |   rearr new (p::ps) thm = rearr (new+1)
   449      (map (fn q => if new<=q andalso q<p then q+1 else q) ps)
   450      (permute_prems (new+1) (new-p) (permute_prems new (p-new) thm))
   451   in rearr 0 end;
   452 
   453 (*Resolution: exactly one resolvent must be produced.*)
   454 fun tha RSN (i,thb) =
   455   case Seq.chop 2 (biresolution false [(false,tha)] i thb) of
   456       ([th],_) => th
   457     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   458     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   459 
   460 (*resolution: P==>Q, Q==>R gives P==>R. *)
   461 fun tha RS thb = tha RSN (1,thb);
   462 
   463 (*For joining lists of rules*)
   464 fun thas RLN (i,thbs) =
   465   let val resolve = biresolution false (map (pair false) thas) i
   466       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   467   in maps resb thbs end;
   468 
   469 fun thas RL thbs = thas RLN (1,thbs);
   470 
   471 (*Resolve a list of rules against bottom_rl from right to left;
   472   makes proof trees*)
   473 fun rls MRS bottom_rl =
   474   let fun rs_aux i [] = bottom_rl
   475         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   476   in  rs_aux 1 rls  end;
   477 
   478 (*As above, but for rule lists*)
   479 fun rlss MRL bottom_rls =
   480   let fun rs_aux i [] = bottom_rls
   481         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   482   in  rs_aux 1 rlss  end;
   483 
   484 (*A version of MRS with more appropriate argument order*)
   485 fun bottom_rl OF rls = rls MRS bottom_rl;
   486 
   487 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   488   with no lifting or renaming!  Q may contain ==> or meta-quants
   489   ALWAYS deletes premise i *)
   490 fun compose(tha,i,thb) =
   491     distinct Thm.eq_thm (Seq.list_of (bicompose false (false,tha,0) i thb));
   492 
   493 fun compose_single (tha,i,thb) =
   494   case compose (tha,i,thb) of
   495     [th] => th
   496   | _ => raise THM ("compose: unique result expected", i, [tha,thb]);
   497 
   498 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   499 fun tha COMP thb =
   500     case compose(tha,1,thb) of
   501         [th] => th
   502       | _ =>   raise THM("COMP", 1, [tha,thb]);
   503 
   504 
   505 (** theorem equality **)
   506 
   507 (*Useful "distance" function for BEST_FIRST*)
   508 val size_of_thm = size_of_term o Thm.full_prop_of;
   509 
   510 
   511 
   512 (*** Meta-Rewriting Rules ***)
   513 
   514 val read_prop = certify o SimpleSyntax.read_prop;
   515 
   516 fun store_thm name th =
   517   Context.>>> (Context.map_theory_result (PureThy.store_thm (name, th)));
   518 
   519 fun store_thm_open name th =
   520   Context.>>> (Context.map_theory_result (PureThy.store_thm_open (name, th)));
   521 
   522 fun store_standard_thm name th = store_thm name (standard th);
   523 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   524 
   525 val reflexive_thm =
   526   let val cx = certify (Var(("x",0),TVar(("'a",0),[])))
   527   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   528 
   529 val symmetric_thm =
   530   let val xy = read_prop "x::'a == y::'a"
   531   in store_standard_thm_open "symmetric" (Thm.implies_intr xy (Thm.symmetric (Thm.assume xy))) end;
   532 
   533 val transitive_thm =
   534   let val xy = read_prop "x::'a == y::'a"
   535       val yz = read_prop "y::'a == z::'a"
   536       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   537   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   538 
   539 fun symmetric_fun thm = thm RS symmetric_thm;
   540 
   541 fun extensional eq =
   542   let val eq' =
   543     abstract_rule "x" (Thm.dest_arg (fst (Thm.dest_equals (cprop_of eq)))) eq
   544   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   545 
   546 val equals_cong =
   547   store_standard_thm_open "equals_cong" (Thm.reflexive (read_prop "x::'a == y::'a"));
   548 
   549 val imp_cong =
   550   let
   551     val ABC = read_prop "A ==> B::prop == C::prop"
   552     val AB = read_prop "A ==> B"
   553     val AC = read_prop "A ==> C"
   554     val A = read_prop "A"
   555   in
   556     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   557       (implies_intr AB (implies_intr A
   558         (equal_elim (implies_elim (assume ABC) (assume A))
   559           (implies_elim (assume AB) (assume A)))))
   560       (implies_intr AC (implies_intr A
   561         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   562           (implies_elim (assume AC) (assume A)))))))
   563   end;
   564 
   565 val swap_prems_eq =
   566   let
   567     val ABC = read_prop "A ==> B ==> C"
   568     val BAC = read_prop "B ==> A ==> C"
   569     val A = read_prop "A"
   570     val B = read_prop "B"
   571   in
   572     store_standard_thm_open "swap_prems_eq" (equal_intr
   573       (implies_intr ABC (implies_intr B (implies_intr A
   574         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   575       (implies_intr BAC (implies_intr A (implies_intr B
   576         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   577   end;
   578 
   579 val imp_cong_rule = Thm.combination o Thm.combination (Thm.reflexive implies);
   580 
   581 fun arg_cong_rule ct th = Thm.combination (Thm.reflexive ct) th;    (*AP_TERM in LCF/HOL*)
   582 fun fun_cong_rule th ct = Thm.combination th (Thm.reflexive ct);    (*AP_THM in LCF/HOL*)
   583 fun binop_cong_rule ct th1 th2 = Thm.combination (arg_cong_rule ct th1) th2;
   584 
   585 local
   586   val dest_eq = Thm.dest_equals o cprop_of
   587   val rhs_of = snd o dest_eq
   588 in
   589 fun beta_eta_conversion t =
   590   let val thm = beta_conversion true t
   591   in transitive thm (eta_conversion (rhs_of thm)) end
   592 end;
   593 
   594 fun eta_long_conversion ct = transitive (beta_eta_conversion ct)
   595   (symmetric (beta_eta_conversion (cterm_fun (Pattern.eta_long []) ct)));
   596 
   597 (*Contract all eta-redexes in the theorem, lest they give rise to needless abstractions*)
   598 fun eta_contraction_rule th =
   599   equal_elim (eta_conversion (cprop_of th)) th;
   600 
   601 
   602 (* abs_def *)
   603 
   604 (*
   605    f ?x1 ... ?xn == u
   606   --------------------
   607    f == %x1 ... xn. u
   608 *)
   609 
   610 local
   611 
   612 fun contract_lhs th =
   613   Thm.transitive (Thm.symmetric (beta_eta_conversion
   614     (fst (Thm.dest_equals (cprop_of th))))) th;
   615 
   616 fun var_args ct =
   617   (case try Thm.dest_comb ct of
   618     SOME (f, arg) =>
   619       (case Thm.term_of arg of
   620         Var ((x, _), _) => update (eq_snd (op aconvc)) (x, arg) (var_args f)
   621       | _ => [])
   622   | NONE => []);
   623 
   624 in
   625 
   626 fun abs_def th =
   627   let
   628     val th' = contract_lhs th;
   629     val args = var_args (Thm.lhs_of th');
   630   in contract_lhs (fold (uncurry Thm.abstract_rule) args th') end;
   631 
   632 end;
   633 
   634 
   635 
   636 (*** Some useful meta-theorems ***)
   637 
   638 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   639 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "?psi"));
   640 val _ = store_thm "_" asm_rl;
   641 
   642 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   643 val cut_rl =
   644   store_standard_thm_open "cut_rl"
   645     (Thm.trivial (read_prop "?psi ==> ?theta"));
   646 
   647 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   648      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   649 val revcut_rl =
   650   let val V = read_prop "V"
   651       and VW = read_prop "V ==> W";
   652   in
   653     store_standard_thm_open "revcut_rl"
   654       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   655   end;
   656 
   657 (*for deleting an unwanted assumption*)
   658 val thin_rl =
   659   let val V = read_prop "V"
   660       and W = read_prop "W";
   661   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   662 
   663 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   664 val triv_forall_equality =
   665   let val V  = read_prop "V"
   666       and QV = read_prop "!!x::'a. V"
   667       and x  = certify (Free ("x", Term.aT []));
   668   in
   669     store_standard_thm_open "triv_forall_equality"
   670       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   671         (implies_intr V  (forall_intr x (assume V))))
   672   end;
   673 
   674 (* (PROP ?Phi ==> PROP ?Phi ==> PROP ?Psi) ==>
   675    (PROP ?Phi ==> PROP ?Psi)
   676 *)
   677 val distinct_prems_rl =
   678   let
   679     val AAB = read_prop "Phi ==> Phi ==> Psi"
   680     val A = read_prop "Phi";
   681   in
   682     store_standard_thm_open "distinct_prems_rl"
   683       (implies_intr_list [AAB, A] (implies_elim_list (assume AAB) [assume A, assume A]))
   684   end;
   685 
   686 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   687    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   688    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   689 *)
   690 val swap_prems_rl =
   691   let val cmajor = read_prop "PhiA ==> PhiB ==> Psi";
   692       val major = assume cmajor;
   693       val cminor1 = read_prop "PhiA";
   694       val minor1 = assume cminor1;
   695       val cminor2 = read_prop "PhiB";
   696       val minor2 = assume cminor2;
   697   in store_standard_thm_open "swap_prems_rl"
   698        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   699          (implies_elim (implies_elim major minor1) minor2))))
   700   end;
   701 
   702 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   703    ==> PROP ?phi == PROP ?psi
   704    Introduction rule for == as a meta-theorem.
   705 *)
   706 val equal_intr_rule =
   707   let val PQ = read_prop "phi ==> psi"
   708       and QP = read_prop "psi ==> phi"
   709   in
   710     store_standard_thm_open "equal_intr_rule"
   711       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   712   end;
   713 
   714 (* PROP ?phi == PROP ?psi ==> PROP ?phi ==> PROP ?psi *)
   715 val equal_elim_rule1 =
   716   let val eq = read_prop "phi::prop == psi::prop"
   717       and P = read_prop "phi"
   718   in store_standard_thm_open "equal_elim_rule1"
   719     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   720   end;
   721 
   722 (* PROP ?psi == PROP ?phi ==> PROP ?phi ==> PROP ?psi *)
   723 val equal_elim_rule2 =
   724   store_standard_thm_open "equal_elim_rule2" (symmetric_thm RS equal_elim_rule1);
   725 
   726 (* "[| PROP ?phi; PROP ?phi; PROP ?psi |] ==> PROP ?psi" *)
   727 val remdups_rl =
   728   let val P = read_prop "phi" and Q = read_prop "psi";
   729   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   730 
   731 
   732 (*(PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x))
   733   Rewrite rule for HHF normalization.*)
   734 
   735 val norm_hhf_eq =
   736   let
   737     val aT = TFree ("'a", []);
   738     val all = Term.all aT;
   739     val x = Free ("x", aT);
   740     val phi = Free ("phi", propT);
   741     val psi = Free ("psi", aT --> propT);
   742 
   743     val cx = certify x;
   744     val cphi = certify phi;
   745     val lhs = certify (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   746     val rhs = certify (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   747   in
   748     Thm.equal_intr
   749       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   750         |> Thm.forall_elim cx
   751         |> Thm.implies_intr cphi
   752         |> Thm.forall_intr cx
   753         |> Thm.implies_intr lhs)
   754       (Thm.implies_elim
   755           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   756         |> Thm.forall_intr cx
   757         |> Thm.implies_intr cphi
   758         |> Thm.implies_intr rhs)
   759     |> store_standard_thm_open "norm_hhf_eq"
   760   end;
   761 
   762 val norm_hhf_prop = Logic.dest_equals (Thm.prop_of norm_hhf_eq);
   763 
   764 fun is_norm_hhf tm =
   765   let
   766     fun is_norm (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   767       | is_norm (t $ u) = is_norm t andalso is_norm u
   768       | is_norm (Abs (_, _, t)) = is_norm t
   769       | is_norm _ = true;
   770   in is_norm (Envir.beta_eta_contract tm) end;
   771 
   772 fun norm_hhf thy t =
   773   if is_norm_hhf t then t
   774   else Pattern.rewrite_term thy [norm_hhf_prop] [] t;
   775 
   776 fun norm_hhf_cterm ct =
   777   if is_norm_hhf (Thm.term_of ct) then ct
   778   else cterm_fun (Pattern.rewrite_term (Thm.theory_of_cterm ct) [norm_hhf_prop] []) ct;
   779 
   780 
   781 (* var indexes *)
   782 
   783 (*Increment the indexes of only the type variables*)
   784 fun incr_type_indexes inc th =
   785   let val tvs = term_tvars (prop_of th)
   786       and thy = theory_of_thm th
   787       fun inc_tvar ((a,i),s) = pairself (ctyp_of thy) (TVar ((a,i),s), TVar ((a,i+inc),s))
   788   in Thm.instantiate (map inc_tvar tvs, []) th end;
   789 
   790 fun incr_indexes th = Thm.incr_indexes (Thm.maxidx_of th + 1);
   791 
   792 fun incr_indexes2 th1 th2 =
   793   Thm.incr_indexes (Int.max (Thm.maxidx_of th1, Thm.maxidx_of th2) + 1);
   794 
   795 fun th1 INCR_COMP th2 = incr_indexes th2 th1 COMP th2;
   796 fun th1 COMP_INCR th2 = th1 COMP incr_indexes th1 th2;
   797 
   798 
   799 (*** Instantiate theorem th, reading instantiations in theory thy ****)
   800 
   801 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   802 fun instantiate instpair th =
   803   Thm.adjust_maxidx_thm ~1 (Thm.instantiate instpair th COMP_INCR asm_rl);
   804 
   805 fun read_instantiate_sg' thy sinsts th =
   806     let val ts = types_sorts th;
   807         val used = add_used th [];
   808     in  instantiate (read_insts thy ts ts used sinsts) th  end;
   809 
   810 fun read_instantiate_sg thy sinsts th =
   811   read_instantiate_sg' thy (map (apfst Syntax.read_indexname) sinsts) th;
   812 
   813 (*Instantiate theorem th, reading instantiations under theory of th*)
   814 fun read_instantiate sinsts th =
   815     read_instantiate_sg (Thm.theory_of_thm th) sinsts th;
   816 
   817 fun read_instantiate' sinsts th =
   818     read_instantiate_sg' (Thm.theory_of_thm th) sinsts th;
   819 
   820 
   821 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   822   Instantiates distinct Vars by terms, inferring type instantiations. *)
   823 local
   824   fun add_types ((ct,cu), (thy,tye,maxidx)) =
   825     let
   826         val thyt = Thm.theory_of_cterm ct;
   827         val thyu = Thm.theory_of_cterm cu;
   828         val {t, T, maxidx = maxt, ...} = Thm.rep_cterm ct;
   829         val {t = u, T = U, maxidx = maxu, ...} = Thm.rep_cterm cu;
   830         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   831         val thy' = Theory.merge(thy, Theory.merge(thyt, thyu))
   832         val (tye',maxi') = Sign.typ_unify thy' (T, U) (tye, maxi)
   833           handle Type.TUNIFY => raise TYPE ("Ill-typed instantiation:\nType\n" ^
   834             Sign.string_of_typ thy' (Envir.norm_type tye T) ^
   835             "\nof variable " ^
   836             Sign.string_of_term thy' (Term.map_types (Envir.norm_type tye) t) ^
   837             "\ncannot be unified with type\n" ^
   838             Sign.string_of_typ thy' (Envir.norm_type tye U) ^ "\nof term " ^
   839             Sign.string_of_term thy' (Term.map_types (Envir.norm_type tye) u),
   840             [T, U], [t, u])
   841     in  (thy', tye', maxi')  end;
   842 in
   843 fun cterm_instantiate [] th = th
   844   | cterm_instantiate ctpairs0 th =
   845   let val (thy,tye,_) = List.foldr add_types (Thm.theory_of_thm th, Vartab.empty, 0) ctpairs0
   846       fun instT(ct,cu) =
   847         let val inst = cterm_of thy o Term.map_types (Envir.norm_type tye) o term_of
   848         in (inst ct, inst cu) end
   849       fun ctyp2 (ixn, (S, T)) = (ctyp_of thy (TVar (ixn, S)), ctyp_of thy (Envir.norm_type tye T))
   850   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   851   handle TERM _ =>
   852            raise THM("cterm_instantiate: incompatible theories",0,[th])
   853        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   854 end;
   855 
   856 
   857 (** protected propositions and embedded terms **)
   858 
   859 local
   860   val A = certify (Free ("A", propT));
   861   val get_axiom = Thm.unvarify o Thm.get_axiom (Context.the_theory (Context.the_thread_data ()));
   862   val prop_def = get_axiom "prop_def";
   863   val term_def = get_axiom "term_def";
   864 in
   865   val protect = Thm.capply (certify Logic.protectC);
   866   val protectI = store_thm "protectI" (PureThy.kind_rule Thm.internalK (standard
   867       (Thm.equal_elim (Thm.symmetric prop_def) (Thm.assume A))));
   868   val protectD = store_thm "protectD" (PureThy.kind_rule Thm.internalK (standard
   869       (Thm.equal_elim prop_def (Thm.assume (protect A)))));
   870   val protect_cong = store_standard_thm_open "protect_cong" (Thm.reflexive (protect A));
   871 
   872   val termI = store_thm "termI" (PureThy.kind_rule Thm.internalK (standard
   873       (Thm.equal_elim (Thm.symmetric term_def) (Thm.forall_intr A (Thm.trivial A)))));
   874 end;
   875 
   876 fun implies_intr_protected asms th =
   877   let val asms' = map protect asms in
   878     implies_elim_list
   879       (implies_intr_list asms th)
   880       (map (fn asm' => Thm.assume asm' RS protectD) asms')
   881     |> implies_intr_list asms'
   882   end;
   883 
   884 fun mk_term ct =
   885   let
   886     val thy = Thm.theory_of_cterm ct;
   887     val cert = Thm.cterm_of thy;
   888     val certT = Thm.ctyp_of thy;
   889     val T = Thm.typ_of (Thm.ctyp_of_term ct);
   890     val a = certT (TVar (("'a", 0), []));
   891     val x = cert (Var (("x", 0), T));
   892   in Thm.instantiate ([(a, certT T)], [(x, ct)]) termI end;
   893 
   894 fun dest_term th =
   895   let val cprop = strip_imp_concl (Thm.cprop_of th) in
   896     if can Logic.dest_term (Thm.term_of cprop) then
   897       Thm.dest_arg cprop
   898     else raise THM ("dest_term", 0, [th])
   899   end;
   900 
   901 fun cterm_rule f = dest_term o f o mk_term;
   902 fun term_rule thy f t = Thm.term_of (cterm_rule f (Thm.cterm_of thy t));
   903 
   904 val dummy_thm = mk_term (certify (Term.dummy_pattern propT));
   905 
   906 
   907 
   908 (** variations on instantiate **)
   909 
   910 (* instantiate by left-to-right occurrence of variables *)
   911 
   912 fun instantiate' cTs cts thm =
   913   let
   914     fun err msg =
   915       raise TYPE ("instantiate': " ^ msg,
   916         map_filter (Option.map Thm.typ_of) cTs,
   917         map_filter (Option.map Thm.term_of) cts);
   918 
   919     fun inst_of (v, ct) =
   920       (Thm.cterm_of (Thm.theory_of_cterm ct) (Var v), ct)
   921         handle TYPE (msg, _, _) => err msg;
   922 
   923     fun tyinst_of (v, cT) =
   924       (Thm.ctyp_of (Thm.theory_of_ctyp cT) (TVar v), cT)
   925         handle TYPE (msg, _, _) => err msg;
   926 
   927     fun zip_vars xs ys =
   928       zip_options xs ys handle Library.UnequalLengths =>
   929         err "more instantiations than variables in thm";
   930 
   931     (*instantiate types first!*)
   932     val thm' =
   933       if forall is_none cTs then thm
   934       else Thm.instantiate
   935         (map tyinst_of (zip_vars (rev (Thm.fold_terms Term.add_tvars thm [])) cTs), []) thm;
   936     val thm'' =
   937       if forall is_none cts then thm'
   938       else Thm.instantiate
   939         ([], map inst_of (zip_vars (rev (Thm.fold_terms Term.add_vars thm' [])) cts)) thm';
   940     in thm'' end;
   941 
   942 
   943 
   944 (** renaming of bound variables **)
   945 
   946 (* replace bound variables x_i in thm by y_i *)
   947 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   948 
   949 fun rename_bvars [] thm = thm
   950   | rename_bvars vs thm =
   951       let
   952         val cert = Thm.cterm_of (Thm.theory_of_thm thm);
   953         fun ren (Abs (x, T, t)) = Abs (AList.lookup (op =) vs x |> the_default x, T, ren t)
   954           | ren (t $ u) = ren t $ ren u
   955           | ren t = t;
   956       in equal_elim (reflexive (cert (ren (Thm.prop_of thm)))) thm end;
   957 
   958 
   959 (* renaming in left-to-right order *)
   960 
   961 fun rename_bvars' xs thm =
   962   let
   963     val cert = Thm.cterm_of (Thm.theory_of_thm thm);
   964     val prop = Thm.prop_of thm;
   965     fun rename [] t = ([], t)
   966       | rename (x' :: xs) (Abs (x, T, t)) =
   967           let val (xs', t') = rename xs t
   968           in (xs', Abs (the_default x x', T, t')) end
   969       | rename xs (t $ u) =
   970           let
   971             val (xs', t') = rename xs t;
   972             val (xs'', u') = rename xs' u
   973           in (xs'', t' $ u') end
   974       | rename xs t = (xs, t);
   975   in case rename xs prop of
   976       ([], prop') => equal_elim (reflexive (cert prop')) thm
   977     | _ => error "More names than abstractions in theorem"
   978   end;
   979 
   980 
   981 
   982 (** multi_resolve **)
   983 
   984 local
   985 
   986 fun res th i rule =
   987   Thm.biresolution false [(false, th)] i rule handle THM _ => Seq.empty;
   988 
   989 fun multi_res _ [] rule = Seq.single rule
   990   | multi_res i (th :: ths) rule = Seq.maps (res th i) (multi_res (i + 1) ths rule);
   991 
   992 in
   993 
   994 val multi_resolve = multi_res 1;
   995 fun multi_resolves facts rules = Seq.maps (multi_resolve facts) (Seq.of_list rules);
   996 
   997 end;
   998 
   999 end;
  1000 
  1001 structure BasicDrule: BASIC_DRULE = Drule;
  1002 open BasicDrule;