src/Pure/sign.ML
author wenzelm
Thu Apr 17 18:46:58 1997 +0200 (1997-04-17)
changeset 2979 db6941221197
parent 2963 f3b5af1c5a67
child 3552 f348e8a2db4b
permissions -rw-r--r--
improved type check error messages;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 The abstract type "sg" of signatures.
     6 *)
     7 
     8 signature SIGN =
     9   sig
    10   type sg
    11   val rep_sg: sg ->
    12    {tsig: Type.type_sig,
    13     const_tab: typ Symtab.table,
    14     syn: Syntax.syntax,
    15     stamps: string ref list}
    16   val subsig: sg * sg -> bool
    17   val eq_sg: sg * sg -> bool
    18   val same_sg: sg * sg -> bool
    19   val is_draft: sg -> bool
    20   val const_type: sg -> string -> typ option
    21   val classes: sg -> class list
    22   val subsort: sg -> sort * sort -> bool
    23   val nodup_Vars: term -> unit
    24   val norm_sort: sg -> sort -> sort
    25   val nonempty_sort: sg -> sort list -> sort -> bool
    26   val print_sg: sg -> unit
    27   val pretty_sg: sg -> Pretty.T
    28   val pprint_sg: sg -> pprint_args -> unit
    29   val pretty_term: sg -> term -> Pretty.T
    30   val pretty_typ: sg -> typ -> Pretty.T
    31   val pretty_sort: sort -> Pretty.T
    32   val string_of_term: sg -> term -> string
    33   val string_of_typ: sg -> typ -> string
    34   val pprint_term: sg -> term -> pprint_args -> unit
    35   val pprint_typ: sg -> typ -> pprint_args -> unit
    36   val certify_typ: sg -> typ -> typ
    37   val certify_term: sg -> term -> term * typ * int
    38   val read_typ: sg * (indexname -> sort option) -> string -> typ
    39   val infer_types: sg -> (indexname -> typ option) ->
    40     (indexname -> sort option) -> string list -> bool
    41     -> term list * typ -> int * term * (indexname * typ) list
    42   val add_classes: (class * class list) list -> sg -> sg
    43   val add_classrel: (class * class) list -> sg -> sg
    44   val add_defsort: sort -> sg -> sg
    45   val add_types: (string * int * mixfix) list -> sg -> sg
    46   val add_tyabbrs: (string * string list * string * mixfix) list -> sg -> sg
    47   val add_tyabbrs_i: (string * string list * typ * mixfix) list -> sg -> sg
    48   val add_arities: (string * sort list * sort) list -> sg -> sg
    49   val add_consts: (string * string * mixfix) list -> sg -> sg
    50   val add_consts_i: (string * typ * mixfix) list -> sg -> sg
    51   val add_syntax: (string * string * mixfix) list -> sg -> sg
    52   val add_syntax_i: (string * typ * mixfix) list -> sg -> sg
    53   val add_modesyntax: (string * bool) * (string * string * mixfix) list -> sg -> sg
    54   val add_modesyntax_i: (string * bool) * (string * typ * mixfix) list -> sg -> sg
    55   val add_trfuns:
    56     (string * (ast list -> ast)) list *
    57     (string * (term list -> term)) list *
    58     (string * (term list -> term)) list *
    59     (string * (ast list -> ast)) list -> sg -> sg
    60   val add_trfunsT:
    61     (string * (typ -> term list -> term)) list -> sg -> sg
    62   val add_tokentrfuns:
    63     (string * string * (string -> string * int)) list -> sg -> sg
    64   val add_trrules: (string * string) Syntax.trrule list -> sg -> sg
    65   val add_trrules_i: ast Syntax.trrule list -> sg -> sg
    66   val add_name: string -> sg -> sg
    67   val make_draft: sg -> sg
    68   val merge: sg * sg -> sg
    69   val proto_pure: sg
    70   val pure: sg
    71   val cpure: sg
    72   val const_of_class: class -> string
    73   val class_of_const: string -> class
    74   end;
    75 
    76 structure Sign : SIGN =
    77 struct
    78 
    79 
    80 (** datatype sg **)
    81 
    82 (*the "ref" in stamps ensures that no two signatures are identical -- it is
    83   impossible to forge a signature*)
    84 
    85 datatype sg =
    86   Sg of {
    87     tsig: Type.type_sig,            (*order-sorted signature of types*)
    88     const_tab: typ Symtab.table,    (*types of constants*)
    89     syn: Syntax.syntax,             (*syntax for parsing and printing*)
    90     stamps: string ref list};       (*unique theory indentifier*)
    91 
    92 fun rep_sg (Sg args) = args;
    93 val tsig_of = #tsig o rep_sg;
    94 
    95 
    96 (* inclusion and equality *)
    97 
    98 local
    99   (*avoiding polymorphic equality: factor 10 speedup*)
   100   fun mem_stamp (_:string ref, []) = false
   101     | mem_stamp (x, y :: ys) = x = y orelse mem_stamp (x, ys);
   102 
   103   fun subset_stamp ([], ys) = true
   104     | subset_stamp (x :: xs, ys) =
   105         mem_stamp (x, ys) andalso subset_stamp (xs, ys);
   106 
   107   (*fast partial test*)
   108   fun fast_sub ([]: string ref list, _) = true
   109     | fast_sub (_, []) = false
   110     | fast_sub (x :: xs, y :: ys) =
   111         if x = y then fast_sub (xs, ys)
   112         else fast_sub (x :: xs, ys);
   113 in
   114   fun subsig (Sg {stamps = s1, ...}, Sg {stamps = s2, ...}) =
   115     s1 = s2 orelse subset_stamp (s1, s2);
   116 
   117   fun fast_subsig (Sg {stamps = s1, ...}, Sg {stamps = s2, ...}) =
   118     s1 = s2 orelse fast_sub (s1, s2);
   119 
   120   fun eq_sg (Sg {stamps = s1, ...}, Sg {stamps = s2, ...}) =
   121     s1 = s2 orelse (subset_stamp (s1, s2) andalso subset_stamp (s2, s1));
   122 end;
   123 
   124 
   125 (*test if same theory names are contained in signatures' stamps,
   126   i.e. if signatures belong to same theory but not necessarily to the
   127   same version of it*)
   128 fun same_sg (Sg {stamps = s1, ...}, Sg {stamps = s2, ...}) =
   129   eq_set_string (pairself (map (op !)) (s1, s2));
   130 
   131 (*test for drafts*)
   132 fun is_draft (Sg {stamps = ref "#" :: _, ...}) = true
   133   | is_draft _ = false;
   134 
   135 
   136 (* consts *)
   137 
   138 fun const_type (Sg {const_tab, ...}) c = Symtab.lookup (const_tab, c);
   139 
   140 
   141 (* classes and sorts *)
   142 
   143 val classes = #classes o Type.rep_tsig o tsig_of;
   144 
   145 val subsort = Type.subsort o tsig_of;
   146 val norm_sort = Type.norm_sort o tsig_of;
   147 val nonempty_sort = Type.nonempty_sort o tsig_of;
   148 
   149 (* FIXME move to Sorts? *)
   150 fun pretty_sort [c] = Pretty.str c
   151   | pretty_sort cs = Pretty.str_list "{" "}" cs;
   152 
   153 
   154 
   155 (** print signature **)
   156 
   157 fun stamp_names stamps = rev (map ! stamps);
   158 
   159 fun print_sg sg =
   160   let
   161     fun prt_typ syn ty = Pretty.quote (Syntax.pretty_typ syn ty);
   162 
   163     fun pretty_classrel (cl, cls) = Pretty.block
   164       (Pretty.str (cl ^ " <") :: Pretty.brk 1 ::
   165         Pretty.commas (map Pretty.str cls));
   166 
   167     fun pretty_default cls = Pretty.block
   168       [Pretty.str "default:", Pretty.brk 1, pretty_sort cls];
   169 
   170     fun pretty_ty (ty, n) = Pretty.str (ty ^ " " ^ string_of_int n);
   171 
   172     fun pretty_abbr syn (ty, (vs, rhs)) = Pretty.block
   173       [prt_typ syn (Type (ty, map (fn v => TVar ((v, 0), [])) vs)),
   174         Pretty.str " =", Pretty.brk 1, prt_typ syn rhs];
   175 
   176     fun pretty_arity ty (cl, []) = Pretty.block
   177           [Pretty.str (ty ^ " ::"), Pretty.brk 1, Pretty.str cl]
   178       | pretty_arity ty (cl, srts) = Pretty.block
   179           [Pretty.str (ty ^ " ::"), Pretty.brk 1,
   180             Pretty.list "(" ")" (map pretty_sort srts),
   181             Pretty.brk 1, Pretty.str cl];
   182 
   183     fun pretty_arities (ty, ars) = map (pretty_arity ty) ars;
   184 
   185     fun pretty_const syn (c, ty) = Pretty.block
   186       [Pretty.str (quote c ^ " ::"), Pretty.brk 1, prt_typ syn ty];
   187 
   188 
   189     val Sg {tsig, const_tab, syn, stamps} = sg;
   190     val {classes, classrel, default, tycons, abbrs, arities} =
   191       Type.rep_tsig tsig;
   192   in
   193     Pretty.writeln (Pretty.strs ("stamps:" :: stamp_names stamps));
   194     Pretty.writeln (Pretty.strs ("classes:" :: classes));
   195     Pretty.writeln (Pretty.big_list "classrel:" (map pretty_classrel classrel));
   196     Pretty.writeln (pretty_default default);
   197     Pretty.writeln (Pretty.big_list "types:" (map pretty_ty tycons));
   198     Pretty.writeln (Pretty.big_list "abbrs:" (map (pretty_abbr syn) abbrs));
   199     Pretty.writeln (Pretty.big_list "arities:"
   200       (List.concat (map pretty_arities arities)));
   201     Pretty.writeln (Pretty.big_list "consts:"
   202       (map (pretty_const syn) (Symtab.dest const_tab)))
   203   end;
   204 
   205 
   206 fun pretty_sg (Sg {stamps, ...}) =
   207   Pretty.str_list "{" "}" (stamp_names stamps);
   208 
   209 val pprint_sg = Pretty.pprint o pretty_sg;
   210 
   211 
   212 
   213 (** pretty printing of terms and types **)
   214 
   215 fun pretty_term (Sg {syn, stamps, ...}) =
   216   let val curried = "CPure" mem_string (map ! stamps);
   217   in Syntax.pretty_term curried syn end;
   218 
   219 fun pretty_typ (Sg {syn, ...}) = Syntax.pretty_typ syn;
   220 
   221 fun string_of_term (Sg {syn, stamps, ...}) =
   222   let val curried = "CPure" mem_string (map ! stamps);
   223   in Syntax.string_of_term curried syn end;
   224 
   225 fun string_of_typ (Sg {syn, ...}) = Syntax.string_of_typ syn;
   226 
   227 fun pprint_term sg = Pretty.pprint o Pretty.quote o (pretty_term sg);
   228 fun pprint_typ sg = Pretty.pprint o Pretty.quote o (pretty_typ sg);
   229 
   230 
   231 
   232 (** read types **)  (*exception ERROR*)
   233 
   234 fun err_in_type s =
   235   error ("The error(s) above occurred in type " ^ quote s);
   236 
   237 fun read_raw_typ syn tsig sort_of str =
   238   Syntax.read_typ syn (Type.eq_sort tsig) (Type.get_sort tsig sort_of) str
   239     handle ERROR => err_in_type str;
   240 
   241 (*read and certify typ wrt a signature*)
   242 fun read_typ (Sg {tsig, syn, ...}, sort_of) str =
   243   Type.cert_typ tsig (read_raw_typ syn tsig sort_of str)
   244     handle TYPE (msg, _, _) => (writeln msg; err_in_type str);
   245 
   246 
   247 
   248 (** certify types and terms **)   (*exception TYPE*)
   249 
   250 fun certify_typ (Sg {tsig, ...}) ty = Type.cert_typ tsig ty;
   251 
   252 (*check for duplicate TVars with distinct sorts*)
   253 fun nodup_TVars (tvars, T) =
   254   (case T of
   255     Type (_, Ts) => nodup_TVars_list (tvars, Ts)
   256   | TFree _ => tvars
   257   | TVar (v as (a, S)) =>
   258       (case assoc_string_int (tvars, a) of
   259         Some S' =>
   260           if S = S' then tvars
   261           else raise_type ("Type variable " ^ Syntax.string_of_vname a ^
   262             " has two distinct sorts") [TVar (a, S'), T] []
   263       | None => v :: tvars))
   264 (*equivalent to foldl nodup_TVars_list, but 3X faster under Poly/ML*)
   265 and nodup_TVars_list (tvars, []) = tvars
   266   | nodup_TVars_list (tvars, T :: Ts) =
   267       nodup_TVars_list (nodup_TVars (tvars, T), Ts);
   268 
   269 (*check for duplicate Vars with distinct types*)
   270 fun nodup_Vars tm =
   271   let
   272     fun nodups vars tvars tm =
   273       (case tm of
   274         Const (c, T) => (vars, nodup_TVars (tvars, T))
   275       | Free (a, T) => (vars, nodup_TVars (tvars, T))
   276       | Var (v as (ixn, T)) =>
   277           (case assoc_string_int (vars, ixn) of
   278             Some T' =>
   279               if T = T' then (vars, nodup_TVars (tvars, T))
   280               else raise_type ("Variable " ^ Syntax.string_of_vname ixn ^
   281                 " has two distinct types") [T', T] []
   282           | None => (v :: vars, tvars))
   283       | Bound _ => (vars, tvars)
   284       | Abs(_, T, t) => nodups vars (nodup_TVars (tvars, T)) t
   285       | s $ t =>
   286           let val (vars',tvars') = nodups vars tvars s in
   287             nodups vars' tvars' t
   288           end);
   289   in nodups [] [] tm; () end;
   290 
   291 
   292 fun mapfilt_atoms f (Abs (_, _, t)) = mapfilt_atoms f t
   293   | mapfilt_atoms f (t $ u) = mapfilt_atoms f t @ mapfilt_atoms f u
   294   | mapfilt_atoms f a = (case f a of Some y => [y] | None => []);
   295 
   296 
   297 fun certify_term (sg as Sg {tsig, ...}) tm =
   298   let
   299     fun valid_const a T =
   300       (case const_type sg a of
   301         Some U => Type.typ_instance (tsig, T, U)
   302       | _ => false);
   303 
   304     fun atom_err (Const (a, T)) =
   305           if valid_const a T then None
   306           else Some ("Illegal type for constant " ^ quote a ^ " :: " ^
   307             quote (string_of_typ sg T))
   308       | atom_err (Var ((x, i), _)) =
   309           if i < 0 then Some ("Negative index for Var " ^ quote x) else None
   310       | atom_err _ = None;
   311 
   312     val norm_tm =
   313       (case it_term_types (Type.typ_errors tsig) (tm, []) of
   314         [] => map_term_types (Type.norm_typ tsig) tm
   315       | errs => raise_type (cat_lines errs) [] [tm]);
   316     val _ = nodup_Vars norm_tm;
   317   in
   318     (case mapfilt_atoms atom_err norm_tm of
   319       [] => (norm_tm, type_of norm_tm, maxidx_of_term norm_tm)
   320     | errs => raise_type (cat_lines errs) [] [norm_tm])
   321   end;
   322 
   323 
   324 
   325 (** infer_types **)         (*exception ERROR*)
   326 
   327 (*
   328   ts: list of alternative parses (hopefully only one is type-correct)
   329   T: expected type
   330 
   331   def_type: partial map from indexnames to types (constrains Frees, Vars)
   332   def_sort: partial map from indexnames to sorts (constrains TFrees, TVars)
   333   used: list of already used type variables
   334   freeze: if true then generated parameters are turned into TFrees, else TVars
   335 *)
   336 
   337 fun infer_types sg def_type def_sort used freeze (ts, T) =
   338   let
   339     val Sg {tsig, ...} = sg;
   340     val prt = setmp Syntax.show_brackets true (pretty_term sg);
   341     val prT = pretty_typ sg;
   342     val infer = Type.infer_types prt prT tsig (const_type sg)
   343       def_type def_sort used freeze;
   344 
   345     val T' = certify_typ sg T handle TYPE (msg, _, _) => error msg;
   346 
   347     fun warn () =
   348       if length ts > 1 andalso length ts <= ! Syntax.ambiguity_level
   349       then (*no warning shown yet*)
   350         warning "Currently parsed input \
   351           \produces more than one parse tree.\n\
   352           \For more information lower Syntax.ambiguity_level."
   353       else ();
   354 
   355     datatype result =
   356       One of int * term * (indexname * typ) list |
   357       Errs of string list |
   358       Ambigs of term list;
   359 
   360     fun process_term (res, (t, i)) =
   361       let val ([u], tye) = infer [T'] [t] in
   362         (case res of
   363           One (_, t0, _) => Ambigs ([u, t0])
   364         | Errs _ => One (i, u, tye)
   365         | Ambigs us => Ambigs (u :: us))
   366       end handle TYPE (msg, _, _) =>
   367         (case res of
   368           Errs errs => Errs (msg :: errs)
   369         | _ => res);
   370   in
   371     (case foldl process_term (Errs [], ts ~~ (0 upto (length ts - 1))) of
   372       One res =>
   373        (if length ts > ! Syntax.ambiguity_level then
   374           writeln "Fortunately, only one parse tree is type correct.\n\
   375             \It helps (speed!) if you disambiguate your grammar or your input."
   376         else (); res)
   377     | Errs errs => (warn (); error (cat_lines errs))
   378     | Ambigs us =>
   379         (warn (); error ("Error: More than one term is type correct:\n" ^
   380           (cat_lines (map (Pretty.string_of o prt) us)))))
   381   end;
   382 
   383 
   384 
   385 (** extend signature **)    (*exception ERROR*)
   386 
   387 (** signature extension functions **)  (*exception ERROR*)
   388 
   389 fun decls_of name_of mfixs =
   390   map (fn (x, y, mx) => (name_of x mx, y)) mfixs;
   391 
   392 
   393 (* add default sort *)
   394 
   395 fun ext_defsort (syn, tsig, ctab) defsort =
   396   (syn, Type.ext_tsig_defsort tsig defsort, ctab);
   397 
   398 
   399 (* add type constructors *)
   400 
   401 fun ext_types (syn, tsig, ctab) types =
   402   (Syntax.extend_type_gram syn types,
   403     Type.ext_tsig_types tsig (decls_of Syntax.type_name types),
   404     ctab);
   405 
   406 
   407 (* add type abbreviations *)
   408 
   409 fun read_abbr syn tsig (t, vs, rhs_src) =
   410   (t, vs, read_raw_typ syn tsig (K None) rhs_src)
   411     handle ERROR => error ("in type abbreviation " ^ t);
   412 
   413 fun ext_abbrs rd_abbr (syn, tsig, ctab) abbrs =
   414   let
   415     fun mfix_of (t, vs, _, mx) = (t, length vs, mx);
   416     val syn1 = Syntax.extend_type_gram syn (map mfix_of abbrs);
   417 
   418     fun decl_of (t, vs, rhs, mx) =
   419       rd_abbr syn1 tsig (Syntax.type_name t mx, vs, rhs);
   420   in
   421     (syn1, Type.ext_tsig_abbrs tsig (map decl_of abbrs), ctab)
   422   end;
   423 
   424 fun ext_tyabbrs_i arg = ext_abbrs (K (K I)) arg;
   425 fun ext_tyabbrs   arg = ext_abbrs read_abbr arg;
   426 
   427 
   428 (* add type arities *)
   429 
   430 fun ext_arities (syn, tsig, ctab) arities =
   431   let
   432     val tsig1 = Type.ext_tsig_arities tsig arities;
   433     val log_types = Type.logical_types tsig1;
   434   in
   435     (Syntax.extend_log_types syn log_types, tsig1, ctab)
   436   end;
   437 
   438 
   439 (* add term constants and syntax *)
   440 
   441 fun err_in_const c =
   442   error ("in declaration of constant " ^ quote c);
   443 
   444 fun err_dup_consts cs =
   445   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   446 
   447 
   448 fun read_const syn tsig (c, ty_src, mx) =
   449   (c, read_raw_typ syn tsig (K None) ty_src, mx)
   450     handle ERROR => err_in_const (Syntax.const_name c mx);
   451 
   452 fun ext_cnsts rd_const syn_only prmode (syn, tsig, ctab) raw_consts =
   453   let
   454     fun prep_const (c, ty, mx) =
   455      (c, compress_type (Type.varifyT (Type.cert_typ tsig (Type.no_tvars ty))), mx)
   456        handle TYPE (msg, _, _)
   457          => (writeln msg; err_in_const (Syntax.const_name c mx));
   458 
   459     val consts = map (prep_const o rd_const syn tsig) raw_consts;
   460     val decls =
   461       if syn_only then []
   462       else filter_out (equal "" o fst) (decls_of Syntax.const_name consts);
   463   in
   464     (Syntax.extend_const_gram syn prmode consts, tsig,
   465       Symtab.extend_new (ctab, decls)
   466         handle Symtab.DUPS cs => err_dup_consts cs)
   467   end;
   468 
   469 val ext_consts_i = ext_cnsts (K (K I)) false ("", true);
   470 val ext_consts = ext_cnsts read_const false ("", true);
   471 val ext_syntax_i = ext_cnsts (K (K I)) true ("", true);
   472 val ext_syntax = ext_cnsts read_const true ("", true);
   473 fun ext_modesyntax_i sg (prmode, consts) = ext_cnsts (K (K I)) true prmode sg consts;
   474 fun ext_modesyntax sg (prmode, consts) = ext_cnsts read_const true prmode sg consts;
   475 
   476 
   477 (* add type classes *)
   478 
   479 fun const_of_class c = c ^ "_class";
   480 
   481 fun class_of_const c_class =
   482   let
   483     val c = implode (take (size c_class - 6, explode c_class));
   484   in
   485     if const_of_class c = c_class then c
   486     else raise_term ("class_of_const: bad name " ^ quote c_class) []
   487   end;
   488 
   489 
   490 fun ext_classes (syn, tsig, ctab) classes =
   491   let
   492     val names = map fst classes;
   493     val consts =
   494       map (fn c => (const_of_class c, a_itselfT --> propT, NoSyn)) names;
   495   in
   496     ext_consts_i
   497       (Syntax.extend_consts syn names, Type.ext_tsig_classes tsig classes, ctab)
   498       consts
   499   end;
   500 
   501 
   502 (* add to classrel *)
   503 
   504 fun ext_classrel (syn, tsig, ctab) pairs =
   505   (syn, Type.ext_tsig_classrel tsig pairs, ctab);
   506 
   507 
   508 (* add to syntax *)
   509 
   510 fun ext_syn extfun (syn, tsig, ctab) args =
   511   (extfun syn args, tsig, ctab);
   512 
   513 
   514 (* build signature *)
   515 
   516 fun ext_stamps stamps name =
   517   let
   518     val stmps = (case stamps of ref "#" :: ss => ss | ss => ss);
   519   in
   520     if exists (equal name o !) stmps then
   521       error ("Theory already contains a " ^ quote name ^ " component")
   522     else ref name :: stmps
   523   end;
   524 
   525 fun make_sign (syn, tsig, ctab) stamps name =
   526   Sg {tsig = tsig, const_tab = ctab, syn = syn,
   527     stamps = ext_stamps stamps name};
   528 
   529 fun extend_sign extfun name decls (Sg {tsig, const_tab, syn, stamps}) =
   530   make_sign (extfun (syn, tsig, const_tab) decls) stamps name;
   531 
   532 
   533 (* the external interfaces *)
   534 
   535 val add_classes      = extend_sign ext_classes "#";
   536 val add_classrel     = extend_sign ext_classrel "#";
   537 val add_defsort      = extend_sign ext_defsort "#";
   538 val add_types        = extend_sign ext_types "#";
   539 val add_tyabbrs      = extend_sign ext_tyabbrs "#";
   540 val add_tyabbrs_i    = extend_sign ext_tyabbrs_i "#";
   541 val add_arities      = extend_sign ext_arities "#";
   542 val add_consts       = extend_sign ext_consts "#";
   543 val add_consts_i     = extend_sign ext_consts_i "#";
   544 val add_syntax       = extend_sign ext_syntax "#";
   545 val add_syntax_i     = extend_sign ext_syntax_i "#";
   546 val add_modesyntax   = extend_sign ext_modesyntax "#";
   547 val add_modesyntax_i = extend_sign ext_modesyntax_i "#";
   548 val add_trfuns       = extend_sign (ext_syn Syntax.extend_trfuns) "#";
   549 val add_trfunsT      = extend_sign (ext_syn Syntax.extend_trfunsT) "#";
   550 val add_tokentrfuns  = extend_sign (ext_syn Syntax.extend_tokentrfuns) "#";
   551 val add_trrules      = extend_sign (ext_syn Syntax.extend_trrules) "#";
   552 val add_trrules_i    = extend_sign (ext_syn Syntax.extend_trrules_i) "#";
   553 
   554 fun add_name name sg = extend_sign K name () sg;
   555 val make_draft = add_name "#";
   556 
   557 
   558 
   559 (** merge signatures **)    (*exception TERM*) (*exception ERROR (* FIXME *)*)
   560 
   561 fun merge (sg1, sg2) =
   562   if fast_subsig (sg2, sg1) then sg1
   563   else if fast_subsig (sg1, sg2) then sg2
   564   else if subsig (sg2, sg1) then sg1
   565   else if subsig (sg1, sg2) then sg2
   566   else if is_draft sg1 orelse is_draft sg2 then
   567     raise_term "Illegal merge of draft signatures" []
   568   else
   569     (*neither is union already; must form union*)
   570     let
   571       val Sg {tsig = tsig1, const_tab = const_tab1, syn = syn1,
   572         stamps = stamps1} = sg1;
   573       val Sg {tsig = tsig2, const_tab = const_tab2, syn = syn2,
   574         stamps = stamps2} = sg2;
   575 
   576 
   577       val stamps = merge_rev_lists stamps1 stamps2;
   578       val _ =
   579         (case duplicates (stamp_names stamps) of
   580           [] => ()
   581         | dups => raise_term ("Attempt to merge different versions of theories "
   582             ^ commas_quote dups) []);
   583 
   584       val tsig = Type.merge_tsigs (tsig1, tsig2);
   585 
   586       val const_tab = Symtab.merge (op =) (const_tab1, const_tab2)
   587         handle Symtab.DUPS cs =>
   588           raise_term ("Incompatible types for constant(s) " ^ commas_quote cs) [];
   589 
   590       val syn = Syntax.merge_syntaxes syn1 syn2;
   591     in
   592       Sg {tsig = tsig, const_tab = const_tab, syn = syn, stamps = stamps}
   593     end;
   594 
   595 
   596 
   597 (** the Pure signature **)
   598 
   599 val proto_pure =
   600   make_sign (Syntax.pure_syn, Type.tsig0, Symtab.null) [] "#"
   601   |> add_types
   602    (("fun", 2, NoSyn) ::
   603     ("prop", 0, NoSyn) ::
   604     ("itself", 1, NoSyn) ::
   605     Syntax.pure_types)
   606   |> add_classes [(logicC, [])]
   607   |> add_defsort logicS
   608   |> add_arities
   609    [("fun", [logicS, logicS], logicS),
   610     ("prop", [], logicS),
   611     ("itself", [logicS], logicS)]
   612   |> add_syntax Syntax.pure_syntax
   613   |> add_modesyntax (("symbols", true), Syntax.pure_sym_syntax)
   614   |> add_trfuns Syntax.pure_trfuns
   615   |> add_trfunsT Syntax.pure_trfunsT
   616   |> add_consts
   617    [("==", "['a::{}, 'a] => prop", InfixrName ("==", 2)),
   618     ("=?=", "['a::{}, 'a] => prop", InfixrName ("=?=", 2)),
   619     ("==>", "[prop, prop] => prop", Mixfix ("(_/ ==> _)", [2, 1], 1)),
   620     ("all", "('a => prop) => prop", Binder ("!!", 0, 0)),
   621     ("TYPE", "'a itself", NoSyn)]
   622   |> add_syntax
   623    [("==>", "[prop, prop] => prop", Delimfix "op ==>")]
   624   |> add_name "ProtoPure";
   625 
   626 val pure = proto_pure
   627   |> add_syntax Syntax.pure_appl_syntax
   628   |> add_name "Pure";
   629 
   630 val cpure = proto_pure
   631   |> add_syntax Syntax.pure_applC_syntax
   632   |> add_name "CPure";
   633 
   634 end;