src/HOL/HOL.thy
author wenzelm
Tue Jan 12 11:49:35 2016 +0100 (2016-01-12)
changeset 62151 dc4c9748a86e
parent 61955 e96292f32c3c
child 62390 842917225d56
permissions -rw-r--r--
eliminated old defs;
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 section \<open>The basis of Higher-Order Logic\<close>
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 keywords
    10   "try" "solve_direct" "quickcheck" "print_coercions" "print_claset"
    11     "print_induct_rules" :: diag and
    12   "quickcheck_params" :: thy_decl
    13 begin
    14 
    15 ML_file "~~/src/Tools/misc_legacy.ML"
    16 ML_file "~~/src/Tools/try.ML"
    17 ML_file "~~/src/Tools/quickcheck.ML"
    18 ML_file "~~/src/Tools/solve_direct.ML"
    19 ML_file "~~/src/Tools/IsaPlanner/zipper.ML"
    20 ML_file "~~/src/Tools/IsaPlanner/isand.ML"
    21 ML_file "~~/src/Tools/IsaPlanner/rw_inst.ML"
    22 ML_file "~~/src/Provers/hypsubst.ML"
    23 ML_file "~~/src/Provers/splitter.ML"
    24 ML_file "~~/src/Provers/classical.ML"
    25 ML_file "~~/src/Provers/blast.ML"
    26 ML_file "~~/src/Provers/clasimp.ML"
    27 ML_file "~~/src/Tools/eqsubst.ML"
    28 ML_file "~~/src/Provers/quantifier1.ML"
    29 ML_file "~~/src/Tools/atomize_elim.ML"
    30 ML_file "~~/src/Tools/cong_tac.ML"
    31 ML_file "~~/src/Tools/intuitionistic.ML" setup \<open>Intuitionistic.method_setup @{binding iprover}\<close>
    32 ML_file "~~/src/Tools/project_rule.ML"
    33 ML_file "~~/src/Tools/subtyping.ML"
    34 ML_file "~~/src/Tools/case_product.ML"
    35 
    36 
    37 ML \<open>Plugin_Name.declare_setup @{binding extraction}\<close>
    38 
    39 ML \<open>
    40   Plugin_Name.declare_setup @{binding quickcheck_random};
    41   Plugin_Name.declare_setup @{binding quickcheck_exhaustive};
    42   Plugin_Name.declare_setup @{binding quickcheck_bounded_forall};
    43   Plugin_Name.declare_setup @{binding quickcheck_full_exhaustive};
    44   Plugin_Name.declare_setup @{binding quickcheck_narrowing};
    45 \<close>
    46 ML \<open>
    47   Plugin_Name.define_setup @{binding quickcheck}
    48    [@{plugin quickcheck_exhaustive},
    49     @{plugin quickcheck_random},
    50     @{plugin quickcheck_bounded_forall},
    51     @{plugin quickcheck_full_exhaustive},
    52     @{plugin quickcheck_narrowing}]
    53 \<close>
    54 
    55 
    56 subsection \<open>Primitive logic\<close>
    57 
    58 subsubsection \<open>Core syntax\<close>
    59 
    60 setup \<open>Axclass.class_axiomatization (@{binding type}, [])\<close>
    61 default_sort type
    62 setup \<open>Object_Logic.add_base_sort @{sort type}\<close>
    63 
    64 axiomatization where fun_arity: "OFCLASS('a \<Rightarrow> 'b, type_class)"
    65 instance "fun" :: (type, type) type by (rule fun_arity)
    66 
    67 axiomatization where itself_arity: "OFCLASS('a itself, type_class)"
    68 instance itself :: (type) type by (rule itself_arity)
    69 
    70 typedecl bool
    71 
    72 judgment Trueprop :: "bool \<Rightarrow> prop"  ("(_)" 5)
    73 
    74 axiomatization implies :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<longrightarrow>" 25)
    75   and eq :: "['a, 'a] \<Rightarrow> bool"  (infixl "=" 50)
    76   and The :: "('a \<Rightarrow> bool) \<Rightarrow> 'a"
    77 
    78 
    79 subsubsection \<open>Defined connectives and quantifiers\<close>
    80 
    81 definition True :: bool
    82   where "True \<equiv> ((\<lambda>x::bool. x) = (\<lambda>x. x))"
    83 
    84 definition All :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<forall>" 10)
    85   where "All P \<equiv> (P = (\<lambda>x. True))"
    86 
    87 definition Ex :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<exists>" 10)
    88   where "Ex P \<equiv> \<forall>Q. (\<forall>x. P x \<longrightarrow> Q) \<longrightarrow> Q"
    89 
    90 definition False :: bool
    91   where "False \<equiv> (\<forall>P. P)"
    92 
    93 definition Not :: "bool \<Rightarrow> bool"  ("\<not> _" [40] 40)
    94   where not_def: "\<not> P \<equiv> P \<longrightarrow> False"
    95 
    96 definition conj :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<and>" 35)
    97   where and_def: "P \<and> Q \<equiv> \<forall>R. (P \<longrightarrow> Q \<longrightarrow> R) \<longrightarrow> R"
    98 
    99 definition disj :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<or>" 30)
   100   where or_def: "P \<or> Q \<equiv> \<forall>R. (P \<longrightarrow> R) \<longrightarrow> (Q \<longrightarrow> R) \<longrightarrow> R"
   101 
   102 definition Ex1 :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<exists>!" 10)
   103   where "Ex1 P \<equiv> \<exists>x. P x \<and> (\<forall>y. P y \<longrightarrow> y = x)"
   104 
   105 
   106 subsubsection \<open>Additional concrete syntax\<close>
   107 
   108 abbreviation not_equal :: "['a, 'a] \<Rightarrow> bool"  (infixl "\<noteq>" 50)
   109   where "x \<noteq> y \<equiv> \<not> (x = y)"
   110 
   111 notation (output)
   112   eq  (infix "=" 50) and
   113   not_equal  (infix "\<noteq>" 50)
   114 
   115 notation (ASCII output)
   116   not_equal  (infix "~=" 50)
   117 
   118 notation (ASCII)
   119   Not  ("~ _" [40] 40) and
   120   conj  (infixr "&" 35) and
   121   disj  (infixr "|" 30) and
   122   implies  (infixr "-->" 25) and
   123   not_equal  (infixl "~=" 50)
   124 
   125 abbreviation (iff)
   126   iff :: "[bool, bool] \<Rightarrow> bool"  (infixr "\<longleftrightarrow>" 25)
   127   where "A \<longleftrightarrow> B \<equiv> A = B"
   128 
   129 syntax "_The" :: "[pttrn, bool] \<Rightarrow> 'a"  ("(3THE _./ _)" [0, 10] 10)
   130 translations "THE x. P" \<rightleftharpoons> "CONST The (\<lambda>x. P)"
   131 print_translation \<open>
   132   [(@{const_syntax The}, fn _ => fn [Abs abs] =>
   133       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
   134       in Syntax.const @{syntax_const "_The"} $ x $ t end)]
   135 \<close>  \<comment> \<open>To avoid eta-contraction of body\<close>
   136 
   137 nonterminal letbinds and letbind
   138 syntax
   139   "_bind"       :: "[pttrn, 'a] \<Rightarrow> letbind"              ("(2_ =/ _)" 10)
   140   ""            :: "letbind \<Rightarrow> letbinds"                 ("_")
   141   "_binds"      :: "[letbind, letbinds] \<Rightarrow> letbinds"     ("_;/ _")
   142   "_Let"        :: "[letbinds, 'a] \<Rightarrow> 'a"                ("(let (_)/ in (_))" [0, 10] 10)
   143 
   144 nonterminal case_syn and cases_syn
   145 syntax
   146   "_case_syntax" :: "['a, cases_syn] \<Rightarrow> 'b"  ("(case _ of/ _)" 10)
   147   "_case1" :: "['a, 'b] \<Rightarrow> case_syn"  ("(2_ \<Rightarrow>/ _)" 10)
   148   "" :: "case_syn \<Rightarrow> cases_syn"  ("_")
   149   "_case2" :: "[case_syn, cases_syn] \<Rightarrow> cases_syn"  ("_/ | _")
   150 syntax (ASCII)
   151   "_case1" :: "['a, 'b] \<Rightarrow> case_syn"  ("(2_ =>/ _)" 10)
   152 
   153 notation (ASCII)
   154   All  (binder "ALL " 10) and
   155   Ex  (binder "EX " 10) and
   156   Ex1  (binder "EX! " 10)
   157 
   158 notation (HOL)
   159   All  (binder "! " 10) and
   160   Ex  (binder "? " 10) and
   161   Ex1  (binder "?! " 10)
   162 
   163 
   164 subsubsection \<open>Axioms and basic definitions\<close>
   165 
   166 axiomatization where
   167   refl: "t = (t::'a)" and
   168   subst: "s = t \<Longrightarrow> P s \<Longrightarrow> P t" and
   169   ext: "(\<And>x::'a. (f x ::'b) = g x) \<Longrightarrow> (\<lambda>x. f x) = (\<lambda>x. g x)"
   170     \<comment> \<open>Extensionality is built into the meta-logic, and this rule expresses
   171          a related property.  It is an eta-expanded version of the traditional
   172          rule, and similar to the ABS rule of HOL\<close> and
   173 
   174   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   175 
   176 axiomatization where
   177   impI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<longrightarrow> Q" and
   178   mp: "\<lbrakk>P \<longrightarrow> Q; P\<rbrakk> \<Longrightarrow> Q" and
   179 
   180   iff: "(P \<longrightarrow> Q) \<longrightarrow> (Q \<longrightarrow> P) \<longrightarrow> (P = Q)" and
   181   True_or_False: "(P = True) \<or> (P = False)"
   182 
   183 definition If :: "bool \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a" ("(if (_)/ then (_)/ else (_))" [0, 0, 10] 10)
   184   where "If P x y \<equiv> (THE z::'a. (P = True \<longrightarrow> z = x) \<and> (P = False \<longrightarrow> z = y))"
   185 
   186 definition Let :: "'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b"
   187   where "Let s f \<equiv> f s"
   188 
   189 translations
   190   "_Let (_binds b bs) e"  \<rightleftharpoons> "_Let b (_Let bs e)"
   191   "let x = a in e"        \<rightleftharpoons> "CONST Let a (\<lambda>x. e)"
   192 
   193 axiomatization undefined :: 'a
   194 
   195 class default = fixes default :: 'a
   196 
   197 
   198 subsection \<open>Fundamental rules\<close>
   199 
   200 subsubsection \<open>Equality\<close>
   201 
   202 lemma sym: "s = t \<Longrightarrow> t = s"
   203   by (erule subst) (rule refl)
   204 
   205 lemma ssubst: "t = s \<Longrightarrow> P s \<Longrightarrow> P t"
   206   by (drule sym) (erule subst)
   207 
   208 lemma trans: "\<lbrakk>r = s; s = t\<rbrakk> \<Longrightarrow> r = t"
   209   by (erule subst)
   210 
   211 lemma trans_sym [Pure.elim?]: "r = s \<Longrightarrow> t = s \<Longrightarrow> r = t"
   212   by (rule trans [OF _ sym])
   213 
   214 lemma meta_eq_to_obj_eq:
   215   assumes meq: "A \<equiv> B"
   216   shows "A = B"
   217   by (unfold meq) (rule refl)
   218 
   219 text \<open>Useful with \<open>erule\<close> for proving equalities from known equalities.\<close>
   220      (* a = b
   221         |   |
   222         c = d   *)
   223 lemma box_equals: "\<lbrakk>a = b; a = c; b = d\<rbrakk> \<Longrightarrow> c = d"
   224 apply (rule trans)
   225 apply (rule trans)
   226 apply (rule sym)
   227 apply assumption+
   228 done
   229 
   230 text \<open>For calculational reasoning:\<close>
   231 
   232 lemma forw_subst: "a = b \<Longrightarrow> P b \<Longrightarrow> P a"
   233   by (rule ssubst)
   234 
   235 lemma back_subst: "P a \<Longrightarrow> a = b \<Longrightarrow> P b"
   236   by (rule subst)
   237 
   238 
   239 subsubsection \<open>Congruence rules for application\<close>
   240 
   241 text \<open>Similar to \<open>AP_THM\<close> in Gordon's HOL.\<close>
   242 lemma fun_cong: "(f :: 'a \<Rightarrow> 'b) = g \<Longrightarrow> f x = g x"
   243 apply (erule subst)
   244 apply (rule refl)
   245 done
   246 
   247 text \<open>Similar to \<open>AP_TERM\<close> in Gordon's HOL and FOL's \<open>subst_context\<close>.\<close>
   248 lemma arg_cong: "x = y \<Longrightarrow> f x = f y"
   249 apply (erule subst)
   250 apply (rule refl)
   251 done
   252 
   253 lemma arg_cong2: "\<lbrakk>a = b; c = d\<rbrakk> \<Longrightarrow> f a c = f b d"
   254 apply (erule ssubst)+
   255 apply (rule refl)
   256 done
   257 
   258 lemma cong: "\<lbrakk>f = g; (x::'a) = y\<rbrakk> \<Longrightarrow> f x = g y"
   259 apply (erule subst)+
   260 apply (rule refl)
   261 done
   262 
   263 ML \<open>fun cong_tac ctxt = Cong_Tac.cong_tac ctxt @{thm cong}\<close>
   264 
   265 
   266 subsubsection \<open>Equality of booleans -- iff\<close>
   267 
   268 lemma iffI: assumes "P \<Longrightarrow> Q" and "Q \<Longrightarrow> P" shows "P = Q"
   269   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   270 
   271 lemma iffD2: "\<lbrakk>P = Q; Q\<rbrakk> \<Longrightarrow> P"
   272   by (erule ssubst)
   273 
   274 lemma rev_iffD2: "\<lbrakk>Q; P = Q\<rbrakk> \<Longrightarrow> P"
   275   by (erule iffD2)
   276 
   277 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   278   by (drule sym) (rule iffD2)
   279 
   280 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   281   by (drule sym) (rule rev_iffD2)
   282 
   283 lemma iffE:
   284   assumes major: "P = Q"
   285     and minor: "\<lbrakk>P \<longrightarrow> Q; Q \<longrightarrow> P\<rbrakk> \<Longrightarrow> R"
   286   shows R
   287   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   288 
   289 
   290 subsubsection \<open>True\<close>
   291 
   292 lemma TrueI: "True"
   293   unfolding True_def by (rule refl)
   294 
   295 lemma eqTrueI: "P \<Longrightarrow> P = True"
   296   by (iprover intro: iffI TrueI)
   297 
   298 lemma eqTrueE: "P = True \<Longrightarrow> P"
   299   by (erule iffD2) (rule TrueI)
   300 
   301 
   302 subsubsection \<open>Universal quantifier\<close>
   303 
   304 lemma allI: assumes "\<And>x::'a. P x" shows "\<forall>x. P x"
   305   unfolding All_def by (iprover intro: ext eqTrueI assms)
   306 
   307 lemma spec: "\<forall>x::'a. P x \<Longrightarrow> P x"
   308 apply (unfold All_def)
   309 apply (rule eqTrueE)
   310 apply (erule fun_cong)
   311 done
   312 
   313 lemma allE:
   314   assumes major: "\<forall>x. P x"
   315     and minor: "P x \<Longrightarrow> R"
   316   shows R
   317   by (iprover intro: minor major [THEN spec])
   318 
   319 lemma all_dupE:
   320   assumes major: "\<forall>x. P x"
   321     and minor: "\<lbrakk>P x; \<forall>x. P x\<rbrakk> \<Longrightarrow> R"
   322   shows R
   323   by (iprover intro: minor major major [THEN spec])
   324 
   325 
   326 subsubsection \<open>False\<close>
   327 
   328 text \<open>
   329   Depends upon \<open>spec\<close>; it is impossible to do propositional
   330   logic before quantifiers!
   331 \<close>
   332 
   333 lemma FalseE: "False \<Longrightarrow> P"
   334   apply (unfold False_def)
   335   apply (erule spec)
   336   done
   337 
   338 lemma False_neq_True: "False = True \<Longrightarrow> P"
   339   by (erule eqTrueE [THEN FalseE])
   340 
   341 
   342 subsubsection \<open>Negation\<close>
   343 
   344 lemma notI:
   345   assumes "P \<Longrightarrow> False"
   346   shows "\<not> P"
   347   apply (unfold not_def)
   348   apply (iprover intro: impI assms)
   349   done
   350 
   351 lemma False_not_True: "False \<noteq> True"
   352   apply (rule notI)
   353   apply (erule False_neq_True)
   354   done
   355 
   356 lemma True_not_False: "True \<noteq> False"
   357   apply (rule notI)
   358   apply (drule sym)
   359   apply (erule False_neq_True)
   360   done
   361 
   362 lemma notE: "\<lbrakk>\<not> P; P\<rbrakk> \<Longrightarrow> R"
   363   apply (unfold not_def)
   364   apply (erule mp [THEN FalseE])
   365   apply assumption
   366   done
   367 
   368 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   369   by (erule notE [THEN notI]) (erule meta_mp)
   370 
   371 
   372 subsubsection \<open>Implication\<close>
   373 
   374 lemma impE:
   375   assumes "P \<longrightarrow> Q" P "Q \<Longrightarrow> R"
   376   shows R
   377 by (iprover intro: assms mp)
   378 
   379 (* Reduces Q to P \<longrightarrow> Q, allowing substitution in P. *)
   380 lemma rev_mp: "\<lbrakk>P; P \<longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   381 by (iprover intro: mp)
   382 
   383 lemma contrapos_nn:
   384   assumes major: "\<not> Q"
   385       and minor: "P \<Longrightarrow> Q"
   386   shows "\<not> P"
   387 by (iprover intro: notI minor major [THEN notE])
   388 
   389 (*not used at all, but we already have the other 3 combinations *)
   390 lemma contrapos_pn:
   391   assumes major: "Q"
   392       and minor: "P \<Longrightarrow> \<not> Q"
   393   shows "\<not> P"
   394 by (iprover intro: notI minor major notE)
   395 
   396 lemma not_sym: "t \<noteq> s \<Longrightarrow> s \<noteq> t"
   397   by (erule contrapos_nn) (erule sym)
   398 
   399 lemma eq_neq_eq_imp_neq: "\<lbrakk>x = a; a \<noteq> b; b = y\<rbrakk> \<Longrightarrow> x \<noteq> y"
   400   by (erule subst, erule ssubst, assumption)
   401 
   402 
   403 subsubsection \<open>Existential quantifier\<close>
   404 
   405 lemma exI: "P x \<Longrightarrow> \<exists>x::'a. P x"
   406 apply (unfold Ex_def)
   407 apply (iprover intro: allI allE impI mp)
   408 done
   409 
   410 lemma exE:
   411   assumes major: "\<exists>x::'a. P x"
   412       and minor: "\<And>x. P x \<Longrightarrow> Q"
   413   shows "Q"
   414 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   415 apply (iprover intro: impI [THEN allI] minor)
   416 done
   417 
   418 
   419 subsubsection \<open>Conjunction\<close>
   420 
   421 lemma conjI: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> P \<and> Q"
   422 apply (unfold and_def)
   423 apply (iprover intro: impI [THEN allI] mp)
   424 done
   425 
   426 lemma conjunct1: "\<lbrakk>P \<and> Q\<rbrakk> \<Longrightarrow> P"
   427 apply (unfold and_def)
   428 apply (iprover intro: impI dest: spec mp)
   429 done
   430 
   431 lemma conjunct2: "\<lbrakk>P \<and> Q\<rbrakk> \<Longrightarrow> Q"
   432 apply (unfold and_def)
   433 apply (iprover intro: impI dest: spec mp)
   434 done
   435 
   436 lemma conjE:
   437   assumes major: "P \<and> Q"
   438       and minor: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> R"
   439   shows R
   440 apply (rule minor)
   441 apply (rule major [THEN conjunct1])
   442 apply (rule major [THEN conjunct2])
   443 done
   444 
   445 lemma context_conjI:
   446   assumes P "P \<Longrightarrow> Q" shows "P \<and> Q"
   447 by (iprover intro: conjI assms)
   448 
   449 
   450 subsubsection \<open>Disjunction\<close>
   451 
   452 lemma disjI1: "P \<Longrightarrow> P \<or> Q"
   453 apply (unfold or_def)
   454 apply (iprover intro: allI impI mp)
   455 done
   456 
   457 lemma disjI2: "Q \<Longrightarrow> P \<or> Q"
   458 apply (unfold or_def)
   459 apply (iprover intro: allI impI mp)
   460 done
   461 
   462 lemma disjE:
   463   assumes major: "P \<or> Q"
   464       and minorP: "P \<Longrightarrow> R"
   465       and minorQ: "Q \<Longrightarrow> R"
   466   shows R
   467 by (iprover intro: minorP minorQ impI
   468                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   469 
   470 
   471 subsubsection \<open>Classical logic\<close>
   472 
   473 lemma classical:
   474   assumes prem: "\<not> P \<Longrightarrow> P"
   475   shows P
   476 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   477 apply assumption
   478 apply (rule notI [THEN prem, THEN eqTrueI])
   479 apply (erule subst)
   480 apply assumption
   481 done
   482 
   483 lemmas ccontr = FalseE [THEN classical]
   484 
   485 (*notE with premises exchanged; it discharges \<not> R so that it can be used to
   486   make elimination rules*)
   487 lemma rev_notE:
   488   assumes premp: P
   489       and premnot: "\<not> R \<Longrightarrow> \<not> P"
   490   shows R
   491 apply (rule ccontr)
   492 apply (erule notE [OF premnot premp])
   493 done
   494 
   495 (*Double negation law*)
   496 lemma notnotD: "\<not>\<not> P \<Longrightarrow> P"
   497 apply (rule classical)
   498 apply (erule notE)
   499 apply assumption
   500 done
   501 
   502 lemma contrapos_pp:
   503   assumes p1: Q
   504       and p2: "\<not> P \<Longrightarrow> \<not> Q"
   505   shows P
   506 by (iprover intro: classical p1 p2 notE)
   507 
   508 
   509 subsubsection \<open>Unique existence\<close>
   510 
   511 lemma ex1I:
   512   assumes "P a" "\<And>x. P x \<Longrightarrow> x = a"
   513   shows "\<exists>!x. P x"
   514 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   515 
   516 text\<open>Sometimes easier to use: the premises have no shared variables.  Safe!\<close>
   517 lemma ex_ex1I:
   518   assumes ex_prem: "\<exists>x. P x"
   519       and eq: "\<And>x y. \<lbrakk>P x; P y\<rbrakk> \<Longrightarrow> x = y"
   520   shows "\<exists>!x. P x"
   521 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   522 
   523 lemma ex1E:
   524   assumes major: "\<exists>!x. P x"
   525       and minor: "\<And>x. \<lbrakk>P x; \<forall>y. P y \<longrightarrow> y = x\<rbrakk> \<Longrightarrow> R"
   526   shows R
   527 apply (rule major [unfolded Ex1_def, THEN exE])
   528 apply (erule conjE)
   529 apply (iprover intro: minor)
   530 done
   531 
   532 lemma ex1_implies_ex: "\<exists>!x. P x \<Longrightarrow> \<exists>x. P x"
   533 apply (erule ex1E)
   534 apply (rule exI)
   535 apply assumption
   536 done
   537 
   538 
   539 subsubsection \<open>Classical intro rules for disjunction and existential quantifiers\<close>
   540 
   541 lemma disjCI:
   542   assumes "\<not> Q \<Longrightarrow> P" shows "P \<or> Q"
   543 apply (rule classical)
   544 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   545 done
   546 
   547 lemma excluded_middle: "\<not> P \<or> P"
   548 by (iprover intro: disjCI)
   549 
   550 text \<open>
   551   case distinction as a natural deduction rule.
   552   Note that @{term "\<not> P"} is the second case, not the first
   553 \<close>
   554 lemma case_split [case_names True False]:
   555   assumes prem1: "P \<Longrightarrow> Q"
   556       and prem2: "\<not> P \<Longrightarrow> Q"
   557   shows Q
   558 apply (rule excluded_middle [THEN disjE])
   559 apply (erule prem2)
   560 apply (erule prem1)
   561 done
   562 
   563 (*Classical implies (\<longrightarrow>) elimination. *)
   564 lemma impCE:
   565   assumes major: "P \<longrightarrow> Q"
   566       and minor: "\<not> P \<Longrightarrow> R" "Q \<Longrightarrow> R"
   567   shows R
   568 apply (rule excluded_middle [of P, THEN disjE])
   569 apply (iprover intro: minor major [THEN mp])+
   570 done
   571 
   572 (*This version of \<longrightarrow> elimination works on Q before P.  It works best for
   573   those cases in which P holds "almost everywhere".  Can't install as
   574   default: would break old proofs.*)
   575 lemma impCE':
   576   assumes major: "P \<longrightarrow> Q"
   577       and minor: "Q \<Longrightarrow> R" "\<not> P \<Longrightarrow> R"
   578   shows R
   579 apply (rule excluded_middle [of P, THEN disjE])
   580 apply (iprover intro: minor major [THEN mp])+
   581 done
   582 
   583 (*Classical <-> elimination. *)
   584 lemma iffCE:
   585   assumes major: "P = Q"
   586       and minor: "\<lbrakk>P; Q\<rbrakk> \<Longrightarrow> R" "\<lbrakk>\<not> P; \<not> Q\<rbrakk> \<Longrightarrow> R"
   587   shows R
   588 apply (rule major [THEN iffE])
   589 apply (iprover intro: minor elim: impCE notE)
   590 done
   591 
   592 lemma exCI:
   593   assumes "\<forall>x. \<not> P x \<Longrightarrow> P a"
   594   shows "\<exists>x. P x"
   595 apply (rule ccontr)
   596 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   597 done
   598 
   599 
   600 subsubsection \<open>Intuitionistic Reasoning\<close>
   601 
   602 lemma impE':
   603   assumes 1: "P \<longrightarrow> Q"
   604     and 2: "Q \<Longrightarrow> R"
   605     and 3: "P \<longrightarrow> Q \<Longrightarrow> P"
   606   shows R
   607 proof -
   608   from 3 and 1 have P .
   609   with 1 have Q by (rule impE)
   610   with 2 show R .
   611 qed
   612 
   613 lemma allE':
   614   assumes 1: "\<forall>x. P x"
   615     and 2: "P x \<Longrightarrow> \<forall>x. P x \<Longrightarrow> Q"
   616   shows Q
   617 proof -
   618   from 1 have "P x" by (rule spec)
   619   from this and 1 show Q by (rule 2)
   620 qed
   621 
   622 lemma notE':
   623   assumes 1: "\<not> P"
   624     and 2: "\<not> P \<Longrightarrow> P"
   625   shows R
   626 proof -
   627   from 2 and 1 have P .
   628   with 1 show R by (rule notE)
   629 qed
   630 
   631 lemma TrueE: "True \<Longrightarrow> P \<Longrightarrow> P" .
   632 lemma notFalseE: "\<not> False \<Longrightarrow> P \<Longrightarrow> P" .
   633 
   634 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   635   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   636   and [Pure.elim 2] = allE notE' impE'
   637   and [Pure.intro] = exI disjI2 disjI1
   638 
   639 lemmas [trans] = trans
   640   and [sym] = sym not_sym
   641   and [Pure.elim?] = iffD1 iffD2 impE
   642 
   643 
   644 subsubsection \<open>Atomizing meta-level connectives\<close>
   645 
   646 axiomatization where
   647   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   648 
   649 lemma atomize_all [atomize]: "(\<And>x. P x) \<equiv> Trueprop (\<forall>x. P x)"
   650 proof
   651   assume "\<And>x. P x"
   652   then show "\<forall>x. P x" ..
   653 next
   654   assume "\<forall>x. P x"
   655   then show "\<And>x. P x" by (rule allE)
   656 qed
   657 
   658 lemma atomize_imp [atomize]: "(A \<Longrightarrow> B) \<equiv> Trueprop (A \<longrightarrow> B)"
   659 proof
   660   assume r: "A \<Longrightarrow> B"
   661   show "A \<longrightarrow> B" by (rule impI) (rule r)
   662 next
   663   assume "A \<longrightarrow> B" and A
   664   then show B by (rule mp)
   665 qed
   666 
   667 lemma atomize_not: "(A \<Longrightarrow> False) \<equiv> Trueprop (\<not> A)"
   668 proof
   669   assume r: "A \<Longrightarrow> False"
   670   show "\<not> A" by (rule notI) (rule r)
   671 next
   672   assume "\<not> A" and A
   673   then show False by (rule notE)
   674 qed
   675 
   676 lemma atomize_eq [atomize, code]: "(x \<equiv> y) \<equiv> Trueprop (x = y)"
   677 proof
   678   assume "x \<equiv> y"
   679   show "x = y" by (unfold \<open>x \<equiv> y\<close>) (rule refl)
   680 next
   681   assume "x = y"
   682   then show "x \<equiv> y" by (rule eq_reflection)
   683 qed
   684 
   685 lemma atomize_conj [atomize]: "(A &&& B) \<equiv> Trueprop (A \<and> B)"
   686 proof
   687   assume conj: "A &&& B"
   688   show "A \<and> B"
   689   proof (rule conjI)
   690     from conj show A by (rule conjunctionD1)
   691     from conj show B by (rule conjunctionD2)
   692   qed
   693 next
   694   assume conj: "A \<and> B"
   695   show "A &&& B"
   696   proof -
   697     from conj show A ..
   698     from conj show B ..
   699   qed
   700 qed
   701 
   702 lemmas [symmetric, rulify] = atomize_all atomize_imp
   703   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   704 
   705 
   706 subsubsection \<open>Atomizing elimination rules\<close>
   707 
   708 lemma atomize_exL[atomize_elim]: "(\<And>x. P x \<Longrightarrow> Q) \<equiv> ((\<exists>x. P x) \<Longrightarrow> Q)"
   709   by rule iprover+
   710 
   711 lemma atomize_conjL[atomize_elim]: "(A \<Longrightarrow> B \<Longrightarrow> C) \<equiv> (A \<and> B \<Longrightarrow> C)"
   712   by rule iprover+
   713 
   714 lemma atomize_disjL[atomize_elim]: "((A \<Longrightarrow> C) \<Longrightarrow> (B \<Longrightarrow> C) \<Longrightarrow> C) \<equiv> ((A \<or> B \<Longrightarrow> C) \<Longrightarrow> C)"
   715   by rule iprover+
   716 
   717 lemma atomize_elimL[atomize_elim]: "(\<And>B. (A \<Longrightarrow> B) \<Longrightarrow> B) \<equiv> Trueprop A" ..
   718 
   719 
   720 subsection \<open>Package setup\<close>
   721 
   722 ML_file "Tools/hologic.ML"
   723 
   724 
   725 subsubsection \<open>Sledgehammer setup\<close>
   726 
   727 text \<open>
   728 Theorems blacklisted to Sledgehammer. These theorems typically produce clauses
   729 that are prolific (match too many equality or membership literals) and relate to
   730 seldom-used facts. Some duplicate other rules.
   731 \<close>
   732 
   733 named_theorems no_atp "theorems that should be filtered out by Sledgehammer"
   734 
   735 
   736 subsubsection \<open>Classical Reasoner setup\<close>
   737 
   738 lemma imp_elim: "P \<longrightarrow> Q \<Longrightarrow> (\<not> R \<Longrightarrow> P) \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   739   by (rule classical) iprover
   740 
   741 lemma swap: "\<not> P \<Longrightarrow> (\<not> R \<Longrightarrow> P) \<Longrightarrow> R"
   742   by (rule classical) iprover
   743 
   744 lemma thin_refl: "\<And>X. \<lbrakk>x = x; PROP W\<rbrakk> \<Longrightarrow> PROP W" .
   745 
   746 ML \<open>
   747 structure Hypsubst = Hypsubst
   748 (
   749   val dest_eq = HOLogic.dest_eq
   750   val dest_Trueprop = HOLogic.dest_Trueprop
   751   val dest_imp = HOLogic.dest_imp
   752   val eq_reflection = @{thm eq_reflection}
   753   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   754   val imp_intr = @{thm impI}
   755   val rev_mp = @{thm rev_mp}
   756   val subst = @{thm subst}
   757   val sym = @{thm sym}
   758   val thin_refl = @{thm thin_refl};
   759 );
   760 open Hypsubst;
   761 
   762 structure Classical = Classical
   763 (
   764   val imp_elim = @{thm imp_elim}
   765   val not_elim = @{thm notE}
   766   val swap = @{thm swap}
   767   val classical = @{thm classical}
   768   val sizef = Drule.size_of_thm
   769   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   770 );
   771 
   772 structure Basic_Classical: BASIC_CLASSICAL = Classical;
   773 open Basic_Classical;
   774 \<close>
   775 
   776 setup \<open>
   777   (*prevent substitution on bool*)
   778   let
   779     fun non_bool_eq (@{const_name HOL.eq}, Type (_, [T, _])) = T <> @{typ bool}
   780       | non_bool_eq _ = false;
   781     fun hyp_subst_tac' ctxt =
   782       SUBGOAL (fn (goal, i) =>
   783         if Term.exists_Const non_bool_eq goal
   784         then Hypsubst.hyp_subst_tac ctxt i
   785         else no_tac);
   786   in
   787     Context_Rules.addSWrapper (fn ctxt => fn tac => hyp_subst_tac' ctxt ORELSE' tac)
   788   end
   789 \<close>
   790 
   791 declare iffI [intro!]
   792   and notI [intro!]
   793   and impI [intro!]
   794   and disjCI [intro!]
   795   and conjI [intro!]
   796   and TrueI [intro!]
   797   and refl [intro!]
   798 
   799 declare iffCE [elim!]
   800   and FalseE [elim!]
   801   and impCE [elim!]
   802   and disjE [elim!]
   803   and conjE [elim!]
   804 
   805 declare ex_ex1I [intro!]
   806   and allI [intro!]
   807   and exI [intro]
   808 
   809 declare exE [elim!]
   810   allE [elim]
   811 
   812 ML \<open>val HOL_cs = claset_of @{context}\<close>
   813 
   814 lemma contrapos_np: "\<not> Q \<Longrightarrow> (\<not> P \<Longrightarrow> Q) \<Longrightarrow> P"
   815   apply (erule swap)
   816   apply (erule (1) meta_mp)
   817   done
   818 
   819 declare ex_ex1I [rule del, intro! 2]
   820   and ex1I [intro]
   821 
   822 declare ext [intro]
   823 
   824 lemmas [intro?] = ext
   825   and [elim?] = ex1_implies_ex
   826 
   827 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   828 lemma alt_ex1E [elim!]:
   829   assumes major: "\<exists>!x. P x"
   830       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   831   shows R
   832 apply (rule ex1E [OF major])
   833 apply (rule prem)
   834 apply assumption
   835 apply (rule allI)+
   836 apply (tactic \<open>eresolve_tac @{context} [Classical.dup_elim @{context} @{thm allE}] 1\<close>)
   837 apply iprover
   838 done
   839 
   840 ML \<open>
   841   structure Blast = Blast
   842   (
   843     structure Classical = Classical
   844     val Trueprop_const = dest_Const @{const Trueprop}
   845     val equality_name = @{const_name HOL.eq}
   846     val not_name = @{const_name Not}
   847     val notE = @{thm notE}
   848     val ccontr = @{thm ccontr}
   849     val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   850   );
   851   val blast_tac = Blast.blast_tac;
   852 \<close>
   853 
   854 
   855 subsubsection \<open>THE: definite description operator\<close>
   856 
   857 lemma the_equality [intro]:
   858   assumes "P a"
   859       and "\<And>x. P x \<Longrightarrow> x = a"
   860   shows "(THE x. P x) = a"
   861   by (blast intro: assms trans [OF arg_cong [where f=The] the_eq_trivial])
   862 
   863 lemma theI:
   864   assumes "P a" and "\<And>x. P x \<Longrightarrow> x = a"
   865   shows "P (THE x. P x)"
   866 by (iprover intro: assms the_equality [THEN ssubst])
   867 
   868 lemma theI': "\<exists>!x. P x \<Longrightarrow> P (THE x. P x)"
   869   by (blast intro: theI)
   870 
   871 (*Easier to apply than theI: only one occurrence of P*)
   872 lemma theI2:
   873   assumes "P a" "\<And>x. P x \<Longrightarrow> x = a" "\<And>x. P x \<Longrightarrow> Q x"
   874   shows "Q (THE x. P x)"
   875 by (iprover intro: assms theI)
   876 
   877 lemma the1I2: assumes "\<exists>!x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   878 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   879            elim:allE impE)
   880 
   881 lemma the1_equality [elim?]: "\<lbrakk>\<exists>!x. P x; P a\<rbrakk> \<Longrightarrow> (THE x. P x) = a"
   882   by blast
   883 
   884 lemma the_sym_eq_trivial: "(THE y. x = y) = x"
   885   by blast
   886 
   887 
   888 subsubsection \<open>Simplifier\<close>
   889 
   890 lemma eta_contract_eq: "(\<lambda>s. f s) = f" ..
   891 
   892 lemma simp_thms:
   893   shows not_not: "(\<not> \<not> P) = P"
   894   and Not_eq_iff: "((\<not> P) = (\<not> Q)) = (P = Q)"
   895   and
   896     "(P \<noteq> Q) = (P = (\<not> Q))"
   897     "(P \<or> \<not>P) = True"    "(\<not> P \<or> P) = True"
   898     "(x = x) = True"
   899   and not_True_eq_False [code]: "(\<not> True) = False"
   900   and not_False_eq_True [code]: "(\<not> False) = True"
   901   and
   902     "(\<not> P) \<noteq> P"  "P \<noteq> (\<not> P)"
   903     "(True = P) = P"
   904   and eq_True: "(P = True) = P"
   905   and "(False = P) = (\<not> P)"
   906   and eq_False: "(P = False) = (\<not> P)"
   907   and
   908     "(True \<longrightarrow> P) = P"  "(False \<longrightarrow> P) = True"
   909     "(P \<longrightarrow> True) = True"  "(P \<longrightarrow> P) = True"
   910     "(P \<longrightarrow> False) = (\<not> P)"  "(P \<longrightarrow> \<not> P) = (\<not> P)"
   911     "(P \<and> True) = P"  "(True \<and> P) = P"
   912     "(P \<and> False) = False"  "(False \<and> P) = False"
   913     "(P \<and> P) = P"  "(P \<and> (P \<and> Q)) = (P \<and> Q)"
   914     "(P \<and> \<not> P) = False"    "(\<not> P \<and> P) = False"
   915     "(P \<or> True) = True"  "(True \<or> P) = True"
   916     "(P \<or> False) = P"  "(False \<or> P) = P"
   917     "(P \<or> P) = P"  "(P \<or> (P \<or> Q)) = (P \<or> Q)" and
   918     "(\<forall>x. P) = P"  "(\<exists>x. P) = P"  "\<exists>x. x = t"  "\<exists>x. t = x"
   919   and
   920     "\<And>P. (\<exists>x. x = t \<and> P x) = P t"
   921     "\<And>P. (\<exists>x. t = x \<and> P x) = P t"
   922     "\<And>P. (\<forall>x. x = t \<longrightarrow> P x) = P t"
   923     "\<And>P. (\<forall>x. t = x \<longrightarrow> P x) = P t"
   924   by (blast, blast, blast, blast, blast, iprover+)
   925 
   926 lemma disj_absorb: "(A \<or> A) = A"
   927   by blast
   928 
   929 lemma disj_left_absorb: "(A \<or> (A \<or> B)) = (A \<or> B)"
   930   by blast
   931 
   932 lemma conj_absorb: "(A \<and> A) = A"
   933   by blast
   934 
   935 lemma conj_left_absorb: "(A \<and> (A \<and> B)) = (A \<and> B)"
   936   by blast
   937 
   938 lemma eq_ac:
   939   shows eq_commute: "a = b \<longleftrightarrow> b = a"
   940     and iff_left_commute: "(P \<longleftrightarrow> (Q \<longleftrightarrow> R)) \<longleftrightarrow> (Q \<longleftrightarrow> (P \<longleftrightarrow> R))"
   941     and iff_assoc: "((P \<longleftrightarrow> Q) \<longleftrightarrow> R) \<longleftrightarrow> (P \<longleftrightarrow> (Q \<longleftrightarrow> R))" by (iprover, blast+)
   942 lemma neq_commute: "a \<noteq> b \<longleftrightarrow> b \<noteq> a" by iprover
   943 
   944 lemma conj_comms:
   945   shows conj_commute: "(P \<and> Q) = (Q \<and> P)"
   946     and conj_left_commute: "(P \<and> (Q \<and> R)) = (Q \<and> (P \<and> R))" by iprover+
   947 lemma conj_assoc: "((P \<and> Q) \<and> R) = (P \<and> (Q \<and> R))" by iprover
   948 
   949 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
   950 
   951 lemma disj_comms:
   952   shows disj_commute: "(P \<or> Q) = (Q \<or> P)"
   953     and disj_left_commute: "(P \<or> (Q \<or> R)) = (Q \<or> (P \<or> R))" by iprover+
   954 lemma disj_assoc: "((P \<or> Q) \<or> R) = (P \<or> (Q \<or> R))" by iprover
   955 
   956 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
   957 
   958 lemma conj_disj_distribL: "(P \<and> (Q \<or> R)) = (P \<and> Q \<or> P \<and> R)" by iprover
   959 lemma conj_disj_distribR: "((P \<or> Q) \<and> R) = (P \<and> R \<or> Q \<and> R)" by iprover
   960 
   961 lemma disj_conj_distribL: "(P \<or> (Q \<and> R)) = ((P \<or> Q) \<and> (P \<or> R))" by iprover
   962 lemma disj_conj_distribR: "((P \<and> Q) \<or> R) = ((P \<or> R) \<and> (Q \<or> R))" by iprover
   963 
   964 lemma imp_conjR: "(P \<longrightarrow> (Q \<and> R)) = ((P \<longrightarrow> Q) \<and> (P \<longrightarrow> R))" by iprover
   965 lemma imp_conjL: "((P \<and> Q) \<longrightarrow> R) = (P \<longrightarrow> (Q \<longrightarrow> R))" by iprover
   966 lemma imp_disjL: "((P \<or> Q) \<longrightarrow> R) = ((P \<longrightarrow> R) \<and> (Q \<longrightarrow> R))" by iprover
   967 
   968 text \<open>These two are specialized, but \<open>imp_disj_not1\<close> is useful in \<open>Auth/Yahalom\<close>.\<close>
   969 lemma imp_disj_not1: "(P \<longrightarrow> Q \<or> R) = (\<not> Q \<longrightarrow> P \<longrightarrow> R)" by blast
   970 lemma imp_disj_not2: "(P \<longrightarrow> Q \<or> R) = (\<not> R \<longrightarrow> P \<longrightarrow> Q)" by blast
   971 
   972 lemma imp_disj1: "((P \<longrightarrow> Q) \<or> R) = (P \<longrightarrow> Q \<or> R)" by blast
   973 lemma imp_disj2: "(Q \<or> (P \<longrightarrow> R)) = (P \<longrightarrow> Q \<or> R)" by blast
   974 
   975 lemma imp_cong: "(P = P') \<Longrightarrow> (P' \<Longrightarrow> (Q = Q')) \<Longrightarrow> ((P \<longrightarrow> Q) = (P' \<longrightarrow> Q'))"
   976   by iprover
   977 
   978 lemma de_Morgan_disj: "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not> Q)" by iprover
   979 lemma de_Morgan_conj: "(\<not> (P \<and> Q)) = (\<not> P \<or> \<not> Q)" by blast
   980 lemma not_imp: "(\<not> (P \<longrightarrow> Q)) = (P \<and> \<not> Q)" by blast
   981 lemma not_iff: "(P \<noteq> Q) = (P = (\<not> Q))" by blast
   982 lemma disj_not1: "(\<not> P \<or> Q) = (P \<longrightarrow> Q)" by blast
   983 lemma disj_not2: "(P \<or> \<not> Q) = (Q \<longrightarrow> P)"  \<comment> \<open>changes orientation :-(\<close>
   984   by blast
   985 lemma imp_conv_disj: "(P \<longrightarrow> Q) = ((\<not> P) \<or> Q)" by blast
   986 
   987 lemma iff_conv_conj_imp: "(P = Q) = ((P \<longrightarrow> Q) \<and> (Q \<longrightarrow> P))" by iprover
   988 
   989 
   990 lemma cases_simp: "((P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> Q)) = Q"
   991   \<comment> \<open>Avoids duplication of subgoals after \<open>split_if\<close>, when the true and false\<close>
   992   \<comment> \<open>cases boil down to the same thing.\<close>
   993   by blast
   994 
   995 lemma not_all: "(\<not> (\<forall>x. P x)) = (\<exists>x. \<not> P x)" by blast
   996 lemma imp_all: "((\<forall>x. P x) \<longrightarrow> Q) = (\<exists>x. P x \<longrightarrow> Q)" by blast
   997 lemma not_ex: "(\<not> (\<exists>x. P x)) = (\<forall>x. \<not> P x)" by iprover
   998 lemma imp_ex: "((\<exists>x. P x) \<longrightarrow> Q) = (\<forall>x. P x \<longrightarrow> Q)" by iprover
   999 lemma all_not_ex: "(\<forall>x. P x) = (\<not> (\<exists>x. \<not> P x ))" by blast
  1000 
  1001 declare All_def [no_atp]
  1002 
  1003 lemma ex_disj_distrib: "(\<exists>x. P x \<or> Q x) = ((\<exists>x. P x) \<or> (\<exists>x. Q x))" by iprover
  1004 lemma all_conj_distrib: "(\<forall>x. P x \<and> Q x) = ((\<forall>x. P x) \<and> (\<forall>x. Q x))" by iprover
  1005 
  1006 text \<open>
  1007   \medskip The \<open>\<and>\<close> congruence rule: not included by default!
  1008   May slow rewrite proofs down by as much as 50\%\<close>
  1009 
  1010 lemma conj_cong:
  1011     "(P = P') \<Longrightarrow> (P' \<Longrightarrow> (Q = Q')) \<Longrightarrow> ((P \<and> Q) = (P' \<and> Q'))"
  1012   by iprover
  1013 
  1014 lemma rev_conj_cong:
  1015     "(Q = Q') \<Longrightarrow> (Q' \<Longrightarrow> (P = P')) \<Longrightarrow> ((P \<and> Q) = (P' \<and> Q'))"
  1016   by iprover
  1017 
  1018 text \<open>The \<open>|\<close> congruence rule: not included by default!\<close>
  1019 
  1020 lemma disj_cong:
  1021     "(P = P') \<Longrightarrow> (\<not> P' \<Longrightarrow> (Q = Q')) \<Longrightarrow> ((P \<or> Q) = (P' \<or> Q'))"
  1022   by blast
  1023 
  1024 
  1025 text \<open>\medskip if-then-else rules\<close>
  1026 
  1027 lemma if_True [code]: "(if True then x else y) = x"
  1028   by (unfold If_def) blast
  1029 
  1030 lemma if_False [code]: "(if False then x else y) = y"
  1031   by (unfold If_def) blast
  1032 
  1033 lemma if_P: "P \<Longrightarrow> (if P then x else y) = x"
  1034   by (unfold If_def) blast
  1035 
  1036 lemma if_not_P: "\<not> P \<Longrightarrow> (if P then x else y) = y"
  1037   by (unfold If_def) blast
  1038 
  1039 lemma split_if: "P (if Q then x else y) = ((Q \<longrightarrow> P x) \<and> (\<not> Q \<longrightarrow> P y))"
  1040   apply (rule case_split [of Q])
  1041    apply (simplesubst if_P)
  1042     prefer 3 apply (simplesubst if_not_P, blast+)
  1043   done
  1044 
  1045 lemma split_if_asm: "P (if Q then x else y) = (\<not> ((Q \<and> \<not> P x) \<or> (\<not> Q \<and> \<not> P y)))"
  1046 by (simplesubst split_if, blast)
  1047 
  1048 lemmas if_splits [no_atp] = split_if split_if_asm
  1049 
  1050 lemma if_cancel: "(if c then x else x) = x"
  1051 by (simplesubst split_if, blast)
  1052 
  1053 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1054 by (simplesubst split_if, blast)
  1055 
  1056 lemma if_bool_eq_conj: "(if P then Q else R) = ((P \<longrightarrow> Q) \<and> (\<not> P \<longrightarrow> R))"
  1057   \<comment> \<open>This form is useful for expanding \<open>if\<close>s on the RIGHT of the \<open>\<Longrightarrow>\<close> symbol.\<close>
  1058   by (rule split_if)
  1059 
  1060 lemma if_bool_eq_disj: "(if P then Q else R) = ((P \<and> Q) \<or> (\<not> P \<and> R))"
  1061   \<comment> \<open>And this form is useful for expanding \<open>if\<close>s on the LEFT.\<close>
  1062   by (simplesubst split_if) blast
  1063 
  1064 lemma Eq_TrueI: "P \<Longrightarrow> P \<equiv> True" by (unfold atomize_eq) iprover
  1065 lemma Eq_FalseI: "\<not> P \<Longrightarrow> P \<equiv> False" by (unfold atomize_eq) iprover
  1066 
  1067 text \<open>\medskip let rules for simproc\<close>
  1068 
  1069 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow> Let x f \<equiv> Let x g"
  1070   by (unfold Let_def)
  1071 
  1072 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow> Let x f \<equiv> g"
  1073   by (unfold Let_def)
  1074 
  1075 text \<open>
  1076   The following copy of the implication operator is useful for
  1077   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1078   its premise.
  1079 \<close>
  1080 
  1081 definition simp_implies :: "[prop, prop] \<Rightarrow> prop"  (infixr "=simp=>" 1) where
  1082   "simp_implies \<equiv> op \<Longrightarrow>"
  1083 
  1084 lemma simp_impliesI:
  1085   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1086   shows "PROP P =simp=> PROP Q"
  1087   apply (unfold simp_implies_def)
  1088   apply (rule PQ)
  1089   apply assumption
  1090   done
  1091 
  1092 lemma simp_impliesE:
  1093   assumes PQ: "PROP P =simp=> PROP Q"
  1094   and P: "PROP P"
  1095   and QR: "PROP Q \<Longrightarrow> PROP R"
  1096   shows "PROP R"
  1097   apply (rule QR)
  1098   apply (rule PQ [unfolded simp_implies_def])
  1099   apply (rule P)
  1100   done
  1101 
  1102 lemma simp_implies_cong:
  1103   assumes PP' :"PROP P \<equiv> PROP P'"
  1104   and P'QQ': "PROP P' \<Longrightarrow> (PROP Q \<equiv> PROP Q')"
  1105   shows "(PROP P =simp=> PROP Q) \<equiv> (PROP P' =simp=> PROP Q')"
  1106 proof (unfold simp_implies_def, rule equal_intr_rule)
  1107   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1108   and P': "PROP P'"
  1109   from PP' [symmetric] and P' have "PROP P"
  1110     by (rule equal_elim_rule1)
  1111   then have "PROP Q" by (rule PQ)
  1112   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1113 next
  1114   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1115   and P: "PROP P"
  1116   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1117   then have "PROP Q'" by (rule P'Q')
  1118   with P'QQ' [OF P', symmetric] show "PROP Q"
  1119     by (rule equal_elim_rule1)
  1120 qed
  1121 
  1122 lemma uncurry:
  1123   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1124   shows "P \<and> Q \<longrightarrow> R"
  1125   using assms by blast
  1126 
  1127 lemma iff_allI:
  1128   assumes "\<And>x. P x = Q x"
  1129   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1130   using assms by blast
  1131 
  1132 lemma iff_exI:
  1133   assumes "\<And>x. P x = Q x"
  1134   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1135   using assms by blast
  1136 
  1137 lemma all_comm:
  1138   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1139   by blast
  1140 
  1141 lemma ex_comm:
  1142   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1143   by blast
  1144 
  1145 ML_file "Tools/simpdata.ML"
  1146 ML \<open>open Simpdata\<close>
  1147 
  1148 setup \<open>
  1149   map_theory_simpset (put_simpset HOL_basic_ss) #>
  1150   Simplifier.method_setup Splitter.split_modifiers
  1151 \<close>
  1152 
  1153 simproc_setup defined_Ex ("\<exists>x. P x") = \<open>fn _ => Quantifier1.rearrange_ex\<close>
  1154 simproc_setup defined_All ("\<forall>x. P x") = \<open>fn _ => Quantifier1.rearrange_all\<close>
  1155 
  1156 text \<open>Simproc for proving \<open>(y = x) \<equiv> False\<close> from premise \<open>\<not> (x = y)\<close>:\<close>
  1157 
  1158 simproc_setup neq ("x = y") = \<open>fn _ =>
  1159 let
  1160   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1161   fun is_neq eq lhs rhs thm =
  1162     (case Thm.prop_of thm of
  1163       _ $ (Not $ (eq' $ l' $ r')) =>
  1164         Not = HOLogic.Not andalso eq' = eq andalso
  1165         r' aconv lhs andalso l' aconv rhs
  1166     | _ => false);
  1167   fun proc ss ct =
  1168     (case Thm.term_of ct of
  1169       eq $ lhs $ rhs =>
  1170         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of ss) of
  1171           SOME thm => SOME (thm RS neq_to_EQ_False)
  1172         | NONE => NONE)
  1173      | _ => NONE);
  1174 in proc end;
  1175 \<close>
  1176 
  1177 simproc_setup let_simp ("Let x f") = \<open>
  1178 let
  1179   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1180     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1181     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1182     | count_loose _ _ = 0;
  1183   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1184     (case t of
  1185       Abs (_, _, t') => count_loose t' 0 <= 1
  1186     | _ => true);
  1187 in
  1188   fn _ => fn ctxt => fn ct =>
  1189     if is_trivial_let (Thm.term_of ct)
  1190     then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1191     else
  1192       let (*Norbert Schirmer's case*)
  1193         val t = Thm.term_of ct;
  1194         val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1195       in
  1196         Option.map (hd o Variable.export ctxt' ctxt o single)
  1197           (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1198             if is_Free x orelse is_Bound x orelse is_Const x
  1199             then SOME @{thm Let_def}
  1200             else
  1201               let
  1202                 val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1203                 val cx = Thm.cterm_of ctxt x;
  1204                 val xT = Thm.typ_of_cterm cx;
  1205                 val cf = Thm.cterm_of ctxt f;
  1206                 val fx_g = Simplifier.rewrite ctxt (Thm.apply cf cx);
  1207                 val (_ $ _ $ g) = Thm.prop_of fx_g;
  1208                 val g' = abstract_over (x, g);
  1209                 val abs_g'= Abs (n, xT, g');
  1210               in
  1211                 if g aconv g' then
  1212                   let
  1213                     val rl =
  1214                       infer_instantiate ctxt [(("f", 0), cf), (("x", 0), cx)] @{thm Let_unfold};
  1215                   in SOME (rl OF [fx_g]) end
  1216                 else if (Envir.beta_eta_contract f) aconv (Envir.beta_eta_contract abs_g')
  1217                 then NONE (*avoid identity conversion*)
  1218                 else
  1219                   let
  1220                     val g'x = abs_g' $ x;
  1221                     val g_g'x = Thm.symmetric (Thm.beta_conversion false (Thm.cterm_of ctxt g'x));
  1222                     val rl =
  1223                       @{thm Let_folded} |> infer_instantiate ctxt
  1224                         [(("f", 0), Thm.cterm_of ctxt f),
  1225                          (("x", 0), cx),
  1226                          (("g", 0), Thm.cterm_of ctxt abs_g')];
  1227                   in SOME (rl OF [Thm.transitive fx_g g_g'x]) end
  1228               end
  1229           | _ => NONE)
  1230       end
  1231 end\<close>
  1232 
  1233 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1234 proof
  1235   assume "True \<Longrightarrow> PROP P"
  1236   from this [OF TrueI] show "PROP P" .
  1237 next
  1238   assume "PROP P"
  1239   then show "PROP P" .
  1240 qed
  1241 
  1242 lemma implies_True_equals: "(PROP P \<Longrightarrow> True) \<equiv> Trueprop True"
  1243   by standard (intro TrueI)
  1244 
  1245 lemma False_implies_equals: "(False \<Longrightarrow> P) \<equiv> Trueprop True"
  1246   by standard simp_all
  1247 
  1248 (* This is not made a simp rule because it does not improve any proofs
  1249    but slows some AFP entries down by 5% (cpu time). May 2015 *)
  1250 lemma implies_False_swap: "NO_MATCH (Trueprop False) P \<Longrightarrow>
  1251   (False \<Longrightarrow> PROP P \<Longrightarrow> PROP Q) \<equiv> (PROP P \<Longrightarrow> False \<Longrightarrow> PROP Q)"
  1252 by(rule swap_prems_eq)
  1253 
  1254 lemma ex_simps:
  1255   "\<And>P Q. (\<exists>x. P x \<and> Q)   = ((\<exists>x. P x) \<and> Q)"
  1256   "\<And>P Q. (\<exists>x. P \<and> Q x)   = (P \<and> (\<exists>x. Q x))"
  1257   "\<And>P Q. (\<exists>x. P x \<or> Q)   = ((\<exists>x. P x) \<or> Q)"
  1258   "\<And>P Q. (\<exists>x. P \<or> Q x)   = (P \<or> (\<exists>x. Q x))"
  1259   "\<And>P Q. (\<exists>x. P x \<longrightarrow> Q) = ((\<forall>x. P x) \<longrightarrow> Q)"
  1260   "\<And>P Q. (\<exists>x. P \<longrightarrow> Q x) = (P \<longrightarrow> (\<exists>x. Q x))"
  1261   \<comment> \<open>Miniscoping: pushing in existential quantifiers.\<close>
  1262   by (iprover | blast)+
  1263 
  1264 lemma all_simps:
  1265   "\<And>P Q. (\<forall>x. P x \<and> Q)   = ((\<forall>x. P x) \<and> Q)"
  1266   "\<And>P Q. (\<forall>x. P \<and> Q x)   = (P \<and> (\<forall>x. Q x))"
  1267   "\<And>P Q. (\<forall>x. P x \<or> Q)   = ((\<forall>x. P x) \<or> Q)"
  1268   "\<And>P Q. (\<forall>x. P \<or> Q x)   = (P \<or> (\<forall>x. Q x))"
  1269   "\<And>P Q. (\<forall>x. P x \<longrightarrow> Q) = ((\<exists>x. P x) \<longrightarrow> Q)"
  1270   "\<And>P Q. (\<forall>x. P \<longrightarrow> Q x) = (P \<longrightarrow> (\<forall>x. Q x))"
  1271   \<comment> \<open>Miniscoping: pushing in universal quantifiers.\<close>
  1272   by (iprover | blast)+
  1273 
  1274 lemmas [simp] =
  1275   triv_forall_equality (*prunes params*)
  1276   True_implies_equals implies_True_equals (*prune True in asms*)
  1277   False_implies_equals (*prune False in asms*)
  1278   if_True
  1279   if_False
  1280   if_cancel
  1281   if_eq_cancel
  1282   imp_disjL
  1283   (*In general it seems wrong to add distributive laws by default: they
  1284     might cause exponential blow-up.  But imp_disjL has been in for a while
  1285     and cannot be removed without affecting existing proofs.  Moreover,
  1286     rewriting by "(P \<or> Q \<longrightarrow> R) = ((P \<longrightarrow> R) \<and> (Q \<longrightarrow> R))" might be justified on the
  1287     grounds that it allows simplification of R in the two cases.*)
  1288   conj_assoc
  1289   disj_assoc
  1290   de_Morgan_conj
  1291   de_Morgan_disj
  1292   imp_disj1
  1293   imp_disj2
  1294   not_imp
  1295   disj_not1
  1296   not_all
  1297   not_ex
  1298   cases_simp
  1299   the_eq_trivial
  1300   the_sym_eq_trivial
  1301   ex_simps
  1302   all_simps
  1303   simp_thms
  1304 
  1305 lemmas [cong] = imp_cong simp_implies_cong
  1306 lemmas [split] = split_if
  1307 
  1308 ML \<open>val HOL_ss = simpset_of @{context}\<close>
  1309 
  1310 text \<open>Simplifies @{term x} assuming @{prop c} and @{term y} assuming @{prop "\<not> c"}\<close>
  1311 lemma if_cong:
  1312   assumes "b = c"
  1313       and "c \<Longrightarrow> x = u"
  1314       and "\<not> c \<Longrightarrow> y = v"
  1315   shows "(if b then x else y) = (if c then u else v)"
  1316   using assms by simp
  1317 
  1318 text \<open>Prevents simplification of x and y:
  1319   faster and allows the execution of functional programs.\<close>
  1320 lemma if_weak_cong [cong]:
  1321   assumes "b = c"
  1322   shows "(if b then x else y) = (if c then x else y)"
  1323   using assms by (rule arg_cong)
  1324 
  1325 text \<open>Prevents simplification of t: much faster\<close>
  1326 lemma let_weak_cong:
  1327   assumes "a = b"
  1328   shows "(let x = a in t x) = (let x = b in t x)"
  1329   using assms by (rule arg_cong)
  1330 
  1331 text \<open>To tidy up the result of a simproc.  Only the RHS will be simplified.\<close>
  1332 lemma eq_cong2:
  1333   assumes "u = u'"
  1334   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1335   using assms by simp
  1336 
  1337 lemma if_distrib:
  1338   "f (if c then x else y) = (if c then f x else f y)"
  1339   by simp
  1340 
  1341 text\<open>As a simplification rule, it replaces all function equalities by
  1342   first-order equalities.\<close>
  1343 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
  1344   by auto
  1345 
  1346 
  1347 subsubsection \<open>Generic cases and induction\<close>
  1348 
  1349 text \<open>Rule projections:\<close>
  1350 ML \<open>
  1351 structure Project_Rule = Project_Rule
  1352 (
  1353   val conjunct1 = @{thm conjunct1}
  1354   val conjunct2 = @{thm conjunct2}
  1355   val mp = @{thm mp}
  1356 );
  1357 \<close>
  1358 
  1359 context
  1360 begin
  1361 
  1362 qualified definition "induct_forall P \<equiv> \<forall>x. P x"
  1363 qualified definition "induct_implies A B \<equiv> A \<longrightarrow> B"
  1364 qualified definition "induct_equal x y \<equiv> x = y"
  1365 qualified definition "induct_conj A B \<equiv> A \<and> B"
  1366 qualified definition "induct_true \<equiv> True"
  1367 qualified definition "induct_false \<equiv> False"
  1368 
  1369 lemma induct_forall_eq: "(\<And>x. P x) \<equiv> Trueprop (induct_forall (\<lambda>x. P x))"
  1370   by (unfold atomize_all induct_forall_def)
  1371 
  1372 lemma induct_implies_eq: "(A \<Longrightarrow> B) \<equiv> Trueprop (induct_implies A B)"
  1373   by (unfold atomize_imp induct_implies_def)
  1374 
  1375 lemma induct_equal_eq: "(x \<equiv> y) \<equiv> Trueprop (induct_equal x y)"
  1376   by (unfold atomize_eq induct_equal_def)
  1377 
  1378 lemma induct_conj_eq: "(A &&& B) \<equiv> Trueprop (induct_conj A B)"
  1379   by (unfold atomize_conj induct_conj_def)
  1380 
  1381 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
  1382 lemmas induct_atomize = induct_atomize' induct_equal_eq
  1383 lemmas induct_rulify' [symmetric] = induct_atomize'
  1384 lemmas induct_rulify [symmetric] = induct_atomize
  1385 lemmas induct_rulify_fallback =
  1386   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1387   induct_true_def induct_false_def
  1388 
  1389 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1390     induct_conj (induct_forall A) (induct_forall B)"
  1391   by (unfold induct_forall_def induct_conj_def) iprover
  1392 
  1393 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1394     induct_conj (induct_implies C A) (induct_implies C B)"
  1395   by (unfold induct_implies_def induct_conj_def) iprover
  1396 
  1397 lemma induct_conj_curry: "(induct_conj A B \<Longrightarrow> PROP C) \<equiv> (A \<Longrightarrow> B \<Longrightarrow> PROP C)"
  1398 proof
  1399   assume r: "induct_conj A B \<Longrightarrow> PROP C"
  1400   assume ab: A B
  1401   show "PROP C" by (rule r) (simp add: induct_conj_def ab)
  1402 next
  1403   assume r: "A \<Longrightarrow> B \<Longrightarrow> PROP C"
  1404   assume ab: "induct_conj A B"
  1405   show "PROP C" by (rule r) (simp_all add: ab [unfolded induct_conj_def])
  1406 qed
  1407 
  1408 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1409 
  1410 lemma induct_trueI: "induct_true"
  1411   by (simp add: induct_true_def)
  1412 
  1413 text \<open>Method setup.\<close>
  1414 
  1415 ML_file "~~/src/Tools/induct.ML"
  1416 ML \<open>
  1417 structure Induct = Induct
  1418 (
  1419   val cases_default = @{thm case_split}
  1420   val atomize = @{thms induct_atomize}
  1421   val rulify = @{thms induct_rulify'}
  1422   val rulify_fallback = @{thms induct_rulify_fallback}
  1423   val equal_def = @{thm induct_equal_def}
  1424   fun dest_def (Const (@{const_name induct_equal}, _) $ t $ u) = SOME (t, u)
  1425     | dest_def _ = NONE
  1426   fun trivial_tac ctxt = match_tac ctxt @{thms induct_trueI}
  1427 )
  1428 \<close>
  1429 
  1430 ML_file "~~/src/Tools/induction.ML"
  1431 
  1432 declaration \<open>
  1433   fn _ => Induct.map_simpset (fn ss => ss
  1434     addsimprocs
  1435       [Simplifier.make_simproc @{context} "swap_induct_false"
  1436         {lhss = [@{term "induct_false \<Longrightarrow> PROP P \<Longrightarrow> PROP Q"}],
  1437          proc = fn _ => fn _ => fn ct =>
  1438           (case Thm.term_of ct of
  1439             _ $ (P as _ $ @{const induct_false}) $ (_ $ Q $ _) =>
  1440               if P <> Q then SOME Drule.swap_prems_eq else NONE
  1441           | _ => NONE),
  1442          identifier = []},
  1443        Simplifier.make_simproc @{context} "induct_equal_conj_curry"
  1444         {lhss = [@{term "induct_conj P Q \<Longrightarrow> PROP R"}],
  1445          proc = fn _ => fn _ => fn ct =>
  1446           (case Thm.term_of ct of
  1447             _ $ (_ $ P) $ _ =>
  1448               let
  1449                 fun is_conj (@{const induct_conj} $ P $ Q) =
  1450                       is_conj P andalso is_conj Q
  1451                   | is_conj (Const (@{const_name induct_equal}, _) $ _ $ _) = true
  1452                   | is_conj @{const induct_true} = true
  1453                   | is_conj @{const induct_false} = true
  1454                   | is_conj _ = false
  1455               in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
  1456             | _ => NONE),
  1457           identifier = []}]
  1458     |> Simplifier.set_mksimps (fn ctxt =>
  1459         Simpdata.mksimps Simpdata.mksimps_pairs ctxt #>
  1460         map (rewrite_rule ctxt (map Thm.symmetric @{thms induct_rulify_fallback}))))
  1461 \<close>
  1462 
  1463 text \<open>Pre-simplification of induction and cases rules\<close>
  1464 
  1465 lemma [induct_simp]: "(\<And>x. induct_equal x t \<Longrightarrow> PROP P x) \<equiv> PROP P t"
  1466   unfolding induct_equal_def
  1467 proof
  1468   assume r: "\<And>x. x = t \<Longrightarrow> PROP P x"
  1469   show "PROP P t" by (rule r [OF refl])
  1470 next
  1471   fix x
  1472   assume "PROP P t" "x = t"
  1473   then show "PROP P x" by simp
  1474 qed
  1475 
  1476 lemma [induct_simp]: "(\<And>x. induct_equal t x \<Longrightarrow> PROP P x) \<equiv> PROP P t"
  1477   unfolding induct_equal_def
  1478 proof
  1479   assume r: "\<And>x. t = x \<Longrightarrow> PROP P x"
  1480   show "PROP P t" by (rule r [OF refl])
  1481 next
  1482   fix x
  1483   assume "PROP P t" "t = x"
  1484   then show "PROP P x" by simp
  1485 qed
  1486 
  1487 lemma [induct_simp]: "(induct_false \<Longrightarrow> P) \<equiv> Trueprop induct_true"
  1488   unfolding induct_false_def induct_true_def
  1489   by (iprover intro: equal_intr_rule)
  1490 
  1491 lemma [induct_simp]: "(induct_true \<Longrightarrow> PROP P) \<equiv> PROP P"
  1492   unfolding induct_true_def
  1493 proof
  1494   assume "True \<Longrightarrow> PROP P"
  1495   then show "PROP P" using TrueI .
  1496 next
  1497   assume "PROP P"
  1498   then show "PROP P" .
  1499 qed
  1500 
  1501 lemma [induct_simp]: "(PROP P \<Longrightarrow> induct_true) \<equiv> Trueprop induct_true"
  1502   unfolding induct_true_def
  1503   by (iprover intro: equal_intr_rule)
  1504 
  1505 lemma [induct_simp]: "(\<And>x. induct_true) \<equiv> Trueprop induct_true"
  1506   unfolding induct_true_def
  1507   by (iprover intro: equal_intr_rule)
  1508 
  1509 lemma [induct_simp]: "induct_implies induct_true P \<equiv> P"
  1510   by (simp add: induct_implies_def induct_true_def)
  1511 
  1512 lemma [induct_simp]: "x = x \<longleftrightarrow> True"
  1513   by (rule simp_thms)
  1514 
  1515 end
  1516 
  1517 ML_file "~~/src/Tools/induct_tacs.ML"
  1518 
  1519 
  1520 subsubsection \<open>Coherent logic\<close>
  1521 
  1522 ML_file "~~/src/Tools/coherent.ML"
  1523 ML \<open>
  1524 structure Coherent = Coherent
  1525 (
  1526   val atomize_elimL = @{thm atomize_elimL};
  1527   val atomize_exL = @{thm atomize_exL};
  1528   val atomize_conjL = @{thm atomize_conjL};
  1529   val atomize_disjL = @{thm atomize_disjL};
  1530   val operator_names = [@{const_name HOL.disj}, @{const_name HOL.conj}, @{const_name Ex}];
  1531 );
  1532 \<close>
  1533 
  1534 
  1535 subsubsection \<open>Reorienting equalities\<close>
  1536 
  1537 ML \<open>
  1538 signature REORIENT_PROC =
  1539 sig
  1540   val add : (term -> bool) -> theory -> theory
  1541   val proc : morphism -> Proof.context -> cterm -> thm option
  1542 end;
  1543 
  1544 structure Reorient_Proc : REORIENT_PROC =
  1545 struct
  1546   structure Data = Theory_Data
  1547   (
  1548     type T = ((term -> bool) * stamp) list;
  1549     val empty = [];
  1550     val extend = I;
  1551     fun merge data : T = Library.merge (eq_snd op =) data;
  1552   );
  1553   fun add m = Data.map (cons (m, stamp ()));
  1554   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1555 
  1556   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1557   fun proc phi ctxt ct =
  1558     let
  1559       val thy = Proof_Context.theory_of ctxt;
  1560     in
  1561       case Thm.term_of ct of
  1562         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1563       | _ => NONE
  1564     end;
  1565 end;
  1566 \<close>
  1567 
  1568 
  1569 subsection \<open>Other simple lemmas and lemma duplicates\<close>
  1570 
  1571 lemma ex1_eq [iff]: "\<exists>!x. x = t" "\<exists>!x. t = x"
  1572   by blast+
  1573 
  1574 lemma choice_eq: "(\<forall>x. \<exists>!y. P x y) = (\<exists>!f. \<forall>x. P x (f x))"
  1575   apply (rule iffI)
  1576   apply (rule_tac a = "\<lambda>x. THE y. P x y" in ex1I)
  1577   apply (fast dest!: theI')
  1578   apply (fast intro: the1_equality [symmetric])
  1579   apply (erule ex1E)
  1580   apply (rule allI)
  1581   apply (rule ex1I)
  1582   apply (erule spec)
  1583   apply (erule_tac x = "\<lambda>z. if z = x then y else f z" in allE)
  1584   apply (erule impE)
  1585   apply (rule allI)
  1586   apply (case_tac "xa = x")
  1587   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1588   done
  1589 
  1590 lemmas eq_sym_conv = eq_commute
  1591 
  1592 lemma nnf_simps:
  1593   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)"
  1594   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))"
  1595   "(\<not> \<not>(P)) = P"
  1596 by blast+
  1597 
  1598 subsection \<open>Basic ML bindings\<close>
  1599 
  1600 ML \<open>
  1601 val FalseE = @{thm FalseE}
  1602 val Let_def = @{thm Let_def}
  1603 val TrueI = @{thm TrueI}
  1604 val allE = @{thm allE}
  1605 val allI = @{thm allI}
  1606 val all_dupE = @{thm all_dupE}
  1607 val arg_cong = @{thm arg_cong}
  1608 val box_equals = @{thm box_equals}
  1609 val ccontr = @{thm ccontr}
  1610 val classical = @{thm classical}
  1611 val conjE = @{thm conjE}
  1612 val conjI = @{thm conjI}
  1613 val conjunct1 = @{thm conjunct1}
  1614 val conjunct2 = @{thm conjunct2}
  1615 val disjCI = @{thm disjCI}
  1616 val disjE = @{thm disjE}
  1617 val disjI1 = @{thm disjI1}
  1618 val disjI2 = @{thm disjI2}
  1619 val eq_reflection = @{thm eq_reflection}
  1620 val ex1E = @{thm ex1E}
  1621 val ex1I = @{thm ex1I}
  1622 val ex1_implies_ex = @{thm ex1_implies_ex}
  1623 val exE = @{thm exE}
  1624 val exI = @{thm exI}
  1625 val excluded_middle = @{thm excluded_middle}
  1626 val ext = @{thm ext}
  1627 val fun_cong = @{thm fun_cong}
  1628 val iffD1 = @{thm iffD1}
  1629 val iffD2 = @{thm iffD2}
  1630 val iffI = @{thm iffI}
  1631 val impE = @{thm impE}
  1632 val impI = @{thm impI}
  1633 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1634 val mp = @{thm mp}
  1635 val notE = @{thm notE}
  1636 val notI = @{thm notI}
  1637 val not_all = @{thm not_all}
  1638 val not_ex = @{thm not_ex}
  1639 val not_iff = @{thm not_iff}
  1640 val not_not = @{thm not_not}
  1641 val not_sym = @{thm not_sym}
  1642 val refl = @{thm refl}
  1643 val rev_mp = @{thm rev_mp}
  1644 val spec = @{thm spec}
  1645 val ssubst = @{thm ssubst}
  1646 val subst = @{thm subst}
  1647 val sym = @{thm sym}
  1648 val trans = @{thm trans}
  1649 \<close>
  1650 
  1651 ML_file "Tools/cnf.ML"
  1652 
  1653 
  1654 section \<open>\<open>NO_MATCH\<close> simproc\<close>
  1655 
  1656 text \<open>
  1657  The simplification procedure can be used to avoid simplification of terms of a certain form
  1658 \<close>
  1659 
  1660 definition NO_MATCH :: "'a \<Rightarrow> 'b \<Rightarrow> bool" where "NO_MATCH pat val \<equiv> True"
  1661 
  1662 lemma NO_MATCH_cong[cong]: "NO_MATCH pat val = NO_MATCH pat val" by (rule refl)
  1663 
  1664 declare [[coercion_args NO_MATCH - -]]
  1665 
  1666 simproc_setup NO_MATCH ("NO_MATCH pat val") = \<open>fn _ => fn ctxt => fn ct =>
  1667   let
  1668     val thy = Proof_Context.theory_of ctxt
  1669     val dest_binop = Term.dest_comb #> apfst (Term.dest_comb #> snd)
  1670     val m = Pattern.matches thy (dest_binop (Thm.term_of ct))
  1671   in if m then NONE else SOME @{thm NO_MATCH_def} end
  1672 \<close>
  1673 
  1674 text \<open>
  1675   This setup ensures that a rewrite rule of the form @{term "NO_MATCH pat val \<Longrightarrow> t"}
  1676   is only applied, if the pattern @{term pat} does not match the value @{term val}.
  1677 \<close>
  1678 
  1679 
  1680 text\<open>Tagging a premise of a simp rule with ASSUMPTION forces the simplifier
  1681 not to simplify the argument and to solve it by an assumption.\<close>
  1682 
  1683 definition ASSUMPTION :: "bool \<Rightarrow> bool" where
  1684 "ASSUMPTION A \<equiv> A"
  1685 
  1686 lemma ASSUMPTION_cong[cong]: "ASSUMPTION A = ASSUMPTION A"
  1687 by (rule refl)
  1688 
  1689 lemma ASSUMPTION_I: "A \<Longrightarrow> ASSUMPTION A"
  1690 by(simp add: ASSUMPTION_def)
  1691 
  1692 lemma ASSUMPTION_D: "ASSUMPTION A \<Longrightarrow> A"
  1693 by(simp add: ASSUMPTION_def)
  1694 
  1695 setup \<open>
  1696 let
  1697   val asm_sol = mk_solver "ASSUMPTION" (fn ctxt =>
  1698     resolve_tac ctxt [@{thm ASSUMPTION_I}] THEN'
  1699     resolve_tac ctxt (Simplifier.prems_of ctxt))
  1700 in
  1701   map_theory_simpset (fn ctxt => Simplifier.addSolver (ctxt,asm_sol))
  1702 end
  1703 \<close>
  1704 
  1705 
  1706 subsection \<open>Code generator setup\<close>
  1707 
  1708 subsubsection \<open>Generic code generator preprocessor setup\<close>
  1709 
  1710 lemma conj_left_cong:
  1711   "P \<longleftrightarrow> Q \<Longrightarrow> P \<and> R \<longleftrightarrow> Q \<and> R"
  1712   by (fact arg_cong)
  1713 
  1714 lemma disj_left_cong:
  1715   "P \<longleftrightarrow> Q \<Longrightarrow> P \<or> R \<longleftrightarrow> Q \<or> R"
  1716   by (fact arg_cong)
  1717 
  1718 setup \<open>
  1719   Code_Preproc.map_pre (put_simpset HOL_basic_ss) #>
  1720   Code_Preproc.map_post (put_simpset HOL_basic_ss) #>
  1721   Code_Simp.map_ss (put_simpset HOL_basic_ss #>
  1722   Simplifier.add_cong @{thm conj_left_cong} #>
  1723   Simplifier.add_cong @{thm disj_left_cong})
  1724 \<close>
  1725 
  1726 
  1727 subsubsection \<open>Equality\<close>
  1728 
  1729 class equal =
  1730   fixes equal :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1731   assumes equal_eq: "equal x y \<longleftrightarrow> x = y"
  1732 begin
  1733 
  1734 lemma equal: "equal = (op =)"
  1735   by (rule ext equal_eq)+
  1736 
  1737 lemma equal_refl: "equal x x \<longleftrightarrow> True"
  1738   unfolding equal by rule+
  1739 
  1740 lemma eq_equal: "(op =) \<equiv> equal"
  1741   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule equal_eq)
  1742 
  1743 end
  1744 
  1745 declare eq_equal [symmetric, code_post]
  1746 declare eq_equal [code]
  1747 
  1748 setup \<open>
  1749   Code_Preproc.map_pre (fn ctxt =>
  1750     ctxt addsimprocs
  1751       [Simplifier.make_simproc @{context} "equal"
  1752         {lhss = [@{term HOL.eq}],
  1753          proc = fn _ => fn _ => fn ct =>
  1754           (case Thm.term_of ct of
  1755             Const (_, Type (@{type_name fun}, [Type _, _])) => SOME @{thm eq_equal}
  1756           | _ => NONE),
  1757          identifier = []}])
  1758 \<close>
  1759 
  1760 
  1761 subsubsection \<open>Generic code generator foundation\<close>
  1762 
  1763 text \<open>Datatype @{typ bool}\<close>
  1764 
  1765 code_datatype True False
  1766 
  1767 lemma [code]:
  1768   shows "False \<and> P \<longleftrightarrow> False"
  1769     and "True \<and> P \<longleftrightarrow> P"
  1770     and "P \<and> False \<longleftrightarrow> False"
  1771     and "P \<and> True \<longleftrightarrow> P" by simp_all
  1772 
  1773 lemma [code]:
  1774   shows "False \<or> P \<longleftrightarrow> P"
  1775     and "True \<or> P \<longleftrightarrow> True"
  1776     and "P \<or> False \<longleftrightarrow> P"
  1777     and "P \<or> True \<longleftrightarrow> True" by simp_all
  1778 
  1779 lemma [code]:
  1780   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1781     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1782     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1783     and "(P \<longrightarrow> True) \<longleftrightarrow> True" by simp_all
  1784 
  1785 text \<open>More about @{typ prop}\<close>
  1786 
  1787 lemma [code nbe]:
  1788   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q"
  1789     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
  1790     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)" by (auto intro!: equal_intr_rule)
  1791 
  1792 lemma Trueprop_code [code]:
  1793   "Trueprop True \<equiv> Code_Generator.holds"
  1794   by (auto intro!: equal_intr_rule holds)
  1795 
  1796 declare Trueprop_code [symmetric, code_post]
  1797 
  1798 text \<open>Equality\<close>
  1799 
  1800 declare simp_thms(6) [code nbe]
  1801 
  1802 instantiation itself :: (type) equal
  1803 begin
  1804 
  1805 definition equal_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1806   "equal_itself x y \<longleftrightarrow> x = y"
  1807 
  1808 instance proof
  1809 qed (fact equal_itself_def)
  1810 
  1811 end
  1812 
  1813 lemma equal_itself_code [code]:
  1814   "equal TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1815   by (simp add: equal)
  1816 
  1817 setup \<open>Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a::type \<Rightarrow> 'a \<Rightarrow> bool"})\<close>
  1818 
  1819 lemma equal_alias_cert: "OFCLASS('a, equal_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> equal)" (is "?ofclass \<equiv> ?equal")
  1820 proof
  1821   assume "PROP ?ofclass"
  1822   show "PROP ?equal"
  1823     by (tactic \<open>ALLGOALS (resolve_tac @{context} [Thm.unconstrainT @{thm eq_equal}])\<close>)
  1824       (fact \<open>PROP ?ofclass\<close>)
  1825 next
  1826   assume "PROP ?equal"
  1827   show "PROP ?ofclass" proof
  1828   qed (simp add: \<open>PROP ?equal\<close>)
  1829 qed
  1830 
  1831 setup \<open>Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a::equal \<Rightarrow> 'a \<Rightarrow> bool"})\<close>
  1832 
  1833 setup \<open>Nbe.add_const_alias @{thm equal_alias_cert}\<close>
  1834 
  1835 text \<open>Cases\<close>
  1836 
  1837 lemma Let_case_cert:
  1838   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1839   shows "CASE x \<equiv> f x"
  1840   using assms by simp_all
  1841 
  1842 setup \<open>
  1843   Code.add_case @{thm Let_case_cert} #>
  1844   Code.add_undefined @{const_name undefined}
  1845 \<close>
  1846 
  1847 declare [[code abort: undefined]]
  1848 
  1849 
  1850 subsubsection \<open>Generic code generator target languages\<close>
  1851 
  1852 text \<open>type @{typ bool}\<close>
  1853 
  1854 code_printing
  1855   type_constructor bool \<rightharpoonup>
  1856     (SML) "bool" and (OCaml) "bool" and (Haskell) "Bool" and (Scala) "Boolean"
  1857 | constant True \<rightharpoonup>
  1858     (SML) "true" and (OCaml) "true" and (Haskell) "True" and (Scala) "true"
  1859 | constant False \<rightharpoonup>
  1860     (SML) "false" and (OCaml) "false" and (Haskell) "False" and (Scala) "false"
  1861 
  1862 code_reserved SML
  1863   bool true false
  1864 
  1865 code_reserved OCaml
  1866   bool
  1867 
  1868 code_reserved Scala
  1869   Boolean
  1870 
  1871 code_printing
  1872   constant Not \<rightharpoonup>
  1873     (SML) "not" and (OCaml) "not" and (Haskell) "not" and (Scala) "'! _"
  1874 | constant HOL.conj \<rightharpoonup>
  1875     (SML) infixl 1 "andalso" and (OCaml) infixl 3 "&&" and (Haskell) infixr 3 "&&" and (Scala) infixl 3 "&&"
  1876 | constant HOL.disj \<rightharpoonup>
  1877     (SML) infixl 0 "orelse" and (OCaml) infixl 2 "||" and (Haskell) infixl 2 "||" and (Scala) infixl 1 "||"
  1878 | constant HOL.implies \<rightharpoonup>
  1879     (SML) "!(if (_)/ then (_)/ else true)"
  1880     and (OCaml) "!(if (_)/ then (_)/ else true)"
  1881     and (Haskell) "!(if (_)/ then (_)/ else True)"
  1882     and (Scala) "!(if ((_))/ (_)/ else true)"
  1883 | constant If \<rightharpoonup>
  1884     (SML) "!(if (_)/ then (_)/ else (_))"
  1885     and (OCaml) "!(if (_)/ then (_)/ else (_))"
  1886     and (Haskell) "!(if (_)/ then (_)/ else (_))"
  1887     and (Scala) "!(if ((_))/ (_)/ else (_))"
  1888 
  1889 code_reserved SML
  1890   not
  1891 
  1892 code_reserved OCaml
  1893   not
  1894 
  1895 code_identifier
  1896   code_module Pure \<rightharpoonup>
  1897     (SML) HOL and (OCaml) HOL and (Haskell) HOL and (Scala) HOL
  1898 
  1899 text \<open>using built-in Haskell equality\<close>
  1900 
  1901 code_printing
  1902   type_class equal \<rightharpoonup> (Haskell) "Eq"
  1903 | constant HOL.equal \<rightharpoonup> (Haskell) infix 4 "=="
  1904 | constant HOL.eq \<rightharpoonup> (Haskell) infix 4 "=="
  1905 
  1906 text \<open>undefined\<close>
  1907 
  1908 code_printing
  1909   constant undefined \<rightharpoonup>
  1910     (SML) "!(raise/ Fail/ \"undefined\")"
  1911     and (OCaml) "failwith/ \"undefined\""
  1912     and (Haskell) "error/ \"undefined\""
  1913     and (Scala) "!sys.error(\"undefined\")"
  1914 
  1915 
  1916 subsubsection \<open>Evaluation and normalization by evaluation\<close>
  1917 
  1918 method_setup eval = \<open>
  1919   let
  1920     fun eval_tac ctxt =
  1921       let val conv = Code_Runtime.dynamic_holds_conv ctxt
  1922       in
  1923         CONVERSION (Conv.params_conv ~1 (K (Conv.concl_conv ~1 conv)) ctxt) THEN'
  1924         resolve_tac ctxt [TrueI]
  1925       end
  1926   in
  1927     Scan.succeed (SIMPLE_METHOD' o eval_tac)
  1928   end
  1929 \<close> "solve goal by evaluation"
  1930 
  1931 method_setup normalization = \<open>
  1932   Scan.succeed (fn ctxt =>
  1933     SIMPLE_METHOD'
  1934       (CHANGED_PROP o
  1935         (CONVERSION (Nbe.dynamic_conv ctxt)
  1936           THEN_ALL_NEW (TRY o resolve_tac ctxt [TrueI]))))
  1937 \<close> "solve goal by normalization"
  1938 
  1939 
  1940 subsection \<open>Counterexample Search Units\<close>
  1941 
  1942 subsubsection \<open>Quickcheck\<close>
  1943 
  1944 quickcheck_params [size = 5, iterations = 50]
  1945 
  1946 
  1947 subsubsection \<open>Nitpick setup\<close>
  1948 
  1949 named_theorems nitpick_unfold "alternative definitions of constants as needed by Nitpick"
  1950   and nitpick_simp "equational specification of constants as needed by Nitpick"
  1951   and nitpick_psimp "partial equational specification of constants as needed by Nitpick"
  1952   and nitpick_choice_spec "choice specification of constants as needed by Nitpick"
  1953 
  1954 declare if_bool_eq_conj [nitpick_unfold, no_atp]
  1955         if_bool_eq_disj [no_atp]
  1956 
  1957 
  1958 subsection \<open>Preprocessing for the predicate compiler\<close>
  1959 
  1960 named_theorems code_pred_def "alternative definitions of constants for the Predicate Compiler"
  1961   and code_pred_inline "inlining definitions for the Predicate Compiler"
  1962   and code_pred_simp "simplification rules for the optimisations in the Predicate Compiler"
  1963 
  1964 
  1965 subsection \<open>Legacy tactics and ML bindings\<close>
  1966 
  1967 ML \<open>
  1968   (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1969   local
  1970     fun wrong_prem (Const (@{const_name All}, _) $ Abs (_, _, t)) = wrong_prem t
  1971       | wrong_prem (Bound _) = true
  1972       | wrong_prem _ = false;
  1973     val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  1974     fun smp i = funpow i (fn m => filter_right ([spec] RL m)) [mp];
  1975   in
  1976     fun smp_tac ctxt j = EVERY' [dresolve_tac ctxt (smp j), assume_tac ctxt];
  1977   end;
  1978 
  1979   local
  1980     val nnf_ss =
  1981       simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms simp_thms nnf_simps});
  1982   in
  1983     fun nnf_conv ctxt = Simplifier.rewrite (put_simpset nnf_ss ctxt);
  1984   end
  1985 \<close>
  1986 
  1987 hide_const (open) eq equal
  1988 
  1989 end