src/Pure/Isar/expression.ML
author wenzelm
Thu Oct 11 15:26:33 2012 +0200 (2012-10-11)
changeset 49818 db42a1147986
parent 49817 85b37aece3b3
child 49819 97b572c10fe9
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/Isar/expression.ML
     2     Author:     Clemens Ballarin, TU Muenchen
     3 
     4 Locale expressions and user interface layer of locales.
     5 *)
     6 
     7 signature EXPRESSION =
     8 sig
     9   (* Locale expressions *)
    10   datatype 'term map = Positional of 'term option list | Named of (string * 'term) list
    11   type ('name, 'term) expr = ('name * ((string * bool) * 'term map)) list
    12   type expression_i = (string, term) expr * (binding * typ option * mixfix) list
    13   type expression = (xstring * Position.T, string) expr * (binding * string option * mixfix) list
    14 
    15   (* Processing of context statements *)
    16   val cert_statement: Element.context_i list -> (term * term list) list list ->
    17     Proof.context -> (term * term list) list list * Proof.context
    18   val read_statement: Element.context list -> (string * string list) list list ->
    19     Proof.context -> (term * term list) list list * Proof.context
    20 
    21   (* Declaring locales *)
    22   val cert_declaration: expression_i -> (Proof.context -> Proof.context) -> Element.context_i list ->
    23     Proof.context -> (((string * typ) * mixfix) list * (string * morphism) list
    24       * Element.context_i list * Proof.context) * ((string * typ) list * Proof.context)
    25   val cert_read_declaration: expression_i -> (Proof.context -> Proof.context) -> Element.context list ->
    26     Proof.context -> (((string * typ) * mixfix) list * (string * morphism) list
    27       * Element.context_i list * Proof.context) * ((string * typ) list * Proof.context)
    28       (*FIXME*)
    29   val read_declaration: expression -> (Proof.context -> Proof.context) -> Element.context list ->
    30     Proof.context -> (((string * typ) * mixfix) list * (string * morphism) list
    31       * Element.context_i list * Proof.context) * ((string * typ) list * Proof.context)
    32   val add_locale: (local_theory -> local_theory) -> binding -> binding ->
    33     expression_i -> Element.context_i list -> theory -> string * local_theory
    34   val add_locale_cmd: (local_theory -> local_theory) -> binding -> binding ->
    35     expression -> Element.context list -> theory -> string * local_theory
    36 
    37   (* Interpretation *)
    38   val cert_goal_expression: expression_i -> Proof.context ->
    39     (term list list * (string * morphism) list * morphism) * Proof.context
    40   val read_goal_expression: expression -> Proof.context ->
    41     (term list list * (string * morphism) list * morphism) * Proof.context
    42   val sublocale: (local_theory -> local_theory) -> string -> expression_i ->
    43     (Attrib.binding * term) list -> theory -> Proof.state
    44   val sublocale_cmd: (local_theory -> local_theory) -> xstring * Position.T -> expression ->
    45     (Attrib.binding * string) list -> theory -> Proof.state
    46   val interpretation: expression_i -> (Attrib.binding * term) list -> theory -> Proof.state
    47   val interpretation_cmd: expression -> (Attrib.binding * string) list -> theory -> Proof.state
    48   val interpret: expression_i -> (Attrib.binding * term) list -> bool -> Proof.state -> Proof.state
    49   val interpret_cmd: expression -> (Attrib.binding * string) list ->
    50     bool -> Proof.state -> Proof.state
    51 
    52   (* Diagnostic *)
    53   val print_dependencies: Proof.context -> bool -> expression -> unit
    54 end;
    55 
    56 structure Expression : EXPRESSION =
    57 struct
    58 
    59 datatype ctxt = datatype Element.ctxt;
    60 
    61 
    62 (*** Expressions ***)
    63 
    64 datatype 'term map =
    65   Positional of 'term option list |
    66   Named of (string * 'term) list;
    67 
    68 type ('name, 'term) expr = ('name * ((string * bool) * 'term map)) list;
    69 
    70 type expression_i = (string, term) expr * (binding * typ option * mixfix) list;
    71 type expression = (xstring * Position.T, string) expr * (binding * string option * mixfix) list;
    72 
    73 
    74 (** Internalise locale names in expr **)
    75 
    76 fun check_expr thy instances = map (apfst (Locale.check thy)) instances;
    77 
    78 
    79 (** Parameters of expression **)
    80 
    81 (*Sanity check of instantiations and extraction of implicit parameters.
    82   The latter only occurs iff strict = false.
    83   Positional instantiations are extended to match full length of parameter list
    84   of instantiated locale.*)
    85 
    86 fun parameters_of thy strict (expr, fixed) =
    87   let
    88     fun reject_dups message xs =
    89       (case duplicates (op =) xs of
    90         [] => ()
    91       | dups => error (message ^ commas dups));
    92 
    93     fun parm_eq ((p1: string, mx1: mixfix), (p2, mx2)) = p1 = p2 andalso
    94       (mx1 = mx2 orelse error ("Conflicting syntax for parameter " ^ quote p1 ^ " in expression"));
    95 
    96     fun params_loc loc = Locale.params_of thy loc |> map (apfst #1);
    97     fun params_inst (loc, (prfx, Positional insts)) =
    98           let
    99             val ps = params_loc loc;
   100             val d = length ps - length insts;
   101             val insts' =
   102               if d < 0 then error ("More arguments than parameters in instantiation of locale " ^
   103                 quote (Locale.extern thy loc))
   104               else insts @ replicate d NONE;
   105             val ps' = (ps ~~ insts') |>
   106               map_filter (fn (p, NONE) => SOME p | (_, SOME _) => NONE);
   107           in (ps', (loc, (prfx, Positional insts'))) end
   108       | params_inst (loc, (prfx, Named insts)) =
   109           let
   110             val _ = reject_dups "Duplicate instantiation of the following parameter(s): "
   111               (map fst insts);
   112             val ps' = (insts, params_loc loc) |-> fold (fn (p, _) => fn ps =>
   113               if AList.defined (op =) ps p then AList.delete (op =) p ps
   114               else error (quote p ^ " not a parameter of instantiated expression"));
   115           in (ps', (loc, (prfx, Named insts))) end;
   116     fun params_expr is =
   117       let
   118         val (is', ps') = fold_map (fn i => fn ps =>
   119           let
   120             val (ps', i') = params_inst i;
   121             val ps'' = distinct parm_eq (ps @ ps');
   122           in (i', ps'') end) is []
   123       in (ps', is') end;
   124 
   125     val (implicit, expr') = params_expr expr;
   126 
   127     val implicit' = map #1 implicit;
   128     val fixed' = map (Variable.check_name o #1) fixed;
   129     val _ = reject_dups "Duplicate fixed parameter(s): " fixed';
   130     val implicit'' =
   131       if strict then []
   132       else
   133         let val _ = reject_dups
   134           "Parameter(s) declared simultaneously in expression and for clause: " (implicit' @ fixed')
   135         in map (fn (x, mx) => (Binding.name x, NONE, mx)) implicit end;
   136 
   137   in (expr', implicit'' @ fixed) end;
   138 
   139 
   140 (** Read instantiation **)
   141 
   142 (* Parse positional or named instantiation *)
   143 
   144 local
   145 
   146 fun prep_inst prep_term ctxt parms (Positional insts) =
   147       (insts ~~ parms) |> map
   148         (fn (NONE, p) => Free (p, dummyT)
   149           | (SOME t, _) => prep_term ctxt t)
   150   | prep_inst prep_term ctxt parms (Named insts) =
   151       parms |> map (fn p =>
   152         (case AList.lookup (op =) insts p of
   153           SOME t => prep_term ctxt t |
   154           NONE => Free (p, dummyT)));
   155 
   156 in
   157 
   158 fun parse_inst x = prep_inst Syntax.parse_term x;
   159 fun make_inst x = prep_inst (K I) x;
   160 
   161 end;
   162 
   163 
   164 (* Instantiation morphism *)
   165 
   166 fun inst_morph (parm_names, parm_types) ((prfx, mandatory), insts') ctxt =
   167   let
   168     (* parameters *)
   169     val type_parm_names = fold Term.add_tfreesT parm_types [] |> map fst;
   170 
   171     (* type inference and contexts *)
   172     val parm_types' = map (Type_Infer.paramify_vars o Logic.varifyT_global) parm_types;
   173     val type_parms = fold Term.add_tvarsT parm_types' [] |> map (Logic.mk_type o TVar);
   174     val arg = type_parms @ map2 Type.constraint parm_types' insts';
   175     val res = Syntax.check_terms ctxt arg;
   176     val ctxt' = ctxt |> fold Variable.auto_fixes res;
   177 
   178     (* instantiation *)
   179     val (type_parms'', res') = chop (length type_parms) res;
   180     val insts'' = (parm_names ~~ res') |> map_filter
   181       (fn inst as (x, Free (y, _)) => if x = y then NONE else SOME inst
   182         | inst => SOME inst);
   183     val instT = Symtab.make (type_parm_names ~~ map Logic.dest_type type_parms'');
   184     val inst = Symtab.make insts'';
   185   in
   186     (Element.inst_morphism (Proof_Context.theory_of ctxt) (instT, inst) $>
   187       Morphism.binding_morphism (Binding.prefix mandatory prfx), ctxt')
   188   end;
   189 
   190 
   191 (*** Locale processing ***)
   192 
   193 (** Parsing **)
   194 
   195 fun parse_elem prep_typ prep_term ctxt =
   196   Element.map_ctxt
   197    {binding = I,
   198     typ = prep_typ ctxt,
   199     term = prep_term (Proof_Context.set_mode Proof_Context.mode_schematic ctxt),
   200     pattern = prep_term (Proof_Context.set_mode Proof_Context.mode_pattern ctxt),
   201     fact = I,
   202     attrib = I};
   203 
   204 fun parse_concl prep_term ctxt concl =
   205   (map o map) (fn (t, ps) =>
   206     (prep_term (Proof_Context.set_mode Proof_Context.mode_schematic ctxt) t,
   207       map (prep_term (Proof_Context.set_mode Proof_Context.mode_pattern ctxt)) ps)) concl;
   208 
   209 
   210 (** Simultaneous type inference: instantiations + elements + conclusion **)
   211 
   212 local
   213 
   214 fun mk_type T = (Logic.mk_type T, []);
   215 fun mk_term t = (t, []);
   216 fun mk_propp (p, pats) = (Type.constraint propT p, pats);
   217 
   218 fun dest_type (T, []) = Logic.dest_type T;
   219 fun dest_term (t, []) = t;
   220 fun dest_propp (p, pats) = (p, pats);
   221 
   222 fun extract_inst (_, (_, ts)) = map mk_term ts;
   223 fun restore_inst ((l, (p, _)), cs) = (l, (p, map dest_term cs));
   224 
   225 fun extract_elem (Fixes fixes) = map (#2 #> the_list #> map mk_type) fixes
   226   | extract_elem (Constrains csts) = map (#2 #> single #> map mk_type) csts
   227   | extract_elem (Assumes asms) = map (#2 #> map mk_propp) asms
   228   | extract_elem (Defines defs) = map (fn (_, (t, ps)) => [mk_propp (t, ps)]) defs
   229   | extract_elem (Notes _) = [];
   230 
   231 fun restore_elem (Fixes fixes, css) =
   232       (fixes ~~ css) |> map (fn ((x, _, mx), cs) =>
   233         (x, cs |> map dest_type |> try hd, mx)) |> Fixes
   234   | restore_elem (Constrains csts, css) =
   235       (csts ~~ css) |> map (fn ((x, _), cs) =>
   236         (x, cs |> map dest_type |> hd)) |> Constrains
   237   | restore_elem (Assumes asms, css) =
   238       (asms ~~ css) |> map (fn ((b, _), cs) => (b, map dest_propp cs)) |> Assumes
   239   | restore_elem (Defines defs, css) =
   240       (defs ~~ css) |> map (fn ((b, _), [c]) => (b, dest_propp c)) |> Defines
   241   | restore_elem (Notes notes, _) = Notes notes;
   242 
   243 fun check cs context =
   244   let
   245     fun prep (_, pats) (ctxt, t :: ts) =
   246       let val ctxt' = Variable.auto_fixes t ctxt
   247       in
   248         ((t, Syntax.check_props (Proof_Context.set_mode Proof_Context.mode_pattern ctxt') pats),
   249           (ctxt', ts))
   250       end;
   251     val (cs', (context', _)) = fold_map prep cs
   252       (context, Syntax.check_terms
   253         (Proof_Context.set_mode Proof_Context.mode_schematic context) (map fst cs));
   254   in (cs', context') end;
   255 
   256 in
   257 
   258 fun check_autofix insts elems concl ctxt =
   259   let
   260     val inst_cs = map extract_inst insts;
   261     val elem_css = map extract_elem elems;
   262     val concl_cs = (map o map) mk_propp concl;
   263     (* Type inference *)
   264     val (inst_cs' :: css', ctxt') =
   265       (fold_burrow o fold_burrow) check (inst_cs :: elem_css @ [concl_cs]) ctxt;
   266     val (elem_css', [concl_cs']) = chop (length elem_css) css';
   267   in
   268     (map restore_inst (insts ~~ inst_cs'),
   269       map restore_elem (elems ~~ elem_css'),
   270       concl_cs', ctxt')
   271   end;
   272 
   273 end;
   274 
   275 
   276 (** Prepare locale elements **)
   277 
   278 fun declare_elem prep_vars (Fixes fixes) ctxt =
   279       let val (vars, _) = prep_vars fixes ctxt
   280       in ctxt |> Proof_Context.add_fixes vars |> snd end
   281   | declare_elem prep_vars (Constrains csts) ctxt =
   282       ctxt |> prep_vars (map (fn (x, T) => (Binding.name x, SOME T, NoSyn)) csts) |> snd
   283   | declare_elem _ (Assumes _) ctxt = ctxt
   284   | declare_elem _ (Defines _) ctxt = ctxt
   285   | declare_elem _ (Notes _) ctxt = ctxt;
   286 
   287 
   288 (** Finish locale elements **)
   289 
   290 fun finish_fixes (parms: (string * typ) list) = map (fn (binding, _, mx) =>
   291   let val x = Binding.name_of binding
   292   in (binding, AList.lookup (op =) parms x, mx) end);
   293 
   294 local
   295 
   296 fun closeup _ _ false elem = elem
   297   | closeup ctxt parms true elem =
   298       let
   299         (* FIXME consider closing in syntactic phase -- before type checking *)
   300         fun close_frees t =
   301           let
   302             val rev_frees =
   303               Term.fold_aterms (fn Free (x, T) =>
   304                 if AList.defined (op =) parms x then I else insert (op =) (x, T) | _ => I) t [];
   305           in fold (Logic.all o Free) rev_frees t end;
   306 
   307         fun no_binds [] = []
   308           | no_binds _ = error "Illegal term bindings in context element";
   309       in
   310         (case elem of
   311           Assumes asms => Assumes (asms |> map (fn (a, propps) =>
   312             (a, map (fn (t, ps) => (close_frees t, no_binds ps)) propps)))
   313         | Defines defs => Defines (defs |> map (fn ((name, atts), (t, ps)) =>
   314             let val ((c, _), t') = Local_Defs.cert_def ctxt (close_frees t)
   315             in ((Thm.def_binding_optional (Binding.name c) name, atts), (t', no_binds ps)) end))
   316         | e => e)
   317       end;
   318 
   319 fun finish_elem _ parms _ (Fixes fixes) = Fixes (finish_fixes parms fixes)
   320   | finish_elem _ _ _ (Constrains _) = Constrains []
   321   | finish_elem ctxt parms do_close (Assumes asms) = closeup ctxt parms do_close (Assumes asms)
   322   | finish_elem ctxt parms do_close (Defines defs) = closeup ctxt parms do_close (Defines defs)
   323   | finish_elem _ _ _ (Notes facts) = Notes facts;
   324 
   325 fun finish_inst ctxt (loc, (prfx, inst)) =
   326   let
   327     val thy = Proof_Context.theory_of ctxt;
   328     val (parm_names, parm_types) = Locale.params_of thy loc |> map #1 |> split_list;
   329     val (morph, _) = inst_morph (parm_names, parm_types) (prfx, inst) ctxt;
   330   in (loc, morph) end;
   331 
   332 in
   333 
   334 fun finish ctxt parms do_close insts elems =
   335   let
   336     val deps = map (finish_inst ctxt) insts;
   337     val elems' = map (finish_elem ctxt parms do_close) elems;
   338   in (deps, elems') end;
   339 
   340 end;
   341 
   342 
   343 (** Process full context statement: instantiations + elements + conclusion **)
   344 
   345 (* Interleave incremental parsing and type inference over entire parsed stretch. *)
   346 
   347 local
   348 
   349 fun prep_full_context_statement
   350     parse_typ parse_prop prep_vars_elem prep_inst prep_vars_inst prep_expr
   351     {strict, do_close, fixed_frees} raw_import init_body raw_elems raw_concl ctxt1 =
   352   let
   353     val thy = Proof_Context.theory_of ctxt1;
   354 
   355     val (raw_insts, fixed) = parameters_of thy strict (apfst (prep_expr thy) raw_import);
   356 
   357     fun prep_insts_cumulative (loc, (prfx, inst)) (i, insts, ctxt) =
   358       let
   359         val (parm_names, parm_types) = Locale.params_of thy loc |> map #1 |> split_list;
   360         val inst' = prep_inst ctxt parm_names inst;
   361         val parm_types' = parm_types
   362           |> map (Type_Infer.paramify_vars o
   363               Term.map_type_tvar (fn ((x, _), S) => TVar ((x, i), S)) o Logic.varifyT_global);
   364         val inst'' = map2 Type.constraint parm_types' inst';
   365         val insts' = insts @ [(loc, (prfx, inst''))];
   366         val (insts'', _, _, _) = check_autofix insts' [] [] ctxt;
   367         val inst''' = insts'' |> List.last |> snd |> snd;
   368         val (morph, _) = inst_morph (parm_names, parm_types) (prfx, inst''') ctxt;
   369         val ctxt'' = Locale.activate_declarations (loc, morph) ctxt;
   370       in (i + 1, insts', ctxt'') end;
   371 
   372     fun prep_elem insts raw_elem ctxt =
   373       let
   374         val ctxt' = ctxt
   375           |> Context_Position.set_visible false
   376           |> declare_elem prep_vars_elem raw_elem
   377           |> Context_Position.restore_visible ctxt;
   378         val elems' = parse_elem parse_typ parse_prop ctxt' raw_elem;
   379       in (elems', ctxt') end;
   380 
   381     fun prep_concl raw_concl (insts, elems, ctxt) =
   382       let
   383         val concl = parse_concl parse_prop ctxt raw_concl;
   384       in check_autofix insts elems concl ctxt end;
   385 
   386     val fors = prep_vars_inst fixed ctxt1 |> fst;
   387     val ctxt2 = ctxt1 |> Proof_Context.add_fixes fors |> snd;
   388     val (_, insts', ctxt3) = fold prep_insts_cumulative raw_insts (0, [], ctxt2);
   389 
   390     val _ =
   391       if fixed_frees then ()
   392       else
   393         (case fold (fold (Variable.add_frees ctxt3) o snd o snd) insts' [] of
   394           [] => ()
   395         | frees => error ("Illegal free variables in expression: " ^
   396             commas_quote (map (Syntax.string_of_term ctxt3 o Free) (rev frees))));
   397 
   398     val ctxt4 = init_body ctxt3;
   399     val (elems, ctxt5) = fold_map (prep_elem insts') raw_elems ctxt4;
   400     val (insts, elems', concl, ctxt6) = prep_concl raw_concl (insts', elems, ctxt5);
   401 
   402     (* Retrieve parameter types *)
   403     val xs = fold (fn Fixes fixes => (fn ps => ps @ map (Variable.check_name o #1) fixes)
   404       | _ => fn ps => ps) (Fixes fors :: elems') [];
   405     val (Ts, ctxt7) = fold_map Proof_Context.inferred_param xs ctxt6;
   406     val parms = xs ~~ Ts;  (* params from expression and elements *)
   407 
   408     val fors' = finish_fixes parms fors;
   409     val fixed = map (fn (b, SOME T, mx) => ((Binding.name_of b, T), mx)) fors';
   410     val (deps, elems'') = finish ctxt6 parms do_close insts elems';
   411 
   412   in ((fixed, deps, elems'', concl), (parms, ctxt7)) end
   413 
   414 in
   415 
   416 fun cert_full_context_statement x =
   417   prep_full_context_statement (K I) (K I) Proof_Context.cert_vars
   418   make_inst Proof_Context.cert_vars (K I) x;
   419 
   420 fun cert_read_full_context_statement x =
   421   prep_full_context_statement Syntax.parse_typ Syntax.parse_prop Proof_Context.read_vars
   422   make_inst Proof_Context.cert_vars (K I) x;
   423 
   424 fun read_full_context_statement x =
   425   prep_full_context_statement Syntax.parse_typ Syntax.parse_prop Proof_Context.read_vars
   426   parse_inst Proof_Context.read_vars check_expr x;
   427 
   428 end;
   429 
   430 
   431 (* Context statement: elements + conclusion *)
   432 
   433 local
   434 
   435 fun prep_statement prep activate raw_elems raw_concl context =
   436   let
   437     val ((_, _, elems, concl), _) =
   438       prep {strict = true, do_close = false, fixed_frees = true}
   439         ([], []) I raw_elems raw_concl context;
   440     val (_, context') = context
   441       |> Proof_Context.set_stmt true
   442       |> fold_map activate elems;
   443   in (concl, context') end;
   444 
   445 in
   446 
   447 fun cert_statement x = prep_statement cert_full_context_statement Element.activate_i x;
   448 fun read_statement x = prep_statement read_full_context_statement Element.activate x;
   449 
   450 end;
   451 
   452 
   453 (* Locale declaration: import + elements *)
   454 
   455 fun fix_params params =
   456   Proof_Context.add_fixes (map (fn ((x, T), mx) => (Binding.name x, SOME T, mx)) params) #> snd;
   457 
   458 local
   459 
   460 fun prep_declaration prep activate raw_import init_body raw_elems context =
   461   let
   462     val ((fixed, deps, elems, _), (parms, ctxt')) =
   463       prep {strict = false, do_close = true, fixed_frees = false}
   464         raw_import init_body raw_elems [] context;
   465     (* Declare parameters and imported facts *)
   466     val context' = context |>
   467       fix_params fixed |>
   468       fold (Context.proof_map o Locale.activate_facts NONE) deps;
   469     val (elems', context'') = context' |>
   470       Proof_Context.set_stmt true |>
   471       fold_map activate elems;
   472   in ((fixed, deps, elems', context''), (parms, ctxt')) end;
   473 
   474 in
   475 
   476 fun cert_declaration x = prep_declaration cert_full_context_statement Element.activate_i x;
   477 fun cert_read_declaration x = prep_declaration cert_read_full_context_statement Element.activate x;
   478 fun read_declaration x = prep_declaration read_full_context_statement Element.activate x;
   479 
   480 end;
   481 
   482 
   483 (* Locale expression to set up a goal *)
   484 
   485 local
   486 
   487 fun props_of thy (name, morph) =
   488   let
   489     val (asm, defs) = Locale.specification_of thy name;
   490   in
   491     (case asm of NONE => defs | SOME asm => asm :: defs) |> map (Morphism.term morph)
   492   end;
   493 
   494 fun prep_goal_expression prep expression context =
   495   let
   496     val thy = Proof_Context.theory_of context;
   497 
   498     val ((fixed, deps, _, _), _) =
   499       prep {strict = true, do_close = true, fixed_frees = true} expression I [] [] context;
   500     (* proof obligations *)
   501     val propss = map (props_of thy) deps;
   502 
   503     val goal_ctxt = context |>
   504       fix_params fixed |>
   505       (fold o fold) Variable.auto_fixes propss;
   506 
   507     val export = Variable.export_morphism goal_ctxt context;
   508     val exp_fact = Drule.zero_var_indexes_list o map Thm.strip_shyps o Morphism.fact export;
   509     val exp_term = Term_Subst.zero_var_indexes o Morphism.term export;
   510     val exp_typ = Logic.type_map exp_term;
   511     val export' =
   512       Morphism.morphism {binding = [], typ = [exp_typ], term = [exp_term], fact = [exp_fact]};
   513   in ((propss, deps, export'), goal_ctxt) end;
   514 
   515 in
   516 
   517 fun cert_goal_expression x = prep_goal_expression cert_full_context_statement x;
   518 fun read_goal_expression x = prep_goal_expression read_full_context_statement x;
   519 
   520 end;
   521 
   522 
   523 (*** Locale declarations ***)
   524 
   525 (* extract specification text *)
   526 
   527 val norm_term = Envir.beta_norm oo Term.subst_atomic;
   528 
   529 fun bind_def ctxt eq (xs, env, eqs) =
   530   let
   531     val _ = Local_Defs.cert_def ctxt eq;
   532     val ((y, T), b) = Local_Defs.abs_def eq;
   533     val b' = norm_term env b;
   534     fun err msg = error (msg ^ ": " ^ quote y);
   535   in
   536     (case filter (fn (Free (y', _), _) => y = y' | _ => false) env of
   537       [] => (Term.add_frees b' xs, (Free (y, T), b') :: env, eq :: eqs)
   538     | dups =>
   539         if forall (fn (_, b'') => b' aconv b'') dups then (xs, env, eqs)
   540         else err "Attempt to redefine variable")
   541   end;
   542 
   543 (* text has the following structure:
   544        (((exts, exts'), (ints, ints')), (xs, env, defs))
   545    where
   546      exts: external assumptions (terms in assumes elements)
   547      exts': dito, normalised wrt. env
   548      ints: internal assumptions (terms in assumptions from insts)
   549      ints': dito, normalised wrt. env
   550      xs: the free variables in exts' and ints' and rhss of definitions,
   551        this includes parameters except defined parameters
   552      env: list of term pairs encoding substitutions, where the first term
   553        is a free variable; substitutions represent defines elements and
   554        the rhs is normalised wrt. the previous env
   555      defs: the equations from the defines elements
   556    *)
   557 
   558 fun eval_text _ _ (Fixes _) text = text
   559   | eval_text _ _ (Constrains _) text = text
   560   | eval_text _ is_ext (Assumes asms)
   561         (((exts, exts'), (ints, ints')), (xs, env, defs)) =
   562       let
   563         val ts = maps (map #1 o #2) asms;
   564         val ts' = map (norm_term env) ts;
   565         val spec' =
   566           if is_ext then ((exts @ ts, exts' @ ts'), (ints, ints'))
   567           else ((exts, exts'), (ints @ ts, ints' @ ts'));
   568       in (spec', (fold Term.add_frees ts' xs, env, defs)) end
   569   | eval_text ctxt _ (Defines defs) (spec, binds) =
   570       (spec, fold (bind_def ctxt o #1 o #2) defs binds)
   571   | eval_text _ _ (Notes _) text = text;
   572 
   573 fun eval_inst ctxt (loc, morph) text =
   574   let
   575     val thy = Proof_Context.theory_of ctxt;
   576     val (asm, defs) = Locale.specification_of thy loc;
   577     val asm' = Option.map (Morphism.term morph) asm;
   578     val defs' = map (Morphism.term morph) defs;
   579     val text' = text |>
   580       (if is_some asm
   581         then eval_text ctxt false (Assumes [(Attrib.empty_binding, [(the asm', [])])])
   582         else I) |>
   583       (if not (null defs)
   584         then eval_text ctxt false (Defines (map (fn def => (Attrib.empty_binding, (def, []))) defs'))
   585         else I)
   586 (* FIXME clone from locale.ML *)
   587   in text' end;
   588 
   589 fun eval_elem ctxt elem text =
   590   eval_text ctxt true elem text;
   591 
   592 fun eval ctxt deps elems =
   593   let
   594     val text' = fold (eval_inst ctxt) deps ((([], []), ([], [])), ([], [], []));
   595     val ((spec, (_, _, defs))) = fold (eval_elem ctxt) elems text';
   596   in (spec, defs) end;
   597 
   598 (* axiomsN: name of theorem set with destruct rules for locale predicates,
   599      also name suffix of delta predicates and assumptions. *)
   600 
   601 val axiomsN = "axioms";
   602 
   603 local
   604 
   605 (* introN: name of theorems for introduction rules of locale and
   606      delta predicates *)
   607 
   608 val introN = "intro";
   609 
   610 fun atomize_spec thy ts =
   611   let
   612     val t = Logic.mk_conjunction_balanced ts;
   613     val body = Object_Logic.atomize_term thy t;
   614     val bodyT = Term.fastype_of body;
   615   in
   616     if bodyT = propT then (t, propT, Thm.reflexive (Thm.cterm_of thy t))
   617     else (body, bodyT, Object_Logic.atomize (Thm.cterm_of thy t))
   618   end;
   619 
   620 (* achieve plain syntax for locale predicates (without "PROP") *)
   621 
   622 fun aprop_tr' n c = (Lexicon.mark_const c, fn ctxt => fn args =>
   623   if length args = n then
   624     Syntax.const "_aprop" $   (* FIXME avoid old-style early externing (!??) *)
   625       Term.list_comb (Syntax.free (Proof_Context.extern_const ctxt c), args)
   626   else raise Match);
   627 
   628 (* define one predicate including its intro rule and axioms
   629    - binding: predicate name
   630    - parms: locale parameters
   631    - defs: thms representing substitutions from defines elements
   632    - ts: terms representing locale assumptions (not normalised wrt. defs)
   633    - norm_ts: terms representing locale assumptions (normalised wrt. defs)
   634    - thy: the theory
   635 *)
   636 
   637 fun def_pred binding parms defs ts norm_ts thy =
   638   let
   639     val name = Sign.full_name thy binding;
   640 
   641     val (body, bodyT, body_eq) = atomize_spec thy norm_ts;
   642     val env = Term.add_free_names body [];
   643     val xs = filter (member (op =) env o #1) parms;
   644     val Ts = map #2 xs;
   645     val extraTs =
   646       (subtract (op =) (fold Term.add_tfreesT Ts []) (Term.add_tfrees body []))
   647       |> Library.sort_wrt #1 |> map TFree;
   648     val predT = map Term.itselfT extraTs ---> Ts ---> bodyT;
   649 
   650     val args = map Logic.mk_type extraTs @ map Free xs;
   651     val head = Term.list_comb (Const (name, predT), args);
   652     val statement = Object_Logic.ensure_propT thy head;
   653 
   654     val ([pred_def], defs_thy) =
   655       thy
   656       |> bodyT = propT ? Sign.add_advanced_trfuns ([], [], [aprop_tr' (length args) name], [])
   657       |> Sign.declare_const_global ((Binding.conceal binding, predT), NoSyn) |> snd
   658       |> Global_Theory.add_defs false
   659         [((Binding.conceal (Thm.def_binding binding), Logic.mk_equals (head, body)), [])];
   660     val defs_ctxt = Proof_Context.init_global defs_thy |> Variable.declare_term head;
   661 
   662     val cert = Thm.cterm_of defs_thy;
   663 
   664     val intro = Goal.prove_global defs_thy [] norm_ts statement (fn _ =>
   665       rewrite_goals_tac [pred_def] THEN
   666       Tactic.compose_tac (false, body_eq RS Drule.equal_elim_rule1, 1) 1 THEN
   667       Tactic.compose_tac (false,
   668         Conjunction.intr_balanced (map (Thm.assume o cert) norm_ts), 0) 1);
   669 
   670     val conjuncts =
   671       (Drule.equal_elim_rule2 OF [body_eq,
   672         Raw_Simplifier.rewrite_rule [pred_def] (Thm.assume (cert statement))])
   673       |> Conjunction.elim_balanced (length ts);
   674     val axioms = ts ~~ conjuncts |> map (fn (t, ax) =>
   675       Element.prove_witness defs_ctxt t
   676        (rewrite_goals_tac defs THEN
   677         Tactic.compose_tac (false, ax, 0) 1));
   678   in ((statement, intro, axioms), defs_thy) end;
   679 
   680 in
   681 
   682 (* main predicate definition function *)
   683 
   684 fun define_preds binding parms (((exts, exts'), (ints, ints')), defs) thy =
   685   let
   686     val defs' = map (cterm_of thy #> Assumption.assume #> Drule.abs_def) defs;
   687 
   688     val (a_pred, a_intro, a_axioms, thy'') =
   689       if null exts then (NONE, NONE, [], thy)
   690       else
   691         let
   692           val abinding = if null ints then binding else Binding.suffix_name ("_" ^ axiomsN) binding;
   693           val ((statement, intro, axioms), thy') =
   694             thy
   695             |> def_pred abinding parms defs' exts exts';
   696           val (_, thy'') =
   697             thy'
   698             |> Sign.qualified_path true abinding
   699             |> Global_Theory.note_thmss ""
   700               [((Binding.conceal (Binding.name introN), []), [([intro], [Locale.unfold_add])])]
   701             ||> Sign.restore_naming thy';
   702           in (SOME statement, SOME intro, axioms, thy'') end;
   703     val (b_pred, b_intro, b_axioms, thy'''') =
   704       if null ints then (NONE, NONE, [], thy'')
   705       else
   706         let
   707           val ((statement, intro, axioms), thy''') =
   708             thy''
   709             |> def_pred binding parms defs' (ints @ the_list a_pred) (ints' @ the_list a_pred);
   710           val (_, thy'''') =
   711             thy'''
   712             |> Sign.qualified_path true binding
   713             |> Global_Theory.note_thmss ""
   714                  [((Binding.conceal (Binding.name introN), []), [([intro], [Locale.intro_add])]),
   715                   ((Binding.conceal (Binding.name axiomsN), []),
   716                     [(map (Drule.export_without_context o Element.conclude_witness) axioms, [])])]
   717             ||> Sign.restore_naming thy''';
   718         in (SOME statement, SOME intro, axioms, thy'''') end;
   719   in ((a_pred, a_intro, a_axioms), (b_pred, b_intro, b_axioms), thy'''') end;
   720 
   721 end;
   722 
   723 
   724 local
   725 
   726 fun assumes_to_notes (Assumes asms) axms =
   727       fold_map (fn (a, spec) => fn axs =>
   728           let val (ps, qs) = chop (length spec) axs
   729           in ((a, [(ps, [])]), qs) end) asms axms
   730       |> apfst (curry Notes "")
   731   | assumes_to_notes e axms = (e, axms);
   732 
   733 fun defines_to_notes thy (Defines defs) =
   734       Notes ("", map (fn (a, (def, _)) =>
   735         (a, [([Assumption.assume (cterm_of thy def)],
   736           [(Attrib.internal o K) Locale.witness_add])])) defs)
   737   | defines_to_notes _ e = e;
   738 
   739 fun gen_add_locale prep_decl
   740     before_exit binding raw_predicate_binding raw_import raw_body thy =
   741   let
   742     val name = Sign.full_name thy binding;
   743     val _ = Locale.defined thy name andalso
   744       error ("Duplicate definition of locale " ^ quote name);
   745 
   746     val ((fixed, deps, body_elems, _), (parms, ctxt')) =
   747       prep_decl raw_import I raw_body (Proof_Context.init_global thy);
   748     val text as (((_, exts'), _), defs) = eval ctxt' deps body_elems;
   749 
   750     val extraTs =
   751       subtract (op =) (fold Term.add_tfreesT (map snd parms) []) (fold Term.add_tfrees exts' []);
   752     val _ =
   753       if null extraTs then ()
   754       else warning ("Additional type variable(s) in locale specification " ^
   755           Binding.print binding ^ ": " ^
   756           commas (map (Syntax.string_of_typ ctxt' o TFree) (sort_wrt #1 extraTs)));
   757 
   758     val predicate_binding =
   759       if Binding.is_empty raw_predicate_binding then binding
   760       else raw_predicate_binding;
   761     val ((a_statement, a_intro, a_axioms), (b_statement, b_intro, b_axioms), thy') =
   762       define_preds predicate_binding parms text thy;
   763 
   764     val a_satisfy = Element.satisfy_morphism a_axioms;
   765     val b_satisfy = Element.satisfy_morphism b_axioms;
   766 
   767     val params = fixed @
   768       maps (fn Fixes fixes =>
   769         map (fn (b, SOME T, mx) => ((Binding.name_of b, T), mx)) fixes | _ => []) body_elems;
   770     val asm = if is_some b_statement then b_statement else a_statement;
   771 
   772     val notes =
   773       if is_some asm then
   774         [("", [((Binding.conceal (Binding.suffix_name ("_" ^ axiomsN) binding), []),
   775           [([Assumption.assume (cterm_of thy' (the asm))],
   776             [(Attrib.internal o K) Locale.witness_add])])])]
   777       else [];
   778 
   779     val notes' = body_elems |>
   780       map (defines_to_notes thy') |>
   781       map (Element.transform_ctxt a_satisfy) |>
   782       (fn elems => fold_map assumes_to_notes elems (map Element.conclude_witness a_axioms)) |>
   783       fst |>
   784       map (Element.transform_ctxt b_satisfy) |>
   785       map_filter (fn Notes notes => SOME notes | _ => NONE);
   786 
   787     val deps' = map (fn (l, morph) => (l, morph $> b_satisfy)) deps;
   788     val axioms = map Element.conclude_witness b_axioms;
   789 
   790     val loc_ctxt = thy'
   791       |> Locale.register_locale binding (extraTs, params)
   792           (asm, rev defs) (a_intro, b_intro) axioms [] (rev notes) (rev deps')
   793       |> Named_Target.init before_exit name
   794       |> fold (fn (kind, facts) => Local_Theory.notes_kind kind facts #> snd) notes';
   795 
   796   in (name, loc_ctxt) end;
   797 
   798 in
   799 
   800 val add_locale = gen_add_locale cert_declaration;
   801 val add_locale_cmd = gen_add_locale read_declaration;
   802 
   803 end;
   804 
   805 
   806 (*** Interpretation ***)
   807 
   808 fun read_with_extended_syntax parse_prop deps ctxt props =
   809   let
   810     val deps_ctxt = fold Locale.activate_declarations deps ctxt;
   811   in
   812     map (parse_prop deps_ctxt o snd) props |> Syntax.check_terms deps_ctxt
   813       |> Variable.export_terms deps_ctxt ctxt
   814   end;
   815 
   816 fun meta_rewrite ctxt = map (Local_Defs.meta_rewrite_rule ctxt #> Drule.abs_def);
   817 
   818 
   819 (** Interpretation in theories and proof contexts **)
   820 
   821 local
   822 
   823 fun note_eqns_register deps witss attrss eqns export export' =
   824   Attrib.generic_notes Thm.lemmaK
   825     (attrss ~~ map (fn eqn => [([Morphism.thm (export' $> export) eqn], [])]) eqns)
   826   #-> (fn facts => `(fn context => meta_rewrite (Context.proof_of context) (maps snd facts)))
   827   #-> (fn eqns => fold (fn ((dep, morph), wits) =>
   828     fn context =>
   829       Locale.add_registration
   830         (dep, morph $> Element.satisfy_morphism (map (Element.transform_witness export') wits))
   831         (Element.eq_morphism (Context.theory_of context) eqns |> Option.map (rpair true))
   832         export context) (deps ~~ witss));
   833 
   834 fun gen_interpretation prep_expr parse_prop prep_attr
   835     expression equations thy =
   836   let
   837     val ((propss, deps, export), expr_ctxt) = Proof_Context.init_global thy
   838       |> prep_expr expression;
   839     val eqns = read_with_extended_syntax parse_prop deps expr_ctxt equations;
   840 
   841     val attrss = map (apsnd (map (prep_attr thy)) o fst) equations;
   842     val goal_ctxt = fold Variable.auto_fixes eqns expr_ctxt;
   843     val export' = Variable.export_morphism goal_ctxt expr_ctxt;
   844 
   845     fun after_qed witss eqns =
   846       (Proof_Context.background_theory o Context.theory_map)
   847         (note_eqns_register deps witss attrss eqns export export');
   848 
   849   in Element.witness_proof_eqs after_qed propss eqns goal_ctxt end;
   850 
   851 fun gen_interpret prep_expr parse_prop prep_attr
   852     expression equations int state =
   853   let
   854     val _ = Proof.assert_forward_or_chain state;
   855     val ctxt = Proof.context_of state;
   856     val thy = Proof_Context.theory_of ctxt;
   857 
   858     val ((propss, deps, export), expr_ctxt) = prep_expr expression ctxt;
   859     val eqns = read_with_extended_syntax parse_prop deps expr_ctxt equations;
   860 
   861     val attrss = map (apsnd (map (prep_attr thy)) o fst) equations;
   862     val goal_ctxt = fold Variable.auto_fixes eqns expr_ctxt;
   863     val export' = Variable.export_morphism goal_ctxt expr_ctxt;
   864 
   865     fun after_qed witss eqns =
   866       (Proof.map_context o Context.proof_map)
   867         (note_eqns_register deps witss attrss eqns export export')
   868       #> Proof.reset_facts;
   869   in
   870     state
   871     |> Element.witness_local_proof_eqs after_qed "interpret" propss eqns goal_ctxt int
   872   end;
   873 
   874 in
   875 
   876 fun interpretation x = gen_interpretation cert_goal_expression (K I) (K I) x;
   877 fun interpretation_cmd x = gen_interpretation read_goal_expression
   878   Syntax.parse_prop Attrib.intern_src x;
   879 
   880 fun interpret x = gen_interpret cert_goal_expression (K I) (K I) x;
   881 fun interpret_cmd x = gen_interpret read_goal_expression
   882   Syntax.parse_prop Attrib.intern_src x;
   883 
   884 end;
   885 
   886 
   887 (** Interpretation between locales: declaring sublocale relationships **)
   888 
   889 local
   890 
   891 fun note_eqns_dependency target deps witss attrss eqns export export' ctxt =
   892   let
   893     val facts =
   894       (attrss ~~ map (fn eqn => [([Morphism.thm (export' $> export) eqn], [])]) eqns);
   895     val eqns' = ctxt
   896       |> Attrib.local_notes Thm.lemmaK facts
   897       |-> (fn facts => `(fn ctxt => meta_rewrite ctxt (maps snd facts)))
   898       |> fst;  (* FIXME duplication to add_thmss *)
   899   in
   900     ctxt
   901     |> Locale.add_thmss target Thm.lemmaK (Attrib.partial_evaluation ctxt facts)
   902     |> Proof_Context.background_theory (fold (fn ((dep, morph), wits) =>
   903       fn thy =>
   904         Locale.add_dependency target
   905           (dep, morph $> Element.satisfy_morphism (map (Element.transform_witness export') wits))
   906           (Element.eq_morphism thy eqns' |> Option.map (rpair true))
   907           export thy) (deps ~~ witss))
   908   end;
   909 
   910 fun gen_sublocale prep_expr prep_loc parse_prop prep_attr
   911     before_exit raw_target expression equations thy =
   912   let
   913     val target = prep_loc thy raw_target;
   914     val target_ctxt = Named_Target.init before_exit target thy;
   915     val ((propss, deps, export), expr_ctxt) = prep_expr expression target_ctxt;
   916     val eqns = read_with_extended_syntax parse_prop deps expr_ctxt equations;
   917 
   918     val attrss = map (apsnd (map (prep_attr thy)) o fst) equations;
   919     val goal_ctxt = fold Variable.auto_fixes eqns expr_ctxt;
   920     val export' = Variable.export_morphism goal_ctxt expr_ctxt;
   921 
   922     fun after_qed witss eqns =
   923       note_eqns_dependency target deps witss attrss eqns export export';
   924 
   925   in Element.witness_proof_eqs after_qed propss eqns goal_ctxt end;
   926 in
   927 
   928 fun sublocale x = gen_sublocale cert_goal_expression (K I) (K I) (K I) x;
   929 fun sublocale_cmd x =
   930   gen_sublocale read_goal_expression Locale.check Syntax.parse_prop Attrib.intern_src x;
   931 
   932 end;
   933 
   934 
   935 (** Print the instances that would be activated by an interpretation
   936   of the expression in the current context (clean = false) or in an
   937   empty context (clean = true). **)
   938 
   939 fun print_dependencies ctxt clean expression =
   940   let
   941     val ((_, deps, export), expr_ctxt) = read_goal_expression expression ctxt;
   942   in
   943     Locale.print_dependencies expr_ctxt clean export deps
   944   end;
   945 
   946 end;
   947