src/HOL/Algebra/UnivPoly.thy
 author haftmann Mon Nov 17 17:00:55 2008 +0100 (2008-11-17) changeset 28823 dcbef866c9e2 parent 27933 4b867f6a65d3 child 29237 e90d9d51106b permissions -rw-r--r--
tuned unfold_locales invocation
     1 (*

     2   Title:     HOL/Algebra/UnivPoly.thy

     3   Id:        $Id$

     4   Author:    Clemens Ballarin, started 9 December 1996

     5   Copyright: Clemens Ballarin

     6

     7 Contributions, in particular on long division, by Jesus Aransay.

     8 *)

     9

    10 theory UnivPoly

    11 imports Module RingHom

    12 begin

    13

    14

    15 section {* Univariate Polynomials *}

    16

    17 text {*

    18   Polynomials are formalised as modules with additional operations for

    19   extracting coefficients from polynomials and for obtaining monomials

    20   from coefficients and exponents (record @{text "up_ring"}).  The

    21   carrier set is a set of bounded functions from Nat to the

    22   coefficient domain.  Bounded means that these functions return zero

    23   above a certain bound (the degree).  There is a chapter on the

    24   formalisation of polynomials in the PhD thesis \cite{Ballarin:1999},

    25   which was implemented with axiomatic type classes.  This was later

    26   ported to Locales.

    27 *}

    28

    29

    30 subsection {* The Constructor for Univariate Polynomials *}

    31

    32 text {*

    33   Functions with finite support.

    34 *}

    35

    36 locale bound =

    37   fixes z :: 'a

    38     and n :: nat

    39     and f :: "nat => 'a"

    40   assumes bound: "!!m. n < m \<Longrightarrow> f m = z"

    41

    42 declare bound.intro [intro!]

    43   and bound.bound [dest]

    44

    45 lemma bound_below:

    46   assumes bound: "bound z m f" and nonzero: "f n \<noteq> z" shows "n \<le> m"

    47 proof (rule classical)

    48   assume "~ ?thesis"

    49   then have "m < n" by arith

    50   with bound have "f n = z" ..

    51   with nonzero show ?thesis by contradiction

    52 qed

    53

    54 record ('a, 'p) up_ring = "('a, 'p) module" +

    55   monom :: "['a, nat] => 'p"

    56   coeff :: "['p, nat] => 'a"

    57

    58 definition up :: "('a, 'm) ring_scheme => (nat => 'a) set"

    59   where up_def: "up R == {f. f \<in> UNIV -> carrier R & (EX n. bound \<zero>\<^bsub>R\<^esub> n f)}"

    60

    61 definition UP :: "('a, 'm) ring_scheme => ('a, nat => 'a) up_ring"

    62   where UP_def: "UP R == (|

    63    carrier = up R,

    64    mult = (%p:up R. %q:up R. %n. \<Oplus>\<^bsub>R\<^esub>i \<in> {..n}. p i \<otimes>\<^bsub>R\<^esub> q (n-i)),

    65    one = (%i. if i=0 then \<one>\<^bsub>R\<^esub> else \<zero>\<^bsub>R\<^esub>),

    66    zero = (%i. \<zero>\<^bsub>R\<^esub>),

    67    add = (%p:up R. %q:up R. %i. p i \<oplus>\<^bsub>R\<^esub> q i),

    68    smult = (%a:carrier R. %p:up R. %i. a \<otimes>\<^bsub>R\<^esub> p i),

    69    monom = (%a:carrier R. %n i. if i=n then a else \<zero>\<^bsub>R\<^esub>),

    70    coeff = (%p:up R. %n. p n) |)"

    71

    72 text {*

    73   Properties of the set of polynomials @{term up}.

    74 *}

    75

    76 lemma mem_upI [intro]:

    77   "[| !!n. f n \<in> carrier R; EX n. bound (zero R) n f |] ==> f \<in> up R"

    78   by (simp add: up_def Pi_def)

    79

    80 lemma mem_upD [dest]:

    81   "f \<in> up R ==> f n \<in> carrier R"

    82   by (simp add: up_def Pi_def)

    83

    84 context ring

    85 begin

    86

    87 lemma bound_upD [dest]: "f \<in> up R ==> EX n. bound \<zero> n f" by (simp add: up_def)

    88

    89 lemma up_one_closed: "(%n. if n = 0 then \<one> else \<zero>) \<in> up R" using up_def by force

    90

    91 lemma up_smult_closed: "[| a \<in> carrier R; p \<in> up R |] ==> (%i. a \<otimes> p i) \<in> up R" by force

    92

    93 lemma up_add_closed:

    94   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<oplus> q i) \<in> up R"

    95 proof

    96   fix n

    97   assume "p \<in> up R" and "q \<in> up R"

    98   then show "p n \<oplus> q n \<in> carrier R"

    99     by auto

   100 next

   101   assume UP: "p \<in> up R" "q \<in> up R"

   102   show "EX n. bound \<zero> n (%i. p i \<oplus> q i)"

   103   proof -

   104     from UP obtain n where boundn: "bound \<zero> n p" by fast

   105     from UP obtain m where boundm: "bound \<zero> m q" by fast

   106     have "bound \<zero> (max n m) (%i. p i \<oplus> q i)"

   107     proof

   108       fix i

   109       assume "max n m < i"

   110       with boundn and boundm and UP show "p i \<oplus> q i = \<zero>" by fastsimp

   111     qed

   112     then show ?thesis ..

   113   qed

   114 qed

   115

   116 lemma up_a_inv_closed:

   117   "p \<in> up R ==> (%i. \<ominus> (p i)) \<in> up R"

   118 proof

   119   assume R: "p \<in> up R"

   120   then obtain n where "bound \<zero> n p" by auto

   121   then have "bound \<zero> n (%i. \<ominus> p i)" by auto

   122   then show "EX n. bound \<zero> n (%i. \<ominus> p i)" by auto

   123 qed auto

   124

   125 lemma up_minus_closed:

   126   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<ominus> q i) \<in> up R"

   127   using mem_upD [of p R] mem_upD [of q R] up_add_closed up_a_inv_closed a_minus_def [of _ R]

   128   by auto

   129

   130 lemma up_mult_closed:

   131   "[| p \<in> up R; q \<in> up R |] ==>

   132   (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> up R"

   133 proof

   134   fix n

   135   assume "p \<in> up R" "q \<in> up R"

   136   then show "(\<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> carrier R"

   137     by (simp add: mem_upD  funcsetI)

   138 next

   139   assume UP: "p \<in> up R" "q \<in> up R"

   140   show "EX n. bound \<zero> n (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i))"

   141   proof -

   142     from UP obtain n where boundn: "bound \<zero> n p" by fast

   143     from UP obtain m where boundm: "bound \<zero> m q" by fast

   144     have "bound \<zero> (n + m) (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n - i))"

   145     proof

   146       fix k assume bound: "n + m < k"

   147       {

   148         fix i

   149         have "p i \<otimes> q (k-i) = \<zero>"

   150         proof (cases "n < i")

   151           case True

   152           with boundn have "p i = \<zero>" by auto

   153           moreover from UP have "q (k-i) \<in> carrier R" by auto

   154           ultimately show ?thesis by simp

   155         next

   156           case False

   157           with bound have "m < k-i" by arith

   158           with boundm have "q (k-i) = \<zero>" by auto

   159           moreover from UP have "p i \<in> carrier R" by auto

   160           ultimately show ?thesis by simp

   161         qed

   162       }

   163       then show "(\<Oplus>i \<in> {..k}. p i \<otimes> q (k-i)) = \<zero>"

   164         by (simp add: Pi_def)

   165     qed

   166     then show ?thesis by fast

   167   qed

   168 qed

   169

   170 end

   171

   172

   173 subsection {* Effect of Operations on Coefficients *}

   174

   175 locale UP =

   176   fixes R (structure) and P (structure)

   177   defines P_def: "P == UP R"

   178

   179 locale UP_ring = UP + ring R

   180

   181 locale UP_cring = UP + cring R

   182

   183 interpretation UP_cring < UP_ring

   184   by (rule P_def) intro_locales

   185

   186 locale UP_domain = UP + "domain" R

   187

   188 interpretation UP_domain < UP_cring

   189   by (rule P_def) intro_locales

   190

   191 context UP

   192 begin

   193

   194 text {*Temporarily declare @{thm [locale=UP] P_def} as simp rule.*}

   195

   196 declare P_def [simp]

   197

   198 lemma up_eqI:

   199   assumes prem: "!!n. coeff P p n = coeff P q n" and R: "p \<in> carrier P" "q \<in> carrier P"

   200   shows "p = q"

   201 proof

   202   fix x

   203   from prem and R show "p x = q x" by (simp add: UP_def)

   204 qed

   205

   206 lemma coeff_closed [simp]:

   207   "p \<in> carrier P ==> coeff P p n \<in> carrier R" by (auto simp add: UP_def)

   208

   209 end

   210

   211 context UP_ring

   212 begin

   213

   214 (* Theorems generalised from commutative rings to rings by Jesus Aransay. *)

   215

   216 lemma coeff_monom [simp]:

   217   "a \<in> carrier R ==> coeff P (monom P a m) n = (if m=n then a else \<zero>)"

   218 proof -

   219   assume R: "a \<in> carrier R"

   220   then have "(%n. if n = m then a else \<zero>) \<in> up R"

   221     using up_def by force

   222   with R show ?thesis by (simp add: UP_def)

   223 qed

   224

   225 lemma coeff_zero [simp]: "coeff P \<zero>\<^bsub>P\<^esub> n = \<zero>" by (auto simp add: UP_def)

   226

   227 lemma coeff_one [simp]: "coeff P \<one>\<^bsub>P\<^esub> n = (if n=0 then \<one> else \<zero>)"

   228   using up_one_closed by (simp add: UP_def)

   229

   230 lemma coeff_smult [simp]:

   231   "[| a \<in> carrier R; p \<in> carrier P |] ==> coeff P (a \<odot>\<^bsub>P\<^esub> p) n = a \<otimes> coeff P p n"

   232   by (simp add: UP_def up_smult_closed)

   233

   234 lemma coeff_add [simp]:

   235   "[| p \<in> carrier P; q \<in> carrier P |] ==> coeff P (p \<oplus>\<^bsub>P\<^esub> q) n = coeff P p n \<oplus> coeff P q n"

   236   by (simp add: UP_def up_add_closed)

   237

   238 lemma coeff_mult [simp]:

   239   "[| p \<in> carrier P; q \<in> carrier P |] ==> coeff P (p \<otimes>\<^bsub>P\<^esub> q) n = (\<Oplus>i \<in> {..n}. coeff P p i \<otimes> coeff P q (n-i))"

   240   by (simp add: UP_def up_mult_closed)

   241

   242 end

   243

   244

   245 subsection {* Polynomials Form a Ring. *}

   246

   247 context UP_ring

   248 begin

   249

   250 text {* Operations are closed over @{term P}. *}

   251

   252 lemma UP_mult_closed [simp]:

   253   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<otimes>\<^bsub>P\<^esub> q \<in> carrier P" by (simp add: UP_def up_mult_closed)

   254

   255 lemma UP_one_closed [simp]:

   256   "\<one>\<^bsub>P\<^esub> \<in> carrier P" by (simp add: UP_def up_one_closed)

   257

   258 lemma UP_zero_closed [intro, simp]:

   259   "\<zero>\<^bsub>P\<^esub> \<in> carrier P" by (auto simp add: UP_def)

   260

   261 lemma UP_a_closed [intro, simp]:

   262   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<oplus>\<^bsub>P\<^esub> q \<in> carrier P" by (simp add: UP_def up_add_closed)

   263

   264 lemma monom_closed [simp]:

   265   "a \<in> carrier R ==> monom P a n \<in> carrier P" by (auto simp add: UP_def up_def Pi_def)

   266

   267 lemma UP_smult_closed [simp]:

   268   "[| a \<in> carrier R; p \<in> carrier P |] ==> a \<odot>\<^bsub>P\<^esub> p \<in> carrier P" by (simp add: UP_def up_smult_closed)

   269

   270 end

   271

   272 declare (in UP) P_def [simp del]

   273

   274 text {* Algebraic ring properties *}

   275

   276 context UP_ring

   277 begin

   278

   279 lemma UP_a_assoc:

   280   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"

   281   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<oplus>\<^bsub>P\<^esub> r = p \<oplus>\<^bsub>P\<^esub> (q \<oplus>\<^bsub>P\<^esub> r)" by (rule up_eqI, simp add: a_assoc R, simp_all add: R)

   282

   283 lemma UP_l_zero [simp]:

   284   assumes R: "p \<in> carrier P"

   285   shows "\<zero>\<^bsub>P\<^esub> \<oplus>\<^bsub>P\<^esub> p = p" by (rule up_eqI, simp_all add: R)

   286

   287 lemma UP_l_neg_ex:

   288   assumes R: "p \<in> carrier P"

   289   shows "EX q : carrier P. q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"

   290 proof -

   291   let ?q = "%i. \<ominus> (p i)"

   292   from R have closed: "?q \<in> carrier P"

   293     by (simp add: UP_def P_def up_a_inv_closed)

   294   from R have coeff: "!!n. coeff P ?q n = \<ominus> (coeff P p n)"

   295     by (simp add: UP_def P_def up_a_inv_closed)

   296   show ?thesis

   297   proof

   298     show "?q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"

   299       by (auto intro!: up_eqI simp add: R closed coeff R.l_neg)

   300   qed (rule closed)

   301 qed

   302

   303 lemma UP_a_comm:

   304   assumes R: "p \<in> carrier P" "q \<in> carrier P"

   305   shows "p \<oplus>\<^bsub>P\<^esub> q = q \<oplus>\<^bsub>P\<^esub> p" by (rule up_eqI, simp add: a_comm R, simp_all add: R)

   306

   307 lemma UP_m_assoc:

   308   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"

   309   shows "(p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"

   310 proof (rule up_eqI)

   311   fix n

   312   {

   313     fix k and a b c :: "nat=>'a"

   314     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"

   315       "c \<in> UNIV -> carrier R"

   316     then have "k <= n ==>

   317       (\<Oplus>j \<in> {..k}. (\<Oplus>i \<in> {..j}. a i \<otimes> b (j-i)) \<otimes> c (n-j)) =

   318       (\<Oplus>j \<in> {..k}. a j \<otimes> (\<Oplus>i \<in> {..k-j}. b i \<otimes> c (n-j-i)))"

   319       (is "_ \<Longrightarrow> ?eq k")

   320     proof (induct k)

   321       case 0 then show ?case by (simp add: Pi_def m_assoc)

   322     next

   323       case (Suc k)

   324       then have "k <= n" by arith

   325       from this R have "?eq k" by (rule Suc)

   326       with R show ?case

   327         by (simp cong: finsum_cong

   328              add: Suc_diff_le Pi_def l_distr r_distr m_assoc)

   329            (simp cong: finsum_cong add: Pi_def a_ac finsum_ldistr m_assoc)

   330     qed

   331   }

   332   with R show "coeff P ((p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r) n = coeff P (p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)) n"

   333     by (simp add: Pi_def)

   334 qed (simp_all add: R)

   335

   336 lemma UP_r_one [simp]:

   337   assumes R: "p \<in> carrier P" shows "p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub> = p"

   338 proof (rule up_eqI)

   339   fix n

   340   show "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) n = coeff P p n"

   341   proof (cases n)

   342     case 0

   343     {

   344       with R show ?thesis by simp

   345     }

   346   next

   347     case Suc

   348     {

   349       (*JE: in the locale UP_cring the proof was solved only with "by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)", but I did not get it to work here*)

   350       fix nn assume Succ: "n = Suc nn"

   351       have "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) (Suc nn) = coeff P p (Suc nn)"

   352       proof -

   353 	have "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) (Suc nn) = (\<Oplus>i\<in>{..Suc nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" using R by simp

   354 	also have "\<dots> = coeff P p (Suc nn) \<otimes> (if Suc nn \<le> Suc nn then \<one> else \<zero>) \<oplus> (\<Oplus>i\<in>{..nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))"

   355 	  using finsum_Suc [of "(\<lambda>i::nat. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" "nn"] unfolding Pi_def using R by simp

   356 	also have "\<dots> = coeff P p (Suc nn) \<otimes> (if Suc nn \<le> Suc nn then \<one> else \<zero>)"

   357 	proof -

   358 	  have "(\<Oplus>i\<in>{..nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>)) = (\<Oplus>i\<in>{..nn}. \<zero>)"

   359 	    using finsum_cong [of "{..nn}" "{..nn}" "(\<lambda>i::nat. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" "(\<lambda>i::nat. \<zero>)"] using R

   360 	    unfolding Pi_def by simp

   361 	  also have "\<dots> = \<zero>" by simp

   362 	  finally show ?thesis using r_zero R by simp

   363 	qed

   364 	also have "\<dots> = coeff P p (Suc nn)" using R by simp

   365 	finally show ?thesis by simp

   366       qed

   367       then show ?thesis using Succ by simp

   368     }

   369   qed

   370 qed (simp_all add: R)

   371

   372 lemma UP_l_one [simp]:

   373   assumes R: "p \<in> carrier P"

   374   shows "\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p = p"

   375 proof (rule up_eqI)

   376   fix n

   377   show "coeff P (\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p) n = coeff P p n"

   378   proof (cases n)

   379     case 0 with R show ?thesis by simp

   380   next

   381     case Suc with R show ?thesis

   382       by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)

   383   qed

   384 qed (simp_all add: R)

   385

   386 lemma UP_l_distr:

   387   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"

   388   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = (p \<otimes>\<^bsub>P\<^esub> r) \<oplus>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"

   389   by (rule up_eqI) (simp add: l_distr R Pi_def, simp_all add: R)

   390

   391 lemma UP_r_distr:

   392   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"

   393   shows "r \<otimes>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = (r \<otimes>\<^bsub>P\<^esub> p) \<oplus>\<^bsub>P\<^esub> (r \<otimes>\<^bsub>P\<^esub> q)"

   394   by (rule up_eqI) (simp add: r_distr R Pi_def, simp_all add: R)

   395

   396 theorem UP_ring: "ring P"

   397   by (auto intro!: ringI abelian_groupI monoidI UP_a_assoc)

   398     (auto intro: UP_a_comm UP_l_neg_ex UP_m_assoc UP_l_distr UP_r_distr)

   399

   400 end

   401

   402

   403 subsection {* Polynomials Form a Commutative Ring. *}

   404

   405 context UP_cring

   406 begin

   407

   408 lemma UP_m_comm:

   409   assumes R1: "p \<in> carrier P" and R2: "q \<in> carrier P" shows "p \<otimes>\<^bsub>P\<^esub> q = q \<otimes>\<^bsub>P\<^esub> p"

   410 proof (rule up_eqI)

   411   fix n

   412   {

   413     fix k and a b :: "nat=>'a"

   414     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"

   415     then have "k <= n ==>

   416       (\<Oplus>i \<in> {..k}. a i \<otimes> b (n-i)) = (\<Oplus>i \<in> {..k}. a (k-i) \<otimes> b (i+n-k))"

   417       (is "_ \<Longrightarrow> ?eq k")

   418     proof (induct k)

   419       case 0 then show ?case by (simp add: Pi_def)

   420     next

   421       case (Suc k) then show ?case

   422         by (subst (2) finsum_Suc2) (simp add: Pi_def a_comm)+

   423     qed

   424   }

   425   note l = this

   426   from R1 R2 show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) n =  coeff P (q \<otimes>\<^bsub>P\<^esub> p) n"

   427     unfolding coeff_mult [OF R1 R2, of n]

   428     unfolding coeff_mult [OF R2 R1, of n]

   429     using l [of "(\<lambda>i. coeff P p i)" "(\<lambda>i. coeff P q i)" "n"] by (simp add: Pi_def m_comm)

   430 qed (simp_all add: R1 R2)

   431

   432 subsection{*Polynomials over a commutative ring for a commutative ring*}

   433

   434 theorem UP_cring:

   435   "cring P" using UP_ring unfolding cring_def by (auto intro!: comm_monoidI UP_m_assoc UP_m_comm)

   436

   437 end

   438

   439 context UP_ring

   440 begin

   441

   442 lemma UP_a_inv_closed [intro, simp]:

   443   "p \<in> carrier P ==> \<ominus>\<^bsub>P\<^esub> p \<in> carrier P"

   444   by (rule abelian_group.a_inv_closed [OF ring.is_abelian_group [OF UP_ring]])

   445

   446 lemma coeff_a_inv [simp]:

   447   assumes R: "p \<in> carrier P"

   448   shows "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> (coeff P p n)"

   449 proof -

   450   from R coeff_closed UP_a_inv_closed have

   451     "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> coeff P p n \<oplus> (coeff P p n \<oplus> coeff P (\<ominus>\<^bsub>P\<^esub> p) n)"

   452     by algebra

   453   also from R have "... =  \<ominus> (coeff P p n)"

   454     by (simp del: coeff_add add: coeff_add [THEN sym]

   455       abelian_group.r_neg [OF ring.is_abelian_group [OF UP_ring]])

   456   finally show ?thesis .

   457 qed

   458

   459 end

   460

   461 interpretation UP_ring < ring P using UP_ring .

   462 interpretation UP_cring < cring P using UP_cring .

   463

   464

   465 subsection {* Polynomials Form an Algebra *}

   466

   467 context UP_ring

   468 begin

   469

   470 lemma UP_smult_l_distr:

   471   "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>

   472   (a \<oplus> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> b \<odot>\<^bsub>P\<^esub> p"

   473   by (rule up_eqI) (simp_all add: R.l_distr)

   474

   475 lemma UP_smult_r_distr:

   476   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>

   477   a \<odot>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> a \<odot>\<^bsub>P\<^esub> q"

   478   by (rule up_eqI) (simp_all add: R.r_distr)

   479

   480 lemma UP_smult_assoc1:

   481       "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>

   482       (a \<otimes> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> p)"

   483   by (rule up_eqI) (simp_all add: R.m_assoc)

   484

   485 lemma UP_smult_zero [simp]:

   486       "p \<in> carrier P ==> \<zero> \<odot>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"

   487   by (rule up_eqI) simp_all

   488

   489 lemma UP_smult_one [simp]:

   490       "p \<in> carrier P ==> \<one> \<odot>\<^bsub>P\<^esub> p = p"

   491   by (rule up_eqI) simp_all

   492

   493 lemma UP_smult_assoc2:

   494   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>

   495   (a \<odot>\<^bsub>P\<^esub> p) \<otimes>\<^bsub>P\<^esub> q = a \<odot>\<^bsub>P\<^esub> (p \<otimes>\<^bsub>P\<^esub> q)"

   496   by (rule up_eqI) (simp_all add: R.finsum_rdistr R.m_assoc Pi_def)

   497

   498 end

   499

   500 text {*

   501   Interpretation of lemmas from @{term algebra}.

   502 *}

   503

   504 lemma (in cring) cring:

   505   "cring R" ..

   506

   507 lemma (in UP_cring) UP_algebra:

   508   "algebra R P" by (auto intro!: algebraI R.cring UP_cring UP_smult_l_distr UP_smult_r_distr

   509     UP_smult_assoc1 UP_smult_assoc2)

   510

   511 interpretation UP_cring < algebra R P using UP_algebra .

   512

   513

   514 subsection {* Further Lemmas Involving Monomials *}

   515

   516 context UP_ring

   517 begin

   518

   519 lemma monom_zero [simp]:

   520   "monom P \<zero> n = \<zero>\<^bsub>P\<^esub>" by (simp add: UP_def P_def)

   521

   522 lemma monom_mult_is_smult:

   523   assumes R: "a \<in> carrier R" "p \<in> carrier P"

   524   shows "monom P a 0 \<otimes>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p"

   525 proof (rule up_eqI)

   526   fix n

   527   show "coeff P (monom P a 0 \<otimes>\<^bsub>P\<^esub> p) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"

   528   proof (cases n)

   529     case 0 with R show ?thesis by simp

   530   next

   531     case Suc with R show ?thesis

   532       using R.finsum_Suc2 by (simp del: R.finsum_Suc add: R.r_null Pi_def)

   533   qed

   534 qed (simp_all add: R)

   535

   536 lemma monom_one [simp]:

   537   "monom P \<one> 0 = \<one>\<^bsub>P\<^esub>"

   538   by (rule up_eqI) simp_all

   539

   540 lemma monom_add [simp]:

   541   "[| a \<in> carrier R; b \<in> carrier R |] ==>

   542   monom P (a \<oplus> b) n = monom P a n \<oplus>\<^bsub>P\<^esub> monom P b n"

   543   by (rule up_eqI) simp_all

   544

   545 lemma monom_one_Suc:

   546   "monom P \<one> (Suc n) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"

   547 proof (rule up_eqI)

   548   fix k

   549   show "coeff P (monom P \<one> (Suc n)) k = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"

   550   proof (cases "k = Suc n")

   551     case True show ?thesis

   552     proof -

   553       fix m

   554       from True have less_add_diff:

   555         "!!i. [| n < i; i <= n + m |] ==> n + m - i < m" by arith

   556       from True have "coeff P (monom P \<one> (Suc n)) k = \<one>" by simp

   557       also from True

   558       have "... = (\<Oplus>i \<in> {..<n} \<union> {n}. coeff P (monom P \<one> n) i \<otimes>

   559         coeff P (monom P \<one> 1) (k - i))"

   560         by (simp cong: R.finsum_cong add: Pi_def)

   561       also have "... = (\<Oplus>i \<in>  {..n}. coeff P (monom P \<one> n) i \<otimes>

   562         coeff P (monom P \<one> 1) (k - i))"

   563         by (simp only: ivl_disj_un_singleton)

   564       also from True

   565       have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. coeff P (monom P \<one> n) i \<otimes>

   566         coeff P (monom P \<one> 1) (k - i))"

   567         by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one

   568           order_less_imp_not_eq Pi_def)

   569       also from True have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"

   570         by (simp add: ivl_disj_un_one)

   571       finally show ?thesis .

   572     qed

   573   next

   574     case False

   575     note neq = False

   576     let ?s =

   577       "\<lambda>i. (if n = i then \<one> else \<zero>) \<otimes> (if Suc 0 = k - i then \<one> else \<zero>)"

   578     from neq have "coeff P (monom P \<one> (Suc n)) k = \<zero>" by simp

   579     also have "... = (\<Oplus>i \<in> {..k}. ?s i)"

   580     proof -

   581       have f1: "(\<Oplus>i \<in> {..<n}. ?s i) = \<zero>"

   582         by (simp cong: R.finsum_cong add: Pi_def)

   583       from neq have f2: "(\<Oplus>i \<in> {n}. ?s i) = \<zero>"

   584         by (simp cong: R.finsum_cong add: Pi_def) arith

   585       have f3: "n < k ==> (\<Oplus>i \<in> {n<..k}. ?s i) = \<zero>"

   586         by (simp cong: R.finsum_cong add: order_less_imp_not_eq Pi_def)

   587       show ?thesis

   588       proof (cases "k < n")

   589         case True then show ?thesis by (simp cong: R.finsum_cong add: Pi_def)

   590       next

   591         case False then have n_le_k: "n <= k" by arith

   592         show ?thesis

   593         proof (cases "n = k")

   594           case True

   595           then have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"

   596             by (simp cong: R.finsum_cong add: ivl_disj_int_singleton Pi_def)

   597           also from True have "... = (\<Oplus>i \<in> {..k}. ?s i)"

   598             by (simp only: ivl_disj_un_singleton)

   599           finally show ?thesis .

   600         next

   601           case False with n_le_k have n_less_k: "n < k" by arith

   602           with neq have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"

   603             by (simp add: R.finsum_Un_disjoint f1 f2

   604               ivl_disj_int_singleton Pi_def del: Un_insert_right)

   605           also have "... = (\<Oplus>i \<in> {..n}. ?s i)"

   606             by (simp only: ivl_disj_un_singleton)

   607           also from n_less_k neq have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. ?s i)"

   608             by (simp add: R.finsum_Un_disjoint f3 ivl_disj_int_one Pi_def)

   609           also from n_less_k have "... = (\<Oplus>i \<in> {..k}. ?s i)"

   610             by (simp only: ivl_disj_un_one)

   611           finally show ?thesis .

   612         qed

   613       qed

   614     qed

   615     also have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k" by simp

   616     finally show ?thesis .

   617   qed

   618 qed (simp_all)

   619

   620 lemma monom_one_Suc2:

   621   "monom P \<one> (Suc n) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> n"

   622 proof (induct n)

   623   case 0 show ?case by simp

   624 next

   625   case Suc

   626   {

   627     fix k:: nat

   628     assume hypo: "monom P \<one> (Suc k) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k"

   629     then show "monom P \<one> (Suc (Suc k)) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> (Suc k)"

   630     proof -

   631       have lhs: "monom P \<one> (Suc (Suc k)) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"

   632 	unfolding monom_one_Suc [of "Suc k"] unfolding hypo ..

   633       note cl = monom_closed [OF R.one_closed, of 1]

   634       note clk = monom_closed [OF R.one_closed, of k]

   635       have rhs: "monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> (Suc k) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"

   636 	unfolding monom_one_Suc [of k] unfolding sym [OF m_assoc  [OF cl clk cl]] ..

   637       from lhs rhs show ?thesis by simp

   638     qed

   639   }

   640 qed

   641

   642 text{*The following corollary follows from lemmas @{thm [locale=UP_ring] "monom_one_Suc"}

   643   and @{thm [locale=UP_ring] "monom_one_Suc2"}, and is trivial in @{term UP_cring}*}

   644

   645 corollary monom_one_comm: shows "monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k"

   646   unfolding monom_one_Suc [symmetric] monom_one_Suc2 [symmetric] ..

   647

   648 lemma monom_mult_smult:

   649   "[| a \<in> carrier R; b \<in> carrier R |] ==> monom P (a \<otimes> b) n = a \<odot>\<^bsub>P\<^esub> monom P b n"

   650   by (rule up_eqI) simp_all

   651

   652 lemma monom_one_mult:

   653   "monom P \<one> (n + m) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m"

   654 proof (induct n)

   655   case 0 show ?case by simp

   656 next

   657   case Suc then show ?case

   658     unfolding add_Suc unfolding monom_one_Suc unfolding Suc.hyps

   659     using m_assoc monom_one_comm [of m] by simp

   660 qed

   661

   662 lemma monom_one_mult_comm: "monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m = monom P \<one> m \<otimes>\<^bsub>P\<^esub> monom P \<one> n"

   663   unfolding monom_one_mult [symmetric] by (rule up_eqI) simp_all

   664

   665 lemma monom_mult [simp]:

   666   assumes a_in_R: "a \<in> carrier R" and b_in_R: "b \<in> carrier R"

   667   shows "monom P (a \<otimes> b) (n + m) = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m"

   668 proof (rule up_eqI)

   669   fix k

   670   show "coeff P (monom P (a \<otimes> b) (n + m)) k = coeff P (monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m) k"

   671   proof (cases "n + m = k")

   672     case True

   673     {

   674       show ?thesis

   675 	unfolding True [symmetric]

   676 	  coeff_mult [OF monom_closed [OF a_in_R, of n] monom_closed [OF b_in_R, of m], of "n + m"]

   677 	  coeff_monom [OF a_in_R, of n] coeff_monom [OF b_in_R, of m]

   678 	using R.finsum_cong [of "{.. n + m}" "{.. n + m}" "(\<lambda>i. (if n = i then a else \<zero>) \<otimes> (if m = n + m - i then b else \<zero>))"

   679 	  "(\<lambda>i. if n = i then a \<otimes> b else \<zero>)"]

   680 	  a_in_R b_in_R

   681 	unfolding simp_implies_def

   682 	using R.finsum_singleton [of n "{.. n + m}" "(\<lambda>i. a \<otimes> b)"]

   683 	unfolding Pi_def by auto

   684     }

   685   next

   686     case False

   687     {

   688       show ?thesis

   689 	unfolding coeff_monom [OF R.m_closed [OF a_in_R b_in_R], of "n + m" k] apply (simp add: False)

   690 	unfolding coeff_mult [OF monom_closed [OF a_in_R, of n] monom_closed [OF b_in_R, of m], of k]

   691 	unfolding coeff_monom [OF a_in_R, of n] unfolding coeff_monom [OF b_in_R, of m] using False

   692 	using R.finsum_cong [of "{..k}" "{..k}" "(\<lambda>i. (if n = i then a else \<zero>) \<otimes> (if m = k - i then b else \<zero>))" "(\<lambda>i. \<zero>)"]

   693 	unfolding Pi_def simp_implies_def using a_in_R b_in_R by force

   694     }

   695   qed

   696 qed (simp_all add: a_in_R b_in_R)

   697

   698 lemma monom_a_inv [simp]:

   699   "a \<in> carrier R ==> monom P (\<ominus> a) n = \<ominus>\<^bsub>P\<^esub> monom P a n"

   700   by (rule up_eqI) simp_all

   701

   702 lemma monom_inj:

   703   "inj_on (%a. monom P a n) (carrier R)"

   704 proof (rule inj_onI)

   705   fix x y

   706   assume R: "x \<in> carrier R" "y \<in> carrier R" and eq: "monom P x n = monom P y n"

   707   then have "coeff P (monom P x n) n = coeff P (monom P y n) n" by simp

   708   with R show "x = y" by simp

   709 qed

   710

   711 end

   712

   713

   714 subsection {* The Degree Function *}

   715

   716 definition deg :: "[('a, 'm) ring_scheme, nat => 'a] => nat"

   717   where "deg R p == LEAST n. bound \<zero>\<^bsub>R\<^esub> n (coeff (UP R) p)"

   718

   719 context UP_ring

   720 begin

   721

   722 lemma deg_aboveI:

   723   "[| (!!m. n < m ==> coeff P p m = \<zero>); p \<in> carrier P |] ==> deg R p <= n"

   724   by (unfold deg_def P_def) (fast intro: Least_le)

   725

   726 (*

   727 lemma coeff_bound_ex: "EX n. bound n (coeff p)"

   728 proof -

   729   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)

   730   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast

   731   then show ?thesis ..

   732 qed

   733

   734 lemma bound_coeff_obtain:

   735   assumes prem: "(!!n. bound n (coeff p) ==> P)" shows "P"

   736 proof -

   737   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)

   738   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast

   739   with prem show P .

   740 qed

   741 *)

   742

   743 lemma deg_aboveD:

   744   assumes "deg R p < m" and "p \<in> carrier P"

   745   shows "coeff P p m = \<zero>"

   746 proof -

   747   from p \<in> carrier P obtain n where "bound \<zero> n (coeff P p)"

   748     by (auto simp add: UP_def P_def)

   749   then have "bound \<zero> (deg R p) (coeff P p)"

   750     by (auto simp: deg_def P_def dest: LeastI)

   751   from this and deg R p < m show ?thesis ..

   752 qed

   753

   754 lemma deg_belowI:

   755   assumes non_zero: "n ~= 0 ==> coeff P p n ~= \<zero>"

   756     and R: "p \<in> carrier P"

   757   shows "n <= deg R p"

   758 -- {* Logically, this is a slightly stronger version of

   759    @{thm [source] deg_aboveD} *}

   760 proof (cases "n=0")

   761   case True then show ?thesis by simp

   762 next

   763   case False then have "coeff P p n ~= \<zero>" by (rule non_zero)

   764   then have "~ deg R p < n" by (fast dest: deg_aboveD intro: R)

   765   then show ?thesis by arith

   766 qed

   767

   768 lemma lcoeff_nonzero_deg:

   769   assumes deg: "deg R p ~= 0" and R: "p \<in> carrier P"

   770   shows "coeff P p (deg R p) ~= \<zero>"

   771 proof -

   772   from R obtain m where "deg R p <= m" and m_coeff: "coeff P p m ~= \<zero>"

   773   proof -

   774     have minus: "!!(n::nat) m. n ~= 0 ==> (n - Suc 0 < m) = (n <= m)"

   775       by arith

   776     from deg have "deg R p - 1 < (LEAST n. bound \<zero> n (coeff P p))"

   777       by (unfold deg_def P_def) simp

   778     then have "~ bound \<zero> (deg R p - 1) (coeff P p)" by (rule not_less_Least)

   779     then have "EX m. deg R p - 1 < m & coeff P p m ~= \<zero>"

   780       by (unfold bound_def) fast

   781     then have "EX m. deg R p <= m & coeff P p m ~= \<zero>" by (simp add: deg minus)

   782     then show ?thesis by (auto intro: that)

   783   qed

   784   with deg_belowI R have "deg R p = m" by fastsimp

   785   with m_coeff show ?thesis by simp

   786 qed

   787

   788 lemma lcoeff_nonzero_nonzero:

   789   assumes deg: "deg R p = 0" and nonzero: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"

   790   shows "coeff P p 0 ~= \<zero>"

   791 proof -

   792   have "EX m. coeff P p m ~= \<zero>"

   793   proof (rule classical)

   794     assume "~ ?thesis"

   795     with R have "p = \<zero>\<^bsub>P\<^esub>" by (auto intro: up_eqI)

   796     with nonzero show ?thesis by contradiction

   797   qed

   798   then obtain m where coeff: "coeff P p m ~= \<zero>" ..

   799   from this and R have "m <= deg R p" by (rule deg_belowI)

   800   then have "m = 0" by (simp add: deg)

   801   with coeff show ?thesis by simp

   802 qed

   803

   804 lemma lcoeff_nonzero:

   805   assumes neq: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"

   806   shows "coeff P p (deg R p) ~= \<zero>"

   807 proof (cases "deg R p = 0")

   808   case True with neq R show ?thesis by (simp add: lcoeff_nonzero_nonzero)

   809 next

   810   case False with neq R show ?thesis by (simp add: lcoeff_nonzero_deg)

   811 qed

   812

   813 lemma deg_eqI:

   814   "[| !!m. n < m ==> coeff P p m = \<zero>;

   815       !!n. n ~= 0 ==> coeff P p n ~= \<zero>; p \<in> carrier P |] ==> deg R p = n"

   816 by (fast intro: le_anti_sym deg_aboveI deg_belowI)

   817

   818 text {* Degree and polynomial operations *}

   819

   820 lemma deg_add [simp]:

   821   assumes R: "p \<in> carrier P" "q \<in> carrier P"

   822   shows "deg R (p \<oplus>\<^bsub>P\<^esub> q) <= max (deg R p) (deg R q)"

   823 proof (cases "deg R p <= deg R q")

   824   case True show ?thesis

   825     by (rule deg_aboveI) (simp_all add: True R deg_aboveD)

   826 next

   827   case False show ?thesis

   828     by (rule deg_aboveI) (simp_all add: False R deg_aboveD)

   829 qed

   830

   831 lemma deg_monom_le:

   832   "a \<in> carrier R ==> deg R (monom P a n) <= n"

   833   by (intro deg_aboveI) simp_all

   834

   835 lemma deg_monom [simp]:

   836   "[| a ~= \<zero>; a \<in> carrier R |] ==> deg R (monom P a n) = n"

   837   by (fastsimp intro: le_anti_sym deg_aboveI deg_belowI)

   838

   839 lemma deg_const [simp]:

   840   assumes R: "a \<in> carrier R" shows "deg R (monom P a 0) = 0"

   841 proof (rule le_anti_sym)

   842   show "deg R (monom P a 0) <= 0" by (rule deg_aboveI) (simp_all add: R)

   843 next

   844   show "0 <= deg R (monom P a 0)" by (rule deg_belowI) (simp_all add: R)

   845 qed

   846

   847 lemma deg_zero [simp]:

   848   "deg R \<zero>\<^bsub>P\<^esub> = 0"

   849 proof (rule le_anti_sym)

   850   show "deg R \<zero>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all

   851 next

   852   show "0 <= deg R \<zero>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all

   853 qed

   854

   855 lemma deg_one [simp]:

   856   "deg R \<one>\<^bsub>P\<^esub> = 0"

   857 proof (rule le_anti_sym)

   858   show "deg R \<one>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all

   859 next

   860   show "0 <= deg R \<one>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all

   861 qed

   862

   863 lemma deg_uminus [simp]:

   864   assumes R: "p \<in> carrier P" shows "deg R (\<ominus>\<^bsub>P\<^esub> p) = deg R p"

   865 proof (rule le_anti_sym)

   866   show "deg R (\<ominus>\<^bsub>P\<^esub> p) <= deg R p" by (simp add: deg_aboveI deg_aboveD R)

   867 next

   868   show "deg R p <= deg R (\<ominus>\<^bsub>P\<^esub> p)"

   869     by (simp add: deg_belowI lcoeff_nonzero_deg

   870       inj_on_iff [OF R.a_inv_inj, of _ "\<zero>", simplified] R)

   871 qed

   872

   873 text{*The following lemma is later \emph{overwritten} by the most

   874   specific one for domains, @{text deg_smult}.*}

   875

   876 lemma deg_smult_ring [simp]:

   877   "[| a \<in> carrier R; p \<in> carrier P |] ==>

   878   deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"

   879   by (cases "a = \<zero>") (simp add: deg_aboveI deg_aboveD)+

   880

   881 end

   882

   883 context UP_domain

   884 begin

   885

   886 lemma deg_smult [simp]:

   887   assumes R: "a \<in> carrier R" "p \<in> carrier P"

   888   shows "deg R (a \<odot>\<^bsub>P\<^esub> p) = (if a = \<zero> then 0 else deg R p)"

   889 proof (rule le_anti_sym)

   890   show "deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"

   891     using R by (rule deg_smult_ring)

   892 next

   893   show "(if a = \<zero> then 0 else deg R p) <= deg R (a \<odot>\<^bsub>P\<^esub> p)"

   894   proof (cases "a = \<zero>")

   895   qed (simp, simp add: deg_belowI lcoeff_nonzero_deg integral_iff R)

   896 qed

   897

   898 end

   899

   900 context UP_ring

   901 begin

   902

   903 lemma deg_mult_ring:

   904   assumes R: "p \<in> carrier P" "q \<in> carrier P"

   905   shows "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q"

   906 proof (rule deg_aboveI)

   907   fix m

   908   assume boundm: "deg R p + deg R q < m"

   909   {

   910     fix k i

   911     assume boundk: "deg R p + deg R q < k"

   912     then have "coeff P p i \<otimes> coeff P q (k - i) = \<zero>"

   913     proof (cases "deg R p < i")

   914       case True then show ?thesis by (simp add: deg_aboveD R)

   915     next

   916       case False with boundk have "deg R q < k - i" by arith

   917       then show ?thesis by (simp add: deg_aboveD R)

   918     qed

   919   }

   920   with boundm R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) m = \<zero>" by simp

   921 qed (simp add: R)

   922

   923 end

   924

   925 context UP_domain

   926 begin

   927

   928 lemma deg_mult [simp]:

   929   "[| p ~= \<zero>\<^bsub>P\<^esub>; q ~= \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==>

   930   deg R (p \<otimes>\<^bsub>P\<^esub> q) = deg R p + deg R q"

   931 proof (rule le_anti_sym)

   932   assume "p \<in> carrier P" " q \<in> carrier P"

   933   then show "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q" by (rule deg_mult_ring)

   934 next

   935   let ?s = "(%i. coeff P p i \<otimes> coeff P q (deg R p + deg R q - i))"

   936   assume R: "p \<in> carrier P" "q \<in> carrier P" and nz: "p ~= \<zero>\<^bsub>P\<^esub>" "q ~= \<zero>\<^bsub>P\<^esub>"

   937   have less_add_diff: "!!(k::nat) n m. k < n ==> m < n + m - k" by arith

   938   show "deg R p + deg R q <= deg R (p \<otimes>\<^bsub>P\<^esub> q)"

   939   proof (rule deg_belowI, simp add: R)

   940     have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)

   941       = (\<Oplus>i \<in> {..< deg R p} \<union> {deg R p .. deg R p + deg R q}. ?s i)"

   942       by (simp only: ivl_disj_un_one)

   943     also have "... = (\<Oplus>i \<in> {deg R p .. deg R p + deg R q}. ?s i)"

   944       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one

   945         deg_aboveD less_add_diff R Pi_def)

   946     also have "...= (\<Oplus>i \<in> {deg R p} \<union> {deg R p <.. deg R p + deg R q}. ?s i)"

   947       by (simp only: ivl_disj_un_singleton)

   948     also have "... = coeff P p (deg R p) \<otimes> coeff P q (deg R q)"

   949       by (simp cong: R.finsum_cong

   950 	add: ivl_disj_int_singleton deg_aboveD R Pi_def)

   951     finally have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)

   952       = coeff P p (deg R p) \<otimes> coeff P q (deg R q)" .

   953     with nz show "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i) ~= \<zero>"

   954       by (simp add: integral_iff lcoeff_nonzero R)

   955   qed (simp add: R)

   956 qed

   957

   958 end

   959

   960 text{*The following lemmas also can be lifted to @{term UP_ring}.*}

   961

   962 context UP_ring

   963 begin

   964

   965 lemma coeff_finsum:

   966   assumes fin: "finite A"

   967   shows "p \<in> A -> carrier P ==>

   968     coeff P (finsum P p A) k = (\<Oplus>i \<in> A. coeff P (p i) k)"

   969   using fin by induct (auto simp: Pi_def)

   970

   971 lemma up_repr:

   972   assumes R: "p \<in> carrier P"

   973   shows "(\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. monom P (coeff P p i) i) = p"

   974 proof (rule up_eqI)

   975   let ?s = "(%i. monom P (coeff P p i) i)"

   976   fix k

   977   from R have RR: "!!i. (if i = k then coeff P p i else \<zero>) \<in> carrier R"

   978     by simp

   979   show "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k = coeff P p k"

   980   proof (cases "k <= deg R p")

   981     case True

   982     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =

   983           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k} \<union> {k<..deg R p}. ?s i) k"

   984       by (simp only: ivl_disj_un_one)

   985     also from True

   986     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k}. ?s i) k"

   987       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint

   988         ivl_disj_int_one order_less_imp_not_eq2 coeff_finsum R RR Pi_def)

   989     also

   990     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<k} \<union> {k}. ?s i) k"

   991       by (simp only: ivl_disj_un_singleton)

   992     also have "... = coeff P p k"

   993       by (simp cong: R.finsum_cong

   994 	add: ivl_disj_int_singleton coeff_finsum deg_aboveD R RR Pi_def)

   995     finally show ?thesis .

   996   next

   997     case False

   998     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =

   999           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<deg R p} \<union> {deg R p}. ?s i) k"

  1000       by (simp only: ivl_disj_un_singleton)

  1001     also from False have "... = coeff P p k"

  1002       by (simp cong: R.finsum_cong

  1003 	add: ivl_disj_int_singleton coeff_finsum deg_aboveD R Pi_def)

  1004     finally show ?thesis .

  1005   qed

  1006 qed (simp_all add: R Pi_def)

  1007

  1008 lemma up_repr_le:

  1009   "[| deg R p <= n; p \<in> carrier P |] ==>

  1010   (\<Oplus>\<^bsub>P\<^esub> i \<in> {..n}. monom P (coeff P p i) i) = p"

  1011 proof -

  1012   let ?s = "(%i. monom P (coeff P p i) i)"

  1013   assume R: "p \<in> carrier P" and "deg R p <= n"

  1014   then have "finsum P ?s {..n} = finsum P ?s ({..deg R p} \<union> {deg R p<..n})"

  1015     by (simp only: ivl_disj_un_one)

  1016   also have "... = finsum P ?s {..deg R p}"

  1017     by (simp cong: P.finsum_cong add: P.finsum_Un_disjoint ivl_disj_int_one

  1018       deg_aboveD R Pi_def)

  1019   also have "... = p" using R by (rule up_repr)

  1020   finally show ?thesis .

  1021 qed

  1022

  1023 end

  1024

  1025

  1026 subsection {* Polynomials over Integral Domains *}

  1027

  1028 lemma domainI:

  1029   assumes cring: "cring R"

  1030     and one_not_zero: "one R ~= zero R"

  1031     and integral: "!!a b. [| mult R a b = zero R; a \<in> carrier R;

  1032       b \<in> carrier R |] ==> a = zero R | b = zero R"

  1033   shows "domain R"

  1034   by (auto intro!: domain.intro domain_axioms.intro cring.axioms assms

  1035     del: disjCI)

  1036

  1037 context UP_domain

  1038 begin

  1039

  1040 lemma UP_one_not_zero:

  1041   "\<one>\<^bsub>P\<^esub> ~= \<zero>\<^bsub>P\<^esub>"

  1042 proof

  1043   assume "\<one>\<^bsub>P\<^esub> = \<zero>\<^bsub>P\<^esub>"

  1044   hence "coeff P \<one>\<^bsub>P\<^esub> 0 = (coeff P \<zero>\<^bsub>P\<^esub> 0)" by simp

  1045   hence "\<one> = \<zero>" by simp

  1046   with R.one_not_zero show "False" by contradiction

  1047 qed

  1048

  1049 lemma UP_integral:

  1050   "[| p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==> p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"

  1051 proof -

  1052   fix p q

  1053   assume pq: "p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P" "q \<in> carrier P"

  1054   show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"

  1055   proof (rule classical)

  1056     assume c: "~ (p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>)"

  1057     with R have "deg R p + deg R q = deg R (p \<otimes>\<^bsub>P\<^esub> q)" by simp

  1058     also from pq have "... = 0" by simp

  1059     finally have "deg R p + deg R q = 0" .

  1060     then have f1: "deg R p = 0 & deg R q = 0" by simp

  1061     from f1 R have "p = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P p i) i)"

  1062       by (simp only: up_repr_le)

  1063     also from R have "... = monom P (coeff P p 0) 0" by simp

  1064     finally have p: "p = monom P (coeff P p 0) 0" .

  1065     from f1 R have "q = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P q i) i)"

  1066       by (simp only: up_repr_le)

  1067     also from R have "... = monom P (coeff P q 0) 0" by simp

  1068     finally have q: "q = monom P (coeff P q 0) 0" .

  1069     from R have "coeff P p 0 \<otimes> coeff P q 0 = coeff P (p \<otimes>\<^bsub>P\<^esub> q) 0" by simp

  1070     also from pq have "... = \<zero>" by simp

  1071     finally have "coeff P p 0 \<otimes> coeff P q 0 = \<zero>" .

  1072     with R have "coeff P p 0 = \<zero> | coeff P q 0 = \<zero>"

  1073       by (simp add: R.integral_iff)

  1074     with p q show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>" by fastsimp

  1075   qed

  1076 qed

  1077

  1078 theorem UP_domain:

  1079   "domain P"

  1080   by (auto intro!: domainI UP_cring UP_one_not_zero UP_integral del: disjCI)

  1081

  1082 end

  1083

  1084 text {*

  1085   Interpretation of theorems from @{term domain}.

  1086 *}

  1087

  1088 interpretation UP_domain < "domain" P

  1089   by intro_locales (rule domain.axioms UP_domain)+

  1090

  1091

  1092 subsection {* The Evaluation Homomorphism and Universal Property*}

  1093

  1094 (* alternative congruence rule (possibly more efficient)

  1095 lemma (in abelian_monoid) finsum_cong2:

  1096   "[| !!i. i \<in> A ==> f i \<in> carrier G = True; A = B;

  1097   !!i. i \<in> B ==> f i = g i |] ==> finsum G f A = finsum G g B"

  1098   sorry*)

  1099

  1100 lemma (in abelian_monoid) boundD_carrier:

  1101   "[| bound \<zero> n f; n < m |] ==> f m \<in> carrier G"

  1102   by auto

  1103

  1104 context ring

  1105 begin

  1106

  1107 theorem diagonal_sum:

  1108   "[| f \<in> {..n + m::nat} -> carrier R; g \<in> {..n + m} -> carrier R |] ==>

  1109   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =

  1110   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"

  1111 proof -

  1112   assume Rf: "f \<in> {..n + m} -> carrier R" and Rg: "g \<in> {..n + m} -> carrier R"

  1113   {

  1114     fix j

  1115     have "j <= n + m ==>

  1116       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =

  1117       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..j - k}. f k \<otimes> g i)"

  1118     proof (induct j)

  1119       case 0 from Rf Rg show ?case by (simp add: Pi_def)

  1120     next

  1121       case (Suc j)

  1122       have R6: "!!i k. [| k <= j; i <= Suc j - k |] ==> g i \<in> carrier R"

  1123         using Suc by (auto intro!: funcset_mem [OF Rg])

  1124       have R8: "!!i k. [| k <= Suc j; i <= k |] ==> g (k - i) \<in> carrier R"

  1125         using Suc by (auto intro!: funcset_mem [OF Rg])

  1126       have R9: "!!i k. [| k <= Suc j |] ==> f k \<in> carrier R"

  1127         using Suc by (auto intro!: funcset_mem [OF Rf])

  1128       have R10: "!!i k. [| k <= Suc j; i <= Suc j - k |] ==> g i \<in> carrier R"

  1129         using Suc by (auto intro!: funcset_mem [OF Rg])

  1130       have R11: "g 0 \<in> carrier R"

  1131         using Suc by (auto intro!: funcset_mem [OF Rg])

  1132       from Suc show ?case

  1133         by (simp cong: finsum_cong add: Suc_diff_le a_ac

  1134           Pi_def R6 R8 R9 R10 R11)

  1135     qed

  1136   }

  1137   then show ?thesis by fast

  1138 qed

  1139

  1140 theorem cauchy_product:

  1141   assumes bf: "bound \<zero> n f" and bg: "bound \<zero> m g"

  1142     and Rf: "f \<in> {..n} -> carrier R" and Rg: "g \<in> {..m} -> carrier R"

  1143   shows "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =

  1144     (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"      (* State reverse direction? *)

  1145 proof -

  1146   have f: "!!x. f x \<in> carrier R"

  1147   proof -

  1148     fix x

  1149     show "f x \<in> carrier R"

  1150       using Rf bf boundD_carrier by (cases "x <= n") (auto simp: Pi_def)

  1151   qed

  1152   have g: "!!x. g x \<in> carrier R"

  1153   proof -

  1154     fix x

  1155     show "g x \<in> carrier R"

  1156       using Rg bg boundD_carrier by (cases "x <= m") (auto simp: Pi_def)

  1157   qed

  1158   from f g have "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =

  1159       (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"

  1160     by (simp add: diagonal_sum Pi_def)

  1161   also have "... = (\<Oplus>k \<in> {..n} \<union> {n<..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"

  1162     by (simp only: ivl_disj_un_one)

  1163   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"

  1164     by (simp cong: finsum_cong

  1165       add: bound.bound [OF bf] finsum_Un_disjoint ivl_disj_int_one Pi_def)

  1166   also from f g

  1167   have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m} \<union> {m<..n + m - k}. f k \<otimes> g i)"

  1168     by (simp cong: finsum_cong add: ivl_disj_un_one le_add_diff Pi_def)

  1169   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m}. f k \<otimes> g i)"

  1170     by (simp cong: finsum_cong

  1171       add: bound.bound [OF bg] finsum_Un_disjoint ivl_disj_int_one Pi_def)

  1172   also from f g have "... = (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"

  1173     by (simp add: finsum_ldistr diagonal_sum Pi_def,

  1174       simp cong: finsum_cong add: finsum_rdistr Pi_def)

  1175   finally show ?thesis .

  1176 qed

  1177

  1178 end

  1179

  1180 lemma (in UP_ring) const_ring_hom:

  1181   "(%a. monom P a 0) \<in> ring_hom R P"

  1182   by (auto intro!: ring_hom_memI intro: up_eqI simp: monom_mult_is_smult)

  1183

  1184 definition

  1185   eval :: "[('a, 'm) ring_scheme, ('b, 'n) ring_scheme,

  1186            'a => 'b, 'b, nat => 'a] => 'b"

  1187   where "eval R S phi s == \<lambda>p \<in> carrier (UP R).

  1188     \<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. phi (coeff (UP R) p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i"

  1189

  1190 context UP

  1191 begin

  1192

  1193 lemma eval_on_carrier:

  1194   fixes S (structure)

  1195   shows "p \<in> carrier P ==>

  1196   eval R S phi s p = (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. phi (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1197   by (unfold eval_def, fold P_def) simp

  1198

  1199 lemma eval_extensional:

  1200   "eval R S phi p \<in> extensional (carrier P)"

  1201   by (unfold eval_def, fold P_def) simp

  1202

  1203 end

  1204

  1205 text {* The universal property of the polynomial ring *}

  1206

  1207 locale UP_pre_univ_prop = ring_hom_cring R S h + UP_cring R P

  1208

  1209 locale UP_univ_prop = UP_pre_univ_prop +

  1210   fixes s and Eval

  1211   assumes indet_img_carrier [simp, intro]: "s \<in> carrier S"

  1212   defines Eval_def: "Eval == eval R S h s"

  1213

  1214 text{*JE: I have moved the following lemma from Ring.thy and lifted then to the locale @{term ring_hom_ring} from @{term ring_hom_cring}.*}

  1215 text{*JE: I was considering using it in @{text eval_ring_hom}, but that property does not hold for non commutative rings, so

  1216   maybe it is not that necessary.*}

  1217

  1218 lemma (in ring_hom_ring) hom_finsum [simp]:

  1219   "[| finite A; f \<in> A -> carrier R |] ==>

  1220   h (finsum R f A) = finsum S (h o f) A"

  1221 proof (induct set: finite)

  1222   case empty then show ?case by simp

  1223 next

  1224   case insert then show ?case by (simp add: Pi_def)

  1225 qed

  1226

  1227 context UP_pre_univ_prop

  1228 begin

  1229

  1230 theorem eval_ring_hom:

  1231   assumes S: "s \<in> carrier S"

  1232   shows "eval R S h s \<in> ring_hom P S"

  1233 proof (rule ring_hom_memI)

  1234   fix p

  1235   assume R: "p \<in> carrier P"

  1236   then show "eval R S h s p \<in> carrier S"

  1237     by (simp only: eval_on_carrier) (simp add: S Pi_def)

  1238 next

  1239   fix p q

  1240   assume R: "p \<in> carrier P" "q \<in> carrier P"

  1241   then show "eval R S h s (p \<oplus>\<^bsub>P\<^esub> q) = eval R S h s p \<oplus>\<^bsub>S\<^esub> eval R S h s q"

  1242   proof (simp only: eval_on_carrier P.a_closed)

  1243     from S R have

  1244       "(\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =

  1245       (\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<oplus>\<^bsub>P\<^esub> q)<..max (deg R p) (deg R q)}.

  1246         h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1247       by (simp cong: S.finsum_cong

  1248         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def del: coeff_add)

  1249     also from R have "... =

  1250         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..max (deg R p) (deg R q)}.

  1251           h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1252       by (simp add: ivl_disj_un_one)

  1253     also from R S have "... =

  1254       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>

  1255       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1256       by (simp cong: S.finsum_cong

  1257         add: S.l_distr deg_aboveD ivl_disj_int_one Pi_def)

  1258     also have "... =

  1259         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p} \<union> {deg R p<..max (deg R p) (deg R q)}.

  1260           h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>

  1261         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q} \<union> {deg R q<..max (deg R p) (deg R q)}.

  1262           h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1263       by (simp only: ivl_disj_un_one le_maxI1 le_maxI2)

  1264     also from R S have "... =

  1265       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>

  1266       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1267       by (simp cong: S.finsum_cong

  1268         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)

  1269     finally show

  1270       "(\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =

  1271       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>

  1272       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .

  1273   qed

  1274 next

  1275   show "eval R S h s \<one>\<^bsub>P\<^esub> = \<one>\<^bsub>S\<^esub>"

  1276     by (simp only: eval_on_carrier UP_one_closed) simp

  1277 next

  1278   fix p q

  1279   assume R: "p \<in> carrier P" "q \<in> carrier P"

  1280   then show "eval R S h s (p \<otimes>\<^bsub>P\<^esub> q) = eval R S h s p \<otimes>\<^bsub>S\<^esub> eval R S h s q"

  1281   proof (simp only: eval_on_carrier UP_mult_closed)

  1282     from R S have

  1283       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =

  1284       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<otimes>\<^bsub>P\<^esub> q)<..deg R p + deg R q}.

  1285         h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1286       by (simp cong: S.finsum_cong

  1287         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def

  1288         del: coeff_mult)

  1289     also from R have "... =

  1290       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1291       by (simp only: ivl_disj_un_one deg_mult_ring)

  1292     also from R S have "... =

  1293       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}.

  1294          \<Oplus>\<^bsub>S\<^esub> k \<in> {..i}.

  1295            h (coeff P p k) \<otimes>\<^bsub>S\<^esub> h (coeff P q (i - k)) \<otimes>\<^bsub>S\<^esub>

  1296            (s (^)\<^bsub>S\<^esub> k \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> (i - k)))"

  1297       by (simp cong: S.finsum_cong add: S.nat_pow_mult Pi_def

  1298         S.m_ac S.finsum_rdistr)

  1299     also from R S have "... =

  1300       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>

  1301       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1302       by (simp add: S.cauchy_product [THEN sym] bound.intro deg_aboveD S.m_ac

  1303         Pi_def)

  1304     finally show

  1305       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =

  1306       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>

  1307       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .

  1308   qed

  1309 qed

  1310

  1311 text {*

  1312   The following lemma could be proved in @{text UP_cring} with the additional

  1313   assumption that @{text h} is closed. *}

  1314

  1315 lemma (in UP_pre_univ_prop) eval_const:

  1316   "[| s \<in> carrier S; r \<in> carrier R |] ==> eval R S h s (monom P r 0) = h r"

  1317   by (simp only: eval_on_carrier monom_closed) simp

  1318

  1319 text {* Further properties of the evaluation homomorphism. *}

  1320

  1321 text {* The following proof is complicated by the fact that in arbitrary

  1322   rings one might have @{term "one R = zero R"}. *}

  1323

  1324 (* TODO: simplify by cases "one R = zero R" *)

  1325

  1326 lemma (in UP_pre_univ_prop) eval_monom1:

  1327   assumes S: "s \<in> carrier S"

  1328   shows "eval R S h s (monom P \<one> 1) = s"

  1329 proof (simp only: eval_on_carrier monom_closed R.one_closed)

  1330    from S have

  1331     "(\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =

  1332     (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)} \<union> {deg R (monom P \<one> 1)<..1}.

  1333       h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1334     by (simp cong: S.finsum_cong del: coeff_monom

  1335       add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)

  1336   also have "... =

  1337     (\<Oplus>\<^bsub>S\<^esub> i \<in> {..1}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"

  1338     by (simp only: ivl_disj_un_one deg_monom_le R.one_closed)

  1339   also have "... = s"

  1340   proof (cases "s = \<zero>\<^bsub>S\<^esub>")

  1341     case True then show ?thesis by (simp add: Pi_def)

  1342   next

  1343     case False then show ?thesis by (simp add: S Pi_def)

  1344   qed

  1345   finally show "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (monom P \<one> 1)}.

  1346     h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) = s" .

  1347 qed

  1348

  1349 end

  1350

  1351 text {* Interpretation of ring homomorphism lemmas. *}

  1352

  1353 interpretation UP_univ_prop < ring_hom_cring P S Eval

  1354   apply (unfold Eval_def)

  1355   apply intro_locales

  1356   apply (rule ring_hom_cring.axioms)

  1357   apply (rule ring_hom_cring.intro)

  1358   apply unfold_locales

  1359   apply (rule eval_ring_hom)

  1360   apply rule

  1361   done

  1362

  1363 lemma (in UP_cring) monom_pow:

  1364   assumes R: "a \<in> carrier R"

  1365   shows "(monom P a n) (^)\<^bsub>P\<^esub> m = monom P (a (^) m) (n * m)"

  1366 proof (induct m)

  1367   case 0 from R show ?case by simp

  1368 next

  1369   case Suc with R show ?case

  1370     by (simp del: monom_mult add: monom_mult [THEN sym] add_commute)

  1371 qed

  1372

  1373 lemma (in ring_hom_cring) hom_pow [simp]:

  1374   "x \<in> carrier R ==> h (x (^) n) = h x (^)\<^bsub>S\<^esub> (n::nat)"

  1375   by (induct n) simp_all

  1376

  1377 lemma (in UP_univ_prop) Eval_monom:

  1378   "r \<in> carrier R ==> Eval (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"

  1379 proof -

  1380   assume R: "r \<in> carrier R"

  1381   from R have "Eval (monom P r n) = Eval (monom P r 0 \<otimes>\<^bsub>P\<^esub> (monom P \<one> 1) (^)\<^bsub>P\<^esub> n)"

  1382     by (simp del: monom_mult add: monom_mult [THEN sym] monom_pow)

  1383   also

  1384   from R eval_monom1 [where s = s, folded Eval_def]

  1385   have "... = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"

  1386     by (simp add: eval_const [where s = s, folded Eval_def])

  1387   finally show ?thesis .

  1388 qed

  1389

  1390 lemma (in UP_pre_univ_prop) eval_monom:

  1391   assumes R: "r \<in> carrier R" and S: "s \<in> carrier S"

  1392   shows "eval R S h s (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"

  1393 proof -

  1394   interpret UP_univ_prop [R S h P s _]

  1395     using UP_pre_univ_prop_axioms P_def R S

  1396     by (auto intro: UP_univ_prop.intro UP_univ_prop_axioms.intro)

  1397   from R

  1398   show ?thesis by (rule Eval_monom)

  1399 qed

  1400

  1401 lemma (in UP_univ_prop) Eval_smult:

  1402   "[| r \<in> carrier R; p \<in> carrier P |] ==> Eval (r \<odot>\<^bsub>P\<^esub> p) = h r \<otimes>\<^bsub>S\<^esub> Eval p"

  1403 proof -

  1404   assume R: "r \<in> carrier R" and P: "p \<in> carrier P"

  1405   then show ?thesis

  1406     by (simp add: monom_mult_is_smult [THEN sym]

  1407       eval_const [where s = s, folded Eval_def])

  1408 qed

  1409

  1410 lemma ring_hom_cringI:

  1411   assumes "cring R"

  1412     and "cring S"

  1413     and "h \<in> ring_hom R S"

  1414   shows "ring_hom_cring R S h"

  1415   by (fast intro: ring_hom_cring.intro ring_hom_cring_axioms.intro

  1416     cring.axioms assms)

  1417

  1418 context UP_pre_univ_prop

  1419 begin

  1420

  1421 lemma UP_hom_unique:

  1422   assumes "ring_hom_cring P S Phi"

  1423   assumes Phi: "Phi (monom P \<one> (Suc 0)) = s"

  1424       "!!r. r \<in> carrier R ==> Phi (monom P r 0) = h r"

  1425   assumes "ring_hom_cring P S Psi"

  1426   assumes Psi: "Psi (monom P \<one> (Suc 0)) = s"

  1427       "!!r. r \<in> carrier R ==> Psi (monom P r 0) = h r"

  1428     and P: "p \<in> carrier P" and S: "s \<in> carrier S"

  1429   shows "Phi p = Psi p"

  1430 proof -

  1431   interpret ring_hom_cring [P S Phi] by fact

  1432   interpret ring_hom_cring [P S Psi] by fact

  1433   have "Phi p =

  1434       Phi (\<Oplus>\<^bsub>P \<^esub>i \<in> {..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"

  1435     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)

  1436   also

  1437   have "... =

  1438       Psi (\<Oplus>\<^bsub>P \<^esub>i\<in>{..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"

  1439     by (simp add: Phi Psi P Pi_def comp_def)

  1440   also have "... = Psi p"

  1441     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)

  1442   finally show ?thesis .

  1443 qed

  1444

  1445 lemma ring_homD:

  1446   assumes Phi: "Phi \<in> ring_hom P S"

  1447   shows "ring_hom_cring P S Phi"

  1448 proof (rule ring_hom_cring.intro)

  1449   show "ring_hom_cring_axioms P S Phi"

  1450   by (rule ring_hom_cring_axioms.intro) (rule Phi)

  1451 qed unfold_locales

  1452

  1453 theorem UP_universal_property:

  1454   assumes S: "s \<in> carrier S"

  1455   shows "EX! Phi. Phi \<in> ring_hom P S \<inter> extensional (carrier P) &

  1456     Phi (monom P \<one> 1) = s &

  1457     (ALL r : carrier R. Phi (monom P r 0) = h r)"

  1458   using S eval_monom1

  1459   apply (auto intro: eval_ring_hom eval_const eval_extensional)

  1460   apply (rule extensionalityI)

  1461   apply (auto intro: UP_hom_unique ring_homD)

  1462   done

  1463

  1464 end

  1465

  1466 text{*JE: The following lemma was added by me; it might be even lifted to a simpler locale*}

  1467

  1468 context monoid

  1469 begin

  1470

  1471 lemma nat_pow_eone[simp]: assumes x_in_G: "x \<in> carrier G" shows "x (^) (1::nat) = x"

  1472   using nat_pow_Suc [of x 0] unfolding nat_pow_0 [of x] unfolding l_one [OF x_in_G] by simp

  1473

  1474 end

  1475

  1476 context UP_ring

  1477 begin

  1478

  1479 abbreviation lcoeff :: "(nat =>'a) => 'a" where "lcoeff p == coeff P p (deg R p)"

  1480

  1481 lemma lcoeff_nonzero2: assumes p_in_R: "p \<in> carrier P" and p_not_zero: "p \<noteq> \<zero>\<^bsub>P\<^esub>" shows "lcoeff p \<noteq> \<zero>"

  1482   using lcoeff_nonzero [OF p_not_zero p_in_R] .

  1483

  1484 subsection{*The long division algorithm: some previous facts.*}

  1485

  1486 lemma coeff_minus [simp]:

  1487   assumes p: "p \<in> carrier P" and q: "q \<in> carrier P" shows "coeff P (p \<ominus>\<^bsub>P\<^esub> q) n = coeff P p n \<ominus> coeff P q n"

  1488   unfolding a_minus_def [OF p q] unfolding coeff_add [OF p a_inv_closed [OF q]] unfolding coeff_a_inv [OF q]

  1489   using coeff_closed [OF p, of n] using coeff_closed [OF q, of n] by algebra

  1490

  1491 lemma lcoeff_closed [simp]: assumes p: "p \<in> carrier P" shows "lcoeff p \<in> carrier R"

  1492   using coeff_closed [OF p, of "deg R p"] by simp

  1493

  1494 lemma deg_smult_decr: assumes a_in_R: "a \<in> carrier R" and f_in_P: "f \<in> carrier P" shows "deg R (a \<odot>\<^bsub>P\<^esub> f) \<le> deg R f"

  1495   using deg_smult_ring [OF a_in_R f_in_P] by (cases "a = \<zero>", auto)

  1496

  1497 lemma coeff_monom_mult: assumes R: "c \<in> carrier R" and P: "p \<in> carrier P"

  1498   shows "coeff P (monom P c n \<otimes>\<^bsub>P\<^esub> p) (m + n) = c \<otimes> (coeff P p m)"

  1499 proof -

  1500   have "coeff P (monom P c n \<otimes>\<^bsub>P\<^esub> p) (m + n) = (\<Oplus>i\<in>{..m + n}. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i))"

  1501     unfolding coeff_mult [OF monom_closed [OF R, of n] P, of "m + n"] unfolding coeff_monom [OF R, of n] by simp

  1502   also have "(\<Oplus>i\<in>{..m + n}. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i)) =

  1503     (\<Oplus>i\<in>{..m + n}. (if n = i then c \<otimes> coeff P p (m + n - i) else \<zero>))"

  1504     using  R.finsum_cong [of "{..m + n}" "{..m + n}" "(\<lambda>i::nat. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i))"

  1505       "(\<lambda>i::nat. (if n = i then c \<otimes> coeff P p (m + n - i) else \<zero>))"]

  1506     using coeff_closed [OF P] unfolding Pi_def simp_implies_def using R by auto

  1507   also have "\<dots> = c \<otimes> coeff P p m" using R.finsum_singleton [of n "{..m + n}" "(\<lambda>i. c \<otimes> coeff P p (m + n - i))"]

  1508     unfolding Pi_def using coeff_closed [OF P] using P R by auto

  1509   finally show ?thesis by simp

  1510 qed

  1511

  1512 lemma deg_lcoeff_cancel:

  1513   assumes p_in_P: "p \<in> carrier P" and q_in_P: "q \<in> carrier P" and r_in_P: "r \<in> carrier P"

  1514   and deg_r_nonzero: "deg R r \<noteq> 0"

  1515   and deg_R_p: "deg R p \<le> deg R r" and deg_R_q: "deg R q \<le> deg R r"

  1516   and coeff_R_p_eq_q: "coeff P p (deg R r) = \<ominus>\<^bsub>R\<^esub> (coeff P q (deg R r))"

  1517   shows "deg R (p \<oplus>\<^bsub>P\<^esub> q) < deg R r"

  1518 proof -

  1519   have deg_le: "deg R (p \<oplus>\<^bsub>P\<^esub> q) \<le> deg R r"

  1520   proof (rule deg_aboveI)

  1521     fix m

  1522     assume deg_r_le: "deg R r < m"

  1523     show "coeff P (p \<oplus>\<^bsub>P\<^esub> q) m = \<zero>"

  1524     proof -

  1525       have slp: "deg R p < m" and "deg R q < m" using deg_R_p deg_R_q using deg_r_le by auto

  1526       then have max_sl: "max (deg R p) (deg R q) < m" by simp

  1527       then have "deg R (p \<oplus>\<^bsub>P\<^esub> q) < m" using deg_add [OF p_in_P q_in_P] by arith

  1528       with deg_R_p deg_R_q show ?thesis using coeff_add [OF p_in_P q_in_P, of m]

  1529 	using deg_aboveD [of "p \<oplus>\<^bsub>P\<^esub> q" m] using p_in_P q_in_P by simp

  1530     qed

  1531   qed (simp add: p_in_P q_in_P)

  1532   moreover have deg_ne: "deg R (p \<oplus>\<^bsub>P\<^esub> q) \<noteq> deg R r"

  1533   proof (rule ccontr)

  1534     assume nz: "\<not> deg R (p \<oplus>\<^bsub>P\<^esub> q) \<noteq> deg R r" then have deg_eq: "deg R (p \<oplus>\<^bsub>P\<^esub> q) = deg R r" by simp

  1535     from deg_r_nonzero have r_nonzero: "r \<noteq> \<zero>\<^bsub>P\<^esub>" by (cases "r = \<zero>\<^bsub>P\<^esub>", simp_all)

  1536     have "coeff P (p \<oplus>\<^bsub>P\<^esub> q) (deg R r) = \<zero>\<^bsub>R\<^esub>" using coeff_add [OF p_in_P q_in_P, of "deg R r"] using coeff_R_p_eq_q

  1537       using coeff_closed [OF p_in_P, of "deg R r"] coeff_closed [OF q_in_P, of "deg R r"] by algebra

  1538     with lcoeff_nonzero [OF r_nonzero r_in_P]  and deg_eq show False using lcoeff_nonzero [of "p \<oplus>\<^bsub>P\<^esub> q"] using p_in_P q_in_P

  1539       using deg_r_nonzero by (cases "p \<oplus>\<^bsub>P\<^esub> q \<noteq> \<zero>\<^bsub>P\<^esub>", auto)

  1540   qed

  1541   ultimately show ?thesis by simp

  1542 qed

  1543

  1544 lemma monom_deg_mult:

  1545   assumes f_in_P: "f \<in> carrier P" and g_in_P: "g \<in> carrier P" and deg_le: "deg R g \<le> deg R f"

  1546   and a_in_R: "a \<in> carrier R"

  1547   shows "deg R (g \<otimes>\<^bsub>P\<^esub> monom P a (deg R f - deg R g)) \<le> deg R f"

  1548   using deg_mult_ring [OF g_in_P monom_closed [OF a_in_R, of "deg R f - deg R g"]]

  1549   apply (cases "a = \<zero>") using g_in_P apply simp

  1550   using deg_monom [OF _ a_in_R, of "deg R f - deg R g"] using deg_le by simp

  1551

  1552 lemma deg_zero_impl_monom:

  1553   assumes f_in_P: "f \<in> carrier P" and deg_f: "deg R f = 0"

  1554   shows "f = monom P (coeff P f 0) 0"

  1555   apply (rule up_eqI) using coeff_monom [OF coeff_closed [OF f_in_P], of 0 0]

  1556   using f_in_P deg_f using deg_aboveD [of f _] by auto

  1557

  1558 end

  1559

  1560

  1561 subsection {* The long division proof for commutative rings *}

  1562

  1563 context UP_cring

  1564 begin

  1565

  1566 lemma exI3: assumes exist: "Pred x y z"

  1567   shows "\<exists> x y z. Pred x y z"

  1568   using exist by blast

  1569

  1570 text {* Jacobson's Theorem 2.14 *}

  1571

  1572 lemma long_div_theorem:

  1573   assumes g_in_P [simp]: "g \<in> carrier P" and f_in_P [simp]: "f \<in> carrier P"

  1574   and g_not_zero: "g \<noteq> \<zero>\<^bsub>P\<^esub>"

  1575   shows "\<exists> q r (k::nat). (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> (lcoeff g)(^)\<^bsub>R\<^esub>k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g)"

  1576 proof -

  1577   let ?pred = "(\<lambda> q r (k::nat).

  1578     (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> (lcoeff g)(^)\<^bsub>R\<^esub>k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g))"

  1579     and ?lg = "lcoeff g"

  1580   show ?thesis

  1581     (*JE: we distinguish some particular cases where the solution is almost direct.*)

  1582   proof (cases "deg R f < deg R g")

  1583     case True

  1584       (*JE: if the degree of f is smaller than the one of g the solution is straightforward.*)

  1585       (* CB: avoid exI3 *)

  1586       have "?pred \<zero>\<^bsub>P\<^esub> f 0" using True by force

  1587       then show ?thesis by fast

  1588   next

  1589     case False then have deg_g_le_deg_f: "deg R g \<le> deg R f" by simp

  1590     {

  1591       (*JE: we now apply the induction hypothesis with some additional facts required*)

  1592       from f_in_P deg_g_le_deg_f show ?thesis

  1593       proof (induct n \<equiv> "deg R f" arbitrary: "f" rule: nat_less_induct)

  1594 	fix n f

  1595 	assume hypo: "\<forall>m<n. \<forall>x. x \<in> carrier P \<longrightarrow>

  1596           deg R g \<le> deg R x \<longrightarrow>

  1597 	  m = deg R x \<longrightarrow>

  1598 	  (\<exists>q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and> lcoeff g (^) k \<odot>\<^bsub>P\<^esub> x = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r & (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g))"

  1599 	  and prem: "n = deg R f" and f_in_P [simp]: "f \<in> carrier P"

  1600 	  and deg_g_le_deg_f: "deg R g \<le> deg R f"

  1601 	let ?k = "1::nat" and ?r = "(g \<otimes>\<^bsub>P\<^esub> (monom P (lcoeff f) (deg R f - deg R g))) \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)"

  1602 	  and ?q = "monom P (lcoeff f) (deg R f - deg R g)"

  1603 	show "\<exists> q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and> lcoeff g (^) k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r & (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g)"

  1604 	proof -

  1605 	  (*JE: we first extablish the existence of a triple satisfying the previous equation.

  1606 	    Then we will have to prove the second part of the predicate.*)

  1607 	  have exist: "lcoeff g (^) ?k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r"

  1608 	    using minus_add

  1609 	    using sym [OF a_assoc [of "g \<otimes>\<^bsub>P\<^esub> ?q" "\<ominus>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q)" "lcoeff g \<odot>\<^bsub>P\<^esub> f"]]

  1610 	    using r_neg by auto

  1611 	  show ?thesis

  1612 	  proof (cases "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R g")

  1613 	    (*JE: if the degree of the remainder satisfies the statement property we are done*)

  1614 	    case True

  1615 	    {

  1616 	      show ?thesis

  1617 	      proof (rule exI3 [of _ ?q "\<ominus>\<^bsub>P\<^esub> ?r" ?k], intro conjI)

  1618 		show "lcoeff g (^) ?k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r" using exist by simp

  1619 		show "\<ominus>\<^bsub>P\<^esub> ?r = \<zero>\<^bsub>P\<^esub> \<or> deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R g" using True by simp

  1620 	      qed (simp_all)

  1621 	    }

  1622 	  next

  1623 	    case False note n_deg_r_l_deg_g = False

  1624 	    {

  1625 	      (*JE: otherwise, we verify the conditions of the induction hypothesis.*)

  1626 	      show ?thesis

  1627 	      proof (cases "deg R f = 0")

  1628 		(*JE: the solutions are different if the degree of f is zero or not*)

  1629 		case True

  1630 		{

  1631 		  have deg_g: "deg R g = 0" using True using deg_g_le_deg_f by simp

  1632 		  have "lcoeff g (^) (1::nat) \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> f \<oplus>\<^bsub>P\<^esub> \<zero>\<^bsub>P\<^esub>"

  1633 		    unfolding deg_g apply simp

  1634 		    unfolding sym [OF monom_mult_is_smult [OF coeff_closed [OF g_in_P, of 0] f_in_P]]

  1635 		    using deg_zero_impl_monom [OF g_in_P deg_g] by simp

  1636 		  then show ?thesis using f_in_P by blast

  1637 		}

  1638 	      next

  1639 		case False note deg_f_nzero = False

  1640 		{

  1641 		  (*JE: now it only remains the case where the induction hypothesis can be used.*)

  1642 		  (*JE: we first prove that the degree of the remainder is smaller than the one of f*)

  1643 		  have deg_remainder_l_f: "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < n"

  1644 		  proof -

  1645 		    have "deg R (\<ominus>\<^bsub>P\<^esub> ?r) = deg R ?r" using deg_uminus [of ?r] by simp

  1646 		    also have "\<dots> < deg R f"

  1647 		    proof (rule deg_lcoeff_cancel)

  1648 		      show "deg R (\<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)) \<le> deg R f"

  1649 			using deg_smult_ring [of "lcoeff g" f] using prem

  1650 			using lcoeff_nonzero2 [OF g_in_P g_not_zero] by simp

  1651 		      show "deg R (g \<otimes>\<^bsub>P\<^esub> ?q) \<le> deg R f"

  1652 			using monom_deg_mult [OF _ g_in_P, of f "lcoeff f"] and deg_g_le_deg_f

  1653 			by simp

  1654 		      show "coeff P (g \<otimes>\<^bsub>P\<^esub> ?q) (deg R f) = \<ominus> coeff P (\<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)) (deg R f)"

  1655 			unfolding coeff_mult [OF g_in_P monom_closed [OF lcoeff_closed [OF f_in_P], of "deg R f - deg R g"], of "deg R f"]

  1656 			unfolding coeff_monom [OF lcoeff_closed [OF f_in_P], of "(deg R f - deg R g)"]

  1657 			using R.finsum_cong' [of "{..deg R f}" "{..deg R f}"

  1658 			  "(\<lambda>i. coeff P g i \<otimes> (if deg R f - deg R g = deg R f - i then lcoeff f else \<zero>))"

  1659 			  "(\<lambda>i. if deg R g = i then coeff P g i \<otimes> lcoeff f else \<zero>)"]

  1660 			using R.finsum_singleton [of "deg R g" "{.. deg R f}" "(\<lambda>i. coeff P g i \<otimes> lcoeff f)"]

  1661 			unfolding Pi_def using deg_g_le_deg_f by force

  1662 		    qed (simp_all add: deg_f_nzero)

  1663 		    finally show "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < n" unfolding prem .

  1664 		  qed

  1665 		  moreover have "\<ominus>\<^bsub>P\<^esub> ?r \<in> carrier P" by simp

  1666 		  moreover obtain m where deg_rem_eq_m: "deg R (\<ominus>\<^bsub>P\<^esub> ?r) = m" by auto

  1667 		  moreover have "deg R g \<le> deg R (\<ominus>\<^bsub>P\<^esub> ?r)" using n_deg_r_l_deg_g by simp

  1668 		    (*JE: now, by applying the induction hypothesis, we obtain new quotient, remainder and exponent.*)

  1669 		  ultimately obtain q' r' k'

  1670 		    where rem_desc: "lcoeff g (^) (k'::nat) \<odot>\<^bsub>P\<^esub> (\<ominus>\<^bsub>P\<^esub> ?r) = g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r'"and rem_deg: "(r' = \<zero>\<^bsub>P\<^esub> \<or> deg R r' < deg R g)"

  1671 		    and q'_in_carrier: "q' \<in> carrier P" and r'_in_carrier: "r' \<in> carrier P"

  1672 		    using hypo by blast

  1673 		      (*JE: we now prove that the new quotient, remainder and exponent can be used to get

  1674 		      the quotient, remainder and exponent of the long division theorem*)

  1675 		  show ?thesis

  1676 		  proof (rule exI3 [of _ "((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q')" r' "Suc k'"], intro conjI)

  1677 		    show "(lcoeff g (^) (Suc k')) \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q') \<oplus>\<^bsub>P\<^esub> r'"

  1678 		    proof -

  1679 		      have "(lcoeff g (^) (Suc k')) \<odot>\<^bsub>P\<^esub> f = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r)"

  1680 			using smult_assoc1 exist by simp

  1681 		      also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ( \<ominus>\<^bsub>P\<^esub> ?r))"

  1682 			using UP_smult_r_distr by simp

  1683 		      also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r')"

  1684 			using rem_desc by simp

  1685 		      also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r'"

  1686 			using sym [OF a_assoc [of "lcoeff g (^) k' \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q)" "g \<otimes>\<^bsub>P\<^esub> q'" "r'"]]

  1687 			using q'_in_carrier r'_in_carrier by simp

  1688 		      also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (?q \<otimes>\<^bsub>P\<^esub> g) \<oplus>\<^bsub>P\<^esub> q' \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"

  1689 			using q'_in_carrier by (auto simp add: m_comm)

  1690 		      also have "\<dots> = (((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q) \<otimes>\<^bsub>P\<^esub> g) \<oplus>\<^bsub>P\<^esub> q' \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"

  1691 			using smult_assoc2 q'_in_carrier by auto

  1692 		      also have "\<dots> = ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q') \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"

  1693 			using sym [OF l_distr] and q'_in_carrier by auto

  1694 		      finally show ?thesis using m_comm q'_in_carrier by auto

  1695 		    qed

  1696 		  qed (simp_all add: rem_deg q'_in_carrier r'_in_carrier)

  1697 		}

  1698 	      qed

  1699 	    }

  1700 	  qed

  1701 	qed

  1702       qed

  1703     }

  1704   qed

  1705 qed

  1706

  1707 end

  1708

  1709

  1710 text {*The remainder theorem as corollary of the long division theorem.*}

  1711

  1712 context UP_cring

  1713 begin

  1714

  1715 lemma deg_minus_monom:

  1716   assumes a: "a \<in> carrier R"

  1717   and R_not_trivial: "(carrier R \<noteq> {\<zero>})"

  1718   shows "deg R (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = 1"

  1719   (is "deg R ?g = 1")

  1720 proof -

  1721   have "deg R ?g \<le> 1"

  1722   proof (rule deg_aboveI)

  1723     fix m

  1724     assume "(1::nat) < m"

  1725     then show "coeff P ?g m = \<zero>"

  1726       using coeff_minus using a by auto algebra

  1727   qed (simp add: a)

  1728   moreover have "deg R ?g \<ge> 1"

  1729   proof (rule deg_belowI)

  1730     show "coeff P ?g 1 \<noteq> \<zero>"

  1731       using a using R.carrier_one_not_zero R_not_trivial by simp algebra

  1732   qed (simp add: a)

  1733   ultimately show ?thesis by simp

  1734 qed

  1735

  1736 lemma lcoeff_monom:

  1737   assumes a: "a \<in> carrier R" and R_not_trivial: "(carrier R \<noteq> {\<zero>})"

  1738   shows "lcoeff (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = \<one>"

  1739   using deg_minus_monom [OF a R_not_trivial]

  1740   using coeff_minus a by auto algebra

  1741

  1742 lemma deg_nzero_nzero:

  1743   assumes deg_p_nzero: "deg R p \<noteq> 0"

  1744   shows "p \<noteq> \<zero>\<^bsub>P\<^esub>"

  1745   using deg_zero deg_p_nzero by auto

  1746

  1747 lemma deg_monom_minus:

  1748   assumes a: "a \<in> carrier R"

  1749   and R_not_trivial: "carrier R \<noteq> {\<zero>}"

  1750   shows "deg R (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = 1"

  1751   (is "deg R ?g = 1")

  1752 proof -

  1753   have "deg R ?g \<le> 1"

  1754   proof (rule deg_aboveI)

  1755     fix m::nat assume "1 < m" then show "coeff P ?g m = \<zero>"

  1756       using coeff_minus [OF monom_closed [OF R.one_closed, of 1] monom_closed [OF a, of 0], of m]

  1757       using coeff_monom [OF R.one_closed, of 1 m] using coeff_monom [OF a, of 0 m] by auto algebra

  1758   qed (simp add: a)

  1759   moreover have "1 \<le> deg R ?g"

  1760   proof (rule deg_belowI)

  1761     show "coeff P ?g 1 \<noteq> \<zero>"

  1762       using coeff_minus [OF monom_closed [OF R.one_closed, of 1] monom_closed [OF a, of 0], of 1]

  1763       using coeff_monom [OF R.one_closed, of 1 1] using coeff_monom [OF a, of 0 1]

  1764       using R_not_trivial using R.carrier_one_not_zero

  1765       by auto algebra

  1766   qed (simp add: a)

  1767   ultimately show ?thesis by simp

  1768 qed

  1769

  1770 lemma eval_monom_expr:

  1771   assumes a: "a \<in> carrier R"

  1772   shows "eval R R id a (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = \<zero>"

  1773   (is "eval R R id a ?g = _")

  1774 proof -

  1775   interpret UP_pre_univ_prop [R R id P] proof qed simp

  1776   have eval_ring_hom: "eval R R id a \<in> ring_hom P R" using eval_ring_hom [OF a] by simp

  1777   interpret ring_hom_cring [P R "eval R R id a"] proof qed (simp add: eval_ring_hom)

  1778   have mon1_closed: "monom P \<one>\<^bsub>R\<^esub> 1 \<in> carrier P"

  1779     and mon0_closed: "monom P a 0 \<in> carrier P"

  1780     and min_mon0_closed: "\<ominus>\<^bsub>P\<^esub> monom P a 0 \<in> carrier P"

  1781     using a R.a_inv_closed by auto

  1782   have "eval R R id a ?g = eval R R id a (monom P \<one> 1) \<ominus> eval R R id a (monom P a 0)"

  1783     unfolding P.minus_eq [OF mon1_closed mon0_closed]

  1784     unfolding R_S_h.hom_add [OF mon1_closed min_mon0_closed]

  1785     unfolding R_S_h.hom_a_inv [OF mon0_closed]

  1786     using R.minus_eq [symmetric] mon1_closed mon0_closed by auto

  1787   also have "\<dots> = a \<ominus> a"

  1788     using eval_monom [OF R.one_closed a, of 1] using eval_monom [OF a a, of 0] using a by simp

  1789   also have "\<dots> = \<zero>"

  1790     using a by algebra

  1791   finally show ?thesis by simp

  1792 qed

  1793

  1794 lemma remainder_theorem_exist:

  1795   assumes f: "f \<in> carrier P" and a: "a \<in> carrier R"

  1796   and R_not_trivial: "carrier R \<noteq> {\<zero>}"

  1797   shows "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (deg R r = 0)"

  1798   (is "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (deg R r = 0)")

  1799 proof -

  1800   let ?g = "monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0"

  1801   from deg_minus_monom [OF a R_not_trivial]

  1802   have deg_g_nzero: "deg R ?g \<noteq> 0" by simp

  1803   have "\<exists>q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and>

  1804     lcoeff ?g (^) k \<odot>\<^bsub>P\<^esub> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> \<or> deg R r < deg R ?g)"

  1805     using long_div_theorem [OF _ f deg_nzero_nzero [OF deg_g_nzero]] a

  1806     by auto

  1807   then show ?thesis

  1808     unfolding lcoeff_monom [OF a R_not_trivial]

  1809     unfolding deg_monom_minus [OF a R_not_trivial]

  1810     using smult_one [OF f] using deg_zero by force

  1811 qed

  1812

  1813 lemma remainder_theorem_expression:

  1814   assumes f [simp]: "f \<in> carrier P" and a [simp]: "a \<in> carrier R"

  1815   and q [simp]: "q \<in> carrier P" and r [simp]: "r \<in> carrier P"

  1816   and R_not_trivial: "carrier R \<noteq> {\<zero>}"

  1817   and f_expr: "f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r"

  1818   (is "f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r" is "f = ?gq \<oplus>\<^bsub>P\<^esub> r")

  1819     and deg_r_0: "deg R r = 0"

  1820     shows "r = monom P (eval R R id a f) 0"

  1821 proof -

  1822   interpret UP_pre_univ_prop [R R id P] proof qed simp

  1823   have eval_ring_hom: "eval R R id a \<in> ring_hom P R"

  1824     using eval_ring_hom [OF a] by simp

  1825   have "eval R R id a f = eval R R id a ?gq \<oplus>\<^bsub>R\<^esub> eval R R id a r"

  1826     unfolding f_expr using ring_hom_add [OF eval_ring_hom] by auto

  1827   also have "\<dots> = ((eval R R id a ?g) \<otimes> (eval R R id a q)) \<oplus>\<^bsub>R\<^esub> eval R R id a r"

  1828     using ring_hom_mult [OF eval_ring_hom] by auto

  1829   also have "\<dots> = \<zero> \<oplus> eval R R id a r"

  1830     unfolding eval_monom_expr [OF a] using eval_ring_hom

  1831     unfolding ring_hom_def using q unfolding Pi_def by simp

  1832   also have "\<dots> = eval R R id a r"

  1833     using eval_ring_hom unfolding ring_hom_def using r unfolding Pi_def by simp

  1834   finally have eval_eq: "eval R R id a f = eval R R id a r" by simp

  1835   from deg_zero_impl_monom [OF r deg_r_0]

  1836   have "r = monom P (coeff P r 0) 0" by simp

  1837   with eval_const [OF a, of "coeff P r 0"] eval_eq

  1838   show ?thesis by auto

  1839 qed

  1840

  1841 corollary remainder_theorem:

  1842   assumes f [simp]: "f \<in> carrier P" and a [simp]: "a \<in> carrier R"

  1843   and R_not_trivial: "carrier R \<noteq> {\<zero>}"

  1844   shows "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and>

  1845      f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> monom P (eval R R id a f) 0"

  1846   (is "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> monom P (eval R R id a f) 0")

  1847 proof -

  1848   from remainder_theorem_exist [OF f a R_not_trivial]

  1849   obtain q r

  1850     where q_r: "q \<in> carrier P \<and> r \<in> carrier P \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r"

  1851     and deg_r: "deg R r = 0" by force

  1852   with remainder_theorem_expression [OF f a _ _ R_not_trivial, of q r]

  1853   show ?thesis by auto

  1854 qed

  1855

  1856 end

  1857

  1858

  1859 subsection {* Sample Application of Evaluation Homomorphism *}

  1860

  1861 lemma UP_pre_univ_propI:

  1862   assumes "cring R"

  1863     and "cring S"

  1864     and "h \<in> ring_hom R S"

  1865   shows "UP_pre_univ_prop R S h"

  1866   using assms

  1867   by (auto intro!: UP_pre_univ_prop.intro ring_hom_cring.intro

  1868     ring_hom_cring_axioms.intro UP_cring.intro)

  1869

  1870 definition  INTEG :: "int ring"

  1871   where INTEG_def: "INTEG == (| carrier = UNIV, mult = op *, one = 1, zero = 0, add = op + |)"

  1872

  1873 lemma INTEG_cring:

  1874   "cring INTEG"

  1875   by (unfold INTEG_def) (auto intro!: cringI abelian_groupI comm_monoidI

  1876     zadd_zminus_inverse2 zadd_zmult_distrib)

  1877

  1878 lemma INTEG_id_eval:

  1879   "UP_pre_univ_prop INTEG INTEG id"

  1880   by (fast intro: UP_pre_univ_propI INTEG_cring id_ring_hom)

  1881

  1882 text {*

  1883   Interpretation now enables to import all theorems and lemmas

  1884   valid in the context of homomorphisms between @{term INTEG} and @{term

  1885   "UP INTEG"} globally.

  1886 *}

  1887

  1888 interpretation INTEG: UP_pre_univ_prop [INTEG INTEG id]

  1889   using INTEG_id_eval by simp_all

  1890

  1891 lemma INTEG_closed [intro, simp]:

  1892   "z \<in> carrier INTEG"

  1893   by (unfold INTEG_def) simp

  1894

  1895 lemma INTEG_mult [simp]:

  1896   "mult INTEG z w = z * w"

  1897   by (unfold INTEG_def) simp

  1898

  1899 lemma INTEG_pow [simp]:

  1900   "pow INTEG z n = z ^ n"

  1901   by (induct n) (simp_all add: INTEG_def nat_pow_def)

  1902

  1903 lemma "eval INTEG INTEG id 10 (monom (UP INTEG) 5 2) = 500"

  1904   by (simp add: INTEG.eval_monom)

  1905

  1906 end