src/HOL/Complete_Lattice.thy
author haftmann
Sun Jul 17 15:15:58 2011 +0200 (2011-07-17)
changeset 43865 db18f4d0cc7d
parent 43854 f1d23df1adde
child 43866 8a50dc70cbff
permissions -rw-r--r--
further generalization from sets to complete lattices
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices, with special focus on sets *}
     4 
     5 theory Complete_Lattice
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50) and
    12   inf (infixl "\<sqinter>" 70) and
    13   sup (infixl "\<squnion>" 65) and
    14   top ("\<top>") and
    15   bot ("\<bottom>")
    16 
    17 
    18 subsection {* Syntactic infimum and supremum operations *}
    19 
    20 class Inf =
    21   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    22 
    23 class Sup =
    24   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    25 
    26 subsection {* Abstract complete lattices *}
    27 
    28 class complete_lattice = bounded_lattice + Inf + Sup +
    29   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    30      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    31   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    32      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    33 begin
    34 
    35 lemma dual_complete_lattice:
    36   "class.complete_lattice Sup Inf (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) \<top> \<bottom>"
    37   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    38     (unfold_locales, (fact bot_least top_greatest
    39         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    40 
    41 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
    42   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    43 
    44 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
    45   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    46 
    47 lemma Inf_empty [simp]:
    48   "\<Sqinter>{} = \<top>"
    49   by (auto intro: antisym Inf_greatest)
    50 
    51 lemma Sup_empty [simp]:
    52   "\<Squnion>{} = \<bottom>"
    53   by (auto intro: antisym Sup_least)
    54 
    55 lemma Inf_UNIV [simp]:
    56   "\<Sqinter>UNIV = \<bottom>"
    57   by (simp add: Sup_Inf Sup_empty [symmetric])
    58 
    59 lemma Sup_UNIV [simp]:
    60   "\<Squnion>UNIV = \<top>"
    61   by (simp add: Inf_Sup Inf_empty [symmetric])
    62 
    63 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
    64   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
    65 
    66 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
    67   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
    68 
    69 lemma Inf_singleton [simp]:
    70   "\<Sqinter>{a} = a"
    71   by (auto intro: antisym Inf_lower Inf_greatest)
    72 
    73 lemma Sup_singleton [simp]:
    74   "\<Squnion>{a} = a"
    75   by (auto intro: antisym Sup_upper Sup_least)
    76 
    77 lemma Inf_binary:
    78   "\<Sqinter>{a, b} = a \<sqinter> b"
    79   by (simp add: Inf_insert)
    80 
    81 lemma Sup_binary:
    82   "\<Squnion>{a, b} = a \<squnion> b"
    83   by (simp add: Sup_insert)
    84 
    85 lemma le_Inf_iff: "b \<sqsubseteq> \<Sqinter>A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
    86   by (auto intro: Inf_greatest dest: Inf_lower)
    87 
    88 lemma Sup_le_iff: "\<Squnion>A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
    89   by (auto intro: Sup_least dest: Sup_upper)
    90 
    91 lemma Inf_mono:
    92   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<sqsubseteq> b"
    93   shows "\<Sqinter>A \<sqsubseteq> \<Sqinter>B"
    94 proof (rule Inf_greatest)
    95   fix b assume "b \<in> B"
    96   with assms obtain a where "a \<in> A" and "a \<sqsubseteq> b" by blast
    97   from `a \<in> A` have "\<Sqinter>A \<sqsubseteq> a" by (rule Inf_lower)
    98   with `a \<sqsubseteq> b` show "\<Sqinter>A \<sqsubseteq> b" by auto
    99 qed
   100 
   101 lemma Sup_mono:
   102   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<sqsubseteq> b"
   103   shows "\<Squnion>A \<sqsubseteq> \<Squnion>B"
   104 proof (rule Sup_least)
   105   fix a assume "a \<in> A"
   106   with assms obtain b where "b \<in> B" and "a \<sqsubseteq> b" by blast
   107   from `b \<in> B` have "b \<sqsubseteq> \<Squnion>B" by (rule Sup_upper)
   108   with `a \<sqsubseteq> b` show "a \<sqsubseteq> \<Squnion>B" by auto
   109 qed
   110 
   111 lemma Sup_upper2: "u \<in> A \<Longrightarrow> v \<sqsubseteq> u \<Longrightarrow> v \<sqsubseteq> \<Squnion>A"
   112   using Sup_upper[of u A] by auto
   113 
   114 lemma Inf_lower2: "u \<in> A \<Longrightarrow> u \<sqsubseteq> v \<Longrightarrow> \<Sqinter>A \<sqsubseteq> v"
   115   using Inf_lower[of u A] by auto
   116 
   117 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   118   "INFI A f = \<Sqinter> (f ` A)"
   119 
   120 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   121   "SUPR A f = \<Squnion> (f ` A)"
   122 
   123 end
   124 
   125 syntax
   126   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3INF _./ _)" [0, 10] 10)
   127   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
   128   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3SUP _./ _)" [0, 10] 10)
   129   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
   130 
   131 syntax (xsymbols)
   132   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   133   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   134   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   135   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   136 
   137 translations
   138   "INF x y. B"   == "INF x. INF y. B"
   139   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
   140   "INF x. B"     == "INF x:CONST UNIV. B"
   141   "INF x:A. B"   == "CONST INFI A (%x. B)"
   142   "SUP x y. B"   == "SUP x. SUP y. B"
   143   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
   144   "SUP x. B"     == "SUP x:CONST UNIV. B"
   145   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   146 
   147 print_translation {*
   148   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   149     Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   150 *} -- {* to avoid eta-contraction of body *}
   151 
   152 context complete_lattice
   153 begin
   154 
   155 lemma INF_empty: "(\<Sqinter>x\<in>{}. f x) = \<top>"
   156   by (simp add: INFI_def)
   157 
   158 lemma INF_insert: "(\<Sqinter>x\<in>insert a A. f x) = f a \<sqinter> INFI A f"
   159   by (simp add: INFI_def Inf_insert)
   160 
   161 lemma INF_leI: "i \<in> A \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> f i"
   162   by (auto simp add: INFI_def intro: Inf_lower)
   163 
   164 lemma INF_leI2: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> u \<Longrightarrow> (\<Sqinter>i\<in>A. f i) \<sqsubseteq> u"
   165   using INF_leI [of i A f] by auto
   166 
   167 lemma le_INFI: "(\<And>i. i \<in> A \<Longrightarrow> u \<sqsubseteq> f i) \<Longrightarrow> u \<sqsubseteq> (\<Sqinter>i\<in>A. f i)"
   168   by (auto simp add: INFI_def intro: Inf_greatest)
   169 
   170 lemma le_INF_iff: "u \<sqsubseteq> (\<Sqinter>i\<in>A. f i) \<longleftrightarrow> (\<forall>i \<in> A. u \<sqsubseteq> f i)"
   171   by (auto simp add: INFI_def le_Inf_iff)
   172 
   173 lemma INF_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>i\<in>A. f) = f"
   174   by (auto intro: antisym INF_leI le_INFI)
   175 
   176 lemma INF_cong:
   177   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Sqinter>x\<in>A. C x) = (\<Sqinter>x\<in>B. D x)"
   178   by (simp add: INFI_def image_def)
   179 
   180 lemma INF_mono:
   181   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Sqinter>n\<in>A. f n) \<sqsubseteq> (\<Sqinter>n\<in>B. g n)"
   182   by (force intro!: Inf_mono simp: INFI_def)
   183 
   184 lemma INF_subset:  "A \<subseteq> B \<Longrightarrow> INFI B f \<sqsubseteq> INFI A f"
   185   by (intro INF_mono) auto
   186 
   187 lemma INF_commute: "(\<Sqinter>i\<in>A. \<Sqinter>j\<in>B. f i j) = (\<Sqinter>j\<in>B. \<Sqinter>i\<in>A. f i j)"
   188   by (iprover intro: INF_leI le_INFI order_trans antisym)
   189 
   190 lemma SUP_cong:
   191   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Squnion>x\<in>A. C x) = (\<Squnion>x\<in>B. D x)"
   192   by (simp add: SUPR_def image_def)
   193 
   194 lemma le_SUPI: "i \<in> A \<Longrightarrow> f i \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   195   by (auto simp add: SUPR_def intro: Sup_upper)
   196 
   197 lemma le_SUPI2: "i \<in> A \<Longrightarrow> u \<sqsubseteq> f i \<Longrightarrow> u \<sqsubseteq> (\<Squnion>i\<in>A. f i)"
   198   using le_SUPI [of i A f] by auto
   199 
   200 lemma SUP_leI: "(\<And>i. i \<in> A \<Longrightarrow> f i \<sqsubseteq> u) \<Longrightarrow> (\<Squnion>i\<in>A. f i) \<sqsubseteq> u"
   201   by (auto simp add: SUPR_def intro: Sup_least)
   202 
   203 lemma SUP_le_iff: "(\<Squnion>i\<in>A. f i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i \<in> A. f i \<sqsubseteq> u)"
   204   unfolding SUPR_def by (auto simp add: Sup_le_iff)
   205 
   206 lemma SUP_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>i\<in>A. f) = f"
   207   by (auto intro: antisym SUP_leI le_SUPI)
   208 
   209 lemma SUP_mono:
   210   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<sqsubseteq> g m) \<Longrightarrow> (\<Squnion>n\<in>A. f n) \<sqsubseteq> (\<Squnion>n\<in>B. g n)"
   211   by (force intro!: Sup_mono simp: SUPR_def)
   212 
   213 lemma SUP_subset:  "A \<subseteq> B \<Longrightarrow> SUPR A f \<sqsubseteq> SUPR B f"
   214   by (intro SUP_mono) auto
   215 
   216 lemma SUP_commute: "(\<Squnion>i\<in>A. \<Squnion>j\<in>B. f i j) = (\<Squnion>j\<in>B. \<Squnion>i\<in>A. f i j)"
   217   by (iprover intro: SUP_leI le_SUPI order_trans antisym)
   218 
   219 lemma SUP_empty: "(\<Squnion>x\<in>{}. f x) = \<bottom>"
   220   by (simp add: SUPR_def)
   221 
   222 lemma SUP_insert: "(\<Squnion>x\<in>insert a A. f x) = f a \<squnion> SUPR A f"
   223   by (simp add: SUPR_def Sup_insert)
   224 
   225 end
   226 
   227 lemma Inf_less_iff:
   228   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   229   shows "\<Sqinter>S \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>S. x \<sqsubset> a)"
   230   unfolding not_le [symmetric] le_Inf_iff by auto
   231 
   232 lemma INF_less_iff:
   233   fixes a :: "'a::{complete_lattice,linorder}"
   234   shows "(\<Sqinter>i\<in>A. f i) \<sqsubset> a \<longleftrightarrow> (\<exists>x\<in>A. f x \<sqsubset> a)"
   235   unfolding INFI_def Inf_less_iff by auto
   236 
   237 lemma less_Sup_iff:
   238   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   239   shows "a \<sqsubset> \<Squnion>S \<longleftrightarrow> (\<exists>x\<in>S. a \<sqsubset> x)"
   240   unfolding not_le [symmetric] Sup_le_iff by auto
   241 
   242 lemma less_SUP_iff:
   243   fixes a :: "'a::{complete_lattice,linorder}"
   244   shows "a \<sqsubset> (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a \<sqsubset> f x)"
   245   unfolding SUPR_def less_Sup_iff by auto
   246 
   247 subsection {* @{typ bool} and @{typ "_ \<Rightarrow> _"} as complete lattice *}
   248 
   249 instantiation bool :: complete_lattice
   250 begin
   251 
   252 definition
   253   "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   254 
   255 definition
   256   "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   257 
   258 instance proof
   259 qed (auto simp add: Inf_bool_def Sup_bool_def)
   260 
   261 end
   262 
   263 lemma INFI_bool_eq [simp]:
   264   "INFI = Ball"
   265 proof (rule ext)+
   266   fix A :: "'a set"
   267   fix P :: "'a \<Rightarrow> bool"
   268   show "(\<Sqinter>x\<in>A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P x)"
   269     by (auto simp add: Ball_def INFI_def Inf_bool_def)
   270 qed
   271 
   272 lemma SUPR_bool_eq [simp]:
   273   "SUPR = Bex"
   274 proof (rule ext)+
   275   fix A :: "'a set"
   276   fix P :: "'a \<Rightarrow> bool"
   277   show "(\<Squnion>x\<in>A. P x) \<longleftrightarrow> (\<exists>x\<in>A. P x)"
   278     by (auto simp add: Bex_def SUPR_def Sup_bool_def)
   279 qed
   280 
   281 instantiation "fun" :: (type, complete_lattice) complete_lattice
   282 begin
   283 
   284 definition
   285   "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   286 
   287 lemma Inf_apply:
   288   "(\<Sqinter>A) x = \<Sqinter>{y. \<exists>f\<in>A. y = f x}"
   289   by (simp add: Inf_fun_def)
   290 
   291 definition
   292   "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   293 
   294 lemma Sup_apply:
   295   "(\<Squnion>A) x = \<Squnion>{y. \<exists>f\<in>A. y = f x}"
   296   by (simp add: Sup_fun_def)
   297 
   298 instance proof
   299 qed (auto simp add: le_fun_def Inf_apply Sup_apply
   300   intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   301 
   302 end
   303 
   304 lemma INFI_apply:
   305   "(\<Sqinter>y\<in>A. f y) x = (\<Sqinter>y\<in>A. f y x)"
   306   by (auto intro: arg_cong [of _ _ Inf] simp add: INFI_def Inf_apply)
   307 
   308 lemma SUPR_apply:
   309   "(\<Squnion>y\<in>A. f y) x = (\<Squnion>y\<in>A. f y x)"
   310   by (auto intro: arg_cong [of _ _ Sup] simp add: SUPR_def Sup_apply)
   311 
   312 
   313 subsection {* Inter *}
   314 
   315 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   316   "Inter S \<equiv> \<Sqinter>S"
   317   
   318 notation (xsymbols)
   319   Inter  ("\<Inter>_" [90] 90)
   320 
   321 lemma Inter_eq:
   322   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   323 proof (rule set_eqI)
   324   fix x
   325   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   326     by auto
   327   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   328     by (simp add: Inf_fun_def Inf_bool_def) (simp add: mem_def)
   329 qed
   330 
   331 lemma Inter_iff [simp,no_atp]: "A \<in> \<Inter>C \<longleftrightarrow> (\<forall>X\<in>C. A \<in> X)"
   332   by (unfold Inter_eq) blast
   333 
   334 lemma InterI [intro!]: "(\<And>X. X \<in> C \<Longrightarrow> A \<in> X) \<Longrightarrow> A \<in> \<Inter>C"
   335   by (simp add: Inter_eq)
   336 
   337 text {*
   338   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   339   contains @{term A} as an element, but @{prop "A \<in> X"} can hold when
   340   @{prop "X \<in> C"} does not!  This rule is analogous to @{text spec}.
   341 *}
   342 
   343 lemma InterD [elim, Pure.elim]: "A \<in> \<Inter>C \<Longrightarrow> X \<in> C \<Longrightarrow> A \<in> X"
   344   by auto
   345 
   346 lemma InterE [elim]: "A \<in> \<Inter>C \<Longrightarrow> (X \<notin> C \<Longrightarrow> R) \<Longrightarrow> (A \<in> X \<Longrightarrow> R) \<Longrightarrow> R"
   347   -- {* ``Classical'' elimination rule -- does not require proving
   348     @{prop "X \<in> C"}. *}
   349   by (unfold Inter_eq) blast
   350 
   351 lemma Inter_lower: "B \<in> A \<Longrightarrow> \<Inter>A \<subseteq> B"
   352   by (fact Inf_lower)
   353 
   354 lemma (in complete_lattice) Inf_less_eq:
   355   assumes "\<And>v. v \<in> A \<Longrightarrow> v \<sqsubseteq> u"
   356     and "A \<noteq> {}"
   357   shows "\<Sqinter>A \<sqsubseteq> u"
   358 proof -
   359   from `A \<noteq> {}` obtain v where "v \<in> A" by blast
   360   moreover with assms have "v \<sqsubseteq> u" by blast
   361   ultimately show ?thesis by (rule Inf_lower2)
   362 qed
   363 
   364 lemma Inter_subset:
   365   "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> B) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> \<Inter>A \<subseteq> B"
   366   by (fact Inf_less_eq)
   367 
   368 lemma Inter_greatest: "(\<And>X. X \<in> A \<Longrightarrow> C \<subseteq> X) \<Longrightarrow> C \<subseteq> Inter A"
   369   by (fact Inf_greatest)
   370 
   371 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
   372   by (fact Inf_binary [symmetric])
   373 
   374 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
   375   by (fact Inf_empty)
   376 
   377 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
   378   by (fact Inf_UNIV)
   379 
   380 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   381   by (fact Inf_insert)
   382 
   383 lemma (in complete_lattice) Inf_inter_less: "\<Sqinter>A \<squnion> \<Sqinter>B \<sqsubseteq> \<Sqinter>(A \<inter> B)"
   384   by (auto intro: Inf_greatest Inf_lower)
   385 
   386 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   387   by (fact Inf_inter_less)
   388 
   389 lemma (in complete_lattice) Inf_union_distrib: "\<Sqinter>(A \<union> B) = \<Sqinter>A \<sqinter> \<Sqinter>B"
   390   by (rule antisym) (auto intro: Inf_greatest Inf_lower le_infI1 le_infI2)
   391 
   392 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   393   by (fact Inf_union_distrib)
   394 
   395 lemma (in complete_lattice) Inf_top_conv [no_atp]:
   396   "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   397   "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   398 proof -
   399   show "\<Sqinter>A = \<top> \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)"
   400   proof
   401     assume "\<forall>x\<in>A. x = \<top>"
   402     then have "A = {} \<or> A = {\<top>}" by auto
   403     then show "\<Sqinter>A = \<top>" by auto
   404   next
   405     assume "\<Sqinter>A = \<top>"
   406     show "\<forall>x\<in>A. x = \<top>"
   407     proof (rule ccontr)
   408       assume "\<not> (\<forall>x\<in>A. x = \<top>)"
   409       then obtain x where "x \<in> A" and "x \<noteq> \<top>" by blast
   410       then obtain B where "A = insert x B" by blast
   411       with `\<Sqinter>A = \<top>` `x \<noteq> \<top>` show False by (simp add: Inf_insert)
   412     qed
   413   qed
   414   then show "\<top> = \<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x = \<top>)" by auto
   415 qed
   416 
   417 lemma Inter_UNIV_conv [simp,no_atp]:
   418   "\<Inter>A = UNIV \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   419   "UNIV = \<Inter>A \<longleftrightarrow> (\<forall>x\<in>A. x = UNIV)"
   420   by (fact Inf_top_conv)+
   421 
   422 lemma (in complete_lattice) Inf_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> \<Sqinter>B"
   423   by (auto intro: Inf_greatest Inf_lower)
   424 
   425 lemma Inter_anti_mono: "B \<subseteq> A \<Longrightarrow> \<Inter>A \<subseteq> \<Inter>B"
   426   by (fact Inf_anti_mono)
   427 
   428 
   429 subsection {* Intersections of families *}
   430 
   431 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   432   "INTER \<equiv> INFI"
   433 
   434 syntax
   435   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   436   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   437 
   438 syntax (xsymbols)
   439   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   440   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   441 
   442 syntax (latex output)
   443   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   444   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   445 
   446 translations
   447   "INT x y. B"  == "INT x. INT y. B"
   448   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   449   "INT x. B"    == "INT x:CONST UNIV. B"
   450   "INT x:A. B"  == "CONST INTER A (%x. B)"
   451 
   452 print_translation {*
   453   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   454 *} -- {* to avoid eta-contraction of body *}
   455 
   456 lemma INTER_eq_Inter_image:
   457   "(\<Inter>x\<in>A. B x) = \<Inter>(B`A)"
   458   by (fact INFI_def)
   459   
   460 lemma Inter_def:
   461   "\<Inter>S = (\<Inter>x\<in>S. x)"
   462   by (simp add: INTER_eq_Inter_image image_def)
   463 
   464 lemma INTER_def:
   465   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   466   by (auto simp add: INTER_eq_Inter_image Inter_eq)
   467 
   468 lemma Inter_image_eq [simp]:
   469   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   470   by (rule sym) (fact INFI_def)
   471 
   472 lemma INT_iff [simp]: "b \<in> (\<Inter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. b \<in> B x)"
   473   by (unfold INTER_def) blast
   474 
   475 lemma INT_I [intro!]: "(\<And>x. x \<in> A \<Longrightarrow> b \<in> B x) \<Longrightarrow> b \<in> (\<Inter>x\<in>A. B x)"
   476   by (unfold INTER_def) blast
   477 
   478 lemma INT_D [elim, Pure.elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> B a"
   479   by auto
   480 
   481 lemma INT_E [elim]: "b \<in> (\<Inter>x\<in>A. B x) \<Longrightarrow> (b \<in> B a \<Longrightarrow> R) \<Longrightarrow> (a \<notin> A \<Longrightarrow> R) \<Longrightarrow> R"
   482   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a\<in>A"}. *}
   483   by (unfold INTER_def) blast
   484 
   485 lemma INT_cong [cong]:
   486   "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Inter>x\<in>A. C x) = (\<Inter>x\<in>B. D x)"
   487   by (fact INF_cong)
   488 
   489 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   490   by blast
   491 
   492 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   493   by blast
   494 
   495 lemma INT_lower: "a \<in> A \<Longrightarrow> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   496   by (fact INF_leI)
   497 
   498 lemma INT_greatest: "(\<And>x. x \<in> A \<Longrightarrow> C \<subseteq> B x) \<Longrightarrow> C \<subseteq> (\<Inter>x\<in>A. B x)"
   499   by (fact le_INFI)
   500 
   501 lemma (in complete_lattice) INFI_empty:
   502   "(\<Sqinter>x\<in>{}. B x) = \<top>"
   503   by (simp add: INFI_def)
   504 
   505 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
   506   by (fact INFI_empty)
   507 
   508 lemma (in complete_lattice) INFI_absorb:
   509   assumes "k \<in> I"
   510   shows "A k \<sqinter> (\<Sqinter>i\<in>I. A i) = (\<Sqinter>i\<in>I. A i)"
   511 proof -
   512   from assms obtain J where "I = insert k J" by blast
   513   then show ?thesis by (simp add: INF_insert)
   514 qed
   515 
   516 lemma INT_absorb: "k \<in> I \<Longrightarrow> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   517   by (fact INFI_absorb)
   518 
   519 lemma INT_subset_iff: "B \<subseteq> (\<Inter>i\<in>I. A i) \<longleftrightarrow> (\<forall>i\<in>I. B \<subseteq> A i)"
   520   by (fact le_INF_iff)
   521 
   522 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   523   by (fact INF_insert)
   524 
   525 lemma (in complete_lattice) INF_union:
   526   "(\<Sqinter>i \<in> A \<union> B. M i) = (\<Sqinter>i \<in> A. M i) \<sqinter> (\<Sqinter>i\<in>B. M i)"
   527   by (auto intro!: antisym INF_mono intro: le_infI1 le_infI2 le_INFI INF_leI)
   528 
   529 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   530   by (fact INF_union)
   531 
   532 lemma INT_insert_distrib:
   533   "u \<in> A \<Longrightarrow> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   534   by blast
   535 
   536 -- {* continue generalization from here *}
   537 
   538 lemma (in complete_lattice) INF_constant:
   539   "(\<Sqinter>y\<in>A. c) = (if A = {} then \<top> else c)"
   540   by (simp add: INF_empty)
   541 
   542 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   543   by (fact INF_constant)
   544 
   545 lemma (in complete_lattice) INF_eq:
   546   "(\<Sqinter>x\<in>A. B x) = \<Sqinter>({Y. \<exists>x\<in>A. Y = B x})"
   547   by (simp add: INFI_def image_def)
   548 
   549 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
   550   -- {* Look: it has an \emph{existential} quantifier *}
   551   by (fact INF_eq)
   552 
   553 lemma (in complete_lattice) INF_top_conv:
   554  "\<top> = (\<Sqinter>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   555  "(\<Sqinter>x\<in>A. B x) = \<top> \<longleftrightarrow> (\<forall>x\<in>A. B x = \<top>)"
   556   by (auto simp add: INFI_def Inf_top_conv)
   557 
   558 lemma INTER_UNIV_conv [simp]:
   559  "(UNIV = (\<Inter>x\<in>A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   560  "((\<Inter>x\<in>A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   561   by (fact INF_top_conv)+
   562 
   563 lemma (in complete_lattice) INFI_UNIV_range:
   564   "(\<Sqinter>x\<in>UNIV. f x) = \<Sqinter>range f"
   565   by (simp add: INFI_def)
   566 
   567 lemma UNIV_bool [no_atp]: -- "FIXME move"
   568   "UNIV = {False, True}"
   569   by auto
   570 
   571 lemma (in complete_lattice) INF_bool_eq:
   572   "(\<Sqinter>b. A b) = A True \<sqinter> A False"
   573   by (simp add: UNIV_bool INF_empty INF_insert inf_commute)
   574 
   575 lemma INT_bool_eq: "(\<Inter>b. A b) = A True \<inter> A False"
   576   by (fact INF_bool_eq)
   577 
   578 lemma (in complete_lattice) INF_anti_mono:
   579   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow> (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   580   -- {* The last inclusion is POSITIVE! *}
   581   by (blast dest: subsetD)
   582 
   583 lemma INT_anti_mono:
   584   "B \<subseteq> A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow> (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   585   -- {* The last inclusion is POSITIVE! *}
   586   by (blast dest: subsetD)
   587 
   588 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   589   by blast
   590 
   591 lemma vimage_INT: "f -` (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. f -` B x)"
   592   by blast
   593 
   594 
   595 subsection {* Union *}
   596 
   597 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   598   "Union S \<equiv> \<Squnion>S"
   599 
   600 notation (xsymbols)
   601   Union  ("\<Union>_" [90] 90)
   602 
   603 lemma Union_eq:
   604   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   605 proof (rule set_eqI)
   606   fix x
   607   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   608     by auto
   609   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   610     by (simp add: Sup_fun_def Sup_bool_def) (simp add: mem_def)
   611 qed
   612 
   613 lemma Union_iff [simp, no_atp]:
   614   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   615   by (unfold Union_eq) blast
   616 
   617 lemma UnionI [intro]:
   618   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   619   -- {* The order of the premises presupposes that @{term C} is rigid;
   620     @{term A} may be flexible. *}
   621   by auto
   622 
   623 lemma UnionE [elim!]:
   624   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A \<in> X \<Longrightarrow> X \<in> C \<Longrightarrow> R) \<Longrightarrow> R"
   625   by auto
   626 
   627 lemma Union_upper: "B \<in> A \<Longrightarrow> B \<subseteq> \<Union>A"
   628   by (iprover intro: subsetI UnionI)
   629 
   630 lemma Union_least: "(\<And>X. X \<in> A \<Longrightarrow> X \<subseteq> C) \<Longrightarrow> \<Union>A \<subseteq> C"
   631   by (iprover intro: subsetI elim: UnionE dest: subsetD)
   632 
   633 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
   634   by blast
   635 
   636 lemma Union_empty [simp]: "\<Union>{} = {}"
   637   by blast
   638 
   639 lemma Union_UNIV [simp]: "\<Union>UNIV = UNIV"
   640   by blast
   641 
   642 lemma Union_insert [simp]: "\<Union>insert a B = a \<union> \<Union>B"
   643   by blast
   644 
   645 lemma Union_Un_distrib [simp]: "\<Union>(A \<union> B) = \<Union>A \<union> \<Union>B"
   646   by blast
   647 
   648 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   649   by blast
   650 
   651 lemma Union_empty_conv [simp,no_atp]: "(\<Union>A = {}) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   652   by blast
   653 
   654 lemma empty_Union_conv [simp,no_atp]: "({} = \<Union>A) \<longleftrightarrow> (\<forall>x\<in>A. x = {})"
   655   by blast
   656 
   657 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) \<longleftrightarrow> (\<forall>B\<in>C. B \<inter> A = {})"
   658   by blast
   659 
   660 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   661   by blast
   662 
   663 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   664   by blast
   665 
   666 lemma Union_mono: "A \<subseteq> B \<Longrightarrow> \<Union>A \<subseteq> \<Union>B"
   667   by blast
   668 
   669 
   670 subsection {* Unions of families *}
   671 
   672 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   673   "UNION \<equiv> SUPR"
   674 
   675 syntax
   676   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   677   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
   678 
   679 syntax (xsymbols)
   680   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   681   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
   682 
   683 syntax (latex output)
   684   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   685   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   686 
   687 translations
   688   "UN x y. B"   == "UN x. UN y. B"
   689   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   690   "UN x. B"     == "UN x:CONST UNIV. B"
   691   "UN x:A. B"   == "CONST UNION A (%x. B)"
   692 
   693 text {*
   694   Note the difference between ordinary xsymbol syntax of indexed
   695   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   696   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   697   former does not make the index expression a subscript of the
   698   union/intersection symbol because this leads to problems with nested
   699   subscripts in Proof General.
   700 *}
   701 
   702 print_translation {*
   703   [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
   704 *} -- {* to avoid eta-contraction of body *}
   705 
   706 lemma UNION_eq_Union_image:
   707   "(\<Union>x\<in>A. B x) = \<Union>(B ` A)"
   708   by (fact SUPR_def)
   709 
   710 lemma Union_def:
   711   "\<Union>S = (\<Union>x\<in>S. x)"
   712   by (simp add: UNION_eq_Union_image image_def)
   713 
   714 lemma UNION_def [no_atp]:
   715   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
   716   by (auto simp add: UNION_eq_Union_image Union_eq)
   717   
   718 lemma Union_image_eq [simp]:
   719   "\<Union>(B ` A) = (\<Union>x\<in>A. B x)"
   720   by (rule sym) (fact UNION_eq_Union_image)
   721   
   722 lemma UN_iff [simp]: "(b \<in> (\<Union>x\<in>A. B x)) = (\<exists>x\<in>A. b \<in> B x)"
   723   by (unfold UNION_def) blast
   724 
   725 lemma UN_I [intro]: "a \<in> A \<Longrightarrow> b \<in> B a \<Longrightarrow> b \<in> (\<Union>x\<in>A. B x)"
   726   -- {* The order of the premises presupposes that @{term A} is rigid;
   727     @{term b} may be flexible. *}
   728   by auto
   729 
   730 lemma UN_E [elim!]: "b \<in> (\<Union>x\<in>A. B x) \<Longrightarrow> (\<And>x. x\<in>A \<Longrightarrow> b \<in> B x \<Longrightarrow> R) \<Longrightarrow> R"
   731   by (unfold UNION_def) blast
   732 
   733 lemma UN_cong [cong]:
   734     "A = B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
   735   by (simp add: UNION_def)
   736 
   737 lemma strong_UN_cong:
   738     "A = B \<Longrightarrow> (\<And>x. x \<in> B =simp=> C x = D x) \<Longrightarrow> (\<Union>x\<in>A. C x) = (\<Union>x\<in>B. D x)"
   739   by (simp add: UNION_def simp_implies_def)
   740 
   741 lemma image_eq_UN: "f ` A = (\<Union>x\<in>A. {f x})"
   742   by blast
   743 
   744 lemma UN_upper: "a \<in> A \<Longrightarrow> B a \<subseteq> (\<Union>x\<in>A. B x)"
   745   by (fact le_SUPI)
   746 
   747 lemma UN_least: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C) \<Longrightarrow> (\<Union>x\<in>A. B x) \<subseteq> C"
   748   by (iprover intro: subsetI elim: UN_E dest: subsetD)
   749 
   750 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
   751   by blast
   752 
   753 lemma UN_insert_distrib: "u \<in> A \<Longrightarrow> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
   754   by blast
   755 
   756 lemma UN_empty [simp,no_atp]: "(\<Union>x\<in>{}. B x) = {}"
   757   by blast
   758 
   759 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
   760   by blast
   761 
   762 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
   763   by blast
   764 
   765 lemma UN_absorb: "k \<in> I \<Longrightarrow> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
   766   by auto
   767 
   768 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
   769   by blast
   770 
   771 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
   772   by blast
   773 
   774 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
   775   by blast
   776 
   777 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
   778   by (fact SUP_le_iff)
   779 
   780 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
   781   by blast
   782 
   783 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
   784   by auto
   785 
   786 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
   787   by blast
   788 
   789 lemma UNION_empty_conv[simp]:
   790   "{} = (\<Union>x\<in>A. B x) \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
   791   "(\<Union>x\<in>A. B x) = {} \<longleftrightarrow> (\<forall>x\<in>A. B x = {})"
   792 by blast+
   793 
   794 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
   795   by blast
   796 
   797 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
   798   by blast
   799 
   800 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
   801   by blast
   802 
   803 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
   804   by (auto simp add: split_if_mem2)
   805 
   806 lemma UN_bool_eq: "(\<Union>b. A b) = (A True \<union> A False)"
   807   by (auto intro: bool_contrapos)
   808 
   809 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
   810   by blast
   811 
   812 lemma UN_mono:
   813   "A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<subseteq> g x) \<Longrightarrow>
   814     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
   815   by (blast dest: subsetD)
   816 
   817 lemma vimage_Union: "f -` (\<Union>A) = (\<Union>X\<in>A. f -` X)"
   818   by blast
   819 
   820 lemma vimage_UN: "f -` (\<Union>x\<in>A. B x) = (\<Union>x\<in>A. f -` B x)"
   821   by blast
   822 
   823 lemma vimage_eq_UN: "f -` B = (\<Union>y\<in>B. f -` {y})"
   824   -- {* NOT suitable for rewriting *}
   825   by blast
   826 
   827 lemma image_UN: "f ` UNION A B = (\<Union>x\<in>A. f ` B x)"
   828   by blast
   829 
   830 
   831 subsection {* Distributive laws *}
   832 
   833 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
   834   by blast
   835 
   836 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
   837   by blast
   838 
   839 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A ` C) \<union> \<Union>(B ` C)"
   840   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
   841   -- {* Union of a family of unions *}
   842   by blast
   843 
   844 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
   845   -- {* Equivalent version *}
   846   by blast
   847 
   848 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
   849   by blast
   850 
   851 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A ` C) \<inter> \<Inter>(B ` C)"
   852   by blast
   853 
   854 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
   855   -- {* Equivalent version *}
   856   by blast
   857 
   858 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
   859   -- {* Halmos, Naive Set Theory, page 35. *}
   860   by blast
   861 
   862 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
   863   by blast
   864 
   865 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
   866   by blast
   867 
   868 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
   869   by blast
   870 
   871 
   872 subsection {* Complement *}
   873 
   874 lemma Compl_UN [simp]: "- (\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
   875   by blast
   876 
   877 lemma Compl_INT [simp]: "- (\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
   878   by blast
   879 
   880 
   881 subsection {* Miniscoping and maxiscoping *}
   882 
   883 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
   884            and Intersections. *}
   885 
   886 lemma UN_simps [simp]:
   887   "\<And>a B C. (\<Union>x\<in>C. insert a (B x)) = (if C={} then {} else insert a (\<Union>x\<in>C. B x))"
   888   "\<And>A B C. (\<Union>x\<in>C. A x \<union>  B) = ((if C={} then {} else (\<Union>x\<in>C. A x) \<union> B))"
   889   "\<And>A B C. (\<Union>x\<in>C. A \<union> B x) = ((if C={} then {} else A \<union> (\<Union>x\<in>C. B x)))"
   890   "\<And>A B C. (\<Union>x\<in>C. A x \<inter> B) = ((\<Union>x\<in>C. A x) \<inter>B)"
   891   "\<And>A B C. (\<Union>x\<in>C. A \<inter> B x) = (A \<inter>(\<Union>x\<in>C. B x))"
   892   "\<And>A B C. (\<Union>x\<in>C. A x - B) = ((\<Union>x\<in>C. A x) - B)"
   893   "\<And>A B C. (\<Union>x\<in>C. A - B x) = (A - (\<Inter>x\<in>C. B x))"
   894   "\<And>A B. (\<Union>x\<in>\<Union>A. B x) = (\<Union>y\<in>A. \<Union>x\<in>y. B x)"
   895   "\<And>A B C. (\<Union>z\<in>UNION A B. C z) = (\<Union>x\<in>A. \<Union>z\<in>B x. C z)"
   896   "\<And>A B f. (\<Union>x\<in>f`A. B x) = (\<Union>a\<in>A. B (f a))"
   897   by auto
   898 
   899 lemma INT_simps [simp]:
   900   "\<And>A B C. (\<Inter>x\<in>C. A x \<inter> B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) \<inter>B)"
   901   "\<And>A B C. (\<Inter>x\<in>C. A \<inter> B x) = (if C={} then UNIV else A \<inter>(\<Inter>x\<in>C. B x))"
   902   "\<And>A B C. (\<Inter>x\<in>C. A x - B) = (if C={} then UNIV else (\<Inter>x\<in>C. A x) - B)"
   903   "\<And>A B C. (\<Inter>x\<in>C. A - B x) = (if C={} then UNIV else A - (\<Union>x\<in>C. B x))"
   904   "\<And>a B C. (\<Inter>x\<in>C. insert a (B x)) = insert a (\<Inter>x\<in>C. B x)"
   905   "\<And>A B C. (\<Inter>x\<in>C. A x \<union> B) = ((\<Inter>x\<in>C. A x) \<union> B)"
   906   "\<And>A B C. (\<Inter>x\<in>C. A \<union> B x) = (A \<union> (\<Inter>x\<in>C. B x))"
   907   "\<And>A B. (\<Inter>x\<in>\<Union>A. B x) = (\<Inter>y\<in>A. \<Inter>x\<in>y. B x)"
   908   "\<And>A B C. (\<Inter>z\<in>UNION A B. C z) = (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z)"
   909   "\<And>A B f. (\<Inter>x\<in>f`A. B x) = (\<Inter>a\<in>A. B (f a))"
   910   by auto
   911 
   912 lemma ball_simps [simp,no_atp]:
   913   "\<And>A P Q. (\<forall>x\<in>A. P x \<or> Q) \<longleftrightarrow> ((\<forall>x\<in>A. P x) \<or> Q)"
   914   "\<And>A P Q. (\<forall>x\<in>A. P \<or> Q x) \<longleftrightarrow> (P \<or> (\<forall>x\<in>A. Q x))"
   915   "\<And>A P Q. (\<forall>x\<in>A. P \<longrightarrow> Q x) \<longleftrightarrow> (P \<longrightarrow> (\<forall>x\<in>A. Q x))"
   916   "\<And>A P Q. (\<forall>x\<in>A. P x \<longrightarrow> Q) \<longleftrightarrow> ((\<exists>x\<in>A. P x) \<longrightarrow> Q)"
   917   "\<And>P. (\<forall>x\<in>{}. P x) \<longleftrightarrow> True"
   918   "\<And>P. (\<forall>x\<in>UNIV. P x) \<longleftrightarrow> (\<forall>x. P x)"
   919   "\<And>a B P. (\<forall>x\<in>insert a B. P x) \<longleftrightarrow> (P a \<and> (\<forall>x\<in>B. P x))"
   920   "\<And>A P. (\<forall>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<forall>y\<in>A. \<forall>x\<in>y. P x)"
   921   "\<And>A B P. (\<forall>x\<in> UNION A B. P x) = (\<forall>a\<in>A. \<forall>x\<in> B a. P x)"
   922   "\<And>P Q. (\<forall>x\<in>Collect Q. P x) \<longleftrightarrow> (\<forall>x. Q x \<longrightarrow> P x)"
   923   "\<And>A P f. (\<forall>x\<in>f`A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P (f x))"
   924   "\<And>A P. (\<not> (\<forall>x\<in>A. P x)) \<longleftrightarrow> (\<exists>x\<in>A. \<not> P x)"
   925   by auto
   926 
   927 lemma bex_simps [simp,no_atp]:
   928   "\<And>A P Q. (\<exists>x\<in>A. P x \<and> Q) \<longleftrightarrow> ((\<exists>x\<in>A. P x) \<and> Q)"
   929   "\<And>A P Q. (\<exists>x\<in>A. P \<and> Q x) \<longleftrightarrow> (P \<and> (\<exists>x\<in>A. Q x))"
   930   "\<And>P. (\<exists>x\<in>{}. P x) \<longleftrightarrow> False"
   931   "\<And>P. (\<exists>x\<in>UNIV. P x) \<longleftrightarrow> (\<exists>x. P x)"
   932   "\<And>a B P. (\<exists>x\<in>insert a B. P x) \<longleftrightarrow> (P a | (\<exists>x\<in>B. P x))"
   933   "\<And>A P. (\<exists>x\<in>\<Union>A. P x) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>x\<in>y. P x)"
   934   "\<And>A B P. (\<exists>x\<in>UNION A B. P x) \<longleftrightarrow> (\<exists>a\<in>A. \<exists>x\<in>B a. P x)"
   935   "\<And>P Q. (\<exists>x\<in>Collect Q. P x) \<longleftrightarrow> (\<exists>x. Q x \<and> P x)"
   936   "\<And>A P f. (\<exists>x\<in>f`A. P x) \<longleftrightarrow> (\<exists>x\<in>A. P (f x))"
   937   "\<And>A P. (\<not>(\<exists>x\<in>A. P x)) \<longleftrightarrow> (\<forall>x\<in>A. \<not> P x)"
   938   by auto
   939 
   940 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
   941 
   942 lemma UN_extend_simps:
   943   "\<And>a B C. insert a (\<Union>x\<in>C. B x) = (if C={} then {a} else (\<Union>x\<in>C. insert a (B x)))"
   944   "\<And>A B C. (\<Union>x\<in>C. A x) \<union>  B  = (if C={} then B else (\<Union>x\<in>C. A x \<union>  B))"
   945   "\<And>A B C. A \<union> (\<Union>x\<in>C. B x) = (if C={} then A else (\<Union>x\<in>C. A \<union> B x))"
   946   "\<And>A B C. ((\<Union>x\<in>C. A x) \<inter> B) = (\<Union>x\<in>C. A x \<inter> B)"
   947   "\<And>A B C. (A \<inter> (\<Union>x\<in>C. B x)) = (\<Union>x\<in>C. A \<inter> B x)"
   948   "\<And>A B C. ((\<Union>x\<in>C. A x) - B) = (\<Union>x\<in>C. A x - B)"
   949   "\<And>A B C. (A - (\<Inter>x\<in>C. B x)) = (\<Union>x\<in>C. A - B x)"
   950   "\<And>A B. (\<Union>y\<in>A. \<Union>x\<in>y. B x) = (\<Union>x\<in>\<Union>A. B x)"
   951   "\<And>A B C. (\<Union>x\<in>A. \<Union>z\<in>B x. C z) = (\<Union>z\<in>UNION A B. C z)"
   952   "\<And>A B f. (\<Union>a\<in>A. B (f a)) = (\<Union>x\<in>f`A. B x)"
   953   by auto
   954 
   955 lemma INT_extend_simps:
   956   "\<And>A B C. (\<Inter>x\<in>C. A x) \<inter> B = (if C={} then B else (\<Inter>x\<in>C. A x \<inter> B))"
   957   "\<And>A B C. A \<inter> (\<Inter>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A \<inter> B x))"
   958   "\<And>A B C. (\<Inter>x\<in>C. A x) - B = (if C={} then UNIV - B else (\<Inter>x\<in>C. A x - B))"
   959   "\<And>A B C. A - (\<Union>x\<in>C. B x) = (if C={} then A else (\<Inter>x\<in>C. A - B x))"
   960   "\<And>a B C. insert a (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. insert a (B x))"
   961   "\<And>A B C. ((\<Inter>x\<in>C. A x) \<union> B) = (\<Inter>x\<in>C. A x \<union> B)"
   962   "\<And>A B C. A \<union> (\<Inter>x\<in>C. B x) = (\<Inter>x\<in>C. A \<union> B x)"
   963   "\<And>A B. (\<Inter>y\<in>A. \<Inter>x\<in>y. B x) = (\<Inter>x\<in>\<Union>A. B x)"
   964   "\<And>A B C. (\<Inter>x\<in>A. \<Inter>z\<in>B x. C z) = (\<Inter>z\<in>UNION A B. C z)"
   965   "\<And>A B f. (\<Inter>a\<in>A. B (f a)) = (\<Inter>x\<in>f`A. B x)"
   966   by auto
   967 
   968 
   969 no_notation
   970   less_eq  (infix "\<sqsubseteq>" 50) and
   971   less (infix "\<sqsubset>" 50) and
   972   bot ("\<bottom>") and
   973   top ("\<top>") and
   974   inf  (infixl "\<sqinter>" 70) and
   975   sup  (infixl "\<squnion>" 65) and
   976   Inf  ("\<Sqinter>_" [900] 900) and
   977   Sup  ("\<Squnion>_" [900] 900)
   978 
   979 no_syntax (xsymbols)
   980   "_INF1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Sqinter>_./ _)" [0, 10] 10)
   981   "_INF"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Sqinter>_\<in>_./ _)" [0, 0, 10] 10)
   982   "_SUP1"     :: "pttrns \<Rightarrow> 'b \<Rightarrow> 'b"           ("(3\<Squnion>_./ _)" [0, 10] 10)
   983   "_SUP"      :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b \<Rightarrow> 'b"  ("(3\<Squnion>_\<in>_./ _)" [0, 0, 10] 10)
   984 
   985 lemmas mem_simps =
   986   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   987   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   988   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   989 
   990 end