src/HOL/Nat.thy
author haftmann
Mon Nov 17 17:00:55 2008 +0100 (2008-11-17)
changeset 28823 dcbef866c9e2
parent 28562 4e74209f113e
child 28952 15a4b2cf8c34
permissions -rw-r--r--
tuned unfold_locales invocation
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Inductive Ring_and_Field
    13 uses
    14   "~~/src/Tools/rat.ML"
    15   "~~/src/Provers/Arith/cancel_sums.ML"
    16   ("arith_data.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   inj_Suc_Rep:          "inj Suc_Rep" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 
    34 subsection {* Type nat *}
    35 
    36 text {* Type definition *}
    37 
    38 inductive Nat :: "ind \<Rightarrow> bool"
    39 where
    40     Zero_RepI: "Nat Zero_Rep"
    41   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    42 
    43 global
    44 
    45 typedef (open Nat)
    46   nat = Nat
    47   by (rule exI, unfold mem_def, rule Nat.Zero_RepI)
    48 
    49 constdefs
    50   Suc ::   "nat => nat"
    51   Suc_def: "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    52 
    53 local
    54 
    55 instantiation nat :: zero
    56 begin
    57 
    58 definition Zero_nat_def [code del]:
    59   "0 = Abs_Nat Zero_Rep"
    60 
    61 instance ..
    62 
    63 end
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   apply (simp add: Zero_nat_def Suc_def Abs_Nat_inject [unfolded mem_def]
    67     Rep_Nat [unfolded mem_def] Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def])
    68   done
    69 
    70 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    71   by (rule not_sym, rule Suc_not_Zero not_sym)
    72 
    73 rep_datatype "0 \<Colon> nat" Suc
    74   apply (unfold Zero_nat_def Suc_def)
    75      apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    76      apply (erule Rep_Nat [unfolded mem_def, THEN Nat.induct])
    77      apply (iprover elim: Abs_Nat_inverse [unfolded mem_def, THEN subst])
    78     apply (simp_all add: Abs_Nat_inject [unfolded mem_def] Rep_Nat [unfolded mem_def]
    79       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def]
    80       Suc_Rep_not_Zero_Rep [unfolded mem_def, symmetric]
    81       inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject)
    82   done
    83 
    84 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    85   -- {* for backward compatibility -- naming of variables differs *}
    86   fixes n
    87   assumes "P 0"
    88     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    89   shows "P n"
    90   using assms by (rule nat.induct) 
    91 
    92 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    93 
    94 lemmas nat_rec_0 = nat.recs(1)
    95   and nat_rec_Suc = nat.recs(2)
    96 
    97 lemmas nat_case_0 = nat.cases(1)
    98   and nat_case_Suc = nat.cases(2)
    99    
   100 
   101 text {* Injectiveness and distinctness lemmas *}
   102 
   103 lemma inj_Suc[simp]: "inj_on Suc N"
   104   by (simp add: inj_on_def)
   105 
   106 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   107 by (rule notE, rule Suc_not_Zero)
   108 
   109 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   110 by (rule Suc_neq_Zero, erule sym)
   111 
   112 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   113 by (rule inj_Suc [THEN injD])
   114 
   115 lemma n_not_Suc_n: "n \<noteq> Suc n"
   116 by (induct n) simp_all
   117 
   118 lemma Suc_n_not_n: "Suc n \<noteq> n"
   119 by (rule not_sym, rule n_not_Suc_n)
   120 
   121 text {* A special form of induction for reasoning
   122   about @{term "m < n"} and @{term "m - n"} *}
   123 
   124 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   125     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   126   apply (rule_tac x = m in spec)
   127   apply (induct n)
   128   prefer 2
   129   apply (rule allI)
   130   apply (induct_tac x, iprover+)
   131   done
   132 
   133 
   134 subsection {* Arithmetic operators *}
   135 
   136 instantiation nat :: "{minus, comm_monoid_add}"
   137 begin
   138 
   139 primrec plus_nat
   140 where
   141   add_0:      "0 + n = (n\<Colon>nat)"
   142   | add_Suc:  "Suc m + n = Suc (m + n)"
   143 
   144 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   145   by (induct m) simp_all
   146 
   147 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   148   by (induct m) simp_all
   149 
   150 declare add_0 [code]
   151 
   152 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   153   by simp
   154 
   155 primrec minus_nat
   156 where
   157   diff_0:     "m - 0 = (m\<Colon>nat)"
   158   | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   159 
   160 declare diff_Suc [simp del]
   161 declare diff_0 [code]
   162 
   163 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   164   by (induct n) (simp_all add: diff_Suc)
   165 
   166 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   167   by (induct n) (simp_all add: diff_Suc)
   168 
   169 instance proof
   170   fix n m q :: nat
   171   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   172   show "n + m = m + n" by (induct n) simp_all
   173   show "0 + n = n" by simp
   174 qed
   175 
   176 end
   177 
   178 instantiation nat :: comm_semiring_1_cancel
   179 begin
   180 
   181 definition
   182   One_nat_def [simp]: "1 = Suc 0"
   183 
   184 primrec times_nat
   185 where
   186   mult_0:     "0 * n = (0\<Colon>nat)"
   187   | mult_Suc: "Suc m * n = n + (m * n)"
   188 
   189 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   190   by (induct m) simp_all
   191 
   192 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   193   by (induct m) (simp_all add: add_left_commute)
   194 
   195 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   196   by (induct m) (simp_all add: add_assoc)
   197 
   198 instance proof
   199   fix n m q :: nat
   200   show "0 \<noteq> (1::nat)" by simp
   201   show "1 * n = n" by simp
   202   show "n * m = m * n" by (induct n) simp_all
   203   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   204   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   205   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   206 qed
   207 
   208 end
   209 
   210 subsubsection {* Addition *}
   211 
   212 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   213   by (rule add_assoc)
   214 
   215 lemma nat_add_commute: "m + n = n + (m::nat)"
   216   by (rule add_commute)
   217 
   218 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   219   by (rule add_left_commute)
   220 
   221 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   222   by (rule add_left_cancel)
   223 
   224 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   225   by (rule add_right_cancel)
   226 
   227 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   228 
   229 lemma add_is_0 [iff]:
   230   fixes m n :: nat
   231   shows "(m + n = 0) = (m = 0 & n = 0)"
   232   by (cases m) simp_all
   233 
   234 lemma add_is_1:
   235   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   236   by (cases m) simp_all
   237 
   238 lemma one_is_add:
   239   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   240   by (rule trans, rule eq_commute, rule add_is_1)
   241 
   242 lemma add_eq_self_zero:
   243   fixes m n :: nat
   244   shows "m + n = m \<Longrightarrow> n = 0"
   245   by (induct m) simp_all
   246 
   247 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   248   apply (induct k)
   249    apply simp
   250   apply(drule comp_inj_on[OF _ inj_Suc])
   251   apply (simp add:o_def)
   252   done
   253 
   254 
   255 subsubsection {* Difference *}
   256 
   257 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   258   by (induct m) simp_all
   259 
   260 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   261   by (induct i j rule: diff_induct) simp_all
   262 
   263 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   264   by (simp add: diff_diff_left)
   265 
   266 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   267   by (simp add: diff_diff_left add_commute)
   268 
   269 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   270   by (induct n) simp_all
   271 
   272 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   273   by (simp add: diff_add_inverse add_commute [of m n])
   274 
   275 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   276   by (induct k) simp_all
   277 
   278 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   279   by (simp add: diff_cancel add_commute)
   280 
   281 lemma diff_add_0: "n - (n + m) = (0::nat)"
   282   by (induct n) simp_all
   283 
   284 text {* Difference distributes over multiplication *}
   285 
   286 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   287 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   288 
   289 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   290 by (simp add: diff_mult_distrib mult_commute [of k])
   291   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   292 
   293 
   294 subsubsection {* Multiplication *}
   295 
   296 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   297   by (rule mult_assoc)
   298 
   299 lemma nat_mult_commute: "m * n = n * (m::nat)"
   300   by (rule mult_commute)
   301 
   302 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   303   by (rule right_distrib)
   304 
   305 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   306   by (induct m) auto
   307 
   308 lemmas nat_distrib =
   309   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   310 
   311 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   312   apply (induct m)
   313    apply simp
   314   apply (induct n)
   315    apply auto
   316   done
   317 
   318 lemma one_eq_mult_iff [simp,noatp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   319   apply (rule trans)
   320   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   321   done
   322 
   323 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   324 proof -
   325   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   326   proof (induct n arbitrary: m)
   327     case 0 then show "m = 0" by simp
   328   next
   329     case (Suc n) then show "m = Suc n"
   330       by (cases m) (simp_all add: eq_commute [of "0"])
   331   qed
   332   then show ?thesis by auto
   333 qed
   334 
   335 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   336   by (simp add: mult_commute)
   337 
   338 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   339   by (subst mult_cancel1) simp
   340 
   341 
   342 subsection {* Orders on @{typ nat} *}
   343 
   344 subsubsection {* Operation definition *}
   345 
   346 instantiation nat :: linorder
   347 begin
   348 
   349 primrec less_eq_nat where
   350   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   351   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   352 
   353 declare less_eq_nat.simps [simp del]
   354 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   355 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   356 
   357 definition less_nat where
   358   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   359 
   360 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   361   by (simp add: less_eq_nat.simps(2))
   362 
   363 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   364   unfolding less_eq_Suc_le ..
   365 
   366 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   367   by (induct n) (simp_all add: less_eq_nat.simps(2))
   368 
   369 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   370   by (simp add: less_eq_Suc_le)
   371 
   372 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   373   by simp
   374 
   375 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   376   by (simp add: less_eq_Suc_le)
   377 
   378 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   379   by (simp add: less_eq_Suc_le)
   380 
   381 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   382   by (induct m arbitrary: n)
   383     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   384 
   385 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   386   by (cases n) (auto intro: le_SucI)
   387 
   388 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   389   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   390 
   391 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   392   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   393 
   394 instance
   395 proof
   396   fix n m :: nat
   397   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   398   proof (induct n arbitrary: m)
   399     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   400   next
   401     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   402   qed
   403 next
   404   fix n :: nat show "n \<le> n" by (induct n) simp_all
   405 next
   406   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   407   then show "n = m"
   408     by (induct n arbitrary: m)
   409       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   410 next
   411   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   412   then show "n \<le> q"
   413   proof (induct n arbitrary: m q)
   414     case 0 show ?case by simp
   415   next
   416     case (Suc n) then show ?case
   417       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   418         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   419         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   420   qed
   421 next
   422   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   423     by (induct n arbitrary: m)
   424       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   425 qed
   426 
   427 end
   428 
   429 subsubsection {* Introduction properties *}
   430 
   431 lemma lessI [iff]: "n < Suc n"
   432   by (simp add: less_Suc_eq_le)
   433 
   434 lemma zero_less_Suc [iff]: "0 < Suc n"
   435   by (simp add: less_Suc_eq_le)
   436 
   437 
   438 subsubsection {* Elimination properties *}
   439 
   440 lemma less_not_refl: "~ n < (n::nat)"
   441   by (rule order_less_irrefl)
   442 
   443 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   444   by (rule not_sym) (rule less_imp_neq) 
   445 
   446 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   447   by (rule less_imp_neq)
   448 
   449 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   450   by (rule notE, rule less_not_refl)
   451 
   452 lemma less_zeroE: "(n::nat) < 0 ==> R"
   453   by (rule notE) (rule not_less0)
   454 
   455 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   456   unfolding less_Suc_eq_le le_less ..
   457 
   458 lemma less_one [iff, noatp]: "(n < (1::nat)) = (n = 0)"
   459   by (simp add: less_Suc_eq)
   460 
   461 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   462   by (simp add: less_Suc_eq)
   463 
   464 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   465   by simp
   466 
   467 text {* "Less than" is antisymmetric, sort of *}
   468 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   469   unfolding not_less less_Suc_eq_le by (rule antisym)
   470 
   471 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   472   by (rule linorder_neq_iff)
   473 
   474 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   475   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   476   shows "P n m"
   477   apply (rule less_linear [THEN disjE])
   478   apply (erule_tac [2] disjE)
   479   apply (erule lessCase)
   480   apply (erule sym [THEN eqCase])
   481   apply (erule major)
   482   done
   483 
   484 
   485 subsubsection {* Inductive (?) properties *}
   486 
   487 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   488   unfolding less_eq_Suc_le [of m] le_less by simp 
   489 
   490 lemma lessE:
   491   assumes major: "i < k"
   492   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   493   shows P
   494 proof -
   495   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   496     unfolding less_eq_Suc_le by (induct k) simp_all
   497   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   498     by (clarsimp simp add: less_le)
   499   with p1 p2 show P by auto
   500 qed
   501 
   502 lemma less_SucE: assumes major: "m < Suc n"
   503   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   504   apply (rule major [THEN lessE])
   505   apply (rule eq, blast)
   506   apply (rule less, blast)
   507   done
   508 
   509 lemma Suc_lessE: assumes major: "Suc i < k"
   510   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   511   apply (rule major [THEN lessE])
   512   apply (erule lessI [THEN minor])
   513   apply (erule Suc_lessD [THEN minor], assumption)
   514   done
   515 
   516 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   517   by simp
   518 
   519 lemma less_trans_Suc:
   520   assumes le: "i < j" shows "j < k ==> Suc i < k"
   521   apply (induct k, simp_all)
   522   apply (insert le)
   523   apply (simp add: less_Suc_eq)
   524   apply (blast dest: Suc_lessD)
   525   done
   526 
   527 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   528 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   529   unfolding not_less less_Suc_eq_le ..
   530 
   531 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   532   unfolding not_le Suc_le_eq ..
   533 
   534 text {* Properties of "less than or equal" *}
   535 
   536 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   537   unfolding less_Suc_eq_le .
   538 
   539 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   540   unfolding not_le less_Suc_eq_le ..
   541 
   542 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   543   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   544 
   545 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   546   by (drule le_Suc_eq [THEN iffD1], iprover+)
   547 
   548 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   549   unfolding Suc_le_eq .
   550 
   551 text {* Stronger version of @{text Suc_leD} *}
   552 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   553   unfolding Suc_le_eq .
   554 
   555 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   556   unfolding less_eq_Suc_le by (rule Suc_leD)
   557 
   558 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   559 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   560 
   561 
   562 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   563 
   564 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   565   unfolding le_less .
   566 
   567 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   568   by (rule le_less)
   569 
   570 text {* Useful with @{text blast}. *}
   571 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   572   by auto
   573 
   574 lemma le_refl: "n \<le> (n::nat)"
   575   by simp
   576 
   577 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   578   by (rule order_trans)
   579 
   580 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   581   by (rule antisym)
   582 
   583 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   584   by (rule less_le)
   585 
   586 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   587   unfolding less_le ..
   588 
   589 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   590   by (rule linear)
   591 
   592 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   593 
   594 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   595   unfolding less_Suc_eq_le by auto
   596 
   597 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   598   unfolding not_less by (rule le_less_Suc_eq)
   599 
   600 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   601 
   602 text {* These two rules ease the use of primitive recursion.
   603 NOTE USE OF @{text "=="} *}
   604 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   605 by simp
   606 
   607 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   608 by simp
   609 
   610 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   611 by (cases n) simp_all
   612 
   613 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   614 by (cases n) simp_all
   615 
   616 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   617 by (cases n) simp_all
   618 
   619 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   620 by (cases n) simp_all
   621 
   622 text {* This theorem is useful with @{text blast} *}
   623 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   624 by (rule neq0_conv[THEN iffD1], iprover)
   625 
   626 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   627 by (fast intro: not0_implies_Suc)
   628 
   629 lemma not_gr0 [iff,noatp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   630 using neq0_conv by blast
   631 
   632 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   633 by (induct m') simp_all
   634 
   635 text {* Useful in certain inductive arguments *}
   636 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   637 by (cases m) simp_all
   638 
   639 
   640 subsubsection {* @{term min} and @{term max} *}
   641 
   642 lemma mono_Suc: "mono Suc"
   643 by (rule monoI) simp
   644 
   645 lemma min_0L [simp]: "min 0 n = (0::nat)"
   646 by (rule min_leastL) simp
   647 
   648 lemma min_0R [simp]: "min n 0 = (0::nat)"
   649 by (rule min_leastR) simp
   650 
   651 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   652 by (simp add: mono_Suc min_of_mono)
   653 
   654 lemma min_Suc1:
   655    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   656 by (simp split: nat.split)
   657 
   658 lemma min_Suc2:
   659    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   660 by (simp split: nat.split)
   661 
   662 lemma max_0L [simp]: "max 0 n = (n::nat)"
   663 by (rule max_leastL) simp
   664 
   665 lemma max_0R [simp]: "max n 0 = (n::nat)"
   666 by (rule max_leastR) simp
   667 
   668 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   669 by (simp add: mono_Suc max_of_mono)
   670 
   671 lemma max_Suc1:
   672    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   673 by (simp split: nat.split)
   674 
   675 lemma max_Suc2:
   676    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   677 by (simp split: nat.split)
   678 
   679 
   680 subsubsection {* Monotonicity of Addition *}
   681 
   682 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   683 by (simp add: diff_Suc split: nat.split)
   684 
   685 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   686 by (induct k) simp_all
   687 
   688 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   689 by (induct k) simp_all
   690 
   691 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   692 by(auto dest:gr0_implies_Suc)
   693 
   694 text {* strict, in 1st argument *}
   695 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   696 by (induct k) simp_all
   697 
   698 text {* strict, in both arguments *}
   699 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   700   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   701   apply (induct j, simp_all)
   702   done
   703 
   704 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   705 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   706   apply (induct n)
   707   apply (simp_all add: order_le_less)
   708   apply (blast elim!: less_SucE
   709                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   710   done
   711 
   712 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   713 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   714 apply(auto simp: gr0_conv_Suc)
   715 apply (induct_tac m)
   716 apply (simp_all add: add_less_mono)
   717 done
   718 
   719 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   720 instance nat :: ordered_semidom
   721 proof
   722   fix i j k :: nat
   723   show "0 < (1::nat)" by simp
   724   show "i \<le> j ==> k + i \<le> k + j" by simp
   725   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   726 qed
   727 
   728 lemma nat_mult_1: "(1::nat) * n = n"
   729 by simp
   730 
   731 lemma nat_mult_1_right: "n * (1::nat) = n"
   732 by simp
   733 
   734 
   735 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   736 
   737 text {* Complete induction, aka course-of-values induction *}
   738 
   739 instance nat :: wellorder proof
   740   fix P and n :: nat
   741   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   742   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   743   proof (induct n)
   744     case (0 n)
   745     have "P 0" by (rule step) auto
   746     thus ?case using 0 by auto
   747   next
   748     case (Suc m n)
   749     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   750     thus ?case
   751     proof
   752       assume "n \<le> m" thus "P n" by (rule Suc(1))
   753     next
   754       assume n: "n = Suc m"
   755       show "P n"
   756         by (rule step) (rule Suc(1), simp add: n le_simps)
   757     qed
   758   qed
   759   then show "P n" by auto
   760 qed
   761 
   762 lemma Least_Suc:
   763      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   764   apply (case_tac "n", auto)
   765   apply (frule LeastI)
   766   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   767   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   768   apply (erule_tac [2] Least_le)
   769   apply (case_tac "LEAST x. P x", auto)
   770   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   771   apply (blast intro: order_antisym)
   772   done
   773 
   774 lemma Least_Suc2:
   775    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   776   apply (erule (1) Least_Suc [THEN ssubst])
   777   apply simp
   778   done
   779 
   780 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   781   apply (cases n)
   782    apply blast
   783   apply (rule_tac x="LEAST k. P(k)" in exI)
   784   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   785   done
   786 
   787 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   788   apply (cases n)
   789    apply blast
   790   apply (frule (1) ex_least_nat_le)
   791   apply (erule exE)
   792   apply (case_tac k)
   793    apply simp
   794   apply (rename_tac k1)
   795   apply (rule_tac x=k1 in exI)
   796   apply (auto simp add: less_eq_Suc_le)
   797   done
   798 
   799 lemma nat_less_induct:
   800   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   801   using assms less_induct by blast
   802 
   803 lemma measure_induct_rule [case_names less]:
   804   fixes f :: "'a \<Rightarrow> nat"
   805   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   806   shows "P a"
   807 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   808 
   809 text {* old style induction rules: *}
   810 lemma measure_induct:
   811   fixes f :: "'a \<Rightarrow> nat"
   812   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   813   by (rule measure_induct_rule [of f P a]) iprover
   814 
   815 lemma full_nat_induct:
   816   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   817   shows "P n"
   818   by (rule less_induct) (auto intro: step simp:le_simps)
   819 
   820 text{*An induction rule for estabilishing binary relations*}
   821 lemma less_Suc_induct:
   822   assumes less:  "i < j"
   823      and  step:  "!!i. P i (Suc i)"
   824      and  trans: "!!i j k. P i j ==> P j k ==> P i k"
   825   shows "P i j"
   826 proof -
   827   from less obtain k where j: "j = Suc(i+k)" by (auto dest: less_imp_Suc_add)
   828   have "P i (Suc (i + k))"
   829   proof (induct k)
   830     case 0
   831     show ?case by (simp add: step)
   832   next
   833     case (Suc k)
   834     thus ?case by (auto intro: assms)
   835   qed
   836   thus "P i j" by (simp add: j)
   837 qed
   838 
   839 lemma nat_induct2: "[|P 0; P (Suc 0); !!k. P k ==> P (Suc (Suc k))|] ==> P n"
   840   apply (rule nat_less_induct)
   841   apply (case_tac n)
   842   apply (case_tac [2] nat)
   843   apply (blast intro: less_trans)+
   844   done
   845 
   846 text {* The method of infinite descent, frequently used in number theory.
   847 Provided by Roelof Oosterhuis.
   848 $P(n)$ is true for all $n\in\mathbb{N}$ if
   849 \begin{itemize}
   850   \item case ``0'': given $n=0$ prove $P(n)$,
   851   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   852         a smaller integer $m$ such that $\neg P(m)$.
   853 \end{itemize} *}
   854 
   855 text{* A compact version without explicit base case: *}
   856 lemma infinite_descent:
   857   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   858 by (induct n rule: less_induct, auto)
   859 
   860 lemma infinite_descent0[case_names 0 smaller]: 
   861   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   862 by (rule infinite_descent) (case_tac "n>0", auto)
   863 
   864 text {*
   865 Infinite descent using a mapping to $\mathbb{N}$:
   866 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   867 \begin{itemize}
   868 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   869 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   870 \end{itemize}
   871 NB: the proof also shows how to use the previous lemma. *}
   872 
   873 corollary infinite_descent0_measure [case_names 0 smaller]:
   874   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   875     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   876   shows "P x"
   877 proof -
   878   obtain n where "n = V x" by auto
   879   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   880   proof (induct n rule: infinite_descent0)
   881     case 0 -- "i.e. $V(x) = 0$"
   882     with A0 show "P x" by auto
   883   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   884     case (smaller n)
   885     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   886     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   887     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   888     then show ?case by auto
   889   qed
   890   ultimately show "P x" by auto
   891 qed
   892 
   893 text{* Again, without explicit base case: *}
   894 lemma infinite_descent_measure:
   895 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   896 proof -
   897   from assms obtain n where "n = V x" by auto
   898   moreover have "!!x. V x = n \<Longrightarrow> P x"
   899   proof (induct n rule: infinite_descent, auto)
   900     fix x assume "\<not> P x"
   901     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   902   qed
   903   ultimately show "P x" by auto
   904 qed
   905 
   906 text {* A [clumsy] way of lifting @{text "<"}
   907   monotonicity to @{text "\<le>"} monotonicity *}
   908 lemma less_mono_imp_le_mono:
   909   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   910 by (simp add: order_le_less) (blast)
   911 
   912 
   913 text {* non-strict, in 1st argument *}
   914 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   915 by (rule add_right_mono)
   916 
   917 text {* non-strict, in both arguments *}
   918 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   919 by (rule add_mono)
   920 
   921 lemma le_add2: "n \<le> ((m + n)::nat)"
   922 by (insert add_right_mono [of 0 m n], simp)
   923 
   924 lemma le_add1: "n \<le> ((n + m)::nat)"
   925 by (simp add: add_commute, rule le_add2)
   926 
   927 lemma less_add_Suc1: "i < Suc (i + m)"
   928 by (rule le_less_trans, rule le_add1, rule lessI)
   929 
   930 lemma less_add_Suc2: "i < Suc (m + i)"
   931 by (rule le_less_trans, rule le_add2, rule lessI)
   932 
   933 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   934 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   935 
   936 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   937 by (rule le_trans, assumption, rule le_add1)
   938 
   939 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   940 by (rule le_trans, assumption, rule le_add2)
   941 
   942 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   943 by (rule less_le_trans, assumption, rule le_add1)
   944 
   945 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   946 by (rule less_le_trans, assumption, rule le_add2)
   947 
   948 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   949 apply (rule le_less_trans [of _ "i+j"])
   950 apply (simp_all add: le_add1)
   951 done
   952 
   953 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   954 apply (rule notI)
   955 apply (drule add_lessD1)
   956 apply (erule less_irrefl [THEN notE])
   957 done
   958 
   959 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   960 by (simp add: add_commute)
   961 
   962 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   963 apply (rule order_trans [of _ "m+k"])
   964 apply (simp_all add: le_add1)
   965 done
   966 
   967 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   968 apply (simp add: add_commute)
   969 apply (erule add_leD1)
   970 done
   971 
   972 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   973 by (blast dest: add_leD1 add_leD2)
   974 
   975 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   976 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   977 by (force simp del: add_Suc_right
   978     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   979 
   980 
   981 subsubsection {* More results about difference *}
   982 
   983 text {* Addition is the inverse of subtraction:
   984   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   985 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   986 by (induct m n rule: diff_induct) simp_all
   987 
   988 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   989 by (simp add: add_diff_inverse linorder_not_less)
   990 
   991 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   992 by (simp add: add_commute)
   993 
   994 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   995 by (induct m n rule: diff_induct) simp_all
   996 
   997 lemma diff_less_Suc: "m - n < Suc m"
   998 apply (induct m n rule: diff_induct)
   999 apply (erule_tac [3] less_SucE)
  1000 apply (simp_all add: less_Suc_eq)
  1001 done
  1002 
  1003 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1004 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1005 
  1006 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1007   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1008 
  1009 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1010 by (rule le_less_trans, rule diff_le_self)
  1011 
  1012 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1013 by (cases n) (auto simp add: le_simps)
  1014 
  1015 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1016 by (induct j k rule: diff_induct) simp_all
  1017 
  1018 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1019 by (simp add: add_commute diff_add_assoc)
  1020 
  1021 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1022 by (auto simp add: diff_add_inverse2)
  1023 
  1024 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1025 by (induct m n rule: diff_induct) simp_all
  1026 
  1027 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1028 by (rule iffD2, rule diff_is_0_eq)
  1029 
  1030 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1031 by (induct m n rule: diff_induct) simp_all
  1032 
  1033 lemma less_imp_add_positive:
  1034   assumes "i < j"
  1035   shows "\<exists>k::nat. 0 < k & i + k = j"
  1036 proof
  1037   from assms show "0 < j - i & i + (j - i) = j"
  1038     by (simp add: order_less_imp_le)
  1039 qed
  1040 
  1041 text {* a nice rewrite for bounded subtraction *}
  1042 lemma nat_minus_add_max:
  1043   fixes n m :: nat
  1044   shows "n - m + m = max n m"
  1045     by (simp add: max_def not_le order_less_imp_le)
  1046 
  1047 lemma nat_diff_split:
  1048   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1049     -- {* elimination of @{text -} on @{text nat} *}
  1050 by (cases "a < b")
  1051   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1052     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1053 
  1054 lemma nat_diff_split_asm:
  1055   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1056     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1057 by (auto split: nat_diff_split)
  1058 
  1059 
  1060 subsubsection {* Monotonicity of Multiplication *}
  1061 
  1062 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1063 by (simp add: mult_right_mono)
  1064 
  1065 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1066 by (simp add: mult_left_mono)
  1067 
  1068 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1069 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1070 by (simp add: mult_mono)
  1071 
  1072 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1073 by (simp add: mult_strict_right_mono)
  1074 
  1075 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1076       there are no negative numbers.*}
  1077 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1078   apply (induct m)
  1079    apply simp
  1080   apply (case_tac n)
  1081    apply simp_all
  1082   done
  1083 
  1084 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
  1085   apply (induct m)
  1086    apply simp
  1087   apply (case_tac n)
  1088    apply simp_all
  1089   done
  1090 
  1091 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1092   apply (safe intro!: mult_less_mono1)
  1093   apply (case_tac k, auto)
  1094   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1095   apply (blast intro: mult_le_mono1)
  1096   done
  1097 
  1098 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1099 by (simp add: mult_commute [of k])
  1100 
  1101 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1102 by (simp add: linorder_not_less [symmetric], auto)
  1103 
  1104 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1105 by (simp add: linorder_not_less [symmetric], auto)
  1106 
  1107 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1108 by (subst mult_less_cancel1) simp
  1109 
  1110 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1111 by (subst mult_le_cancel1) simp
  1112 
  1113 lemma le_square: "m \<le> m * (m::nat)"
  1114   by (cases m) (auto intro: le_add1)
  1115 
  1116 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1117   by (cases m) (auto intro: le_add1)
  1118 
  1119 text {* Lemma for @{text gcd} *}
  1120 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1121   apply (drule sym)
  1122   apply (rule disjCI)
  1123   apply (rule nat_less_cases, erule_tac [2] _)
  1124    apply (drule_tac [2] mult_less_mono2)
  1125     apply (auto)
  1126   done
  1127 
  1128 text {* the lattice order on @{typ nat} *}
  1129 
  1130 instantiation nat :: distrib_lattice
  1131 begin
  1132 
  1133 definition
  1134   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1135 
  1136 definition
  1137   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1138 
  1139 instance by intro_classes
  1140   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1141     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1142 
  1143 end
  1144 
  1145 
  1146 subsection {* Embedding of the Naturals into any
  1147   @{text semiring_1}: @{term of_nat} *}
  1148 
  1149 context semiring_1
  1150 begin
  1151 
  1152 primrec
  1153   of_nat :: "nat \<Rightarrow> 'a"
  1154 where
  1155   of_nat_0:     "of_nat 0 = 0"
  1156   | of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1157 
  1158 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1159   by simp
  1160 
  1161 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1162   by (induct m) (simp_all add: add_ac)
  1163 
  1164 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1165   by (induct m) (simp_all add: add_ac left_distrib)
  1166 
  1167 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1168   "of_nat_aux inc 0 i = i"
  1169   | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1170 
  1171 lemma of_nat_code [code, code unfold, code inline del]:
  1172   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1173 proof (induct n)
  1174   case 0 then show ?case by simp
  1175 next
  1176   case (Suc n)
  1177   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1178     by (induct n) simp_all
  1179   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1180     by simp
  1181   with Suc show ?case by (simp add: add_commute)
  1182 qed
  1183     
  1184 end
  1185 
  1186 text{*Class for unital semirings with characteristic zero.
  1187  Includes non-ordered rings like the complex numbers.*}
  1188 
  1189 class semiring_char_0 = semiring_1 +
  1190   assumes of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1191 begin
  1192 
  1193 text{*Special cases where either operand is zero*}
  1194 
  1195 lemma of_nat_0_eq_iff [simp, noatp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1196   by (rule of_nat_eq_iff [of 0, simplified])
  1197 
  1198 lemma of_nat_eq_0_iff [simp, noatp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1199   by (rule of_nat_eq_iff [of _ 0, simplified])
  1200 
  1201 lemma inj_of_nat: "inj of_nat"
  1202   by (simp add: inj_on_def)
  1203 
  1204 end
  1205 
  1206 context ordered_semidom
  1207 begin
  1208 
  1209 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1210   apply (induct m, simp_all)
  1211   apply (erule order_trans)
  1212   apply (rule ord_le_eq_trans [OF _ add_commute])
  1213   apply (rule less_add_one [THEN less_imp_le])
  1214   done
  1215 
  1216 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1217   apply (induct m n rule: diff_induct, simp_all)
  1218   apply (insert add_less_le_mono [OF zero_less_one zero_le_imp_of_nat], force)
  1219   done
  1220 
  1221 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1222   apply (induct m n rule: diff_induct, simp_all)
  1223   apply (insert zero_le_imp_of_nat)
  1224   apply (force simp add: not_less [symmetric])
  1225   done
  1226 
  1227 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1228   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1229 
  1230 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1231   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1232 
  1233 text{*Every @{text ordered_semidom} has characteristic zero.*}
  1234 
  1235 subclass semiring_char_0
  1236   proof qed (simp add: eq_iff order_eq_iff)
  1237 
  1238 text{*Special cases where either operand is zero*}
  1239 
  1240 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1241   by (rule of_nat_le_iff [of 0, simplified])
  1242 
  1243 lemma of_nat_le_0_iff [simp, noatp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1244   by (rule of_nat_le_iff [of _ 0, simplified])
  1245 
  1246 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1247   by (rule of_nat_less_iff [of 0, simplified])
  1248 
  1249 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1250   by (rule of_nat_less_iff [of _ 0, simplified])
  1251 
  1252 end
  1253 
  1254 context ring_1
  1255 begin
  1256 
  1257 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1258   by (simp add: compare_rls of_nat_add [symmetric])
  1259 
  1260 end
  1261 
  1262 context ordered_idom
  1263 begin
  1264 
  1265 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1266   unfolding abs_if by auto
  1267 
  1268 end
  1269 
  1270 lemma of_nat_id [simp]: "of_nat n = n"
  1271   by (induct n) auto
  1272 
  1273 lemma of_nat_eq_id [simp]: "of_nat = id"
  1274   by (auto simp add: expand_fun_eq)
  1275 
  1276 
  1277 subsection {* The Set of Natural Numbers *}
  1278 
  1279 context semiring_1
  1280 begin
  1281 
  1282 definition
  1283   Nats  :: "'a set" where
  1284   [code del]: "Nats = range of_nat"
  1285 
  1286 notation (xsymbols)
  1287   Nats  ("\<nat>")
  1288 
  1289 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1290   by (simp add: Nats_def)
  1291 
  1292 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1293 apply (simp add: Nats_def)
  1294 apply (rule range_eqI)
  1295 apply (rule of_nat_0 [symmetric])
  1296 done
  1297 
  1298 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1299 apply (simp add: Nats_def)
  1300 apply (rule range_eqI)
  1301 apply (rule of_nat_1 [symmetric])
  1302 done
  1303 
  1304 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1305 apply (auto simp add: Nats_def)
  1306 apply (rule range_eqI)
  1307 apply (rule of_nat_add [symmetric])
  1308 done
  1309 
  1310 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1311 apply (auto simp add: Nats_def)
  1312 apply (rule range_eqI)
  1313 apply (rule of_nat_mult [symmetric])
  1314 done
  1315 
  1316 end
  1317 
  1318 
  1319 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1320 
  1321 lemma subst_equals:
  1322   assumes 1: "t = s" and 2: "u = t"
  1323   shows "u = s"
  1324   using 2 1 by (rule trans)
  1325 
  1326 use "arith_data.ML"
  1327 declaration {* K ArithData.setup *}
  1328 
  1329 use "Tools/lin_arith.ML"
  1330 declaration {* K LinArith.setup *}
  1331 
  1332 lemmas [arith_split] = nat_diff_split split_min split_max
  1333 
  1334 
  1335 context order
  1336 begin
  1337 
  1338 lemma lift_Suc_mono_le:
  1339   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1340   shows "f n \<le> f n'"
  1341 proof (cases "n < n'")
  1342   case True
  1343   thus ?thesis
  1344     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1345 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1346 
  1347 lemma lift_Suc_mono_less:
  1348   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1349   shows "f n < f n'"
  1350 using `n < n'`
  1351 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1352 
  1353 lemma lift_Suc_mono_less_iff:
  1354   "(!!n. f n < f(Suc n)) \<Longrightarrow> f(n) < f(m) \<longleftrightarrow> n<m"
  1355 by(blast intro: less_asym' lift_Suc_mono_less[of f]
  1356          dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq[THEN iffD1])
  1357 
  1358 end
  1359 
  1360 
  1361 lemma mono_nat_linear_lb:
  1362   "(!!m n::nat. m<n \<Longrightarrow> f m < f n) \<Longrightarrow> f(m)+k \<le> f(m+k)"
  1363 apply(induct_tac k)
  1364  apply simp
  1365 apply(erule_tac x="m+n" in meta_allE)
  1366 apply(erule_tac x="m+n+1" in meta_allE)
  1367 apply simp
  1368 done
  1369 
  1370 
  1371 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1372 
  1373 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1374 by arith
  1375 
  1376 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1377 by arith
  1378 
  1379 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1380 by arith
  1381 
  1382 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1383 by arith
  1384 
  1385 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1386 by arith
  1387 
  1388 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1389 by arith
  1390 
  1391 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1392   second premise n\<le>m*)
  1393 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1394 by arith
  1395 
  1396 text {* Simplification of relational expressions involving subtraction *}
  1397 
  1398 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1399 by (simp split add: nat_diff_split)
  1400 
  1401 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1402 by (auto split add: nat_diff_split)
  1403 
  1404 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1405 by (auto split add: nat_diff_split)
  1406 
  1407 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1408 by (auto split add: nat_diff_split)
  1409 
  1410 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1411 
  1412 (* Monotonicity of subtraction in first argument *)
  1413 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1414 by (simp split add: nat_diff_split)
  1415 
  1416 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1417 by (simp split add: nat_diff_split)
  1418 
  1419 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1420 by (simp split add: nat_diff_split)
  1421 
  1422 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1423 by (simp split add: nat_diff_split)
  1424 
  1425 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1426 unfolding min_def by auto
  1427 
  1428 lemma inj_on_diff_nat: 
  1429   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1430   shows "inj_on (\<lambda>n. n - k) N"
  1431 proof (rule inj_onI)
  1432   fix x y
  1433   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1434   with k_le_n have "x - k + k = y - k + k" by auto
  1435   with a k_le_n show "x = y" by auto
  1436 qed
  1437 
  1438 text{*Rewriting to pull differences out*}
  1439 
  1440 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1441 by arith
  1442 
  1443 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1444 by arith
  1445 
  1446 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1447 by arith
  1448 
  1449 text{*Lemmas for ex/Factorization*}
  1450 
  1451 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1452 by (cases m) auto
  1453 
  1454 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1455 by (cases m) auto
  1456 
  1457 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1458 by (cases m) auto
  1459 
  1460 text {* Specialized induction principles that work "backwards": *}
  1461 
  1462 lemma inc_induct[consumes 1, case_names base step]:
  1463   assumes less: "i <= j"
  1464   assumes base: "P j"
  1465   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1466   shows "P i"
  1467   using less
  1468 proof (induct d=="j - i" arbitrary: i)
  1469   case (0 i)
  1470   hence "i = j" by simp
  1471   with base show ?case by simp
  1472 next
  1473   case (Suc d i)
  1474   hence "i < j" "P (Suc i)"
  1475     by simp_all
  1476   thus "P i" by (rule step)
  1477 qed
  1478 
  1479 lemma strict_inc_induct[consumes 1, case_names base step]:
  1480   assumes less: "i < j"
  1481   assumes base: "!!i. j = Suc i ==> P i"
  1482   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1483   shows "P i"
  1484   using less
  1485 proof (induct d=="j - i - 1" arbitrary: i)
  1486   case (0 i)
  1487   with `i < j` have "j = Suc i" by simp
  1488   with base show ?case by simp
  1489 next
  1490   case (Suc d i)
  1491   hence "i < j" "P (Suc i)"
  1492     by simp_all
  1493   thus "P i" by (rule step)
  1494 qed
  1495 
  1496 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1497   using inc_induct[of "k - i" k P, simplified] by blast
  1498 
  1499 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1500   using inc_induct[of 0 k P] by blast
  1501 
  1502 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
  1503   by auto
  1504 
  1505 (*The others are
  1506       i - j - k = i - (j + k),
  1507       k \<le> j ==> j - k + i = j + i - k,
  1508       k \<le> j ==> i + (j - k) = i + j - k *)
  1509 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1510 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1511 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1512 
  1513 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1514 Least_Suc}, since there appears to be no need.*}
  1515 
  1516 
  1517 subsection {* size of a datatype value *}
  1518 
  1519 class size = type +
  1520   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1521 
  1522 end